src/Pure/display.ML
author wenzelm
Tue Jan 12 13:14:22 1999 +0100 (1999-01-12)
changeset 6087 c8ec08fced15
parent 5902 c39b23d752b6
child 6279 eb4dc43023af
permissions -rw-r--r--
show_tags;
pretty/print_thms;
     1 (*  Title:      Pure/display.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Printing of theories, theorems, etc.
     7 *)
     8 
     9 signature DISPLAY =
    10 sig
    11   val show_hyps		: bool ref
    12   val show_tags		: bool ref
    13   val pretty_thm	: thm -> Pretty.T
    14   val pretty_thms	: thm list -> Pretty.T
    15   val string_of_thm	: thm -> string
    16   val pprint_thm	: thm -> pprint_args -> unit
    17   val print_thm		: thm -> unit
    18   val print_thms	: thm list -> unit
    19   val prth		: thm -> thm
    20   val prthq		: thm Seq.seq -> thm Seq.seq
    21   val prths		: thm list -> thm list
    22   val pretty_ctyp	: ctyp -> Pretty.T
    23   val pprint_ctyp	: ctyp -> pprint_args -> unit
    24   val string_of_ctyp	: ctyp -> string
    25   val print_ctyp	: ctyp -> unit
    26   val pretty_cterm	: cterm -> Pretty.T
    27   val pprint_cterm	: cterm -> pprint_args -> unit
    28   val string_of_cterm	: cterm -> string
    29   val print_cterm	: cterm -> unit
    30   val pretty_theory	: theory -> Pretty.T
    31   val pprint_theory	: theory -> pprint_args -> unit
    32   val print_syntax	: theory -> unit
    33   val print_theory	: theory -> unit
    34   val pretty_name_space : string * NameSpace.T -> Pretty.T
    35   val show_consts	: bool ref
    36 end;
    37 
    38 structure Display: DISPLAY =
    39 struct
    40 
    41 (** print thm **)
    42 
    43 val show_hyps = ref true;	(*false: print meta-hypotheses as dots*)
    44 val show_tags = ref false;	(*false: suppress tags*)
    45 
    46 fun pretty_tag (name, args) = Pretty.strs (name :: args);
    47 val pretty_tags = Pretty.list "[" "]" o map pretty_tag;
    48 
    49 fun pretty_thm th =
    50   let
    51     val {sign, hyps, prop, ...} = rep_thm th;
    52     val xshyps = Thm.extra_shyps th;
    53     val (_, tags) = Thm.get_name_tags th;
    54 
    55     val hlen = length xshyps + length hyps;
    56     val hsymbs =
    57       if hlen = 0 then []
    58       else if ! show_hyps then
    59         [Pretty.brk 2, Pretty.list "[" "]"
    60           (map (Sign.pretty_term sign) hyps @
    61            map (Sign.pretty_sort sign) xshyps)]
    62       else
    63         [Pretty.brk 2, Pretty.str ("[" ^ implode (replicate hlen ".") ^ "]")];
    64     val tsymbs =
    65       if null tags orelse not (! show_tags) then []
    66       else [Pretty.brk 1, pretty_tags tags];
    67   in Pretty.block (Sign.pretty_term sign prop :: (hsymbs @ tsymbs)) end;
    68 
    69 val string_of_thm = Pretty.string_of o pretty_thm;
    70 val pprint_thm = Pretty.pprint o Pretty.quote o pretty_thm;
    71 
    72 fun pretty_thms [th] = pretty_thm th
    73   | pretty_thms ths = Pretty.block (Pretty.fbreaks (map pretty_thm ths));
    74 
    75 
    76 (* top-level commands for printing theorems *)
    77 
    78 val print_thm = Pretty.writeln o pretty_thm;
    79 val print_thms = Pretty.writeln o pretty_thms;
    80 
    81 fun prth th = (print_thm th; th);
    82 
    83 (*Print and return a sequence of theorems, separated by blank lines. *)
    84 fun prthq thseq =
    85   (Seq.print (fn _ => print_thm) 100000 thseq; thseq);
    86 
    87 (*Print and return a list of theorems, separated by blank lines. *)
    88 fun prths ths = (seq (fn th => (print_thm th; writeln "")) ths; ths);
    89 
    90 
    91 (* other printing commands *)
    92 
    93 fun pretty_ctyp cT =
    94   let val {sign, T} = rep_ctyp cT in Sign.pretty_typ sign T end;
    95 
    96 fun pprint_ctyp cT =
    97   let val {sign, T} = rep_ctyp cT in Sign.pprint_typ sign T end;
    98 
    99 fun string_of_ctyp cT =
   100   let val {sign, T} = rep_ctyp cT in Sign.string_of_typ sign T end;
   101 
   102 val print_ctyp = writeln o string_of_ctyp;
   103 
   104 fun pretty_cterm ct =
   105   let val {sign, t, ...} = rep_cterm ct in Sign.pretty_term sign t end;
   106 
   107 fun pprint_cterm ct =
   108   let val {sign, t, ...} = rep_cterm ct in Sign.pprint_term sign t end;
   109 
   110 fun string_of_cterm ct =
   111   let val {sign, t, ...} = rep_cterm ct in Sign.string_of_term sign t end;
   112 
   113 val print_cterm = writeln o string_of_cterm;
   114 
   115 
   116 
   117 (** print theory **)
   118 
   119 val pretty_theory = Sign.pretty_sg o sign_of;
   120 val pprint_theory = Sign.pprint_sg o sign_of;
   121 
   122 val print_syntax = Syntax.print_syntax o syn_of;
   123 
   124 
   125 (* pretty_name_space  *)
   126 
   127 fun pretty_name_space (kind, space) =
   128   let
   129     fun prt_entry (name, accs) = Pretty.block
   130       (Pretty.str (quote name ^ " =") :: Pretty.brk 1 ::
   131         Pretty.commas (map (Pretty.str o quote) accs));
   132   in
   133     Pretty.fbreaks (Pretty.str (kind ^ ":") :: map prt_entry (NameSpace.dest space))
   134     |> Pretty.block
   135   end;
   136 
   137 
   138 
   139 (* print signature *)
   140 
   141 fun print_sign sg =
   142   let
   143     fun prt_cls c = Sign.pretty_sort sg [c];
   144     fun prt_sort S = Sign.pretty_sort sg S;
   145     fun prt_arity t (c, Ss) = Sign.pretty_arity sg (t, Ss, [c]);
   146     fun prt_typ ty = Pretty.quote (Sign.pretty_typ sg ty);
   147 
   148     val ext_class = Sign.cond_extern sg Sign.classK;
   149     val ext_tycon = Sign.cond_extern sg Sign.typeK;
   150     val ext_const = Sign.cond_extern sg Sign.constK;
   151 
   152 
   153     fun pretty_classes cs = Pretty.block
   154       (Pretty.breaks (Pretty.str "classes:" :: map prt_cls cs));
   155 
   156     fun pretty_classrel (c, cs) = Pretty.block
   157       (prt_cls c :: Pretty.str " <" :: Pretty.brk 1 ::
   158         Pretty.commas (map prt_cls cs));
   159 
   160     fun pretty_default S = Pretty.block
   161       [Pretty.str "default:", Pretty.brk 1, prt_sort S];
   162 
   163     fun pretty_ty (t, n) = Pretty.block
   164       [Pretty.str (ext_tycon t), Pretty.spc 1, Pretty.str (string_of_int n)];
   165 
   166     fun pretty_abbr (t, (vs, rhs)) = Pretty.block
   167       [prt_typ (Type (t, map (fn v => TVar ((v, 0), [])) vs)),
   168         Pretty.str " =", Pretty.brk 1, prt_typ rhs];
   169 
   170     fun pretty_arities (t, ars) = map (prt_arity t) ars;
   171 
   172     fun pretty_const (c, ty) = Pretty.block
   173       [Pretty.str c, Pretty.str " ::", Pretty.brk 1, prt_typ ty];
   174 
   175     val {self = _, tsig, const_tab, syn = _, path, spaces, data} = Sign.rep_sg sg;
   176     val spaces' = sort_wrt fst spaces;
   177     val {classes, classrel, default, tycons, abbrs, arities} =
   178       Type.rep_tsig tsig;
   179     val consts = sort_wrt fst (map (apfst ext_const) (Symtab.dest const_tab));
   180   in
   181     Pretty.writeln (Pretty.strs ("stamps:" :: Sign.stamp_names_of sg));
   182     Pretty.writeln (Pretty.strs ("data:" :: Sign.data_kinds data));
   183     Pretty.writeln (Pretty.strs ["name prefix:", NameSpace.pack path]);
   184     Pretty.writeln (Pretty.big_list "name spaces:" (map pretty_name_space spaces'));
   185     Pretty.writeln (pretty_classes classes);
   186     Pretty.writeln (Pretty.big_list "class relation:" (map pretty_classrel classrel));
   187     Pretty.writeln (pretty_default default);
   188     Pretty.writeln (Pretty.big_list "type constructors:" (map pretty_ty tycons));
   189     Pretty.writeln (Pretty.big_list "type abbreviations:" (map pretty_abbr abbrs));
   190     Pretty.writeln (Pretty.big_list "type arities:" (flat (map pretty_arities arities)));
   191     Pretty.writeln (Pretty.big_list "consts:" (map pretty_const consts))
   192   end;
   193 
   194 
   195 (* print axioms, oracles, theorems *)
   196 
   197 fun print_thy thy =
   198   let
   199     val {sign, axioms, oracles, ...} = rep_theory thy;
   200     val axioms = Symtab.dest axioms;
   201     val oras = map fst (Symtab.dest oracles);
   202 
   203     fun prt_axm (a, t) = Pretty.block
   204       [Pretty.str (Sign.cond_extern sign Theory.axiomK a ^ ":"), Pretty.brk 1,
   205         Pretty.quote (Sign.pretty_term sign t)];
   206   in
   207     Pretty.writeln (Pretty.big_list "axioms:" (map prt_axm axioms));
   208     Pretty.writeln (Pretty.strs ("oracles:" :: oras))
   209   end;
   210 
   211 fun print_theory thy = (print_sign (sign_of thy); print_thy thy);
   212 
   213 (*also show consts in case of showing types?*)
   214 val show_consts = ref false;
   215 
   216 
   217 end;
   218 
   219 open Display;