src/HOL/Nat.thy
author wenzelm
Tue Mar 18 20:33:29 2008 +0100 (2008-03-18)
changeset 26315 cb3badaa192e
parent 26300 03def556e26e
child 26335 961bbcc9d85b
permissions -rw-r--r--
removed redundant less_trans, less_linear, le_imp_less_or_eq, le_less_trans, less_le_trans (cf. Orderings.thy);
renamed less_imp_le to less_imp_le_nat;
     1 (*  Title:      HOL/Nat.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     4 
     5 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     6 and * (for div, mod and dvd, see theory Divides).
     7 *)
     8 
     9 header {* Natural numbers *}
    10 
    11 theory Nat
    12 imports Inductive Ring_and_Field
    13 uses
    14   "~~/src/Tools/rat.ML"
    15   "~~/src/Provers/Arith/cancel_sums.ML"
    16   ("arith_data.ML")
    17   "~~/src/Provers/Arith/fast_lin_arith.ML"
    18   ("Tools/lin_arith.ML")
    19 begin
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization
    26   Zero_Rep :: ind and
    27   Suc_Rep :: "ind => ind"
    28 where
    29   -- {* the axiom of infinity in 2 parts *}
    30   inj_Suc_Rep:          "inj Suc_Rep" and
    31   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    32 
    33 
    34 subsection {* Type nat *}
    35 
    36 text {* Type definition *}
    37 
    38 inductive Nat :: "ind \<Rightarrow> bool"
    39 where
    40     Zero_RepI: "Nat Zero_Rep"
    41   | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    42 
    43 global
    44 
    45 typedef (open Nat)
    46   nat = "Collect Nat"
    47   by (rule exI, rule CollectI, rule Nat.Zero_RepI)
    48 
    49 constdefs
    50   Suc :: "nat => nat"
    51   Suc_def:      "Suc == (%n. Abs_Nat (Suc_Rep (Rep_Nat n)))"
    52 
    53 local
    54 
    55 instantiation nat :: zero
    56 begin
    57 
    58 definition Zero_nat_def [code func del]:
    59   "0 = Abs_Nat Zero_Rep"
    60 
    61 instance ..
    62 
    63 end
    64 
    65 lemma nat_induct: "P 0 ==> (!!n. P n ==> P (Suc n)) ==> P n"
    66   apply (unfold Zero_nat_def Suc_def)
    67   apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    68   apply (erule Rep_Nat [THEN CollectD, THEN Nat.induct])
    69   apply (iprover elim: Abs_Nat_inverse [OF CollectI, THEN subst])
    70   done
    71 
    72 lemma Suc_not_Zero [iff]: "Suc m \<noteq> 0"
    73   by (simp add: Zero_nat_def Suc_def
    74     Abs_Nat_inject Rep_Nat [THEN CollectD] Suc_RepI Zero_RepI
    75       Suc_Rep_not_Zero_Rep)
    76 
    77 lemma Zero_not_Suc [iff]: "0 \<noteq> Suc m"
    78   by (rule not_sym, rule Suc_not_Zero not_sym)
    79 
    80 lemma inj_Suc[simp]: "inj_on Suc N"
    81   by (simp add: Suc_def inj_on_def Abs_Nat_inject Rep_Nat [THEN CollectD] Suc_RepI
    82                 inj_Suc_Rep [THEN inj_eq] Rep_Nat_inject)
    83 
    84 lemma Suc_Suc_eq [iff]: "Suc m = Suc n \<longleftrightarrow> m = n"
    85   by (rule inj_Suc [THEN inj_eq])
    86 
    87 rep_datatype nat
    88   distinct  Suc_not_Zero Zero_not_Suc
    89   inject    Suc_Suc_eq
    90   induction nat_induct
    91 
    92 declare nat.induct [case_names 0 Suc, induct type: nat]
    93 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    94 
    95 lemmas nat_rec_0 = nat.recs(1)
    96   and nat_rec_Suc = nat.recs(2)
    97 
    98 lemmas nat_case_0 = nat.cases(1)
    99   and nat_case_Suc = nat.cases(2)
   100 
   101 
   102 text {* Injectiveness and distinctness lemmas *}
   103 
   104 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   105 by (rule notE, rule Suc_not_Zero)
   106 
   107 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   108 by (rule Suc_neq_Zero, erule sym)
   109 
   110 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   111 by (rule inj_Suc [THEN injD])
   112 
   113 lemma n_not_Suc_n: "n \<noteq> Suc n"
   114 by (induct n) simp_all
   115 
   116 lemma Suc_n_not_n: "Suc n \<noteq> n"
   117 by (rule not_sym, rule n_not_Suc_n)
   118 
   119 text {* A special form of induction for reasoning
   120   about @{term "m < n"} and @{term "m - n"} *}
   121 
   122 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   123     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   124   apply (rule_tac x = m in spec)
   125   apply (induct n)
   126   prefer 2
   127   apply (rule allI)
   128   apply (induct_tac x, iprover+)
   129   done
   130 
   131 
   132 subsection {* Arithmetic operators *}
   133 
   134 instantiation nat :: "{minus, comm_monoid_add}"
   135 begin
   136 
   137 primrec plus_nat
   138 where
   139   add_0:      "0 + n = (n\<Colon>nat)"
   140   | add_Suc:  "Suc m + n = Suc (m + n)"
   141 
   142 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   143   by (induct m) simp_all
   144 
   145 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   146   by (induct m) simp_all
   147 
   148 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   149   by simp
   150 
   151 primrec minus_nat
   152 where
   153   diff_0:     "m - 0 = (m\<Colon>nat)"
   154   | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   155 
   156 declare diff_Suc [simp del, code del]
   157 
   158 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   159   by (induct n) (simp_all add: diff_Suc)
   160 
   161 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   162   by (induct n) (simp_all add: diff_Suc)
   163 
   164 instance proof
   165   fix n m q :: nat
   166   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   167   show "n + m = m + n" by (induct n) simp_all
   168   show "0 + n = n" by simp
   169 qed
   170 
   171 end
   172 
   173 instantiation nat :: comm_semiring_1_cancel
   174 begin
   175 
   176 definition
   177   One_nat_def [simp]: "1 = Suc 0"
   178 
   179 primrec times_nat
   180 where
   181   mult_0:     "0 * n = (0\<Colon>nat)"
   182   | mult_Suc: "Suc m * n = n + (m * n)"
   183 
   184 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   185   by (induct m) simp_all
   186 
   187 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   188   by (induct m) (simp_all add: add_left_commute)
   189 
   190 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   191   by (induct m) (simp_all add: add_assoc)
   192 
   193 instance proof
   194   fix n m q :: nat
   195   show "0 \<noteq> (1::nat)" by simp
   196   show "1 * n = n" by simp
   197   show "n * m = m * n" by (induct n) simp_all
   198   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   199   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   200   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   201 qed
   202 
   203 end
   204 
   205 subsubsection {* Addition *}
   206 
   207 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   208   by (rule add_assoc)
   209 
   210 lemma nat_add_commute: "m + n = n + (m::nat)"
   211   by (rule add_commute)
   212 
   213 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   214   by (rule add_left_commute)
   215 
   216 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   217   by (rule add_left_cancel)
   218 
   219 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   220   by (rule add_right_cancel)
   221 
   222 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   223 
   224 lemma add_is_0 [iff]:
   225   fixes m n :: nat
   226   shows "(m + n = 0) = (m = 0 & n = 0)"
   227   by (cases m) simp_all
   228 
   229 lemma add_is_1:
   230   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   231   by (cases m) simp_all
   232 
   233 lemma one_is_add:
   234   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   235   by (rule trans, rule eq_commute, rule add_is_1)
   236 
   237 lemma add_eq_self_zero:
   238   fixes m n :: nat
   239   shows "m + n = m \<Longrightarrow> n = 0"
   240   by (induct m) simp_all
   241 
   242 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   243   apply (induct k)
   244    apply simp
   245   apply(drule comp_inj_on[OF _ inj_Suc])
   246   apply (simp add:o_def)
   247   done
   248 
   249 
   250 subsubsection {* Difference *}
   251 
   252 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   253   by (induct m) simp_all
   254 
   255 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   256   by (induct i j rule: diff_induct) simp_all
   257 
   258 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   259   by (simp add: diff_diff_left)
   260 
   261 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   262   by (simp add: diff_diff_left add_commute)
   263 
   264 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   265   by (induct n) simp_all
   266 
   267 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   268   by (simp add: diff_add_inverse add_commute [of m n])
   269 
   270 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   271   by (induct k) simp_all
   272 
   273 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   274   by (simp add: diff_cancel add_commute)
   275 
   276 lemma diff_add_0: "n - (n + m) = (0::nat)"
   277   by (induct n) simp_all
   278 
   279 text {* Difference distributes over multiplication *}
   280 
   281 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   282 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   283 
   284 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   285 by (simp add: diff_mult_distrib mult_commute [of k])
   286   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   287 
   288 
   289 subsubsection {* Multiplication *}
   290 
   291 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   292   by (rule mult_assoc)
   293 
   294 lemma nat_mult_commute: "m * n = n * (m::nat)"
   295   by (rule mult_commute)
   296 
   297 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   298   by (rule right_distrib)
   299 
   300 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   301   by (induct m) auto
   302 
   303 lemmas nat_distrib =
   304   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   305 
   306 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = 1 & n = 1)"
   307   apply (induct m)
   308    apply simp
   309   apply (induct n)
   310    apply auto
   311   done
   312 
   313 lemma one_eq_mult_iff [simp,noatp]: "(Suc 0 = m * n) = (m = 1 & n = 1)"
   314   apply (rule trans)
   315   apply (rule_tac [2] mult_eq_1_iff, fastsimp)
   316   done
   317 
   318 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   319 proof -
   320   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   321   proof (induct n arbitrary: m)
   322     case 0 then show "m = 0" by simp
   323   next
   324     case (Suc n) then show "m = Suc n"
   325       by (cases m) (simp_all add: eq_commute [of "0"])
   326   qed
   327   then show ?thesis by auto
   328 qed
   329 
   330 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   331   by (simp add: mult_commute)
   332 
   333 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   334   by (subst mult_cancel1) simp
   335 
   336 
   337 subsection {* Orders on @{typ nat} *}
   338 
   339 subsubsection {* Operation definition *}
   340 
   341 instantiation nat :: linorder
   342 begin
   343 
   344 primrec less_eq_nat where
   345   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   346   | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   347 
   348 declare less_eq_nat.simps [simp del, code del]
   349 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   350 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   351 
   352 definition less_nat where
   353   less_eq_Suc_le [code func del]: "n < m \<longleftrightarrow> Suc n \<le> m"
   354 
   355 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   356   by (simp add: less_eq_nat.simps(2))
   357 
   358 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   359   unfolding less_eq_Suc_le ..
   360 
   361 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   362   by (induct n) (simp_all add: less_eq_nat.simps(2))
   363 
   364 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   365   by (simp add: less_eq_Suc_le)
   366 
   367 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   368   by simp
   369 
   370 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   371   by (simp add: less_eq_Suc_le)
   372 
   373 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   374   by (simp add: less_eq_Suc_le)
   375 
   376 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   377   by (induct m arbitrary: n)
   378     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   379 
   380 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   381   by (cases n) (auto intro: le_SucI)
   382 
   383 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   384   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   385 
   386 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   387   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   388 
   389 instance
   390 proof
   391   fix n m :: nat
   392   have less_imp_le: "n < m \<Longrightarrow> n \<le> m"
   393     unfolding less_eq_Suc_le by (erule Suc_leD)
   394   have irrefl: "\<not> m < m" by (induct m) auto
   395   have strict: "n \<le> m \<Longrightarrow> n \<noteq> m \<Longrightarrow> n < m"
   396   proof (induct n arbitrary: m)
   397     case 0 then show ?case
   398       by (cases m) (simp_all add: less_eq_Suc_le)
   399   next
   400     case (Suc n) then show ?case
   401       by (cases m) (simp_all add: less_eq_Suc_le)
   402   qed
   403   show "n < m \<longleftrightarrow> n \<le> m \<and> n \<noteq> m"
   404     by (auto simp add: irrefl intro: less_imp_le strict)
   405 next
   406   fix n :: nat show "n \<le> n" by (induct n) simp_all
   407 next
   408   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   409   then show "n = m"
   410     by (induct n arbitrary: m)
   411       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   412 next
   413   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   414   then show "n \<le> q"
   415   proof (induct n arbitrary: m q)
   416     case 0 show ?case by simp
   417   next
   418     case (Suc n) then show ?case
   419       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   420         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   421         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   422   qed
   423 next
   424   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   425     by (induct n arbitrary: m)
   426       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   427 qed
   428 
   429 end
   430 
   431 subsubsection {* Introduction properties *}
   432 
   433 lemma lessI [iff]: "n < Suc n"
   434   by (simp add: less_Suc_eq_le)
   435 
   436 lemma zero_less_Suc [iff]: "0 < Suc n"
   437   by (simp add: less_Suc_eq_le)
   438 
   439 
   440 subsubsection {* Elimination properties *}
   441 
   442 lemma less_not_sym: "n < m ==> ~ m < (n::nat)"
   443   by (rule order_less_not_sym)
   444 
   445 lemma less_asym:
   446   assumes h1: "(n::nat) < m" and h2: "~ P ==> m < n" shows P
   447   apply (rule contrapos_np)
   448   apply (rule less_not_sym)
   449   apply (rule h1)
   450   apply (erule h2)
   451   done
   452 
   453 lemma less_not_refl: "~ n < (n::nat)"
   454   by (rule order_less_irrefl)
   455 
   456 lemma less_irrefl [elim!]: "(n::nat) < n ==> R"
   457   by (rule notE, rule less_not_refl)
   458 
   459 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   460   by (rule less_imp_neq)
   461 
   462 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   463   by (rule not_sym) (rule less_imp_neq) 
   464 
   465 lemma less_zeroE: "(n::nat) < 0 ==> R"
   466   by (rule notE) (rule not_less0)
   467 
   468 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   469   unfolding less_Suc_eq_le le_less ..
   470 
   471 lemma less_one [iff, noatp]: "(n < (1::nat)) = (n = 0)"
   472   by (simp add: less_Suc_eq)
   473 
   474 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   475   by (simp add: less_Suc_eq)
   476 
   477 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   478   by simp
   479 
   480 text {* "Less than" is antisymmetric, sort of *}
   481 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   482   unfolding not_less less_Suc_eq_le by (rule antisym)
   483 
   484 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   485   by (rule linorder_neq_iff)
   486 
   487 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   488   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   489   shows "P n m"
   490   apply (rule less_linear [THEN disjE])
   491   apply (erule_tac [2] disjE)
   492   apply (erule lessCase)
   493   apply (erule sym [THEN eqCase])
   494   apply (erule major)
   495   done
   496 
   497 
   498 subsubsection {* Inductive (?) properties *}
   499 
   500 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   501   unfolding less_eq_Suc_le [of m] le_less by simp 
   502 
   503 lemma lessE:
   504   assumes major: "i < k"
   505   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   506   shows P
   507 proof -
   508   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   509     unfolding less_eq_Suc_le by (induct k) simp_all
   510   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   511     by (clarsimp simp add: less_le)
   512   with p1 p2 show P by auto
   513 qed
   514 
   515 lemma less_SucE: assumes major: "m < Suc n"
   516   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   517   apply (rule major [THEN lessE])
   518   apply (rule eq, blast)
   519   apply (rule less, blast)
   520   done
   521 
   522 lemma Suc_lessE: assumes major: "Suc i < k"
   523   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   524   apply (rule major [THEN lessE])
   525   apply (erule lessI [THEN minor])
   526   apply (erule Suc_lessD [THEN minor], assumption)
   527   done
   528 
   529 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   530   by simp
   531 
   532 lemma less_trans_Suc:
   533   assumes le: "i < j" shows "j < k ==> Suc i < k"
   534   apply (induct k, simp_all)
   535   apply (insert le)
   536   apply (simp add: less_Suc_eq)
   537   apply (blast dest: Suc_lessD)
   538   done
   539 
   540 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   541 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   542   unfolding not_less less_Suc_eq_le ..
   543 
   544 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   545   unfolding not_le Suc_le_eq ..
   546 
   547 text {* Properties of "less than or equal" *}
   548 
   549 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   550   unfolding less_Suc_eq_le .
   551 
   552 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   553   unfolding not_le less_Suc_eq_le ..
   554 
   555 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   556   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   557 
   558 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   559   by (drule le_Suc_eq [THEN iffD1], iprover+)
   560 
   561 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   562   unfolding Suc_le_eq .
   563 
   564 text {* Stronger version of @{text Suc_leD} *}
   565 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   566   unfolding Suc_le_eq .
   567 
   568 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   569   unfolding less_eq_Suc_le by (rule Suc_leD)
   570 
   571 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   572 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   573 
   574 
   575 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   576 
   577 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   578   unfolding le_less .
   579 
   580 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   581   by (rule le_less)
   582 
   583 text {* Useful with @{text blast}. *}
   584 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   585   by auto
   586 
   587 lemma le_refl: "n \<le> (n::nat)"
   588   by simp
   589 
   590 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   591   by (rule order_trans)
   592 
   593 lemma le_anti_sym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   594   by (rule antisym)
   595 
   596 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   597   by (rule less_le)
   598 
   599 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   600   unfolding less_le ..
   601 
   602 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   603   by (rule linear)
   604 
   605 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   606 
   607 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   608   unfolding less_Suc_eq_le by auto
   609 
   610 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   611   unfolding not_less by (rule le_less_Suc_eq)
   612 
   613 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   614 
   615 text {* These two rules ease the use of primitive recursion.
   616 NOTE USE OF @{text "=="} *}
   617 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   618 by simp
   619 
   620 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   621 by simp
   622 
   623 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   624 by (cases n) simp_all
   625 
   626 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   627 by (cases n) simp_all
   628 
   629 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   630 by (cases n) simp_all
   631 
   632 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   633 by (cases n) simp_all
   634 
   635 text {* This theorem is useful with @{text blast} *}
   636 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   637 by (rule neq0_conv[THEN iffD1], iprover)
   638 
   639 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   640 by (fast intro: not0_implies_Suc)
   641 
   642 lemma not_gr0 [iff,noatp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   643 using neq0_conv by blast
   644 
   645 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   646 by (induct m') simp_all
   647 
   648 text {* Useful in certain inductive arguments *}
   649 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   650 by (cases m) simp_all
   651 
   652 
   653 subsubsection {* @{term min} and @{term max} *}
   654 
   655 lemma mono_Suc: "mono Suc"
   656 by (rule monoI) simp
   657 
   658 lemma min_0L [simp]: "min 0 n = (0::nat)"
   659 by (rule min_leastL) simp
   660 
   661 lemma min_0R [simp]: "min n 0 = (0::nat)"
   662 by (rule min_leastR) simp
   663 
   664 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   665 by (simp add: mono_Suc min_of_mono)
   666 
   667 lemma min_Suc1:
   668    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   669 by (simp split: nat.split)
   670 
   671 lemma min_Suc2:
   672    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   673 by (simp split: nat.split)
   674 
   675 lemma max_0L [simp]: "max 0 n = (n::nat)"
   676 by (rule max_leastL) simp
   677 
   678 lemma max_0R [simp]: "max n 0 = (n::nat)"
   679 by (rule max_leastR) simp
   680 
   681 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   682 by (simp add: mono_Suc max_of_mono)
   683 
   684 lemma max_Suc1:
   685    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   686 by (simp split: nat.split)
   687 
   688 lemma max_Suc2:
   689    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   690 by (simp split: nat.split)
   691 
   692 
   693 subsubsection {* Monotonicity of Addition *}
   694 
   695 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   696 by (simp add: diff_Suc split: nat.split)
   697 
   698 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   699 by (induct k) simp_all
   700 
   701 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   702 by (induct k) simp_all
   703 
   704 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   705 by(auto dest:gr0_implies_Suc)
   706 
   707 text {* strict, in 1st argument *}
   708 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   709 by (induct k) simp_all
   710 
   711 text {* strict, in both arguments *}
   712 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   713   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   714   apply (induct j, simp_all)
   715   done
   716 
   717 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   718 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   719   apply (induct n)
   720   apply (simp_all add: order_le_less)
   721   apply (blast elim!: less_SucE
   722                intro!: add_0_right [symmetric] add_Suc_right [symmetric])
   723   done
   724 
   725 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   726 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   727 apply(auto simp: gr0_conv_Suc)
   728 apply (induct_tac m)
   729 apply (simp_all add: add_less_mono)
   730 done
   731 
   732 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   733 instance nat :: ordered_semidom
   734 proof
   735   fix i j k :: nat
   736   show "0 < (1::nat)" by simp
   737   show "i \<le> j ==> k + i \<le> k + j" by simp
   738   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   739 qed
   740 
   741 lemma nat_mult_1: "(1::nat) * n = n"
   742 by simp
   743 
   744 lemma nat_mult_1_right: "n * (1::nat) = n"
   745 by simp
   746 
   747 
   748 subsubsection {* Additional theorems about "less than" *}
   749 
   750 text{*An induction rule for estabilishing binary relations*}
   751 lemma less_Suc_induct:
   752   assumes less:  "i < j"
   753      and  step:  "!!i. P i (Suc i)"
   754      and  trans: "!!i j k. P i j ==> P j k ==> P i k"
   755   shows "P i j"
   756 proof -
   757   from less obtain k where j: "j = Suc(i+k)" by (auto dest: less_imp_Suc_add)
   758   have "P i (Suc (i + k))"
   759   proof (induct k)
   760     case 0
   761     show ?case by (simp add: step)
   762   next
   763     case (Suc k)
   764     thus ?case by (auto intro: assms)
   765   qed
   766   thus "P i j" by (simp add: j)
   767 qed
   768 
   769 text {* A [clumsy] way of lifting @{text "<"}
   770   monotonicity to @{text "\<le>"} monotonicity *}
   771 lemma less_mono_imp_le_mono:
   772   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   773 by (simp add: order_le_less) (blast)
   774 
   775 
   776 text {* non-strict, in 1st argument *}
   777 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   778 by (rule add_right_mono)
   779 
   780 text {* non-strict, in both arguments *}
   781 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   782 by (rule add_mono)
   783 
   784 lemma le_add2: "n \<le> ((m + n)::nat)"
   785 by (insert add_right_mono [of 0 m n], simp)
   786 
   787 lemma le_add1: "n \<le> ((n + m)::nat)"
   788 by (simp add: add_commute, rule le_add2)
   789 
   790 lemma less_add_Suc1: "i < Suc (i + m)"
   791 by (rule le_less_trans, rule le_add1, rule lessI)
   792 
   793 lemma less_add_Suc2: "i < Suc (m + i)"
   794 by (rule le_less_trans, rule le_add2, rule lessI)
   795 
   796 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   797 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   798 
   799 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   800 by (rule le_trans, assumption, rule le_add1)
   801 
   802 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   803 by (rule le_trans, assumption, rule le_add2)
   804 
   805 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   806 by (rule less_le_trans, assumption, rule le_add1)
   807 
   808 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   809 by (rule less_le_trans, assumption, rule le_add2)
   810 
   811 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   812 apply (rule le_less_trans [of _ "i+j"])
   813 apply (simp_all add: le_add1)
   814 done
   815 
   816 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
   817 apply (rule notI)
   818 apply (erule add_lessD1 [THEN less_irrefl])
   819 done
   820 
   821 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
   822 by (simp add: add_commute not_add_less1)
   823 
   824 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
   825 apply (rule order_trans [of _ "m+k"])
   826 apply (simp_all add: le_add1)
   827 done
   828 
   829 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
   830 apply (simp add: add_commute)
   831 apply (erule add_leD1)
   832 done
   833 
   834 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
   835 by (blast dest: add_leD1 add_leD2)
   836 
   837 text {* needs @{text "!!k"} for @{text add_ac} to work *}
   838 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
   839 by (force simp del: add_Suc_right
   840     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
   841 
   842 
   843 subsubsection {* More results about difference *}
   844 
   845 text {* Addition is the inverse of subtraction:
   846   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
   847 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
   848 by (induct m n rule: diff_induct) simp_all
   849 
   850 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
   851 by (simp add: add_diff_inverse linorder_not_less)
   852 
   853 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
   854 by (simp add: le_add_diff_inverse add_commute)
   855 
   856 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
   857 by (induct m n rule: diff_induct) simp_all
   858 
   859 lemma diff_less_Suc: "m - n < Suc m"
   860 apply (induct m n rule: diff_induct)
   861 apply (erule_tac [3] less_SucE)
   862 apply (simp_all add: less_Suc_eq)
   863 done
   864 
   865 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
   866 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
   867 
   868 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
   869   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
   870 
   871 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
   872 by (rule le_less_trans, rule diff_le_self)
   873 
   874 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
   875 by (cases n) (auto simp add: le_simps)
   876 
   877 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
   878 by (induct j k rule: diff_induct) simp_all
   879 
   880 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
   881 by (simp add: add_commute diff_add_assoc)
   882 
   883 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
   884 by (auto simp add: diff_add_inverse2)
   885 
   886 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
   887 by (induct m n rule: diff_induct) simp_all
   888 
   889 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
   890 by (rule iffD2, rule diff_is_0_eq)
   891 
   892 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
   893 by (induct m n rule: diff_induct) simp_all
   894 
   895 lemma less_imp_add_positive:
   896   assumes "i < j"
   897   shows "\<exists>k::nat. 0 < k & i + k = j"
   898 proof
   899   from assms show "0 < j - i & i + (j - i) = j"
   900     by (simp add: order_less_imp_le)
   901 qed
   902 
   903 text {* a nice rewrite for bounded subtraction *}
   904 lemma nat_minus_add_max:
   905   fixes n m :: nat
   906   shows "n - m + m = max n m"
   907     by (simp add: max_def not_le order_less_imp_le)
   908 
   909 lemma nat_diff_split:
   910   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
   911     -- {* elimination of @{text -} on @{text nat} *}
   912 by (cases "a < b")
   913   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
   914     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
   915 
   916 lemma nat_diff_split_asm:
   917   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
   918     -- {* elimination of @{text -} on @{text nat} in assumptions *}
   919 by (auto split: nat_diff_split)
   920 
   921 
   922 subsubsection {* Monotonicity of Multiplication *}
   923 
   924 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
   925 by (simp add: mult_right_mono)
   926 
   927 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
   928 by (simp add: mult_left_mono)
   929 
   930 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
   931 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
   932 by (simp add: mult_mono)
   933 
   934 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
   935 by (simp add: mult_strict_right_mono)
   936 
   937 text{*Differs from the standard @{text zero_less_mult_iff} in that
   938       there are no negative numbers.*}
   939 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
   940   apply (induct m)
   941    apply simp
   942   apply (case_tac n)
   943    apply simp_all
   944   done
   945 
   946 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (1 \<le> m & 1 \<le> n)"
   947   apply (induct m)
   948    apply simp
   949   apply (case_tac n)
   950    apply simp_all
   951   done
   952 
   953 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
   954   apply (safe intro!: mult_less_mono1)
   955   apply (case_tac k, auto)
   956   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
   957   apply (blast intro: mult_le_mono1)
   958   done
   959 
   960 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
   961 by (simp add: mult_commute [of k])
   962 
   963 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
   964 by (simp add: linorder_not_less [symmetric], auto)
   965 
   966 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
   967 by (simp add: linorder_not_less [symmetric], auto)
   968 
   969 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
   970 by (subst mult_less_cancel1) simp
   971 
   972 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
   973 by (subst mult_le_cancel1) simp
   974 
   975 lemma le_square: "m \<le> m * (m::nat)"
   976   by (cases m) (auto intro: le_add1)
   977 
   978 lemma le_cube: "(m::nat) \<le> m * (m * m)"
   979   by (cases m) (auto intro: le_add1)
   980 
   981 text {* Lemma for @{text gcd} *}
   982 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
   983   apply (drule sym)
   984   apply (rule disjCI)
   985   apply (rule nat_less_cases, erule_tac [2] _)
   986    apply (drule_tac [2] mult_less_mono2)
   987     apply (auto)
   988   done
   989 
   990 text {* the lattice order on @{typ nat} *}
   991 
   992 instantiation nat :: distrib_lattice
   993 begin
   994 
   995 definition
   996   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
   997 
   998 definition
   999   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1000 
  1001 instance by intro_classes
  1002   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1003     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1004 
  1005 end
  1006 
  1007 
  1008 subsection {* Embedding of the Naturals into any
  1009   @{text semiring_1}: @{term of_nat} *}
  1010 
  1011 context semiring_1
  1012 begin
  1013 
  1014 primrec
  1015   of_nat :: "nat \<Rightarrow> 'a"
  1016 where
  1017   of_nat_0:     "of_nat 0 = 0"
  1018   | of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1019 
  1020 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1021   by simp
  1022 
  1023 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1024   by (induct m) (simp_all add: add_ac)
  1025 
  1026 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1027   by (induct m) (simp_all add: add_ac left_distrib)
  1028 
  1029 definition
  1030   of_nat_aux :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1031 where
  1032   [code func del]: "of_nat_aux n i = of_nat n + i"
  1033 
  1034 lemma of_nat_aux_code [code]:
  1035   "of_nat_aux 0 i = i"
  1036   "of_nat_aux (Suc n) i = of_nat_aux n (i + 1)" -- {* tail recursive *}
  1037   by (simp_all add: of_nat_aux_def add_ac)
  1038 
  1039 lemma of_nat_code [code]:
  1040   "of_nat n = of_nat_aux n 0"
  1041   by (simp add: of_nat_aux_def)
  1042 
  1043 end
  1044 
  1045 text{*Class for unital semirings with characteristic zero.
  1046  Includes non-ordered rings like the complex numbers.*}
  1047 
  1048 class semiring_char_0 = semiring_1 +
  1049   assumes of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1050 begin
  1051 
  1052 text{*Special cases where either operand is zero*}
  1053 
  1054 lemma of_nat_0_eq_iff [simp, noatp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1055   by (rule of_nat_eq_iff [of 0, simplified])
  1056 
  1057 lemma of_nat_eq_0_iff [simp, noatp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1058   by (rule of_nat_eq_iff [of _ 0, simplified])
  1059 
  1060 lemma inj_of_nat: "inj of_nat"
  1061   by (simp add: inj_on_def)
  1062 
  1063 end
  1064 
  1065 context ordered_semidom
  1066 begin
  1067 
  1068 lemma zero_le_imp_of_nat: "0 \<le> of_nat m"
  1069   apply (induct m, simp_all)
  1070   apply (erule order_trans)
  1071   apply (rule ord_le_eq_trans [OF _ add_commute])
  1072   apply (rule less_add_one [THEN less_imp_le])
  1073   done
  1074 
  1075 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1076   apply (induct m n rule: diff_induct, simp_all)
  1077   apply (insert add_less_le_mono [OF zero_less_one zero_le_imp_of_nat], force)
  1078   done
  1079 
  1080 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1081   apply (induct m n rule: diff_induct, simp_all)
  1082   apply (insert zero_le_imp_of_nat)
  1083   apply (force simp add: not_less [symmetric])
  1084   done
  1085 
  1086 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1087   by (blast intro: of_nat_less_imp_less less_imp_of_nat_less)
  1088 
  1089 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1090   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1091 
  1092 text{*Every @{text ordered_semidom} has characteristic zero.*}
  1093 
  1094 subclass semiring_char_0
  1095   by unfold_locales (simp add: eq_iff order_eq_iff)
  1096 
  1097 text{*Special cases where either operand is zero*}
  1098 
  1099 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1100   by (rule of_nat_le_iff [of 0, simplified])
  1101 
  1102 lemma of_nat_le_0_iff [simp, noatp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1103   by (rule of_nat_le_iff [of _ 0, simplified])
  1104 
  1105 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1106   by (rule of_nat_less_iff [of 0, simplified])
  1107 
  1108 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1109   by (rule of_nat_less_iff [of _ 0, simplified])
  1110 
  1111 end
  1112 
  1113 context ring_1
  1114 begin
  1115 
  1116 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1117   by (simp add: compare_rls of_nat_add [symmetric])
  1118 
  1119 end
  1120 
  1121 context ordered_idom
  1122 begin
  1123 
  1124 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1125   unfolding abs_if by auto
  1126 
  1127 end
  1128 
  1129 lemma of_nat_id [simp]: "of_nat n = n"
  1130   by (induct n) auto
  1131 
  1132 lemma of_nat_eq_id [simp]: "of_nat = id"
  1133   by (auto simp add: expand_fun_eq)
  1134 
  1135 
  1136 subsection {* The Set of Natural Numbers *}
  1137 
  1138 context semiring_1
  1139 begin
  1140 
  1141 definition
  1142   Nats  :: "'a set" where
  1143   "Nats = range of_nat"
  1144 
  1145 notation (xsymbols)
  1146   Nats  ("\<nat>")
  1147 
  1148 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1149   by (simp add: Nats_def)
  1150 
  1151 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1152 apply (simp add: Nats_def)
  1153 apply (rule range_eqI)
  1154 apply (rule of_nat_0 [symmetric])
  1155 done
  1156 
  1157 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1158 apply (simp add: Nats_def)
  1159 apply (rule range_eqI)
  1160 apply (rule of_nat_1 [symmetric])
  1161 done
  1162 
  1163 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1164 apply (auto simp add: Nats_def)
  1165 apply (rule range_eqI)
  1166 apply (rule of_nat_add [symmetric])
  1167 done
  1168 
  1169 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1170 apply (auto simp add: Nats_def)
  1171 apply (rule range_eqI)
  1172 apply (rule of_nat_mult [symmetric])
  1173 done
  1174 
  1175 end
  1176 
  1177 
  1178 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1179 
  1180 lemma subst_equals:
  1181   assumes 1: "t = s" and 2: "u = t"
  1182   shows "u = s"
  1183   using 2 1 by (rule trans)
  1184 
  1185 use "arith_data.ML"
  1186 declaration {* K ArithData.setup *}
  1187 
  1188 use "Tools/lin_arith.ML"
  1189 declaration {* K LinArith.setup *}
  1190 
  1191 lemmas [arith_split] = nat_diff_split split_min split_max
  1192 
  1193 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1194 
  1195 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1196 by arith
  1197 
  1198 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1199 by arith
  1200 
  1201 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1202 by arith
  1203 
  1204 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1205 by arith
  1206 
  1207 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1208 by arith
  1209 
  1210 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1211 by arith
  1212 
  1213 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1214   second premise n\<le>m*)
  1215 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1216 by arith
  1217 
  1218 text {* Simplification of relational expressions involving subtraction *}
  1219 
  1220 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1221 by (simp split add: nat_diff_split)
  1222 
  1223 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1224 by (auto split add: nat_diff_split)
  1225 
  1226 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1227 by (auto split add: nat_diff_split)
  1228 
  1229 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1230 by (auto split add: nat_diff_split)
  1231 
  1232 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1233 
  1234 (* Monotonicity of subtraction in first argument *)
  1235 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1236 by (simp split add: nat_diff_split)
  1237 
  1238 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1239 by (simp split add: nat_diff_split)
  1240 
  1241 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1242 by (simp split add: nat_diff_split)
  1243 
  1244 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1245 by (simp split add: nat_diff_split)
  1246 
  1247 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1248 unfolding min_def by auto
  1249 
  1250 lemma inj_on_diff_nat: 
  1251   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1252   shows "inj_on (\<lambda>n. n - k) N"
  1253 proof (rule inj_onI)
  1254   fix x y
  1255   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1256   with k_le_n have "x - k + k = y - k + k" by auto
  1257   with a k_le_n show "x = y" by auto
  1258 qed
  1259 
  1260 text{*Rewriting to pull differences out*}
  1261 
  1262 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1263 by arith
  1264 
  1265 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1266 by arith
  1267 
  1268 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1269 by arith
  1270 
  1271 text{*Lemmas for ex/Factorization*}
  1272 
  1273 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1274 by (cases m) auto
  1275 
  1276 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1277 by (cases m) auto
  1278 
  1279 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1280 by (cases m) auto
  1281 
  1282 text {* Specialized induction principles that work "backwards": *}
  1283 
  1284 lemma inc_induct[consumes 1, case_names base step]:
  1285   assumes less: "i <= j"
  1286   assumes base: "P j"
  1287   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1288   shows "P i"
  1289   using less
  1290 proof (induct d=="j - i" arbitrary: i)
  1291   case (0 i)
  1292   hence "i = j" by simp
  1293   with base show ?case by simp
  1294 next
  1295   case (Suc d i)
  1296   hence "i < j" "P (Suc i)"
  1297     by simp_all
  1298   thus "P i" by (rule step)
  1299 qed
  1300 
  1301 lemma strict_inc_induct[consumes 1, case_names base step]:
  1302   assumes less: "i < j"
  1303   assumes base: "!!i. j = Suc i ==> P i"
  1304   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1305   shows "P i"
  1306   using less
  1307 proof (induct d=="j - i - 1" arbitrary: i)
  1308   case (0 i)
  1309   with `i < j` have "j = Suc i" by simp
  1310   with base show ?case by simp
  1311 next
  1312   case (Suc d i)
  1313   hence "i < j" "P (Suc i)"
  1314     by simp_all
  1315   thus "P i" by (rule step)
  1316 qed
  1317 
  1318 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1319   using inc_induct[of "k - i" k P, simplified] by blast
  1320 
  1321 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1322   using inc_induct[of 0 k P] by blast
  1323 
  1324 lemma nat_not_singleton: "(\<forall>x. x = (0::nat)) = False"
  1325   by auto
  1326 
  1327 (*The others are
  1328       i - j - k = i - (j + k),
  1329       k \<le> j ==> j - k + i = j + i - k,
  1330       k \<le> j ==> i + (j - k) = i + j - k *)
  1331 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1332 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1333 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1334 
  1335 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1336 Least_Suc}, since there appears to be no need.*}
  1337 
  1338 subsection {* size of a datatype value *}
  1339 
  1340 class size = type +
  1341   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded_Recursion} *}
  1342 
  1343 end