src/HOL/Analysis/Complex_Analysis_Basics.thy
author wenzelm
Fri Aug 18 20:47:47 2017 +0200 (22 months ago)
changeset 66453 cc19f7ca2ed6
parent 66252 b73f94b366b7
child 66486 ffaaa83543b2
permissions -rw-r--r--
session-qualified theory imports: isabelle imports -U -i -d '~~/src/Benchmarks' -a;
     1 (*  Author: John Harrison, Marco Maggesi, Graziano Gentili, Gianni Ciolli, Valentina Bruno
     2     Ported from "hol_light/Multivariate/canal.ml" by L C Paulson (2014)
     3 *)
     4 
     5 section \<open>Complex Analysis Basics\<close>
     6 
     7 theory Complex_Analysis_Basics
     8 imports Equivalence_Lebesgue_Henstock_Integration "HOL-Library.Nonpos_Ints"
     9 begin
    10 
    11 
    12 subsection\<open>General lemmas\<close>
    13 
    14 lemma nonneg_Reals_cmod_eq_Re: "z \<in> \<real>\<^sub>\<ge>\<^sub>0 \<Longrightarrow> norm z = Re z"
    15   by (simp add: complex_nonneg_Reals_iff cmod_eq_Re)
    16 
    17 lemma has_derivative_mult_right:
    18   fixes c:: "'a :: real_normed_algebra"
    19   shows "((op * c) has_derivative (op * c)) F"
    20 by (rule has_derivative_mult_right [OF has_derivative_id])
    21 
    22 lemma has_derivative_of_real[derivative_intros, simp]:
    23   "(f has_derivative f') F \<Longrightarrow> ((\<lambda>x. of_real (f x)) has_derivative (\<lambda>x. of_real (f' x))) F"
    24   using bounded_linear.has_derivative[OF bounded_linear_of_real] .
    25 
    26 lemma has_vector_derivative_real_field:
    27   "DERIV f (of_real a) :> f' \<Longrightarrow> ((\<lambda>x. f (of_real x)) has_vector_derivative f') (at a within s)"
    28   using has_derivative_compose[of of_real of_real a _ f "op * f'"]
    29   by (simp add: scaleR_conv_of_real ac_simps has_vector_derivative_def has_field_derivative_def)
    30 lemmas has_vector_derivative_real_complex = has_vector_derivative_real_field
    31 
    32 lemma fact_cancel:
    33   fixes c :: "'a::real_field"
    34   shows "of_nat (Suc n) * c / (fact (Suc n)) = c / (fact n)"
    35   by (simp add: of_nat_mult del: of_nat_Suc times_nat.simps)
    36 
    37 lemma bilinear_times:
    38   fixes c::"'a::real_algebra" shows "bilinear (\<lambda>x y::'a. x*y)"
    39   by (auto simp: bilinear_def distrib_left distrib_right intro!: linearI)
    40 
    41 lemma linear_cnj: "linear cnj"
    42   using bounded_linear.linear[OF bounded_linear_cnj] .
    43 
    44 lemma tendsto_Re_upper:
    45   assumes "~ (trivial_limit F)"
    46           "(f \<longlongrightarrow> l) F"
    47           "eventually (\<lambda>x. Re(f x) \<le> b) F"
    48     shows  "Re(l) \<le> b"
    49   by (metis assms tendsto_le [OF _ tendsto_const]  tendsto_Re)
    50 
    51 lemma tendsto_Re_lower:
    52   assumes "~ (trivial_limit F)"
    53           "(f \<longlongrightarrow> l) F"
    54           "eventually (\<lambda>x. b \<le> Re(f x)) F"
    55     shows  "b \<le> Re(l)"
    56   by (metis assms tendsto_le [OF _ _ tendsto_const]  tendsto_Re)
    57 
    58 lemma tendsto_Im_upper:
    59   assumes "~ (trivial_limit F)"
    60           "(f \<longlongrightarrow> l) F"
    61           "eventually (\<lambda>x. Im(f x) \<le> b) F"
    62     shows  "Im(l) \<le> b"
    63   by (metis assms tendsto_le [OF _ tendsto_const]  tendsto_Im)
    64 
    65 lemma tendsto_Im_lower:
    66   assumes "~ (trivial_limit F)"
    67           "(f \<longlongrightarrow> l) F"
    68           "eventually (\<lambda>x. b \<le> Im(f x)) F"
    69     shows  "b \<le> Im(l)"
    70   by (metis assms tendsto_le [OF _ _ tendsto_const]  tendsto_Im)
    71 
    72 lemma lambda_zero: "(\<lambda>h::'a::mult_zero. 0) = op * 0"
    73   by auto
    74 
    75 lemma lambda_one: "(\<lambda>x::'a::monoid_mult. x) = op * 1"
    76   by auto
    77 
    78 lemma continuous_mult_left:
    79   fixes c::"'a::real_normed_algebra"
    80   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. c * f x)"
    81 by (rule continuous_mult [OF continuous_const])
    82 
    83 lemma continuous_mult_right:
    84   fixes c::"'a::real_normed_algebra"
    85   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. f x * c)"
    86 by (rule continuous_mult [OF _ continuous_const])
    87 
    88 lemma continuous_on_mult_left:
    89   fixes c::"'a::real_normed_algebra"
    90   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. c * f x)"
    91 by (rule continuous_on_mult [OF continuous_on_const])
    92 
    93 lemma continuous_on_mult_right:
    94   fixes c::"'a::real_normed_algebra"
    95   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. f x * c)"
    96 by (rule continuous_on_mult [OF _ continuous_on_const])
    97 
    98 lemma uniformly_continuous_on_cmul_right [continuous_intros]:
    99   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
   100   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s (\<lambda>x. f x * c)"
   101   using bounded_linear.uniformly_continuous_on[OF bounded_linear_mult_left] .
   102 
   103 lemma uniformly_continuous_on_cmul_left[continuous_intros]:
   104   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
   105   assumes "uniformly_continuous_on s f"
   106     shows "uniformly_continuous_on s (\<lambda>x. c * f x)"
   107 by (metis assms bounded_linear.uniformly_continuous_on bounded_linear_mult_right)
   108 
   109 lemma continuous_within_norm_id [continuous_intros]: "continuous (at x within S) norm"
   110   by (rule continuous_norm [OF continuous_ident])
   111 
   112 lemma continuous_on_norm_id [continuous_intros]: "continuous_on S norm"
   113   by (intro continuous_on_id continuous_on_norm)
   114 
   115 subsection\<open>DERIV stuff\<close>
   116 
   117 lemma DERIV_zero_connected_constant:
   118   fixes f :: "'a::{real_normed_field,euclidean_space} \<Rightarrow> 'a"
   119   assumes "connected s"
   120       and "open s"
   121       and "finite k"
   122       and "continuous_on s f"
   123       and "\<forall>x\<in>(s - k). DERIV f x :> 0"
   124     obtains c where "\<And>x. x \<in> s \<Longrightarrow> f(x) = c"
   125 using has_derivative_zero_connected_constant [OF assms(1-4)] assms
   126 by (metis DERIV_const has_derivative_const Diff_iff at_within_open frechet_derivative_at has_field_derivative_def)
   127 
   128 lemmas DERIV_zero_constant = has_field_derivative_zero_constant
   129 
   130 lemma DERIV_zero_unique:
   131   assumes "convex s"
   132       and d0: "\<And>x. x\<in>s \<Longrightarrow> (f has_field_derivative 0) (at x within s)"
   133       and "a \<in> s"
   134       and "x \<in> s"
   135     shows "f x = f a"
   136   by (rule has_derivative_zero_unique [OF assms(1) _ assms(4,3)])
   137      (metis d0 has_field_derivative_imp_has_derivative lambda_zero)
   138 
   139 lemma DERIV_zero_connected_unique:
   140   assumes "connected s"
   141       and "open s"
   142       and d0: "\<And>x. x\<in>s \<Longrightarrow> DERIV f x :> 0"
   143       and "a \<in> s"
   144       and "x \<in> s"
   145     shows "f x = f a"
   146     by (rule has_derivative_zero_unique_connected [OF assms(2,1) _ assms(5,4)])
   147        (metis has_field_derivative_def lambda_zero d0)
   148 
   149 lemma DERIV_transform_within:
   150   assumes "(f has_field_derivative f') (at a within s)"
   151       and "0 < d" "a \<in> s"
   152       and "\<And>x. x\<in>s \<Longrightarrow> dist x a < d \<Longrightarrow> f x = g x"
   153     shows "(g has_field_derivative f') (at a within s)"
   154   using assms unfolding has_field_derivative_def
   155   by (blast intro: has_derivative_transform_within)
   156 
   157 lemma DERIV_transform_within_open:
   158   assumes "DERIV f a :> f'"
   159       and "open s" "a \<in> s"
   160       and "\<And>x. x\<in>s \<Longrightarrow> f x = g x"
   161     shows "DERIV g a :> f'"
   162   using assms unfolding has_field_derivative_def
   163 by (metis has_derivative_transform_within_open)
   164 
   165 lemma DERIV_transform_at:
   166   assumes "DERIV f a :> f'"
   167       and "0 < d"
   168       and "\<And>x. dist x a < d \<Longrightarrow> f x = g x"
   169     shows "DERIV g a :> f'"
   170   by (blast intro: assms DERIV_transform_within)
   171 
   172 (*generalising DERIV_isconst_all, which requires type real (using the ordering)*)
   173 lemma DERIV_zero_UNIV_unique:
   174   "(\<And>x. DERIV f x :> 0) \<Longrightarrow> f x = f a"
   175   by (metis DERIV_zero_unique UNIV_I convex_UNIV)
   176 
   177 subsection \<open>Some limit theorems about real part of real series etc.\<close>
   178 
   179 (*MOVE? But not to Finite_Cartesian_Product*)
   180 lemma sums_vec_nth :
   181   assumes "f sums a"
   182   shows "(\<lambda>x. f x $ i) sums a $ i"
   183 using assms unfolding sums_def
   184 by (auto dest: tendsto_vec_nth [where i=i])
   185 
   186 lemma summable_vec_nth :
   187   assumes "summable f"
   188   shows "summable (\<lambda>x. f x $ i)"
   189 using assms unfolding summable_def
   190 by (blast intro: sums_vec_nth)
   191 
   192 subsection \<open>Complex number lemmas\<close>
   193 
   194 lemma
   195   shows open_halfspace_Re_lt: "open {z. Re(z) < b}"
   196     and open_halfspace_Re_gt: "open {z. Re(z) > b}"
   197     and closed_halfspace_Re_ge: "closed {z. Re(z) \<ge> b}"
   198     and closed_halfspace_Re_le: "closed {z. Re(z) \<le> b}"
   199     and closed_halfspace_Re_eq: "closed {z. Re(z) = b}"
   200     and open_halfspace_Im_lt: "open {z. Im(z) < b}"
   201     and open_halfspace_Im_gt: "open {z. Im(z) > b}"
   202     and closed_halfspace_Im_ge: "closed {z. Im(z) \<ge> b}"
   203     and closed_halfspace_Im_le: "closed {z. Im(z) \<le> b}"
   204     and closed_halfspace_Im_eq: "closed {z. Im(z) = b}"
   205   by (intro open_Collect_less closed_Collect_le closed_Collect_eq continuous_on_Re
   206             continuous_on_Im continuous_on_id continuous_on_const)+
   207 
   208 lemma closed_complex_Reals: "closed (\<real> :: complex set)"
   209 proof -
   210   have "(\<real> :: complex set) = {z. Im z = 0}"
   211     by (auto simp: complex_is_Real_iff)
   212   then show ?thesis
   213     by (metis closed_halfspace_Im_eq)
   214 qed
   215 
   216 lemma closed_Real_halfspace_Re_le: "closed (\<real> \<inter> {w. Re w \<le> x})"
   217   by (simp add: closed_Int closed_complex_Reals closed_halfspace_Re_le)
   218 
   219 corollary closed_nonpos_Reals_complex [simp]: "closed (\<real>\<^sub>\<le>\<^sub>0 :: complex set)"
   220 proof -
   221   have "\<real>\<^sub>\<le>\<^sub>0 = \<real> \<inter> {z. Re(z) \<le> 0}"
   222     using complex_nonpos_Reals_iff complex_is_Real_iff by auto
   223   then show ?thesis
   224     by (metis closed_Real_halfspace_Re_le)
   225 qed
   226 
   227 lemma closed_Real_halfspace_Re_ge: "closed (\<real> \<inter> {w. x \<le> Re(w)})"
   228   using closed_halfspace_Re_ge
   229   by (simp add: closed_Int closed_complex_Reals)
   230 
   231 corollary closed_nonneg_Reals_complex [simp]: "closed (\<real>\<^sub>\<ge>\<^sub>0 :: complex set)"
   232 proof -
   233   have "\<real>\<^sub>\<ge>\<^sub>0 = \<real> \<inter> {z. Re(z) \<ge> 0}"
   234     using complex_nonneg_Reals_iff complex_is_Real_iff by auto
   235   then show ?thesis
   236     by (metis closed_Real_halfspace_Re_ge)
   237 qed
   238 
   239 lemma closed_real_abs_le: "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   240 proof -
   241   have "{w \<in> \<real>. \<bar>Re w\<bar> \<le> r} = (\<real> \<inter> {w. Re w \<le> r}) \<inter> (\<real> \<inter> {w. Re w \<ge> -r})"
   242     by auto
   243   then show "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   244     by (simp add: closed_Int closed_Real_halfspace_Re_ge closed_Real_halfspace_Re_le)
   245 qed
   246 
   247 lemma real_lim:
   248   fixes l::complex
   249   assumes "(f \<longlongrightarrow> l) F" and "~(trivial_limit F)" and "eventually P F" and "\<And>a. P a \<Longrightarrow> f a \<in> \<real>"
   250   shows  "l \<in> \<real>"
   251 proof (rule Lim_in_closed_set[OF closed_complex_Reals _ assms(2,1)])
   252   show "eventually (\<lambda>x. f x \<in> \<real>) F"
   253     using assms(3, 4) by (auto intro: eventually_mono)
   254 qed
   255 
   256 lemma real_lim_sequentially:
   257   fixes l::complex
   258   shows "(f \<longlongrightarrow> l) sequentially \<Longrightarrow> (\<exists>N. \<forall>n\<ge>N. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   259 by (rule real_lim [where F=sequentially]) (auto simp: eventually_sequentially)
   260 
   261 lemma real_series:
   262   fixes l::complex
   263   shows "f sums l \<Longrightarrow> (\<And>n. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   264 unfolding sums_def
   265 by (metis real_lim_sequentially sum_in_Reals)
   266 
   267 lemma Lim_null_comparison_Re:
   268   assumes "eventually (\<lambda>x. norm(f x) \<le> Re(g x)) F" "(g \<longlongrightarrow> 0) F" shows "(f \<longlongrightarrow> 0) F"
   269   by (rule Lim_null_comparison[OF assms(1)] tendsto_eq_intros assms(2))+ simp
   270 
   271 subsection\<open>Holomorphic functions\<close>
   272 
   273 subsection\<open>Holomorphic functions\<close>
   274 
   275 definition holomorphic_on :: "[complex \<Rightarrow> complex, complex set] \<Rightarrow> bool"
   276            (infixl "(holomorphic'_on)" 50)
   277   where "f holomorphic_on s \<equiv> \<forall>x\<in>s. f field_differentiable (at x within s)"
   278 
   279 named_theorems holomorphic_intros "structural introduction rules for holomorphic_on"
   280 
   281 lemma holomorphic_onI [intro?]: "(\<And>x. x \<in> s \<Longrightarrow> f field_differentiable (at x within s)) \<Longrightarrow> f holomorphic_on s"
   282   by (simp add: holomorphic_on_def)
   283 
   284 lemma holomorphic_onD [dest?]: "\<lbrakk>f holomorphic_on s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x within s)"
   285   by (simp add: holomorphic_on_def)
   286 
   287 lemma holomorphic_on_imp_differentiable_on:
   288     "f holomorphic_on s \<Longrightarrow> f differentiable_on s"
   289   unfolding holomorphic_on_def differentiable_on_def
   290   by (simp add: field_differentiable_imp_differentiable)
   291 
   292 lemma holomorphic_on_imp_differentiable_at:
   293    "\<lbrakk>f holomorphic_on s; open s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x)"
   294 using at_within_open holomorphic_on_def by fastforce
   295 
   296 lemma holomorphic_on_empty [holomorphic_intros]: "f holomorphic_on {}"
   297   by (simp add: holomorphic_on_def)
   298 
   299 lemma holomorphic_on_open:
   300     "open s \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> (\<forall>x \<in> s. \<exists>f'. DERIV f x :> f')"
   301   by (auto simp: holomorphic_on_def field_differentiable_def has_field_derivative_def at_within_open [of _ s])
   302 
   303 lemma holomorphic_on_imp_continuous_on:
   304     "f holomorphic_on s \<Longrightarrow> continuous_on s f"
   305   by (metis field_differentiable_imp_continuous_at continuous_on_eq_continuous_within holomorphic_on_def)
   306 
   307 lemma holomorphic_on_subset [elim]:
   308     "f holomorphic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f holomorphic_on t"
   309   unfolding holomorphic_on_def
   310   by (metis field_differentiable_within_subset subsetD)
   311 
   312 lemma holomorphic_transform: "\<lbrakk>f holomorphic_on s; \<And>x. x \<in> s \<Longrightarrow> f x = g x\<rbrakk> \<Longrightarrow> g holomorphic_on s"
   313   by (metis field_differentiable_transform_within linordered_field_no_ub holomorphic_on_def)
   314 
   315 lemma holomorphic_cong: "s = t ==> (\<And>x. x \<in> s \<Longrightarrow> f x = g x) \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> g holomorphic_on t"
   316   by (metis holomorphic_transform)
   317 
   318 lemma holomorphic_on_linear [simp, holomorphic_intros]: "(op * c) holomorphic_on s"
   319   unfolding holomorphic_on_def by (metis field_differentiable_linear)
   320 
   321 lemma holomorphic_on_const [simp, holomorphic_intros]: "(\<lambda>z. c) holomorphic_on s"
   322   unfolding holomorphic_on_def by (metis field_differentiable_const)
   323 
   324 lemma holomorphic_on_ident [simp, holomorphic_intros]: "(\<lambda>x. x) holomorphic_on s"
   325   unfolding holomorphic_on_def by (metis field_differentiable_ident)
   326 
   327 lemma holomorphic_on_id [simp, holomorphic_intros]: "id holomorphic_on s"
   328   unfolding id_def by (rule holomorphic_on_ident)
   329 
   330 lemma holomorphic_on_compose:
   331   "f holomorphic_on s \<Longrightarrow> g holomorphic_on (f ` s) \<Longrightarrow> (g o f) holomorphic_on s"
   332   using field_differentiable_compose_within[of f _ s g]
   333   by (auto simp: holomorphic_on_def)
   334 
   335 lemma holomorphic_on_compose_gen:
   336   "f holomorphic_on s \<Longrightarrow> g holomorphic_on t \<Longrightarrow> f ` s \<subseteq> t \<Longrightarrow> (g o f) holomorphic_on s"
   337   by (metis holomorphic_on_compose holomorphic_on_subset)
   338 
   339 lemma holomorphic_on_minus [holomorphic_intros]: "f holomorphic_on s \<Longrightarrow> (\<lambda>z. -(f z)) holomorphic_on s"
   340   by (metis field_differentiable_minus holomorphic_on_def)
   341 
   342 lemma holomorphic_on_add [holomorphic_intros]:
   343   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z + g z) holomorphic_on s"
   344   unfolding holomorphic_on_def by (metis field_differentiable_add)
   345 
   346 lemma holomorphic_on_diff [holomorphic_intros]:
   347   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z - g z) holomorphic_on s"
   348   unfolding holomorphic_on_def by (metis field_differentiable_diff)
   349 
   350 lemma holomorphic_on_mult [holomorphic_intros]:
   351   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z * g z) holomorphic_on s"
   352   unfolding holomorphic_on_def by (metis field_differentiable_mult)
   353 
   354 lemma holomorphic_on_inverse [holomorphic_intros]:
   355   "\<lbrakk>f holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. inverse (f z)) holomorphic_on s"
   356   unfolding holomorphic_on_def by (metis field_differentiable_inverse)
   357 
   358 lemma holomorphic_on_divide [holomorphic_intros]:
   359   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. f z / g z) holomorphic_on s"
   360   unfolding holomorphic_on_def by (metis field_differentiable_divide)
   361 
   362 lemma holomorphic_on_power [holomorphic_intros]:
   363   "f holomorphic_on s \<Longrightarrow> (\<lambda>z. (f z)^n) holomorphic_on s"
   364   unfolding holomorphic_on_def by (metis field_differentiable_power)
   365 
   366 lemma holomorphic_on_sum [holomorphic_intros]:
   367   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) holomorphic_on s"
   368   unfolding holomorphic_on_def by (metis field_differentiable_sum)
   369 
   370 lemma DERIV_deriv_iff_field_differentiable:
   371   "DERIV f x :> deriv f x \<longleftrightarrow> f field_differentiable at x"
   372   unfolding field_differentiable_def by (metis DERIV_imp_deriv)
   373 
   374 lemma holomorphic_derivI:
   375      "\<lbrakk>f holomorphic_on S; open S; x \<in> S\<rbrakk>
   376       \<Longrightarrow> (f has_field_derivative deriv f x) (at x within T)"
   377 by (metis DERIV_deriv_iff_field_differentiable at_within_open  holomorphic_on_def has_field_derivative_at_within)
   378 
   379 lemma complex_derivative_chain:
   380   "f field_differentiable at x \<Longrightarrow> g field_differentiable at (f x)
   381     \<Longrightarrow> deriv (g o f) x = deriv g (f x) * deriv f x"
   382   by (metis DERIV_deriv_iff_field_differentiable DERIV_chain DERIV_imp_deriv)
   383 
   384 lemma deriv_linear [simp]: "deriv (\<lambda>w. c * w) = (\<lambda>z. c)"
   385   by (metis DERIV_imp_deriv DERIV_cmult_Id)
   386 
   387 lemma deriv_ident [simp]: "deriv (\<lambda>w. w) = (\<lambda>z. 1)"
   388   by (metis DERIV_imp_deriv DERIV_ident)
   389 
   390 lemma deriv_id [simp]: "deriv id = (\<lambda>z. 1)"
   391   by (simp add: id_def)
   392 
   393 lemma deriv_const [simp]: "deriv (\<lambda>w. c) = (\<lambda>z. 0)"
   394   by (metis DERIV_imp_deriv DERIV_const)
   395 
   396 lemma deriv_add [simp]:
   397   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   398    \<Longrightarrow> deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   399   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   400   by (auto intro!: DERIV_imp_deriv derivative_intros)
   401 
   402 lemma deriv_diff [simp]:
   403   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   404    \<Longrightarrow> deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   405   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   406   by (auto intro!: DERIV_imp_deriv derivative_intros)
   407 
   408 lemma deriv_mult [simp]:
   409   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   410    \<Longrightarrow> deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   411   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   412   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   413 
   414 lemma deriv_cmult [simp]:
   415   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. c * f w) z = c * deriv f z"
   416   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   417   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   418 
   419 lemma deriv_cmult_right [simp]:
   420   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w * c) z = deriv f z * c"
   421   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   422   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   423 
   424 lemma deriv_cdivide_right [simp]:
   425   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w / c) z = deriv f z / c"
   426   unfolding Fields.field_class.field_divide_inverse
   427   by (blast intro: deriv_cmult_right)
   428 
   429 lemma complex_derivative_transform_within_open:
   430   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; open s; z \<in> s; \<And>w. w \<in> s \<Longrightarrow> f w = g w\<rbrakk>
   431    \<Longrightarrow> deriv f z = deriv g z"
   432   unfolding holomorphic_on_def
   433   by (rule DERIV_imp_deriv)
   434      (metis DERIV_deriv_iff_field_differentiable DERIV_transform_within_open at_within_open)
   435 
   436 lemma deriv_compose_linear:
   437   "f field_differentiable at (c * z) \<Longrightarrow> deriv (\<lambda>w. f (c * w)) z = c * deriv f (c * z)"
   438 apply (rule DERIV_imp_deriv)
   439 apply (simp add: DERIV_deriv_iff_field_differentiable [symmetric])
   440 apply (drule DERIV_chain' [of "times c" c z UNIV f "deriv f (c * z)", OF DERIV_cmult_Id])
   441 apply (simp add: algebra_simps)
   442 done
   443 
   444 lemma nonzero_deriv_nonconstant:
   445   assumes df: "DERIV f \<xi> :> df" and S: "open S" "\<xi> \<in> S" and "df \<noteq> 0"
   446     shows "\<not> f constant_on S"
   447 unfolding constant_on_def
   448 by (metis \<open>df \<noteq> 0\<close> DERIV_transform_within_open [OF df S] DERIV_const DERIV_unique)
   449 
   450 lemma holomorphic_nonconstant:
   451   assumes holf: "f holomorphic_on S" and "open S" "\<xi> \<in> S" "deriv f \<xi> \<noteq> 0"
   452     shows "\<not> f constant_on S"
   453     apply (rule nonzero_deriv_nonconstant [of f "deriv f \<xi>" \<xi> S])
   454     using assms
   455     apply (auto simp: holomorphic_derivI)
   456     done
   457 
   458 subsection\<open>Caratheodory characterization\<close>
   459 
   460 lemma field_differentiable_caratheodory_at:
   461   "f field_differentiable (at z) \<longleftrightarrow>
   462          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z) g)"
   463   using CARAT_DERIV [of f]
   464   by (simp add: field_differentiable_def has_field_derivative_def)
   465 
   466 lemma field_differentiable_caratheodory_within:
   467   "f field_differentiable (at z within s) \<longleftrightarrow>
   468          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z within s) g)"
   469   using DERIV_caratheodory_within [of f]
   470   by (simp add: field_differentiable_def has_field_derivative_def)
   471 
   472 subsection\<open>Analyticity on a set\<close>
   473 
   474 definition analytic_on (infixl "(analytic'_on)" 50)
   475   where
   476    "f analytic_on s \<equiv> \<forall>x \<in> s. \<exists>e. 0 < e \<and> f holomorphic_on (ball x e)"
   477 
   478 named_theorems analytic_intros "introduction rules for proving analyticity"
   479 
   480 lemma analytic_imp_holomorphic: "f analytic_on s \<Longrightarrow> f holomorphic_on s"
   481   by (simp add: at_within_open [OF _ open_ball] analytic_on_def holomorphic_on_def)
   482      (metis centre_in_ball field_differentiable_at_within)
   483 
   484 lemma analytic_on_open: "open s \<Longrightarrow> f analytic_on s \<longleftrightarrow> f holomorphic_on s"
   485 apply (auto simp: analytic_imp_holomorphic)
   486 apply (auto simp: analytic_on_def holomorphic_on_def)
   487 by (metis holomorphic_on_def holomorphic_on_subset open_contains_ball)
   488 
   489 lemma analytic_on_imp_differentiable_at:
   490   "f analytic_on s \<Longrightarrow> x \<in> s \<Longrightarrow> f field_differentiable (at x)"
   491  apply (auto simp: analytic_on_def holomorphic_on_def)
   492 by (metis Topology_Euclidean_Space.open_ball centre_in_ball field_differentiable_within_open)
   493 
   494 lemma analytic_on_subset: "f analytic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f analytic_on t"
   495   by (auto simp: analytic_on_def)
   496 
   497 lemma analytic_on_Un: "f analytic_on (s \<union> t) \<longleftrightarrow> f analytic_on s \<and> f analytic_on t"
   498   by (auto simp: analytic_on_def)
   499 
   500 lemma analytic_on_Union: "f analytic_on (\<Union>s) \<longleftrightarrow> (\<forall>t \<in> s. f analytic_on t)"
   501   by (auto simp: analytic_on_def)
   502 
   503 lemma analytic_on_UN: "f analytic_on (\<Union>i\<in>I. s i) \<longleftrightarrow> (\<forall>i\<in>I. f analytic_on (s i))"
   504   by (auto simp: analytic_on_def)
   505 
   506 lemma analytic_on_holomorphic:
   507   "f analytic_on s \<longleftrightarrow> (\<exists>t. open t \<and> s \<subseteq> t \<and> f holomorphic_on t)"
   508   (is "?lhs = ?rhs")
   509 proof -
   510   have "?lhs \<longleftrightarrow> (\<exists>t. open t \<and> s \<subseteq> t \<and> f analytic_on t)"
   511   proof safe
   512     assume "f analytic_on s"
   513     then show "\<exists>t. open t \<and> s \<subseteq> t \<and> f analytic_on t"
   514       apply (simp add: analytic_on_def)
   515       apply (rule exI [where x="\<Union>{u. open u \<and> f analytic_on u}"], auto)
   516       apply (metis Topology_Euclidean_Space.open_ball analytic_on_open centre_in_ball)
   517       by (metis analytic_on_def)
   518   next
   519     fix t
   520     assume "open t" "s \<subseteq> t" "f analytic_on t"
   521     then show "f analytic_on s"
   522         by (metis analytic_on_subset)
   523   qed
   524   also have "... \<longleftrightarrow> ?rhs"
   525     by (auto simp: analytic_on_open)
   526   finally show ?thesis .
   527 qed
   528 
   529 lemma analytic_on_linear [analytic_intros,simp]: "(op * c) analytic_on s"
   530   by (auto simp add: analytic_on_holomorphic)
   531 
   532 lemma analytic_on_const [analytic_intros,simp]: "(\<lambda>z. c) analytic_on s"
   533   by (metis analytic_on_def holomorphic_on_const zero_less_one)
   534 
   535 lemma analytic_on_ident [analytic_intros,simp]: "(\<lambda>x. x) analytic_on s"
   536   by (simp add: analytic_on_def gt_ex)
   537 
   538 lemma analytic_on_id [analytic_intros]: "id analytic_on s"
   539   unfolding id_def by (rule analytic_on_ident)
   540 
   541 lemma analytic_on_compose:
   542   assumes f: "f analytic_on s"
   543       and g: "g analytic_on (f ` s)"
   544     shows "(g o f) analytic_on s"
   545 unfolding analytic_on_def
   546 proof (intro ballI)
   547   fix x
   548   assume x: "x \<in> s"
   549   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball x e" using f
   550     by (metis analytic_on_def)
   551   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball (f x) e'" using g
   552     by (metis analytic_on_def g image_eqI x)
   553   have "isCont f x"
   554     by (metis analytic_on_imp_differentiable_at field_differentiable_imp_continuous_at f x)
   555   with e' obtain d where d: "0 < d" and fd: "f ` ball x d \<subseteq> ball (f x) e'"
   556      by (auto simp: continuous_at_ball)
   557   have "g \<circ> f holomorphic_on ball x (min d e)"
   558     apply (rule holomorphic_on_compose)
   559     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   560     by (metis fd gh holomorphic_on_subset image_mono min.cobounded1 subset_ball)
   561   then show "\<exists>e>0. g \<circ> f holomorphic_on ball x e"
   562     by (metis d e min_less_iff_conj)
   563 qed
   564 
   565 lemma analytic_on_compose_gen:
   566   "f analytic_on s \<Longrightarrow> g analytic_on t \<Longrightarrow> (\<And>z. z \<in> s \<Longrightarrow> f z \<in> t)
   567              \<Longrightarrow> g o f analytic_on s"
   568 by (metis analytic_on_compose analytic_on_subset image_subset_iff)
   569 
   570 lemma analytic_on_neg [analytic_intros]:
   571   "f analytic_on s \<Longrightarrow> (\<lambda>z. -(f z)) analytic_on s"
   572 by (metis analytic_on_holomorphic holomorphic_on_minus)
   573 
   574 lemma analytic_on_add [analytic_intros]:
   575   assumes f: "f analytic_on s"
   576       and g: "g analytic_on s"
   577     shows "(\<lambda>z. f z + g z) analytic_on s"
   578 unfolding analytic_on_def
   579 proof (intro ballI)
   580   fix z
   581   assume z: "z \<in> s"
   582   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   583     by (metis analytic_on_def)
   584   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   585     by (metis analytic_on_def g z)
   586   have "(\<lambda>z. f z + g z) holomorphic_on ball z (min e e')"
   587     apply (rule holomorphic_on_add)
   588     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   589     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   590   then show "\<exists>e>0. (\<lambda>z. f z + g z) holomorphic_on ball z e"
   591     by (metis e e' min_less_iff_conj)
   592 qed
   593 
   594 lemma analytic_on_diff [analytic_intros]:
   595   assumes f: "f analytic_on s"
   596       and g: "g analytic_on s"
   597     shows "(\<lambda>z. f z - g z) analytic_on s"
   598 unfolding analytic_on_def
   599 proof (intro ballI)
   600   fix z
   601   assume z: "z \<in> s"
   602   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   603     by (metis analytic_on_def)
   604   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   605     by (metis analytic_on_def g z)
   606   have "(\<lambda>z. f z - g z) holomorphic_on ball z (min e e')"
   607     apply (rule holomorphic_on_diff)
   608     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   609     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   610   then show "\<exists>e>0. (\<lambda>z. f z - g z) holomorphic_on ball z e"
   611     by (metis e e' min_less_iff_conj)
   612 qed
   613 
   614 lemma analytic_on_mult [analytic_intros]:
   615   assumes f: "f analytic_on s"
   616       and g: "g analytic_on s"
   617     shows "(\<lambda>z. f z * g z) analytic_on s"
   618 unfolding analytic_on_def
   619 proof (intro ballI)
   620   fix z
   621   assume z: "z \<in> s"
   622   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   623     by (metis analytic_on_def)
   624   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   625     by (metis analytic_on_def g z)
   626   have "(\<lambda>z. f z * g z) holomorphic_on ball z (min e e')"
   627     apply (rule holomorphic_on_mult)
   628     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   629     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   630   then show "\<exists>e>0. (\<lambda>z. f z * g z) holomorphic_on ball z e"
   631     by (metis e e' min_less_iff_conj)
   632 qed
   633 
   634 lemma analytic_on_inverse [analytic_intros]:
   635   assumes f: "f analytic_on s"
   636       and nz: "(\<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0)"
   637     shows "(\<lambda>z. inverse (f z)) analytic_on s"
   638 unfolding analytic_on_def
   639 proof (intro ballI)
   640   fix z
   641   assume z: "z \<in> s"
   642   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   643     by (metis analytic_on_def)
   644   have "continuous_on (ball z e) f"
   645     by (metis fh holomorphic_on_imp_continuous_on)
   646   then obtain e' where e': "0 < e'" and nz': "\<And>y. dist z y < e' \<Longrightarrow> f y \<noteq> 0"
   647     by (metis Topology_Euclidean_Space.open_ball centre_in_ball continuous_on_open_avoid e z nz)
   648   have "(\<lambda>z. inverse (f z)) holomorphic_on ball z (min e e')"
   649     apply (rule holomorphic_on_inverse)
   650     apply (metis fh holomorphic_on_subset min.cobounded2 min.commute subset_ball)
   651     by (metis nz' mem_ball min_less_iff_conj)
   652   then show "\<exists>e>0. (\<lambda>z. inverse (f z)) holomorphic_on ball z e"
   653     by (metis e e' min_less_iff_conj)
   654 qed
   655 
   656 lemma analytic_on_divide [analytic_intros]:
   657   assumes f: "f analytic_on s"
   658       and g: "g analytic_on s"
   659       and nz: "(\<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0)"
   660     shows "(\<lambda>z. f z / g z) analytic_on s"
   661 unfolding divide_inverse
   662 by (metis analytic_on_inverse analytic_on_mult f g nz)
   663 
   664 lemma analytic_on_power [analytic_intros]:
   665   "f analytic_on s \<Longrightarrow> (\<lambda>z. (f z) ^ n) analytic_on s"
   666 by (induct n) (auto simp: analytic_on_mult)
   667 
   668 lemma analytic_on_sum [analytic_intros]:
   669   "(\<And>i. i \<in> I \<Longrightarrow> (f i) analytic_on s) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) analytic_on s"
   670   by (induct I rule: infinite_finite_induct) (auto simp: analytic_on_const analytic_on_add)
   671 
   672 lemma deriv_left_inverse:
   673   assumes "f holomorphic_on S" and "g holomorphic_on T"
   674       and "open S" and "open T"
   675       and "f ` S \<subseteq> T"
   676       and [simp]: "\<And>z. z \<in> S \<Longrightarrow> g (f z) = z"
   677       and "w \<in> S"
   678     shows "deriv f w * deriv g (f w) = 1"
   679 proof -
   680   have "deriv f w * deriv g (f w) = deriv g (f w) * deriv f w"
   681     by (simp add: algebra_simps)
   682   also have "... = deriv (g o f) w"
   683     using assms
   684     by (metis analytic_on_imp_differentiable_at analytic_on_open complex_derivative_chain image_subset_iff)
   685   also have "... = deriv id w"
   686     apply (rule complex_derivative_transform_within_open [where s=S])
   687     apply (rule assms holomorphic_on_compose_gen holomorphic_intros)+
   688     apply simp
   689     done
   690   also have "... = 1"
   691     by simp
   692   finally show ?thesis .
   693 qed
   694 
   695 subsection\<open>analyticity at a point\<close>
   696 
   697 lemma analytic_at_ball:
   698   "f analytic_on {z} \<longleftrightarrow> (\<exists>e. 0<e \<and> f holomorphic_on ball z e)"
   699 by (metis analytic_on_def singleton_iff)
   700 
   701 lemma analytic_at:
   702     "f analytic_on {z} \<longleftrightarrow> (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s)"
   703 by (metis analytic_on_holomorphic empty_subsetI insert_subset)
   704 
   705 lemma analytic_on_analytic_at:
   706     "f analytic_on s \<longleftrightarrow> (\<forall>z \<in> s. f analytic_on {z})"
   707 by (metis analytic_at_ball analytic_on_def)
   708 
   709 lemma analytic_at_two:
   710   "f analytic_on {z} \<and> g analytic_on {z} \<longleftrightarrow>
   711    (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s \<and> g holomorphic_on s)"
   712   (is "?lhs = ?rhs")
   713 proof
   714   assume ?lhs
   715   then obtain s t
   716     where st: "open s" "z \<in> s" "f holomorphic_on s"
   717               "open t" "z \<in> t" "g holomorphic_on t"
   718     by (auto simp: analytic_at)
   719   show ?rhs
   720     apply (rule_tac x="s \<inter> t" in exI)
   721     using st
   722     apply (auto simp: Diff_subset holomorphic_on_subset)
   723     done
   724 next
   725   assume ?rhs
   726   then show ?lhs
   727     by (force simp add: analytic_at)
   728 qed
   729 
   730 subsection\<open>Combining theorems for derivative with ``analytic at'' hypotheses\<close>
   731 
   732 lemma
   733   assumes "f analytic_on {z}" "g analytic_on {z}"
   734   shows complex_derivative_add_at: "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   735     and complex_derivative_diff_at: "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   736     and complex_derivative_mult_at: "deriv (\<lambda>w. f w * g w) z =
   737            f z * deriv g z + deriv f z * g z"
   738 proof -
   739   obtain s where s: "open s" "z \<in> s" "f holomorphic_on s" "g holomorphic_on s"
   740     using assms by (metis analytic_at_two)
   741   show "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   742     apply (rule DERIV_imp_deriv [OF DERIV_add])
   743     using s
   744     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   745     done
   746   show "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   747     apply (rule DERIV_imp_deriv [OF DERIV_diff])
   748     using s
   749     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   750     done
   751   show "deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   752     apply (rule DERIV_imp_deriv [OF DERIV_mult'])
   753     using s
   754     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   755     done
   756 qed
   757 
   758 lemma deriv_cmult_at:
   759   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. c * f w) z = c * deriv f z"
   760 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   761 
   762 lemma deriv_cmult_right_at:
   763   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. f w * c) z = deriv f z * c"
   764 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   765 
   766 subsection\<open>Complex differentiation of sequences and series\<close>
   767 
   768 (* TODO: Could probably be simplified using Uniform_Limit *)
   769 lemma has_complex_derivative_sequence:
   770   fixes s :: "complex set"
   771   assumes cvs: "convex s"
   772       and df:  "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x within s)"
   773       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> s \<longrightarrow> norm (f' n x - g' x) \<le> e"
   774       and "\<exists>x l. x \<in> s \<and> ((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   775     shows "\<exists>g. \<forall>x \<in> s. ((\<lambda>n. f n x) \<longlongrightarrow> g x) sequentially \<and>
   776                        (g has_field_derivative (g' x)) (at x within s)"
   777 proof -
   778   from assms obtain x l where x: "x \<in> s" and tf: "((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   779     by blast
   780   { fix e::real assume e: "e > 0"
   781     then obtain N where N: "\<forall>n\<ge>N. \<forall>x. x \<in> s \<longrightarrow> cmod (f' n x - g' x) \<le> e"
   782       by (metis conv)
   783     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   784     proof (rule exI [of _ N], clarify)
   785       fix n y h
   786       assume "N \<le> n" "y \<in> s"
   787       then have "cmod (f' n y - g' y) \<le> e"
   788         by (metis N)
   789       then have "cmod h * cmod (f' n y - g' y) \<le> cmod h * e"
   790         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   791       then show "cmod (f' n y * h - g' y * h) \<le> e * cmod h"
   792         by (simp add: norm_mult [symmetric] field_simps)
   793     qed
   794   } note ** = this
   795   show ?thesis
   796   unfolding has_field_derivative_def
   797   proof (rule has_derivative_sequence [OF cvs _ _ x])
   798     show "\<forall>n. \<forall>x\<in>s. (f n has_derivative (op * (f' n x))) (at x within s)"
   799       by (metis has_field_derivative_def df)
   800   next show "(\<lambda>n. f n x) \<longlonglongrightarrow> l"
   801     by (rule tf)
   802   next show "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   803     by (blast intro: **)
   804   qed
   805 qed
   806 
   807 lemma has_complex_derivative_series:
   808   fixes s :: "complex set"
   809   assumes cvs: "convex s"
   810       and df:  "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x within s)"
   811       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> s
   812                 \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   813       and "\<exists>x l. x \<in> s \<and> ((\<lambda>n. f n x) sums l)"
   814     shows "\<exists>g. \<forall>x \<in> s. ((\<lambda>n. f n x) sums g x) \<and> ((g has_field_derivative g' x) (at x within s))"
   815 proof -
   816   from assms obtain x l where x: "x \<in> s" and sf: "((\<lambda>n. f n x) sums l)"
   817     by blast
   818   { fix e::real assume e: "e > 0"
   819     then obtain N where N: "\<forall>n x. n \<ge> N \<longrightarrow> x \<in> s
   820             \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   821       by (metis conv)
   822     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   823     proof (rule exI [of _ N], clarify)
   824       fix n y h
   825       assume "N \<le> n" "y \<in> s"
   826       then have "cmod ((\<Sum>i<n. f' i y) - g' y) \<le> e"
   827         by (metis N)
   828       then have "cmod h * cmod ((\<Sum>i<n. f' i y) - g' y) \<le> cmod h * e"
   829         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   830       then show "cmod ((\<Sum>i<n. h * f' i y) - g' y * h) \<le> e * cmod h"
   831         by (simp add: norm_mult [symmetric] field_simps sum_distrib_left)
   832     qed
   833   } note ** = this
   834   show ?thesis
   835   unfolding has_field_derivative_def
   836   proof (rule has_derivative_series [OF cvs _ _ x])
   837     fix n x
   838     assume "x \<in> s"
   839     then show "((f n) has_derivative (\<lambda>z. z * f' n x)) (at x within s)"
   840       by (metis df has_field_derivative_def mult_commute_abs)
   841   next show " ((\<lambda>n. f n x) sums l)"
   842     by (rule sf)
   843   next show "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   844     by (blast intro: **)
   845   qed
   846 qed
   847 
   848 
   849 lemma field_differentiable_series:
   850   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach} \<Rightarrow> 'a"
   851   assumes "convex s" "open s"
   852   assumes "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   853   assumes "uniformly_convergent_on s (\<lambda>n x. \<Sum>i<n. f' i x)"
   854   assumes "x0 \<in> s" "summable (\<lambda>n. f n x0)" and x: "x \<in> s"
   855   shows   "summable (\<lambda>n. f n x)" and "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)"
   856 proof -
   857   from assms(4) obtain g' where A: "uniform_limit s (\<lambda>n x. \<Sum>i<n. f' i x) g' sequentially"
   858     unfolding uniformly_convergent_on_def by blast
   859   from x and \<open>open s\<close> have s: "at x within s = at x" by (rule at_within_open)
   860   have "\<exists>g. \<forall>x\<in>s. (\<lambda>n. f n x) sums g x \<and> (g has_field_derivative g' x) (at x within s)"
   861     by (intro has_field_derivative_series[of s f f' g' x0] assms A has_field_derivative_at_within)
   862   then obtain g where g: "\<And>x. x \<in> s \<Longrightarrow> (\<lambda>n. f n x) sums g x"
   863     "\<And>x. x \<in> s \<Longrightarrow> (g has_field_derivative g' x) (at x within s)" by blast
   864   from g[OF x] show "summable (\<lambda>n. f n x)" by (auto simp: summable_def)
   865   from g(2)[OF x] have g': "(g has_derivative op * (g' x)) (at x)"
   866     by (simp add: has_field_derivative_def s)
   867   have "((\<lambda>x. \<Sum>n. f n x) has_derivative op * (g' x)) (at x)"
   868     by (rule has_derivative_transform_within_open[OF g' \<open>open s\<close> x])
   869        (insert g, auto simp: sums_iff)
   870   thus "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)" unfolding differentiable_def
   871     by (auto simp: summable_def field_differentiable_def has_field_derivative_def)
   872 qed
   873 
   874 lemma field_differentiable_series':
   875   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach} \<Rightarrow> 'a"
   876   assumes "convex s" "open s"
   877   assumes "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   878   assumes "uniformly_convergent_on s (\<lambda>n x. \<Sum>i<n. f' i x)"
   879   assumes "x0 \<in> s" "summable (\<lambda>n. f n x0)"
   880   shows   "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x0)"
   881   using field_differentiable_series[OF assms, of x0] \<open>x0 \<in> s\<close> by blast+
   882 
   883 subsection\<open>Bound theorem\<close>
   884 
   885 lemma field_differentiable_bound:
   886   fixes s :: "'a::real_normed_field set"
   887   assumes cvs: "convex s"
   888       and df:  "\<And>z. z \<in> s \<Longrightarrow> (f has_field_derivative f' z) (at z within s)"
   889       and dn:  "\<And>z. z \<in> s \<Longrightarrow> norm (f' z) \<le> B"
   890       and "x \<in> s"  "y \<in> s"
   891     shows "norm(f x - f y) \<le> B * norm(x - y)"
   892   apply (rule differentiable_bound [OF cvs])
   893   apply (rule ballI, erule df [unfolded has_field_derivative_def])
   894   apply (rule ballI, rule onorm_le, simp add: norm_mult mult_right_mono dn)
   895   apply fact
   896   apply fact
   897   done
   898 
   899 subsection\<open>Inverse function theorem for complex derivatives\<close>
   900 
   901 lemma has_field_derivative_inverse_basic:
   902   shows "DERIV f (g y) :> f' \<Longrightarrow>
   903         f' \<noteq> 0 \<Longrightarrow>
   904         continuous (at y) g \<Longrightarrow>
   905         open t \<Longrightarrow>
   906         y \<in> t \<Longrightarrow>
   907         (\<And>z. z \<in> t \<Longrightarrow> f (g z) = z)
   908         \<Longrightarrow> DERIV g y :> inverse (f')"
   909   unfolding has_field_derivative_def
   910   apply (rule has_derivative_inverse_basic)
   911   apply (auto simp:  bounded_linear_mult_right)
   912   done
   913 
   914 lemmas has_complex_derivative_inverse_basic = has_field_derivative_inverse_basic
   915 
   916 lemma has_field_derivative_inverse_strong:
   917   fixes f :: "'a::{euclidean_space,real_normed_field} \<Rightarrow> 'a"
   918   shows "DERIV f x :> f' \<Longrightarrow>
   919          f' \<noteq> 0 \<Longrightarrow>
   920          open s \<Longrightarrow>
   921          x \<in> s \<Longrightarrow>
   922          continuous_on s f \<Longrightarrow>
   923          (\<And>z. z \<in> s \<Longrightarrow> g (f z) = z)
   924          \<Longrightarrow> DERIV g (f x) :> inverse (f')"
   925   unfolding has_field_derivative_def
   926   apply (rule has_derivative_inverse_strong [of s x f g ])
   927   by auto
   928 lemmas has_complex_derivative_inverse_strong = has_field_derivative_inverse_strong
   929 
   930 lemma has_field_derivative_inverse_strong_x:
   931   fixes f :: "'a::{euclidean_space,real_normed_field} \<Rightarrow> 'a"
   932   shows  "DERIV f (g y) :> f' \<Longrightarrow>
   933           f' \<noteq> 0 \<Longrightarrow>
   934           open s \<Longrightarrow>
   935           continuous_on s f \<Longrightarrow>
   936           g y \<in> s \<Longrightarrow> f(g y) = y \<Longrightarrow>
   937           (\<And>z. z \<in> s \<Longrightarrow> g (f z) = z)
   938           \<Longrightarrow> DERIV g y :> inverse (f')"
   939   unfolding has_field_derivative_def
   940   apply (rule has_derivative_inverse_strong_x [of s g y f])
   941   by auto
   942 lemmas has_complex_derivative_inverse_strong_x = has_field_derivative_inverse_strong_x
   943 
   944 subsection \<open>Taylor on Complex Numbers\<close>
   945 
   946 lemma sum_Suc_reindex:
   947   fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   948     shows  "sum f {0..n} = f 0 - f (Suc n) + sum (\<lambda>i. f (Suc i)) {0..n}"
   949 by (induct n) auto
   950 
   951 lemma field_taylor:
   952   assumes s: "convex s"
   953       and f: "\<And>i x. x \<in> s \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within s)"
   954       and B: "\<And>x. x \<in> s \<Longrightarrow> norm (f (Suc n) x) \<le> B"
   955       and w: "w \<in> s"
   956       and z: "z \<in> s"
   957     shows "norm(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
   958           \<le> B * norm(z - w)^(Suc n) / fact n"
   959 proof -
   960   have wzs: "closed_segment w z \<subseteq> s" using assms
   961     by (metis convex_contains_segment)
   962   { fix u
   963     assume "u \<in> closed_segment w z"
   964     then have "u \<in> s"
   965       by (metis wzs subsetD)
   966     have "(\<Sum>i\<le>n. f i u * (- of_nat i * (z-u)^(i - 1)) / (fact i) +
   967                       f (Suc i) u * (z-u)^i / (fact i)) =
   968               f (Suc n) u * (z-u) ^ n / (fact n)"
   969     proof (induction n)
   970       case 0 show ?case by simp
   971     next
   972       case (Suc n)
   973       have "(\<Sum>i\<le>Suc n. f i u * (- of_nat i * (z-u) ^ (i - 1)) / (fact i) +
   974                              f (Suc i) u * (z-u) ^ i / (fact i)) =
   975            f (Suc n) u * (z-u) ^ n / (fact n) +
   976            f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n) / (fact (Suc n)) -
   977            f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n) / (fact (Suc n))"
   978         using Suc by simp
   979       also have "... = f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n))"
   980       proof -
   981         have "(fact(Suc n)) *
   982              (f(Suc n) u *(z-u) ^ n / (fact n) +
   983                f(Suc(Suc n)) u *((z-u) *(z-u) ^ n) / (fact(Suc n)) -
   984                f(Suc n) u *((1 + of_nat n) *(z-u) ^ n) / (fact(Suc n))) =
   985             ((fact(Suc n)) *(f(Suc n) u *(z-u) ^ n)) / (fact n) +
   986             ((fact(Suc n)) *(f(Suc(Suc n)) u *((z-u) *(z-u) ^ n)) / (fact(Suc n))) -
   987             ((fact(Suc n)) *(f(Suc n) u *(of_nat(Suc n) *(z-u) ^ n))) / (fact(Suc n))"
   988           by (simp add: algebra_simps del: fact_Suc)
   989         also have "... = ((fact (Suc n)) * (f (Suc n) u * (z-u) ^ n)) / (fact n) +
   990                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
   991                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
   992           by (simp del: fact_Suc)
   993         also have "... = (of_nat (Suc n) * (f (Suc n) u * (z-u) ^ n)) +
   994                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
   995                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
   996           by (simp only: fact_Suc of_nat_mult ac_simps) simp
   997         also have "... = f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)"
   998           by (simp add: algebra_simps)
   999         finally show ?thesis
  1000         by (simp add: mult_left_cancel [where c = "(fact (Suc n))", THEN iffD1] del: fact_Suc)
  1001       qed
  1002       finally show ?case .
  1003     qed
  1004     then have "((\<lambda>v. (\<Sum>i\<le>n. f i v * (z - v)^i / (fact i)))
  1005                 has_field_derivative f (Suc n) u * (z-u) ^ n / (fact n))
  1006                (at u within s)"
  1007       apply (intro derivative_eq_intros)
  1008       apply (blast intro: assms \<open>u \<in> s\<close>)
  1009       apply (rule refl)+
  1010       apply (auto simp: field_simps)
  1011       done
  1012   } note sum_deriv = this
  1013   { fix u
  1014     assume u: "u \<in> closed_segment w z"
  1015     then have us: "u \<in> s"
  1016       by (metis wzs subsetD)
  1017     have "norm (f (Suc n) u) * norm (z - u) ^ n \<le> norm (f (Suc n) u) * norm (u - z) ^ n"
  1018       by (metis norm_minus_commute order_refl)
  1019     also have "... \<le> norm (f (Suc n) u) * norm (z - w) ^ n"
  1020       by (metis mult_left_mono norm_ge_zero power_mono segment_bound [OF u])
  1021     also have "... \<le> B * norm (z - w) ^ n"
  1022       by (metis norm_ge_zero zero_le_power mult_right_mono  B [OF us])
  1023     finally have "norm (f (Suc n) u) * norm (z - u) ^ n \<le> B * norm (z - w) ^ n" .
  1024   } note cmod_bound = this
  1025   have "(\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)) = (\<Sum>i\<le>n. (f i z / (fact i)) * 0 ^ i)"
  1026     by simp
  1027   also have "\<dots> = f 0 z / (fact 0)"
  1028     by (subst sum_zero_power) simp
  1029   finally have "norm (f 0 z - (\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)))
  1030                 \<le> norm ((\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)) -
  1031                         (\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)))"
  1032     by (simp add: norm_minus_commute)
  1033   also have "... \<le> B * norm (z - w) ^ n / (fact n) * norm (w - z)"
  1034     apply (rule field_differentiable_bound
  1035       [where f' = "\<lambda>w. f (Suc n) w * (z - w)^n / (fact n)"
  1036          and s = "closed_segment w z", OF convex_closed_segment])
  1037     apply (auto simp: ends_in_segment DERIV_subset [OF sum_deriv wzs]
  1038                   norm_divide norm_mult norm_power divide_le_cancel cmod_bound)
  1039     done
  1040   also have "...  \<le> B * norm (z - w) ^ Suc n / (fact n)"
  1041     by (simp add: algebra_simps norm_minus_commute)
  1042   finally show ?thesis .
  1043 qed
  1044 
  1045 lemma complex_taylor:
  1046   assumes s: "convex s"
  1047       and f: "\<And>i x. x \<in> s \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within s)"
  1048       and B: "\<And>x. x \<in> s \<Longrightarrow> cmod (f (Suc n) x) \<le> B"
  1049       and w: "w \<in> s"
  1050       and z: "z \<in> s"
  1051     shows "cmod(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
  1052           \<le> B * cmod(z - w)^(Suc n) / fact n"
  1053   using assms by (rule field_taylor)
  1054 
  1055 
  1056 text\<open>Something more like the traditional MVT for real components\<close>
  1057 
  1058 lemma complex_mvt_line:
  1059   assumes "\<And>u. u \<in> closed_segment w z \<Longrightarrow> (f has_field_derivative f'(u)) (at u)"
  1060     shows "\<exists>u. u \<in> closed_segment w z \<and> Re(f z) - Re(f w) = Re(f'(u) * (z - w))"
  1061 proof -
  1062   have twz: "\<And>t. (1 - t) *\<^sub>R w + t *\<^sub>R z = w + t *\<^sub>R (z - w)"
  1063     by (simp add: real_vector.scale_left_diff_distrib real_vector.scale_right_diff_distrib)
  1064   note assms[unfolded has_field_derivative_def, derivative_intros]
  1065   show ?thesis
  1066     apply (cut_tac mvt_simple
  1067                      [of 0 1 "Re o f o (\<lambda>t. (1 - t) *\<^sub>R w +  t *\<^sub>R z)"
  1068                       "\<lambda>u. Re o (\<lambda>h. f'((1 - u) *\<^sub>R w + u *\<^sub>R z) * h) o (\<lambda>t. t *\<^sub>R (z - w))"])
  1069     apply auto
  1070     apply (rule_tac x="(1 - x) *\<^sub>R w + x *\<^sub>R z" in exI)
  1071     apply (auto simp: closed_segment_def twz) []
  1072     apply (intro derivative_eq_intros has_derivative_at_within, simp_all)
  1073     apply (simp add: fun_eq_iff real_vector.scale_right_diff_distrib)
  1074     apply (force simp: twz closed_segment_def)
  1075     done
  1076 qed
  1077 
  1078 lemma complex_taylor_mvt:
  1079   assumes "\<And>i x. \<lbrakk>x \<in> closed_segment w z; i \<le> n\<rbrakk> \<Longrightarrow> ((f i) has_field_derivative f (Suc i) x) (at x)"
  1080     shows "\<exists>u. u \<in> closed_segment w z \<and>
  1081             Re (f 0 z) =
  1082             Re ((\<Sum>i = 0..n. f i w * (z - w) ^ i / (fact i)) +
  1083                 (f (Suc n) u * (z-u)^n / (fact n)) * (z - w))"
  1084 proof -
  1085   { fix u
  1086     assume u: "u \<in> closed_segment w z"
  1087     have "(\<Sum>i = 0..n.
  1088                (f (Suc i) u * (z-u) ^ i - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) /
  1089                (fact i)) =
  1090           f (Suc 0) u -
  1091              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1092              (fact (Suc n)) +
  1093              (\<Sum>i = 0..n.
  1094                  (f (Suc (Suc i)) u * ((z-u) ^ Suc i) - of_nat (Suc i) * (f (Suc i) u * (z-u) ^ i)) /
  1095                  (fact (Suc i)))"
  1096        by (subst sum_Suc_reindex) simp
  1097     also have "... = f (Suc 0) u -
  1098              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1099              (fact (Suc n)) +
  1100              (\<Sum>i = 0..n.
  1101                  f (Suc (Suc i)) u * ((z-u) ^ Suc i) / (fact (Suc i))  -
  1102                  f (Suc i) u * (z-u) ^ i / (fact i))"
  1103       by (simp only: diff_divide_distrib fact_cancel ac_simps)
  1104     also have "... = f (Suc 0) u -
  1105              (f (Suc (Suc n)) u * (z-u) ^ Suc n - of_nat (Suc n) * (z-u) ^ n * f (Suc n) u) /
  1106              (fact (Suc n)) +
  1107              f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n)) - f (Suc 0) u"
  1108       by (subst sum_Suc_diff) auto
  1109     also have "... = f (Suc n) u * (z-u) ^ n / (fact n)"
  1110       by (simp only: algebra_simps diff_divide_distrib fact_cancel)
  1111     finally have "(\<Sum>i = 0..n. (f (Suc i) u * (z - u) ^ i
  1112                              - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) / (fact i)) =
  1113                   f (Suc n) u * (z - u) ^ n / (fact n)" .
  1114     then have "((\<lambda>u. \<Sum>i = 0..n. f i u * (z - u) ^ i / (fact i)) has_field_derivative
  1115                 f (Suc n) u * (z - u) ^ n / (fact n))  (at u)"
  1116       apply (intro derivative_eq_intros)+
  1117       apply (force intro: u assms)
  1118       apply (rule refl)+
  1119       apply (auto simp: ac_simps)
  1120       done
  1121   }
  1122   then show ?thesis
  1123     apply (cut_tac complex_mvt_line [of w z "\<lambda>u. \<Sum>i = 0..n. f i u * (z-u) ^ i / (fact i)"
  1124                "\<lambda>u. (f (Suc n) u * (z-u)^n / (fact n))"])
  1125     apply (auto simp add: intro: open_closed_segment)
  1126     done
  1127 qed
  1128 
  1129 
  1130 subsection \<open>Polynomal function extremal theorem, from HOL Light\<close>
  1131 
  1132 lemma polyfun_extremal_lemma: (*COMPLEX_POLYFUN_EXTREMAL_LEMMA in HOL Light*)
  1133     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1134   assumes "0 < e"
  1135     shows "\<exists>M. \<forall>z. M \<le> norm(z) \<longrightarrow> norm (\<Sum>i\<le>n. c(i) * z^i) \<le> e * norm(z) ^ (Suc n)"
  1136 proof (induct n)
  1137   case 0 with assms
  1138   show ?case
  1139     apply (rule_tac x="norm (c 0) / e" in exI)
  1140     apply (auto simp: field_simps)
  1141     done
  1142 next
  1143   case (Suc n)
  1144   obtain M where M: "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1145     using Suc assms by blast
  1146   show ?case
  1147   proof (rule exI [where x= "max M (1 + norm(c(Suc n)) / e)"], clarsimp simp del: power_Suc)
  1148     fix z::'a
  1149     assume z1: "M \<le> norm z" and "1 + norm (c (Suc n)) / e \<le> norm z"
  1150     then have z2: "e + norm (c (Suc n)) \<le> e * norm z"
  1151       using assms by (simp add: field_simps)
  1152     have "norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1153       using M [OF z1] by simp
  1154     then have "norm (\<Sum>i\<le>n. c i * z^i) + norm (c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1155       by simp
  1156     then have "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1157       by (blast intro: norm_triangle_le elim: )
  1158     also have "... \<le> (e + norm (c (Suc n))) * norm z ^ Suc n"
  1159       by (simp add: norm_power norm_mult algebra_simps)
  1160     also have "... \<le> (e * norm z) * norm z ^ Suc n"
  1161       by (metis z2 mult.commute mult_left_mono norm_ge_zero norm_power)
  1162     finally show "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc (Suc n)"
  1163       by simp
  1164   qed
  1165 qed
  1166 
  1167 lemma polyfun_extremal: (*COMPLEX_POLYFUN_EXTREMAL in HOL Light*)
  1168     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1169   assumes k: "c k \<noteq> 0" "1\<le>k" and kn: "k\<le>n"
  1170     shows "eventually (\<lambda>z. norm (\<Sum>i\<le>n. c(i) * z^i) \<ge> B) at_infinity"
  1171 using kn
  1172 proof (induction n)
  1173   case 0
  1174   then show ?case
  1175     using k  by simp
  1176 next
  1177   case (Suc m)
  1178   let ?even = ?case
  1179   show ?even
  1180   proof (cases "c (Suc m) = 0")
  1181     case True
  1182     then show ?even using Suc k
  1183       by auto (metis antisym_conv less_eq_Suc_le not_le)
  1184   next
  1185     case False
  1186     then obtain M where M:
  1187           "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>m. c i * z^i) \<le> norm (c (Suc m)) / 2 * norm z ^ Suc m"
  1188       using polyfun_extremal_lemma [of "norm(c (Suc m)) / 2" c m] Suc
  1189       by auto
  1190     have "\<exists>b. \<forall>z. b \<le> norm z \<longrightarrow> B \<le> norm (\<Sum>i\<le>Suc m. c i * z^i)"
  1191     proof (rule exI [where x="max M (max 1 (\<bar>B\<bar> / (norm(c (Suc m)) / 2)))"], clarsimp simp del: power_Suc)
  1192       fix z::'a
  1193       assume z1: "M \<le> norm z" "1 \<le> norm z"
  1194          and "\<bar>B\<bar> * 2 / norm (c (Suc m)) \<le> norm z"
  1195       then have z2: "\<bar>B\<bar> \<le> norm (c (Suc m)) * norm z / 2"
  1196         using False by (simp add: field_simps)
  1197       have nz: "norm z \<le> norm z ^ Suc m"
  1198         by (metis \<open>1 \<le> norm z\<close> One_nat_def less_eq_Suc_le power_increasing power_one_right zero_less_Suc)
  1199       have *: "\<And>y x. norm (c (Suc m)) * norm z / 2 \<le> norm y - norm x \<Longrightarrow> B \<le> norm (x + y)"
  1200         by (metis abs_le_iff add.commute norm_diff_ineq order_trans z2)
  1201       have "norm z * norm (c (Suc m)) + 2 * norm (\<Sum>i\<le>m. c i * z^i)
  1202             \<le> norm (c (Suc m)) * norm z + norm (c (Suc m)) * norm z ^ Suc m"
  1203         using M [of z] Suc z1  by auto
  1204       also have "... \<le> 2 * (norm (c (Suc m)) * norm z ^ Suc m)"
  1205         using nz by (simp add: mult_mono del: power_Suc)
  1206       finally show "B \<le> norm ((\<Sum>i\<le>m. c i * z^i) + c (Suc m) * z ^ Suc m)"
  1207         using Suc.IH
  1208         apply (auto simp: eventually_at_infinity)
  1209         apply (rule *)
  1210         apply (simp add: field_simps norm_mult norm_power)
  1211         done
  1212     qed
  1213     then show ?even
  1214       by (simp add: eventually_at_infinity)
  1215   qed
  1216 qed
  1217 
  1218 end