src/HOL/Tools/BNF/bnf_fp_n2m.ML
author traytel
Tue Mar 03 19:08:04 2015 +0100 (2015-03-03)
changeset 59580 cbc38731d42f
parent 59058 a78612c67ec0
child 59621 291934bac95e
permissions -rw-r--r--
eliminated some clones of Proof_Context.cterm_of
     1 (*  Title:      HOL/Tools/BNF/bnf_fp_n2m.ML
     2     Author:     Dmitriy Traytel, TU Muenchen
     3     Copyright   2013
     4 
     5 Flattening of nested to mutual (co)recursion.
     6 *)
     7 
     8 signature BNF_FP_N2M =
     9 sig
    10   val construct_mutualized_fp: BNF_Util.fp_kind -> int list -> typ list ->
    11     BNF_FP_Def_Sugar.fp_sugar list -> binding list -> (string * sort) list ->
    12     typ list * typ list list -> BNF_Def.bnf list -> BNF_Comp.absT_info list -> local_theory ->
    13     BNF_FP_Util.fp_result * local_theory
    14 end;
    15 
    16 structure BNF_FP_N2M : BNF_FP_N2M =
    17 struct
    18 
    19 open BNF_Def
    20 open BNF_Util
    21 open BNF_Comp
    22 open BNF_FP_Util
    23 open BNF_FP_Def_Sugar
    24 open BNF_Tactics
    25 open BNF_FP_N2M_Tactics
    26 
    27 fun force_typ ctxt T =
    28   Term.map_types Type_Infer.paramify_vars
    29   #> Type.constraint T
    30   #> Syntax.check_term ctxt
    31   #> singleton (Variable.polymorphic ctxt);
    32 
    33 fun mk_prod_map f g =
    34   let
    35     val ((fAT, fBT), fT) = `dest_funT (fastype_of f);
    36     val ((gAT, gBT), gT) = `dest_funT (fastype_of g);
    37   in
    38     Const (@{const_name map_prod},
    39       fT --> gT --> HOLogic.mk_prodT (fAT, gAT) --> HOLogic.mk_prodT (fBT, gBT)) $ f $ g
    40   end;
    41 
    42 fun mk_map_sum f g =
    43   let
    44     val ((fAT, fBT), fT) = `dest_funT (fastype_of f);
    45     val ((gAT, gBT), gT) = `dest_funT (fastype_of g);
    46   in
    47     Const (@{const_name map_sum}, fT --> gT --> mk_sumT (fAT, gAT) --> mk_sumT (fBT, gBT)) $ f $ g
    48   end;
    49 
    50 fun construct_mutualized_fp fp mutual_cliques fpTs (fp_sugars : fp_sugar list) bs resBs (resDs, Dss)
    51     bnfs (absT_infos : absT_info list) lthy =
    52   let
    53     fun of_fp_res get =
    54       map (fn {fp_res, fp_res_index, ...} => nth (get fp_res) fp_res_index) fp_sugars;
    55 
    56     fun mk_co_algT T U = case_fp fp (T --> U) (U --> T);
    57     fun co_swap pair = case_fp fp I swap pair;
    58     val mk_co_comp = HOLogic.mk_comp o co_swap;
    59     val co_productC = BNF_FP_Rec_Sugar_Util.case_fp fp @{type_name prod} @{type_name sum};
    60 
    61     val dest_co_algT = co_swap o dest_funT;
    62     val co_alg_argT = case_fp fp range_type domain_type;
    63     val co_alg_funT = case_fp fp domain_type range_type;
    64     val mk_co_product = curry (case_fp fp mk_convol mk_case_sum);
    65     val mk_map_co_product = case_fp fp mk_prod_map mk_map_sum;
    66     val co_proj1_const = case_fp fp (fst_const o fst) (uncurry Inl_const o dest_sumT o snd);
    67     val mk_co_productT = curry (case_fp fp HOLogic.mk_prodT mk_sumT);
    68     val dest_co_productT = case_fp fp HOLogic.dest_prodT dest_sumT;
    69     val rewrite_comp_comp = case_fp fp @{thm rewriteL_comp_comp} @{thm rewriteR_comp_comp};
    70 
    71     val fp_absT_infos = map #absT_info fp_sugars;
    72     val fp_bnfs = of_fp_res #bnfs;
    73     val pre_bnfs = map #pre_bnf fp_sugars;
    74     val nesting_bnfss =
    75       map (fn sugar => #fp_nesting_bnfs sugar @ #live_nesting_bnfs sugar) fp_sugars;
    76     val fp_or_nesting_bnfss = fp_bnfs :: nesting_bnfss;
    77     val fp_or_nesting_bnfs = distinct (op = o apply2 T_of_bnf) (flat fp_or_nesting_bnfss);
    78 
    79     val fp_absTs = map #absT fp_absT_infos;
    80     val fp_repTs = map #repT fp_absT_infos;
    81     val fp_abss = map #abs fp_absT_infos;
    82     val fp_reps = map #rep fp_absT_infos;
    83     val fp_type_definitions = map #type_definition fp_absT_infos;
    84 
    85     val absTs = map #absT absT_infos;
    86     val repTs = map #repT absT_infos;
    87     val absTs' = map (Logic.type_map (singleton (Variable.polymorphic lthy))) absTs;
    88     val repTs' = map (Logic.type_map (singleton (Variable.polymorphic lthy))) repTs;
    89     val abss = map #abs absT_infos;
    90     val reps = map #rep absT_infos;
    91     val abs_inverses = map #abs_inverse absT_infos;
    92     val type_definitions = map #type_definition absT_infos;
    93 
    94     val n = length bnfs;
    95     val deads = fold (union (op =)) Dss resDs;
    96     val As = subtract (op =) deads (map TFree resBs);
    97     val names_lthy = fold Variable.declare_typ (As @ deads) lthy;
    98     val m = length As;
    99     val live = m + n;
   100 
   101     val ((Xs, Bs), names_lthy) = names_lthy
   102       |> mk_TFrees n
   103       ||>> mk_TFrees m;
   104 
   105     val allAs = As @ Xs;
   106     val allBs = Bs @ Xs;
   107     val phiTs = map2 mk_pred2T As Bs;
   108     val thetaBs = As ~~ Bs;
   109     val fpTs' = map (Term.typ_subst_atomic thetaBs) fpTs;
   110     val fold_thetaAs = Xs ~~ fpTs;
   111     val fold_thetaBs = Xs ~~ fpTs';
   112     val rec_theta = Xs ~~ map2 mk_co_productT fpTs Xs;
   113     val pre_phiTs = map2 mk_pred2T fpTs fpTs';
   114 
   115     val ((ctors, dtors), (xtor's, xtors)) =
   116       let
   117         val ctors = map2 (force_typ names_lthy o (fn T => dummyT --> T)) fpTs (of_fp_res #ctors);
   118         val dtors = map2 (force_typ names_lthy o (fn T => T --> dummyT)) fpTs (of_fp_res #dtors);
   119       in
   120         ((ctors, dtors), `(map (Term.subst_atomic_types thetaBs)) (case_fp fp ctors dtors))
   121       end;
   122 
   123     val absATs = map (domain_type o fastype_of) ctors;
   124     val absBTs = map (Term.typ_subst_atomic thetaBs) absATs;
   125     val xTs = map (domain_type o fastype_of) xtors;
   126     val yTs = map (domain_type o fastype_of) xtor's;
   127 
   128     val absAs = @{map 3} (fn Ds => mk_abs o mk_T_of_bnf Ds allAs) Dss bnfs abss;
   129     val absBs = @{map 3} (fn Ds => mk_abs o mk_T_of_bnf Ds allBs) Dss bnfs abss;
   130     val fp_repAs = map2 mk_rep absATs fp_reps;
   131     val fp_repBs = map2 mk_rep absBTs fp_reps;
   132 
   133     val (((((phis, phis'), pre_phis), xs), ys), names_lthy) = names_lthy
   134       |> mk_Frees' "R" phiTs
   135       ||>> mk_Frees "S" pre_phiTs
   136       ||>> mk_Frees "x" xTs
   137       ||>> mk_Frees "y" yTs;
   138 
   139     val rels =
   140       let
   141         fun find_rel T As Bs = fp_or_nesting_bnfss
   142           |> map (filter_out (curry (op = o apply2 name_of_bnf) BNF_Comp.DEADID_bnf))
   143           |> get_first (find_first (fn bnf => Type.could_unify (T_of_bnf bnf, T)))
   144           |> Option.map (fn bnf =>
   145             let val live = live_of_bnf bnf;
   146             in (mk_rel live As Bs (rel_of_bnf bnf), live) end)
   147           |> the_default (HOLogic.eq_const T, 0);
   148 
   149         fun mk_rel (T as Type (_, Ts)) (Type (_, Us)) =
   150               let
   151                 val (rel, live) = find_rel T Ts Us;
   152                 val (Ts', Us') = fastype_of rel |> strip_typeN live |> fst |> map_split dest_pred2T;
   153                 val rels = map2 mk_rel Ts' Us';
   154               in
   155                 Term.list_comb (rel, rels)
   156               end
   157           | mk_rel (T as TFree _) _ = (nth phis (find_index (curry op = T) As)
   158               handle General.Subscript => HOLogic.eq_const T)
   159           | mk_rel _ _ = raise Fail "fpTs contains schematic type variables";
   160       in
   161         map2 (fold_rev Term.absfree phis' oo mk_rel) fpTs fpTs'
   162       end;
   163 
   164     val pre_rels = map2 (fn Ds => mk_rel_of_bnf Ds (As @ fpTs) (Bs @ fpTs')) Dss bnfs;
   165 
   166     val rel_unfolds = maps (no_refl o single o rel_def_of_bnf) pre_bnfs;
   167     val rel_xtor_co_inducts = of_fp_res (split_conj_thm o #xtor_rel_co_induct)
   168       |> map (unfold_thms lthy (id_apply :: rel_unfolds));
   169 
   170     val rel_defs = map rel_def_of_bnf bnfs;
   171     val rel_monos = map rel_mono_of_bnf bnfs;
   172 
   173     fun cast castA castB pre_rel =
   174       let
   175         val castAB = mk_vimage2p (Term.subst_atomic_types fold_thetaAs castA)
   176           (Term.subst_atomic_types fold_thetaBs castB);
   177       in
   178         fold_rev (fold_rev Term.absdummy) [phiTs, pre_phiTs]
   179           (castAB $ Term.list_comb (pre_rel, map Bound (live - 1 downto 0)))
   180       end;
   181 
   182     val castAs = map2 (curry HOLogic.mk_comp) absAs fp_repAs;
   183     val castBs = map2 (curry HOLogic.mk_comp) absBs fp_repBs;
   184 
   185     val fp_or_nesting_rel_eqs = no_refl (map rel_eq_of_bnf fp_or_nesting_bnfs);
   186     val fp_or_nesting_rel_monos = map rel_mono_of_bnf fp_or_nesting_bnfs;
   187 
   188     val rel_xtor_co_inducts_inst =
   189       let
   190         val extract =
   191           case_fp fp (snd o Term.dest_comb) (snd o Term.dest_comb o fst o Term.dest_comb);
   192         val raw_phis = map (extract o HOLogic.dest_Trueprop o Thm.concl_of) rel_xtor_co_inducts;
   193         val thetas = AList.group (op =)
   194           (mutual_cliques ~~ map (apply2 (Proof_Context.cterm_of lthy)) (raw_phis ~~ pre_phis));
   195       in
   196         map2 (Drule.cterm_instantiate o the o AList.lookup (op =) thetas)
   197         mutual_cliques rel_xtor_co_inducts
   198       end
   199 
   200     val xtor_rel_co_induct =
   201       mk_xtor_rel_co_induct_thm fp (@{map 3} cast castAs castBs pre_rels) pre_phis rels phis xs ys
   202         xtors xtor's (mk_rel_xtor_co_induct_tactic fp abs_inverses rel_xtor_co_inducts_inst rel_defs
   203           rel_monos fp_or_nesting_rel_eqs fp_or_nesting_rel_monos)
   204         lthy;
   205 
   206     val map_id0s = no_refl (map map_id0_of_bnf bnfs);
   207 
   208     val xtor_co_induct_thm =
   209       (case fp of
   210         Least_FP =>
   211           let
   212             val (Ps, names_lthy) = names_lthy
   213               |> mk_Frees "P" (map (fn T => T --> HOLogic.boolT) fpTs);
   214             fun mk_Grp_id P =
   215               let val T = domain_type (fastype_of P);
   216               in mk_Grp (HOLogic.Collect_const T $ P) (HOLogic.id_const T) end;
   217             val cts = map (SOME o Proof_Context.cterm_of lthy) (map HOLogic.eq_const As @ map mk_Grp_id Ps);
   218             fun mk_fp_type_copy_thms thm = map (curry op RS thm)
   219               @{thms type_copy_Abs_o_Rep type_copy_vimage2p_Grp_Rep};
   220             fun mk_type_copy_thms thm = map (curry op RS thm)
   221               @{thms type_copy_Rep_o_Abs type_copy_vimage2p_Grp_Abs};
   222           in
   223             cterm_instantiate_pos cts xtor_rel_co_induct
   224             |> singleton (Proof_Context.export names_lthy lthy)
   225             |> unfold_thms lthy (@{thms eq_le_Grp_id_iff all_simps(1,2)[symmetric]} @
   226                 fp_or_nesting_rel_eqs)
   227             |> funpow n (fn thm => thm RS spec)
   228             |> unfold_thms lthy (@{thm eq_alt} :: map rel_Grp_of_bnf bnfs @ map_id0s)
   229             |> unfold_thms lthy (@{thms vimage2p_id vimage2p_comp comp_apply comp_id
   230                Grp_id_mono_subst eqTrueI[OF subset_UNIV] simp_thms(22)} @
   231                maps mk_fp_type_copy_thms fp_type_definitions @
   232                maps mk_type_copy_thms type_definitions)
   233             |> unfold_thms lthy @{thms subset_iff mem_Collect_eq
   234                atomize_conjL[symmetric] atomize_all[symmetric] atomize_imp[symmetric]}
   235           end
   236       | Greatest_FP =>
   237           let
   238             val cts = NONE :: map (SOME o Proof_Context.cterm_of lthy) (map HOLogic.eq_const As);
   239           in
   240             cterm_instantiate_pos cts xtor_rel_co_induct
   241             |> unfold_thms lthy (@{thms le_fun_def le_bool_def all_simps(1,2)[symmetric]} @
   242                 fp_or_nesting_rel_eqs)
   243             |> funpow (2 * n) (fn thm => thm RS spec)
   244             |> Conv.fconv_rule (Object_Logic.atomize lthy)
   245             |> funpow n (fn thm => thm RS mp)
   246           end);
   247 
   248     val fold_preTs = map2 (fn Ds => mk_T_of_bnf Ds allAs) Dss bnfs;
   249     val rec_preTs = map (Term.typ_subst_atomic rec_theta) fold_preTs;
   250 
   251     val rec_strTs = map2 mk_co_algT rec_preTs Xs;
   252     val resTs = map2 mk_co_algT fpTs Xs;
   253 
   254     val ((rec_strs, rec_strs'), names_lthy) = names_lthy
   255       |> mk_Frees' "s" rec_strTs;
   256 
   257     val co_recs = of_fp_res #xtor_co_recs;
   258     val ns = map (length o #Ts o #fp_res) fp_sugars;
   259 
   260     val typ_subst_nonatomic_sorted = fold_rev (typ_subst_nonatomic o single);
   261 
   262     fun foldT_of_recT recT =
   263       let
   264         val ((FTXs, Ys), TX) = strip_fun_type recT |>> map_split dest_co_algT;
   265         val Zs = union op = Xs Ys;
   266         fun subst (Type (C, Ts as [_, X])) =
   267             if C = co_productC andalso member op = Zs X then X else Type (C, map subst Ts)
   268           | subst (Type (C, Ts)) = Type (C, map subst Ts)
   269           | subst T = T;
   270       in
   271         map2 (mk_co_algT o subst) FTXs Ys ---> TX
   272       end;
   273 
   274     fun force_rec i TU raw_rec =
   275       let
   276         val thy = Proof_Context.theory_of lthy;
   277 
   278         val approx_rec = raw_rec
   279           |> force_typ names_lthy (replicate (nth ns i) dummyT ---> TU);
   280         val subst = Term.typ_subst_atomic fold_thetaAs;
   281 
   282         fun mk_fp_absT_repT fp_repT fp_absT = mk_absT thy fp_repT fp_absT ooo mk_repT;
   283         val mk_fp_absT_repTs = @{map 5} mk_fp_absT_repT fp_repTs fp_absTs absTs repTs;
   284 
   285         val fold_preTs' = mk_fp_absT_repTs (map subst fold_preTs);
   286 
   287         val fold_pre_deads_only_Ts =
   288           map (typ_subst_nonatomic_sorted (map (rpair dummyT)
   289             (As @ sort (int_ord o apply2 Term.size_of_typ) fpTs))) fold_preTs';
   290 
   291         val (mutual_clique, TUs) =
   292           map_split dest_co_algT (binder_fun_types (foldT_of_recT (fastype_of approx_rec)))
   293           |>> map subst
   294           |> `(fn (_, Ys) =>
   295             nth mutual_cliques (find_index (fn X => X = the (find_first (can dest_TFree) Ys)) Xs))
   296           ||> uncurry (map2 mk_co_algT);
   297         val cands = mutual_cliques ~~ map2 mk_co_algT fold_preTs' Xs;
   298         val js = find_indices (fn ((cl, cand), TU) =>
   299           cl = mutual_clique andalso Type.could_unify (TU, cand)) TUs cands;
   300         val Tpats = map (fn j => mk_co_algT (nth fold_pre_deads_only_Ts j) (nth Xs j)) js;
   301       in
   302         force_typ names_lthy (Tpats ---> TU) raw_rec
   303       end;
   304 
   305     fun mk_co_comp_abs_rep fp_absT absT fp_abs fp_rep abs rep t =
   306       case_fp fp (HOLogic.mk_comp (HOLogic.mk_comp (t, mk_abs absT abs), mk_rep fp_absT fp_rep))
   307         (HOLogic.mk_comp (mk_abs fp_absT fp_abs, HOLogic.mk_comp (mk_rep absT rep, t)));
   308 
   309     fun mk_rec b_opt recs lthy TU =
   310       let
   311         val thy = Proof_Context.theory_of lthy;
   312 
   313         val x = co_alg_argT TU;
   314         val i = find_index (fn T => x = T) Xs;
   315         val TUrec =
   316           (case find_first (fn f => body_fun_type (fastype_of f) = TU) recs of
   317             NONE => force_rec i TU (nth co_recs i)
   318           | SOME f => f);
   319 
   320         val TUs = binder_fun_types (fastype_of TUrec);
   321 
   322         fun mk_s TU' =
   323           let
   324             fun mk_absT_fp_repT repT absT = mk_absT thy repT absT ooo mk_repT;
   325 
   326             val i = find_index (fn T => co_alg_argT TU' = T) Xs;
   327             val fp_abs = nth fp_abss i;
   328             val fp_rep = nth fp_reps i;
   329             val abs = nth abss i;
   330             val rep = nth reps i;
   331             val sF = co_alg_funT TU';
   332             val sF' =
   333               mk_absT_fp_repT (nth repTs' i) (nth absTs' i) (nth fp_absTs i) (nth fp_repTs i) sF
   334                 handle Term.TYPE _ => sF;
   335             val F = nth rec_preTs i;
   336             val s = nth rec_strs i;
   337           in
   338             if sF = F then s
   339             else if sF' = F then mk_co_comp_abs_rep sF sF' fp_abs fp_rep abs rep s
   340             else
   341               let
   342                 val smapT = replicate live dummyT ---> mk_co_algT sF' F;
   343                 fun hidden_to_unit t =
   344                   Term.subst_TVars (map (rpair HOLogic.unitT) (Term.add_tvar_names t [])) t;
   345                 val smap = map_of_bnf (nth bnfs i)
   346                   |> force_typ names_lthy smapT
   347                   |> hidden_to_unit;
   348                 val smap_argTs = strip_typeN live (fastype_of smap) |> fst;
   349                 fun mk_smap_arg T_to_U =
   350                   (if domain_type T_to_U = range_type T_to_U then
   351                     HOLogic.id_const (domain_type T_to_U)
   352                   else
   353                     let
   354                       val (TY, (U, X)) = T_to_U |> dest_co_algT ||> dest_co_productT;
   355                       val T = mk_co_algT TY U;
   356                       fun mk_co_proj TU =
   357                         build_map lthy [] (fn TU =>
   358                           let val ((T1, T2), U) = TU |> co_swap |>> dest_co_productT in
   359                             if T1 = U then co_proj1_const TU
   360                             else mk_co_comp (mk_co_proj (co_swap (T1, U)),
   361                               co_proj1_const (co_swap (mk_co_productT T1 T2, T1)))
   362                           end)
   363                           TU;
   364                       fun default () =
   365                         mk_co_product (mk_co_proj (dest_funT T))
   366                           (fst (fst (mk_rec NONE recs lthy (mk_co_algT TY X))));
   367                     in
   368                       if can dest_co_productT TY then
   369                         mk_map_co_product (mk_co_proj (co_swap (dest_co_productT TY |> fst, U)))
   370                           (HOLogic.id_const X)
   371                         handle TYPE _ => default () (*N2M involving "prod" type*)
   372                       else
   373                         default ()
   374                     end)
   375                 val smap_args = map mk_smap_arg smap_argTs;
   376               in
   377                 mk_co_comp_abs_rep sF sF' fp_abs fp_rep abs rep
   378                   (mk_co_comp (s, Term.list_comb (smap, smap_args)))
   379               end
   380           end;
   381         val t = Term.list_comb (TUrec, map mk_s TUs);
   382       in
   383         (case b_opt of
   384           NONE => ((t, Drule.dummy_thm), lthy)
   385         | SOME b => Local_Theory.define ((b, NoSyn), ((Binding.conceal (Thm.def_binding b), []),
   386             fold_rev Term.absfree rec_strs' t)) lthy |>> apsnd snd)
   387       end;
   388 
   389     val recN = case_fp fp ctor_recN dtor_corecN;
   390     fun mk_recs lthy =
   391       fold2 (fn TU => fn b => fn ((recs, defs), lthy) =>
   392         mk_rec (SOME b) recs lthy TU |>> (fn (f, d) => (f :: recs, d :: defs)))
   393       resTs (map (Binding.suffix_name ("_" ^ recN)) bs) (([], []), lthy)
   394       |>> map_prod rev rev;
   395     val ((raw_co_recs, raw_co_rec_defs), (lthy, raw_lthy)) = lthy
   396       |> mk_recs
   397       ||> `Local_Theory.restore;
   398 
   399     val phi = Proof_Context.export_morphism raw_lthy lthy;
   400 
   401     val co_recs = map (Morphism.term phi) raw_co_recs;
   402 
   403     val fp_rec_o_maps = of_fp_res #xtor_co_rec_o_maps
   404       |> maps (fn thm => [thm, thm RS rewrite_comp_comp]);
   405 
   406     val xtor_co_rec_thms =
   407       let
   408         val recs = map (fn r => Term.list_comb (r, rec_strs)) raw_co_recs;
   409         val rec_mapTs = co_swap (As @ fpTs, As @ map2 mk_co_productT fpTs Xs);
   410         val pre_rec_maps =
   411           map2 (fn Ds => fn bnf =>
   412             Term.list_comb (uncurry (mk_map_of_bnf Ds) rec_mapTs bnf,
   413               map HOLogic.id_const As @ map2 (mk_co_product o HOLogic.id_const) fpTs recs))
   414           Dss bnfs;
   415 
   416         fun mk_goals f xtor s smap fp_abs fp_rep abs rep =
   417           let
   418             val lhs = mk_co_comp (f, xtor);
   419             val rhs = mk_co_comp (s, smap);
   420           in
   421             HOLogic.mk_eq (lhs,
   422               mk_co_comp_abs_rep (co_alg_funT (fastype_of lhs)) (co_alg_funT (fastype_of rhs))
   423                 fp_abs fp_rep abs rep rhs)
   424           end;
   425 
   426         val goals = @{map 8} mk_goals recs xtors rec_strs pre_rec_maps fp_abss fp_reps abss reps;
   427 
   428         val pre_map_defs = no_refl (map map_def_of_bnf bnfs);
   429         val fp_pre_map_defs = no_refl (map map_def_of_bnf pre_bnfs);
   430 
   431         val unfold_map = map (unfold_thms lthy (id_apply :: pre_map_defs));
   432 
   433         val fp_xtor_co_recs = map (mk_pointfree lthy) (of_fp_res #xtor_co_rec_thms);
   434 
   435         val fold_thms = case_fp fp @{thm comp_assoc} @{thm comp_assoc[symmetric]} ::
   436           map (fn thm => thm RS rewrite_comp_comp) @{thms map_prod.comp map_sum.comp} @
   437           @{thms id_apply comp_id id_comp map_prod.comp map_prod.id map_sum.comp map_sum.id};
   438         val rec_thms = fold_thms @ case_fp fp
   439           @{thms fst_convol map_prod_o_convol convol_o fst_comp_map_prod}
   440           @{thms case_sum_o_inj(1) case_sum_o_map_sum o_case_sum map_sum_o_inj(1)};
   441 
   442         val eq_thm_prop_untyped = Term.aconv_untyped o apply2 Thm.full_prop_of;
   443 
   444         val map_thms = no_refl (maps (fn bnf =>
   445            let val map_comp0 = map_comp0_of_bnf bnf RS sym
   446            in [map_comp0, map_comp0 RS rewrite_comp_comp, map_id0_of_bnf bnf] end)
   447           fp_or_nesting_bnfs) @
   448           remove eq_thm_prop_untyped (case_fp fp @{thm comp_assoc[symmetric]} @{thm comp_assoc})
   449           (map2 (fn thm => fn bnf =>
   450             @{thm type_copy_map_comp0_undo} OF
   451               (replicate 3 thm @ unfold_map [map_comp0_of_bnf bnf]) RS
   452               rewrite_comp_comp)
   453           type_definitions bnfs);
   454 
   455         fun mk_Rep_o_Abs thm = (thm RS @{thm type_copy_Rep_o_Abs})
   456           |> (fn thm => [thm, thm RS rewrite_comp_comp]);
   457 
   458         val fp_Rep_o_Abss = maps mk_Rep_o_Abs fp_type_definitions;
   459         val Rep_o_Abss = maps mk_Rep_o_Abs type_definitions;
   460 
   461         fun tac {context = ctxt, prems = _} =
   462           unfold_thms_tac ctxt (flat [rec_thms, raw_co_rec_defs, pre_map_defs,
   463             fp_pre_map_defs, fp_xtor_co_recs, fp_rec_o_maps, map_thms, fp_Rep_o_Abss,
   464             Rep_o_Abss]) THEN
   465           CONJ_WRAP (K (HEADGOAL (rtac refl))) bnfs;
   466       in
   467         Library.foldr1 HOLogic.mk_conj goals
   468         |> HOLogic.mk_Trueprop
   469         |> fold_rev Logic.all rec_strs
   470         |> (fn goal => Goal.prove_sorry raw_lthy [] [] goal tac)
   471         |> Thm.close_derivation
   472         |> Morphism.thm phi
   473         |> split_conj_thm
   474         |> map (fn thm => thm RS @{thm comp_eq_dest})
   475       end;
   476 
   477     (* These results are half broken. This is deliberate. We care only about those fields that are
   478        used by "primrec", "primcorecursive", and "datatype_compat". *)
   479     val fp_res =
   480       ({Ts = fpTs, bnfs = of_fp_res #bnfs, dtors = dtors, ctors = ctors,
   481         xtor_co_recs = co_recs, xtor_co_induct = xtor_co_induct_thm,
   482         dtor_ctors = of_fp_res #dtor_ctors (*too general types*),
   483         ctor_dtors = of_fp_res #ctor_dtors (*too general types*),
   484         ctor_injects = of_fp_res #ctor_injects (*too general types*),
   485         dtor_injects = of_fp_res #dtor_injects (*too general types*),
   486         xtor_maps = of_fp_res #xtor_maps (*too general types and terms*),
   487         xtor_setss = of_fp_res #xtor_setss (*too general types and terms*),
   488         xtor_rels = of_fp_res #xtor_rels (*too general types and terms*),
   489         xtor_co_rec_thms = xtor_co_rec_thms,
   490         xtor_co_rec_o_maps = fp_rec_o_maps (*theorems about old constants*),
   491         xtor_rel_co_induct = xtor_rel_co_induct,
   492         dtor_set_inducts = [],
   493         xtor_co_rec_transfers = []}
   494        |> morph_fp_result (Morphism.term_morphism "BNF" (singleton (Variable.polymorphic lthy))));
   495   in
   496     (fp_res, lthy)
   497   end;
   498 
   499 end;