src/Pure/pattern.ML
author wenzelm
Fri Apr 12 14:54:14 2013 +0200 (2013-04-12)
changeset 51700 c8f2bad67dbb
parent 46857 628b4a3fbf6e
child 52127 a40dfe02dd83
permissions -rw-r--r--
tuned signature;
tuned comments;
     1 (*  Title:      Pure/pattern.ML
     2     Author:     Tobias Nipkow, Christine Heinzelmann, and Stefan Berghofer, TU Muenchen
     3 
     4 Unification of Higher-Order Patterns.
     5 
     6 See also:
     7 Tobias Nipkow. Functional Unification of Higher-Order Patterns.
     8 In Proceedings of the 8th IEEE Symposium Logic in Computer Science, 1993.
     9 
    10 TODO: optimize red by special-casing it
    11 *)
    12 
    13 infix aeconv;
    14 
    15 signature PATTERN =
    16 sig
    17   val trace_unify_fail: bool Unsynchronized.ref
    18   val aeconv: term * term -> bool
    19   val eta_long: typ list -> term -> term
    20   val match: theory -> term * term -> Type.tyenv * Envir.tenv -> Type.tyenv * Envir.tenv
    21   val first_order_match: theory -> term * term
    22     -> Type.tyenv * Envir.tenv -> Type.tyenv * Envir.tenv
    23   val matches: theory -> term * term -> bool
    24   val matchess: theory -> term list * term list -> bool
    25   val equiv: theory -> term * term -> bool
    26   val matches_subterm: theory -> term * term -> bool
    27   val unify: theory -> term * term -> Envir.env -> Envir.env
    28   val first_order: term -> bool
    29   val pattern: term -> bool
    30   val match_rew: theory -> term -> term * term -> (term * term) option
    31   val rewrite_term: theory -> (term * term) list -> (term -> term option) list -> term -> term
    32   val rewrite_term_top: theory -> (term * term) list -> (term -> term option) list -> term -> term
    33   exception Unif
    34   exception MATCH
    35   exception Pattern
    36 end;
    37 
    38 structure Pattern: PATTERN =
    39 struct
    40 
    41 exception Unif;
    42 exception Pattern;
    43 
    44 val trace_unify_fail = Unsynchronized.ref false;
    45 
    46 fun string_of_term thy env binders t =
    47   Syntax.string_of_term_global thy
    48     (Envir.norm_term env (subst_bounds (map Free binders, t)));
    49 
    50 fun bname binders i = fst (nth binders i);
    51 fun bnames binders is = space_implode " " (map (bname binders) is);
    52 
    53 fun typ_clash thy (tye,T,U) =
    54   if !trace_unify_fail
    55   then let val t = Syntax.string_of_typ_global thy (Envir.norm_type tye T)
    56            and u = Syntax.string_of_typ_global thy (Envir.norm_type tye U)
    57        in tracing("The following types do not unify:\n" ^ t ^ "\n" ^ u) end
    58   else ()
    59 
    60 fun clash a b =
    61   if !trace_unify_fail then tracing("Clash: " ^ a ^ " =/= " ^ b) else ()
    62 
    63 fun boundVar binders i =
    64   "bound variable " ^ bname binders i ^ " (depth " ^ string_of_int i ^ ")";
    65 
    66 fun clashBB binders i j =
    67   if !trace_unify_fail then clash (boundVar binders i) (boundVar binders j)
    68   else ()
    69 
    70 fun clashB binders i s =
    71   if !trace_unify_fail then clash (boundVar binders i) s
    72   else ()
    73 
    74 fun proj_fail thy (env,binders,F,_,is,t) =
    75   if !trace_unify_fail
    76   then let val f = Term.string_of_vname F
    77            val xs = bnames binders is
    78            val u = string_of_term thy env binders t
    79            val ys = bnames binders (subtract (op =) is (loose_bnos t))
    80        in tracing("Cannot unify variable " ^ f ^
    81                " (depending on bound variables " ^ xs ^ ")\nwith term " ^ u ^
    82                "\nTerm contains additional bound variable(s) " ^ ys)
    83        end
    84   else ()
    85 
    86 fun ocheck_fail thy (F,t,binders,env) =
    87   if !trace_unify_fail
    88   then let val f = Term.string_of_vname F
    89            val u = string_of_term thy env binders t
    90        in tracing("Variable " ^ f ^ " occurs in term\n" ^ u ^
    91                   "\nCannot unify!\n")
    92        end
    93   else ()
    94 
    95 fun occurs(F,t,env) =
    96     let fun occ(Var (G, T))   = (case Envir.lookup env (G, T) of
    97                                  SOME(t) => occ t
    98                                | NONE    => F=G)
    99           | occ(t1$t2)      = occ t1 orelse occ t2
   100           | occ(Abs(_,_,t)) = occ t
   101           | occ _           = false
   102     in occ t end;
   103 
   104 
   105 fun mapbnd f =
   106     let fun mpb d (Bound(i))     = if i < d then Bound(i) else Bound(f(i-d)+d)
   107           | mpb d (Abs(s,T,t))   = Abs(s,T,mpb(d+1) t)
   108           | mpb d ((u1 $ u2))    = (mpb d u1)$(mpb d u2)
   109           | mpb _ atom           = atom
   110     in mpb 0 end;
   111 
   112 fun idx [] j     = raise Unif
   113   | idx(i::is) j = if (i:int) =j then length is else idx is j;
   114 
   115 fun mkabs (binders,is,t)  =
   116     let fun mk(i::is) = let val (x,T) = nth binders i
   117                         in Abs(x,T,mk is) end
   118           | mk []     = t
   119     in mk is end;
   120 
   121 val incr = mapbnd (fn i => i+1);
   122 
   123 fun ints_of []             = []
   124   | ints_of (Bound i ::bs) =
   125       let val is = ints_of bs
   126       in if member (op =) is i then raise Pattern else i::is end
   127   | ints_of _              = raise Pattern;
   128 
   129 fun ints_of' env ts = ints_of (map (Envir.head_norm env) ts);
   130 
   131 
   132 fun app (s,(i::is)) = app (s$Bound(i),is)
   133   | app (s,[])      = s;
   134 
   135 fun red (Abs(_,_,s)) (i::is) js = red s is (i::js)
   136   | red t            []      [] = t
   137   | red t            is      jn = app (mapbnd (nth jn) t,is);
   138 
   139 
   140 (* split_type ([T1,....,Tn]---> T,n,[]) = ([Tn,...,T1],T) *)
   141 fun split_type (T,0,Ts)                    = (Ts,T)
   142   | split_type (Type ("fun",[T1,T2]),n,Ts) = split_type (T2,n-1,T1::Ts)
   143   | split_type _                           = error("split_type");
   144 
   145 fun type_of_G env (T, n, is) =
   146   let
   147     val tyenv = Envir.type_env env;
   148     val (Ts, U) = split_type (Envir.norm_type tyenv T, n, []);
   149   in map (nth Ts) is ---> U end;
   150 
   151 fun mkhnf (binders,is,G,js) = mkabs (binders, is, app(G,js));
   152 
   153 fun mknewhnf(env,binders,is,F as (a,_),T,js) =
   154   let val (env',G) = Envir.genvar a (env,type_of_G env (T,length is,js))
   155   in Envir.update ((F, T), mkhnf (binders, is, G, js)) env' end;
   156 
   157 
   158 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   159 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   160   | downto0 ([], n) = n = ~1;
   161 
   162 (*mk_proj_list(is) = [ |is| - k | 1 <= k <= |is| and is[k] >= 0 ]*)
   163 fun mk_proj_list is =
   164     let fun mk(i::is,j) = if is_some i then j :: mk(is,j-1) else mk(is,j-1)
   165           | mk([],_)    = []
   166     in mk(is,length is - 1) end;
   167 
   168 fun proj(s,env,binders,is) =
   169     let fun trans d i = if i<d then i else (idx is (i-d))+d;
   170         fun pr(s,env,d,binders) = (case Envir.head_norm env s of
   171               Abs(a,T,t) => let val (t',env') = pr(t,env,d+1,((a,T)::binders))
   172                             in (Abs(a,T,t'),env') end
   173             | t => (case strip_comb t of
   174                 (c as Const _,ts) =>
   175                          let val (ts',env') = prs(ts,env,d,binders)
   176                          in (list_comb(c,ts'),env') end
   177                  | (f as Free _,ts) =>
   178                          let val (ts',env') = prs(ts,env,d,binders)
   179                          in (list_comb(f,ts'),env') end
   180                  | (Bound(i),ts) =>
   181                          let val j = trans d i
   182                              val (ts',env') = prs(ts,env,d,binders)
   183                          in (list_comb(Bound j,ts'),env') end
   184                  | (Var(F as (a,_),Fty),ts) =>
   185                       let val js = ints_of' env ts;
   186                           val js' = map (try (trans d)) js;
   187                           val ks = mk_proj_list js';
   188                           val ls = map_filter I js'
   189                           val Hty = type_of_G env (Fty,length js,ks)
   190                           val (env',H) = Envir.genvar a (env,Hty)
   191                           val env'' =
   192                             Envir.update ((F, Fty), mkhnf (binders, js, H, ks)) env'
   193                       in (app(H,ls),env'') end
   194                  | _  => raise Pattern))
   195         and prs(s::ss,env,d,binders) =
   196               let val (s',env1) = pr(s,env,d,binders)
   197                   val (ss',env2) = prs(ss,env1,d,binders)
   198               in (s'::ss',env2) end
   199           | prs([],env,_,_) = ([],env)
   200    in if downto0(is,length binders - 1) then (s,env)
   201       else pr(s,env,0,binders)
   202    end;
   203 
   204 
   205 (* mk_ff_list(is,js) = [ length(is) - k | 1 <= k <= |is| and is[k] = js[k] ] *)
   206 fun mk_ff_list(is,js) =
   207     let fun mk([],[],_)        = []
   208           | mk(i::is,j::js, k) = if (i:int) = j then k :: mk(is,js,k-1)
   209                                         else mk(is,js,k-1)
   210           | mk _               = error"mk_ff_list"
   211     in mk(is,js,length is-1) end;
   212 
   213 fun flexflex1(env,binders,F,Fty,is,js) =
   214   if is=js then env
   215   else let val ks = mk_ff_list(is,js)
   216        in mknewhnf(env,binders,is,F,Fty,ks) end;
   217 
   218 fun flexflex2(env,binders,F,Fty,is,G,Gty,js) =
   219   let fun ff(F,Fty,is,G as (a,_),Gty,js) =
   220             if subset (op =) (js, is)
   221             then let val t= mkabs(binders,is,app(Var(G,Gty),map (idx is) js))
   222                  in Envir.update ((F, Fty), t) env end
   223             else let val ks = inter (op =) js is
   224                      val Hty = type_of_G env (Fty,length is,map (idx is) ks)
   225                      val (env',H) = Envir.genvar a (env,Hty)
   226                      fun lam(is) = mkabs(binders,is,app(H,map (idx is) ks));
   227                  in Envir.update ((G, Gty), lam js) (Envir.update ((F, Fty), lam is) env')
   228                  end;
   229   in if Term_Ord.indexname_ord (G,F) = LESS then ff(F,Fty,is,G,Gty,js) else ff(G,Gty,js,F,Fty,is) end
   230 
   231 fun unify_types thy (T, U) (env as Envir.Envir {maxidx, tenv, tyenv}) =
   232   if T = U then env
   233   else
   234     let val (tyenv', maxidx') = Sign.typ_unify thy (U, T) (tyenv, maxidx)
   235     in Envir.Envir {maxidx = maxidx', tenv = tenv, tyenv = tyenv'} end
   236     handle Type.TUNIFY => (typ_clash thy (tyenv, T, U); raise Unif);
   237 
   238 fun unif thy binders (s,t) env = case (Envir.head_norm env s, Envir.head_norm env t) of
   239       (Abs(ns,Ts,ts),Abs(nt,Tt,tt)) =>
   240          let val name = if ns = "" then nt else ns
   241          in unif thy ((name,Ts)::binders) (ts,tt) env end
   242     | (Abs(ns,Ts,ts),t) => unif thy ((ns,Ts)::binders) (ts,(incr t)$Bound(0)) env
   243     | (t,Abs(nt,Tt,tt)) => unif thy ((nt,Tt)::binders) ((incr t)$Bound(0),tt) env
   244     | p => cases thy (binders,env,p)
   245 
   246 and cases thy (binders,env,(s,t)) = case (strip_comb s,strip_comb t) of
   247        ((Var(F,Fty),ss),(Var(G,Gty),ts)) =>
   248          if F = G then flexflex1(env,binders,F,Fty,ints_of' env ss,ints_of' env ts)
   249                   else flexflex2(env,binders,F,Fty,ints_of' env ss,G,Gty,ints_of' env ts)
   250       | ((Var(F,Fty),ss),_)           => flexrigid thy (env,binders,F,Fty,ints_of' env ss,t)
   251       | (_,(Var(F,Fty),ts))           => flexrigid thy (env,binders,F,Fty,ints_of' env ts,s)
   252       | ((Const c,ss),(Const d,ts))   => rigidrigid thy (env,binders,c,d,ss,ts)
   253       | ((Free(f),ss),(Free(g),ts))   => rigidrigid thy (env,binders,f,g,ss,ts)
   254       | ((Bound(i),ss),(Bound(j),ts)) => rigidrigidB thy (env,binders,i,j,ss,ts)
   255       | ((Abs(_),_),_)                => raise Pattern
   256       | (_,(Abs(_),_))                => raise Pattern
   257       | ((Const(c,_),_),(Free(f,_),_)) => (clash c f; raise Unif)
   258       | ((Const(c,_),_),(Bound i,_))   => (clashB binders i c; raise Unif)
   259       | ((Free(f,_),_),(Const(c,_),_)) => (clash f c; raise Unif)
   260       | ((Free(f,_),_),(Bound i,_))    => (clashB binders i f; raise Unif)
   261       | ((Bound i,_),(Const(c,_),_))   => (clashB binders i c; raise Unif)
   262       | ((Bound i,_),(Free(f,_),_))    => (clashB binders i f; raise Unif)
   263 
   264 
   265 and rigidrigid thy (env,binders,(a,Ta),(b,Tb),ss,ts) =
   266       if a<>b then (clash a b; raise Unif)
   267       else env |> unify_types thy (Ta,Tb) |> fold (unif thy binders) (ss~~ts)
   268 
   269 and rigidrigidB thy (env,binders,i,j,ss,ts) =
   270      if i <> j then (clashBB binders i j; raise Unif)
   271      else fold (unif thy binders) (ss~~ts) env
   272 
   273 and flexrigid thy (params as (env,binders,F,Fty,is,t)) =
   274       if occurs(F,t,env) then (ocheck_fail thy (F,t,binders,env); raise Unif)
   275       else (let val (u,env') = proj(t,env,binders,is)
   276             in Envir.update ((F, Fty), mkabs (binders, is, u)) env' end
   277             handle Unif => (proj_fail thy params; raise Unif));
   278 
   279 fun unify thy = unif thy [];
   280 
   281 
   282 (* put a term into eta long beta normal form *)
   283 fun eta_long Ts (Abs (s, T, t)) = Abs (s, T, eta_long (T :: Ts) t)
   284   | eta_long Ts t =
   285       (case strip_comb t of
   286         (Abs _, _) => eta_long Ts (Envir.beta_norm t)
   287       | (u, ts) =>
   288           let
   289             val Us = binder_types (fastype_of1 (Ts, t));
   290             val i = length Us;
   291           in
   292             fold_rev (Term.abs o pair "x") Us
   293               (list_comb (incr_boundvars i u, map (eta_long (rev Us @ Ts))
   294                 (map (incr_boundvars i) ts @ map Bound (i - 1 downto 0))))
   295           end);
   296 
   297 
   298 (*Tests whether 2 terms are alpha/eta-convertible and have same type.
   299   Note that Consts and Vars may have more than one type.*)
   300 fun t aeconv u = t aconv u orelse
   301   Envir.eta_contract t aconv Envir.eta_contract u;
   302 
   303 
   304 (*** Matching ***)
   305 
   306 exception MATCH;
   307 
   308 fun typ_match thy TU tyenv = Sign.typ_match thy TU tyenv
   309   handle Type.TYPE_MATCH => raise MATCH;
   310 
   311 (*First-order matching;
   312   The pattern and object may have variables in common.
   313   Instantiation does not affect the object, so matching ?a with ?a+1 works.
   314   Object is eta-contracted on the fly (by eta-expanding the pattern).
   315   Precondition: the pattern is already eta-contracted!
   316   Types are matched on the fly*)
   317 fun first_order_match thy =
   318   let
   319     fun mtch k (instsp as (tyinsts,insts)) = fn
   320         (Var(ixn,T), t)  =>
   321           if k > 0 andalso Term.is_open t then raise MATCH
   322           else (case Envir.lookup1 insts (ixn, T) of
   323                   NONE => (typ_match thy (T, fastype_of t) tyinsts,
   324                            Vartab.update_new (ixn, (T, t)) insts)
   325                 | SOME u => if t aeconv u then instsp else raise MATCH)
   326       | (Free (a,T), Free (b,U)) =>
   327           if a=b then (typ_match thy (T,U) tyinsts, insts) else raise MATCH
   328       | (Const (a,T), Const (b,U))  =>
   329           if a=b then (typ_match thy (T,U) tyinsts, insts) else raise MATCH
   330       | (Bound i, Bound j)  =>  if  i=j  then  instsp  else raise MATCH
   331       | (Abs(_,T,t), Abs(_,U,u))  =>
   332           mtch (k + 1) (typ_match thy (T,U) tyinsts, insts) (t,u)
   333       | (f$t, g$u) => mtch k (mtch k instsp (f,g)) (t, u)
   334       | (t, Abs(_,U,u))  =>  mtch (k + 1) instsp ((incr t)$(Bound 0), u)
   335       | _ => raise MATCH
   336   in fn tu => fn env => mtch 0 env tu end;
   337 
   338 
   339 (* Matching of higher-order patterns *)
   340 
   341 fun match_bind(itms,binders,ixn,T,is,t) =
   342   let val js = loose_bnos t
   343   in if null is
   344      then if null js then Vartab.update_new (ixn, (T, t)) itms else raise MATCH
   345      else if subset (op =) (js, is)
   346           then let val t' = if downto0(is,length binders - 1) then t
   347                             else mapbnd (idx is) t
   348                in Vartab.update_new (ixn, (T, mkabs (binders, is, t'))) itms end
   349           else raise MATCH
   350   end;
   351 
   352 fun match thy (po as (pat,obj)) envir =
   353 let
   354   (* Pre: pat and obj have same type *)
   355   fun mtch binders (pat,obj) (env as (iTs,itms)) =
   356     case pat of
   357       Abs(ns,Ts,ts) =>
   358         (case obj of
   359            Abs(nt,Tt,tt) => mtch ((nt,Tt)::binders) (ts,tt) env
   360          | _ => let val Tt = Envir.subst_type iTs Ts
   361                 in mtch((ns,Tt)::binders) (ts,(incr obj)$Bound(0)) env end)
   362     | _ => (case obj of
   363               Abs(nt,Tt,tt) =>
   364                 mtch((nt,Tt)::binders) ((incr pat)$Bound(0),tt) env
   365             | _ => cases(binders,env,pat,obj))
   366 
   367   and cases(binders,env as (iTs,itms),pat,obj) =
   368     let val (ph,pargs) = strip_comb pat
   369         fun rigrig1(iTs,oargs) = fold (mtch binders) (pargs~~oargs) (iTs,itms)
   370           handle ListPair.UnequalLengths => raise MATCH
   371         fun rigrig2((a:string,Ta),(b,Tb),oargs) =
   372               if a <> b then raise MATCH
   373               else rigrig1(typ_match thy (Ta,Tb) iTs, oargs)
   374     in case ph of
   375          Var(ixn,T) =>
   376            let val is = ints_of pargs
   377            in case Envir.lookup1 itms (ixn, T) of
   378                 NONE => (iTs,match_bind(itms,binders,ixn,T,is,obj))
   379               | SOME u => if obj aeconv (red u is []) then env
   380                           else raise MATCH
   381            end
   382        | _ =>
   383            let val (oh,oargs) = strip_comb obj
   384            in case (ph,oh) of
   385                 (Const c,Const d) => rigrig2(c,d,oargs)
   386               | (Free f,Free g)   => rigrig2(f,g,oargs)
   387               | (Bound i,Bound j) => if i<>j then raise MATCH
   388                                      else rigrig1(iTs,oargs)
   389               | (Abs _, _)        => raise Pattern
   390               | (_, Abs _)        => raise Pattern
   391               | _                 => raise MATCH
   392            end
   393     end;
   394 
   395   val pT = fastype_of pat
   396   and oT = fastype_of obj
   397   val envir' = apfst (typ_match thy (pT, oT)) envir;
   398 in mtch [] po envir' handle Pattern => first_order_match thy po envir' end;
   399 
   400 fun matches thy po = (match thy po (Vartab.empty, Vartab.empty); true) handle MATCH => false;
   401 
   402 fun matchess thy (ps, os) =
   403   length ps = length os andalso
   404     ((fold (match thy) (ps ~~ os) (Vartab.empty, Vartab.empty); true) handle MATCH => false);
   405 
   406 fun equiv thy (t, u) = matches thy (t, u) andalso matches thy (u, t);
   407 
   408 
   409 (* Does pat match a subterm of obj? *)
   410 fun matches_subterm thy (pat, obj) =
   411   let
   412     fun msub bounds obj = matches thy (pat, obj) orelse
   413       (case obj of
   414         Abs (x, T, t) => msub (bounds + 1) (snd (Term.dest_abs (Name.bound bounds, T, t)))
   415       | t $ u => msub bounds t orelse msub bounds u
   416       | _ => false)
   417   in msub 0 obj end;
   418 
   419 fun first_order(Abs(_,_,t)) = first_order t
   420   | first_order(t $ u) = first_order t andalso first_order u andalso
   421                          not(is_Var t)
   422   | first_order _ = true;
   423 
   424 fun pattern (Abs (_, _, t)) = pattern t
   425   | pattern t =
   426       let val (head, args) = strip_comb t in
   427         if is_Var head then
   428           forall is_Bound args andalso not (has_duplicates (op aconv) args)
   429         else forall pattern args
   430       end;
   431 
   432 
   433 (* rewriting -- simple but fast *)
   434 
   435 fun match_rew thy tm (tm1, tm2) =
   436   let val rtm = the_default tm2 (Term.rename_abs tm1 tm tm2) in
   437     SOME (Envir.subst_term (match thy (tm1, tm) (Vartab.empty, Vartab.empty)) rtm, rtm)
   438       handle MATCH => NONE
   439   end;
   440 
   441 fun gen_rewrite_term bot thy rules procs tm =
   442   let
   443     val skel0 = Bound 0;
   444 
   445     fun variant_absfree bounds (x, T, t) =
   446       let
   447         val (x', t') = Term.dest_abs (Name.bound bounds, T, t);
   448         fun abs u = Abs (x, T, abstract_over (Free (x', T), u));
   449       in (abs, t') end;
   450 
   451     fun rew (Abs (_, _, body) $ t) = SOME (subst_bound (t, body), skel0)
   452       | rew tm =
   453           (case get_first (match_rew thy tm) rules of
   454             NONE => Option.map (rpair skel0) (get_first (fn p => p tm) procs)
   455           | x => x);
   456 
   457     fun rew_sub r bounds skel (tm1 $ tm2) = (case tm1 of
   458             Abs (_, _, body) =>
   459               let val tm' = subst_bound (tm2, body)
   460               in SOME (the_default tm' (rew_sub r bounds skel0 tm')) end
   461           | _ =>
   462             let val (skel1, skel2) = (case skel of
   463                 skel1 $ skel2 => (skel1, skel2)
   464               | _ => (skel0, skel0))
   465             in case r bounds skel1 tm1 of
   466                 SOME tm1' => (case r bounds skel2 tm2 of
   467                     SOME tm2' => SOME (tm1' $ tm2')
   468                   | NONE => SOME (tm1' $ tm2))
   469               | NONE => (case r bounds skel2 tm2 of
   470                     SOME tm2' => SOME (tm1 $ tm2')
   471                   | NONE => NONE)
   472             end)
   473       | rew_sub r bounds skel (Abs body) =
   474           let
   475             val (abs, tm') = variant_absfree bounds body;
   476             val skel' = (case skel of Abs (_, _, skel') => skel' | _ => skel0)
   477           in case r (bounds + 1) skel' tm' of
   478               SOME tm'' => SOME (abs tm'')
   479             | NONE => NONE
   480           end
   481       | rew_sub _ _ _ _ = NONE;
   482 
   483     fun rew_bot bounds (Var _) _ = NONE
   484       | rew_bot bounds skel tm = (case rew_sub rew_bot bounds skel tm of
   485           SOME tm1 => (case rew tm1 of
   486               SOME (tm2, skel') => SOME (the_default tm2 (rew_bot bounds skel' tm2))
   487             | NONE => SOME tm1)
   488         | NONE => (case rew tm of
   489               SOME (tm1, skel') => SOME (the_default tm1 (rew_bot bounds skel' tm1))
   490             | NONE => NONE));
   491 
   492     fun rew_top bounds _ tm = (case rew tm of
   493           SOME (tm1, _) => (case rew_sub rew_top bounds skel0 tm1 of
   494               SOME tm2 => SOME (the_default tm2 (rew_top bounds skel0 tm2))
   495             | NONE => SOME tm1)
   496         | NONE => (case rew_sub rew_top bounds skel0 tm of
   497               SOME tm1 => SOME (the_default tm1 (rew_top bounds skel0 tm1))
   498             | NONE => NONE));
   499 
   500   in the_default tm ((if bot then rew_bot else rew_top) 0 skel0 tm) end;
   501 
   502 val rewrite_term = gen_rewrite_term true;
   503 val rewrite_term_top = gen_rewrite_term false;
   504 
   505 end;
   506 
   507 val trace_unify_fail = Pattern.trace_unify_fail;