src/Pure/net.ML
author wenzelm
Fri Apr 12 14:54:14 2013 +0200 (2013-04-12)
changeset 51700 c8f2bad67dbb
parent 45404 69ec395ef6ca
child 55741 b969263fcf02
permissions -rw-r--r--
tuned signature;
tuned comments;
     1 (*  Title:      Pure/net.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1993  University of Cambridge
     4 
     5 Discrimination nets: a data structure for indexing items
     6 
     7 From the book
     8     E. Charniak, C. K. Riesbeck, D. V. McDermott.
     9     Artificial Intelligence Programming.
    10     (Lawrence Erlbaum Associates, 1980).  [Chapter 14]
    11 
    12 match_term no longer treats abstractions as wildcards; instead they match
    13 only wildcards in patterns.  Requires operands to be beta-eta-normal.
    14 *)
    15 
    16 signature NET =
    17 sig
    18   type key
    19   val key_of_term: term -> key list
    20   val encode_type: typ -> term
    21   type 'a net
    22   val empty: 'a net
    23   exception INSERT
    24   val insert: ('a * 'a -> bool) -> key list * 'a -> 'a net -> 'a net
    25   val insert_term: ('a * 'a -> bool) -> term * 'a -> 'a net -> 'a net
    26   val insert_safe: ('a * 'a -> bool) -> key list * 'a -> 'a net -> 'a net
    27   val insert_term_safe: ('a * 'a -> bool) -> term * 'a -> 'a net -> 'a net
    28   exception DELETE
    29   val delete: ('b * 'a -> bool) -> key list * 'b -> 'a net -> 'a net
    30   val delete_term: ('b * 'a -> bool) -> term * 'b -> 'a net -> 'a net
    31   val delete_safe: ('b * 'a -> bool) -> key list * 'b -> 'a net -> 'a net
    32   val delete_term_safe: ('b * 'a -> bool) -> term * 'b -> 'a net -> 'a net
    33   val lookup: 'a net -> key list -> 'a list
    34   val match_term: 'a net -> term -> 'a list
    35   val unify_term: 'a net -> term -> 'a list
    36   val entries: 'a net -> 'a list
    37   val subtract: ('b * 'a -> bool) -> 'a net -> 'b net -> 'b list
    38   val merge: ('a * 'a -> bool) -> 'a net * 'a net -> 'a net
    39   val content: 'a net -> 'a list
    40 end;
    41 
    42 structure Net: NET =
    43 struct
    44 
    45 datatype key = CombK | VarK | AtomK of string;
    46 
    47 (*Keys are preorder lists of symbols -- Combinations, Vars, Atoms.
    48   Any term whose head is a Var is regarded entirely as a Var.
    49   Abstractions are also regarded as Vars;  this covers eta-conversion
    50     and "near" eta-conversions such as %x.?P(?f(x)).
    51 *)
    52 fun add_key_of_terms (t, cs) =
    53   let fun rands (f$t, cs) = CombK :: rands (f, add_key_of_terms(t, cs))
    54         | rands (Const(c,_), cs) = AtomK c :: cs
    55         | rands (Free(c,_),  cs) = AtomK c :: cs
    56         | rands (Bound i,  cs)   = AtomK (Name.bound i) :: cs
    57   in case head_of t of
    58       Var _ => VarK :: cs
    59     | Abs _ => VarK :: cs
    60     | _     => rands(t,cs)
    61   end;
    62 
    63 (*convert a term to a list of keys*)
    64 fun key_of_term t = add_key_of_terms (t, []);
    65 
    66 (*encode_type -- for indexing purposes*)
    67 fun encode_type (Type (c, Ts)) = Term.list_comb (Const (c, dummyT), map encode_type Ts)
    68   | encode_type (TFree (a, _)) = Free (a, dummyT)
    69   | encode_type (TVar (a, _)) = Var (a, dummyT);
    70 
    71 
    72 (*Trees indexed by key lists: each arc is labelled by a key.
    73   Each node contains a list of items, and arcs to children.
    74   The empty key addresses the entire net.
    75   Lookup functions preserve order in items stored at same level.
    76 *)
    77 datatype 'a net = Leaf of 'a list
    78                 | Net of {comb: 'a net,
    79                           var: 'a net,
    80                           atoms: 'a net Symtab.table};
    81 
    82 val empty = Leaf[];
    83 fun is_empty (Leaf []) = true | is_empty _ = false;
    84 val emptynet = Net{comb=empty, var=empty, atoms=Symtab.empty};
    85 
    86 
    87 (*** Insertion into a discrimination net ***)
    88 
    89 exception INSERT;       (*duplicate item in the net*)
    90 
    91 
    92 (*Adds item x to the list at the node addressed by the keys.
    93   Creates node if not already present.
    94   eq is the equality test for items.
    95   The empty list of keys generates a Leaf node, others a Net node.
    96 *)
    97 fun insert eq (keys,x) net =
    98   let fun ins1 ([], Leaf xs) =
    99             if member eq xs x then  raise INSERT  else Leaf(x::xs)
   100         | ins1 (keys, Leaf[]) = ins1 (keys, emptynet)   (*expand empty...*)
   101         | ins1 (CombK :: keys, Net{comb,var,atoms}) =
   102             Net{comb=ins1(keys,comb), var=var, atoms=atoms}
   103         | ins1 (VarK :: keys, Net{comb,var,atoms}) =
   104             Net{comb=comb, var=ins1(keys,var), atoms=atoms}
   105         | ins1 (AtomK a :: keys, Net{comb,var,atoms}) =
   106             let val atoms' = Symtab.map_default (a, empty) (fn net' => ins1 (keys, net')) atoms;
   107             in  Net{comb=comb, var=var, atoms=atoms'}  end
   108   in  ins1 (keys,net)  end;
   109 
   110 fun insert_term eq (t, x) = insert eq (key_of_term t, x);
   111 
   112 fun insert_safe eq entry net = insert eq entry net handle INSERT => net;
   113 fun insert_term_safe eq entry net = insert_term eq entry net handle INSERT => net;
   114 
   115 
   116 (*** Deletion from a discrimination net ***)
   117 
   118 exception DELETE;       (*missing item in the net*)
   119 
   120 (*Create a new Net node if it would be nonempty*)
   121 fun newnet (args as {comb,var,atoms}) =
   122   if is_empty comb andalso is_empty var andalso Symtab.is_empty atoms
   123   then empty else Net args;
   124 
   125 (*Deletes item x from the list at the node addressed by the keys.
   126   Raises DELETE if absent.  Collapses the net if possible.
   127   eq is the equality test for items. *)
   128 fun delete eq (keys, x) net =
   129   let fun del1 ([], Leaf xs) =
   130             if member eq xs x then Leaf (remove eq x xs)
   131             else raise DELETE
   132         | del1 (keys, Leaf[]) = raise DELETE
   133         | del1 (CombK :: keys, Net{comb,var,atoms}) =
   134             newnet{comb=del1(keys,comb), var=var, atoms=atoms}
   135         | del1 (VarK :: keys, Net{comb,var,atoms}) =
   136             newnet{comb=comb, var=del1(keys,var), atoms=atoms}
   137         | del1 (AtomK a :: keys, Net{comb,var,atoms}) =
   138             let val atoms' =
   139               (case Symtab.lookup atoms a of
   140                 NONE => raise DELETE
   141               | SOME net' =>
   142                   (case del1 (keys, net') of
   143                     Leaf [] => Symtab.delete a atoms
   144                   | net'' => Symtab.update (a, net'') atoms))
   145             in  newnet{comb=comb, var=var, atoms=atoms'}  end
   146   in  del1 (keys,net)  end;
   147 
   148 fun delete_term eq (t, x) = delete eq (key_of_term t, x);
   149 
   150 fun delete_safe eq entry net = delete eq entry net handle DELETE => net;
   151 fun delete_term_safe eq entry net = delete_term eq entry net handle DELETE => net;
   152 
   153 
   154 (*** Retrieval functions for discrimination nets ***)
   155 
   156 exception ABSENT;
   157 
   158 fun the_atom atoms a =
   159   (case Symtab.lookup atoms a of
   160     NONE => raise ABSENT
   161   | SOME net => net);
   162 
   163 (*Return the list of items at the given node, [] if no such node*)
   164 fun lookup (Leaf xs) [] = xs
   165   | lookup (Leaf _) (_ :: _) = []  (*non-empty keys and empty net*)
   166   | lookup (Net {comb, var, atoms}) (CombK :: keys) = lookup comb keys
   167   | lookup (Net {comb, var, atoms}) (VarK :: keys) = lookup var keys
   168   | lookup (Net {comb, var, atoms}) (AtomK a :: keys) =
   169       lookup (the_atom atoms a) keys handle ABSENT => [];
   170 
   171 
   172 (*Skipping a term in a net.  Recursively skip 2 levels if a combination*)
   173 fun net_skip (Leaf _) nets = nets
   174   | net_skip (Net{comb,var,atoms}) nets =
   175       fold_rev net_skip (net_skip comb []) (Symtab.fold (cons o #2) atoms (var::nets));
   176 
   177 
   178 (** Matching and Unification **)
   179 
   180 (*conses the linked net, if present, to nets*)
   181 fun look1 (atoms, a) nets =
   182   the_atom atoms a :: nets handle ABSENT => nets;
   183 
   184 (*Return the nodes accessible from the term (cons them before nets)
   185   "unif" signifies retrieval for unification rather than matching.
   186   Var in net matches any term.
   187   Abs or Var in object: if "unif", regarded as wildcard,
   188                                    else matches only a variable in net.
   189 *)
   190 fun matching unif t net nets =
   191   let fun rands _ (Leaf _, nets) = nets
   192         | rands t (Net{comb,atoms,...}, nets) =
   193             case t of
   194                 f$t => fold_rev (matching unif t) (rands f (comb,[])) nets
   195               | Const(c,_) => look1 (atoms, c) nets
   196               | Free(c,_)  => look1 (atoms, c) nets
   197               | Bound i    => look1 (atoms, Name.bound i) nets
   198               | _          => nets
   199   in
   200      case net of
   201          Leaf _ => nets
   202        | Net{var,...} =>
   203              case head_of t of
   204                  Var _ => if unif then net_skip net nets
   205                           else var::nets           (*only matches Var in net*)
   206   (*If "unif" then a var instantiation in the abstraction could allow
   207     an eta-reduction, so regard the abstraction as a wildcard.*)
   208                | Abs _ => if unif then net_skip net nets
   209                           else var::nets           (*only a Var can match*)
   210                | _ => rands t (net, var::nets)  (*var could match also*)
   211   end;
   212 
   213 fun extract_leaves l = maps (fn Leaf xs => xs) l;
   214 
   215 (*return items whose key could match t, WHICH MUST BE BETA-ETA NORMAL*)
   216 fun match_term net t =
   217     extract_leaves (matching false t net []);
   218 
   219 (*return items whose key could unify with t*)
   220 fun unify_term net t =
   221     extract_leaves (matching true t net []);
   222 
   223 
   224 (** operations on nets **)
   225 
   226 (*subtraction: collect entries of second net that are NOT present in first net*)
   227 fun subtract eq net1 net2 =
   228   let
   229     fun subtr (Net _) (Leaf ys) = append ys
   230       | subtr (Leaf xs) (Leaf ys) =
   231           fold_rev (fn y => if member eq xs y then I else cons y) ys
   232       | subtr (Leaf _) (net as Net _) = subtr emptynet net
   233       | subtr (Net {comb = comb1, var = var1, atoms = atoms1})
   234             (Net {comb = comb2, var = var2, atoms = atoms2}) =
   235           subtr comb1 comb2
   236           #> subtr var1 var2
   237           #> Symtab.fold (fn (a, net) =>
   238             subtr (the_default emptynet (Symtab.lookup atoms1 a)) net) atoms2
   239   in subtr net1 net2 [] end;
   240 
   241 fun entries net = subtract (K false) empty net;
   242 
   243 
   244 (* merge *)
   245 
   246 fun cons_fst x (xs, y) = (x :: xs, y);
   247 
   248 fun dest (Leaf xs) = map (pair []) xs
   249   | dest (Net {comb, var, atoms}) =
   250       map (cons_fst CombK) (dest comb) @
   251       map (cons_fst VarK) (dest var) @
   252       maps (fn (a, net) => map (cons_fst (AtomK a)) (dest net)) (Symtab.dest atoms);
   253 
   254 fun merge eq (net1, net2) = fold (insert_safe eq) (dest net2) net1;
   255 
   256 fun content net = map #2 (dest net);
   257 
   258 end;