src/Pure/Proof/extraction.ML
author haftmann
Wed Jan 21 16:47:04 2009 +0100 (2009-01-21)
changeset 29579 cb520b766e00
parent 29270 0eade173f77e
child 29635 31d14e9fa0da
permissions -rw-r--r--
binding replaces bstring
     1 (*  Title:      Pure/Proof/extraction.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 Extraction of programs from proofs.
     5 *)
     6 
     7 signature EXTRACTION =
     8 sig
     9   val set_preprocessor : (theory -> Proofterm.proof -> Proofterm.proof) -> theory -> theory
    10   val add_realizes_eqns_i : ((term * term) list * (term * term)) list -> theory -> theory
    11   val add_realizes_eqns : string list -> theory -> theory
    12   val add_typeof_eqns_i : ((term * term) list * (term * term)) list -> theory -> theory
    13   val add_typeof_eqns : string list -> theory -> theory
    14   val add_realizers_i : (string * (string list * term * Proofterm.proof)) list
    15     -> theory -> theory
    16   val add_realizers : (thm * (string list * string * string)) list
    17     -> theory -> theory
    18   val add_expand_thms : thm list -> theory -> theory
    19   val add_types : (xstring * ((term -> term option) list *
    20     (term -> typ -> term -> typ -> term) option)) list -> theory -> theory
    21   val extract : (thm * string list) list -> theory -> theory
    22   val nullT : typ
    23   val nullt : term
    24   val mk_typ : typ -> term
    25   val etype_of : theory -> string list -> typ list -> term -> typ
    26   val realizes_of: theory -> string list -> term -> term -> term
    27 end;
    28 
    29 structure Extraction : EXTRACTION =
    30 struct
    31 
    32 open Proofterm;
    33 
    34 (**** tools ****)
    35 
    36 fun add_syntax thy =
    37   thy
    38   |> Theory.copy
    39   |> Sign.root_path
    40   |> Sign.add_types [("Type", 0, NoSyn), ("Null", 0, NoSyn)]
    41   |> Sign.add_consts
    42       [("typeof", "'b::{} => Type", NoSyn),
    43        ("Type", "'a::{} itself => Type", NoSyn),
    44        ("Null", "Null", NoSyn),
    45        ("realizes", "'a::{} => 'b::{} => 'b", NoSyn)];
    46 
    47 val nullT = Type ("Null", []);
    48 val nullt = Const ("Null", nullT);
    49 
    50 fun mk_typ T =
    51   Const ("Type", Term.itselfT T --> Type ("Type", [])) $ Logic.mk_type T;
    52 
    53 fun typeof_proc defaultS vs (Const ("typeof", _) $ u) =
    54       SOME (mk_typ (case strip_comb u of
    55           (Var ((a, i), _), _) =>
    56             if member (op =) vs a then TFree ("'" ^ a ^ ":" ^ string_of_int i, defaultS)
    57             else nullT
    58         | (Free (a, _), _) =>
    59             if member (op =) vs a then TFree ("'" ^ a, defaultS) else nullT
    60         | _ => nullT))
    61   | typeof_proc _ _ _ = NONE;
    62 
    63 fun rlz_proc (Const ("realizes", Type (_, [Type ("Null", []), _])) $ r $ t) = SOME t
    64   | rlz_proc (Const ("realizes", Type (_, [T, _])) $ r $ t) =
    65       (case strip_comb t of
    66          (Var (ixn, U), ts) => SOME (list_comb (Var (ixn, T --> U), r :: ts))
    67        | (Free (s, U), ts) => SOME (list_comb (Free (s, T --> U), r :: ts))
    68        | _ => NONE)
    69   | rlz_proc _ = NONE;
    70 
    71 val unpack_ixn = apfst implode o apsnd (fst o read_int o tl) o
    72   take_prefix (fn s => s <> ":") o explode;
    73 
    74 type rules =
    75   {next: int, rs: ((term * term) list * (term * term)) list,
    76    net: (int * ((term * term) list * (term * term))) Net.net};
    77 
    78 val empty_rules : rules = {next = 0, rs = [], net = Net.empty};
    79 
    80 fun add_rule (r as (_, (lhs, _)), {next, rs, net} : rules) =
    81   {next = next - 1, rs = r :: rs, net = Net.insert_term (K false)
    82      (Envir.eta_contract lhs, (next, r)) net};
    83 
    84 fun merge_rules
    85   ({next, rs = rs1, net} : rules) ({next = next2, rs = rs2, ...} : rules) =
    86   List.foldr add_rule {next = next, rs = rs1, net = net} (subtract (op =) rs1 rs2);
    87 
    88 fun condrew thy rules procs =
    89   let
    90     fun rew tm =
    91       Pattern.rewrite_term thy [] (condrew' :: procs) tm
    92     and condrew' tm =
    93       let
    94         val cache = ref ([] : (term * term) list);
    95         fun lookup f x = (case AList.lookup (op =) (!cache) x of
    96             NONE =>
    97               let val y = f x
    98               in (cache := (x, y) :: !cache; y) end
    99           | SOME y => y);
   100       in
   101         get_first (fn (_, (prems, (tm1, tm2))) =>
   102         let
   103           fun ren t = the_default t (Term.rename_abs tm1 tm t);
   104           val inc = Logic.incr_indexes ([], maxidx_of_term tm + 1);
   105           val env as (Tenv, tenv) = Pattern.match thy (inc tm1, tm) (Vartab.empty, Vartab.empty);
   106           val prems' = map (pairself (Envir.subst_vars env o inc o ren)) prems;
   107           val env' = Envir.Envir
   108             {maxidx = Library.foldl Int.max
   109               (~1, map (Int.max o pairself maxidx_of_term) prems'),
   110              iTs = Tenv, asol = tenv};
   111           val env'' = fold (Pattern.unify thy o pairself (lookup rew)) prems' env';
   112         in SOME (Envir.norm_term env'' (inc (ren tm2)))
   113         end handle Pattern.MATCH => NONE | Pattern.Unif => NONE)
   114           (sort (int_ord o pairself fst)
   115             (Net.match_term rules (Envir.eta_contract tm)))
   116       end;
   117 
   118   in rew end;
   119 
   120 val chtype = change_type o SOME;
   121 
   122 fun extr_name s vs = NameSpace.append "extr" (space_implode "_" (s :: vs));
   123 fun corr_name s vs = extr_name s vs ^ "_correctness";
   124 
   125 fun msg d s = priority (Symbol.spaces d ^ s);
   126 
   127 fun vars_of t = map Var (rev (Term.add_vars t []));
   128 fun frees_of t = map Free (rev (Term.add_frees t []));
   129 fun vfs_of t = vars_of t @ frees_of t;
   130 
   131 fun forall_intr_prf (t, prf) =
   132   let val (a, T) = (case t of Var ((a, _), T) => (a, T) | Free p => p)
   133   in Abst (a, SOME T, prf_abstract_over t prf) end;
   134 
   135 val mkabs = List.foldr (fn (v, t) => Abs ("x", fastype_of v, abstract_over (v, t)));
   136 
   137 fun strip_abs 0 t = t
   138   | strip_abs n (Abs (_, _, t)) = strip_abs (n-1) t
   139   | strip_abs _ _ = error "strip_abs: not an abstraction";
   140 
   141 fun prf_subst_TVars tye =
   142   map_proof_terms (subst_TVars tye) (typ_subst_TVars tye);
   143 
   144 fun relevant_vars types prop = List.foldr (fn
   145       (Var ((a, i), T), vs) => (case strip_type T of
   146         (_, Type (s, _)) => if member (op =) types s then a :: vs else vs
   147       | _ => vs)
   148     | (_, vs) => vs) [] (vars_of prop);
   149 
   150 fun tname_of (Type (s, _)) = s
   151   | tname_of _ = "";
   152 
   153 fun get_var_type t =
   154   let
   155     val vs = Term.add_vars t [];
   156     val fs = Term.add_frees t [];
   157   in fn 
   158       Var (ixn, _) => (case AList.lookup (op =) vs ixn of
   159           NONE => error "get_var_type: no such variable in term"
   160         | SOME T => Var (ixn, T))
   161     | Free (s, _) => (case AList.lookup (op =) fs s of
   162           NONE => error "get_var_type: no such variable in term"
   163         | SOME T => Free (s, T))
   164     | _ => error "get_var_type: not a variable"
   165   end;
   166 
   167 
   168 (**** theory data ****)
   169 
   170 (* theory data *)
   171 
   172 structure ExtractionData = TheoryDataFun
   173 (
   174   type T =
   175     {realizes_eqns : rules,
   176      typeof_eqns : rules,
   177      types : (string * ((term -> term option) list *
   178        (term -> typ -> term -> typ -> term) option)) list,
   179      realizers : (string list * (term * proof)) list Symtab.table,
   180      defs : thm list,
   181      expand : (string * term) list,
   182      prep : (theory -> proof -> proof) option}
   183 
   184   val empty =
   185     {realizes_eqns = empty_rules,
   186      typeof_eqns = empty_rules,
   187      types = [],
   188      realizers = Symtab.empty,
   189      defs = [],
   190      expand = [],
   191      prep = NONE};
   192   val copy = I;
   193   val extend = I;
   194 
   195   fun merge _
   196     (({realizes_eqns = realizes_eqns1, typeof_eqns = typeof_eqns1, types = types1,
   197        realizers = realizers1, defs = defs1, expand = expand1, prep = prep1},
   198       {realizes_eqns = realizes_eqns2, typeof_eqns = typeof_eqns2, types = types2,
   199        realizers = realizers2, defs = defs2, expand = expand2, prep = prep2}) : T * T) =
   200     {realizes_eqns = merge_rules realizes_eqns1 realizes_eqns2,
   201      typeof_eqns = merge_rules typeof_eqns1 typeof_eqns2,
   202      types = AList.merge (op =) (K true) (types1, types2),
   203      realizers = Symtab.merge_list (gen_eq_set (op =) o pairself #1) (realizers1, realizers2),
   204      defs = Library.merge Thm.eq_thm (defs1, defs2),
   205      expand = Library.merge (op =) (expand1, expand2),
   206      prep = (case prep1 of NONE => prep2 | _ => prep1)};
   207 );
   208 
   209 fun read_condeq thy =
   210   let val thy' = add_syntax thy
   211   in fn s =>
   212     let val t = Logic.varify (Syntax.read_prop_global thy' s)
   213     in (map Logic.dest_equals (Logic.strip_imp_prems t),
   214       Logic.dest_equals (Logic.strip_imp_concl t))
   215     end handle TERM _ => error ("Not a (conditional) meta equality:\n" ^ s)
   216   end;
   217 
   218 (** preprocessor **)
   219 
   220 fun set_preprocessor prep thy =
   221   let val {realizes_eqns, typeof_eqns, types, realizers,
   222     defs, expand, ...} = ExtractionData.get thy
   223   in
   224     ExtractionData.put
   225       {realizes_eqns = realizes_eqns, typeof_eqns = typeof_eqns, types = types,
   226        realizers = realizers, defs = defs, expand = expand, prep = SOME prep} thy
   227   end;
   228 
   229 (** equations characterizing realizability **)
   230 
   231 fun gen_add_realizes_eqns prep_eq eqns thy =
   232   let val {realizes_eqns, typeof_eqns, types, realizers,
   233     defs, expand, prep} = ExtractionData.get thy;
   234   in
   235     ExtractionData.put
   236       {realizes_eqns = List.foldr add_rule realizes_eqns (map (prep_eq thy) eqns),
   237        typeof_eqns = typeof_eqns, types = types, realizers = realizers,
   238        defs = defs, expand = expand, prep = prep} thy
   239   end
   240 
   241 val add_realizes_eqns_i = gen_add_realizes_eqns (K I);
   242 val add_realizes_eqns = gen_add_realizes_eqns read_condeq;
   243 
   244 (** equations characterizing type of extracted program **)
   245 
   246 fun gen_add_typeof_eqns prep_eq eqns thy =
   247   let
   248     val {realizes_eqns, typeof_eqns, types, realizers,
   249       defs, expand, prep} = ExtractionData.get thy;
   250     val eqns' = map (prep_eq thy) eqns
   251   in
   252     ExtractionData.put
   253       {realizes_eqns = realizes_eqns, realizers = realizers,
   254        typeof_eqns = List.foldr add_rule typeof_eqns eqns',
   255        types = types, defs = defs, expand = expand, prep = prep} thy
   256   end
   257 
   258 val add_typeof_eqns_i = gen_add_typeof_eqns (K I);
   259 val add_typeof_eqns = gen_add_typeof_eqns read_condeq;
   260 
   261 fun thaw (T as TFree (a, S)) =
   262       if exists_string (fn s => s = ":") a then TVar (unpack_ixn a, S) else T
   263   | thaw (Type (a, Ts)) = Type (a, map thaw Ts)
   264   | thaw T = T;
   265 
   266 fun freeze (TVar ((a, i), S)) = TFree (a ^ ":" ^ string_of_int i, S)
   267   | freeze (Type (a, Ts)) = Type (a, map freeze Ts)
   268   | freeze T = T;
   269 
   270 fun freeze_thaw f x =
   271   map_types thaw (f (map_types freeze x));
   272 
   273 fun etype_of thy vs Ts t =
   274   let
   275     val {typeof_eqns, ...} = ExtractionData.get thy;
   276     fun err () = error ("Unable to determine type of extracted program for\n" ^
   277       Syntax.string_of_term_global thy t)
   278   in case strip_abs_body (freeze_thaw (condrew thy (#net typeof_eqns)
   279     [typeof_proc (Sign.defaultS thy) vs]) (list_abs (map (pair "x") (rev Ts),
   280       Const ("typeof", fastype_of1 (Ts, t) --> Type ("Type", [])) $ t))) of
   281       Const ("Type", _) $ u => (Logic.dest_type u handle TERM _ => err ())
   282     | _ => err ()
   283   end;
   284 
   285 (** realizers for axioms / theorems, together with correctness proofs **)
   286 
   287 fun gen_add_realizers prep_rlz rs thy =
   288   let val {realizes_eqns, typeof_eqns, types, realizers,
   289     defs, expand, prep} = ExtractionData.get thy
   290   in
   291     ExtractionData.put
   292       {realizes_eqns = realizes_eqns, typeof_eqns = typeof_eqns, types = types,
   293        realizers = fold (Symtab.cons_list o prep_rlz thy) rs realizers,
   294        defs = defs, expand = expand, prep = prep} thy
   295   end
   296 
   297 fun prep_realizer thy =
   298   let
   299     val {realizes_eqns, typeof_eqns, defs, types, ...} =
   300       ExtractionData.get thy;
   301     val procs = maps (fst o snd) types;
   302     val rtypes = map fst types;
   303     val eqns = Net.merge (K false) (#net realizes_eqns, #net typeof_eqns);
   304     val thy' = add_syntax thy;
   305     val rd = ProofSyntax.read_proof thy' false
   306   in fn (thm, (vs, s1, s2)) =>
   307     let
   308       val name = Thm.get_name thm;
   309       val _ = name <> "" orelse error "add_realizers: unnamed theorem";
   310       val prop = Pattern.rewrite_term thy'
   311         (map (Logic.dest_equals o prop_of) defs) [] (prop_of thm);
   312       val vars = vars_of prop;
   313       val vars' = filter_out (fn v =>
   314         member (op =) rtypes (tname_of (body_type (fastype_of v)))) vars;
   315       val T = etype_of thy' vs [] prop;
   316       val (T', thw) = Type.freeze_thaw_type
   317         (if T = nullT then nullT else map fastype_of vars' ---> T);
   318       val t = map_types thw (OldGoals.simple_read_term thy' T' s1);
   319       val r' = freeze_thaw (condrew thy' eqns
   320         (procs @ [typeof_proc (Sign.defaultS thy') vs, rlz_proc]))
   321           (Const ("realizes", T --> propT --> propT) $
   322             (if T = nullT then t else list_comb (t, vars')) $ prop);
   323       val r = fold_rev Logic.all (map (get_var_type r') vars) r';
   324       val prf = Reconstruct.reconstruct_proof thy' r (rd s2);
   325     in (name, (vs, (t, prf))) end
   326   end;
   327 
   328 val add_realizers_i = gen_add_realizers
   329   (fn _ => fn (name, (vs, t, prf)) => (name, (vs, (t, prf))));
   330 val add_realizers = gen_add_realizers prep_realizer;
   331 
   332 fun realizes_of thy vs t prop =
   333   let
   334     val thy' = add_syntax thy;
   335     val {realizes_eqns, typeof_eqns, defs, types, ...} =
   336       ExtractionData.get thy';
   337     val procs = maps (rev o fst o snd) types;
   338     val eqns = Net.merge (K false) (#net realizes_eqns, #net typeof_eqns);
   339     val prop' = Pattern.rewrite_term thy'
   340       (map (Logic.dest_equals o prop_of) defs) [] prop;
   341   in freeze_thaw (condrew thy' eqns
   342     (procs @ [typeof_proc (Sign.defaultS thy') vs, rlz_proc]))
   343       (Const ("realizes", fastype_of t --> propT --> propT) $ t $ prop')
   344   end;
   345 
   346 (** expanding theorems / definitions **)
   347 
   348 fun add_expand_thm thm thy =
   349   let
   350     val {realizes_eqns, typeof_eqns, types, realizers,
   351       defs, expand, prep} = ExtractionData.get thy;
   352 
   353     val name = Thm.get_name thm;
   354     val _ = name <> "" orelse error "add_expand_thms: unnamed theorem";
   355 
   356     val is_def =
   357       (case strip_comb (fst (Logic.dest_equals (prop_of thm))) of
   358          (Const _, ts) => forall is_Var ts andalso not (has_duplicates (op =) ts)
   359            andalso (Thm.get_kind thm = Thm.definitionK orelse can (Thm.axiom thy) name)
   360        | _ => false) handle TERM _ => false;
   361   in
   362     (ExtractionData.put (if is_def then
   363         {realizes_eqns = realizes_eqns,
   364          typeof_eqns = add_rule (([],
   365            Logic.dest_equals (prop_of (Drule.abs_def thm))), typeof_eqns),
   366          types = types,
   367          realizers = realizers, defs = insert Thm.eq_thm thm defs,
   368          expand = expand, prep = prep}
   369       else
   370         {realizes_eqns = realizes_eqns, typeof_eqns = typeof_eqns, types = types,
   371          realizers = realizers, defs = defs,
   372          expand = insert (op =) (name, prop_of thm) expand, prep = prep}) thy)
   373   end;
   374 
   375 val add_expand_thms = fold add_expand_thm;
   376 
   377 val extraction_expand =
   378   Attrib.no_args (Thm.declaration_attribute (fn th => Context.mapping (add_expand_thm th) I));
   379 
   380 
   381 (** types with computational content **)
   382 
   383 fun add_types tys thy =
   384   ExtractionData.map
   385     (fn {realizes_eqns, typeof_eqns, types, realizers, defs, expand, prep} =>
   386       {realizes_eqns = realizes_eqns, typeof_eqns = typeof_eqns,
   387        types = fold (AList.update (op =) o apfst (Sign.intern_type thy)) tys types,
   388        realizers = realizers, defs = defs, expand = expand, prep = prep})
   389     thy;
   390 
   391 
   392 (** Pure setup **)
   393 
   394 val _ = Context.>> (Context.map_theory
   395   (add_types [("prop", ([], NONE))] #>
   396 
   397    add_typeof_eqns
   398      ["(typeof (PROP P)) == (Type (TYPE(Null))) ==>  \
   399     \  (typeof (PROP Q)) == (Type (TYPE('Q))) ==>  \
   400     \    (typeof (PROP P ==> PROP Q)) == (Type (TYPE('Q)))",
   401 
   402       "(typeof (PROP Q)) == (Type (TYPE(Null))) ==>  \
   403     \    (typeof (PROP P ==> PROP Q)) == (Type (TYPE(Null)))",
   404 
   405       "(typeof (PROP P)) == (Type (TYPE('P))) ==>  \
   406     \  (typeof (PROP Q)) == (Type (TYPE('Q))) ==>  \
   407     \    (typeof (PROP P ==> PROP Q)) == (Type (TYPE('P => 'Q)))",
   408 
   409       "(%x. typeof (PROP P (x))) == (%x. Type (TYPE(Null))) ==>  \
   410     \    (typeof (!!x. PROP P (x))) == (Type (TYPE(Null)))",
   411 
   412       "(%x. typeof (PROP P (x))) == (%x. Type (TYPE('P))) ==>  \
   413     \    (typeof (!!x::'a. PROP P (x))) == (Type (TYPE('a => 'P)))",
   414 
   415       "(%x. typeof (f (x))) == (%x. Type (TYPE('f))) ==>  \
   416     \    (typeof (f)) == (Type (TYPE('f)))"] #>
   417 
   418    add_realizes_eqns
   419      ["(typeof (PROP P)) == (Type (TYPE(Null))) ==>  \
   420     \    (realizes (r) (PROP P ==> PROP Q)) ==  \
   421     \    (PROP realizes (Null) (PROP P) ==> PROP realizes (r) (PROP Q))",
   422 
   423       "(typeof (PROP P)) == (Type (TYPE('P))) ==>  \
   424     \  (typeof (PROP Q)) == (Type (TYPE(Null))) ==>  \
   425     \    (realizes (r) (PROP P ==> PROP Q)) ==  \
   426     \    (!!x::'P. PROP realizes (x) (PROP P) ==> PROP realizes (Null) (PROP Q))",
   427 
   428       "(realizes (r) (PROP P ==> PROP Q)) ==  \
   429     \  (!!x. PROP realizes (x) (PROP P) ==> PROP realizes (r (x)) (PROP Q))",
   430 
   431       "(%x. typeof (PROP P (x))) == (%x. Type (TYPE(Null))) ==>  \
   432     \    (realizes (r) (!!x. PROP P (x))) ==  \
   433     \    (!!x. PROP realizes (Null) (PROP P (x)))",
   434 
   435       "(realizes (r) (!!x. PROP P (x))) ==  \
   436     \  (!!x. PROP realizes (r (x)) (PROP P (x)))"] #>
   437 
   438    Attrib.add_attributes
   439      [("extraction_expand", extraction_expand,
   440        "specify theorems / definitions to be expanded during extraction")]));
   441 
   442 
   443 (**** extract program ****)
   444 
   445 val dummyt = Const ("dummy", dummyT);
   446 
   447 fun extract thms thy =
   448   let
   449     val thy' = add_syntax thy;
   450     val {realizes_eqns, typeof_eqns, types, realizers, defs, expand, prep} =
   451       ExtractionData.get thy;
   452     val procs = maps (rev o fst o snd) types;
   453     val rtypes = map fst types;
   454     val typroc = typeof_proc (Sign.defaultS thy');
   455     val prep = the_default (K I) prep thy' o ProofRewriteRules.elim_defs thy' false defs o
   456       Reconstruct.expand_proof thy' (("", NONE) :: map (apsnd SOME) expand);
   457     val rrews = Net.merge (K false) (#net realizes_eqns, #net typeof_eqns);
   458 
   459     fun find_inst prop Ts ts vs =
   460       let
   461         val rvs = relevant_vars rtypes prop;
   462         val vars = vars_of prop;
   463         val n = Int.min (length vars, length ts);
   464 
   465         fun add_args ((Var ((a, i), _), t), (vs', tye)) =
   466           if member (op =) rvs a then
   467             let val T = etype_of thy' vs Ts t
   468             in if T = nullT then (vs', tye)
   469                else (a :: vs', (("'" ^ a, i), T) :: tye)
   470             end
   471           else (vs', tye)
   472 
   473       in List.foldr add_args ([], []) (Library.take (n, vars) ~~ Library.take (n, ts)) end;
   474 
   475     fun find (vs: string list) = Option.map snd o find_first (curry (gen_eq_set (op =)) vs o fst);
   476     fun find' (s: string) = map_filter (fn (s', x) => if s = s' then SOME x else NONE);
   477 
   478     fun app_rlz_rews Ts vs t = strip_abs (length Ts) (freeze_thaw
   479       (condrew thy' rrews (procs @ [typroc vs, rlz_proc])) (list_abs
   480         (map (pair "x") (rev Ts), t)));
   481 
   482     fun realizes_null vs prop = app_rlz_rews [] vs
   483       (Const ("realizes", nullT --> propT --> propT) $ nullt $ prop);
   484 
   485     fun corr d defs vs ts Ts hs (PBound i) _ _ = (defs, PBound i)
   486 
   487       | corr d defs vs ts Ts hs (Abst (s, SOME T, prf)) (Abst (_, _, prf')) t =
   488           let val (defs', corr_prf) = corr d defs vs [] (T :: Ts)
   489             (dummyt :: hs) prf (incr_pboundvars 1 0 prf')
   490             (case t of SOME (Abs (_, _, u)) => SOME u | _ => NONE)
   491           in (defs', Abst (s, SOME T, corr_prf)) end
   492 
   493       | corr d defs vs ts Ts hs (AbsP (s, SOME prop, prf)) (AbsP (_, _, prf')) t =
   494           let
   495             val T = etype_of thy' vs Ts prop;
   496             val u = if T = nullT then 
   497                 (case t of SOME u => SOME (incr_boundvars 1 u) | NONE => NONE)
   498               else (case t of SOME (Abs (_, _, u)) => SOME u | _ => NONE);
   499             val (defs', corr_prf) = corr d defs vs [] (T :: Ts) (prop :: hs)
   500               (incr_pboundvars 0 1 prf) (incr_pboundvars 0 1 prf') u;
   501             val rlz = Const ("realizes", T --> propT --> propT)
   502           in (defs',
   503             if T = nullT then AbsP ("R",
   504               SOME (app_rlz_rews Ts vs (rlz $ nullt $ prop)),
   505                 prf_subst_bounds [nullt] corr_prf)
   506             else Abst (s, SOME T, AbsP ("R",
   507               SOME (app_rlz_rews (T :: Ts) vs
   508                 (rlz $ Bound 0 $ incr_boundvars 1 prop)), corr_prf)))
   509           end
   510 
   511       | corr d defs vs ts Ts hs (prf % SOME t) (prf' % _) t' =
   512           let
   513             val (Us, T) = strip_type (fastype_of1 (Ts, t));
   514             val (defs', corr_prf) = corr d defs vs (t :: ts) Ts hs prf prf'
   515               (if member (op =) rtypes (tname_of T) then t'
   516                else (case t' of SOME (u $ _) => SOME u | _ => NONE));
   517             val u = if not (member (op =) rtypes (tname_of T)) then t else
   518               let
   519                 val eT = etype_of thy' vs Ts t;
   520                 val (r, Us') = if eT = nullT then (nullt, Us) else
   521                   (Bound (length Us), eT :: Us);
   522                 val u = list_comb (incr_boundvars (length Us') t,
   523                   map Bound (length Us - 1 downto 0));
   524                 val u' = (case AList.lookup (op =) types (tname_of T) of
   525                     SOME ((_, SOME f)) => f r eT u T
   526                   | _ => Const ("realizes", eT --> T --> T) $ r $ u)
   527               in app_rlz_rews Ts vs (list_abs (map (pair "x") Us', u')) end
   528           in (defs', corr_prf % SOME u) end
   529 
   530       | corr d defs vs ts Ts hs (prf1 %% prf2) (prf1' %% prf2') t =
   531           let
   532             val prop = Reconstruct.prop_of' hs prf2';
   533             val T = etype_of thy' vs Ts prop;
   534             val (defs1, f, u) = if T = nullT then (defs, t, NONE) else
   535               (case t of
   536                  SOME (f $ u) => (defs, SOME f, SOME u)
   537                | _ =>
   538                  let val (defs1, u) = extr d defs vs [] Ts hs prf2'
   539                  in (defs1, NONE, SOME u) end)
   540             val (defs2, corr_prf1) = corr d defs1 vs [] Ts hs prf1 prf1' f;
   541             val (defs3, corr_prf2) = corr d defs2 vs [] Ts hs prf2 prf2' u;
   542           in
   543             if T = nullT then (defs3, corr_prf1 %% corr_prf2) else
   544               (defs3, corr_prf1 % u %% corr_prf2)
   545           end
   546 
   547       | corr d defs vs ts Ts hs (prf0 as PThm (_, ((name, prop, SOME Ts'), body))) _ _ =
   548           let
   549             val prf = force_proof body;
   550             val (vs', tye) = find_inst prop Ts ts vs;
   551             val tye' = (map fst (OldTerm.term_tvars prop) ~~ Ts') @ tye;
   552             val T = etype_of thy' vs' [] prop;
   553             val defs' = if T = nullT then defs
   554               else fst (extr d defs vs ts Ts hs prf0)
   555           in
   556             if T = nullT andalso realizes_null vs' prop aconv prop then (defs, prf0)
   557             else case Symtab.lookup realizers name of
   558               NONE => (case find vs' (find' name defs') of
   559                 NONE =>
   560                   let
   561                     val _ = T = nullT orelse error "corr: internal error";
   562                     val _ = msg d ("Building correctness proof for " ^ quote name ^
   563                       (if null vs' then ""
   564                        else " (relevant variables: " ^ commas_quote vs' ^ ")"));
   565                     val prf' = prep (Reconstruct.reconstruct_proof thy' prop prf);
   566                     val (defs'', corr_prf) =
   567                       corr (d + 1) defs' vs' [] [] [] prf' prf' NONE;
   568                     val corr_prop = Reconstruct.prop_of corr_prf;
   569                     val corr_prf' = List.foldr forall_intr_prf
   570                       (proof_combt
   571                          (PThm (serial (),
   572                           ((corr_name name vs', corr_prop, SOME (map TVar (OldTerm.term_tvars corr_prop))),
   573                             Lazy.value (make_proof_body corr_prf))), vfs_of corr_prop))
   574                       (map (get_var_type corr_prop) (vfs_of prop))
   575                   in
   576                     ((name, (vs', ((nullt, nullt), (corr_prf, corr_prf')))) :: defs'',
   577                      prf_subst_TVars tye' corr_prf')
   578                   end
   579               | SOME (_, (_, prf')) => (defs', prf_subst_TVars tye' prf'))
   580             | SOME rs => (case find vs' rs of
   581                 SOME (_, prf') => (defs', prf_subst_TVars tye' prf')
   582               | NONE => error ("corr: no realizer for instance of theorem " ^
   583                   quote name ^ ":\n" ^ Syntax.string_of_term_global thy' (Envir.beta_norm
   584                     (Reconstruct.prop_of (proof_combt (prf0, ts))))))
   585           end
   586 
   587       | corr d defs vs ts Ts hs (prf0 as PAxm (s, prop, SOME Ts')) _ _ =
   588           let
   589             val (vs', tye) = find_inst prop Ts ts vs;
   590             val tye' = (map fst (OldTerm.term_tvars prop) ~~ Ts') @ tye
   591           in
   592             if etype_of thy' vs' [] prop = nullT andalso
   593               realizes_null vs' prop aconv prop then (defs, prf0)
   594             else case find vs' (Symtab.lookup_list realizers s) of
   595               SOME (_, prf) => (defs, prf_subst_TVars tye' prf)
   596             | NONE => error ("corr: no realizer for instance of axiom " ^
   597                 quote s ^ ":\n" ^ Syntax.string_of_term_global thy' (Envir.beta_norm
   598                   (Reconstruct.prop_of (proof_combt (prf0, ts)))))
   599           end
   600 
   601       | corr d defs vs ts Ts hs _ _ _ = error "corr: bad proof"
   602 
   603     and extr d defs vs ts Ts hs (PBound i) = (defs, Bound i)
   604 
   605       | extr d defs vs ts Ts hs (Abst (s, SOME T, prf)) =
   606           let val (defs', t) = extr d defs vs []
   607             (T :: Ts) (dummyt :: hs) (incr_pboundvars 1 0 prf)
   608           in (defs', Abs (s, T, t)) end
   609 
   610       | extr d defs vs ts Ts hs (AbsP (s, SOME t, prf)) =
   611           let
   612             val T = etype_of thy' vs Ts t;
   613             val (defs', t) = extr d defs vs [] (T :: Ts) (t :: hs)
   614               (incr_pboundvars 0 1 prf)
   615           in (defs',
   616             if T = nullT then subst_bound (nullt, t) else Abs (s, T, t))
   617           end
   618 
   619       | extr d defs vs ts Ts hs (prf % SOME t) =
   620           let val (defs', u) = extr d defs vs (t :: ts) Ts hs prf
   621           in (defs',
   622             if member (op =) rtypes (tname_of (body_type (fastype_of1 (Ts, t)))) then u
   623             else u $ t)
   624           end
   625 
   626       | extr d defs vs ts Ts hs (prf1 %% prf2) =
   627           let
   628             val (defs', f) = extr d defs vs [] Ts hs prf1;
   629             val prop = Reconstruct.prop_of' hs prf2;
   630             val T = etype_of thy' vs Ts prop
   631           in
   632             if T = nullT then (defs', f) else
   633               let val (defs'', t) = extr d defs' vs [] Ts hs prf2
   634               in (defs'', f $ t) end
   635           end
   636 
   637       | extr d defs vs ts Ts hs (prf0 as PThm (_, ((s, prop, SOME Ts'), body))) =
   638           let
   639             val prf = force_proof body;
   640             val (vs', tye) = find_inst prop Ts ts vs;
   641             val tye' = (map fst (OldTerm.term_tvars prop) ~~ Ts') @ tye
   642           in
   643             case Symtab.lookup realizers s of
   644               NONE => (case find vs' (find' s defs) of
   645                 NONE =>
   646                   let
   647                     val _ = msg d ("Extracting " ^ quote s ^
   648                       (if null vs' then ""
   649                        else " (relevant variables: " ^ commas_quote vs' ^ ")"));
   650                     val prf' = prep (Reconstruct.reconstruct_proof thy' prop prf);
   651                     val (defs', t) = extr (d + 1) defs vs' [] [] [] prf';
   652                     val (defs'', corr_prf) =
   653                       corr (d + 1) defs' vs' [] [] [] prf' prf' (SOME t);
   654 
   655                     val nt = Envir.beta_norm t;
   656                     val args = filter_out (fn v => member (op =) rtypes
   657                       (tname_of (body_type (fastype_of v)))) (vfs_of prop);
   658                     val args' = List.filter (fn v => Logic.occs (v, nt)) args;
   659                     val t' = mkabs nt args';
   660                     val T = fastype_of t';
   661                     val cname = extr_name s vs';
   662                     val c = Const (cname, T);
   663                     val u = mkabs (list_comb (c, args')) args;
   664                     val eqn = Logic.mk_equals (c, t');
   665                     val rlz =
   666                       Const ("realizes", fastype_of nt --> propT --> propT);
   667                     val lhs = app_rlz_rews [] vs' (rlz $ nt $ prop);
   668                     val rhs = app_rlz_rews [] vs' (rlz $ list_comb (c, args') $ prop);
   669                     val f = app_rlz_rews [] vs'
   670                       (Abs ("x", T, rlz $ list_comb (Bound 0, args') $ prop));
   671 
   672                     val corr_prf' =
   673                       chtype [] equal_elim_axm %> lhs %> rhs %%
   674                        (chtype [propT] symmetric_axm %> rhs %> lhs %%
   675                          (chtype [propT, T] combination_axm %> f %> f %> c %> t' %%
   676                            (chtype [T --> propT] reflexive_axm %> f) %%
   677                            PAxm (cname ^ "_def", eqn,
   678                              SOME (map TVar (OldTerm.term_tvars eqn))))) %% corr_prf;
   679                     val corr_prop = Reconstruct.prop_of corr_prf';
   680                     val corr_prf'' = List.foldr forall_intr_prf
   681                       (proof_combt
   682                         (PThm (serial (),
   683                          ((corr_name s vs', corr_prop, SOME (map TVar (OldTerm.term_tvars corr_prop))),
   684                            Lazy.value (make_proof_body corr_prf'))), vfs_of corr_prop))
   685                       (map (get_var_type corr_prop) (vfs_of prop));
   686                   in
   687                     ((s, (vs', ((t', u), (corr_prf', corr_prf'')))) :: defs'',
   688                      subst_TVars tye' u)
   689                   end
   690               | SOME ((_, u), _) => (defs, subst_TVars tye' u))
   691             | SOME rs => (case find vs' rs of
   692                 SOME (t, _) => (defs, subst_TVars tye' t)
   693               | NONE => error ("extr: no realizer for instance of theorem " ^
   694                   quote s ^ ":\n" ^ Syntax.string_of_term_global thy' (Envir.beta_norm
   695                     (Reconstruct.prop_of (proof_combt (prf0, ts))))))
   696           end
   697 
   698       | extr d defs vs ts Ts hs (prf0 as PAxm (s, prop, SOME Ts')) =
   699           let
   700             val (vs', tye) = find_inst prop Ts ts vs;
   701             val tye' = (map fst (OldTerm.term_tvars prop) ~~ Ts') @ tye
   702           in
   703             case find vs' (Symtab.lookup_list realizers s) of
   704               SOME (t, _) => (defs, subst_TVars tye' t)
   705             | NONE => error ("extr: no realizer for instance of axiom " ^
   706                 quote s ^ ":\n" ^ Syntax.string_of_term_global thy' (Envir.beta_norm
   707                   (Reconstruct.prop_of (proof_combt (prf0, ts)))))
   708           end
   709 
   710       | extr d defs vs ts Ts hs _ = error "extr: bad proof";
   711 
   712     fun prep_thm (thm, vs) =
   713       let
   714         val thy = Thm.theory_of_thm thm;
   715         val prop = Thm.prop_of thm;
   716         val prf = Thm.proof_of thm;
   717         val name = Thm.get_name thm;
   718         val _ = name <> "" orelse error "extraction: unnamed theorem";
   719         val _ = etype_of thy' vs [] prop <> nullT orelse error ("theorem " ^
   720           quote name ^ " has no computational content")
   721       in (Reconstruct.reconstruct_proof thy prop prf, vs) end;
   722 
   723     val defs = Library.foldl (fn (defs, (prf, vs)) =>
   724       fst (extr 0 defs vs [] [] [] prf)) ([], map prep_thm thms);
   725 
   726     fun add_def (s, (vs, ((t, u), (prf, _)))) thy =
   727       (case Sign.const_type thy (extr_name s vs) of
   728          NONE =>
   729            let
   730              val corr_prop = Reconstruct.prop_of prf;
   731              val ft = Type.freeze t;
   732              val fu = Type.freeze u;
   733              val (def_thms, thy') = if t = nullt then ([], thy) else
   734                thy
   735                |> Sign.add_consts_i [(extr_name s vs, fastype_of ft, NoSyn)]
   736                |> PureThy.add_defs false [((Binding.name (extr_name s vs ^ "_def"),
   737                     Logic.mk_equals (head_of (strip_abs_body fu), ft)), [])]
   738            in
   739              thy'
   740              |> PureThy.store_thm (Binding.name (corr_name s vs),
   741                   Thm.varifyT (funpow (length (OldTerm.term_vars corr_prop))
   742                     (Thm.forall_elim_var 0) (forall_intr_frees
   743                       (ProofChecker.thm_of_proof thy'
   744                        (fst (Proofterm.freeze_thaw_prf prf))))))
   745              |> snd
   746              |> fold Code.add_default_eqn def_thms
   747            end
   748        | SOME _ => thy);
   749 
   750   in
   751     thy
   752     |> Sign.absolute_path
   753     |> fold_rev add_def defs
   754     |> Sign.restore_naming thy
   755   end;
   756 
   757 
   758 (**** interface ****)
   759 
   760 structure P = OuterParse and K = OuterKeyword;
   761 
   762 val parse_vars = Scan.optional (P.$$$ "(" |-- P.list1 P.name --| P.$$$ ")") [];
   763 
   764 val _ =
   765   OuterSyntax.command "realizers"
   766   "specify realizers for primitive axioms / theorems, together with correctness proof"
   767   K.thy_decl
   768     (Scan.repeat1 (P.xname -- parse_vars --| P.$$$ ":" -- P.string -- P.string) >>
   769      (fn xs => Toplevel.theory (fn thy => add_realizers
   770        (map (fn (((a, vs), s1), s2) => (PureThy.get_thm thy a, (vs, s1, s2))) xs) thy)));
   771 
   772 val _ =
   773   OuterSyntax.command "realizability"
   774   "add equations characterizing realizability" K.thy_decl
   775   (Scan.repeat1 P.string >> (Toplevel.theory o add_realizes_eqns));
   776 
   777 val _ =
   778   OuterSyntax.command "extract_type"
   779   "add equations characterizing type of extracted program" K.thy_decl
   780   (Scan.repeat1 P.string >> (Toplevel.theory o add_typeof_eqns));
   781 
   782 val _ =
   783   OuterSyntax.command "extract" "extract terms from proofs" K.thy_decl
   784     (Scan.repeat1 (P.xname -- parse_vars) >> (fn xs => Toplevel.theory (fn thy =>
   785       extract (map (apfst (PureThy.get_thm thy)) xs) thy)));
   786 
   787 val etype_of = etype_of o add_syntax;
   788 
   789 end;