src/HOL/Multivariate_Analysis/Topology_Euclidean_Space.thy
author noschinl
Mon Mar 12 21:34:43 2012 +0100 (2012-03-12)
changeset 46887 cb891d9a23c1
parent 45776 714100f5fda4
child 47108 2a1953f0d20d
permissions -rw-r--r--
use eventually_elim method
     1 (*  title:      HOL/Library/Topology_Euclidian_Space.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3     Author:     Robert Himmelmann, TU Muenchen
     4     Author:     Brian Huffman, Portland State University
     5 *)
     6 
     7 header {* Elementary topology in Euclidean space. *}
     8 
     9 theory Topology_Euclidean_Space
    10 imports SEQ Linear_Algebra "~~/src/HOL/Library/Glbs" Norm_Arith
    11 begin
    12 
    13 subsection {* General notion of a topology as a value *}
    14 
    15 definition "istopology L \<longleftrightarrow> L {} \<and> (\<forall>S T. L S \<longrightarrow> L T \<longrightarrow> L (S \<inter> T)) \<and> (\<forall>K. Ball K L \<longrightarrow> L (\<Union> K))"
    16 typedef (open) 'a topology = "{L::('a set) \<Rightarrow> bool. istopology L}"
    17   morphisms "openin" "topology"
    18   unfolding istopology_def by blast
    19 
    20 lemma istopology_open_in[intro]: "istopology(openin U)"
    21   using openin[of U] by blast
    22 
    23 lemma topology_inverse': "istopology U \<Longrightarrow> openin (topology U) = U"
    24   using topology_inverse[unfolded mem_Collect_eq] .
    25 
    26 lemma topology_inverse_iff: "istopology U \<longleftrightarrow> openin (topology U) = U"
    27   using topology_inverse[of U] istopology_open_in[of "topology U"] by auto
    28 
    29 lemma topology_eq: "T1 = T2 \<longleftrightarrow> (\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S)"
    30 proof-
    31   {assume "T1=T2" hence "\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S" by simp}
    32   moreover
    33   {assume H: "\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S"
    34     hence "openin T1 = openin T2" by (simp add: fun_eq_iff)
    35     hence "topology (openin T1) = topology (openin T2)" by simp
    36     hence "T1 = T2" unfolding openin_inverse .}
    37   ultimately show ?thesis by blast
    38 qed
    39 
    40 text{* Infer the "universe" from union of all sets in the topology. *}
    41 
    42 definition "topspace T =  \<Union>{S. openin T S}"
    43 
    44 subsubsection {* Main properties of open sets *}
    45 
    46 lemma openin_clauses:
    47   fixes U :: "'a topology"
    48   shows "openin U {}"
    49   "\<And>S T. openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S\<inter>T)"
    50   "\<And>K. (\<forall>S \<in> K. openin U S) \<Longrightarrow> openin U (\<Union>K)"
    51   using openin[of U] unfolding istopology_def mem_Collect_eq
    52   by fast+
    53 
    54 lemma openin_subset[intro]: "openin U S \<Longrightarrow> S \<subseteq> topspace U"
    55   unfolding topspace_def by blast
    56 lemma openin_empty[simp]: "openin U {}" by (simp add: openin_clauses)
    57 
    58 lemma openin_Int[intro]: "openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S \<inter> T)"
    59   using openin_clauses by simp
    60 
    61 lemma openin_Union[intro]: "(\<forall>S \<in>K. openin U S) \<Longrightarrow> openin U (\<Union> K)"
    62   using openin_clauses by simp
    63 
    64 lemma openin_Un[intro]: "openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S \<union> T)"
    65   using openin_Union[of "{S,T}" U] by auto
    66 
    67 lemma openin_topspace[intro, simp]: "openin U (topspace U)" by (simp add: openin_Union topspace_def)
    68 
    69 lemma openin_subopen: "openin U S \<longleftrightarrow> (\<forall>x \<in> S. \<exists>T. openin U T \<and> x \<in> T \<and> T \<subseteq> S)" (is "?lhs \<longleftrightarrow> ?rhs")
    70 proof
    71   assume ?lhs then show ?rhs by auto
    72 next
    73   assume H: ?rhs
    74   let ?t = "\<Union>{T. openin U T \<and> T \<subseteq> S}"
    75   have "openin U ?t" by (simp add: openin_Union)
    76   also have "?t = S" using H by auto
    77   finally show "openin U S" .
    78 qed
    79 
    80 subsubsection {* Closed sets *}
    81 
    82 definition "closedin U S \<longleftrightarrow> S \<subseteq> topspace U \<and> openin U (topspace U - S)"
    83 
    84 lemma closedin_subset: "closedin U S \<Longrightarrow> S \<subseteq> topspace U" by (metis closedin_def)
    85 lemma closedin_empty[simp]: "closedin U {}" by (simp add: closedin_def)
    86 lemma closedin_topspace[intro,simp]:
    87   "closedin U (topspace U)" by (simp add: closedin_def)
    88 lemma closedin_Un[intro]: "closedin U S \<Longrightarrow> closedin U T \<Longrightarrow> closedin U (S \<union> T)"
    89   by (auto simp add: Diff_Un closedin_def)
    90 
    91 lemma Diff_Inter[intro]: "A - \<Inter>S = \<Union> {A - s|s. s\<in>S}" by auto
    92 lemma closedin_Inter[intro]: assumes Ke: "K \<noteq> {}" and Kc: "\<forall>S \<in>K. closedin U S"
    93   shows "closedin U (\<Inter> K)"  using Ke Kc unfolding closedin_def Diff_Inter by auto
    94 
    95 lemma closedin_Int[intro]: "closedin U S \<Longrightarrow> closedin U T \<Longrightarrow> closedin U (S \<inter> T)"
    96   using closedin_Inter[of "{S,T}" U] by auto
    97 
    98 lemma Diff_Diff_Int: "A - (A - B) = A \<inter> B" by blast
    99 lemma openin_closedin_eq: "openin U S \<longleftrightarrow> S \<subseteq> topspace U \<and> closedin U (topspace U - S)"
   100   apply (auto simp add: closedin_def Diff_Diff_Int inf_absorb2)
   101   apply (metis openin_subset subset_eq)
   102   done
   103 
   104 lemma openin_closedin:  "S \<subseteq> topspace U \<Longrightarrow> (openin U S \<longleftrightarrow> closedin U (topspace U - S))"
   105   by (simp add: openin_closedin_eq)
   106 
   107 lemma openin_diff[intro]: assumes oS: "openin U S" and cT: "closedin U T" shows "openin U (S - T)"
   108 proof-
   109   have "S - T = S \<inter> (topspace U - T)" using openin_subset[of U S]  oS cT
   110     by (auto simp add: topspace_def openin_subset)
   111   then show ?thesis using oS cT by (auto simp add: closedin_def)
   112 qed
   113 
   114 lemma closedin_diff[intro]: assumes oS: "closedin U S" and cT: "openin U T" shows "closedin U (S - T)"
   115 proof-
   116   have "S - T = S \<inter> (topspace U - T)" using closedin_subset[of U S]  oS cT
   117     by (auto simp add: topspace_def )
   118   then show ?thesis using oS cT by (auto simp add: openin_closedin_eq)
   119 qed
   120 
   121 subsubsection {* Subspace topology *}
   122 
   123 definition "subtopology U V = topology (\<lambda>T. \<exists>S. T = S \<inter> V \<and> openin U S)"
   124 
   125 lemma istopology_subtopology: "istopology (\<lambda>T. \<exists>S. T = S \<inter> V \<and> openin U S)"
   126   (is "istopology ?L")
   127 proof-
   128   have "?L {}" by blast
   129   {fix A B assume A: "?L A" and B: "?L B"
   130     from A B obtain Sa and Sb where Sa: "openin U Sa" "A = Sa \<inter> V" and Sb: "openin U Sb" "B = Sb \<inter> V" by blast
   131     have "A\<inter>B = (Sa \<inter> Sb) \<inter> V" "openin U (Sa \<inter> Sb)"  using Sa Sb by blast+
   132     then have "?L (A \<inter> B)" by blast}
   133   moreover
   134   {fix K assume K: "K \<subseteq> Collect ?L"
   135     have th0: "Collect ?L = (\<lambda>S. S \<inter> V) ` Collect (openin U)"
   136       apply (rule set_eqI)
   137       apply (simp add: Ball_def image_iff)
   138       by metis
   139     from K[unfolded th0 subset_image_iff]
   140     obtain Sk where Sk: "Sk \<subseteq> Collect (openin U)" "K = (\<lambda>S. S \<inter> V) ` Sk" by blast
   141     have "\<Union>K = (\<Union>Sk) \<inter> V" using Sk by auto
   142     moreover have "openin U (\<Union> Sk)" using Sk by (auto simp add: subset_eq)
   143     ultimately have "?L (\<Union>K)" by blast}
   144   ultimately show ?thesis
   145     unfolding subset_eq mem_Collect_eq istopology_def by blast
   146 qed
   147 
   148 lemma openin_subtopology:
   149   "openin (subtopology U V) S \<longleftrightarrow> (\<exists> T. (openin U T) \<and> (S = T \<inter> V))"
   150   unfolding subtopology_def topology_inverse'[OF istopology_subtopology]
   151   by auto
   152 
   153 lemma topspace_subtopology: "topspace(subtopology U V) = topspace U \<inter> V"
   154   by (auto simp add: topspace_def openin_subtopology)
   155 
   156 lemma closedin_subtopology:
   157   "closedin (subtopology U V) S \<longleftrightarrow> (\<exists>T. closedin U T \<and> S = T \<inter> V)"
   158   unfolding closedin_def topspace_subtopology
   159   apply (simp add: openin_subtopology)
   160   apply (rule iffI)
   161   apply clarify
   162   apply (rule_tac x="topspace U - T" in exI)
   163   by auto
   164 
   165 lemma openin_subtopology_refl: "openin (subtopology U V) V \<longleftrightarrow> V \<subseteq> topspace U"
   166   unfolding openin_subtopology
   167   apply (rule iffI, clarify)
   168   apply (frule openin_subset[of U])  apply blast
   169   apply (rule exI[where x="topspace U"])
   170   by auto
   171 
   172 lemma subtopology_superset: assumes UV: "topspace U \<subseteq> V"
   173   shows "subtopology U V = U"
   174 proof-
   175   {fix S
   176     {fix T assume T: "openin U T" "S = T \<inter> V"
   177       from T openin_subset[OF T(1)] UV have eq: "S = T" by blast
   178       have "openin U S" unfolding eq using T by blast}
   179     moreover
   180     {assume S: "openin U S"
   181       hence "\<exists>T. openin U T \<and> S = T \<inter> V"
   182         using openin_subset[OF S] UV by auto}
   183     ultimately have "(\<exists>T. openin U T \<and> S = T \<inter> V) \<longleftrightarrow> openin U S" by blast}
   184   then show ?thesis unfolding topology_eq openin_subtopology by blast
   185 qed
   186 
   187 lemma subtopology_topspace[simp]: "subtopology U (topspace U) = U"
   188   by (simp add: subtopology_superset)
   189 
   190 lemma subtopology_UNIV[simp]: "subtopology U UNIV = U"
   191   by (simp add: subtopology_superset)
   192 
   193 subsubsection {* The standard Euclidean topology *}
   194 
   195 definition
   196   euclidean :: "'a::topological_space topology" where
   197   "euclidean = topology open"
   198 
   199 lemma open_openin: "open S \<longleftrightarrow> openin euclidean S"
   200   unfolding euclidean_def
   201   apply (rule cong[where x=S and y=S])
   202   apply (rule topology_inverse[symmetric])
   203   apply (auto simp add: istopology_def)
   204   done
   205 
   206 lemma topspace_euclidean: "topspace euclidean = UNIV"
   207   apply (simp add: topspace_def)
   208   apply (rule set_eqI)
   209   by (auto simp add: open_openin[symmetric])
   210 
   211 lemma topspace_euclidean_subtopology[simp]: "topspace (subtopology euclidean S) = S"
   212   by (simp add: topspace_euclidean topspace_subtopology)
   213 
   214 lemma closed_closedin: "closed S \<longleftrightarrow> closedin euclidean S"
   215   by (simp add: closed_def closedin_def topspace_euclidean open_openin Compl_eq_Diff_UNIV)
   216 
   217 lemma open_subopen: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S)"
   218   by (simp add: open_openin openin_subopen[symmetric])
   219 
   220 text {* Basic "localization" results are handy for connectedness. *}
   221 
   222 lemma openin_open: "openin (subtopology euclidean U) S \<longleftrightarrow> (\<exists>T. open T \<and> (S = U \<inter> T))"
   223   by (auto simp add: openin_subtopology open_openin[symmetric])
   224 
   225 lemma openin_open_Int[intro]: "open S \<Longrightarrow> openin (subtopology euclidean U) (U \<inter> S)"
   226   by (auto simp add: openin_open)
   227 
   228 lemma open_openin_trans[trans]:
   229  "open S \<Longrightarrow> open T \<Longrightarrow> T \<subseteq> S \<Longrightarrow> openin (subtopology euclidean S) T"
   230   by (metis Int_absorb1  openin_open_Int)
   231 
   232 lemma open_subset:  "S \<subseteq> T \<Longrightarrow> open S \<Longrightarrow> openin (subtopology euclidean T) S"
   233   by (auto simp add: openin_open)
   234 
   235 lemma closedin_closed: "closedin (subtopology euclidean U) S \<longleftrightarrow> (\<exists>T. closed T \<and> S = U \<inter> T)"
   236   by (simp add: closedin_subtopology closed_closedin Int_ac)
   237 
   238 lemma closedin_closed_Int: "closed S ==> closedin (subtopology euclidean U) (U \<inter> S)"
   239   by (metis closedin_closed)
   240 
   241 lemma closed_closedin_trans: "closed S \<Longrightarrow> closed T \<Longrightarrow> T \<subseteq> S \<Longrightarrow> closedin (subtopology euclidean S) T"
   242   apply (subgoal_tac "S \<inter> T = T" )
   243   apply auto
   244   apply (frule closedin_closed_Int[of T S])
   245   by simp
   246 
   247 lemma closed_subset: "S \<subseteq> T \<Longrightarrow> closed S \<Longrightarrow> closedin (subtopology euclidean T) S"
   248   by (auto simp add: closedin_closed)
   249 
   250 lemma openin_euclidean_subtopology_iff:
   251   fixes S U :: "'a::metric_space set"
   252   shows "openin (subtopology euclidean U) S
   253   \<longleftrightarrow> S \<subseteq> U \<and> (\<forall>x\<in>S. \<exists>e>0. \<forall>x'\<in>U. dist x' x < e \<longrightarrow> x'\<in> S)" (is "?lhs \<longleftrightarrow> ?rhs")
   254 proof
   255   assume ?lhs thus ?rhs unfolding openin_open open_dist by blast
   256 next
   257   def T \<equiv> "{x. \<exists>a\<in>S. \<exists>d>0. (\<forall>y\<in>U. dist y a < d \<longrightarrow> y \<in> S) \<and> dist x a < d}"
   258   have 1: "\<forall>x\<in>T. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> T"
   259     unfolding T_def
   260     apply clarsimp
   261     apply (rule_tac x="d - dist x a" in exI)
   262     apply (clarsimp simp add: less_diff_eq)
   263     apply (erule rev_bexI)
   264     apply (rule_tac x=d in exI, clarify)
   265     apply (erule le_less_trans [OF dist_triangle])
   266     done
   267   assume ?rhs hence 2: "S = U \<inter> T"
   268     unfolding T_def
   269     apply auto
   270     apply (drule (1) bspec, erule rev_bexI)
   271     apply auto
   272     done
   273   from 1 2 show ?lhs
   274     unfolding openin_open open_dist by fast
   275 qed
   276 
   277 text {* These "transitivity" results are handy too *}
   278 
   279 lemma openin_trans[trans]: "openin (subtopology euclidean T) S \<Longrightarrow> openin (subtopology euclidean U) T
   280   \<Longrightarrow> openin (subtopology euclidean U) S"
   281   unfolding open_openin openin_open by blast
   282 
   283 lemma openin_open_trans: "openin (subtopology euclidean T) S \<Longrightarrow> open T \<Longrightarrow> open S"
   284   by (auto simp add: openin_open intro: openin_trans)
   285 
   286 lemma closedin_trans[trans]:
   287  "closedin (subtopology euclidean T) S \<Longrightarrow>
   288            closedin (subtopology euclidean U) T
   289            ==> closedin (subtopology euclidean U) S"
   290   by (auto simp add: closedin_closed closed_closedin closed_Inter Int_assoc)
   291 
   292 lemma closedin_closed_trans: "closedin (subtopology euclidean T) S \<Longrightarrow> closed T \<Longrightarrow> closed S"
   293   by (auto simp add: closedin_closed intro: closedin_trans)
   294 
   295 
   296 subsection {* Open and closed balls *}
   297 
   298 definition
   299   ball :: "'a::metric_space \<Rightarrow> real \<Rightarrow> 'a set" where
   300   "ball x e = {y. dist x y < e}"
   301 
   302 definition
   303   cball :: "'a::metric_space \<Rightarrow> real \<Rightarrow> 'a set" where
   304   "cball x e = {y. dist x y \<le> e}"
   305 
   306 lemma mem_ball [simp]: "y \<in> ball x e \<longleftrightarrow> dist x y < e"
   307   by (simp add: ball_def)
   308 
   309 lemma mem_cball [simp]: "y \<in> cball x e \<longleftrightarrow> dist x y \<le> e"
   310   by (simp add: cball_def)
   311 
   312 lemma mem_ball_0:
   313   fixes x :: "'a::real_normed_vector"
   314   shows "x \<in> ball 0 e \<longleftrightarrow> norm x < e"
   315   by (simp add: dist_norm)
   316 
   317 lemma mem_cball_0:
   318   fixes x :: "'a::real_normed_vector"
   319   shows "x \<in> cball 0 e \<longleftrightarrow> norm x \<le> e"
   320   by (simp add: dist_norm)
   321 
   322 lemma centre_in_ball: "x \<in> ball x e \<longleftrightarrow> 0 < e"
   323   by simp
   324 
   325 lemma centre_in_cball: "x \<in> cball x e \<longleftrightarrow> 0 \<le> e"
   326   by simp
   327 
   328 lemma ball_subset_cball[simp,intro]: "ball x e \<subseteq> cball x e" by (simp add: subset_eq)
   329 lemma subset_ball[intro]: "d <= e ==> ball x d \<subseteq> ball x e" by (simp add: subset_eq)
   330 lemma subset_cball[intro]: "d <= e ==> cball x d \<subseteq> cball x e" by (simp add: subset_eq)
   331 lemma ball_max_Un: "ball a (max r s) = ball a r \<union> ball a s"
   332   by (simp add: set_eq_iff) arith
   333 
   334 lemma ball_min_Int: "ball a (min r s) = ball a r \<inter> ball a s"
   335   by (simp add: set_eq_iff)
   336 
   337 lemma diff_less_iff: "(a::real) - b > 0 \<longleftrightarrow> a > b"
   338   "(a::real) - b < 0 \<longleftrightarrow> a < b"
   339   "a - b < c \<longleftrightarrow> a < c +b" "a - b > c \<longleftrightarrow> a > c +b" by arith+
   340 lemma diff_le_iff: "(a::real) - b \<ge> 0 \<longleftrightarrow> a \<ge> b" "(a::real) - b \<le> 0 \<longleftrightarrow> a \<le> b"
   341   "a - b \<le> c \<longleftrightarrow> a \<le> c +b" "a - b \<ge> c \<longleftrightarrow> a \<ge> c +b"  by arith+
   342 
   343 lemma open_ball[intro, simp]: "open (ball x e)"
   344   unfolding open_dist ball_def mem_Collect_eq Ball_def
   345   unfolding dist_commute
   346   apply clarify
   347   apply (rule_tac x="e - dist xa x" in exI)
   348   using dist_triangle_alt[where z=x]
   349   apply (clarsimp simp add: diff_less_iff)
   350   apply atomize
   351   apply (erule_tac x="y" in allE)
   352   apply (erule_tac x="xa" in allE)
   353   by arith
   354 
   355 lemma open_contains_ball: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. ball x e \<subseteq> S)"
   356   unfolding open_dist subset_eq mem_ball Ball_def dist_commute ..
   357 
   358 lemma openE[elim?]:
   359   assumes "open S" "x\<in>S" 
   360   obtains e where "e>0" "ball x e \<subseteq> S"
   361   using assms unfolding open_contains_ball by auto
   362 
   363 lemma open_contains_ball_eq: "open S \<Longrightarrow> \<forall>x. x\<in>S \<longleftrightarrow> (\<exists>e>0. ball x e \<subseteq> S)"
   364   by (metis open_contains_ball subset_eq centre_in_ball)
   365 
   366 lemma ball_eq_empty[simp]: "ball x e = {} \<longleftrightarrow> e \<le> 0"
   367   unfolding mem_ball set_eq_iff
   368   apply (simp add: not_less)
   369   by (metis zero_le_dist order_trans dist_self)
   370 
   371 lemma ball_empty[intro]: "e \<le> 0 ==> ball x e = {}" by simp
   372 
   373 
   374 subsection{* Connectedness *}
   375 
   376 definition "connected S \<longleftrightarrow>
   377   ~(\<exists>e1 e2. open e1 \<and> open e2 \<and> S \<subseteq> (e1 \<union> e2) \<and> (e1 \<inter> e2 \<inter> S = {})
   378   \<and> ~(e1 \<inter> S = {}) \<and> ~(e2 \<inter> S = {}))"
   379 
   380 lemma connected_local:
   381  "connected S \<longleftrightarrow> ~(\<exists>e1 e2.
   382                  openin (subtopology euclidean S) e1 \<and>
   383                  openin (subtopology euclidean S) e2 \<and>
   384                  S \<subseteq> e1 \<union> e2 \<and>
   385                  e1 \<inter> e2 = {} \<and>
   386                  ~(e1 = {}) \<and>
   387                  ~(e2 = {}))"
   388 unfolding connected_def openin_open by (safe, blast+)
   389 
   390 lemma exists_diff:
   391   fixes P :: "'a set \<Rightarrow> bool"
   392   shows "(\<exists>S. P(- S)) \<longleftrightarrow> (\<exists>S. P S)" (is "?lhs \<longleftrightarrow> ?rhs")
   393 proof-
   394   {assume "?lhs" hence ?rhs by blast }
   395   moreover
   396   {fix S assume H: "P S"
   397     have "S = - (- S)" by auto
   398     with H have "P (- (- S))" by metis }
   399   ultimately show ?thesis by metis
   400 qed
   401 
   402 lemma connected_clopen: "connected S \<longleftrightarrow>
   403         (\<forall>T. openin (subtopology euclidean S) T \<and>
   404             closedin (subtopology euclidean S) T \<longrightarrow> T = {} \<or> T = S)" (is "?lhs \<longleftrightarrow> ?rhs")
   405 proof-
   406   have " \<not> connected S \<longleftrightarrow> (\<exists>e1 e2. open e1 \<and> open (- e2) \<and> S \<subseteq> e1 \<union> (- e2) \<and> e1 \<inter> (- e2) \<inter> S = {} \<and> e1 \<inter> S \<noteq> {} \<and> (- e2) \<inter> S \<noteq> {})"
   407     unfolding connected_def openin_open closedin_closed
   408     apply (subst exists_diff) by blast
   409   hence th0: "connected S \<longleftrightarrow> \<not> (\<exists>e2 e1. closed e2 \<and> open e1 \<and> S \<subseteq> e1 \<union> (- e2) \<and> e1 \<inter> (- e2) \<inter> S = {} \<and> e1 \<inter> S \<noteq> {} \<and> (- e2) \<inter> S \<noteq> {})"
   410     (is " _ \<longleftrightarrow> \<not> (\<exists>e2 e1. ?P e2 e1)") apply (simp add: closed_def) by metis
   411 
   412   have th1: "?rhs \<longleftrightarrow> \<not> (\<exists>t' t. closed t'\<and>t = S\<inter>t' \<and> t\<noteq>{} \<and> t\<noteq>S \<and> (\<exists>t'. open t' \<and> t = S \<inter> t'))"
   413     (is "_ \<longleftrightarrow> \<not> (\<exists>t' t. ?Q t' t)")
   414     unfolding connected_def openin_open closedin_closed by auto
   415   {fix e2
   416     {fix e1 have "?P e2 e1 \<longleftrightarrow> (\<exists>t.  closed e2 \<and> t = S\<inter>e2 \<and> open e1 \<and> t = S\<inter>e1 \<and> t\<noteq>{} \<and> t\<noteq>S)"
   417         by auto}
   418     then have "(\<exists>e1. ?P e2 e1) \<longleftrightarrow> (\<exists>t. ?Q e2 t)" by metis}
   419   then have "\<forall>e2. (\<exists>e1. ?P e2 e1) \<longleftrightarrow> (\<exists>t. ?Q e2 t)" by blast
   420   then show ?thesis unfolding th0 th1 by simp
   421 qed
   422 
   423 lemma connected_empty[simp, intro]: "connected {}"
   424   by (simp add: connected_def)
   425 
   426 
   427 subsection{* Limit points *}
   428 
   429 definition (in topological_space)
   430   islimpt:: "'a \<Rightarrow> 'a set \<Rightarrow> bool" (infixr "islimpt" 60) where
   431   "x islimpt S \<longleftrightarrow> (\<forall>T. x\<in>T \<longrightarrow> open T \<longrightarrow> (\<exists>y\<in>S. y\<in>T \<and> y\<noteq>x))"
   432 
   433 lemma islimptI:
   434   assumes "\<And>T. x \<in> T \<Longrightarrow> open T \<Longrightarrow> \<exists>y\<in>S. y \<in> T \<and> y \<noteq> x"
   435   shows "x islimpt S"
   436   using assms unfolding islimpt_def by auto
   437 
   438 lemma islimptE:
   439   assumes "x islimpt S" and "x \<in> T" and "open T"
   440   obtains y where "y \<in> S" and "y \<in> T" and "y \<noteq> x"
   441   using assms unfolding islimpt_def by auto
   442 
   443 lemma islimpt_iff_eventually: "x islimpt S \<longleftrightarrow> \<not> eventually (\<lambda>y. y \<notin> S) (at x)"
   444   unfolding islimpt_def eventually_at_topological by auto
   445 
   446 lemma islimpt_subset: "\<lbrakk>x islimpt S; S \<subseteq> T\<rbrakk> \<Longrightarrow> x islimpt T"
   447   unfolding islimpt_def by fast
   448 
   449 lemma islimpt_approachable:
   450   fixes x :: "'a::metric_space"
   451   shows "x islimpt S \<longleftrightarrow> (\<forall>e>0. \<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e)"
   452   unfolding islimpt_iff_eventually eventually_at by fast
   453 
   454 lemma islimpt_approachable_le:
   455   fixes x :: "'a::metric_space"
   456   shows "x islimpt S \<longleftrightarrow> (\<forall>e>0. \<exists>x'\<in> S. x' \<noteq> x \<and> dist x' x <= e)"
   457   unfolding islimpt_approachable
   458   using approachable_lt_le [where f="\<lambda>y. dist y x" and P="\<lambda>y. y \<notin> S \<or> y = x",
   459     THEN arg_cong [where f=Not]]
   460   by (simp add: Bex_def conj_commute conj_left_commute)
   461 
   462 lemma islimpt_UNIV_iff: "x islimpt UNIV \<longleftrightarrow> \<not> open {x}"
   463   unfolding islimpt_def by (safe, fast, case_tac "T = {x}", fast, fast)
   464 
   465 text {* A perfect space has no isolated points. *}
   466 
   467 lemma islimpt_UNIV [simp, intro]: "(x::'a::perfect_space) islimpt UNIV"
   468   unfolding islimpt_UNIV_iff by (rule not_open_singleton)
   469 
   470 lemma perfect_choose_dist:
   471   fixes x :: "'a::{perfect_space, metric_space}"
   472   shows "0 < r \<Longrightarrow> \<exists>a. a \<noteq> x \<and> dist a x < r"
   473 using islimpt_UNIV [of x]
   474 by (simp add: islimpt_approachable)
   475 
   476 lemma closed_limpt: "closed S \<longleftrightarrow> (\<forall>x. x islimpt S \<longrightarrow> x \<in> S)"
   477   unfolding closed_def
   478   apply (subst open_subopen)
   479   apply (simp add: islimpt_def subset_eq)
   480   by (metis ComplE ComplI)
   481 
   482 lemma islimpt_EMPTY[simp]: "\<not> x islimpt {}"
   483   unfolding islimpt_def by auto
   484 
   485 lemma finite_set_avoid:
   486   fixes a :: "'a::metric_space"
   487   assumes fS: "finite S" shows  "\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<longrightarrow> d <= dist a x"
   488 proof(induct rule: finite_induct[OF fS])
   489   case 1 thus ?case by (auto intro: zero_less_one)
   490 next
   491   case (2 x F)
   492   from 2 obtain d where d: "d >0" "\<forall>x\<in>F. x\<noteq>a \<longrightarrow> d \<le> dist a x" by blast
   493   {assume "x = a" hence ?case using d by auto  }
   494   moreover
   495   {assume xa: "x\<noteq>a"
   496     let ?d = "min d (dist a x)"
   497     have dp: "?d > 0" using xa d(1) using dist_nz by auto
   498     from d have d': "\<forall>x\<in>F. x\<noteq>a \<longrightarrow> ?d \<le> dist a x" by auto
   499     with dp xa have ?case by(auto intro!: exI[where x="?d"]) }
   500   ultimately show ?case by blast
   501 qed
   502 
   503 lemma islimpt_finite:
   504   fixes S :: "'a::metric_space set"
   505   assumes fS: "finite S" shows "\<not> a islimpt S"
   506   unfolding islimpt_approachable
   507   using finite_set_avoid[OF fS, of a] by (metis dist_commute  not_le)
   508 
   509 lemma islimpt_Un: "x islimpt (S \<union> T) \<longleftrightarrow> x islimpt S \<or> x islimpt T"
   510   apply (rule iffI)
   511   defer
   512   apply (metis Un_upper1 Un_upper2 islimpt_subset)
   513   unfolding islimpt_def
   514   apply (rule ccontr, clarsimp, rename_tac A B)
   515   apply (drule_tac x="A \<inter> B" in spec)
   516   apply (auto simp add: open_Int)
   517   done
   518 
   519 lemma discrete_imp_closed:
   520   fixes S :: "'a::metric_space set"
   521   assumes e: "0 < e" and d: "\<forall>x \<in> S. \<forall>y \<in> S. dist y x < e \<longrightarrow> y = x"
   522   shows "closed S"
   523 proof-
   524   {fix x assume C: "\<forall>e>0. \<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e"
   525     from e have e2: "e/2 > 0" by arith
   526     from C[rule_format, OF e2] obtain y where y: "y \<in> S" "y\<noteq>x" "dist y x < e/2" by blast
   527     let ?m = "min (e/2) (dist x y) "
   528     from e2 y(2) have mp: "?m > 0" by (simp add: dist_nz[THEN sym])
   529     from C[rule_format, OF mp] obtain z where z: "z \<in> S" "z\<noteq>x" "dist z x < ?m" by blast
   530     have th: "dist z y < e" using z y
   531       by (intro dist_triangle_lt [where z=x], simp)
   532     from d[rule_format, OF y(1) z(1) th] y z
   533     have False by (auto simp add: dist_commute)}
   534   then show ?thesis by (metis islimpt_approachable closed_limpt [where 'a='a])
   535 qed
   536 
   537 
   538 subsection {* Interior of a Set *}
   539 
   540 definition "interior S = \<Union>{T. open T \<and> T \<subseteq> S}"
   541 
   542 lemma interiorI [intro?]:
   543   assumes "open T" and "x \<in> T" and "T \<subseteq> S"
   544   shows "x \<in> interior S"
   545   using assms unfolding interior_def by fast
   546 
   547 lemma interiorE [elim?]:
   548   assumes "x \<in> interior S"
   549   obtains T where "open T" and "x \<in> T" and "T \<subseteq> S"
   550   using assms unfolding interior_def by fast
   551 
   552 lemma open_interior [simp, intro]: "open (interior S)"
   553   by (simp add: interior_def open_Union)
   554 
   555 lemma interior_subset: "interior S \<subseteq> S"
   556   by (auto simp add: interior_def)
   557 
   558 lemma interior_maximal: "T \<subseteq> S \<Longrightarrow> open T \<Longrightarrow> T \<subseteq> interior S"
   559   by (auto simp add: interior_def)
   560 
   561 lemma interior_open: "open S \<Longrightarrow> interior S = S"
   562   by (intro equalityI interior_subset interior_maximal subset_refl)
   563 
   564 lemma interior_eq: "interior S = S \<longleftrightarrow> open S"
   565   by (metis open_interior interior_open)
   566 
   567 lemma open_subset_interior: "open S \<Longrightarrow> S \<subseteq> interior T \<longleftrightarrow> S \<subseteq> T"
   568   by (metis interior_maximal interior_subset subset_trans)
   569 
   570 lemma interior_empty [simp]: "interior {} = {}"
   571   using open_empty by (rule interior_open)
   572 
   573 lemma interior_UNIV [simp]: "interior UNIV = UNIV"
   574   using open_UNIV by (rule interior_open)
   575 
   576 lemma interior_interior [simp]: "interior (interior S) = interior S"
   577   using open_interior by (rule interior_open)
   578 
   579 lemma interior_mono: "S \<subseteq> T \<Longrightarrow> interior S \<subseteq> interior T"
   580   by (auto simp add: interior_def)
   581 
   582 lemma interior_unique:
   583   assumes "T \<subseteq> S" and "open T"
   584   assumes "\<And>T'. T' \<subseteq> S \<Longrightarrow> open T' \<Longrightarrow> T' \<subseteq> T"
   585   shows "interior S = T"
   586   by (intro equalityI assms interior_subset open_interior interior_maximal)
   587 
   588 lemma interior_inter [simp]: "interior (S \<inter> T) = interior S \<inter> interior T"
   589   by (intro equalityI Int_mono Int_greatest interior_mono Int_lower1
   590     Int_lower2 interior_maximal interior_subset open_Int open_interior)
   591 
   592 lemma mem_interior: "x \<in> interior S \<longleftrightarrow> (\<exists>e>0. ball x e \<subseteq> S)"
   593   using open_contains_ball_eq [where S="interior S"]
   594   by (simp add: open_subset_interior)
   595 
   596 lemma interior_limit_point [intro]:
   597   fixes x :: "'a::perfect_space"
   598   assumes x: "x \<in> interior S" shows "x islimpt S"
   599   using x islimpt_UNIV [of x]
   600   unfolding interior_def islimpt_def
   601   apply (clarsimp, rename_tac T T')
   602   apply (drule_tac x="T \<inter> T'" in spec)
   603   apply (auto simp add: open_Int)
   604   done
   605 
   606 lemma interior_closed_Un_empty_interior:
   607   assumes cS: "closed S" and iT: "interior T = {}"
   608   shows "interior (S \<union> T) = interior S"
   609 proof
   610   show "interior S \<subseteq> interior (S \<union> T)"
   611     by (rule interior_mono, rule Un_upper1)
   612 next
   613   show "interior (S \<union> T) \<subseteq> interior S"
   614   proof
   615     fix x assume "x \<in> interior (S \<union> T)"
   616     then obtain R where "open R" "x \<in> R" "R \<subseteq> S \<union> T" ..
   617     show "x \<in> interior S"
   618     proof (rule ccontr)
   619       assume "x \<notin> interior S"
   620       with `x \<in> R` `open R` obtain y where "y \<in> R - S"
   621         unfolding interior_def by fast
   622       from `open R` `closed S` have "open (R - S)" by (rule open_Diff)
   623       from `R \<subseteq> S \<union> T` have "R - S \<subseteq> T" by fast
   624       from `y \<in> R - S` `open (R - S)` `R - S \<subseteq> T` `interior T = {}`
   625       show "False" unfolding interior_def by fast
   626     qed
   627   qed
   628 qed
   629 
   630 lemma interior_Times: "interior (A \<times> B) = interior A \<times> interior B"
   631 proof (rule interior_unique)
   632   show "interior A \<times> interior B \<subseteq> A \<times> B"
   633     by (intro Sigma_mono interior_subset)
   634   show "open (interior A \<times> interior B)"
   635     by (intro open_Times open_interior)
   636   fix T assume "T \<subseteq> A \<times> B" and "open T" thus "T \<subseteq> interior A \<times> interior B"
   637   proof (safe)
   638     fix x y assume "(x, y) \<in> T"
   639     then obtain C D where "open C" "open D" "C \<times> D \<subseteq> T" "x \<in> C" "y \<in> D"
   640       using `open T` unfolding open_prod_def by fast
   641     hence "open C" "open D" "C \<subseteq> A" "D \<subseteq> B" "x \<in> C" "y \<in> D"
   642       using `T \<subseteq> A \<times> B` by auto
   643     thus "x \<in> interior A" and "y \<in> interior B"
   644       by (auto intro: interiorI)
   645   qed
   646 qed
   647 
   648 
   649 subsection {* Closure of a Set *}
   650 
   651 definition "closure S = S \<union> {x | x. x islimpt S}"
   652 
   653 lemma interior_closure: "interior S = - (closure (- S))"
   654   unfolding interior_def closure_def islimpt_def by auto
   655 
   656 lemma closure_interior: "closure S = - interior (- S)"
   657   unfolding interior_closure by simp
   658 
   659 lemma closed_closure[simp, intro]: "closed (closure S)"
   660   unfolding closure_interior by (simp add: closed_Compl)
   661 
   662 lemma closure_subset: "S \<subseteq> closure S"
   663   unfolding closure_def by simp
   664 
   665 lemma closure_hull: "closure S = closed hull S"
   666   unfolding hull_def closure_interior interior_def by auto
   667 
   668 lemma closure_eq: "closure S = S \<longleftrightarrow> closed S"
   669   unfolding closure_hull using closed_Inter by (rule hull_eq)
   670 
   671 lemma closure_closed [simp]: "closed S \<Longrightarrow> closure S = S"
   672   unfolding closure_eq .
   673 
   674 lemma closure_closure [simp]: "closure (closure S) = closure S"
   675   unfolding closure_hull by (rule hull_hull)
   676 
   677 lemma closure_mono: "S \<subseteq> T \<Longrightarrow> closure S \<subseteq> closure T"
   678   unfolding closure_hull by (rule hull_mono)
   679 
   680 lemma closure_minimal: "S \<subseteq> T \<Longrightarrow> closed T \<Longrightarrow> closure S \<subseteq> T"
   681   unfolding closure_hull by (rule hull_minimal)
   682 
   683 lemma closure_unique:
   684   assumes "S \<subseteq> T" and "closed T"
   685   assumes "\<And>T'. S \<subseteq> T' \<Longrightarrow> closed T' \<Longrightarrow> T \<subseteq> T'"
   686   shows "closure S = T"
   687   using assms unfolding closure_hull by (rule hull_unique)
   688 
   689 lemma closure_empty [simp]: "closure {} = {}"
   690   using closed_empty by (rule closure_closed)
   691 
   692 lemma closure_UNIV [simp]: "closure UNIV = UNIV"
   693   using closed_UNIV by (rule closure_closed)
   694 
   695 lemma closure_union [simp]: "closure (S \<union> T) = closure S \<union> closure T"
   696   unfolding closure_interior by simp
   697 
   698 lemma closure_eq_empty: "closure S = {} \<longleftrightarrow> S = {}"
   699   using closure_empty closure_subset[of S]
   700   by blast
   701 
   702 lemma closure_subset_eq: "closure S \<subseteq> S \<longleftrightarrow> closed S"
   703   using closure_eq[of S] closure_subset[of S]
   704   by simp
   705 
   706 lemma open_inter_closure_eq_empty:
   707   "open S \<Longrightarrow> (S \<inter> closure T) = {} \<longleftrightarrow> S \<inter> T = {}"
   708   using open_subset_interior[of S "- T"]
   709   using interior_subset[of "- T"]
   710   unfolding closure_interior
   711   by auto
   712 
   713 lemma open_inter_closure_subset:
   714   "open S \<Longrightarrow> (S \<inter> (closure T)) \<subseteq> closure(S \<inter> T)"
   715 proof
   716   fix x
   717   assume as: "open S" "x \<in> S \<inter> closure T"
   718   { assume *:"x islimpt T"
   719     have "x islimpt (S \<inter> T)"
   720     proof (rule islimptI)
   721       fix A
   722       assume "x \<in> A" "open A"
   723       with as have "x \<in> A \<inter> S" "open (A \<inter> S)"
   724         by (simp_all add: open_Int)
   725       with * obtain y where "y \<in> T" "y \<in> A \<inter> S" "y \<noteq> x"
   726         by (rule islimptE)
   727       hence "y \<in> S \<inter> T" "y \<in> A \<and> y \<noteq> x"
   728         by simp_all
   729       thus "\<exists>y\<in>(S \<inter> T). y \<in> A \<and> y \<noteq> x" ..
   730     qed
   731   }
   732   then show "x \<in> closure (S \<inter> T)" using as
   733     unfolding closure_def
   734     by blast
   735 qed
   736 
   737 lemma closure_complement: "closure (- S) = - interior S"
   738   unfolding closure_interior by simp
   739 
   740 lemma interior_complement: "interior (- S) = - closure S"
   741   unfolding closure_interior by simp
   742 
   743 lemma closure_Times: "closure (A \<times> B) = closure A \<times> closure B"
   744 proof (rule closure_unique)
   745   show "A \<times> B \<subseteq> closure A \<times> closure B"
   746     by (intro Sigma_mono closure_subset)
   747   show "closed (closure A \<times> closure B)"
   748     by (intro closed_Times closed_closure)
   749   fix T assume "A \<times> B \<subseteq> T" and "closed T" thus "closure A \<times> closure B \<subseteq> T"
   750     apply (simp add: closed_def open_prod_def, clarify)
   751     apply (rule ccontr)
   752     apply (drule_tac x="(a, b)" in bspec, simp, clarify, rename_tac C D)
   753     apply (simp add: closure_interior interior_def)
   754     apply (drule_tac x=C in spec)
   755     apply (drule_tac x=D in spec)
   756     apply auto
   757     done
   758 qed
   759 
   760 
   761 subsection {* Frontier (aka boundary) *}
   762 
   763 definition "frontier S = closure S - interior S"
   764 
   765 lemma frontier_closed: "closed(frontier S)"
   766   by (simp add: frontier_def closed_Diff)
   767 
   768 lemma frontier_closures: "frontier S = (closure S) \<inter> (closure(- S))"
   769   by (auto simp add: frontier_def interior_closure)
   770 
   771 lemma frontier_straddle:
   772   fixes a :: "'a::metric_space"
   773   shows "a \<in> frontier S \<longleftrightarrow> (\<forall>e>0. (\<exists>x\<in>S. dist a x < e) \<and> (\<exists>x. x \<notin> S \<and> dist a x < e))"
   774   unfolding frontier_def closure_interior
   775   by (auto simp add: mem_interior subset_eq ball_def)
   776 
   777 lemma frontier_subset_closed: "closed S \<Longrightarrow> frontier S \<subseteq> S"
   778   by (metis frontier_def closure_closed Diff_subset)
   779 
   780 lemma frontier_empty[simp]: "frontier {} = {}"
   781   by (simp add: frontier_def)
   782 
   783 lemma frontier_subset_eq: "frontier S \<subseteq> S \<longleftrightarrow> closed S"
   784 proof-
   785   { assume "frontier S \<subseteq> S"
   786     hence "closure S \<subseteq> S" using interior_subset unfolding frontier_def by auto
   787     hence "closed S" using closure_subset_eq by auto
   788   }
   789   thus ?thesis using frontier_subset_closed[of S] ..
   790 qed
   791 
   792 lemma frontier_complement: "frontier(- S) = frontier S"
   793   by (auto simp add: frontier_def closure_complement interior_complement)
   794 
   795 lemma frontier_disjoint_eq: "frontier S \<inter> S = {} \<longleftrightarrow> open S"
   796   using frontier_complement frontier_subset_eq[of "- S"]
   797   unfolding open_closed by auto
   798 
   799 
   800 subsection {* Filters and the ``eventually true'' quantifier *}
   801 
   802 definition
   803   at_infinity :: "'a::real_normed_vector filter" where
   804   "at_infinity = Abs_filter (\<lambda>P. \<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x)"
   805 
   806 definition
   807   indirection :: "'a::real_normed_vector \<Rightarrow> 'a \<Rightarrow> 'a filter"
   808     (infixr "indirection" 70) where
   809   "a indirection v = (at a) within {b. \<exists>c\<ge>0. b - a = scaleR c v}"
   810 
   811 text{* Prove That They are all filters. *}
   812 
   813 lemma eventually_at_infinity:
   814   "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. norm x >= b \<longrightarrow> P x)"
   815 unfolding at_infinity_def
   816 proof (rule eventually_Abs_filter, rule is_filter.intro)
   817   fix P Q :: "'a \<Rightarrow> bool"
   818   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<exists>s. \<forall>x. s \<le> norm x \<longrightarrow> Q x"
   819   then obtain r s where
   820     "\<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<forall>x. s \<le> norm x \<longrightarrow> Q x" by auto
   821   then have "\<forall>x. max r s \<le> norm x \<longrightarrow> P x \<and> Q x" by simp
   822   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x \<and> Q x" ..
   823 qed auto
   824 
   825 text {* Identify Trivial limits, where we can't approach arbitrarily closely. *}
   826 
   827 lemma trivial_limit_within:
   828   shows "trivial_limit (at a within S) \<longleftrightarrow> \<not> a islimpt S"
   829 proof
   830   assume "trivial_limit (at a within S)"
   831   thus "\<not> a islimpt S"
   832     unfolding trivial_limit_def
   833     unfolding eventually_within eventually_at_topological
   834     unfolding islimpt_def
   835     apply (clarsimp simp add: set_eq_iff)
   836     apply (rename_tac T, rule_tac x=T in exI)
   837     apply (clarsimp, drule_tac x=y in bspec, simp_all)
   838     done
   839 next
   840   assume "\<not> a islimpt S"
   841   thus "trivial_limit (at a within S)"
   842     unfolding trivial_limit_def
   843     unfolding eventually_within eventually_at_topological
   844     unfolding islimpt_def
   845     apply clarsimp
   846     apply (rule_tac x=T in exI)
   847     apply auto
   848     done
   849 qed
   850 
   851 lemma trivial_limit_at_iff: "trivial_limit (at a) \<longleftrightarrow> \<not> a islimpt UNIV"
   852   using trivial_limit_within [of a UNIV] by simp
   853 
   854 lemma trivial_limit_at:
   855   fixes a :: "'a::perfect_space"
   856   shows "\<not> trivial_limit (at a)"
   857   by (rule at_neq_bot)
   858 
   859 lemma trivial_limit_at_infinity:
   860   "\<not> trivial_limit (at_infinity :: ('a::{real_normed_vector,perfect_space}) filter)"
   861   unfolding trivial_limit_def eventually_at_infinity
   862   apply clarsimp
   863   apply (subgoal_tac "\<exists>x::'a. x \<noteq> 0", clarify)
   864    apply (rule_tac x="scaleR (b / norm x) x" in exI, simp)
   865   apply (cut_tac islimpt_UNIV [of "0::'a", unfolded islimpt_def])
   866   apply (drule_tac x=UNIV in spec, simp)
   867   done
   868 
   869 text {* Some property holds "sufficiently close" to the limit point. *}
   870 
   871 lemma eventually_at: (* FIXME: this replaces Limits.eventually_at *)
   872   "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
   873 unfolding eventually_at dist_nz by auto
   874 
   875 lemma eventually_within: "eventually P (at a within S) \<longleftrightarrow>
   876         (\<exists>d>0. \<forall>x\<in>S. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
   877 unfolding eventually_within eventually_at dist_nz by auto
   878 
   879 lemma eventually_within_le: "eventually P (at a within S) \<longleftrightarrow>
   880         (\<exists>d>0. \<forall>x\<in>S. 0 < dist x a \<and> dist x a <= d \<longrightarrow> P x)" (is "?lhs = ?rhs")
   881 unfolding eventually_within
   882 by auto (metis dense order_le_less_trans)
   883 
   884 lemma eventually_happens: "eventually P net ==> trivial_limit net \<or> (\<exists>x. P x)"
   885   unfolding trivial_limit_def
   886   by (auto elim: eventually_rev_mp)
   887 
   888 lemma trivial_limit_eventually: "trivial_limit net \<Longrightarrow> eventually P net"
   889   by simp
   890 
   891 lemma trivial_limit_eq: "trivial_limit net \<longleftrightarrow> (\<forall>P. eventually P net)"
   892   by (simp add: filter_eq_iff)
   893 
   894 text{* Combining theorems for "eventually" *}
   895 
   896 lemma eventually_rev_mono:
   897   "eventually P net \<Longrightarrow> (\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually Q net"
   898 using eventually_mono [of P Q] by fast
   899 
   900 lemma not_eventually: "(\<forall>x. \<not> P x ) \<Longrightarrow> ~(trivial_limit net) ==> ~(eventually (\<lambda>x. P x) net)"
   901   by (simp add: eventually_False)
   902 
   903 
   904 subsection {* Limits *}
   905 
   906 text{* Notation Lim to avoid collition with lim defined in analysis *}
   907 
   908 definition Lim :: "'a filter \<Rightarrow> ('a \<Rightarrow> 'b::t2_space) \<Rightarrow> 'b"
   909   where "Lim A f = (THE l. (f ---> l) A)"
   910 
   911 lemma Lim:
   912  "(f ---> l) net \<longleftrightarrow>
   913         trivial_limit net \<or>
   914         (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) net)"
   915   unfolding tendsto_iff trivial_limit_eq by auto
   916 
   917 text{* Show that they yield usual definitions in the various cases. *}
   918 
   919 lemma Lim_within_le: "(f ---> l)(at a within S) \<longleftrightarrow>
   920            (\<forall>e>0. \<exists>d>0. \<forall>x\<in>S. 0 < dist x a  \<and> dist x a  <= d \<longrightarrow> dist (f x) l < e)"
   921   by (auto simp add: tendsto_iff eventually_within_le)
   922 
   923 lemma Lim_within: "(f ---> l) (at a within S) \<longleftrightarrow>
   924         (\<forall>e >0. \<exists>d>0. \<forall>x \<in> S. 0 < dist x a  \<and> dist x a  < d  \<longrightarrow> dist (f x) l < e)"
   925   by (auto simp add: tendsto_iff eventually_within)
   926 
   927 lemma Lim_at: "(f ---> l) (at a) \<longleftrightarrow>
   928         (\<forall>e >0. \<exists>d>0. \<forall>x. 0 < dist x a  \<and> dist x a  < d  \<longrightarrow> dist (f x) l < e)"
   929   by (auto simp add: tendsto_iff eventually_at)
   930 
   931 lemma Lim_at_infinity:
   932   "(f ---> l) at_infinity \<longleftrightarrow> (\<forall>e>0. \<exists>b. \<forall>x. norm x >= b \<longrightarrow> dist (f x) l < e)"
   933   by (auto simp add: tendsto_iff eventually_at_infinity)
   934 
   935 lemma Lim_eventually: "eventually (\<lambda>x. f x = l) net \<Longrightarrow> (f ---> l) net"
   936   by (rule topological_tendstoI, auto elim: eventually_rev_mono)
   937 
   938 text{* The expected monotonicity property. *}
   939 
   940 lemma Lim_within_empty: "(f ---> l) (net within {})"
   941   unfolding tendsto_def Limits.eventually_within by simp
   942 
   943 lemma Lim_within_subset: "(f ---> l) (net within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f ---> l) (net within T)"
   944   unfolding tendsto_def Limits.eventually_within
   945   by (auto elim!: eventually_elim1)
   946 
   947 lemma Lim_Un: assumes "(f ---> l) (net within S)" "(f ---> l) (net within T)"
   948   shows "(f ---> l) (net within (S \<union> T))"
   949   using assms unfolding tendsto_def Limits.eventually_within
   950   apply clarify
   951   apply (drule spec, drule (1) mp, drule (1) mp)
   952   apply (drule spec, drule (1) mp, drule (1) mp)
   953   apply (auto elim: eventually_elim2)
   954   done
   955 
   956 lemma Lim_Un_univ:
   957  "(f ---> l) (net within S) \<Longrightarrow> (f ---> l) (net within T) \<Longrightarrow>  S \<union> T = UNIV
   958         ==> (f ---> l) net"
   959   by (metis Lim_Un within_UNIV)
   960 
   961 text{* Interrelations between restricted and unrestricted limits. *}
   962 
   963 lemma Lim_at_within: "(f ---> l) net ==> (f ---> l)(net within S)"
   964   (* FIXME: rename *)
   965   unfolding tendsto_def Limits.eventually_within
   966   apply (clarify, drule spec, drule (1) mp, drule (1) mp)
   967   by (auto elim!: eventually_elim1)
   968 
   969 lemma eventually_within_interior:
   970   assumes "x \<in> interior S"
   971   shows "eventually P (at x within S) \<longleftrightarrow> eventually P (at x)" (is "?lhs = ?rhs")
   972 proof-
   973   from assms obtain T where T: "open T" "x \<in> T" "T \<subseteq> S" ..
   974   { assume "?lhs"
   975     then obtain A where "open A" "x \<in> A" "\<forall>y\<in>A. y \<noteq> x \<longrightarrow> y \<in> S \<longrightarrow> P y"
   976       unfolding Limits.eventually_within Limits.eventually_at_topological
   977       by auto
   978     with T have "open (A \<inter> T)" "x \<in> A \<inter> T" "\<forall>y\<in>(A \<inter> T). y \<noteq> x \<longrightarrow> P y"
   979       by auto
   980     then have "?rhs"
   981       unfolding Limits.eventually_at_topological by auto
   982   } moreover
   983   { assume "?rhs" hence "?lhs"
   984       unfolding Limits.eventually_within
   985       by (auto elim: eventually_elim1)
   986   } ultimately
   987   show "?thesis" ..
   988 qed
   989 
   990 lemma at_within_interior:
   991   "x \<in> interior S \<Longrightarrow> at x within S = at x"
   992   by (simp add: filter_eq_iff eventually_within_interior)
   993 
   994 lemma at_within_open:
   995   "\<lbrakk>x \<in> S; open S\<rbrakk> \<Longrightarrow> at x within S = at x"
   996   by (simp only: at_within_interior interior_open)
   997 
   998 lemma Lim_within_open:
   999   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1000   assumes"a \<in> S" "open S"
  1001   shows "(f ---> l)(at a within S) \<longleftrightarrow> (f ---> l)(at a)"
  1002   using assms by (simp only: at_within_open)
  1003 
  1004 lemma Lim_within_LIMSEQ:
  1005   fixes a :: "'a::metric_space"
  1006   assumes "\<forall>S. (\<forall>n. S n \<noteq> a \<and> S n \<in> T) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L"
  1007   shows "(X ---> L) (at a within T)"
  1008   using assms unfolding tendsto_def [where l=L]
  1009   by (simp add: sequentially_imp_eventually_within)
  1010 
  1011 lemma Lim_right_bound:
  1012   fixes f :: "real \<Rightarrow> real"
  1013   assumes mono: "\<And>a b. a \<in> I \<Longrightarrow> b \<in> I \<Longrightarrow> x < a \<Longrightarrow> a \<le> b \<Longrightarrow> f a \<le> f b"
  1014   assumes bnd: "\<And>a. a \<in> I \<Longrightarrow> x < a \<Longrightarrow> K \<le> f a"
  1015   shows "(f ---> Inf (f ` ({x<..} \<inter> I))) (at x within ({x<..} \<inter> I))"
  1016 proof cases
  1017   assume "{x<..} \<inter> I = {}" then show ?thesis by (simp add: Lim_within_empty)
  1018 next
  1019   assume [simp]: "{x<..} \<inter> I \<noteq> {}"
  1020   show ?thesis
  1021   proof (rule Lim_within_LIMSEQ, safe)
  1022     fix S assume S: "\<forall>n. S n \<noteq> x \<and> S n \<in> {x <..} \<inter> I" "S ----> x"
  1023     
  1024     show "(\<lambda>n. f (S n)) ----> Inf (f ` ({x<..} \<inter> I))"
  1025     proof (rule LIMSEQ_I, rule ccontr)
  1026       fix r :: real assume "0 < r"
  1027       with Inf_close[of "f ` ({x<..} \<inter> I)" r]
  1028       obtain y where y: "x < y" "y \<in> I" "f y < Inf (f ` ({x <..} \<inter> I)) + r" by auto
  1029       from `x < y` have "0 < y - x" by auto
  1030       from S(2)[THEN LIMSEQ_D, OF this]
  1031       obtain N where N: "\<And>n. N \<le> n \<Longrightarrow> \<bar>S n - x\<bar> < y - x" by auto
  1032       
  1033       assume "\<not> (\<exists>N. \<forall>n\<ge>N. norm (f (S n) - Inf (f ` ({x<..} \<inter> I))) < r)"
  1034       moreover have "\<And>n. Inf (f ` ({x<..} \<inter> I)) \<le> f (S n)"
  1035         using S bnd by (intro Inf_lower[where z=K]) auto
  1036       ultimately obtain n where n: "N \<le> n" "r + Inf (f ` ({x<..} \<inter> I)) \<le> f (S n)"
  1037         by (auto simp: not_less field_simps)
  1038       with N[OF n(1)] mono[OF _ `y \<in> I`, of "S n"] S(1)[THEN spec, of n] y
  1039       show False by auto
  1040     qed
  1041   qed
  1042 qed
  1043 
  1044 text{* Another limit point characterization. *}
  1045 
  1046 lemma islimpt_sequential:
  1047   fixes x :: "'a::metric_space"
  1048   shows "x islimpt S \<longleftrightarrow> (\<exists>f. (\<forall>n::nat. f n \<in> S -{x}) \<and> (f ---> x) sequentially)"
  1049     (is "?lhs = ?rhs")
  1050 proof
  1051   assume ?lhs
  1052   then obtain f where f:"\<forall>y. y>0 \<longrightarrow> f y \<in> S \<and> f y \<noteq> x \<and> dist (f y) x < y"
  1053     unfolding islimpt_approachable
  1054     using choice[of "\<lambda>e y. e>0 \<longrightarrow> y\<in>S \<and> y\<noteq>x \<and> dist y x < e"] by auto
  1055   let ?I = "\<lambda>n. inverse (real (Suc n))"
  1056   have "\<forall>n. f (?I n) \<in> S - {x}" using f by simp
  1057   moreover have "(\<lambda>n. f (?I n)) ----> x"
  1058   proof (rule metric_tendsto_imp_tendsto)
  1059     show "?I ----> 0"
  1060       by (rule LIMSEQ_inverse_real_of_nat)
  1061     show "eventually (\<lambda>n. dist (f (?I n)) x \<le> dist (?I n) 0) sequentially"
  1062       by (simp add: norm_conv_dist [symmetric] less_imp_le f)
  1063   qed
  1064   ultimately show ?rhs by fast
  1065 next
  1066   assume ?rhs
  1067   then obtain f::"nat\<Rightarrow>'a"  where f:"(\<forall>n. f n \<in> S - {x})" "(\<forall>e>0. \<exists>N. \<forall>n\<ge>N. dist (f n) x < e)" unfolding LIMSEQ_def by auto
  1068   { fix e::real assume "e>0"
  1069     then obtain N where "dist (f N) x < e" using f(2) by auto
  1070     moreover have "f N\<in>S" "f N \<noteq> x" using f(1) by auto
  1071     ultimately have "\<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e" by auto
  1072   }
  1073   thus ?lhs unfolding islimpt_approachable by auto
  1074 qed
  1075 
  1076 lemma Lim_inv: (* TODO: delete *)
  1077   fixes f :: "'a \<Rightarrow> real" and A :: "'a filter"
  1078   assumes "(f ---> l) A" and "l \<noteq> 0"
  1079   shows "((inverse o f) ---> inverse l) A"
  1080   unfolding o_def using assms by (rule tendsto_inverse)
  1081 
  1082 lemma Lim_null:
  1083   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1084   shows "(f ---> l) net \<longleftrightarrow> ((\<lambda>x. f(x) - l) ---> 0) net"
  1085   by (simp add: Lim dist_norm)
  1086 
  1087 lemma Lim_null_comparison:
  1088   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1089   assumes "eventually (\<lambda>x. norm (f x) \<le> g x) net" "(g ---> 0) net"
  1090   shows "(f ---> 0) net"
  1091 proof (rule metric_tendsto_imp_tendsto)
  1092   show "(g ---> 0) net" by fact
  1093   show "eventually (\<lambda>x. dist (f x) 0 \<le> dist (g x) 0) net"
  1094     using assms(1) by (rule eventually_elim1, simp add: dist_norm)
  1095 qed
  1096 
  1097 lemma Lim_transform_bound:
  1098   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1099   fixes g :: "'a \<Rightarrow> 'c::real_normed_vector"
  1100   assumes "eventually (\<lambda>n. norm(f n) <= norm(g n)) net"  "(g ---> 0) net"
  1101   shows "(f ---> 0) net"
  1102   using assms(1) tendsto_norm_zero [OF assms(2)]
  1103   by (rule Lim_null_comparison)
  1104 
  1105 text{* Deducing things about the limit from the elements. *}
  1106 
  1107 lemma Lim_in_closed_set:
  1108   assumes "closed S" "eventually (\<lambda>x. f(x) \<in> S) net" "\<not>(trivial_limit net)" "(f ---> l) net"
  1109   shows "l \<in> S"
  1110 proof (rule ccontr)
  1111   assume "l \<notin> S"
  1112   with `closed S` have "open (- S)" "l \<in> - S"
  1113     by (simp_all add: open_Compl)
  1114   with assms(4) have "eventually (\<lambda>x. f x \<in> - S) net"
  1115     by (rule topological_tendstoD)
  1116   with assms(2) have "eventually (\<lambda>x. False) net"
  1117     by (rule eventually_elim2) simp
  1118   with assms(3) show "False"
  1119     by (simp add: eventually_False)
  1120 qed
  1121 
  1122 text{* Need to prove closed(cball(x,e)) before deducing this as a corollary. *}
  1123 
  1124 lemma Lim_dist_ubound:
  1125   assumes "\<not>(trivial_limit net)" "(f ---> l) net" "eventually (\<lambda>x. dist a (f x) <= e) net"
  1126   shows "dist a l <= e"
  1127 proof-
  1128   have "dist a l \<in> {..e}"
  1129   proof (rule Lim_in_closed_set)
  1130     show "closed {..e}" by simp
  1131     show "eventually (\<lambda>x. dist a (f x) \<in> {..e}) net" by (simp add: assms)
  1132     show "\<not> trivial_limit net" by fact
  1133     show "((\<lambda>x. dist a (f x)) ---> dist a l) net" by (intro tendsto_intros assms)
  1134   qed
  1135   thus ?thesis by simp
  1136 qed
  1137 
  1138 lemma Lim_norm_ubound:
  1139   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1140   assumes "\<not>(trivial_limit net)" "(f ---> l) net" "eventually (\<lambda>x. norm(f x) <= e) net"
  1141   shows "norm(l) <= e"
  1142 proof-
  1143   have "norm l \<in> {..e}"
  1144   proof (rule Lim_in_closed_set)
  1145     show "closed {..e}" by simp
  1146     show "eventually (\<lambda>x. norm (f x) \<in> {..e}) net" by (simp add: assms)
  1147     show "\<not> trivial_limit net" by fact
  1148     show "((\<lambda>x. norm (f x)) ---> norm l) net" by (intro tendsto_intros assms)
  1149   qed
  1150   thus ?thesis by simp
  1151 qed
  1152 
  1153 lemma Lim_norm_lbound:
  1154   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1155   assumes "\<not> (trivial_limit net)"  "(f ---> l) net"  "eventually (\<lambda>x. e <= norm(f x)) net"
  1156   shows "e \<le> norm l"
  1157 proof-
  1158   have "norm l \<in> {e..}"
  1159   proof (rule Lim_in_closed_set)
  1160     show "closed {e..}" by simp
  1161     show "eventually (\<lambda>x. norm (f x) \<in> {e..}) net" by (simp add: assms)
  1162     show "\<not> trivial_limit net" by fact
  1163     show "((\<lambda>x. norm (f x)) ---> norm l) net" by (intro tendsto_intros assms)
  1164   qed
  1165   thus ?thesis by simp
  1166 qed
  1167 
  1168 text{* Uniqueness of the limit, when nontrivial. *}
  1169 
  1170 lemma tendsto_Lim:
  1171   fixes f :: "'a \<Rightarrow> 'b::t2_space"
  1172   shows "~(trivial_limit net) \<Longrightarrow> (f ---> l) net ==> Lim net f = l"
  1173   unfolding Lim_def using tendsto_unique[of net f] by auto
  1174 
  1175 text{* Limit under bilinear function *}
  1176 
  1177 lemma Lim_bilinear:
  1178   assumes "(f ---> l) net" and "(g ---> m) net" and "bounded_bilinear h"
  1179   shows "((\<lambda>x. h (f x) (g x)) ---> (h l m)) net"
  1180 using `bounded_bilinear h` `(f ---> l) net` `(g ---> m) net`
  1181 by (rule bounded_bilinear.tendsto)
  1182 
  1183 text{* These are special for limits out of the same vector space. *}
  1184 
  1185 lemma Lim_within_id: "(id ---> a) (at a within s)"
  1186   unfolding id_def by (rule tendsto_ident_at_within)
  1187 
  1188 lemma Lim_at_id: "(id ---> a) (at a)"
  1189   unfolding id_def by (rule tendsto_ident_at)
  1190 
  1191 lemma Lim_at_zero:
  1192   fixes a :: "'a::real_normed_vector"
  1193   fixes l :: "'b::topological_space"
  1194   shows "(f ---> l) (at a) \<longleftrightarrow> ((\<lambda>x. f(a + x)) ---> l) (at 0)" (is "?lhs = ?rhs")
  1195   using LIM_offset_zero LIM_offset_zero_cancel ..
  1196 
  1197 text{* It's also sometimes useful to extract the limit point from the filter. *}
  1198 
  1199 definition
  1200   netlimit :: "'a::t2_space filter \<Rightarrow> 'a" where
  1201   "netlimit net = (SOME a. ((\<lambda>x. x) ---> a) net)"
  1202 
  1203 lemma netlimit_within:
  1204   assumes "\<not> trivial_limit (at a within S)"
  1205   shows "netlimit (at a within S) = a"
  1206 unfolding netlimit_def
  1207 apply (rule some_equality)
  1208 apply (rule Lim_at_within)
  1209 apply (rule tendsto_ident_at)
  1210 apply (erule tendsto_unique [OF assms])
  1211 apply (rule Lim_at_within)
  1212 apply (rule tendsto_ident_at)
  1213 done
  1214 
  1215 lemma netlimit_at:
  1216   fixes a :: "'a::{perfect_space,t2_space}"
  1217   shows "netlimit (at a) = a"
  1218   using netlimit_within [of a UNIV] by simp
  1219 
  1220 lemma lim_within_interior:
  1221   "x \<in> interior S \<Longrightarrow> (f ---> l) (at x within S) \<longleftrightarrow> (f ---> l) (at x)"
  1222   by (simp add: at_within_interior)
  1223 
  1224 lemma netlimit_within_interior:
  1225   fixes x :: "'a::{t2_space,perfect_space}"
  1226   assumes "x \<in> interior S"
  1227   shows "netlimit (at x within S) = x"
  1228 using assms by (simp add: at_within_interior netlimit_at)
  1229 
  1230 text{* Transformation of limit. *}
  1231 
  1232 lemma Lim_transform:
  1233   fixes f g :: "'a::type \<Rightarrow> 'b::real_normed_vector"
  1234   assumes "((\<lambda>x. f x - g x) ---> 0) net" "(f ---> l) net"
  1235   shows "(g ---> l) net"
  1236   using tendsto_diff [OF assms(2) assms(1)] by simp
  1237 
  1238 lemma Lim_transform_eventually:
  1239   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f ---> l) net \<Longrightarrow> (g ---> l) net"
  1240   apply (rule topological_tendstoI)
  1241   apply (drule (2) topological_tendstoD)
  1242   apply (erule (1) eventually_elim2, simp)
  1243   done
  1244 
  1245 lemma Lim_transform_within:
  1246   assumes "0 < d" and "\<forall>x'\<in>S. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1247   and "(f ---> l) (at x within S)"
  1248   shows "(g ---> l) (at x within S)"
  1249 proof (rule Lim_transform_eventually)
  1250   show "eventually (\<lambda>x. f x = g x) (at x within S)"
  1251     unfolding eventually_within
  1252     using assms(1,2) by auto
  1253   show "(f ---> l) (at x within S)" by fact
  1254 qed
  1255 
  1256 lemma Lim_transform_at:
  1257   assumes "0 < d" and "\<forall>x'. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1258   and "(f ---> l) (at x)"
  1259   shows "(g ---> l) (at x)"
  1260 proof (rule Lim_transform_eventually)
  1261   show "eventually (\<lambda>x. f x = g x) (at x)"
  1262     unfolding eventually_at
  1263     using assms(1,2) by auto
  1264   show "(f ---> l) (at x)" by fact
  1265 qed
  1266 
  1267 text{* Common case assuming being away from some crucial point like 0. *}
  1268 
  1269 lemma Lim_transform_away_within:
  1270   fixes a b :: "'a::t1_space"
  1271   assumes "a \<noteq> b" and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1272   and "(f ---> l) (at a within S)"
  1273   shows "(g ---> l) (at a within S)"
  1274 proof (rule Lim_transform_eventually)
  1275   show "(f ---> l) (at a within S)" by fact
  1276   show "eventually (\<lambda>x. f x = g x) (at a within S)"
  1277     unfolding Limits.eventually_within eventually_at_topological
  1278     by (rule exI [where x="- {b}"], simp add: open_Compl assms)
  1279 qed
  1280 
  1281 lemma Lim_transform_away_at:
  1282   fixes a b :: "'a::t1_space"
  1283   assumes ab: "a\<noteq>b" and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1284   and fl: "(f ---> l) (at a)"
  1285   shows "(g ---> l) (at a)"
  1286   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl
  1287   by simp
  1288 
  1289 text{* Alternatively, within an open set. *}
  1290 
  1291 lemma Lim_transform_within_open:
  1292   assumes "open S" and "a \<in> S" and "\<forall>x\<in>S. x \<noteq> a \<longrightarrow> f x = g x"
  1293   and "(f ---> l) (at a)"
  1294   shows "(g ---> l) (at a)"
  1295 proof (rule Lim_transform_eventually)
  1296   show "eventually (\<lambda>x. f x = g x) (at a)"
  1297     unfolding eventually_at_topological
  1298     using assms(1,2,3) by auto
  1299   show "(f ---> l) (at a)" by fact
  1300 qed
  1301 
  1302 text{* A congruence rule allowing us to transform limits assuming not at point. *}
  1303 
  1304 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
  1305 
  1306 lemma Lim_cong_within(*[cong add]*):
  1307   assumes "a = b" "x = y" "S = T"
  1308   assumes "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
  1309   shows "(f ---> x) (at a within S) \<longleftrightarrow> (g ---> y) (at b within T)"
  1310   unfolding tendsto_def Limits.eventually_within eventually_at_topological
  1311   using assms by simp
  1312 
  1313 lemma Lim_cong_at(*[cong add]*):
  1314   assumes "a = b" "x = y"
  1315   assumes "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
  1316   shows "((\<lambda>x. f x) ---> x) (at a) \<longleftrightarrow> ((g ---> y) (at a))"
  1317   unfolding tendsto_def eventually_at_topological
  1318   using assms by simp
  1319 
  1320 text{* Useful lemmas on closure and set of possible sequential limits.*}
  1321 
  1322 lemma closure_sequential:
  1323   fixes l :: "'a::metric_space"
  1324   shows "l \<in> closure S \<longleftrightarrow> (\<exists>x. (\<forall>n. x n \<in> S) \<and> (x ---> l) sequentially)" (is "?lhs = ?rhs")
  1325 proof
  1326   assume "?lhs" moreover
  1327   { assume "l \<in> S"
  1328     hence "?rhs" using tendsto_const[of l sequentially] by auto
  1329   } moreover
  1330   { assume "l islimpt S"
  1331     hence "?rhs" unfolding islimpt_sequential by auto
  1332   } ultimately
  1333   show "?rhs" unfolding closure_def by auto
  1334 next
  1335   assume "?rhs"
  1336   thus "?lhs" unfolding closure_def unfolding islimpt_sequential by auto
  1337 qed
  1338 
  1339 lemma closed_sequential_limits:
  1340   fixes S :: "'a::metric_space set"
  1341   shows "closed S \<longleftrightarrow> (\<forall>x l. (\<forall>n. x n \<in> S) \<and> (x ---> l) sequentially \<longrightarrow> l \<in> S)"
  1342   unfolding closed_limpt
  1343   using closure_sequential [where 'a='a] closure_closed [where 'a='a] closed_limpt [where 'a='a] islimpt_sequential [where 'a='a] mem_delete [where 'a='a]
  1344   by metis
  1345 
  1346 lemma closure_approachable:
  1347   fixes S :: "'a::metric_space set"
  1348   shows "x \<in> closure S \<longleftrightarrow> (\<forall>e>0. \<exists>y\<in>S. dist y x < e)"
  1349   apply (auto simp add: closure_def islimpt_approachable)
  1350   by (metis dist_self)
  1351 
  1352 lemma closed_approachable:
  1353   fixes S :: "'a::metric_space set"
  1354   shows "closed S ==> (\<forall>e>0. \<exists>y\<in>S. dist y x < e) \<longleftrightarrow> x \<in> S"
  1355   by (metis closure_closed closure_approachable)
  1356 
  1357 text{* Some other lemmas about sequences. *}
  1358 
  1359 lemma sequentially_offset:
  1360   assumes "eventually (\<lambda>i. P i) sequentially"
  1361   shows "eventually (\<lambda>i. P (i + k)) sequentially"
  1362   using assms unfolding eventually_sequentially by (metis trans_le_add1)
  1363 
  1364 lemma seq_offset:
  1365   assumes "(f ---> l) sequentially"
  1366   shows "((\<lambda>i. f (i + k)) ---> l) sequentially"
  1367   using assms by (rule LIMSEQ_ignore_initial_segment) (* FIXME: redundant *)
  1368 
  1369 lemma seq_offset_neg:
  1370   "(f ---> l) sequentially ==> ((\<lambda>i. f(i - k)) ---> l) sequentially"
  1371   apply (rule topological_tendstoI)
  1372   apply (drule (2) topological_tendstoD)
  1373   apply (simp only: eventually_sequentially)
  1374   apply (subgoal_tac "\<And>N k (n::nat). N + k <= n ==> N <= n - k")
  1375   apply metis
  1376   by arith
  1377 
  1378 lemma seq_offset_rev:
  1379   "((\<lambda>i. f(i + k)) ---> l) sequentially ==> (f ---> l) sequentially"
  1380   by (rule LIMSEQ_offset) (* FIXME: redundant *)
  1381 
  1382 lemma seq_harmonic: "((\<lambda>n. inverse (real n)) ---> 0) sequentially"
  1383   using LIMSEQ_inverse_real_of_nat by (rule LIMSEQ_imp_Suc)
  1384 
  1385 subsection {* More properties of closed balls *}
  1386 
  1387 lemma closed_cball: "closed (cball x e)"
  1388 unfolding cball_def closed_def
  1389 unfolding Collect_neg_eq [symmetric] not_le
  1390 apply (clarsimp simp add: open_dist, rename_tac y)
  1391 apply (rule_tac x="dist x y - e" in exI, clarsimp)
  1392 apply (rename_tac x')
  1393 apply (cut_tac x=x and y=x' and z=y in dist_triangle)
  1394 apply simp
  1395 done
  1396 
  1397 lemma open_contains_cball: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0.  cball x e \<subseteq> S)"
  1398 proof-
  1399   { fix x and e::real assume "x\<in>S" "e>0" "ball x e \<subseteq> S"
  1400     hence "\<exists>d>0. cball x d \<subseteq> S" unfolding subset_eq by (rule_tac x="e/2" in exI, auto)
  1401   } moreover
  1402   { fix x and e::real assume "x\<in>S" "e>0" "cball x e \<subseteq> S"
  1403     hence "\<exists>d>0. ball x d \<subseteq> S" unfolding subset_eq apply(rule_tac x="e/2" in exI) by auto
  1404   } ultimately
  1405   show ?thesis unfolding open_contains_ball by auto
  1406 qed
  1407 
  1408 lemma open_contains_cball_eq: "open S ==> (\<forall>x. x \<in> S \<longleftrightarrow> (\<exists>e>0. cball x e \<subseteq> S))"
  1409   by (metis open_contains_cball subset_eq order_less_imp_le centre_in_cball)
  1410 
  1411 lemma mem_interior_cball: "x \<in> interior S \<longleftrightarrow> (\<exists>e>0. cball x e \<subseteq> S)"
  1412   apply (simp add: interior_def, safe)
  1413   apply (force simp add: open_contains_cball)
  1414   apply (rule_tac x="ball x e" in exI)
  1415   apply (simp add: subset_trans [OF ball_subset_cball])
  1416   done
  1417 
  1418 lemma islimpt_ball:
  1419   fixes x y :: "'a::{real_normed_vector,perfect_space}"
  1420   shows "y islimpt ball x e \<longleftrightarrow> 0 < e \<and> y \<in> cball x e" (is "?lhs = ?rhs")
  1421 proof
  1422   assume "?lhs"
  1423   { assume "e \<le> 0"
  1424     hence *:"ball x e = {}" using ball_eq_empty[of x e] by auto
  1425     have False using `?lhs` unfolding * using islimpt_EMPTY[of y] by auto
  1426   }
  1427   hence "e > 0" by (metis not_less)
  1428   moreover
  1429   have "y \<in> cball x e" using closed_cball[of x e] islimpt_subset[of y "ball x e" "cball x e"] ball_subset_cball[of x e] `?lhs` unfolding closed_limpt by auto
  1430   ultimately show "?rhs" by auto
  1431 next
  1432   assume "?rhs" hence "e>0"  by auto
  1433   { fix d::real assume "d>0"
  1434     have "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1435     proof(cases "d \<le> dist x y")
  1436       case True thus "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1437       proof(cases "x=y")
  1438         case True hence False using `d \<le> dist x y` `d>0` by auto
  1439         thus "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d" by auto
  1440       next
  1441         case False
  1442 
  1443         have "dist x (y - (d / (2 * dist y x)) *\<^sub>R (y - x))
  1444               = norm (x - y + (d / (2 * norm (y - x))) *\<^sub>R (y - x))"
  1445           unfolding mem_cball mem_ball dist_norm diff_diff_eq2 diff_add_eq[THEN sym] by auto
  1446         also have "\<dots> = \<bar>- 1 + d / (2 * norm (x - y))\<bar> * norm (x - y)"
  1447           using scaleR_left_distrib[of "- 1" "d / (2 * norm (y - x))", THEN sym, of "y - x"]
  1448           unfolding scaleR_minus_left scaleR_one
  1449           by (auto simp add: norm_minus_commute)
  1450         also have "\<dots> = \<bar>- norm (x - y) + d / 2\<bar>"
  1451           unfolding abs_mult_pos[of "norm (x - y)", OF norm_ge_zero[of "x - y"]]
  1452           unfolding left_distrib using `x\<noteq>y`[unfolded dist_nz, unfolded dist_norm] by auto
  1453         also have "\<dots> \<le> e - d/2" using `d \<le> dist x y` and `d>0` and `?rhs` by(auto simp add: dist_norm)
  1454         finally have "y - (d / (2 * dist y x)) *\<^sub>R (y - x) \<in> ball x e" using `d>0` by auto
  1455 
  1456         moreover
  1457 
  1458         have "(d / (2*dist y x)) *\<^sub>R (y - x) \<noteq> 0"
  1459           using `x\<noteq>y`[unfolded dist_nz] `d>0` unfolding scaleR_eq_0_iff by (auto simp add: dist_commute)
  1460         moreover
  1461         have "dist (y - (d / (2 * dist y x)) *\<^sub>R (y - x)) y < d" unfolding dist_norm apply simp unfolding norm_minus_cancel
  1462           using `d>0` `x\<noteq>y`[unfolded dist_nz] dist_commute[of x y]
  1463           unfolding dist_norm by auto
  1464         ultimately show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d" by (rule_tac  x="y - (d / (2*dist y x)) *\<^sub>R (y - x)" in bexI) auto
  1465       qed
  1466     next
  1467       case False hence "d > dist x y" by auto
  1468       show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1469       proof(cases "x=y")
  1470         case True
  1471         obtain z where **: "z \<noteq> y" "dist z y < min e d"
  1472           using perfect_choose_dist[of "min e d" y]
  1473           using `d > 0` `e>0` by auto
  1474         show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1475           unfolding `x = y`
  1476           using `z \<noteq> y` **
  1477           by (rule_tac x=z in bexI, auto simp add: dist_commute)
  1478       next
  1479         case False thus "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1480           using `d>0` `d > dist x y` `?rhs` by(rule_tac x=x in bexI, auto)
  1481       qed
  1482     qed  }
  1483   thus "?lhs" unfolding mem_cball islimpt_approachable mem_ball by auto
  1484 qed
  1485 
  1486 lemma closure_ball_lemma:
  1487   fixes x y :: "'a::real_normed_vector"
  1488   assumes "x \<noteq> y" shows "y islimpt ball x (dist x y)"
  1489 proof (rule islimptI)
  1490   fix T assume "y \<in> T" "open T"
  1491   then obtain r where "0 < r" "\<forall>z. dist z y < r \<longrightarrow> z \<in> T"
  1492     unfolding open_dist by fast
  1493   (* choose point between x and y, within distance r of y. *)
  1494   def k \<equiv> "min 1 (r / (2 * dist x y))"
  1495   def z \<equiv> "y + scaleR k (x - y)"
  1496   have z_def2: "z = x + scaleR (1 - k) (y - x)"
  1497     unfolding z_def by (simp add: algebra_simps)
  1498   have "dist z y < r"
  1499     unfolding z_def k_def using `0 < r`
  1500     by (simp add: dist_norm min_def)
  1501   hence "z \<in> T" using `\<forall>z. dist z y < r \<longrightarrow> z \<in> T` by simp
  1502   have "dist x z < dist x y"
  1503     unfolding z_def2 dist_norm
  1504     apply (simp add: norm_minus_commute)
  1505     apply (simp only: dist_norm [symmetric])
  1506     apply (subgoal_tac "\<bar>1 - k\<bar> * dist x y < 1 * dist x y", simp)
  1507     apply (rule mult_strict_right_mono)
  1508     apply (simp add: k_def divide_pos_pos zero_less_dist_iff `0 < r` `x \<noteq> y`)
  1509     apply (simp add: zero_less_dist_iff `x \<noteq> y`)
  1510     done
  1511   hence "z \<in> ball x (dist x y)" by simp
  1512   have "z \<noteq> y"
  1513     unfolding z_def k_def using `x \<noteq> y` `0 < r`
  1514     by (simp add: min_def)
  1515   show "\<exists>z\<in>ball x (dist x y). z \<in> T \<and> z \<noteq> y"
  1516     using `z \<in> ball x (dist x y)` `z \<in> T` `z \<noteq> y`
  1517     by fast
  1518 qed
  1519 
  1520 lemma closure_ball:
  1521   fixes x :: "'a::real_normed_vector"
  1522   shows "0 < e \<Longrightarrow> closure (ball x e) = cball x e"
  1523 apply (rule equalityI)
  1524 apply (rule closure_minimal)
  1525 apply (rule ball_subset_cball)
  1526 apply (rule closed_cball)
  1527 apply (rule subsetI, rename_tac y)
  1528 apply (simp add: le_less [where 'a=real])
  1529 apply (erule disjE)
  1530 apply (rule subsetD [OF closure_subset], simp)
  1531 apply (simp add: closure_def)
  1532 apply clarify
  1533 apply (rule closure_ball_lemma)
  1534 apply (simp add: zero_less_dist_iff)
  1535 done
  1536 
  1537 (* In a trivial vector space, this fails for e = 0. *)
  1538 lemma interior_cball:
  1539   fixes x :: "'a::{real_normed_vector, perfect_space}"
  1540   shows "interior (cball x e) = ball x e"
  1541 proof(cases "e\<ge>0")
  1542   case False note cs = this
  1543   from cs have "ball x e = {}" using ball_empty[of e x] by auto moreover
  1544   { fix y assume "y \<in> cball x e"
  1545     hence False unfolding mem_cball using dist_nz[of x y] cs by auto  }
  1546   hence "cball x e = {}" by auto
  1547   hence "interior (cball x e) = {}" using interior_empty by auto
  1548   ultimately show ?thesis by blast
  1549 next
  1550   case True note cs = this
  1551   have "ball x e \<subseteq> cball x e" using ball_subset_cball by auto moreover
  1552   { fix S y assume as: "S \<subseteq> cball x e" "open S" "y\<in>S"
  1553     then obtain d where "d>0" and d:"\<forall>x'. dist x' y < d \<longrightarrow> x' \<in> S" unfolding open_dist by blast
  1554 
  1555     then obtain xa where xa_y: "xa \<noteq> y" and xa: "dist xa y < d"
  1556       using perfect_choose_dist [of d] by auto
  1557     have "xa\<in>S" using d[THEN spec[where x=xa]] using xa by(auto simp add: dist_commute)
  1558     hence xa_cball:"xa \<in> cball x e" using as(1) by auto
  1559 
  1560     hence "y \<in> ball x e" proof(cases "x = y")
  1561       case True
  1562       hence "e>0" using xa_y[unfolded dist_nz] xa_cball[unfolded mem_cball] by (auto simp add: dist_commute)
  1563       thus "y \<in> ball x e" using `x = y ` by simp
  1564     next
  1565       case False
  1566       have "dist (y + (d / 2 / dist y x) *\<^sub>R (y - x)) y < d" unfolding dist_norm
  1567         using `d>0` norm_ge_zero[of "y - x"] `x \<noteq> y` by auto
  1568       hence *:"y + (d / 2 / dist y x) *\<^sub>R (y - x) \<in> cball x e" using d as(1)[unfolded subset_eq] by blast
  1569       have "y - x \<noteq> 0" using `x \<noteq> y` by auto
  1570       hence **:"d / (2 * norm (y - x)) > 0" unfolding zero_less_norm_iff[THEN sym]
  1571         using `d>0` divide_pos_pos[of d "2*norm (y - x)"] by auto
  1572 
  1573       have "dist (y + (d / 2 / dist y x) *\<^sub>R (y - x)) x = norm (y + (d / (2 * norm (y - x))) *\<^sub>R y - (d / (2 * norm (y - x))) *\<^sub>R x - x)"
  1574         by (auto simp add: dist_norm algebra_simps)
  1575       also have "\<dots> = norm ((1 + d / (2 * norm (y - x))) *\<^sub>R (y - x))"
  1576         by (auto simp add: algebra_simps)
  1577       also have "\<dots> = \<bar>1 + d / (2 * norm (y - x))\<bar> * norm (y - x)"
  1578         using ** by auto
  1579       also have "\<dots> = (dist y x) + d/2"using ** by (auto simp add: left_distrib dist_norm)
  1580       finally have "e \<ge> dist x y +d/2" using *[unfolded mem_cball] by (auto simp add: dist_commute)
  1581       thus "y \<in> ball x e" unfolding mem_ball using `d>0` by auto
  1582     qed  }
  1583   hence "\<forall>S \<subseteq> cball x e. open S \<longrightarrow> S \<subseteq> ball x e" by auto
  1584   ultimately show ?thesis using interior_unique[of "ball x e" "cball x e"] using open_ball[of x e] by auto
  1585 qed
  1586 
  1587 lemma frontier_ball:
  1588   fixes a :: "'a::real_normed_vector"
  1589   shows "0 < e ==> frontier(ball a e) = {x. dist a x = e}"
  1590   apply (simp add: frontier_def closure_ball interior_open order_less_imp_le)
  1591   apply (simp add: set_eq_iff)
  1592   by arith
  1593 
  1594 lemma frontier_cball:
  1595   fixes a :: "'a::{real_normed_vector, perfect_space}"
  1596   shows "frontier(cball a e) = {x. dist a x = e}"
  1597   apply (simp add: frontier_def interior_cball closed_cball order_less_imp_le)
  1598   apply (simp add: set_eq_iff)
  1599   by arith
  1600 
  1601 lemma cball_eq_empty: "(cball x e = {}) \<longleftrightarrow> e < 0"
  1602   apply (simp add: set_eq_iff not_le)
  1603   by (metis zero_le_dist dist_self order_less_le_trans)
  1604 lemma cball_empty: "e < 0 ==> cball x e = {}" by (simp add: cball_eq_empty)
  1605 
  1606 lemma cball_eq_sing:
  1607   fixes x :: "'a::{metric_space,perfect_space}"
  1608   shows "(cball x e = {x}) \<longleftrightarrow> e = 0"
  1609 proof (rule linorder_cases)
  1610   assume e: "0 < e"
  1611   obtain a where "a \<noteq> x" "dist a x < e"
  1612     using perfect_choose_dist [OF e] by auto
  1613   hence "a \<noteq> x" "dist x a \<le> e" by (auto simp add: dist_commute)
  1614   with e show ?thesis by (auto simp add: set_eq_iff)
  1615 qed auto
  1616 
  1617 lemma cball_sing:
  1618   fixes x :: "'a::metric_space"
  1619   shows "e = 0 ==> cball x e = {x}"
  1620   by (auto simp add: set_eq_iff)
  1621 
  1622 
  1623 subsection {* Boundedness *}
  1624 
  1625   (* FIXME: This has to be unified with BSEQ!! *)
  1626 definition (in metric_space)
  1627   bounded :: "'a set \<Rightarrow> bool" where
  1628   "bounded S \<longleftrightarrow> (\<exists>x e. \<forall>y\<in>S. dist x y \<le> e)"
  1629 
  1630 lemma bounded_any_center: "bounded S \<longleftrightarrow> (\<exists>e. \<forall>y\<in>S. dist a y \<le> e)"
  1631 unfolding bounded_def
  1632 apply safe
  1633 apply (rule_tac x="dist a x + e" in exI, clarify)
  1634 apply (drule (1) bspec)
  1635 apply (erule order_trans [OF dist_triangle add_left_mono])
  1636 apply auto
  1637 done
  1638 
  1639 lemma bounded_iff: "bounded S \<longleftrightarrow> (\<exists>a. \<forall>x\<in>S. norm x \<le> a)"
  1640 unfolding bounded_any_center [where a=0]
  1641 by (simp add: dist_norm)
  1642 
  1643 lemma bounded_empty[simp]: "bounded {}" by (simp add: bounded_def)
  1644 lemma bounded_subset: "bounded T \<Longrightarrow> S \<subseteq> T ==> bounded S"
  1645   by (metis bounded_def subset_eq)
  1646 
  1647 lemma bounded_interior[intro]: "bounded S ==> bounded(interior S)"
  1648   by (metis bounded_subset interior_subset)
  1649 
  1650 lemma bounded_closure[intro]: assumes "bounded S" shows "bounded(closure S)"
  1651 proof-
  1652   from assms obtain x and a where a: "\<forall>y\<in>S. dist x y \<le> a" unfolding bounded_def by auto
  1653   { fix y assume "y \<in> closure S"
  1654     then obtain f where f: "\<forall>n. f n \<in> S"  "(f ---> y) sequentially"
  1655       unfolding closure_sequential by auto
  1656     have "\<forall>n. f n \<in> S \<longrightarrow> dist x (f n) \<le> a" using a by simp
  1657     hence "eventually (\<lambda>n. dist x (f n) \<le> a) sequentially"
  1658       by (rule eventually_mono, simp add: f(1))
  1659     have "dist x y \<le> a"
  1660       apply (rule Lim_dist_ubound [of sequentially f])
  1661       apply (rule trivial_limit_sequentially)
  1662       apply (rule f(2))
  1663       apply fact
  1664       done
  1665   }
  1666   thus ?thesis unfolding bounded_def by auto
  1667 qed
  1668 
  1669 lemma bounded_cball[simp,intro]: "bounded (cball x e)"
  1670   apply (simp add: bounded_def)
  1671   apply (rule_tac x=x in exI)
  1672   apply (rule_tac x=e in exI)
  1673   apply auto
  1674   done
  1675 
  1676 lemma bounded_ball[simp,intro]: "bounded(ball x e)"
  1677   by (metis ball_subset_cball bounded_cball bounded_subset)
  1678 
  1679 lemma finite_imp_bounded[intro]:
  1680   fixes S :: "'a::metric_space set" assumes "finite S" shows "bounded S"
  1681 proof-
  1682   { fix a and F :: "'a set" assume as:"bounded F"
  1683     then obtain x e where "\<forall>y\<in>F. dist x y \<le> e" unfolding bounded_def by auto
  1684     hence "\<forall>y\<in>(insert a F). dist x y \<le> max e (dist x a)" by auto
  1685     hence "bounded (insert a F)" unfolding bounded_def by (intro exI)
  1686   }
  1687   thus ?thesis using finite_induct[of S bounded]  using bounded_empty assms by auto
  1688 qed
  1689 
  1690 lemma bounded_Un[simp]: "bounded (S \<union> T) \<longleftrightarrow> bounded S \<and> bounded T"
  1691   apply (auto simp add: bounded_def)
  1692   apply (rename_tac x y r s)
  1693   apply (rule_tac x=x in exI)
  1694   apply (rule_tac x="max r (dist x y + s)" in exI)
  1695   apply (rule ballI, rename_tac z, safe)
  1696   apply (drule (1) bspec, simp)
  1697   apply (drule (1) bspec)
  1698   apply (rule min_max.le_supI2)
  1699   apply (erule order_trans [OF dist_triangle add_left_mono])
  1700   done
  1701 
  1702 lemma bounded_Union[intro]: "finite F \<Longrightarrow> (\<forall>S\<in>F. bounded S) \<Longrightarrow> bounded(\<Union>F)"
  1703   by (induct rule: finite_induct[of F], auto)
  1704 
  1705 lemma bounded_pos: "bounded S \<longleftrightarrow> (\<exists>b>0. \<forall>x\<in> S. norm x <= b)"
  1706   apply (simp add: bounded_iff)
  1707   apply (subgoal_tac "\<And>x (y::real). 0 < 1 + abs y \<and> (x <= y \<longrightarrow> x <= 1 + abs y)")
  1708   by metis arith
  1709 
  1710 lemma bounded_Int[intro]: "bounded S \<or> bounded T \<Longrightarrow> bounded (S \<inter> T)"
  1711   by (metis Int_lower1 Int_lower2 bounded_subset)
  1712 
  1713 lemma bounded_diff[intro]: "bounded S ==> bounded (S - T)"
  1714 apply (metis Diff_subset bounded_subset)
  1715 done
  1716 
  1717 lemma bounded_insert[intro]:"bounded(insert x S) \<longleftrightarrow> bounded S"
  1718   by (metis Diff_cancel Un_empty_right Un_insert_right bounded_Un bounded_subset finite.emptyI finite_imp_bounded infinite_remove subset_insertI)
  1719 
  1720 lemma not_bounded_UNIV[simp, intro]:
  1721   "\<not> bounded (UNIV :: 'a::{real_normed_vector, perfect_space} set)"
  1722 proof(auto simp add: bounded_pos not_le)
  1723   obtain x :: 'a where "x \<noteq> 0"
  1724     using perfect_choose_dist [OF zero_less_one] by fast
  1725   fix b::real  assume b: "b >0"
  1726   have b1: "b +1 \<ge> 0" using b by simp
  1727   with `x \<noteq> 0` have "b < norm (scaleR (b + 1) (sgn x))"
  1728     by (simp add: norm_sgn)
  1729   then show "\<exists>x::'a. b < norm x" ..
  1730 qed
  1731 
  1732 lemma bounded_linear_image:
  1733   assumes "bounded S" "bounded_linear f"
  1734   shows "bounded(f ` S)"
  1735 proof-
  1736   from assms(1) obtain b where b:"b>0" "\<forall>x\<in>S. norm x \<le> b" unfolding bounded_pos by auto
  1737   from assms(2) obtain B where B:"B>0" "\<forall>x. norm (f x) \<le> B * norm x" using bounded_linear.pos_bounded by (auto simp add: mult_ac)
  1738   { fix x assume "x\<in>S"
  1739     hence "norm x \<le> b" using b by auto
  1740     hence "norm (f x) \<le> B * b" using B(2) apply(erule_tac x=x in allE)
  1741       by (metis B(1) B(2) order_trans mult_le_cancel_left_pos)
  1742   }
  1743   thus ?thesis unfolding bounded_pos apply(rule_tac x="b*B" in exI)
  1744     using b B mult_pos_pos [of b B] by (auto simp add: mult_commute)
  1745 qed
  1746 
  1747 lemma bounded_scaling:
  1748   fixes S :: "'a::real_normed_vector set"
  1749   shows "bounded S \<Longrightarrow> bounded ((\<lambda>x. c *\<^sub>R x) ` S)"
  1750   apply (rule bounded_linear_image, assumption)
  1751   apply (rule bounded_linear_scaleR_right)
  1752   done
  1753 
  1754 lemma bounded_translation:
  1755   fixes S :: "'a::real_normed_vector set"
  1756   assumes "bounded S" shows "bounded ((\<lambda>x. a + x) ` S)"
  1757 proof-
  1758   from assms obtain b where b:"b>0" "\<forall>x\<in>S. norm x \<le> b" unfolding bounded_pos by auto
  1759   { fix x assume "x\<in>S"
  1760     hence "norm (a + x) \<le> b + norm a" using norm_triangle_ineq[of a x] b by auto
  1761   }
  1762   thus ?thesis unfolding bounded_pos using norm_ge_zero[of a] b(1) using add_strict_increasing[of b 0 "norm a"]
  1763     by (auto intro!: add exI[of _ "b + norm a"])
  1764 qed
  1765 
  1766 
  1767 text{* Some theorems on sups and infs using the notion "bounded". *}
  1768 
  1769 lemma bounded_real:
  1770   fixes S :: "real set"
  1771   shows "bounded S \<longleftrightarrow>  (\<exists>a. \<forall>x\<in>S. abs x <= a)"
  1772   by (simp add: bounded_iff)
  1773 
  1774 lemma bounded_has_Sup:
  1775   fixes S :: "real set"
  1776   assumes "bounded S" "S \<noteq> {}"
  1777   shows "\<forall>x\<in>S. x <= Sup S" and "\<forall>b. (\<forall>x\<in>S. x <= b) \<longrightarrow> Sup S <= b"
  1778 proof
  1779   fix x assume "x\<in>S"
  1780   thus "x \<le> Sup S"
  1781     by (metis SupInf.Sup_upper abs_le_D1 assms(1) bounded_real)
  1782 next
  1783   show "\<forall>b. (\<forall>x\<in>S. x \<le> b) \<longrightarrow> Sup S \<le> b" using assms
  1784     by (metis SupInf.Sup_least)
  1785 qed
  1786 
  1787 lemma Sup_insert:
  1788   fixes S :: "real set"
  1789   shows "bounded S ==> Sup(insert x S) = (if S = {} then x else max x (Sup S))" 
  1790 by auto (metis Int_absorb Sup_insert_nonempty assms bounded_has_Sup(1) disjoint_iff_not_equal) 
  1791 
  1792 lemma Sup_insert_finite:
  1793   fixes S :: "real set"
  1794   shows "finite S \<Longrightarrow> Sup(insert x S) = (if S = {} then x else max x (Sup S))"
  1795   apply (rule Sup_insert)
  1796   apply (rule finite_imp_bounded)
  1797   by simp
  1798 
  1799 lemma bounded_has_Inf:
  1800   fixes S :: "real set"
  1801   assumes "bounded S"  "S \<noteq> {}"
  1802   shows "\<forall>x\<in>S. x >= Inf S" and "\<forall>b. (\<forall>x\<in>S. x >= b) \<longrightarrow> Inf S >= b"
  1803 proof
  1804   fix x assume "x\<in>S"
  1805   from assms(1) obtain a where a:"\<forall>x\<in>S. \<bar>x\<bar> \<le> a" unfolding bounded_real by auto
  1806   thus "x \<ge> Inf S" using `x\<in>S`
  1807     by (metis Inf_lower_EX abs_le_D2 minus_le_iff)
  1808 next
  1809   show "\<forall>b. (\<forall>x\<in>S. x >= b) \<longrightarrow> Inf S \<ge> b" using assms
  1810     by (metis SupInf.Inf_greatest)
  1811 qed
  1812 
  1813 lemma Inf_insert:
  1814   fixes S :: "real set"
  1815   shows "bounded S ==> Inf(insert x S) = (if S = {} then x else min x (Inf S))" 
  1816 by auto (metis Int_absorb Inf_insert_nonempty bounded_has_Inf(1) disjoint_iff_not_equal) 
  1817 lemma Inf_insert_finite:
  1818   fixes S :: "real set"
  1819   shows "finite S ==> Inf(insert x S) = (if S = {} then x else min x (Inf S))"
  1820   by (rule Inf_insert, rule finite_imp_bounded, simp)
  1821 
  1822 (* TODO: Move this to RComplete.thy -- would need to include Glb into RComplete *)
  1823 lemma real_isGlb_unique: "[| isGlb R S x; isGlb R S y |] ==> x = (y::real)"
  1824   apply (frule isGlb_isLb)
  1825   apply (frule_tac x = y in isGlb_isLb)
  1826   apply (blast intro!: order_antisym dest!: isGlb_le_isLb)
  1827   done
  1828 
  1829 
  1830 subsection {* Equivalent versions of compactness *}
  1831 
  1832 subsubsection{* Sequential compactness *}
  1833 
  1834 definition
  1835   compact :: "'a::metric_space set \<Rightarrow> bool" where (* TODO: generalize *)
  1836   "compact S \<longleftrightarrow>
  1837    (\<forall>f. (\<forall>n. f n \<in> S) \<longrightarrow>
  1838        (\<exists>l\<in>S. \<exists>r. subseq r \<and> ((f o r) ---> l) sequentially))"
  1839 
  1840 lemma compactI:
  1841   assumes "\<And>f. \<forall>n. f n \<in> S \<Longrightarrow> \<exists>l\<in>S. \<exists>r. subseq r \<and> ((f o r) ---> l) sequentially"
  1842   shows "compact S"
  1843   unfolding compact_def using assms by fast
  1844 
  1845 lemma compactE:
  1846   assumes "compact S" "\<forall>n. f n \<in> S"
  1847   obtains l r where "l \<in> S" "subseq r" "((f \<circ> r) ---> l) sequentially"
  1848   using assms unfolding compact_def by fast
  1849 
  1850 text {*
  1851   A metric space (or topological vector space) is said to have the
  1852   Heine-Borel property if every closed and bounded subset is compact.
  1853 *}
  1854 
  1855 class heine_borel = metric_space +
  1856   assumes bounded_imp_convergent_subsequence:
  1857     "bounded s \<Longrightarrow> \<forall>n. f n \<in> s
  1858       \<Longrightarrow> \<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  1859 
  1860 lemma bounded_closed_imp_compact:
  1861   fixes s::"'a::heine_borel set"
  1862   assumes "bounded s" and "closed s" shows "compact s"
  1863 proof (unfold compact_def, clarify)
  1864   fix f :: "nat \<Rightarrow> 'a" assume f: "\<forall>n. f n \<in> s"
  1865   obtain l r where r: "subseq r" and l: "((f \<circ> r) ---> l) sequentially"
  1866     using bounded_imp_convergent_subsequence [OF `bounded s` `\<forall>n. f n \<in> s`] by auto
  1867   from f have fr: "\<forall>n. (f \<circ> r) n \<in> s" by simp
  1868   have "l \<in> s" using `closed s` fr l
  1869     unfolding closed_sequential_limits by blast
  1870   show "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  1871     using `l \<in> s` r l by blast
  1872 qed
  1873 
  1874 lemma subseq_bigger: assumes "subseq r" shows "n \<le> r n"
  1875 proof(induct n)
  1876   show "0 \<le> r 0" by auto
  1877 next
  1878   fix n assume "n \<le> r n"
  1879   moreover have "r n < r (Suc n)"
  1880     using assms [unfolded subseq_def] by auto
  1881   ultimately show "Suc n \<le> r (Suc n)" by auto
  1882 qed
  1883 
  1884 lemma eventually_subseq:
  1885   assumes r: "subseq r"
  1886   shows "eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  1887 unfolding eventually_sequentially
  1888 by (metis subseq_bigger [OF r] le_trans)
  1889 
  1890 lemma lim_subseq:
  1891   "subseq r \<Longrightarrow> (s ---> l) sequentially \<Longrightarrow> ((s o r) ---> l) sequentially"
  1892 unfolding tendsto_def eventually_sequentially o_def
  1893 by (metis subseq_bigger le_trans)
  1894 
  1895 lemma num_Axiom: "EX! g. g 0 = e \<and> (\<forall>n. g (Suc n) = f n (g n))"
  1896   unfolding Ex1_def
  1897   apply (rule_tac x="nat_rec e f" in exI)
  1898   apply (rule conjI)+
  1899 apply (rule def_nat_rec_0, simp)
  1900 apply (rule allI, rule def_nat_rec_Suc, simp)
  1901 apply (rule allI, rule impI, rule ext)
  1902 apply (erule conjE)
  1903 apply (induct_tac x)
  1904 apply simp
  1905 apply (erule_tac x="n" in allE)
  1906 apply (simp)
  1907 done
  1908 
  1909 lemma convergent_bounded_increasing: fixes s ::"nat\<Rightarrow>real"
  1910   assumes "incseq s" and "\<forall>n. abs(s n) \<le> b"
  1911   shows "\<exists> l. \<forall>e::real>0. \<exists> N. \<forall>n \<ge> N.  abs(s n - l) < e"
  1912 proof-
  1913   have "isUb UNIV (range s) b" using assms(2) and abs_le_D1 unfolding isUb_def and setle_def by auto
  1914   then obtain t where t:"isLub UNIV (range s) t" using reals_complete[of "range s" ] by auto
  1915   { fix e::real assume "e>0" and as:"\<forall>N. \<exists>n\<ge>N. \<not> \<bar>s n - t\<bar> < e"
  1916     { fix n::nat
  1917       obtain N where "N\<ge>n" and n:"\<bar>s N - t\<bar> \<ge> e" using as[THEN spec[where x=n]] by auto
  1918       have "t \<ge> s N" using isLub_isUb[OF t, unfolded isUb_def setle_def] by auto
  1919       with n have "s N \<le> t - e" using `e>0` by auto
  1920       hence "s n \<le> t - e" using assms(1)[unfolded incseq_def, THEN spec[where x=n], THEN spec[where x=N]] using `n\<le>N` by auto  }
  1921     hence "isUb UNIV (range s) (t - e)" unfolding isUb_def and setle_def by auto
  1922     hence False using isLub_le_isUb[OF t, of "t - e"] and `e>0` by auto  }
  1923   thus ?thesis by blast
  1924 qed
  1925 
  1926 lemma convergent_bounded_monotone: fixes s::"nat \<Rightarrow> real"
  1927   assumes "\<forall>n. abs(s n) \<le> b" and "monoseq s"
  1928   shows "\<exists>l. \<forall>e::real>0. \<exists>N. \<forall>n\<ge>N. abs(s n - l) < e"
  1929   using convergent_bounded_increasing[of s b] assms using convergent_bounded_increasing[of "\<lambda>n. - s n" b]
  1930   unfolding monoseq_def incseq_def
  1931   apply auto unfolding minus_add_distrib[THEN sym, unfolded diff_minus[THEN sym]]
  1932   unfolding abs_minus_cancel by(rule_tac x="-l" in exI)auto
  1933 
  1934 (* TODO: merge this lemma with the ones above *)
  1935 lemma bounded_increasing_convergent: fixes s::"nat \<Rightarrow> real"
  1936   assumes "bounded {s n| n::nat. True}"  "\<forall>n. (s n) \<le>(s(Suc n))"
  1937   shows "\<exists>l. (s ---> l) sequentially"
  1938 proof-
  1939   obtain a where a:"\<forall>n. \<bar> (s n)\<bar> \<le>  a" using assms(1)[unfolded bounded_iff] by auto
  1940   { fix m::nat
  1941     have "\<And> n. n\<ge>m \<longrightarrow>  (s m) \<le> (s n)"
  1942       apply(induct_tac n) apply simp using assms(2) apply(erule_tac x="na" in allE)
  1943       apply(case_tac "m \<le> na") unfolding not_less_eq_eq by(auto simp add: not_less_eq_eq)  }
  1944   hence "\<forall>m n. m \<le> n \<longrightarrow> (s m) \<le> (s n)" by auto
  1945   then obtain l where "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<bar> (s n) - l\<bar> < e" using convergent_bounded_monotone[OF a]
  1946     unfolding monoseq_def by auto
  1947   thus ?thesis unfolding LIMSEQ_def apply(rule_tac x="l" in exI)
  1948     unfolding dist_norm  by auto
  1949 qed
  1950 
  1951 lemma compact_real_lemma:
  1952   assumes "\<forall>n::nat. abs(s n) \<le> b"
  1953   shows "\<exists>(l::real) r. subseq r \<and> ((s \<circ> r) ---> l) sequentially"
  1954 proof-
  1955   obtain r where r:"subseq r" "monoseq (\<lambda>n. s (r n))"
  1956     using seq_monosub[of s] by auto
  1957   thus ?thesis using convergent_bounded_monotone[of "\<lambda>n. s (r n)" b] and assms
  1958     unfolding tendsto_iff dist_norm eventually_sequentially by auto
  1959 qed
  1960 
  1961 instance real :: heine_borel
  1962 proof
  1963   fix s :: "real set" and f :: "nat \<Rightarrow> real"
  1964   assume s: "bounded s" and f: "\<forall>n. f n \<in> s"
  1965   then obtain b where b: "\<forall>n. abs (f n) \<le> b"
  1966     unfolding bounded_iff by auto
  1967   obtain l :: real and r :: "nat \<Rightarrow> nat" where
  1968     r: "subseq r" and l: "((f \<circ> r) ---> l) sequentially"
  1969     using compact_real_lemma [OF b] by auto
  1970   thus "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  1971     by auto
  1972 qed
  1973 
  1974 lemma bounded_component: "bounded s \<Longrightarrow> bounded ((\<lambda>x. x $$ i) ` s)"
  1975   apply (erule bounded_linear_image)
  1976   apply (rule bounded_linear_euclidean_component)
  1977   done
  1978 
  1979 lemma compact_lemma:
  1980   fixes f :: "nat \<Rightarrow> 'a::euclidean_space"
  1981   assumes "bounded s" and "\<forall>n. f n \<in> s"
  1982   shows "\<forall>d. \<exists>l::'a. \<exists> r. subseq r \<and>
  1983         (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) $$ i) (l $$ i) < e) sequentially)"
  1984 proof
  1985   fix d'::"nat set" def d \<equiv> "d' \<inter> {..<DIM('a)}"
  1986   have "finite d" "d\<subseteq>{..<DIM('a)}" unfolding d_def by auto
  1987   hence "\<exists>l::'a. \<exists>r. subseq r \<and>
  1988       (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) $$ i) (l $$ i) < e) sequentially)"
  1989   proof(induct d) case empty thus ?case unfolding subseq_def by auto
  1990   next case (insert k d) have k[intro]:"k<DIM('a)" using insert by auto
  1991     have s': "bounded ((\<lambda>x. x $$ k) ` s)" using `bounded s` by (rule bounded_component)
  1992     obtain l1::"'a" and r1 where r1:"subseq r1" and
  1993       lr1:"\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 n) $$ i) (l1 $$ i) < e) sequentially"
  1994       using insert(3) using insert(4) by auto
  1995     have f': "\<forall>n. f (r1 n) $$ k \<in> (\<lambda>x. x $$ k) ` s" using `\<forall>n. f n \<in> s` by simp
  1996     obtain l2 r2 where r2:"subseq r2" and lr2:"((\<lambda>i. f (r1 (r2 i)) $$ k) ---> l2) sequentially"
  1997       using bounded_imp_convergent_subsequence[OF s' f'] unfolding o_def by auto
  1998     def r \<equiv> "r1 \<circ> r2" have r:"subseq r"
  1999       using r1 and r2 unfolding r_def o_def subseq_def by auto
  2000     moreover
  2001     def l \<equiv> "(\<chi>\<chi> i. if i = k then l2 else l1$$i)::'a"
  2002     { fix e::real assume "e>0"
  2003       from lr1 `e>0` have N1:"eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 n) $$ i) (l1 $$ i) < e) sequentially" by blast
  2004       from lr2 `e>0` have N2:"eventually (\<lambda>n. dist (f (r1 (r2 n)) $$ k) l2 < e) sequentially" by (rule tendstoD)
  2005       from r2 N1 have N1': "eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 (r2 n)) $$ i) (l1 $$ i) < e) sequentially"
  2006         by (rule eventually_subseq)
  2007       have "eventually (\<lambda>n. \<forall>i\<in>(insert k d). dist (f (r n) $$ i) (l $$ i) < e) sequentially"
  2008         using N1' N2 apply(rule eventually_elim2) unfolding l_def r_def o_def
  2009         using insert.prems by auto
  2010     }
  2011     ultimately show ?case by auto
  2012   qed
  2013   thus "\<exists>l::'a. \<exists>r. subseq r \<and>
  2014       (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d'. dist (f (r n) $$ i) (l $$ i) < e) sequentially)"
  2015     apply safe apply(rule_tac x=l in exI,rule_tac x=r in exI) apply safe
  2016     apply(erule_tac x=e in allE) unfolding d_def eventually_sequentially apply safe 
  2017     apply(rule_tac x=N in exI) apply safe apply(erule_tac x=n in allE,safe)
  2018     apply(erule_tac x=i in ballE) 
  2019   proof- fix i and r::"nat=>nat" and n::nat and e::real and l::'a
  2020     assume "i\<in>d'" "i \<notin> d' \<inter> {..<DIM('a)}" and e:"e>0"
  2021     hence *:"i\<ge>DIM('a)" by auto
  2022     thus "dist (f (r n) $$ i) (l $$ i) < e" using e by auto
  2023   qed
  2024 qed
  2025 
  2026 instance euclidean_space \<subseteq> heine_borel
  2027 proof
  2028   fix s :: "'a set" and f :: "nat \<Rightarrow> 'a"
  2029   assume s: "bounded s" and f: "\<forall>n. f n \<in> s"
  2030   then obtain l::'a and r where r: "subseq r"
  2031     and l: "\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>UNIV. dist (f (r n) $$ i) (l $$ i) < e) sequentially"
  2032     using compact_lemma [OF s f] by blast
  2033   let ?d = "{..<DIM('a)}"
  2034   { fix e::real assume "e>0"
  2035     hence "0 < e / (real_of_nat (card ?d))"
  2036       using DIM_positive using divide_pos_pos[of e, of "real_of_nat (card ?d)"] by auto
  2037     with l have "eventually (\<lambda>n. \<forall>i. dist (f (r n) $$ i) (l $$ i) < e / (real_of_nat (card ?d))) sequentially"
  2038       by simp
  2039     moreover
  2040     { fix n assume n: "\<forall>i. dist (f (r n) $$ i) (l $$ i) < e / (real_of_nat (card ?d))"
  2041       have "dist (f (r n)) l \<le> (\<Sum>i\<in>?d. dist (f (r n) $$ i) (l $$ i))"
  2042         apply(subst euclidean_dist_l2) using zero_le_dist by (rule setL2_le_setsum)
  2043       also have "\<dots> < (\<Sum>i\<in>?d. e / (real_of_nat (card ?d)))"
  2044         apply(rule setsum_strict_mono) using n by auto
  2045       finally have "dist (f (r n)) l < e" unfolding setsum_constant
  2046         using DIM_positive[where 'a='a] by auto
  2047     }
  2048     ultimately have "eventually (\<lambda>n. dist (f (r n)) l < e) sequentially"
  2049       by (rule eventually_elim1)
  2050   }
  2051   hence *:"((f \<circ> r) ---> l) sequentially" unfolding o_def tendsto_iff by simp
  2052   with r show "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially" by auto
  2053 qed
  2054 
  2055 lemma bounded_fst: "bounded s \<Longrightarrow> bounded (fst ` s)"
  2056 unfolding bounded_def
  2057 apply clarify
  2058 apply (rule_tac x="a" in exI)
  2059 apply (rule_tac x="e" in exI)
  2060 apply clarsimp
  2061 apply (drule (1) bspec)
  2062 apply (simp add: dist_Pair_Pair)
  2063 apply (erule order_trans [OF real_sqrt_sum_squares_ge1])
  2064 done
  2065 
  2066 lemma bounded_snd: "bounded s \<Longrightarrow> bounded (snd ` s)"
  2067 unfolding bounded_def
  2068 apply clarify
  2069 apply (rule_tac x="b" in exI)
  2070 apply (rule_tac x="e" in exI)
  2071 apply clarsimp
  2072 apply (drule (1) bspec)
  2073 apply (simp add: dist_Pair_Pair)
  2074 apply (erule order_trans [OF real_sqrt_sum_squares_ge2])
  2075 done
  2076 
  2077 instance prod :: (heine_borel, heine_borel) heine_borel
  2078 proof
  2079   fix s :: "('a * 'b) set" and f :: "nat \<Rightarrow> 'a * 'b"
  2080   assume s: "bounded s" and f: "\<forall>n. f n \<in> s"
  2081   from s have s1: "bounded (fst ` s)" by (rule bounded_fst)
  2082   from f have f1: "\<forall>n. fst (f n) \<in> fst ` s" by simp
  2083   obtain l1 r1 where r1: "subseq r1"
  2084     and l1: "((\<lambda>n. fst (f (r1 n))) ---> l1) sequentially"
  2085     using bounded_imp_convergent_subsequence [OF s1 f1]
  2086     unfolding o_def by fast
  2087   from s have s2: "bounded (snd ` s)" by (rule bounded_snd)
  2088   from f have f2: "\<forall>n. snd (f (r1 n)) \<in> snd ` s" by simp
  2089   obtain l2 r2 where r2: "subseq r2"
  2090     and l2: "((\<lambda>n. snd (f (r1 (r2 n)))) ---> l2) sequentially"
  2091     using bounded_imp_convergent_subsequence [OF s2 f2]
  2092     unfolding o_def by fast
  2093   have l1': "((\<lambda>n. fst (f (r1 (r2 n)))) ---> l1) sequentially"
  2094     using lim_subseq [OF r2 l1] unfolding o_def .
  2095   have l: "((f \<circ> (r1 \<circ> r2)) ---> (l1, l2)) sequentially"
  2096     using tendsto_Pair [OF l1' l2] unfolding o_def by simp
  2097   have r: "subseq (r1 \<circ> r2)"
  2098     using r1 r2 unfolding subseq_def by simp
  2099   show "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2100     using l r by fast
  2101 qed
  2102 
  2103 subsubsection{* Completeness *}
  2104 
  2105 lemma cauchy_def:
  2106   "Cauchy s \<longleftrightarrow> (\<forall>e>0. \<exists>N. \<forall>m n. m \<ge> N \<and> n \<ge> N --> dist(s m)(s n) < e)"
  2107 unfolding Cauchy_def by blast
  2108 
  2109 definition
  2110   complete :: "'a::metric_space set \<Rightarrow> bool" where
  2111   "complete s \<longleftrightarrow> (\<forall>f. (\<forall>n. f n \<in> s) \<and> Cauchy f
  2112                       --> (\<exists>l \<in> s. (f ---> l) sequentially))"
  2113 
  2114 lemma cauchy: "Cauchy s \<longleftrightarrow> (\<forall>e>0.\<exists> N::nat. \<forall>n\<ge>N. dist(s n)(s N) < e)" (is "?lhs = ?rhs")
  2115 proof-
  2116   { assume ?rhs
  2117     { fix e::real
  2118       assume "e>0"
  2119       with `?rhs` obtain N where N:"\<forall>n\<ge>N. dist (s n) (s N) < e/2"
  2120         by (erule_tac x="e/2" in allE) auto
  2121       { fix n m
  2122         assume nm:"N \<le> m \<and> N \<le> n"
  2123         hence "dist (s m) (s n) < e" using N
  2124           using dist_triangle_half_l[of "s m" "s N" "e" "s n"]
  2125           by blast
  2126       }
  2127       hence "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < e"
  2128         by blast
  2129     }
  2130     hence ?lhs
  2131       unfolding cauchy_def
  2132       by blast
  2133   }
  2134   thus ?thesis
  2135     unfolding cauchy_def
  2136     using dist_triangle_half_l
  2137     by blast
  2138 qed
  2139 
  2140 lemma convergent_imp_cauchy:
  2141  "(s ---> l) sequentially ==> Cauchy s"
  2142 proof(simp only: cauchy_def, rule, rule)
  2143   fix e::real assume "e>0" "(s ---> l) sequentially"
  2144   then obtain N::nat where N:"\<forall>n\<ge>N. dist (s n) l < e/2" unfolding LIMSEQ_def by(erule_tac x="e/2" in allE) auto
  2145   thus "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < e"  using dist_triangle_half_l[of _ l e _] by (rule_tac x=N in exI) auto
  2146 qed
  2147 
  2148 lemma cauchy_imp_bounded: assumes "Cauchy s" shows "bounded (range s)"
  2149 proof-
  2150   from assms obtain N::nat where "\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < 1" unfolding cauchy_def apply(erule_tac x= 1 in allE) by auto
  2151   hence N:"\<forall>n. N \<le> n \<longrightarrow> dist (s N) (s n) < 1" by auto
  2152   moreover
  2153   have "bounded (s ` {0..N})" using finite_imp_bounded[of "s ` {1..N}"] by auto
  2154   then obtain a where a:"\<forall>x\<in>s ` {0..N}. dist (s N) x \<le> a"
  2155     unfolding bounded_any_center [where a="s N"] by auto
  2156   ultimately show "?thesis"
  2157     unfolding bounded_any_center [where a="s N"]
  2158     apply(rule_tac x="max a 1" in exI) apply auto
  2159     apply(erule_tac x=y in allE) apply(erule_tac x=y in ballE) by auto
  2160 qed
  2161 
  2162 lemma compact_imp_complete: assumes "compact s" shows "complete s"
  2163 proof-
  2164   { fix f assume as: "(\<forall>n::nat. f n \<in> s)" "Cauchy f"
  2165     from as(1) obtain l r where lr: "l\<in>s" "subseq r" "((f \<circ> r) ---> l) sequentially" using assms unfolding compact_def by blast
  2166 
  2167     note lr' = subseq_bigger [OF lr(2)]
  2168 
  2169     { fix e::real assume "e>0"
  2170       from as(2) obtain N where N:"\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (f m) (f n) < e/2" unfolding cauchy_def using `e>0` apply (erule_tac x="e/2" in allE) by auto
  2171       from lr(3)[unfolded LIMSEQ_def, THEN spec[where x="e/2"]] obtain M where M:"\<forall>n\<ge>M. dist ((f \<circ> r) n) l < e/2" using `e>0` by auto
  2172       { fix n::nat assume n:"n \<ge> max N M"
  2173         have "dist ((f \<circ> r) n) l < e/2" using n M by auto
  2174         moreover have "r n \<ge> N" using lr'[of n] n by auto
  2175         hence "dist (f n) ((f \<circ> r) n) < e / 2" using N using n by auto
  2176         ultimately have "dist (f n) l < e" using dist_triangle_half_r[of "f (r n)" "f n" e l] by (auto simp add: dist_commute)  }
  2177       hence "\<exists>N. \<forall>n\<ge>N. dist (f n) l < e" by blast  }
  2178     hence "\<exists>l\<in>s. (f ---> l) sequentially" using `l\<in>s` unfolding LIMSEQ_def by auto  }
  2179   thus ?thesis unfolding complete_def by auto
  2180 qed
  2181 
  2182 instance heine_borel < complete_space
  2183 proof
  2184   fix f :: "nat \<Rightarrow> 'a" assume "Cauchy f"
  2185   hence "bounded (range f)"
  2186     by (rule cauchy_imp_bounded)
  2187   hence "compact (closure (range f))"
  2188     using bounded_closed_imp_compact [of "closure (range f)"] by auto
  2189   hence "complete (closure (range f))"
  2190     by (rule compact_imp_complete)
  2191   moreover have "\<forall>n. f n \<in> closure (range f)"
  2192     using closure_subset [of "range f"] by auto
  2193   ultimately have "\<exists>l\<in>closure (range f). (f ---> l) sequentially"
  2194     using `Cauchy f` unfolding complete_def by auto
  2195   then show "convergent f"
  2196     unfolding convergent_def by auto
  2197 qed
  2198 
  2199 instance euclidean_space \<subseteq> banach ..
  2200 
  2201 lemma complete_univ: "complete (UNIV :: 'a::complete_space set)"
  2202 proof(simp add: complete_def, rule, rule)
  2203   fix f :: "nat \<Rightarrow> 'a" assume "Cauchy f"
  2204   hence "convergent f" by (rule Cauchy_convergent)
  2205   thus "\<exists>l. f ----> l" unfolding convergent_def .  
  2206 qed
  2207 
  2208 lemma complete_imp_closed: assumes "complete s" shows "closed s"
  2209 proof -
  2210   { fix x assume "x islimpt s"
  2211     then obtain f where f: "\<forall>n. f n \<in> s - {x}" "(f ---> x) sequentially"
  2212       unfolding islimpt_sequential by auto
  2213     then obtain l where l: "l\<in>s" "(f ---> l) sequentially"
  2214       using `complete s`[unfolded complete_def] using convergent_imp_cauchy[of f x] by auto
  2215     hence "x \<in> s"  using tendsto_unique[of sequentially f l x] trivial_limit_sequentially f(2) by auto
  2216   }
  2217   thus "closed s" unfolding closed_limpt by auto
  2218 qed
  2219 
  2220 lemma complete_eq_closed:
  2221   fixes s :: "'a::complete_space set"
  2222   shows "complete s \<longleftrightarrow> closed s" (is "?lhs = ?rhs")
  2223 proof
  2224   assume ?lhs thus ?rhs by (rule complete_imp_closed)
  2225 next
  2226   assume ?rhs
  2227   { fix f assume as:"\<forall>n::nat. f n \<in> s" "Cauchy f"
  2228     then obtain l where "(f ---> l) sequentially" using complete_univ[unfolded complete_def, THEN spec[where x=f]] by auto
  2229     hence "\<exists>l\<in>s. (f ---> l) sequentially" using `?rhs`[unfolded closed_sequential_limits, THEN spec[where x=f], THEN spec[where x=l]] using as(1) by auto  }
  2230   thus ?lhs unfolding complete_def by auto
  2231 qed
  2232 
  2233 lemma convergent_eq_cauchy:
  2234   fixes s :: "nat \<Rightarrow> 'a::complete_space"
  2235   shows "(\<exists>l. (s ---> l) sequentially) \<longleftrightarrow> Cauchy s"
  2236   unfolding Cauchy_convergent_iff convergent_def ..
  2237 
  2238 lemma convergent_imp_bounded:
  2239   fixes s :: "nat \<Rightarrow> 'a::metric_space"
  2240   shows "(s ---> l) sequentially \<Longrightarrow> bounded (range s)"
  2241   by (intro cauchy_imp_bounded convergent_imp_cauchy)
  2242 
  2243 subsubsection{* Total boundedness *}
  2244 
  2245 fun helper_1::"('a::metric_space set) \<Rightarrow> real \<Rightarrow> nat \<Rightarrow> 'a" where
  2246   "helper_1 s e n = (SOME y::'a. y \<in> s \<and> (\<forall>m<n. \<not> (dist (helper_1 s e m) y < e)))"
  2247 declare helper_1.simps[simp del]
  2248 
  2249 lemma compact_imp_totally_bounded:
  2250   assumes "compact s"
  2251   shows "\<forall>e>0. \<exists>k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> (\<Union>((\<lambda>x. ball x e) ` k))"
  2252 proof(rule, rule, rule ccontr)
  2253   fix e::real assume "e>0" and assm:"\<not> (\<exists>k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> \<Union>(\<lambda>x. ball x e) ` k)"
  2254   def x \<equiv> "helper_1 s e"
  2255   { fix n
  2256     have "x n \<in> s \<and> (\<forall>m<n. \<not> dist (x m) (x n) < e)"
  2257     proof(induct_tac rule:nat_less_induct)
  2258       fix n  def Q \<equiv> "(\<lambda>y. y \<in> s \<and> (\<forall>m<n. \<not> dist (x m) y < e))"
  2259       assume as:"\<forall>m<n. x m \<in> s \<and> (\<forall>ma<m. \<not> dist (x ma) (x m) < e)"
  2260       have "\<not> s \<subseteq> (\<Union>x\<in>x ` {0..<n}. ball x e)" using assm apply simp apply(erule_tac x="x ` {0 ..< n}" in allE) using as by auto
  2261       then obtain z where z:"z\<in>s" "z \<notin> (\<Union>x\<in>x ` {0..<n}. ball x e)" unfolding subset_eq by auto
  2262       have "Q (x n)" unfolding x_def and helper_1.simps[of s e n]
  2263         apply(rule someI2[where a=z]) unfolding x_def[symmetric] and Q_def using z by auto
  2264       thus "x n \<in> s \<and> (\<forall>m<n. \<not> dist (x m) (x n) < e)" unfolding Q_def by auto
  2265     qed }
  2266   hence "\<forall>n::nat. x n \<in> s" and x:"\<forall>n. \<forall>m < n. \<not> (dist (x m) (x n) < e)" by blast+
  2267   then obtain l r where "l\<in>s" and r:"subseq r" and "((x \<circ> r) ---> l) sequentially" using assms(1)[unfolded compact_def, THEN spec[where x=x]] by auto
  2268   from this(3) have "Cauchy (x \<circ> r)" using convergent_imp_cauchy by auto
  2269   then obtain N::nat where N:"\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist ((x \<circ> r) m) ((x \<circ> r) n) < e" unfolding cauchy_def using `e>0` by auto
  2270   show False
  2271     using N[THEN spec[where x=N], THEN spec[where x="N+1"]]
  2272     using r[unfolded subseq_def, THEN spec[where x=N], THEN spec[where x="N+1"]]
  2273     using x[THEN spec[where x="r (N+1)"], THEN spec[where x="r (N)"]] by auto
  2274 qed
  2275 
  2276 subsubsection{* Heine-Borel theorem *}
  2277 
  2278 text {* Following Burkill \& Burkill vol. 2. *}
  2279 
  2280 lemma heine_borel_lemma: fixes s::"'a::metric_space set"
  2281   assumes "compact s"  "s \<subseteq> (\<Union> t)"  "\<forall>b \<in> t. open b"
  2282   shows "\<exists>e>0. \<forall>x \<in> s. \<exists>b \<in> t. ball x e \<subseteq> b"
  2283 proof(rule ccontr)
  2284   assume "\<not> (\<exists>e>0. \<forall>x\<in>s. \<exists>b\<in>t. ball x e \<subseteq> b)"
  2285   hence cont:"\<forall>e>0. \<exists>x\<in>s. \<forall>xa\<in>t. \<not> (ball x e \<subseteq> xa)" by auto
  2286   { fix n::nat
  2287     have "1 / real (n + 1) > 0" by auto
  2288     hence "\<exists>x. x\<in>s \<and> (\<forall>xa\<in>t. \<not> (ball x (inverse (real (n+1))) \<subseteq> xa))" using cont unfolding Bex_def by auto }
  2289   hence "\<forall>n::nat. \<exists>x. x \<in> s \<and> (\<forall>xa\<in>t. \<not> ball x (inverse (real (n + 1))) \<subseteq> xa)" by auto
  2290   then obtain f where f:"\<forall>n::nat. f n \<in> s \<and> (\<forall>xa\<in>t. \<not> ball (f n) (inverse (real (n + 1))) \<subseteq> xa)"
  2291     using choice[of "\<lambda>n::nat. \<lambda>x. x\<in>s \<and> (\<forall>xa\<in>t. \<not> ball x (inverse (real (n + 1))) \<subseteq> xa)"] by auto
  2292 
  2293   then obtain l r where l:"l\<in>s" and r:"subseq r" and lr:"((f \<circ> r) ---> l) sequentially"
  2294     using assms(1)[unfolded compact_def, THEN spec[where x=f]] by auto
  2295 
  2296   obtain b where "l\<in>b" "b\<in>t" using assms(2) and l by auto
  2297   then obtain e where "e>0" and e:"\<forall>z. dist z l < e \<longrightarrow> z\<in>b"
  2298     using assms(3)[THEN bspec[where x=b]] unfolding open_dist by auto
  2299 
  2300   then obtain N1 where N1:"\<forall>n\<ge>N1. dist ((f \<circ> r) n) l < e / 2"
  2301     using lr[unfolded LIMSEQ_def, THEN spec[where x="e/2"]] by auto
  2302 
  2303   obtain N2::nat where N2:"N2>0" "inverse (real N2) < e /2" using real_arch_inv[of "e/2"] and `e>0` by auto
  2304   have N2':"inverse (real (r (N1 + N2) +1 )) < e/2"
  2305     apply(rule order_less_trans) apply(rule less_imp_inverse_less) using N2
  2306     using subseq_bigger[OF r, of "N1 + N2"] by auto
  2307 
  2308   def x \<equiv> "(f (r (N1 + N2)))"
  2309   have x:"\<not> ball x (inverse (real (r (N1 + N2) + 1))) \<subseteq> b" unfolding x_def
  2310     using f[THEN spec[where x="r (N1 + N2)"]] using `b\<in>t` by auto
  2311   have "\<exists>y\<in>ball x (inverse (real (r (N1 + N2) + 1))). y\<notin>b" apply(rule ccontr) using x by auto
  2312   then obtain y where y:"y \<in> ball x (inverse (real (r (N1 + N2) + 1)))" "y \<notin> b" by auto
  2313 
  2314   have "dist x l < e/2" using N1 unfolding x_def o_def by auto
  2315   hence "dist y l < e" using y N2' using dist_triangle[of y l x]by (auto simp add:dist_commute)
  2316 
  2317   thus False using e and `y\<notin>b` by auto
  2318 qed
  2319 
  2320 lemma compact_imp_heine_borel: "compact s ==> (\<forall>f. (\<forall>t \<in> f. open t) \<and> s \<subseteq> (\<Union> f)
  2321                \<longrightarrow> (\<exists>f'. f' \<subseteq> f \<and> finite f' \<and> s \<subseteq> (\<Union> f')))"
  2322 proof clarify
  2323   fix f assume "compact s" " \<forall>t\<in>f. open t" "s \<subseteq> \<Union>f"
  2324   then obtain e::real where "e>0" and "\<forall>x\<in>s. \<exists>b\<in>f. ball x e \<subseteq> b" using heine_borel_lemma[of s f] by auto
  2325   hence "\<forall>x\<in>s. \<exists>b. b\<in>f \<and> ball x e \<subseteq> b" by auto
  2326   hence "\<exists>bb. \<forall>x\<in>s. bb x \<in>f \<and> ball x e \<subseteq> bb x" using bchoice[of s "\<lambda>x b. b\<in>f \<and> ball x e \<subseteq> b"] by auto
  2327   then obtain  bb where bb:"\<forall>x\<in>s. (bb x) \<in> f \<and> ball x e \<subseteq> (bb x)" by blast
  2328 
  2329   from `compact s` have  "\<exists> k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> \<Union>(\<lambda>x. ball x e) ` k" using compact_imp_totally_bounded[of s] `e>0` by auto
  2330   then obtain k where k:"finite k" "k \<subseteq> s" "s \<subseteq> \<Union>(\<lambda>x. ball x e) ` k" by auto
  2331 
  2332   have "finite (bb ` k)" using k(1) by auto
  2333   moreover
  2334   { fix x assume "x\<in>s"
  2335     hence "x\<in>\<Union>(\<lambda>x. ball x e) ` k" using k(3)  unfolding subset_eq by auto
  2336     hence "\<exists>X\<in>bb ` k. x \<in> X" using bb k(2) by blast
  2337     hence "x \<in> \<Union>(bb ` k)" using  Union_iff[of x "bb ` k"] by auto
  2338   }
  2339   ultimately show "\<exists>f'\<subseteq>f. finite f' \<and> s \<subseteq> \<Union>f'" using bb k(2) by (rule_tac x="bb ` k" in exI) auto
  2340 qed
  2341 
  2342 subsubsection {* Bolzano-Weierstrass property *}
  2343 
  2344 lemma heine_borel_imp_bolzano_weierstrass:
  2345   assumes "\<forall>f. (\<forall>t \<in> f. open t) \<and> s \<subseteq> (\<Union> f) --> (\<exists>f'. f' \<subseteq> f \<and> finite f' \<and> s \<subseteq> (\<Union> f'))"
  2346           "infinite t"  "t \<subseteq> s"
  2347   shows "\<exists>x \<in> s. x islimpt t"
  2348 proof(rule ccontr)
  2349   assume "\<not> (\<exists>x \<in> s. x islimpt t)"
  2350   then obtain f where f:"\<forall>x\<in>s. x \<in> f x \<and> open (f x) \<and> (\<forall>y\<in>t. y \<in> f x \<longrightarrow> y = x)" unfolding islimpt_def
  2351     using bchoice[of s "\<lambda> x T. x \<in> T \<and> open T \<and> (\<forall>y\<in>t. y \<in> T \<longrightarrow> y = x)"] by auto
  2352   obtain g where g:"g\<subseteq>{t. \<exists>x. x \<in> s \<and> t = f x}" "finite g" "s \<subseteq> \<Union>g"
  2353     using assms(1)[THEN spec[where x="{t. \<exists>x. x\<in>s \<and> t = f x}"]] using f by auto
  2354   from g(1,3) have g':"\<forall>x\<in>g. \<exists>xa \<in> s. x = f xa" by auto
  2355   { fix x y assume "x\<in>t" "y\<in>t" "f x = f y"
  2356     hence "x \<in> f x"  "y \<in> f x \<longrightarrow> y = x" using f[THEN bspec[where x=x]] and `t\<subseteq>s` by auto
  2357     hence "x = y" using `f x = f y` and f[THEN bspec[where x=y]] and `y\<in>t` and `t\<subseteq>s` by auto  }
  2358   hence "inj_on f t" unfolding inj_on_def by simp
  2359   hence "infinite (f ` t)" using assms(2) using finite_imageD by auto
  2360   moreover
  2361   { fix x assume "x\<in>t" "f x \<notin> g"
  2362     from g(3) assms(3) `x\<in>t` obtain h where "h\<in>g" and "x\<in>h" by auto
  2363     then obtain y where "y\<in>s" "h = f y" using g'[THEN bspec[where x=h]] by auto
  2364     hence "y = x" using f[THEN bspec[where x=y]] and `x\<in>t` and `x\<in>h`[unfolded `h = f y`] by auto
  2365     hence False using `f x \<notin> g` `h\<in>g` unfolding `h = f y` by auto  }
  2366   hence "f ` t \<subseteq> g" by auto
  2367   ultimately show False using g(2) using finite_subset by auto
  2368 qed
  2369 
  2370 subsubsection {* Complete the chain of compactness variants *}
  2371 
  2372 lemma islimpt_range_imp_convergent_subsequence:
  2373   fixes f :: "nat \<Rightarrow> 'a::metric_space"
  2374   assumes "l islimpt (range f)"
  2375   shows "\<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2376 proof (intro exI conjI)
  2377   have *: "\<And>e. 0 < e \<Longrightarrow> \<exists>n. 0 < dist (f n) l \<and> dist (f n) l < e"
  2378     using assms unfolding islimpt_def
  2379     by (drule_tac x="ball l e" in spec)
  2380        (auto simp add: zero_less_dist_iff dist_commute)
  2381 
  2382   def t \<equiv> "\<lambda>e. LEAST n. 0 < dist (f n) l \<and> dist (f n) l < e"
  2383   have f_t_neq: "\<And>e. 0 < e \<Longrightarrow> 0 < dist (f (t e)) l"
  2384     unfolding t_def by (rule LeastI2_ex [OF * conjunct1])
  2385   have f_t_closer: "\<And>e. 0 < e \<Longrightarrow> dist (f (t e)) l < e"
  2386     unfolding t_def by (rule LeastI2_ex [OF * conjunct2])
  2387   have t_le: "\<And>n e. 0 < dist (f n) l \<Longrightarrow> dist (f n) l < e \<Longrightarrow> t e \<le> n"
  2388     unfolding t_def by (simp add: Least_le)
  2389   have less_tD: "\<And>n e. n < t e \<Longrightarrow> 0 < dist (f n) l \<Longrightarrow> e \<le> dist (f n) l"
  2390     unfolding t_def by (drule not_less_Least) simp
  2391   have t_antimono: "\<And>e e'. 0 < e \<Longrightarrow> e \<le> e' \<Longrightarrow> t e' \<le> t e"
  2392     apply (rule t_le)
  2393     apply (erule f_t_neq)
  2394     apply (erule (1) less_le_trans [OF f_t_closer])
  2395     done
  2396   have t_dist_f_neq: "\<And>n. 0 < dist (f n) l \<Longrightarrow> t (dist (f n) l) \<noteq> n"
  2397     by (drule f_t_closer) auto
  2398   have t_less: "\<And>e. 0 < e \<Longrightarrow> t e < t (dist (f (t e)) l)"
  2399     apply (subst less_le)
  2400     apply (rule conjI)
  2401     apply (rule t_antimono)
  2402     apply (erule f_t_neq)
  2403     apply (erule f_t_closer [THEN less_imp_le])
  2404     apply (rule t_dist_f_neq [symmetric])
  2405     apply (erule f_t_neq)
  2406     done
  2407   have dist_f_t_less':
  2408     "\<And>e e'. 0 < e \<Longrightarrow> 0 < e' \<Longrightarrow> t e \<le> t e' \<Longrightarrow> dist (f (t e')) l < e"
  2409     apply (simp add: le_less)
  2410     apply (erule disjE)
  2411     apply (rule less_trans)
  2412     apply (erule f_t_closer)
  2413     apply (rule le_less_trans)
  2414     apply (erule less_tD)
  2415     apply (erule f_t_neq)
  2416     apply (erule f_t_closer)
  2417     apply (erule subst)
  2418     apply (erule f_t_closer)
  2419     done
  2420 
  2421   def r \<equiv> "nat_rec (t 1) (\<lambda>_ x. t (dist (f x) l))"
  2422   have r_simps: "r 0 = t 1" "\<And>n. r (Suc n) = t (dist (f (r n)) l)"
  2423     unfolding r_def by simp_all
  2424   have f_r_neq: "\<And>n. 0 < dist (f (r n)) l"
  2425     by (induct_tac n) (simp_all add: r_simps f_t_neq)
  2426 
  2427   show "subseq r"
  2428     unfolding subseq_Suc_iff
  2429     apply (rule allI)
  2430     apply (case_tac n)
  2431     apply (simp_all add: r_simps)
  2432     apply (rule t_less, rule zero_less_one)
  2433     apply (rule t_less, rule f_r_neq)
  2434     done
  2435   show "((f \<circ> r) ---> l) sequentially"
  2436     unfolding LIMSEQ_def o_def
  2437     apply (clarify, rename_tac e, rule_tac x="t e" in exI, clarify)
  2438     apply (drule le_trans, rule seq_suble [OF `subseq r`])
  2439     apply (case_tac n, simp_all add: r_simps dist_f_t_less' f_r_neq)
  2440     done
  2441 qed
  2442 
  2443 lemma finite_range_imp_infinite_repeats:
  2444   fixes f :: "nat \<Rightarrow> 'a"
  2445   assumes "finite (range f)"
  2446   shows "\<exists>k. infinite {n. f n = k}"
  2447 proof -
  2448   { fix A :: "'a set" assume "finite A"
  2449     hence "\<And>f. infinite {n. f n \<in> A} \<Longrightarrow> \<exists>k. infinite {n. f n = k}"
  2450     proof (induct)
  2451       case empty thus ?case by simp
  2452     next
  2453       case (insert x A)
  2454      show ?case
  2455       proof (cases "finite {n. f n = x}")
  2456         case True
  2457         with `infinite {n. f n \<in> insert x A}`
  2458         have "infinite {n. f n \<in> A}" by simp
  2459         thus "\<exists>k. infinite {n. f n = k}" by (rule insert)
  2460       next
  2461         case False thus "\<exists>k. infinite {n. f n = k}" ..
  2462       qed
  2463     qed
  2464   } note H = this
  2465   from assms show "\<exists>k. infinite {n. f n = k}"
  2466     by (rule H) simp
  2467 qed
  2468 
  2469 lemma bolzano_weierstrass_imp_compact:
  2470   fixes s :: "'a::metric_space set"
  2471   assumes "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t)"
  2472   shows "compact s"
  2473 proof -
  2474   { fix f :: "nat \<Rightarrow> 'a" assume f: "\<forall>n. f n \<in> s"
  2475     have "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2476     proof (cases "finite (range f)")
  2477       case True
  2478       hence "\<exists>l. infinite {n. f n = l}"
  2479         by (rule finite_range_imp_infinite_repeats)
  2480       then obtain l where "infinite {n. f n = l}" ..
  2481       hence "\<exists>r. subseq r \<and> (\<forall>n. r n \<in> {n. f n = l})"
  2482         by (rule infinite_enumerate)
  2483       then obtain r where "subseq r" and fr: "\<forall>n. f (r n) = l" by auto
  2484       hence "subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2485         unfolding o_def by (simp add: fr tendsto_const)
  2486       hence "\<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2487         by - (rule exI)
  2488       from f have "\<forall>n. f (r n) \<in> s" by simp
  2489       hence "l \<in> s" by (simp add: fr)
  2490       thus "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2491         by (rule rev_bexI) fact
  2492     next
  2493       case False
  2494       with f assms have "\<exists>x\<in>s. x islimpt (range f)" by auto
  2495       then obtain l where "l \<in> s" "l islimpt (range f)" ..
  2496       have "\<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2497         using `l islimpt (range f)`
  2498         by (rule islimpt_range_imp_convergent_subsequence)
  2499       with `l \<in> s` show "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially" ..
  2500     qed
  2501   }
  2502   thus ?thesis unfolding compact_def by auto
  2503 qed
  2504 
  2505 primrec helper_2::"(real \<Rightarrow> 'a::metric_space) \<Rightarrow> nat \<Rightarrow> 'a" where
  2506   "helper_2 beyond 0 = beyond 0" |
  2507   "helper_2 beyond (Suc n) = beyond (dist undefined (helper_2 beyond n) + 1 )"
  2508 
  2509 lemma bolzano_weierstrass_imp_bounded: fixes s::"'a::metric_space set"
  2510   assumes "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t)"
  2511   shows "bounded s"
  2512 proof(rule ccontr)
  2513   assume "\<not> bounded s"
  2514   then obtain beyond where "\<forall>a. beyond a \<in>s \<and> \<not> dist undefined (beyond a) \<le> a"
  2515     unfolding bounded_any_center [where a=undefined]
  2516     apply simp using choice[of "\<lambda>a x. x\<in>s \<and> \<not> dist undefined x \<le> a"] by auto
  2517   hence beyond:"\<And>a. beyond a \<in>s" "\<And>a. dist undefined (beyond a) > a"
  2518     unfolding linorder_not_le by auto
  2519   def x \<equiv> "helper_2 beyond"
  2520 
  2521   { fix m n ::nat assume "m<n"
  2522     hence "dist undefined (x m) + 1 < dist undefined (x n)"
  2523     proof(induct n)
  2524       case 0 thus ?case by auto
  2525     next
  2526       case (Suc n)
  2527       have *:"dist undefined (x n) + 1 < dist undefined (x (Suc n))"
  2528         unfolding x_def and helper_2.simps
  2529         using beyond(2)[of "dist undefined (helper_2 beyond n) + 1"] by auto
  2530       thus ?case proof(cases "m < n")
  2531         case True thus ?thesis using Suc and * by auto
  2532       next
  2533         case False hence "m = n" using Suc(2) by auto
  2534         thus ?thesis using * by auto
  2535       qed
  2536     qed  } note * = this
  2537   { fix m n ::nat assume "m\<noteq>n"
  2538     have "1 < dist (x m) (x n)"
  2539     proof(cases "m<n")
  2540       case True
  2541       hence "1 < dist undefined (x n) - dist undefined (x m)" using *[of m n] by auto
  2542       thus ?thesis using dist_triangle [of undefined "x n" "x m"] by arith
  2543     next
  2544       case False hence "n<m" using `m\<noteq>n` by auto
  2545       hence "1 < dist undefined (x m) - dist undefined (x n)" using *[of n m] by auto
  2546       thus ?thesis using dist_triangle2 [of undefined "x m" "x n"] by arith
  2547     qed  } note ** = this
  2548   { fix a b assume "x a = x b" "a \<noteq> b"
  2549     hence False using **[of a b] by auto  }
  2550   hence "inj x" unfolding inj_on_def by auto
  2551   moreover
  2552   { fix n::nat
  2553     have "x n \<in> s"
  2554     proof(cases "n = 0")
  2555       case True thus ?thesis unfolding x_def using beyond by auto
  2556     next
  2557       case False then obtain z where "n = Suc z" using not0_implies_Suc by auto
  2558       thus ?thesis unfolding x_def using beyond by auto
  2559     qed  }
  2560   ultimately have "infinite (range x) \<and> range x \<subseteq> s" unfolding x_def using range_inj_infinite[of "helper_2 beyond"] using beyond(1) by auto
  2561 
  2562   then obtain l where "l\<in>s" and l:"l islimpt range x" using assms[THEN spec[where x="range x"]] by auto
  2563   then obtain y where "x y \<noteq> l" and y:"dist (x y) l < 1/2" unfolding islimpt_approachable apply(erule_tac x="1/2" in allE) by auto
  2564   then obtain z where "x z \<noteq> l" and z:"dist (x z) l < dist (x y) l" using l[unfolded islimpt_approachable, THEN spec[where x="dist (x y) l"]]
  2565     unfolding dist_nz by auto
  2566   show False using y and z and dist_triangle_half_l[of "x y" l 1 "x z"] and **[of y z] by auto
  2567 qed
  2568 
  2569 lemma sequence_infinite_lemma:
  2570   fixes f :: "nat \<Rightarrow> 'a::t1_space"
  2571   assumes "\<forall>n. f n \<noteq> l" and "(f ---> l) sequentially"
  2572   shows "infinite (range f)"
  2573 proof
  2574   assume "finite (range f)"
  2575   hence "closed (range f)" by (rule finite_imp_closed)
  2576   hence "open (- range f)" by (rule open_Compl)
  2577   from assms(1) have "l \<in> - range f" by auto
  2578   from assms(2) have "eventually (\<lambda>n. f n \<in> - range f) sequentially"
  2579     using `open (- range f)` `l \<in> - range f` by (rule topological_tendstoD)
  2580   thus False unfolding eventually_sequentially by auto
  2581 qed
  2582 
  2583 lemma closure_insert:
  2584   fixes x :: "'a::t1_space"
  2585   shows "closure (insert x s) = insert x (closure s)"
  2586 apply (rule closure_unique)
  2587 apply (rule insert_mono [OF closure_subset])
  2588 apply (rule closed_insert [OF closed_closure])
  2589 apply (simp add: closure_minimal)
  2590 done
  2591 
  2592 lemma islimpt_insert:
  2593   fixes x :: "'a::t1_space"
  2594   shows "x islimpt (insert a s) \<longleftrightarrow> x islimpt s"
  2595 proof
  2596   assume *: "x islimpt (insert a s)"
  2597   show "x islimpt s"
  2598   proof (rule islimptI)
  2599     fix t assume t: "x \<in> t" "open t"
  2600     show "\<exists>y\<in>s. y \<in> t \<and> y \<noteq> x"
  2601     proof (cases "x = a")
  2602       case True
  2603       obtain y where "y \<in> insert a s" "y \<in> t" "y \<noteq> x"
  2604         using * t by (rule islimptE)
  2605       with `x = a` show ?thesis by auto
  2606     next
  2607       case False
  2608       with t have t': "x \<in> t - {a}" "open (t - {a})"
  2609         by (simp_all add: open_Diff)
  2610       obtain y where "y \<in> insert a s" "y \<in> t - {a}" "y \<noteq> x"
  2611         using * t' by (rule islimptE)
  2612       thus ?thesis by auto
  2613     qed
  2614   qed
  2615 next
  2616   assume "x islimpt s" thus "x islimpt (insert a s)"
  2617     by (rule islimpt_subset) auto
  2618 qed
  2619 
  2620 lemma islimpt_union_finite:
  2621   fixes x :: "'a::t1_space"
  2622   shows "finite s \<Longrightarrow> x islimpt (s \<union> t) \<longleftrightarrow> x islimpt t"
  2623 by (induct set: finite, simp_all add: islimpt_insert)
  2624  
  2625 lemma sequence_unique_limpt:
  2626   fixes f :: "nat \<Rightarrow> 'a::t2_space"
  2627   assumes "(f ---> l) sequentially" and "l' islimpt (range f)"
  2628   shows "l' = l"
  2629 proof (rule ccontr)
  2630   assume "l' \<noteq> l"
  2631   obtain s t where "open s" "open t" "l' \<in> s" "l \<in> t" "s \<inter> t = {}"
  2632     using hausdorff [OF `l' \<noteq> l`] by auto
  2633   have "eventually (\<lambda>n. f n \<in> t) sequentially"
  2634     using assms(1) `open t` `l \<in> t` by (rule topological_tendstoD)
  2635   then obtain N where "\<forall>n\<ge>N. f n \<in> t"
  2636     unfolding eventually_sequentially by auto
  2637 
  2638   have "UNIV = {..<N} \<union> {N..}" by auto
  2639   hence "l' islimpt (f ` ({..<N} \<union> {N..}))" using assms(2) by simp
  2640   hence "l' islimpt (f ` {..<N} \<union> f ` {N..})" by (simp add: image_Un)
  2641   hence "l' islimpt (f ` {N..})" by (simp add: islimpt_union_finite)
  2642   then obtain y where "y \<in> f ` {N..}" "y \<in> s" "y \<noteq> l'"
  2643     using `l' \<in> s` `open s` by (rule islimptE)
  2644   then obtain n where "N \<le> n" "f n \<in> s" "f n \<noteq> l'" by auto
  2645   with `\<forall>n\<ge>N. f n \<in> t` have "f n \<in> s \<inter> t" by simp
  2646   with `s \<inter> t = {}` show False by simp
  2647 qed
  2648 
  2649 lemma bolzano_weierstrass_imp_closed:
  2650   fixes s :: "'a::metric_space set" (* TODO: can this be generalized? *)
  2651   assumes "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t)"
  2652   shows "closed s"
  2653 proof-
  2654   { fix x l assume as: "\<forall>n::nat. x n \<in> s" "(x ---> l) sequentially"
  2655     hence "l \<in> s"
  2656     proof(cases "\<forall>n. x n \<noteq> l")
  2657       case False thus "l\<in>s" using as(1) by auto
  2658     next
  2659       case True note cas = this
  2660       with as(2) have "infinite (range x)" using sequence_infinite_lemma[of x l] by auto
  2661       then obtain l' where "l'\<in>s" "l' islimpt (range x)" using assms[THEN spec[where x="range x"]] as(1) by auto
  2662       thus "l\<in>s" using sequence_unique_limpt[of x l l'] using as cas by auto
  2663     qed  }
  2664   thus ?thesis unfolding closed_sequential_limits by fast
  2665 qed
  2666 
  2667 text {* Hence express everything as an equivalence. *}
  2668 
  2669 lemma compact_eq_heine_borel:
  2670   fixes s :: "'a::metric_space set"
  2671   shows "compact s \<longleftrightarrow>
  2672            (\<forall>f. (\<forall>t \<in> f. open t) \<and> s \<subseteq> (\<Union> f)
  2673                --> (\<exists>f'. f' \<subseteq> f \<and> finite f' \<and> s \<subseteq> (\<Union> f')))" (is "?lhs = ?rhs")
  2674 proof
  2675   assume ?lhs thus ?rhs by (rule compact_imp_heine_borel)
  2676 next
  2677   assume ?rhs
  2678   hence "\<forall>t. infinite t \<and> t \<subseteq> s \<longrightarrow> (\<exists>x\<in>s. x islimpt t)"
  2679     by (blast intro: heine_borel_imp_bolzano_weierstrass[of s])
  2680   thus ?lhs by (rule bolzano_weierstrass_imp_compact)
  2681 qed
  2682 
  2683 lemma compact_eq_bolzano_weierstrass:
  2684   fixes s :: "'a::metric_space set"
  2685   shows "compact s \<longleftrightarrow> (\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t))" (is "?lhs = ?rhs")
  2686 proof
  2687   assume ?lhs thus ?rhs unfolding compact_eq_heine_borel using heine_borel_imp_bolzano_weierstrass[of s] by auto
  2688 next
  2689   assume ?rhs thus ?lhs by (rule bolzano_weierstrass_imp_compact)
  2690 qed
  2691 
  2692 lemma compact_eq_bounded_closed:
  2693   fixes s :: "'a::heine_borel set"
  2694   shows "compact s \<longleftrightarrow> bounded s \<and> closed s"  (is "?lhs = ?rhs")
  2695 proof
  2696   assume ?lhs thus ?rhs unfolding compact_eq_bolzano_weierstrass using bolzano_weierstrass_imp_bounded bolzano_weierstrass_imp_closed by auto
  2697 next
  2698   assume ?rhs thus ?lhs using bounded_closed_imp_compact by auto
  2699 qed
  2700 
  2701 lemma compact_imp_bounded:
  2702   fixes s :: "'a::metric_space set"
  2703   shows "compact s ==> bounded s"
  2704 proof -
  2705   assume "compact s"
  2706   hence "\<forall>f. (\<forall>t\<in>f. open t) \<and> s \<subseteq> \<Union>f \<longrightarrow> (\<exists>f'\<subseteq>f. finite f' \<and> s \<subseteq> \<Union>f')"
  2707     by (rule compact_imp_heine_borel)
  2708   hence "\<forall>t. infinite t \<and> t \<subseteq> s \<longrightarrow> (\<exists>x \<in> s. x islimpt t)"
  2709     using heine_borel_imp_bolzano_weierstrass[of s] by auto
  2710   thus "bounded s"
  2711     by (rule bolzano_weierstrass_imp_bounded)
  2712 qed
  2713 
  2714 lemma compact_imp_closed:
  2715   fixes s :: "'a::metric_space set"
  2716   shows "compact s ==> closed s"
  2717 proof -
  2718   assume "compact s"
  2719   hence "\<forall>f. (\<forall>t\<in>f. open t) \<and> s \<subseteq> \<Union>f \<longrightarrow> (\<exists>f'\<subseteq>f. finite f' \<and> s \<subseteq> \<Union>f')"
  2720     by (rule compact_imp_heine_borel)
  2721   hence "\<forall>t. infinite t \<and> t \<subseteq> s \<longrightarrow> (\<exists>x \<in> s. x islimpt t)"
  2722     using heine_borel_imp_bolzano_weierstrass[of s] by auto
  2723   thus "closed s"
  2724     by (rule bolzano_weierstrass_imp_closed)
  2725 qed
  2726 
  2727 text{* In particular, some common special cases. *}
  2728 
  2729 lemma compact_empty[simp]:
  2730  "compact {}"
  2731   unfolding compact_def
  2732   by simp
  2733 
  2734 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  2735   unfolding subseq_def by simp (* TODO: move somewhere else *)
  2736 
  2737 lemma compact_union [intro]:
  2738   assumes "compact s" and "compact t"
  2739   shows "compact (s \<union> t)"
  2740 proof (rule compactI)
  2741   fix f :: "nat \<Rightarrow> 'a"
  2742   assume "\<forall>n. f n \<in> s \<union> t"
  2743   hence "infinite {n. f n \<in> s \<union> t}" by simp
  2744   hence "infinite {n. f n \<in> s} \<or> infinite {n. f n \<in> t}" by simp
  2745   thus "\<exists>l\<in>s \<union> t. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2746   proof
  2747     assume "infinite {n. f n \<in> s}"
  2748     from infinite_enumerate [OF this]
  2749     obtain q where "subseq q" "\<forall>n. (f \<circ> q) n \<in> s" by auto
  2750     obtain r l where "l \<in> s" "subseq r" "((f \<circ> q \<circ> r) ---> l) sequentially"
  2751       using `compact s` `\<forall>n. (f \<circ> q) n \<in> s` by (rule compactE)
  2752     hence "l \<in> s \<union> t" "subseq (q \<circ> r)" "((f \<circ> (q \<circ> r)) ---> l) sequentially"
  2753       using `subseq q` by (simp_all add: subseq_o o_assoc)
  2754     thus ?thesis by auto
  2755   next
  2756     assume "infinite {n. f n \<in> t}"
  2757     from infinite_enumerate [OF this]
  2758     obtain q where "subseq q" "\<forall>n. (f \<circ> q) n \<in> t" by auto
  2759     obtain r l where "l \<in> t" "subseq r" "((f \<circ> q \<circ> r) ---> l) sequentially"
  2760       using `compact t` `\<forall>n. (f \<circ> q) n \<in> t` by (rule compactE)
  2761     hence "l \<in> s \<union> t" "subseq (q \<circ> r)" "((f \<circ> (q \<circ> r)) ---> l) sequentially"
  2762       using `subseq q` by (simp_all add: subseq_o o_assoc)
  2763     thus ?thesis by auto
  2764   qed
  2765 qed
  2766 
  2767 lemma compact_inter_closed [intro]:
  2768   assumes "compact s" and "closed t"
  2769   shows "compact (s \<inter> t)"
  2770 proof (rule compactI)
  2771   fix f :: "nat \<Rightarrow> 'a"
  2772   assume "\<forall>n. f n \<in> s \<inter> t"
  2773   hence "\<forall>n. f n \<in> s" and "\<forall>n. f n \<in> t" by simp_all
  2774   obtain l r where "l \<in> s" "subseq r" "((f \<circ> r) ---> l) sequentially"
  2775     using `compact s` `\<forall>n. f n \<in> s` by (rule compactE)
  2776   moreover
  2777   from `closed t` `\<forall>n. f n \<in> t` `((f \<circ> r) ---> l) sequentially` have "l \<in> t"
  2778     unfolding closed_sequential_limits o_def by fast
  2779   ultimately show "\<exists>l\<in>s \<inter> t. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2780     by auto
  2781 qed
  2782 
  2783 lemma closed_inter_compact [intro]:
  2784   assumes "closed s" and "compact t"
  2785   shows "compact (s \<inter> t)"
  2786   using compact_inter_closed [of t s] assms
  2787   by (simp add: Int_commute)
  2788 
  2789 lemma compact_inter [intro]:
  2790   assumes "compact s" and "compact t"
  2791   shows "compact (s \<inter> t)"
  2792   using assms by (intro compact_inter_closed compact_imp_closed)
  2793 
  2794 lemma compact_sing [simp]: "compact {a}"
  2795   unfolding compact_def o_def subseq_def
  2796   by (auto simp add: tendsto_const)
  2797 
  2798 lemma compact_insert [simp]:
  2799   assumes "compact s" shows "compact (insert x s)"
  2800 proof -
  2801   have "compact ({x} \<union> s)"
  2802     using compact_sing assms by (rule compact_union)
  2803   thus ?thesis by simp
  2804 qed
  2805 
  2806 lemma finite_imp_compact:
  2807   shows "finite s \<Longrightarrow> compact s"
  2808   by (induct set: finite) simp_all
  2809 
  2810 lemma compact_cball[simp]:
  2811   fixes x :: "'a::heine_borel"
  2812   shows "compact(cball x e)"
  2813   using compact_eq_bounded_closed bounded_cball closed_cball
  2814   by blast
  2815 
  2816 lemma compact_frontier_bounded[intro]:
  2817   fixes s :: "'a::heine_borel set"
  2818   shows "bounded s ==> compact(frontier s)"
  2819   unfolding frontier_def
  2820   using compact_eq_bounded_closed
  2821   by blast
  2822 
  2823 lemma compact_frontier[intro]:
  2824   fixes s :: "'a::heine_borel set"
  2825   shows "compact s ==> compact (frontier s)"
  2826   using compact_eq_bounded_closed compact_frontier_bounded
  2827   by blast
  2828 
  2829 lemma frontier_subset_compact:
  2830   fixes s :: "'a::heine_borel set"
  2831   shows "compact s ==> frontier s \<subseteq> s"
  2832   using frontier_subset_closed compact_eq_bounded_closed
  2833   by blast
  2834 
  2835 lemma open_delete:
  2836   fixes s :: "'a::t1_space set"
  2837   shows "open s \<Longrightarrow> open (s - {x})"
  2838   by (simp add: open_Diff)
  2839 
  2840 text{* Finite intersection property. I could make it an equivalence in fact. *}
  2841 
  2842 lemma compact_imp_fip:
  2843   assumes "compact s"  "\<forall>t \<in> f. closed t"
  2844         "\<forall>f'. finite f' \<and> f' \<subseteq> f --> (s \<inter> (\<Inter> f') \<noteq> {})"
  2845   shows "s \<inter> (\<Inter> f) \<noteq> {}"
  2846 proof
  2847   assume as:"s \<inter> (\<Inter> f) = {}"
  2848   hence "s \<subseteq> \<Union> uminus ` f" by auto
  2849   moreover have "Ball (uminus ` f) open" using open_Diff closed_Diff using assms(2) by auto
  2850   ultimately obtain f' where f':"f' \<subseteq> uminus ` f"  "finite f'"  "s \<subseteq> \<Union>f'" using assms(1)[unfolded compact_eq_heine_borel, THEN spec[where x="(\<lambda>t. - t) ` f"]] by auto
  2851   hence "finite (uminus ` f') \<and> uminus ` f' \<subseteq> f" by(auto simp add: Diff_Diff_Int)
  2852   hence "s \<inter> \<Inter>uminus ` f' \<noteq> {}" using assms(3)[THEN spec[where x="uminus ` f'"]] by auto
  2853   thus False using f'(3) unfolding subset_eq and Union_iff by blast
  2854 qed
  2855 
  2856 
  2857 subsection {* Bounded closed nest property (proof does not use Heine-Borel) *}
  2858 
  2859 lemma bounded_closed_nest:
  2860   assumes "\<forall>n. closed(s n)" "\<forall>n. (s n \<noteq> {})"
  2861   "(\<forall>m n. m \<le> n --> s n \<subseteq> s m)"  "bounded(s 0)"
  2862   shows "\<exists>a::'a::heine_borel. \<forall>n::nat. a \<in> s(n)"
  2863 proof-
  2864   from assms(2) obtain x where x:"\<forall>n::nat. x n \<in> s n" using choice[of "\<lambda>n x. x\<in> s n"] by auto
  2865   from assms(4,1) have *:"compact (s 0)" using bounded_closed_imp_compact[of "s 0"] by auto
  2866 
  2867   then obtain l r where lr:"l\<in>s 0" "subseq r" "((x \<circ> r) ---> l) sequentially"
  2868     unfolding compact_def apply(erule_tac x=x in allE)  using x using assms(3) by blast
  2869 
  2870   { fix n::nat
  2871     { fix e::real assume "e>0"
  2872       with lr(3) obtain N where N:"\<forall>m\<ge>N. dist ((x \<circ> r) m) l < e" unfolding LIMSEQ_def by auto
  2873       hence "dist ((x \<circ> r) (max N n)) l < e" by auto
  2874       moreover
  2875       have "r (max N n) \<ge> n" using lr(2) using subseq_bigger[of r "max N n"] by auto
  2876       hence "(x \<circ> r) (max N n) \<in> s n"
  2877         using x apply(erule_tac x=n in allE)
  2878         using x apply(erule_tac x="r (max N n)" in allE)
  2879         using assms(3) apply(erule_tac x=n in allE)apply( erule_tac x="r (max N n)" in allE) by auto
  2880       ultimately have "\<exists>y\<in>s n. dist y l < e" by auto
  2881     }
  2882     hence "l \<in> s n" using closed_approachable[of "s n" l] assms(1) by blast
  2883   }
  2884   thus ?thesis by auto
  2885 qed
  2886 
  2887 text {* Decreasing case does not even need compactness, just completeness. *}
  2888 
  2889 lemma decreasing_closed_nest:
  2890   assumes "\<forall>n. closed(s n)"
  2891           "\<forall>n. (s n \<noteq> {})"
  2892           "\<forall>m n. m \<le> n --> s n \<subseteq> s m"
  2893           "\<forall>e>0. \<exists>n. \<forall>x \<in> (s n). \<forall> y \<in> (s n). dist x y < e"
  2894   shows "\<exists>a::'a::complete_space. \<forall>n::nat. a \<in> s n"
  2895 proof-
  2896   have "\<forall>n. \<exists> x. x\<in>s n" using assms(2) by auto
  2897   hence "\<exists>t. \<forall>n. t n \<in> s n" using choice[of "\<lambda> n x. x \<in> s n"] by auto
  2898   then obtain t where t: "\<forall>n. t n \<in> s n" by auto
  2899   { fix e::real assume "e>0"
  2900     then obtain N where N:"\<forall>x\<in>s N. \<forall>y\<in>s N. dist x y < e" using assms(4) by auto
  2901     { fix m n ::nat assume "N \<le> m \<and> N \<le> n"
  2902       hence "t m \<in> s N" "t n \<in> s N" using assms(3) t unfolding  subset_eq t by blast+
  2903       hence "dist (t m) (t n) < e" using N by auto
  2904     }
  2905     hence "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (t m) (t n) < e" by auto
  2906   }
  2907   hence  "Cauchy t" unfolding cauchy_def by auto
  2908   then obtain l where l:"(t ---> l) sequentially" using complete_univ unfolding complete_def by auto
  2909   { fix n::nat
  2910     { fix e::real assume "e>0"
  2911       then obtain N::nat where N:"\<forall>n\<ge>N. dist (t n) l < e" using l[unfolded LIMSEQ_def] by auto
  2912       have "t (max n N) \<in> s n" using assms(3) unfolding subset_eq apply(erule_tac x=n in allE) apply (erule_tac x="max n N" in allE) using t by auto
  2913       hence "\<exists>y\<in>s n. dist y l < e" apply(rule_tac x="t (max n N)" in bexI) using N by auto
  2914     }
  2915     hence "l \<in> s n" using closed_approachable[of "s n" l] assms(1) by auto
  2916   }
  2917   then show ?thesis by auto
  2918 qed
  2919 
  2920 text {* Strengthen it to the intersection actually being a singleton. *}
  2921 
  2922 lemma decreasing_closed_nest_sing:
  2923   fixes s :: "nat \<Rightarrow> 'a::complete_space set"
  2924   assumes "\<forall>n. closed(s n)"
  2925           "\<forall>n. s n \<noteq> {}"
  2926           "\<forall>m n. m \<le> n --> s n \<subseteq> s m"
  2927           "\<forall>e>0. \<exists>n. \<forall>x \<in> (s n). \<forall> y\<in>(s n). dist x y < e"
  2928   shows "\<exists>a. \<Inter>(range s) = {a}"
  2929 proof-
  2930   obtain a where a:"\<forall>n. a \<in> s n" using decreasing_closed_nest[of s] using assms by auto
  2931   { fix b assume b:"b \<in> \<Inter>(range s)"
  2932     { fix e::real assume "e>0"
  2933       hence "dist a b < e" using assms(4 )using b using a by blast
  2934     }
  2935     hence "dist a b = 0" by (metis dist_eq_0_iff dist_nz less_le)
  2936   }
  2937   with a have "\<Inter>(range s) = {a}" unfolding image_def by auto
  2938   thus ?thesis ..
  2939 qed
  2940 
  2941 text{* Cauchy-type criteria for uniform convergence. *}
  2942 
  2943 lemma uniformly_convergent_eq_cauchy: fixes s::"nat \<Rightarrow> 'b \<Rightarrow> 'a::heine_borel" shows
  2944  "(\<exists>l. \<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x --> dist(s n x)(l x) < e) \<longleftrightarrow>
  2945   (\<forall>e>0. \<exists>N. \<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x  --> dist (s m x) (s n x) < e)" (is "?lhs = ?rhs")
  2946 proof(rule)
  2947   assume ?lhs
  2948   then obtain l where l:"\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l x) < e" by auto
  2949   { fix e::real assume "e>0"
  2950     then obtain N::nat where N:"\<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l x) < e / 2" using l[THEN spec[where x="e/2"]] by auto
  2951     { fix n m::nat and x::"'b" assume "N \<le> m \<and> N \<le> n \<and> P x"
  2952       hence "dist (s m x) (s n x) < e"
  2953         using N[THEN spec[where x=m], THEN spec[where x=x]]
  2954         using N[THEN spec[where x=n], THEN spec[where x=x]]
  2955         using dist_triangle_half_l[of "s m x" "l x" e "s n x"] by auto  }
  2956     hence "\<exists>N. \<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x  --> dist (s m x) (s n x) < e"  by auto  }
  2957   thus ?rhs by auto
  2958 next
  2959   assume ?rhs
  2960   hence "\<forall>x. P x \<longrightarrow> Cauchy (\<lambda>n. s n x)" unfolding cauchy_def apply auto by (erule_tac x=e in allE)auto
  2961   then obtain l where l:"\<forall>x. P x \<longrightarrow> ((\<lambda>n. s n x) ---> l x) sequentially" unfolding convergent_eq_cauchy[THEN sym]
  2962     using choice[of "\<lambda>x l. P x \<longrightarrow> ((\<lambda>n. s n x) ---> l) sequentially"] by auto
  2963   { fix e::real assume "e>0"
  2964     then obtain N where N:"\<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x \<longrightarrow> dist (s m x) (s n x) < e/2"
  2965       using `?rhs`[THEN spec[where x="e/2"]] by auto
  2966     { fix x assume "P x"
  2967       then obtain M where M:"\<forall>n\<ge>M. dist (s n x) (l x) < e/2"
  2968         using l[THEN spec[where x=x], unfolded LIMSEQ_def] using `e>0` by(auto elim!: allE[where x="e/2"])
  2969       fix n::nat assume "n\<ge>N"
  2970       hence "dist(s n x)(l x) < e"  using `P x`and N[THEN spec[where x=n], THEN spec[where x="N+M"], THEN spec[where x=x]]
  2971         using M[THEN spec[where x="N+M"]] and dist_triangle_half_l[of "s n x" "s (N+M) x" e "l x"] by (auto simp add: dist_commute)  }
  2972     hence "\<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist(s n x)(l x) < e" by auto }
  2973   thus ?lhs by auto
  2974 qed
  2975 
  2976 lemma uniformly_cauchy_imp_uniformly_convergent:
  2977   fixes s :: "nat \<Rightarrow> 'a \<Rightarrow> 'b::heine_borel"
  2978   assumes "\<forall>e>0.\<exists>N. \<forall>m (n::nat) x. N \<le> m \<and> N \<le> n \<and> P x --> dist(s m x)(s n x) < e"
  2979           "\<forall>x. P x --> (\<forall>e>0. \<exists>N. \<forall>n. N \<le> n --> dist(s n x)(l x) < e)"
  2980   shows "\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x --> dist(s n x)(l x) < e"
  2981 proof-
  2982   obtain l' where l:"\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l' x) < e"
  2983     using assms(1) unfolding uniformly_convergent_eq_cauchy[THEN sym] by auto
  2984   moreover
  2985   { fix x assume "P x"
  2986     hence "l x = l' x" using tendsto_unique[OF trivial_limit_sequentially, of "\<lambda>n. s n x" "l x" "l' x"]
  2987       using l and assms(2) unfolding LIMSEQ_def by blast  }
  2988   ultimately show ?thesis by auto
  2989 qed
  2990 
  2991 
  2992 subsection {* Continuity *}
  2993 
  2994 text {* Define continuity over a net to take in restrictions of the set. *}
  2995 
  2996 definition
  2997   continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool"
  2998   where "continuous net f \<longleftrightarrow> (f ---> f(netlimit net)) net"
  2999 
  3000 lemma continuous_trivial_limit:
  3001  "trivial_limit net ==> continuous net f"
  3002   unfolding continuous_def tendsto_def trivial_limit_eq by auto
  3003 
  3004 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f ---> f(x)) (at x within s)"
  3005   unfolding continuous_def
  3006   unfolding tendsto_def
  3007   using netlimit_within[of x s]
  3008   by (cases "trivial_limit (at x within s)") (auto simp add: trivial_limit_eventually)
  3009 
  3010 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> (f ---> f(x)) (at x)"
  3011   using continuous_within [of x UNIV f] by simp
  3012 
  3013 lemma continuous_at_within:
  3014   assumes "continuous (at x) f"  shows "continuous (at x within s) f"
  3015   using assms unfolding continuous_at continuous_within
  3016   by (rule Lim_at_within)
  3017 
  3018 text{* Derive the epsilon-delta forms, which we often use as "definitions" *}
  3019 
  3020 lemma continuous_within_eps_delta:
  3021   "continuous (at x within s) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0. \<forall>x'\<in> s.  dist x' x < d --> dist (f x') (f x) < e)"
  3022   unfolding continuous_within and Lim_within
  3023   apply auto unfolding dist_nz[THEN sym] apply(auto del: allE elim!:allE) apply(rule_tac x=d in exI) by auto
  3024 
  3025 lemma continuous_at_eps_delta: "continuous (at x) f \<longleftrightarrow>  (\<forall>e>0. \<exists>d>0.
  3026                            \<forall>x'. dist x' x < d --> dist(f x')(f x) < e)"
  3027   using continuous_within_eps_delta [of x UNIV f] by simp
  3028 
  3029 text{* Versions in terms of open balls. *}
  3030 
  3031 lemma continuous_within_ball:
  3032  "continuous (at x within s) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0.
  3033                             f ` (ball x d \<inter> s) \<subseteq> ball (f x) e)" (is "?lhs = ?rhs")
  3034 proof
  3035   assume ?lhs
  3036   { fix e::real assume "e>0"
  3037     then obtain d where d: "d>0" "\<forall>xa\<in>s. 0 < dist xa x \<and> dist xa x < d \<longrightarrow> dist (f xa) (f x) < e"
  3038       using `?lhs`[unfolded continuous_within Lim_within] by auto
  3039     { fix y assume "y\<in>f ` (ball x d \<inter> s)"
  3040       hence "y \<in> ball (f x) e" using d(2) unfolding dist_nz[THEN sym]
  3041         apply (auto simp add: dist_commute) apply(erule_tac x=xa in ballE) apply auto using `e>0` by auto
  3042     }
  3043     hence "\<exists>d>0. f ` (ball x d \<inter> s) \<subseteq> ball (f x) e" using `d>0` unfolding subset_eq ball_def by (auto simp add: dist_commute)  }
  3044   thus ?rhs by auto
  3045 next
  3046   assume ?rhs thus ?lhs unfolding continuous_within Lim_within ball_def subset_eq
  3047     apply (auto simp add: dist_commute) apply(erule_tac x=e in allE) by auto
  3048 qed
  3049 
  3050 lemma continuous_at_ball:
  3051   "continuous (at x) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0. f ` (ball x d) \<subseteq> ball (f x) e)" (is "?lhs = ?rhs")
  3052 proof
  3053   assume ?lhs thus ?rhs unfolding continuous_at Lim_at subset_eq Ball_def Bex_def image_iff mem_ball
  3054     apply auto apply(erule_tac x=e in allE) apply auto apply(rule_tac x=d in exI) apply auto apply(erule_tac x=xa in allE) apply (auto simp add: dist_commute dist_nz)
  3055     unfolding dist_nz[THEN sym] by auto
  3056 next
  3057   assume ?rhs thus ?lhs unfolding continuous_at Lim_at subset_eq Ball_def Bex_def image_iff mem_ball
  3058     apply auto apply(erule_tac x=e in allE) apply auto apply(rule_tac x=d in exI) apply auto apply(erule_tac x="f xa" in allE) by (auto simp add: dist_commute dist_nz)
  3059 qed
  3060 
  3061 text{* Define setwise continuity in terms of limits within the set. *}
  3062 
  3063 definition
  3064   continuous_on ::
  3065     "'a set \<Rightarrow> ('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> bool"
  3066 where
  3067   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f ---> f x) (at x within s))"
  3068 
  3069 lemma continuous_on_topological:
  3070   "continuous_on s f \<longleftrightarrow>
  3071     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow>
  3072       (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  3073 unfolding continuous_on_def tendsto_def
  3074 unfolding Limits.eventually_within eventually_at_topological
  3075 by (intro ball_cong [OF refl] all_cong imp_cong ex_cong conj_cong refl) auto
  3076 
  3077 lemma continuous_on_iff:
  3078   "continuous_on s f \<longleftrightarrow>
  3079     (\<forall>x\<in>s. \<forall>e>0. \<exists>d>0. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  3080 unfolding continuous_on_def Lim_within
  3081 apply (intro ball_cong [OF refl] all_cong ex_cong)
  3082 apply (rename_tac y, case_tac "y = x", simp)
  3083 apply (simp add: dist_nz)
  3084 done
  3085 
  3086 definition
  3087   uniformly_continuous_on ::
  3088     "'a set \<Rightarrow> ('a::metric_space \<Rightarrow> 'b::metric_space) \<Rightarrow> bool"
  3089 where
  3090   "uniformly_continuous_on s f \<longleftrightarrow>
  3091     (\<forall>e>0. \<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  3092 
  3093 text{* Some simple consequential lemmas. *}
  3094 
  3095 lemma uniformly_continuous_imp_continuous:
  3096  " uniformly_continuous_on s f ==> continuous_on s f"
  3097   unfolding uniformly_continuous_on_def continuous_on_iff by blast
  3098 
  3099 lemma continuous_at_imp_continuous_within:
  3100  "continuous (at x) f ==> continuous (at x within s) f"
  3101   unfolding continuous_within continuous_at using Lim_at_within by auto
  3102 
  3103 lemma Lim_trivial_limit: "trivial_limit net \<Longrightarrow> (f ---> l) net"
  3104 unfolding tendsto_def by (simp add: trivial_limit_eq)
  3105 
  3106 lemma continuous_at_imp_continuous_on:
  3107   assumes "\<forall>x\<in>s. continuous (at x) f"
  3108   shows "continuous_on s f"
  3109 unfolding continuous_on_def
  3110 proof
  3111   fix x assume "x \<in> s"
  3112   with assms have *: "(f ---> f (netlimit (at x))) (at x)"
  3113     unfolding continuous_def by simp
  3114   have "(f ---> f x) (at x)"
  3115   proof (cases "trivial_limit (at x)")
  3116     case True thus ?thesis
  3117       by (rule Lim_trivial_limit)
  3118   next
  3119     case False
  3120     hence 1: "netlimit (at x) = x"
  3121       using netlimit_within [of x UNIV] by simp
  3122     with * show ?thesis by simp
  3123   qed
  3124   thus "(f ---> f x) (at x within s)"
  3125     by (rule Lim_at_within)
  3126 qed
  3127 
  3128 lemma continuous_on_eq_continuous_within:
  3129   "continuous_on s f \<longleftrightarrow> (\<forall>x \<in> s. continuous (at x within s) f)"
  3130 unfolding continuous_on_def continuous_def
  3131 apply (rule ball_cong [OF refl])
  3132 apply (case_tac "trivial_limit (at x within s)")
  3133 apply (simp add: Lim_trivial_limit)
  3134 apply (simp add: netlimit_within)
  3135 done
  3136 
  3137 lemmas continuous_on = continuous_on_def -- "legacy theorem name"
  3138 
  3139 lemma continuous_on_eq_continuous_at:
  3140   shows "open s ==> (continuous_on s f \<longleftrightarrow> (\<forall>x \<in> s. continuous (at x) f))"
  3141   by (auto simp add: continuous_on continuous_at Lim_within_open)
  3142 
  3143 lemma continuous_within_subset:
  3144  "continuous (at x within s) f \<Longrightarrow> t \<subseteq> s
  3145              ==> continuous (at x within t) f"
  3146   unfolding continuous_within by(metis Lim_within_subset)
  3147 
  3148 lemma continuous_on_subset:
  3149   shows "continuous_on s f \<Longrightarrow> t \<subseteq> s ==> continuous_on t f"
  3150   unfolding continuous_on by (metis subset_eq Lim_within_subset)
  3151 
  3152 lemma continuous_on_interior:
  3153   shows "continuous_on s f \<Longrightarrow> x \<in> interior s \<Longrightarrow> continuous (at x) f"
  3154   by (erule interiorE, drule (1) continuous_on_subset,
  3155     simp add: continuous_on_eq_continuous_at)
  3156 
  3157 lemma continuous_on_eq:
  3158   "(\<forall>x \<in> s. f x = g x) \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on s g"
  3159   unfolding continuous_on_def tendsto_def Limits.eventually_within
  3160   by simp
  3161 
  3162 text {* Characterization of various kinds of continuity in terms of sequences. *}
  3163 
  3164 lemma continuous_within_sequentially:
  3165   fixes f :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  3166   shows "continuous (at a within s) f \<longleftrightarrow>
  3167                 (\<forall>x. (\<forall>n::nat. x n \<in> s) \<and> (x ---> a) sequentially
  3168                      --> ((f o x) ---> f a) sequentially)" (is "?lhs = ?rhs")
  3169 proof
  3170   assume ?lhs
  3171   { fix x::"nat \<Rightarrow> 'a" assume x:"\<forall>n. x n \<in> s" "\<forall>e>0. eventually (\<lambda>n. dist (x n) a < e) sequentially"
  3172     fix T::"'b set" assume "open T" and "f a \<in> T"
  3173     with `?lhs` obtain d where "d>0" and d:"\<forall>x\<in>s. 0 < dist x a \<and> dist x a < d \<longrightarrow> f x \<in> T"
  3174       unfolding continuous_within tendsto_def eventually_within by auto
  3175     have "eventually (\<lambda>n. dist (x n) a < d) sequentially"
  3176       using x(2) `d>0` by simp
  3177     hence "eventually (\<lambda>n. (f \<circ> x) n \<in> T) sequentially"
  3178     proof eventually_elim
  3179       case (elim n) thus ?case
  3180         using d x(1) `f a \<in> T` unfolding dist_nz[THEN sym] by auto
  3181     qed
  3182   }
  3183   thus ?rhs unfolding tendsto_iff unfolding tendsto_def by simp
  3184 next
  3185   assume ?rhs thus ?lhs
  3186     unfolding continuous_within tendsto_def [where l="f a"]
  3187     by (simp add: sequentially_imp_eventually_within)
  3188 qed
  3189 
  3190 lemma continuous_at_sequentially:
  3191   fixes f :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  3192   shows "continuous (at a) f \<longleftrightarrow> (\<forall>x. (x ---> a) sequentially
  3193                   --> ((f o x) ---> f a) sequentially)"
  3194   using continuous_within_sequentially[of a UNIV f] by simp
  3195 
  3196 lemma continuous_on_sequentially:
  3197   fixes f :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  3198   shows "continuous_on s f \<longleftrightarrow>
  3199     (\<forall>x. \<forall>a \<in> s. (\<forall>n. x(n) \<in> s) \<and> (x ---> a) sequentially
  3200                     --> ((f o x) ---> f(a)) sequentially)" (is "?lhs = ?rhs")
  3201 proof
  3202   assume ?rhs thus ?lhs using continuous_within_sequentially[of _ s f] unfolding continuous_on_eq_continuous_within by auto
  3203 next
  3204   assume ?lhs thus ?rhs unfolding continuous_on_eq_continuous_within using continuous_within_sequentially[of _ s f] by auto
  3205 qed
  3206 
  3207 lemma uniformly_continuous_on_sequentially:
  3208   "uniformly_continuous_on s f \<longleftrightarrow> (\<forall>x y. (\<forall>n. x n \<in> s) \<and> (\<forall>n. y n \<in> s) \<and>
  3209                     ((\<lambda>n. dist (x n) (y n)) ---> 0) sequentially
  3210                     \<longrightarrow> ((\<lambda>n. dist (f(x n)) (f(y n))) ---> 0) sequentially)" (is "?lhs = ?rhs")
  3211 proof
  3212   assume ?lhs
  3213   { fix x y assume x:"\<forall>n. x n \<in> s" and y:"\<forall>n. y n \<in> s" and xy:"((\<lambda>n. dist (x n) (y n)) ---> 0) sequentially"
  3214     { fix e::real assume "e>0"
  3215       then obtain d where "d>0" and d:"\<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e"
  3216         using `?lhs`[unfolded uniformly_continuous_on_def, THEN spec[where x=e]] by auto
  3217       obtain N where N:"\<forall>n\<ge>N. dist (x n) (y n) < d" using xy[unfolded LIMSEQ_def dist_norm] and `d>0` by auto
  3218       { fix n assume "n\<ge>N"
  3219         hence "dist (f (x n)) (f (y n)) < e"
  3220           using N[THEN spec[where x=n]] using d[THEN bspec[where x="x n"], THEN bspec[where x="y n"]] using x and y
  3221           unfolding dist_commute by simp  }
  3222       hence "\<exists>N. \<forall>n\<ge>N. dist (f (x n)) (f (y n)) < e"  by auto  }
  3223     hence "((\<lambda>n. dist (f(x n)) (f(y n))) ---> 0) sequentially" unfolding LIMSEQ_def and dist_real_def by auto  }
  3224   thus ?rhs by auto
  3225 next
  3226   assume ?rhs
  3227   { assume "\<not> ?lhs"
  3228     then obtain e where "e>0" "\<forall>d>0. \<exists>x\<in>s. \<exists>x'\<in>s. dist x' x < d \<and> \<not> dist (f x') (f x) < e" unfolding uniformly_continuous_on_def by auto
  3229     then obtain fa where fa:"\<forall>x.  0 < x \<longrightarrow> fst (fa x) \<in> s \<and> snd (fa x) \<in> s \<and> dist (fst (fa x)) (snd (fa x)) < x \<and> \<not> dist (f (fst (fa x))) (f (snd (fa x))) < e"
  3230       using choice[of "\<lambda>d x. d>0 \<longrightarrow> fst x \<in> s \<and> snd x \<in> s \<and> dist (snd x) (fst x) < d \<and> \<not> dist (f (snd x)) (f (fst x)) < e"] unfolding Bex_def
  3231       by (auto simp add: dist_commute)
  3232     def x \<equiv> "\<lambda>n::nat. fst (fa (inverse (real n + 1)))"
  3233     def y \<equiv> "\<lambda>n::nat. snd (fa (inverse (real n + 1)))"
  3234     have xyn:"\<forall>n. x n \<in> s \<and> y n \<in> s" and xy0:"\<forall>n. dist (x n) (y n) < inverse (real n + 1)" and fxy:"\<forall>n. \<not> dist (f (x n)) (f (y n)) < e"
  3235       unfolding x_def and y_def using fa by auto
  3236     { fix e::real assume "e>0"
  3237       then obtain N::nat where "N \<noteq> 0" and N:"0 < inverse (real N) \<and> inverse (real N) < e" unfolding real_arch_inv[of e]   by auto
  3238       { fix n::nat assume "n\<ge>N"
  3239         hence "inverse (real n + 1) < inverse (real N)" using real_of_nat_ge_zero and `N\<noteq>0` by auto
  3240         also have "\<dots> < e" using N by auto
  3241         finally have "inverse (real n + 1) < e" by auto
  3242         hence "dist (x n) (y n) < e" using xy0[THEN spec[where x=n]] by auto  }
  3243       hence "\<exists>N. \<forall>n\<ge>N. dist (x n) (y n) < e" by auto  }
  3244     hence "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. dist (f (x n)) (f (y n)) < e" using `?rhs`[THEN spec[where x=x], THEN spec[where x=y]] and xyn unfolding LIMSEQ_def dist_real_def by auto
  3245     hence False using fxy and `e>0` by auto  }
  3246   thus ?lhs unfolding uniformly_continuous_on_def by blast
  3247 qed
  3248 
  3249 text{* The usual transformation theorems. *}
  3250 
  3251 lemma continuous_transform_within:
  3252   fixes f g :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  3253   assumes "0 < d" "x \<in> s" "\<forall>x' \<in> s. dist x' x < d --> f x' = g x'"
  3254           "continuous (at x within s) f"
  3255   shows "continuous (at x within s) g"
  3256 unfolding continuous_within
  3257 proof (rule Lim_transform_within)
  3258   show "0 < d" by fact
  3259   show "\<forall>x'\<in>s. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  3260     using assms(3) by auto
  3261   have "f x = g x"
  3262     using assms(1,2,3) by auto
  3263   thus "(f ---> g x) (at x within s)"
  3264     using assms(4) unfolding continuous_within by simp
  3265 qed
  3266 
  3267 lemma continuous_transform_at:
  3268   fixes f g :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  3269   assumes "0 < d" "\<forall>x'. dist x' x < d --> f x' = g x'"
  3270           "continuous (at x) f"
  3271   shows "continuous (at x) g"
  3272   using continuous_transform_within [of d x UNIV f g] assms by simp
  3273 
  3274 subsubsection {* Structural rules for pointwise continuity *}
  3275 
  3276 lemma continuous_within_id: "continuous (at a within s) (\<lambda>x. x)"
  3277   unfolding continuous_within by (rule tendsto_ident_at_within)
  3278 
  3279 lemma continuous_at_id: "continuous (at a) (\<lambda>x. x)"
  3280   unfolding continuous_at by (rule tendsto_ident_at)
  3281 
  3282 lemma continuous_const: "continuous F (\<lambda>x. c)"
  3283   unfolding continuous_def by (rule tendsto_const)
  3284 
  3285 lemma continuous_dist:
  3286   assumes "continuous F f" and "continuous F g"
  3287   shows "continuous F (\<lambda>x. dist (f x) (g x))"
  3288   using assms unfolding continuous_def by (rule tendsto_dist)
  3289 
  3290 lemma continuous_norm:
  3291   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
  3292   unfolding continuous_def by (rule tendsto_norm)
  3293 
  3294 lemma continuous_infnorm:
  3295   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. infnorm (f x))"
  3296   unfolding continuous_def by (rule tendsto_infnorm)
  3297 
  3298 lemma continuous_add:
  3299   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3300   shows "\<lbrakk>continuous F f; continuous F g\<rbrakk> \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
  3301   unfolding continuous_def by (rule tendsto_add)
  3302 
  3303 lemma continuous_minus:
  3304   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3305   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
  3306   unfolding continuous_def by (rule tendsto_minus)
  3307 
  3308 lemma continuous_diff:
  3309   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3310   shows "\<lbrakk>continuous F f; continuous F g\<rbrakk> \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
  3311   unfolding continuous_def by (rule tendsto_diff)
  3312 
  3313 lemma continuous_scaleR:
  3314   fixes g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3315   shows "\<lbrakk>continuous F f; continuous F g\<rbrakk> \<Longrightarrow> continuous F (\<lambda>x. f x *\<^sub>R g x)"
  3316   unfolding continuous_def by (rule tendsto_scaleR)
  3317 
  3318 lemma continuous_mult:
  3319   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  3320   shows "\<lbrakk>continuous F f; continuous F g\<rbrakk> \<Longrightarrow> continuous F (\<lambda>x. f x * g x)"
  3321   unfolding continuous_def by (rule tendsto_mult)
  3322 
  3323 lemma continuous_inner:
  3324   assumes "continuous F f" and "continuous F g"
  3325   shows "continuous F (\<lambda>x. inner (f x) (g x))"
  3326   using assms unfolding continuous_def by (rule tendsto_inner)
  3327 
  3328 lemma continuous_euclidean_component:
  3329   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. f x $$ i)"
  3330   unfolding continuous_def by (rule tendsto_euclidean_component)
  3331 
  3332 lemma continuous_inverse:
  3333   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
  3334   assumes "continuous F f" and "f (netlimit F) \<noteq> 0"
  3335   shows "continuous F (\<lambda>x. inverse (f x))"
  3336   using assms unfolding continuous_def by (rule tendsto_inverse)
  3337 
  3338 lemma continuous_at_within_inverse:
  3339   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
  3340   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
  3341   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
  3342   using assms unfolding continuous_within by (rule tendsto_inverse)
  3343 
  3344 lemma continuous_at_inverse:
  3345   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
  3346   assumes "continuous (at a) f" and "f a \<noteq> 0"
  3347   shows "continuous (at a) (\<lambda>x. inverse (f x))"
  3348   using assms unfolding continuous_at by (rule tendsto_inverse)
  3349 
  3350 lemmas continuous_intros = continuous_at_id continuous_within_id
  3351   continuous_const continuous_dist continuous_norm continuous_infnorm
  3352   continuous_add continuous_minus continuous_diff
  3353   continuous_scaleR continuous_mult
  3354   continuous_inner continuous_euclidean_component
  3355   continuous_at_inverse continuous_at_within_inverse
  3356 
  3357 subsubsection {* Structural rules for setwise continuity *}
  3358 
  3359 lemma continuous_on_id: "continuous_on s (\<lambda>x. x)"
  3360   unfolding continuous_on_def by (fast intro: tendsto_ident_at_within)
  3361 
  3362 lemma continuous_on_const: "continuous_on s (\<lambda>x. c)"
  3363   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3364 
  3365 lemma continuous_on_norm:
  3366   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
  3367   unfolding continuous_on_def by (fast intro: tendsto_norm)
  3368 
  3369 lemma continuous_on_infnorm:
  3370   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. infnorm (f x))"
  3371   unfolding continuous_on by (fast intro: tendsto_infnorm)
  3372 
  3373 lemma continuous_on_minus:
  3374   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3375   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
  3376   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3377 
  3378 lemma continuous_on_add:
  3379   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3380   shows "continuous_on s f \<Longrightarrow> continuous_on s g
  3381            \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
  3382   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3383 
  3384 lemma continuous_on_diff:
  3385   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3386   shows "continuous_on s f \<Longrightarrow> continuous_on s g
  3387            \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
  3388   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3389 
  3390 lemma (in bounded_linear) continuous_on:
  3391   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
  3392   unfolding continuous_on_def by (fast intro: tendsto)
  3393 
  3394 lemma (in bounded_bilinear) continuous_on:
  3395   "\<lbrakk>continuous_on s f; continuous_on s g\<rbrakk> \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
  3396   unfolding continuous_on_def by (fast intro: tendsto)
  3397 
  3398 lemma continuous_on_scaleR:
  3399   fixes g :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3400   assumes "continuous_on s f" and "continuous_on s g"
  3401   shows "continuous_on s (\<lambda>x. f x *\<^sub>R g x)"
  3402   using bounded_bilinear_scaleR assms
  3403   by (rule bounded_bilinear.continuous_on)
  3404 
  3405 lemma continuous_on_mult:
  3406   fixes g :: "'a::topological_space \<Rightarrow> 'b::real_normed_algebra"
  3407   assumes "continuous_on s f" and "continuous_on s g"
  3408   shows "continuous_on s (\<lambda>x. f x * g x)"
  3409   using bounded_bilinear_mult assms
  3410   by (rule bounded_bilinear.continuous_on)
  3411 
  3412 lemma continuous_on_inner:
  3413   fixes g :: "'a::topological_space \<Rightarrow> 'b::real_inner"
  3414   assumes "continuous_on s f" and "continuous_on s g"
  3415   shows "continuous_on s (\<lambda>x. inner (f x) (g x))"
  3416   using bounded_bilinear_inner assms
  3417   by (rule bounded_bilinear.continuous_on)
  3418 
  3419 lemma continuous_on_euclidean_component:
  3420   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. f x $$ i)"
  3421   using bounded_linear_euclidean_component
  3422   by (rule bounded_linear.continuous_on)
  3423 
  3424 lemma continuous_on_inverse:
  3425   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
  3426   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
  3427   shows "continuous_on s (\<lambda>x. inverse (f x))"
  3428   using assms unfolding continuous_on by (fast intro: tendsto_inverse)
  3429 
  3430 subsubsection {* Structural rules for uniform continuity *}
  3431 
  3432 lemma uniformly_continuous_on_id:
  3433   shows "uniformly_continuous_on s (\<lambda>x. x)"
  3434   unfolding uniformly_continuous_on_def by auto
  3435 
  3436 lemma uniformly_continuous_on_const:
  3437   shows "uniformly_continuous_on s (\<lambda>x. c)"
  3438   unfolding uniformly_continuous_on_def by simp
  3439 
  3440 lemma uniformly_continuous_on_dist:
  3441   fixes f g :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  3442   assumes "uniformly_continuous_on s f"
  3443   assumes "uniformly_continuous_on s g"
  3444   shows "uniformly_continuous_on s (\<lambda>x. dist (f x) (g x))"
  3445 proof -
  3446   { fix a b c d :: 'b have "\<bar>dist a b - dist c d\<bar> \<le> dist a c + dist b d"
  3447       using dist_triangle2 [of a b c] dist_triangle2 [of b c d]
  3448       using dist_triangle3 [of c d a] dist_triangle [of a d b]
  3449       by arith
  3450   } note le = this
  3451   { fix x y
  3452     assume f: "(\<lambda>n. dist (f (x n)) (f (y n))) ----> 0"
  3453     assume g: "(\<lambda>n. dist (g (x n)) (g (y n))) ----> 0"
  3454     have "(\<lambda>n. \<bar>dist (f (x n)) (g (x n)) - dist (f (y n)) (g (y n))\<bar>) ----> 0"
  3455       by (rule Lim_transform_bound [OF _ tendsto_add_zero [OF f g]],
  3456         simp add: le)
  3457   }
  3458   thus ?thesis using assms unfolding uniformly_continuous_on_sequentially
  3459     unfolding dist_real_def by simp
  3460 qed
  3461 
  3462 lemma uniformly_continuous_on_norm:
  3463   assumes "uniformly_continuous_on s f"
  3464   shows "uniformly_continuous_on s (\<lambda>x. norm (f x))"
  3465   unfolding norm_conv_dist using assms
  3466   by (intro uniformly_continuous_on_dist uniformly_continuous_on_const)
  3467 
  3468 lemma (in bounded_linear) uniformly_continuous_on:
  3469   assumes "uniformly_continuous_on s g"
  3470   shows "uniformly_continuous_on s (\<lambda>x. f (g x))"
  3471   using assms unfolding uniformly_continuous_on_sequentially
  3472   unfolding dist_norm tendsto_norm_zero_iff diff[symmetric]
  3473   by (auto intro: tendsto_zero)
  3474 
  3475 lemma uniformly_continuous_on_cmul:
  3476   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3477   assumes "uniformly_continuous_on s f"
  3478   shows "uniformly_continuous_on s (\<lambda>x. c *\<^sub>R f(x))"
  3479   using bounded_linear_scaleR_right assms
  3480   by (rule bounded_linear.uniformly_continuous_on)
  3481 
  3482 lemma dist_minus:
  3483   fixes x y :: "'a::real_normed_vector"
  3484   shows "dist (- x) (- y) = dist x y"
  3485   unfolding dist_norm minus_diff_minus norm_minus_cancel ..
  3486 
  3487 lemma uniformly_continuous_on_minus:
  3488   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3489   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s (\<lambda>x. - f x)"
  3490   unfolding uniformly_continuous_on_def dist_minus .
  3491 
  3492 lemma uniformly_continuous_on_add:
  3493   fixes f g :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3494   assumes "uniformly_continuous_on s f"
  3495   assumes "uniformly_continuous_on s g"
  3496   shows "uniformly_continuous_on s (\<lambda>x. f x + g x)"
  3497   using assms unfolding uniformly_continuous_on_sequentially
  3498   unfolding dist_norm tendsto_norm_zero_iff add_diff_add
  3499   by (auto intro: tendsto_add_zero)
  3500 
  3501 lemma uniformly_continuous_on_diff:
  3502   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3503   assumes "uniformly_continuous_on s f" and "uniformly_continuous_on s g"
  3504   shows "uniformly_continuous_on s (\<lambda>x. f x - g x)"
  3505   unfolding ab_diff_minus using assms
  3506   by (intro uniformly_continuous_on_add uniformly_continuous_on_minus)
  3507 
  3508 text{* Continuity of all kinds is preserved under composition. *}
  3509 
  3510 lemma continuous_within_topological:
  3511   "continuous (at x within s) f \<longleftrightarrow>
  3512     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow>
  3513       (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  3514 unfolding continuous_within
  3515 unfolding tendsto_def Limits.eventually_within eventually_at_topological
  3516 by (intro ball_cong [OF refl] all_cong imp_cong ex_cong conj_cong refl) auto
  3517 
  3518 lemma continuous_within_compose:
  3519   assumes "continuous (at x within s) f"
  3520   assumes "continuous (at (f x) within f ` s) g"
  3521   shows "continuous (at x within s) (g o f)"
  3522 using assms unfolding continuous_within_topological by simp metis
  3523 
  3524 lemma continuous_at_compose:
  3525   assumes "continuous (at x) f" and "continuous (at (f x)) g"
  3526   shows "continuous (at x) (g o f)"
  3527 proof-
  3528   have "continuous (at (f x) within range f) g" using assms(2)
  3529     using continuous_within_subset[of "f x" UNIV g "range f"] by simp
  3530   thus ?thesis using assms(1)
  3531     using continuous_within_compose[of x UNIV f g] by simp
  3532 qed
  3533 
  3534 lemma continuous_on_compose:
  3535   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g o f)"
  3536   unfolding continuous_on_topological by simp metis
  3537 
  3538 lemma uniformly_continuous_on_compose:
  3539   assumes "uniformly_continuous_on s f"  "uniformly_continuous_on (f ` s) g"
  3540   shows "uniformly_continuous_on s (g o f)"
  3541 proof-
  3542   { fix e::real assume "e>0"
  3543     then obtain d where "d>0" and d:"\<forall>x\<in>f ` s. \<forall>x'\<in>f ` s. dist x' x < d \<longrightarrow> dist (g x') (g x) < e" using assms(2) unfolding uniformly_continuous_on_def by auto
  3544     obtain d' where "d'>0" "\<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d' \<longrightarrow> dist (f x') (f x) < d" using `d>0` using assms(1) unfolding uniformly_continuous_on_def by auto
  3545     hence "\<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist ((g \<circ> f) x') ((g \<circ> f) x) < e" using `d>0` using d by auto  }
  3546   thus ?thesis using assms unfolding uniformly_continuous_on_def by auto
  3547 qed
  3548 
  3549 lemmas continuous_on_intros = continuous_on_id continuous_on_const
  3550   continuous_on_compose continuous_on_norm continuous_on_infnorm
  3551   continuous_on_add continuous_on_minus continuous_on_diff
  3552   continuous_on_scaleR continuous_on_mult continuous_on_inverse
  3553   continuous_on_inner continuous_on_euclidean_component
  3554   uniformly_continuous_on_id uniformly_continuous_on_const
  3555   uniformly_continuous_on_dist uniformly_continuous_on_norm
  3556   uniformly_continuous_on_compose uniformly_continuous_on_add
  3557   uniformly_continuous_on_minus uniformly_continuous_on_diff
  3558   uniformly_continuous_on_cmul
  3559 
  3560 text{* Continuity in terms of open preimages. *}
  3561 
  3562 lemma continuous_at_open:
  3563   shows "continuous (at x) f \<longleftrightarrow> (\<forall>t. open t \<and> f x \<in> t --> (\<exists>s. open s \<and> x \<in> s \<and> (\<forall>x' \<in> s. (f x') \<in> t)))"
  3564 unfolding continuous_within_topological [of x UNIV f, unfolded within_UNIV]
  3565 unfolding imp_conjL by (intro all_cong imp_cong ex_cong conj_cong refl) auto
  3566 
  3567 lemma continuous_on_open:
  3568   shows "continuous_on s f \<longleftrightarrow>
  3569         (\<forall>t. openin (subtopology euclidean (f ` s)) t
  3570             --> openin (subtopology euclidean s) {x \<in> s. f x \<in> t})" (is "?lhs = ?rhs")
  3571 proof (safe)
  3572   fix t :: "'b set"
  3573   assume 1: "continuous_on s f"
  3574   assume 2: "openin (subtopology euclidean (f ` s)) t"
  3575   from 2 obtain B where B: "open B" and t: "t = f ` s \<inter> B"
  3576     unfolding openin_open by auto
  3577   def U == "\<Union>{A. open A \<and> (\<forall>x\<in>s. x \<in> A \<longrightarrow> f x \<in> B)}"
  3578   have "open U" unfolding U_def by (simp add: open_Union)
  3579   moreover have "\<forall>x\<in>s. x \<in> U \<longleftrightarrow> f x \<in> t"
  3580   proof (intro ballI iffI)
  3581     fix x assume "x \<in> s" and "x \<in> U" thus "f x \<in> t"
  3582       unfolding U_def t by auto
  3583   next
  3584     fix x assume "x \<in> s" and "f x \<in> t"
  3585     hence "x \<in> s" and "f x \<in> B"
  3586       unfolding t by auto
  3587     with 1 B obtain A where "open A" "x \<in> A" "\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B"
  3588       unfolding t continuous_on_topological by metis
  3589     then show "x \<in> U"
  3590       unfolding U_def by auto
  3591   qed
  3592   ultimately have "open U \<and> {x \<in> s. f x \<in> t} = s \<inter> U" by auto
  3593   then show "openin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  3594     unfolding openin_open by fast
  3595 next
  3596   assume "?rhs" show "continuous_on s f"
  3597   unfolding continuous_on_topological
  3598   proof (clarify)
  3599     fix x and B assume "x \<in> s" and "open B" and "f x \<in> B"
  3600     have "openin (subtopology euclidean (f ` s)) (f ` s \<inter> B)"
  3601       unfolding openin_open using `open B` by auto
  3602     then have "openin (subtopology euclidean s) {x \<in> s. f x \<in> f ` s \<inter> B}"
  3603       using `?rhs` by fast
  3604     then show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  3605       unfolding openin_open using `x \<in> s` and `f x \<in> B` by auto
  3606   qed
  3607 qed
  3608 
  3609 text {* Similarly in terms of closed sets. *}
  3610 
  3611 lemma continuous_on_closed:
  3612   shows "continuous_on s f \<longleftrightarrow>  (\<forall>t. closedin (subtopology euclidean (f ` s)) t  --> closedin (subtopology euclidean s) {x \<in> s. f x \<in> t})" (is "?lhs = ?rhs")
  3613 proof
  3614   assume ?lhs
  3615   { fix t
  3616     have *:"s - {x \<in> s. f x \<in> f ` s - t} = {x \<in> s. f x \<in> t}" by auto
  3617     have **:"f ` s - (f ` s - (f ` s - t)) = f ` s - t" by auto
  3618     assume as:"closedin (subtopology euclidean (f ` s)) t"
  3619     hence "closedin (subtopology euclidean (f ` s)) (f ` s - (f ` s - t))" unfolding closedin_def topspace_euclidean_subtopology unfolding ** by auto
  3620     hence "closedin (subtopology euclidean s) {x \<in> s. f x \<in> t}" using `?lhs`[unfolded continuous_on_open, THEN spec[where x="(f ` s) - t"]]
  3621       unfolding openin_closedin_eq topspace_euclidean_subtopology unfolding * by auto  }
  3622   thus ?rhs by auto
  3623 next
  3624   assume ?rhs
  3625   { fix t
  3626     have *:"s - {x \<in> s. f x \<in> f ` s - t} = {x \<in> s. f x \<in> t}" by auto
  3627     assume as:"openin (subtopology euclidean (f ` s)) t"
  3628     hence "openin (subtopology euclidean s) {x \<in> s. f x \<in> t}" using `?rhs`[THEN spec[where x="(f ` s) - t"]]
  3629       unfolding openin_closedin_eq topspace_euclidean_subtopology *[THEN sym] closedin_subtopology by auto }
  3630   thus ?lhs unfolding continuous_on_open by auto
  3631 qed
  3632 
  3633 text {* Half-global and completely global cases. *}
  3634 
  3635 lemma continuous_open_in_preimage:
  3636   assumes "continuous_on s f"  "open t"
  3637   shows "openin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  3638 proof-
  3639   have *:"\<forall>x. x \<in> s \<and> f x \<in> t \<longleftrightarrow> x \<in> s \<and> f x \<in> (t \<inter> f ` s)" by auto
  3640   have "openin (subtopology euclidean (f ` s)) (t \<inter> f ` s)"
  3641     using openin_open_Int[of t "f ` s", OF assms(2)] unfolding openin_open by auto
  3642   thus ?thesis using assms(1)[unfolded continuous_on_open, THEN spec[where x="t \<inter> f ` s"]] using * by auto
  3643 qed
  3644 
  3645 lemma continuous_closed_in_preimage:
  3646   assumes "continuous_on s f"  "closed t"
  3647   shows "closedin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  3648 proof-
  3649   have *:"\<forall>x. x \<in> s \<and> f x \<in> t \<longleftrightarrow> x \<in> s \<and> f x \<in> (t \<inter> f ` s)" by auto
  3650   have "closedin (subtopology euclidean (f ` s)) (t \<inter> f ` s)"
  3651     using closedin_closed_Int[of t "f ` s", OF assms(2)] unfolding Int_commute by auto
  3652   thus ?thesis
  3653     using assms(1)[unfolded continuous_on_closed, THEN spec[where x="t \<inter> f ` s"]] using * by auto
  3654 qed
  3655 
  3656 lemma continuous_open_preimage:
  3657   assumes "continuous_on s f" "open s" "open t"
  3658   shows "open {x \<in> s. f x \<in> t}"
  3659 proof-
  3660   obtain T where T: "open T" "{x \<in> s. f x \<in> t} = s \<inter> T"
  3661     using continuous_open_in_preimage[OF assms(1,3)] unfolding openin_open by auto
  3662   thus ?thesis using open_Int[of s T, OF assms(2)] by auto
  3663 qed
  3664 
  3665 lemma continuous_closed_preimage:
  3666   assumes "continuous_on s f" "closed s" "closed t"
  3667   shows "closed {x \<in> s. f x \<in> t}"
  3668 proof-
  3669   obtain T where T: "closed T" "{x \<in> s. f x \<in> t} = s \<inter> T"
  3670     using continuous_closed_in_preimage[OF assms(1,3)] unfolding closedin_closed by auto
  3671   thus ?thesis using closed_Int[of s T, OF assms(2)] by auto
  3672 qed
  3673 
  3674 lemma continuous_open_preimage_univ:
  3675   shows "\<forall>x. continuous (at x) f \<Longrightarrow> open s \<Longrightarrow> open {x. f x \<in> s}"
  3676   using continuous_open_preimage[of UNIV f s] open_UNIV continuous_at_imp_continuous_on by auto
  3677 
  3678 lemma continuous_closed_preimage_univ:
  3679   shows "(\<forall>x. continuous (at x) f) \<Longrightarrow> closed s ==> closed {x. f x \<in> s}"
  3680   using continuous_closed_preimage[of UNIV f s] closed_UNIV continuous_at_imp_continuous_on by auto
  3681 
  3682 lemma continuous_open_vimage:
  3683   shows "\<forall>x. continuous (at x) f \<Longrightarrow> open s \<Longrightarrow> open (f -` s)"
  3684   unfolding vimage_def by (rule continuous_open_preimage_univ)
  3685 
  3686 lemma continuous_closed_vimage:
  3687   shows "\<forall>x. continuous (at x) f \<Longrightarrow> closed s \<Longrightarrow> closed (f -` s)"
  3688   unfolding vimage_def by (rule continuous_closed_preimage_univ)
  3689 
  3690 lemma interior_image_subset:
  3691   assumes "\<forall>x. continuous (at x) f" "inj f"
  3692   shows "interior (f ` s) \<subseteq> f ` (interior s)"
  3693 proof
  3694   fix x assume "x \<in> interior (f ` s)"
  3695   then obtain T where as: "open T" "x \<in> T" "T \<subseteq> f ` s" ..
  3696   hence "x \<in> f ` s" by auto
  3697   then obtain y where y: "y \<in> s" "x = f y" by auto
  3698   have "open (vimage f T)"
  3699     using assms(1) `open T` by (rule continuous_open_vimage)
  3700   moreover have "y \<in> vimage f T"
  3701     using `x = f y` `x \<in> T` by simp
  3702   moreover have "vimage f T \<subseteq> s"
  3703     using `T \<subseteq> image f s` `inj f` unfolding inj_on_def subset_eq by auto
  3704   ultimately have "y \<in> interior s" ..
  3705   with `x = f y` show "x \<in> f ` interior s" ..
  3706 qed
  3707 
  3708 text {* Equality of continuous functions on closure and related results. *}
  3709 
  3710 lemma continuous_closed_in_preimage_constant:
  3711   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3712   shows "continuous_on s f ==> closedin (subtopology euclidean s) {x \<in> s. f x = a}"
  3713   using continuous_closed_in_preimage[of s f "{a}"] by auto
  3714 
  3715 lemma continuous_closed_preimage_constant:
  3716   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3717   shows "continuous_on s f \<Longrightarrow> closed s ==> closed {x \<in> s. f x = a}"
  3718   using continuous_closed_preimage[of s f "{a}"] by auto
  3719 
  3720 lemma continuous_constant_on_closure:
  3721   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3722   assumes "continuous_on (closure s) f"
  3723           "\<forall>x \<in> s. f x = a"
  3724   shows "\<forall>x \<in> (closure s). f x = a"
  3725     using continuous_closed_preimage_constant[of "closure s" f a]
  3726     assms closure_minimal[of s "{x \<in> closure s. f x = a}"] closure_subset unfolding subset_eq by auto
  3727 
  3728 lemma image_closure_subset:
  3729   assumes "continuous_on (closure s) f"  "closed t"  "(f ` s) \<subseteq> t"
  3730   shows "f ` (closure s) \<subseteq> t"
  3731 proof-
  3732   have "s \<subseteq> {x \<in> closure s. f x \<in> t}" using assms(3) closure_subset by auto
  3733   moreover have "closed {x \<in> closure s. f x \<in> t}"
  3734     using continuous_closed_preimage[OF assms(1)] and assms(2) by auto
  3735   ultimately have "closure s = {x \<in> closure s . f x \<in> t}"
  3736     using closure_minimal[of s "{x \<in> closure s. f x \<in> t}"] by auto
  3737   thus ?thesis by auto
  3738 qed
  3739 
  3740 lemma continuous_on_closure_norm_le:
  3741   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3742   assumes "continuous_on (closure s) f"  "\<forall>y \<in> s. norm(f y) \<le> b"  "x \<in> (closure s)"
  3743   shows "norm(f x) \<le> b"
  3744 proof-
  3745   have *:"f ` s \<subseteq> cball 0 b" using assms(2)[unfolded mem_cball_0[THEN sym]] by auto
  3746   show ?thesis
  3747     using image_closure_subset[OF assms(1) closed_cball[of 0 b] *] assms(3)
  3748     unfolding subset_eq apply(erule_tac x="f x" in ballE) by (auto simp add: dist_norm)
  3749 qed
  3750 
  3751 text {* Making a continuous function avoid some value in a neighbourhood. *}
  3752 
  3753 lemma continuous_within_avoid:
  3754   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* FIXME: generalize *)
  3755   assumes "continuous (at x within s) f"  "x \<in> s"  "f x \<noteq> a"
  3756   shows "\<exists>e>0. \<forall>y \<in> s. dist x y < e --> f y \<noteq> a"
  3757 proof-
  3758   obtain d where "d>0" and d:"\<forall>xa\<in>s. 0 < dist xa x \<and> dist xa x < d \<longrightarrow> dist (f xa) (f x) < dist (f x) a"
  3759     using assms(1)[unfolded continuous_within Lim_within, THEN spec[where x="dist (f x) a"]] assms(3)[unfolded dist_nz] by auto
  3760   { fix y assume " y\<in>s"  "dist x y < d"
  3761     hence "f y \<noteq> a" using d[THEN bspec[where x=y]] assms(3)[unfolded dist_nz]
  3762       apply auto unfolding dist_nz[THEN sym] by (auto simp add: dist_commute) }
  3763   thus ?thesis using `d>0` by auto
  3764 qed
  3765 
  3766 lemma continuous_at_avoid:
  3767   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* FIXME: generalize *)
  3768   assumes "continuous (at x) f" and "f x \<noteq> a"
  3769   shows "\<exists>e>0. \<forall>y. dist x y < e \<longrightarrow> f y \<noteq> a"
  3770   using assms continuous_within_avoid[of x UNIV f a] by simp
  3771 
  3772 lemma continuous_on_avoid:
  3773   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* TODO: generalize *)
  3774   assumes "continuous_on s f"  "x \<in> s"  "f x \<noteq> a"
  3775   shows "\<exists>e>0. \<forall>y \<in> s. dist x y < e \<longrightarrow> f y \<noteq> a"
  3776 using assms(1)[unfolded continuous_on_eq_continuous_within, THEN bspec[where x=x], OF assms(2)]  continuous_within_avoid[of x s f a]  assms(2,3) by auto
  3777 
  3778 lemma continuous_on_open_avoid:
  3779   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* TODO: generalize *)
  3780   assumes "continuous_on s f"  "open s"  "x \<in> s"  "f x \<noteq> a"
  3781   shows "\<exists>e>0. \<forall>y. dist x y < e \<longrightarrow> f y \<noteq> a"
  3782 using assms(1)[unfolded continuous_on_eq_continuous_at[OF assms(2)], THEN bspec[where x=x], OF assms(3)]  continuous_at_avoid[of x f a]  assms(3,4) by auto
  3783 
  3784 text {* Proving a function is constant by proving open-ness of level set. *}
  3785 
  3786 lemma continuous_levelset_open_in_cases:
  3787   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3788   shows "connected s \<Longrightarrow> continuous_on s f \<Longrightarrow>
  3789         openin (subtopology euclidean s) {x \<in> s. f x = a}
  3790         ==> (\<forall>x \<in> s. f x \<noteq> a) \<or> (\<forall>x \<in> s. f x = a)"
  3791 unfolding connected_clopen using continuous_closed_in_preimage_constant by auto
  3792 
  3793 lemma continuous_levelset_open_in:
  3794   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3795   shows "connected s \<Longrightarrow> continuous_on s f \<Longrightarrow>
  3796         openin (subtopology euclidean s) {x \<in> s. f x = a} \<Longrightarrow>
  3797         (\<exists>x \<in> s. f x = a)  ==> (\<forall>x \<in> s. f x = a)"
  3798 using continuous_levelset_open_in_cases[of s f ]
  3799 by meson
  3800 
  3801 lemma continuous_levelset_open:
  3802   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3803   assumes "connected s"  "continuous_on s f"  "open {x \<in> s. f x = a}"  "\<exists>x \<in> s.  f x = a"
  3804   shows "\<forall>x \<in> s. f x = a"
  3805 using continuous_levelset_open_in[OF assms(1,2), of a, unfolded openin_open] using assms (3,4) by fast
  3806 
  3807 text {* Some arithmetical combinations (more to prove). *}
  3808 
  3809 lemma open_scaling[intro]:
  3810   fixes s :: "'a::real_normed_vector set"
  3811   assumes "c \<noteq> 0"  "open s"
  3812   shows "open((\<lambda>x. c *\<^sub>R x) ` s)"
  3813 proof-
  3814   { fix x assume "x \<in> s"
  3815     then obtain e where "e>0" and e:"\<forall>x'. dist x' x < e \<longrightarrow> x' \<in> s" using assms(2)[unfolded open_dist, THEN bspec[where x=x]] by auto
  3816     have "e * abs c > 0" using assms(1)[unfolded zero_less_abs_iff[THEN sym]] using mult_pos_pos[OF `e>0`] by auto
  3817     moreover
  3818     { fix y assume "dist y (c *\<^sub>R x) < e * \<bar>c\<bar>"
  3819       hence "norm ((1 / c) *\<^sub>R y - x) < e" unfolding dist_norm
  3820         using norm_scaleR[of c "(1 / c) *\<^sub>R y - x", unfolded scaleR_right_diff_distrib, unfolded scaleR_scaleR] assms(1)
  3821           assms(1)[unfolded zero_less_abs_iff[THEN sym]] by (simp del:zero_less_abs_iff)
  3822       hence "y \<in> op *\<^sub>R c ` s" using rev_image_eqI[of "(1 / c) *\<^sub>R y" s y "op *\<^sub>R c"]  e[THEN spec[where x="(1 / c) *\<^sub>R y"]]  assms(1) unfolding dist_norm scaleR_scaleR by auto  }
  3823     ultimately have "\<exists>e>0. \<forall>x'. dist x' (c *\<^sub>R x) < e \<longrightarrow> x' \<in> op *\<^sub>R c ` s" apply(rule_tac x="e * abs c" in exI) by auto  }
  3824   thus ?thesis unfolding open_dist by auto
  3825 qed
  3826 
  3827 lemma minus_image_eq_vimage:
  3828   fixes A :: "'a::ab_group_add set"
  3829   shows "(\<lambda>x. - x) ` A = (\<lambda>x. - x) -` A"
  3830   by (auto intro!: image_eqI [where f="\<lambda>x. - x"])
  3831 
  3832 lemma open_negations:
  3833   fixes s :: "'a::real_normed_vector set"
  3834   shows "open s ==> open ((\<lambda> x. -x) ` s)"
  3835   unfolding scaleR_minus1_left [symmetric]
  3836   by (rule open_scaling, auto)
  3837 
  3838 lemma open_translation:
  3839   fixes s :: "'a::real_normed_vector set"
  3840   assumes "open s"  shows "open((\<lambda>x. a + x) ` s)"
  3841 proof-
  3842   { fix x have "continuous (at x) (\<lambda>x. x - a)"
  3843       by (intro continuous_diff continuous_at_id continuous_const) }
  3844   moreover have "{x. x - a \<in> s} = op + a ` s" by force
  3845   ultimately show ?thesis using continuous_open_preimage_univ[of "\<lambda>x. x - a" s] using assms by auto
  3846 qed
  3847 
  3848 lemma open_affinity:
  3849   fixes s :: "'a::real_normed_vector set"
  3850   assumes "open s"  "c \<noteq> 0"
  3851   shows "open ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  3852 proof-
  3853   have *:"(\<lambda>x. a + c *\<^sub>R x) = (\<lambda>x. a + x) \<circ> (\<lambda>x. c *\<^sub>R x)" unfolding o_def ..
  3854   have "op + a ` op *\<^sub>R c ` s = (op + a \<circ> op *\<^sub>R c) ` s" by auto
  3855   thus ?thesis using assms open_translation[of "op *\<^sub>R c ` s" a] unfolding * by auto
  3856 qed
  3857 
  3858 lemma interior_translation:
  3859   fixes s :: "'a::real_normed_vector set"
  3860   shows "interior ((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (interior s)"
  3861 proof (rule set_eqI, rule)
  3862   fix x assume "x \<in> interior (op + a ` s)"
  3863   then obtain e where "e>0" and e:"ball x e \<subseteq> op + a ` s" unfolding mem_interior by auto
  3864   hence "ball (x - a) e \<subseteq> s" unfolding subset_eq Ball_def mem_ball dist_norm apply auto apply(erule_tac x="a + xa" in allE) unfolding ab_group_add_class.diff_diff_eq[THEN sym] by auto
  3865   thus "x \<in> op + a ` interior s" unfolding image_iff apply(rule_tac x="x - a" in bexI) unfolding mem_interior using `e > 0` by auto
  3866 next
  3867   fix x assume "x \<in> op + a ` interior s"
  3868   then obtain y e where "e>0" and e:"ball y e \<subseteq> s" and y:"x = a + y" unfolding image_iff Bex_def mem_interior by auto
  3869   { fix z have *:"a + y - z = y + a - z" by auto
  3870     assume "z\<in>ball x e"
  3871     hence "z - a \<in> s" using e[unfolded subset_eq, THEN bspec[where x="z - a"]] unfolding mem_ball dist_norm y group_add_class.diff_diff_eq2 * by auto
  3872     hence "z \<in> op + a ` s" unfolding image_iff by(auto intro!: bexI[where x="z - a"])  }
  3873   hence "ball x e \<subseteq> op + a ` s" unfolding subset_eq by auto
  3874   thus "x \<in> interior (op + a ` s)" unfolding mem_interior using `e>0` by auto
  3875 qed
  3876 
  3877 text {* Topological properties of linear functions. *}
  3878 
  3879 lemma linear_lim_0:
  3880   assumes "bounded_linear f" shows "(f ---> 0) (at (0))"
  3881 proof-
  3882   interpret f: bounded_linear f by fact
  3883   have "(f ---> f 0) (at 0)"
  3884     using tendsto_ident_at by (rule f.tendsto)
  3885   thus ?thesis unfolding f.zero .
  3886 qed
  3887 
  3888 lemma linear_continuous_at:
  3889   assumes "bounded_linear f"  shows "continuous (at a) f"
  3890   unfolding continuous_at using assms
  3891   apply (rule bounded_linear.tendsto)
  3892   apply (rule tendsto_ident_at)
  3893   done
  3894 
  3895 lemma linear_continuous_within:
  3896   shows "bounded_linear f ==> continuous (at x within s) f"
  3897   using continuous_at_imp_continuous_within[of x f s] using linear_continuous_at[of f] by auto
  3898 
  3899 lemma linear_continuous_on:
  3900   shows "bounded_linear f ==> continuous_on s f"
  3901   using continuous_at_imp_continuous_on[of s f] using linear_continuous_at[of f] by auto
  3902 
  3903 text {* Also bilinear functions, in composition form. *}
  3904 
  3905 lemma bilinear_continuous_at_compose:
  3906   shows "continuous (at x) f \<Longrightarrow> continuous (at x) g \<Longrightarrow> bounded_bilinear h
  3907         ==> continuous (at x) (\<lambda>x. h (f x) (g x))"
  3908   unfolding continuous_at using Lim_bilinear[of f "f x" "(at x)" g "g x" h] by auto
  3909 
  3910 lemma bilinear_continuous_within_compose:
  3911   shows "continuous (at x within s) f \<Longrightarrow> continuous (at x within s) g \<Longrightarrow> bounded_bilinear h
  3912         ==> continuous (at x within s) (\<lambda>x. h (f x) (g x))"
  3913   unfolding continuous_within using Lim_bilinear[of f "f x"] by auto
  3914 
  3915 lemma bilinear_continuous_on_compose:
  3916   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> bounded_bilinear h
  3917              ==> continuous_on s (\<lambda>x. h (f x) (g x))"
  3918   unfolding continuous_on_def
  3919   by (fast elim: bounded_bilinear.tendsto)
  3920 
  3921 text {* Preservation of compactness and connectedness under continuous function. *}
  3922 
  3923 lemma compact_continuous_image:
  3924   assumes "continuous_on s f"  "compact s"
  3925   shows "compact(f ` s)"
  3926 proof-
  3927   { fix x assume x:"\<forall>n::nat. x n \<in> f ` s"
  3928     then obtain y where y:"\<forall>n. y n \<in> s \<and> x n = f (y n)" unfolding image_iff Bex_def using choice[of "\<lambda>n xa. xa \<in> s \<and> x n = f xa"] by auto
  3929     then obtain l r where "l\<in>s" and r:"subseq r" and lr:"((y \<circ> r) ---> l) sequentially" using assms(2)[unfolded compact_def, THEN spec[where x=y]] by auto
  3930     { fix e::real assume "e>0"
  3931       then obtain d where "d>0" and d:"\<forall>x'\<in>s. dist x' l < d \<longrightarrow> dist (f x') (f l) < e" using assms(1)[unfolded continuous_on_iff, THEN bspec[where x=l], OF `l\<in>s`] by auto
  3932       then obtain N::nat where N:"\<forall>n\<ge>N. dist ((y \<circ> r) n) l < d" using lr[unfolded LIMSEQ_def, THEN spec[where x=d]] by auto
  3933       { fix n::nat assume "n\<ge>N" hence "dist ((x \<circ> r) n) (f l) < e" using N[THEN spec[where x=n]] d[THEN bspec[where x="y (r n)"]] y[THEN spec[where x="r n"]] by auto  }
  3934       hence "\<exists>N. \<forall>n\<ge>N. dist ((x \<circ> r) n) (f l) < e" by auto  }
  3935     hence "\<exists>l\<in>f ` s. \<exists>r. subseq r \<and> ((x \<circ> r) ---> l) sequentially" unfolding LIMSEQ_def using r lr `l\<in>s` by auto  }
  3936   thus ?thesis unfolding compact_def by auto
  3937 qed
  3938 
  3939 lemma connected_continuous_image:
  3940   assumes "continuous_on s f"  "connected s"
  3941   shows "connected(f ` s)"
  3942 proof-
  3943   { fix T assume as: "T \<noteq> {}"  "T \<noteq> f ` s"  "openin (subtopology euclidean (f ` s)) T"  "closedin (subtopology euclidean (f ` s)) T"
  3944     have "{x \<in> s. f x \<in> T} = {} \<or> {x \<in> s. f x \<in> T} = s"
  3945       using assms(1)[unfolded continuous_on_open, THEN spec[where x=T]]
  3946       using assms(1)[unfolded continuous_on_closed, THEN spec[where x=T]]
  3947       using assms(2)[unfolded connected_clopen, THEN spec[where x="{x \<in> s. f x \<in> T}"]] as(3,4) by auto
  3948     hence False using as(1,2)
  3949       using as(4)[unfolded closedin_def topspace_euclidean_subtopology] by auto }
  3950   thus ?thesis unfolding connected_clopen by auto
  3951 qed
  3952 
  3953 text {* Continuity implies uniform continuity on a compact domain. *}
  3954 
  3955 lemma compact_uniformly_continuous:
  3956   assumes "continuous_on s f"  "compact s"
  3957   shows "uniformly_continuous_on s f"
  3958 proof-
  3959     { fix x assume x:"x\<in>s"
  3960       hence "\<forall>xa. \<exists>y. 0 < xa \<longrightarrow> (y > 0 \<and> (\<forall>x'\<in>s. dist x' x < y \<longrightarrow> dist (f x') (f x) < xa))" using assms(1)[unfolded continuous_on_iff, THEN bspec[where x=x]] by auto
  3961       hence "\<exists>fa. \<forall>xa>0. \<forall>x'\<in>s. fa xa > 0 \<and> (dist x' x < fa xa \<longrightarrow> dist (f x') (f x) < xa)" using choice[of "\<lambda>e d. e>0 \<longrightarrow> d>0 \<and>(\<forall>x'\<in>s. (dist x' x < d \<longrightarrow> dist (f x') (f x) < e))"] by auto  }
  3962     then have "\<forall>x\<in>s. \<exists>y. \<forall>xa. 0 < xa \<longrightarrow> (\<forall>x'\<in>s. y xa > 0 \<and> (dist x' x < y xa \<longrightarrow> dist (f x') (f x) < xa))" by auto
  3963     then obtain d where d:"\<forall>e>0. \<forall>x\<in>s. \<forall>x'\<in>s. d x e > 0 \<and> (dist x' x < d x e \<longrightarrow> dist (f x') (f x) < e)"
  3964       using bchoice[of s "\<lambda>x fa. \<forall>xa>0. \<forall>x'\<in>s. fa xa > 0 \<and> (dist x' x < fa xa \<longrightarrow> dist (f x') (f x) < xa)"] by blast
  3965 
  3966   { fix e::real assume "e>0"
  3967 
  3968     { fix x assume "x\<in>s" hence "x \<in> ball x (d x (e / 2))" unfolding centre_in_ball using d[THEN spec[where x="e/2"]] using `e>0` by auto  }
  3969     hence "s \<subseteq> \<Union>{ball x (d x (e / 2)) |x. x \<in> s}" unfolding subset_eq by auto
  3970     moreover
  3971     { fix b assume "b\<in>{ball x (d x (e / 2)) |x. x \<in> s}" hence "open b" by auto  }
  3972     ultimately obtain ea where "ea>0" and ea:"\<forall>x\<in>s. \<exists>b\<in>{ball x (d x (e / 2)) |x. x \<in> s}. ball x ea \<subseteq> b" using heine_borel_lemma[OF assms(2), of "{ball x (d x (e / 2)) | x. x\<in>s }"] by auto
  3973 
  3974     { fix x y assume "x\<in>s" "y\<in>s" and as:"dist y x < ea"
  3975       obtain z where "z\<in>s" and z:"ball x ea \<subseteq> ball z (d z (e / 2))" using ea[THEN bspec[where x=x]] and `x\<in>s` by auto
  3976       hence "x\<in>ball z (d z (e / 2))" using `ea>0` unfolding subset_eq by auto
  3977       hence "dist (f z) (f x) < e / 2" using d[THEN spec[where x="e/2"]] and `e>0` and `x\<in>s` and `z\<in>s`
  3978         by (auto  simp add: dist_commute)
  3979       moreover have "y\<in>ball z (d z (e / 2))" using as and `ea>0` and z[unfolded subset_eq]
  3980         by (auto simp add: dist_commute)
  3981       hence "dist (f z) (f y) < e / 2" using d[THEN spec[where x="e/2"]] and `e>0` and `y\<in>s` and `z\<in>s`
  3982         by (auto  simp add: dist_commute)
  3983       ultimately have "dist (f y) (f x) < e" using dist_triangle_half_r[of "f z" "f x" e "f y"]
  3984         by (auto simp add: dist_commute)  }
  3985     then have "\<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e" using `ea>0` by auto  }
  3986   thus ?thesis unfolding uniformly_continuous_on_def by auto
  3987 qed
  3988 
  3989 text{* Continuity of inverse function on compact domain. *}
  3990 
  3991 lemma continuous_on_inv:
  3992   fixes f :: "'a::heine_borel \<Rightarrow> 'b::heine_borel"
  3993     (* TODO: can this be generalized more? *)
  3994   assumes "continuous_on s f"  "compact s"  "\<forall>x \<in> s. g (f x) = x"
  3995   shows "continuous_on (f ` s) g"
  3996 proof-
  3997   have *:"g ` f ` s = s" using assms(3) by (auto simp add: image_iff)
  3998   { fix t assume t:"closedin (subtopology euclidean (g ` f ` s)) t"
  3999     then obtain T where T: "closed T" "t = s \<inter> T" unfolding closedin_closed unfolding * by auto
  4000     have "continuous_on (s \<inter> T) f" using continuous_on_subset[OF assms(1), of "s \<inter> t"]
  4001       unfolding T(2) and Int_left_absorb by auto
  4002     moreover have "compact (s \<inter> T)"
  4003       using assms(2) unfolding compact_eq_bounded_closed
  4004       using bounded_subset[of s "s \<inter> T"] and T(1) by auto
  4005     ultimately have "closed (f ` t)" using T(1) unfolding T(2)
  4006       using compact_continuous_image [of "s \<inter> T" f] unfolding compact_eq_bounded_closed by auto
  4007     moreover have "{x \<in> f ` s. g x \<in> t} = f ` s \<inter> f ` t" using assms(3) unfolding T(2) by auto
  4008     ultimately have "closedin (subtopology euclidean (f ` s)) {x \<in> f ` s. g x \<in> t}"
  4009       unfolding closedin_closed by auto  }
  4010   thus ?thesis unfolding continuous_on_closed by auto
  4011 qed
  4012 
  4013 text {* A uniformly convergent limit of continuous functions is continuous. *}
  4014 
  4015 lemma continuous_uniform_limit:
  4016   fixes f :: "'a \<Rightarrow> 'b::metric_space \<Rightarrow> 'c::metric_space"
  4017   assumes "\<not> trivial_limit F"
  4018   assumes "eventually (\<lambda>n. continuous_on s (f n)) F"
  4019   assumes "\<forall>e>0. eventually (\<lambda>n. \<forall>x\<in>s. dist (f n x) (g x) < e) F"
  4020   shows "continuous_on s g"
  4021 proof-
  4022   { fix x and e::real assume "x\<in>s" "e>0"
  4023     have "eventually (\<lambda>n. \<forall>x\<in>s. dist (f n x) (g x) < e / 3) F"
  4024       using `e>0` assms(3)[THEN spec[where x="e/3"]] by auto
  4025     from eventually_happens [OF eventually_conj [OF this assms(2)]]
  4026     obtain n where n:"\<forall>x\<in>s. dist (f n x) (g x) < e / 3"  "continuous_on s (f n)"
  4027       using assms(1) by blast
  4028     have "e / 3 > 0" using `e>0` by auto
  4029     then obtain d where "d>0" and d:"\<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f n x') (f n x) < e / 3"
  4030       using n(2)[unfolded continuous_on_iff, THEN bspec[where x=x], OF `x\<in>s`, THEN spec[where x="e/3"]] by blast
  4031     { fix y assume "y \<in> s" and "dist y x < d"
  4032       hence "dist (f n y) (f n x) < e / 3"
  4033         by (rule d [rule_format])
  4034       hence "dist (f n y) (g x) < 2 * e / 3"
  4035         using dist_triangle [of "f n y" "g x" "f n x"]
  4036         using n(1)[THEN bspec[where x=x], OF `x\<in>s`]
  4037         by auto
  4038       hence "dist (g y) (g x) < e"
  4039         using n(1)[THEN bspec[where x=y], OF `y\<in>s`]
  4040         using dist_triangle3 [of "g y" "g x" "f n y"]
  4041         by auto }
  4042     hence "\<exists>d>0. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (g x') (g x) < e"
  4043       using `d>0` by auto }
  4044   thus ?thesis unfolding continuous_on_iff by auto
  4045 qed
  4046 
  4047 
  4048 subsection {* Topological stuff lifted from and dropped to R *}
  4049 
  4050 lemma open_real:
  4051   fixes s :: "real set" shows
  4052  "open s \<longleftrightarrow>
  4053         (\<forall>x \<in> s. \<exists>e>0. \<forall>x'. abs(x' - x) < e --> x' \<in> s)" (is "?lhs = ?rhs")
  4054   unfolding open_dist dist_norm by simp
  4055 
  4056 lemma islimpt_approachable_real:
  4057   fixes s :: "real set"
  4058   shows "x islimpt s \<longleftrightarrow> (\<forall>e>0.  \<exists>x'\<in> s. x' \<noteq> x \<and> abs(x' - x) < e)"
  4059   unfolding islimpt_approachable dist_norm by simp
  4060 
  4061 lemma closed_real:
  4062   fixes s :: "real set"
  4063   shows "closed s \<longleftrightarrow>
  4064         (\<forall>x. (\<forall>e>0.  \<exists>x' \<in> s. x' \<noteq> x \<and> abs(x' - x) < e)
  4065             --> x \<in> s)"
  4066   unfolding closed_limpt islimpt_approachable dist_norm by simp
  4067 
  4068 lemma continuous_at_real_range:
  4069   fixes f :: "'a::real_normed_vector \<Rightarrow> real"
  4070   shows "continuous (at x) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0.
  4071         \<forall>x'. norm(x' - x) < d --> abs(f x' - f x) < e)"
  4072   unfolding continuous_at unfolding Lim_at
  4073   unfolding dist_nz[THEN sym] unfolding dist_norm apply auto
  4074   apply(erule_tac x=e in allE) apply auto apply (rule_tac x=d in exI) apply auto apply (erule_tac x=x' in allE) apply auto
  4075   apply(erule_tac x=e in allE) by auto
  4076 
  4077 lemma continuous_on_real_range:
  4078   fixes f :: "'a::real_normed_vector \<Rightarrow> real"
  4079   shows "continuous_on s f \<longleftrightarrow> (\<forall>x \<in> s. \<forall>e>0. \<exists>d>0. (\<forall>x' \<in> s. norm(x' - x) < d --> abs(f x' - f x) < e))"
  4080   unfolding continuous_on_iff dist_norm by simp
  4081 
  4082 text {* Hence some handy theorems on distance, diameter etc. of/from a set. *}
  4083 
  4084 lemma compact_attains_sup:
  4085   fixes s :: "real set"
  4086   assumes "compact s"  "s \<noteq> {}"
  4087   shows "\<exists>x \<in> s. \<forall>y \<in> s. y \<le> x"
  4088 proof-
  4089   from assms(1) have a:"bounded s" "closed s" unfolding compact_eq_bounded_closed by auto
  4090   { fix e::real assume as: "\<forall>x\<in>s. x \<le> Sup s" "Sup s \<notin> s"  "0 < e" "\<forall>x'\<in>s. x' = Sup s \<or> \<not> Sup s - x' < e"
  4091     have "isLub UNIV s (Sup s)" using Sup[OF assms(2)] unfolding setle_def using as(1) by auto
  4092     moreover have "isUb UNIV s (Sup s - e)" unfolding isUb_def unfolding setle_def using as(4,2) by auto
  4093     ultimately have False using isLub_le_isUb[of UNIV s "Sup s" "Sup s - e"] using `e>0` by auto  }
  4094   thus ?thesis using bounded_has_Sup(1)[OF a(1) assms(2)] using a(2)[unfolded closed_real, THEN spec[where x="Sup s"]]
  4095     apply(rule_tac x="Sup s" in bexI) by auto
  4096 qed
  4097 
  4098 lemma Inf:
  4099   fixes S :: "real set"
  4100   shows "S \<noteq> {} ==> (\<exists>b. b <=* S) ==> isGlb UNIV S (Inf S)"
  4101 by (auto simp add: isLb_def setle_def setge_def isGlb_def greatestP_def) 
  4102 
  4103 lemma compact_attains_inf:
  4104   fixes s :: "real set"
  4105   assumes "compact s" "s \<noteq> {}"  shows "\<exists>x \<in> s. \<forall>y \<in> s. x \<le> y"
  4106 proof-
  4107   from assms(1) have a:"bounded s" "closed s" unfolding compact_eq_bounded_closed by auto
  4108   { fix e::real assume as: "\<forall>x\<in>s. x \<ge> Inf s"  "Inf s \<notin> s"  "0 < e"
  4109       "\<forall>x'\<in>s. x' = Inf s \<or> \<not> abs (x' - Inf s) < e"
  4110     have "isGlb UNIV s (Inf s)" using Inf[OF assms(2)] unfolding setge_def using as(1) by auto
  4111     moreover
  4112     { fix x assume "x \<in> s"
  4113       hence *:"abs (x - Inf s) = x - Inf s" using as(1)[THEN bspec[where x=x]] by auto
  4114       have "Inf s + e \<le> x" using as(4)[THEN bspec[where x=x]] using as(2) `x\<in>s` unfolding * by auto }
  4115     hence "isLb UNIV s (Inf s + e)" unfolding isLb_def and setge_def by auto
  4116     ultimately have False using isGlb_le_isLb[of UNIV s "Inf s" "Inf s + e"] using `e>0` by auto  }
  4117   thus ?thesis using bounded_has_Inf(1)[OF a(1) assms(2)] using a(2)[unfolded closed_real, THEN spec[where x="Inf s"]]
  4118     apply(rule_tac x="Inf s" in bexI) by auto
  4119 qed
  4120 
  4121 lemma continuous_attains_sup:
  4122   fixes f :: "'a::metric_space \<Rightarrow> real"
  4123   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f
  4124         ==> (\<exists>x \<in> s. \<forall>y \<in> s.  f y \<le> f x)"
  4125   using compact_attains_sup[of "f ` s"]
  4126   using compact_continuous_image[of s f] by auto
  4127 
  4128 lemma continuous_attains_inf:
  4129   fixes f :: "'a::metric_space \<Rightarrow> real"
  4130   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f
  4131         \<Longrightarrow> (\<exists>x \<in> s. \<forall>y \<in> s. f x \<le> f y)"
  4132   using compact_attains_inf[of "f ` s"]
  4133   using compact_continuous_image[of s f] by auto
  4134 
  4135 lemma distance_attains_sup:
  4136   assumes "compact s" "s \<noteq> {}"
  4137   shows "\<exists>x \<in> s. \<forall>y \<in> s. dist a y \<le> dist a x"
  4138 proof (rule continuous_attains_sup [OF assms])
  4139   { fix x assume "x\<in>s"
  4140     have "(dist a ---> dist a x) (at x within s)"
  4141       by (intro tendsto_dist tendsto_const Lim_at_within tendsto_ident_at)
  4142   }
  4143   thus "continuous_on s (dist a)"
  4144     unfolding continuous_on ..
  4145 qed
  4146 
  4147 text {* For \emph{minimal} distance, we only need closure, not compactness. *}
  4148 
  4149 lemma distance_attains_inf:
  4150   fixes a :: "'a::heine_borel"
  4151   assumes "closed s"  "s \<noteq> {}"
  4152   shows "\<exists>x \<in> s. \<forall>y \<in> s. dist a x \<le> dist a y"
  4153 proof-
  4154   from assms(2) obtain b where "b\<in>s" by auto
  4155   let ?B = "cball a (dist b a) \<inter> s"
  4156   have "b \<in> ?B" using `b\<in>s` by (simp add: dist_commute)
  4157   hence "?B \<noteq> {}" by auto
  4158   moreover
  4159   { fix x assume "x\<in>?B"
  4160     fix e::real assume "e>0"
  4161     { fix x' assume "x'\<in>?B" and as:"dist x' x < e"
  4162       from as have "\<bar>dist a x' - dist a x\<bar> < e"
  4163         unfolding abs_less_iff minus_diff_eq
  4164         using dist_triangle2 [of a x' x]
  4165         using dist_triangle [of a x x']
  4166         by arith
  4167     }
  4168     hence "\<exists>d>0. \<forall>x'\<in>?B. dist x' x < d \<longrightarrow> \<bar>dist a x' - dist a x\<bar> < e"
  4169       using `e>0` by auto
  4170   }
  4171   hence "continuous_on (cball a (dist b a) \<inter> s) (dist a)"
  4172     unfolding continuous_on Lim_within dist_norm real_norm_def
  4173     by fast
  4174   moreover have "compact ?B"
  4175     using compact_cball[of a "dist b a"]
  4176     unfolding compact_eq_bounded_closed
  4177     using bounded_Int and closed_Int and assms(1) by auto
  4178   ultimately obtain x where "x\<in>cball a (dist b a) \<inter> s" "\<forall>y\<in>cball a (dist b a) \<inter> s. dist a x \<le> dist a y"
  4179     using continuous_attains_inf[of ?B "dist a"] by fastforce
  4180   thus ?thesis by fastforce
  4181 qed
  4182 
  4183 
  4184 subsection {* Pasted sets *}
  4185 
  4186 lemma bounded_Times:
  4187   assumes "bounded s" "bounded t" shows "bounded (s \<times> t)"
  4188 proof-
  4189   obtain x y a b where "\<forall>z\<in>s. dist x z \<le> a" "\<forall>z\<in>t. dist y z \<le> b"
  4190     using assms [unfolded bounded_def] by auto
  4191   then have "\<forall>z\<in>s \<times> t. dist (x, y) z \<le> sqrt (a\<twosuperior> + b\<twosuperior>)"
  4192     by (auto simp add: dist_Pair_Pair real_sqrt_le_mono add_mono power_mono)
  4193   thus ?thesis unfolding bounded_any_center [where a="(x, y)"] by auto
  4194 qed
  4195 
  4196 lemma mem_Times_iff: "x \<in> A \<times> B \<longleftrightarrow> fst x \<in> A \<and> snd x \<in> B"
  4197 by (induct x) simp
  4198 
  4199 lemma compact_Times: "compact s \<Longrightarrow> compact t \<Longrightarrow> compact (s \<times> t)"
  4200 unfolding compact_def
  4201 apply clarify
  4202 apply (drule_tac x="fst \<circ> f" in spec)
  4203 apply (drule mp, simp add: mem_Times_iff)
  4204 apply (clarify, rename_tac l1 r1)
  4205 apply (drule_tac x="snd \<circ> f \<circ> r1" in spec)
  4206 apply (drule mp, simp add: mem_Times_iff)
  4207 apply (clarify, rename_tac l2 r2)
  4208 apply (rule_tac x="(l1, l2)" in rev_bexI, simp)
  4209 apply (rule_tac x="r1 \<circ> r2" in exI)
  4210 apply (rule conjI, simp add: subseq_def)
  4211 apply (drule_tac r=r2 in lim_subseq [COMP swap_prems_rl], assumption)
  4212 apply (drule (1) tendsto_Pair) back
  4213 apply (simp add: o_def)
  4214 done
  4215 
  4216 text{* Hence some useful properties follow quite easily. *}
  4217 
  4218 lemma compact_scaling:
  4219   fixes s :: "'a::real_normed_vector set"
  4220   assumes "compact s"  shows "compact ((\<lambda>x. c *\<^sub>R x) ` s)"
  4221 proof-
  4222   let ?f = "\<lambda>x. scaleR c x"
  4223   have *:"bounded_linear ?f" by (rule bounded_linear_scaleR_right)
  4224   show ?thesis using compact_continuous_image[of s ?f] continuous_at_imp_continuous_on[of s ?f]
  4225     using linear_continuous_at[OF *] assms by auto
  4226 qed
  4227 
  4228 lemma compact_negations:
  4229   fixes s :: "'a::real_normed_vector set"
  4230   assumes "compact s"  shows "compact ((\<lambda>x. -x) ` s)"
  4231   using compact_scaling [OF assms, of "- 1"] by auto
  4232 
  4233 lemma compact_sums:
  4234   fixes s t :: "'a::real_normed_vector set"
  4235   assumes "compact s"  "compact t"  shows "compact {x + y | x y. x \<in> s \<and> y \<in> t}"
  4236 proof-
  4237   have *:"{x + y | x y. x \<in> s \<and> y \<in> t} = (\<lambda>z. fst z + snd z) ` (s \<times> t)"
  4238     apply auto unfolding image_iff apply(rule_tac x="(xa, y)" in bexI) by auto
  4239   have "continuous_on (s \<times> t) (\<lambda>z. fst z + snd z)"
  4240     unfolding continuous_on by (rule ballI) (intro tendsto_intros)
  4241   thus ?thesis unfolding * using compact_continuous_image compact_Times [OF assms] by auto
  4242 qed
  4243 
  4244 lemma compact_differences:
  4245   fixes s t :: "'a::real_normed_vector set"
  4246   assumes "compact s" "compact t"  shows "compact {x - y | x y. x \<in> s \<and> y \<in> t}"
  4247 proof-
  4248   have "{x - y | x y. x\<in>s \<and> y \<in> t} =  {x + y | x y. x \<in> s \<and> y \<in> (uminus ` t)}"
  4249     apply auto apply(rule_tac x= xa in exI) apply auto apply(rule_tac x=xa in exI) by auto
  4250   thus ?thesis using compact_sums[OF assms(1) compact_negations[OF assms(2)]] by auto
  4251 qed
  4252 
  4253 lemma compact_translation:
  4254   fixes s :: "'a::real_normed_vector set"
  4255   assumes "compact s"  shows "compact ((\<lambda>x. a + x) ` s)"
  4256 proof-
  4257   have "{x + y |x y. x \<in> s \<and> y \<in> {a}} = (\<lambda>x. a + x) ` s" by auto
  4258   thus ?thesis using compact_sums[OF assms compact_sing[of a]] by auto
  4259 qed
  4260 
  4261 lemma compact_affinity:
  4262   fixes s :: "'a::real_normed_vector set"
  4263   assumes "compact s"  shows "compact ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  4264 proof-
  4265   have "op + a ` op *\<^sub>R c ` s = (\<lambda>x. a + c *\<^sub>R x) ` s" by auto
  4266   thus ?thesis using compact_translation[OF compact_scaling[OF assms], of a c] by auto
  4267 qed
  4268 
  4269 text {* Hence we get the following. *}
  4270 
  4271 lemma compact_sup_maxdistance:
  4272   fixes s :: "'a::real_normed_vector set"
  4273   assumes "compact s"  "s \<noteq> {}"
  4274   shows "\<exists>x\<in>s. \<exists>y\<in>s. \<forall>u\<in>s. \<forall>v\<in>s. norm(u - v) \<le> norm(x - y)"
  4275 proof-
  4276   have "{x - y | x y . x\<in>s \<and> y\<in>s} \<noteq> {}" using `s \<noteq> {}` by auto
  4277   then obtain x where x:"x\<in>{x - y |x y. x \<in> s \<and> y \<in> s}"  "\<forall>y\<in>{x - y |x y. x \<in> s \<and> y \<in> s}. norm y \<le> norm x"
  4278     using compact_differences[OF assms(1) assms(1)]
  4279     using distance_attains_sup[where 'a="'a", unfolded dist_norm, of "{x - y | x y . x\<in>s \<and> y\<in>s}" 0] by auto
  4280   from x(1) obtain a b where "a\<in>s" "b\<in>s" "x = a - b" by auto
  4281   thus ?thesis using x(2)[unfolded `x = a - b`] by blast
  4282 qed
  4283 
  4284 text {* We can state this in terms of diameter of a set. *}
  4285 
  4286 definition "diameter s = (if s = {} then 0::real else Sup {norm(x - y) | x y. x \<in> s \<and> y \<in> s})"
  4287   (* TODO: generalize to class metric_space *)
  4288 
  4289 lemma diameter_bounded:
  4290   assumes "bounded s"
  4291   shows "\<forall>x\<in>s. \<forall>y\<in>s. norm(x - y) \<le> diameter s"
  4292         "\<forall>d>0. d < diameter s --> (\<exists>x\<in>s. \<exists>y\<in>s. norm(x - y) > d)"
  4293 proof-
  4294   let ?D = "{norm (x - y) |x y. x \<in> s \<and> y \<in> s}"
  4295   obtain a where a:"\<forall>x\<in>s. norm x \<le> a" using assms[unfolded bounded_iff] by auto
  4296   { fix x y assume "x \<in> s" "y \<in> s"
  4297     hence "norm (x - y) \<le> 2 * a" using norm_triangle_ineq[of x "-y", unfolded norm_minus_cancel] a[THEN bspec[where x=x]] a[THEN bspec[where x=y]] by (auto simp add: field_simps)  }
  4298   note * = this
  4299   { fix x y assume "x\<in>s" "y\<in>s"  hence "s \<noteq> {}" by auto
  4300     have "norm(x - y) \<le> diameter s" unfolding diameter_def using `s\<noteq>{}` *[OF `x\<in>s` `y\<in>s`] `x\<in>s` `y\<in>s`
  4301       by simp (blast del: Sup_upper intro!: * Sup_upper) }
  4302   moreover
  4303   { fix d::real assume "d>0" "d < diameter s"
  4304     hence "s\<noteq>{}" unfolding diameter_def by auto
  4305     have "\<exists>d' \<in> ?D. d' > d"
  4306     proof(rule ccontr)
  4307       assume "\<not> (\<exists>d'\<in>{norm (x - y) |x y. x \<in> s \<and> y \<in> s}. d < d')"
  4308       hence "\<forall>d'\<in>?D. d' \<le> d" by auto (metis not_leE) 
  4309       thus False using `d < diameter s` `s\<noteq>{}` 
  4310         apply (auto simp add: diameter_def) 
  4311         apply (drule Sup_real_iff [THEN [2] rev_iffD2])
  4312         apply (auto, force) 
  4313         done
  4314     qed
  4315     hence "\<exists>x\<in>s. \<exists>y\<in>s. norm(x - y) > d" by auto  }
  4316   ultimately show "\<forall>x\<in>s. \<forall>y\<in>s. norm(x - y) \<le> diameter s"
  4317         "\<forall>d>0. d < diameter s --> (\<exists>x\<in>s. \<exists>y\<in>s. norm(x - y) > d)" by auto
  4318 qed
  4319 
  4320 lemma diameter_bounded_bound:
  4321  "bounded s \<Longrightarrow> x \<in> s \<Longrightarrow> y \<in> s ==> norm(x - y) \<le> diameter s"
  4322   using diameter_bounded by blast
  4323 
  4324 lemma diameter_compact_attained:
  4325   fixes s :: "'a::real_normed_vector set"
  4326   assumes "compact s"  "s \<noteq> {}"
  4327   shows "\<exists>x\<in>s. \<exists>y\<in>s. (norm(x - y) = diameter s)"
  4328 proof-
  4329   have b:"bounded s" using assms(1) by (rule compact_imp_bounded)
  4330   then obtain x y where xys:"x\<in>s" "y\<in>s" and xy:"\<forall>u\<in>s. \<forall>v\<in>s. norm (u - v) \<le> norm (x - y)" using compact_sup_maxdistance[OF assms] by auto
  4331   hence "diameter s \<le> norm (x - y)"
  4332     unfolding diameter_def by clarsimp (rule Sup_least, fast+)
  4333   thus ?thesis
  4334     by (metis b diameter_bounded_bound order_antisym xys)
  4335 qed
  4336 
  4337 text {* Related results with closure as the conclusion. *}
  4338 
  4339 lemma closed_scaling:
  4340   fixes s :: "'a::real_normed_vector set"
  4341   assumes "closed s" shows "closed ((\<lambda>x. c *\<^sub>R x) ` s)"
  4342 proof(cases "s={}")
  4343   case True thus ?thesis by auto
  4344 next
  4345   case False
  4346   show ?thesis
  4347   proof(cases "c=0")
  4348     have *:"(\<lambda>x. 0) ` s = {0}" using `s\<noteq>{}` by auto
  4349     case True thus ?thesis apply auto unfolding * by auto
  4350   next
  4351     case False
  4352     { fix x l assume as:"\<forall>n::nat. x n \<in> scaleR c ` s"  "(x ---> l) sequentially"
  4353       { fix n::nat have "scaleR (1 / c) (x n) \<in> s"
  4354           using as(1)[THEN spec[where x=n]]
  4355           using `c\<noteq>0` by auto
  4356       }
  4357       moreover
  4358       { fix e::real assume "e>0"
  4359         hence "0 < e *\<bar>c\<bar>"  using `c\<noteq>0` mult_pos_pos[of e "abs c"] by auto
  4360         then obtain N where "\<forall>n\<ge>N. dist (x n) l < e * \<bar>c\<bar>"
  4361           using as(2)[unfolded LIMSEQ_def, THEN spec[where x="e * abs c"]] by auto
  4362         hence "\<exists>N. \<forall>n\<ge>N. dist (scaleR (1 / c) (x n)) (scaleR (1 / c) l) < e"
  4363           unfolding dist_norm unfolding scaleR_right_diff_distrib[THEN sym]
  4364           using mult_imp_div_pos_less[of "abs c" _ e] `c\<noteq>0` by auto  }
  4365       hence "((\<lambda>n. scaleR (1 / c) (x n)) ---> scaleR (1 / c) l) sequentially" unfolding LIMSEQ_def by auto
  4366       ultimately have "l \<in> scaleR c ` s"
  4367         using assms[unfolded closed_sequential_limits, THEN spec[where x="\<lambda>n. scaleR (1/c) (x n)"], THEN spec[where x="scaleR (1/c) l"]]
  4368         unfolding image_iff using `c\<noteq>0` apply(rule_tac x="scaleR (1 / c) l" in bexI) by auto  }
  4369     thus ?thesis unfolding closed_sequential_limits by fast
  4370   qed
  4371 qed
  4372 
  4373 lemma closed_negations:
  4374   fixes s :: "'a::real_normed_vector set"
  4375   assumes "closed s"  shows "closed ((\<lambda>x. -x) ` s)"
  4376   using closed_scaling[OF assms, of "- 1"] by simp
  4377 
  4378 lemma compact_closed_sums:
  4379   fixes s :: "'a::real_normed_vector set"
  4380   assumes "compact s"  "closed t"  shows "closed {x + y | x y. x \<in> s \<and> y \<in> t}"
  4381 proof-
  4382   let ?S = "{x + y |x y. x \<in> s \<and> y \<in> t}"
  4383   { fix x l assume as:"\<forall>n. x n \<in> ?S"  "(x ---> l) sequentially"
  4384     from as(1) obtain f where f:"\<forall>n. x n = fst (f n) + snd (f n)"  "\<forall>n. fst (f n) \<in> s"  "\<forall>n. snd (f n) \<in> t"
  4385       using choice[of "\<lambda>n y. x n = (fst y) + (snd y) \<and> fst y \<in> s \<and> snd y \<in> t"] by auto
  4386     obtain l' r where "l'\<in>s" and r:"subseq r" and lr:"(((\<lambda>n. fst (f n)) \<circ> r) ---> l') sequentially"
  4387       using assms(1)[unfolded compact_def, THEN spec[where x="\<lambda> n. fst (f n)"]] using f(2) by auto
  4388     have "((\<lambda>n. snd (f (r n))) ---> l - l') sequentially"
  4389       using tendsto_diff[OF lim_subseq[OF r as(2)] lr] and f(1) unfolding o_def by auto
  4390     hence "l - l' \<in> t"
  4391       using assms(2)[unfolded closed_sequential_limits, THEN spec[where x="\<lambda> n. snd (f (r n))"], THEN spec[where x="l - l'"]]
  4392       using f(3) by auto
  4393     hence "l \<in> ?S" using `l' \<in> s` apply auto apply(rule_tac x=l' in exI) apply(rule_tac x="l - l'" in exI) by auto
  4394   }
  4395   thus ?thesis unfolding closed_sequential_limits by fast
  4396 qed
  4397 
  4398 lemma closed_compact_sums:
  4399   fixes s t :: "'a::real_normed_vector set"
  4400   assumes "closed s"  "compact t"
  4401   shows "closed {x + y | x y. x \<in> s \<and> y \<in> t}"
  4402 proof-
  4403   have "{x + y |x y. x \<in> t \<and> y \<in> s} = {x + y |x y. x \<in> s \<and> y \<in> t}" apply auto
  4404     apply(rule_tac x=y in exI) apply auto apply(rule_tac x=y in exI) by auto
  4405   thus ?thesis using compact_closed_sums[OF assms(2,1)] by simp
  4406 qed
  4407 
  4408 lemma compact_closed_differences:
  4409   fixes s t :: "'a::real_normed_vector set"
  4410   assumes "compact s"  "closed t"
  4411   shows "closed {x - y | x y. x \<in> s \<and> y \<in> t}"
  4412 proof-
  4413   have "{x + y |x y. x \<in> s \<and> y \<in> uminus ` t} =  {x - y |x y. x \<in> s \<and> y \<in> t}"
  4414     apply auto apply(rule_tac x=xa in exI) apply auto apply(rule_tac x=xa in exI) by auto
  4415   thus ?thesis using compact_closed_sums[OF assms(1) closed_negations[OF assms(2)]] by auto
  4416 qed
  4417 
  4418 lemma closed_compact_differences:
  4419   fixes s t :: "'a::real_normed_vector set"
  4420   assumes "closed s" "compact t"
  4421   shows "closed {x - y | x y. x \<in> s \<and> y \<in> t}"
  4422 proof-
  4423   have "{x + y |x y. x \<in> s \<and> y \<in> uminus ` t} = {x - y |x y. x \<in> s \<and> y \<in> t}"
  4424     apply auto apply(rule_tac x=xa in exI) apply auto apply(rule_tac x=xa in exI) by auto
  4425  thus ?thesis using closed_compact_sums[OF assms(1) compact_negations[OF assms(2)]] by simp
  4426 qed
  4427 
  4428 lemma closed_translation:
  4429   fixes a :: "'a::real_normed_vector"
  4430   assumes "closed s"  shows "closed ((\<lambda>x. a + x) ` s)"
  4431 proof-
  4432   have "{a + y |y. y \<in> s} = (op + a ` s)" by auto
  4433   thus ?thesis using compact_closed_sums[OF compact_sing[of a] assms] by auto
  4434 qed
  4435 
  4436 lemma translation_Compl:
  4437   fixes a :: "'a::ab_group_add"
  4438   shows "(\<lambda>x. a + x) ` (- t) = - ((\<lambda>x. a + x) ` t)"
  4439   apply (auto simp add: image_iff) apply(rule_tac x="x - a" in bexI) by auto
  4440 
  4441 lemma translation_UNIV:
  4442   fixes a :: "'a::ab_group_add" shows "range (\<lambda>x. a + x) = UNIV"
  4443   apply (auto simp add: image_iff) apply(rule_tac x="x - a" in exI) by auto
  4444 
  4445 lemma translation_diff:
  4446   fixes a :: "'a::ab_group_add"
  4447   shows "(\<lambda>x. a + x) ` (s - t) = ((\<lambda>x. a + x) ` s) - ((\<lambda>x. a + x) ` t)"
  4448   by auto
  4449 
  4450 lemma closure_translation:
  4451   fixes a :: "'a::real_normed_vector"
  4452   shows "closure ((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (closure s)"
  4453 proof-
  4454   have *:"op + a ` (- s) = - op + a ` s"
  4455     apply auto unfolding image_iff apply(rule_tac x="x - a" in bexI) by auto
  4456   show ?thesis unfolding closure_interior translation_Compl
  4457     using interior_translation[of a "- s"] unfolding * by auto
  4458 qed
  4459 
  4460 lemma frontier_translation:
  4461   fixes a :: "'a::real_normed_vector"
  4462   shows "frontier((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (frontier s)"
  4463   unfolding frontier_def translation_diff interior_translation closure_translation by auto
  4464 
  4465 
  4466 subsection {* Separation between points and sets *}
  4467 
  4468 lemma separate_point_closed:
  4469   fixes s :: "'a::heine_borel set"
  4470   shows "closed s \<Longrightarrow> a \<notin> s  ==> (\<exists>d>0. \<forall>x\<in>s. d \<le> dist a x)"
  4471 proof(cases "s = {}")
  4472   case True
  4473   thus ?thesis by(auto intro!: exI[where x=1])
  4474 next
  4475   case False
  4476   assume "closed s" "a \<notin> s"
  4477   then obtain x where "x\<in>s" "\<forall>y\<in>s. dist a x \<le> dist a y" using `s \<noteq> {}` distance_attains_inf [of s a] by blast
  4478   with `x\<in>s` show ?thesis using dist_pos_lt[of a x] and`a \<notin> s` by blast
  4479 qed
  4480 
  4481 lemma separate_compact_closed:
  4482   fixes s t :: "'a::{heine_borel, real_normed_vector} set"
  4483     (* TODO: does this generalize to heine_borel? *)
  4484   assumes "compact s" and "closed t" and "s \<inter> t = {}"
  4485   shows "\<exists>d>0. \<forall>x\<in>s. \<forall>y\<in>t. d \<le> dist x y"
  4486 proof-
  4487   have "0 \<notin> {x - y |x y. x \<in> s \<and> y \<in> t}" using assms(3) by auto
  4488   then obtain d where "d>0" and d:"\<forall>x\<in>{x - y |x y. x \<in> s \<and> y \<in> t}. d \<le> dist 0 x"
  4489     using separate_point_closed[OF compact_closed_differences[OF assms(1,2)], of 0] by auto
  4490   { fix x y assume "x\<in>s" "y\<in>t"
  4491     hence "x - y \<in> {x - y |x y. x \<in> s \<and> y \<in> t}" by auto
  4492     hence "d \<le> dist (x - y) 0" using d[THEN bspec[where x="x - y"]] using dist_commute
  4493       by (auto  simp add: dist_commute)
  4494     hence "d \<le> dist x y" unfolding dist_norm by auto  }
  4495   thus ?thesis using `d>0` by auto
  4496 qed
  4497 
  4498 lemma separate_closed_compact:
  4499   fixes s t :: "'a::{heine_borel, real_normed_vector} set"
  4500   assumes "closed s" and "compact t" and "s \<inter> t = {}"
  4501   shows "\<exists>d>0. \<forall>x\<in>s. \<forall>y\<in>t. d \<le> dist x y"
  4502 proof-
  4503   have *:"t \<inter> s = {}" using assms(3) by auto
  4504   show ?thesis using separate_compact_closed[OF assms(2,1) *]
  4505     apply auto apply(rule_tac x=d in exI) apply auto apply (erule_tac x=y in ballE)
  4506     by (auto simp add: dist_commute)
  4507 qed
  4508 
  4509 
  4510 subsection {* Intervals *}
  4511   
  4512 lemma interval: fixes a :: "'a::ordered_euclidean_space" shows
  4513   "{a <..< b} = {x::'a. \<forall>i<DIM('a). a$$i < x$$i \<and> x$$i < b$$i}" and
  4514   "{a .. b} = {x::'a. \<forall>i<DIM('a). a$$i \<le> x$$i \<and> x$$i \<le> b$$i}"
  4515   by(auto simp add:set_eq_iff eucl_le[where 'a='a] eucl_less[where 'a='a])
  4516 
  4517 lemma mem_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4518   "x \<in> {a<..<b} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i < x$$i \<and> x$$i < b$$i)"
  4519   "x \<in> {a .. b} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i \<le> x$$i \<and> x$$i \<le> b$$i)"
  4520   using interval[of a b] by(auto simp add: set_eq_iff eucl_le[where 'a='a] eucl_less[where 'a='a])
  4521 
  4522 lemma interval_eq_empty: fixes a :: "'a::ordered_euclidean_space" shows
  4523  "({a <..< b} = {} \<longleftrightarrow> (\<exists>i<DIM('a). b$$i \<le> a$$i))" (is ?th1) and
  4524  "({a  ..  b} = {} \<longleftrightarrow> (\<exists>i<DIM('a). b$$i < a$$i))" (is ?th2)
  4525 proof-
  4526   { fix i x assume i:"i<DIM('a)" and as:"b$$i \<le> a$$i" and x:"x\<in>{a <..< b}"
  4527     hence "a $$ i < x $$ i \<and> x $$ i < b $$ i" unfolding mem_interval by auto
  4528     hence "a$$i < b$$i" by auto
  4529     hence False using as by auto  }
  4530   moreover
  4531   { assume as:"\<forall>i<DIM('a). \<not> (b$$i \<le> a$$i)"
  4532     let ?x = "(1/2) *\<^sub>R (a + b)"
  4533     { fix i assume i:"i<DIM('a)" 
  4534       have "a$$i < b$$i" using as[THEN spec[where x=i]] using i by auto
  4535       hence "a$$i < ((1/2) *\<^sub>R (a+b)) $$ i" "((1/2) *\<^sub>R (a+b)) $$ i < b$$i"
  4536         unfolding euclidean_simps by auto }
  4537     hence "{a <..< b} \<noteq> {}" using mem_interval(1)[of "?x" a b] by auto  }
  4538   ultimately show ?th1 by blast
  4539 
  4540   { fix i x assume i:"i<DIM('a)" and as:"b$$i < a$$i" and x:"x\<in>{a .. b}"
  4541     hence "a $$ i \<le> x $$ i \<and> x $$ i \<le> b $$ i" unfolding mem_interval by auto
  4542     hence "a$$i \<le> b$$i" by auto
  4543     hence False using as by auto  }
  4544   moreover
  4545   { assume as:"\<forall>i<DIM('a). \<not> (b$$i < a$$i)"
  4546     let ?x = "(1/2) *\<^sub>R (a + b)"
  4547     { fix i assume i:"i<DIM('a)"
  4548       have "a$$i \<le> b$$i" using as[THEN spec[where x=i]] by auto
  4549       hence "a$$i \<le> ((1/2) *\<^sub>R (a+b)) $$ i" "((1/2) *\<^sub>R (a+b)) $$ i \<le> b$$i"
  4550         unfolding euclidean_simps by auto }
  4551     hence "{a .. b} \<noteq> {}" using mem_interval(2)[of "?x" a b] by auto  }
  4552   ultimately show ?th2 by blast
  4553 qed
  4554 
  4555 lemma interval_ne_empty: fixes a :: "'a::ordered_euclidean_space" shows
  4556   "{a  ..  b} \<noteq> {} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i \<le> b$$i)" and
  4557   "{a <..< b} \<noteq> {} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i < b$$i)"
  4558   unfolding interval_eq_empty[of a b] by fastforce+
  4559 
  4560 lemma interval_sing:
  4561   fixes a :: "'a::ordered_euclidean_space"
  4562   shows "{a .. a} = {a}" and "{a<..<a} = {}"
  4563   unfolding set_eq_iff mem_interval eq_iff [symmetric]
  4564   by (auto simp add: euclidean_eq[where 'a='a] eq_commute
  4565     eucl_less[where 'a='a] eucl_le[where 'a='a])
  4566 
  4567 lemma subset_interval_imp: fixes a :: "'a::ordered_euclidean_space" shows
  4568  "(\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i) \<Longrightarrow> {c .. d} \<subseteq> {a .. b}" and
  4569  "(\<forall>i<DIM('a). a$$i < c$$i \<and> d$$i < b$$i) \<Longrightarrow> {c .. d} \<subseteq> {a<..<b}" and
  4570  "(\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i) \<Longrightarrow> {c<..<d} \<subseteq> {a .. b}" and
  4571  "(\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i) \<Longrightarrow> {c<..<d} \<subseteq> {a<..<b}"
  4572   unfolding subset_eq[unfolded Ball_def] unfolding mem_interval
  4573   by (best intro: order_trans less_le_trans le_less_trans less_imp_le)+
  4574 
  4575 lemma interval_open_subset_closed:
  4576   fixes a :: "'a::ordered_euclidean_space"
  4577   shows "{a<..<b} \<subseteq> {a .. b}"
  4578   unfolding subset_eq [unfolded Ball_def] mem_interval
  4579   by (fast intro: less_imp_le)
  4580 
  4581 lemma subset_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4582  "{c .. d} \<subseteq> {a .. b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i \<le> d$$i) --> (\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i)" (is ?th1) and
  4583  "{c .. d} \<subseteq> {a<..<b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i \<le> d$$i) --> (\<forall>i<DIM('a). a$$i < c$$i \<and> d$$i < b$$i)" (is ?th2) and
  4584  "{c<..<d} \<subseteq> {a .. b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i < d$$i) --> (\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i)" (is ?th3) and
  4585  "{c<..<d} \<subseteq> {a<..<b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i < d$$i) --> (\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i)" (is ?th4)
  4586 proof-
  4587   show ?th1 unfolding subset_eq and Ball_def and mem_interval by (auto intro: order_trans)
  4588   show ?th2 unfolding subset_eq and Ball_def and mem_interval by (auto intro: le_less_trans less_le_trans order_trans less_imp_le)
  4589   { assume as: "{c<..<d} \<subseteq> {a .. b}" "\<forall>i<DIM('a). c$$i < d$$i"
  4590     hence "{c<..<d} \<noteq> {}" unfolding interval_eq_empty by auto
  4591     fix i assume i:"i<DIM('a)"
  4592     (** TODO combine the following two parts as done in the HOL_light version. **)
  4593     { let ?x = "(\<chi>\<chi> j. (if j=i then ((min (a$$j) (d$$j))+c$$j)/2 else (c$$j+d$$j)/2))::'a"
  4594       assume as2: "a$$i > c$$i"
  4595       { fix j assume j:"j<DIM('a)"
  4596         hence "c $$ j < ?x $$ j \<and> ?x $$ j < d $$ j"
  4597           apply(cases "j=i") using as(2)[THEN spec[where x=j]] i
  4598           by (auto simp add: as2)  }
  4599       hence "?x\<in>{c<..<d}" using i unfolding mem_interval by auto
  4600       moreover
  4601       have "?x\<notin>{a .. b}"
  4602         unfolding mem_interval apply auto apply(rule_tac x=i in exI)
  4603         using as(2)[THEN spec[where x=i]] and as2 i
  4604         by auto
  4605       ultimately have False using as by auto  }
  4606     hence "a$$i \<le> c$$i" by(rule ccontr)auto
  4607     moreover
  4608     { let ?x = "(\<chi>\<chi> j. (if j=i then ((max (b$$j) (c$$j))+d$$j)/2 else (c$$j+d$$j)/2))::'a"
  4609       assume as2: "b$$i < d$$i"
  4610       { fix j assume "j<DIM('a)"
  4611         hence "d $$ j > ?x $$ j \<and> ?x $$ j > c $$ j" 
  4612           apply(cases "j=i") using as(2)[THEN spec[where x=j]]
  4613           by (auto simp add: as2)  }
  4614       hence "?x\<in>{c<..<d}" unfolding mem_interval by auto
  4615       moreover
  4616       have "?x\<notin>{a .. b}"
  4617         unfolding mem_interval apply auto apply(rule_tac x=i in exI)
  4618         using as(2)[THEN spec[where x=i]] and as2 using i
  4619         by auto
  4620       ultimately have False using as by auto  }
  4621     hence "b$$i \<ge> d$$i" by(rule ccontr)auto
  4622     ultimately
  4623     have "a$$i \<le> c$$i \<and> d$$i \<le> b$$i" by auto
  4624   } note part1 = this
  4625   show ?th3 unfolding subset_eq and Ball_def and mem_interval 
  4626     apply(rule,rule,rule,rule) apply(rule part1) unfolding subset_eq and Ball_def and mem_interval
  4627     prefer 4 apply auto by(erule_tac x=i in allE,erule_tac x=i in allE,fastforce)+ 
  4628   { assume as:"{c<..<d} \<subseteq> {a<..<b}" "\<forall>i<DIM('a). c$$i < d$$i"
  4629     fix i assume i:"i<DIM('a)"
  4630     from as(1) have "{c<..<d} \<subseteq> {a..b}" using interval_open_subset_closed[of a b] by auto
  4631     hence "a$$i \<le> c$$i \<and> d$$i \<le> b$$i" using part1 and as(2) using i by auto  } note * = this
  4632   show ?th4 unfolding subset_eq and Ball_def and mem_interval 
  4633     apply(rule,rule,rule,rule) apply(rule *) unfolding subset_eq and Ball_def and mem_interval prefer 4
  4634     apply auto by(erule_tac x=i in allE, simp)+ 
  4635 qed
  4636 
  4637 lemma disjoint_interval: fixes a::"'a::ordered_euclidean_space" shows
  4638   "{a .. b} \<inter> {c .. d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i < a$$i \<or> d$$i < c$$i \<or> b$$i < c$$i \<or> d$$i < a$$i))" (is ?th1) and
  4639   "{a .. b} \<inter> {c<..<d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i < a$$i \<or> d$$i \<le> c$$i \<or> b$$i \<le> c$$i \<or> d$$i \<le> a$$i))" (is ?th2) and
  4640   "{a<..<b} \<inter> {c .. d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i \<le> a$$i \<or> d$$i < c$$i \<or> b$$i \<le> c$$i \<or> d$$i \<le> a$$i))" (is ?th3) and
  4641   "{a<..<b} \<inter> {c<..<d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i \<le> a$$i \<or> d$$i \<le> c$$i \<or> b$$i \<le> c$$i \<or> d$$i \<le> a$$i))" (is ?th4)
  4642 proof-
  4643   let ?z = "(\<chi>\<chi> i. ((max (a$$i) (c$$i)) + (min (b$$i) (d$$i))) / 2)::'a"
  4644   note * = set_eq_iff Int_iff empty_iff mem_interval all_conj_distrib[THEN sym] eq_False
  4645   show ?th1 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4646     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4647   show ?th2 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4648     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4649   show ?th3 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4650     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4651   show ?th4 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4652     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4653 qed
  4654 
  4655 lemma inter_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4656  "{a .. b} \<inter> {c .. d} =  {(\<chi>\<chi> i. max (a$$i) (c$$i)) .. (\<chi>\<chi> i. min (b$$i) (d$$i))}"
  4657   unfolding set_eq_iff and Int_iff and mem_interval
  4658   by auto
  4659 
  4660 (* Moved interval_open_subset_closed a bit upwards *)
  4661 
  4662 lemma open_interval[intro]:
  4663   fixes a b :: "'a::ordered_euclidean_space" shows "open {a<..<b}"
  4664 proof-
  4665   have "open (\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i<..<b$$i})"
  4666     by (intro open_INT finite_lessThan ballI continuous_open_vimage allI
  4667       linear_continuous_at bounded_linear_euclidean_component
  4668       open_real_greaterThanLessThan)
  4669   also have "(\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i<..<b$$i}) = {a<..<b}"
  4670     by (auto simp add: eucl_less [where 'a='a])
  4671   finally show "open {a<..<b}" .
  4672 qed
  4673 
  4674 lemma closed_interval[intro]:
  4675   fixes a b :: "'a::ordered_euclidean_space" shows "closed {a .. b}"
  4676 proof-
  4677   have "closed (\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i .. b$$i})"
  4678     by (intro closed_INT ballI continuous_closed_vimage allI
  4679       linear_continuous_at bounded_linear_euclidean_component
  4680       closed_real_atLeastAtMost)
  4681   also have "(\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i .. b$$i}) = {a .. b}"
  4682     by (auto simp add: eucl_le [where 'a='a])
  4683   finally show "closed {a .. b}" .
  4684 qed
  4685 
  4686 lemma interior_closed_interval [intro]:
  4687   fixes a b :: "'a::ordered_euclidean_space"
  4688   shows "interior {a..b} = {a<..<b}" (is "?L = ?R")
  4689 proof(rule subset_antisym)
  4690   show "?R \<subseteq> ?L" using interval_open_subset_closed open_interval
  4691     by (rule interior_maximal)
  4692 next
  4693   { fix x assume "x \<in> interior {a..b}"
  4694     then obtain s where s:"open s" "x \<in> s" "s \<subseteq> {a..b}" ..
  4695     then obtain e where "e>0" and e:"\<forall>x'. dist x' x < e \<longrightarrow> x' \<in> {a..b}" unfolding open_dist and subset_eq by auto
  4696     { fix i assume i:"i<DIM('a)"
  4697       have "dist (x - (e / 2) *\<^sub>R basis i) x < e"
  4698            "dist (x + (e / 2) *\<^sub>R basis i) x < e"
  4699         unfolding dist_norm apply auto
  4700         unfolding norm_minus_cancel using norm_basis and `e>0` by auto
  4701       hence "a $$ i \<le> (x - (e / 2) *\<^sub>R basis i) $$ i"
  4702                      "(x + (e / 2) *\<^sub>R basis i) $$ i \<le> b $$ i"
  4703         using e[THEN spec[where x="x - (e/2) *\<^sub>R basis i"]]
  4704         and   e[THEN spec[where x="x + (e/2) *\<^sub>R basis i"]]
  4705         unfolding mem_interval using i by blast+
  4706       hence "a $$ i < x $$ i" and "x $$ i < b $$ i" unfolding euclidean_simps
  4707         unfolding basis_component using `e>0` i by auto  }
  4708     hence "x \<in> {a<..<b}" unfolding mem_interval by auto  }
  4709   thus "?L \<subseteq> ?R" ..
  4710 qed
  4711 
  4712 lemma bounded_closed_interval: fixes a :: "'a::ordered_euclidean_space" shows "bounded {a .. b}"
  4713 proof-
  4714   let ?b = "\<Sum>i<DIM('a). \<bar>a$$i\<bar> + \<bar>b$$i\<bar>"
  4715   { fix x::"'a" assume x:"\<forall>i<DIM('a). a $$ i \<le> x $$ i \<and> x $$ i \<le> b $$ i"
  4716     { fix i assume "i<DIM('a)"
  4717       hence "\<bar>x$$i\<bar> \<le> \<bar>a$$i\<bar> + \<bar>b$$i\<bar>" using x[THEN spec[where x=i]] by auto  }
  4718     hence "(\<Sum>i<DIM('a). \<bar>x $$ i\<bar>) \<le> ?b" apply-apply(rule setsum_mono) by auto
  4719     hence "norm x \<le> ?b" using norm_le_l1[of x] by auto  }
  4720   thus ?thesis unfolding interval and bounded_iff by auto
  4721 qed
  4722 
  4723 lemma bounded_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4724  "bounded {a .. b} \<and> bounded {a<..<b}"
  4725   using bounded_closed_interval[of a b]
  4726   using interval_open_subset_closed[of a b]
  4727   using bounded_subset[of "{a..b}" "{a<..<b}"]
  4728   by simp
  4729 
  4730 lemma not_interval_univ: fixes a :: "'a::ordered_euclidean_space" shows
  4731  "({a .. b} \<noteq> UNIV) \<and> ({a<..<b} \<noteq> UNIV)"
  4732   using bounded_interval[of a b] by auto
  4733 
  4734 lemma compact_interval: fixes a :: "'a::ordered_euclidean_space" shows "compact {a .. b}"
  4735   using bounded_closed_imp_compact[of "{a..b}"] using bounded_interval[of a b]
  4736   by auto
  4737 
  4738 lemma open_interval_midpoint: fixes a :: "'a::ordered_euclidean_space"
  4739   assumes "{a<..<b} \<noteq> {}" shows "((1/2) *\<^sub>R (a + b)) \<in> {a<..<b}"
  4740 proof-
  4741   { fix i assume "i<DIM('a)"
  4742     hence "a $$ i < ((1 / 2) *\<^sub>R (a + b)) $$ i \<and> ((1 / 2) *\<^sub>R (a + b)) $$ i < b $$ i"
  4743       using assms[unfolded interval_ne_empty, THEN spec[where x=i]]
  4744       unfolding euclidean_simps by auto  }
  4745   thus ?thesis unfolding mem_interval by auto
  4746 qed
  4747 
  4748 lemma open_closed_interval_convex: fixes x :: "'a::ordered_euclidean_space"
  4749   assumes x:"x \<in> {a<..<b}" and y:"y \<in> {a .. b}" and e:"0 < e" "e \<le> 1"
  4750   shows "(e *\<^sub>R x + (1 - e) *\<^sub>R y) \<in> {a<..<b}"
  4751 proof-
  4752   { fix i assume i:"i<DIM('a)"
  4753     have "a $$ i = e * a$$i + (1 - e) * a$$i" unfolding left_diff_distrib by simp
  4754     also have "\<dots> < e * x $$ i + (1 - e) * y $$ i" apply(rule add_less_le_mono)
  4755       using e unfolding mult_less_cancel_left and mult_le_cancel_left apply simp_all
  4756       using x unfolding mem_interval using i apply simp
  4757       using y unfolding mem_interval using i apply simp
  4758       done
  4759     finally have "a $$ i < (e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i" unfolding euclidean_simps by auto
  4760     moreover {
  4761     have "b $$ i = e * b$$i + (1 - e) * b$$i" unfolding left_diff_distrib by simp
  4762     also have "\<dots> > e * x $$ i + (1 - e) * y $$ i" apply(rule add_less_le_mono)
  4763       using e unfolding mult_less_cancel_left and mult_le_cancel_left apply simp_all
  4764       using x unfolding mem_interval using i apply simp
  4765       using y unfolding mem_interval using i apply simp
  4766       done
  4767     finally have "(e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i < b $$ i" unfolding euclidean_simps by auto
  4768     } ultimately have "a $$ i < (e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i \<and> (e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i < b $$ i" by auto }
  4769   thus ?thesis unfolding mem_interval by auto
  4770 qed
  4771 
  4772 lemma closure_open_interval: fixes a :: "'a::ordered_euclidean_space"
  4773   assumes "{a<..<b} \<noteq> {}"
  4774   shows "closure {a<..<b} = {a .. b}"
  4775 proof-
  4776   have ab:"a < b" using assms[unfolded interval_ne_empty] apply(subst eucl_less) by auto
  4777   let ?c = "(1 / 2) *\<^sub>R (a + b)"
  4778   { fix x assume as:"x \<in> {a .. b}"
  4779     def f == "\<lambda>n::nat. x + (inverse (real n + 1)) *\<^sub>R (?c - x)"
  4780     { fix n assume fn:"f n < b \<longrightarrow> a < f n \<longrightarrow> f n = x" and xc:"x \<noteq> ?c"
  4781       have *:"0 < inverse (real n + 1)" "inverse (real n + 1) \<le> 1" unfolding inverse_le_1_iff by auto
  4782       have "(inverse (real n + 1)) *\<^sub>R ((1 / 2) *\<^sub>R (a + b)) + (1 - inverse (real n + 1)) *\<^sub>R x =
  4783         x + (inverse (real n + 1)) *\<^sub>R (((1 / 2) *\<^sub>R (a + b)) - x)"
  4784         by (auto simp add: algebra_simps)
  4785       hence "f n < b" and "a < f n" using open_closed_interval_convex[OF open_interval_midpoint[OF assms] as *] unfolding f_def by auto
  4786       hence False using fn unfolding f_def using xc by auto  }
  4787     moreover
  4788     { assume "\<not> (f ---> x) sequentially"
  4789       { fix e::real assume "e>0"
  4790         hence "\<exists>N::nat. inverse (real (N + 1)) < e" using real_arch_inv[of e] apply (auto simp add: Suc_pred') apply(rule_tac x="n - 1" in exI) by auto
  4791         then obtain N::nat where "inverse (real (N + 1)) < e" by auto
  4792         hence "\<forall>n\<ge>N. inverse (real n + 1) < e" by (auto, metis Suc_le_mono le_SucE less_imp_inverse_less nat_le_real_less order_less_trans real_of_nat_Suc real_of_nat_Suc_gt_zero)
  4793         hence "\<exists>N::nat. \<forall>n\<ge>N. inverse (real n + 1) < e" by auto  }
  4794       hence "((\<lambda>n. inverse (real n + 1)) ---> 0) sequentially"
  4795         unfolding LIMSEQ_def by(auto simp add: dist_norm)
  4796       hence "(f ---> x) sequentially" unfolding f_def
  4797         using tendsto_add[OF tendsto_const, of "\<lambda>n::nat. (inverse (real n + 1)) *\<^sub>R ((1 / 2) *\<^sub>R (a + b) - x)" 0 sequentially x]
  4798         using tendsto_scaleR [OF _ tendsto_const, of "\<lambda>n::nat. inverse (real n + 1)" 0 sequentially "((1 / 2) *\<^sub>R (a + b) - x)"] by auto  }
  4799     ultimately have "x \<in> closure {a<..<b}"
  4800       using as and open_interval_midpoint[OF assms] unfolding closure_def unfolding islimpt_sequential by(cases "x=?c")auto  }
  4801   thus ?thesis using closure_minimal[OF interval_open_subset_closed closed_interval, of a b] by blast
  4802 qed
  4803 
  4804 lemma bounded_subset_open_interval_symmetric: fixes s::"('a::ordered_euclidean_space) set"
  4805   assumes "bounded s"  shows "\<exists>a. s \<subseteq> {-a<..<a}"
  4806 proof-
  4807   obtain b where "b>0" and b:"\<forall>x\<in>s. norm x \<le> b" using assms[unfolded bounded_pos] by auto
  4808   def a \<equiv> "(\<chi>\<chi> i. b+1)::'a"
  4809   { fix x assume "x\<in>s"
  4810     fix i assume i:"i<DIM('a)"
  4811     hence "(-a)$$i < x$$i" and "x$$i < a$$i" using b[THEN bspec[where x=x], OF `x\<in>s`]
  4812       and component_le_norm[of x i] unfolding euclidean_simps and a_def by auto  }
  4813   thus ?thesis by(auto intro: exI[where x=a] simp add: eucl_less[where 'a='a])
  4814 qed
  4815 
  4816 lemma bounded_subset_open_interval:
  4817   fixes s :: "('a::ordered_euclidean_space) set"
  4818   shows "bounded s ==> (\<exists>a b. s \<subseteq> {a<..<b})"
  4819   by (auto dest!: bounded_subset_open_interval_symmetric)
  4820 
  4821 lemma bounded_subset_closed_interval_symmetric:
  4822   fixes s :: "('a::ordered_euclidean_space) set"
  4823   assumes "bounded s" shows "\<exists>a. s \<subseteq> {-a .. a}"
  4824 proof-
  4825   obtain a where "s \<subseteq> {- a<..<a}" using bounded_subset_open_interval_symmetric[OF assms] by auto
  4826   thus ?thesis using interval_open_subset_closed[of "-a" a] by auto
  4827 qed
  4828 
  4829 lemma bounded_subset_closed_interval:
  4830   fixes s :: "('a::ordered_euclidean_space) set"
  4831   shows "bounded s ==> (\<exists>a b. s \<subseteq> {a .. b})"
  4832   using bounded_subset_closed_interval_symmetric[of s] by auto
  4833 
  4834 lemma frontier_closed_interval:
  4835   fixes a b :: "'a::ordered_euclidean_space"
  4836   shows "frontier {a .. b} = {a .. b} - {a<..<b}"
  4837   unfolding frontier_def unfolding interior_closed_interval and closure_closed[OF closed_interval] ..
  4838 
  4839 lemma frontier_open_interval:
  4840   fixes a b :: "'a::ordered_euclidean_space"
  4841   shows "frontier {a<..<b} = (if {a<..<b} = {} then {} else {a .. b} - {a<..<b})"
  4842 proof(cases "{a<..<b} = {}")
  4843   case True thus ?thesis using frontier_empty by auto
  4844 next
  4845   case False thus ?thesis unfolding frontier_def and closure_open_interval[OF False] and interior_open[OF open_interval] by auto
  4846 qed
  4847 
  4848 lemma inter_interval_mixed_eq_empty: fixes a :: "'a::ordered_euclidean_space"
  4849   assumes "{c<..<d} \<noteq> {}"  shows "{a<..<b} \<inter> {c .. d} = {} \<longleftrightarrow> {a<..<b} \<inter> {c<..<d} = {}"
  4850   unfolding closure_open_interval[OF assms, THEN sym] unfolding open_inter_closure_eq_empty[OF open_interval] ..
  4851 
  4852 
  4853 (* Some stuff for half-infinite intervals too; FIXME: notation?  *)
  4854 
  4855 lemma closed_interval_left: fixes b::"'a::euclidean_space"
  4856   shows "closed {x::'a. \<forall>i<DIM('a). x$$i \<le> b$$i}"
  4857 proof-
  4858   { fix i assume i:"i<DIM('a)"
  4859     fix x::"'a" assume x:"\<forall>e>0. \<exists>x'\<in>{x. \<forall>i<DIM('a). x $$ i \<le> b $$ i}. x' \<noteq> x \<and> dist x' x < e"
  4860     { assume "x$$i > b$$i"
  4861       then obtain y where "y $$ i \<le> b $$ i"  "y \<noteq> x"  "dist y x < x$$i - b$$i"
  4862         using x[THEN spec[where x="x$$i - b$$i"]] using i by auto
  4863       hence False using component_le_norm[of "y - x" i] unfolding dist_norm euclidean_simps using i 
  4864         by auto   }
  4865     hence "x$$i \<le> b$$i" by(rule ccontr)auto  }
  4866   thus ?thesis unfolding closed_limpt unfolding islimpt_approachable by blast
  4867 qed
  4868 
  4869 lemma closed_interval_right: fixes a::"'a::euclidean_space"
  4870   shows "closed {x::'a. \<forall>i<DIM('a). a$$i \<le> x$$i}"
  4871 proof-
  4872   { fix i assume i:"i<DIM('a)"
  4873     fix x::"'a" assume x:"\<forall>e>0. \<exists>x'\<in>{x. \<forall>i<DIM('a). a $$ i \<le> x $$ i}. x' \<noteq> x \<and> dist x' x < e"
  4874     { assume "a$$i > x$$i"
  4875       then obtain y where "a $$ i \<le> y $$ i"  "y \<noteq> x"  "dist y x < a$$i - x$$i"
  4876         using x[THEN spec[where x="a$$i - x$$i"]] i by auto
  4877       hence False using component_le_norm[of "y - x" i] unfolding dist_norm and euclidean_simps by auto   }
  4878     hence "a$$i \<le> x$$i" by(rule ccontr)auto  }
  4879   thus ?thesis unfolding closed_limpt unfolding islimpt_approachable by blast
  4880 qed
  4881 
  4882 text {* Intervals in general, including infinite and mixtures of open and closed. *}
  4883 
  4884 definition "is_interval (s::('a::euclidean_space) set) \<longleftrightarrow>
  4885   (\<forall>a\<in>s. \<forall>b\<in>s. \<forall>x. (\<forall>i<DIM('a). ((a$$i \<le> x$$i \<and> x$$i \<le> b$$i) \<or> (b$$i \<le> x$$i \<and> x$$i \<le> a$$i))) \<longrightarrow> x \<in> s)"
  4886 
  4887 lemma is_interval_interval: "is_interval {a .. b::'a::ordered_euclidean_space}" (is ?th1)
  4888   "is_interval {a<..<b}" (is ?th2) proof -
  4889   show ?th1 ?th2  unfolding is_interval_def mem_interval Ball_def atLeastAtMost_iff
  4890     by(meson order_trans le_less_trans less_le_trans less_trans)+ qed
  4891 
  4892 lemma is_interval_empty:
  4893  "is_interval {}"
  4894   unfolding is_interval_def
  4895   by simp
  4896 
  4897 lemma is_interval_univ:
  4898  "is_interval UNIV"
  4899   unfolding is_interval_def
  4900   by simp
  4901 
  4902 
  4903 subsection {* Closure of halfspaces and hyperplanes *}
  4904 
  4905 lemma isCont_open_vimage:
  4906   assumes "\<And>x. isCont f x" and "open s" shows "open (f -` s)"
  4907 proof -
  4908   from assms(1) have "continuous_on UNIV f"
  4909     unfolding isCont_def continuous_on_def within_UNIV by simp
  4910   hence "open {x \<in> UNIV. f x \<in> s}"
  4911     using open_UNIV `open s` by (rule continuous_open_preimage)
  4912   thus "open (f -` s)"
  4913     by (simp add: vimage_def)
  4914 qed
  4915 
  4916 lemma isCont_closed_vimage:
  4917   assumes "\<And>x. isCont f x" and "closed s" shows "closed (f -` s)"
  4918   using assms unfolding closed_def vimage_Compl [symmetric]
  4919   by (rule isCont_open_vimage)
  4920 
  4921 lemma open_Collect_less:
  4922   fixes f g :: "'a::topological_space \<Rightarrow> real"
  4923   assumes f: "\<And>x. isCont f x"
  4924   assumes g: "\<And>x. isCont g x"
  4925   shows "open {x. f x < g x}"
  4926 proof -
  4927   have "open ((\<lambda>x. g x - f x) -` {0<..})"
  4928     using isCont_diff [OF g f] open_real_greaterThan
  4929     by (rule isCont_open_vimage)
  4930   also have "((\<lambda>x. g x - f x) -` {0<..}) = {x. f x < g x}"
  4931     by auto
  4932   finally show ?thesis .
  4933 qed
  4934 
  4935 lemma closed_Collect_le:
  4936   fixes f g :: "'a::topological_space \<Rightarrow> real"
  4937   assumes f: "\<And>x. isCont f x"
  4938   assumes g: "\<And>x. isCont g x"
  4939   shows "closed {x. f x \<le> g x}"
  4940 proof -
  4941   have "closed ((\<lambda>x. g x - f x) -` {0..})"
  4942     using isCont_diff [OF g f] closed_real_atLeast
  4943     by (rule isCont_closed_vimage)
  4944   also have "((\<lambda>x. g x - f x) -` {0..}) = {x. f x \<le> g x}"
  4945     by auto
  4946   finally show ?thesis .
  4947 qed
  4948 
  4949 lemma closed_Collect_eq:
  4950   fixes f g :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  4951   assumes f: "\<And>x. isCont f x"
  4952   assumes g: "\<And>x. isCont g x"
  4953   shows "closed {x. f x = g x}"
  4954 proof -
  4955   have "open {(x::'b, y::'b). x \<noteq> y}"
  4956     unfolding open_prod_def by (auto dest!: hausdorff)
  4957   hence "closed {(x::'b, y::'b). x = y}"
  4958     unfolding closed_def split_def Collect_neg_eq .
  4959   with isCont_Pair [OF f g]
  4960   have "closed ((\<lambda>x. (f x, g x)) -` {(x, y). x = y})"
  4961     by (rule isCont_closed_vimage)
  4962   also have "\<dots> = {x. f x = g x}" by auto
  4963   finally show ?thesis .
  4964 qed
  4965 
  4966 lemma continuous_at_inner: "continuous (at x) (inner a)"
  4967   unfolding continuous_at by (intro tendsto_intros)
  4968 
  4969 lemma continuous_at_euclidean_component[intro!, simp]: "continuous (at x) (\<lambda>x. x $$ i)"
  4970   unfolding euclidean_component_def by (rule continuous_at_inner)
  4971 
  4972 lemma closed_halfspace_le: "closed {x. inner a x \<le> b}"
  4973   by (simp add: closed_Collect_le)
  4974 
  4975 lemma closed_halfspace_ge: "closed {x. inner a x \<ge> b}"
  4976   by (simp add: closed_Collect_le)
  4977 
  4978 lemma closed_hyperplane: "closed {x. inner a x = b}"
  4979   by (simp add: closed_Collect_eq)
  4980 
  4981 lemma closed_halfspace_component_le:
  4982   shows "closed {x::'a::euclidean_space. x$$i \<le> a}"
  4983   by (simp add: closed_Collect_le)
  4984 
  4985 lemma closed_halfspace_component_ge:
  4986   shows "closed {x::'a::euclidean_space. x$$i \<ge> a}"
  4987   by (simp add: closed_Collect_le)
  4988 
  4989 text {* Openness of halfspaces. *}
  4990 
  4991 lemma open_halfspace_lt: "open {x. inner a x < b}"
  4992   by (simp add: open_Collect_less)
  4993 
  4994 lemma open_halfspace_gt: "open {x. inner a x > b}"
  4995   by (simp add: open_Collect_less)
  4996 
  4997 lemma open_halfspace_component_lt:
  4998   shows "open {x::'a::euclidean_space. x$$i < a}"
  4999   by (simp add: open_Collect_less)
  5000 
  5001 lemma open_halfspace_component_gt:
  5002   shows "open {x::'a::euclidean_space. x$$i > a}"
  5003   by (simp add: open_Collect_less)
  5004 
  5005 text{* Instantiation for intervals on @{text ordered_euclidean_space} *}
  5006 
  5007 lemma eucl_lessThan_eq_halfspaces:
  5008   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5009   shows "{..<a} = (\<Inter>i<DIM('a). {x. x $$ i < a $$ i})"
  5010  by (auto simp: eucl_less[where 'a='a])
  5011 
  5012 lemma eucl_greaterThan_eq_halfspaces:
  5013   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5014   shows "{a<..} = (\<Inter>i<DIM('a). {x. a $$ i < x $$ i})"
  5015  by (auto simp: eucl_less[where 'a='a])
  5016 
  5017 lemma eucl_atMost_eq_halfspaces:
  5018   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5019   shows "{.. a} = (\<Inter>i<DIM('a). {x. x $$ i \<le> a $$ i})"
  5020  by (auto simp: eucl_le[where 'a='a])
  5021 
  5022 lemma eucl_atLeast_eq_halfspaces:
  5023   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5024   shows "{a ..} = (\<Inter>i<DIM('a). {x. a $$ i \<le> x $$ i})"
  5025  by (auto simp: eucl_le[where 'a='a])
  5026 
  5027 lemma open_eucl_lessThan[simp, intro]:
  5028   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5029   shows "open {..< a}"
  5030   by (auto simp: eucl_lessThan_eq_halfspaces open_halfspace_component_lt)
  5031 
  5032 lemma open_eucl_greaterThan[simp, intro]:
  5033   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5034   shows "open {a <..}"
  5035   by (auto simp: eucl_greaterThan_eq_halfspaces open_halfspace_component_gt)
  5036 
  5037 lemma closed_eucl_atMost[simp, intro]:
  5038   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5039   shows "closed {.. a}"
  5040   unfolding eucl_atMost_eq_halfspaces
  5041   by (simp add: closed_INT closed_Collect_le)
  5042 
  5043 lemma closed_eucl_atLeast[simp, intro]:
  5044   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5045   shows "closed {a ..}"
  5046   unfolding eucl_atLeast_eq_halfspaces
  5047   by (simp add: closed_INT closed_Collect_le)
  5048 
  5049 lemma open_vimage_euclidean_component: "open S \<Longrightarrow> open ((\<lambda>x. x $$ i) -` S)"
  5050   by (auto intro!: continuous_open_vimage)
  5051 
  5052 text {* This gives a simple derivation of limit component bounds. *}
  5053 
  5054 lemma Lim_component_le: fixes f :: "'a \<Rightarrow> 'b::euclidean_space"
  5055   assumes "(f ---> l) net" "\<not> (trivial_limit net)"  "eventually (\<lambda>x. f(x)$$i \<le> b) net"
  5056   shows "l$$i \<le> b"
  5057 proof-
  5058   { fix x have "x \<in> {x::'b. inner (basis i) x \<le> b} \<longleftrightarrow> x$$i \<le> b"
  5059       unfolding euclidean_component_def by auto  } note * = this
  5060   show ?thesis using Lim_in_closed_set[of "{x. inner (basis i) x \<le> b}" f net l] unfolding *
  5061     using closed_halfspace_le[of "(basis i)::'b" b] and assms(1,2,3) by auto
  5062 qed
  5063 
  5064 lemma Lim_component_ge: fixes f :: "'a \<Rightarrow> 'b::euclidean_space"
  5065   assumes "(f ---> l) net"  "\<not> (trivial_limit net)"  "eventually (\<lambda>x. b \<le> (f x)$$i) net"
  5066   shows "b \<le> l$$i"
  5067 proof-
  5068   { fix x have "x \<in> {x::'b. inner (basis i) x \<ge> b} \<longleftrightarrow> x$$i \<ge> b"
  5069       unfolding euclidean_component_def by auto  } note * = this
  5070   show ?thesis using Lim_in_closed_set[of "{x. inner (basis i) x \<ge> b}" f net l] unfolding *
  5071     using closed_halfspace_ge[of b "(basis i)"] and assms(1,2,3) by auto
  5072 qed
  5073 
  5074 lemma Lim_component_eq: fixes f :: "'a \<Rightarrow> 'b::euclidean_space"
  5075   assumes net:"(f ---> l) net" "~(trivial_limit net)" and ev:"eventually (\<lambda>x. f(x)$$i = b) net"
  5076   shows "l$$i = b"
  5077   using ev[unfolded order_eq_iff eventually_conj_iff] using Lim_component_ge[OF net, of b i] and Lim_component_le[OF net, of i b] by auto
  5078 text{* Limits relative to a union.                                               *}
  5079 
  5080 lemma eventually_within_Un:
  5081   "eventually P (net within (s \<union> t)) \<longleftrightarrow>
  5082     eventually P (net within s) \<and> eventually P (net within t)"
  5083   unfolding Limits.eventually_within
  5084   by (auto elim!: eventually_rev_mp)
  5085 
  5086 lemma Lim_within_union:
  5087  "(f ---> l) (net within (s \<union> t)) \<longleftrightarrow>
  5088   (f ---> l) (net within s) \<and> (f ---> l) (net within t)"
  5089   unfolding tendsto_def
  5090   by (auto simp add: eventually_within_Un)
  5091 
  5092 lemma Lim_topological:
  5093  "(f ---> l) net \<longleftrightarrow>
  5094         trivial_limit net \<or>
  5095         (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) net)"
  5096   unfolding tendsto_def trivial_limit_eq by auto
  5097 
  5098 lemma continuous_on_union:
  5099   assumes "closed s" "closed t" "continuous_on s f" "continuous_on t f"
  5100   shows "continuous_on (s \<union> t) f"
  5101   using assms unfolding continuous_on Lim_within_union
  5102   unfolding Lim_topological trivial_limit_within closed_limpt by auto
  5103 
  5104 lemma continuous_on_cases:
  5105   assumes "closed s" "closed t" "continuous_on s f" "continuous_on t g"
  5106           "\<forall>x. (x\<in>s \<and> \<not> P x) \<or> (x \<in> t \<and> P x) \<longrightarrow> f x = g x"
  5107   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)"
  5108 proof-
  5109   let ?h = "(\<lambda>x. if P x then f x else g x)"
  5110   have "\<forall>x\<in>s. f x = (if P x then f x else g x)" using assms(5) by auto
  5111   hence "continuous_on s ?h" using continuous_on_eq[of s f ?h] using assms(3) by auto
  5112   moreover
  5113   have "\<forall>x\<in>t. g x = (if P x then f x else g x)" using assms(5) by auto
  5114   hence "continuous_on t ?h" using continuous_on_eq[of t g ?h] using assms(4) by auto
  5115   ultimately show ?thesis using continuous_on_union[OF assms(1,2), of ?h] by auto
  5116 qed
  5117 
  5118 
  5119 text{* Some more convenient intermediate-value theorem formulations.             *}
  5120 
  5121 lemma connected_ivt_hyperplane:
  5122   assumes "connected s" "x \<in> s" "y \<in> s" "inner a x \<le> b" "b \<le> inner a y"
  5123   shows "\<exists>z \<in> s. inner a z = b"
  5124 proof(rule ccontr)
  5125   assume as:"\<not> (\<exists>z\<in>s. inner a z = b)"
  5126   let ?A = "{x. inner a x < b}"
  5127   let ?B = "{x. inner a x > b}"
  5128   have "open ?A" "open ?B" using open_halfspace_lt and open_halfspace_gt by auto
  5129   moreover have "?A \<inter> ?B = {}" by auto
  5130   moreover have "s \<subseteq> ?A \<union> ?B" using as by auto
  5131   ultimately show False using assms(1)[unfolded connected_def not_ex, THEN spec[where x="?A"], THEN spec[where x="?B"]] and assms(2-5) by auto
  5132 qed
  5133 
  5134 lemma connected_ivt_component: fixes x::"'a::euclidean_space" shows
  5135  "connected s \<Longrightarrow> x \<in> s \<Longrightarrow> y \<in> s \<Longrightarrow> x$$k \<le> a \<Longrightarrow> a \<le> y$$k \<Longrightarrow> (\<exists>z\<in>s.  z$$k = a)"
  5136   using connected_ivt_hyperplane[of s x y "(basis k)::'a" a]
  5137   unfolding euclidean_component_def by auto
  5138 
  5139 
  5140 subsection {* Homeomorphisms *}
  5141 
  5142 definition "homeomorphism s t f g \<equiv>
  5143      (\<forall>x\<in>s. (g(f x) = x)) \<and> (f ` s = t) \<and> continuous_on s f \<and>
  5144      (\<forall>y\<in>t. (f(g y) = y)) \<and> (g ` t = s) \<and> continuous_on t g"
  5145 
  5146 definition
  5147   homeomorphic :: "'a::metric_space set \<Rightarrow> 'b::metric_space set \<Rightarrow> bool"
  5148     (infixr "homeomorphic" 60) where
  5149   homeomorphic_def: "s homeomorphic t \<equiv> (\<exists>f g. homeomorphism s t f g)"
  5150 
  5151 lemma homeomorphic_refl: "s homeomorphic s"
  5152   unfolding homeomorphic_def
  5153   unfolding homeomorphism_def
  5154   using continuous_on_id
  5155   apply(rule_tac x = "(\<lambda>x. x)" in exI)
  5156   apply(rule_tac x = "(\<lambda>x. x)" in exI)
  5157   by blast
  5158 
  5159 lemma homeomorphic_sym:
  5160  "s homeomorphic t \<longleftrightarrow> t homeomorphic s"
  5161 unfolding homeomorphic_def
  5162 unfolding homeomorphism_def
  5163 by blast 
  5164 
  5165 lemma homeomorphic_trans:
  5166   assumes "s homeomorphic t" "t homeomorphic u" shows "s homeomorphic u"
  5167 proof-
  5168   obtain f1 g1 where fg1:"\<forall>x\<in>s. g1 (f1 x) = x"  "f1 ` s = t" "continuous_on s f1" "\<forall>y\<in>t. f1 (g1 y) = y" "g1 ` t = s" "continuous_on t g1"
  5169     using assms(1) unfolding homeomorphic_def homeomorphism_def by auto
  5170   obtain f2 g2 where fg2:"\<forall>x\<in>t. g2 (f2 x) = x"  "f2 ` t = u" "continuous_on t f2" "\<forall>y\<in>u. f2 (g2 y) = y" "g2 ` u = t" "continuous_on u g2"
  5171     using assms(2) unfolding homeomorphic_def homeomorphism_def by auto
  5172 
  5173   { fix x assume "x\<in>s" hence "(g1 \<circ> g2) ((f2 \<circ> f1) x) = x" using fg1(1)[THEN bspec[where x=x]] and fg2(1)[THEN bspec[where x="f1 x"]] and fg1(2) by auto }
  5174   moreover have "(f2 \<circ> f1) ` s = u" using fg1(2) fg2(2) by auto
  5175   moreover have "continuous_on s (f2 \<circ> f1)" using continuous_on_compose[OF fg1(3)] and fg2(3) unfolding fg1(2) by auto
  5176   moreover { fix y assume "y\<in>u" hence "(f2 \<circ> f1) ((g1 \<circ> g2) y) = y" using fg2(4)[THEN bspec[where x=y]] and fg1(4)[THEN bspec[where x="g2 y"]] and fg2(5) by auto }
  5177   moreover have "(g1 \<circ> g2) ` u = s" using fg1(5) fg2(5) by auto
  5178   moreover have "continuous_on u (g1 \<circ> g2)" using continuous_on_compose[OF fg2(6)] and fg1(6)  unfolding fg2(5) by auto
  5179   ultimately show ?thesis unfolding homeomorphic_def homeomorphism_def apply(rule_tac x="f2 \<circ> f1" in exI) apply(rule_tac x="g1 \<circ> g2" in exI) by auto
  5180 qed
  5181 
  5182 lemma homeomorphic_minimal:
  5183  "s homeomorphic t \<longleftrightarrow>
  5184     (\<exists>f g. (\<forall>x\<in>s. f(x) \<in> t \<and> (g(f(x)) = x)) \<and>
  5185            (\<forall>y\<in>t. g(y) \<in> s \<and> (f(g(y)) = y)) \<and>
  5186            continuous_on s f \<and> continuous_on t g)"
  5187 unfolding homeomorphic_def homeomorphism_def
  5188 apply auto apply (rule_tac x=f in exI) apply (rule_tac x=g in exI)
  5189 apply auto apply (rule_tac x=f in exI) apply (rule_tac x=g in exI) apply auto
  5190 unfolding image_iff
  5191 apply(erule_tac x="g x" in ballE) apply(erule_tac x="x" in ballE)
  5192 apply auto apply(rule_tac x="g x" in bexI) apply auto
  5193 apply(erule_tac x="f x" in ballE) apply(erule_tac x="x" in ballE)
  5194 apply auto apply(rule_tac x="f x" in bexI) by auto
  5195 
  5196 text {* Relatively weak hypotheses if a set is compact. *}
  5197 
  5198 lemma homeomorphism_compact:
  5199   fixes f :: "'a::heine_borel \<Rightarrow> 'b::heine_borel"
  5200     (* class constraint due to continuous_on_inv *)
  5201   assumes "compact s" "continuous_on s f"  "f ` s = t"  "inj_on f s"
  5202   shows "\<exists>g. homeomorphism s t f g"
  5203 proof-
  5204   def g \<equiv> "\<lambda>x. SOME y. y\<in>s \<and> f y = x"
  5205   have g:"\<forall>x\<in>s. g (f x) = x" using assms(3) assms(4)[unfolded inj_on_def] unfolding g_def by auto
  5206   { fix y assume "y\<in>t"
  5207     then obtain x where x:"f x = y" "x\<in>s" using assms(3) by auto
  5208     hence "g (f x) = x" using g by auto
  5209     hence "f (g y) = y" unfolding x(1)[THEN sym] by auto  }
  5210   hence g':"\<forall>x\<in>t. f (g x) = x" by auto
  5211   moreover
  5212   { fix x
  5213     have "x\<in>s \<Longrightarrow> x \<in> g ` t" using g[THEN bspec[where x=x]] unfolding image_iff using assms(3) by(auto intro!: bexI[where x="f x"])
  5214     moreover
  5215     { assume "x\<in>g ` t"
  5216       then obtain y where y:"y\<in>t" "g y = x" by auto
  5217       then obtain x' where x':"x'\<in>s" "f x' = y" using assms(3) by auto
  5218       hence "x \<in> s" unfolding g_def using someI2[of "\<lambda>b. b\<in>s \<and> f b = y" x' "\<lambda>x. x\<in>s"] unfolding y(2)[THEN sym] and g_def by auto }
  5219     ultimately have "x\<in>s \<longleftrightarrow> x \<in> g ` t" ..  }
  5220   hence "g ` t = s" by auto
  5221   ultimately
  5222   show ?thesis unfolding homeomorphism_def homeomorphic_def
  5223     apply(rule_tac x=g in exI) using g and assms(3) and continuous_on_inv[OF assms(2,1), of g, unfolded assms(3)] and assms(2) by auto
  5224 qed
  5225 
  5226 lemma homeomorphic_compact:
  5227   fixes f :: "'a::heine_borel \<Rightarrow> 'b::heine_borel"
  5228     (* class constraint due to continuous_on_inv *)
  5229   shows "compact s \<Longrightarrow> continuous_on s f \<Longrightarrow> (f ` s = t) \<Longrightarrow> inj_on f s
  5230           \<Longrightarrow> s homeomorphic t"
  5231   unfolding homeomorphic_def by (metis homeomorphism_compact)
  5232 
  5233 text{* Preservation of topological properties.                                   *}
  5234 
  5235 lemma homeomorphic_compactness:
  5236  "s homeomorphic t ==> (compact s \<longleftrightarrow> compact t)"
  5237 unfolding homeomorphic_def homeomorphism_def
  5238 by (metis compact_continuous_image)
  5239 
  5240 text{* Results on translation, scaling etc.                                      *}
  5241 
  5242 lemma homeomorphic_scaling:
  5243   fixes s :: "'a::real_normed_vector set"
  5244   assumes "c \<noteq> 0"  shows "s homeomorphic ((\<lambda>x. c *\<^sub>R x) ` s)"
  5245   unfolding homeomorphic_minimal
  5246   apply(rule_tac x="\<lambda>x. c *\<^sub>R x" in exI)
  5247   apply(rule_tac x="\<lambda>x. (1 / c) *\<^sub>R x" in exI)
  5248   using assms by (auto simp add: continuous_on_intros)
  5249 
  5250 lemma homeomorphic_translation:
  5251   fixes s :: "'a::real_normed_vector set"
  5252   shows "s homeomorphic ((\<lambda>x. a + x) ` s)"
  5253   unfolding homeomorphic_minimal
  5254   apply(rule_tac x="\<lambda>x. a + x" in exI)
  5255   apply(rule_tac x="\<lambda>x. -a + x" in exI)
  5256   using continuous_on_add[OF continuous_on_const continuous_on_id] by auto
  5257 
  5258 lemma homeomorphic_affinity:
  5259   fixes s :: "'a::real_normed_vector set"
  5260   assumes "c \<noteq> 0"  shows "s homeomorphic ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  5261 proof-
  5262   have *:"op + a ` op *\<^sub>R c ` s = (\<lambda>x. a + c *\<^sub>R x) ` s" by auto
  5263   show ?thesis
  5264     using homeomorphic_trans
  5265     using homeomorphic_scaling[OF assms, of s]
  5266     using homeomorphic_translation[of "(\<lambda>x. c *\<^sub>R x) ` s" a] unfolding * by auto
  5267 qed
  5268 
  5269 lemma homeomorphic_balls:
  5270   fixes a b ::"'a::real_normed_vector" (* FIXME: generalize to metric_space *)
  5271   assumes "0 < d"  "0 < e"
  5272   shows "(ball a d) homeomorphic  (ball b e)" (is ?th)
  5273         "(cball a d) homeomorphic (cball b e)" (is ?cth)
  5274 proof-
  5275   have *:"\<bar>e / d\<bar> > 0" "\<bar>d / e\<bar> >0" using assms using divide_pos_pos by auto
  5276   show ?th unfolding homeomorphic_minimal
  5277     apply(rule_tac x="\<lambda>x. b + (e/d) *\<^sub>R (x - a)" in exI)
  5278     apply(rule_tac x="\<lambda>x. a + (d/e) *\<^sub>R (x - b)" in exI)
  5279     using assms apply (auto simp add: dist_commute)
  5280     unfolding dist_norm
  5281     apply (auto simp add: pos_divide_less_eq mult_strict_left_mono)
  5282     unfolding continuous_on
  5283     by (intro ballI tendsto_intros, simp)+
  5284 next
  5285   have *:"\<bar>e / d\<bar> > 0" "\<bar>d / e\<bar> >0" using assms using divide_pos_pos by auto
  5286   show ?cth unfolding homeomorphic_minimal
  5287     apply(rule_tac x="\<lambda>x. b + (e/d) *\<^sub>R (x - a)" in exI)
  5288     apply(rule_tac x="\<lambda>x. a + (d/e) *\<^sub>R (x - b)" in exI)
  5289     using assms apply (auto simp add: dist_commute)
  5290     unfolding dist_norm
  5291     apply (auto simp add: pos_divide_le_eq)
  5292     unfolding continuous_on
  5293     by (intro ballI tendsto_intros, simp)+
  5294 qed
  5295 
  5296 text{* "Isometry" (up to constant bounds) of injective linear map etc.           *}
  5297 
  5298 lemma cauchy_isometric:
  5299   fixes x :: "nat \<Rightarrow> 'a::euclidean_space"
  5300   assumes e:"0 < e" and s:"subspace s" and f:"bounded_linear f" and normf:"\<forall>x\<in>s. norm(f x) \<ge> e * norm(x)" and xs:"\<forall>n::nat. x n \<in> s" and cf:"Cauchy(f o x)"
  5301   shows "Cauchy x"
  5302 proof-
  5303   interpret f: bounded_linear f by fact
  5304   { fix d::real assume "d>0"
  5305     then obtain N where N:"\<forall>n\<ge>N. norm (f (x n) - f (x N)) < e * d"
  5306       using cf[unfolded cauchy o_def dist_norm, THEN spec[where x="e*d"]] and e and mult_pos_pos[of e d] by auto
  5307     { fix n assume "n\<ge>N"
  5308       have "e * norm (x n - x N) \<le> norm (f (x n - x N))"
  5309         using subspace_sub[OF s, of "x n" "x N"] using xs[THEN spec[where x=N]] and xs[THEN spec[where x=n]]
  5310         using normf[THEN bspec[where x="x n - x N"]] by auto
  5311       also have "norm (f (x n - x N)) < e * d"
  5312         using `N \<le> n` N unfolding f.diff[THEN sym] by auto
  5313       finally have "norm (x n - x N) < d" using `e>0` by simp }
  5314     hence "\<exists>N. \<forall>n\<ge>N. norm (x n - x N) < d" by auto }
  5315   thus ?thesis unfolding cauchy and dist_norm by auto
  5316 qed
  5317 
  5318 lemma complete_isometric_image:
  5319   fixes f :: "'a::euclidean_space => 'b::euclidean_space"
  5320   assumes "0 < e" and s:"subspace s" and f:"bounded_linear f" and normf:"\<forall>x\<in>s. norm(f x) \<ge> e * norm(x)" and cs:"complete s"
  5321   shows "complete(f ` s)"
  5322 proof-
  5323   { fix g assume as:"\<forall>n::nat. g n \<in> f ` s" and cfg:"Cauchy g"
  5324     then obtain x where "\<forall>n. x n \<in> s \<and> g n = f (x n)" 
  5325       using choice[of "\<lambda> n xa. xa \<in> s \<and> g n = f xa"] by auto
  5326     hence x:"\<forall>n. x n \<in> s"  "\<forall>n. g n = f (x n)" by auto
  5327     hence "f \<circ> x = g" unfolding fun_eq_iff by auto
  5328     then obtain l where "l\<in>s" and l:"(x ---> l) sequentially"
  5329       using cs[unfolded complete_def, THEN spec[where x="x"]]
  5330       using cauchy_isometric[OF `0<e` s f normf] and cfg and x(1) by auto
  5331     hence "\<exists>l\<in>f ` s. (g ---> l) sequentially"
  5332       using linear_continuous_at[OF f, unfolded continuous_at_sequentially, THEN spec[where x=x], of l]
  5333       unfolding `f \<circ> x = g` by auto  }
  5334   thus ?thesis unfolding complete_def by auto
  5335 qed
  5336 
  5337 lemma dist_0_norm:
  5338   fixes x :: "'a::real_normed_vector"
  5339   shows "dist 0 x = norm x"
  5340 unfolding dist_norm by simp
  5341 
  5342 lemma injective_imp_isometric: fixes f::"'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  5343   assumes s:"closed s"  "subspace s"  and f:"bounded_linear f" "\<forall>x\<in>s. (f x = 0) \<longrightarrow> (x = 0)"
  5344   shows "\<exists>e>0. \<forall>x\<in>s. norm (f x) \<ge> e * norm(x)"
  5345 proof(cases "s \<subseteq> {0::'a}")
  5346   case True
  5347   { fix x assume "x \<in> s"
  5348     hence "x = 0" using True by auto
  5349     hence "norm x \<le> norm (f x)" by auto  }
  5350   thus ?thesis by(auto intro!: exI[where x=1])
  5351 next
  5352   interpret f: bounded_linear f by fact
  5353   case False
  5354   then obtain a where a:"a\<noteq>0" "a\<in>s" by auto
  5355   from False have "s \<noteq> {}" by auto
  5356   let ?S = "{f x| x. (x \<in> s \<and> norm x = norm a)}"
  5357   let ?S' = "{x::'a. x\<in>s \<and> norm x = norm a}"
  5358   let ?S'' = "{x::'a. norm x = norm a}"
  5359 
  5360   have "?S'' = frontier(cball 0 (norm a))" unfolding frontier_cball and dist_norm by auto
  5361   hence "compact ?S''" using compact_frontier[OF compact_cball, of 0 "norm a"] by auto
  5362   moreover have "?S' = s \<inter> ?S''" by auto
  5363   ultimately have "compact ?S'" using closed_inter_compact[of s ?S''] using s(1) by auto
  5364   moreover have *:"f ` ?S' = ?S" by auto
  5365   ultimately have "compact ?S" using compact_continuous_image[OF linear_continuous_on[OF f(1)], of ?S'] by auto
  5366   hence "closed ?S" using compact_imp_closed by auto
  5367   moreover have "?S \<noteq> {}" using a by auto
  5368   ultimately obtain b' where "b'\<in>?S" "\<forall>y\<in>?S. norm b' \<le> norm y" using distance_attains_inf[of ?S 0] unfolding dist_0_norm by auto
  5369   then obtain b where "b\<in>s" and ba:"norm b = norm a" and b:"\<forall>x\<in>{x \<in> s. norm x = norm a}. norm (f b) \<le> norm (f x)" unfolding *[THEN sym] unfolding image_iff by auto
  5370 
  5371   let ?e = "norm (f b) / norm b"
  5372   have "norm b > 0" using ba and a and norm_ge_zero by auto
  5373   moreover have "norm (f b) > 0" using f(2)[THEN bspec[where x=b], OF `b\<in>s`] using `norm b >0` unfolding zero_less_norm_iff by auto
  5374   ultimately have "0 < norm (f b) / norm b" by(simp only: divide_pos_pos)
  5375   moreover
  5376   { fix x assume "x\<in>s"
  5377     hence "norm (f b) / norm b * norm x \<le> norm (f x)"
  5378     proof(cases "x=0")
  5379       case True thus "norm (f b) / norm b * norm x \<le> norm (f x)" by auto
  5380     next
  5381       case False
  5382       hence *:"0 < norm a / norm x" using `a\<noteq>0` unfolding zero_less_norm_iff[THEN sym] by(simp only: divide_pos_pos)
  5383       have "\<forall>c. \<forall>x\<in>s. c *\<^sub>R x \<in> s" using s[unfolded subspace_def] by auto
  5384       hence "(norm a / norm x) *\<^sub>R x \<in> {x \<in> s. norm x = norm a}" using `x\<in>s` and `x\<noteq>0` by auto
  5385       thus "norm (f b) / norm b * norm x \<le> norm (f x)" using b[THEN bspec[where x="(norm a / norm x) *\<^sub>R x"]]
  5386         unfolding f.scaleR and ba using `x\<noteq>0` `a\<noteq>0`
  5387         by (auto simp add: mult_commute pos_le_divide_eq pos_divide_le_eq)
  5388     qed }
  5389   ultimately
  5390   show ?thesis by auto
  5391 qed
  5392 
  5393 lemma closed_injective_image_subspace:
  5394   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  5395   assumes "subspace s" "bounded_linear f" "\<forall>x\<in>s. f x = 0 --> x = 0" "closed s"
  5396   shows "closed(f ` s)"
  5397 proof-
  5398   obtain e where "e>0" and e:"\<forall>x\<in>s. e * norm x \<le> norm (f x)" using injective_imp_isometric[OF assms(4,1,2,3)] by auto
  5399   show ?thesis using complete_isometric_image[OF `e>0` assms(1,2) e] and assms(4)
  5400     unfolding complete_eq_closed[THEN sym] by auto
  5401 qed
  5402 
  5403 
  5404 subsection {* Some properties of a canonical subspace *}
  5405 
  5406 lemma subspace_substandard:
  5407   "subspace {x::'a::euclidean_space. (\<forall>i<DIM('a). P i \<longrightarrow> x$$i = 0)}"
  5408   unfolding subspace_def by auto
  5409 
  5410 lemma closed_substandard:
  5411  "closed {x::'a::euclidean_space. \<forall>i<DIM('a). P i --> x$$i = 0}" (is "closed ?A")
  5412 proof-
  5413   let ?D = "{i. P i} \<inter> {..<DIM('a)}"
  5414   have "closed (\<Inter>i\<in>?D. {x::'a. x$$i = 0})"
  5415     by (simp add: closed_INT closed_Collect_eq)
  5416   also have "(\<Inter>i\<in>?D. {x::'a. x$$i = 0}) = ?A"
  5417     by auto
  5418   finally show "closed ?A" .
  5419 qed
  5420 
  5421 lemma dim_substandard: assumes "d\<subseteq>{..<DIM('a::euclidean_space)}"
  5422   shows "dim {x::'a::euclidean_space. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x$$i = 0} = card d" (is "dim ?A = _")
  5423 proof-
  5424   let ?D = "{..<DIM('a)}"
  5425   let ?B = "(basis::nat => 'a) ` d"
  5426   let ?bas = "basis::nat \<Rightarrow> 'a"
  5427   have "?B \<subseteq> ?A" by auto
  5428   moreover
  5429   { fix x::"'a" assume "x\<in>?A"
  5430     hence "finite d" "x\<in>?A" using assms by(auto intro:finite_subset)
  5431     hence "x\<in> span ?B"
  5432     proof(induct d arbitrary: x)
  5433       case empty hence "x=0" apply(subst euclidean_eq) by auto
  5434       thus ?case using subspace_0[OF subspace_span[of "{}"]] by auto
  5435     next
  5436       case (insert k F)
  5437       hence *:"\<forall>i<DIM('a). i \<notin> insert k F \<longrightarrow> x $$ i = 0" by auto
  5438       have **:"F \<subseteq> insert k F" by auto
  5439       def y \<equiv> "x - x$$k *\<^sub>R basis k"
  5440       have y:"x = y + (x$$k) *\<^sub>R basis k" unfolding y_def by auto
  5441       { fix i assume i':"i \<notin> F"
  5442         hence "y $$ i = 0" unfolding y_def 
  5443           using *[THEN spec[where x=i]] by auto }
  5444       hence "y \<in> span (basis ` F)" using insert(3) by auto
  5445       hence "y \<in> span (basis ` (insert k F))"
  5446         using span_mono[of "?bas ` F" "?bas ` (insert k F)"]
  5447         using image_mono[OF **, of basis] using assms by auto
  5448       moreover
  5449       have "basis k \<in> span (?bas ` (insert k F))" by(rule span_superset, auto)
  5450       hence "x$$k *\<^sub>R basis k \<in> span (?bas ` (insert k F))"
  5451         using span_mul by auto
  5452       ultimately
  5453       have "y + x$$k *\<^sub>R basis k \<in> span (?bas ` (insert k F))"
  5454         using span_add by auto
  5455       thus ?case using y by auto
  5456     qed
  5457   }
  5458   hence "?A \<subseteq> span ?B" by auto
  5459   moreover
  5460   { fix x assume "x \<in> ?B"
  5461     hence "x\<in>{(basis i)::'a |i. i \<in> ?D}" using assms by auto  }
  5462   hence "independent ?B" using independent_mono[OF independent_basis, of ?B] and assms by auto
  5463   moreover
  5464   have "d \<subseteq> ?D" unfolding subset_eq using assms by auto
  5465   hence *:"inj_on (basis::nat\<Rightarrow>'a) d" using subset_inj_on[OF basis_inj, of "d"] by auto
  5466   have "card ?B = card d" unfolding card_image[OF *] by auto
  5467   ultimately show ?thesis using dim_unique[of "basis ` d" ?A] by auto
  5468 qed
  5469 
  5470 text{* Hence closure and completeness of all subspaces.                          *}
  5471 
  5472 lemma closed_subspace_lemma: "n \<le> card (UNIV::'n::finite set) \<Longrightarrow> \<exists>A::'n set. card A = n"
  5473 apply (induct n)
  5474 apply (rule_tac x="{}" in exI, simp)
  5475 apply clarsimp
  5476 apply (subgoal_tac "\<exists>x. x \<notin> A")
  5477 apply (erule exE)
  5478 apply (rule_tac x="insert x A" in exI, simp)
  5479 apply (subgoal_tac "A \<noteq> UNIV", auto)
  5480 done
  5481 
  5482 lemma closed_subspace: fixes s::"('a::euclidean_space) set"
  5483   assumes "subspace s" shows "closed s"
  5484 proof-
  5485   have *:"dim s \<le> DIM('a)" using dim_subset_UNIV by auto
  5486   def d \<equiv> "{..<dim s}" have t:"card d = dim s" unfolding d_def by auto
  5487   let ?t = "{x::'a. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x$$i = 0}"
  5488   have "\<exists>f. linear f \<and> f ` {x::'a. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x $$ i = 0} = s \<and>
  5489       inj_on f {x::'a. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x $$ i = 0}"
  5490     apply(rule subspace_isomorphism[OF subspace_substandard[of "\<lambda>i. i \<notin> d"]])
  5491     using dim_substandard[of d,where 'a='a] and t unfolding d_def using * assms by auto
  5492   then guess f apply-by(erule exE conjE)+ note f = this
  5493   interpret f: bounded_linear f using f unfolding linear_conv_bounded_linear by auto
  5494   have "\<forall>x\<in>?t. f x = 0 \<longrightarrow> x = 0" using f.zero using f(3)[unfolded inj_on_def]
  5495     by(erule_tac x=0 in ballE) auto
  5496   moreover have "closed ?t" using closed_substandard .
  5497   moreover have "subspace ?t" using subspace_substandard .
  5498   ultimately show ?thesis using closed_injective_image_subspace[of ?t f]
  5499     unfolding f(2) using f(1) unfolding linear_conv_bounded_linear by auto
  5500 qed
  5501 
  5502 lemma complete_subspace:
  5503   fixes s :: "('a::euclidean_space) set" shows "subspace s ==> complete s"
  5504   using complete_eq_closed closed_subspace
  5505   by auto
  5506 
  5507 lemma dim_closure:
  5508   fixes s :: "('a::euclidean_space) set"
  5509   shows "dim(closure s) = dim s" (is "?dc = ?d")
  5510 proof-
  5511   have "?dc \<le> ?d" using closure_minimal[OF span_inc, of s]
  5512     using closed_subspace[OF subspace_span, of s]
  5513     using dim_subset[of "closure s" "span s"] unfolding dim_span by auto
  5514   thus ?thesis using dim_subset[OF closure_subset, of s] by auto
  5515 qed
  5516 
  5517 
  5518 subsection {* Affine transformations of intervals *}
  5519 
  5520 lemma real_affinity_le:
  5521  "0 < (m::'a::linordered_field) ==> (m * x + c \<le> y \<longleftrightarrow> x \<le> inverse(m) * y + -(c / m))"
  5522   by (simp add: field_simps inverse_eq_divide)
  5523 
  5524 lemma real_le_affinity:
  5525  "0 < (m::'a::linordered_field) ==> (y \<le> m * x + c \<longleftrightarrow> inverse(m) * y + -(c / m) \<le> x)"
  5526   by (simp add: field_simps inverse_eq_divide)
  5527 
  5528 lemma real_affinity_lt:
  5529  "0 < (m::'a::linordered_field) ==> (m * x + c < y \<longleftrightarrow> x < inverse(m) * y + -(c / m))"
  5530   by (simp add: field_simps inverse_eq_divide)
  5531 
  5532 lemma real_lt_affinity:
  5533  "0 < (m::'a::linordered_field) ==> (y < m * x + c \<longleftrightarrow> inverse(m) * y + -(c / m) < x)"
  5534   by (simp add: field_simps inverse_eq_divide)
  5535 
  5536 lemma real_affinity_eq:
  5537  "(m::'a::linordered_field) \<noteq> 0 ==> (m * x + c = y \<longleftrightarrow> x = inverse(m) * y + -(c / m))"
  5538   by (simp add: field_simps inverse_eq_divide)
  5539 
  5540 lemma real_eq_affinity:
  5541  "(m::'a::linordered_field) \<noteq> 0 ==> (y = m * x + c  \<longleftrightarrow> inverse(m) * y + -(c / m) = x)"
  5542   by (simp add: field_simps inverse_eq_divide)
  5543 
  5544 lemma image_affinity_interval: fixes m::real
  5545   fixes a b c :: "'a::ordered_euclidean_space"
  5546   shows "(\<lambda>x. m *\<^sub>R x + c) ` {a .. b} =
  5547             (if {a .. b} = {} then {}
  5548             else (if 0 \<le> m then {m *\<^sub>R a + c .. m *\<^sub>R b + c}
  5549             else {m *\<^sub>R b + c .. m *\<^sub>R a + c}))"
  5550 proof(cases "m=0")  
  5551   { fix x assume "x \<le> c" "c \<le> x"
  5552     hence "x=c" unfolding eucl_le[where 'a='a] apply-
  5553       apply(subst euclidean_eq) by (auto intro: order_antisym) }
  5554   moreover case True
  5555   moreover have "c \<in> {m *\<^sub>R a + c..m *\<^sub>R b + c}" unfolding True by(auto simp add: eucl_le[where 'a='a])
  5556   ultimately show ?thesis by auto
  5557 next
  5558   case False
  5559   { fix y assume "a \<le> y" "y \<le> b" "m > 0"
  5560     hence "m *\<^sub>R a + c \<le> m *\<^sub>R y + c"  "m *\<^sub>R y + c \<le> m *\<^sub>R b + c"
  5561       unfolding eucl_le[where 'a='a] by auto
  5562   } moreover
  5563   { fix y assume "a \<le> y" "y \<le> b" "m < 0"
  5564     hence "m *\<^sub>R b + c \<le> m *\<^sub>R y + c"  "m *\<^sub>R y + c \<le> m *\<^sub>R a + c"
  5565       unfolding eucl_le[where 'a='a] by(auto simp add: mult_left_mono_neg)
  5566   } moreover
  5567   { fix y assume "m > 0"  "m *\<^sub>R a + c \<le> y"  "y \<le> m *\<^sub>R b + c"
  5568     hence "y \<in> (\<lambda>x. m *\<^sub>R x + c) ` {a..b}"
  5569       unfolding image_iff Bex_def mem_interval eucl_le[where 'a='a]
  5570       apply (intro exI[where x="(1 / m) *\<^sub>R (y - c)"])
  5571       by(auto simp add: pos_le_divide_eq pos_divide_le_eq mult_commute diff_le_iff)
  5572   } moreover
  5573   { fix y assume "m *\<^sub>R b + c \<le> y" "y \<le> m *\<^sub>R a + c" "m < 0"
  5574     hence "y \<in> (\<lambda>x. m *\<^sub>R x + c) ` {a..b}"
  5575       unfolding image_iff Bex_def mem_interval eucl_le[where 'a='a]
  5576       apply (intro exI[where x="(1 / m) *\<^sub>R (y - c)"])
  5577       by(auto simp add: neg_le_divide_eq neg_divide_le_eq mult_commute diff_le_iff)
  5578   }
  5579   ultimately show ?thesis using False by auto
  5580 qed
  5581 
  5582 lemma image_smult_interval:"(\<lambda>x. m *\<^sub>R (x::_::ordered_euclidean_space)) ` {a..b} =
  5583   (if {a..b} = {} then {} else if 0 \<le> m then {m *\<^sub>R a..m *\<^sub>R b} else {m *\<^sub>R b..m *\<^sub>R a})"
  5584   using image_affinity_interval[of m 0 a b] by auto
  5585 
  5586 
  5587 subsection {* Banach fixed point theorem (not really topological...) *}
  5588 
  5589 lemma banach_fix:
  5590   assumes s:"complete s" "s \<noteq> {}" and c:"0 \<le> c" "c < 1" and f:"(f ` s) \<subseteq> s" and
  5591           lipschitz:"\<forall>x\<in>s. \<forall>y\<in>s. dist (f x) (f y) \<le> c * dist x y"
  5592   shows "\<exists>! x\<in>s. (f x = x)"
  5593 proof-
  5594   have "1 - c > 0" using c by auto
  5595 
  5596   from s(2) obtain z0 where "z0 \<in> s" by auto
  5597   def z \<equiv> "\<lambda>n. (f ^^ n) z0"
  5598   { fix n::nat
  5599     have "z n \<in> s" unfolding z_def
  5600     proof(induct n) case 0 thus ?case using `z0 \<in>s` by auto
  5601     next case Suc thus ?case using f by auto qed }
  5602   note z_in_s = this
  5603 
  5604   def d \<equiv> "dist (z 0) (z 1)"
  5605 
  5606   have fzn:"\<And>n. f (z n) = z (Suc n)" unfolding z_def by auto
  5607   { fix n::nat
  5608     have "dist (z n) (z (Suc n)) \<le> (c ^ n) * d"
  5609     proof(induct n)
  5610       case 0 thus ?case unfolding d_def by auto
  5611     next
  5612       case (Suc m)
  5613       hence "c * dist (z m) (z (Suc m)) \<le> c ^ Suc m * d"
  5614         using `0 \<le> c` using mult_left_mono[of "dist (z m) (z (Suc m))" "c ^ m * d" c] by auto
  5615       thus ?case using lipschitz[THEN bspec[where x="z m"], OF z_in_s, THEN bspec[where x="z (Suc m)"], OF z_in_s]
  5616         unfolding fzn and mult_le_cancel_left by auto
  5617     qed
  5618   } note cf_z = this
  5619 
  5620   { fix n m::nat
  5621     have "(1 - c) * dist (z m) (z (m+n)) \<le> (c ^ m) * d * (1 - c ^ n)"
  5622     proof(induct n)
  5623       case 0 show ?case by auto
  5624     next
  5625       case (Suc k)
  5626       have "(1 - c) * dist (z m) (z (m + Suc k)) \<le> (1 - c) * (dist (z m) (z (m + k)) + dist (z (m + k)) (z (Suc (m + k))))"
  5627         using dist_triangle and c by(auto simp add: dist_triangle)
  5628       also have "\<dots> \<le> (1 - c) * (dist (z m) (z (m + k)) + c ^ (m + k) * d)"
  5629         using cf_z[of "m + k"] and c by auto
  5630       also have "\<dots> \<le> c ^ m * d * (1 - c ^ k) + (1 - c) * c ^ (m + k) * d"
  5631         using Suc by (auto simp add: field_simps)
  5632       also have "\<dots> = (c ^ m) * (d * (1 - c ^ k) + (1 - c) * c ^ k * d)"
  5633         unfolding power_add by (auto simp add: field_simps)
  5634       also have "\<dots> \<le> (c ^ m) * d * (1 - c ^ Suc k)"
  5635         using c by (auto simp add: field_simps)
  5636       finally show ?case by auto
  5637     qed
  5638   } note cf_z2 = this
  5639   { fix e::real assume "e>0"
  5640     hence "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (z m) (z n) < e"
  5641     proof(cases "d = 0")
  5642       case True
  5643       have *: "\<And>x. ((1 - c) * x \<le> 0) = (x \<le> 0)" using `1 - c > 0`
  5644         by (metis mult_zero_left mult_commute real_mult_le_cancel_iff1)
  5645       from True have "\<And>n. z n = z0" using cf_z2[of 0] and c unfolding z_def
  5646         by (simp add: *)
  5647       thus ?thesis using `e>0` by auto
  5648     next
  5649       case False hence "d>0" unfolding d_def using zero_le_dist[of "z 0" "z 1"]
  5650         by (metis False d_def less_le)
  5651       hence "0 < e * (1 - c) / d" using `e>0` and `1-c>0`
  5652         using divide_pos_pos[of "e * (1 - c)" d] and mult_pos_pos[of e "1 - c"] by auto
  5653       then obtain N where N:"c ^ N < e * (1 - c) / d" using real_arch_pow_inv[of "e * (1 - c) / d" c] and c by auto
  5654       { fix m n::nat assume "m>n" and as:"m\<ge>N" "n\<ge>N"
  5655         have *:"c ^ n \<le> c ^ N" using `n\<ge>N` and c using power_decreasing[OF `n\<ge>N`, of c] by auto
  5656         have "1 - c ^ (m - n) > 0" using c and power_strict_mono[of c 1 "m - n"] using `m>n` by auto
  5657         hence **:"d * (1 - c ^ (m - n)) / (1 - c) > 0"
  5658           using mult_pos_pos[OF `d>0`, of "1 - c ^ (m - n)"]
  5659           using divide_pos_pos[of "d * (1 - c ^ (m - n))" "1 - c"]
  5660           using `0 < 1 - c` by auto
  5661 
  5662         have "dist (z m) (z n) \<le> c ^ n * d * (1 - c ^ (m - n)) / (1 - c)"
  5663           using cf_z2[of n "m - n"] and `m>n` unfolding pos_le_divide_eq[OF `1-c>0`]
  5664           by (auto simp add: mult_commute dist_commute)
  5665         also have "\<dots> \<le> c ^ N * d * (1 - c ^ (m - n)) / (1 - c)"
  5666           using mult_right_mono[OF * order_less_imp_le[OF **]]
  5667           unfolding mult_assoc by auto
  5668         also have "\<dots> < (e * (1 - c) / d) * d * (1 - c ^ (m - n)) / (1 - c)"
  5669           using mult_strict_right_mono[OF N **] unfolding mult_assoc by auto
  5670         also have "\<dots> = e * (1 - c ^ (m - n))" using c and `d>0` and `1 - c > 0` by auto
  5671         also have "\<dots> \<le> e" using c and `1 - c ^ (m - n) > 0` and `e>0` using mult_right_le_one_le[of e "1 - c ^ (m - n)"] by auto
  5672         finally have  "dist (z m) (z n) < e" by auto
  5673       } note * = this
  5674       { fix m n::nat assume as:"N\<le>m" "N\<le>n"
  5675         hence "dist (z n) (z m) < e"
  5676         proof(cases "n = m")
  5677           case True thus ?thesis using `e>0` by auto
  5678         next
  5679           case False thus ?thesis using as and *[of n m] *[of m n] unfolding nat_neq_iff by (auto simp add: dist_commute)
  5680         qed }
  5681       thus ?thesis by auto
  5682     qed
  5683   }
  5684   hence "Cauchy z" unfolding cauchy_def by auto
  5685   then obtain x where "x\<in>s" and x:"(z ---> x) sequentially" using s(1)[unfolded compact_def complete_def, THEN spec[where x=z]] and z_in_s by auto
  5686 
  5687   def e \<equiv> "dist (f x) x"
  5688   have "e = 0" proof(rule ccontr)
  5689     assume "e \<noteq> 0" hence "e>0" unfolding e_def using zero_le_dist[of "f x" x]
  5690       by (metis dist_eq_0_iff dist_nz e_def)
  5691     then obtain N where N:"\<forall>n\<ge>N. dist (z n) x < e / 2"
  5692       using x[unfolded LIMSEQ_def, THEN spec[where x="e/2"]] by auto
  5693     hence N':"dist (z N) x < e / 2" by auto
  5694 
  5695     have *:"c * dist (z N) x \<le> dist (z N) x" unfolding mult_le_cancel_right2
  5696       using zero_le_dist[of "z N" x] and c
  5697       by (metis dist_eq_0_iff dist_nz order_less_asym less_le)
  5698     have "dist (f (z N)) (f x) \<le> c * dist (z N) x" using lipschitz[THEN bspec[where x="z N"], THEN bspec[where x=x]]
  5699       using z_in_s[of N] `x\<in>s` using c by auto
  5700     also have "\<dots> < e / 2" using N' and c using * by auto
  5701     finally show False unfolding fzn
  5702       using N[THEN spec[where x="Suc N"]] and dist_triangle_half_r[of "z (Suc N)" "f x" e x]
  5703       unfolding e_def by auto
  5704   qed
  5705   hence "f x = x" unfolding e_def by auto
  5706   moreover
  5707   { fix y assume "f y = y" "y\<in>s"
  5708     hence "dist x y \<le> c * dist x y" using lipschitz[THEN bspec[where x=x], THEN bspec[where x=y]]
  5709       using `x\<in>s` and `f x = x` by auto
  5710     hence "dist x y = 0" unfolding mult_le_cancel_right1
  5711       using c and zero_le_dist[of x y] by auto
  5712     hence "y = x" by auto
  5713   }
  5714   ultimately show ?thesis using `x\<in>s` by blast+
  5715 qed
  5716 
  5717 subsection {* Edelstein fixed point theorem *}
  5718 
  5719 lemma edelstein_fix:
  5720   fixes s :: "'a::real_normed_vector set"
  5721   assumes s:"compact s" "s \<noteq> {}" and gs:"(g ` s) \<subseteq> s"
  5722       and dist:"\<forall>x\<in>s. \<forall>y\<in>s. x \<noteq> y \<longrightarrow> dist (g x) (g y) < dist x y"
  5723   shows "\<exists>! x\<in>s. g x = x"
  5724 proof(cases "\<exists>x\<in>s. g x \<noteq> x")
  5725   obtain x where "x\<in>s" using s(2) by auto
  5726   case False hence g:"\<forall>x\<in>s. g x = x" by auto
  5727   { fix y assume "y\<in>s"
  5728     hence "x = y" using `x\<in>s` and dist[THEN bspec[where x=x], THEN bspec[where x=y]]
  5729       unfolding g[THEN bspec[where x=x], OF `x\<in>s`]
  5730       unfolding g[THEN bspec[where x=y], OF `y\<in>s`] by auto  }
  5731   thus ?thesis using `x\<in>s` and g by blast+
  5732 next
  5733   case True
  5734   then obtain x where [simp]:"x\<in>s" and "g x \<noteq> x" by auto
  5735   { fix x y assume "x \<in> s" "y \<in> s"
  5736     hence "dist (g x) (g y) \<le> dist x y"
  5737       using dist[THEN bspec[where x=x], THEN bspec[where x=y]] by auto } note dist' = this
  5738   def y \<equiv> "g x"
  5739   have [simp]:"y\<in>s" unfolding y_def using gs[unfolded image_subset_iff] and `x\<in>s` by blast
  5740   def f \<equiv> "\<lambda>n. g ^^ n"
  5741   have [simp]:"\<And>n z. g (f n z) = f (Suc n) z" unfolding f_def by auto
  5742   have [simp]:"\<And>z. f 0 z = z" unfolding f_def by auto
  5743   { fix n::nat and z assume "z\<in>s"
  5744     have "f n z \<in> s" unfolding f_def
  5745     proof(induct n)
  5746       case 0 thus ?case using `z\<in>s` by simp