src/Pure/axclass.ML
author haftmann
Fri Mar 02 15:43:16 2007 +0100 (2007-03-02)
changeset 22385 cc2be3315e72
parent 21953 ab834c5c3858
child 22570 f166a5416b3f
permissions -rw-r--r--
syntax for "class attach const"
     1 (*  Title:      Pure/axclass.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Type classes as parameter records and predicates, with explicit
     6 definitions and proofs.
     7 *)
     8 
     9 signature AX_CLASS =
    10 sig
    11   val get_definition: theory -> class -> {def: thm, intro: thm, axioms: thm list,
    12     params: (string * typ) list}
    13   val class_intros: theory -> thm list
    14   val class_of_param: theory -> string -> class option
    15   val params_of_class: theory -> class -> string * (string * typ) list
    16   val param_tyvarname: string
    17   val print_axclasses: theory -> unit
    18   val cert_classrel: theory -> class * class -> class * class
    19   val read_classrel: theory -> xstring * xstring -> class * class
    20   val add_classrel: thm -> theory -> theory
    21   val add_arity: thm -> theory -> theory
    22   val prove_classrel: class * class -> tactic -> theory -> theory
    23   val prove_arity: string * sort list * sort -> tactic -> theory -> theory
    24   val define_class: bstring * xstring list -> string list ->
    25     ((bstring * Attrib.src list) * string list) list -> theory -> class * theory
    26   val define_class_i: bstring * class list -> string list ->
    27     ((bstring * attribute list) * term list) list -> theory -> class * theory
    28   val read_param: theory -> string -> string
    29   val axiomatize_class: bstring * xstring list -> theory -> theory
    30   val axiomatize_class_i: bstring * class list -> theory -> theory
    31   val axiomatize_classrel: (xstring * xstring) list -> theory -> theory
    32   val axiomatize_classrel_i: (class * class) list -> theory -> theory
    33   val axiomatize_arity: xstring * string list * string -> theory -> theory
    34   val axiomatize_arity_i: arity -> theory -> theory
    35   type cache
    36   val cache: cache
    37   val of_sort: theory -> typ * sort -> cache -> thm list * cache  (*exception Sorts.CLASS_ERROR*)
    38 end;
    39 
    40 structure AxClass: AX_CLASS =
    41 struct
    42 
    43 (** theory data **)
    44 
    45 (* class parameters (canonical order) *)
    46 
    47 type param = string * class;
    48 
    49 fun add_param pp ((x, c): param) params =
    50   (case AList.lookup (op =) params x of
    51     NONE => (x, c) :: params
    52   | SOME c' => error ("Duplicate class parameter " ^ quote x ^
    53       " for " ^ Pretty.string_of_sort pp [c] ^
    54       (if c = c' then "" else " and " ^ Pretty.string_of_sort pp [c'])));
    55 
    56 fun merge_params _ ([], qs) = qs
    57   | merge_params pp (ps, qs) =
    58       fold_rev (fn q => if member (op =) ps q then I else add_param pp q) qs ps;
    59 
    60 
    61 (* axclasses *)
    62 
    63 val introN = "intro";
    64 val superN = "super";
    65 val axiomsN = "axioms";
    66 
    67 val param_tyvarname = "'a";
    68 
    69 datatype axclass = AxClass of
    70  {def: thm,
    71   intro: thm,
    72   axioms: thm list,
    73   params: (string * typ) list};
    74 
    75 type axclasses = axclass Symtab.table * param list;
    76 
    77 fun make_axclass ((def, intro, axioms), params) =
    78   AxClass {def = def, intro = intro, axioms = axioms, params = params};
    79 
    80 fun merge_axclasses pp ((tab1, params1), (tab2, params2)) : axclasses =
    81   (Symtab.merge (K true) (tab1, tab2), merge_params pp (params1, params2));
    82 
    83 
    84 (* instances *)
    85 
    86 val classrel_prefix = "classrel_";
    87 val arity_prefix = "arity_";
    88 
    89 type instances =
    90   ((class * class) * thm) list *
    91   ((class * sort list) * thm) list Symtab.table;
    92 
    93 fun merge_instances ((classrel1, arities1): instances, (classrel2, arities2)) =
    94  (merge (eq_fst op =) (classrel1, classrel2),
    95   Symtab.join (K (merge (eq_fst op =))) (arities1, arities2));
    96 
    97 
    98 (* setup data *)
    99 
   100 structure AxClassData = TheoryDataFun
   101 (struct
   102   val name = "Pure/axclass";
   103   type T = axclasses * instances;
   104   val empty : T = ((Symtab.empty, []), ([], Symtab.empty));
   105   val copy = I;
   106   val extend = I;
   107   fun merge pp ((axclasses1, instances1), (axclasses2, instances2)) =
   108     (merge_axclasses pp (axclasses1, axclasses2), (merge_instances (instances1, instances2)));
   109   fun print _ _ = ();
   110 end);
   111 
   112 val _ = Context.add_setup AxClassData.init;
   113 
   114 
   115 (* maintain axclasses *)
   116 
   117 val get_axclasses = #1 o AxClassData.get;
   118 fun map_axclasses f = AxClassData.map (apfst f);
   119 
   120 val lookup_def = Symtab.lookup o #1 o get_axclasses;
   121 
   122 fun get_definition thy c =
   123   (case lookup_def thy c of
   124     SOME (AxClass info) => info
   125   | NONE => error ("No such axclass: " ^ quote c));
   126 
   127 fun class_intros thy =
   128   let
   129     fun add_intro c =
   130       (case lookup_def thy c of SOME (AxClass {intro, ...}) => cons intro | _ => I);
   131     val classes = Sign.all_classes thy;
   132   in map (Thm.class_triv thy) classes @ fold add_intro classes [] end;
   133 
   134 
   135 fun get_params thy pred =
   136   let val params = #2 (get_axclasses thy);
   137   in fold (fn (x, c) => if pred c then cons x else I) params [] end;
   138 
   139 fun params_of thy c = get_params thy (fn c' => c' = c);
   140 fun all_params_of thy S = get_params thy (fn c => Sign.subsort thy (S, [c]));
   141 
   142 fun class_of_param thy =
   143   AList.lookup (op =) (#2 (get_axclasses thy));
   144 
   145 fun params_of_class thy class =
   146   (param_tyvarname, (#params o get_definition thy) class);
   147 
   148 
   149 (* maintain instances *)
   150 
   151 val get_instances = #2 o AxClassData.get;
   152 fun map_instances f = AxClassData.map (apsnd f);
   153 
   154 
   155 fun the_classrel thy (c1, c2) =
   156   (case AList.lookup (op =) (#1 (get_instances thy)) (c1, c2) of
   157     SOME th => Thm.transfer thy th
   158   | NONE => error ("Unproven class relation " ^ Sign.string_of_classrel thy [c1, c2]));
   159 
   160 fun put_classrel arg = map_instances (fn (classrel, arities) =>
   161   (insert (eq_fst op =) arg classrel, arities));
   162 
   163 
   164 fun the_arity thy a (c, Ss) =
   165   (case AList.lookup (op =) (Symtab.lookup_list (#2 (get_instances thy)) a) (c, Ss)  of
   166     SOME th => Thm.transfer thy th
   167   | NONE => error ("Unproven type arity " ^ Sign.string_of_arity thy (a, Ss, [c])));
   168 
   169 fun put_arity ((t, Ss, c), th) = map_instances (fn (classrel, arities) =>
   170   (classrel, arities |> Symtab.insert_list (eq_fst op =) (t, ((c, Ss), th))));
   171 
   172 
   173 (* print data *)
   174 
   175 fun print_axclasses thy =
   176   let
   177     val axclasses = #1 (get_axclasses thy);
   178     val ctxt = ProofContext.init thy;
   179 
   180     fun pretty_axclass (class, AxClass {def, intro, axioms, params}) =
   181       Pretty.block (Pretty.fbreaks
   182        [Pretty.block
   183           [Pretty.str "class ", ProofContext.pretty_sort ctxt [class], Pretty.str ":"],
   184         Pretty.strs ("parameters:" :: params_of thy class),
   185         ProofContext.pretty_fact ctxt ("def", [def]),
   186         ProofContext.pretty_fact ctxt (introN, [intro]),
   187         ProofContext.pretty_fact ctxt (axiomsN, axioms)]);
   188   in Pretty.writeln (Pretty.chunks (map pretty_axclass (Symtab.dest axclasses))) end;
   189 
   190 
   191 
   192 (** instances **)
   193 
   194 (* class relations *)
   195 
   196 fun cert_classrel thy raw_rel =
   197   let
   198     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
   199     val _ = Type.add_classrel (Sign.pp thy) (c1, c2) (Sign.tsig_of thy);
   200     val _ =
   201       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
   202         [] => ()
   203       | xs => raise TYPE ("Class " ^ Sign.string_of_sort thy [c1] ^ " lacks parameter(s) " ^
   204           commas_quote xs ^ " of " ^ Sign.string_of_sort thy [c2], [], []));
   205   in (c1, c2) end;
   206 
   207 fun read_classrel thy raw_rel =
   208   cert_classrel thy (pairself (Sign.read_class thy) raw_rel)
   209     handle TYPE (msg, _, _) => error msg;
   210 
   211 
   212 (* primitive rules *)
   213 
   214 fun add_classrel th thy =
   215   let
   216     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
   217     val prop = Drule.plain_prop_of (Thm.transfer thy th);
   218     val rel = Logic.dest_classrel prop handle TERM _ => err ();
   219     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
   220   in
   221     thy
   222     |> Sign.primitive_classrel (c1, c2)
   223     |> put_classrel ((c1, c2), Drule.unconstrainTs th)
   224   end;
   225 
   226 fun add_arity th thy =
   227   let
   228     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
   229     val prop = Drule.plain_prop_of (Thm.transfer thy th);
   230     val (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
   231     val _ = if map (Sign.certify_sort thy) Ss = Ss then () else err ();
   232   in
   233     thy
   234     |> Sign.primitive_arity (t, Ss, [c])
   235     |> put_arity ((t, Ss, c), Drule.unconstrainTs th)
   236   end;
   237 
   238 
   239 (* tactical proofs *)
   240 
   241 fun prove_classrel raw_rel tac thy =
   242   let
   243     val (c1, c2) = cert_classrel thy raw_rel;
   244     val th = Goal.prove (ProofContext.init thy) [] []
   245         (Logic.mk_classrel (c1, c2)) (fn _ => tac) handle ERROR msg =>
   246       cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
   247         quote (Sign.string_of_classrel thy [c1, c2]));
   248   in
   249     thy
   250     |> PureThy.add_thms [((prefix classrel_prefix (Logic.name_classrel (c1, c2)), th), [])]
   251     |-> (fn [th'] => add_classrel th')
   252   end;
   253 
   254 fun prove_arity raw_arity tac thy =
   255   let
   256     val arity = Sign.cert_arity thy raw_arity;
   257     val names = map (prefix arity_prefix) (Logic.name_arities arity);
   258     val props = Logic.mk_arities arity;
   259     val ths = Goal.prove_multi (ProofContext.init thy) [] [] props
   260       (fn _ => Goal.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
   261         cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
   262           quote (Sign.string_of_arity thy arity));
   263   in
   264     thy
   265     |> PureThy.add_thms (map (rpair []) (names ~~ ths))
   266     |-> fold add_arity
   267   end;
   268 
   269 
   270 
   271 (** class definitions **)
   272 
   273 fun read_param thy raw_t =
   274   let
   275     val t = Sign.read_term thy raw_t
   276   in case try dest_Const t
   277    of SOME (c, _) => c
   278     | NONE => error ("Not a constant: " ^ Sign.string_of_term thy t)
   279   end;
   280 
   281 local
   282 
   283 fun def_class prep_class prep_att prep_param prep_propp
   284     (bclass, raw_super) raw_params raw_specs thy =
   285   let
   286     val ctxt = ProofContext.init thy;
   287     val pp = ProofContext.pp ctxt;
   288 
   289 
   290     (* prepare specification *)
   291 
   292     val bconst = Logic.const_of_class bclass;
   293     val class = Sign.full_name thy bclass;
   294     val super = map (prep_class thy) raw_super |> Sign.certify_sort thy;
   295 
   296     fun prep_axiom t =
   297       (case Term.add_tfrees t [] of
   298         [(a, S)] =>
   299           if Sign.subsort thy (super, S) then t
   300           else error ("Sort constraint of type variable " ^
   301             setmp show_sorts true (Pretty.string_of_typ pp) (TFree (a, S)) ^
   302             " needs to be weaker than " ^ Pretty.string_of_sort pp super)
   303       | [] => t
   304       | _ => error ("Multiple type variables in class axiom:\n" ^ Pretty.string_of_term pp t))
   305       |> map_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
   306       |> Logic.close_form;
   307 
   308     val axiomss = prep_propp (ctxt, map (map (rpair []) o snd) raw_specs)
   309       |> snd |> map (map (prep_axiom o fst));
   310     val name_atts = Attrib.map_specs (prep_att thy) raw_specs |> map fst;
   311 
   312 
   313     (* definition *)
   314 
   315     val conjs = map (curry Logic.mk_inclass (Term.aT [])) super @ flat axiomss;
   316     val class_eq =
   317       Logic.mk_equals (Logic.mk_inclass (Term.aT [], class), Logic.mk_conjunction_list conjs);
   318 
   319     val ([def], def_thy) =
   320       thy
   321       |> Sign.primitive_class (bclass, super)
   322       |> PureThy.add_defs_i false [((Thm.def_name bconst, class_eq), [])];
   323     val (raw_intro, (raw_classrel, raw_axioms)) =
   324       (Conjunction.split_defined (length conjs) def) ||> chop (length super);
   325 
   326 
   327     (* facts *)
   328 
   329     val class_triv = Thm.class_triv def_thy class;
   330     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
   331       def_thy
   332       |> PureThy.note_thmss_qualified "" bconst
   333         [((introN, []), [([Drule.standard raw_intro], [])]),
   334          ((superN, []), [(map Drule.standard raw_classrel, [])]),
   335          ((axiomsN, []), [(map (fn th => Drule.standard (class_triv RS th)) raw_axioms, [])])];
   336 
   337     (* params *)
   338 
   339     val params = map (prep_param thy) raw_params;
   340     val params_typs = map (fn param =>
   341       let
   342         val ty = Sign.the_const_type thy param;
   343         val _ = case Term.typ_tvars ty
   344          of [_] => ()
   345           | _ => error ("Exactly one type variable required in parameter " ^ quote param);
   346         val ty' = Term.map_type_tvar (fn _ => TFree (param_tyvarname, [class])) ty;
   347       in (param, ty') end) params;
   348 
   349     (* result *)
   350 
   351     val axclass = make_axclass ((def, intro, axioms), params_typs);
   352     val result_thy =
   353       facts_thy
   354       |> fold put_classrel (map (pair class) super ~~ classrel)
   355       |> Sign.add_path bconst
   356       |> PureThy.note_thmss_i "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms)) |> snd
   357       |> Sign.restore_naming facts_thy
   358       |> map_axclasses (fn (axclasses, parameters) =>
   359         (Symtab.update (class, axclass) axclasses,
   360           fold (fn x => add_param pp (x, class)) params parameters));
   361 
   362   in (class, result_thy) end;
   363 
   364 in
   365 
   366 val define_class = def_class Sign.read_class Attrib.attribute read_param ProofContext.read_propp;
   367 val define_class_i = def_class Sign.certify_class (K I) (K I) ProofContext.cert_propp;
   368 
   369 end;
   370 
   371 
   372 
   373 (** axiomatizations **)
   374 
   375 local
   376 
   377 fun axiomatize prep mk name add raw_args thy =
   378   let
   379     val args = prep thy raw_args;
   380     val specs = mk args;
   381     val names = name args;
   382   in thy |> PureThy.add_axioms_i (map (rpair []) (names ~~ specs)) |-> fold add end;
   383 
   384 fun ax_classrel prep =
   385   axiomatize (map o prep) (map Logic.mk_classrel)
   386     (map (prefix classrel_prefix o Logic.name_classrel)) add_classrel;
   387 
   388 fun ax_arity prep =
   389   axiomatize prep Logic.mk_arities
   390     (map (prefix arity_prefix) o Logic.name_arities) add_arity;
   391 
   392 fun class_const c =
   393   (Logic.const_of_class c, Term.itselfT (Term.aT []) --> propT);
   394 
   395 fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
   396   let
   397     val class = Sign.full_name thy bclass;
   398     val super = map (prep_class thy) raw_super |> Sign.certify_sort thy;
   399   in
   400     thy
   401     |> Sign.primitive_class (bclass, super)
   402     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
   403     |> Theory.add_deps "" (class_const class) (map class_const super)
   404   end;
   405 
   406 in
   407 
   408 val axiomatize_class = ax_class Sign.read_class read_classrel;
   409 val axiomatize_class_i = ax_class Sign.certify_class cert_classrel;
   410 val axiomatize_classrel = ax_classrel read_classrel;
   411 val axiomatize_classrel_i = ax_classrel cert_classrel;
   412 val axiomatize_arity = ax_arity Sign.read_arity;
   413 val axiomatize_arity_i = ax_arity Sign.cert_arity;
   414 
   415 end;
   416 
   417 
   418 
   419 (** explicit derivations -- cached **)
   420 
   421 datatype cache = Types of (class * thm) list Typtab.table;
   422 val cache = Types Typtab.empty;
   423 
   424 local
   425 
   426 fun lookup_type (Types cache) = AList.lookup (op =) o Typtab.lookup_list cache;
   427 fun insert_type T der (Types cache) = Types (Typtab.insert_list (eq_fst op =) (T, der) cache);
   428 
   429 fun derive_type _ (_, []) = []
   430   | derive_type thy (typ, sort) =
   431       let
   432         val vars = Term.fold_atyps
   433             (fn T as TFree (_, S) => insert (eq_fst op =) (T, S)
   434               | T as TVar (_, S) => insert (eq_fst op =) (T, S)
   435               | _ => I) typ [];
   436         val hyps = vars
   437           |> map (fn (T, S) => (T, Drule.sort_triv thy (T, S) ~~ S));
   438         val ths = (typ, sort) |> Sorts.of_sort_derivation (Sign.pp thy) (Sign.classes_of thy)
   439            {classrel =
   440               fn (th, c1) => fn c2 => th RS the_classrel thy (c1, c2),
   441             constructor =
   442               fn a => fn dom => fn c =>
   443                 let val Ss = map (map snd) dom and ths = maps (map fst) dom
   444                 in ths MRS the_arity thy a (c, Ss) end,
   445             variable =
   446               the_default [] o AList.lookup (op =) hyps};
   447       in ths end;
   448 
   449 in
   450 
   451 fun of_sort thy (typ, sort) cache =
   452   let
   453     val sort' = filter (is_none o lookup_type cache typ) sort;
   454     val ths' = derive_type thy (typ, sort')
   455       handle ERROR msg => cat_error msg ("The error(s) above occurred for sort derivation: " ^
   456         Sign.string_of_typ thy typ ^ " :: " ^ Sign.string_of_sort thy sort');
   457     val cache' = cache |> fold (insert_type typ) (sort' ~~ ths');
   458     val ths =
   459       sort |> map (fn c =>
   460         Goal.finish (the (lookup_type cache' typ c) RS
   461           Goal.init (Thm.cterm_of thy (Logic.mk_inclass (typ, c))))
   462         |> Thm.adjust_maxidx_thm ~1);
   463   in (ths, cache') end;
   464 
   465 end;
   466 
   467 end;