src/Pure/axclass.ML
author wenzelm
Fri Apr 12 14:54:14 2013 +0200 (2013-04-12)
changeset 51700 c8f2bad67dbb
parent 51685 385ef6706252
child 52230 1105b3b5aa77
permissions -rw-r--r--
tuned signature;
tuned comments;
     1 (*  Title:      Pure/axclass.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Type classes defined as predicates, associated with a record of
     5 parameters.  Proven class relations and type arities.
     6 *)
     7 
     8 signature AXCLASS =
     9 sig
    10   type info = {def: thm, intro: thm, axioms: thm list, params: (string * typ) list}
    11   val get_info: theory -> class -> info
    12   val class_of_param: theory -> string -> class option
    13   val instance_name: string * class -> string
    14   val thynames_of_arity: theory -> class * string -> string list
    15   val param_of_inst: theory -> string * string -> string
    16   val inst_of_param: theory -> string -> (string * string) option
    17   val unoverload: theory -> thm -> thm
    18   val overload: theory -> thm -> thm
    19   val unoverload_conv: theory -> conv
    20   val overload_conv: theory -> conv
    21   val lookup_inst_param: Consts.T -> ((string * string) * 'a) list -> string * typ -> 'a option
    22   val unoverload_const: theory -> string * typ -> string
    23   val cert_classrel: theory -> class * class -> class * class
    24   val read_classrel: theory -> xstring * xstring -> class * class
    25   val declare_overloaded: string * typ -> theory -> term * theory
    26   val define_overloaded: binding -> string * term -> theory -> thm * theory
    27   val add_classrel: thm -> theory -> theory
    28   val add_arity: thm -> theory -> theory
    29   val prove_classrel: class * class -> (Proof.context -> tactic) -> theory -> theory
    30   val prove_arity: string * sort list * sort -> (Proof.context -> tactic) -> theory -> theory
    31   val define_class: binding * class list -> string list ->
    32     (Thm.binding * term list) list -> theory -> class * theory
    33   val axiomatize_class: binding * class list -> theory -> theory
    34   val axiomatize_class_cmd: binding * xstring list -> theory -> theory
    35   val axiomatize_classrel: (class * class) list -> theory -> theory
    36   val axiomatize_classrel_cmd: (xstring * xstring) list -> theory -> theory
    37   val axiomatize_arity: arity -> theory -> theory
    38   val axiomatize_arity_cmd: xstring * string list * string -> theory -> theory
    39 end;
    40 
    41 structure Axclass: AXCLASS =
    42 struct
    43 
    44 (** theory data **)
    45 
    46 (* axclass info *)
    47 
    48 type info =
    49  {def: thm,
    50   intro: thm,
    51   axioms: thm list,
    52   params: (string * typ) list};
    53 
    54 fun make_axclass (def, intro, axioms, params): info =
    55   {def = def, intro = intro, axioms = axioms, params = params};
    56 
    57 
    58 (* class parameters (canonical order) *)
    59 
    60 type param = string * class;
    61 
    62 fun add_param ctxt ((x, c): param) params =
    63   (case AList.lookup (op =) params x of
    64     NONE => (x, c) :: params
    65   | SOME c' =>
    66       error ("Duplicate class parameter " ^ quote x ^ " for " ^ Syntax.string_of_sort ctxt [c] ^
    67         (if c = c' then "" else " and " ^ Syntax.string_of_sort ctxt [c'])));
    68 
    69 
    70 (* setup data *)
    71 
    72 datatype data = Data of
    73  {axclasses: info Symtab.table,
    74   params: param list,
    75   proven_classrels: thm Symreltab.table,
    76   proven_arities: ((class * sort list) * (thm * string)) list Symtab.table,
    77     (*arity theorems with theory name*)
    78   inst_params:
    79     (string * thm) Symtab.table Symtab.table *
    80       (*constant name ~> type constructor ~> (constant name, equation)*)
    81     (string * string) Symtab.table (*constant name ~> (constant name, type constructor)*)};
    82 
    83 fun make_data
    84     (axclasses, params, proven_classrels, proven_arities, inst_params) =
    85   Data {axclasses = axclasses, params = params, proven_classrels = proven_classrels,
    86     proven_arities = proven_arities, inst_params = inst_params};
    87 
    88 structure Data = Theory_Data_PP
    89 (
    90   type T = data;
    91   val empty =
    92     make_data (Symtab.empty, [], Symreltab.empty, Symtab.empty, (Symtab.empty, Symtab.empty));
    93   val extend = I;
    94   fun merge pp
    95       (Data {axclasses = axclasses1, params = params1, proven_classrels = proven_classrels1,
    96         proven_arities = proven_arities1, inst_params = inst_params1},
    97        Data {axclasses = axclasses2, params = params2, proven_classrels = proven_classrels2,
    98         proven_arities = proven_arities2, inst_params = inst_params2}) =
    99     let
   100       val ctxt = Syntax.init_pretty pp;
   101 
   102       val axclasses' = Symtab.merge (K true) (axclasses1, axclasses2);
   103       val params' =
   104         if null params1 then params2
   105         else
   106           fold_rev (fn p => if member (op =) params1 p then I else add_param ctxt p)
   107             params2 params1;
   108 
   109       (*see Theory.at_begin hook for transitive closure of classrels and arity completion*)
   110       val proven_classrels' = Symreltab.merge (K true) (proven_classrels1, proven_classrels2);
   111       val proven_arities' = Symtab.merge_list (eq_fst op =) (proven_arities1, proven_arities2);
   112 
   113       val inst_params' =
   114         (Symtab.join (K (Symtab.merge (K true))) (#1 inst_params1, #1 inst_params2),
   115           Symtab.merge (K true) (#2 inst_params1, #2 inst_params2));
   116     in
   117       make_data (axclasses', params', proven_classrels', proven_arities', inst_params')
   118     end;
   119 );
   120 
   121 fun map_data f =
   122   Data.map (fn Data {axclasses, params, proven_classrels, proven_arities, inst_params} =>
   123     make_data (f (axclasses, params, proven_classrels, proven_arities, inst_params)));
   124 
   125 fun map_axclasses f =
   126   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params) =>
   127     (f axclasses, params, proven_classrels, proven_arities, inst_params));
   128 
   129 fun map_params f =
   130   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params) =>
   131     (axclasses, f params, proven_classrels, proven_arities, inst_params));
   132 
   133 fun map_proven_classrels f =
   134   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params) =>
   135     (axclasses, params, f proven_classrels, proven_arities, inst_params));
   136 
   137 fun map_proven_arities f =
   138   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params) =>
   139     (axclasses, params, proven_classrels, f proven_arities, inst_params));
   140 
   141 fun map_inst_params f =
   142   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params) =>
   143     (axclasses, params, proven_classrels, proven_arities, f inst_params));
   144 
   145 val rep_data = Data.get #> (fn Data args => args);
   146 
   147 val axclasses_of = #axclasses o rep_data;
   148 val params_of = #params o rep_data;
   149 val proven_classrels_of = #proven_classrels o rep_data;
   150 val proven_arities_of = #proven_arities o rep_data;
   151 val inst_params_of = #inst_params o rep_data;
   152 
   153 
   154 (* axclasses with parameters *)
   155 
   156 fun get_info thy c =
   157   (case Symtab.lookup (axclasses_of thy) c of
   158     SOME info => info
   159   | NONE => error ("No such axclass: " ^ quote c));
   160 
   161 fun all_params_of thy S =
   162   let val params = params_of thy;
   163   in fold (fn (x, c) => if Sign.subsort thy (S, [c]) then cons x else I) params [] end;
   164 
   165 fun class_of_param thy = AList.lookup (op =) (params_of thy);
   166 
   167 
   168 (* maintain instances *)
   169 
   170 val classrel_prefix = "classrel_";
   171 val arity_prefix = "arity_";
   172 
   173 fun instance_name (a, c) = Long_Name.base_name c ^ "_" ^ Long_Name.base_name a;
   174 
   175 
   176 val update_classrel = map_proven_classrels o Symreltab.update;
   177 
   178 val is_classrel = Symreltab.defined o proven_classrels_of;
   179 
   180 fun the_classrel thy (c1, c2) =
   181   (case Symreltab.lookup (proven_classrels_of thy) (c1, c2) of
   182     SOME thm => Thm.transfer thy thm
   183   | NONE => error ("Unproven class relation " ^
   184       Syntax.string_of_classrel (Proof_Context.init_global thy) [c1, c2]));
   185 
   186 fun complete_classrels thy =
   187   let
   188     fun complete (c, (_, (all_preds, all_succs))) (finished1, thy1) =
   189       let
   190         fun compl c1 c2 (finished2, thy2) =
   191           if is_classrel thy2 (c1, c2) then (finished2, thy2)
   192           else
   193             (false,
   194               thy2
   195               |> update_classrel ((c1, c2),
   196                 (the_classrel thy2 (c1, c) RS the_classrel thy2 (c, c2))
   197                 |> Drule.instantiate' [SOME (ctyp_of thy2 (TVar ((Name.aT, 0), [])))] []
   198                 |> Thm.close_derivation));
   199 
   200         val proven = is_classrel thy1;
   201         val preds = Graph.Keys.fold (fn c1 => proven (c1, c) ? cons c1) all_preds [];
   202         val succs = Graph.Keys.fold (fn c2 => proven (c, c2) ? cons c2) all_succs [];
   203       in
   204         fold_product compl preds succs (finished1, thy1)
   205       end;
   206   in
   207     (case Graph.fold complete (Sorts.classes_of (Sign.classes_of thy)) (true, thy) of
   208       (true, _) => NONE
   209     | (_, thy') => SOME thy')
   210   end;
   211 
   212 
   213 fun the_arity thy (a, Ss, c) =
   214   (case AList.lookup (op =) (Symtab.lookup_list (proven_arities_of thy) a) (c, Ss) of
   215     SOME (thm, _) => Thm.transfer thy thm
   216   | NONE => error ("Unproven type arity " ^
   217       Syntax.string_of_arity (Proof_Context.init_global thy) (a, Ss, [c])));
   218 
   219 fun thynames_of_arity thy (c, a) =
   220   Symtab.lookup_list (proven_arities_of thy) a
   221   |> map_filter (fn ((c', _), (_, name)) => if c = c' then SOME name else NONE)
   222   |> rev;
   223 
   224 fun insert_arity_completions thy t ((c, Ss), ((th, thy_name))) (finished, arities) =
   225   let
   226     val algebra = Sign.classes_of thy;
   227     val ars = Symtab.lookup_list arities t;
   228     val super_class_completions =
   229       Sign.super_classes thy c
   230       |> filter_out (fn c1 => exists (fn ((c2, Ss2), _) =>
   231             c1 = c2 andalso Sorts.sorts_le algebra (Ss2, Ss)) ars);
   232 
   233     val names = Name.invent Name.context Name.aT (length Ss);
   234     val std_vars = map (fn a => SOME (ctyp_of thy (TVar ((a, 0), [])))) names;
   235 
   236     val completions = super_class_completions |> map (fn c1 =>
   237       let
   238         val th1 =
   239           (th RS the_classrel thy (c, c1))
   240           |> Drule.instantiate' std_vars []
   241           |> Thm.close_derivation;
   242       in ((th1, thy_name), c1) end);
   243 
   244     val finished' = finished andalso null completions;
   245     val arities' = fold (fn (th, c1) => Symtab.cons_list (t, ((c1, Ss), th))) completions arities;
   246   in (finished', arities') end;
   247 
   248 fun put_arity_completion ((t, Ss, c), th) thy =
   249   let val ar = ((c, Ss), (th, Context.theory_name thy)) in
   250     thy
   251     |> map_proven_arities
   252       (Symtab.insert_list (eq_fst op =) (t, ar) #>
   253        curry (insert_arity_completions thy t ar) true #> #2)
   254   end;
   255 
   256 fun complete_arities thy =
   257   let
   258     val arities = proven_arities_of thy;
   259     val (finished, arities') =
   260       Symtab.fold (fn (t, ars) => fold (insert_arity_completions thy t) ars)
   261         arities (true, arities);
   262   in
   263     if finished then NONE
   264     else SOME (map_proven_arities (K arities') thy)
   265   end;
   266 
   267 val _ = Context.>> (Context.map_theory
   268   (Theory.at_begin complete_classrels #>
   269    Theory.at_begin complete_arities));
   270 
   271 val _ = Proofterm.install_axclass_proofs
   272   {classrel_proof = Thm.proof_of oo the_classrel,
   273    arity_proof = Thm.proof_of oo the_arity};
   274 
   275 
   276 (* maintain instance parameters *)
   277 
   278 fun get_inst_param thy (c, tyco) =
   279   (case Symtab.lookup (the_default Symtab.empty (Symtab.lookup (#1 (inst_params_of thy)) c)) tyco of
   280     SOME c' => c'
   281   | NONE => error ("No instance parameter for constant " ^ quote c ^ " on type " ^ quote tyco));
   282 
   283 fun add_inst_param (c, tyco) inst =
   284   (map_inst_params o apfst o Symtab.map_default (c, Symtab.empty)) (Symtab.update_new (tyco, inst))
   285   #> (map_inst_params o apsnd) (Symtab.update_new (#1 inst, (c, tyco)));
   286 
   287 val inst_of_param = Symtab.lookup o #2 o inst_params_of;
   288 val param_of_inst = #1 oo get_inst_param;
   289 
   290 fun inst_thms thy =
   291   Symtab.fold (Symtab.fold (cons o #2 o #2) o #2) (#1 (inst_params_of thy)) [];
   292 
   293 fun get_inst_tyco consts = try (#1 o dest_Type o the_single o Consts.typargs consts);
   294 
   295 fun unoverload thy = Raw_Simplifier.simplify true (inst_thms thy);
   296 fun overload thy = Raw_Simplifier.simplify true (map Thm.symmetric (inst_thms thy));
   297 
   298 fun unoverload_conv thy = Raw_Simplifier.rewrite true (inst_thms thy);
   299 fun overload_conv thy = Raw_Simplifier.rewrite true (map Thm.symmetric (inst_thms thy));
   300 
   301 fun lookup_inst_param consts params (c, T) =
   302   (case get_inst_tyco consts (c, T) of
   303     SOME tyco => AList.lookup (op =) params (c, tyco)
   304   | NONE => NONE);
   305 
   306 fun unoverload_const thy (c_ty as (c, _)) =
   307   if is_some (class_of_param thy c) then
   308     (case get_inst_tyco (Sign.consts_of thy) c_ty of
   309       SOME tyco => try (param_of_inst thy) (c, tyco) |> the_default c
   310     | NONE => c)
   311   else c;
   312 
   313 
   314 
   315 (** instances **)
   316 
   317 (* class relations *)
   318 
   319 fun cert_classrel thy raw_rel =
   320   let
   321     val string_of_sort = Syntax.string_of_sort_global thy;
   322     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
   323     val _ = Sign.primitive_classrel (c1, c2) (Theory.copy thy);
   324     val _ =
   325       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
   326         [] => ()
   327       | xs => raise TYPE ("Class " ^ string_of_sort [c1] ^ " lacks parameter(s) " ^
   328           commas_quote xs ^ " of " ^ string_of_sort [c2], [], []));
   329   in (c1, c2) end;
   330 
   331 fun read_classrel thy raw_rel =
   332   cert_classrel thy (pairself (Proof_Context.read_class (Proof_Context.init_global thy)) raw_rel)
   333     handle TYPE (msg, _, _) => error msg;
   334 
   335 
   336 (* declaration and definition of instances of overloaded constants *)
   337 
   338 fun inst_tyco_of thy (c, T) =
   339   (case get_inst_tyco (Sign.consts_of thy) (c, T) of
   340     SOME tyco => tyco
   341   | NONE => error ("Illegal type for instantiation of class parameter: " ^
   342       quote (c ^ " :: " ^ Syntax.string_of_typ_global thy T)));
   343 
   344 fun declare_overloaded (c, T) thy =
   345   let
   346     val class =
   347       (case class_of_param thy c of
   348         SOME class => class
   349       | NONE => error ("Not a class parameter: " ^ quote c));
   350     val tyco = inst_tyco_of thy (c, T);
   351     val name_inst = instance_name (tyco, class) ^ "_inst";
   352     val c' = instance_name (tyco, c);
   353     val T' = Type.strip_sorts T;
   354   in
   355     thy
   356     |> Sign.qualified_path true (Binding.name name_inst)
   357     |> Sign.declare_const_global ((Binding.name c', T'), NoSyn)
   358     |-> (fn const' as Const (c'', _) =>
   359       Thm.add_def_global false true
   360         (Binding.name (Thm.def_name c'), Logic.mk_equals (Const (c, T'), const'))
   361       #>> apsnd Thm.varifyT_global
   362       #-> (fn (_, thm) => add_inst_param (c, tyco) (c'', thm)
   363         #> Global_Theory.add_thm ((Binding.conceal (Binding.name c'), thm), [])
   364         #> #2
   365         #> pair (Const (c, T))))
   366     ||> Sign.restore_naming thy
   367   end;
   368 
   369 fun define_overloaded b (c, t) thy =
   370   let
   371     val T = Term.fastype_of t;
   372     val tyco = inst_tyco_of thy (c, T);
   373     val (c', eq) = get_inst_param thy (c, tyco);
   374     val prop = Logic.mk_equals (Const (c', T), t);
   375     val b' = Thm.def_binding_optional (Binding.name (instance_name (tyco, c))) b;
   376   in
   377     thy
   378     |> Thm.add_def_global false false (b', prop)
   379     |>> (fn (_, thm) => Drule.transitive_thm OF [eq, thm])
   380   end;
   381 
   382 
   383 (* primitive rules *)
   384 
   385 fun add_classrel raw_th thy =
   386   let
   387     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   388     val prop = Thm.plain_prop_of th;
   389     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
   390     val rel = Logic.dest_classrel prop handle TERM _ => err ();
   391     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
   392     val (th', thy') =
   393       Global_Theory.store_thm
   394         (Binding.name (prefix classrel_prefix (Logic.name_classrel (c1, c2))), th) thy;
   395     val th'' = th'
   396       |> Thm.unconstrainT
   397       |> Drule.instantiate' [SOME (ctyp_of thy' (TVar ((Name.aT, 0), [])))] [];
   398   in
   399     thy'
   400     |> Sign.primitive_classrel (c1, c2)
   401     |> map_proven_classrels (Symreltab.update ((c1, c2), th''))
   402     |> perhaps complete_classrels
   403     |> perhaps complete_arities
   404   end;
   405 
   406 fun add_arity raw_th thy =
   407   let
   408     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   409     val prop = Thm.plain_prop_of th;
   410     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
   411     val arity as (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
   412 
   413     val (th', thy') =
   414       Global_Theory.store_thm
   415         (Binding.name (prefix arity_prefix (Logic.name_arity arity)), th) thy;
   416 
   417     val args = Name.invent_names Name.context Name.aT Ss;
   418     val T = Type (t, map TFree args);
   419     val std_vars = map (fn (a, S) => SOME (ctyp_of thy' (TVar ((a, 0), [])))) args;
   420 
   421     val missing_params = Sign.complete_sort thy' [c]
   422       |> maps (these o Option.map #params o try (get_info thy'))
   423       |> filter_out (fn (const, _) => can (get_inst_param thy') (const, t))
   424       |> (map o apsnd o map_atyps) (K T);
   425     val th'' = th'
   426       |> Thm.unconstrainT
   427       |> Drule.instantiate' std_vars [];
   428   in
   429     thy'
   430     |> fold (#2 oo declare_overloaded) missing_params
   431     |> Sign.primitive_arity (t, Ss, [c])
   432     |> put_arity_completion ((t, Ss, c), th'')
   433   end;
   434 
   435 
   436 (* tactical proofs *)
   437 
   438 fun prove_classrel raw_rel tac thy =
   439   let
   440     val ctxt = Proof_Context.init_global thy;
   441     val (c1, c2) = cert_classrel thy raw_rel;
   442     val th =
   443       Goal.prove ctxt [] [] (Logic.mk_classrel (c1, c2)) (fn {context, ...} => tac context)
   444         handle ERROR msg =>
   445           cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
   446             quote (Syntax.string_of_classrel ctxt [c1, c2]));
   447   in
   448     thy |> add_classrel th
   449   end;
   450 
   451 fun prove_arity raw_arity tac thy =
   452   let
   453     val ctxt = Proof_Context.init_global thy;
   454     val arity = Proof_Context.cert_arity ctxt raw_arity;
   455     val names = map (prefix arity_prefix) (Logic.name_arities arity);
   456     val props = Logic.mk_arities arity;
   457     val ths =
   458       Goal.prove_multi ctxt [] [] props
   459       (fn {context, ...} => Goal.precise_conjunction_tac (length props) 1 THEN tac context)
   460         handle ERROR msg =>
   461           cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
   462             quote (Syntax.string_of_arity ctxt arity));
   463   in
   464     thy |> fold add_arity ths
   465   end;
   466 
   467 
   468 
   469 (** class definitions **)
   470 
   471 fun split_defined n eq =
   472   let
   473     val intro =
   474       (eq RS Drule.equal_elim_rule2)
   475       |> Conjunction.curry_balanced n
   476       |> n = 0 ? Thm.eq_assumption 1;
   477     val dests =
   478       if n = 0 then []
   479       else
   480         (eq RS Drule.equal_elim_rule1)
   481         |> Balanced_Tree.dest (fn th =>
   482           (th RS Conjunction.conjunctionD1, th RS Conjunction.conjunctionD2)) n;
   483   in (intro, dests) end;
   484 
   485 fun define_class (bclass, raw_super) raw_params raw_specs thy =
   486   let
   487     val ctxt = Syntax.init_pretty_global thy;
   488 
   489 
   490     (* class *)
   491 
   492     val bconst = Binding.map_name Logic.const_of_class bclass;
   493     val class = Sign.full_name thy bclass;
   494     val super = Sign.minimize_sort thy (Sign.certify_sort thy raw_super);
   495 
   496     fun check_constraint (a, S) =
   497       if Sign.subsort thy (super, S) then ()
   498       else error ("Sort constraint of type variable " ^
   499         Syntax.string_of_typ (Config.put show_sorts true ctxt) (TFree (a, S)) ^
   500         " needs to be weaker than " ^ Syntax.string_of_sort ctxt super);
   501 
   502 
   503     (* params *)
   504 
   505     val params = raw_params |> map (fn p =>
   506       let
   507         val T = Sign.the_const_type thy p;
   508         val _ =
   509           (case Term.add_tvarsT T [] of
   510             [((a, _), S)] => check_constraint (a, S)
   511           | _ => error ("Exactly one type variable expected in class parameter " ^ quote p));
   512         val T' = Term.map_type_tvar (fn _ => TFree (Name.aT, [class])) T;
   513       in (p, T') end);
   514 
   515 
   516     (* axioms *)
   517 
   518     fun prep_axiom t =
   519       (case Term.add_tfrees t [] of
   520         [(a, S)] => check_constraint (a, S)
   521       | [] => ()
   522       | _ => error ("Multiple type variables in class axiom:\n" ^ Syntax.string_of_term ctxt t);
   523       t
   524       |> Term.map_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
   525       |> Logic.close_form);
   526 
   527     val axiomss = map (map (prep_axiom o Sign.cert_prop thy) o snd) raw_specs;
   528     val name_atts = map fst raw_specs;
   529 
   530 
   531     (* definition *)
   532 
   533     val conjs = Logic.mk_of_sort (Term.aT [], super) @ flat axiomss;
   534     val class_eq =
   535       Logic.mk_equals (Logic.mk_of_class (Term.aT [], class), Logic.mk_conjunction_balanced conjs);
   536 
   537     val ([def], def_thy) =
   538       thy
   539       |> Sign.primitive_class (bclass, super)
   540       |> Global_Theory.add_defs false [((Thm.def_binding bconst, class_eq), [])];
   541     val (raw_intro, (raw_classrel, raw_axioms)) =
   542       split_defined (length conjs) def ||> chop (length super);
   543 
   544 
   545     (* facts *)
   546 
   547     val class_triv = Thm.class_triv def_thy class;
   548     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
   549       def_thy
   550       |> Sign.qualified_path true bconst
   551       |> Global_Theory.note_thmss ""
   552         [((Binding.name "intro", []), [([Drule.export_without_context raw_intro], [])]),
   553          ((Binding.name "super", []), [(map Drule.export_without_context raw_classrel, [])]),
   554          ((Binding.name "axioms", []),
   555            [(map (fn th => Drule.export_without_context (class_triv RS th)) raw_axioms, [])])]
   556       ||> Sign.restore_naming def_thy;
   557 
   558 
   559     (* result *)
   560 
   561     val axclass = make_axclass (def, intro, axioms, params);
   562     val result_thy =
   563       facts_thy
   564       |> map_proven_classrels
   565           (fold2 (fn c => fn th => Symreltab.update ((class, c), th)) super classrel)
   566       |> perhaps complete_classrels
   567       |> Sign.qualified_path false bconst
   568       |> Global_Theory.note_thmss "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms))
   569       |> #2
   570       |> Sign.restore_naming facts_thy
   571       |> map_axclasses (Symtab.update (class, axclass))
   572       |> map_params (fold (fn (x, _) => add_param ctxt (x, class)) params);
   573 
   574   in (class, result_thy) end;
   575 
   576 
   577 
   578 (** axiomatizations **)
   579 
   580 local
   581 
   582 (*old-style axioms*)
   583 fun axiomatize prep mk name add raw_args thy =
   584   let
   585     val args = prep thy raw_args;
   586     val specs = mk args;
   587     val names = name args;
   588   in
   589     thy
   590     |> fold_map Thm.add_axiom_global (map Binding.name names ~~ specs)
   591     |-> fold (add o Drule.export_without_context o snd)
   592   end;
   593 
   594 fun ax_classrel prep =
   595   axiomatize (map o prep) (map Logic.mk_classrel)
   596     (map (prefix classrel_prefix o Logic.name_classrel)) add_classrel;
   597 
   598 fun ax_arity prep =
   599   axiomatize (prep o Proof_Context.init_global) Logic.mk_arities
   600     (map (prefix arity_prefix) o Logic.name_arities) add_arity;
   601 
   602 fun class_const c =
   603   (Logic.const_of_class c, Term.itselfT (Term.aT []) --> propT);
   604 
   605 fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
   606   let
   607     val class = Sign.full_name thy bclass;
   608     val super = map (prep_class thy) raw_super |> Sign.minimize_sort thy;
   609   in
   610     thy
   611     |> Sign.primitive_class (bclass, super)
   612     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
   613     |> Theory.add_deps_global "" (class_const class) (map class_const super)
   614   end;
   615 
   616 in
   617 
   618 val axiomatize_class = ax_class Sign.certify_class cert_classrel;
   619 val axiomatize_class_cmd =
   620   ax_class (Proof_Context.read_class o Proof_Context.init_global) read_classrel;
   621 val axiomatize_classrel = ax_classrel cert_classrel;
   622 val axiomatize_classrel_cmd = ax_classrel read_classrel;
   623 val axiomatize_arity = ax_arity Proof_Context.cert_arity;
   624 val axiomatize_arity_cmd = ax_arity Proof_Context.read_arity;
   625 
   626 end;
   627 
   628 end;