src/HOL/Number_Theory/Residues.thy
author wenzelm
Fri Aug 18 20:47:47 2017 +0200 (23 months ago)
changeset 66453 cc19f7ca2ed6
parent 66305 7454317f883c
child 66817 0b12755ccbb2
permissions -rw-r--r--
session-qualified theory imports: isabelle imports -U -i -d '~~/src/Benchmarks' -a;
     1 (*  Title:      HOL/Number_Theory/Residues.thy
     2     Author:     Jeremy Avigad
     3 
     4 An algebraic treatment of residue rings, and resulting proofs of
     5 Euler's theorem and Wilson's theorem.
     6 *)
     7 
     8 section \<open>Residue rings\<close>
     9 
    10 theory Residues
    11 imports
    12   Cong
    13   "HOL-Algebra.More_Group"
    14   "HOL-Algebra.More_Ring"
    15   "HOL-Algebra.More_Finite_Product"
    16   "HOL-Algebra.Multiplicative_Group"
    17   Totient
    18 begin
    19 
    20 definition QuadRes :: "int \<Rightarrow> int \<Rightarrow> bool"
    21   where "QuadRes p a = (\<exists>y. ([y^2 = a] (mod p)))"
    22 
    23 definition Legendre :: "int \<Rightarrow> int \<Rightarrow> int"
    24   where "Legendre a p =
    25     (if ([a = 0] (mod p)) then 0
    26      else if QuadRes p a then 1
    27      else -1)"
    28 
    29 
    30 subsection \<open>A locale for residue rings\<close>
    31 
    32 definition residue_ring :: "int \<Rightarrow> int ring"
    33   where
    34     "residue_ring m =
    35       \<lparr>carrier = {0..m - 1},
    36        monoid.mult = \<lambda>x y. (x * y) mod m,
    37        one = 1,
    38        zero = 0,
    39        add = \<lambda>x y. (x + y) mod m\<rparr>"
    40 
    41 locale residues =
    42   fixes m :: int and R (structure)
    43   assumes m_gt_one: "m > 1"
    44   defines "R \<equiv> residue_ring m"
    45 begin
    46 
    47 lemma abelian_group: "abelian_group R"
    48 proof -
    49   have "\<exists>y\<in>{0..m - 1}. (x + y) mod m = 0" if "0 \<le> x" "x < m" for x
    50   proof (cases "x = 0")
    51     case True
    52     with m_gt_one show ?thesis by simp
    53   next
    54     case False
    55     then have "(x + (m - x)) mod m = 0"
    56       by simp
    57     with m_gt_one that show ?thesis
    58       by (metis False atLeastAtMost_iff diff_ge_0_iff_ge diff_left_mono int_one_le_iff_zero_less less_le)
    59   qed
    60   with m_gt_one show ?thesis
    61     by (fastforce simp add: R_def residue_ring_def mod_add_right_eq ac_simps  intro!: abelian_groupI)
    62 qed
    63 
    64 lemma comm_monoid: "comm_monoid R"
    65   unfolding R_def residue_ring_def
    66   apply (rule comm_monoidI)
    67     using m_gt_one  apply auto
    68   apply (metis mod_mult_right_eq mult.assoc mult.commute)
    69   apply (metis mult.commute)
    70   done
    71 
    72 lemma cring: "cring R"
    73   apply (intro cringI abelian_group comm_monoid)
    74   unfolding R_def residue_ring_def
    75   apply (auto simp add: comm_semiring_class.distrib mod_add_eq mod_mult_left_eq)
    76   done
    77 
    78 end
    79 
    80 sublocale residues < cring
    81   by (rule cring)
    82 
    83 
    84 context residues
    85 begin
    86 
    87 text \<open>
    88   These lemmas translate back and forth between internal and
    89   external concepts.
    90 \<close>
    91 
    92 lemma res_carrier_eq: "carrier R = {0..m - 1}"
    93   by (auto simp: R_def residue_ring_def)
    94 
    95 lemma res_add_eq: "x \<oplus> y = (x + y) mod m"
    96   by (auto simp: R_def residue_ring_def)
    97 
    98 lemma res_mult_eq: "x \<otimes> y = (x * y) mod m"
    99   by (auto simp: R_def residue_ring_def)
   100 
   101 lemma res_zero_eq: "\<zero> = 0"
   102   by (auto simp: R_def residue_ring_def)
   103 
   104 lemma res_one_eq: "\<one> = 1"
   105   by (auto simp: R_def residue_ring_def units_of_def)
   106 
   107 lemma res_units_eq: "Units R = {x. 0 < x \<and> x < m \<and> coprime x m}"
   108   using m_gt_one
   109   unfolding Units_def R_def residue_ring_def
   110   apply auto
   111     apply (subgoal_tac "x \<noteq> 0")
   112      apply auto
   113    apply (metis invertible_coprime_int)
   114   apply (subst (asm) coprime_iff_invertible'_int)
   115    apply (auto simp add: cong_int_def mult.commute)
   116   done
   117 
   118 lemma res_neg_eq: "\<ominus> x = (- x) mod m"
   119   using m_gt_one unfolding R_def a_inv_def m_inv_def residue_ring_def
   120   apply simp
   121   apply (rule the_equality)
   122    apply (simp add: mod_add_right_eq)
   123    apply (simp add: add.commute mod_add_right_eq)
   124   apply (metis add.right_neutral minus_add_cancel mod_add_right_eq mod_pos_pos_trivial)
   125   done
   126 
   127 lemma finite [iff]: "finite (carrier R)"
   128   by (simp add: res_carrier_eq)
   129 
   130 lemma finite_Units [iff]: "finite (Units R)"
   131   by (simp add: finite_ring_finite_units)
   132 
   133 text \<open>
   134   The function \<open>a \<mapsto> a mod m\<close> maps the integers to the
   135   residue classes. The following lemmas show that this mapping
   136   respects addition and multiplication on the integers.
   137 \<close>
   138 
   139 lemma mod_in_carrier [iff]: "a mod m \<in> carrier R"
   140   unfolding res_carrier_eq
   141   using insert m_gt_one by auto
   142 
   143 lemma add_cong: "(x mod m) \<oplus> (y mod m) = (x + y) mod m"
   144   by (auto simp: R_def residue_ring_def mod_simps)
   145 
   146 lemma mult_cong: "(x mod m) \<otimes> (y mod m) = (x * y) mod m"
   147   by (auto simp: R_def residue_ring_def mod_simps)
   148 
   149 lemma zero_cong: "\<zero> = 0"
   150   by (auto simp: R_def residue_ring_def)
   151 
   152 lemma one_cong: "\<one> = 1 mod m"
   153   using m_gt_one by (auto simp: R_def residue_ring_def)
   154 
   155 (* FIXME revise algebra library to use 1? *)
   156 lemma pow_cong: "(x mod m) (^) n = x^n mod m"
   157   using m_gt_one
   158   apply (induct n)
   159   apply (auto simp add: nat_pow_def one_cong)
   160   apply (metis mult.commute mult_cong)
   161   done
   162 
   163 lemma neg_cong: "\<ominus> (x mod m) = (- x) mod m"
   164   by (metis mod_minus_eq res_neg_eq)
   165 
   166 lemma (in residues) prod_cong: "finite A \<Longrightarrow> (\<Otimes>i\<in>A. (f i) mod m) = (\<Prod>i\<in>A. f i) mod m"
   167   by (induct set: finite) (auto simp: one_cong mult_cong)
   168 
   169 lemma (in residues) sum_cong: "finite A \<Longrightarrow> (\<Oplus>i\<in>A. (f i) mod m) = (\<Sum>i\<in>A. f i) mod m"
   170   by (induct set: finite) (auto simp: zero_cong add_cong)
   171 
   172 lemma mod_in_res_units [simp]:
   173   assumes "1 < m" and "coprime a m"
   174   shows "a mod m \<in> Units R"
   175 proof (cases "a mod m = 0")
   176   case True
   177   with assms show ?thesis
   178     by (auto simp add: res_units_eq gcd_red_int [symmetric])
   179 next
   180   case False
   181   from assms have "0 < m" by simp
   182   then have "0 \<le> a mod m" by (rule pos_mod_sign [of m a])
   183   with False have "0 < a mod m" by simp
   184   with assms show ?thesis
   185     by (auto simp add: res_units_eq gcd_red_int [symmetric] ac_simps)
   186 qed
   187 
   188 lemma res_eq_to_cong: "(a mod m) = (b mod m) \<longleftrightarrow> [a = b] (mod m)"
   189   by (auto simp: cong_int_def)
   190 
   191 
   192 text \<open>Simplifying with these will translate a ring equation in R to a congruence.\<close>
   193 lemmas res_to_cong_simps =
   194   add_cong mult_cong pow_cong one_cong
   195   prod_cong sum_cong neg_cong res_eq_to_cong
   196 
   197 text \<open>Other useful facts about the residue ring.\<close>
   198 lemma one_eq_neg_one: "\<one> = \<ominus> \<one> \<Longrightarrow> m = 2"
   199   apply (simp add: res_one_eq res_neg_eq)
   200   apply (metis add.commute add_diff_cancel mod_mod_trivial one_add_one uminus_add_conv_diff
   201     zero_neq_one zmod_zminus1_eq_if)
   202   done
   203 
   204 end
   205 
   206 
   207 subsection \<open>Prime residues\<close>
   208 
   209 locale residues_prime =
   210   fixes p :: nat and R (structure)
   211   assumes p_prime [intro]: "prime p"
   212   defines "R \<equiv> residue_ring (int p)"
   213 
   214 sublocale residues_prime < residues p
   215   unfolding R_def residues_def
   216   using p_prime apply auto
   217   apply (metis (full_types) of_nat_1 of_nat_less_iff prime_gt_1_nat)
   218   done
   219 
   220 context residues_prime
   221 begin
   222 
   223 lemma is_field: "field R"
   224 proof -
   225   have "gcd x (int p) \<noteq> 1 \<Longrightarrow> 0 \<le> x \<Longrightarrow> x < int p \<Longrightarrow> x = 0" for x
   226     by (metis dual_order.order_iff_strict gcd.commute less_le_not_le p_prime prime_imp_coprime prime_nat_int_transfer zdvd_imp_le)
   227   then show ?thesis
   228     apply (intro cring.field_intro2 cring)
   229      apply (auto simp add: res_carrier_eq res_one_eq res_zero_eq res_units_eq)
   230     done
   231 qed
   232 
   233 lemma res_prime_units_eq: "Units R = {1..p - 1}"
   234   apply (subst res_units_eq)
   235   apply auto
   236   apply (subst gcd.commute)
   237   apply (auto simp add: p_prime prime_imp_coprime_int zdvd_not_zless)
   238   done
   239 
   240 end
   241 
   242 sublocale residues_prime < field
   243   by (rule is_field)
   244 
   245 
   246 section \<open>Test cases: Euler's theorem and Wilson's theorem\<close>
   247 
   248 subsection \<open>Euler's theorem\<close>
   249 
   250 lemma (in residues) totient_eq: "totient (nat m) = card (Units R)"
   251 proof -
   252   have *: "inj_on nat (Units R)"
   253     by (rule inj_onI) (auto simp add: res_units_eq)
   254   define m' where "m' = nat m"
   255   from m_gt_one have "m = int m'" "m' > 1"
   256     by (simp_all add: m'_def)
   257   then have "x \<in> Units R \<longleftrightarrow> x \<in> int ` totatives m'" for x
   258     unfolding res_units_eq
   259     by (cases x; cases "x = m") (auto simp: totatives_def transfer_int_nat_gcd)
   260   then have "Units R = int ` totatives m'"
   261     by blast
   262   then have "totatives m' = nat ` Units R"
   263     by (simp add: image_image)
   264   then have "card (totatives (nat m)) = card (nat ` Units R)"
   265     by (simp add: m'_def)
   266   also have "\<dots> = card (Units R)"
   267     using * card_image [of nat "Units R"] by auto
   268   finally show ?thesis
   269     by (simp add: totient_def)
   270 qed
   271 
   272 lemma (in residues_prime) totient_eq: "totient p = p - 1"
   273   using totient_eq by (simp add: res_prime_units_eq)
   274 
   275 lemma (in residues) euler_theorem:
   276   assumes "coprime a m"
   277   shows "[a ^ totient (nat m) = 1] (mod m)"
   278 proof -
   279   have "a ^ totient (nat m) mod m = 1 mod m"
   280     by (metis assms finite_Units m_gt_one mod_in_res_units one_cong totient_eq pow_cong units_power_order_eq_one)
   281   then show ?thesis
   282     using res_eq_to_cong by blast
   283 qed
   284 
   285 lemma euler_theorem:
   286   fixes a m :: nat
   287   assumes "coprime a m"
   288   shows "[a ^ totient m = 1] (mod m)"
   289 proof (cases "m = 0 | m = 1")
   290   case True
   291   then show ?thesis by auto
   292 next
   293   case False
   294   with assms show ?thesis
   295     using residues.euler_theorem [of "int m" "int a"] transfer_int_nat_cong
   296     by (auto simp add: residues_def transfer_int_nat_gcd(1)) force
   297 qed
   298 
   299 lemma fermat_theorem:
   300   fixes p a :: nat
   301   assumes "prime p" and "\<not> p dvd a"
   302   shows "[a ^ (p - 1) = 1] (mod p)"
   303 proof -
   304   from assms prime_imp_coprime [of p a] have "coprime a p"
   305     by (auto simp add: ac_simps)
   306   then have "[a ^ totient p = 1] (mod p)"
   307      by (rule euler_theorem)
   308   also have "totient p = p - 1"
   309     by (rule totient_prime) (rule assms)
   310   finally show ?thesis .
   311 qed
   312 
   313 
   314 subsection \<open>Wilson's theorem\<close>
   315 
   316 lemma (in field) inv_pair_lemma: "x \<in> Units R \<Longrightarrow> y \<in> Units R \<Longrightarrow>
   317     {x, inv x} \<noteq> {y, inv y} \<Longrightarrow> {x, inv x} \<inter> {y, inv y} = {}"
   318   apply auto
   319   apply (metis Units_inv_inv)+
   320   done
   321 
   322 lemma (in residues_prime) wilson_theorem1:
   323   assumes a: "p > 2"
   324   shows "[fact (p - 1) = (-1::int)] (mod p)"
   325 proof -
   326   let ?Inverse_Pairs = "{{x, inv x}| x. x \<in> Units R - {\<one>, \<ominus> \<one>}}"
   327   have UR: "Units R = {\<one>, \<ominus> \<one>} \<union> \<Union>?Inverse_Pairs"
   328     by auto
   329   have "(\<Otimes>i\<in>Units R. i) = (\<Otimes>i\<in>{\<one>, \<ominus> \<one>}. i) \<otimes> (\<Otimes>i\<in>\<Union>?Inverse_Pairs. i)"
   330     apply (subst UR)
   331     apply (subst finprod_Un_disjoint)
   332          apply (auto intro: funcsetI)
   333     using inv_one apply auto[1]
   334     using inv_eq_neg_one_eq apply auto
   335     done
   336   also have "(\<Otimes>i\<in>{\<one>, \<ominus> \<one>}. i) = \<ominus> \<one>"
   337     apply (subst finprod_insert)
   338         apply auto
   339     apply (frule one_eq_neg_one)
   340     using a apply force
   341     done
   342   also have "(\<Otimes>i\<in>(\<Union>?Inverse_Pairs). i) = (\<Otimes>A\<in>?Inverse_Pairs. (\<Otimes>y\<in>A. y))"
   343     apply (subst finprod_Union_disjoint)
   344        apply auto
   345      apply (metis Units_inv_inv)+
   346     done
   347   also have "\<dots> = \<one>"
   348     apply (rule finprod_one)
   349      apply auto
   350     apply (subst finprod_insert)
   351         apply auto
   352     apply (metis inv_eq_self)
   353     done
   354   finally have "(\<Otimes>i\<in>Units R. i) = \<ominus> \<one>"
   355     by simp
   356   also have "(\<Otimes>i\<in>Units R. i) = (\<Otimes>i\<in>Units R. i mod p)"
   357     by (rule finprod_cong') (auto simp: res_units_eq)
   358   also have "\<dots> = (\<Prod>i\<in>Units R. i) mod p"
   359     by (rule prod_cong) auto
   360   also have "\<dots> = fact (p - 1) mod p"
   361     apply (simp add: fact_prod)
   362     using assms
   363     apply (subst res_prime_units_eq)
   364     apply (simp add: int_prod zmod_int prod_int_eq)
   365     done
   366   finally have "fact (p - 1) mod p = \<ominus> \<one>" .
   367   then show ?thesis
   368     by (metis of_nat_fact Divides.transfer_int_nat_functions(2)
   369         cong_int_def res_neg_eq res_one_eq)
   370 qed
   371 
   372 lemma wilson_theorem:
   373   assumes "prime p"
   374   shows "[fact (p - 1) = - 1] (mod p)"
   375 proof (cases "p = 2")
   376   case True
   377   then show ?thesis
   378     by (simp add: cong_int_def fact_prod)
   379 next
   380   case False
   381   then show ?thesis
   382     using assms prime_ge_2_nat
   383     by (metis residues_prime.wilson_theorem1 residues_prime.intro le_eq_less_or_eq)
   384 qed
   385 
   386 text \<open>
   387   This result can be transferred to the multiplicative group of
   388   \<open>\<int>/p\<int>\<close> for \<open>p\<close> prime.\<close>
   389 
   390 lemma mod_nat_int_pow_eq:
   391   fixes n :: nat and p a :: int
   392   shows "a \<ge> 0 \<Longrightarrow> p \<ge> 0 \<Longrightarrow> (nat a ^ n) mod (nat p) = nat ((a ^ n) mod p)"
   393   by (simp add: int_one_le_iff_zero_less nat_mod_distrib order_less_imp_le nat_power_eq[symmetric])
   394 
   395 theorem residue_prime_mult_group_has_gen :
   396  fixes p :: nat
   397  assumes prime_p : "prime p"
   398  shows "\<exists>a \<in> {1 .. p - 1}. {1 .. p - 1} = {a^i mod p|i . i \<in> UNIV}"
   399 proof -
   400   have "p \<ge> 2"
   401     using prime_gt_1_nat[OF prime_p] by simp
   402   interpret R: residues_prime p "residue_ring p"
   403     by (simp add: residues_prime_def prime_p)
   404   have car: "carrier (residue_ring (int p)) - {\<zero>\<^bsub>residue_ring (int p)\<^esub>} = {1 .. int p - 1}"
   405     by (auto simp add: R.zero_cong R.res_carrier_eq)
   406 
   407   have "x (^)\<^bsub>residue_ring (int p)\<^esub> i = x ^ i mod (int p)"
   408     if "x \<in> {1 .. int p - 1}" for x and i :: nat
   409     using that R.pow_cong[of x i] by auto
   410   moreover
   411   obtain a where a: "a \<in> {1 .. int p - 1}"
   412     and a_gen: "{1 .. int p - 1} = {a(^)\<^bsub>residue_ring (int p)\<^esub>i|i::nat . i \<in> UNIV}"
   413     using field.finite_field_mult_group_has_gen[OF R.is_field]
   414     by (auto simp add: car[symmetric] carrier_mult_of)
   415   moreover
   416   have "nat ` {1 .. int p - 1} = {1 .. p - 1}" (is "?L = ?R")
   417   proof
   418     have "n \<in> ?R" if "n \<in> ?L" for n
   419       using that \<open>p\<ge>2\<close> by force
   420     then show "?L \<subseteq> ?R" by blast
   421     have "n \<in> ?L" if "n \<in> ?R" for n
   422       using that \<open>p\<ge>2\<close> Set_Interval.transfer_nat_int_set_functions(2) by fastforce
   423     then show "?R \<subseteq> ?L" by blast
   424   qed
   425   moreover
   426   have "nat ` {a^i mod (int p) | i::nat. i \<in> UNIV} = {nat a^i mod p | i . i \<in> UNIV}" (is "?L = ?R")
   427   proof
   428     have "x \<in> ?R" if "x \<in> ?L" for x
   429     proof -
   430       from that obtain i where i: "x = nat (a^i mod (int p))"
   431         by blast
   432       then have "x = nat a ^ i mod p"
   433         using mod_nat_int_pow_eq[of a "int p" i] a \<open>p\<ge>2\<close> by auto
   434       with i show ?thesis by blast
   435     qed
   436     then show "?L \<subseteq> ?R" by blast
   437     have "x \<in> ?L" if "x \<in> ?R" for x
   438     proof -
   439       from that obtain i where i: "x = nat a^i mod p"
   440         by blast
   441       with mod_nat_int_pow_eq[of a "int p" i] a \<open>p\<ge>2\<close> show ?thesis
   442         by auto
   443     qed
   444     then show "?R \<subseteq> ?L" by blast
   445   qed
   446   ultimately have "{1 .. p - 1} = {nat a^i mod p | i. i \<in> UNIV}"
   447     by presburger
   448   moreover from a have "nat a \<in> {1 .. p - 1}" by force
   449   ultimately show ?thesis ..
   450 qed
   451 
   452 end