src/Provers/blast.ML
author wenzelm
Sun Nov 09 17:04:14 2014 +0100 (2014-11-09)
changeset 58957 c9e744ea8a38
parent 58956 a816aa3ff391
child 58958 114255dce178
permissions -rw-r--r--
proper context for match_tac etc.;
     1 (*  Title:      Provers/blast.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1997  University of Cambridge
     4 
     5 Generic tableau prover with proof reconstruction
     6 
     7   SKOLEMIZES ReplaceI WRONGLY: allow new vars in prems, or forbid such rules??
     8   Needs explicit instantiation of assumptions?
     9 
    10 Given the typeargs system, constructor Const could be eliminated, with
    11 TConst replaced by a constructor that takes the typargs list as an argument.
    12 However, Const is heavily used for logical connectives.
    13 
    14 Blast_tac is often more powerful than fast_tac, but has some limitations.
    15 Blast_tac...
    16   * ignores wrappers (addss, addbefore, addafter, addWrapper, ...);
    17     this restriction is intrinsic
    18   * ignores elimination rules that don't have the correct format
    19         (conclusion must be a formula variable)
    20   * rules must not require higher-order unification, e.g. apply_type in ZF
    21     + message "Function Var's argument not a bound variable" relates to this
    22   * its proof strategy is more general but can actually be slower
    23 
    24 Known problems:
    25   "Recursive" chains of rules can sometimes exclude other unsafe formulae
    26         from expansion.  This happens because newly-created formulae always
    27         have priority over existing ones.  But obviously recursive rules
    28         such as transitivity are treated specially to prevent this.  Sometimes
    29         the formulae get into the wrong order (see WRONG below).
    30 
    31   With substition for equalities (hyp_subst_tac):
    32         When substitution affects a haz formula or literal, it is moved
    33         back to the list of safe formulae.
    34         But there's no way of putting it in the right place.  A "moved" or
    35         "no DETERM" flag would prevent proofs failing here.
    36 *)
    37 
    38 signature BLAST_DATA =
    39 sig
    40   structure Classical: CLASSICAL
    41   val Trueprop_const: string * typ
    42   val equality_name: string
    43   val not_name: string
    44   val notE: thm           (* [| ~P;  P |] ==> R *)
    45   val ccontr: thm
    46   val hyp_subst_tac: Proof.context -> bool -> int -> tactic
    47 end;
    48 
    49 signature BLAST =
    50 sig
    51   exception TRANS of string    (*reports translation errors*)
    52   datatype term =
    53       Const of string * term list
    54     | Skolem of string * term option Unsynchronized.ref list
    55     | Free  of string
    56     | Var   of term option Unsynchronized.ref
    57     | Bound of int
    58     | Abs   of string*term
    59     | $  of term*term;
    60   val depth_tac: Proof.context -> int -> int -> tactic
    61   val depth_limit: int Config.T
    62   val trace: bool Config.T
    63   val stats: bool Config.T
    64   val blast_tac: Proof.context -> int -> tactic
    65   (*debugging tools*)
    66   type branch
    67   val tryIt: Proof.context -> int -> string ->
    68     {fullTrace: branch list list,
    69       result: ((int -> tactic) list * branch list list * (int * int * exn) list)}
    70 end;
    71 
    72 functor Blast(Data: BLAST_DATA): BLAST =
    73 struct
    74 
    75 structure Classical = Data.Classical;
    76 
    77 (* options *)
    78 
    79 val depth_limit = Attrib.setup_config_int @{binding blast_depth_limit} (K 20);
    80 val (trace, _) = Attrib.config_bool @{binding blast_trace} (K false);
    81 val (stats, _) = Attrib.config_bool @{binding blast_stats} (K false);
    82 
    83 
    84 datatype term =
    85     Const  of string * term list  (*typargs constant--as a terms!*)
    86   | Skolem of string * term option Unsynchronized.ref list
    87   | Free   of string
    88   | Var    of term option Unsynchronized.ref
    89   | Bound  of int
    90   | Abs    of string*term
    91   | op $   of term*term;
    92 
    93 (*Pending formulae carry md (may duplicate) flags*)
    94 type branch =
    95     {pairs: ((term*bool) list * (*safe formulae on this level*)
    96                (term*bool) list) list,  (*haz formulae  on this level*)
    97      lits:   term list,                 (*literals: irreducible formulae*)
    98      vars:   term option Unsynchronized.ref list,  (*variables occurring in branch*)
    99      lim:    int};                      (*resource limit*)
   100 
   101 
   102 (* global state information *)
   103 
   104 datatype state = State of
   105  {ctxt: Proof.context,
   106   names: Name.context Unsynchronized.ref,
   107   fullTrace: branch list list Unsynchronized.ref,
   108   trail: term option Unsynchronized.ref list Unsynchronized.ref,
   109   ntrail: int Unsynchronized.ref,
   110   nclosed: int Unsynchronized.ref,
   111   ntried: int Unsynchronized.ref}
   112 
   113 fun reject_const thy c =
   114   is_some (Sign.const_type thy c) andalso
   115     error ("blast: theory contains illegal constant " ^ quote c);
   116 
   117 fun initialize ctxt =
   118   let
   119     val thy = Proof_Context.theory_of ctxt;
   120     val _ = reject_const thy "*Goal*";
   121     val _ = reject_const thy "*False*";
   122   in
   123     State
   124      {ctxt = ctxt,
   125       names = Unsynchronized.ref (Variable.names_of ctxt),
   126       fullTrace = Unsynchronized.ref [],
   127       trail = Unsynchronized.ref [],
   128       ntrail = Unsynchronized.ref 0,
   129       nclosed = Unsynchronized.ref 0, (*number of branches closed during the search*)
   130       ntried = Unsynchronized.ref 1} (*number of branches created by splitting (counting from 1)*)
   131   end;
   132 
   133 fun gensym (State {names, ...}) x =
   134   Unsynchronized.change_result names (Name.variant x);
   135 
   136 
   137 (** Basic syntactic operations **)
   138 
   139 fun is_Var (Var _) = true
   140   | is_Var _ = false;
   141 
   142 fun dest_Var (Var x) =  x;
   143 
   144 fun rand (f$x) = x;
   145 
   146 (* maps   (f, [t1,...,tn])  to  f(t1,...,tn) *)
   147 val list_comb : term * term list -> term = Library.foldl (op $);
   148 
   149 (* maps   f(t1,...,tn)  to  (f, [t1,...,tn]) ; naturally tail-recursive*)
   150 fun strip_comb u : term * term list =
   151     let fun stripc (f$t, ts) = stripc (f, t::ts)
   152         |   stripc  x =  x
   153     in  stripc(u,[])  end;
   154 
   155 (* maps   f(t1,...,tn)  to  f , which is never a combination *)
   156 fun head_of (f$t) = head_of f
   157   | head_of u = u;
   158 
   159 
   160 (** Particular constants **)
   161 
   162 fun negate P = Const (Data.not_name, []) $ P;
   163 
   164 fun isNot (Const (c, _) $ _) = c = Data.not_name
   165   | isNot _ = false;
   166 
   167 fun mkGoal P = Const ("*Goal*", []) $ P;
   168 
   169 fun isGoal (Const ("*Goal*", _) $ _) = true
   170   | isGoal _ = false;
   171 
   172 val (TruepropC, TruepropT) = Data.Trueprop_const;
   173 
   174 fun mk_Trueprop t = Term.$ (Term.Const (TruepropC, TruepropT), t);
   175 
   176 fun strip_Trueprop (tm as Const (c, _) $ t) = if c = TruepropC then t else tm
   177   | strip_Trueprop tm = tm;
   178 
   179 
   180 
   181 (*** Dealing with overloaded constants ***)
   182 
   183 (*alist is a map from TVar names to Vars.  We need to unify the TVars
   184   faithfully in order to track overloading*)
   185 fun fromType alist (Term.Type(a,Ts)) = list_comb (Const (a, []), map (fromType alist) Ts)
   186   | fromType alist (Term.TFree(a,_)) = Free a
   187   | fromType alist (Term.TVar (ixn,_)) =
   188               (case (AList.lookup (op =) (!alist) ixn) of
   189                    NONE => let val t' = Var (Unsynchronized.ref NONE)
   190                            in  alist := (ixn, t') :: !alist;  t'
   191                            end
   192                  | SOME v => v)
   193 
   194 fun fromConst thy alist (a, T) =
   195   Const (a, map (fromType alist) (Sign.const_typargs thy (a, T)));
   196 
   197 
   198 (*Tests whether 2 terms are alpha-convertible; chases instantiations*)
   199 fun (Const (a, ts)) aconv (Const (b, us)) = a = b andalso aconvs (ts, us)
   200   | (Skolem (a,_)) aconv (Skolem (b,_)) = a = b  (*arglists must then be equal*)
   201   | (Free a) aconv (Free b) = a = b
   202   | (Var (Unsynchronized.ref(SOME t))) aconv u = t aconv u
   203   | t aconv (Var (Unsynchronized.ref (SOME u))) = t aconv u
   204   | (Var v)        aconv (Var w)        = v=w   (*both Vars are un-assigned*)
   205   | (Bound i)      aconv (Bound j)      = i=j
   206   | (Abs(_,t))     aconv (Abs(_,u))     = t aconv u
   207   | (f$t)          aconv (g$u)          = (f aconv g) andalso (t aconv u)
   208   | _ aconv _  =  false
   209 and aconvs ([], []) = true
   210   | aconvs (t :: ts, u :: us) = t aconv u andalso aconvs (ts, us)
   211   | aconvs _ = false;
   212 
   213 
   214 fun mem_term (_, [])     = false
   215   | mem_term (t, t'::ts) = t aconv t' orelse mem_term(t,ts);
   216 
   217 fun ins_term(t,ts) = if mem_term(t,ts) then ts else t :: ts;
   218 
   219 fun mem_var (v: term option Unsynchronized.ref, []) = false
   220   | mem_var (v, v'::vs)              = v=v' orelse mem_var(v,vs);
   221 
   222 fun ins_var(v,vs) = if mem_var(v,vs) then vs else v :: vs;
   223 
   224 
   225 (** Vars **)
   226 
   227 (*Accumulates the Vars in the term, suppressing duplicates*)
   228 fun add_term_vars (Skolem(a,args),  vars) = add_vars_vars(args,vars)
   229   | add_term_vars (Var (v as Unsynchronized.ref NONE), vars) = ins_var (v, vars)
   230   | add_term_vars (Var (Unsynchronized.ref (SOME u)), vars) = add_term_vars (u, vars)
   231   | add_term_vars (Const (_, ts), vars) = add_terms_vars (ts, vars)
   232   | add_term_vars (Abs (_, body), vars) = add_term_vars (body, vars)
   233   | add_term_vars (f $ t, vars) = add_term_vars (f, add_term_vars (t, vars))
   234   | add_term_vars (_, vars) = vars
   235 (*Term list version.  [The fold functionals are slow]*)
   236 and add_terms_vars ([],    vars) = vars
   237   | add_terms_vars (t::ts, vars) = add_terms_vars (ts, add_term_vars(t,vars))
   238 (*Var list version.*)
   239 and add_vars_vars ([], vars) = vars
   240   | add_vars_vars (Unsynchronized.ref (SOME u) :: vs, vars) =
   241         add_vars_vars (vs, add_term_vars(u,vars))
   242   | add_vars_vars (v::vs, vars) =   (*v must be a ref NONE*)
   243         add_vars_vars (vs, ins_var (v, vars));
   244 
   245 
   246 (*Chase assignments in "vars"; return a list of unassigned variables*)
   247 fun vars_in_vars vars = add_vars_vars(vars,[]);
   248 
   249 
   250 
   251 (*increment a term's non-local bound variables
   252      inc is  increment for bound variables
   253      lev is  level at which a bound variable is considered 'loose'*)
   254 fun incr_bv (inc, lev, u as Bound i) = if i>=lev then Bound(i+inc) else u
   255   | incr_bv (inc, lev, Abs(a,body)) = Abs(a, incr_bv(inc,lev+1,body))
   256   | incr_bv (inc, lev, f$t) = incr_bv(inc,lev,f) $ incr_bv(inc,lev,t)
   257   | incr_bv (inc, lev, u) = u;
   258 
   259 fun incr_boundvars  0  t = t
   260   | incr_boundvars inc t = incr_bv(inc,0,t);
   261 
   262 
   263 (*Accumulate all 'loose' bound vars referring to level 'lev' or beyond.
   264    (Bound 0) is loose at level 0 *)
   265 fun add_loose_bnos (Bound i, lev, js)   = if i<lev then js
   266                                           else insert (op =) (i - lev) js
   267   | add_loose_bnos (Abs (_,t), lev, js) = add_loose_bnos (t, lev+1, js)
   268   | add_loose_bnos (f$t, lev, js)       =
   269                 add_loose_bnos (f, lev, add_loose_bnos (t, lev, js))
   270   | add_loose_bnos (_, _, js)           = js;
   271 
   272 fun loose_bnos t = add_loose_bnos (t, 0, []);
   273 
   274 fun subst_bound (arg, t) : term =
   275   let fun subst (t as Bound i, lev) =
   276             if i<lev then  t    (*var is locally bound*)
   277             else  if i=lev then incr_boundvars lev arg
   278                            else Bound(i-1)  (*loose: change it*)
   279         | subst (Abs(a,body), lev) = Abs(a, subst(body,lev+1))
   280         | subst (f$t, lev) =  subst(f,lev)  $  subst(t,lev)
   281         | subst (t,lev)    = t
   282   in  subst (t,0)  end;
   283 
   284 
   285 (*Normalize...but not the bodies of ABSTRACTIONS*)
   286 fun norm t = case t of
   287     Skolem (a, args) => Skolem (a, vars_in_vars args)
   288   | Const (a, ts) => Const (a, map norm ts)
   289   | (Var (Unsynchronized.ref NONE)) => t
   290   | (Var (Unsynchronized.ref (SOME u))) => norm u
   291   | (f $ u) => (case norm f of
   292                     Abs(_,body) => norm (subst_bound (u, body))
   293                   | nf => nf $ norm u)
   294   | _ => t;
   295 
   296 
   297 (*Weak (one-level) normalize for use in unification*)
   298 fun wkNormAux t = case t of
   299     (Var v) => (case !v of
   300                     SOME u => wkNorm u
   301                   | NONE   => t)
   302   | (f $ u) => (case wkNormAux f of
   303                     Abs(_,body) => wkNorm (subst_bound (u, body))
   304                   | nf          => nf $ u)
   305   | Abs (a,body) =>     (*eta-contract if possible*)
   306         (case wkNormAux body of
   307              nb as (f $ t) =>
   308                  if member (op =) (loose_bnos f) 0 orelse wkNorm t <> Bound 0
   309                  then Abs(a,nb)
   310                  else wkNorm (incr_boundvars ~1 f)
   311            | nb => Abs (a,nb))
   312   | _ => t
   313 and wkNorm t = case head_of t of
   314     Const _        => t
   315   | Skolem(a,args) => t
   316   | Free _         => t
   317   | _              => wkNormAux t;
   318 
   319 
   320 (*Does variable v occur in u?  For unification.
   321   Dangling bound vars are also forbidden.*)
   322 fun varOccur v =
   323   let fun occL lev [] = false   (*same as (exists occ), but faster*)
   324         | occL lev (u::us) = occ lev u orelse occL lev us
   325       and occ lev (Var w) =
   326               v=w orelse
   327               (case !w of NONE   => false
   328                         | SOME u => occ lev u)
   329         | occ lev (Skolem(_,args)) = occL lev (map Var args)
   330             (*ignore Const, since term variables can't occur in types (?) *)
   331         | occ lev (Bound i)  = lev <= i
   332         | occ lev (Abs(_,u)) = occ (lev+1) u
   333         | occ lev (f$u)      = occ lev u  orelse  occ lev f
   334         | occ lev _          = false;
   335   in  occ 0  end;
   336 
   337 exception UNIFY;
   338 
   339 
   340 (*Restore the trail to some previous state: for backtracking*)
   341 fun clearTo (State {ntrail, trail, ...}) n =
   342     while !ntrail<>n do
   343         (hd(!trail) := NONE;
   344          trail := tl (!trail);
   345          ntrail := !ntrail - 1);
   346 
   347 
   348 (*First-order unification with bound variables.
   349   "vars" is a list of variables local to the rule and NOT to be put
   350         on the trail (no point in doing so)
   351 *)
   352 fun unify state (vars,t,u) =
   353     let val State {ntrail, trail, ...} = state
   354         val n = !ntrail
   355         fun update (t as Var v, u) =
   356             if t aconv u then ()
   357             else if varOccur v u then raise UNIFY
   358             else if mem_var(v, vars) then v := SOME u
   359                  else (*avoid updating Vars in the branch if possible!*)
   360                       if is_Var u andalso mem_var(dest_Var u, vars)
   361                       then dest_Var u := SOME t
   362                       else (v := SOME u;
   363                             trail := v :: !trail;  ntrail := !ntrail + 1)
   364         fun unifyAux (t,u) =
   365             case (wkNorm t,  wkNorm u) of
   366                 (nt as Var v,  nu) => update(nt,nu)
   367               | (nu,  nt as Var v) => update(nt,nu)
   368               | (Const(a,ats), Const(b,bts)) => if a=b then unifysAux(ats,bts)
   369                                                 else raise UNIFY
   370               | (Abs(_,t'),  Abs(_,u')) => unifyAux(t',u')
   371                     (*NB: can yield unifiers having dangling Bound vars!*)
   372               | (f$t',  g$u') => (unifyAux(f,g); unifyAux(t',u'))
   373               | (nt,  nu)    => if nt aconv nu then () else raise UNIFY
   374         and unifysAux ([], []) = ()
   375           | unifysAux (t :: ts, u :: us) = (unifyAux (t, u); unifysAux (ts, us))
   376           | unifysAux _ = raise UNIFY;
   377     in  (unifyAux(t,u); true) handle UNIFY => (clearTo state n; false)
   378     end;
   379 
   380 
   381 (*Convert from "real" terms to prototerms; eta-contract.
   382   Code is similar to fromSubgoal.*)
   383 fun fromTerm thy t =
   384   let val alistVar = Unsynchronized.ref []
   385       and alistTVar = Unsynchronized.ref []
   386       fun from (Term.Const aT) = fromConst thy alistTVar aT
   387         | from (Term.Free  (a,_)) = Free a
   388         | from (Term.Bound i)     = Bound i
   389         | from (Term.Var (ixn,T)) =
   390               (case (AList.lookup (op =) (!alistVar) ixn) of
   391                    NONE => let val t' = Var (Unsynchronized.ref NONE)
   392                            in  alistVar := (ixn, t') :: !alistVar;  t'
   393                            end
   394                  | SOME v => v)
   395         | from (Term.Abs (a,_,u)) =
   396               (case  from u  of
   397                 u' as (f $ Bound 0) =>
   398                   if member (op =) (loose_bnos f) 0 then Abs(a,u')
   399                   else incr_boundvars ~1 f
   400               | u' => Abs(a,u'))
   401         | from (Term.$ (f,u)) = from f $ from u
   402   in  from t  end;
   403 
   404 (*A debugging function: replaces all Vars by dummy Frees for visual inspection
   405   of whether they are distinct.  Function revert undoes the assignments.*)
   406 fun instVars t =
   407   let val name = Unsynchronized.ref "a"
   408       val updated = Unsynchronized.ref []
   409       fun inst (Const(a,ts)) = List.app inst ts
   410         | inst (Var(v as Unsynchronized.ref NONE)) = (updated := v :: (!updated);
   411                                        v       := SOME (Free ("?" ^ !name));
   412                                        name    := Symbol.bump_string (!name))
   413         | inst (Abs(a,t))    = inst t
   414         | inst (f $ u)       = (inst f; inst u)
   415         | inst _             = ()
   416       fun revert() = List.app (fn v => v:=NONE) (!updated)
   417   in  inst t; revert  end;
   418 
   419 
   420 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   421 fun strip_imp_prems (Const (@{const_name Pure.imp}, _) $ A $ B) =
   422       strip_Trueprop A :: strip_imp_prems B
   423   | strip_imp_prems _ = [];
   424 
   425 (* A1==>...An==>B  goes to B, where B is not an implication *)
   426 fun strip_imp_concl (Const (@{const_name Pure.imp}, _) $ A $ B) = strip_imp_concl B
   427   | strip_imp_concl A = strip_Trueprop A;
   428 
   429 
   430 
   431 (*** Conversion of Elimination Rules to Tableau Operations ***)
   432 
   433 exception ElimBadConcl and ElimBadPrem;
   434 
   435 (*The conclusion becomes the goal/negated assumption *False*: delete it!
   436   If we don't find it then the premise is ill-formed and could cause
   437   PROOF FAILED*)
   438 fun delete_concl [] = raise ElimBadPrem
   439   | delete_concl (P :: Ps) =
   440       (case P of
   441         Const (c, _) $ Var (Unsynchronized.ref (SOME (Const ("*False*", _)))) =>
   442           if c = "*Goal*" orelse c = Data.not_name then Ps
   443           else P :: delete_concl Ps
   444       | _ => P :: delete_concl Ps);
   445 
   446 fun skoPrem state vars (Const (@{const_name Pure.all}, _) $ Abs (_, P)) =
   447         skoPrem state vars (subst_bound (Skolem (gensym state "S", vars), P))
   448   | skoPrem _ _ P = P;
   449 
   450 fun convertPrem t =
   451     delete_concl (mkGoal (strip_imp_concl t) :: strip_imp_prems t);
   452 
   453 (*Expects elimination rules to have a formula variable as conclusion*)
   454 fun convertRule state vars t =
   455   let val (P::Ps) = strip_imp_prems t
   456       val Var v   = strip_imp_concl t
   457   in  v := SOME (Const ("*False*", []));
   458       (P, map (convertPrem o skoPrem state vars) Ps)
   459   end
   460   handle Bind => raise ElimBadConcl;
   461 
   462 
   463 (*Like dup_elim, but puts the duplicated major premise FIRST*)
   464 fun rev_dup_elim th = (th RSN (2, revcut_rl)) |> Thm.assumption NONE 2 |> Seq.hd;
   465 
   466 
   467 (*Rotate the assumptions in all new subgoals for the LIFO discipline*)
   468 local
   469   (*Count new hyps so that they can be rotated*)
   470   fun nNewHyps []                         = 0
   471     | nNewHyps (Const ("*Goal*", _) $ _ :: Ps) = nNewHyps Ps
   472     | nNewHyps (P::Ps)                    = 1 + nNewHyps Ps;
   473 
   474   fun rot_tac [] i st      = Seq.single st
   475     | rot_tac (0::ks) i st = rot_tac ks (i+1) st
   476     | rot_tac (k::ks) i st = rot_tac ks (i+1) (Thm.rotate_rule (~k) i st);
   477 in
   478 fun rot_subgoals_tac (rot, rl) =
   479      rot_tac (if rot then map nNewHyps rl else [])
   480 end;
   481 
   482 
   483 fun cond_tracing true msg = tracing (msg ())
   484   | cond_tracing false _ = ();
   485 
   486 fun TRACE ctxt rl tac i st =
   487   (cond_tracing (Config.get ctxt trace) (fn () => Display.string_of_thm ctxt rl); tac i st);
   488 
   489 (*Resolution/matching tactics: if upd then the proof state may be updated.
   490   Matching makes the tactics more deterministic in the presence of Vars.*)
   491 fun emtac ctxt upd rl = TRACE ctxt rl (if upd then eresolve_tac [rl] else ematch_tac ctxt [rl]);
   492 fun rmtac ctxt upd rl = TRACE ctxt rl (if upd then resolve_tac [rl] else match_tac ctxt [rl]);
   493 
   494 (*Tableau rule from elimination rule.
   495   Flag "upd" says that the inference updated the branch.
   496   Flag "dup" requests duplication of the affected formula.*)
   497 fun fromRule (state as State {ctxt, ...}) vars rl =
   498   let val thy = Proof_Context.theory_of ctxt
   499       val trl = rl |> Thm.prop_of |> fromTerm thy |> convertRule state vars
   500       fun tac (upd, dup,rot) i =
   501         emtac ctxt upd (if dup then rev_dup_elim rl else rl) i
   502         THEN
   503         rot_subgoals_tac (rot, #2 trl) i
   504   in Option.SOME (trl, tac) end
   505   handle
   506     ElimBadPrem => (*reject: prems don't preserve conclusion*)
   507       (if Context_Position.is_visible ctxt then
   508         warning ("Ignoring weak elimination rule\n" ^ Display.string_of_thm ctxt rl)
   509        else ();
   510        Option.NONE)
   511   | ElimBadConcl => (*ignore: conclusion is not just a variable*)
   512       (cond_tracing (Config.get ctxt trace)
   513         (fn () => "Ignoring ill-formed elimination rule:\n" ^
   514           "conclusion should be a variable\n" ^ Display.string_of_thm ctxt rl);
   515        Option.NONE);
   516 
   517 
   518 (*** Conversion of Introduction Rules ***)
   519 
   520 fun convertIntrPrem t = mkGoal (strip_imp_concl t) :: strip_imp_prems t;
   521 
   522 fun convertIntrRule state vars t =
   523   let val Ps = strip_imp_prems t
   524       val P  = strip_imp_concl t
   525   in  (mkGoal P, map (convertIntrPrem o skoPrem state vars) Ps)
   526   end;
   527 
   528 (*Tableau rule from introduction rule.
   529   Flag "upd" says that the inference updated the branch.
   530   Flag "dup" requests duplication of the affected formula.
   531   Since haz rules are now delayed, "dup" is always FALSE for
   532   introduction rules.*)
   533 fun fromIntrRule (state as State {ctxt, ...}) vars rl =
   534   let val thy = Proof_Context.theory_of ctxt
   535       val trl = rl |> Thm.prop_of |> fromTerm thy |> convertIntrRule state vars
   536       fun tac (upd,dup,rot) i =
   537          rmtac ctxt upd (if dup then Classical.dup_intr rl else rl) i
   538          THEN
   539          rot_subgoals_tac (rot, #2 trl) i
   540   in (trl, tac) end;
   541 
   542 
   543 val dummyVar = Term.Var (("etc",0), dummyT);
   544 
   545 (*Convert from prototerms to ordinary terms with dummy types
   546   Ignore abstractions; identify all Vars; STOP at given depth*)
   547 fun toTerm 0 _             = dummyVar
   548   | toTerm d (Const(a,_))  = Term.Const (a,dummyT)  (*no need to convert typargs*)
   549   | toTerm d (Skolem(a,_)) = Term.Const (a,dummyT)
   550   | toTerm d (Free a)      = Term.Free  (a,dummyT)
   551   | toTerm d (Bound i)     = Term.Bound i
   552   | toTerm d (Var _)       = dummyVar
   553   | toTerm d (Abs(a,_))    = dummyVar
   554   | toTerm d (f $ u)       = Term.$ (toTerm d f, toTerm (d-1) u);
   555 
   556 
   557 fun netMkRules state P vars (nps: Classical.netpair list) =
   558   case P of
   559       (Const ("*Goal*", _) $ G) =>
   560         let val pG = mk_Trueprop (toTerm 2 G)
   561             val intrs = maps (fn (inet,_) => Net.unify_term inet pG) nps
   562         in  map (fromIntrRule state vars o #2) (order_list intrs)  end
   563     | _ =>
   564         let val pP = mk_Trueprop (toTerm 3 P)
   565             val elims = maps (fn (_,enet) => Net.unify_term enet pP) nps
   566         in  map_filter (fromRule state vars o #2) (order_list elims)  end;
   567 
   568 
   569 (*Normalize a branch--for tracing*)
   570 fun norm2 (G,md) = (norm G, md);
   571 
   572 fun normLev (Gs,Hs) = (map norm2 Gs, map norm2 Hs);
   573 
   574 fun normBr {pairs, lits, vars, lim} =
   575      {pairs = map normLev pairs,
   576       lits  = map norm lits,
   577       vars  = vars,
   578       lim   = lim};
   579 
   580 
   581 val dummyTVar = Term.TVar(("a",0), []);
   582 val dummyVar2 = Term.Var(("var",0), dummyT);
   583 
   584 (*convert blast_tac's type representation to real types for tracing*)
   585 fun showType (Free a)  = Term.TFree (a,[])
   586   | showType (Var _)   = dummyTVar
   587   | showType t         =
   588       (case strip_comb t of
   589            (Const (a, _), us) => Term.Type(a, map showType us)
   590          | _ => dummyT);
   591 
   592 (*Display top-level overloading if any*)
   593 fun topType thy (Const (c, ts)) = SOME (Sign.const_instance thy (c, map showType ts))
   594   | topType thy (Abs(a,t)) = topType thy t
   595   | topType thy (f $ u) = (case topType thy f of NONE => topType thy u | some => some)
   596   | topType _ _ = NONE;
   597 
   598 
   599 (*Convert from prototerms to ordinary terms with dummy types for tracing*)
   600 fun showTerm d (Const (a,_)) = Term.Const (a,dummyT)
   601   | showTerm d (Skolem(a,_)) = Term.Const (a,dummyT)
   602   | showTerm d (Free a) = Term.Free  (a,dummyT)
   603   | showTerm d (Bound i) = Term.Bound i
   604   | showTerm d (Var (Unsynchronized.ref(SOME u))) = showTerm d u
   605   | showTerm d (Var (Unsynchronized.ref NONE)) = dummyVar2
   606   | showTerm d (Abs(a,t))    = if d=0 then dummyVar
   607                                else Term.Abs(a, dummyT, showTerm (d-1) t)
   608   | showTerm d (f $ u)       = if d=0 then dummyVar
   609                                else Term.$ (showTerm d f, showTerm (d-1) u);
   610 
   611 fun string_of ctxt d t = Syntax.string_of_term ctxt (showTerm d t);
   612 
   613 (*Convert a Goal to an ordinary Not.  Used also in dup_intr, where a goal like
   614   Ex(P) is duplicated as the assumption ~Ex(P). *)
   615 fun negOfGoal (Const ("*Goal*", _) $ G) = negate G
   616   | negOfGoal G = G;
   617 
   618 fun negOfGoal2 (G,md) = (negOfGoal G, md);
   619 
   620 (*Converts all Goals to Nots in the safe parts of a branch.  They could
   621   have been moved there from the literals list after substitution (equalSubst).
   622   There can be at most one--this function could be made more efficient.*)
   623 fun negOfGoals pairs = map (fn (Gs,haz) => (map negOfGoal2 Gs, haz)) pairs;
   624 
   625 (*Tactic.  Convert *Goal* to negated assumption in FIRST position*)
   626 fun negOfGoal_tac ctxt i =
   627   TRACE ctxt Data.ccontr (resolve_tac [Data.ccontr]) i THEN rotate_tac ~1 i;
   628 
   629 fun traceTerm ctxt t =
   630   let val thy = Proof_Context.theory_of ctxt
   631       val t' = norm (negOfGoal t)
   632       val stm = string_of ctxt 8 t'
   633   in
   634       case topType thy t' of
   635           NONE   => stm   (*no type to attach*)
   636         | SOME T => stm ^ " :: " ^ Syntax.string_of_typ ctxt T
   637   end;
   638 
   639 
   640 (*Print tracing information at each iteration of prover*)
   641 fun trace_prover (State {ctxt, fullTrace, ...}) brs =
   642   let fun printPairs (((G,_)::_,_)::_)  = tracing (traceTerm ctxt G)
   643         | printPairs (([],(H,_)::_)::_) = tracing (traceTerm ctxt H ^ "  (Unsafe)")
   644         | printPairs _                 = ()
   645       fun printBrs (brs0 as {pairs, lits, lim, ...} :: brs) =
   646             (fullTrace := brs0 :: !fullTrace;
   647              List.app (fn _ => tracing "+") brs;
   648              tracing (" [" ^ string_of_int lim ^ "] ");
   649              printPairs pairs;
   650              tracing "")
   651   in if Config.get ctxt trace then printBrs (map normBr brs) else () end;
   652 
   653 (*Tracing: variables updated in the last branch operation?*)
   654 fun traceVars (State {ctxt, ntrail, trail, ...}) ntrl =
   655   if Config.get ctxt trace then
   656       (case !ntrail-ntrl of
   657             0 => ()
   658           | 1 => tracing " 1 variable UPDATED:"
   659           | n => tracing (" " ^ string_of_int n ^ " variables UPDATED:");
   660        (*display the instantiations themselves, though no variable names*)
   661        List.app (fn v => tracing ("   " ^ string_of ctxt 4 (the (!v))))
   662            (List.take(!trail, !ntrail-ntrl));
   663        tracing "")
   664     else ();
   665 
   666 (*Tracing: how many new branches are created?*)
   667 fun traceNew true prems =
   668       (case length prems of
   669         0 => tracing "branch closed by rule"
   670       | 1 => tracing "branch extended (1 new subgoal)"
   671       | n => tracing ("branch split: "^ string_of_int n ^ " new subgoals"))
   672   | traceNew _ _ = ();
   673 
   674 
   675 
   676 (*** Code for handling equality: naive substitution, like hyp_subst_tac ***)
   677 
   678 (*Replace the ATOMIC term "old" by "new" in t*)
   679 fun subst_atomic (old,new) t =
   680     let fun subst (Var(Unsynchronized.ref(SOME u))) = subst u
   681           | subst (Abs(a,body)) = Abs(a, subst body)
   682           | subst (f$t) = subst f $ subst t
   683           | subst t = if t aconv old then new else t
   684     in  subst t  end;
   685 
   686 (*Eta-contract a term from outside: just enough to reduce it to an atom*)
   687 fun eta_contract_atom (t0 as Abs(a, body)) =
   688       (case  eta_contract2 body  of
   689         f $ Bound 0 => if member (op =) (loose_bnos f) 0 then t0
   690                        else eta_contract_atom (incr_boundvars ~1 f)
   691       | _ => t0)
   692   | eta_contract_atom t = t
   693 and eta_contract2 (f$t) = f $ eta_contract_atom t
   694   | eta_contract2 t     = eta_contract_atom t;
   695 
   696 
   697 (*When can we safely delete the equality?
   698     Not if it equates two constants; consider 0=1.
   699     Not if it resembles x=t[x], since substitution does not eliminate x.
   700     Not if it resembles ?x=0; another goal could instantiate ?x to Suc(i)
   701   Prefer to eliminate Bound variables if possible.
   702   Result:  true = use as is,  false = reorient first *)
   703 
   704 (*Can t occur in u?  For substitution.
   705   Does NOT examine the args of Skolem terms: substitution does not affect them.
   706   REFLEXIVE because hyp_subst_tac fails on x=x.*)
   707 fun substOccur t =
   708   let (*NO vars are permitted in u except the arguments of t, if it is
   709         a Skolem term.  This ensures that no equations are deleted that could
   710         be instantiated to a cycle.  For example, x=?a is rejected because ?a
   711         could be instantiated to Suc(x).*)
   712       val vars = case t of
   713                      Skolem(_,vars) => vars
   714                    | _ => []
   715       fun occEq u = (t aconv u) orelse occ u
   716       and occ (Var(Unsynchronized.ref(SOME u))) = occEq u
   717         | occ (Var v) = not (mem_var (v, vars))
   718         | occ (Abs(_,u)) = occEq u
   719         | occ (f$u) = occEq u  orelse  occEq f
   720         | occ _ = false;
   721   in  occEq  end;
   722 
   723 exception DEST_EQ;
   724 
   725 (*Take apart an equality.  NO constant Trueprop*)
   726 fun dest_eq (Const (c, _) $ t $ u) =
   727       if c = Data.equality_name then (eta_contract_atom t, eta_contract_atom u)
   728       else raise DEST_EQ
   729   | dest_eq _ = raise DEST_EQ;
   730 
   731 (*Reject the equality if u occurs in (or equals!) t*)
   732 fun check (t,u,v) = if substOccur t u then raise DEST_EQ else v;
   733 
   734 (*IF the goal is an equality with a substitutable variable
   735   THEN orient that equality ELSE raise exception DEST_EQ*)
   736 fun orientGoal (t,u) = case (t,u) of
   737        (Skolem _, _) => check(t,u,(t,u))        (*eliminates t*)
   738      | (_, Skolem _) => check(u,t,(u,t))        (*eliminates u*)
   739      | (Free _, _)   => check(t,u,(t,u))        (*eliminates t*)
   740      | (_, Free _)   => check(u,t,(u,t))        (*eliminates u*)
   741      | _             => raise DEST_EQ;
   742 
   743 (*Substitute through the branch if an equality goal (else raise DEST_EQ).
   744   Moves affected literals back into the branch, but it is not clear where
   745   they should go: this could make proofs fail.*)
   746 fun equalSubst ctxt (G, {pairs, lits, vars, lim}) =
   747   let val (t,u) = orientGoal(dest_eq G)
   748       val subst = subst_atomic (t,u)
   749       fun subst2(G,md) = (subst G, md)
   750       (*substitute throughout list; extract affected formulae*)
   751       fun subForm ((G,md), (changed, pairs)) =
   752             let val nG = subst G
   753             in  if nG aconv G then (changed, (G,md)::pairs)
   754                               else ((nG,md)::changed, pairs)
   755             end
   756       (*substitute throughout "stack frame"; extract affected formulae*)
   757       fun subFrame ((Gs,Hs), (changed, frames)) =
   758             let val (changed', Gs') = List.foldr subForm (changed, []) Gs
   759                 val (changed'', Hs') = List.foldr subForm (changed', []) Hs
   760             in  (changed'', (Gs',Hs')::frames)  end
   761       (*substitute throughout literals; extract affected ones*)
   762       fun subLit (lit, (changed, nlits)) =
   763             let val nlit = subst lit
   764             in  if nlit aconv lit then (changed, nlit::nlits)
   765                                   else ((nlit,true)::changed, nlits)
   766             end
   767       val (changed, lits') = List.foldr subLit ([], []) lits
   768       val (changed', pairs') = List.foldr subFrame (changed, []) pairs
   769   in  if Config.get ctxt trace then tracing ("Substituting " ^ traceTerm ctxt u ^
   770                               " for " ^ traceTerm ctxt t ^ " in branch" )
   771       else ();
   772       {pairs = (changed',[])::pairs',   (*affected formulas, and others*)
   773        lits  = lits',                   (*unaffected literals*)
   774        vars  = vars,
   775        lim   = lim}
   776   end;
   777 
   778 
   779 exception NEWBRANCHES and CLOSEF;
   780 
   781 exception PROVE;
   782 
   783 (*Trying eq_contr_tac first INCREASES the effort, slowing reconstruction*)
   784 fun contr_tac ctxt =
   785   ematch_tac ctxt [Data.notE] THEN' (eq_assume_tac ORELSE' assume_tac);
   786 
   787 (*Try to unify complementary literals and return the corresponding tactic. *)
   788 fun tryClose state (G, L) =
   789   let
   790     val State {ctxt, ...} = state;
   791     val eContr_tac = TRACE ctxt Data.notE contr_tac;
   792     val eAssume_tac = TRACE ctxt asm_rl (eq_assume_tac ORELSE' assume_tac);
   793     fun close t u tac = if unify state ([], t, u) then SOME tac else NONE;
   794     fun arg (_ $ t) = t;
   795   in
   796     if isGoal G then close (arg G) L eAssume_tac
   797     else if isGoal L then close G (arg L) eAssume_tac
   798     else if isNot G then close (arg G) L (eContr_tac ctxt)
   799     else if isNot L then close G (arg L) (eContr_tac ctxt)
   800     else NONE
   801   end;
   802 
   803 (*Were there Skolem terms in the premise?  Must NOT chase Vars*)
   804 fun hasSkolem (Skolem _)     = true
   805   | hasSkolem (Abs (_,body)) = hasSkolem body
   806   | hasSkolem (f$t)          = hasSkolem f orelse hasSkolem t
   807   | hasSkolem _              = false;
   808 
   809 (*Attach the right "may duplicate" flag to new formulae: if they contain
   810   Skolem terms then allow duplication.*)
   811 fun joinMd md [] = []
   812   | joinMd md (G::Gs) = (G, hasSkolem G orelse md) :: joinMd md Gs;
   813 
   814 
   815 (** Backtracking and Pruning **)
   816 
   817 (*clashVar vars (n,trail) determines whether any of the last n elements
   818   of "trail" occur in "vars" OR in their instantiations*)
   819 fun clashVar [] = (fn _ => false)
   820   | clashVar vars =
   821       let fun clash (0, _)     = false
   822             | clash (_, [])    = false
   823             | clash (n, v::vs) = exists (varOccur v) vars orelse clash(n-1,vs)
   824       in  clash  end;
   825 
   826 
   827 (*nbrs = # of branches just prior to closing this one.  Delete choice points
   828   for goals proved by the latest inference, provided NO variables in the
   829   next branch have been updated.*)
   830 fun prune _ (1, nxtVars, choices) = choices  (*DON'T prune at very end: allow
   831                                              backtracking over bad proofs*)
   832   | prune (State {ctxt, ntrail, trail, ...}) (nbrs: int, nxtVars, choices) =
   833       let fun traceIt last =
   834                 let val ll = length last
   835                     and lc = length choices
   836                 in if Config.get ctxt trace andalso ll<lc then
   837                     (tracing ("Pruning " ^ string_of_int(lc-ll) ^ " levels");
   838                      last)
   839                    else last
   840                 end
   841           fun pruneAux (last, _, _, []) = last
   842             | pruneAux (last, ntrl, trl, (ntrl',nbrs',exn) :: choices) =
   843                 if nbrs' < nbrs
   844                 then last  (*don't backtrack beyond first solution of goal*)
   845                 else if nbrs' > nbrs then pruneAux (last, ntrl, trl, choices)
   846                 else (* nbrs'=nbrs *)
   847                      if clashVar nxtVars (ntrl-ntrl', trl) then last
   848                      else (*no clashes: can go back at least this far!*)
   849                           pruneAux(choices, ntrl', List.drop(trl, ntrl-ntrl'),
   850                                    choices)
   851   in  traceIt (pruneAux (choices, !ntrail, !trail, choices))  end;
   852 
   853 fun nextVars ({pairs, lits, vars, lim} :: _) = map Var vars
   854   | nextVars []                              = [];
   855 
   856 fun backtrack trace (choices as (ntrl, nbrs, exn)::_) =
   857       (cond_tracing trace
   858         (fn () => "Backtracking; now there are " ^ string_of_int nbrs ^ " branches");
   859        raise exn)
   860   | backtrack _ _ = raise PROVE;
   861 
   862 (*Add the literal G, handling *Goal* and detecting duplicates.*)
   863 fun addLit (Const ("*Goal*", _) $ G, lits) =
   864       (*New literal is a *Goal*, so change all other Goals to Nots*)
   865       let fun bad (Const ("*Goal*", _) $ _) = true
   866             | bad (Const (c, _) $ G')   = c = Data.not_name andalso G aconv G'
   867             | bad _                   = false;
   868           fun change [] = []
   869             | change (lit :: lits) =
   870                 (case lit of
   871                   Const (c, _) $ G' =>
   872                     if c = "*Goal*" orelse c = Data.not_name then
   873                       if G aconv G' then change lits
   874                       else negate G' :: change lits
   875                     else lit :: change lits
   876                 | _ => lit :: change lits)
   877       in
   878         Const ("*Goal*", []) $ G :: (if exists bad lits then change lits else lits)
   879       end
   880   | addLit (G,lits) = ins_term(G, lits)
   881 
   882 
   883 (*For calculating the "penalty" to assess on a branching factor of n
   884   log2 seems a little too severe*)
   885 fun log n = if n<4 then 0 else 1 + log(n div 4);
   886 
   887 
   888 (*match(t,u) says whether the term u might be an instance of the pattern t
   889   Used to detect "recursive" rules such as transitivity*)
   890 fun match (Var _) u   = true
   891   | match (Const (a,tas)) (Const (b,tbs)) =
   892       a = "*Goal*" andalso b = Data.not_name orelse
   893       a = Data.not_name andalso b = "*Goal*" orelse
   894       a = b andalso matchs tas tbs
   895   | match (Free a)        (Free b)        = (a=b)
   896   | match (Bound i)       (Bound j)       = (i=j)
   897   | match (Abs(_,t))      (Abs(_,u))      = match t u
   898   | match (f$t)           (g$u)           = match f g andalso match t u
   899   | match t               u   = false
   900 and matchs [] [] = true
   901   | matchs (t :: ts) (u :: us) = match t u andalso matchs ts us;
   902 
   903 
   904 fun printStats (State {ntried, nclosed, ...}) (b, start, tacs) =
   905   if b then
   906     tracing (Timing.message (Timing.result start) ^ " for search.  Closed: "
   907              ^ string_of_int (!nclosed) ^
   908              " tried: " ^ string_of_int (!ntried) ^
   909              " tactics: " ^ string_of_int (length tacs))
   910   else ();
   911 
   912 
   913 (*Tableau prover based on leanTaP.  Argument is a list of branches.  Each
   914   branch contains a list of unexpanded formulae, a list of literals, and a
   915   bound on unsafe expansions.
   916  "start" is CPU time at start, for printing search time
   917 *)
   918 fun prove (state, start, brs, cont) =
   919  let val State {ctxt, ntrail, nclosed, ntried, ...} = state;
   920      val trace = Config.get ctxt trace;
   921      val stats = Config.get ctxt stats;
   922      val {safe0_netpair, safep_netpair, haz_netpair, ...} =
   923        Classical.rep_cs (Classical.claset_of ctxt);
   924      val safeList = [safe0_netpair, safep_netpair]
   925      and hazList  = [haz_netpair]
   926      fun prv (tacs, trs, choices, []) =
   927                 (printStats state (trace orelse stats, start, tacs);
   928                  cont (tacs, trs, choices))   (*all branches closed!*)
   929        | prv (tacs, trs, choices,
   930               brs0 as {pairs = ((G,md)::br, haz)::pairs,
   931                        lits, vars, lim} :: brs) =
   932              (*apply a safe rule only (possibly allowing instantiation);
   933                defer any haz formulae*)
   934           let exception PRV (*backtrack to precisely this recursion!*)
   935               val ntrl = !ntrail
   936               val nbrs = length brs0
   937               val nxtVars = nextVars brs
   938               val G = norm G
   939               val rules = netMkRules state G vars safeList
   940               (*Make a new branch, decrementing "lim" if instantiations occur*)
   941               fun newBr (vars',lim') prems =
   942                   map (fn prem =>
   943                        if (exists isGoal prem)
   944                        then {pairs = ((joinMd md prem, []) ::
   945                                       negOfGoals ((br, haz)::pairs)),
   946                              lits  = map negOfGoal lits,
   947                              vars  = vars',
   948                              lim   = lim'}
   949                        else {pairs = ((joinMd md prem, []) ::
   950                                       (br, haz) :: pairs),
   951                              lits = lits,
   952                              vars = vars',
   953                              lim  = lim'})
   954                   prems @
   955                   brs
   956               (*Seek a matching rule.  If unifiable then add new premises
   957                 to branch.*)
   958               fun deeper [] = raise NEWBRANCHES
   959                 | deeper (((P,prems),tac)::grls) =
   960                     if unify state (add_term_vars(P,[]), P, G)
   961                     then  (*P comes from the rule; G comes from the branch.*)
   962                      let val updated = ntrl < !ntrail (*branch updated*)
   963                          val lim' = if updated
   964                                     then lim - (1+log(length rules))
   965                                     else lim   (*discourage branching updates*)
   966                          val vars  = vars_in_vars vars
   967                          val vars' = List.foldr add_terms_vars vars prems
   968                          val choices' = (ntrl, nbrs, PRV) :: choices
   969                          val tacs' = (tac(updated,false,true))
   970                                      :: tacs  (*no duplication; rotate*)
   971                      in
   972                          traceNew trace prems;  traceVars state ntrl;
   973                          (if null prems then (*closed the branch: prune!*)
   974                             (nclosed := !nclosed + 1;
   975                              prv(tacs',  brs0::trs,
   976                                  prune state (nbrs, nxtVars, choices'),
   977                                  brs))
   978                           else (*prems non-null*)
   979                           if lim'<0 (*faster to kill ALL the alternatives*)
   980                           then (cond_tracing trace (fn () => "Excessive branching: KILLED");
   981                                 clearTo state ntrl;  raise NEWBRANCHES)
   982                           else
   983                             (ntried := !ntried + length prems - 1;
   984                              prv(tacs',  brs0::trs, choices',
   985                                  newBr (vars',lim') prems)))
   986                          handle PRV =>
   987                            if updated then
   988                                 (*Backtrack at this level.
   989                                   Reset Vars and try another rule*)
   990                                 (clearTo state ntrl;  deeper grls)
   991                            else (*backtrack to previous level*)
   992                                 backtrack trace choices
   993                      end
   994                     else deeper grls
   995               (*Try to close branch by unifying with head goal*)
   996               fun closeF [] = raise CLOSEF
   997                 | closeF (L::Ls) =
   998                     case tryClose state (G,L) of
   999                         NONE     => closeF Ls
  1000                       | SOME tac =>
  1001                             let val choices' =
  1002                                     (if trace then (tracing "branch closed";
  1003                                                      traceVars state ntrl)
  1004                                                else ();
  1005                                      prune state (nbrs, nxtVars,
  1006                                             (ntrl, nbrs, PRV) :: choices))
  1007                             in  nclosed := !nclosed + 1;
  1008                                 prv (tac::tacs, brs0::trs, choices', brs)
  1009                                 handle PRV =>
  1010                                     (*reset Vars and try another literal
  1011                                       [this handler is pruned if possible!]*)
  1012                                  (clearTo state ntrl;  closeF Ls)
  1013                             end
  1014               (*Try to unify a queued formula (safe or haz) with head goal*)
  1015               fun closeFl [] = raise CLOSEF
  1016                 | closeFl ((br, haz)::pairs) =
  1017                     closeF (map fst br)
  1018                       handle CLOSEF => closeF (map fst haz)
  1019                         handle CLOSEF => closeFl pairs
  1020           in
  1021              trace_prover state brs0;
  1022              if lim<0 then (cond_tracing trace (fn () => "Limit reached."); backtrack trace choices)
  1023              else
  1024              prv (Data.hyp_subst_tac ctxt trace :: tacs,
  1025                   brs0::trs,  choices,
  1026                   equalSubst ctxt
  1027                     (G, {pairs = (br,haz)::pairs,
  1028                          lits  = lits, vars  = vars, lim   = lim})
  1029                     :: brs)
  1030              handle DEST_EQ =>   closeF lits
  1031               handle CLOSEF =>   closeFl ((br,haz)::pairs)
  1032                 handle CLOSEF => deeper rules
  1033                   handle NEWBRANCHES =>
  1034                    (case netMkRules state G vars hazList of
  1035                        [] => (*there are no plausible haz rules*)
  1036                              (cond_tracing trace (fn () => "moving formula to literals");
  1037                               prv (tacs, brs0::trs, choices,
  1038                                    {pairs = (br,haz)::pairs,
  1039                                     lits  = addLit(G,lits),
  1040                                     vars  = vars,
  1041                                     lim   = lim}  :: brs))
  1042                     | _ => (*G admits some haz rules: try later*)
  1043                            (cond_tracing trace (fn () => "moving formula to haz list");
  1044                             prv (if isGoal G then negOfGoal_tac ctxt :: tacs
  1045                                              else tacs,
  1046                                  brs0::trs,
  1047                                  choices,
  1048                                  {pairs = (br, haz@[(negOfGoal G, md)])::pairs,
  1049                                   lits  = lits,
  1050                                   vars  = vars,
  1051                                   lim   = lim}  :: brs)))
  1052           end
  1053        | prv (tacs, trs, choices,
  1054               {pairs = ([],haz)::(Gs,haz')::pairs, lits, vars, lim} :: brs) =
  1055              (*no more "safe" formulae: transfer haz down a level*)
  1056            prv (tacs, trs, choices,
  1057                 {pairs = (Gs,haz@haz')::pairs,
  1058                  lits  = lits,
  1059                  vars  = vars,
  1060                  lim    = lim} :: brs)
  1061        | prv (tacs, trs, choices,
  1062               brs0 as {pairs = [([], (H,md)::Hs)],
  1063                        lits, vars, lim} :: brs) =
  1064              (*no safe steps possible at any level: apply a haz rule*)
  1065           let exception PRV (*backtrack to precisely this recursion!*)
  1066               val H = norm H
  1067               val ntrl = !ntrail
  1068               val rules = netMkRules state H vars hazList
  1069               (*new premises of haz rules may NOT be duplicated*)
  1070               fun newPrem (vars,P,dup,lim') prem =
  1071                   let val Gs' = map (fn Q => (Q,false)) prem
  1072                       and Hs' = if dup then Hs @ [(negOfGoal H, md)] else Hs
  1073                       and lits' = if (exists isGoal prem)
  1074                                   then map negOfGoal lits
  1075                                   else lits
  1076                   in  {pairs = if exists (match P) prem then [(Gs',Hs')]
  1077                                (*Recursive in this premise.  Don't make new
  1078                                  "stack frame".  New haz premises will end up
  1079                                  at the BACK of the queue, preventing
  1080                                  exclusion of others*)
  1081                             else [(Gs',[]), ([],Hs')],
  1082                        lits = lits',
  1083                        vars = vars,
  1084                        lim  = lim'}
  1085                   end
  1086               fun newBr x prems = map (newPrem x) prems  @  brs
  1087               (*Seek a matching rule.  If unifiable then add new premises
  1088                 to branch.*)
  1089               fun deeper [] = raise NEWBRANCHES
  1090                 | deeper (((P,prems),tac)::grls) =
  1091                     if unify state (add_term_vars(P,[]), P, H)
  1092                     then
  1093                      let val updated = ntrl < !ntrail (*branch updated*)
  1094                          val vars  = vars_in_vars vars
  1095                          val vars' = List.foldr add_terms_vars vars prems
  1096                             (*duplicate H if md permits*)
  1097                          val dup = md (*earlier had "andalso vars' <> vars":
  1098                                   duplicate only if the subgoal has new vars*)
  1099                              (*any instances of P in the subgoals?
  1100                                NB: boolean "recur" affects tracing only!*)
  1101                          and recur = exists (exists (match P)) prems
  1102                          val lim' = (*Decrement "lim" extra if updates occur*)
  1103                              if updated then lim - (1+log(length rules))
  1104                              else lim-1
  1105                                  (*It is tempting to leave "lim" UNCHANGED if
  1106                                    both dup and recur are false.  Proofs are
  1107                                    found at shallower depths, but looping
  1108                                    occurs too often...*)
  1109                          val mayUndo =
  1110                              (*Allowing backtracking from a rule application
  1111                                if other matching rules exist, if the rule
  1112                                updated variables, or if the rule did not
  1113                                introduce new variables.  This latter condition
  1114                                means it is not a standard "gamma-rule" but
  1115                                some other form of unsafe rule.  Aim is to
  1116                                emulate Fast_tac, which allows all unsafe steps
  1117                                to be undone.*)
  1118                              not(null grls)   (*other rules to try?*)
  1119                              orelse updated
  1120                              orelse vars=vars'   (*no new Vars?*)
  1121                          val tac' = tac(updated, dup, true)
  1122                        (*if recur then perhaps shouldn't call rotate_tac: new
  1123                          formulae should be last, but that's WRONG if the new
  1124                          formulae are Goals, since they remain in the first
  1125                          position*)
  1126 
  1127                      in
  1128                        if lim'<0 andalso not (null prems)
  1129                        then (*it's faster to kill ALL the alternatives*)
  1130                            (cond_tracing trace (fn () => "Excessive branching: KILLED");
  1131                             clearTo state ntrl;  raise NEWBRANCHES)
  1132                        else
  1133                          traceNew trace prems;
  1134                          cond_tracing (trace andalso dup) (fn () => " (duplicating)");
  1135                          cond_tracing (trace andalso recur) (fn () => " (recursive)");
  1136                          traceVars state ntrl;
  1137                          if null prems then nclosed := !nclosed + 1
  1138                          else ntried := !ntried + length prems - 1;
  1139                          prv(tac' :: tacs,
  1140                              brs0::trs,
  1141                              (ntrl, length brs0, PRV) :: choices,
  1142                              newBr (vars', P, dup, lim') prems)
  1143                           handle PRV =>
  1144                               if mayUndo
  1145                               then (*reset Vars and try another rule*)
  1146                                    (clearTo state ntrl;  deeper grls)
  1147                               else (*backtrack to previous level*)
  1148                                    backtrack trace choices
  1149                      end
  1150                     else deeper grls
  1151           in
  1152              trace_prover state brs0;
  1153              if lim<1 then (cond_tracing trace (fn () => "Limit reached."); backtrack trace choices)
  1154              else deeper rules
  1155              handle NEWBRANCHES =>
  1156                  (*cannot close branch: move H to literals*)
  1157                  prv (tacs,  brs0::trs,  choices,
  1158                       {pairs = [([], Hs)],
  1159                        lits  = H::lits,
  1160                        vars  = vars,
  1161                        lim   = lim}  :: brs)
  1162           end
  1163        | prv (tacs, trs, choices, _ :: brs) = backtrack trace choices
  1164  in prv ([], [], [(!ntrail, length brs, PROVE)], brs) end;
  1165 
  1166 
  1167 (*Construct an initial branch.*)
  1168 fun initBranch (ts,lim) =
  1169     {pairs = [(map (fn t => (t,true)) ts, [])],
  1170      lits  = [],
  1171      vars  = add_terms_vars (ts,[]),
  1172      lim   = lim};
  1173 
  1174 
  1175 (*** Conversion & Skolemization of the Isabelle proof state ***)
  1176 
  1177 (*Make a list of all the parameters in a subgoal, even if nested*)
  1178 local open Term
  1179 in
  1180 fun discard_foralls (Const(@{const_name Pure.all},_)$Abs(a,T,t)) = discard_foralls t
  1181   | discard_foralls t = t;
  1182 end;
  1183 
  1184 (*List of variables not appearing as arguments to the given parameter*)
  1185 fun getVars []                  i = []
  1186   | getVars ((_,(v,is))::alist) (i: int) =
  1187         if member (op =) is i then getVars alist i
  1188         else v :: getVars alist i;
  1189 
  1190 exception TRANS of string;
  1191 
  1192 (*Translation of a subgoal: Skolemize all parameters*)
  1193 fun fromSubgoal (state as State {ctxt, ...}) t =
  1194   let val thy = Proof_Context.theory_of ctxt
  1195       val alistVar = Unsynchronized.ref []
  1196       and alistTVar = Unsynchronized.ref []
  1197       fun hdvar ((ix,(v,is))::_) = v
  1198       fun from lev t =
  1199         let val (ht,ts) = Term.strip_comb t
  1200             fun apply u = list_comb (u, map (from lev) ts)
  1201             fun bounds [] = []
  1202               | bounds (Term.Bound i::ts) =
  1203                   if i<lev then raise TRANS
  1204                       "Function unknown's argument not a parameter"
  1205                   else i-lev :: bounds ts
  1206               | bounds ts = raise TRANS
  1207                       "Function unknown's argument not a bound variable"
  1208         in
  1209           case ht of
  1210               Term.Const aT    => apply (fromConst thy alistTVar aT)
  1211             | Term.Free  (a,_) => apply (Free a)
  1212             | Term.Bound i     => apply (Bound i)
  1213             | Term.Var (ix,_) =>
  1214                   (case (AList.lookup (op =) (!alistVar) ix) of
  1215                        NONE => (alistVar := (ix, (Unsynchronized.ref NONE, bounds ts))
  1216                                           :: !alistVar;
  1217                                 Var (hdvar(!alistVar)))
  1218                      | SOME(v,is) => if is=bounds ts then Var v
  1219                             else raise TRANS
  1220                                 ("Discrepancy among occurrences of "
  1221                                  ^ Term.string_of_vname ix))
  1222             | Term.Abs (a,_,body) =>
  1223                   if null ts then Abs(a, from (lev+1) body)
  1224                   else raise TRANS "argument not in normal form"
  1225         end
  1226 
  1227       val npars = length (Logic.strip_params t)
  1228 
  1229       (*Skolemize a subgoal from a proof state*)
  1230       fun skoSubgoal i t =
  1231           if i<npars then
  1232               skoSubgoal (i+1)
  1233                 (subst_bound (Skolem (gensym state "T", getVars (!alistVar) i), t))
  1234           else t
  1235 
  1236   in  skoSubgoal 0 (from 0 (discard_foralls t))  end;
  1237 
  1238 
  1239 (*Tableau engine and proof reconstruction operating on subgoal 1.
  1240  "start" is CPU time at start, for printing SEARCH time (also prints reconstruction time)
  1241  "lim" is depth limit.*)
  1242 fun raw_blast start ctxt lim st =
  1243   let val state = initialize ctxt
  1244       val trace = Config.get ctxt trace;
  1245       val stats = Config.get ctxt stats;
  1246       val skoprem = fromSubgoal state (#1 (Logic.dest_implies (Thm.prop_of st)))
  1247       val hyps  = strip_imp_prems skoprem
  1248       and concl = strip_imp_concl skoprem
  1249       fun cont (tacs,_,choices) =
  1250           let val start = Timing.start ()
  1251           in
  1252           case Seq.pull(EVERY' (rev tacs) 1 st) of
  1253               NONE => (cond_tracing trace (fn () => "PROOF FAILED for depth " ^ string_of_int lim);
  1254                        backtrack trace choices)
  1255             | cell => (cond_tracing (trace orelse stats)
  1256                         (fn () => Timing.message (Timing.result start) ^ " for reconstruction");
  1257                        Seq.make(fn()=> cell))
  1258           end
  1259   in
  1260     prove (state, start, [initBranch (mkGoal concl :: hyps, lim)], cont)
  1261   end
  1262   handle PROVE => Seq.empty
  1263     | TRANS s => (cond_tracing (Config.get ctxt trace) (fn () => "Blast: " ^ s); Seq.empty);
  1264 
  1265 fun depth_tac ctxt lim i st =
  1266   SELECT_GOAL
  1267     (Object_Logic.atomize_prems_tac ctxt 1 THEN
  1268       raw_blast (Timing.start ()) ctxt lim) i st;
  1269 
  1270 fun blast_tac ctxt i st =
  1271   let
  1272     val start = Timing.start ();
  1273     val lim = Config.get ctxt depth_limit;
  1274   in
  1275     SELECT_GOAL
  1276      (Object_Logic.atomize_prems_tac ctxt 1 THEN
  1277       DEEPEN (1, lim) (fn m => fn _ => raw_blast start ctxt m) 0 1) i st
  1278   end;
  1279 
  1280 
  1281 
  1282 (*** For debugging: these apply the prover to a subgoal and return
  1283      the resulting tactics, trace, etc.                            ***)
  1284 
  1285 (*Read a string to make an initial, singleton branch*)
  1286 fun readGoal ctxt s =
  1287   Syntax.read_prop ctxt s |> fromTerm (Proof_Context.theory_of ctxt) |> rand |> mkGoal;
  1288 
  1289 fun tryIt ctxt lim s =
  1290   let
  1291     val state as State {fullTrace, ...} = initialize ctxt;
  1292     val res = timeap prove (state, Timing.start (), [initBranch ([readGoal ctxt s], lim)], I);
  1293   in {fullTrace = !fullTrace, result = res} end;
  1294 
  1295 
  1296 
  1297 (** method setup **)
  1298 
  1299 val _ =
  1300   Theory.setup
  1301     (Method.setup @{binding blast}
  1302       (Scan.lift (Scan.option Parse.nat) --| Method.sections Classical.cla_modifiers >>
  1303         (fn NONE => SIMPLE_METHOD' o blast_tac
  1304           | SOME lim => (fn ctxt => SIMPLE_METHOD' (depth_tac ctxt lim))))
  1305       "classical tableau prover");
  1306 
  1307 end;