src/HOL/HOL.thy
author wenzelm
Sun Sep 18 15:16:42 2016 +0200 (2016-09-18)
changeset 63909 cc15bd7c5396
parent 63575 b9bd9e61fd63
child 63912 9f8325206465
permissions -rw-r--r--
clarified notation;
     1 (*  Title:      HOL/HOL.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 section \<open>The basis of Higher-Order Logic\<close>
     6 
     7 theory HOL
     8 imports Pure "~~/src/Tools/Code_Generator"
     9 keywords
    10   "try" "solve_direct" "quickcheck" "print_coercions" "print_claset"
    11     "print_induct_rules" :: diag and
    12   "quickcheck_params" :: thy_decl
    13 begin
    14 
    15 ML_file "~~/src/Tools/misc_legacy.ML"
    16 ML_file "~~/src/Tools/try.ML"
    17 ML_file "~~/src/Tools/quickcheck.ML"
    18 ML_file "~~/src/Tools/solve_direct.ML"
    19 ML_file "~~/src/Tools/IsaPlanner/zipper.ML"
    20 ML_file "~~/src/Tools/IsaPlanner/isand.ML"
    21 ML_file "~~/src/Tools/IsaPlanner/rw_inst.ML"
    22 ML_file "~~/src/Provers/hypsubst.ML"
    23 ML_file "~~/src/Provers/splitter.ML"
    24 ML_file "~~/src/Provers/classical.ML"
    25 ML_file "~~/src/Provers/blast.ML"
    26 ML_file "~~/src/Provers/clasimp.ML"
    27 ML_file "~~/src/Tools/eqsubst.ML"
    28 ML_file "~~/src/Provers/quantifier1.ML"
    29 ML_file "~~/src/Tools/atomize_elim.ML"
    30 ML_file "~~/src/Tools/cong_tac.ML"
    31 ML_file "~~/src/Tools/intuitionistic.ML" setup \<open>Intuitionistic.method_setup @{binding iprover}\<close>
    32 ML_file "~~/src/Tools/project_rule.ML"
    33 ML_file "~~/src/Tools/subtyping.ML"
    34 ML_file "~~/src/Tools/case_product.ML"
    35 
    36 
    37 ML \<open>Plugin_Name.declare_setup @{binding extraction}\<close>
    38 
    39 ML \<open>
    40   Plugin_Name.declare_setup @{binding quickcheck_random};
    41   Plugin_Name.declare_setup @{binding quickcheck_exhaustive};
    42   Plugin_Name.declare_setup @{binding quickcheck_bounded_forall};
    43   Plugin_Name.declare_setup @{binding quickcheck_full_exhaustive};
    44   Plugin_Name.declare_setup @{binding quickcheck_narrowing};
    45 \<close>
    46 ML \<open>
    47   Plugin_Name.define_setup @{binding quickcheck}
    48    [@{plugin quickcheck_exhaustive},
    49     @{plugin quickcheck_random},
    50     @{plugin quickcheck_bounded_forall},
    51     @{plugin quickcheck_full_exhaustive},
    52     @{plugin quickcheck_narrowing}]
    53 \<close>
    54 
    55 
    56 subsection \<open>Primitive logic\<close>
    57 
    58 subsubsection \<open>Core syntax\<close>
    59 
    60 setup \<open>Axclass.class_axiomatization (@{binding type}, [])\<close>
    61 default_sort type
    62 setup \<open>Object_Logic.add_base_sort @{sort type}\<close>
    63 
    64 axiomatization where fun_arity: "OFCLASS('a \<Rightarrow> 'b, type_class)"
    65 instance "fun" :: (type, type) type by (rule fun_arity)
    66 
    67 axiomatization where itself_arity: "OFCLASS('a itself, type_class)"
    68 instance itself :: (type) type by (rule itself_arity)
    69 
    70 typedecl bool
    71 
    72 judgment Trueprop :: "bool \<Rightarrow> prop"  ("(_)" 5)
    73 
    74 axiomatization implies :: "[bool, bool] \<Rightarrow> bool"  (infixr "\<longrightarrow>" 25)
    75   and eq :: "['a, 'a] \<Rightarrow> bool"  (infixl "=" 50)
    76   and The :: "('a \<Rightarrow> bool) \<Rightarrow> 'a"
    77 
    78 
    79 subsubsection \<open>Defined connectives and quantifiers\<close>
    80 
    81 definition True :: bool
    82   where "True \<equiv> ((\<lambda>x::bool. x) = (\<lambda>x. x))"
    83 
    84 definition All :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<forall>" 10)
    85   where "All P \<equiv> (P = (\<lambda>x. True))"
    86 
    87 definition Ex :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<exists>" 10)
    88   where "Ex P \<equiv> \<forall>Q. (\<forall>x. P x \<longrightarrow> Q) \<longrightarrow> Q"
    89 
    90 definition False :: bool
    91   where "False \<equiv> (\<forall>P. P)"
    92 
    93 definition Not :: "bool \<Rightarrow> bool"  ("\<not> _" [40] 40)
    94   where not_def: "\<not> P \<equiv> P \<longrightarrow> False"
    95 
    96 definition conj :: "[bool, bool] \<Rightarrow> bool"  (infixr "\<and>" 35)
    97   where and_def: "P \<and> Q \<equiv> \<forall>R. (P \<longrightarrow> Q \<longrightarrow> R) \<longrightarrow> R"
    98 
    99 definition disj :: "[bool, bool] \<Rightarrow> bool"  (infixr "\<or>" 30)
   100   where or_def: "P \<or> Q \<equiv> \<forall>R. (P \<longrightarrow> R) \<longrightarrow> (Q \<longrightarrow> R) \<longrightarrow> R"
   101 
   102 definition Ex1 :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
   103   where "Ex1 P \<equiv> \<exists>x. P x \<and> (\<forall>y. P y \<longrightarrow> y = x)"
   104 
   105 
   106 subsubsection \<open>Additional concrete syntax\<close>
   107 
   108 syntax (ASCII)
   109   "_Ex1" :: "pttrn \<Rightarrow> bool \<Rightarrow> bool"  ("(3EX! _./ _)" [0, 10] 10)
   110 syntax (input)
   111   "_Ex1" :: "pttrn \<Rightarrow> bool \<Rightarrow> bool"  ("(3?! _./ _)" [0, 10] 10)
   112 syntax "_Ex1" :: "pttrn \<Rightarrow> bool \<Rightarrow> bool"  ("(3\<exists>!_./ _)" [0, 10] 10)
   113 translations "\<exists>!x. P" \<rightleftharpoons> "CONST Ex1 (\<lambda>x. P)"
   114 
   115 print_translation \<open>
   116  [Syntax_Trans.preserve_binder_abs_tr' @{const_syntax Ex1} @{syntax_const "_Ex1"}]
   117 \<close> \<comment> \<open>to avoid eta-contraction of body\<close>
   118 
   119 
   120 abbreviation Not_Ex :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<nexists>" 10)
   121   where "\<nexists>x. P x \<equiv> \<not> (\<exists>x. P x)"
   122 
   123 abbreviation Not_Ex1 :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<nexists>!" 10)
   124   where "\<nexists>!x. P x \<equiv> \<not> (\<exists>!x. P x)"
   125 
   126 abbreviation not_equal :: "['a, 'a] \<Rightarrow> bool"  (infixl "\<noteq>" 50)
   127   where "x \<noteq> y \<equiv> \<not> (x = y)"
   128 
   129 notation (output)
   130   eq  (infix "=" 50) and
   131   not_equal  (infix "\<noteq>" 50)
   132 
   133 notation (ASCII output)
   134   not_equal  (infix "~=" 50)
   135 
   136 notation (ASCII)
   137   Not  ("~ _" [40] 40) and
   138   conj  (infixr "&" 35) and
   139   disj  (infixr "|" 30) and
   140   implies  (infixr "-->" 25) and
   141   not_equal  (infixl "~=" 50)
   142 
   143 abbreviation (iff)
   144   iff :: "[bool, bool] \<Rightarrow> bool"  (infixr "\<longleftrightarrow>" 25)
   145   where "A \<longleftrightarrow> B \<equiv> A = B"
   146 
   147 syntax "_The" :: "[pttrn, bool] \<Rightarrow> 'a"  ("(3THE _./ _)" [0, 10] 10)
   148 translations "THE x. P" \<rightleftharpoons> "CONST The (\<lambda>x. P)"
   149 print_translation \<open>
   150   [(@{const_syntax The}, fn _ => fn [Abs abs] =>
   151       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
   152       in Syntax.const @{syntax_const "_The"} $ x $ t end)]
   153 \<close>  \<comment> \<open>To avoid eta-contraction of body\<close>
   154 
   155 nonterminal letbinds and letbind
   156 syntax
   157   "_bind"       :: "[pttrn, 'a] \<Rightarrow> letbind"              ("(2_ =/ _)" 10)
   158   ""            :: "letbind \<Rightarrow> letbinds"                 ("_")
   159   "_binds"      :: "[letbind, letbinds] \<Rightarrow> letbinds"     ("_;/ _")
   160   "_Let"        :: "[letbinds, 'a] \<Rightarrow> 'a"                ("(let (_)/ in (_))" [0, 10] 10)
   161 
   162 nonterminal case_syn and cases_syn
   163 syntax
   164   "_case_syntax" :: "['a, cases_syn] \<Rightarrow> 'b"  ("(case _ of/ _)" 10)
   165   "_case1" :: "['a, 'b] \<Rightarrow> case_syn"  ("(2_ \<Rightarrow>/ _)" 10)
   166   "" :: "case_syn \<Rightarrow> cases_syn"  ("_")
   167   "_case2" :: "[case_syn, cases_syn] \<Rightarrow> cases_syn"  ("_/ | _")
   168 syntax (ASCII)
   169   "_case1" :: "['a, 'b] \<Rightarrow> case_syn"  ("(2_ =>/ _)" 10)
   170 
   171 notation (ASCII)
   172   All  (binder "ALL " 10) and
   173   Ex  (binder "EX " 10)
   174 
   175 notation (input)
   176   All  (binder "! " 10) and
   177   Ex  (binder "? " 10)
   178 
   179 
   180 subsubsection \<open>Axioms and basic definitions\<close>
   181 
   182 axiomatization where
   183   refl: "t = (t::'a)" and
   184   subst: "s = t \<Longrightarrow> P s \<Longrightarrow> P t" and
   185   ext: "(\<And>x::'a. (f x ::'b) = g x) \<Longrightarrow> (\<lambda>x. f x) = (\<lambda>x. g x)"
   186     \<comment> \<open>Extensionality is built into the meta-logic, and this rule expresses
   187          a related property.  It is an eta-expanded version of the traditional
   188          rule, and similar to the ABS rule of HOL\<close> and
   189 
   190   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   191 
   192 axiomatization where
   193   impI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<longrightarrow> Q" and
   194   mp: "\<lbrakk>P \<longrightarrow> Q; P\<rbrakk> \<Longrightarrow> Q" and
   195 
   196   iff: "(P \<longrightarrow> Q) \<longrightarrow> (Q \<longrightarrow> P) \<longrightarrow> (P = Q)" and
   197   True_or_False: "(P = True) \<or> (P = False)"
   198 
   199 definition If :: "bool \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'a" ("(if (_)/ then (_)/ else (_))" [0, 0, 10] 10)
   200   where "If P x y \<equiv> (THE z::'a. (P = True \<longrightarrow> z = x) \<and> (P = False \<longrightarrow> z = y))"
   201 
   202 definition Let :: "'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b"
   203   where "Let s f \<equiv> f s"
   204 
   205 translations
   206   "_Let (_binds b bs) e"  \<rightleftharpoons> "_Let b (_Let bs e)"
   207   "let x = a in e"        \<rightleftharpoons> "CONST Let a (\<lambda>x. e)"
   208 
   209 axiomatization undefined :: 'a
   210 
   211 class default = fixes default :: 'a
   212 
   213 
   214 subsection \<open>Fundamental rules\<close>
   215 
   216 subsubsection \<open>Equality\<close>
   217 
   218 lemma sym: "s = t \<Longrightarrow> t = s"
   219   by (erule subst) (rule refl)
   220 
   221 lemma ssubst: "t = s \<Longrightarrow> P s \<Longrightarrow> P t"
   222   by (drule sym) (erule subst)
   223 
   224 lemma trans: "\<lbrakk>r = s; s = t\<rbrakk> \<Longrightarrow> r = t"
   225   by (erule subst)
   226 
   227 lemma trans_sym [Pure.elim?]: "r = s \<Longrightarrow> t = s \<Longrightarrow> r = t"
   228   by (rule trans [OF _ sym])
   229 
   230 lemma meta_eq_to_obj_eq:
   231   assumes "A \<equiv> B"
   232   shows "A = B"
   233   unfolding assms by (rule refl)
   234 
   235 text \<open>Useful with \<open>erule\<close> for proving equalities from known equalities.\<close>
   236      (* a = b
   237         |   |
   238         c = d   *)
   239 lemma box_equals: "\<lbrakk>a = b; a = c; b = d\<rbrakk> \<Longrightarrow> c = d"
   240   apply (rule trans)
   241    apply (rule trans)
   242     apply (rule sym)
   243     apply assumption+
   244   done
   245 
   246 text \<open>For calculational reasoning:\<close>
   247 
   248 lemma forw_subst: "a = b \<Longrightarrow> P b \<Longrightarrow> P a"
   249   by (rule ssubst)
   250 
   251 lemma back_subst: "P a \<Longrightarrow> a = b \<Longrightarrow> P b"
   252   by (rule subst)
   253 
   254 
   255 subsubsection \<open>Congruence rules for application\<close>
   256 
   257 text \<open>Similar to \<open>AP_THM\<close> in Gordon's HOL.\<close>
   258 lemma fun_cong: "(f :: 'a \<Rightarrow> 'b) = g \<Longrightarrow> f x = g x"
   259   apply (erule subst)
   260   apply (rule refl)
   261   done
   262 
   263 text \<open>Similar to \<open>AP_TERM\<close> in Gordon's HOL and FOL's \<open>subst_context\<close>.\<close>
   264 lemma arg_cong: "x = y \<Longrightarrow> f x = f y"
   265   apply (erule subst)
   266   apply (rule refl)
   267   done
   268 
   269 lemma arg_cong2: "\<lbrakk>a = b; c = d\<rbrakk> \<Longrightarrow> f a c = f b d"
   270   apply (erule ssubst)+
   271   apply (rule refl)
   272   done
   273 
   274 lemma cong: "\<lbrakk>f = g; (x::'a) = y\<rbrakk> \<Longrightarrow> f x = g y"
   275   apply (erule subst)+
   276   apply (rule refl)
   277   done
   278 
   279 ML \<open>fun cong_tac ctxt = Cong_Tac.cong_tac ctxt @{thm cong}\<close>
   280 
   281 
   282 subsubsection \<open>Equality of booleans -- iff\<close>
   283 
   284 lemma iffI: assumes "P \<Longrightarrow> Q" and "Q \<Longrightarrow> P" shows "P = Q"
   285   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   286 
   287 lemma iffD2: "\<lbrakk>P = Q; Q\<rbrakk> \<Longrightarrow> P"
   288   by (erule ssubst)
   289 
   290 lemma rev_iffD2: "\<lbrakk>Q; P = Q\<rbrakk> \<Longrightarrow> P"
   291   by (erule iffD2)
   292 
   293 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   294   by (drule sym) (rule iffD2)
   295 
   296 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   297   by (drule sym) (rule rev_iffD2)
   298 
   299 lemma iffE:
   300   assumes major: "P = Q"
   301     and minor: "\<lbrakk>P \<longrightarrow> Q; Q \<longrightarrow> P\<rbrakk> \<Longrightarrow> R"
   302   shows R
   303   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   304 
   305 
   306 subsubsection \<open>True\<close>
   307 
   308 lemma TrueI: True
   309   unfolding True_def by (rule refl)
   310 
   311 lemma eqTrueI: "P \<Longrightarrow> P = True"
   312   by (iprover intro: iffI TrueI)
   313 
   314 lemma eqTrueE: "P = True \<Longrightarrow> P"
   315   by (erule iffD2) (rule TrueI)
   316 
   317 
   318 subsubsection \<open>Universal quantifier\<close>
   319 
   320 lemma allI:
   321   assumes "\<And>x::'a. P x"
   322   shows "\<forall>x. P x"
   323   unfolding All_def by (iprover intro: ext eqTrueI assms)
   324 
   325 lemma spec: "\<forall>x::'a. P x \<Longrightarrow> P x"
   326   apply (unfold All_def)
   327   apply (rule eqTrueE)
   328   apply (erule fun_cong)
   329   done
   330 
   331 lemma allE:
   332   assumes major: "\<forall>x. P x"
   333     and minor: "P x \<Longrightarrow> R"
   334   shows R
   335   by (iprover intro: minor major [THEN spec])
   336 
   337 lemma all_dupE:
   338   assumes major: "\<forall>x. P x"
   339     and minor: "\<lbrakk>P x; \<forall>x. P x\<rbrakk> \<Longrightarrow> R"
   340   shows R
   341   by (iprover intro: minor major major [THEN spec])
   342 
   343 
   344 subsubsection \<open>False\<close>
   345 
   346 text \<open>
   347   Depends upon \<open>spec\<close>; it is impossible to do propositional
   348   logic before quantifiers!
   349 \<close>
   350 
   351 lemma FalseE: "False \<Longrightarrow> P"
   352   apply (unfold False_def)
   353   apply (erule spec)
   354   done
   355 
   356 lemma False_neq_True: "False = True \<Longrightarrow> P"
   357   by (erule eqTrueE [THEN FalseE])
   358 
   359 
   360 subsubsection \<open>Negation\<close>
   361 
   362 lemma notI:
   363   assumes "P \<Longrightarrow> False"
   364   shows "\<not> P"
   365   apply (unfold not_def)
   366   apply (iprover intro: impI assms)
   367   done
   368 
   369 lemma False_not_True: "False \<noteq> True"
   370   apply (rule notI)
   371   apply (erule False_neq_True)
   372   done
   373 
   374 lemma True_not_False: "True \<noteq> False"
   375   apply (rule notI)
   376   apply (drule sym)
   377   apply (erule False_neq_True)
   378   done
   379 
   380 lemma notE: "\<lbrakk>\<not> P; P\<rbrakk> \<Longrightarrow> R"
   381   apply (unfold not_def)
   382   apply (erule mp [THEN FalseE])
   383   apply assumption
   384   done
   385 
   386 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   387   by (erule notE [THEN notI]) (erule meta_mp)
   388 
   389 
   390 subsubsection \<open>Implication\<close>
   391 
   392 lemma impE:
   393   assumes "P \<longrightarrow> Q" P "Q \<Longrightarrow> R"
   394   shows R
   395   by (iprover intro: assms mp)
   396 
   397 text \<open>Reduces \<open>Q\<close> to \<open>P \<longrightarrow> Q\<close>, allowing substitution in \<open>P\<close>.\<close>
   398 lemma rev_mp: "\<lbrakk>P; P \<longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   399   by (iprover intro: mp)
   400 
   401 lemma contrapos_nn:
   402   assumes major: "\<not> Q"
   403     and minor: "P \<Longrightarrow> Q"
   404   shows "\<not> P"
   405   by (iprover intro: notI minor major [THEN notE])
   406 
   407 text \<open>Not used at all, but we already have the other 3 combinations.\<close>
   408 lemma contrapos_pn:
   409   assumes major: "Q"
   410     and minor: "P \<Longrightarrow> \<not> Q"
   411   shows "\<not> P"
   412   by (iprover intro: notI minor major notE)
   413 
   414 lemma not_sym: "t \<noteq> s \<Longrightarrow> s \<noteq> t"
   415   by (erule contrapos_nn) (erule sym)
   416 
   417 lemma eq_neq_eq_imp_neq: "\<lbrakk>x = a; a \<noteq> b; b = y\<rbrakk> \<Longrightarrow> x \<noteq> y"
   418   by (erule subst, erule ssubst, assumption)
   419 
   420 
   421 subsubsection \<open>Existential quantifier\<close>
   422 
   423 lemma exI: "P x \<Longrightarrow> \<exists>x::'a. P x"
   424   unfolding Ex_def by (iprover intro: allI allE impI mp)
   425 
   426 lemma exE:
   427   assumes major: "\<exists>x::'a. P x"
   428     and minor: "\<And>x. P x \<Longrightarrow> Q"
   429   shows "Q"
   430   by (rule major [unfolded Ex_def, THEN spec, THEN mp]) (iprover intro: impI [THEN allI] minor)
   431 
   432 
   433 subsubsection \<open>Conjunction\<close>
   434 
   435 lemma conjI: "\<lbrakk>P; Q\<rbrakk> \<Longrightarrow> P \<and> Q"
   436   unfolding and_def by (iprover intro: impI [THEN allI] mp)
   437 
   438 lemma conjunct1: "\<lbrakk>P \<and> Q\<rbrakk> \<Longrightarrow> P"
   439   unfolding and_def by (iprover intro: impI dest: spec mp)
   440 
   441 lemma conjunct2: "\<lbrakk>P \<and> Q\<rbrakk> \<Longrightarrow> Q"
   442   unfolding and_def by (iprover intro: impI dest: spec mp)
   443 
   444 lemma conjE:
   445   assumes major: "P \<and> Q"
   446     and minor: "\<lbrakk>P; Q\<rbrakk> \<Longrightarrow> R"
   447   shows R
   448   apply (rule minor)
   449    apply (rule major [THEN conjunct1])
   450   apply (rule major [THEN conjunct2])
   451   done
   452 
   453 lemma context_conjI:
   454   assumes P "P \<Longrightarrow> Q"
   455   shows "P \<and> Q"
   456   by (iprover intro: conjI assms)
   457 
   458 
   459 subsubsection \<open>Disjunction\<close>
   460 
   461 lemma disjI1: "P \<Longrightarrow> P \<or> Q"
   462   unfolding or_def by (iprover intro: allI impI mp)
   463 
   464 lemma disjI2: "Q \<Longrightarrow> P \<or> Q"
   465   unfolding or_def by (iprover intro: allI impI mp)
   466 
   467 lemma disjE:
   468   assumes major: "P \<or> Q"
   469     and minorP: "P \<Longrightarrow> R"
   470     and minorQ: "Q \<Longrightarrow> R"
   471   shows R
   472   by (iprover intro: minorP minorQ impI
   473       major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   474 
   475 
   476 subsubsection \<open>Classical logic\<close>
   477 
   478 lemma classical:
   479   assumes prem: "\<not> P \<Longrightarrow> P"
   480   shows P
   481   apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   482    apply assumption
   483   apply (rule notI [THEN prem, THEN eqTrueI])
   484   apply (erule subst)
   485   apply assumption
   486   done
   487 
   488 lemmas ccontr = FalseE [THEN classical]
   489 
   490 text \<open>\<open>notE\<close> with premises exchanged; it discharges \<open>\<not> R\<close> so that it can be used to
   491   make elimination rules.\<close>
   492 lemma rev_notE:
   493   assumes premp: P
   494     and premnot: "\<not> R \<Longrightarrow> \<not> P"
   495   shows R
   496   apply (rule ccontr)
   497   apply (erule notE [OF premnot premp])
   498   done
   499 
   500 text \<open>Double negation law.\<close>
   501 lemma notnotD: "\<not>\<not> P \<Longrightarrow> P"
   502   apply (rule classical)
   503   apply (erule notE)
   504   apply assumption
   505   done
   506 
   507 lemma contrapos_pp:
   508   assumes p1: Q
   509     and p2: "\<not> P \<Longrightarrow> \<not> Q"
   510   shows P
   511   by (iprover intro: classical p1 p2 notE)
   512 
   513 
   514 subsubsection \<open>Unique existence\<close>
   515 
   516 lemma ex1I:
   517   assumes "P a" "\<And>x. P x \<Longrightarrow> x = a"
   518   shows "\<exists>!x. P x"
   519   unfolding Ex1_def by (iprover intro: assms exI conjI allI impI)
   520 
   521 text \<open>Sometimes easier to use: the premises have no shared variables. Safe!\<close>
   522 lemma ex_ex1I:
   523   assumes ex_prem: "\<exists>x. P x"
   524     and eq: "\<And>x y. \<lbrakk>P x; P y\<rbrakk> \<Longrightarrow> x = y"
   525   shows "\<exists>!x. P x"
   526   by (iprover intro: ex_prem [THEN exE] ex1I eq)
   527 
   528 lemma ex1E:
   529   assumes major: "\<exists>!x. P x"
   530     and minor: "\<And>x. \<lbrakk>P x; \<forall>y. P y \<longrightarrow> y = x\<rbrakk> \<Longrightarrow> R"
   531   shows R
   532   apply (rule major [unfolded Ex1_def, THEN exE])
   533   apply (erule conjE)
   534   apply (iprover intro: minor)
   535   done
   536 
   537 lemma ex1_implies_ex: "\<exists>!x. P x \<Longrightarrow> \<exists>x. P x"
   538   apply (erule ex1E)
   539   apply (rule exI)
   540   apply assumption
   541   done
   542 
   543 
   544 subsubsection \<open>Classical intro rules for disjunction and existential quantifiers\<close>
   545 
   546 lemma disjCI:
   547   assumes "\<not> Q \<Longrightarrow> P"
   548   shows "P \<or> Q"
   549   by (rule classical) (iprover intro: assms disjI1 disjI2 notI elim: notE)
   550 
   551 lemma excluded_middle: "\<not> P \<or> P"
   552   by (iprover intro: disjCI)
   553 
   554 text \<open>
   555   case distinction as a natural deduction rule.
   556   Note that \<open>\<not> P\<close> is the second case, not the first.
   557 \<close>
   558 lemma case_split [case_names True False]:
   559   assumes prem1: "P \<Longrightarrow> Q"
   560     and prem2: "\<not> P \<Longrightarrow> Q"
   561   shows Q
   562   apply (rule excluded_middle [THEN disjE])
   563    apply (erule prem2)
   564   apply (erule prem1)
   565   done
   566 
   567 text \<open>Classical implies (\<open>\<longrightarrow>\<close>) elimination.\<close>
   568 lemma impCE:
   569   assumes major: "P \<longrightarrow> Q"
   570     and minor: "\<not> P \<Longrightarrow> R" "Q \<Longrightarrow> R"
   571   shows R
   572   apply (rule excluded_middle [of P, THEN disjE])
   573    apply (iprover intro: minor major [THEN mp])+
   574   done
   575 
   576 text \<open>
   577   This version of \<open>\<longrightarrow>\<close> elimination works on \<open>Q\<close> before \<open>P\<close>.  It works best for
   578   those cases in which \<open>P\<close> holds "almost everywhere".  Can't install as
   579   default: would break old proofs.
   580 \<close>
   581 lemma impCE':
   582   assumes major: "P \<longrightarrow> Q"
   583     and minor: "Q \<Longrightarrow> R" "\<not> P \<Longrightarrow> R"
   584   shows R
   585   apply (rule excluded_middle [of P, THEN disjE])
   586    apply (iprover intro: minor major [THEN mp])+
   587   done
   588 
   589 text \<open>Classical \<open>\<longleftrightarrow>\<close> elimination.\<close>
   590 lemma iffCE:
   591   assumes major: "P = Q"
   592     and minor: "\<lbrakk>P; Q\<rbrakk> \<Longrightarrow> R" "\<lbrakk>\<not> P; \<not> Q\<rbrakk> \<Longrightarrow> R"
   593   shows R
   594   by (rule major [THEN iffE]) (iprover intro: minor elim: impCE notE)
   595 
   596 lemma exCI:
   597   assumes "\<forall>x. \<not> P x \<Longrightarrow> P a"
   598   shows "\<exists>x. P x"
   599   by (rule ccontr) (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   600 
   601 
   602 subsubsection \<open>Intuitionistic Reasoning\<close>
   603 
   604 lemma impE':
   605   assumes 1: "P \<longrightarrow> Q"
   606     and 2: "Q \<Longrightarrow> R"
   607     and 3: "P \<longrightarrow> Q \<Longrightarrow> P"
   608   shows R
   609 proof -
   610   from 3 and 1 have P .
   611   with 1 have Q by (rule impE)
   612   with 2 show R .
   613 qed
   614 
   615 lemma allE':
   616   assumes 1: "\<forall>x. P x"
   617     and 2: "P x \<Longrightarrow> \<forall>x. P x \<Longrightarrow> Q"
   618   shows Q
   619 proof -
   620   from 1 have "P x" by (rule spec)
   621   from this and 1 show Q by (rule 2)
   622 qed
   623 
   624 lemma notE':
   625   assumes 1: "\<not> P"
   626     and 2: "\<not> P \<Longrightarrow> P"
   627   shows R
   628 proof -
   629   from 2 and 1 have P .
   630   with 1 show R by (rule notE)
   631 qed
   632 
   633 lemma TrueE: "True \<Longrightarrow> P \<Longrightarrow> P" .
   634 lemma notFalseE: "\<not> False \<Longrightarrow> P \<Longrightarrow> P" .
   635 
   636 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   637   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   638   and [Pure.elim 2] = allE notE' impE'
   639   and [Pure.intro] = exI disjI2 disjI1
   640 
   641 lemmas [trans] = trans
   642   and [sym] = sym not_sym
   643   and [Pure.elim?] = iffD1 iffD2 impE
   644 
   645 
   646 subsubsection \<open>Atomizing meta-level connectives\<close>
   647 
   648 axiomatization where
   649   eq_reflection: "x = y \<Longrightarrow> x \<equiv> y"  \<comment> \<open>admissible axiom\<close>
   650 
   651 lemma atomize_all [atomize]: "(\<And>x. P x) \<equiv> Trueprop (\<forall>x. P x)"
   652 proof
   653   assume "\<And>x. P x"
   654   then show "\<forall>x. P x" ..
   655 next
   656   assume "\<forall>x. P x"
   657   then show "\<And>x. P x" by (rule allE)
   658 qed
   659 
   660 lemma atomize_imp [atomize]: "(A \<Longrightarrow> B) \<equiv> Trueprop (A \<longrightarrow> B)"
   661 proof
   662   assume r: "A \<Longrightarrow> B"
   663   show "A \<longrightarrow> B" by (rule impI) (rule r)
   664 next
   665   assume "A \<longrightarrow> B" and A
   666   then show B by (rule mp)
   667 qed
   668 
   669 lemma atomize_not: "(A \<Longrightarrow> False) \<equiv> Trueprop (\<not> A)"
   670 proof
   671   assume r: "A \<Longrightarrow> False"
   672   show "\<not> A" by (rule notI) (rule r)
   673 next
   674   assume "\<not> A" and A
   675   then show False by (rule notE)
   676 qed
   677 
   678 lemma atomize_eq [atomize, code]: "(x \<equiv> y) \<equiv> Trueprop (x = y)"
   679 proof
   680   assume "x \<equiv> y"
   681   show "x = y" by (unfold \<open>x \<equiv> y\<close>) (rule refl)
   682 next
   683   assume "x = y"
   684   then show "x \<equiv> y" by (rule eq_reflection)
   685 qed
   686 
   687 lemma atomize_conj [atomize]: "(A &&& B) \<equiv> Trueprop (A \<and> B)"
   688 proof
   689   assume conj: "A &&& B"
   690   show "A \<and> B"
   691   proof (rule conjI)
   692     from conj show A by (rule conjunctionD1)
   693     from conj show B by (rule conjunctionD2)
   694   qed
   695 next
   696   assume conj: "A \<and> B"
   697   show "A &&& B"
   698   proof -
   699     from conj show A ..
   700     from conj show B ..
   701   qed
   702 qed
   703 
   704 lemmas [symmetric, rulify] = atomize_all atomize_imp
   705   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   706 
   707 
   708 subsubsection \<open>Atomizing elimination rules\<close>
   709 
   710 lemma atomize_exL[atomize_elim]: "(\<And>x. P x \<Longrightarrow> Q) \<equiv> ((\<exists>x. P x) \<Longrightarrow> Q)"
   711   by rule iprover+
   712 
   713 lemma atomize_conjL[atomize_elim]: "(A \<Longrightarrow> B \<Longrightarrow> C) \<equiv> (A \<and> B \<Longrightarrow> C)"
   714   by rule iprover+
   715 
   716 lemma atomize_disjL[atomize_elim]: "((A \<Longrightarrow> C) \<Longrightarrow> (B \<Longrightarrow> C) \<Longrightarrow> C) \<equiv> ((A \<or> B \<Longrightarrow> C) \<Longrightarrow> C)"
   717   by rule iprover+
   718 
   719 lemma atomize_elimL[atomize_elim]: "(\<And>B. (A \<Longrightarrow> B) \<Longrightarrow> B) \<equiv> Trueprop A" ..
   720 
   721 
   722 subsection \<open>Package setup\<close>
   723 
   724 ML_file "Tools/hologic.ML"
   725 
   726 
   727 subsubsection \<open>Sledgehammer setup\<close>
   728 
   729 text \<open>
   730   Theorems blacklisted to Sledgehammer. These theorems typically produce clauses
   731   that are prolific (match too many equality or membership literals) and relate to
   732   seldom-used facts. Some duplicate other rules.
   733 \<close>
   734 
   735 named_theorems no_atp "theorems that should be filtered out by Sledgehammer"
   736 
   737 
   738 subsubsection \<open>Classical Reasoner setup\<close>
   739 
   740 lemma imp_elim: "P \<longrightarrow> Q \<Longrightarrow> (\<not> R \<Longrightarrow> P) \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
   741   by (rule classical) iprover
   742 
   743 lemma swap: "\<not> P \<Longrightarrow> (\<not> R \<Longrightarrow> P) \<Longrightarrow> R"
   744   by (rule classical) iprover
   745 
   746 lemma thin_refl: "\<lbrakk>x = x; PROP W\<rbrakk> \<Longrightarrow> PROP W" .
   747 
   748 ML \<open>
   749 structure Hypsubst = Hypsubst
   750 (
   751   val dest_eq = HOLogic.dest_eq
   752   val dest_Trueprop = HOLogic.dest_Trueprop
   753   val dest_imp = HOLogic.dest_imp
   754   val eq_reflection = @{thm eq_reflection}
   755   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   756   val imp_intr = @{thm impI}
   757   val rev_mp = @{thm rev_mp}
   758   val subst = @{thm subst}
   759   val sym = @{thm sym}
   760   val thin_refl = @{thm thin_refl};
   761 );
   762 open Hypsubst;
   763 
   764 structure Classical = Classical
   765 (
   766   val imp_elim = @{thm imp_elim}
   767   val not_elim = @{thm notE}
   768   val swap = @{thm swap}
   769   val classical = @{thm classical}
   770   val sizef = Drule.size_of_thm
   771   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   772 );
   773 
   774 structure Basic_Classical: BASIC_CLASSICAL = Classical;
   775 open Basic_Classical;
   776 \<close>
   777 
   778 setup \<open>
   779   (*prevent substitution on bool*)
   780   let
   781     fun non_bool_eq (@{const_name HOL.eq}, Type (_, [T, _])) = T <> @{typ bool}
   782       | non_bool_eq _ = false;
   783     fun hyp_subst_tac' ctxt =
   784       SUBGOAL (fn (goal, i) =>
   785         if Term.exists_Const non_bool_eq goal
   786         then Hypsubst.hyp_subst_tac ctxt i
   787         else no_tac);
   788   in
   789     Context_Rules.addSWrapper (fn ctxt => fn tac => hyp_subst_tac' ctxt ORELSE' tac)
   790   end
   791 \<close>
   792 
   793 declare iffI [intro!]
   794   and notI [intro!]
   795   and impI [intro!]
   796   and disjCI [intro!]
   797   and conjI [intro!]
   798   and TrueI [intro!]
   799   and refl [intro!]
   800 
   801 declare iffCE [elim!]
   802   and FalseE [elim!]
   803   and impCE [elim!]
   804   and disjE [elim!]
   805   and conjE [elim!]
   806 
   807 declare ex_ex1I [intro!]
   808   and allI [intro!]
   809   and exI [intro]
   810 
   811 declare exE [elim!]
   812   allE [elim]
   813 
   814 ML \<open>val HOL_cs = claset_of @{context}\<close>
   815 
   816 lemma contrapos_np: "\<not> Q \<Longrightarrow> (\<not> P \<Longrightarrow> Q) \<Longrightarrow> P"
   817   apply (erule swap)
   818   apply (erule (1) meta_mp)
   819   done
   820 
   821 declare ex_ex1I [rule del, intro! 2]
   822   and ex1I [intro]
   823 
   824 declare ext [intro]
   825 
   826 lemmas [intro?] = ext
   827   and [elim?] = ex1_implies_ex
   828 
   829 text \<open>Better than \<open>ex1E\<close> for classical reasoner: needs no quantifier duplication!\<close>
   830 lemma alt_ex1E [elim!]:
   831   assumes major: "\<exists>!x. P x"
   832     and prem: "\<And>x. \<lbrakk>P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y'\<rbrakk> \<Longrightarrow> R"
   833   shows R
   834   apply (rule ex1E [OF major])
   835   apply (rule prem)
   836    apply assumption
   837   apply (rule allI)+
   838   apply (tactic \<open>eresolve_tac @{context} [Classical.dup_elim @{context} @{thm allE}] 1\<close>)
   839   apply iprover
   840   done
   841 
   842 ML \<open>
   843   structure Blast = Blast
   844   (
   845     structure Classical = Classical
   846     val Trueprop_const = dest_Const @{const Trueprop}
   847     val equality_name = @{const_name HOL.eq}
   848     val not_name = @{const_name Not}
   849     val notE = @{thm notE}
   850     val ccontr = @{thm ccontr}
   851     val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
   852   );
   853   val blast_tac = Blast.blast_tac;
   854 \<close>
   855 
   856 
   857 subsubsection \<open>THE: definite description operator\<close>
   858 
   859 lemma the_equality [intro]:
   860   assumes "P a"
   861     and "\<And>x. P x \<Longrightarrow> x = a"
   862   shows "(THE x. P x) = a"
   863   by (blast intro: assms trans [OF arg_cong [where f=The] the_eq_trivial])
   864 
   865 lemma theI:
   866   assumes "P a"
   867     and "\<And>x. P x \<Longrightarrow> x = a"
   868   shows "P (THE x. P x)"
   869   by (iprover intro: assms the_equality [THEN ssubst])
   870 
   871 lemma theI': "\<exists>!x. P x \<Longrightarrow> P (THE x. P x)"
   872   by (blast intro: theI)
   873 
   874 text \<open>Easier to apply than \<open>theI\<close>: only one occurrence of \<open>P\<close>.\<close>
   875 lemma theI2:
   876   assumes "P a" "\<And>x. P x \<Longrightarrow> x = a" "\<And>x. P x \<Longrightarrow> Q x"
   877   shows "Q (THE x. P x)"
   878   by (iprover intro: assms theI)
   879 
   880 lemma the1I2:
   881   assumes "\<exists>!x. P x" "\<And>x. P x \<Longrightarrow> Q x"
   882   shows "Q (THE x. P x)"
   883   by (iprover intro: assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)] elim: allE impE)
   884 
   885 lemma the1_equality [elim?]: "\<lbrakk>\<exists>!x. P x; P a\<rbrakk> \<Longrightarrow> (THE x. P x) = a"
   886   by blast
   887 
   888 lemma the_sym_eq_trivial: "(THE y. x = y) = x"
   889   by blast
   890 
   891 
   892 subsubsection \<open>Simplifier\<close>
   893 
   894 lemma eta_contract_eq: "(\<lambda>s. f s) = f" ..
   895 
   896 lemma simp_thms:
   897   shows not_not: "(\<not> \<not> P) = P"
   898   and Not_eq_iff: "((\<not> P) = (\<not> Q)) = (P = Q)"
   899   and
   900     "(P \<noteq> Q) = (P = (\<not> Q))"
   901     "(P \<or> \<not>P) = True"    "(\<not> P \<or> P) = True"
   902     "(x = x) = True"
   903   and not_True_eq_False [code]: "(\<not> True) = False"
   904   and not_False_eq_True [code]: "(\<not> False) = True"
   905   and
   906     "(\<not> P) \<noteq> P"  "P \<noteq> (\<not> P)"
   907     "(True = P) = P"
   908   and eq_True: "(P = True) = P"
   909   and "(False = P) = (\<not> P)"
   910   and eq_False: "(P = False) = (\<not> P)"
   911   and
   912     "(True \<longrightarrow> P) = P"  "(False \<longrightarrow> P) = True"
   913     "(P \<longrightarrow> True) = True"  "(P \<longrightarrow> P) = True"
   914     "(P \<longrightarrow> False) = (\<not> P)"  "(P \<longrightarrow> \<not> P) = (\<not> P)"
   915     "(P \<and> True) = P"  "(True \<and> P) = P"
   916     "(P \<and> False) = False"  "(False \<and> P) = False"
   917     "(P \<and> P) = P"  "(P \<and> (P \<and> Q)) = (P \<and> Q)"
   918     "(P \<and> \<not> P) = False"    "(\<not> P \<and> P) = False"
   919     "(P \<or> True) = True"  "(True \<or> P) = True"
   920     "(P \<or> False) = P"  "(False \<or> P) = P"
   921     "(P \<or> P) = P"  "(P \<or> (P \<or> Q)) = (P \<or> Q)" and
   922     "(\<forall>x. P) = P"  "(\<exists>x. P) = P"  "\<exists>x. x = t"  "\<exists>x. t = x"
   923   and
   924     "\<And>P. (\<exists>x. x = t \<and> P x) = P t"
   925     "\<And>P. (\<exists>x. t = x \<and> P x) = P t"
   926     "\<And>P. (\<forall>x. x = t \<longrightarrow> P x) = P t"
   927     "\<And>P. (\<forall>x. t = x \<longrightarrow> P x) = P t"
   928   by (blast, blast, blast, blast, blast, iprover+)
   929 
   930 lemma disj_absorb: "A \<or> A \<longleftrightarrow> A"
   931   by blast
   932 
   933 lemma disj_left_absorb: "A \<or> (A \<or> B) \<longleftrightarrow> A \<or> B"
   934   by blast
   935 
   936 lemma conj_absorb: "A \<and> A \<longleftrightarrow> A"
   937   by blast
   938 
   939 lemma conj_left_absorb: "A \<and> (A \<and> B) \<longleftrightarrow> A \<and> B"
   940   by blast
   941 
   942 lemma eq_ac:
   943   shows eq_commute: "a = b \<longleftrightarrow> b = a"
   944     and iff_left_commute: "(P \<longleftrightarrow> (Q \<longleftrightarrow> R)) \<longleftrightarrow> (Q \<longleftrightarrow> (P \<longleftrightarrow> R))"
   945     and iff_assoc: "((P \<longleftrightarrow> Q) \<longleftrightarrow> R) \<longleftrightarrow> (P \<longleftrightarrow> (Q \<longleftrightarrow> R))"
   946   by (iprover, blast+)
   947 
   948 lemma neq_commute: "a \<noteq> b \<longleftrightarrow> b \<noteq> a" by iprover
   949 
   950 lemma conj_comms:
   951   shows conj_commute: "P \<and> Q \<longleftrightarrow> Q \<and> P"
   952     and conj_left_commute: "P \<and> (Q \<and> R) \<longleftrightarrow> Q \<and> (P \<and> R)" by iprover+
   953 lemma conj_assoc: "(P \<and> Q) \<and> R \<longleftrightarrow> P \<and> (Q \<and> R)" by iprover
   954 
   955 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
   956 
   957 lemma disj_comms:
   958   shows disj_commute: "P \<or> Q \<longleftrightarrow> Q \<or> P"
   959     and disj_left_commute: "P \<or> (Q \<or> R) \<longleftrightarrow> Q \<or> (P \<or> R)" by iprover+
   960 lemma disj_assoc: "(P \<or> Q) \<or> R \<longleftrightarrow> P \<or> (Q \<or> R)" by iprover
   961 
   962 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
   963 
   964 lemma conj_disj_distribL: "P \<and> (Q \<or> R) \<longleftrightarrow> P \<and> Q \<or> P \<and> R" by iprover
   965 lemma conj_disj_distribR: "(P \<or> Q) \<and> R \<longleftrightarrow> P \<and> R \<or> Q \<and> R" by iprover
   966 
   967 lemma disj_conj_distribL: "P \<or> (Q \<and> R) \<longleftrightarrow> (P \<or> Q) \<and> (P \<or> R)" by iprover
   968 lemma disj_conj_distribR: "(P \<and> Q) \<or> R \<longleftrightarrow> (P \<or> R) \<and> (Q \<or> R)" by iprover
   969 
   970 lemma imp_conjR: "(P \<longrightarrow> (Q \<and> R)) = ((P \<longrightarrow> Q) \<and> (P \<longrightarrow> R))" by iprover
   971 lemma imp_conjL: "((P \<and> Q) \<longrightarrow> R) = (P \<longrightarrow> (Q \<longrightarrow> R))" by iprover
   972 lemma imp_disjL: "((P \<or> Q) \<longrightarrow> R) = ((P \<longrightarrow> R) \<and> (Q \<longrightarrow> R))" by iprover
   973 
   974 text \<open>These two are specialized, but \<open>imp_disj_not1\<close> is useful in \<open>Auth/Yahalom\<close>.\<close>
   975 lemma imp_disj_not1: "(P \<longrightarrow> Q \<or> R) \<longleftrightarrow> (\<not> Q \<longrightarrow> P \<longrightarrow> R)" by blast
   976 lemma imp_disj_not2: "(P \<longrightarrow> Q \<or> R) \<longleftrightarrow> (\<not> R \<longrightarrow> P \<longrightarrow> Q)" by blast
   977 
   978 lemma imp_disj1: "((P \<longrightarrow> Q) \<or> R) \<longleftrightarrow> (P \<longrightarrow> Q \<or> R)" by blast
   979 lemma imp_disj2: "(Q \<or> (P \<longrightarrow> R)) \<longleftrightarrow> (P \<longrightarrow> Q \<or> R)" by blast
   980 
   981 lemma imp_cong: "(P = P') \<Longrightarrow> (P' \<Longrightarrow> (Q = Q')) \<Longrightarrow> ((P \<longrightarrow> Q) \<longleftrightarrow> (P' \<longrightarrow> Q'))"
   982   by iprover
   983 
   984 lemma de_Morgan_disj: "\<not> (P \<or> Q) \<longleftrightarrow> \<not> P \<and> \<not> Q" by iprover
   985 lemma de_Morgan_conj: "\<not> (P \<and> Q) \<longleftrightarrow> \<not> P \<or> \<not> Q" by blast
   986 lemma not_imp: "\<not> (P \<longrightarrow> Q) \<longleftrightarrow> P \<and> \<not> Q" by blast
   987 lemma not_iff: "P \<noteq> Q \<longleftrightarrow> (P \<longleftrightarrow> \<not> Q)" by blast
   988 lemma disj_not1: "\<not> P \<or> Q \<longleftrightarrow> (P \<longrightarrow> Q)" by blast
   989 lemma disj_not2: "P \<or> \<not> Q \<longleftrightarrow> (Q \<longrightarrow> P)" by blast  \<comment> \<open>changes orientation :-(\<close>
   990 lemma imp_conv_disj: "(P \<longrightarrow> Q) \<longleftrightarrow> (\<not> P) \<or> Q" by blast
   991 lemma disj_imp: "P \<or> Q \<longleftrightarrow> \<not> P \<longrightarrow> Q" by blast
   992 
   993 lemma iff_conv_conj_imp: "(P \<longleftrightarrow> Q) \<longleftrightarrow> (P \<longrightarrow> Q) \<and> (Q \<longrightarrow> P)" by iprover
   994 
   995 
   996 lemma cases_simp: "(P \<longrightarrow> Q) \<and> (\<not> P \<longrightarrow> Q) \<longleftrightarrow> Q"
   997   \<comment> \<open>Avoids duplication of subgoals after \<open>if_split\<close>, when the true and false\<close>
   998   \<comment> \<open>cases boil down to the same thing.\<close>
   999   by blast
  1000 
  1001 lemma not_all: "\<not> (\<forall>x. P x) \<longleftrightarrow> (\<exists>x. \<not> P x)" by blast
  1002 lemma imp_all: "((\<forall>x. P x) \<longrightarrow> Q) \<longleftrightarrow> (\<exists>x. P x \<longrightarrow> Q)" by blast
  1003 lemma not_ex: "\<not> (\<exists>x. P x) \<longleftrightarrow> (\<forall>x. \<not> P x)" by iprover
  1004 lemma imp_ex: "((\<exists>x. P x) \<longrightarrow> Q) \<longleftrightarrow> (\<forall>x. P x \<longrightarrow> Q)" by iprover
  1005 lemma all_not_ex: "(\<forall>x. P x) \<longleftrightarrow> \<not> (\<exists>x. \<not> P x)" by blast
  1006 
  1007 declare All_def [no_atp]
  1008 
  1009 lemma ex_disj_distrib: "(\<exists>x. P x \<or> Q x) \<longleftrightarrow> (\<exists>x. P x) \<or> (\<exists>x. Q x)" by iprover
  1010 lemma all_conj_distrib: "(\<forall>x. P x \<and> Q x) \<longleftrightarrow> (\<forall>x. P x) \<and> (\<forall>x. Q x)" by iprover
  1011 
  1012 text \<open>
  1013   \<^medskip> The \<open>\<and>\<close> congruence rule: not included by default!
  1014   May slow rewrite proofs down by as much as 50\%\<close>
  1015 
  1016 lemma conj_cong: "P = P' \<Longrightarrow> (P' \<Longrightarrow> Q = Q') \<Longrightarrow> (P \<and> Q) = (P' \<and> Q')"
  1017   by iprover
  1018 
  1019 lemma rev_conj_cong: "Q = Q' \<Longrightarrow> (Q' \<Longrightarrow> P = P') \<Longrightarrow> (P \<and> Q) = (P' \<and> Q')"
  1020   by iprover
  1021 
  1022 text \<open>The \<open>|\<close> congruence rule: not included by default!\<close>
  1023 
  1024 lemma disj_cong: "P = P' \<Longrightarrow> (\<not> P' \<Longrightarrow> Q = Q') \<Longrightarrow> (P \<or> Q) = (P' \<or> Q')"
  1025   by blast
  1026 
  1027 
  1028 text \<open>\<^medskip> if-then-else rules\<close>
  1029 
  1030 lemma if_True [code]: "(if True then x else y) = x"
  1031   unfolding If_def by blast
  1032 
  1033 lemma if_False [code]: "(if False then x else y) = y"
  1034   unfolding If_def by blast
  1035 
  1036 lemma if_P: "P \<Longrightarrow> (if P then x else y) = x"
  1037   unfolding If_def by blast
  1038 
  1039 lemma if_not_P: "\<not> P \<Longrightarrow> (if P then x else y) = y"
  1040   unfolding If_def by blast
  1041 
  1042 lemma if_split: "P (if Q then x else y) = ((Q \<longrightarrow> P x) \<and> (\<not> Q \<longrightarrow> P y))"
  1043   apply (rule case_split [of Q])
  1044    apply (simplesubst if_P)
  1045     prefer 3
  1046     apply (simplesubst if_not_P)
  1047      apply blast+
  1048   done
  1049 
  1050 lemma if_split_asm: "P (if Q then x else y) = (\<not> ((Q \<and> \<not> P x) \<or> (\<not> Q \<and> \<not> P y)))"
  1051   by (simplesubst if_split) blast
  1052 
  1053 lemmas if_splits [no_atp] = if_split if_split_asm
  1054 
  1055 lemma if_cancel: "(if c then x else x) = x"
  1056   by (simplesubst if_split) blast
  1057 
  1058 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1059   by (simplesubst if_split) blast
  1060 
  1061 lemma if_bool_eq_conj: "(if P then Q else R) = ((P \<longrightarrow> Q) \<and> (\<not> P \<longrightarrow> R))"
  1062   \<comment> \<open>This form is useful for expanding \<open>if\<close>s on the RIGHT of the \<open>\<Longrightarrow>\<close> symbol.\<close>
  1063   by (rule if_split)
  1064 
  1065 lemma if_bool_eq_disj: "(if P then Q else R) = ((P \<and> Q) \<or> (\<not> P \<and> R))"
  1066   \<comment> \<open>And this form is useful for expanding \<open>if\<close>s on the LEFT.\<close>
  1067   by (simplesubst if_split) blast
  1068 
  1069 lemma Eq_TrueI: "P \<Longrightarrow> P \<equiv> True" unfolding atomize_eq by iprover
  1070 lemma Eq_FalseI: "\<not> P \<Longrightarrow> P \<equiv> False" unfolding atomize_eq by iprover
  1071 
  1072 text \<open>\<^medskip> let rules for simproc\<close>
  1073 
  1074 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow> Let x f \<equiv> Let x g"
  1075   by (unfold Let_def)
  1076 
  1077 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow> Let x f \<equiv> g"
  1078   by (unfold Let_def)
  1079 
  1080 text \<open>
  1081   The following copy of the implication operator is useful for
  1082   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1083   its premise.
  1084 \<close>
  1085 
  1086 definition simp_implies :: "prop \<Rightarrow> prop \<Rightarrow> prop"  (infixr "=simp=>" 1)
  1087   where "simp_implies \<equiv> op \<Longrightarrow>"
  1088 
  1089 lemma simp_impliesI:
  1090   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1091   shows "PROP P =simp=> PROP Q"
  1092   apply (unfold simp_implies_def)
  1093   apply (rule PQ)
  1094   apply assumption
  1095   done
  1096 
  1097 lemma simp_impliesE:
  1098   assumes PQ: "PROP P =simp=> PROP Q"
  1099     and P: "PROP P"
  1100     and QR: "PROP Q \<Longrightarrow> PROP R"
  1101   shows "PROP R"
  1102   apply (rule QR)
  1103   apply (rule PQ [unfolded simp_implies_def])
  1104   apply (rule P)
  1105   done
  1106 
  1107 lemma simp_implies_cong:
  1108   assumes PP' :"PROP P \<equiv> PROP P'"
  1109     and P'QQ': "PROP P' \<Longrightarrow> (PROP Q \<equiv> PROP Q')"
  1110   shows "(PROP P =simp=> PROP Q) \<equiv> (PROP P' =simp=> PROP Q')"
  1111   unfolding simp_implies_def
  1112 proof (rule equal_intr_rule)
  1113   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1114     and P': "PROP P'"
  1115   from PP' [symmetric] and P' have "PROP P"
  1116     by (rule equal_elim_rule1)
  1117   then have "PROP Q" by (rule PQ)
  1118   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1119 next
  1120   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1121     and P: "PROP P"
  1122   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1123   then have "PROP Q'" by (rule P'Q')
  1124   with P'QQ' [OF P', symmetric] show "PROP Q"
  1125     by (rule equal_elim_rule1)
  1126 qed
  1127 
  1128 lemma uncurry:
  1129   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1130   shows "P \<and> Q \<longrightarrow> R"
  1131   using assms by blast
  1132 
  1133 lemma iff_allI:
  1134   assumes "\<And>x. P x = Q x"
  1135   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1136   using assms by blast
  1137 
  1138 lemma iff_exI:
  1139   assumes "\<And>x. P x = Q x"
  1140   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1141   using assms by blast
  1142 
  1143 lemma all_comm: "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1144   by blast
  1145 
  1146 lemma ex_comm: "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1147   by blast
  1148 
  1149 ML_file "Tools/simpdata.ML"
  1150 ML \<open>open Simpdata\<close>
  1151 
  1152 setup \<open>
  1153   map_theory_simpset (put_simpset HOL_basic_ss) #>
  1154   Simplifier.method_setup Splitter.split_modifiers
  1155 \<close>
  1156 
  1157 simproc_setup defined_Ex ("\<exists>x. P x") = \<open>fn _ => Quantifier1.rearrange_ex\<close>
  1158 simproc_setup defined_All ("\<forall>x. P x") = \<open>fn _ => Quantifier1.rearrange_all\<close>
  1159 
  1160 text \<open>Simproc for proving \<open>(y = x) \<equiv> False\<close> from premise \<open>\<not> (x = y)\<close>:\<close>
  1161 
  1162 simproc_setup neq ("x = y") = \<open>fn _ =>
  1163   let
  1164     val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1165     fun is_neq eq lhs rhs thm =
  1166       (case Thm.prop_of thm of
  1167         _ $ (Not $ (eq' $ l' $ r')) =>
  1168           Not = HOLogic.Not andalso eq' = eq andalso
  1169           r' aconv lhs andalso l' aconv rhs
  1170       | _ => false);
  1171     fun proc ss ct =
  1172       (case Thm.term_of ct of
  1173         eq $ lhs $ rhs =>
  1174           (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of ss) of
  1175             SOME thm => SOME (thm RS neq_to_EQ_False)
  1176           | NONE => NONE)
  1177        | _ => NONE);
  1178   in proc end;
  1179 \<close>
  1180 
  1181 simproc_setup let_simp ("Let x f") = \<open>
  1182   let
  1183     fun count_loose (Bound i) k = if i >= k then 1 else 0
  1184       | count_loose (s $ t) k = count_loose s k + count_loose t k
  1185       | count_loose (Abs (_, _, t)) k = count_loose  t (k + 1)
  1186       | count_loose _ _ = 0;
  1187     fun is_trivial_let (Const (@{const_name Let}, _) $ x $ t) =
  1188       (case t of
  1189         Abs (_, _, t') => count_loose t' 0 <= 1
  1190       | _ => true);
  1191   in
  1192     fn _ => fn ctxt => fn ct =>
  1193       if is_trivial_let (Thm.term_of ct)
  1194       then SOME @{thm Let_def} (*no or one ocurrence of bound variable*)
  1195       else
  1196         let (*Norbert Schirmer's case*)
  1197           val t = Thm.term_of ct;
  1198           val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1199         in
  1200           Option.map (hd o Variable.export ctxt' ctxt o single)
  1201             (case t' of Const (@{const_name Let},_) $ x $ f => (* x and f are already in normal form *)
  1202               if is_Free x orelse is_Bound x orelse is_Const x
  1203               then SOME @{thm Let_def}
  1204               else
  1205                 let
  1206                   val n = case f of (Abs (x, _, _)) => x | _ => "x";
  1207                   val cx = Thm.cterm_of ctxt x;
  1208                   val xT = Thm.typ_of_cterm cx;
  1209                   val cf = Thm.cterm_of ctxt f;
  1210                   val fx_g = Simplifier.rewrite ctxt (Thm.apply cf cx);
  1211                   val (_ $ _ $ g) = Thm.prop_of fx_g;
  1212                   val g' = abstract_over (x, g);
  1213                   val abs_g'= Abs (n, xT, g');
  1214                 in
  1215                   if g aconv g' then
  1216                     let
  1217                       val rl =
  1218                         infer_instantiate ctxt [(("f", 0), cf), (("x", 0), cx)] @{thm Let_unfold};
  1219                     in SOME (rl OF [fx_g]) end
  1220                   else if (Envir.beta_eta_contract f) aconv (Envir.beta_eta_contract abs_g')
  1221                   then NONE (*avoid identity conversion*)
  1222                   else
  1223                     let
  1224                       val g'x = abs_g' $ x;
  1225                       val g_g'x = Thm.symmetric (Thm.beta_conversion false (Thm.cterm_of ctxt g'x));
  1226                       val rl =
  1227                         @{thm Let_folded} |> infer_instantiate ctxt
  1228                           [(("f", 0), Thm.cterm_of ctxt f),
  1229                            (("x", 0), cx),
  1230                            (("g", 0), Thm.cterm_of ctxt abs_g')];
  1231                     in SOME (rl OF [Thm.transitive fx_g g_g'x]) end
  1232                 end
  1233             | _ => NONE)
  1234         end
  1235   end
  1236 \<close>
  1237 
  1238 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1239 proof
  1240   assume "True \<Longrightarrow> PROP P"
  1241   from this [OF TrueI] show "PROP P" .
  1242 next
  1243   assume "PROP P"
  1244   then show "PROP P" .
  1245 qed
  1246 
  1247 lemma implies_True_equals: "(PROP P \<Longrightarrow> True) \<equiv> Trueprop True"
  1248   by standard (intro TrueI)
  1249 
  1250 lemma False_implies_equals: "(False \<Longrightarrow> P) \<equiv> Trueprop True"
  1251   by standard simp_all
  1252 
  1253 (* This is not made a simp rule because it does not improve any proofs
  1254    but slows some AFP entries down by 5% (cpu time). May 2015 *)
  1255 lemma implies_False_swap:
  1256   "NO_MATCH (Trueprop False) P \<Longrightarrow>
  1257     (False \<Longrightarrow> PROP P \<Longrightarrow> PROP Q) \<equiv> (PROP P \<Longrightarrow> False \<Longrightarrow> PROP Q)"
  1258   by (rule swap_prems_eq)
  1259 
  1260 lemma ex_simps:
  1261   "\<And>P Q. (\<exists>x. P x \<and> Q)   = ((\<exists>x. P x) \<and> Q)"
  1262   "\<And>P Q. (\<exists>x. P \<and> Q x)   = (P \<and> (\<exists>x. Q x))"
  1263   "\<And>P Q. (\<exists>x. P x \<or> Q)   = ((\<exists>x. P x) \<or> Q)"
  1264   "\<And>P Q. (\<exists>x. P \<or> Q x)   = (P \<or> (\<exists>x. Q x))"
  1265   "\<And>P Q. (\<exists>x. P x \<longrightarrow> Q) = ((\<forall>x. P x) \<longrightarrow> Q)"
  1266   "\<And>P Q. (\<exists>x. P \<longrightarrow> Q x) = (P \<longrightarrow> (\<exists>x. Q x))"
  1267   \<comment> \<open>Miniscoping: pushing in existential quantifiers.\<close>
  1268   by (iprover | blast)+
  1269 
  1270 lemma all_simps:
  1271   "\<And>P Q. (\<forall>x. P x \<and> Q)   = ((\<forall>x. P x) \<and> Q)"
  1272   "\<And>P Q. (\<forall>x. P \<and> Q x)   = (P \<and> (\<forall>x. Q x))"
  1273   "\<And>P Q. (\<forall>x. P x \<or> Q)   = ((\<forall>x. P x) \<or> Q)"
  1274   "\<And>P Q. (\<forall>x. P \<or> Q x)   = (P \<or> (\<forall>x. Q x))"
  1275   "\<And>P Q. (\<forall>x. P x \<longrightarrow> Q) = ((\<exists>x. P x) \<longrightarrow> Q)"
  1276   "\<And>P Q. (\<forall>x. P \<longrightarrow> Q x) = (P \<longrightarrow> (\<forall>x. Q x))"
  1277   \<comment> \<open>Miniscoping: pushing in universal quantifiers.\<close>
  1278   by (iprover | blast)+
  1279 
  1280 lemmas [simp] =
  1281   triv_forall_equality  \<comment> \<open>prunes params\<close>
  1282   True_implies_equals implies_True_equals  \<comment> \<open>prune \<open>True\<close> in asms\<close>
  1283   False_implies_equals  \<comment> \<open>prune \<open>False\<close> in asms\<close>
  1284   if_True
  1285   if_False
  1286   if_cancel
  1287   if_eq_cancel
  1288   imp_disjL \<comment>
  1289    \<open>In general it seems wrong to add distributive laws by default: they
  1290     might cause exponential blow-up.  But \<open>imp_disjL\<close> has been in for a while
  1291     and cannot be removed without affecting existing proofs.  Moreover,
  1292     rewriting by \<open>(P \<or> Q \<longrightarrow> R) = ((P \<longrightarrow> R) \<and> (Q \<longrightarrow> R))\<close> might be justified on the
  1293     grounds that it allows simplification of \<open>R\<close> in the two cases.\<close>
  1294   conj_assoc
  1295   disj_assoc
  1296   de_Morgan_conj
  1297   de_Morgan_disj
  1298   imp_disj1
  1299   imp_disj2
  1300   not_imp
  1301   disj_not1
  1302   not_all
  1303   not_ex
  1304   cases_simp
  1305   the_eq_trivial
  1306   the_sym_eq_trivial
  1307   ex_simps
  1308   all_simps
  1309   simp_thms
  1310 
  1311 lemmas [cong] = imp_cong simp_implies_cong
  1312 lemmas [split] = if_split
  1313 
  1314 ML \<open>val HOL_ss = simpset_of @{context}\<close>
  1315 
  1316 text \<open>Simplifies \<open>x\<close> assuming \<open>c\<close> and \<open>y\<close> assuming \<open>\<not> c\<close>.\<close>
  1317 lemma if_cong:
  1318   assumes "b = c"
  1319     and "c \<Longrightarrow> x = u"
  1320     and "\<not> c \<Longrightarrow> y = v"
  1321   shows "(if b then x else y) = (if c then u else v)"
  1322   using assms by simp
  1323 
  1324 text \<open>Prevents simplification of \<open>x\<close> and \<open>y\<close>:
  1325   faster and allows the execution of functional programs.\<close>
  1326 lemma if_weak_cong [cong]:
  1327   assumes "b = c"
  1328   shows "(if b then x else y) = (if c then x else y)"
  1329   using assms by (rule arg_cong)
  1330 
  1331 text \<open>Prevents simplification of t: much faster\<close>
  1332 lemma let_weak_cong:
  1333   assumes "a = b"
  1334   shows "(let x = a in t x) = (let x = b in t x)"
  1335   using assms by (rule arg_cong)
  1336 
  1337 text \<open>To tidy up the result of a simproc.  Only the RHS will be simplified.\<close>
  1338 lemma eq_cong2:
  1339   assumes "u = u'"
  1340   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1341   using assms by simp
  1342 
  1343 lemma if_distrib: "f (if c then x else y) = (if c then f x else f y)"
  1344   by simp
  1345 
  1346 text \<open>As a simplification rule, it replaces all function equalities by
  1347   first-order equalities.\<close>
  1348 lemma fun_eq_iff: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
  1349   by auto
  1350 
  1351 
  1352 subsubsection \<open>Generic cases and induction\<close>
  1353 
  1354 text \<open>Rule projections:\<close>
  1355 ML \<open>
  1356 structure Project_Rule = Project_Rule
  1357 (
  1358   val conjunct1 = @{thm conjunct1}
  1359   val conjunct2 = @{thm conjunct2}
  1360   val mp = @{thm mp}
  1361 );
  1362 \<close>
  1363 
  1364 context
  1365 begin
  1366 
  1367 qualified definition "induct_forall P \<equiv> \<forall>x. P x"
  1368 qualified definition "induct_implies A B \<equiv> A \<longrightarrow> B"
  1369 qualified definition "induct_equal x y \<equiv> x = y"
  1370 qualified definition "induct_conj A B \<equiv> A \<and> B"
  1371 qualified definition "induct_true \<equiv> True"
  1372 qualified definition "induct_false \<equiv> False"
  1373 
  1374 lemma induct_forall_eq: "(\<And>x. P x) \<equiv> Trueprop (induct_forall (\<lambda>x. P x))"
  1375   by (unfold atomize_all induct_forall_def)
  1376 
  1377 lemma induct_implies_eq: "(A \<Longrightarrow> B) \<equiv> Trueprop (induct_implies A B)"
  1378   by (unfold atomize_imp induct_implies_def)
  1379 
  1380 lemma induct_equal_eq: "(x \<equiv> y) \<equiv> Trueprop (induct_equal x y)"
  1381   by (unfold atomize_eq induct_equal_def)
  1382 
  1383 lemma induct_conj_eq: "(A &&& B) \<equiv> Trueprop (induct_conj A B)"
  1384   by (unfold atomize_conj induct_conj_def)
  1385 
  1386 lemmas induct_atomize' = induct_forall_eq induct_implies_eq induct_conj_eq
  1387 lemmas induct_atomize = induct_atomize' induct_equal_eq
  1388 lemmas induct_rulify' [symmetric] = induct_atomize'
  1389 lemmas induct_rulify [symmetric] = induct_atomize
  1390 lemmas induct_rulify_fallback =
  1391   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1392   induct_true_def induct_false_def
  1393 
  1394 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1395     induct_conj (induct_forall A) (induct_forall B)"
  1396   by (unfold induct_forall_def induct_conj_def) iprover
  1397 
  1398 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1399     induct_conj (induct_implies C A) (induct_implies C B)"
  1400   by (unfold induct_implies_def induct_conj_def) iprover
  1401 
  1402 lemma induct_conj_curry: "(induct_conj A B \<Longrightarrow> PROP C) \<equiv> (A \<Longrightarrow> B \<Longrightarrow> PROP C)"
  1403 proof
  1404   assume r: "induct_conj A B \<Longrightarrow> PROP C"
  1405   assume ab: A B
  1406   show "PROP C" by (rule r) (simp add: induct_conj_def ab)
  1407 next
  1408   assume r: "A \<Longrightarrow> B \<Longrightarrow> PROP C"
  1409   assume ab: "induct_conj A B"
  1410   show "PROP C" by (rule r) (simp_all add: ab [unfolded induct_conj_def])
  1411 qed
  1412 
  1413 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1414 
  1415 lemma induct_trueI: "induct_true"
  1416   by (simp add: induct_true_def)
  1417 
  1418 text \<open>Method setup.\<close>
  1419 
  1420 ML_file "~~/src/Tools/induct.ML"
  1421 ML \<open>
  1422 structure Induct = Induct
  1423 (
  1424   val cases_default = @{thm case_split}
  1425   val atomize = @{thms induct_atomize}
  1426   val rulify = @{thms induct_rulify'}
  1427   val rulify_fallback = @{thms induct_rulify_fallback}
  1428   val equal_def = @{thm induct_equal_def}
  1429   fun dest_def (Const (@{const_name induct_equal}, _) $ t $ u) = SOME (t, u)
  1430     | dest_def _ = NONE
  1431   fun trivial_tac ctxt = match_tac ctxt @{thms induct_trueI}
  1432 )
  1433 \<close>
  1434 
  1435 ML_file "~~/src/Tools/induction.ML"
  1436 
  1437 declaration \<open>
  1438   fn _ => Induct.map_simpset (fn ss => ss
  1439     addsimprocs
  1440       [Simplifier.make_simproc @{context} "swap_induct_false"
  1441         {lhss = [@{term "induct_false \<Longrightarrow> PROP P \<Longrightarrow> PROP Q"}],
  1442          proc = fn _ => fn _ => fn ct =>
  1443           (case Thm.term_of ct of
  1444             _ $ (P as _ $ @{const induct_false}) $ (_ $ Q $ _) =>
  1445               if P <> Q then SOME Drule.swap_prems_eq else NONE
  1446           | _ => NONE)},
  1447        Simplifier.make_simproc @{context} "induct_equal_conj_curry"
  1448         {lhss = [@{term "induct_conj P Q \<Longrightarrow> PROP R"}],
  1449          proc = fn _ => fn _ => fn ct =>
  1450           (case Thm.term_of ct of
  1451             _ $ (_ $ P) $ _ =>
  1452               let
  1453                 fun is_conj (@{const induct_conj} $ P $ Q) =
  1454                       is_conj P andalso is_conj Q
  1455                   | is_conj (Const (@{const_name induct_equal}, _) $ _ $ _) = true
  1456                   | is_conj @{const induct_true} = true
  1457                   | is_conj @{const induct_false} = true
  1458                   | is_conj _ = false
  1459               in if is_conj P then SOME @{thm induct_conj_curry} else NONE end
  1460             | _ => NONE)}]
  1461     |> Simplifier.set_mksimps (fn ctxt =>
  1462         Simpdata.mksimps Simpdata.mksimps_pairs ctxt #>
  1463         map (rewrite_rule ctxt (map Thm.symmetric @{thms induct_rulify_fallback}))))
  1464 \<close>
  1465 
  1466 text \<open>Pre-simplification of induction and cases rules\<close>
  1467 
  1468 lemma [induct_simp]: "(\<And>x. induct_equal x t \<Longrightarrow> PROP P x) \<equiv> PROP P t"
  1469   unfolding induct_equal_def
  1470 proof
  1471   assume r: "\<And>x. x = t \<Longrightarrow> PROP P x"
  1472   show "PROP P t" by (rule r [OF refl])
  1473 next
  1474   fix x
  1475   assume "PROP P t" "x = t"
  1476   then show "PROP P x" by simp
  1477 qed
  1478 
  1479 lemma [induct_simp]: "(\<And>x. induct_equal t x \<Longrightarrow> PROP P x) \<equiv> PROP P t"
  1480   unfolding induct_equal_def
  1481 proof
  1482   assume r: "\<And>x. t = x \<Longrightarrow> PROP P x"
  1483   show "PROP P t" by (rule r [OF refl])
  1484 next
  1485   fix x
  1486   assume "PROP P t" "t = x"
  1487   then show "PROP P x" by simp
  1488 qed
  1489 
  1490 lemma [induct_simp]: "(induct_false \<Longrightarrow> P) \<equiv> Trueprop induct_true"
  1491   unfolding induct_false_def induct_true_def
  1492   by (iprover intro: equal_intr_rule)
  1493 
  1494 lemma [induct_simp]: "(induct_true \<Longrightarrow> PROP P) \<equiv> PROP P"
  1495   unfolding induct_true_def
  1496 proof
  1497   assume "True \<Longrightarrow> PROP P"
  1498   then show "PROP P" using TrueI .
  1499 next
  1500   assume "PROP P"
  1501   then show "PROP P" .
  1502 qed
  1503 
  1504 lemma [induct_simp]: "(PROP P \<Longrightarrow> induct_true) \<equiv> Trueprop induct_true"
  1505   unfolding induct_true_def
  1506   by (iprover intro: equal_intr_rule)
  1507 
  1508 lemma [induct_simp]: "(\<And>x::'a::{}. induct_true) \<equiv> Trueprop induct_true"
  1509   unfolding induct_true_def
  1510   by (iprover intro: equal_intr_rule)
  1511 
  1512 lemma [induct_simp]: "induct_implies induct_true P \<equiv> P"
  1513   by (simp add: induct_implies_def induct_true_def)
  1514 
  1515 lemma [induct_simp]: "x = x \<longleftrightarrow> True"
  1516   by (rule simp_thms)
  1517 
  1518 end
  1519 
  1520 ML_file "~~/src/Tools/induct_tacs.ML"
  1521 
  1522 
  1523 subsubsection \<open>Coherent logic\<close>
  1524 
  1525 ML_file "~~/src/Tools/coherent.ML"
  1526 ML \<open>
  1527 structure Coherent = Coherent
  1528 (
  1529   val atomize_elimL = @{thm atomize_elimL};
  1530   val atomize_exL = @{thm atomize_exL};
  1531   val atomize_conjL = @{thm atomize_conjL};
  1532   val atomize_disjL = @{thm atomize_disjL};
  1533   val operator_names = [@{const_name HOL.disj}, @{const_name HOL.conj}, @{const_name Ex}];
  1534 );
  1535 \<close>
  1536 
  1537 
  1538 subsubsection \<open>Reorienting equalities\<close>
  1539 
  1540 ML \<open>
  1541 signature REORIENT_PROC =
  1542 sig
  1543   val add : (term -> bool) -> theory -> theory
  1544   val proc : morphism -> Proof.context -> cterm -> thm option
  1545 end;
  1546 
  1547 structure Reorient_Proc : REORIENT_PROC =
  1548 struct
  1549   structure Data = Theory_Data
  1550   (
  1551     type T = ((term -> bool) * stamp) list;
  1552     val empty = [];
  1553     val extend = I;
  1554     fun merge data : T = Library.merge (eq_snd op =) data;
  1555   );
  1556   fun add m = Data.map (cons (m, stamp ()));
  1557   fun matches thy t = exists (fn (m, _) => m t) (Data.get thy);
  1558 
  1559   val meta_reorient = @{thm eq_commute [THEN eq_reflection]};
  1560   fun proc phi ctxt ct =
  1561     let
  1562       val thy = Proof_Context.theory_of ctxt;
  1563     in
  1564       case Thm.term_of ct of
  1565         (_ $ t $ u) => if matches thy u then NONE else SOME meta_reorient
  1566       | _ => NONE
  1567     end;
  1568 end;
  1569 \<close>
  1570 
  1571 
  1572 subsection \<open>Other simple lemmas and lemma duplicates\<close>
  1573 
  1574 lemma ex1_eq [iff]: "\<exists>!x. x = t" "\<exists>!x. t = x"
  1575   by blast+
  1576 
  1577 lemma choice_eq: "(\<forall>x. \<exists>!y. P x y) = (\<exists>!f. \<forall>x. P x (f x))"
  1578   apply (rule iffI)
  1579    apply (rule_tac a = "\<lambda>x. THE y. P x y" in ex1I)
  1580     apply (fast dest!: theI')
  1581    apply (fast intro: the1_equality [symmetric])
  1582   apply (erule ex1E)
  1583   apply (rule allI)
  1584   apply (rule ex1I)
  1585    apply (erule spec)
  1586   apply (erule_tac x = "\<lambda>z. if z = x then y else f z" in allE)
  1587   apply (erule impE)
  1588    apply (rule allI)
  1589    apply (case_tac "xa = x")
  1590     apply (drule_tac [3] x = x in fun_cong)
  1591     apply simp_all
  1592   done
  1593 
  1594 lemmas eq_sym_conv = eq_commute
  1595 
  1596 lemma nnf_simps:
  1597   "(\<not> (P \<and> Q)) = (\<not> P \<or> \<not> Q)"
  1598   "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not> Q)"
  1599   "(P \<longrightarrow> Q) = (\<not> P \<or> Q)"
  1600   "(P = Q) = ((P \<and> Q) \<or> (\<not> P \<and> \<not> Q))"
  1601   "(\<not> (P = Q)) = ((P \<and> \<not> Q) \<or> (\<not> P \<and> Q))"
  1602   "(\<not> \<not> P) = P"
  1603   by blast+
  1604 
  1605 
  1606 subsection \<open>Basic ML bindings\<close>
  1607 
  1608 ML \<open>
  1609 val FalseE = @{thm FalseE}
  1610 val Let_def = @{thm Let_def}
  1611 val TrueI = @{thm TrueI}
  1612 val allE = @{thm allE}
  1613 val allI = @{thm allI}
  1614 val all_dupE = @{thm all_dupE}
  1615 val arg_cong = @{thm arg_cong}
  1616 val box_equals = @{thm box_equals}
  1617 val ccontr = @{thm ccontr}
  1618 val classical = @{thm classical}
  1619 val conjE = @{thm conjE}
  1620 val conjI = @{thm conjI}
  1621 val conjunct1 = @{thm conjunct1}
  1622 val conjunct2 = @{thm conjunct2}
  1623 val disjCI = @{thm disjCI}
  1624 val disjE = @{thm disjE}
  1625 val disjI1 = @{thm disjI1}
  1626 val disjI2 = @{thm disjI2}
  1627 val eq_reflection = @{thm eq_reflection}
  1628 val ex1E = @{thm ex1E}
  1629 val ex1I = @{thm ex1I}
  1630 val ex1_implies_ex = @{thm ex1_implies_ex}
  1631 val exE = @{thm exE}
  1632 val exI = @{thm exI}
  1633 val excluded_middle = @{thm excluded_middle}
  1634 val ext = @{thm ext}
  1635 val fun_cong = @{thm fun_cong}
  1636 val iffD1 = @{thm iffD1}
  1637 val iffD2 = @{thm iffD2}
  1638 val iffI = @{thm iffI}
  1639 val impE = @{thm impE}
  1640 val impI = @{thm impI}
  1641 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1642 val mp = @{thm mp}
  1643 val notE = @{thm notE}
  1644 val notI = @{thm notI}
  1645 val not_all = @{thm not_all}
  1646 val not_ex = @{thm not_ex}
  1647 val not_iff = @{thm not_iff}
  1648 val not_not = @{thm not_not}
  1649 val not_sym = @{thm not_sym}
  1650 val refl = @{thm refl}
  1651 val rev_mp = @{thm rev_mp}
  1652 val spec = @{thm spec}
  1653 val ssubst = @{thm ssubst}
  1654 val subst = @{thm subst}
  1655 val sym = @{thm sym}
  1656 val trans = @{thm trans}
  1657 \<close>
  1658 
  1659 ML_file "Tools/cnf.ML"
  1660 
  1661 
  1662 section \<open>\<open>NO_MATCH\<close> simproc\<close>
  1663 
  1664 text \<open>
  1665   The simplification procedure can be used to avoid simplification of terms
  1666   of a certain form.
  1667 \<close>
  1668 
  1669 definition NO_MATCH :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
  1670   where "NO_MATCH pat val \<equiv> True"
  1671 
  1672 lemma NO_MATCH_cong[cong]: "NO_MATCH pat val = NO_MATCH pat val"
  1673   by (rule refl)
  1674 
  1675 declare [[coercion_args NO_MATCH - -]]
  1676 
  1677 simproc_setup NO_MATCH ("NO_MATCH pat val") = \<open>fn _ => fn ctxt => fn ct =>
  1678   let
  1679     val thy = Proof_Context.theory_of ctxt
  1680     val dest_binop = Term.dest_comb #> apfst (Term.dest_comb #> snd)
  1681     val m = Pattern.matches thy (dest_binop (Thm.term_of ct))
  1682   in if m then NONE else SOME @{thm NO_MATCH_def} end
  1683 \<close>
  1684 
  1685 text \<open>
  1686   This setup ensures that a rewrite rule of the form @{term "NO_MATCH pat val \<Longrightarrow> t"}
  1687   is only applied, if the pattern \<open>pat\<close> does not match the value \<open>val\<close>.
  1688 \<close>
  1689 
  1690 
  1691 text\<open>
  1692   Tagging a premise of a simp rule with ASSUMPTION forces the simplifier
  1693   not to simplify the argument and to solve it by an assumption.
  1694 \<close>
  1695 
  1696 definition ASSUMPTION :: "bool \<Rightarrow> bool"
  1697   where "ASSUMPTION A \<equiv> A"
  1698 
  1699 lemma ASSUMPTION_cong[cong]: "ASSUMPTION A = ASSUMPTION A"
  1700   by (rule refl)
  1701 
  1702 lemma ASSUMPTION_I: "A \<Longrightarrow> ASSUMPTION A"
  1703   by (simp add: ASSUMPTION_def)
  1704 
  1705 lemma ASSUMPTION_D: "ASSUMPTION A \<Longrightarrow> A"
  1706   by (simp add: ASSUMPTION_def)
  1707 
  1708 setup \<open>
  1709 let
  1710   val asm_sol = mk_solver "ASSUMPTION" (fn ctxt =>
  1711     resolve_tac ctxt [@{thm ASSUMPTION_I}] THEN'
  1712     resolve_tac ctxt (Simplifier.prems_of ctxt))
  1713 in
  1714   map_theory_simpset (fn ctxt => Simplifier.addSolver (ctxt,asm_sol))
  1715 end
  1716 \<close>
  1717 
  1718 
  1719 subsection \<open>Code generator setup\<close>
  1720 
  1721 subsubsection \<open>Generic code generator preprocessor setup\<close>
  1722 
  1723 lemma conj_left_cong: "P \<longleftrightarrow> Q \<Longrightarrow> P \<and> R \<longleftrightarrow> Q \<and> R"
  1724   by (fact arg_cong)
  1725 
  1726 lemma disj_left_cong: "P \<longleftrightarrow> Q \<Longrightarrow> P \<or> R \<longleftrightarrow> Q \<or> R"
  1727   by (fact arg_cong)
  1728 
  1729 setup \<open>
  1730   Code_Preproc.map_pre (put_simpset HOL_basic_ss) #>
  1731   Code_Preproc.map_post (put_simpset HOL_basic_ss) #>
  1732   Code_Simp.map_ss (put_simpset HOL_basic_ss #>
  1733   Simplifier.add_cong @{thm conj_left_cong} #>
  1734   Simplifier.add_cong @{thm disj_left_cong})
  1735 \<close>
  1736 
  1737 
  1738 subsubsection \<open>Equality\<close>
  1739 
  1740 class equal =
  1741   fixes equal :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1742   assumes equal_eq: "equal x y \<longleftrightarrow> x = y"
  1743 begin
  1744 
  1745 lemma equal: "equal = (op =)"
  1746   by (rule ext equal_eq)+
  1747 
  1748 lemma equal_refl: "equal x x \<longleftrightarrow> True"
  1749   unfolding equal by rule+
  1750 
  1751 lemma eq_equal: "(op =) \<equiv> equal"
  1752   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule equal_eq)
  1753 
  1754 end
  1755 
  1756 declare eq_equal [symmetric, code_post]
  1757 declare eq_equal [code]
  1758 
  1759 setup \<open>
  1760   Code_Preproc.map_pre (fn ctxt =>
  1761     ctxt addsimprocs
  1762       [Simplifier.make_simproc @{context} "equal"
  1763         {lhss = [@{term HOL.eq}],
  1764          proc = fn _ => fn _ => fn ct =>
  1765           (case Thm.term_of ct of
  1766             Const (_, Type (@{type_name fun}, [Type _, _])) => SOME @{thm eq_equal}
  1767           | _ => NONE)}])
  1768 \<close>
  1769 
  1770 
  1771 subsubsection \<open>Generic code generator foundation\<close>
  1772 
  1773 text \<open>Datatype @{typ bool}\<close>
  1774 
  1775 code_datatype True False
  1776 
  1777 lemma [code]:
  1778   shows "False \<and> P \<longleftrightarrow> False"
  1779     and "True \<and> P \<longleftrightarrow> P"
  1780     and "P \<and> False \<longleftrightarrow> False"
  1781     and "P \<and> True \<longleftrightarrow> P"
  1782   by simp_all
  1783 
  1784 lemma [code]:
  1785   shows "False \<or> P \<longleftrightarrow> P"
  1786     and "True \<or> P \<longleftrightarrow> True"
  1787     and "P \<or> False \<longleftrightarrow> P"
  1788     and "P \<or> True \<longleftrightarrow> True"
  1789   by simp_all
  1790 
  1791 lemma [code]:
  1792   shows "(False \<longrightarrow> P) \<longleftrightarrow> True"
  1793     and "(True \<longrightarrow> P) \<longleftrightarrow> P"
  1794     and "(P \<longrightarrow> False) \<longleftrightarrow> \<not> P"
  1795     and "(P \<longrightarrow> True) \<longleftrightarrow> True"
  1796   by simp_all
  1797 
  1798 text \<open>More about @{typ prop}\<close>
  1799 
  1800 lemma [code nbe]:
  1801   shows "(True \<Longrightarrow> PROP Q) \<equiv> PROP Q"
  1802     and "(PROP Q \<Longrightarrow> True) \<equiv> Trueprop True"
  1803     and "(P \<Longrightarrow> R) \<equiv> Trueprop (P \<longrightarrow> R)"
  1804   by (auto intro!: equal_intr_rule)
  1805 
  1806 lemma Trueprop_code [code]: "Trueprop True \<equiv> Code_Generator.holds"
  1807   by (auto intro!: equal_intr_rule holds)
  1808 
  1809 declare Trueprop_code [symmetric, code_post]
  1810 
  1811 text \<open>Equality\<close>
  1812 
  1813 declare simp_thms(6) [code nbe]
  1814 
  1815 instantiation itself :: (type) equal
  1816 begin
  1817 
  1818 definition equal_itself :: "'a itself \<Rightarrow> 'a itself \<Rightarrow> bool"
  1819   where "equal_itself x y \<longleftrightarrow> x = y"
  1820 
  1821 instance
  1822   by standard (fact equal_itself_def)
  1823 
  1824 end
  1825 
  1826 lemma equal_itself_code [code]: "equal TYPE('a) TYPE('a) \<longleftrightarrow> True"
  1827   by (simp add: equal)
  1828 
  1829 setup \<open>Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a::type \<Rightarrow> 'a \<Rightarrow> bool"})\<close>
  1830 
  1831 lemma equal_alias_cert: "OFCLASS('a, equal_class) \<equiv> ((op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool) \<equiv> equal)"
  1832   (is "?ofclass \<equiv> ?equal")
  1833 proof
  1834   assume "PROP ?ofclass"
  1835   show "PROP ?equal"
  1836     by (tactic \<open>ALLGOALS (resolve_tac @{context} [Thm.unconstrainT @{thm eq_equal}])\<close>)
  1837       (fact \<open>PROP ?ofclass\<close>)
  1838 next
  1839   assume "PROP ?equal"
  1840   show "PROP ?ofclass" proof
  1841   qed (simp add: \<open>PROP ?equal\<close>)
  1842 qed
  1843 
  1844 setup \<open>Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a::equal \<Rightarrow> 'a \<Rightarrow> bool"})\<close>
  1845 
  1846 setup \<open>Nbe.add_const_alias @{thm equal_alias_cert}\<close>
  1847 
  1848 text \<open>Cases\<close>
  1849 
  1850 lemma Let_case_cert:
  1851   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1852   shows "CASE x \<equiv> f x"
  1853   using assms by simp_all
  1854 
  1855 setup \<open>
  1856   Code.add_case @{thm Let_case_cert} #>
  1857   Code.add_undefined @{const_name undefined}
  1858 \<close>
  1859 
  1860 declare [[code abort: undefined]]
  1861 
  1862 
  1863 subsubsection \<open>Generic code generator target languages\<close>
  1864 
  1865 text \<open>type @{typ bool}\<close>
  1866 
  1867 code_printing
  1868   type_constructor bool \<rightharpoonup>
  1869     (SML) "bool" and (OCaml) "bool" and (Haskell) "Bool" and (Scala) "Boolean"
  1870 | constant True \<rightharpoonup>
  1871     (SML) "true" and (OCaml) "true" and (Haskell) "True" and (Scala) "true"
  1872 | constant False \<rightharpoonup>
  1873     (SML) "false" and (OCaml) "false" and (Haskell) "False" and (Scala) "false"
  1874 
  1875 code_reserved SML
  1876   bool true false
  1877 
  1878 code_reserved OCaml
  1879   bool
  1880 
  1881 code_reserved Scala
  1882   Boolean
  1883 
  1884 code_printing
  1885   constant Not \<rightharpoonup>
  1886     (SML) "not" and (OCaml) "not" and (Haskell) "not" and (Scala) "'! _"
  1887 | constant HOL.conj \<rightharpoonup>
  1888     (SML) infixl 1 "andalso" and (OCaml) infixl 3 "&&" and (Haskell) infixr 3 "&&" and (Scala) infixl 3 "&&"
  1889 | constant HOL.disj \<rightharpoonup>
  1890     (SML) infixl 0 "orelse" and (OCaml) infixl 2 "||" and (Haskell) infixl 2 "||" and (Scala) infixl 1 "||"
  1891 | constant HOL.implies \<rightharpoonup>
  1892     (SML) "!(if (_)/ then (_)/ else true)"
  1893     and (OCaml) "!(if (_)/ then (_)/ else true)"
  1894     and (Haskell) "!(if (_)/ then (_)/ else True)"
  1895     and (Scala) "!(if ((_))/ (_)/ else true)"
  1896 | constant If \<rightharpoonup>
  1897     (SML) "!(if (_)/ then (_)/ else (_))"
  1898     and (OCaml) "!(if (_)/ then (_)/ else (_))"
  1899     and (Haskell) "!(if (_)/ then (_)/ else (_))"
  1900     and (Scala) "!(if ((_))/ (_)/ else (_))"
  1901 
  1902 code_reserved SML
  1903   not
  1904 
  1905 code_reserved OCaml
  1906   not
  1907 
  1908 code_identifier
  1909   code_module Pure \<rightharpoonup>
  1910     (SML) HOL and (OCaml) HOL and (Haskell) HOL and (Scala) HOL
  1911 
  1912 text \<open>Using built-in Haskell equality.\<close>
  1913 code_printing
  1914   type_class equal \<rightharpoonup> (Haskell) "Eq"
  1915 | constant HOL.equal \<rightharpoonup> (Haskell) infix 4 "=="
  1916 | constant HOL.eq \<rightharpoonup> (Haskell) infix 4 "=="
  1917 
  1918 text \<open>\<open>undefined\<close>\<close>
  1919 code_printing
  1920   constant undefined \<rightharpoonup>
  1921     (SML) "!(raise/ Fail/ \"undefined\")"
  1922     and (OCaml) "failwith/ \"undefined\""
  1923     and (Haskell) "error/ \"undefined\""
  1924     and (Scala) "!sys.error(\"undefined\")"
  1925 
  1926 
  1927 subsubsection \<open>Evaluation and normalization by evaluation\<close>
  1928 
  1929 method_setup eval = \<open>
  1930   let
  1931     fun eval_tac ctxt =
  1932       let val conv = Code_Runtime.dynamic_holds_conv ctxt
  1933       in
  1934         CONVERSION (Conv.params_conv ~1 (K (Conv.concl_conv ~1 conv)) ctxt) THEN'
  1935         resolve_tac ctxt [TrueI]
  1936       end
  1937   in
  1938     Scan.succeed (SIMPLE_METHOD' o eval_tac)
  1939   end
  1940 \<close> "solve goal by evaluation"
  1941 
  1942 method_setup normalization = \<open>
  1943   Scan.succeed (fn ctxt =>
  1944     SIMPLE_METHOD'
  1945       (CHANGED_PROP o
  1946         (CONVERSION (Nbe.dynamic_conv ctxt)
  1947           THEN_ALL_NEW (TRY o resolve_tac ctxt [TrueI]))))
  1948 \<close> "solve goal by normalization"
  1949 
  1950 
  1951 subsection \<open>Counterexample Search Units\<close>
  1952 
  1953 subsubsection \<open>Quickcheck\<close>
  1954 
  1955 quickcheck_params [size = 5, iterations = 50]
  1956 
  1957 
  1958 subsubsection \<open>Nitpick setup\<close>
  1959 
  1960 named_theorems nitpick_unfold "alternative definitions of constants as needed by Nitpick"
  1961   and nitpick_simp "equational specification of constants as needed by Nitpick"
  1962   and nitpick_psimp "partial equational specification of constants as needed by Nitpick"
  1963   and nitpick_choice_spec "choice specification of constants as needed by Nitpick"
  1964 
  1965 declare if_bool_eq_conj [nitpick_unfold, no_atp]
  1966   and if_bool_eq_disj [no_atp]
  1967 
  1968 
  1969 subsection \<open>Preprocessing for the predicate compiler\<close>
  1970 
  1971 named_theorems code_pred_def "alternative definitions of constants for the Predicate Compiler"
  1972   and code_pred_inline "inlining definitions for the Predicate Compiler"
  1973   and code_pred_simp "simplification rules for the optimisations in the Predicate Compiler"
  1974 
  1975 
  1976 subsection \<open>Legacy tactics and ML bindings\<close>
  1977 
  1978 ML \<open>
  1979   (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1980   local
  1981     fun wrong_prem (Const (@{const_name All}, _) $ Abs (_, _, t)) = wrong_prem t
  1982       | wrong_prem (Bound _) = true
  1983       | wrong_prem _ = false;
  1984     val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  1985     fun smp i = funpow i (fn m => filter_right ([spec] RL m)) [mp];
  1986   in
  1987     fun smp_tac ctxt j = EVERY' [dresolve_tac ctxt (smp j), assume_tac ctxt];
  1988   end;
  1989 
  1990   local
  1991     val nnf_ss =
  1992       simpset_of (put_simpset HOL_basic_ss @{context} addsimps @{thms simp_thms nnf_simps});
  1993   in
  1994     fun nnf_conv ctxt = Simplifier.rewrite (put_simpset nnf_ss ctxt);
  1995   end
  1996 \<close>
  1997 
  1998 hide_const (open) eq equal
  1999 
  2000 end