src/HOL/List.thy
author haftmann
Fri Jan 06 20:39:50 2012 +0100 (2012-01-06)
changeset 46143 c932c80d3eae
parent 46138 85f8d8a8c711
child 46147 2c4d8de91c4c
permissions -rw-r--r--
farewell to theory More_List
     1 (*  Title:      HOL/List.thy
     2     Author:     Tobias Nipkow
     3 *)
     4 
     5 header {* The datatype of finite lists *}
     6 
     7 theory List
     8 imports Plain Presburger Code_Numeral Quotient ATP
     9 uses
    10   ("Tools/list_code.ML")
    11   ("Tools/list_to_set_comprehension.ML")
    12 begin
    13 
    14 datatype 'a list =
    15     Nil    ("[]")
    16   | Cons 'a  "'a list"    (infixr "#" 65)
    17 
    18 syntax
    19   -- {* list Enumeration *}
    20   "_list" :: "args => 'a list"    ("[(_)]")
    21 
    22 translations
    23   "[x, xs]" == "x#[xs]"
    24   "[x]" == "x#[]"
    25 
    26 
    27 subsection {* Basic list processing functions *}
    28 
    29 primrec
    30   hd :: "'a list \<Rightarrow> 'a" where
    31   "hd (x # xs) = x"
    32 
    33 primrec
    34   tl :: "'a list \<Rightarrow> 'a list" where
    35     "tl [] = []"
    36   | "tl (x # xs) = xs"
    37 
    38 primrec
    39   last :: "'a list \<Rightarrow> 'a" where
    40   "last (x # xs) = (if xs = [] then x else last xs)"
    41 
    42 primrec
    43   butlast :: "'a list \<Rightarrow> 'a list" where
    44     "butlast []= []"
    45   | "butlast (x # xs) = (if xs = [] then [] else x # butlast xs)"
    46 
    47 primrec
    48   set :: "'a list \<Rightarrow> 'a set" where
    49     "set [] = {}"
    50   | "set (x # xs) = insert x (set xs)"
    51 
    52 definition
    53   coset :: "'a list \<Rightarrow> 'a set" where
    54   [simp]: "coset xs = - set xs"
    55 
    56 primrec
    57   map :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a list \<Rightarrow> 'b list" where
    58     "map f [] = []"
    59   | "map f (x # xs) = f x # map f xs"
    60 
    61 primrec
    62   append :: "'a list \<Rightarrow> 'a list \<Rightarrow> 'a list" (infixr "@" 65) where
    63     append_Nil:"[] @ ys = ys"
    64   | append_Cons: "(x#xs) @ ys = x # xs @ ys"
    65 
    66 primrec
    67   rev :: "'a list \<Rightarrow> 'a list" where
    68     "rev [] = []"
    69   | "rev (x # xs) = rev xs @ [x]"
    70 
    71 primrec
    72   filter:: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> 'a list" where
    73     "filter P [] = []"
    74   | "filter P (x # xs) = (if P x then x # filter P xs else filter P xs)"
    75 
    76 syntax
    77   -- {* Special syntax for filter *}
    78   "_filter" :: "[pttrn, 'a list, bool] => 'a list"    ("(1[_<-_./ _])")
    79 
    80 translations
    81   "[x<-xs . P]"== "CONST filter (%x. P) xs"
    82 
    83 syntax (xsymbols)
    84   "_filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<leftarrow>_ ./ _])")
    85 syntax (HTML output)
    86   "_filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<leftarrow>_ ./ _])")
    87 
    88 primrec -- {* canonical argument order *}
    89   fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a list \<Rightarrow> 'b \<Rightarrow> 'b" where
    90     "fold f [] = id"
    91   | "fold f (x # xs) = fold f xs \<circ> f x"
    92 
    93 definition 
    94   foldr :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a list \<Rightarrow> 'b \<Rightarrow> 'b" where
    95   [code_abbrev]: "foldr f xs = fold f (rev xs)"
    96 
    97 definition
    98   foldl :: "('b \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a list \<Rightarrow> 'b" where
    99   "foldl f s xs = fold (\<lambda>x s. f s x)  xs s"
   100 
   101 primrec
   102   concat:: "'a list list \<Rightarrow> 'a list" where
   103     "concat [] = []"
   104   | "concat (x # xs) = x @ concat xs"
   105 
   106 definition (in monoid_add)
   107   listsum :: "'a list \<Rightarrow> 'a" where
   108   "listsum xs = foldr plus xs 0"
   109 
   110 primrec
   111   drop:: "nat \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   112     drop_Nil: "drop n [] = []"
   113   | drop_Cons: "drop n (x # xs) = (case n of 0 \<Rightarrow> x # xs | Suc m \<Rightarrow> drop m xs)"
   114   -- {*Warning: simpset does not contain this definition, but separate
   115        theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   116 
   117 primrec
   118   take:: "nat \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   119     take_Nil:"take n [] = []"
   120   | take_Cons: "take n (x # xs) = (case n of 0 \<Rightarrow> [] | Suc m \<Rightarrow> x # take m xs)"
   121   -- {*Warning: simpset does not contain this definition, but separate
   122        theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   123 
   124 primrec
   125   nth :: "'a list => nat => 'a" (infixl "!" 100) where
   126   nth_Cons: "(x # xs) ! n = (case n of 0 \<Rightarrow> x | Suc k \<Rightarrow> xs ! k)"
   127   -- {*Warning: simpset does not contain this definition, but separate
   128        theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   129 
   130 primrec
   131   list_update :: "'a list \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a list" where
   132     "list_update [] i v = []"
   133   | "list_update (x # xs) i v = (case i of 0 \<Rightarrow> v # xs | Suc j \<Rightarrow> x # list_update xs j v)"
   134 
   135 nonterminal lupdbinds and lupdbind
   136 
   137 syntax
   138   "_lupdbind":: "['a, 'a] => lupdbind"    ("(2_ :=/ _)")
   139   "" :: "lupdbind => lupdbinds"    ("_")
   140   "_lupdbinds" :: "[lupdbind, lupdbinds] => lupdbinds"    ("_,/ _")
   141   "_LUpdate" :: "['a, lupdbinds] => 'a"    ("_/[(_)]" [900,0] 900)
   142 
   143 translations
   144   "_LUpdate xs (_lupdbinds b bs)" == "_LUpdate (_LUpdate xs b) bs"
   145   "xs[i:=x]" == "CONST list_update xs i x"
   146 
   147 primrec
   148   takeWhile :: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   149     "takeWhile P [] = []"
   150   | "takeWhile P (x # xs) = (if P x then x # takeWhile P xs else [])"
   151 
   152 primrec
   153   dropWhile :: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   154     "dropWhile P [] = []"
   155   | "dropWhile P (x # xs) = (if P x then dropWhile P xs else x # xs)"
   156 
   157 primrec
   158   zip :: "'a list \<Rightarrow> 'b list \<Rightarrow> ('a \<times> 'b) list" where
   159     "zip xs [] = []"
   160   | zip_Cons: "zip xs (y # ys) = (case xs of [] => [] | z # zs => (z, y) # zip zs ys)"
   161   -- {*Warning: simpset does not contain this definition, but separate
   162        theorems for @{text "xs = []"} and @{text "xs = z # zs"} *}
   163 
   164 primrec 
   165   upt :: "nat \<Rightarrow> nat \<Rightarrow> nat list" ("(1[_..</_'])") where
   166     upt_0: "[i..<0] = []"
   167   | upt_Suc: "[i..<(Suc j)] = (if i <= j then [i..<j] @ [j] else [])"
   168 
   169 definition
   170   insert :: "'a \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   171   "insert x xs = (if x \<in> set xs then xs else x # xs)"
   172 
   173 hide_const (open) insert
   174 hide_fact (open) insert_def
   175 
   176 primrec
   177   remove1 :: "'a \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   178     "remove1 x [] = []"
   179   | "remove1 x (y # xs) = (if x = y then xs else y # remove1 x xs)"
   180 
   181 primrec
   182   removeAll :: "'a \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   183     "removeAll x [] = []"
   184   | "removeAll x (y # xs) = (if x = y then removeAll x xs else y # removeAll x xs)"
   185 
   186 primrec
   187   distinct :: "'a list \<Rightarrow> bool" where
   188     "distinct [] \<longleftrightarrow> True"
   189   | "distinct (x # xs) \<longleftrightarrow> x \<notin> set xs \<and> distinct xs"
   190 
   191 primrec
   192   remdups :: "'a list \<Rightarrow> 'a list" where
   193     "remdups [] = []"
   194   | "remdups (x # xs) = (if x \<in> set xs then remdups xs else x # remdups xs)"
   195 
   196 primrec
   197   replicate :: "nat \<Rightarrow> 'a \<Rightarrow> 'a list" where
   198     replicate_0: "replicate 0 x = []"
   199   | replicate_Suc: "replicate (Suc n) x = x # replicate n x"
   200 
   201 text {*
   202   Function @{text size} is overloaded for all datatypes. Users may
   203   refer to the list version as @{text length}. *}
   204 
   205 abbreviation
   206   length :: "'a list \<Rightarrow> nat" where
   207   "length \<equiv> size"
   208 
   209 definition
   210   rotate1 :: "'a list \<Rightarrow> 'a list" where
   211   "rotate1 xs = (case xs of [] \<Rightarrow> [] | x#xs \<Rightarrow> xs @ [x])"
   212 
   213 definition
   214   rotate :: "nat \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   215   "rotate n = rotate1 ^^ n"
   216 
   217 definition
   218   list_all2 :: "('a => 'b => bool) => 'a list => 'b list => bool" where
   219   "list_all2 P xs ys =
   220     (length xs = length ys \<and> (\<forall>(x, y) \<in> set (zip xs ys). P x y))"
   221 
   222 definition
   223   sublist :: "'a list => nat set => 'a list" where
   224   "sublist xs A = map fst (filter (\<lambda>p. snd p \<in> A) (zip xs [0..<size xs]))"
   225 
   226 fun splice :: "'a list \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   227 "splice [] ys = ys" |
   228 "splice xs [] = xs" |
   229 "splice (x#xs) (y#ys) = x # y # splice xs ys"
   230 
   231 text{*
   232 \begin{figure}[htbp]
   233 \fbox{
   234 \begin{tabular}{l}
   235 @{lemma "[a,b]@[c,d] = [a,b,c,d]" by simp}\\
   236 @{lemma "length [a,b,c] = 3" by simp}\\
   237 @{lemma "set [a,b,c] = {a,b,c}" by simp}\\
   238 @{lemma "map f [a,b,c] = [f a, f b, f c]" by simp}\\
   239 @{lemma "rev [a,b,c] = [c,b,a]" by simp}\\
   240 @{lemma "hd [a,b,c,d] = a" by simp}\\
   241 @{lemma "tl [a,b,c,d] = [b,c,d]" by simp}\\
   242 @{lemma "last [a,b,c,d] = d" by simp}\\
   243 @{lemma "butlast [a,b,c,d] = [a,b,c]" by simp}\\
   244 @{lemma[source] "filter (\<lambda>n::nat. n<2) [0,2,1] = [0,1]" by simp}\\
   245 @{lemma "concat [[a,b],[c,d,e],[],[f]] = [a,b,c,d,e,f]" by simp}\\
   246 @{lemma "fold f [a,b,c] x = f c (f b (f a x))" by simp}\\
   247 @{lemma "foldr f [a,b,c] x = f a (f b (f c x))" by (simp add: foldr_def)}\\
   248 @{lemma "foldl f x [a,b,c] = f (f (f x a) b) c" by (simp add: foldl_def)}\\
   249 @{lemma "zip [a,b,c] [x,y,z] = [(a,x),(b,y),(c,z)]" by simp}\\
   250 @{lemma "zip [a,b] [x,y,z] = [(a,x),(b,y)]" by simp}\\
   251 @{lemma "splice [a,b,c] [x,y,z] = [a,x,b,y,c,z]" by simp}\\
   252 @{lemma "splice [a,b,c,d] [x,y] = [a,x,b,y,c,d]" by simp}\\
   253 @{lemma "take 2 [a,b,c,d] = [a,b]" by simp}\\
   254 @{lemma "take 6 [a,b,c,d] = [a,b,c,d]" by simp}\\
   255 @{lemma "drop 2 [a,b,c,d] = [c,d]" by simp}\\
   256 @{lemma "drop 6 [a,b,c,d] = []" by simp}\\
   257 @{lemma "takeWhile (%n::nat. n<3) [1,2,3,0] = [1,2]" by simp}\\
   258 @{lemma "dropWhile (%n::nat. n<3) [1,2,3,0] = [3,0]" by simp}\\
   259 @{lemma "distinct [2,0,1::nat]" by simp}\\
   260 @{lemma "remdups [2,0,2,1::nat,2] = [0,1,2]" by simp}\\
   261 @{lemma "List.insert 2 [0::nat,1,2] = [0,1,2]" by (simp add: List.insert_def)}\\
   262 @{lemma "List.insert 3 [0::nat,1,2] = [3,0,1,2]" by (simp add: List.insert_def)}\\
   263 @{lemma "remove1 2 [2,0,2,1::nat,2] = [0,2,1,2]" by simp}\\
   264 @{lemma "removeAll 2 [2,0,2,1::nat,2] = [0,1]" by simp}\\
   265 @{lemma "nth [a,b,c,d] 2 = c" by simp}\\
   266 @{lemma "[a,b,c,d][2 := x] = [a,b,x,d]" by simp}\\
   267 @{lemma "sublist [a,b,c,d,e] {0,2,3} = [a,c,d]" by (simp add:sublist_def)}\\
   268 @{lemma "rotate1 [a,b,c,d] = [b,c,d,a]" by (simp add:rotate1_def)}\\
   269 @{lemma "rotate 3 [a,b,c,d] = [d,a,b,c]" by (simp add:rotate1_def rotate_def eval_nat_numeral)}\\
   270 @{lemma "replicate 4 a = [a,a,a,a]" by (simp add:eval_nat_numeral)}\\
   271 @{lemma "[2..<5] = [2,3,4]" by (simp add:eval_nat_numeral)}\\
   272 @{lemma "listsum [1,2,3::nat] = 6" by (simp add: listsum_def foldr_def)}
   273 \end{tabular}}
   274 \caption{Characteristic examples}
   275 \label{fig:Characteristic}
   276 \end{figure}
   277 Figure~\ref{fig:Characteristic} shows characteristic examples
   278 that should give an intuitive understanding of the above functions.
   279 *}
   280 
   281 text{* The following simple sort functions are intended for proofs,
   282 not for efficient implementations. *}
   283 
   284 context linorder
   285 begin
   286 
   287 inductive sorted :: "'a list \<Rightarrow> bool" where
   288   Nil [iff]: "sorted []"
   289 | Cons: "\<forall>y\<in>set xs. x \<le> y \<Longrightarrow> sorted xs \<Longrightarrow> sorted (x # xs)"
   290 
   291 lemma sorted_single [iff]:
   292   "sorted [x]"
   293   by (rule sorted.Cons) auto
   294 
   295 lemma sorted_many:
   296   "x \<le> y \<Longrightarrow> sorted (y # zs) \<Longrightarrow> sorted (x # y # zs)"
   297   by (rule sorted.Cons) (cases "y # zs" rule: sorted.cases, auto)
   298 
   299 lemma sorted_many_eq [simp, code]:
   300   "sorted (x # y # zs) \<longleftrightarrow> x \<le> y \<and> sorted (y # zs)"
   301   by (auto intro: sorted_many elim: sorted.cases)
   302 
   303 lemma [code]:
   304   "sorted [] \<longleftrightarrow> True"
   305   "sorted [x] \<longleftrightarrow> True"
   306   by simp_all
   307 
   308 primrec insort_key :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b \<Rightarrow> 'b list \<Rightarrow> 'b list" where
   309   "insort_key f x [] = [x]" |
   310   "insort_key f x (y#ys) = (if f x \<le> f y then (x#y#ys) else y#(insort_key f x ys))"
   311 
   312 definition sort_key :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b list \<Rightarrow> 'b list" where
   313   "sort_key f xs = foldr (insort_key f) xs []"
   314 
   315 definition insort_insert_key :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b \<Rightarrow> 'b list \<Rightarrow> 'b list" where
   316   "insort_insert_key f x xs = (if f x \<in> f ` set xs then xs else insort_key f x xs)"
   317 
   318 abbreviation "sort \<equiv> sort_key (\<lambda>x. x)"
   319 abbreviation "insort \<equiv> insort_key (\<lambda>x. x)"
   320 abbreviation "insort_insert \<equiv> insort_insert_key (\<lambda>x. x)"
   321 
   322 end
   323 
   324 
   325 subsubsection {* List comprehension *}
   326 
   327 text{* Input syntax for Haskell-like list comprehension notation.
   328 Typical example: @{text"[(x,y). x \<leftarrow> xs, y \<leftarrow> ys, x \<noteq> y]"},
   329 the list of all pairs of distinct elements from @{text xs} and @{text ys}.
   330 The syntax is as in Haskell, except that @{text"|"} becomes a dot
   331 (like in Isabelle's set comprehension): @{text"[e. x \<leftarrow> xs, \<dots>]"} rather than
   332 \verb![e| x <- xs, ...]!.
   333 
   334 The qualifiers after the dot are
   335 \begin{description}
   336 \item[generators] @{text"p \<leftarrow> xs"},
   337  where @{text p} is a pattern and @{text xs} an expression of list type, or
   338 \item[guards] @{text"b"}, where @{text b} is a boolean expression.
   339 %\item[local bindings] @ {text"let x = e"}.
   340 \end{description}
   341 
   342 Just like in Haskell, list comprehension is just a shorthand. To avoid
   343 misunderstandings, the translation into desugared form is not reversed
   344 upon output. Note that the translation of @{text"[e. x \<leftarrow> xs]"} is
   345 optmized to @{term"map (%x. e) xs"}.
   346 
   347 It is easy to write short list comprehensions which stand for complex
   348 expressions. During proofs, they may become unreadable (and
   349 mangled). In such cases it can be advisable to introduce separate
   350 definitions for the list comprehensions in question.  *}
   351 
   352 nonterminal lc_qual and lc_quals
   353 
   354 syntax
   355   "_listcompr" :: "'a \<Rightarrow> lc_qual \<Rightarrow> lc_quals \<Rightarrow> 'a list"  ("[_ . __")
   356   "_lc_gen" :: "'a \<Rightarrow> 'a list \<Rightarrow> lc_qual"  ("_ <- _")
   357   "_lc_test" :: "bool \<Rightarrow> lc_qual" ("_")
   358   (*"_lc_let" :: "letbinds => lc_qual"  ("let _")*)
   359   "_lc_end" :: "lc_quals" ("]")
   360   "_lc_quals" :: "lc_qual \<Rightarrow> lc_quals \<Rightarrow> lc_quals"  (", __")
   361   "_lc_abs" :: "'a => 'b list => 'b list"
   362 
   363 (* These are easier than ML code but cannot express the optimized
   364    translation of [e. p<-xs]
   365 translations
   366   "[e. p<-xs]" => "concat(map (_lc_abs p [e]) xs)"
   367   "_listcompr e (_lc_gen p xs) (_lc_quals Q Qs)"
   368    => "concat (map (_lc_abs p (_listcompr e Q Qs)) xs)"
   369   "[e. P]" => "if P then [e] else []"
   370   "_listcompr e (_lc_test P) (_lc_quals Q Qs)"
   371    => "if P then (_listcompr e Q Qs) else []"
   372   "_listcompr e (_lc_let b) (_lc_quals Q Qs)"
   373    => "_Let b (_listcompr e Q Qs)"
   374 *)
   375 
   376 syntax (xsymbols)
   377   "_lc_gen" :: "'a \<Rightarrow> 'a list \<Rightarrow> lc_qual"  ("_ \<leftarrow> _")
   378 syntax (HTML output)
   379   "_lc_gen" :: "'a \<Rightarrow> 'a list \<Rightarrow> lc_qual"  ("_ \<leftarrow> _")
   380 
   381 parse_translation (advanced) {*
   382   let
   383     val NilC = Syntax.const @{const_syntax Nil};
   384     val ConsC = Syntax.const @{const_syntax Cons};
   385     val mapC = Syntax.const @{const_syntax map};
   386     val concatC = Syntax.const @{const_syntax concat};
   387     val IfC = Syntax.const @{const_syntax If};
   388 
   389     fun single x = ConsC $ x $ NilC;
   390 
   391     fun pat_tr ctxt p e opti = (* %x. case x of p => e | _ => [] *)
   392       let
   393         (* FIXME proper name context!? *)
   394         val x =
   395           Free (singleton (Name.variant_list (fold Term.add_free_names [p, e] [])) "x", dummyT);
   396         val e = if opti then single e else e;
   397         val case1 = Syntax.const @{syntax_const "_case1"} $ p $ e;
   398         val case2 =
   399           Syntax.const @{syntax_const "_case1"} $
   400             Syntax.const @{const_syntax dummy_pattern} $ NilC;
   401         val cs = Syntax.const @{syntax_const "_case2"} $ case1 $ case2;
   402       in Syntax_Trans.abs_tr [x, Datatype_Case.case_tr false ctxt [x, cs]] end;
   403 
   404     fun abs_tr ctxt p e opti =
   405       (case Term_Position.strip_positions p of
   406         Free (s, T) =>
   407           let
   408             val thy = Proof_Context.theory_of ctxt;
   409             val s' = Proof_Context.intern_const ctxt s;
   410           in
   411             if Sign.declared_const thy s'
   412             then (pat_tr ctxt p e opti, false)
   413             else (Syntax_Trans.abs_tr [p, e], true)
   414           end
   415       | _ => (pat_tr ctxt p e opti, false));
   416 
   417     fun lc_tr ctxt [e, Const (@{syntax_const "_lc_test"}, _) $ b, qs] =
   418           let
   419             val res =
   420               (case qs of
   421                 Const (@{syntax_const "_lc_end"}, _) => single e
   422               | Const (@{syntax_const "_lc_quals"}, _) $ q $ qs => lc_tr ctxt [e, q, qs]);
   423           in IfC $ b $ res $ NilC end
   424       | lc_tr ctxt
   425             [e, Const (@{syntax_const "_lc_gen"}, _) $ p $ es,
   426               Const(@{syntax_const "_lc_end"}, _)] =
   427           (case abs_tr ctxt p e true of
   428             (f, true) => mapC $ f $ es
   429           | (f, false) => concatC $ (mapC $ f $ es))
   430       | lc_tr ctxt
   431             [e, Const (@{syntax_const "_lc_gen"}, _) $ p $ es,
   432               Const (@{syntax_const "_lc_quals"}, _) $ q $ qs] =
   433           let val e' = lc_tr ctxt [e, q, qs];
   434           in concatC $ (mapC $ (fst (abs_tr ctxt p e' false)) $ es) end;
   435 
   436   in [(@{syntax_const "_listcompr"}, lc_tr)] end
   437 *}
   438 
   439 ML {*
   440   let
   441     val read = Syntax.read_term @{context};
   442     fun check s1 s2 = read s1 aconv read s2 orelse error ("Check failed: " ^ quote s1);
   443   in
   444     check "[(x,y,z). b]" "if b then [(x, y, z)] else []";
   445     check "[(x,y,z). x\<leftarrow>xs]" "map (\<lambda>x. (x, y, z)) xs";
   446     check "[e x y. x\<leftarrow>xs, y\<leftarrow>ys]" "concat (map (\<lambda>x. map (\<lambda>y. e x y) ys) xs)";
   447     check "[(x,y,z). x<a, x>b]" "if x < a then if b < x then [(x, y, z)] else [] else []";
   448     check "[(x,y,z). x\<leftarrow>xs, x>b]" "concat (map (\<lambda>x. if b < x then [(x, y, z)] else []) xs)";
   449     check "[(x,y,z). x<a, x\<leftarrow>xs]" "if x < a then map (\<lambda>x. (x, y, z)) xs else []";
   450     check "[(x,y). Cons True x \<leftarrow> xs]"
   451       "concat (map (\<lambda>xa. case xa of [] \<Rightarrow> [] | True # x \<Rightarrow> [(x, y)] | False # x \<Rightarrow> []) xs)";
   452     check "[(x,y,z). Cons x [] \<leftarrow> xs]"
   453       "concat (map (\<lambda>xa. case xa of [] \<Rightarrow> [] | [x] \<Rightarrow> [(x, y, z)] | x # aa # lista \<Rightarrow> []) xs)";
   454     check "[(x,y,z). x<a, x>b, x=d]"
   455       "if x < a then if b < x then if x = d then [(x, y, z)] else [] else [] else []";
   456     check "[(x,y,z). x<a, x>b, y\<leftarrow>ys]"
   457       "if x < a then if b < x then map (\<lambda>y. (x, y, z)) ys else [] else []";
   458     check "[(x,y,z). x<a, x\<leftarrow>xs,y>b]"
   459       "if x < a then concat (map (\<lambda>x. if b < y then [(x, y, z)] else []) xs) else []";
   460     check "[(x,y,z). x<a, x\<leftarrow>xs, y\<leftarrow>ys]"
   461       "if x < a then concat (map (\<lambda>x. map (\<lambda>y. (x, y, z)) ys) xs) else []";
   462     check "[(x,y,z). x\<leftarrow>xs, x>b, y<a]"
   463       "concat (map (\<lambda>x. if b < x then if y < a then [(x, y, z)] else [] else []) xs)";
   464     check "[(x,y,z). x\<leftarrow>xs, x>b, y\<leftarrow>ys]"
   465       "concat (map (\<lambda>x. if b < x then map (\<lambda>y. (x, y, z)) ys else []) xs)";
   466     check "[(x,y,z). x\<leftarrow>xs, y\<leftarrow>ys,y>x]"
   467       "concat (map (\<lambda>x. concat (map (\<lambda>y. if x < y then [(x, y, z)] else []) ys)) xs)";
   468     check "[(x,y,z). x\<leftarrow>xs, y\<leftarrow>ys,z\<leftarrow>zs]"
   469       "concat (map (\<lambda>x. concat (map (\<lambda>y. map (\<lambda>z. (x, y, z)) zs) ys)) xs)"
   470   end;
   471 *}
   472 
   473 (*
   474 term "[(x,y). x\<leftarrow>xs, let xx = x+x, y\<leftarrow>ys, y \<noteq> xx]"
   475 *)
   476 
   477 
   478 use "Tools/list_to_set_comprehension.ML"
   479 
   480 simproc_setup list_to_set_comprehension ("set xs") = {* K List_to_Set_Comprehension.simproc *}
   481 
   482 code_datatype set coset
   483 
   484 hide_const (open) coset
   485 
   486 subsubsection {* @{const Nil} and @{const Cons} *}
   487 
   488 lemma not_Cons_self [simp]:
   489   "xs \<noteq> x # xs"
   490 by (induct xs) auto
   491 
   492 lemma not_Cons_self2 [simp]:
   493   "x # xs \<noteq> xs"
   494 by (rule not_Cons_self [symmetric])
   495 
   496 lemma neq_Nil_conv: "(xs \<noteq> []) = (\<exists>y ys. xs = y # ys)"
   497 by (induct xs) auto
   498 
   499 lemma length_induct:
   500   "(\<And>xs. \<forall>ys. length ys < length xs \<longrightarrow> P ys \<Longrightarrow> P xs) \<Longrightarrow> P xs"
   501 by (rule measure_induct [of length]) iprover
   502 
   503 lemma list_nonempty_induct [consumes 1, case_names single cons]:
   504   assumes "xs \<noteq> []"
   505   assumes single: "\<And>x. P [x]"
   506   assumes cons: "\<And>x xs. xs \<noteq> [] \<Longrightarrow> P xs \<Longrightarrow> P (x # xs)"
   507   shows "P xs"
   508 using `xs \<noteq> []` proof (induct xs)
   509   case Nil then show ?case by simp
   510 next
   511   case (Cons x xs) show ?case proof (cases xs)
   512     case Nil with single show ?thesis by simp
   513   next
   514     case Cons then have "xs \<noteq> []" by simp
   515     moreover with Cons.hyps have "P xs" .
   516     ultimately show ?thesis by (rule cons)
   517   qed
   518 qed
   519 
   520 lemma inj_split_Cons: "inj_on (\<lambda>(xs, n). n#xs) X"
   521   by (auto intro!: inj_onI)
   522 
   523 subsubsection {* @{const length} *}
   524 
   525 text {*
   526   Needs to come before @{text "@"} because of theorem @{text
   527   append_eq_append_conv}.
   528 *}
   529 
   530 lemma length_append [simp]: "length (xs @ ys) = length xs + length ys"
   531 by (induct xs) auto
   532 
   533 lemma length_map [simp]: "length (map f xs) = length xs"
   534 by (induct xs) auto
   535 
   536 lemma length_rev [simp]: "length (rev xs) = length xs"
   537 by (induct xs) auto
   538 
   539 lemma length_tl [simp]: "length (tl xs) = length xs - 1"
   540 by (cases xs) auto
   541 
   542 lemma length_0_conv [iff]: "(length xs = 0) = (xs = [])"
   543 by (induct xs) auto
   544 
   545 lemma length_greater_0_conv [iff]: "(0 < length xs) = (xs \<noteq> [])"
   546 by (induct xs) auto
   547 
   548 lemma length_pos_if_in_set: "x : set xs \<Longrightarrow> length xs > 0"
   549 by auto
   550 
   551 lemma length_Suc_conv:
   552 "(length xs = Suc n) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   553 by (induct xs) auto
   554 
   555 lemma Suc_length_conv:
   556 "(Suc n = length xs) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   557 apply (induct xs, simp, simp)
   558 apply blast
   559 done
   560 
   561 lemma impossible_Cons: "length xs <= length ys ==> xs = x # ys = False"
   562   by (induct xs) auto
   563 
   564 lemma list_induct2 [consumes 1, case_names Nil Cons]:
   565   "length xs = length ys \<Longrightarrow> P [] [] \<Longrightarrow>
   566    (\<And>x xs y ys. length xs = length ys \<Longrightarrow> P xs ys \<Longrightarrow> P (x#xs) (y#ys))
   567    \<Longrightarrow> P xs ys"
   568 proof (induct xs arbitrary: ys)
   569   case Nil then show ?case by simp
   570 next
   571   case (Cons x xs ys) then show ?case by (cases ys) simp_all
   572 qed
   573 
   574 lemma list_induct3 [consumes 2, case_names Nil Cons]:
   575   "length xs = length ys \<Longrightarrow> length ys = length zs \<Longrightarrow> P [] [] [] \<Longrightarrow>
   576    (\<And>x xs y ys z zs. length xs = length ys \<Longrightarrow> length ys = length zs \<Longrightarrow> P xs ys zs \<Longrightarrow> P (x#xs) (y#ys) (z#zs))
   577    \<Longrightarrow> P xs ys zs"
   578 proof (induct xs arbitrary: ys zs)
   579   case Nil then show ?case by simp
   580 next
   581   case (Cons x xs ys zs) then show ?case by (cases ys, simp_all)
   582     (cases zs, simp_all)
   583 qed
   584 
   585 lemma list_induct4 [consumes 3, case_names Nil Cons]:
   586   "length xs = length ys \<Longrightarrow> length ys = length zs \<Longrightarrow> length zs = length ws \<Longrightarrow>
   587    P [] [] [] [] \<Longrightarrow> (\<And>x xs y ys z zs w ws. length xs = length ys \<Longrightarrow>
   588    length ys = length zs \<Longrightarrow> length zs = length ws \<Longrightarrow> P xs ys zs ws \<Longrightarrow>
   589    P (x#xs) (y#ys) (z#zs) (w#ws)) \<Longrightarrow> P xs ys zs ws"
   590 proof (induct xs arbitrary: ys zs ws)
   591   case Nil then show ?case by simp
   592 next
   593   case (Cons x xs ys zs ws) then show ?case by ((cases ys, simp_all), (cases zs,simp_all)) (cases ws, simp_all)
   594 qed
   595 
   596 lemma list_induct2': 
   597   "\<lbrakk> P [] [];
   598   \<And>x xs. P (x#xs) [];
   599   \<And>y ys. P [] (y#ys);
   600    \<And>x xs y ys. P xs ys  \<Longrightarrow> P (x#xs) (y#ys) \<rbrakk>
   601  \<Longrightarrow> P xs ys"
   602 by (induct xs arbitrary: ys) (case_tac x, auto)+
   603 
   604 lemma neq_if_length_neq: "length xs \<noteq> length ys \<Longrightarrow> (xs = ys) == False"
   605 by (rule Eq_FalseI) auto
   606 
   607 simproc_setup list_neq ("(xs::'a list) = ys") = {*
   608 (*
   609 Reduces xs=ys to False if xs and ys cannot be of the same length.
   610 This is the case if the atomic sublists of one are a submultiset
   611 of those of the other list and there are fewer Cons's in one than the other.
   612 *)
   613 
   614 let
   615 
   616 fun len (Const(@{const_name Nil},_)) acc = acc
   617   | len (Const(@{const_name Cons},_) $ _ $ xs) (ts,n) = len xs (ts,n+1)
   618   | len (Const(@{const_name append},_) $ xs $ ys) acc = len xs (len ys acc)
   619   | len (Const(@{const_name rev},_) $ xs) acc = len xs acc
   620   | len (Const(@{const_name map},_) $ _ $ xs) acc = len xs acc
   621   | len t (ts,n) = (t::ts,n);
   622 
   623 fun list_neq _ ss ct =
   624   let
   625     val (Const(_,eqT) $ lhs $ rhs) = Thm.term_of ct;
   626     val (ls,m) = len lhs ([],0) and (rs,n) = len rhs ([],0);
   627     fun prove_neq() =
   628       let
   629         val Type(_,listT::_) = eqT;
   630         val size = HOLogic.size_const listT;
   631         val eq_len = HOLogic.mk_eq (size $ lhs, size $ rhs);
   632         val neq_len = HOLogic.mk_Trueprop (HOLogic.Not $ eq_len);
   633         val thm = Goal.prove (Simplifier.the_context ss) [] [] neq_len
   634           (K (simp_tac (Simplifier.inherit_context ss @{simpset}) 1));
   635       in SOME (thm RS @{thm neq_if_length_neq}) end
   636   in
   637     if m < n andalso submultiset (op aconv) (ls,rs) orelse
   638        n < m andalso submultiset (op aconv) (rs,ls)
   639     then prove_neq() else NONE
   640   end;
   641 in list_neq end;
   642 *}
   643 
   644 
   645 subsubsection {* @{text "@"} -- append *}
   646 
   647 lemma append_assoc [simp]: "(xs @ ys) @ zs = xs @ (ys @ zs)"
   648 by (induct xs) auto
   649 
   650 lemma append_Nil2 [simp]: "xs @ [] = xs"
   651 by (induct xs) auto
   652 
   653 lemma append_is_Nil_conv [iff]: "(xs @ ys = []) = (xs = [] \<and> ys = [])"
   654 by (induct xs) auto
   655 
   656 lemma Nil_is_append_conv [iff]: "([] = xs @ ys) = (xs = [] \<and> ys = [])"
   657 by (induct xs) auto
   658 
   659 lemma append_self_conv [iff]: "(xs @ ys = xs) = (ys = [])"
   660 by (induct xs) auto
   661 
   662 lemma self_append_conv [iff]: "(xs = xs @ ys) = (ys = [])"
   663 by (induct xs) auto
   664 
   665 lemma append_eq_append_conv [simp, no_atp]:
   666  "length xs = length ys \<or> length us = length vs
   667  ==> (xs@us = ys@vs) = (xs=ys \<and> us=vs)"
   668 apply (induct xs arbitrary: ys)
   669  apply (case_tac ys, simp, force)
   670 apply (case_tac ys, force, simp)
   671 done
   672 
   673 lemma append_eq_append_conv2: "(xs @ ys = zs @ ts) =
   674   (EX us. xs = zs @ us & us @ ys = ts | xs @ us = zs & ys = us@ ts)"
   675 apply (induct xs arbitrary: ys zs ts)
   676  apply fastforce
   677 apply(case_tac zs)
   678  apply simp
   679 apply fastforce
   680 done
   681 
   682 lemma same_append_eq [iff, induct_simp]: "(xs @ ys = xs @ zs) = (ys = zs)"
   683 by simp
   684 
   685 lemma append1_eq_conv [iff]: "(xs @ [x] = ys @ [y]) = (xs = ys \<and> x = y)"
   686 by simp
   687 
   688 lemma append_same_eq [iff, induct_simp]: "(ys @ xs = zs @ xs) = (ys = zs)"
   689 by simp
   690 
   691 lemma append_self_conv2 [iff]: "(xs @ ys = ys) = (xs = [])"
   692 using append_same_eq [of _ _ "[]"] by auto
   693 
   694 lemma self_append_conv2 [iff]: "(ys = xs @ ys) = (xs = [])"
   695 using append_same_eq [of "[]"] by auto
   696 
   697 lemma hd_Cons_tl [simp,no_atp]: "xs \<noteq> [] ==> hd xs # tl xs = xs"
   698 by (induct xs) auto
   699 
   700 lemma hd_append: "hd (xs @ ys) = (if xs = [] then hd ys else hd xs)"
   701 by (induct xs) auto
   702 
   703 lemma hd_append2 [simp]: "xs \<noteq> [] ==> hd (xs @ ys) = hd xs"
   704 by (simp add: hd_append split: list.split)
   705 
   706 lemma tl_append: "tl (xs @ ys) = (case xs of [] => tl ys | z#zs => zs @ ys)"
   707 by (simp split: list.split)
   708 
   709 lemma tl_append2 [simp]: "xs \<noteq> [] ==> tl (xs @ ys) = tl xs @ ys"
   710 by (simp add: tl_append split: list.split)
   711 
   712 
   713 lemma Cons_eq_append_conv: "x#xs = ys@zs =
   714  (ys = [] & x#xs = zs | (EX ys'. x#ys' = ys & xs = ys'@zs))"
   715 by(cases ys) auto
   716 
   717 lemma append_eq_Cons_conv: "(ys@zs = x#xs) =
   718  (ys = [] & zs = x#xs | (EX ys'. ys = x#ys' & ys'@zs = xs))"
   719 by(cases ys) auto
   720 
   721 
   722 text {* Trivial rules for solving @{text "@"}-equations automatically. *}
   723 
   724 lemma eq_Nil_appendI: "xs = ys ==> xs = [] @ ys"
   725 by simp
   726 
   727 lemma Cons_eq_appendI:
   728 "[| x # xs1 = ys; xs = xs1 @ zs |] ==> x # xs = ys @ zs"
   729 by (drule sym) simp
   730 
   731 lemma append_eq_appendI:
   732 "[| xs @ xs1 = zs; ys = xs1 @ us |] ==> xs @ ys = zs @ us"
   733 by (drule sym) simp
   734 
   735 
   736 text {*
   737 Simplification procedure for all list equalities.
   738 Currently only tries to rearrange @{text "@"} to see if
   739 - both lists end in a singleton list,
   740 - or both lists end in the same list.
   741 *}
   742 
   743 simproc_setup list_eq ("(xs::'a list) = ys")  = {*
   744   let
   745     fun last (cons as Const (@{const_name Cons}, _) $ _ $ xs) =
   746           (case xs of Const (@{const_name Nil}, _) => cons | _ => last xs)
   747       | last (Const(@{const_name append},_) $ _ $ ys) = last ys
   748       | last t = t;
   749     
   750     fun list1 (Const(@{const_name Cons},_) $ _ $ Const(@{const_name Nil},_)) = true
   751       | list1 _ = false;
   752     
   753     fun butlast ((cons as Const(@{const_name Cons},_) $ x) $ xs) =
   754           (case xs of Const (@{const_name Nil}, _) => xs | _ => cons $ butlast xs)
   755       | butlast ((app as Const (@{const_name append}, _) $ xs) $ ys) = app $ butlast ys
   756       | butlast xs = Const(@{const_name Nil}, fastype_of xs);
   757     
   758     val rearr_ss =
   759       HOL_basic_ss addsimps [@{thm append_assoc}, @{thm append_Nil}, @{thm append_Cons}];
   760     
   761     fun list_eq ss (F as (eq as Const(_,eqT)) $ lhs $ rhs) =
   762       let
   763         val lastl = last lhs and lastr = last rhs;
   764         fun rearr conv =
   765           let
   766             val lhs1 = butlast lhs and rhs1 = butlast rhs;
   767             val Type(_,listT::_) = eqT
   768             val appT = [listT,listT] ---> listT
   769             val app = Const(@{const_name append},appT)
   770             val F2 = eq $ (app$lhs1$lastl) $ (app$rhs1$lastr)
   771             val eq = HOLogic.mk_Trueprop (HOLogic.mk_eq (F,F2));
   772             val thm = Goal.prove (Simplifier.the_context ss) [] [] eq
   773               (K (simp_tac (Simplifier.inherit_context ss rearr_ss) 1));
   774           in SOME ((conv RS (thm RS trans)) RS eq_reflection) end;
   775       in
   776         if list1 lastl andalso list1 lastr then rearr @{thm append1_eq_conv}
   777         else if lastl aconv lastr then rearr @{thm append_same_eq}
   778         else NONE
   779       end;
   780   in fn _ => fn ss => fn ct => list_eq ss (term_of ct) end;
   781 *}
   782 
   783 
   784 subsubsection {* @{text map} *}
   785 
   786 lemma hd_map:
   787   "xs \<noteq> [] \<Longrightarrow> hd (map f xs) = f (hd xs)"
   788   by (cases xs) simp_all
   789 
   790 lemma map_tl:
   791   "map f (tl xs) = tl (map f xs)"
   792   by (cases xs) simp_all
   793 
   794 lemma map_ext: "(!!x. x : set xs --> f x = g x) ==> map f xs = map g xs"
   795 by (induct xs) simp_all
   796 
   797 lemma map_ident [simp]: "map (\<lambda>x. x) = (\<lambda>xs. xs)"
   798 by (rule ext, induct_tac xs) auto
   799 
   800 lemma map_append [simp]: "map f (xs @ ys) = map f xs @ map f ys"
   801 by (induct xs) auto
   802 
   803 lemma map_map [simp]: "map f (map g xs) = map (f \<circ> g) xs"
   804 by (induct xs) auto
   805 
   806 lemma map_comp_map[simp]: "((map f) o (map g)) = map(f o g)"
   807 apply(rule ext)
   808 apply(simp)
   809 done
   810 
   811 lemma rev_map: "rev (map f xs) = map f (rev xs)"
   812 by (induct xs) auto
   813 
   814 lemma map_eq_conv[simp]: "(map f xs = map g xs) = (!x : set xs. f x = g x)"
   815 by (induct xs) auto
   816 
   817 lemma map_cong [fundef_cong]:
   818   "xs = ys \<Longrightarrow> (\<And>x. x \<in> set ys \<Longrightarrow> f x = g x) \<Longrightarrow> map f xs = map g ys"
   819   by simp
   820 
   821 lemma map_is_Nil_conv [iff]: "(map f xs = []) = (xs = [])"
   822 by (cases xs) auto
   823 
   824 lemma Nil_is_map_conv [iff]: "([] = map f xs) = (xs = [])"
   825 by (cases xs) auto
   826 
   827 lemma map_eq_Cons_conv:
   828  "(map f xs = y#ys) = (\<exists>z zs. xs = z#zs \<and> f z = y \<and> map f zs = ys)"
   829 by (cases xs) auto
   830 
   831 lemma Cons_eq_map_conv:
   832  "(x#xs = map f ys) = (\<exists>z zs. ys = z#zs \<and> x = f z \<and> xs = map f zs)"
   833 by (cases ys) auto
   834 
   835 lemmas map_eq_Cons_D = map_eq_Cons_conv [THEN iffD1]
   836 lemmas Cons_eq_map_D = Cons_eq_map_conv [THEN iffD1]
   837 declare map_eq_Cons_D [dest!]  Cons_eq_map_D [dest!]
   838 
   839 lemma ex_map_conv:
   840   "(EX xs. ys = map f xs) = (ALL y : set ys. EX x. y = f x)"
   841 by(induct ys, auto simp add: Cons_eq_map_conv)
   842 
   843 lemma map_eq_imp_length_eq:
   844   assumes "map f xs = map g ys"
   845   shows "length xs = length ys"
   846 using assms proof (induct ys arbitrary: xs)
   847   case Nil then show ?case by simp
   848 next
   849   case (Cons y ys) then obtain z zs where xs: "xs = z # zs" by auto
   850   from Cons xs have "map f zs = map g ys" by simp
   851   moreover with Cons have "length zs = length ys" by blast
   852   with xs show ?case by simp
   853 qed
   854   
   855 lemma map_inj_on:
   856  "[| map f xs = map f ys; inj_on f (set xs Un set ys) |]
   857   ==> xs = ys"
   858 apply(frule map_eq_imp_length_eq)
   859 apply(rotate_tac -1)
   860 apply(induct rule:list_induct2)
   861  apply simp
   862 apply(simp)
   863 apply (blast intro:sym)
   864 done
   865 
   866 lemma inj_on_map_eq_map:
   867  "inj_on f (set xs Un set ys) \<Longrightarrow> (map f xs = map f ys) = (xs = ys)"
   868 by(blast dest:map_inj_on)
   869 
   870 lemma map_injective:
   871  "map f xs = map f ys ==> inj f ==> xs = ys"
   872 by (induct ys arbitrary: xs) (auto dest!:injD)
   873 
   874 lemma inj_map_eq_map[simp]: "inj f \<Longrightarrow> (map f xs = map f ys) = (xs = ys)"
   875 by(blast dest:map_injective)
   876 
   877 lemma inj_mapI: "inj f ==> inj (map f)"
   878 by (iprover dest: map_injective injD intro: inj_onI)
   879 
   880 lemma inj_mapD: "inj (map f) ==> inj f"
   881 apply (unfold inj_on_def, clarify)
   882 apply (erule_tac x = "[x]" in ballE)
   883  apply (erule_tac x = "[y]" in ballE, simp, blast)
   884 apply blast
   885 done
   886 
   887 lemma inj_map[iff]: "inj (map f) = inj f"
   888 by (blast dest: inj_mapD intro: inj_mapI)
   889 
   890 lemma inj_on_mapI: "inj_on f (\<Union>(set ` A)) \<Longrightarrow> inj_on (map f) A"
   891 apply(rule inj_onI)
   892 apply(erule map_inj_on)
   893 apply(blast intro:inj_onI dest:inj_onD)
   894 done
   895 
   896 lemma map_idI: "(\<And>x. x \<in> set xs \<Longrightarrow> f x = x) \<Longrightarrow> map f xs = xs"
   897 by (induct xs, auto)
   898 
   899 lemma map_fun_upd [simp]: "y \<notin> set xs \<Longrightarrow> map (f(y:=v)) xs = map f xs"
   900 by (induct xs) auto
   901 
   902 lemma map_fst_zip[simp]:
   903   "length xs = length ys \<Longrightarrow> map fst (zip xs ys) = xs"
   904 by (induct rule:list_induct2, simp_all)
   905 
   906 lemma map_snd_zip[simp]:
   907   "length xs = length ys \<Longrightarrow> map snd (zip xs ys) = ys"
   908 by (induct rule:list_induct2, simp_all)
   909 
   910 enriched_type map: map
   911   by (simp_all add: fun_eq_iff id_def)
   912 
   913 
   914 subsubsection {* @{text rev} *}
   915 
   916 lemma rev_append [simp]: "rev (xs @ ys) = rev ys @ rev xs"
   917 by (induct xs) auto
   918 
   919 lemma rev_rev_ident [simp]: "rev (rev xs) = xs"
   920 by (induct xs) auto
   921 
   922 lemma rev_swap: "(rev xs = ys) = (xs = rev ys)"
   923 by auto
   924 
   925 lemma rev_is_Nil_conv [iff]: "(rev xs = []) = (xs = [])"
   926 by (induct xs) auto
   927 
   928 lemma Nil_is_rev_conv [iff]: "([] = rev xs) = (xs = [])"
   929 by (induct xs) auto
   930 
   931 lemma rev_singleton_conv [simp]: "(rev xs = [x]) = (xs = [x])"
   932 by (cases xs) auto
   933 
   934 lemma singleton_rev_conv [simp]: "([x] = rev xs) = (xs = [x])"
   935 by (cases xs) auto
   936 
   937 lemma rev_is_rev_conv [iff]: "(rev xs = rev ys) = (xs = ys)"
   938 apply (induct xs arbitrary: ys, force)
   939 apply (case_tac ys, simp, force)
   940 done
   941 
   942 lemma inj_on_rev[iff]: "inj_on rev A"
   943 by(simp add:inj_on_def)
   944 
   945 lemma rev_induct [case_names Nil snoc]:
   946   "[| P []; !!x xs. P xs ==> P (xs @ [x]) |] ==> P xs"
   947 apply(simplesubst rev_rev_ident[symmetric])
   948 apply(rule_tac list = "rev xs" in list.induct, simp_all)
   949 done
   950 
   951 lemma rev_exhaust [case_names Nil snoc]:
   952   "(xs = [] ==> P) ==>(!!ys y. xs = ys @ [y] ==> P) ==> P"
   953 by (induct xs rule: rev_induct) auto
   954 
   955 lemmas rev_cases = rev_exhaust
   956 
   957 lemma rev_eq_Cons_iff[iff]: "(rev xs = y#ys) = (xs = rev ys @ [y])"
   958 by(rule rev_cases[of xs]) auto
   959 
   960 
   961 subsubsection {* @{text set} *}
   962 
   963 lemma finite_set [iff]: "finite (set xs)"
   964 by (induct xs) auto
   965 
   966 lemma set_append [simp]: "set (xs @ ys) = (set xs \<union> set ys)"
   967 by (induct xs) auto
   968 
   969 lemma hd_in_set[simp]: "xs \<noteq> [] \<Longrightarrow> hd xs : set xs"
   970 by(cases xs) auto
   971 
   972 lemma set_subset_Cons: "set xs \<subseteq> set (x # xs)"
   973 by auto
   974 
   975 lemma set_ConsD: "y \<in> set (x # xs) \<Longrightarrow> y=x \<or> y \<in> set xs" 
   976 by auto
   977 
   978 lemma set_empty [iff]: "(set xs = {}) = (xs = [])"
   979 by (induct xs) auto
   980 
   981 lemma set_empty2[iff]: "({} = set xs) = (xs = [])"
   982 by(induct xs) auto
   983 
   984 lemma set_rev [simp]: "set (rev xs) = set xs"
   985 by (induct xs) auto
   986 
   987 lemma set_map [simp]: "set (map f xs) = f`(set xs)"
   988 by (induct xs) auto
   989 
   990 lemma set_filter [simp]: "set (filter P xs) = {x. x : set xs \<and> P x}"
   991 by (induct xs) auto
   992 
   993 lemma set_upt [simp]: "set[i..<j] = {i..<j}"
   994 by (induct j) auto
   995 
   996 
   997 lemma split_list: "x : set xs \<Longrightarrow> \<exists>ys zs. xs = ys @ x # zs"
   998 proof (induct xs)
   999   case Nil thus ?case by simp
  1000 next
  1001   case Cons thus ?case by (auto intro: Cons_eq_appendI)
  1002 qed
  1003 
  1004 lemma in_set_conv_decomp: "x \<in> set xs \<longleftrightarrow> (\<exists>ys zs. xs = ys @ x # zs)"
  1005   by (auto elim: split_list)
  1006 
  1007 lemma split_list_first: "x : set xs \<Longrightarrow> \<exists>ys zs. xs = ys @ x # zs \<and> x \<notin> set ys"
  1008 proof (induct xs)
  1009   case Nil thus ?case by simp
  1010 next
  1011   case (Cons a xs)
  1012   show ?case
  1013   proof cases
  1014     assume "x = a" thus ?case using Cons by fastforce
  1015   next
  1016     assume "x \<noteq> a" thus ?case using Cons by(fastforce intro!: Cons_eq_appendI)
  1017   qed
  1018 qed
  1019 
  1020 lemma in_set_conv_decomp_first:
  1021   "(x : set xs) = (\<exists>ys zs. xs = ys @ x # zs \<and> x \<notin> set ys)"
  1022   by (auto dest!: split_list_first)
  1023 
  1024 lemma split_list_last: "x \<in> set xs \<Longrightarrow> \<exists>ys zs. xs = ys @ x # zs \<and> x \<notin> set zs"
  1025 proof (induct xs rule: rev_induct)
  1026   case Nil thus ?case by simp
  1027 next
  1028   case (snoc a xs)
  1029   show ?case
  1030   proof cases
  1031     assume "x = a" thus ?case using snoc by (metis List.set.simps(1) emptyE)
  1032   next
  1033     assume "x \<noteq> a" thus ?case using snoc by fastforce
  1034   qed
  1035 qed
  1036 
  1037 lemma in_set_conv_decomp_last:
  1038   "(x : set xs) = (\<exists>ys zs. xs = ys @ x # zs \<and> x \<notin> set zs)"
  1039   by (auto dest!: split_list_last)
  1040 
  1041 lemma split_list_prop: "\<exists>x \<in> set xs. P x \<Longrightarrow> \<exists>ys x zs. xs = ys @ x # zs & P x"
  1042 proof (induct xs)
  1043   case Nil thus ?case by simp
  1044 next
  1045   case Cons thus ?case
  1046     by(simp add:Bex_def)(metis append_Cons append.simps(1))
  1047 qed
  1048 
  1049 lemma split_list_propE:
  1050   assumes "\<exists>x \<in> set xs. P x"
  1051   obtains ys x zs where "xs = ys @ x # zs" and "P x"
  1052 using split_list_prop [OF assms] by blast
  1053 
  1054 lemma split_list_first_prop:
  1055   "\<exists>x \<in> set xs. P x \<Longrightarrow>
  1056    \<exists>ys x zs. xs = ys@x#zs \<and> P x \<and> (\<forall>y \<in> set ys. \<not> P y)"
  1057 proof (induct xs)
  1058   case Nil thus ?case by simp
  1059 next
  1060   case (Cons x xs)
  1061   show ?case
  1062   proof cases
  1063     assume "P x"
  1064     thus ?thesis by simp (metis Un_upper1 contra_subsetD in_set_conv_decomp_first self_append_conv2 set_append)
  1065   next
  1066     assume "\<not> P x"
  1067     hence "\<exists>x\<in>set xs. P x" using Cons(2) by simp
  1068     thus ?thesis using `\<not> P x` Cons(1) by (metis append_Cons set_ConsD)
  1069   qed
  1070 qed
  1071 
  1072 lemma split_list_first_propE:
  1073   assumes "\<exists>x \<in> set xs. P x"
  1074   obtains ys x zs where "xs = ys @ x # zs" and "P x" and "\<forall>y \<in> set ys. \<not> P y"
  1075 using split_list_first_prop [OF assms] by blast
  1076 
  1077 lemma split_list_first_prop_iff:
  1078   "(\<exists>x \<in> set xs. P x) \<longleftrightarrow>
  1079    (\<exists>ys x zs. xs = ys@x#zs \<and> P x \<and> (\<forall>y \<in> set ys. \<not> P y))"
  1080 by (rule, erule split_list_first_prop) auto
  1081 
  1082 lemma split_list_last_prop:
  1083   "\<exists>x \<in> set xs. P x \<Longrightarrow>
  1084    \<exists>ys x zs. xs = ys@x#zs \<and> P x \<and> (\<forall>z \<in> set zs. \<not> P z)"
  1085 proof(induct xs rule:rev_induct)
  1086   case Nil thus ?case by simp
  1087 next
  1088   case (snoc x xs)
  1089   show ?case
  1090   proof cases
  1091     assume "P x" thus ?thesis by (metis emptyE set_empty)
  1092   next
  1093     assume "\<not> P x"
  1094     hence "\<exists>x\<in>set xs. P x" using snoc(2) by simp
  1095     thus ?thesis using `\<not> P x` snoc(1) by fastforce
  1096   qed
  1097 qed
  1098 
  1099 lemma split_list_last_propE:
  1100   assumes "\<exists>x \<in> set xs. P x"
  1101   obtains ys x zs where "xs = ys @ x # zs" and "P x" and "\<forall>z \<in> set zs. \<not> P z"
  1102 using split_list_last_prop [OF assms] by blast
  1103 
  1104 lemma split_list_last_prop_iff:
  1105   "(\<exists>x \<in> set xs. P x) \<longleftrightarrow>
  1106    (\<exists>ys x zs. xs = ys@x#zs \<and> P x \<and> (\<forall>z \<in> set zs. \<not> P z))"
  1107 by (metis split_list_last_prop [where P=P] in_set_conv_decomp)
  1108 
  1109 lemma finite_list: "finite A ==> EX xs. set xs = A"
  1110   by (erule finite_induct)
  1111     (auto simp add: set.simps(2) [symmetric] simp del: set.simps(2))
  1112 
  1113 lemma card_length: "card (set xs) \<le> length xs"
  1114 by (induct xs) (auto simp add: card_insert_if)
  1115 
  1116 lemma set_minus_filter_out:
  1117   "set xs - {y} = set (filter (\<lambda>x. \<not> (x = y)) xs)"
  1118   by (induct xs) auto
  1119 
  1120 
  1121 subsubsection {* @{text filter} *}
  1122 
  1123 lemma filter_append [simp]: "filter P (xs @ ys) = filter P xs @ filter P ys"
  1124 by (induct xs) auto
  1125 
  1126 lemma rev_filter: "rev (filter P xs) = filter P (rev xs)"
  1127 by (induct xs) simp_all
  1128 
  1129 lemma filter_filter [simp]: "filter P (filter Q xs) = filter (\<lambda>x. Q x \<and> P x) xs"
  1130 by (induct xs) auto
  1131 
  1132 lemma length_filter_le [simp]: "length (filter P xs) \<le> length xs"
  1133 by (induct xs) (auto simp add: le_SucI)
  1134 
  1135 lemma sum_length_filter_compl:
  1136   "length(filter P xs) + length(filter (%x. ~P x) xs) = length xs"
  1137 by(induct xs) simp_all
  1138 
  1139 lemma filter_True [simp]: "\<forall>x \<in> set xs. P x ==> filter P xs = xs"
  1140 by (induct xs) auto
  1141 
  1142 lemma filter_False [simp]: "\<forall>x \<in> set xs. \<not> P x ==> filter P xs = []"
  1143 by (induct xs) auto
  1144 
  1145 lemma filter_empty_conv: "(filter P xs = []) = (\<forall>x\<in>set xs. \<not> P x)" 
  1146 by (induct xs) simp_all
  1147 
  1148 lemma filter_id_conv: "(filter P xs = xs) = (\<forall>x\<in>set xs. P x)"
  1149 apply (induct xs)
  1150  apply auto
  1151 apply(cut_tac P=P and xs=xs in length_filter_le)
  1152 apply simp
  1153 done
  1154 
  1155 lemma filter_map:
  1156   "filter P (map f xs) = map f (filter (P o f) xs)"
  1157 by (induct xs) simp_all
  1158 
  1159 lemma length_filter_map[simp]:
  1160   "length (filter P (map f xs)) = length(filter (P o f) xs)"
  1161 by (simp add:filter_map)
  1162 
  1163 lemma filter_is_subset [simp]: "set (filter P xs) \<le> set xs"
  1164 by auto
  1165 
  1166 lemma length_filter_less:
  1167   "\<lbrakk> x : set xs; ~ P x \<rbrakk> \<Longrightarrow> length(filter P xs) < length xs"
  1168 proof (induct xs)
  1169   case Nil thus ?case by simp
  1170 next
  1171   case (Cons x xs) thus ?case
  1172     apply (auto split:split_if_asm)
  1173     using length_filter_le[of P xs] apply arith
  1174   done
  1175 qed
  1176 
  1177 lemma length_filter_conv_card:
  1178  "length(filter p xs) = card{i. i < length xs & p(xs!i)}"
  1179 proof (induct xs)
  1180   case Nil thus ?case by simp
  1181 next
  1182   case (Cons x xs)
  1183   let ?S = "{i. i < length xs & p(xs!i)}"
  1184   have fin: "finite ?S" by(fast intro: bounded_nat_set_is_finite)
  1185   show ?case (is "?l = card ?S'")
  1186   proof (cases)
  1187     assume "p x"
  1188     hence eq: "?S' = insert 0 (Suc ` ?S)"
  1189       by(auto simp: image_def split:nat.split dest:gr0_implies_Suc)
  1190     have "length (filter p (x # xs)) = Suc(card ?S)"
  1191       using Cons `p x` by simp
  1192     also have "\<dots> = Suc(card(Suc ` ?S))" using fin
  1193       by (simp add: card_image)
  1194     also have "\<dots> = card ?S'" using eq fin
  1195       by (simp add:card_insert_if) (simp add:image_def)
  1196     finally show ?thesis .
  1197   next
  1198     assume "\<not> p x"
  1199     hence eq: "?S' = Suc ` ?S"
  1200       by(auto simp add: image_def split:nat.split elim:lessE)
  1201     have "length (filter p (x # xs)) = card ?S"
  1202       using Cons `\<not> p x` by simp
  1203     also have "\<dots> = card(Suc ` ?S)" using fin
  1204       by (simp add: card_image)
  1205     also have "\<dots> = card ?S'" using eq fin
  1206       by (simp add:card_insert_if)
  1207     finally show ?thesis .
  1208   qed
  1209 qed
  1210 
  1211 lemma Cons_eq_filterD:
  1212  "x#xs = filter P ys \<Longrightarrow>
  1213   \<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs"
  1214   (is "_ \<Longrightarrow> \<exists>us vs. ?P ys us vs")
  1215 proof(induct ys)
  1216   case Nil thus ?case by simp
  1217 next
  1218   case (Cons y ys)
  1219   show ?case (is "\<exists>x. ?Q x")
  1220   proof cases
  1221     assume Py: "P y"
  1222     show ?thesis
  1223     proof cases
  1224       assume "x = y"
  1225       with Py Cons.prems have "?Q []" by simp
  1226       then show ?thesis ..
  1227     next
  1228       assume "x \<noteq> y"
  1229       with Py Cons.prems show ?thesis by simp
  1230     qed
  1231   next
  1232     assume "\<not> P y"
  1233     with Cons obtain us vs where "?P (y#ys) (y#us) vs" by fastforce
  1234     then have "?Q (y#us)" by simp
  1235     then show ?thesis ..
  1236   qed
  1237 qed
  1238 
  1239 lemma filter_eq_ConsD:
  1240  "filter P ys = x#xs \<Longrightarrow>
  1241   \<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs"
  1242 by(rule Cons_eq_filterD) simp
  1243 
  1244 lemma filter_eq_Cons_iff:
  1245  "(filter P ys = x#xs) =
  1246   (\<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs)"
  1247 by(auto dest:filter_eq_ConsD)
  1248 
  1249 lemma Cons_eq_filter_iff:
  1250  "(x#xs = filter P ys) =
  1251   (\<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs)"
  1252 by(auto dest:Cons_eq_filterD)
  1253 
  1254 lemma filter_cong[fundef_cong]:
  1255  "xs = ys \<Longrightarrow> (\<And>x. x \<in> set ys \<Longrightarrow> P x = Q x) \<Longrightarrow> filter P xs = filter Q ys"
  1256 apply simp
  1257 apply(erule thin_rl)
  1258 by (induct ys) simp_all
  1259 
  1260 
  1261 subsubsection {* List partitioning *}
  1262 
  1263 primrec partition :: "('a \<Rightarrow> bool) \<Rightarrow>'a list \<Rightarrow> 'a list \<times> 'a list" where
  1264   "partition P [] = ([], [])"
  1265   | "partition P (x # xs) = 
  1266       (let (yes, no) = partition P xs
  1267       in if P x then (x # yes, no) else (yes, x # no))"
  1268 
  1269 lemma partition_filter1:
  1270     "fst (partition P xs) = filter P xs"
  1271 by (induct xs) (auto simp add: Let_def split_def)
  1272 
  1273 lemma partition_filter2:
  1274     "snd (partition P xs) = filter (Not o P) xs"
  1275 by (induct xs) (auto simp add: Let_def split_def)
  1276 
  1277 lemma partition_P:
  1278   assumes "partition P xs = (yes, no)"
  1279   shows "(\<forall>p \<in> set yes.  P p) \<and> (\<forall>p  \<in> set no. \<not> P p)"
  1280 proof -
  1281   from assms have "yes = fst (partition P xs)" and "no = snd (partition P xs)"
  1282     by simp_all
  1283   then show ?thesis by (simp_all add: partition_filter1 partition_filter2)
  1284 qed
  1285 
  1286 lemma partition_set:
  1287   assumes "partition P xs = (yes, no)"
  1288   shows "set yes \<union> set no = set xs"
  1289 proof -
  1290   from assms have "yes = fst (partition P xs)" and "no = snd (partition P xs)"
  1291     by simp_all
  1292   then show ?thesis by (auto simp add: partition_filter1 partition_filter2) 
  1293 qed
  1294 
  1295 lemma partition_filter_conv[simp]:
  1296   "partition f xs = (filter f xs,filter (Not o f) xs)"
  1297 unfolding partition_filter2[symmetric]
  1298 unfolding partition_filter1[symmetric] by simp
  1299 
  1300 declare partition.simps[simp del]
  1301 
  1302 
  1303 subsubsection {* @{text concat} *}
  1304 
  1305 lemma concat_append [simp]: "concat (xs @ ys) = concat xs @ concat ys"
  1306 by (induct xs) auto
  1307 
  1308 lemma concat_eq_Nil_conv [simp]: "(concat xss = []) = (\<forall>xs \<in> set xss. xs = [])"
  1309 by (induct xss) auto
  1310 
  1311 lemma Nil_eq_concat_conv [simp]: "([] = concat xss) = (\<forall>xs \<in> set xss. xs = [])"
  1312 by (induct xss) auto
  1313 
  1314 lemma set_concat [simp]: "set (concat xs) = (UN x:set xs. set x)"
  1315 by (induct xs) auto
  1316 
  1317 lemma concat_map_singleton[simp]: "concat(map (%x. [f x]) xs) = map f xs"
  1318 by (induct xs) auto
  1319 
  1320 lemma map_concat: "map f (concat xs) = concat (map (map f) xs)"
  1321 by (induct xs) auto
  1322 
  1323 lemma filter_concat: "filter p (concat xs) = concat (map (filter p) xs)"
  1324 by (induct xs) auto
  1325 
  1326 lemma rev_concat: "rev (concat xs) = concat (map rev (rev xs))"
  1327 by (induct xs) auto
  1328 
  1329 lemma concat_eq_concat_iff: "\<forall>(x, y) \<in> set (zip xs ys). length x = length y ==> length xs = length ys ==> (concat xs = concat ys) = (xs = ys)"
  1330 proof (induct xs arbitrary: ys)
  1331   case (Cons x xs ys)
  1332   thus ?case by (cases ys) auto
  1333 qed (auto)
  1334 
  1335 lemma concat_injective: "concat xs = concat ys ==> length xs = length ys ==> \<forall>(x, y) \<in> set (zip xs ys). length x = length y ==> xs = ys"
  1336 by (simp add: concat_eq_concat_iff)
  1337 
  1338 
  1339 subsubsection {* @{text nth} *}
  1340 
  1341 lemma nth_Cons_0 [simp, code]: "(x # xs)!0 = x"
  1342 by auto
  1343 
  1344 lemma nth_Cons_Suc [simp, code]: "(x # xs)!(Suc n) = xs!n"
  1345 by auto
  1346 
  1347 declare nth.simps [simp del]
  1348 
  1349 lemma nth_Cons_pos[simp]: "0 < n \<Longrightarrow> (x#xs) ! n = xs ! (n - 1)"
  1350 by(auto simp: Nat.gr0_conv_Suc)
  1351 
  1352 lemma nth_append:
  1353   "(xs @ ys)!n = (if n < length xs then xs!n else ys!(n - length xs))"
  1354 apply (induct xs arbitrary: n, simp)
  1355 apply (case_tac n, auto)
  1356 done
  1357 
  1358 lemma nth_append_length [simp]: "(xs @ x # ys) ! length xs = x"
  1359 by (induct xs) auto
  1360 
  1361 lemma nth_append_length_plus[simp]: "(xs @ ys) ! (length xs + n) = ys ! n"
  1362 by (induct xs) auto
  1363 
  1364 lemma nth_map [simp]: "n < length xs ==> (map f xs)!n = f(xs!n)"
  1365 apply (induct xs arbitrary: n, simp)
  1366 apply (case_tac n, auto)
  1367 done
  1368 
  1369 lemma nth_tl:
  1370   assumes "n < length (tl x)" shows "tl x ! n = x ! Suc n"
  1371 using assms by (induct x) auto
  1372 
  1373 lemma hd_conv_nth: "xs \<noteq> [] \<Longrightarrow> hd xs = xs!0"
  1374 by(cases xs) simp_all
  1375 
  1376 
  1377 lemma list_eq_iff_nth_eq:
  1378  "(xs = ys) = (length xs = length ys \<and> (ALL i<length xs. xs!i = ys!i))"
  1379 apply(induct xs arbitrary: ys)
  1380  apply force
  1381 apply(case_tac ys)
  1382  apply simp
  1383 apply(simp add:nth_Cons split:nat.split)apply blast
  1384 done
  1385 
  1386 lemma set_conv_nth: "set xs = {xs!i | i. i < length xs}"
  1387 apply (induct xs, simp, simp)
  1388 apply safe
  1389 apply (metis nat_case_0 nth.simps zero_less_Suc)
  1390 apply (metis less_Suc_eq_0_disj nth_Cons_Suc)
  1391 apply (case_tac i, simp)
  1392 apply (metis diff_Suc_Suc nat_case_Suc nth.simps zero_less_diff)
  1393 done
  1394 
  1395 lemma in_set_conv_nth: "(x \<in> set xs) = (\<exists>i < length xs. xs!i = x)"
  1396 by(auto simp:set_conv_nth)
  1397 
  1398 lemma list_ball_nth: "[| n < length xs; !x : set xs. P x|] ==> P(xs!n)"
  1399 by (auto simp add: set_conv_nth)
  1400 
  1401 lemma nth_mem [simp]: "n < length xs ==> xs!n : set xs"
  1402 by (auto simp add: set_conv_nth)
  1403 
  1404 lemma all_nth_imp_all_set:
  1405 "[| !i < length xs. P(xs!i); x : set xs|] ==> P x"
  1406 by (auto simp add: set_conv_nth)
  1407 
  1408 lemma all_set_conv_all_nth:
  1409 "(\<forall>x \<in> set xs. P x) = (\<forall>i. i < length xs --> P (xs ! i))"
  1410 by (auto simp add: set_conv_nth)
  1411 
  1412 lemma rev_nth:
  1413   "n < size xs \<Longrightarrow> rev xs ! n = xs ! (length xs - Suc n)"
  1414 proof (induct xs arbitrary: n)
  1415   case Nil thus ?case by simp
  1416 next
  1417   case (Cons x xs)
  1418   hence n: "n < Suc (length xs)" by simp
  1419   moreover
  1420   { assume "n < length xs"
  1421     with n obtain n' where "length xs - n = Suc n'"
  1422       by (cases "length xs - n", auto)
  1423     moreover
  1424     then have "length xs - Suc n = n'" by simp
  1425     ultimately
  1426     have "xs ! (length xs - Suc n) = (x # xs) ! (length xs - n)" by simp
  1427   }
  1428   ultimately
  1429   show ?case by (clarsimp simp add: Cons nth_append)
  1430 qed
  1431 
  1432 lemma Skolem_list_nth:
  1433   "(ALL i<k. EX x. P i x) = (EX xs. size xs = k & (ALL i<k. P i (xs!i)))"
  1434   (is "_ = (EX xs. ?P k xs)")
  1435 proof(induct k)
  1436   case 0 show ?case by simp
  1437 next
  1438   case (Suc k)
  1439   show ?case (is "?L = ?R" is "_ = (EX xs. ?P' xs)")
  1440   proof
  1441     assume "?R" thus "?L" using Suc by auto
  1442   next
  1443     assume "?L"
  1444     with Suc obtain x xs where "?P k xs & P k x" by (metis less_Suc_eq)
  1445     hence "?P'(xs@[x])" by(simp add:nth_append less_Suc_eq)
  1446     thus "?R" ..
  1447   qed
  1448 qed
  1449 
  1450 
  1451 subsubsection {* @{text list_update} *}
  1452 
  1453 lemma length_list_update [simp]: "length(xs[i:=x]) = length xs"
  1454 by (induct xs arbitrary: i) (auto split: nat.split)
  1455 
  1456 lemma nth_list_update:
  1457 "i < length xs==> (xs[i:=x])!j = (if i = j then x else xs!j)"
  1458 by (induct xs arbitrary: i j) (auto simp add: nth_Cons split: nat.split)
  1459 
  1460 lemma nth_list_update_eq [simp]: "i < length xs ==> (xs[i:=x])!i = x"
  1461 by (simp add: nth_list_update)
  1462 
  1463 lemma nth_list_update_neq [simp]: "i \<noteq> j ==> xs[i:=x]!j = xs!j"
  1464 by (induct xs arbitrary: i j) (auto simp add: nth_Cons split: nat.split)
  1465 
  1466 lemma list_update_id[simp]: "xs[i := xs!i] = xs"
  1467 by (induct xs arbitrary: i) (simp_all split:nat.splits)
  1468 
  1469 lemma list_update_beyond[simp]: "length xs \<le> i \<Longrightarrow> xs[i:=x] = xs"
  1470 apply (induct xs arbitrary: i)
  1471  apply simp
  1472 apply (case_tac i)
  1473 apply simp_all
  1474 done
  1475 
  1476 lemma list_update_nonempty[simp]: "xs[k:=x] = [] \<longleftrightarrow> xs=[]"
  1477 by(metis length_0_conv length_list_update)
  1478 
  1479 lemma list_update_same_conv:
  1480 "i < length xs ==> (xs[i := x] = xs) = (xs!i = x)"
  1481 by (induct xs arbitrary: i) (auto split: nat.split)
  1482 
  1483 lemma list_update_append1:
  1484  "i < size xs \<Longrightarrow> (xs @ ys)[i:=x] = xs[i:=x] @ ys"
  1485 apply (induct xs arbitrary: i, simp)
  1486 apply(simp split:nat.split)
  1487 done
  1488 
  1489 lemma list_update_append:
  1490   "(xs @ ys) [n:= x] = 
  1491   (if n < length xs then xs[n:= x] @ ys else xs @ (ys [n-length xs:= x]))"
  1492 by (induct xs arbitrary: n) (auto split:nat.splits)
  1493 
  1494 lemma list_update_length [simp]:
  1495  "(xs @ x # ys)[length xs := y] = (xs @ y # ys)"
  1496 by (induct xs, auto)
  1497 
  1498 lemma map_update: "map f (xs[k:= y]) = (map f xs)[k := f y]"
  1499 by(induct xs arbitrary: k)(auto split:nat.splits)
  1500 
  1501 lemma rev_update:
  1502   "k < length xs \<Longrightarrow> rev (xs[k:= y]) = (rev xs)[length xs - k - 1 := y]"
  1503 by (induct xs arbitrary: k) (auto simp: list_update_append split:nat.splits)
  1504 
  1505 lemma update_zip:
  1506   "(zip xs ys)[i:=xy] = zip (xs[i:=fst xy]) (ys[i:=snd xy])"
  1507 by (induct ys arbitrary: i xy xs) (auto, case_tac xs, auto split: nat.split)
  1508 
  1509 lemma set_update_subset_insert: "set(xs[i:=x]) <= insert x (set xs)"
  1510 by (induct xs arbitrary: i) (auto split: nat.split)
  1511 
  1512 lemma set_update_subsetI: "[| set xs <= A; x:A |] ==> set(xs[i := x]) <= A"
  1513 by (blast dest!: set_update_subset_insert [THEN subsetD])
  1514 
  1515 lemma set_update_memI: "n < length xs \<Longrightarrow> x \<in> set (xs[n := x])"
  1516 by (induct xs arbitrary: n) (auto split:nat.splits)
  1517 
  1518 lemma list_update_overwrite[simp]:
  1519   "xs [i := x, i := y] = xs [i := y]"
  1520 apply (induct xs arbitrary: i) apply simp
  1521 apply (case_tac i, simp_all)
  1522 done
  1523 
  1524 lemma list_update_swap:
  1525   "i \<noteq> i' \<Longrightarrow> xs [i := x, i' := x'] = xs [i' := x', i := x]"
  1526 apply (induct xs arbitrary: i i')
  1527 apply simp
  1528 apply (case_tac i, case_tac i')
  1529 apply auto
  1530 apply (case_tac i')
  1531 apply auto
  1532 done
  1533 
  1534 lemma list_update_code [code]:
  1535   "[][i := y] = []"
  1536   "(x # xs)[0 := y] = y # xs"
  1537   "(x # xs)[Suc i := y] = x # xs[i := y]"
  1538   by simp_all
  1539 
  1540 
  1541 subsubsection {* @{text last} and @{text butlast} *}
  1542 
  1543 lemma last_snoc [simp]: "last (xs @ [x]) = x"
  1544 by (induct xs) auto
  1545 
  1546 lemma butlast_snoc [simp]: "butlast (xs @ [x]) = xs"
  1547 by (induct xs) auto
  1548 
  1549 lemma last_ConsL: "xs = [] \<Longrightarrow> last(x#xs) = x"
  1550   by simp
  1551 
  1552 lemma last_ConsR: "xs \<noteq> [] \<Longrightarrow> last(x#xs) = last xs"
  1553   by simp
  1554 
  1555 lemma last_append: "last(xs @ ys) = (if ys = [] then last xs else last ys)"
  1556 by (induct xs) (auto)
  1557 
  1558 lemma last_appendL[simp]: "ys = [] \<Longrightarrow> last(xs @ ys) = last xs"
  1559 by(simp add:last_append)
  1560 
  1561 lemma last_appendR[simp]: "ys \<noteq> [] \<Longrightarrow> last(xs @ ys) = last ys"
  1562 by(simp add:last_append)
  1563 
  1564 lemma last_tl: "xs = [] \<or> tl xs \<noteq> [] \<Longrightarrow>last (tl xs) = last xs"
  1565 by (induct xs) simp_all
  1566 
  1567 lemma butlast_tl: "butlast (tl xs) = tl (butlast xs)"
  1568 by (induct xs) simp_all
  1569 
  1570 lemma hd_rev: "xs \<noteq> [] \<Longrightarrow> hd(rev xs) = last xs"
  1571 by(rule rev_exhaust[of xs]) simp_all
  1572 
  1573 lemma last_rev: "xs \<noteq> [] \<Longrightarrow> last(rev xs) = hd xs"
  1574 by(cases xs) simp_all
  1575 
  1576 lemma last_in_set[simp]: "as \<noteq> [] \<Longrightarrow> last as \<in> set as"
  1577 by (induct as) auto
  1578 
  1579 lemma length_butlast [simp]: "length (butlast xs) = length xs - 1"
  1580 by (induct xs rule: rev_induct) auto
  1581 
  1582 lemma butlast_append:
  1583   "butlast (xs @ ys) = (if ys = [] then butlast xs else xs @ butlast ys)"
  1584 by (induct xs arbitrary: ys) auto
  1585 
  1586 lemma append_butlast_last_id [simp]:
  1587 "xs \<noteq> [] ==> butlast xs @ [last xs] = xs"
  1588 by (induct xs) auto
  1589 
  1590 lemma in_set_butlastD: "x : set (butlast xs) ==> x : set xs"
  1591 by (induct xs) (auto split: split_if_asm)
  1592 
  1593 lemma in_set_butlast_appendI:
  1594 "x : set (butlast xs) | x : set (butlast ys) ==> x : set (butlast (xs @ ys))"
  1595 by (auto dest: in_set_butlastD simp add: butlast_append)
  1596 
  1597 lemma last_drop[simp]: "n < length xs \<Longrightarrow> last (drop n xs) = last xs"
  1598 apply (induct xs arbitrary: n)
  1599  apply simp
  1600 apply (auto split:nat.split)
  1601 done
  1602 
  1603 lemma nth_butlast:
  1604   assumes "n < length (butlast xs)" shows "butlast xs ! n = xs ! n"
  1605 proof (cases xs)
  1606   case (Cons y ys)
  1607   moreover from assms have "butlast xs ! n = (butlast xs @ [last xs]) ! n"
  1608     by (simp add: nth_append)
  1609   ultimately show ?thesis using append_butlast_last_id by simp
  1610 qed simp
  1611 
  1612 lemma last_conv_nth: "xs\<noteq>[] \<Longrightarrow> last xs = xs!(length xs - 1)"
  1613 by(induct xs)(auto simp:neq_Nil_conv)
  1614 
  1615 lemma butlast_conv_take: "butlast xs = take (length xs - 1) xs"
  1616 by (induct xs, simp, case_tac xs, simp_all)
  1617 
  1618 lemma last_list_update:
  1619   "xs \<noteq> [] \<Longrightarrow> last(xs[k:=x]) = (if k = size xs - 1 then x else last xs)"
  1620 by (auto simp: last_conv_nth)
  1621 
  1622 lemma butlast_list_update:
  1623   "butlast(xs[k:=x]) =
  1624  (if k = size xs - 1 then butlast xs else (butlast xs)[k:=x])"
  1625 apply(cases xs rule:rev_cases)
  1626 apply simp
  1627 apply(simp add:list_update_append split:nat.splits)
  1628 done
  1629 
  1630 lemma last_map:
  1631   "xs \<noteq> [] \<Longrightarrow> last (map f xs) = f (last xs)"
  1632   by (cases xs rule: rev_cases) simp_all
  1633 
  1634 lemma map_butlast:
  1635   "map f (butlast xs) = butlast (map f xs)"
  1636   by (induct xs) simp_all
  1637 
  1638 lemma snoc_eq_iff_butlast:
  1639   "xs @ [x] = ys \<longleftrightarrow> (ys \<noteq> [] & butlast ys = xs & last ys = x)"
  1640 by (metis append_butlast_last_id append_is_Nil_conv butlast_snoc last_snoc not_Cons_self)
  1641 
  1642 
  1643 subsubsection {* @{text take} and @{text drop} *}
  1644 
  1645 lemma take_0 [simp]: "take 0 xs = []"
  1646 by (induct xs) auto
  1647 
  1648 lemma drop_0 [simp]: "drop 0 xs = xs"
  1649 by (induct xs) auto
  1650 
  1651 lemma take_Suc_Cons [simp]: "take (Suc n) (x # xs) = x # take n xs"
  1652 by simp
  1653 
  1654 lemma drop_Suc_Cons [simp]: "drop (Suc n) (x # xs) = drop n xs"
  1655 by simp
  1656 
  1657 declare take_Cons [simp del] and drop_Cons [simp del]
  1658 
  1659 lemma take_1_Cons [simp]: "take 1 (x # xs) = [x]"
  1660   unfolding One_nat_def by simp
  1661 
  1662 lemma drop_1_Cons [simp]: "drop 1 (x # xs) = xs"
  1663   unfolding One_nat_def by simp
  1664 
  1665 lemma take_Suc: "xs ~= [] ==> take (Suc n) xs = hd xs # take n (tl xs)"
  1666 by(clarsimp simp add:neq_Nil_conv)
  1667 
  1668 lemma drop_Suc: "drop (Suc n) xs = drop n (tl xs)"
  1669 by(cases xs, simp_all)
  1670 
  1671 lemma take_tl: "take n (tl xs) = tl (take (Suc n) xs)"
  1672 by (induct xs arbitrary: n) simp_all
  1673 
  1674 lemma drop_tl: "drop n (tl xs) = tl(drop n xs)"
  1675 by(induct xs arbitrary: n, simp_all add:drop_Cons drop_Suc split:nat.split)
  1676 
  1677 lemma tl_take: "tl (take n xs) = take (n - 1) (tl xs)"
  1678 by (cases n, simp, cases xs, auto)
  1679 
  1680 lemma tl_drop: "tl (drop n xs) = drop n (tl xs)"
  1681 by (simp only: drop_tl)
  1682 
  1683 lemma nth_via_drop: "drop n xs = y#ys \<Longrightarrow> xs!n = y"
  1684 apply (induct xs arbitrary: n, simp)
  1685 apply(simp add:drop_Cons nth_Cons split:nat.splits)
  1686 done
  1687 
  1688 lemma take_Suc_conv_app_nth:
  1689   "i < length xs \<Longrightarrow> take (Suc i) xs = take i xs @ [xs!i]"
  1690 apply (induct xs arbitrary: i, simp)
  1691 apply (case_tac i, auto)
  1692 done
  1693 
  1694 lemma drop_Suc_conv_tl:
  1695   "i < length xs \<Longrightarrow> (xs!i) # (drop (Suc i) xs) = drop i xs"
  1696 apply (induct xs arbitrary: i, simp)
  1697 apply (case_tac i, auto)
  1698 done
  1699 
  1700 lemma length_take [simp]: "length (take n xs) = min (length xs) n"
  1701 by (induct n arbitrary: xs) (auto, case_tac xs, auto)
  1702 
  1703 lemma length_drop [simp]: "length (drop n xs) = (length xs - n)"
  1704 by (induct n arbitrary: xs) (auto, case_tac xs, auto)
  1705 
  1706 lemma take_all [simp]: "length xs <= n ==> take n xs = xs"
  1707 by (induct n arbitrary: xs) (auto, case_tac xs, auto)
  1708 
  1709 lemma drop_all [simp]: "length xs <= n ==> drop n xs = []"
  1710 by (induct n arbitrary: xs) (auto, case_tac xs, auto)
  1711 
  1712 lemma take_append [simp]:
  1713   "take n (xs @ ys) = (take n xs @ take (n - length xs) ys)"
  1714 by (induct n arbitrary: xs) (auto, case_tac xs, auto)
  1715 
  1716 lemma drop_append [simp]:
  1717   "drop n (xs @ ys) = drop n xs @ drop (n - length xs) ys"
  1718 by (induct n arbitrary: xs) (auto, case_tac xs, auto)
  1719 
  1720 lemma take_take [simp]: "take n (take m xs) = take (min n m) xs"
  1721 apply (induct m arbitrary: xs n, auto)
  1722 apply (case_tac xs, auto)
  1723 apply (case_tac n, auto)
  1724 done
  1725 
  1726 lemma drop_drop [simp]: "drop n (drop m xs) = drop (n + m) xs"
  1727 apply (induct m arbitrary: xs, auto)
  1728 apply (case_tac xs, auto)
  1729 done
  1730 
  1731 lemma take_drop: "take n (drop m xs) = drop m (take (n + m) xs)"
  1732 apply (induct m arbitrary: xs n, auto)
  1733 apply (case_tac xs, auto)
  1734 done
  1735 
  1736 lemma drop_take: "drop n (take m xs) = take (m-n) (drop n xs)"
  1737 apply(induct xs arbitrary: m n)
  1738  apply simp
  1739 apply(simp add: take_Cons drop_Cons split:nat.split)
  1740 done
  1741 
  1742 lemma append_take_drop_id [simp]: "take n xs @ drop n xs = xs"
  1743 apply (induct n arbitrary: xs, auto)
  1744 apply (case_tac xs, auto)
  1745 done
  1746 
  1747 lemma take_eq_Nil[simp]: "(take n xs = []) = (n = 0 \<or> xs = [])"
  1748 apply(induct xs arbitrary: n)
  1749  apply simp
  1750 apply(simp add:take_Cons split:nat.split)
  1751 done
  1752 
  1753 lemma drop_eq_Nil[simp]: "(drop n xs = []) = (length xs <= n)"
  1754 apply(induct xs arbitrary: n)
  1755 apply simp
  1756 apply(simp add:drop_Cons split:nat.split)
  1757 done
  1758 
  1759 lemma take_map: "take n (map f xs) = map f (take n xs)"
  1760 apply (induct n arbitrary: xs, auto)
  1761 apply (case_tac xs, auto)
  1762 done
  1763 
  1764 lemma drop_map: "drop n (map f xs) = map f (drop n xs)"
  1765 apply (induct n arbitrary: xs, auto)
  1766 apply (case_tac xs, auto)
  1767 done
  1768 
  1769 lemma rev_take: "rev (take i xs) = drop (length xs - i) (rev xs)"
  1770 apply (induct xs arbitrary: i, auto)
  1771 apply (case_tac i, auto)
  1772 done
  1773 
  1774 lemma rev_drop: "rev (drop i xs) = take (length xs - i) (rev xs)"
  1775 apply (induct xs arbitrary: i, auto)
  1776 apply (case_tac i, auto)
  1777 done
  1778 
  1779 lemma nth_take [simp]: "i < n ==> (take n xs)!i = xs!i"
  1780 apply (induct xs arbitrary: i n, auto)
  1781 apply (case_tac n, blast)
  1782 apply (case_tac i, auto)
  1783 done
  1784 
  1785 lemma nth_drop [simp]:
  1786   "n + i <= length xs ==> (drop n xs)!i = xs!(n + i)"
  1787 apply (induct n arbitrary: xs i, auto)
  1788 apply (case_tac xs, auto)
  1789 done
  1790 
  1791 lemma butlast_take:
  1792   "n <= length xs ==> butlast (take n xs) = take (n - 1) xs"
  1793 by (simp add: butlast_conv_take min_max.inf_absorb1 min_max.inf_absorb2)
  1794 
  1795 lemma butlast_drop: "butlast (drop n xs) = drop n (butlast xs)"
  1796 by (simp add: butlast_conv_take drop_take add_ac)
  1797 
  1798 lemma take_butlast: "n < length xs ==> take n (butlast xs) = take n xs"
  1799 by (simp add: butlast_conv_take min_max.inf_absorb1)
  1800 
  1801 lemma drop_butlast: "drop n (butlast xs) = butlast (drop n xs)"
  1802 by (simp add: butlast_conv_take drop_take add_ac)
  1803 
  1804 lemma hd_drop_conv_nth: "\<lbrakk> xs \<noteq> []; n < length xs \<rbrakk> \<Longrightarrow> hd(drop n xs) = xs!n"
  1805 by(simp add: hd_conv_nth)
  1806 
  1807 lemma set_take_subset_set_take:
  1808   "m <= n \<Longrightarrow> set(take m xs) <= set(take n xs)"
  1809 apply (induct xs arbitrary: m n)
  1810 apply simp
  1811 apply (case_tac n)
  1812 apply (auto simp: take_Cons)
  1813 done
  1814 
  1815 lemma set_take_subset: "set(take n xs) \<subseteq> set xs"
  1816 by(induct xs arbitrary: n)(auto simp:take_Cons split:nat.split)
  1817 
  1818 lemma set_drop_subset: "set(drop n xs) \<subseteq> set xs"
  1819 by(induct xs arbitrary: n)(auto simp:drop_Cons split:nat.split)
  1820 
  1821 lemma set_drop_subset_set_drop:
  1822   "m >= n \<Longrightarrow> set(drop m xs) <= set(drop n xs)"
  1823 apply(induct xs arbitrary: m n)
  1824 apply(auto simp:drop_Cons split:nat.split)
  1825 apply (metis set_drop_subset subset_iff)
  1826 done
  1827 
  1828 lemma in_set_takeD: "x : set(take n xs) \<Longrightarrow> x : set xs"
  1829 using set_take_subset by fast
  1830 
  1831 lemma in_set_dropD: "x : set(drop n xs) \<Longrightarrow> x : set xs"
  1832 using set_drop_subset by fast
  1833 
  1834 lemma append_eq_conv_conj:
  1835   "(xs @ ys = zs) = (xs = take (length xs) zs \<and> ys = drop (length xs) zs)"
  1836 apply (induct xs arbitrary: zs, simp, clarsimp)
  1837 apply (case_tac zs, auto)
  1838 done
  1839 
  1840 lemma take_add: 
  1841   "take (i+j) xs = take i xs @ take j (drop i xs)"
  1842 apply (induct xs arbitrary: i, auto) 
  1843 apply (case_tac i, simp_all)
  1844 done
  1845 
  1846 lemma append_eq_append_conv_if:
  1847  "(xs\<^isub>1 @ xs\<^isub>2 = ys\<^isub>1 @ ys\<^isub>2) =
  1848   (if size xs\<^isub>1 \<le> size ys\<^isub>1
  1849    then xs\<^isub>1 = take (size xs\<^isub>1) ys\<^isub>1 \<and> xs\<^isub>2 = drop (size xs\<^isub>1) ys\<^isub>1 @ ys\<^isub>2
  1850    else take (size ys\<^isub>1) xs\<^isub>1 = ys\<^isub>1 \<and> drop (size ys\<^isub>1) xs\<^isub>1 @ xs\<^isub>2 = ys\<^isub>2)"
  1851 apply(induct xs\<^isub>1 arbitrary: ys\<^isub>1)
  1852  apply simp
  1853 apply(case_tac ys\<^isub>1)
  1854 apply simp_all
  1855 done
  1856 
  1857 lemma take_hd_drop:
  1858   "n < length xs \<Longrightarrow> take n xs @ [hd (drop n xs)] = take (Suc n) xs"
  1859 apply(induct xs arbitrary: n)
  1860 apply simp
  1861 apply(simp add:drop_Cons split:nat.split)
  1862 done
  1863 
  1864 lemma id_take_nth_drop:
  1865  "i < length xs \<Longrightarrow> xs = take i xs @ xs!i # drop (Suc i) xs" 
  1866 proof -
  1867   assume si: "i < length xs"
  1868   hence "xs = take (Suc i) xs @ drop (Suc i) xs" by auto
  1869   moreover
  1870   from si have "take (Suc i) xs = take i xs @ [xs!i]"
  1871     apply (rule_tac take_Suc_conv_app_nth) by arith
  1872   ultimately show ?thesis by auto
  1873 qed
  1874   
  1875 lemma upd_conv_take_nth_drop:
  1876  "i < length xs \<Longrightarrow> xs[i:=a] = take i xs @ a # drop (Suc i) xs"
  1877 proof -
  1878   assume i: "i < length xs"
  1879   have "xs[i:=a] = (take i xs @ xs!i # drop (Suc i) xs)[i:=a]"
  1880     by(rule arg_cong[OF id_take_nth_drop[OF i]])
  1881   also have "\<dots> = take i xs @ a # drop (Suc i) xs"
  1882     using i by (simp add: list_update_append)
  1883   finally show ?thesis .
  1884 qed
  1885 
  1886 lemma nth_drop':
  1887   "i < length xs \<Longrightarrow> xs ! i # drop (Suc i) xs = drop i xs"
  1888 apply (induct i arbitrary: xs)
  1889 apply (simp add: neq_Nil_conv)
  1890 apply (erule exE)+
  1891 apply simp
  1892 apply (case_tac xs)
  1893 apply simp_all
  1894 done
  1895 
  1896 
  1897 subsubsection {* @{text takeWhile} and @{text dropWhile} *}
  1898 
  1899 lemma length_takeWhile_le: "length (takeWhile P xs) \<le> length xs"
  1900   by (induct xs) auto
  1901 
  1902 lemma takeWhile_dropWhile_id [simp]: "takeWhile P xs @ dropWhile P xs = xs"
  1903 by (induct xs) auto
  1904 
  1905 lemma takeWhile_append1 [simp]:
  1906 "[| x:set xs; ~P(x)|] ==> takeWhile P (xs @ ys) = takeWhile P xs"
  1907 by (induct xs) auto
  1908 
  1909 lemma takeWhile_append2 [simp]:
  1910 "(!!x. x : set xs ==> P x) ==> takeWhile P (xs @ ys) = xs @ takeWhile P ys"
  1911 by (induct xs) auto
  1912 
  1913 lemma takeWhile_tail: "\<not> P x ==> takeWhile P (xs @ (x#l)) = takeWhile P xs"
  1914 by (induct xs) auto
  1915 
  1916 lemma takeWhile_nth: "j < length (takeWhile P xs) \<Longrightarrow> takeWhile P xs ! j = xs ! j"
  1917 apply (subst (3) takeWhile_dropWhile_id[symmetric]) unfolding nth_append by auto
  1918 
  1919 lemma dropWhile_nth: "j < length (dropWhile P xs) \<Longrightarrow> dropWhile P xs ! j = xs ! (j + length (takeWhile P xs))"
  1920 apply (subst (3) takeWhile_dropWhile_id[symmetric]) unfolding nth_append by auto
  1921 
  1922 lemma length_dropWhile_le: "length (dropWhile P xs) \<le> length xs"
  1923 by (induct xs) auto
  1924 
  1925 lemma dropWhile_append1 [simp]:
  1926 "[| x : set xs; ~P(x)|] ==> dropWhile P (xs @ ys) = (dropWhile P xs)@ys"
  1927 by (induct xs) auto
  1928 
  1929 lemma dropWhile_append2 [simp]:
  1930 "(!!x. x:set xs ==> P(x)) ==> dropWhile P (xs @ ys) = dropWhile P ys"
  1931 by (induct xs) auto
  1932 
  1933 lemma dropWhile_append3:
  1934   "\<not> P y \<Longrightarrow>dropWhile P (xs @ y # ys) = dropWhile P xs @ y # ys"
  1935 by (induct xs) auto
  1936 
  1937 lemma dropWhile_last:
  1938   "x \<in> set xs \<Longrightarrow> \<not> P x \<Longrightarrow> last (dropWhile P xs) = last xs"
  1939 by (auto simp add: dropWhile_append3 in_set_conv_decomp)
  1940 
  1941 lemma set_dropWhileD: "x \<in> set (dropWhile P xs) \<Longrightarrow> x \<in> set xs"
  1942 by (induct xs) (auto split: split_if_asm)
  1943 
  1944 lemma set_takeWhileD: "x : set (takeWhile P xs) ==> x : set xs \<and> P x"
  1945 by (induct xs) (auto split: split_if_asm)
  1946 
  1947 lemma takeWhile_eq_all_conv[simp]:
  1948  "(takeWhile P xs = xs) = (\<forall>x \<in> set xs. P x)"
  1949 by(induct xs, auto)
  1950 
  1951 lemma dropWhile_eq_Nil_conv[simp]:
  1952  "(dropWhile P xs = []) = (\<forall>x \<in> set xs. P x)"
  1953 by(induct xs, auto)
  1954 
  1955 lemma dropWhile_eq_Cons_conv:
  1956  "(dropWhile P xs = y#ys) = (xs = takeWhile P xs @ y # ys & \<not> P y)"
  1957 by(induct xs, auto)
  1958 
  1959 lemma distinct_takeWhile[simp]: "distinct xs ==> distinct (takeWhile P xs)"
  1960 by (induct xs) (auto dest: set_takeWhileD)
  1961 
  1962 lemma distinct_dropWhile[simp]: "distinct xs ==> distinct (dropWhile P xs)"
  1963 by (induct xs) auto
  1964 
  1965 lemma takeWhile_map: "takeWhile P (map f xs) = map f (takeWhile (P \<circ> f) xs)"
  1966 by (induct xs) auto
  1967 
  1968 lemma dropWhile_map: "dropWhile P (map f xs) = map f (dropWhile (P \<circ> f) xs)"
  1969 by (induct xs) auto
  1970 
  1971 lemma takeWhile_eq_take: "takeWhile P xs = take (length (takeWhile P xs)) xs"
  1972 by (induct xs) auto
  1973 
  1974 lemma dropWhile_eq_drop: "dropWhile P xs = drop (length (takeWhile P xs)) xs"
  1975 by (induct xs) auto
  1976 
  1977 lemma hd_dropWhile:
  1978   "dropWhile P xs \<noteq> [] \<Longrightarrow> \<not> P (hd (dropWhile P xs))"
  1979 using assms by (induct xs) auto
  1980 
  1981 lemma takeWhile_eq_filter:
  1982   assumes "\<And> x. x \<in> set (dropWhile P xs) \<Longrightarrow> \<not> P x"
  1983   shows "takeWhile P xs = filter P xs"
  1984 proof -
  1985   have A: "filter P xs = filter P (takeWhile P xs @ dropWhile P xs)"
  1986     by simp
  1987   have B: "filter P (dropWhile P xs) = []"
  1988     unfolding filter_empty_conv using assms by blast
  1989   have "filter P xs = takeWhile P xs"
  1990     unfolding A filter_append B
  1991     by (auto simp add: filter_id_conv dest: set_takeWhileD)
  1992   thus ?thesis ..
  1993 qed
  1994 
  1995 lemma takeWhile_eq_take_P_nth:
  1996   "\<lbrakk> \<And> i. \<lbrakk> i < n ; i < length xs \<rbrakk> \<Longrightarrow> P (xs ! i) ; n < length xs \<Longrightarrow> \<not> P (xs ! n) \<rbrakk> \<Longrightarrow>
  1997   takeWhile P xs = take n xs"
  1998 proof (induct xs arbitrary: n)
  1999   case (Cons x xs)
  2000   thus ?case
  2001   proof (cases n)
  2002     case (Suc n') note this[simp]
  2003     have "P x" using Cons.prems(1)[of 0] by simp
  2004     moreover have "takeWhile P xs = take n' xs"
  2005     proof (rule Cons.hyps)
  2006       case goal1 thus "P (xs ! i)" using Cons.prems(1)[of "Suc i"] by simp
  2007     next case goal2 thus ?case using Cons by auto
  2008     qed
  2009     ultimately show ?thesis by simp
  2010    qed simp
  2011 qed simp
  2012 
  2013 lemma nth_length_takeWhile:
  2014   "length (takeWhile P xs) < length xs \<Longrightarrow> \<not> P (xs ! length (takeWhile P xs))"
  2015 by (induct xs) auto
  2016 
  2017 lemma length_takeWhile_less_P_nth:
  2018   assumes all: "\<And> i. i < j \<Longrightarrow> P (xs ! i)" and "j \<le> length xs"
  2019   shows "j \<le> length (takeWhile P xs)"
  2020 proof (rule classical)
  2021   assume "\<not> ?thesis"
  2022   hence "length (takeWhile P xs) < length xs" using assms by simp
  2023   thus ?thesis using all `\<not> ?thesis` nth_length_takeWhile[of P xs] by auto
  2024 qed
  2025 
  2026 text{* The following two lemmmas could be generalized to an arbitrary
  2027 property. *}
  2028 
  2029 lemma takeWhile_neq_rev: "\<lbrakk>distinct xs; x \<in> set xs\<rbrakk> \<Longrightarrow>
  2030  takeWhile (\<lambda>y. y \<noteq> x) (rev xs) = rev (tl (dropWhile (\<lambda>y. y \<noteq> x) xs))"
  2031 by(induct xs) (auto simp: takeWhile_tail[where l="[]"])
  2032 
  2033 lemma dropWhile_neq_rev: "\<lbrakk>distinct xs; x \<in> set xs\<rbrakk> \<Longrightarrow>
  2034   dropWhile (\<lambda>y. y \<noteq> x) (rev xs) = x # rev (takeWhile (\<lambda>y. y \<noteq> x) xs)"
  2035 apply(induct xs)
  2036  apply simp
  2037 apply auto
  2038 apply(subst dropWhile_append2)
  2039 apply auto
  2040 done
  2041 
  2042 lemma takeWhile_not_last:
  2043  "\<lbrakk> xs \<noteq> []; distinct xs\<rbrakk> \<Longrightarrow> takeWhile (\<lambda>y. y \<noteq> last xs) xs = butlast xs"
  2044 apply(induct xs)
  2045  apply simp
  2046 apply(case_tac xs)
  2047 apply(auto)
  2048 done
  2049 
  2050 lemma takeWhile_cong [fundef_cong]:
  2051   "[| l = k; !!x. x : set l ==> P x = Q x |] 
  2052   ==> takeWhile P l = takeWhile Q k"
  2053 by (induct k arbitrary: l) (simp_all)
  2054 
  2055 lemma dropWhile_cong [fundef_cong]:
  2056   "[| l = k; !!x. x : set l ==> P x = Q x |] 
  2057   ==> dropWhile P l = dropWhile Q k"
  2058 by (induct k arbitrary: l, simp_all)
  2059 
  2060 
  2061 subsubsection {* @{text zip} *}
  2062 
  2063 lemma zip_Nil [simp]: "zip [] ys = []"
  2064 by (induct ys) auto
  2065 
  2066 lemma zip_Cons_Cons [simp]: "zip (x # xs) (y # ys) = (x, y) # zip xs ys"
  2067 by simp
  2068 
  2069 declare zip_Cons [simp del]
  2070 
  2071 lemma [code]:
  2072   "zip [] ys = []"
  2073   "zip xs [] = []"
  2074   "zip (x # xs) (y # ys) = (x, y) # zip xs ys"
  2075   by (fact zip_Nil zip.simps(1) zip_Cons_Cons)+
  2076 
  2077 lemma zip_Cons1:
  2078  "zip (x#xs) ys = (case ys of [] \<Rightarrow> [] | y#ys \<Rightarrow> (x,y)#zip xs ys)"
  2079 by(auto split:list.split)
  2080 
  2081 lemma length_zip [simp]:
  2082 "length (zip xs ys) = min (length xs) (length ys)"
  2083 by (induct xs ys rule:list_induct2') auto
  2084 
  2085 lemma zip_obtain_same_length:
  2086   assumes "\<And>zs ws n. length zs = length ws \<Longrightarrow> n = min (length xs) (length ys)
  2087     \<Longrightarrow> zs = take n xs \<Longrightarrow> ws = take n ys \<Longrightarrow> P (zip zs ws)"
  2088   shows "P (zip xs ys)"
  2089 proof -
  2090   let ?n = "min (length xs) (length ys)"
  2091   have "P (zip (take ?n xs) (take ?n ys))"
  2092     by (rule assms) simp_all
  2093   moreover have "zip xs ys = zip (take ?n xs) (take ?n ys)"
  2094   proof (induct xs arbitrary: ys)
  2095     case Nil then show ?case by simp
  2096   next
  2097     case (Cons x xs) then show ?case by (cases ys) simp_all
  2098   qed
  2099   ultimately show ?thesis by simp
  2100 qed
  2101 
  2102 lemma zip_append1:
  2103 "zip (xs @ ys) zs =
  2104 zip xs (take (length xs) zs) @ zip ys (drop (length xs) zs)"
  2105 by (induct xs zs rule:list_induct2') auto
  2106 
  2107 lemma zip_append2:
  2108 "zip xs (ys @ zs) =
  2109 zip (take (length ys) xs) ys @ zip (drop (length ys) xs) zs"
  2110 by (induct xs ys rule:list_induct2') auto
  2111 
  2112 lemma zip_append [simp]:
  2113  "[| length xs = length us; length ys = length vs |] ==>
  2114 zip (xs@ys) (us@vs) = zip xs us @ zip ys vs"
  2115 by (simp add: zip_append1)
  2116 
  2117 lemma zip_rev:
  2118 "length xs = length ys ==> zip (rev xs) (rev ys) = rev (zip xs ys)"
  2119 by (induct rule:list_induct2, simp_all)
  2120 
  2121 lemma zip_map_map:
  2122   "zip (map f xs) (map g ys) = map (\<lambda> (x, y). (f x, g y)) (zip xs ys)"
  2123 proof (induct xs arbitrary: ys)
  2124   case (Cons x xs) note Cons_x_xs = Cons.hyps
  2125   show ?case
  2126   proof (cases ys)
  2127     case (Cons y ys')
  2128     show ?thesis unfolding Cons using Cons_x_xs by simp
  2129   qed simp
  2130 qed simp
  2131 
  2132 lemma zip_map1:
  2133   "zip (map f xs) ys = map (\<lambda>(x, y). (f x, y)) (zip xs ys)"
  2134 using zip_map_map[of f xs "\<lambda>x. x" ys] by simp
  2135 
  2136 lemma zip_map2:
  2137   "zip xs (map f ys) = map (\<lambda>(x, y). (x, f y)) (zip xs ys)"
  2138 using zip_map_map[of "\<lambda>x. x" xs f ys] by simp
  2139 
  2140 lemma map_zip_map:
  2141   "map f (zip (map g xs) ys) = map (%(x,y). f(g x, y)) (zip xs ys)"
  2142 unfolding zip_map1 by auto
  2143 
  2144 lemma map_zip_map2:
  2145   "map f (zip xs (map g ys)) = map (%(x,y). f(x, g y)) (zip xs ys)"
  2146 unfolding zip_map2 by auto
  2147 
  2148 text{* Courtesy of Andreas Lochbihler: *}
  2149 lemma zip_same_conv_map: "zip xs xs = map (\<lambda>x. (x, x)) xs"
  2150 by(induct xs) auto
  2151 
  2152 lemma nth_zip [simp]:
  2153 "[| i < length xs; i < length ys|] ==> (zip xs ys)!i = (xs!i, ys!i)"
  2154 apply (induct ys arbitrary: i xs, simp)
  2155 apply (case_tac xs)
  2156  apply (simp_all add: nth.simps split: nat.split)
  2157 done
  2158 
  2159 lemma set_zip:
  2160 "set (zip xs ys) = {(xs!i, ys!i) | i. i < min (length xs) (length ys)}"
  2161 by(simp add: set_conv_nth cong: rev_conj_cong)
  2162 
  2163 lemma zip_same: "((a,b) \<in> set (zip xs xs)) = (a \<in> set xs \<and> a = b)"
  2164 by(induct xs) auto
  2165 
  2166 lemma zip_update:
  2167   "zip (xs[i:=x]) (ys[i:=y]) = (zip xs ys)[i:=(x,y)]"
  2168 by(rule sym, simp add: update_zip)
  2169 
  2170 lemma zip_replicate [simp]:
  2171   "zip (replicate i x) (replicate j y) = replicate (min i j) (x,y)"
  2172 apply (induct i arbitrary: j, auto)
  2173 apply (case_tac j, auto)
  2174 done
  2175 
  2176 lemma take_zip:
  2177   "take n (zip xs ys) = zip (take n xs) (take n ys)"
  2178 apply (induct n arbitrary: xs ys)
  2179  apply simp
  2180 apply (case_tac xs, simp)
  2181 apply (case_tac ys, simp_all)
  2182 done
  2183 
  2184 lemma drop_zip:
  2185   "drop n (zip xs ys) = zip (drop n xs) (drop n ys)"
  2186 apply (induct n arbitrary: xs ys)
  2187  apply simp
  2188 apply (case_tac xs, simp)
  2189 apply (case_tac ys, simp_all)
  2190 done
  2191 
  2192 lemma zip_takeWhile_fst: "zip (takeWhile P xs) ys = takeWhile (P \<circ> fst) (zip xs ys)"
  2193 proof (induct xs arbitrary: ys)
  2194   case (Cons x xs) thus ?case by (cases ys) auto
  2195 qed simp
  2196 
  2197 lemma zip_takeWhile_snd: "zip xs (takeWhile P ys) = takeWhile (P \<circ> snd) (zip xs ys)"
  2198 proof (induct xs arbitrary: ys)
  2199   case (Cons x xs) thus ?case by (cases ys) auto
  2200 qed simp
  2201 
  2202 lemma set_zip_leftD:
  2203   "(x,y)\<in> set (zip xs ys) \<Longrightarrow> x \<in> set xs"
  2204 by (induct xs ys rule:list_induct2') auto
  2205 
  2206 lemma set_zip_rightD:
  2207   "(x,y)\<in> set (zip xs ys) \<Longrightarrow> y \<in> set ys"
  2208 by (induct xs ys rule:list_induct2') auto
  2209 
  2210 lemma in_set_zipE:
  2211   "(x,y) : set(zip xs ys) \<Longrightarrow> (\<lbrakk> x : set xs; y : set ys \<rbrakk> \<Longrightarrow> R) \<Longrightarrow> R"
  2212 by(blast dest: set_zip_leftD set_zip_rightD)
  2213 
  2214 lemma zip_map_fst_snd:
  2215   "zip (map fst zs) (map snd zs) = zs"
  2216   by (induct zs) simp_all
  2217 
  2218 lemma zip_eq_conv:
  2219   "length xs = length ys \<Longrightarrow> zip xs ys = zs \<longleftrightarrow> map fst zs = xs \<and> map snd zs = ys"
  2220   by (auto simp add: zip_map_fst_snd)
  2221 
  2222 
  2223 subsubsection {* @{text list_all2} *}
  2224 
  2225 lemma list_all2_lengthD [intro?]: 
  2226   "list_all2 P xs ys ==> length xs = length ys"
  2227 by (simp add: list_all2_def)
  2228 
  2229 lemma list_all2_Nil [iff, code]: "list_all2 P [] ys = (ys = [])"
  2230 by (simp add: list_all2_def)
  2231 
  2232 lemma list_all2_Nil2 [iff, code]: "list_all2 P xs [] = (xs = [])"
  2233 by (simp add: list_all2_def)
  2234 
  2235 lemma list_all2_Cons [iff, code]:
  2236   "list_all2 P (x # xs) (y # ys) = (P x y \<and> list_all2 P xs ys)"
  2237 by (auto simp add: list_all2_def)
  2238 
  2239 lemma list_all2_Cons1:
  2240 "list_all2 P (x # xs) ys = (\<exists>z zs. ys = z # zs \<and> P x z \<and> list_all2 P xs zs)"
  2241 by (cases ys) auto
  2242 
  2243 lemma list_all2_Cons2:
  2244 "list_all2 P xs (y # ys) = (\<exists>z zs. xs = z # zs \<and> P z y \<and> list_all2 P zs ys)"
  2245 by (cases xs) auto
  2246 
  2247 lemma list_all2_induct
  2248   [consumes 1, case_names Nil Cons, induct set: list_all2]:
  2249   assumes P: "list_all2 P xs ys"
  2250   assumes Nil: "R [] []"
  2251   assumes Cons: "\<And>x xs y ys. \<lbrakk>P x y; R xs ys\<rbrakk> \<Longrightarrow> R (x # xs) (y # ys)"
  2252   shows "R xs ys"
  2253 using P
  2254 by (induct xs arbitrary: ys) (auto simp add: list_all2_Cons1 Nil Cons)
  2255 
  2256 lemma list_all2_rev [iff]:
  2257 "list_all2 P (rev xs) (rev ys) = list_all2 P xs ys"
  2258 by (simp add: list_all2_def zip_rev cong: conj_cong)
  2259 
  2260 lemma list_all2_rev1:
  2261 "list_all2 P (rev xs) ys = list_all2 P xs (rev ys)"
  2262 by (subst list_all2_rev [symmetric]) simp
  2263 
  2264 lemma list_all2_append1:
  2265 "list_all2 P (xs @ ys) zs =
  2266 (EX us vs. zs = us @ vs \<and> length us = length xs \<and> length vs = length ys \<and>
  2267 list_all2 P xs us \<and> list_all2 P ys vs)"
  2268 apply (simp add: list_all2_def zip_append1)
  2269 apply (rule iffI)
  2270  apply (rule_tac x = "take (length xs) zs" in exI)
  2271  apply (rule_tac x = "drop (length xs) zs" in exI)
  2272  apply (force split: nat_diff_split simp add: min_def, clarify)
  2273 apply (simp add: ball_Un)
  2274 done
  2275 
  2276 lemma list_all2_append2:
  2277 "list_all2 P xs (ys @ zs) =
  2278 (EX us vs. xs = us @ vs \<and> length us = length ys \<and> length vs = length zs \<and>
  2279 list_all2 P us ys \<and> list_all2 P vs zs)"
  2280 apply (simp add: list_all2_def zip_append2)
  2281 apply (rule iffI)
  2282  apply (rule_tac x = "take (length ys) xs" in exI)
  2283  apply (rule_tac x = "drop (length ys) xs" in exI)
  2284  apply (force split: nat_diff_split simp add: min_def, clarify)
  2285 apply (simp add: ball_Un)
  2286 done
  2287 
  2288 lemma list_all2_append:
  2289   "length xs = length ys \<Longrightarrow>
  2290   list_all2 P (xs@us) (ys@vs) = (list_all2 P xs ys \<and> list_all2 P us vs)"
  2291 by (induct rule:list_induct2, simp_all)
  2292 
  2293 lemma list_all2_appendI [intro?, trans]:
  2294   "\<lbrakk> list_all2 P a b; list_all2 P c d \<rbrakk> \<Longrightarrow> list_all2 P (a@c) (b@d)"
  2295 by (simp add: list_all2_append list_all2_lengthD)
  2296 
  2297 lemma list_all2_conv_all_nth:
  2298 "list_all2 P xs ys =
  2299 (length xs = length ys \<and> (\<forall>i < length xs. P (xs!i) (ys!i)))"
  2300 by (force simp add: list_all2_def set_zip)
  2301 
  2302 lemma list_all2_trans:
  2303   assumes tr: "!!a b c. P1 a b ==> P2 b c ==> P3 a c"
  2304   shows "!!bs cs. list_all2 P1 as bs ==> list_all2 P2 bs cs ==> list_all2 P3 as cs"
  2305         (is "!!bs cs. PROP ?Q as bs cs")
  2306 proof (induct as)
  2307   fix x xs bs assume I1: "!!bs cs. PROP ?Q xs bs cs"
  2308   show "!!cs. PROP ?Q (x # xs) bs cs"
  2309   proof (induct bs)
  2310     fix y ys cs assume I2: "!!cs. PROP ?Q (x # xs) ys cs"
  2311     show "PROP ?Q (x # xs) (y # ys) cs"
  2312       by (induct cs) (auto intro: tr I1 I2)
  2313   qed simp
  2314 qed simp
  2315 
  2316 lemma list_all2_all_nthI [intro?]:
  2317   "length a = length b \<Longrightarrow> (\<And>n. n < length a \<Longrightarrow> P (a!n) (b!n)) \<Longrightarrow> list_all2 P a b"
  2318 by (simp add: list_all2_conv_all_nth)
  2319 
  2320 lemma list_all2I:
  2321   "\<forall>x \<in> set (zip a b). split P x \<Longrightarrow> length a = length b \<Longrightarrow> list_all2 P a b"
  2322 by (simp add: list_all2_def)
  2323 
  2324 lemma list_all2_nthD:
  2325   "\<lbrakk> list_all2 P xs ys; p < size xs \<rbrakk> \<Longrightarrow> P (xs!p) (ys!p)"
  2326 by (simp add: list_all2_conv_all_nth)
  2327 
  2328 lemma list_all2_nthD2:
  2329   "\<lbrakk>list_all2 P xs ys; p < size ys\<rbrakk> \<Longrightarrow> P (xs!p) (ys!p)"
  2330 by (frule list_all2_lengthD) (auto intro: list_all2_nthD)
  2331 
  2332 lemma list_all2_map1: 
  2333   "list_all2 P (map f as) bs = list_all2 (\<lambda>x y. P (f x) y) as bs"
  2334 by (simp add: list_all2_conv_all_nth)
  2335 
  2336 lemma list_all2_map2: 
  2337   "list_all2 P as (map f bs) = list_all2 (\<lambda>x y. P x (f y)) as bs"
  2338 by (auto simp add: list_all2_conv_all_nth)
  2339 
  2340 lemma list_all2_refl [intro?]:
  2341   "(\<And>x. P x x) \<Longrightarrow> list_all2 P xs xs"
  2342 by (simp add: list_all2_conv_all_nth)
  2343 
  2344 lemma list_all2_update_cong:
  2345   "\<lbrakk> i<size xs; list_all2 P xs ys; P x y \<rbrakk> \<Longrightarrow> list_all2 P (xs[i:=x]) (ys[i:=y])"
  2346 by (simp add: list_all2_conv_all_nth nth_list_update)
  2347 
  2348 lemma list_all2_update_cong2:
  2349   "\<lbrakk>list_all2 P xs ys; P x y; i < length ys\<rbrakk> \<Longrightarrow> list_all2 P (xs[i:=x]) (ys[i:=y])"
  2350 by (simp add: list_all2_lengthD list_all2_update_cong)
  2351 
  2352 lemma list_all2_takeI [simp,intro?]:
  2353   "list_all2 P xs ys \<Longrightarrow> list_all2 P (take n xs) (take n ys)"
  2354 apply (induct xs arbitrary: n ys)
  2355  apply simp
  2356 apply (clarsimp simp add: list_all2_Cons1)
  2357 apply (case_tac n)
  2358 apply auto
  2359 done
  2360 
  2361 lemma list_all2_dropI [simp,intro?]:
  2362   "list_all2 P as bs \<Longrightarrow> list_all2 P (drop n as) (drop n bs)"
  2363 apply (induct as arbitrary: n bs, simp)
  2364 apply (clarsimp simp add: list_all2_Cons1)
  2365 apply (case_tac n, simp, simp)
  2366 done
  2367 
  2368 lemma list_all2_mono [intro?]:
  2369   "list_all2 P xs ys \<Longrightarrow> (\<And>xs ys. P xs ys \<Longrightarrow> Q xs ys) \<Longrightarrow> list_all2 Q xs ys"
  2370 apply (induct xs arbitrary: ys, simp)
  2371 apply (case_tac ys, auto)
  2372 done
  2373 
  2374 lemma list_all2_eq:
  2375   "xs = ys \<longleftrightarrow> list_all2 (op =) xs ys"
  2376 by (induct xs ys rule: list_induct2') auto
  2377 
  2378 lemma list_eq_iff_zip_eq:
  2379   "xs = ys \<longleftrightarrow> length xs = length ys \<and> (\<forall>(x,y) \<in> set (zip xs ys). x = y)"
  2380 by(auto simp add: set_zip list_all2_eq list_all2_conv_all_nth cong: conj_cong)
  2381 
  2382 
  2383 subsubsection {* @{const fold} with canonical argument order *}
  2384 
  2385 lemma fold_remove1_split:
  2386   assumes f: "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  2387     and x: "x \<in> set xs"
  2388   shows "fold f xs = fold f (remove1 x xs) \<circ> f x"
  2389   using assms by (induct xs) (auto simp add: o_assoc [symmetric])
  2390 
  2391 lemma fold_cong [fundef_cong]:
  2392   "a = b \<Longrightarrow> xs = ys \<Longrightarrow> (\<And>x. x \<in> set xs \<Longrightarrow> f x = g x)
  2393     \<Longrightarrow> fold f xs a = fold g ys b"
  2394   by (induct ys arbitrary: a b xs) simp_all
  2395 
  2396 lemma fold_id:
  2397   assumes "\<And>x. x \<in> set xs \<Longrightarrow> f x = id"
  2398   shows "fold f xs = id"
  2399   using assms by (induct xs) simp_all
  2400 
  2401 lemma fold_commute:
  2402   assumes "\<And>x. x \<in> set xs \<Longrightarrow> h \<circ> g x = f x \<circ> h"
  2403   shows "h \<circ> fold g xs = fold f xs \<circ> h"
  2404   using assms by (induct xs) (simp_all add: fun_eq_iff)
  2405 
  2406 lemma fold_commute_apply:
  2407   assumes "\<And>x. x \<in> set xs \<Longrightarrow> h \<circ> g x = f x \<circ> h"
  2408   shows "h (fold g xs s) = fold f xs (h s)"
  2409 proof -
  2410   from assms have "h \<circ> fold g xs = fold f xs \<circ> h" by (rule fold_commute)
  2411   then show ?thesis by (simp add: fun_eq_iff)
  2412 qed
  2413 
  2414 lemma fold_invariant: 
  2415   assumes "\<And>x. x \<in> set xs \<Longrightarrow> Q x" and "P s"
  2416     and "\<And>x s. Q x \<Longrightarrow> P s \<Longrightarrow> P (f x s)"
  2417   shows "P (fold f xs s)"
  2418   using assms by (induct xs arbitrary: s) simp_all
  2419 
  2420 lemma fold_append [simp]:
  2421   "fold f (xs @ ys) = fold f ys \<circ> fold f xs"
  2422   by (induct xs) simp_all
  2423 
  2424 lemma fold_map [code_unfold]:
  2425   "fold g (map f xs) = fold (g o f) xs"
  2426   by (induct xs) simp_all
  2427 
  2428 lemma fold_rev:
  2429   assumes "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f y \<circ> f x = f x \<circ> f y"
  2430   shows "fold f (rev xs) = fold f xs"
  2431 using assms by (induct xs) (simp_all add: fold_commute_apply fun_eq_iff)
  2432 
  2433 lemma fold_Cons_rev:
  2434   "fold Cons xs = append (rev xs)"
  2435   by (induct xs) simp_all
  2436 
  2437 lemma rev_conv_fold [code]:
  2438   "rev xs = fold Cons xs []"
  2439   by (simp add: fold_Cons_rev)
  2440 
  2441 lemma fold_append_concat_rev:
  2442   "fold append xss = append (concat (rev xss))"
  2443   by (induct xss) simp_all
  2444 
  2445 text {* @{const Finite_Set.fold} and @{const fold} *}
  2446 
  2447 lemma (in comp_fun_commute) fold_set_fold_remdups:
  2448   "Finite_Set.fold f y (set xs) = fold f (remdups xs) y"
  2449   by (rule sym, induct xs arbitrary: y) (simp_all add: fold_fun_comm insert_absorb)
  2450 
  2451 lemma (in comp_fun_idem) fold_set_fold:
  2452   "Finite_Set.fold f y (set xs) = fold f xs y"
  2453   by (rule sym, induct xs arbitrary: y) (simp_all add: fold_fun_comm)
  2454 
  2455 lemma (in ab_semigroup_idem_mult) fold1_set_fold:
  2456   assumes "xs \<noteq> []"
  2457   shows "Finite_Set.fold1 times (set xs) = fold times (tl xs) (hd xs)"
  2458 proof -
  2459   interpret comp_fun_idem times by (fact comp_fun_idem)
  2460   from assms obtain y ys where xs: "xs = y # ys"
  2461     by (cases xs) auto
  2462   show ?thesis
  2463   proof (cases "set ys = {}")
  2464     case True with xs show ?thesis by simp
  2465   next
  2466     case False
  2467     then have "fold1 times (insert y (set ys)) = Finite_Set.fold times y (set ys)"
  2468       by (simp only: finite_set fold1_eq_fold_idem)
  2469     with xs show ?thesis by (simp add: fold_set_fold mult_commute)
  2470   qed
  2471 qed
  2472 
  2473 lemma (in lattice) Inf_fin_set_fold:
  2474   "Inf_fin (set (x # xs)) = fold inf xs x"
  2475 proof -
  2476   interpret ab_semigroup_idem_mult "inf :: 'a \<Rightarrow> 'a \<Rightarrow> 'a"
  2477     by (fact ab_semigroup_idem_mult_inf)
  2478   show ?thesis
  2479     by (simp add: Inf_fin_def fold1_set_fold del: set.simps)
  2480 qed
  2481 
  2482 lemma (in lattice) Sup_fin_set_fold:
  2483   "Sup_fin (set (x # xs)) = fold sup xs x"
  2484 proof -
  2485   interpret ab_semigroup_idem_mult "sup :: 'a \<Rightarrow> 'a \<Rightarrow> 'a"
  2486     by (fact ab_semigroup_idem_mult_sup)
  2487   show ?thesis
  2488     by (simp add: Sup_fin_def fold1_set_fold del: set.simps)
  2489 qed
  2490 
  2491 lemma (in linorder) Min_fin_set_fold:
  2492   "Min (set (x # xs)) = fold min xs x"
  2493 proof -
  2494   interpret ab_semigroup_idem_mult "min :: 'a \<Rightarrow> 'a \<Rightarrow> 'a"
  2495     by (fact ab_semigroup_idem_mult_min)
  2496   show ?thesis
  2497     by (simp add: Min_def fold1_set_fold del: set.simps)
  2498 qed
  2499 
  2500 lemma (in linorder) Max_fin_set_fold:
  2501   "Max (set (x # xs)) = fold max xs x"
  2502 proof -
  2503   interpret ab_semigroup_idem_mult "max :: 'a \<Rightarrow> 'a \<Rightarrow> 'a"
  2504     by (fact ab_semigroup_idem_mult_max)
  2505   show ?thesis
  2506     by (simp add: Max_def fold1_set_fold del: set.simps)
  2507 qed
  2508 
  2509 lemma (in complete_lattice) Inf_set_fold:
  2510   "Inf (set xs) = fold inf xs top"
  2511 proof -
  2512   interpret comp_fun_idem "inf :: 'a \<Rightarrow> 'a \<Rightarrow> 'a"
  2513     by (fact comp_fun_idem_inf)
  2514   show ?thesis by (simp add: Inf_fold_inf fold_set_fold inf_commute)
  2515 qed
  2516 
  2517 lemma (in complete_lattice) Sup_set_fold:
  2518   "Sup (set xs) = fold sup xs bot"
  2519 proof -
  2520   interpret comp_fun_idem "sup :: 'a \<Rightarrow> 'a \<Rightarrow> 'a"
  2521     by (fact comp_fun_idem_sup)
  2522   show ?thesis by (simp add: Sup_fold_sup fold_set_fold sup_commute)
  2523 qed
  2524 
  2525 lemma (in complete_lattice) INF_set_fold:
  2526   "INFI (set xs) f = fold (inf \<circ> f) xs top"
  2527   unfolding INF_def set_map [symmetric] Inf_set_fold fold_map ..
  2528 
  2529 lemma (in complete_lattice) SUP_set_fold:
  2530   "SUPR (set xs) f = fold (sup \<circ> f) xs bot"
  2531   unfolding SUP_def set_map [symmetric] Sup_set_fold fold_map ..
  2532 
  2533 
  2534 subsubsection {* Fold variants: @{const foldr} and @{const foldl} *}
  2535 
  2536 text {* Correspondence *}
  2537 
  2538 lemma foldr_foldl: -- {* The ``Third Duality Theorem'' in Bird \& Wadler: *}
  2539   "foldr f xs a = foldl (\<lambda>x y. f y x) a (rev xs)"
  2540   by (simp add: foldr_def foldl_def)
  2541 
  2542 lemma foldl_foldr:
  2543   "foldl f a xs = foldr (\<lambda>x y. f y x) (rev xs) a"
  2544   by (simp add: foldr_def foldl_def)
  2545 
  2546 lemma foldr_fold:
  2547   assumes "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f y \<circ> f x = f x \<circ> f y"
  2548   shows "foldr f xs = fold f xs"
  2549   using assms unfolding foldr_def by (rule fold_rev)
  2550 
  2551 lemma
  2552   foldr_Nil [code, simp]: "foldr f [] = id"
  2553   and foldr_Cons [code, simp]: "foldr f (x # xs) = f x \<circ> foldr f xs"
  2554   by (simp_all add: foldr_def)
  2555 
  2556 lemma
  2557   foldl_Nil [simp]: "foldl f a [] = a"
  2558   and foldl_Cons [simp]: "foldl f a (x # xs) = foldl f (f a x) xs"
  2559   by (simp_all add: foldl_def)
  2560 
  2561 lemma foldr_cong [fundef_cong]:
  2562   "a = b \<Longrightarrow> l = k \<Longrightarrow> (\<And>a x. x \<in> set l \<Longrightarrow> f x a = g x a) \<Longrightarrow> foldr f l a = foldr g k b"
  2563   by (auto simp add: foldr_def intro!: fold_cong)
  2564 
  2565 lemma foldl_cong [fundef_cong]:
  2566   "a = b \<Longrightarrow> l = k \<Longrightarrow> (\<And>a x. x \<in> set l \<Longrightarrow> f a x = g a x) \<Longrightarrow> foldl f a l = foldl g b k"
  2567   by (auto simp add: foldl_def intro!: fold_cong)
  2568 
  2569 lemma foldr_append [simp]:
  2570   "foldr f (xs @ ys) a = foldr f xs (foldr f ys a)"
  2571   by (simp add: foldr_def)
  2572 
  2573 lemma foldl_append [simp]:
  2574   "foldl f a (xs @ ys) = foldl f (foldl f a xs) ys"
  2575   by (simp add: foldl_def)
  2576 
  2577 lemma foldr_map [code_unfold]:
  2578   "foldr g (map f xs) a = foldr (g o f) xs a"
  2579   by (simp add: foldr_def fold_map rev_map)
  2580 
  2581 lemma foldl_map [code_unfold]:
  2582   "foldl g a (map f xs) = foldl (\<lambda>a x. g a (f x)) a xs"
  2583   by (simp add: foldl_def fold_map comp_def)
  2584 
  2585 text {* Executing operations in terms of @{const foldr} -- tail-recursive! *}
  2586 
  2587 lemma concat_conv_foldr [code]:
  2588   "concat xss = foldr append xss []"
  2589   by (simp add: fold_append_concat_rev foldr_def)
  2590 
  2591 lemma (in lattice) Inf_fin_set_foldr [code]:
  2592   "Inf_fin (set (x # xs)) = foldr inf xs x"
  2593   by (simp add: Inf_fin_set_fold ac_simps foldr_fold fun_eq_iff del: set.simps)
  2594 
  2595 lemma (in lattice) Sup_fin_set_foldr [code]:
  2596   "Sup_fin (set (x # xs)) = foldr sup xs x"
  2597   by (simp add: Sup_fin_set_fold ac_simps foldr_fold fun_eq_iff del: set.simps)
  2598 
  2599 lemma (in linorder) Min_fin_set_foldr [code]:
  2600   "Min (set (x # xs)) = foldr min xs x"
  2601   by (simp add: Min_fin_set_fold ac_simps foldr_fold fun_eq_iff del: set.simps)
  2602 
  2603 lemma (in linorder) Max_fin_set_foldr [code]:
  2604   "Max (set (x # xs)) = foldr max xs x"
  2605   by (simp add: Max_fin_set_fold ac_simps foldr_fold fun_eq_iff del: set.simps)
  2606 
  2607 lemma (in complete_lattice) Inf_set_foldr:
  2608   "Inf (set xs) = foldr inf xs top"
  2609   by (simp add: Inf_set_fold ac_simps foldr_fold fun_eq_iff)
  2610 
  2611 lemma (in complete_lattice) Sup_set_foldr:
  2612   "Sup (set xs) = foldr sup xs bot"
  2613   by (simp add: Sup_set_fold ac_simps foldr_fold fun_eq_iff)
  2614 
  2615 lemma (in complete_lattice) INF_set_foldr [code]:
  2616   "INFI (set xs) f = foldr (inf \<circ> f) xs top"
  2617   by (simp only: INF_def Inf_set_foldr foldr_map set_map [symmetric])
  2618 
  2619 lemma (in complete_lattice) SUP_set_foldr [code]:
  2620   "SUPR (set xs) f = foldr (sup \<circ> f) xs bot"
  2621   by (simp only: SUP_def Sup_set_foldr foldr_map set_map [symmetric])
  2622 
  2623 
  2624 subsubsection {* @{text upt} *}
  2625 
  2626 lemma upt_rec[code]: "[i..<j] = (if i<j then i#[Suc i..<j] else [])"
  2627 -- {* simp does not terminate! *}
  2628 by (induct j) auto
  2629 
  2630 lemmas upt_rec_number_of[simp] = upt_rec[of "number_of m" "number_of n"] for m n
  2631 
  2632 lemma upt_conv_Nil [simp]: "j <= i ==> [i..<j] = []"
  2633 by (subst upt_rec) simp
  2634 
  2635 lemma upt_eq_Nil_conv[simp]: "([i..<j] = []) = (j = 0 \<or> j <= i)"
  2636 by(induct j)simp_all
  2637 
  2638 lemma upt_eq_Cons_conv:
  2639  "([i..<j] = x#xs) = (i < j & i = x & [i+1..<j] = xs)"
  2640 apply(induct j arbitrary: x xs)
  2641  apply simp
  2642 apply(clarsimp simp add: append_eq_Cons_conv)
  2643 apply arith
  2644 done
  2645 
  2646 lemma upt_Suc_append: "i <= j ==> [i..<(Suc j)] = [i..<j]@[j]"
  2647 -- {* Only needed if @{text upt_Suc} is deleted from the simpset. *}
  2648 by simp
  2649 
  2650 lemma upt_conv_Cons: "i < j ==> [i..<j] = i # [Suc i..<j]"
  2651   by (simp add: upt_rec)
  2652 
  2653 lemma upt_add_eq_append: "i<=j ==> [i..<j+k] = [i..<j]@[j..<j+k]"
  2654 -- {* LOOPS as a simprule, since @{text "j <= j"}. *}
  2655 by (induct k) auto
  2656 
  2657 lemma length_upt [simp]: "length [i..<j] = j - i"
  2658 by (induct j) (auto simp add: Suc_diff_le)
  2659 
  2660 lemma nth_upt [simp]: "i + k < j ==> [i..<j] ! k = i + k"
  2661 apply (induct j)
  2662 apply (auto simp add: less_Suc_eq nth_append split: nat_diff_split)
  2663 done
  2664 
  2665 
  2666 lemma hd_upt[simp]: "i < j \<Longrightarrow> hd[i..<j] = i"
  2667 by(simp add:upt_conv_Cons)
  2668 
  2669 lemma last_upt[simp]: "i < j \<Longrightarrow> last[i..<j] = j - 1"
  2670 apply(cases j)
  2671  apply simp
  2672 by(simp add:upt_Suc_append)
  2673 
  2674 lemma take_upt [simp]: "i+m <= n ==> take m [i..<n] = [i..<i+m]"
  2675 apply (induct m arbitrary: i, simp)
  2676 apply (subst upt_rec)
  2677 apply (rule sym)
  2678 apply (subst upt_rec)
  2679 apply (simp del: upt.simps)
  2680 done
  2681 
  2682 lemma drop_upt[simp]: "drop m [i..<j] = [i+m..<j]"
  2683 apply(induct j)
  2684 apply auto
  2685 done
  2686 
  2687 lemma map_Suc_upt: "map Suc [m..<n] = [Suc m..<Suc n]"
  2688 by (induct n) auto
  2689 
  2690 lemma nth_map_upt: "i < n-m ==> (map f [m..<n]) ! i = f(m+i)"
  2691 apply (induct n m  arbitrary: i rule: diff_induct)
  2692 prefer 3 apply (subst map_Suc_upt[symmetric])
  2693 apply (auto simp add: less_diff_conv)
  2694 done
  2695 
  2696 lemma nth_take_lemma:
  2697   "k <= length xs ==> k <= length ys ==>
  2698      (!!i. i < k --> xs!i = ys!i) ==> take k xs = take k ys"
  2699 apply (atomize, induct k arbitrary: xs ys)
  2700 apply (simp_all add: less_Suc_eq_0_disj all_conj_distrib, clarify)
  2701 txt {* Both lists must be non-empty *}
  2702 apply (case_tac xs, simp)
  2703 apply (case_tac ys, clarify)
  2704  apply (simp (no_asm_use))
  2705 apply clarify
  2706 txt {* prenexing's needed, not miniscoping *}
  2707 apply (simp (no_asm_use) add: all_simps [symmetric] del: all_simps)
  2708 apply blast
  2709 done
  2710 
  2711 lemma nth_equalityI:
  2712  "[| length xs = length ys; ALL i < length xs. xs!i = ys!i |] ==> xs = ys"
  2713   by (frule nth_take_lemma [OF le_refl eq_imp_le]) simp_all
  2714 
  2715 lemma map_nth:
  2716   "map (\<lambda>i. xs ! i) [0..<length xs] = xs"
  2717   by (rule nth_equalityI, auto)
  2718 
  2719 (* needs nth_equalityI *)
  2720 lemma list_all2_antisym:
  2721   "\<lbrakk> (\<And>x y. \<lbrakk>P x y; Q y x\<rbrakk> \<Longrightarrow> x = y); list_all2 P xs ys; list_all2 Q ys xs \<rbrakk> 
  2722   \<Longrightarrow> xs = ys"
  2723   apply (simp add: list_all2_conv_all_nth) 
  2724   apply (rule nth_equalityI, blast, simp)
  2725   done
  2726 
  2727 lemma take_equalityI: "(\<forall>i. take i xs = take i ys) ==> xs = ys"
  2728 -- {* The famous take-lemma. *}
  2729 apply (drule_tac x = "max (length xs) (length ys)" in spec)
  2730 apply (simp add: le_max_iff_disj)
  2731 done
  2732 
  2733 
  2734 lemma take_Cons':
  2735      "take n (x # xs) = (if n = 0 then [] else x # take (n - 1) xs)"
  2736 by (cases n) simp_all
  2737 
  2738 lemma drop_Cons':
  2739      "drop n (x # xs) = (if n = 0 then x # xs else drop (n - 1) xs)"
  2740 by (cases n) simp_all
  2741 
  2742 lemma nth_Cons': "(x # xs)!n = (if n = 0 then x else xs!(n - 1))"
  2743 by (cases n) simp_all
  2744 
  2745 lemmas take_Cons_number_of = take_Cons'[of "number_of v"] for v
  2746 lemmas drop_Cons_number_of = drop_Cons'[of "number_of v"] for v
  2747 lemmas nth_Cons_number_of = nth_Cons'[of _ _ "number_of v"] for v
  2748 
  2749 declare take_Cons_number_of [simp] 
  2750         drop_Cons_number_of [simp] 
  2751         nth_Cons_number_of [simp] 
  2752 
  2753 
  2754 subsubsection {* @{text upto}: interval-list on @{typ int} *}
  2755 
  2756 (* FIXME make upto tail recursive? *)
  2757 
  2758 function upto :: "int \<Rightarrow> int \<Rightarrow> int list" ("(1[_../_])") where
  2759 "upto i j = (if i \<le> j then i # [i+1..j] else [])"
  2760 by auto
  2761 termination
  2762 by(relation "measure(%(i::int,j). nat(j - i + 1))") auto
  2763 
  2764 declare upto.simps[code, simp del]
  2765 
  2766 lemmas upto_rec_number_of[simp] = upto.simps[of "number_of m" "number_of n"] for m n
  2767 
  2768 lemma upto_empty[simp]: "j < i \<Longrightarrow> [i..j] = []"
  2769 by(simp add: upto.simps)
  2770 
  2771 lemma set_upto[simp]: "set[i..j] = {i..j}"
  2772 proof(induct i j rule:upto.induct)
  2773   case (1 i j)
  2774   from this show ?case
  2775     unfolding upto.simps[of i j] simp_from_to[of i j] by auto
  2776 qed
  2777 
  2778 
  2779 subsubsection {* @{text "distinct"} and @{text remdups} *}
  2780 
  2781 lemma distinct_tl:
  2782   "distinct xs \<Longrightarrow> distinct (tl xs)"
  2783   by (cases xs) simp_all
  2784 
  2785 lemma distinct_append [simp]:
  2786 "distinct (xs @ ys) = (distinct xs \<and> distinct ys \<and> set xs \<inter> set ys = {})"
  2787 by (induct xs) auto
  2788 
  2789 lemma distinct_rev[simp]: "distinct(rev xs) = distinct xs"
  2790 by(induct xs) auto
  2791 
  2792 lemma set_remdups [simp]: "set (remdups xs) = set xs"
  2793 by (induct xs) (auto simp add: insert_absorb)
  2794 
  2795 lemma distinct_remdups [iff]: "distinct (remdups xs)"
  2796 by (induct xs) auto
  2797 
  2798 lemma distinct_remdups_id: "distinct xs ==> remdups xs = xs"
  2799 by (induct xs, auto)
  2800 
  2801 lemma remdups_id_iff_distinct [simp]: "remdups xs = xs \<longleftrightarrow> distinct xs"
  2802 by (metis distinct_remdups distinct_remdups_id)
  2803 
  2804 lemma finite_distinct_list: "finite A \<Longrightarrow> EX xs. set xs = A & distinct xs"
  2805 by (metis distinct_remdups finite_list set_remdups)
  2806 
  2807 lemma remdups_eq_nil_iff [simp]: "(remdups x = []) = (x = [])"
  2808 by (induct x, auto) 
  2809 
  2810 lemma remdups_eq_nil_right_iff [simp]: "([] = remdups x) = (x = [])"
  2811 by (induct x, auto)
  2812 
  2813 lemma length_remdups_leq[iff]: "length(remdups xs) <= length xs"
  2814 by (induct xs) auto
  2815 
  2816 lemma length_remdups_eq[iff]:
  2817   "(length (remdups xs) = length xs) = (remdups xs = xs)"
  2818 apply(induct xs)
  2819  apply auto
  2820 apply(subgoal_tac "length (remdups xs) <= length xs")
  2821  apply arith
  2822 apply(rule length_remdups_leq)
  2823 done
  2824 
  2825 lemma remdups_filter: "remdups(filter P xs) = filter P (remdups xs)"
  2826 apply(induct xs)
  2827 apply auto
  2828 done
  2829 
  2830 lemma distinct_map:
  2831   "distinct(map f xs) = (distinct xs & inj_on f (set xs))"
  2832 by (induct xs) auto
  2833 
  2834 
  2835 lemma distinct_filter [simp]: "distinct xs ==> distinct (filter P xs)"
  2836 by (induct xs) auto
  2837 
  2838 lemma distinct_upt[simp]: "distinct[i..<j]"
  2839 by (induct j) auto
  2840 
  2841 lemma distinct_upto[simp]: "distinct[i..j]"
  2842 apply(induct i j rule:upto.induct)
  2843 apply(subst upto.simps)
  2844 apply(simp)
  2845 done
  2846 
  2847 lemma distinct_take[simp]: "distinct xs \<Longrightarrow> distinct (take i xs)"
  2848 apply(induct xs arbitrary: i)
  2849  apply simp
  2850 apply (case_tac i)
  2851  apply simp_all
  2852 apply(blast dest:in_set_takeD)
  2853 done
  2854 
  2855 lemma distinct_drop[simp]: "distinct xs \<Longrightarrow> distinct (drop i xs)"
  2856 apply(induct xs arbitrary: i)
  2857  apply simp
  2858 apply (case_tac i)
  2859  apply simp_all
  2860 done
  2861 
  2862 lemma distinct_list_update:
  2863 assumes d: "distinct xs" and a: "a \<notin> set xs - {xs!i}"
  2864 shows "distinct (xs[i:=a])"
  2865 proof (cases "i < length xs")
  2866   case True
  2867   with a have "a \<notin> set (take i xs @ xs ! i # drop (Suc i) xs) - {xs!i}"
  2868     apply (drule_tac id_take_nth_drop) by simp
  2869   with d True show ?thesis
  2870     apply (simp add: upd_conv_take_nth_drop)
  2871     apply (drule subst [OF id_take_nth_drop]) apply assumption
  2872     apply simp apply (cases "a = xs!i") apply simp by blast
  2873 next
  2874   case False with d show ?thesis by auto
  2875 qed
  2876 
  2877 lemma distinct_concat:
  2878   assumes "distinct xs"
  2879   and "\<And> ys. ys \<in> set xs \<Longrightarrow> distinct ys"
  2880   and "\<And> ys zs. \<lbrakk> ys \<in> set xs ; zs \<in> set xs ; ys \<noteq> zs \<rbrakk> \<Longrightarrow> set ys \<inter> set zs = {}"
  2881   shows "distinct (concat xs)"
  2882   using assms by (induct xs) auto
  2883 
  2884 text {* It is best to avoid this indexed version of distinct, but
  2885 sometimes it is useful. *}
  2886 
  2887 lemma distinct_conv_nth:
  2888 "distinct xs = (\<forall>i < size xs. \<forall>j < size xs. i \<noteq> j --> xs!i \<noteq> xs!j)"
  2889 apply (induct xs, simp, simp)
  2890 apply (rule iffI, clarsimp)
  2891  apply (case_tac i)
  2892 apply (case_tac j, simp)
  2893 apply (simp add: set_conv_nth)
  2894  apply (case_tac j)
  2895 apply (clarsimp simp add: set_conv_nth, simp) 
  2896 apply (rule conjI)
  2897 (*TOO SLOW
  2898 apply (metis Zero_neq_Suc gr0_conv_Suc in_set_conv_nth lessI less_trans_Suc nth_Cons' nth_Cons_Suc)
  2899 *)
  2900  apply (clarsimp simp add: set_conv_nth)
  2901  apply (erule_tac x = 0 in allE, simp)
  2902  apply (erule_tac x = "Suc i" in allE, simp, clarsimp)
  2903 (*TOO SLOW
  2904 apply (metis Suc_Suc_eq lessI less_trans_Suc nth_Cons_Suc)
  2905 *)
  2906 apply (erule_tac x = "Suc i" in allE, simp)
  2907 apply (erule_tac x = "Suc j" in allE, simp)
  2908 done
  2909 
  2910 lemma nth_eq_iff_index_eq:
  2911  "\<lbrakk> distinct xs; i < length xs; j < length xs \<rbrakk> \<Longrightarrow> (xs!i = xs!j) = (i = j)"
  2912 by(auto simp: distinct_conv_nth)
  2913 
  2914 lemma distinct_card: "distinct xs ==> card (set xs) = size xs"
  2915 by (induct xs) auto
  2916 
  2917 lemma card_distinct: "card (set xs) = size xs ==> distinct xs"
  2918 proof (induct xs)
  2919   case Nil thus ?case by simp
  2920 next
  2921   case (Cons x xs)
  2922   show ?case
  2923   proof (cases "x \<in> set xs")
  2924     case False with Cons show ?thesis by simp
  2925   next
  2926     case True with Cons.prems
  2927     have "card (set xs) = Suc (length xs)" 
  2928       by (simp add: card_insert_if split: split_if_asm)
  2929     moreover have "card (set xs) \<le> length xs" by (rule card_length)
  2930     ultimately have False by simp
  2931     thus ?thesis ..
  2932   qed
  2933 qed
  2934 
  2935 lemma distinct_length_filter: "distinct xs \<Longrightarrow> length (filter P xs) = card ({x. P x} Int set xs)"
  2936 by (induct xs) (auto)
  2937 
  2938 lemma not_distinct_decomp: "~ distinct ws ==> EX xs ys zs y. ws = xs@[y]@ys@[y]@zs"
  2939 apply (induct n == "length ws" arbitrary:ws) apply simp
  2940 apply(case_tac ws) apply simp
  2941 apply (simp split:split_if_asm)
  2942 apply (metis Cons_eq_appendI eq_Nil_appendI split_list)
  2943 done
  2944 
  2945 lemma not_distinct_conv_prefix:
  2946   defines "dec as xs y ys \<equiv> y \<in> set xs \<and> distinct xs \<and> as = xs @ y # ys"
  2947   shows "\<not>distinct as \<longleftrightarrow> (\<exists>xs y ys. dec as xs y ys)" (is "?L = ?R")
  2948 proof
  2949   assume "?L" then show "?R"
  2950   proof (induct "length as" arbitrary: as rule: less_induct)
  2951     case less
  2952     obtain xs ys zs y where decomp: "as = (xs @ y # ys) @ y # zs"
  2953       using not_distinct_decomp[OF less.prems] by auto
  2954     show ?case
  2955     proof (cases "distinct (xs @ y # ys)")
  2956       case True
  2957       with decomp have "dec as (xs @ y # ys) y zs" by (simp add: dec_def)
  2958       then show ?thesis by blast
  2959     next
  2960       case False
  2961       with less decomp obtain xs' y' ys' where "dec (xs @ y # ys) xs' y' ys'"
  2962         by atomize_elim auto
  2963       with decomp have "dec as xs' y' (ys' @ y # zs)" by (simp add: dec_def)
  2964       then show ?thesis by blast
  2965     qed
  2966   qed
  2967 qed (auto simp: dec_def)
  2968 
  2969 lemma length_remdups_concat:
  2970   "length (remdups (concat xss)) = card (\<Union>xs\<in>set xss. set xs)"
  2971   by (simp add: distinct_card [symmetric])
  2972 
  2973 lemma length_remdups_card_conv: "length(remdups xs) = card(set xs)"
  2974 proof -
  2975   have xs: "concat[xs] = xs" by simp
  2976   from length_remdups_concat[of "[xs]"] show ?thesis unfolding xs by simp
  2977 qed
  2978 
  2979 lemma remdups_remdups:
  2980   "remdups (remdups xs) = remdups xs"
  2981   by (induct xs) simp_all
  2982 
  2983 lemma distinct_butlast:
  2984   assumes "xs \<noteq> []" and "distinct xs"
  2985   shows "distinct (butlast xs)"
  2986 proof -
  2987   from `xs \<noteq> []` obtain ys y where "xs = ys @ [y]" by (cases xs rule: rev_cases) auto
  2988   with `distinct xs` show ?thesis by simp
  2989 qed
  2990 
  2991 lemma remdups_map_remdups:
  2992   "remdups (map f (remdups xs)) = remdups (map f xs)"
  2993   by (induct xs) simp_all
  2994 
  2995 lemma distinct_zipI1:
  2996   assumes "distinct xs"
  2997   shows "distinct (zip xs ys)"
  2998 proof (rule zip_obtain_same_length)
  2999   fix xs' :: "'a list" and ys' :: "'b list" and n
  3000   assume "length xs' = length ys'"
  3001   assume "xs' = take n xs"
  3002   with assms have "distinct xs'" by simp
  3003   with `length xs' = length ys'` show "distinct (zip xs' ys')"
  3004     by (induct xs' ys' rule: list_induct2) (auto elim: in_set_zipE)
  3005 qed
  3006 
  3007 lemma distinct_zipI2:
  3008   assumes "distinct ys"
  3009   shows "distinct (zip xs ys)"
  3010 proof (rule zip_obtain_same_length)
  3011   fix xs' :: "'b list" and ys' :: "'a list" and n
  3012   assume "length xs' = length ys'"
  3013   assume "ys' = take n ys"
  3014   with assms have "distinct ys'" by simp
  3015   with `length xs' = length ys'` show "distinct (zip xs' ys')"
  3016     by (induct xs' ys' rule: list_induct2) (auto elim: in_set_zipE)
  3017 qed
  3018 
  3019 (* The next two lemmas help Sledgehammer. *)
  3020 
  3021 lemma distinct_singleton: "distinct [x]" by simp
  3022 
  3023 lemma distinct_length_2_or_more:
  3024 "distinct (a # b # xs) \<longleftrightarrow> (a \<noteq> b \<and> distinct (a # xs) \<and> distinct (b # xs))"
  3025 by (metis distinct.simps(2) hd.simps hd_in_set list.simps(2) set_ConsD set_rev_mp set_subset_Cons)
  3026 
  3027 subsubsection {* List summation: @{const listsum} and @{text"\<Sum>"}*}
  3028 
  3029 lemma (in monoid_add) listsum_simps [simp]:
  3030   "listsum [] = 0"
  3031   "listsum (x # xs) = x + listsum xs"
  3032   by (simp_all add: listsum_def)
  3033 
  3034 lemma (in monoid_add) listsum_append [simp]:
  3035   "listsum (xs @ ys) = listsum xs + listsum ys"
  3036   by (induct xs) (simp_all add: add.assoc)
  3037 
  3038 lemma (in comm_monoid_add) listsum_rev [simp]:
  3039   "listsum (rev xs) = listsum xs"
  3040   by (simp add: listsum_def foldr_def fold_rev fun_eq_iff add_ac)
  3041 
  3042 lemma (in monoid_add) fold_plus_listsum_rev:
  3043   "fold plus xs = plus (listsum (rev xs))"
  3044 proof
  3045   fix x
  3046   have "fold plus xs x = fold plus xs (x + 0)" by simp
  3047   also have "\<dots> = fold plus (x # xs) 0" by simp
  3048   also have "\<dots> = foldr plus (rev xs @ [x]) 0" by (simp add: foldr_def)
  3049   also have "\<dots> = listsum (rev xs @ [x])" by (simp add: listsum_def)
  3050   also have "\<dots> = listsum (rev xs) + listsum [x]" by simp
  3051   finally show "fold plus xs x = listsum (rev xs) + x" by simp
  3052 qed
  3053 
  3054 lemma (in semigroup_add) foldl_assoc:
  3055   "foldl plus (x + y) zs = x + foldl plus y zs"
  3056   by (simp add: foldl_def fold_commute_apply [symmetric] fun_eq_iff add_assoc)
  3057 
  3058 lemma (in ab_semigroup_add) foldr_conv_foldl:
  3059   "foldr plus xs a = foldl plus a xs"
  3060   by (simp add: foldl_def foldr_fold fun_eq_iff add_ac)
  3061 
  3062 text {*
  3063   Note: @{text "n \<le> foldl (op +) n ns"} looks simpler, but is more
  3064   difficult to use because it requires an additional transitivity step.
  3065 *}
  3066 
  3067 lemma start_le_sum:
  3068   fixes m n :: nat
  3069   shows "m \<le> n \<Longrightarrow> m \<le> foldl plus n ns"
  3070   by (simp add: foldl_def add_commute fold_plus_listsum_rev)
  3071 
  3072 lemma elem_le_sum:
  3073   fixes m n :: nat 
  3074   shows "n \<in> set ns \<Longrightarrow> n \<le> foldl plus 0 ns"
  3075   by (force intro: start_le_sum simp add: in_set_conv_decomp)
  3076 
  3077 lemma sum_eq_0_conv [iff]:
  3078   fixes m :: nat
  3079   shows "foldl plus m ns = 0 \<longleftrightarrow> m = 0 \<and> (\<forall>n \<in> set ns. n = 0)"
  3080   by (induct ns arbitrary: m) auto
  3081 
  3082 text{* Some syntactic sugar for summing a function over a list: *}
  3083 
  3084 syntax
  3085   "_listsum" :: "pttrn => 'a list => 'b => 'b"    ("(3SUM _<-_. _)" [0, 51, 10] 10)
  3086 syntax (xsymbols)
  3087   "_listsum" :: "pttrn => 'a list => 'b => 'b"    ("(3\<Sum>_\<leftarrow>_. _)" [0, 51, 10] 10)
  3088 syntax (HTML output)
  3089   "_listsum" :: "pttrn => 'a list => 'b => 'b"    ("(3\<Sum>_\<leftarrow>_. _)" [0, 51, 10] 10)
  3090 
  3091 translations -- {* Beware of argument permutation! *}
  3092   "SUM x<-xs. b" == "CONST listsum (CONST map (%x. b) xs)"
  3093   "\<Sum>x\<leftarrow>xs. b" == "CONST listsum (CONST map (%x. b) xs)"
  3094 
  3095 lemma (in comm_monoid_add) listsum_map_remove1:
  3096   "x \<in> set xs \<Longrightarrow> listsum (map f xs) = f x + listsum (map f (remove1 x xs))"
  3097   by (induct xs) (auto simp add: ac_simps)
  3098 
  3099 lemma (in monoid_add) list_size_conv_listsum:
  3100   "list_size f xs = listsum (map f xs) + size xs"
  3101   by (induct xs) auto
  3102 
  3103 lemma (in monoid_add) length_concat:
  3104   "length (concat xss) = listsum (map length xss)"
  3105   by (induct xss) simp_all
  3106 
  3107 lemma (in monoid_add) listsum_map_filter:
  3108   assumes "\<And>x. x \<in> set xs \<Longrightarrow> \<not> P x \<Longrightarrow> f x = 0"
  3109   shows "listsum (map f (filter P xs)) = listsum (map f xs)"
  3110   using assms by (induct xs) auto
  3111 
  3112 lemma (in monoid_add) distinct_listsum_conv_Setsum:
  3113   "distinct xs \<Longrightarrow> listsum xs = Setsum (set xs)"
  3114   by (induct xs) simp_all
  3115 
  3116 lemma listsum_eq_0_nat_iff_nat [simp]:
  3117   "listsum ns = (0::nat) \<longleftrightarrow> (\<forall>n \<in> set ns. n = 0)"
  3118   by (simp add: listsum_def foldr_conv_foldl)
  3119 
  3120 lemma elem_le_listsum_nat:
  3121   "k < size ns \<Longrightarrow> ns ! k \<le> listsum (ns::nat list)"
  3122 apply(induct ns arbitrary: k)
  3123  apply simp
  3124 apply(fastforce simp add:nth_Cons split: nat.split)
  3125 done
  3126 
  3127 lemma listsum_update_nat:
  3128   "k<size ns \<Longrightarrow> listsum (ns[k := (n::nat)]) = listsum ns + n - ns ! k"
  3129 apply(induct ns arbitrary:k)
  3130  apply (auto split:nat.split)
  3131 apply(drule elem_le_listsum_nat)
  3132 apply arith
  3133 done
  3134 
  3135 lemma (in monoid_add) listsum_triv:
  3136   "(\<Sum>x\<leftarrow>xs. r) = of_nat (length xs) * r"
  3137   by (induct xs) (simp_all add: left_distrib)
  3138 
  3139 lemma (in monoid_add) listsum_0 [simp]:
  3140   "(\<Sum>x\<leftarrow>xs. 0) = 0"
  3141   by (induct xs) (simp_all add: left_distrib)
  3142 
  3143 text{* For non-Abelian groups @{text xs} needs to be reversed on one side: *}
  3144 lemma (in ab_group_add) uminus_listsum_map:
  3145   "- listsum (map f xs) = listsum (map (uminus \<circ> f) xs)"
  3146   by (induct xs) simp_all
  3147 
  3148 lemma (in comm_monoid_add) listsum_addf:
  3149   "(\<Sum>x\<leftarrow>xs. f x + g x) = listsum (map f xs) + listsum (map g xs)"
  3150   by (induct xs) (simp_all add: algebra_simps)
  3151 
  3152 lemma (in ab_group_add) listsum_subtractf:
  3153   "(\<Sum>x\<leftarrow>xs. f x - g x) = listsum (map f xs) - listsum (map g xs)"
  3154   by (induct xs) (simp_all add: algebra_simps)
  3155 
  3156 lemma (in semiring_0) listsum_const_mult:
  3157   "(\<Sum>x\<leftarrow>xs. c * f x) = c * (\<Sum>x\<leftarrow>xs. f x)"
  3158   by (induct xs) (simp_all add: algebra_simps)
  3159 
  3160 lemma (in semiring_0) listsum_mult_const:
  3161   "(\<Sum>x\<leftarrow>xs. f x * c) = (\<Sum>x\<leftarrow>xs. f x) * c"
  3162   by (induct xs) (simp_all add: algebra_simps)
  3163 
  3164 lemma (in ordered_ab_group_add_abs) listsum_abs:
  3165   "\<bar>listsum xs\<bar> \<le> listsum (map abs xs)"
  3166   by (induct xs) (simp_all add: order_trans [OF abs_triangle_ineq])
  3167 
  3168 lemma listsum_mono:
  3169   fixes f g :: "'a \<Rightarrow> 'b::{monoid_add, ordered_ab_semigroup_add}"
  3170   shows "(\<And>x. x \<in> set xs \<Longrightarrow> f x \<le> g x) \<Longrightarrow> (\<Sum>x\<leftarrow>xs. f x) \<le> (\<Sum>x\<leftarrow>xs. g x)"
  3171   by (induct xs) (simp, simp add: add_mono)
  3172 
  3173 lemma (in monoid_add) listsum_distinct_conv_setsum_set:
  3174   "distinct xs \<Longrightarrow> listsum (map f xs) = setsum f (set xs)"
  3175   by (induct xs) simp_all
  3176 
  3177 lemma (in monoid_add) interv_listsum_conv_setsum_set_nat:
  3178   "listsum (map f [m..<n]) = setsum f (set [m..<n])"
  3179   by (simp add: listsum_distinct_conv_setsum_set)
  3180 
  3181 lemma (in monoid_add) interv_listsum_conv_setsum_set_int:
  3182   "listsum (map f [k..l]) = setsum f (set [k..l])"
  3183   by (simp add: listsum_distinct_conv_setsum_set)
  3184 
  3185 text {* General equivalence between @{const listsum} and @{const setsum} *}
  3186 lemma (in monoid_add) listsum_setsum_nth:
  3187   "listsum xs = (\<Sum> i = 0 ..< length xs. xs ! i)"
  3188   using interv_listsum_conv_setsum_set_nat [of "op ! xs" 0 "length xs"] by (simp add: map_nth)
  3189 
  3190 
  3191 subsubsection {* @{const insert} *}
  3192 
  3193 lemma in_set_insert [simp]:
  3194   "x \<in> set xs \<Longrightarrow> List.insert x xs = xs"
  3195   by (simp add: List.insert_def)
  3196 
  3197 lemma not_in_set_insert [simp]:
  3198   "x \<notin> set xs \<Longrightarrow> List.insert x xs = x # xs"
  3199   by (simp add: List.insert_def)
  3200 
  3201 lemma insert_Nil [simp]:
  3202   "List.insert x [] = [x]"
  3203   by simp
  3204 
  3205 lemma set_insert [simp]:
  3206   "set (List.insert x xs) = insert x (set xs)"
  3207   by (auto simp add: List.insert_def)
  3208 
  3209 lemma distinct_insert [simp]:
  3210   "distinct xs \<Longrightarrow> distinct (List.insert x xs)"
  3211   by (simp add: List.insert_def)
  3212 
  3213 lemma insert_remdups:
  3214   "List.insert x (remdups xs) = remdups (List.insert x xs)"
  3215   by (simp add: List.insert_def)
  3216 
  3217 
  3218 subsubsection {* @{text remove1} *}
  3219 
  3220 lemma remove1_append:
  3221   "remove1 x (xs @ ys) =
  3222   (if x \<in> set xs then remove1 x xs @ ys else xs @ remove1 x ys)"
  3223 by (induct xs) auto
  3224 
  3225 lemma remove1_commute: "remove1 x (remove1 y zs) = remove1 y (remove1 x zs)"
  3226 by (induct zs) auto
  3227 
  3228 lemma in_set_remove1[simp]:
  3229   "a \<noteq> b \<Longrightarrow> a : set(remove1 b xs) = (a : set xs)"
  3230 apply (induct xs)
  3231 apply auto
  3232 done
  3233 
  3234 lemma set_remove1_subset: "set(remove1 x xs) <= set xs"
  3235 apply(induct xs)
  3236  apply simp
  3237 apply simp
  3238 apply blast
  3239 done
  3240 
  3241 lemma set_remove1_eq [simp]: "distinct xs ==> set(remove1 x xs) = set xs - {x}"
  3242 apply(induct xs)
  3243  apply simp
  3244 apply simp
  3245 apply blast
  3246 done
  3247 
  3248 lemma length_remove1:
  3249   "length(remove1 x xs) = (if x : set xs then length xs - 1 else length xs)"
  3250 apply (induct xs)
  3251  apply (auto dest!:length_pos_if_in_set)
  3252 done
  3253 
  3254 lemma remove1_filter_not[simp]:
  3255   "\<not> P x \<Longrightarrow> remove1 x (filter P xs) = filter P xs"
  3256 by(induct xs) auto
  3257 
  3258 lemma filter_remove1:
  3259   "filter Q (remove1 x xs) = remove1 x (filter Q xs)"
  3260 by (induct xs) auto
  3261 
  3262 lemma notin_set_remove1[simp]: "x ~: set xs ==> x ~: set(remove1 y xs)"
  3263 apply(insert set_remove1_subset)
  3264 apply fast
  3265 done
  3266 
  3267 lemma distinct_remove1[simp]: "distinct xs ==> distinct(remove1 x xs)"
  3268 by (induct xs) simp_all
  3269 
  3270 lemma remove1_remdups:
  3271   "distinct xs \<Longrightarrow> remove1 x (remdups xs) = remdups (remove1 x xs)"
  3272   by (induct xs) simp_all
  3273 
  3274 lemma remove1_idem:
  3275   assumes "x \<notin> set xs"
  3276   shows "remove1 x xs = xs"
  3277   using assms by (induct xs) simp_all
  3278 
  3279 
  3280 subsubsection {* @{text removeAll} *}
  3281 
  3282 lemma removeAll_filter_not_eq:
  3283   "removeAll x = filter (\<lambda>y. x \<noteq> y)"
  3284 proof
  3285   fix xs
  3286   show "removeAll x xs = filter (\<lambda>y. x \<noteq> y) xs"
  3287     by (induct xs) auto
  3288 qed
  3289 
  3290 lemma removeAll_append[simp]:
  3291   "removeAll x (xs @ ys) = removeAll x xs @ removeAll x ys"
  3292 by (induct xs) auto
  3293 
  3294 lemma set_removeAll[simp]: "set(removeAll x xs) = set xs - {x}"
  3295 by (induct xs) auto
  3296 
  3297 lemma removeAll_id[simp]: "x \<notin> set xs \<Longrightarrow> removeAll x xs = xs"
  3298 by (induct xs) auto
  3299 
  3300 (* Needs count:: 'a \<Rightarrow> a' list \<Rightarrow> nat
  3301 lemma length_removeAll:
  3302   "length(removeAll x xs) = length xs - count x xs"
  3303 *)
  3304 
  3305 lemma removeAll_filter_not[simp]:
  3306   "\<not> P x \<Longrightarrow> removeAll x (filter P xs) = filter P xs"
  3307 by(induct xs) auto
  3308 
  3309 lemma distinct_removeAll:
  3310   "distinct xs \<Longrightarrow> distinct (removeAll x xs)"
  3311   by (simp add: removeAll_filter_not_eq)
  3312 
  3313 lemma distinct_remove1_removeAll:
  3314   "distinct xs ==> remove1 x xs = removeAll x xs"
  3315 by (induct xs) simp_all
  3316 
  3317 lemma map_removeAll_inj_on: "inj_on f (insert x (set xs)) \<Longrightarrow>
  3318   map f (removeAll x xs) = removeAll (f x) (map f xs)"
  3319 by (induct xs) (simp_all add:inj_on_def)
  3320 
  3321 lemma map_removeAll_inj: "inj f \<Longrightarrow>
  3322   map f (removeAll x xs) = removeAll (f x) (map f xs)"
  3323 by(metis map_removeAll_inj_on subset_inj_on subset_UNIV)
  3324 
  3325 
  3326 subsubsection {* @{text replicate} *}
  3327 
  3328 lemma length_replicate [simp]: "length (replicate n x) = n"
  3329 by (induct n) auto
  3330 
  3331 lemma Ex_list_of_length: "\<exists>xs. length xs = n"
  3332 by (rule exI[of _ "replicate n undefined"]) simp
  3333 
  3334 lemma map_replicate [simp]: "map f (replicate n x) = replicate n (f x)"
  3335 by (induct n) auto
  3336 
  3337 lemma map_replicate_const:
  3338   "map (\<lambda> x. k) lst = replicate (length lst) k"
  3339   by (induct lst) auto
  3340 
  3341 lemma replicate_app_Cons_same:
  3342 "(replicate n x) @ (x # xs) = x # replicate n x @ xs"
  3343 by (induct n) auto
  3344 
  3345 lemma rev_replicate [simp]: "rev (replicate n x) = replicate n x"
  3346 apply (induct n, simp)
  3347 apply (simp add: replicate_app_Cons_same)
  3348 done
  3349 
  3350 lemma replicate_add: "replicate (n + m) x = replicate n x @ replicate m x"
  3351 by (induct n) auto
  3352 
  3353 text{* Courtesy of Matthias Daum: *}
  3354 lemma append_replicate_commute:
  3355   "replicate n x @ replicate k x = replicate k x @ replicate n x"
  3356 apply (simp add: replicate_add [THEN sym])
  3357 apply (simp add: add_commute)
  3358 done
  3359 
  3360 text{* Courtesy of Andreas Lochbihler: *}
  3361 lemma filter_replicate:
  3362   "filter P (replicate n x) = (if P x then replicate n x else [])"
  3363 by(induct n) auto
  3364 
  3365 lemma hd_replicate [simp]: "n \<noteq> 0 ==> hd (replicate n x) = x"
  3366 by (induct n) auto
  3367 
  3368 lemma tl_replicate [simp]: "n \<noteq> 0 ==> tl (replicate n x) = replicate (n - 1) x"
  3369 by (induct n) auto
  3370 
  3371 lemma last_replicate [simp]: "n \<noteq> 0 ==> last (replicate n x) = x"
  3372 by (atomize (full), induct n) auto
  3373 
  3374 lemma nth_replicate[simp]: "i < n ==> (replicate n x)!i = x"
  3375 apply (induct n arbitrary: i, simp)
  3376 apply (simp add: nth_Cons split: nat.split)
  3377 done
  3378 
  3379 text{* Courtesy of Matthias Daum (2 lemmas): *}
  3380 lemma take_replicate[simp]: "take i (replicate k x) = replicate (min i k) x"
  3381 apply (case_tac "k \<le> i")
  3382  apply  (simp add: min_def)
  3383 apply (drule not_leE)
  3384 apply (simp add: min_def)
  3385 apply (subgoal_tac "replicate k x = replicate i x @ replicate (k - i) x")
  3386  apply  simp
  3387 apply (simp add: replicate_add [symmetric])
  3388 done
  3389 
  3390 lemma drop_replicate[simp]: "drop i (replicate k x) = replicate (k-i) x"
  3391 apply (induct k arbitrary: i)
  3392  apply simp
  3393 apply clarsimp
  3394 apply (case_tac i)
  3395  apply simp
  3396 apply clarsimp
  3397 done
  3398 
  3399 
  3400 lemma set_replicate_Suc: "set (replicate (Suc n) x) = {x}"
  3401 by (induct n) auto
  3402 
  3403 lemma set_replicate [simp]: "n \<noteq> 0 ==> set (replicate n x) = {x}"
  3404 by (fast dest!: not0_implies_Suc intro!: set_replicate_Suc)
  3405 
  3406 lemma set_replicate_conv_if: "set (replicate n x) = (if n = 0 then {} else {x})"
  3407 by auto
  3408 
  3409 lemma in_set_replicate[simp]: "(x : set (replicate n y)) = (x = y & n \<noteq> 0)"
  3410 by (simp add: set_replicate_conv_if)
  3411 
  3412 lemma Ball_set_replicate[simp]:
  3413   "(ALL x : set(replicate n a). P x) = (P a | n=0)"
  3414 by(simp add: set_replicate_conv_if)
  3415 
  3416 lemma Bex_set_replicate[simp]:
  3417   "(EX x : set(replicate n a). P x) = (P a & n\<noteq>0)"
  3418 by(simp add: set_replicate_conv_if)
  3419 
  3420 lemma replicate_append_same:
  3421   "replicate i x @ [x] = x # replicate i x"
  3422   by (induct i) simp_all
  3423 
  3424 lemma map_replicate_trivial:
  3425   "map (\<lambda>i. x) [0..<i] = replicate i x"
  3426   by (induct i) (simp_all add: replicate_append_same)
  3427 
  3428 lemma concat_replicate_trivial[simp]:
  3429   "concat (replicate i []) = []"
  3430   by (induct i) (auto simp add: map_replicate_const)
  3431 
  3432 lemma replicate_empty[simp]: "(replicate n x = []) \<longleftrightarrow> n=0"
  3433 by (induct n) auto
  3434 
  3435 lemma empty_replicate[simp]: "([] = replicate n x) \<longleftrightarrow> n=0"
  3436 by (induct n) auto
  3437 
  3438 lemma replicate_eq_replicate[simp]:
  3439   "(replicate m x = replicate n y) \<longleftrightarrow> (m=n & (m\<noteq>0 \<longrightarrow> x=y))"
  3440 apply(induct m arbitrary: n)
  3441  apply simp
  3442 apply(induct_tac n)
  3443 apply auto
  3444 done
  3445 
  3446 lemma replicate_length_filter:
  3447   "replicate (length (filter (\<lambda>y. x = y) xs)) x = filter (\<lambda>y. x = y) xs"
  3448   by (induct xs) auto
  3449 
  3450 lemma comm_append_are_replicate:
  3451   fixes xs ys :: "'a list"
  3452   assumes "xs \<noteq> []" "ys \<noteq> []"
  3453   assumes "xs @ ys = ys @ xs"
  3454   shows "\<exists>m n zs. concat (replicate m zs) = xs \<and> concat (replicate n zs) = ys"
  3455   using assms
  3456 proof (induct "length (xs @ ys)" arbitrary: xs ys rule: less_induct)
  3457   case less
  3458 
  3459   def xs' \<equiv> "if (length xs \<le> length ys) then xs else ys"
  3460     and ys' \<equiv> "if (length xs \<le> length ys) then ys else xs"
  3461   then have
  3462     prems': "length xs' \<le> length ys'"
  3463             "xs' @ ys' = ys' @ xs'"
  3464       and "xs' \<noteq> []"
  3465       and len: "length (xs @ ys) = length (xs' @ ys')"
  3466     using less by (auto intro: less.hyps)
  3467 
  3468   from prems'
  3469   obtain ws where "ys' = xs' @ ws"
  3470     by (auto simp: append_eq_append_conv2)
  3471 
  3472   have "\<exists>m n zs. concat (replicate m zs) = xs' \<and> concat (replicate n zs) = ys'"
  3473   proof (cases "ws = []")
  3474     case True
  3475     then have "concat (replicate 1 xs') = xs'"
  3476       and "concat (replicate 1 xs') = ys'"
  3477       using `ys' = xs' @ ws` by auto
  3478     then show ?thesis by blast
  3479   next
  3480     case False
  3481     from `ys' = xs' @ ws` and `xs' @ ys' = ys' @ xs'`
  3482     have "xs' @ ws = ws @ xs'" by simp
  3483     then have "\<exists>m n zs. concat (replicate m zs) = xs' \<and> concat (replicate n zs) = ws"
  3484       using False and `xs' \<noteq> []` and `ys' = xs' @ ws` and len
  3485       by (intro less.hyps) auto
  3486     then obtain m n zs where "concat (replicate m zs) = xs'"
  3487       and "concat (replicate n zs) = ws" by blast
  3488     moreover
  3489     then have "concat (replicate (m + n) zs) = ys'"
  3490       using `ys' = xs' @ ws`
  3491       by (simp add: replicate_add)
  3492     ultimately
  3493     show ?thesis by blast
  3494   qed
  3495   then show ?case
  3496     using xs'_def ys'_def by metis
  3497 qed
  3498 
  3499 lemma comm_append_is_replicate:
  3500   fixes xs ys :: "'a list"
  3501   assumes "xs \<noteq> []" "ys \<noteq> []"
  3502   assumes "xs @ ys = ys @ xs"
  3503   shows "\<exists>n zs. n > 1 \<and> concat (replicate n zs) = xs @ ys"
  3504 
  3505 proof -
  3506   obtain m n zs where "concat (replicate m zs) = xs"
  3507     and "concat (replicate n zs) = ys"
  3508     using assms by (metis comm_append_are_replicate)
  3509   then have "m + n > 1" and "concat (replicate (m+n) zs) = xs @ ys"
  3510     using `xs \<noteq> []` and `ys \<noteq> []`
  3511     by (auto simp: replicate_add)
  3512   then show ?thesis by blast
  3513 qed
  3514 
  3515 
  3516 subsubsection{*@{text rotate1} and @{text rotate}*}
  3517 
  3518 lemma rotate_simps[simp]: "rotate1 [] = [] \<and> rotate1 (x#xs) = xs @ [x]"
  3519 by(simp add:rotate1_def)
  3520 
  3521 lemma rotate0[simp]: "rotate 0 = id"
  3522 by(simp add:rotate_def)
  3523 
  3524 lemma rotate_Suc[simp]: "rotate (Suc n) xs = rotate1(rotate n xs)"
  3525 by(simp add:rotate_def)
  3526 
  3527 lemma rotate_add:
  3528   "rotate (m+n) = rotate m o rotate n"
  3529 by(simp add:rotate_def funpow_add)
  3530 
  3531 lemma rotate_rotate: "rotate m (rotate n xs) = rotate (m+n) xs"
  3532 by(simp add:rotate_add)
  3533 
  3534 lemma rotate1_rotate_swap: "rotate1 (rotate n xs) = rotate n (rotate1 xs)"
  3535 by(simp add:rotate_def funpow_swap1)
  3536 
  3537 lemma rotate1_length01[simp]: "length xs <= 1 \<Longrightarrow> rotate1 xs = xs"
  3538 by(cases xs) simp_all
  3539 
  3540 lemma rotate_length01[simp]: "length xs <= 1 \<Longrightarrow> rotate n xs = xs"
  3541 apply(induct n)
  3542  apply simp
  3543 apply (simp add:rotate_def)
  3544 done
  3545 
  3546 lemma rotate1_hd_tl: "xs \<noteq> [] \<Longrightarrow> rotate1 xs = tl xs @ [hd xs]"
  3547 by(simp add:rotate1_def split:list.split)
  3548 
  3549 lemma rotate_drop_take:
  3550   "rotate n xs = drop (n mod length xs) xs @ take (n mod length xs) xs"
  3551 apply(induct n)
  3552  apply simp
  3553 apply(simp add:rotate_def)
  3554 apply(cases "xs = []")
  3555  apply (simp)
  3556 apply(case_tac "n mod length xs = 0")
  3557  apply(simp add:mod_Suc)
  3558  apply(simp add: rotate1_hd_tl drop_Suc take_Suc)
  3559 apply(simp add:mod_Suc rotate1_hd_tl drop_Suc[symmetric] drop_tl[symmetric]
  3560                 take_hd_drop linorder_not_le)
  3561 done
  3562 
  3563 lemma rotate_conv_mod: "rotate n xs = rotate (n mod length xs) xs"
  3564 by(simp add:rotate_drop_take)
  3565 
  3566 lemma rotate_id[simp]: "n mod length xs = 0 \<Longrightarrow> rotate n xs = xs"
  3567 by(simp add:rotate_drop_take)
  3568 
  3569 lemma length_rotate1[simp]: "length(rotate1 xs) = length xs"
  3570 by(simp add:rotate1_def split:list.split)
  3571 
  3572 lemma length_rotate[simp]: "length(rotate n xs) = length xs"
  3573 by (induct n arbitrary: xs) (simp_all add:rotate_def)
  3574 
  3575 lemma distinct1_rotate[simp]: "distinct(rotate1 xs) = distinct xs"
  3576 by(simp add:rotate1_def split:list.split) blast
  3577 
  3578 lemma distinct_rotate[simp]: "distinct(rotate n xs) = distinct xs"
  3579 by (induct n) (simp_all add:rotate_def)
  3580 
  3581 lemma rotate_map: "rotate n (map f xs) = map f (rotate n xs)"
  3582 by(simp add:rotate_drop_take take_map drop_map)
  3583 
  3584 lemma set_rotate1[simp]: "set(rotate1 xs) = set xs"
  3585 by (cases xs) (auto simp add:rotate1_def)
  3586 
  3587 lemma set_rotate[simp]: "set(rotate n xs) = set xs"
  3588 by (induct n) (simp_all add:rotate_def)
  3589 
  3590 lemma rotate1_is_Nil_conv[simp]: "(rotate1 xs = []) = (xs = [])"
  3591 by(simp add:rotate1_def split:list.split)
  3592 
  3593 lemma rotate_is_Nil_conv[simp]: "(rotate n xs = []) = (xs = [])"
  3594 by (induct n) (simp_all add:rotate_def)
  3595 
  3596 lemma rotate_rev:
  3597   "rotate n (rev xs) = rev(rotate (length xs - (n mod length xs)) xs)"
  3598 apply(simp add:rotate_drop_take rev_drop rev_take)
  3599 apply(cases "length xs = 0")
  3600  apply simp
  3601 apply(cases "n mod length xs = 0")
  3602  apply simp
  3603 apply(simp add:rotate_drop_take rev_drop rev_take)
  3604 done
  3605 
  3606 lemma hd_rotate_conv_nth: "xs \<noteq> [] \<Longrightarrow> hd(rotate n xs) = xs!(n mod length xs)"
  3607 apply(simp add:rotate_drop_take hd_append hd_drop_conv_nth hd_conv_nth)
  3608 apply(subgoal_tac "length xs \<noteq> 0")
  3609  prefer 2 apply simp
  3610 using mod_less_divisor[of "length xs" n] by arith
  3611 
  3612 
  3613 subsubsection {* @{text sublist} --- a generalization of @{text nth} to sets *}
  3614 
  3615 lemma sublist_empty [simp]: "sublist xs {} = []"
  3616 by (auto simp add: sublist_def)
  3617 
  3618 lemma sublist_nil [simp]: "sublist [] A = []"
  3619 by (auto simp add: sublist_def)
  3620 
  3621 lemma length_sublist:
  3622   "length(sublist xs I) = card{i. i < length xs \<and> i : I}"
  3623 by(simp add: sublist_def length_filter_conv_card cong:conj_cong)
  3624 
  3625 lemma sublist_shift_lemma_Suc:
  3626   "map fst (filter (%p. P(Suc(snd p))) (zip xs is)) =
  3627    map fst (filter (%p. P(snd p)) (zip xs (map Suc is)))"
  3628 apply(induct xs arbitrary: "is")
  3629  apply simp
  3630 apply (case_tac "is")
  3631  apply simp
  3632 apply simp
  3633 done
  3634 
  3635 lemma sublist_shift_lemma:
  3636      "map fst [p<-zip xs [i..<i + length xs] . snd p : A] =
  3637       map fst [p<-zip xs [0..<length xs] . snd p + i : A]"
  3638 by (induct xs rule: rev_induct) (simp_all add: add_commute)
  3639 
  3640 lemma sublist_append:
  3641      "sublist (l @ l') A = sublist l A @ sublist l' {j. j + length l : A}"
  3642 apply (unfold sublist_def)
  3643 apply (induct l' rule: rev_induct, simp)
  3644 apply (simp add: upt_add_eq_append[of 0] sublist_shift_lemma)
  3645 apply (simp add: add_commute)
  3646 done
  3647 
  3648 lemma sublist_Cons:
  3649 "sublist (x # l) A = (if 0:A then [x] else []) @ sublist l {j. Suc j : A}"
  3650 apply (induct l rule: rev_induct)
  3651  apply (simp add: sublist_def)
  3652 apply (simp del: append_Cons add: append_Cons[symmetric] sublist_append)
  3653 done
  3654 
  3655 lemma set_sublist: "set(sublist xs I) = {xs!i|i. i<size xs \<and> i \<in> I}"
  3656 apply(induct xs arbitrary: I)
  3657 apply(auto simp: sublist_Cons nth_Cons split:nat.split dest!: gr0_implies_Suc)
  3658 done
  3659 
  3660 lemma set_sublist_subset: "set(sublist xs I) \<subseteq> set xs"
  3661 by(auto simp add:set_sublist)
  3662 
  3663 lemma notin_set_sublistI[simp]: "x \<notin> set xs \<Longrightarrow> x \<notin> set(sublist xs I)"
  3664 by(auto simp add:set_sublist)
  3665 
  3666 lemma in_set_sublistD: "x \<in> set(sublist xs I) \<Longrightarrow> x \<in> set xs"
  3667 by(auto simp add:set_sublist)
  3668 
  3669 lemma sublist_singleton [simp]: "sublist [x] A = (if 0 : A then [x] else [])"
  3670 by (simp add: sublist_Cons)
  3671 
  3672 
  3673 lemma distinct_sublistI[simp]: "distinct xs \<Longrightarrow> distinct(sublist xs I)"
  3674 apply(induct xs arbitrary: I)
  3675  apply simp
  3676 apply(auto simp add:sublist_Cons)
  3677 done
  3678 
  3679 
  3680 lemma sublist_upt_eq_take [simp]: "sublist l {..<n} = take n l"
  3681 apply (induct l rule: rev_induct, simp)
  3682 apply (simp split: nat_diff_split add: sublist_append)
  3683 done
  3684 
  3685 lemma filter_in_sublist:
  3686  "distinct xs \<Longrightarrow> filter (%x. x \<in> set(sublist xs s)) xs = sublist xs s"
  3687 proof (induct xs arbitrary: s)
  3688   case Nil thus ?case by simp
  3689 next
  3690   case (Cons a xs)
  3691   moreover hence "!x. x: set xs \<longrightarrow> x \<noteq> a" by auto
  3692   ultimately show ?case by(simp add: sublist_Cons cong:filter_cong)
  3693 qed
  3694 
  3695 
  3696 subsubsection {* @{const splice} *}
  3697 
  3698 lemma splice_Nil2 [simp, code]: "splice xs [] = xs"
  3699 by (cases xs) simp_all
  3700 
  3701 declare splice.simps(1,3)[code]
  3702 declare splice.simps(2)[simp del]
  3703 
  3704 lemma length_splice[simp]: "length(splice xs ys) = length xs + length ys"
  3705 by (induct xs ys rule: splice.induct) auto
  3706 
  3707 
  3708 subsubsection {* Transpose *}
  3709 
  3710 function transpose where
  3711 "transpose []             = []" |
  3712 "transpose ([]     # xss) = transpose xss" |
  3713 "transpose ((x#xs) # xss) =
  3714   (x # [h. (h#t) \<leftarrow> xss]) # transpose (xs # [t. (h#t) \<leftarrow> xss])"
  3715 by pat_completeness auto
  3716 
  3717 lemma transpose_aux_filter_head:
  3718   "concat (map (list_case [] (\<lambda>h t. [h])) xss) =
  3719   map (\<lambda>xs. hd xs) [ys\<leftarrow>xss . ys \<noteq> []]"
  3720   by (induct xss) (auto split: list.split)
  3721 
  3722 lemma transpose_aux_filter_tail:
  3723   "concat (map (list_case [] (\<lambda>h t. [t])) xss) =
  3724   map (\<lambda>xs. tl xs) [ys\<leftarrow>xss . ys \<noteq> []]"
  3725   by (induct xss) (auto split: list.split)
  3726 
  3727 lemma transpose_aux_max:
  3728   "max (Suc (length xs)) (foldr (\<lambda>xs. max (length xs)) xss 0) =
  3729   Suc (max (length xs) (foldr (\<lambda>x. max (length x - Suc 0)) [ys\<leftarrow>xss . ys\<noteq>[]] 0))"
  3730   (is "max _ ?foldB = Suc (max _ ?foldA)")
  3731 proof (cases "[ys\<leftarrow>xss . ys\<noteq>[]] = []")
  3732   case True
  3733   hence "foldr (\<lambda>xs. max (length xs)) xss 0 = 0"
  3734   proof (induct xss)
  3735     case (Cons x xs)
  3736     moreover hence "x = []" by (cases x) auto
  3737     ultimately show ?case by auto
  3738   qed simp
  3739   thus ?thesis using True by simp
  3740 next
  3741   case False
  3742 
  3743   have foldA: "?foldA = foldr (\<lambda>x. max (length x)) [ys\<leftarrow>xss . ys \<noteq> []] 0 - 1"
  3744     by (induct xss) auto
  3745   have foldB: "?foldB = foldr (\<lambda>x. max (length x)) [ys\<leftarrow>xss . ys \<noteq> []] 0"
  3746     by (induct xss) auto
  3747 
  3748   have "0 < ?foldB"
  3749   proof -
  3750     from False
  3751     obtain z zs where zs: "[ys\<leftarrow>xss . ys \<noteq> []] = z#zs" by (auto simp: neq_Nil_conv)
  3752     hence "z \<in> set ([ys\<leftarrow>xss . ys \<noteq> []])" by auto
  3753     hence "z \<noteq> []" by auto
  3754     thus ?thesis
  3755       unfolding foldB zs
  3756       by (auto simp: max_def intro: less_le_trans)
  3757   qed
  3758   thus ?thesis
  3759     unfolding foldA foldB max_Suc_Suc[symmetric]
  3760     by simp
  3761 qed
  3762 
  3763 termination transpose
  3764   by (relation "measure (\<lambda>xs. foldr (\<lambda>xs. max (length xs)) xs 0 + length xs)")
  3765      (auto simp: transpose_aux_filter_tail foldr_map comp_def transpose_aux_max less_Suc_eq_le)
  3766 
  3767 lemma transpose_empty: "(transpose xs = []) \<longleftrightarrow> (\<forall>x \<in> set xs. x = [])"
  3768   by (induct rule: transpose.induct) simp_all
  3769 
  3770 lemma length_transpose:
  3771   fixes xs :: "'a list list"
  3772   shows "length (transpose xs) = foldr (\<lambda>xs. max (length xs)) xs 0"
  3773   by (induct rule: transpose.induct)
  3774     (auto simp: transpose_aux_filter_tail foldr_map comp_def transpose_aux_max
  3775                 max_Suc_Suc[symmetric] simp del: max_Suc_Suc)
  3776 
  3777 lemma nth_transpose:
  3778   fixes xs :: "'a list list"
  3779   assumes "i < length (transpose xs)"
  3780   shows "transpose xs ! i = map (\<lambda>xs. xs ! i) [ys \<leftarrow> xs. i < length ys]"
  3781 using assms proof (induct arbitrary: i rule: transpose.induct)
  3782   case (3 x xs xss)
  3783   def XS == "(x # xs) # xss"
  3784   hence [simp]: "XS \<noteq> []" by auto
  3785   thus ?case
  3786   proof (cases i)
  3787     case 0
  3788     thus ?thesis by (simp add: transpose_aux_filter_head hd_conv_nth)
  3789   next
  3790     case (Suc j)
  3791     have *: "\<And>xss. xs # map tl xss = map tl ((x#xs)#xss)" by simp
  3792     have **: "\<And>xss. (x#xs) # filter (\<lambda>ys. ys \<noteq> []) xss = filter (\<lambda>ys. ys \<noteq> []) ((x#xs)#xss)" by simp
  3793     { fix x have "Suc j < length x \<longleftrightarrow> x \<noteq> [] \<and> j < length x - Suc 0"
  3794       by (cases x) simp_all
  3795     } note *** = this
  3796 
  3797     have j_less: "j < length (transpose (xs # concat (map (list_case [] (\<lambda>h t. [t])) xss)))"
  3798       using "3.prems" by (simp add: transpose_aux_filter_tail length_transpose Suc)
  3799 
  3800     show ?thesis
  3801       unfolding transpose.simps `i = Suc j` nth_Cons_Suc "3.hyps"[OF j_less]
  3802       apply (auto simp: transpose_aux_filter_tail filter_map comp_def length_transpose * ** *** XS_def[symmetric])
  3803       apply (rule_tac y=x in list.exhaust)
  3804       by auto
  3805   qed
  3806 qed simp_all
  3807 
  3808 lemma transpose_map_map:
  3809   "transpose (map (map f) xs) = map (map f) (transpose xs)"
  3810 proof (rule nth_equalityI, safe)
  3811   have [simp]: "length (transpose (map (map f) xs)) = length (transpose xs)"
  3812     by (simp add: length_transpose foldr_map comp_def)
  3813   show "length (transpose (map (map f) xs)) = length (map (map f) (transpose xs))" by simp
  3814 
  3815   fix i assume "i < length (transpose (map (map f) xs))"
  3816   thus "transpose (map (map f) xs) ! i = map (map f) (transpose xs) ! i"
  3817     by (simp add: nth_transpose filter_map comp_def)
  3818 qed
  3819 
  3820 
  3821 subsubsection {* (In)finiteness *}
  3822 
  3823 lemma finite_maxlen:
  3824   "finite (M::'a list set) ==> EX n. ALL s:M. size s < n"
  3825 proof (induct rule: finite.induct)
  3826   case emptyI show ?case by simp
  3827 next
  3828   case (insertI M xs)
  3829   then obtain n where "\<forall>s\<in>M. length s < n" by blast
  3830   hence "ALL s:insert xs M. size s < max n (size xs) + 1" by auto
  3831   thus ?case ..
  3832 qed
  3833 
  3834 lemma lists_length_Suc_eq:
  3835   "{xs. set xs \<subseteq> A \<and> length xs = Suc n} =
  3836     (\<lambda>(xs, n). n#xs) ` ({xs. set xs \<subseteq> A \<and> length xs = n} \<times> A)"
  3837   by (auto simp: length_Suc_conv)
  3838 
  3839 lemma
  3840   assumes "finite A"
  3841   shows finite_lists_length_eq: "finite {xs. set xs \<subseteq> A \<and> length xs = n}"
  3842   and card_lists_length_eq: "card {xs. set xs \<subseteq> A \<and> length xs = n} = (card A)^n"
  3843   using `finite A`
  3844   by (induct n)
  3845      (auto simp: card_image inj_split_Cons lists_length_Suc_eq cong: conj_cong)
  3846 
  3847 lemma finite_lists_length_le:
  3848   assumes "finite A" shows "finite {xs. set xs \<subseteq> A \<and> length xs \<le> n}"
  3849  (is "finite ?S")
  3850 proof-
  3851   have "?S = (\<Union>n\<in>{0..n}. {xs. set xs \<subseteq> A \<and> length xs = n})" by auto
  3852   thus ?thesis by (auto intro: finite_lists_length_eq[OF `finite A`])
  3853 qed
  3854 
  3855 lemma card_lists_length_le:
  3856   assumes "finite A" shows "card {xs. set xs \<subseteq> A \<and> length xs \<le> n} = (\<Sum>i\<le>n. card A^i)"
  3857 proof -
  3858   have "(\<Sum>i\<le>n. card A^i) = card (\<Union>i\<le>n. {xs. set xs \<subseteq> A \<and> length xs = i})"
  3859     using `finite A`
  3860     by (subst card_UN_disjoint)
  3861        (auto simp add: card_lists_length_eq finite_lists_length_eq)
  3862   also have "(\<Union>i\<le>n. {xs. set xs \<subseteq> A \<and> length xs = i}) = {xs. set xs \<subseteq> A \<and> length xs \<le> n}"
  3863     by auto
  3864   finally show ?thesis by simp
  3865 qed
  3866 
  3867 lemma card_lists_distinct_length_eq:
  3868   assumes "k < card A"
  3869   shows "card {xs. length xs = k \<and> distinct xs \<and> set xs \<subseteq> A} = \<Prod>{card A - k + 1 .. card A}"
  3870 using assms
  3871 proof (induct k)
  3872   case 0
  3873   then have "{xs. length xs = 0 \<and> distinct xs \<and> set xs \<subseteq> A} = {[]}" by auto
  3874   then show ?case by simp
  3875 next
  3876   case (Suc k)
  3877   let "?k_list" = "\<lambda>k xs. length xs = k \<and> distinct xs \<and> set xs \<subseteq> A"
  3878   have inj_Cons: "\<And>A. inj_on (\<lambda>(xs, n). n # xs) A"  by (rule inj_onI) auto
  3879 
  3880   from Suc have "k < card A" by simp
  3881   moreover have "finite A" using assms by (simp add: card_ge_0_finite)
  3882   moreover have "finite {xs. ?k_list k xs}"
  3883     using finite_lists_length_eq[OF `finite A`, of k]
  3884     by - (rule finite_subset, auto)
  3885   moreover have "\<And>i j. i \<noteq> j \<longrightarrow> {i} \<times> (A - set i) \<inter> {j} \<times> (A - set j) = {}"
  3886     by auto
  3887   moreover have "\<And>i. i \<in>Collect (?k_list k) \<Longrightarrow> card (A - set i) = card A - k"
  3888     by (simp add: card_Diff_subset distinct_card)
  3889   moreover have "{xs. ?k_list (Suc k) xs} =
  3890       (\<lambda>(xs, n). n#xs) ` \<Union>(\<lambda>xs. {xs} \<times> (A - set xs)) ` {xs. ?k_list k xs}"
  3891     by (auto simp: length_Suc_conv)
  3892   moreover
  3893   have "Suc (card A - Suc k) = card A - k" using Suc.prems by simp
  3894   then have "(card A - k) * \<Prod>{Suc (card A - k)..card A} = \<Prod>{Suc (card A - Suc k)..card A}"
  3895     by (subst setprod_insert[symmetric]) (simp add: atLeastAtMost_insertL)+
  3896   ultimately show ?case
  3897     by (simp add: card_image inj_Cons card_UN_disjoint Suc.hyps algebra_simps)
  3898 qed
  3899 
  3900 lemma infinite_UNIV_listI: "~ finite(UNIV::'a list set)"
  3901 apply(rule notI)
  3902 apply(drule finite_maxlen)
  3903 apply (metis UNIV_I length_replicate less_not_refl)
  3904 done
  3905 
  3906 
  3907 subsection {* Sorting *}
  3908 
  3909 text{* Currently it is not shown that @{const sort} returns a
  3910 permutation of its input because the nicest proof is via multisets,
  3911 which are not yet available. Alternatively one could define a function
  3912 that counts the number of occurrences of an element in a list and use
  3913 that instead of multisets to state the correctness property. *}
  3914 
  3915 context linorder
  3916 begin
  3917 
  3918 lemma length_insort [simp]:
  3919   "length (insort_key f x xs) = Suc (length xs)"
  3920   by (induct xs) simp_all
  3921 
  3922 lemma insort_key_left_comm:
  3923   assumes "f x \<noteq> f y"
  3924   shows "insort_key f y (insort_key f x xs) = insort_key f x (insort_key f y xs)"
  3925   by (induct xs) (auto simp add: assms dest: antisym)
  3926 
  3927 lemma insort_left_comm:
  3928   "insort x (insort y xs) = insort y (insort x xs)"
  3929   by (cases "x = y") (auto intro: insort_key_left_comm)
  3930 
  3931 lemma comp_fun_commute_insort:
  3932   "comp_fun_commute insort"
  3933 proof
  3934 qed (simp add: insort_left_comm fun_eq_iff)
  3935 
  3936 lemma sort_key_simps [simp]:
  3937   "sort_key f [] = []"
  3938   "sort_key f (x#xs) = insort_key f x (sort_key f xs)"
  3939   by (simp_all add: sort_key_def)
  3940 
  3941 lemma (in linorder) sort_key_conv_fold:
  3942   assumes "inj_on f (set xs)"
  3943   shows "sort_key f xs = fold (insort_key f) xs []"
  3944 proof -
  3945   have "fold (insort_key f) (rev xs) = fold (insort_key f) xs"
  3946   proof (rule fold_rev, rule ext)
  3947     fix zs
  3948     fix x y
  3949     assume "x \<in> set xs" "y \<in> set xs"
  3950     with assms have *: "f y = f x \<Longrightarrow> y = x" by (auto dest: inj_onD)
  3951     have **: "x = y \<longleftrightarrow> y = x" by auto
  3952     show "(insort_key f y \<circ> insort_key f x) zs = (insort_key f x \<circ> insort_key f y) zs"
  3953       by (induct zs) (auto intro: * simp add: **)
  3954   qed
  3955   then show ?thesis by (simp add: sort_key_def foldr_def)
  3956 qed
  3957 
  3958 lemma (in linorder) sort_conv_fold:
  3959   "sort xs = fold insort xs []"
  3960   by (rule sort_key_conv_fold) simp
  3961 
  3962 lemma length_sort[simp]: "length (sort_key f xs) = length xs"
  3963 by (induct xs, auto)
  3964 
  3965 lemma sorted_Cons: "sorted (x#xs) = (sorted xs & (ALL y:set xs. x <= y))"
  3966 apply(induct xs arbitrary: x) apply simp
  3967 by simp (blast intro: order_trans)
  3968 
  3969 lemma sorted_tl:
  3970   "sorted xs \<Longrightarrow> sorted (tl xs)"
  3971   by (cases xs) (simp_all add: sorted_Cons)
  3972 
  3973 lemma sorted_append:
  3974   "sorted (xs@ys) = (sorted xs & sorted ys & (\<forall>x \<in> set xs. \<forall>y \<in> set ys. x\<le>y))"
  3975 by (induct xs) (auto simp add:sorted_Cons)
  3976 
  3977 lemma sorted_nth_mono:
  3978   "sorted xs \<Longrightarrow> i \<le> j \<Longrightarrow> j < length xs \<Longrightarrow> xs!i \<le> xs!j"
  3979 by (induct xs arbitrary: i j) (auto simp:nth_Cons' sorted_Cons)
  3980 
  3981 lemma sorted_rev_nth_mono:
  3982   "sorted (rev xs) \<Longrightarrow> i \<le> j \<Longrightarrow> j < length xs \<Longrightarrow> xs!j \<le> xs!i"
  3983 using sorted_nth_mono[ of "rev xs" "length xs - j - 1" "length xs - i - 1"]
  3984       rev_nth[of "length xs - i - 1" "xs"] rev_nth[of "length xs - j - 1" "xs"]
  3985 by auto
  3986 
  3987 lemma sorted_nth_monoI:
  3988   "(\<And> i j. \<lbrakk> i \<le> j ; j < length xs \<rbrakk> \<Longrightarrow> xs ! i \<le> xs ! j) \<Longrightarrow> sorted xs"
  3989 proof (induct xs)
  3990   case (Cons x xs)
  3991   have "sorted xs"
  3992   proof (rule Cons.hyps)
  3993     fix i j assume "i \<le> j" and "j < length xs"
  3994     with Cons.prems[of "Suc i" "Suc j"]
  3995     show "xs ! i \<le> xs ! j" by auto
  3996   qed
  3997   moreover
  3998   {
  3999     fix y assume "y \<in> set xs"
  4000     then obtain j where "j < length xs" and "xs ! j = y"
  4001       unfolding in_set_conv_nth by blast
  4002     with Cons.prems[of 0 "Suc j"]
  4003     have "x \<le> y"
  4004       by auto
  4005   }
  4006   ultimately
  4007   show ?case
  4008     unfolding sorted_Cons by auto
  4009 qed simp
  4010 
  4011 lemma sorted_equals_nth_mono:
  4012   "sorted xs = (\<forall>j < length xs. \<forall>i \<le> j. xs ! i \<le> xs ! j)"
  4013 by (auto intro: sorted_nth_monoI sorted_nth_mono)
  4014 
  4015 lemma set_insort: "set(insort_key f x xs) = insert x (set xs)"
  4016 by (induct xs) auto
  4017 
  4018 lemma set_sort[simp]: "set(sort_key f xs) = set xs"
  4019 by (induct xs) (simp_all add:set_insort)
  4020 
  4021 lemma distinct_insort: "distinct (insort_key f x xs) = (x \<notin> set xs \<and> distinct xs)"
  4022 by(induct xs)(auto simp:set_insort)
  4023 
  4024 lemma distinct_sort[simp]: "distinct (sort_key f xs) = distinct xs"
  4025   by (induct xs) (simp_all add: distinct_insort)
  4026 
  4027 lemma sorted_insort_key: "sorted (map f (insort_key f x xs)) = sorted (map f xs)"
  4028   by (induct xs) (auto simp:sorted_Cons set_insort)
  4029 
  4030 lemma sorted_insort: "sorted (insort x xs) = sorted xs"
  4031   using sorted_insort_key [where f="\<lambda>x. x"] by simp
  4032 
  4033 theorem sorted_sort_key [simp]: "sorted (map f (sort_key f xs))"
  4034   by (induct xs) (auto simp:sorted_insort_key)
  4035 
  4036 theorem sorted_sort [simp]: "sorted (sort xs)"
  4037   using sorted_sort_key [where f="\<lambda>x. x"] by simp
  4038 
  4039 lemma sorted_butlast:
  4040   assumes "xs \<noteq> []" and "sorted xs"
  4041   shows "sorted (butlast xs)"
  4042 proof -
  4043   from `xs \<noteq> []` obtain ys y where "xs = ys @ [y]" by (cases xs rule: rev_cases) auto
  4044   with `sorted xs` show ?thesis by (simp add: sorted_append)
  4045 qed
  4046   
  4047 lemma insort_not_Nil [simp]:
  4048   "insort_key f a xs \<noteq> []"
  4049   by (induct xs) simp_all
  4050 
  4051 lemma insort_is_Cons: "\<forall>x\<in>set xs. f a \<le> f x \<Longrightarrow> insort_key f a xs = a # xs"
  4052 by (cases xs) auto
  4053 
  4054 lemma sorted_sort_id: "sorted xs \<Longrightarrow> sort xs = xs"
  4055   by (induct xs) (auto simp add: sorted_Cons insort_is_Cons)
  4056 
  4057 lemma sorted_map_remove1:
  4058   "sorted (map f xs) \<Longrightarrow> sorted (map f (remove1 x xs))"
  4059   by (induct xs) (auto simp add: sorted_Cons)
  4060 
  4061 lemma sorted_remove1: "sorted xs \<Longrightarrow> sorted (remove1 a xs)"
  4062   using sorted_map_remove1 [of "\<lambda>x. x"] by simp
  4063 
  4064 lemma insort_key_remove1:
  4065   assumes "a \<in> set xs" and "sorted (map f xs)" and "hd (filter (\<lambda>x. f a = f x) xs) = a"
  4066   shows "insort_key f a (remove1 a xs) = xs"
  4067 using assms proof (induct xs)
  4068   case (Cons x xs)
  4069   then show ?case
  4070   proof (cases "x = a")
  4071     case False
  4072     then have "f x \<noteq> f a" using Cons.prems by auto
  4073     then have "f x < f a" using Cons.prems by (auto simp: sorted_Cons)
  4074     with `f x \<noteq> f a` show ?thesis using Cons by (auto simp: sorted_Cons insort_is_Cons)
  4075   qed (auto simp: sorted_Cons insort_is_Cons)
  4076 qed simp
  4077 
  4078 lemma insort_remove1:
  4079   assumes "a \<in> set xs" and "sorted xs"
  4080   shows "insort a (remove1 a xs) = xs"
  4081 proof (rule insort_key_remove1)
  4082   from `a \<in> set xs` show "a \<in> set xs" .
  4083   from `sorted xs` show "sorted (map (\<lambda>x. x) xs)" by simp
  4084   from `a \<in> set xs` have "a \<in> set (filter (op = a) xs)" by auto
  4085   then have "set (filter (op = a) xs) \<noteq> {}" by auto
  4086   then have "filter (op = a) xs \<noteq> []" by (auto simp only: set_empty)
  4087   then have "length (filter (op = a) xs) > 0" by simp
  4088   then obtain n where n: "Suc n = length (filter (op = a) xs)"
  4089     by (cases "length (filter (op = a) xs)") simp_all
  4090   moreover have "replicate (Suc n) a = a # replicate n a"
  4091     by simp
  4092   ultimately show "hd (filter (op = a) xs) = a" by (simp add: replicate_length_filter)
  4093 qed
  4094 
  4095 lemma sorted_remdups[simp]:
  4096   "sorted l \<Longrightarrow> sorted (remdups l)"
  4097 by (induct l) (auto simp: sorted_Cons)
  4098 
  4099 lemma sorted_distinct_set_unique:
  4100 assumes "sorted xs" "distinct xs" "sorted ys" "distinct ys" "set xs = set ys"
  4101 shows "xs = ys"
  4102 proof -
  4103   from assms have 1: "length xs = length ys" by (auto dest!: distinct_card)
  4104   from assms show ?thesis
  4105   proof(induct rule:list_induct2[OF 1])
  4106     case 1 show ?case by simp
  4107   next
  4108     case 2 thus ?case by (simp add:sorted_Cons)
  4109        (metis Diff_insert_absorb antisym insertE insert_iff)
  4110   qed
  4111 qed
  4112 
  4113 lemma map_sorted_distinct_set_unique:
  4114   assumes "inj_on f (set xs \<union> set ys)"
  4115   assumes "sorted (map f xs)" "distinct (map f xs)"
  4116     "sorted (map f ys)" "distinct (map f ys)"
  4117   assumes "set xs = set ys"
  4118   shows "xs = ys"
  4119 proof -
  4120   from assms have "map f xs = map f ys"
  4121     by (simp add: sorted_distinct_set_unique)
  4122   moreover with `inj_on f (set xs \<union> set ys)` show "xs = ys"
  4123     by (blast intro: map_inj_on)
  4124 qed
  4125 
  4126 lemma finite_sorted_distinct_unique:
  4127 shows "finite A \<Longrightarrow> EX! xs. set xs = A & sorted xs & distinct xs"
  4128 apply(drule finite_distinct_list)
  4129 apply clarify
  4130 apply(rule_tac a="sort xs" in ex1I)
  4131 apply (auto simp: sorted_distinct_set_unique)
  4132 done
  4133 
  4134 lemma
  4135   assumes "sorted xs"
  4136   shows sorted_take: "sorted (take n xs)"
  4137   and sorted_drop: "sorted (drop n xs)"
  4138 proof -
  4139   from assms have "sorted (take n xs @ drop n xs)" by simp
  4140   then show "sorted (take n xs)" and "sorted (drop n xs)"
  4141     unfolding sorted_append by simp_all
  4142 qed
  4143 
  4144 lemma sorted_dropWhile: "sorted xs \<Longrightarrow> sorted (dropWhile P xs)"
  4145   by (auto dest: sorted_drop simp add: dropWhile_eq_drop)
  4146 
  4147 lemma sorted_takeWhile: "sorted xs \<Longrightarrow> sorted (takeWhile P xs)"
  4148   by (subst takeWhile_eq_take) (auto dest: sorted_take)
  4149 
  4150 lemma sorted_filter:
  4151   "sorted (map f xs) \<Longrightarrow> sorted (map f (filter P xs))"
  4152   by (induct xs) (simp_all add: sorted_Cons)
  4153 
  4154 lemma foldr_max_sorted:
  4155   assumes "sorted (rev xs)"
  4156   shows "foldr max xs y = (if xs = [] then y else max (xs ! 0) y)"
  4157 using assms proof (induct xs)
  4158   case (Cons x xs)
  4159   moreover hence "sorted (rev xs)" using sorted_append by auto
  4160   ultimately show ?case
  4161     by (cases xs, auto simp add: sorted_append max_def)
  4162 qed simp
  4163 
  4164 lemma filter_equals_takeWhile_sorted_rev:
  4165   assumes sorted: "sorted (rev (map f xs))"
  4166   shows "[x \<leftarrow> xs. t < f x] = takeWhile (\<lambda> x. t < f x) xs"
  4167     (is "filter ?P xs = ?tW")
  4168 proof (rule takeWhile_eq_filter[symmetric])
  4169   let "?dW" = "dropWhile ?P xs"
  4170   fix x assume "x \<in> set ?dW"
  4171   then obtain i where i: "i < length ?dW" and nth_i: "x = ?dW ! i"
  4172     unfolding in_set_conv_nth by auto
  4173   hence "length ?tW + i < length (?tW @ ?dW)"
  4174     unfolding length_append by simp
  4175   hence i': "length (map f ?tW) + i < length (map f xs)" by simp
  4176   have "(map f ?tW @ map f ?dW) ! (length (map f ?tW) + i) \<le>
  4177         (map f ?tW @ map f ?dW) ! (length (map f ?tW) + 0)"
  4178     using sorted_rev_nth_mono[OF sorted _ i', of "length ?tW"]
  4179     unfolding map_append[symmetric] by simp
  4180   hence "f x \<le> f (?dW ! 0)"
  4181     unfolding nth_append_length_plus nth_i
  4182     using i preorder_class.le_less_trans[OF le0 i] by simp
  4183   also have "... \<le> t"
  4184     using hd_dropWhile[of "?P" xs] le0[THEN preorder_class.le_less_trans, OF i]
  4185     using hd_conv_nth[of "?dW"] by simp
  4186   finally show "\<not> t < f x" by simp
  4187 qed
  4188 
  4189 lemma insort_insert_key_triv:
  4190   "f x \<in> f ` set xs \<Longrightarrow> insort_insert_key f x xs = xs"
  4191   by (simp add: insort_insert_key_def)
  4192 
  4193 lemma insort_insert_triv:
  4194   "x \<in> set xs \<Longrightarrow> insort_insert x xs = xs"
  4195   using insort_insert_key_triv [of "\<lambda>x. x"] by simp
  4196 
  4197 lemma insort_insert_insort_key:
  4198   "f x \<notin> f ` set xs \<Longrightarrow> insort_insert_key f x xs = insort_key f x xs"
  4199   by (simp add: insort_insert_key_def)
  4200 
  4201 lemma insort_insert_insort:
  4202   "x \<notin> set xs \<Longrightarrow> insort_insert x xs = insort x xs"
  4203   using insort_insert_insort_key [of "\<lambda>x. x"] by simp
  4204 
  4205 lemma set_insort_insert:
  4206   "set (insort_insert x xs) = insert x (set xs)"
  4207   by (auto simp add: insort_insert_key_def set_insort)
  4208 
  4209 lemma distinct_insort_insert:
  4210   assumes "distinct xs"
  4211   shows "distinct (insort_insert_key f x xs)"
  4212   using assms by (induct xs) (auto simp add: insort_insert_key_def set_insort)
  4213 
  4214 lemma sorted_insort_insert_key:
  4215   assumes "sorted (map f xs)"
  4216   shows "sorted (map f (insort_insert_key f x xs))"
  4217   using assms by (simp add: insort_insert_key_def sorted_insort_key)
  4218 
  4219 lemma sorted_insort_insert:
  4220   assumes "sorted xs"
  4221   shows "sorted (insort_insert x xs)"
  4222   using assms sorted_insort_insert_key [of "\<lambda>x. x"] by simp
  4223 
  4224 lemma filter_insort_triv:
  4225   "\<not> P x \<Longrightarrow> filter P (insort_key f x xs) = filter P xs"
  4226   by (induct xs) simp_all
  4227 
  4228 lemma filter_insort:
  4229   "sorted (map f xs) \<Longrightarrow> P x \<Longrightarrow> filter P (insort_key f x xs) = insort_key f x (filter P xs)"
  4230   using assms by (induct xs)
  4231     (auto simp add: sorted_Cons, subst insort_is_Cons, auto)
  4232 
  4233 lemma filter_sort:
  4234   "filter P (sort_key f xs) = sort_key f (filter P xs)"
  4235   by (induct xs) (simp_all add: filter_insort_triv filter_insort)
  4236 
  4237 lemma sorted_map_same:
  4238   "sorted (map f [x\<leftarrow>xs. f x = g xs])"
  4239 proof (induct xs arbitrary: g)
  4240   case Nil then show ?case by simp
  4241 next
  4242   case (Cons x xs)
  4243   then have "sorted (map f [y\<leftarrow>xs . f y = (\<lambda>xs. f x) xs])" .
  4244   moreover from Cons have "sorted (map f [y\<leftarrow>xs . f y = (g \<circ> Cons x) xs])" .
  4245   ultimately show ?case by (simp_all add: sorted_Cons)
  4246 qed
  4247 
  4248 lemma sorted_same:
  4249   "sorted [x\<leftarrow>xs. x = g xs]"
  4250   using sorted_map_same [of "\<lambda>x. x"] by simp
  4251 
  4252 lemma remove1_insort [simp]:
  4253   "remove1 x (insort x xs) = xs"
  4254   by (induct xs) simp_all
  4255 
  4256 end
  4257 
  4258 lemma sorted_upt[simp]: "sorted[i..<j]"
  4259 by (induct j) (simp_all add:sorted_append)
  4260 
  4261 lemma sorted_upto[simp]: "sorted[i..j]"
  4262 apply(induct i j rule:upto.induct)
  4263 apply(subst upto.simps)
  4264 apply(simp add:sorted_Cons)
  4265 done
  4266 
  4267 
  4268 subsubsection {* @{const transpose} on sorted lists *}
  4269 
  4270 lemma sorted_transpose[simp]:
  4271   shows "sorted (rev (map length (transpose xs)))"
  4272   by (auto simp: sorted_equals_nth_mono rev_nth nth_transpose
  4273     length_filter_conv_card intro: card_mono)
  4274 
  4275 lemma transpose_max_length:
  4276   "foldr (\<lambda>xs. max (length xs)) (transpose xs) 0 = length [x \<leftarrow> xs. x \<noteq> []]"
  4277   (is "?L = ?R")
  4278 proof (cases "transpose xs = []")
  4279   case False
  4280   have "?L = foldr max (map length (transpose xs)) 0"
  4281     by (simp add: foldr_map comp_def)
  4282   also have "... = length (transpose xs ! 0)"
  4283     using False sorted_transpose by (simp add: foldr_max_sorted)
  4284   finally show ?thesis
  4285     using False by (simp add: nth_transpose)
  4286 next
  4287   case True
  4288   hence "[x \<leftarrow> xs. x \<noteq> []] = []"
  4289     by (auto intro!: filter_False simp: transpose_empty)
  4290   thus ?thesis by (simp add: transpose_empty True)
  4291 qed
  4292 
  4293 lemma length_transpose_sorted:
  4294   fixes xs :: "'a list list"
  4295   assumes sorted: "sorted (rev (map length xs))"
  4296   shows "length (transpose xs) = (if xs = [] then 0 else length (xs ! 0))"
  4297 proof (cases "xs = []")
  4298   case False
  4299   thus ?thesis
  4300     using foldr_max_sorted[OF sorted] False
  4301     unfolding length_transpose foldr_map comp_def
  4302     by simp
  4303 qed simp
  4304 
  4305 lemma nth_nth_transpose_sorted[simp]:
  4306   fixes xs :: "'a list list"
  4307   assumes sorted: "sorted (rev (map length xs))"
  4308   and i: "i < length (transpose xs)"
  4309   and j: "j < length [ys \<leftarrow> xs. i < length ys]"
  4310   shows "transpose xs ! i ! j = xs ! j  ! i"
  4311   using j filter_equals_takeWhile_sorted_rev[OF sorted, of i]
  4312     nth_transpose[OF i] nth_map[OF j]
  4313   by (simp add: takeWhile_nth)
  4314 
  4315 lemma transpose_column_length:
  4316   fixes xs :: "'a list list"
  4317   assumes sorted: "sorted (rev (map length xs))" and "i < length xs"
  4318   shows "length (filter (\<lambda>ys. i < length ys) (transpose xs)) = length (xs ! i)"
  4319 proof -
  4320   have "xs \<noteq> []" using `i < length xs` by auto
  4321   note filter_equals_takeWhile_sorted_rev[OF sorted, simp]
  4322   { fix j assume "j \<le> i"
  4323     note sorted_rev_nth_mono[OF sorted, of j i, simplified, OF this `i < length xs`]
  4324   } note sortedE = this[consumes 1]
  4325 
  4326   have "{j. j < length (transpose xs) \<and> i < length (transpose xs ! j)}
  4327     = {..< length (xs ! i)}"
  4328   proof safe
  4329     fix j
  4330     assume "j < length (transpose xs)" and "i < length (transpose xs ! j)"
  4331     with this(2) nth_transpose[OF this(1)]
  4332     have "i < length (takeWhile (\<lambda>ys. j < length ys) xs)" by simp
  4333     from nth_mem[OF this] takeWhile_nth[OF this]
  4334     show "j < length (xs ! i)" by (auto dest: set_takeWhileD)
  4335   next
  4336     fix j assume "j < length (xs ! i)"
  4337     thus "j < length (transpose xs)"
  4338       using foldr_max_sorted[OF sorted] `xs \<noteq> []` sortedE[OF le0]
  4339       by (auto simp: length_transpose comp_def foldr_map)
  4340 
  4341     have "Suc i \<le> length (takeWhile (\<lambda>ys. j < length ys) xs)"
  4342       using `i < length xs` `j < length (xs ! i)` less_Suc_eq_le
  4343       by (auto intro!: length_takeWhile_less_P_nth dest!: sortedE)
  4344     with nth_transpose[OF `j < length (transpose xs)`]
  4345     show "i < length (transpose xs ! j)" by simp
  4346   qed
  4347   thus ?thesis by (simp add: length_filter_conv_card)
  4348 qed
  4349 
  4350 lemma transpose_column:
  4351   fixes xs :: "'a list list"
  4352   assumes sorted: "sorted (rev (map length xs))" and "i < length xs"
  4353   shows "map (\<lambda>ys. ys ! i) (filter (\<lambda>ys. i < length ys) (transpose xs))
  4354     = xs ! i" (is "?R = _")
  4355 proof (rule nth_equalityI, safe)
  4356   show length: "length ?R = length (xs ! i)"
  4357     using transpose_column_length[OF assms] by simp
  4358 
  4359   fix j assume j: "j < length ?R"
  4360   note * = less_le_trans[OF this, unfolded length_map, OF length_filter_le]
  4361   from j have j_less: "j < length (xs ! i)" using length by simp
  4362   have i_less_tW: "Suc i \<le> length (takeWhile (\<lambda>ys. Suc j \<le> length ys) xs)"
  4363   proof (rule length_takeWhile_less_P_nth)
  4364     show "Suc i \<le> length xs" using `i < length xs` by simp
  4365     fix k assume "k < Suc i"
  4366     hence "k \<le> i" by auto
  4367     with sorted_rev_nth_mono[OF sorted this] `i < length xs`
  4368     have "length (xs ! i) \<le> length (xs ! k)" by simp
  4369     thus "Suc j \<le> length (xs ! k)" using j_less by simp
  4370   qed
  4371   have i_less_filter: "i < length [ys\<leftarrow>xs . j < length ys]"
  4372     unfolding filter_equals_takeWhile_sorted_rev[OF sorted, of j]
  4373     using i_less_tW by (simp_all add: Suc_le_eq)
  4374   from j show "?R ! j = xs ! i ! j"
  4375     unfolding filter_equals_takeWhile_sorted_rev[OF sorted_transpose, of i]
  4376     by (simp add: takeWhile_nth nth_nth_transpose_sorted[OF sorted * i_less_filter])
  4377 qed
  4378 
  4379 lemma transpose_transpose:
  4380   fixes xs :: "'a list list"
  4381   assumes sorted: "sorted (rev (map length xs))"
  4382   shows "transpose (transpose xs) = takeWhile (\<lambda>x. x \<noteq> []) xs" (is "?L = ?R")
  4383 proof -
  4384   have len: "length ?L = length ?R"
  4385     unfolding length_transpose transpose_max_length
  4386     using filter_equals_takeWhile_sorted_rev[OF sorted, of 0]
  4387     by simp
  4388 
  4389   { fix i assume "i < length ?R"
  4390     with less_le_trans[OF _ length_takeWhile_le[of _ xs]]
  4391     have "i < length xs" by simp
  4392   } note * = this
  4393   show ?thesis
  4394     by (rule nth_equalityI)
  4395        (simp_all add: len nth_transpose transpose_column[OF sorted] * takeWhile_nth)
  4396 qed
  4397 
  4398 theorem transpose_rectangle:
  4399   assumes "xs = [] \<Longrightarrow> n = 0"
  4400   assumes rect: "\<And> i. i < length xs \<Longrightarrow> length (xs ! i) = n"
  4401   shows "transpose xs = map (\<lambda> i. map (\<lambda> j. xs ! j ! i) [0..<length xs]) [0..<n]"
  4402     (is "?trans = ?map")
  4403 proof (rule nth_equalityI)
  4404   have "sorted (rev (map length xs))"
  4405     by (auto simp: rev_nth rect intro!: sorted_nth_monoI)
  4406   from foldr_max_sorted[OF this] assms
  4407   show len: "length ?trans = length ?map"
  4408     by (simp_all add: length_transpose foldr_map comp_def)
  4409   moreover
  4410   { fix i assume "i < n" hence "[ys\<leftarrow>xs . i < length ys] = xs"
  4411       using rect by (auto simp: in_set_conv_nth intro!: filter_True) }
  4412   ultimately show "\<forall>i < length ?trans. ?trans ! i = ?map ! i"
  4413     by (auto simp: nth_transpose intro: nth_equalityI)
  4414 qed
  4415 
  4416 
  4417 subsubsection {* @{text sorted_list_of_set} *}
  4418 
  4419 text{* This function maps (finite) linearly ordered sets to sorted
  4420 lists. Warning: in most cases it is not a good idea to convert from
  4421 sets to lists but one should convert in the other direction (via
  4422 @{const set}). *}
  4423 
  4424 context linorder
  4425 begin
  4426 
  4427 definition sorted_list_of_set :: "'a set \<Rightarrow> 'a list" where
  4428   "sorted_list_of_set = Finite_Set.fold insort []"
  4429 
  4430 lemma sorted_list_of_set_empty [simp]:
  4431   "sorted_list_of_set {} = []"
  4432   by (simp add: sorted_list_of_set_def)
  4433 
  4434 lemma sorted_list_of_set_insert [simp]:
  4435   assumes "finite A"
  4436   shows "sorted_list_of_set (insert x A) = insort x (sorted_list_of_set (A - {x}))"
  4437 proof -
  4438   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  4439   with assms show ?thesis by (simp add: sorted_list_of_set_def fold_insert_remove)
  4440 qed
  4441 
  4442 lemma sorted_list_of_set [simp]:
  4443   "finite A \<Longrightarrow> set (sorted_list_of_set A) = A \<and> sorted (sorted_list_of_set A) 
  4444     \<and> distinct (sorted_list_of_set A)"
  4445   by (induct A rule: finite_induct) (simp_all add: set_insort sorted_insort distinct_insort)
  4446 
  4447 lemma sorted_list_of_set_sort_remdups:
  4448   "sorted_list_of_set (set xs) = sort (remdups xs)"
  4449 proof -
  4450   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  4451   show ?thesis by (simp add: sorted_list_of_set_def sort_conv_fold fold_set_fold_remdups)
  4452 qed
  4453 
  4454 lemma sorted_list_of_set_remove:
  4455   assumes "finite A"
  4456   shows "sorted_list_of_set (A - {x}) = remove1 x (sorted_list_of_set A)"
  4457 proof (cases "x \<in> A")
  4458   case False with assms have "x \<notin> set (sorted_list_of_set A)" by simp
  4459   with False show ?thesis by (simp add: remove1_idem)
  4460 next
  4461   case True then obtain B where A: "A = insert x B" by (rule Set.set_insert)
  4462   with assms show ?thesis by simp
  4463 qed
  4464 
  4465 end
  4466 
  4467 lemma sorted_list_of_set_range [simp]:
  4468   "sorted_list_of_set {m..<n} = [m..<n]"
  4469   by (rule sorted_distinct_set_unique) simp_all
  4470 
  4471 
  4472 subsubsection {* @{text lists}: the list-forming operator over sets *}
  4473 
  4474 inductive_set
  4475   lists :: "'a set => 'a list set"
  4476   for A :: "'a set"
  4477 where
  4478     Nil [intro!, simp]: "[]: lists A"
  4479   | Cons [intro!, simp, no_atp]: "[| a: A; l: lists A|] ==> a#l : lists A"
  4480 
  4481 inductive_cases listsE [elim!,no_atp]: "x#l : lists A"
  4482 inductive_cases listspE [elim!,no_atp]: "listsp A (x # l)"
  4483 
  4484 lemma listsp_mono [mono]: "A \<le> B ==> listsp A \<le> listsp B"
  4485 by (rule predicate1I, erule listsp.induct, (blast dest: predicate1D)+)
  4486 
  4487 lemmas lists_mono = listsp_mono [to_set pred_subset_eq]
  4488 
  4489 lemma listsp_infI:
  4490   assumes l: "listsp A l" shows "listsp B l ==> listsp (inf A B) l" using l
  4491 by induct blast+
  4492 
  4493 lemmas lists_IntI = listsp_infI [to_set]
  4494 
  4495 lemma listsp_inf_eq [simp]: "listsp (inf A B) = inf (listsp A) (listsp B)"
  4496 proof (rule mono_inf [where f=listsp, THEN order_antisym])
  4497   show "mono listsp" by (simp add: mono_def listsp_mono)
  4498   show "inf (listsp A) (listsp B) \<le> listsp (inf A B)" by (blast intro!: listsp_infI predicate1I)
  4499 qed
  4500 
  4501 lemmas listsp_conj_eq [simp] = listsp_inf_eq [simplified inf_fun_def inf_bool_def]
  4502 
  4503 lemmas lists_Int_eq [simp] = listsp_inf_eq [to_set pred_equals_eq]
  4504 
  4505 lemma Cons_in_lists_iff[simp]: "x#xs : lists A \<longleftrightarrow> x:A \<and> xs : lists A"
  4506 by auto
  4507 
  4508 lemma append_in_listsp_conv [iff]:
  4509      "(listsp A (xs @ ys)) = (listsp A xs \<and> listsp A ys)"
  4510 by (induct xs) auto
  4511 
  4512 lemmas append_in_lists_conv [iff] = append_in_listsp_conv [to_set]
  4513 
  4514 lemma in_listsp_conv_set: "(listsp A xs) = (\<forall>x \<in> set xs. A x)"
  4515 -- {* eliminate @{text listsp} in favour of @{text set} *}
  4516 by (induct xs) auto
  4517 
  4518 lemmas in_lists_conv_set = in_listsp_conv_set [to_set]
  4519 
  4520 lemma in_listspD [dest!,no_atp]: "listsp A xs ==> \<forall>x\<in>set xs. A x"
  4521 by (rule in_listsp_conv_set [THEN iffD1])
  4522 
  4523 lemmas in_listsD [dest!,no_atp] = in_listspD [to_set]
  4524 
  4525 lemma in_listspI [intro!,no_atp]: "\<forall>x\<in>set xs. A x ==> listsp A xs"
  4526 by (rule in_listsp_conv_set [THEN iffD2])
  4527 
  4528 lemmas in_listsI [intro!,no_atp] = in_listspI [to_set]
  4529 
  4530 lemma lists_eq_set: "lists A = {xs. set xs <= A}"
  4531 by auto
  4532 
  4533 lemma lists_empty [simp]: "lists {} = {[]}"
  4534 by auto
  4535 
  4536 lemma lists_UNIV [simp]: "lists UNIV = UNIV"
  4537 by auto
  4538 
  4539 
  4540 subsubsection {* Inductive definition for membership *}
  4541 
  4542 inductive ListMem :: "'a \<Rightarrow> 'a list \<Rightarrow> bool"
  4543 where
  4544     elem:  "ListMem x (x # xs)"
  4545   | insert:  "ListMem x xs \<Longrightarrow> ListMem x (y # xs)"
  4546 
  4547 lemma ListMem_iff: "(ListMem x xs) = (x \<in> set xs)"
  4548 apply (rule iffI)
  4549  apply (induct set: ListMem)
  4550   apply auto
  4551 apply (induct xs)
  4552  apply (auto intro: ListMem.intros)
  4553 done
  4554 
  4555 
  4556 subsubsection {* Lists as Cartesian products *}
  4557 
  4558 text{*@{text"set_Cons A Xs"}: the set of lists with head drawn from
  4559 @{term A} and tail drawn from @{term Xs}.*}
  4560 
  4561 definition
  4562   set_Cons :: "'a set \<Rightarrow> 'a list set \<Rightarrow> 'a list set" where
  4563   "set_Cons A XS = {z. \<exists>x xs. z = x # xs \<and> x \<in> A \<and> xs \<in> XS}"
  4564 
  4565 lemma set_Cons_sing_Nil [simp]: "set_Cons A {[]} = (%x. [x])`A"
  4566 by (auto simp add: set_Cons_def)
  4567 
  4568 text{*Yields the set of lists, all of the same length as the argument and
  4569 with elements drawn from the corresponding element of the argument.*}
  4570 
  4571 primrec
  4572   listset :: "'a set list \<Rightarrow> 'a list set" where
  4573      "listset [] = {[]}"
  4574   |  "listset (A # As) = set_Cons A (listset As)"
  4575 
  4576 
  4577 subsection {* Relations on Lists *}
  4578 
  4579 subsubsection {* Length Lexicographic Ordering *}
  4580 
  4581 text{*These orderings preserve well-foundedness: shorter lists 
  4582   precede longer lists. These ordering are not used in dictionaries.*}
  4583         
  4584 primrec -- {*The lexicographic ordering for lists of the specified length*}
  4585   lexn :: "('a \<times> 'a) set \<Rightarrow> nat \<Rightarrow> ('a list \<times> 'a list) set" where
  4586     "lexn r 0 = {}"
  4587   | "lexn r (Suc n) = (map_pair (%(x, xs). x#xs) (%(x, xs). x#xs) ` (r <*lex*> lexn r n)) Int
  4588       {(xs, ys). length xs = Suc n \<and> length ys = Suc n}"
  4589 
  4590 definition
  4591   lex :: "('a \<times> 'a) set \<Rightarrow> ('a list \<times> 'a list) set" where
  4592   "lex r = (\<Union>n. lexn r n)" -- {*Holds only between lists of the same length*}
  4593 
  4594 definition
  4595   lenlex :: "('a \<times> 'a) set => ('a list \<times> 'a list) set" where
  4596   "lenlex r = inv_image (less_than <*lex*> lex r) (\<lambda>xs. (length xs, xs))"
  4597         -- {*Compares lists by their length and then lexicographically*}
  4598 
  4599 lemma wf_lexn: "wf r ==> wf (lexn r n)"
  4600 apply (induct n, simp, simp)
  4601 apply(rule wf_subset)
  4602  prefer 2 apply (rule Int_lower1)
  4603 apply(rule wf_map_pair_image)
  4604  prefer 2 apply (rule inj_onI, auto)
  4605 done
  4606 
  4607 lemma lexn_length:
  4608   "(xs, ys) : lexn r n ==> length xs = n \<and> length ys = n"
  4609 by (induct n arbitrary: xs ys) auto
  4610 
  4611 lemma wf_lex [intro!]: "wf r ==> wf (lex r)"
  4612 apply (unfold lex_def)
  4613 apply (rule wf_UN)
  4614 apply (blast intro: wf_lexn, clarify)
  4615 apply (rename_tac m n)
  4616 apply (subgoal_tac "m \<noteq> n")
  4617  prefer 2 apply blast
  4618 apply (blast dest: lexn_length not_sym)
  4619 done
  4620 
  4621 lemma lexn_conv:
  4622   "lexn r n =
  4623     {(xs,ys). length xs = n \<and> length ys = n \<and>
  4624     (\<exists>xys x y xs' ys'. xs= xys @ x#xs' \<and> ys= xys @ y # ys' \<and> (x, y):r)}"
  4625 apply (induct n, simp)
  4626 apply (simp add: image_Collect lex_prod_def, safe, blast)
  4627  apply (rule_tac x = "ab # xys" in exI, simp)
  4628 apply (case_tac xys, simp_all, blast)
  4629 done
  4630 
  4631 lemma lex_conv:
  4632   "lex r =
  4633     {(xs,ys). length xs = length ys \<and>
  4634     (\<exists>xys x y xs' ys'. xs = xys @ x # xs' \<and> ys = xys @ y # ys' \<and> (x, y):r)}"
  4635 by (force simp add: lex_def lexn_conv)
  4636 
  4637 lemma wf_lenlex [intro!]: "wf r ==> wf (lenlex r)"
  4638 by (unfold lenlex_def) blast
  4639 
  4640 lemma lenlex_conv:
  4641     "lenlex r = {(xs,ys). length xs < length ys |
  4642                  length xs = length ys \<and> (xs, ys) : lex r}"
  4643 by (simp add: lenlex_def Id_on_def lex_prod_def inv_image_def)
  4644 
  4645 lemma Nil_notin_lex [iff]: "([], ys) \<notin> lex r"
  4646 by (simp add: lex_conv)
  4647 
  4648 lemma Nil2_notin_lex [iff]: "(xs, []) \<notin> lex r"
  4649 by (simp add:lex_conv)
  4650 
  4651 lemma Cons_in_lex [simp]:
  4652     "((x # xs, y # ys) : lex r) =
  4653       ((x, y) : r \<and> length xs = length ys | x = y \<and> (xs, ys) : lex r)"
  4654 apply (simp add: lex_conv)
  4655 apply (rule iffI)
  4656  prefer 2 apply (blast intro: Cons_eq_appendI, clarify)
  4657 apply (case_tac xys, simp, simp)
  4658 apply blast
  4659 done
  4660 
  4661 
  4662 subsubsection {* Lexicographic Ordering *}
  4663 
  4664 text {* Classical lexicographic ordering on lists, ie. "a" < "ab" < "b".
  4665     This ordering does \emph{not} preserve well-foundedness.
  4666      Author: N. Voelker, March 2005. *} 
  4667 
  4668 definition
  4669   lexord :: "('a \<times> 'a) set \<Rightarrow> ('a list \<times> 'a list) set" where
  4670   "lexord r = {(x,y ). \<exists> a v. y = x @ a # v \<or>
  4671             (\<exists> u a b v w. (a,b) \<in> r \<and> x = u @ (a # v) \<and> y = u @ (b # w))}"
  4672 
  4673 lemma lexord_Nil_left[simp]:  "([],y) \<in> lexord r = (\<exists> a x. y = a # x)"
  4674 by (unfold lexord_def, induct_tac y, auto) 
  4675 
  4676 lemma lexord_Nil_right[simp]: "(x,[]) \<notin> lexord r"
  4677 by (unfold lexord_def, induct_tac x, auto)
  4678 
  4679 lemma lexord_cons_cons[simp]:
  4680      "((a # x, b # y) \<in> lexord r) = ((a,b)\<in> r | (a = b & (x,y)\<in> lexord r))"
  4681   apply (unfold lexord_def, safe, simp_all)
  4682   apply (case_tac u, simp, simp)
  4683   apply (case_tac u, simp, clarsimp, blast, blast, clarsimp)
  4684   apply (erule_tac x="b # u" in allE)
  4685   by force
  4686 
  4687 lemmas lexord_simps = lexord_Nil_left lexord_Nil_right lexord_cons_cons
  4688 
  4689 lemma lexord_append_rightI: "\<exists> b z. y = b # z \<Longrightarrow> (x, x @ y) \<in> lexord r"
  4690 by (induct_tac x, auto)  
  4691 
  4692 lemma lexord_append_left_rightI:
  4693      "(a,b) \<in> r \<Longrightarrow> (u @ a # x, u @ b # y) \<in> lexord r"
  4694 by (induct_tac u, auto)
  4695 
  4696 lemma lexord_append_leftI: " (u,v) \<in> lexord r \<Longrightarrow> (x @ u, x @ v) \<in> lexord r"
  4697 by (induct x, auto)
  4698 
  4699 lemma lexord_append_leftD:
  4700      "\<lbrakk> (x @ u, x @ v) \<in> lexord r; (! a. (a,a) \<notin> r) \<rbrakk> \<Longrightarrow> (u,v) \<in> lexord r"
  4701 by (erule rev_mp, induct_tac x, auto)
  4702 
  4703 lemma lexord_take_index_conv: 
  4704    "((x,y) : lexord r) = 
  4705     ((length x < length y \<and> take (length x) y = x) \<or> 
  4706      (\<exists>i. i < min(length x)(length y) & take i x = take i y & (x!i,y!i) \<in> r))"
  4707   apply (unfold lexord_def Let_def, clarsimp) 
  4708   apply (rule_tac f = "(% a b. a \<or> b)" in arg_cong2)
  4709   apply auto 
  4710   apply (rule_tac x="hd (drop (length x) y)" in exI)
  4711   apply (rule_tac x="tl (drop (length x) y)" in exI)
  4712   apply (erule subst, simp add: min_def) 
  4713   apply (rule_tac x ="length u" in exI, simp) 
  4714   apply (rule_tac x ="take i x" in exI) 
  4715   apply (rule_tac x ="x ! i" in exI) 
  4716   apply (rule_tac x ="y ! i" in exI, safe) 
  4717   apply (rule_tac x="drop (Suc i) x" in exI)
  4718   apply (drule sym, simp add: drop_Suc_conv_tl) 
  4719   apply (rule_tac x="drop (Suc i) y" in exI)
  4720   by (simp add: drop_Suc_conv_tl) 
  4721 
  4722 -- {* lexord is extension of partial ordering List.lex *} 
  4723 lemma lexord_lex: "(x,y) \<in> lex r = ((x,y) \<in> lexord r \<and> length x = length y)"
  4724   apply (rule_tac x = y in spec) 
  4725   apply (induct_tac x, clarsimp) 
  4726   by (clarify, case_tac x, simp, force)
  4727 
  4728 lemma lexord_irreflexive: "ALL x. (x,x) \<notin> r \<Longrightarrow> (xs,xs) \<notin> lexord r"
  4729 by (induct xs) auto
  4730 
  4731 text{* By Ren\'e Thiemann: *}
  4732 lemma lexord_partial_trans: 
  4733   "(\<And>x y z. x \<in> set xs \<Longrightarrow> (x,y) \<in> r \<Longrightarrow> (y,z) \<in> r \<Longrightarrow> (x,z) \<in> r)
  4734    \<Longrightarrow>  (xs,ys) \<in> lexord r  \<Longrightarrow>  (ys,zs) \<in> lexord r \<Longrightarrow>  (xs,zs) \<in> lexord r"
  4735 proof (induct xs arbitrary: ys zs)
  4736   case Nil
  4737   from Nil(3) show ?case unfolding lexord_def by (cases zs, auto)
  4738 next
  4739   case (Cons x xs yys zzs)
  4740   from Cons(3) obtain y ys where yys: "yys = y # ys" unfolding lexord_def
  4741     by (cases yys, auto)
  4742   note Cons = Cons[unfolded yys]
  4743   from Cons(3) have one: "(x,y) \<in> r \<or> x = y \<and> (xs,ys) \<in> lexord r" by auto
  4744   from Cons(4) obtain z zs where zzs: "zzs = z # zs" unfolding lexord_def
  4745     by (cases zzs, auto)
  4746   note Cons = Cons[unfolded zzs]
  4747   from Cons(4) have two: "(y,z) \<in> r \<or> y = z \<and> (ys,zs) \<in> lexord r" by auto
  4748   {
  4749     assume "(xs,ys) \<in> lexord r" and "(ys,zs) \<in> lexord r"
  4750     from Cons(1)[OF _ this] Cons(2)
  4751     have "(xs,zs) \<in> lexord r" by auto
  4752   } note ind1 = this
  4753   {
  4754     assume "(x,y) \<in> r" and "(y,z) \<in> r"
  4755     from Cons(2)[OF _ this] have "(x,z) \<in> r" by auto
  4756   } note ind2 = this
  4757   from one two ind1 ind2
  4758   have "(x,z) \<in> r \<or> x = z \<and> (xs,zs) \<in> lexord r" by blast
  4759   thus ?case unfolding zzs by auto
  4760 qed
  4761 
  4762 lemma lexord_trans: 
  4763     "\<lbrakk> (x, y) \<in> lexord r; (y, z) \<in> lexord r; trans r \<rbrakk> \<Longrightarrow> (x, z) \<in> lexord r"
  4764 by(auto simp: trans_def intro:lexord_partial_trans)
  4765 
  4766 lemma lexord_transI:  "trans r \<Longrightarrow> trans (lexord r)"
  4767 by (rule transI, drule lexord_trans, blast) 
  4768 
  4769 lemma lexord_linear: "(! a b. (a,b)\<in> r | a = b | (b,a) \<in> r) \<Longrightarrow> (x,y) : lexord r | x = y | (y,x) : lexord r"
  4770   apply (rule_tac x = y in spec) 
  4771   apply (induct_tac x, rule allI) 
  4772   apply (case_tac x, simp, simp) 
  4773   apply (rule allI, case_tac x, simp, simp) 
  4774   by blast
  4775 
  4776 
  4777 subsubsection {* Lexicographic combination of measure functions *}
  4778 
  4779 text {* These are useful for termination proofs *}
  4780 
  4781 definition
  4782   "measures fs = inv_image (lex less_than) (%a. map (%f. f a) fs)"
  4783 
  4784 lemma wf_measures[simp]: "wf (measures fs)"
  4785 unfolding measures_def
  4786 by blast
  4787 
  4788 lemma in_measures[simp]: 
  4789   "(x, y) \<in> measures [] = False"
  4790   "(x, y) \<in> measures (f # fs)
  4791          = (f x < f y \<or> (f x = f y \<and> (x, y) \<in> measures fs))"  
  4792 unfolding measures_def
  4793 by auto
  4794 
  4795 lemma measures_less: "f x < f y ==> (x, y) \<in> measures (f#fs)"
  4796 by simp
  4797 
  4798 lemma measures_lesseq: "f x <= f y ==> (x, y) \<in> measures fs ==> (x, y) \<in> measures (f#fs)"
  4799 by auto
  4800 
  4801 
  4802 subsubsection {* Lifting Relations to Lists: one element *}
  4803 
  4804 definition listrel1 :: "('a \<times> 'a) set \<Rightarrow> ('a list \<times> 'a list) set" where
  4805 "listrel1 r = {(xs,ys).
  4806    \<exists>us z z' vs. xs = us @ z # vs \<and> (z,z') \<in> r \<and> ys = us @ z' # vs}"
  4807 
  4808 lemma listrel1I:
  4809   "\<lbrakk> (x, y) \<in> r;  xs = us @ x # vs;  ys = us @ y # vs \<rbrakk> \<Longrightarrow>
  4810   (xs, ys) \<in> listrel1 r"
  4811 unfolding listrel1_def by auto
  4812 
  4813 lemma listrel1E:
  4814   "\<lbrakk> (xs, ys) \<in> listrel1 r;
  4815      !!x y us vs. \<lbrakk> (x, y) \<in> r;  xs = us @ x # vs;  ys = us @ y # vs \<rbrakk> \<Longrightarrow> P
  4816    \<rbrakk> \<Longrightarrow> P"
  4817 unfolding listrel1_def by auto
  4818 
  4819 lemma not_Nil_listrel1 [iff]: "([], xs) \<notin> listrel1 r"
  4820 unfolding listrel1_def by blast
  4821 
  4822 lemma not_listrel1_Nil [iff]: "(xs, []) \<notin> listrel1 r"
  4823 unfolding listrel1_def by blast
  4824 
  4825 lemma Cons_listrel1_Cons [iff]:
  4826   "(x # xs, y # ys) \<in> listrel1 r \<longleftrightarrow>
  4827    (x,y) \<in> r \<and> xs = ys \<or> x = y \<and> (xs, ys) \<in> listrel1 r"
  4828 by (simp add: listrel1_def Cons_eq_append_conv) (blast)
  4829 
  4830 lemma listrel1I1: "(x,y) \<in> r \<Longrightarrow> (x # xs, y # xs) \<in> listrel1 r"
  4831 by (metis Cons_listrel1_Cons)
  4832 
  4833 lemma listrel1I2: "(xs, ys) \<in> listrel1 r \<Longrightarrow> (x # xs, x # ys) \<in> listrel1 r"
  4834 by (metis Cons_listrel1_Cons)
  4835 
  4836 lemma append_listrel1I:
  4837   "(xs, ys) \<in> listrel1 r \<and> us = vs \<or> xs = ys \<and> (us, vs) \<in> listrel1 r
  4838     \<Longrightarrow> (xs @ us, ys @ vs) \<in> listrel1 r"
  4839 unfolding listrel1_def
  4840 by auto (blast intro: append_eq_appendI)+
  4841 
  4842 lemma Cons_listrel1E1[elim!]:
  4843   assumes "(x # xs, ys) \<in> listrel1 r"
  4844     and "\<And>y. ys = y # xs \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> R"
  4845     and "\<And>zs. ys = x # zs \<Longrightarrow> (xs, zs) \<in> listrel1 r \<Longrightarrow> R"
  4846   shows R
  4847 using assms by (cases ys) blast+
  4848 
  4849 lemma Cons_listrel1E2[elim!]:
  4850   assumes "(xs, y # ys) \<in> listrel1 r"
  4851     and "\<And>x. xs = x # ys \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> R"
  4852     and "\<And>zs. xs = y # zs \<Longrightarrow> (zs, ys) \<in> listrel1 r \<Longrightarrow> R"
  4853   shows R
  4854 using assms by (cases xs) blast+
  4855 
  4856 lemma snoc_listrel1_snoc_iff:
  4857   "(xs @ [x], ys @ [y]) \<in> listrel1 r
  4858     \<longleftrightarrow> (xs, ys) \<in> listrel1 r \<and> x = y \<or> xs = ys \<and> (x,y) \<in> r" (is "?L \<longleftrightarrow> ?R")
  4859 proof
  4860   assume ?L thus ?R
  4861     by (fastforce simp: listrel1_def snoc_eq_iff_butlast butlast_append)
  4862 next
  4863   assume ?R then show ?L unfolding listrel1_def by force
  4864 qed
  4865 
  4866 lemma listrel1_eq_len: "(xs,ys) \<in> listrel1 r \<Longrightarrow> length xs = length ys"
  4867 unfolding listrel1_def by auto
  4868 
  4869 lemma listrel1_mono:
  4870   "r \<subseteq> s \<Longrightarrow> listrel1 r \<subseteq> listrel1 s"
  4871 unfolding listrel1_def by blast
  4872 
  4873 
  4874 lemma listrel1_converse: "listrel1 (r^-1) = (listrel1 r)^-1"
  4875 unfolding listrel1_def by blast
  4876 
  4877 lemma in_listrel1_converse:
  4878   "(x,y) : listrel1 (r^-1) \<longleftrightarrow> (x,y) : (listrel1 r)^-1"
  4879 unfolding listrel1_def by blast
  4880 
  4881 lemma listrel1_iff_update:
  4882   "(xs,ys) \<in> (listrel1 r)
  4883    \<longleftrightarrow> (\<exists>y n. (xs ! n, y) \<in> r \<and> n < length xs \<and> ys = xs[n:=y])" (is "?L \<longleftrightarrow> ?R")
  4884 proof
  4885   assume "?L"
  4886   then obtain x y u v where "xs = u @ x # v"  "ys = u @ y # v"  "(x,y) \<in> r"
  4887     unfolding listrel1_def by auto
  4888   then have "ys = xs[length u := y]" and "length u < length xs"
  4889     and "(xs ! length u, y) \<in> r" by auto
  4890   then show "?R" by auto
  4891 next
  4892   assume "?R"
  4893   then obtain x y n where "(xs!n, y) \<in> r" "n < size xs" "ys = xs[n:=y]" "x = xs!n"
  4894     by auto
  4895   then obtain u v where "xs = u @ x # v" and "ys = u @ y # v" and "(x, y) \<in> r"
  4896     by (auto intro: upd_conv_take_nth_drop id_take_nth_drop)
  4897   then show "?L" by (auto simp: listrel1_def)
  4898 qed
  4899 
  4900 
  4901 text{* Accessible part and wellfoundedness: *}
  4902 
  4903 lemma Cons_acc_listrel1I [intro!]:
  4904   "x \<in> acc r \<Longrightarrow> xs \<in> acc (listrel1 r) \<Longrightarrow> (x # xs) \<in> acc (listrel1 r)"
  4905 apply (induct arbitrary: xs set: acc)
  4906 apply (erule thin_rl)
  4907 apply (erule acc_induct)
  4908 apply (rule accI)
  4909 apply (blast)
  4910 done
  4911 
  4912 lemma lists_accD: "xs \<in> lists (acc r) \<Longrightarrow> xs \<in> acc (listrel1 r)"
  4913 apply (induct set: lists)
  4914  apply (rule accI)
  4915  apply simp
  4916 apply (rule accI)
  4917 apply (fast dest: acc_downward)
  4918 done
  4919 
  4920 lemma lists_accI: "xs \<in> acc (listrel1 r) \<Longrightarrow> xs \<in> lists (acc r)"
  4921 apply (induct set: acc)
  4922 apply clarify
  4923 apply (rule accI)
  4924 apply (fastforce dest!: in_set_conv_decomp[THEN iffD1] simp: listrel1_def)
  4925 done
  4926 
  4927 lemma wf_listrel1_iff[simp]: "wf(listrel1 r) = wf r"
  4928 by(metis wf_acc_iff in_lists_conv_set lists_accI lists_accD Cons_in_lists_iff)
  4929 
  4930 
  4931 subsubsection {* Lifting Relations to Lists: all elements *}
  4932 
  4933 inductive_set
  4934   listrel :: "('a * 'a)set => ('a list * 'a list)set"
  4935   for r :: "('a * 'a)set"
  4936 where
  4937     Nil:  "([],[]) \<in> listrel r"
  4938   | Cons: "[| (x,y) \<in> r; (xs,ys) \<in> listrel r |] ==> (x#xs, y#ys) \<in> listrel r"
  4939 
  4940 inductive_cases listrel_Nil1 [elim!]: "([],xs) \<in> listrel r"
  4941 inductive_cases listrel_Nil2 [elim!]: "(xs,[]) \<in> listrel r"
  4942 inductive_cases listrel_Cons1 [elim!]: "(y#ys,xs) \<in> listrel r"
  4943 inductive_cases listrel_Cons2 [elim!]: "(xs,y#ys) \<in> listrel r"
  4944 
  4945 
  4946 lemma listrel_eq_len:  "(xs, ys) \<in> listrel r \<Longrightarrow> length xs = length ys"
  4947 by(induct rule: listrel.induct) auto
  4948 
  4949 lemma listrel_iff_zip: "(xs,ys) : listrel r \<longleftrightarrow>
  4950   length xs = length ys & (\<forall>(x,y) \<in> set(zip xs ys). (x,y) \<in> r)" (is "?L \<longleftrightarrow> ?R")
  4951 proof
  4952   assume ?L thus ?R by induct (auto intro: listrel_eq_len)
  4953 next
  4954   assume ?R thus ?L
  4955     apply (clarify)
  4956     by (induct rule: list_induct2) (auto intro: listrel.intros)
  4957 qed
  4958 
  4959 lemma listrel_iff_nth: "(xs,ys) : listrel r \<longleftrightarrow>
  4960   length xs = length ys & (\<forall>n < length xs. (xs!n, ys!n) \<in> r)" (is "?L \<longleftrightarrow> ?R")
  4961 by (auto simp add: all_set_conv_all_nth listrel_iff_zip)
  4962 
  4963 
  4964 lemma listrel_mono: "r \<subseteq> s \<Longrightarrow> listrel r \<subseteq> listrel s"
  4965 apply clarify  
  4966 apply (erule listrel.induct)
  4967 apply (blast intro: listrel.intros)+
  4968 done
  4969 
  4970 lemma listrel_subset: "r \<subseteq> A \<times> A \<Longrightarrow> listrel r \<subseteq> lists A \<times> lists A"
  4971 apply clarify 
  4972 apply (erule listrel.induct, auto) 
  4973 done
  4974 
  4975 lemma listrel_refl_on: "refl_on A r \<Longrightarrow> refl_on (lists A) (listrel r)" 
  4976 apply (simp add: refl_on_def listrel_subset Ball_def)
  4977 apply (rule allI) 
  4978 apply (induct_tac x) 
  4979 apply (auto intro: listrel.intros)
  4980 done
  4981 
  4982 lemma listrel_sym: "sym r \<Longrightarrow> sym (listrel r)" 
  4983 apply (auto simp add: sym_def)
  4984 apply (erule listrel.induct) 
  4985 apply (blast intro: listrel.intros)+
  4986 done
  4987 
  4988 lemma listrel_trans: "trans r \<Longrightarrow> trans (listrel r)" 
  4989 apply (simp add: trans_def)
  4990 apply (intro allI) 
  4991 apply (rule impI) 
  4992 apply (erule listrel.induct) 
  4993 apply (blast intro: listrel.intros)+
  4994 done
  4995 
  4996 theorem equiv_listrel: "equiv A r \<Longrightarrow> equiv (lists A) (listrel r)"
  4997 by (simp add: equiv_def listrel_refl_on listrel_sym listrel_trans) 
  4998 
  4999 lemma listrel_rtrancl_refl[iff]: "(xs,xs) : listrel(r^*)"
  5000 using listrel_refl_on[of UNIV, OF refl_rtrancl]
  5001 by(auto simp: refl_on_def)
  5002 
  5003 lemma listrel_rtrancl_trans:
  5004   "\<lbrakk> (xs,ys) : listrel(r^*);  (ys,zs) : listrel(r^*) \<rbrakk>
  5005   \<Longrightarrow> (xs,zs) : listrel(r^*)"
  5006 by (metis listrel_trans trans_def trans_rtrancl)
  5007 
  5008 
  5009 lemma listrel_Nil [simp]: "listrel r `` {[]} = {[]}"
  5010 by (blast intro: listrel.intros)
  5011 
  5012 lemma listrel_Cons:
  5013      "listrel r `` {x#xs} = set_Cons (r``{x}) (listrel r `` {xs})"
  5014 by (auto simp add: set_Cons_def intro: listrel.intros)
  5015 
  5016 text {* Relating @{term listrel1}, @{term listrel} and closures: *}
  5017 
  5018 lemma listrel1_rtrancl_subset_rtrancl_listrel1:
  5019   "listrel1 (r^*) \<subseteq> (listrel1 r)^*"
  5020 proof (rule subrelI)
  5021   fix xs ys assume 1: "(xs,ys) \<in> listrel1 (r^*)"
  5022   { fix x y us vs
  5023     have "(x,y) : r^* \<Longrightarrow> (us @ x # vs, us @ y # vs) : (listrel1 r)^*"
  5024     proof(induct rule: rtrancl.induct)
  5025       case rtrancl_refl show ?case by simp
  5026     next
  5027       case rtrancl_into_rtrancl thus ?case
  5028         by (metis listrel1I rtrancl.rtrancl_into_rtrancl)
  5029     qed }
  5030   thus "(xs,ys) \<in> (listrel1 r)^*" using 1 by(blast elim: listrel1E)
  5031 qed
  5032 
  5033 lemma rtrancl_listrel1_eq_len: "(x,y) \<in> (listrel1 r)^* \<Longrightarrow> length x = length y"
  5034 by (induct rule: rtrancl.induct) (auto intro: listrel1_eq_len)
  5035 
  5036 lemma rtrancl_listrel1_ConsI1:
  5037   "(xs,ys) : (listrel1 r)^* \<Longrightarrow> (x#xs,x#ys) : (listrel1 r)^*"
  5038 apply(induct rule: rtrancl.induct)
  5039  apply simp
  5040 by (metis listrel1I2 rtrancl.rtrancl_into_rtrancl)
  5041 
  5042 lemma rtrancl_listrel1_ConsI2:
  5043   "(x,y) \<in> r^* \<Longrightarrow> (xs, ys) \<in> (listrel1 r)^*
  5044   \<Longrightarrow> (x # xs, y # ys) \<in> (listrel1 r)^*"
  5045   by (blast intro: rtrancl_trans rtrancl_listrel1_ConsI1 
  5046     subsetD[OF listrel1_rtrancl_subset_rtrancl_listrel1 listrel1I1])
  5047 
  5048 lemma listrel1_subset_listrel:
  5049   "r \<subseteq> r' \<Longrightarrow> refl r' \<Longrightarrow> listrel1 r \<subseteq> listrel(r')"
  5050 by(auto elim!: listrel1E simp add: listrel_iff_zip set_zip refl_on_def)
  5051 
  5052 lemma listrel_reflcl_if_listrel1:
  5053   "(xs,ys) : listrel1 r \<Longrightarrow> (xs,ys) : listrel(r^*)"
  5054 by(erule listrel1E)(auto simp add: listrel_iff_zip set_zip)
  5055 
  5056 lemma listrel_rtrancl_eq_rtrancl_listrel1: "listrel (r^*) = (listrel1 r)^*"
  5057 proof
  5058   { fix x y assume "(x,y) \<in> listrel (r^*)"
  5059     then have "(x,y) \<in> (listrel1 r)^*"
  5060     by induct (auto intro: rtrancl_listrel1_ConsI2) }
  5061   then show "listrel (r^*) \<subseteq> (listrel1 r)^*"
  5062     by (rule subrelI)
  5063 next
  5064   show "listrel (r^*) \<supseteq> (listrel1 r)^*"
  5065   proof(rule subrelI)
  5066     fix xs ys assume "(xs,ys) \<in> (listrel1 r)^*"
  5067     then show "(xs,ys) \<in> listrel (r^*)"
  5068     proof induct
  5069       case base show ?case by(auto simp add: listrel_iff_zip set_zip)
  5070     next
  5071       case (step ys zs)
  5072       thus ?case  by (metis listrel_reflcl_if_listrel1 listrel_rtrancl_trans)
  5073     qed
  5074   qed
  5075 qed
  5076 
  5077 lemma rtrancl_listrel1_if_listrel:
  5078   "(xs,ys) : listrel r \<Longrightarrow> (xs,ys) : (listrel1 r)^*"
  5079 by(metis listrel_rtrancl_eq_rtrancl_listrel1 subsetD[OF listrel_mono] r_into_rtrancl subsetI)
  5080 
  5081 lemma listrel_subset_rtrancl_listrel1: "listrel r \<subseteq> (listrel1 r)^*"
  5082 by(fast intro:rtrancl_listrel1_if_listrel)
  5083 
  5084 
  5085 subsection {* Size function *}
  5086 
  5087 lemma [measure_function]: "is_measure f \<Longrightarrow> is_measure (list_size f)"
  5088 by (rule is_measure_trivial)
  5089 
  5090 lemma [measure_function]: "is_measure f \<Longrightarrow> is_measure (option_size f)"
  5091 by (rule is_measure_trivial)
  5092 
  5093 lemma list_size_estimation[termination_simp]: 
  5094   "x \<in> set xs \<Longrightarrow> y < f x \<Longrightarrow> y < list_size f xs"
  5095 by (induct xs) auto
  5096 
  5097 lemma list_size_estimation'[termination_simp]: 
  5098   "x \<in> set xs \<Longrightarrow> y \<le> f x \<Longrightarrow> y \<le> list_size f xs"
  5099 by (induct xs) auto
  5100 
  5101 lemma list_size_map[simp]: "list_size f (map g xs) = list_size (f o g) xs"
  5102 by (induct xs) auto
  5103 
  5104 lemma list_size_append[simp]: "list_size f (xs @ ys) = list_size f xs + list_size f ys"
  5105 by (induct xs, auto)
  5106 
  5107 lemma list_size_pointwise[termination_simp]: 
  5108   "(\<And>x. x \<in> set xs \<Longrightarrow> f x \<le> g x) \<Longrightarrow> list_size f xs \<le> list_size g xs"
  5109 by (induct xs) force+
  5110 
  5111 
  5112 subsection {* Monad operation *}
  5113 
  5114 definition bind :: "'a list \<Rightarrow> ('a \<Rightarrow> 'b list) \<Rightarrow> 'b list" where
  5115   "bind xs f = concat (map f xs)"
  5116 
  5117 hide_const (open) bind
  5118 
  5119 lemma bind_simps [simp]:
  5120   "List.bind [] f = []"
  5121   "List.bind (x # xs) f = f x @ List.bind xs f"
  5122   by (simp_all add: bind_def)
  5123 
  5124 
  5125 subsection {* Transfer *}
  5126 
  5127 definition
  5128   embed_list :: "nat list \<Rightarrow> int list"
  5129 where
  5130   "embed_list l = map int l"
  5131 
  5132 definition
  5133   nat_list :: "int list \<Rightarrow> bool"
  5134 where
  5135   "nat_list l = nat_set (set l)"
  5136 
  5137 definition
  5138   return_list :: "int list \<Rightarrow> nat list"
  5139 where
  5140   "return_list l = map nat l"
  5141 
  5142 lemma transfer_nat_int_list_return_embed: "nat_list l \<longrightarrow>
  5143     embed_list (return_list l) = l"
  5144   unfolding embed_list_def return_list_def nat_list_def nat_set_def
  5145   apply (induct l)
  5146   apply auto
  5147 done
  5148 
  5149 lemma transfer_nat_int_list_functions:
  5150   "l @ m = return_list (embed_list l @ embed_list m)"
  5151   "[] = return_list []"
  5152   unfolding return_list_def embed_list_def
  5153   apply auto
  5154   apply (induct l, auto)
  5155   apply (induct m, auto)
  5156 done
  5157 
  5158 (*
  5159 lemma transfer_nat_int_fold1: "fold f l x =
  5160     fold (%x. f (nat x)) (embed_list l) x";
  5161 *)
  5162 
  5163 
  5164 subsection {* Code generation *}
  5165 
  5166 subsubsection {* Counterparts for set-related operations *}
  5167 
  5168 definition member :: "'a list \<Rightarrow> 'a \<Rightarrow> bool" where
  5169   [code_abbrev]: "member xs x \<longleftrightarrow> x \<in> set xs"
  5170 
  5171 text {*
  5172   Use @{text member} only for generating executable code.  Otherwise use
  5173   @{prop "x \<in> set xs"} instead --- it is much easier to reason about.
  5174 *}
  5175 
  5176 lemma member_rec [code]:
  5177   "member (x # xs) y \<longleftrightarrow> x = y \<or> member xs y"
  5178   "member [] y \<longleftrightarrow> False"
  5179   by (auto simp add: member_def)
  5180 
  5181 lemma in_set_member (* FIXME delete candidate *):
  5182   "x \<in> set xs \<longleftrightarrow> member xs x"
  5183   by (simp add: member_def)
  5184 
  5185 declare INF_def [code_unfold]
  5186 declare SUP_def [code_unfold]
  5187 
  5188 declare set_map [symmetric, code_unfold]
  5189 
  5190 definition list_all :: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> bool" where
  5191   list_all_iff [code_abbrev]: "list_all P xs \<longleftrightarrow> Ball (set xs) P"
  5192 
  5193 definition list_ex :: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> bool" where
  5194   list_ex_iff [code_abbrev]: "list_ex P xs \<longleftrightarrow> Bex (set xs) P"
  5195 
  5196 definition list_ex1 :: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> bool" where
  5197   list_ex1_iff [code_abbrev]: "list_ex1 P xs \<longleftrightarrow> (\<exists>! x. x \<in> set xs \<and> P x)"
  5198 
  5199 text {*
  5200   Usually you should prefer @{text "\<forall>x\<in>set xs"}, @{text "\<exists>x\<in>set xs"}
  5201   and @{text "\<exists>!x. x\<in>set xs \<and> _"} over @{const list_all}, @{const list_ex}
  5202   and @{const list_ex1} in specifications.
  5203 *}
  5204 
  5205 lemma list_all_simps [simp, code]:
  5206   "list_all P (x # xs) \<longleftrightarrow> P x \<and> list_all P xs"
  5207   "list_all P [] \<longleftrightarrow> True"
  5208   by (simp_all add: list_all_iff)
  5209 
  5210 lemma list_ex_simps [simp, code]:
  5211   "list_ex P (x # xs) \<longleftrightarrow> P x \<or> list_ex P xs"
  5212   "list_ex P [] \<longleftrightarrow> False"
  5213   by (simp_all add: list_ex_iff)
  5214 
  5215 lemma list_ex1_simps [simp, code]:
  5216   "list_ex1 P [] = False"
  5217   "list_ex1 P (x # xs) = (if P x then list_all (\<lambda>y. \<not> P y \<or> x = y) xs else list_ex1 P xs)"
  5218   by (auto simp add: list_ex1_iff list_all_iff)
  5219 
  5220 lemma Ball_set_list_all: (* FIXME delete candidate *)
  5221   "Ball (set xs) P \<longleftrightarrow> list_all P xs"
  5222   by (simp add: list_all_iff)
  5223 
  5224 lemma Bex_set_list_ex: (* FIXME delete candidate *)
  5225   "Bex (set xs) P \<longleftrightarrow> list_ex P xs"
  5226   by (simp add: list_ex_iff)
  5227 
  5228 lemma list_all_append [simp]:
  5229   "list_all P (xs @ ys) \<longleftrightarrow> list_all P xs \<and> list_all P ys"
  5230   by (auto simp add: list_all_iff)
  5231 
  5232 lemma list_ex_append [simp]:
  5233   "list_ex P (xs @ ys) \<longleftrightarrow> list_ex P xs \<or> list_ex P ys"
  5234   by (auto simp add: list_ex_iff)
  5235 
  5236 lemma list_all_rev [simp]:
  5237   "list_all P (rev xs) \<longleftrightarrow> list_all P xs"
  5238   by (simp add: list_all_iff)
  5239 
  5240 lemma list_ex_rev [simp]:
  5241   "list_ex P (rev xs) \<longleftrightarrow> list_ex P xs"
  5242   by (simp add: list_ex_iff)
  5243 
  5244 lemma list_all_length:
  5245   "list_all P xs \<longleftrightarrow> (\<forall>n < length xs. P (xs ! n))"
  5246   by (auto simp add: list_all_iff set_conv_nth)
  5247 
  5248 lemma list_ex_length:
  5249   "list_ex P xs \<longleftrightarrow> (\<exists>n < length xs. P (xs ! n))"
  5250   by (auto simp add: list_ex_iff set_conv_nth)
  5251 
  5252 lemma list_all_cong [fundef_cong]:
  5253   "xs = ys \<Longrightarrow> (\<And>x. x \<in> set ys \<Longrightarrow> f x = g x) \<Longrightarrow> list_all f xs = list_all g ys"
  5254   by (simp add: list_all_iff)
  5255 
  5256 lemma list_any_cong [fundef_cong]:
  5257   "xs = ys \<Longrightarrow> (\<And>x. x \<in> set ys \<Longrightarrow> f x = g x) \<Longrightarrow> list_ex f xs = list_ex g ys"
  5258   by (simp add: list_ex_iff)
  5259 
  5260 text {* Bounded quantification and summation over nats. *}
  5261 
  5262 lemma atMost_upto [code_unfold]:
  5263   "{..n} = set [0..<Suc n]"
  5264   by auto
  5265 
  5266 lemma atLeast_upt [code_unfold]:
  5267   "{..<n} = set [0..<n]"
  5268   by auto
  5269 
  5270 lemma greaterThanLessThan_upt [code_unfold]:
  5271   "{n<..<m} = set [Suc n..<m]"
  5272   by auto
  5273 
  5274 lemmas atLeastLessThan_upt [code_unfold] = set_upt [symmetric]
  5275 
  5276 lemma greaterThanAtMost_upt [code_unfold]:
  5277   "{n<..m} = set [Suc n..<Suc m]"
  5278   by auto
  5279 
  5280 lemma atLeastAtMost_upt [code_unfold]:
  5281   "{n..m} = set [n..<Suc m]"
  5282   by auto
  5283 
  5284 lemma all_nat_less_eq [code_unfold]:
  5285   "(\<forall>m<n\<Colon>nat. P m) \<longleftrightarrow> (\<forall>m \<in> {0..<n}. P m)"
  5286   by auto
  5287 
  5288 lemma ex_nat_less_eq [code_unfold]:
  5289   "(\<exists>m<n\<Colon>nat. P m) \<longleftrightarrow> (\<exists>m \<in> {0..<n}. P m)"
  5290   by auto
  5291 
  5292 lemma all_nat_less [code_unfold]:
  5293   "(\<forall>m\<le>n\<Colon>nat. P m) \<longleftrightarrow> (\<forall>m \<in> {0..n}. P m)"
  5294   by auto
  5295 
  5296 lemma ex_nat_less [code_unfold]:
  5297   "(\<exists>m\<le>n\<Colon>nat. P m) \<longleftrightarrow> (\<exists>m \<in> {0..n}. P m)"
  5298   by auto
  5299 
  5300 lemma setsum_set_upt_conv_listsum_nat [code_unfold]:
  5301   "setsum f (set [m..<n]) = listsum (map f [m..<n])"
  5302   by (simp add: interv_listsum_conv_setsum_set_nat)
  5303 
  5304 text {* Summation over ints. *}
  5305 
  5306 lemma greaterThanLessThan_upto [code_unfold]:
  5307   "{i<..<j::int} = set [i+1..j - 1]"
  5308 by auto
  5309 
  5310 lemma atLeastLessThan_upto [code_unfold]:
  5311   "{i..<j::int} = set [i..j - 1]"
  5312 by auto
  5313 
  5314 lemma greaterThanAtMost_upto [code_unfold]:
  5315   "{i<..j::int} = set [i+1..j]"
  5316 by auto
  5317 
  5318 lemmas atLeastAtMost_upto [code_unfold] = set_upto [symmetric]
  5319 
  5320 lemma setsum_set_upto_conv_listsum_int [code_unfold]:
  5321   "setsum f (set [i..j::int]) = listsum (map f [i..j])"
  5322   by (simp add: interv_listsum_conv_setsum_set_int)
  5323 
  5324 
  5325 subsubsection {* Optimizing by rewriting *}
  5326 
  5327 definition null :: "'a list \<Rightarrow> bool" where
  5328   [code_abbrev]: "null xs \<longleftrightarrow> xs = []"
  5329 
  5330 text {*
  5331   Efficient emptyness check is implemented by @{const null}.
  5332 *}
  5333 
  5334 lemma null_rec [code]:
  5335   "null (x # xs) \<longleftrightarrow> False"
  5336   "null [] \<longleftrightarrow> True"
  5337   by (simp_all add: null_def)
  5338 
  5339 lemma eq_Nil_null: (* FIXME delete candidate *)
  5340   "xs = [] \<longleftrightarrow> null xs"
  5341   by (simp add: null_def)
  5342 
  5343 lemma equal_Nil_null [code_unfold]:
  5344   "HOL.equal xs [] \<longleftrightarrow> null xs"
  5345   by (simp add: equal eq_Nil_null)
  5346 
  5347 definition maps :: "('a \<Rightarrow> 'b list) \<Rightarrow> 'a list \<Rightarrow> 'b list" where
  5348   [code_abbrev]: "maps f xs = concat (map f xs)"
  5349 
  5350 definition map_filter :: "('a \<Rightarrow> 'b option) \<Rightarrow> 'a list \<Rightarrow> 'b list" where
  5351   [code_post]: "map_filter f xs = map (the \<circ> f) (filter (\<lambda>x. f x \<noteq> None) xs)"
  5352 
  5353 text {*
  5354   Operations @{const maps} and @{const map_filter} avoid
  5355   intermediate lists on execution -- do not use for proving.
  5356 *}
  5357 
  5358 lemma maps_simps [code]:
  5359   "maps f (x # xs) = f x @ maps f xs"
  5360   "maps f [] = []"
  5361   by (simp_all add: maps_def)
  5362 
  5363 lemma map_filter_simps [code]:
  5364   "map_filter f (x # xs) = (case f x of None \<Rightarrow> map_filter f xs | Some y \<Rightarrow> y # map_filter f xs)"
  5365   "map_filter f [] = []"
  5366   by (simp_all add: map_filter_def split: option.split)
  5367 
  5368 lemma concat_map_maps: (* FIXME delete candidate *)
  5369   "concat (map f xs) = maps f xs"
  5370   by (simp add: maps_def)
  5371 
  5372 lemma map_filter_map_filter [code_unfold]:
  5373   "map f (filter P xs) = map_filter (\<lambda>x. if P x then Some (f x) else None) xs"
  5374   by (simp add: map_filter_def)
  5375 
  5376 text {* Optimized code for @{text"\<forall>i\<in>{a..b::int}"} and @{text"\<forall>n:{a..<b::nat}"}
  5377 and similiarly for @{text"\<exists>"}. *}
  5378 
  5379 definition all_interval_nat :: "(nat \<Rightarrow> bool) \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> bool" where
  5380   "all_interval_nat P i j \<longleftrightarrow> (\<forall>n \<in> {i..<j}. P n)"
  5381 
  5382 lemma [code]:
  5383   "all_interval_nat P i j \<longleftrightarrow> i \<ge> j \<or> P i \<and> all_interval_nat P (Suc i) j"
  5384 proof -
  5385   have *: "\<And>n. P i \<Longrightarrow> \<forall>n\<in>{Suc i..<j}. P n \<Longrightarrow> i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P n"
  5386   proof -
  5387     fix n
  5388     assume "P i" "\<forall>n\<in>{Suc i..<j}. P n" "i \<le> n" "n < j"
  5389     then show "P n" by (cases "n = i") simp_all
  5390   qed
  5391   show ?thesis by (auto simp add: all_interval_nat_def intro: *)
  5392 qed
  5393 
  5394 lemma list_all_iff_all_interval_nat [code_unfold]:
  5395   "list_all P [i..<j] \<longleftrightarrow> all_interval_nat P i j"
  5396   by (simp add: list_all_iff all_interval_nat_def)
  5397 
  5398 lemma list_ex_iff_not_all_inverval_nat [code_unfold]:
  5399   "list_ex P [i..<j] \<longleftrightarrow> \<not> (all_interval_nat (Not \<circ> P) i j)"
  5400   by (simp add: list_ex_iff all_interval_nat_def)
  5401 
  5402 definition all_interval_int :: "(int \<Rightarrow> bool) \<Rightarrow> int \<Rightarrow> int \<Rightarrow> bool" where
  5403   "all_interval_int P i j \<longleftrightarrow> (\<forall>k \<in> {i..j}. P k)"
  5404 
  5405 lemma [code]:
  5406   "all_interval_int P i j \<longleftrightarrow> i > j \<or> P i \<and> all_interval_int P (i + 1) j"
  5407 proof -
  5408   have *: "\<And>k. P i \<Longrightarrow> \<forall>k\<in>{i+1..j}. P k \<Longrightarrow> i \<le> k \<Longrightarrow> k \<le> j \<Longrightarrow> P k"
  5409   proof -
  5410     fix k
  5411     assume "P i" "\<forall>k\<in>{i+1..j}. P k" "i \<le> k" "k \<le> j"
  5412     then show "P k" by (cases "k = i") simp_all
  5413   qed
  5414   show ?thesis by (auto simp add: all_interval_int_def intro: *)
  5415 qed
  5416 
  5417 lemma list_all_iff_all_interval_int [code_unfold]:
  5418   "list_all P [i..j] \<longleftrightarrow> all_interval_int P i j"
  5419   by (simp add: list_all_iff all_interval_int_def)
  5420 
  5421 lemma list_ex_iff_not_all_inverval_int [code_unfold]:
  5422   "list_ex P [i..j] \<longleftrightarrow> \<not> (all_interval_int (Not \<circ> P) i j)"
  5423   by (simp add: list_ex_iff all_interval_int_def)
  5424 
  5425 hide_const (open) member null maps map_filter all_interval_nat all_interval_int
  5426 
  5427 
  5428 subsubsection {* Pretty lists *}
  5429 
  5430 use "Tools/list_code.ML"
  5431 
  5432 code_type list
  5433   (SML "_ list")
  5434   (OCaml "_ list")
  5435   (Haskell "![(_)]")
  5436   (Scala "List[(_)]")
  5437 
  5438 code_const Nil
  5439   (SML "[]")
  5440   (OCaml "[]")
  5441   (Haskell "[]")
  5442   (Scala "!Nil")
  5443 
  5444 code_instance list :: equal
  5445   (Haskell -)
  5446 
  5447 code_const "HOL.equal \<Colon> 'a list \<Rightarrow> 'a list \<Rightarrow> bool"
  5448   (Haskell infix 4 "==")
  5449 
  5450 code_reserved SML
  5451   list
  5452 
  5453 code_reserved OCaml
  5454   list
  5455 
  5456 setup {* fold (List_Code.add_literal_list) ["SML", "OCaml", "Haskell", "Scala"] *}
  5457 
  5458 
  5459 subsubsection {* Use convenient predefined operations *}
  5460 
  5461 code_const "op @"
  5462   (SML infixr 7 "@")
  5463   (OCaml infixr 6 "@")
  5464   (Haskell infixr 5 "++")
  5465   (Scala infixl 7 "++")
  5466 
  5467 code_const map
  5468   (Haskell "map")
  5469 
  5470 code_const filter
  5471   (Haskell "filter")
  5472 
  5473 code_const concat
  5474   (Haskell "concat")
  5475 
  5476 code_const List.maps
  5477   (Haskell "concatMap")
  5478 
  5479 code_const rev
  5480   (Haskell "reverse")
  5481 
  5482 code_const zip
  5483   (Haskell "zip")
  5484 
  5485 code_const List.null
  5486   (Haskell "null")
  5487 
  5488 code_const takeWhile
  5489   (Haskell "takeWhile")
  5490 
  5491 code_const dropWhile
  5492   (Haskell "dropWhile")
  5493 
  5494 code_const list_all
  5495   (Haskell "all")
  5496 
  5497 code_const list_ex
  5498   (Haskell "any")
  5499 
  5500 end