src/Pure/theory.ML
author wenzelm
Thu Oct 01 23:27:05 2009 +0200 (2009-10-01)
changeset 32843 c8f5a7c8353f
parent 32789 d89327de0b3c
child 32966 5b21661fe618
permissions -rw-r--r--
moved cache_conv to src/Pure/conv.ML, use Thm.cterm_cache;
     1 (*  Title:      Pure/theory.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical theory content: axioms, definitions, and begin/end wrappers.
     5 *)
     6 
     7 signature THEORY =
     8 sig
     9   val eq_thy: theory * theory -> bool
    10   val subthy: theory * theory -> bool
    11   val assert_super: theory -> theory -> theory
    12   val parents_of: theory -> theory list
    13   val ancestors_of: theory -> theory list
    14   val check_thy: theory -> theory_ref
    15   val deref: theory_ref -> theory
    16   val merge: theory * theory -> theory
    17   val merge_refs: theory_ref * theory_ref -> theory_ref
    18   val merge_list: theory list -> theory
    19   val checkpoint: theory -> theory
    20   val copy: theory -> theory
    21   val requires: theory -> string -> string -> unit
    22   val axiom_space: theory -> NameSpace.T
    23   val axiom_table: theory -> term Symtab.table
    24   val axioms_of: theory -> (string * term) list
    25   val all_axioms_of: theory -> (string * term) list
    26   val defs_of: theory -> Defs.T
    27   val at_begin: (theory -> theory option) -> theory -> theory
    28   val at_end: (theory -> theory option) -> theory -> theory
    29   val begin_theory: string -> theory list -> theory
    30   val end_theory: theory -> theory
    31   val add_axioms_i: (binding * term) list -> theory -> theory
    32   val add_axioms: (binding * string) list -> theory -> theory
    33   val add_deps: string -> string * typ -> (string * typ) list -> theory -> theory
    34   val add_defs_i: bool -> bool -> (binding * term) list -> theory -> theory
    35   val add_defs: bool -> bool -> (binding * string) list -> theory -> theory
    36   val add_finals_i: bool -> term list -> theory -> theory
    37   val add_finals: bool -> string list -> theory -> theory
    38   val specify_const: Properties.T -> (binding * typ) * mixfix -> theory -> term * theory
    39 end
    40 
    41 structure Theory: THEORY =
    42 struct
    43 
    44 
    45 (** theory context operations **)
    46 
    47 val eq_thy = Context.eq_thy;
    48 val subthy = Context.subthy;
    49 
    50 fun assert_super thy1 thy2 =
    51   if subthy (thy1, thy2) then thy2
    52   else raise THEORY ("Not a super theory", [thy1, thy2]);
    53 
    54 val parents_of = Context.parents_of;
    55 val ancestors_of = Context.ancestors_of;
    56 
    57 val check_thy = Context.check_thy;
    58 val deref = Context.deref;
    59 
    60 val merge = Context.merge;
    61 val merge_refs = Context.merge_refs;
    62 
    63 fun merge_list [] = raise THEORY ("Empty merge of theories", [])
    64   | merge_list (thy :: thys) = Library.foldl merge (thy, thys);
    65 
    66 val checkpoint = Context.checkpoint_thy;
    67 val copy = Context.copy_thy;
    68 
    69 fun requires thy name what =
    70   if exists (fn thy' => Context.theory_name thy' = name) (thy :: ancestors_of thy) then ()
    71   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
    72 
    73 
    74 
    75 (** datatype thy **)
    76 
    77 type wrapper = (theory -> theory option) * stamp;
    78 
    79 fun apply_wrappers (wrappers: wrapper list) =
    80   perhaps (perhaps_loop (perhaps_apply (map fst wrappers)));
    81 
    82 datatype thy = Thy of
    83  {axioms: term NameSpace.table,
    84   defs: Defs.T,
    85   wrappers: wrapper list * wrapper list};
    86 
    87 fun make_thy (axioms, defs, wrappers) = Thy {axioms = axioms, defs = defs, wrappers = wrappers};
    88 
    89 fun err_dup_axm dup = error ("Duplicate axiom: " ^ quote dup);
    90 
    91 structure ThyData = TheoryDataFun
    92 (
    93   type T = thy;
    94   val empty = make_thy (NameSpace.empty_table, Defs.empty, ([], []));
    95   val copy = I;
    96 
    97   fun extend (Thy {axioms = _, defs, wrappers}) =
    98     make_thy (NameSpace.empty_table, defs, wrappers);
    99 
   100   fun merge pp (thy1, thy2) =
   101     let
   102       val Thy {axioms = _, defs = defs1, wrappers = (bgs1, ens1)} = thy1;
   103       val Thy {axioms = _, defs = defs2, wrappers = (bgs2, ens2)} = thy2;
   104 
   105       val axioms' = NameSpace.empty_table;
   106       val defs' = Defs.merge pp (defs1, defs2);
   107       val bgs' = Library.merge (eq_snd op =) (bgs1, bgs2);
   108       val ens' = Library.merge (eq_snd op =) (ens1, ens2);
   109     in make_thy (axioms', defs', (bgs', ens')) end;
   110 );
   111 
   112 fun rep_theory thy = ThyData.get thy |> (fn Thy args => args);
   113 
   114 fun map_thy f = ThyData.map (fn (Thy {axioms, defs, wrappers}) =>
   115   make_thy (f (axioms, defs, wrappers)));
   116 
   117 
   118 fun map_axioms f = map_thy (fn (axioms, defs, wrappers) => (f axioms, defs, wrappers));
   119 fun map_defs f = map_thy (fn (axioms, defs, wrappers) => (axioms, f defs, wrappers));
   120 fun map_wrappers f = map_thy (fn (axioms, defs, wrappers) => (axioms, defs, f wrappers));
   121 
   122 
   123 (* basic operations *)
   124 
   125 val axiom_space = #1 o #axioms o rep_theory;
   126 val axiom_table = #2 o #axioms o rep_theory;
   127 
   128 val axioms_of = Symtab.dest o #2 o #axioms o rep_theory;
   129 fun all_axioms_of thy = maps axioms_of (thy :: ancestors_of thy);
   130 
   131 val defs_of = #defs o rep_theory;
   132 
   133 
   134 (* begin/end theory *)
   135 
   136 val begin_wrappers = rev o #1 o #wrappers o rep_theory;
   137 val end_wrappers = rev o #2 o #wrappers o rep_theory;
   138 
   139 fun at_begin f = map_wrappers (apfst (cons (f, stamp ())));
   140 fun at_end f = map_wrappers (apsnd (cons (f, stamp ())));
   141 
   142 fun begin_theory name imports =
   143   let
   144     val thy = Context.begin_thy Syntax.pp_global name imports;
   145     val wrappers = begin_wrappers thy;
   146   in thy |> Sign.local_path |> apply_wrappers wrappers end;
   147 
   148 fun end_theory thy =
   149   thy |> apply_wrappers (end_wrappers thy) |> Context.finish_thy;
   150 
   151 
   152 
   153 (** add axioms **)
   154 
   155 (* prepare axioms *)
   156 
   157 fun cert_axm thy (b, raw_tm) =
   158   let
   159     val t = Sign.cert_prop thy raw_tm
   160       handle TYPE (msg, _, _) => error msg
   161         | TERM (msg, _) => error msg;
   162   in
   163     Term.no_dummy_patterns t handle TERM (msg, _) => error msg;
   164     (b, Sign.no_vars (Syntax.pp_global thy) t)
   165   end;
   166 
   167 fun read_axm thy (b, str) =
   168   cert_axm thy (b, Syntax.read_prop_global thy str) handle ERROR msg =>
   169     cat_error msg ("The error(s) above occurred in axiom: " ^ quote (Binding.str_of b));
   170 
   171 
   172 (* add_axioms(_i) *)
   173 
   174 local
   175 
   176 fun gen_add_axioms prep_axm raw_axms thy = thy |> map_axioms (fn axioms =>
   177   let
   178     val axms = map (apsnd Logic.varify o prep_axm thy) raw_axms;
   179     val axioms' = fold (snd oo NameSpace.define (Sign.naming_of thy)) axms axioms
   180       handle Symtab.DUP dup => err_dup_axm dup;
   181   in axioms' end);
   182 
   183 in
   184 
   185 val add_axioms_i = gen_add_axioms cert_axm;
   186 val add_axioms = gen_add_axioms read_axm;
   187 
   188 end;
   189 
   190 
   191 
   192 (** add constant definitions **)
   193 
   194 (* dependencies *)
   195 
   196 fun dependencies thy unchecked is_def name lhs rhs =
   197   let
   198     val pp = Syntax.pp_global thy;
   199     val consts = Sign.consts_of thy;
   200     fun prep const =
   201       let val Const (c, T) = Sign.no_vars pp (Const const)
   202       in (c, Consts.typargs consts (c, Logic.varifyT T)) end;
   203 
   204     val lhs_vars = Term.add_tfreesT (#2 lhs) [];
   205     val rhs_extras = fold (#2 #> Term.fold_atyps (fn TFree v =>
   206       if member (op =) lhs_vars v then I else insert (op =) v | _ => I)) rhs [];
   207     val _ =
   208       if null rhs_extras then ()
   209       else error ("Specification depends on extra type variables: " ^
   210         commas_quote (map (Pretty.string_of_typ pp o TFree) rhs_extras) ^
   211         "\nThe error(s) above occurred in " ^ quote name);
   212   in Defs.define pp unchecked is_def name (prep lhs) (map prep rhs) end;
   213 
   214 fun add_deps a raw_lhs raw_rhs thy =
   215   let
   216     val lhs :: rhs = map (dest_Const o Sign.cert_term thy o Const) (raw_lhs :: raw_rhs);
   217     val name = if a = "" then (#1 lhs ^ " axiom") else a;
   218   in thy |> map_defs (dependencies thy false false name lhs rhs) end;
   219 
   220 fun specify_const tags decl thy =
   221   let val (t as Const const, thy') = Sign.declare_const tags decl thy
   222   in (t, add_deps "" const [] thy') end;
   223 
   224 
   225 (* check_overloading *)
   226 
   227 fun check_overloading thy overloaded (c, T) =
   228   let
   229     val declT = Sign.the_const_constraint thy c
   230       handle TYPE (msg, _, _) => error msg;
   231     val T' = Logic.varifyT T;
   232 
   233     fun message txt =
   234       [Pretty.block [Pretty.str "Specification of constant ",
   235         Pretty.str c, Pretty.str " ::", Pretty.brk 1, Pretty.quote (Syntax.pretty_typ_global thy T)],
   236         Pretty.str txt] |> Pretty.chunks |> Pretty.string_of;
   237   in
   238     if Sign.typ_instance thy (declT, T') then ()
   239     else if Type.raw_instance (declT, T') then
   240       error (Library.setmp show_sorts true
   241         message "imposes additional sort constraints on the constant declaration")
   242     else if overloaded then ()
   243     else warning (message "is strictly less general than the declared type");
   244     (c, T)
   245   end;
   246 
   247 
   248 (* check_def *)
   249 
   250 fun check_def thy unchecked overloaded (b, tm) defs =
   251   let
   252     val ctxt = ProofContext.init thy;
   253     val name = Sign.full_name thy b;
   254     val (lhs_const, rhs) = Sign.cert_def ctxt tm;
   255     val rhs_consts = fold_aterms (fn Const const => insert (op =) const | _ => I) rhs [];
   256     val _ = check_overloading thy overloaded lhs_const;
   257   in defs |> dependencies thy unchecked true name lhs_const rhs_consts end
   258   handle ERROR msg => cat_error msg (Pretty.string_of (Pretty.block
   259    [Pretty.str ("The error(s) above occurred in definition " ^ quote (Binding.str_of b) ^ ":"),
   260     Pretty.fbrk, Pretty.quote (Syntax.pretty_term_global thy tm)]));
   261 
   262 
   263 (* add_defs(_i) *)
   264 
   265 local
   266 
   267 fun gen_add_defs prep_axm unchecked overloaded raw_axms thy =
   268   let val axms = map (prep_axm thy) raw_axms in
   269     thy
   270     |> map_defs (fold (check_def thy unchecked overloaded) axms)
   271     |> add_axioms_i axms
   272   end;
   273 
   274 in
   275 
   276 val add_defs_i = gen_add_defs cert_axm;
   277 val add_defs = gen_add_defs read_axm;
   278 
   279 end;
   280 
   281 
   282 (* add_finals(_i) *)
   283 
   284 local
   285 
   286 fun gen_add_finals prep_term overloaded args thy =
   287   let
   288     fun const_of (Const const) = const
   289       | const_of (Free _) = error "Attempt to finalize variable (or undeclared constant)"
   290       | const_of _ = error "Attempt to finalize non-constant term";
   291     fun specify (c, T) = dependencies thy false false (c ^ " axiom") (c, T) [];
   292     val finalize = specify o check_overloading thy overloaded o const_of o
   293       Sign.cert_term thy o prep_term thy;
   294   in thy |> map_defs (fold finalize args) end;
   295 
   296 in
   297 
   298 val add_finals_i = gen_add_finals (K I);
   299 val add_finals = gen_add_finals Syntax.read_term_global;
   300 
   301 end;
   302 
   303 end;