src/HOL/Divides.thy
author haftmann
Fri Dec 07 15:07:59 2007 +0100 (2007-12-07)
changeset 25571 c9e39eafc7a0
parent 25162 ad4d5365d9d8
child 25942 a52309ac4a4d
permissions -rw-r--r--
instantiation target rather than legacy instance
     1 (*  Title:      HOL/Divides.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1999  University of Cambridge
     5 *)
     6 
     7 header {* The division operators div, mod and the divides relation "dvd" *}
     8 
     9 theory Divides
    10 imports Power
    11 uses "~~/src/Provers/Arith/cancel_div_mod.ML"
    12 begin
    13 
    14 class div = times +
    15   fixes div :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "div" 70)
    16   fixes mod :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "mod" 70)
    17 
    18 instantiation nat :: Divides.div
    19 begin
    20 
    21 definition
    22   div_def: "m div n == wfrec (pred_nat^+)
    23                           (%f j. if j<n | n=0 then 0 else Suc (f (j-n))) m"
    24 
    25 definition
    26   mod_def: "m mod n == wfrec (pred_nat^+)
    27                           (%f j. if j<n | n=0 then j else f (j-n)) m"
    28 
    29 instance ..
    30 
    31 end
    32 
    33 definition (in div)
    34   dvd  :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infixl "dvd" 50)
    35 where
    36   [code func del]: "m dvd n \<longleftrightarrow> (\<exists>k. n = m * k)"
    37 
    38 class dvd_mod = div + zero + -- {* for code generation *}
    39   assumes dvd_def_mod [code func]: "x dvd y \<longleftrightarrow> y mod x = 0"
    40 
    41 definition
    42   quorem :: "(nat*nat) * (nat*nat) => bool" where
    43   (*This definition helps prove the harder properties of div and mod.
    44     It is copied from IntDiv.thy; should it be overloaded?*)
    45   "quorem = (%((a,b), (q,r)).
    46                     a = b*q + r &
    47                     (if 0<b then 0\<le>r & r<b else b<r & r \<le>0))"
    48 
    49 
    50 
    51 subsection{*Initial Lemmas*}
    52 
    53 lemmas wf_less_trans =
    54        def_wfrec [THEN trans, OF eq_reflection wf_pred_nat [THEN wf_trancl],
    55                   standard]
    56 
    57 lemma mod_eq: "(%m. m mod n) =
    58               wfrec (pred_nat^+) (%f j. if j<n | n=0 then j else f (j-n))"
    59 by (simp add: mod_def)
    60 
    61 lemma div_eq: "(%m. m div n) = wfrec (pred_nat^+)
    62                (%f j. if j<n | n=0 then 0 else Suc (f (j-n)))"
    63 by (simp add: div_def)
    64 
    65 
    66 (** Aribtrary definitions for division by zero.  Useful to simplify
    67     certain equations **)
    68 
    69 lemma DIVISION_BY_ZERO_DIV [simp]: "a div 0 = (0::nat)"
    70   by (rule div_eq [THEN wf_less_trans], simp)
    71 
    72 lemma DIVISION_BY_ZERO_MOD [simp]: "a mod 0 = (a::nat)"
    73   by (rule mod_eq [THEN wf_less_trans], simp)
    74 
    75 
    76 subsection{*Remainder*}
    77 
    78 lemma mod_less [simp]: "m<n ==> m mod n = (m::nat)"
    79   by (rule mod_eq [THEN wf_less_trans]) simp
    80 
    81 lemma mod_geq: "~ m < (n::nat) ==> m mod n = (m-n) mod n"
    82   apply (cases "n=0")
    83    apply simp
    84   apply (rule mod_eq [THEN wf_less_trans])
    85   apply (simp add: cut_apply less_eq)
    86   done
    87 
    88 (*Avoids the ugly ~m<n above*)
    89 lemma le_mod_geq: "(n::nat) \<le> m ==> m mod n = (m-n) mod n"
    90   by (simp add: mod_geq linorder_not_less)
    91 
    92 lemma mod_if: "m mod (n::nat) = (if m<n then m else (m-n) mod n)"
    93   by (simp add: mod_geq)
    94 
    95 lemma mod_1 [simp]: "m mod Suc 0 = 0"
    96   by (induct m) (simp_all add: mod_geq)
    97 
    98 lemma mod_self [simp]: "n mod n = (0::nat)"
    99   by (cases "n = 0") (simp_all add: mod_geq)
   100 
   101 lemma mod_add_self2 [simp]: "(m+n) mod n = m mod (n::nat)"
   102   apply (subgoal_tac "(n + m) mod n = (n+m-n) mod n")
   103    apply (simp add: add_commute)
   104   apply (subst mod_geq [symmetric], simp_all)
   105   done
   106 
   107 lemma mod_add_self1 [simp]: "(n+m) mod n = m mod (n::nat)"
   108   by (simp add: add_commute mod_add_self2)
   109 
   110 lemma mod_mult_self1 [simp]: "(m + k*n) mod n = m mod (n::nat)"
   111   by (induct k) (simp_all add: add_left_commute [of _ n])
   112 
   113 lemma mod_mult_self2 [simp]: "(m + n*k) mod n = m mod (n::nat)"
   114   by (simp add: mult_commute mod_mult_self1)
   115 
   116 lemma mod_mult_distrib: "(m mod n) * (k::nat) = (m*k) mod (n*k)"
   117   apply (cases "n = 0", simp)
   118   apply (cases "k = 0", simp)
   119   apply (induct m rule: nat_less_induct)
   120   apply (subst mod_if, simp)
   121   apply (simp add: mod_geq diff_mult_distrib)
   122   done
   123 
   124 lemma mod_mult_distrib2: "(k::nat) * (m mod n) = (k*m) mod (k*n)"
   125   by (simp add: mult_commute [of k] mod_mult_distrib)
   126 
   127 lemma mod_mult_self_is_0 [simp]: "(m*n) mod n = (0::nat)"
   128   apply (cases "n = 0", simp)
   129   apply (induct m, simp)
   130   apply (rename_tac k)
   131   apply (cut_tac m = "k * n" and n = n in mod_add_self2)
   132   apply (simp add: add_commute)
   133   done
   134 
   135 lemma mod_mult_self1_is_0 [simp]: "(n*m) mod n = (0::nat)"
   136   by (simp add: mult_commute mod_mult_self_is_0)
   137 
   138 
   139 subsection{*Quotient*}
   140 
   141 lemma div_less [simp]: "m<n ==> m div n = (0::nat)"
   142   by (rule div_eq [THEN wf_less_trans], simp)
   143 
   144 lemma div_geq: "[| 0<n;  ~m<n |] ==> m div n = Suc((m-n) div n)"
   145   apply (rule div_eq [THEN wf_less_trans])
   146   apply (simp add: cut_apply less_eq)
   147   done
   148 
   149 (*Avoids the ugly ~m<n above*)
   150 lemma le_div_geq: "[| 0<n;  n\<le>m |] ==> m div n = Suc((m-n) div n)"
   151   by (simp add: div_geq linorder_not_less)
   152 
   153 lemma div_if: "0<n ==> m div n = (if m<n then 0 else Suc((m-n) div n))"
   154   by (simp add: div_geq)
   155 
   156 
   157 (*Main Result about quotient and remainder.*)
   158 lemma mod_div_equality: "(m div n)*n + m mod n = (m::nat)"
   159   apply (cases "n = 0", simp)
   160   apply (induct m rule: nat_less_induct)
   161   apply (subst mod_if)
   162   apply (simp_all add: add_assoc div_geq add_diff_inverse)
   163   done
   164 
   165 lemma mod_div_equality2: "n * (m div n) + m mod n = (m::nat)"
   166   apply (cut_tac m = m and n = n in mod_div_equality)
   167   apply (simp add: mult_commute)
   168   done
   169 
   170 subsection{*Simproc for Cancelling Div and Mod*}
   171 
   172 lemma div_mod_equality: "((m div n)*n + m mod n) + k = (m::nat) + k"
   173   by (simp add: mod_div_equality)
   174 
   175 lemma div_mod_equality2: "(n*(m div n) + m mod n) + k = (m::nat) + k"
   176   by (simp add: mod_div_equality2)
   177 
   178 ML
   179 {*
   180 structure CancelDivModData =
   181 struct
   182 
   183 val div_name = @{const_name Divides.div};
   184 val mod_name = @{const_name Divides.mod};
   185 val mk_binop = HOLogic.mk_binop;
   186 val mk_sum = NatArithUtils.mk_sum;
   187 val dest_sum = NatArithUtils.dest_sum;
   188 
   189 (*logic*)
   190 
   191 val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}]
   192 
   193 val trans = trans
   194 
   195 val prove_eq_sums =
   196   let val simps = @{thm add_0} :: @{thm add_0_right} :: @{thms add_ac}
   197   in NatArithUtils.prove_conv all_tac (NatArithUtils.simp_all_tac simps) end;
   198 
   199 end;
   200 
   201 structure CancelDivMod = CancelDivModFun(CancelDivModData);
   202 
   203 val cancel_div_mod_proc = NatArithUtils.prep_simproc
   204       ("cancel_div_mod", ["(m::nat) + n"], K CancelDivMod.proc);
   205 
   206 Addsimprocs[cancel_div_mod_proc];
   207 *}
   208 
   209 
   210 (* a simple rearrangement of mod_div_equality: *)
   211 lemma mult_div_cancel: "(n::nat) * (m div n) = m - (m mod n)"
   212   by (cut_tac m = m and n = n in mod_div_equality2, arith)
   213 
   214 lemma mod_less_divisor [simp]: "0<n ==> m mod n < (n::nat)"
   215   apply (induct m rule: nat_less_induct)
   216   apply (rename_tac m)
   217   apply (case_tac "m<n", simp)
   218   txt{*case @{term "n \<le> m"}*}
   219   apply (simp add: mod_geq)
   220   done
   221 
   222 lemma mod_le_divisor[simp]: "0 < n \<Longrightarrow> m mod n \<le> (n::nat)"
   223   apply (drule mod_less_divisor [where m = m])
   224   apply simp
   225   done
   226 
   227 lemma div_mult_self_is_m [simp]: "0<n ==> (m*n) div n = (m::nat)"
   228   by (cut_tac m = "m*n" and n = n in mod_div_equality, auto)
   229 
   230 lemma div_mult_self1_is_m [simp]: "0<n ==> (n*m) div n = (m::nat)"
   231   by (simp add: mult_commute div_mult_self_is_m)
   232 
   233 (*mod_mult_distrib2 above is the counterpart for remainder*)
   234 
   235 
   236 subsection{*Proving facts about Quotient and Remainder*}
   237 
   238 lemma unique_quotient_lemma:
   239      "[| b*q' + r'  \<le> b*q + r;  x < b;  r < b |]
   240       ==> q' \<le> (q::nat)"
   241   apply (rule leI)
   242   apply (subst less_iff_Suc_add)
   243   apply (auto simp add: add_mult_distrib2)
   244   done
   245 
   246 lemma unique_quotient:
   247      "[| quorem ((a,b), (q,r));  quorem ((a,b), (q',r'));  0 < b |]
   248       ==> q = q'"
   249   apply (simp add: split_ifs quorem_def)
   250   apply (blast intro: order_antisym
   251     dest: order_eq_refl [THEN unique_quotient_lemma] sym)
   252   done
   253 
   254 lemma unique_remainder:
   255      "[| quorem ((a,b), (q,r));  quorem ((a,b), (q',r'));  0 < b |]
   256       ==> r = r'"
   257   apply (subgoal_tac "q = q'")
   258    prefer 2 apply (blast intro: unique_quotient)
   259   apply (simp add: quorem_def)
   260   done
   261 
   262 lemma quorem_div_mod: "b > 0 ==> quorem ((a, b), (a div b, a mod b))"
   263 unfolding quorem_def by simp
   264 
   265 lemma quorem_div: "[| quorem((a,b),(q,r));  b > 0 |] ==> a div b = q"
   266 by (simp add: quorem_div_mod [THEN unique_quotient])
   267 
   268 lemma quorem_mod: "[| quorem((a,b),(q,r));  b > 0 |] ==> a mod b = r"
   269 by (simp add: quorem_div_mod [THEN unique_remainder])
   270 
   271 (** A dividend of zero **)
   272 
   273 lemma div_0 [simp]: "0 div m = (0::nat)"
   274   by (cases "m = 0") simp_all
   275 
   276 lemma mod_0 [simp]: "0 mod m = (0::nat)"
   277   by (cases "m = 0") simp_all
   278 
   279 (** proving (a*b) div c = a * (b div c) + a * (b mod c) **)
   280 
   281 lemma quorem_mult1_eq:
   282   "[| quorem((b,c),(q,r)); c > 0 |]
   283    ==> quorem ((a*b, c), (a*q + a*r div c, a*r mod c))"
   284 by (auto simp add: split_ifs mult_ac quorem_def add_mult_distrib2)
   285 
   286 lemma div_mult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::nat)"
   287 apply (cases "c = 0", simp)
   288 apply (blast intro: quorem_div_mod [THEN quorem_mult1_eq, THEN quorem_div])
   289 done
   290 
   291 lemma mod_mult1_eq: "(a*b) mod c = a*(b mod c) mod (c::nat)"
   292 apply (cases "c = 0", simp)
   293 apply (blast intro: quorem_div_mod [THEN quorem_mult1_eq, THEN quorem_mod])
   294 done
   295 
   296 lemma mod_mult1_eq': "(a*b) mod (c::nat) = ((a mod c) * b) mod c"
   297   apply (rule trans)
   298    apply (rule_tac s = "b*a mod c" in trans)
   299     apply (rule_tac [2] mod_mult1_eq)
   300    apply (simp_all add: mult_commute)
   301   done
   302 
   303 lemma mod_mult_distrib_mod:
   304   "(a*b) mod (c::nat) = ((a mod c) * (b mod c)) mod c"
   305 apply (rule mod_mult1_eq' [THEN trans])
   306 apply (rule mod_mult1_eq)
   307 done
   308 
   309 (** proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) **)
   310 
   311 lemma quorem_add1_eq:
   312   "[| quorem((a,c),(aq,ar));  quorem((b,c),(bq,br));  c > 0 |]
   313    ==> quorem ((a+b, c), (aq + bq + (ar+br) div c, (ar+br) mod c))"
   314 by (auto simp add: split_ifs mult_ac quorem_def add_mult_distrib2)
   315 
   316 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   317 lemma div_add1_eq:
   318   "(a+b) div (c::nat) = a div c + b div c + ((a mod c + b mod c) div c)"
   319 apply (cases "c = 0", simp)
   320 apply (blast intro: quorem_add1_eq [THEN quorem_div] quorem_div_mod)
   321 done
   322 
   323 lemma mod_add1_eq: "(a+b) mod (c::nat) = (a mod c + b mod c) mod c"
   324 apply (cases "c = 0", simp)
   325 apply (blast intro: quorem_div_mod quorem_add1_eq [THEN quorem_mod])
   326 done
   327 
   328 
   329 subsection{*Proving @{term "a div (b*c) = (a div b) div c"}*}
   330 
   331 (** first, a lemma to bound the remainder **)
   332 
   333 lemma mod_lemma: "[| (0::nat) < c; r < b |] ==> b * (q mod c) + r < b * c"
   334   apply (cut_tac m = q and n = c in mod_less_divisor)
   335   apply (drule_tac [2] m = "q mod c" in less_imp_Suc_add, auto)
   336   apply (erule_tac P = "%x. ?lhs < ?rhs x" in ssubst)
   337   apply (simp add: add_mult_distrib2)
   338   done
   339 
   340 lemma quorem_mult2_eq: "[| quorem ((a,b), (q,r));  0 < b;  0 < c |]
   341       ==> quorem ((a, b*c), (q div c, b*(q mod c) + r))"
   342   by (auto simp add: mult_ac quorem_def add_mult_distrib2 [symmetric] mod_lemma)
   343 
   344 lemma div_mult2_eq: "a div (b*c) = (a div b) div (c::nat)"
   345   apply (cases "b = 0", simp)
   346   apply (cases "c = 0", simp)
   347   apply (force simp add: quorem_div_mod [THEN quorem_mult2_eq, THEN quorem_div])
   348   done
   349 
   350 lemma mod_mult2_eq: "a mod (b*c) = b*(a div b mod c) + a mod (b::nat)"
   351   apply (cases "b = 0", simp)
   352   apply (cases "c = 0", simp)
   353   apply (auto simp add: mult_commute quorem_div_mod [THEN quorem_mult2_eq, THEN quorem_mod])
   354   done
   355 
   356 
   357 subsection{*Cancellation of Common Factors in Division*}
   358 
   359 lemma div_mult_mult_lemma:
   360     "[| (0::nat) < b;  0 < c |] ==> (c*a) div (c*b) = a div b"
   361   by (auto simp add: div_mult2_eq)
   362 
   363 lemma div_mult_mult1 [simp]: "(0::nat) < c ==> (c*a) div (c*b) = a div b"
   364   apply (cases "b = 0")
   365   apply (auto simp add: linorder_neq_iff [of b] div_mult_mult_lemma)
   366   done
   367 
   368 lemma div_mult_mult2 [simp]: "(0::nat) < c ==> (a*c) div (b*c) = a div b"
   369   apply (drule div_mult_mult1)
   370   apply (auto simp add: mult_commute)
   371   done
   372 
   373 
   374 subsection{*Further Facts about Quotient and Remainder*}
   375 
   376 lemma div_1 [simp]: "m div Suc 0 = m"
   377   by (induct m) (simp_all add: div_geq)
   378 
   379 lemma div_self [simp]: "0<n ==> n div n = (1::nat)"
   380   by (simp add: div_geq)
   381 
   382 lemma div_add_self2: "0<n ==> (m+n) div n = Suc (m div n)"
   383   apply (subgoal_tac "(n + m) div n = Suc ((n+m-n) div n) ")
   384    apply (simp add: add_commute)
   385   apply (subst div_geq [symmetric], simp_all)
   386   done
   387 
   388 lemma div_add_self1: "0<n ==> (n+m) div n = Suc (m div n)"
   389   by (simp add: add_commute div_add_self2)
   390 
   391 lemma div_mult_self1 [simp]: "!!n::nat. 0<n ==> (m + k*n) div n = k + m div n"
   392   apply (subst div_add1_eq)
   393   apply (subst div_mult1_eq, simp)
   394   done
   395 
   396 lemma div_mult_self2 [simp]: "0<n ==> (m + n*k) div n = k + m div (n::nat)"
   397   by (simp add: mult_commute div_mult_self1)
   398 
   399 
   400 (* Monotonicity of div in first argument *)
   401 lemma div_le_mono [rule_format (no_asm)]:
   402     "\<forall>m::nat. m \<le> n --> (m div k) \<le> (n div k)"
   403 apply (case_tac "k=0", simp)
   404 apply (induct "n" rule: nat_less_induct, clarify)
   405 apply (case_tac "n<k")
   406 (* 1  case n<k *)
   407 apply simp
   408 (* 2  case n >= k *)
   409 apply (case_tac "m<k")
   410 (* 2.1  case m<k *)
   411 apply simp
   412 (* 2.2  case m>=k *)
   413 apply (simp add: div_geq diff_le_mono)
   414 done
   415 
   416 (* Antimonotonicity of div in second argument *)
   417 lemma div_le_mono2: "!!m::nat. [| 0<m; m\<le>n |] ==> (k div n) \<le> (k div m)"
   418 apply (subgoal_tac "0<n")
   419  prefer 2 apply simp
   420 apply (induct_tac k rule: nat_less_induct)
   421 apply (rename_tac "k")
   422 apply (case_tac "k<n", simp)
   423 apply (subgoal_tac "~ (k<m) ")
   424  prefer 2 apply simp
   425 apply (simp add: div_geq)
   426 apply (subgoal_tac "(k-n) div n \<le> (k-m) div n")
   427  prefer 2
   428  apply (blast intro: div_le_mono diff_le_mono2)
   429 apply (rule le_trans, simp)
   430 apply (simp)
   431 done
   432 
   433 lemma div_le_dividend [simp]: "m div n \<le> (m::nat)"
   434 apply (case_tac "n=0", simp)
   435 apply (subgoal_tac "m div n \<le> m div 1", simp)
   436 apply (rule div_le_mono2)
   437 apply (simp_all (no_asm_simp))
   438 done
   439 
   440 (* Similar for "less than" *)
   441 lemma div_less_dividend [rule_format]:
   442      "!!n::nat. 1<n ==> 0 < m --> m div n < m"
   443 apply (induct_tac m rule: nat_less_induct)
   444 apply (rename_tac "m")
   445 apply (case_tac "m<n", simp)
   446 apply (subgoal_tac "0<n")
   447  prefer 2 apply simp
   448 apply (simp add: div_geq)
   449 apply (case_tac "n<m")
   450  apply (subgoal_tac "(m-n) div n < (m-n) ")
   451   apply (rule impI less_trans_Suc)+
   452 apply assumption
   453   apply (simp_all)
   454 done
   455 
   456 declare div_less_dividend [simp]
   457 
   458 text{*A fact for the mutilated chess board*}
   459 lemma mod_Suc: "Suc(m) mod n = (if Suc(m mod n) = n then 0 else Suc(m mod n))"
   460 apply (case_tac "n=0", simp)
   461 apply (induct "m" rule: nat_less_induct)
   462 apply (case_tac "Suc (na) <n")
   463 (* case Suc(na) < n *)
   464 apply (frule lessI [THEN less_trans], simp add: less_not_refl3)
   465 (* case n \<le> Suc(na) *)
   466 apply (simp add: linorder_not_less le_Suc_eq mod_geq)
   467 apply (auto simp add: Suc_diff_le le_mod_geq)
   468 done
   469 
   470 lemma nat_mod_div_trivial [simp]: "m mod n div n = (0 :: nat)"
   471   by (cases "n = 0") auto
   472 
   473 lemma nat_mod_mod_trivial [simp]: "m mod n mod n = (m mod n :: nat)"
   474   by (cases "n = 0") auto
   475 
   476 
   477 subsection{*The Divides Relation*}
   478 
   479 lemma dvdI [intro?]: "n = m * k ==> m dvd n"
   480   unfolding dvd_def by blast
   481 
   482 lemma dvdE [elim?]: "!!P. [|m dvd n;  !!k. n = m*k ==> P|] ==> P"
   483   unfolding dvd_def by blast
   484 
   485 lemma dvd_0_right [iff]: "m dvd (0::nat)"
   486   unfolding dvd_def by (blast intro: mult_0_right [symmetric])
   487 
   488 lemma dvd_0_left: "0 dvd m ==> m = (0::nat)"
   489   by (force simp add: dvd_def)
   490 
   491 lemma dvd_0_left_iff [iff]: "(0 dvd (m::nat)) = (m = 0)"
   492   by (blast intro: dvd_0_left)
   493 
   494 declare dvd_0_left_iff [noatp]
   495 
   496 lemma dvd_1_left [iff]: "Suc 0 dvd k"
   497   unfolding dvd_def by simp
   498 
   499 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
   500   by (simp add: dvd_def)
   501 
   502 lemma dvd_refl [simp]: "m dvd (m::nat)"
   503   unfolding dvd_def by (blast intro: mult_1_right [symmetric])
   504 
   505 lemma dvd_trans [trans]: "[| m dvd n; n dvd p |] ==> m dvd (p::nat)"
   506   unfolding dvd_def by (blast intro: mult_assoc)
   507 
   508 lemma dvd_anti_sym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
   509   unfolding dvd_def
   510   by (force dest: mult_eq_self_implies_10 simp add: mult_assoc mult_eq_1_iff)
   511 
   512 text {* @{term "op dvd"} is a partial order *}
   513 
   514 interpretation dvd: order ["op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> m \<noteq> n"]
   515   by unfold_locales (auto intro: dvd_trans dvd_anti_sym)
   516 
   517 lemma dvd_add: "[| k dvd m; k dvd n |] ==> k dvd (m+n :: nat)"
   518   unfolding dvd_def
   519   by (blast intro: add_mult_distrib2 [symmetric])
   520 
   521 lemma dvd_diff: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
   522   unfolding dvd_def
   523   by (blast intro: diff_mult_distrib2 [symmetric])
   524 
   525 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
   526   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
   527   apply (blast intro: dvd_add)
   528   done
   529 
   530 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
   531   by (drule_tac m = m in dvd_diff, auto)
   532 
   533 lemma dvd_mult: "k dvd n ==> k dvd (m*n :: nat)"
   534   unfolding dvd_def by (blast intro: mult_left_commute)
   535 
   536 lemma dvd_mult2: "k dvd m ==> k dvd (m*n :: nat)"
   537   apply (subst mult_commute)
   538   apply (erule dvd_mult)
   539   done
   540 
   541 lemma dvd_triv_right [iff]: "k dvd (m*k :: nat)"
   542   by (rule dvd_refl [THEN dvd_mult])
   543 
   544 lemma dvd_triv_left [iff]: "k dvd (k*m :: nat)"
   545   by (rule dvd_refl [THEN dvd_mult2])
   546 
   547 lemma dvd_reduce: "(k dvd n + k) = (k dvd (n::nat))"
   548   apply (rule iffI)
   549    apply (erule_tac [2] dvd_add)
   550    apply (rule_tac [2] dvd_refl)
   551   apply (subgoal_tac "n = (n+k) -k")
   552    prefer 2 apply simp
   553   apply (erule ssubst)
   554   apply (erule dvd_diff)
   555   apply (rule dvd_refl)
   556   done
   557 
   558 lemma dvd_mod: "!!n::nat. [| f dvd m; f dvd n |] ==> f dvd m mod n"
   559   unfolding dvd_def
   560   apply (case_tac "n = 0", auto)
   561   apply (blast intro: mod_mult_distrib2 [symmetric])
   562   done
   563 
   564 lemma dvd_mod_imp_dvd: "[| (k::nat) dvd m mod n;  k dvd n |] ==> k dvd m"
   565   apply (subgoal_tac "k dvd (m div n) *n + m mod n")
   566    apply (simp add: mod_div_equality)
   567   apply (simp only: dvd_add dvd_mult)
   568   done
   569 
   570 lemma dvd_mod_iff: "k dvd n ==> ((k::nat) dvd m mod n) = (k dvd m)"
   571   by (blast intro: dvd_mod_imp_dvd dvd_mod)
   572 
   573 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
   574   unfolding dvd_def
   575   apply (erule exE)
   576   apply (simp add: mult_ac)
   577   done
   578 
   579 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
   580   apply auto
   581    apply (subgoal_tac "m*n dvd m*1")
   582    apply (drule dvd_mult_cancel, auto)
   583   done
   584 
   585 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
   586   apply (subst mult_commute)
   587   apply (erule dvd_mult_cancel1)
   588   done
   589 
   590 lemma mult_dvd_mono: "[| i dvd m; j dvd n|] ==> i*j dvd (m*n :: nat)"
   591   apply (unfold dvd_def, clarify)
   592   apply (rule_tac x = "k*ka" in exI)
   593   apply (simp add: mult_ac)
   594   done
   595 
   596 lemma dvd_mult_left: "(i*j :: nat) dvd k ==> i dvd k"
   597   by (simp add: dvd_def mult_assoc, blast)
   598 
   599 lemma dvd_mult_right: "(i*j :: nat) dvd k ==> j dvd k"
   600   apply (unfold dvd_def, clarify)
   601   apply (rule_tac x = "i*k" in exI)
   602   apply (simp add: mult_ac)
   603   done
   604 
   605 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
   606   apply (unfold dvd_def, clarify)
   607   apply (simp_all (no_asm_use) add: zero_less_mult_iff)
   608   apply (erule conjE)
   609   apply (rule le_trans)
   610    apply (rule_tac [2] le_refl [THEN mult_le_mono])
   611    apply (erule_tac [2] Suc_leI, simp)
   612   done
   613 
   614 lemma dvd_eq_mod_eq_0: "!!k::nat. (k dvd n) = (n mod k = 0)"
   615   apply (unfold dvd_def)
   616   apply (case_tac "k=0", simp, safe)
   617    apply (simp add: mult_commute)
   618   apply (rule_tac t = n and n1 = k in mod_div_equality [THEN subst])
   619   apply (subst mult_commute, simp)
   620   done
   621 
   622 lemma dvd_mult_div_cancel: "n dvd m ==> n * (m div n) = (m::nat)"
   623   apply (subgoal_tac "m mod n = 0")
   624    apply (simp add: mult_div_cancel)
   625   apply (simp only: dvd_eq_mod_eq_0)
   626   done
   627 
   628 lemma le_imp_power_dvd: "!!i::nat. m \<le> n ==> i^m dvd i^n"
   629   apply (unfold dvd_def)
   630   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
   631   apply (simp add: power_add)
   632   done
   633 
   634 lemma nat_zero_less_power_iff [simp]: "(x^n > 0) = (x > (0::nat) | n=0)"
   635   by (induct n) auto
   636 
   637 lemma power_le_dvd [rule_format]: "k^j dvd n --> i\<le>j --> k^i dvd (n::nat)"
   638   apply (induct j)
   639    apply (simp_all add: le_Suc_eq)
   640   apply (blast dest!: dvd_mult_right)
   641   done
   642 
   643 lemma power_dvd_imp_le: "[|i^m dvd i^n;  (1::nat) < i|] ==> m \<le> n"
   644   apply (rule power_le_imp_le_exp, assumption)
   645   apply (erule dvd_imp_le, simp)
   646   done
   647 
   648 lemma mod_eq_0_iff: "(m mod d = 0) = (\<exists>q::nat. m = d*q)"
   649   by (auto simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   650 
   651 lemmas mod_eq_0D [dest!] = mod_eq_0_iff [THEN iffD1]
   652 
   653 (*Loses information, namely we also have r<d provided d is nonzero*)
   654 lemma mod_eqD: "(m mod d = r) ==> \<exists>q::nat. m = r + q*d"
   655   apply (cut_tac m = m in mod_div_equality)
   656   apply (simp only: add_ac)
   657   apply (blast intro: sym)
   658   done
   659 
   660 
   661 lemma split_div:
   662  "P(n div k :: nat) =
   663  ((k = 0 \<longrightarrow> P 0) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P i)))"
   664  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   665 proof
   666   assume P: ?P
   667   show ?Q
   668   proof (cases)
   669     assume "k = 0"
   670     with P show ?Q by(simp add:DIVISION_BY_ZERO_DIV)
   671   next
   672     assume not0: "k \<noteq> 0"
   673     thus ?Q
   674     proof (simp, intro allI impI)
   675       fix i j
   676       assume n: "n = k*i + j" and j: "j < k"
   677       show "P i"
   678       proof (cases)
   679         assume "i = 0"
   680         with n j P show "P i" by simp
   681       next
   682         assume "i \<noteq> 0"
   683         with not0 n j P show "P i" by(simp add:add_ac)
   684       qed
   685     qed
   686   qed
   687 next
   688   assume Q: ?Q
   689   show ?P
   690   proof (cases)
   691     assume "k = 0"
   692     with Q show ?P by(simp add:DIVISION_BY_ZERO_DIV)
   693   next
   694     assume not0: "k \<noteq> 0"
   695     with Q have R: ?R by simp
   696     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   697     show ?P by simp
   698   qed
   699 qed
   700 
   701 lemma split_div_lemma:
   702   "0 < n \<Longrightarrow> (n * q \<le> m \<and> m < n * (Suc q)) = (q = ((m::nat) div n))"
   703 apply (rule iffI)
   704  apply (rule_tac a=m and r = "m - n * q" and r' = "m mod n" in unique_quotient)
   705    prefer 3; apply assumption
   706   apply (simp_all add: quorem_def)
   707  apply arith
   708 apply (rule conjI)
   709  apply (rule_tac P="%x. n * (m div n) \<le> x" in
   710     subst [OF mod_div_equality [of _ n]])
   711  apply (simp only: add: mult_ac)
   712  apply (rule_tac P="%x. x < n + n * (m div n)" in
   713     subst [OF mod_div_equality [of _ n]])
   714 apply (simp only: add: mult_ac add_ac)
   715 apply (rule add_less_mono1, simp)
   716 done
   717 
   718 theorem split_div':
   719   "P ((m::nat) div n) = ((n = 0 \<and> P 0) \<or>
   720    (\<exists>q. (n * q \<le> m \<and> m < n * (Suc q)) \<and> P q))"
   721   apply (case_tac "0 < n")
   722   apply (simp only: add: split_div_lemma)
   723   apply (simp_all add: DIVISION_BY_ZERO_DIV)
   724   done
   725 
   726 lemma split_mod:
   727  "P(n mod k :: nat) =
   728  ((k = 0 \<longrightarrow> P n) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P j)))"
   729  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   730 proof
   731   assume P: ?P
   732   show ?Q
   733   proof (cases)
   734     assume "k = 0"
   735     with P show ?Q by(simp add:DIVISION_BY_ZERO_MOD)
   736   next
   737     assume not0: "k \<noteq> 0"
   738     thus ?Q
   739     proof (simp, intro allI impI)
   740       fix i j
   741       assume "n = k*i + j" "j < k"
   742       thus "P j" using not0 P by(simp add:add_ac mult_ac)
   743     qed
   744   qed
   745 next
   746   assume Q: ?Q
   747   show ?P
   748   proof (cases)
   749     assume "k = 0"
   750     with Q show ?P by(simp add:DIVISION_BY_ZERO_MOD)
   751   next
   752     assume not0: "k \<noteq> 0"
   753     with Q have R: ?R by simp
   754     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   755     show ?P by simp
   756   qed
   757 qed
   758 
   759 theorem mod_div_equality': "(m::nat) mod n = m - (m div n) * n"
   760   apply (rule_tac P="%x. m mod n = x - (m div n) * n" in
   761     subst [OF mod_div_equality [of _ n]])
   762   apply arith
   763   done
   764 
   765 lemma div_mod_equality':
   766   fixes m n :: nat
   767   shows "m div n * n = m - m mod n"
   768 proof -
   769   have "m mod n \<le> m mod n" ..
   770   from div_mod_equality have 
   771     "m div n * n + m mod n - m mod n = m - m mod n" by simp
   772   with diff_add_assoc [OF `m mod n \<le> m mod n`, of "m div n * n"] have
   773     "m div n * n + (m mod n - m mod n) = m - m mod n"
   774     by simp
   775   then show ?thesis by simp
   776 qed
   777 
   778 
   779 subsection {*An ``induction'' law for modulus arithmetic.*}
   780 
   781 lemma mod_induct_0:
   782   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
   783   and base: "P i" and i: "i<p"
   784   shows "P 0"
   785 proof (rule ccontr)
   786   assume contra: "\<not>(P 0)"
   787   from i have p: "0<p" by simp
   788   have "\<forall>k. 0<k \<longrightarrow> \<not> P (p-k)" (is "\<forall>k. ?A k")
   789   proof
   790     fix k
   791     show "?A k"
   792     proof (induct k)
   793       show "?A 0" by simp  -- "by contradiction"
   794     next
   795       fix n
   796       assume ih: "?A n"
   797       show "?A (Suc n)"
   798       proof (clarsimp)
   799         assume y: "P (p - Suc n)"
   800         have n: "Suc n < p"
   801         proof (rule ccontr)
   802           assume "\<not>(Suc n < p)"
   803           hence "p - Suc n = 0"
   804             by simp
   805           with y contra show "False"
   806             by simp
   807         qed
   808         hence n2: "Suc (p - Suc n) = p-n" by arith
   809         from p have "p - Suc n < p" by arith
   810         with y step have z: "P ((Suc (p - Suc n)) mod p)"
   811           by blast
   812         show "False"
   813         proof (cases "n=0")
   814           case True
   815           with z n2 contra show ?thesis by simp
   816         next
   817           case False
   818           with p have "p-n < p" by arith
   819           with z n2 False ih show ?thesis by simp
   820         qed
   821       qed
   822     qed
   823   qed
   824   moreover
   825   from i obtain k where "0<k \<and> i+k=p"
   826     by (blast dest: less_imp_add_positive)
   827   hence "0<k \<and> i=p-k" by auto
   828   moreover
   829   note base
   830   ultimately
   831   show "False" by blast
   832 qed
   833 
   834 lemma mod_induct:
   835   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
   836   and base: "P i" and i: "i<p" and j: "j<p"
   837   shows "P j"
   838 proof -
   839   have "\<forall>j<p. P j"
   840   proof
   841     fix j
   842     show "j<p \<longrightarrow> P j" (is "?A j")
   843     proof (induct j)
   844       from step base i show "?A 0"
   845         by (auto elim: mod_induct_0)
   846     next
   847       fix k
   848       assume ih: "?A k"
   849       show "?A (Suc k)"
   850       proof
   851         assume suc: "Suc k < p"
   852         hence k: "k<p" by simp
   853         with ih have "P k" ..
   854         with step k have "P (Suc k mod p)"
   855           by blast
   856         moreover
   857         from suc have "Suc k mod p = Suc k"
   858           by simp
   859         ultimately
   860         show "P (Suc k)" by simp
   861       qed
   862     qed
   863   qed
   864   with j show ?thesis by blast
   865 qed
   866 
   867 
   868 lemma mod_add_left_eq: "((a::nat) + b) mod c = (a mod c + b) mod c"
   869   apply (rule trans [symmetric])
   870    apply (rule mod_add1_eq, simp)
   871   apply (rule mod_add1_eq [symmetric])
   872   done
   873 
   874 lemma mod_add_right_eq: "(a+b) mod (c::nat) = (a + (b mod c)) mod c"
   875   apply (rule trans [symmetric])
   876    apply (rule mod_add1_eq, simp)
   877   apply (rule mod_add1_eq [symmetric])
   878   done
   879 
   880 lemma mod_div_decomp:
   881   fixes n k :: nat
   882   obtains m q where "m = n div k" and "q = n mod k"
   883     and "n = m * k + q"
   884 proof -
   885   from mod_div_equality have "n = n div k * k + n mod k" by auto
   886   moreover have "n div k = n div k" ..
   887   moreover have "n mod k = n mod k" ..
   888   note that ultimately show thesis by blast
   889 qed
   890 
   891 
   892 subsection {* Code generation for div, mod and dvd on nat *}
   893 
   894 definition [code func del]:
   895   "divmod (m\<Colon>nat) n = (m div n, m mod n)"
   896 
   897 lemma divmod_zero [code]: "divmod m 0 = (0, m)"
   898   unfolding divmod_def by simp
   899 
   900 lemma divmod_succ [code]:
   901   "divmod m (Suc k) = (if m < Suc k then (0, m) else
   902     let
   903       (p, q) = divmod (m - Suc k) (Suc k)
   904     in (Suc p, q))"
   905   unfolding divmod_def Let_def split_def
   906   by (auto intro: div_geq mod_geq)
   907 
   908 lemma div_divmod [code]: "m div n = fst (divmod m n)"
   909   unfolding divmod_def by simp
   910 
   911 lemma mod_divmod [code]: "m mod n = snd (divmod m n)"
   912   unfolding divmod_def by simp
   913 
   914 instance nat :: dvd_mod
   915   by default (simp add: dvd_eq_mod_eq_0)
   916 
   917 code_modulename SML
   918   Divides Nat
   919 
   920 code_modulename OCaml
   921   Divides Nat
   922 
   923 code_modulename Haskell
   924   Divides Nat
   925 
   926 hide (open) const divmod
   927 
   928 end