src/HOL/Product_Type.thy
author bulwahn
Wed Oct 17 14:13:57 2012 +0200 (2012-10-17)
changeset 49897 cc69be3c8f87
parent 49834 b27bbb021df1
child 50104 de19856feb54
permissions -rw-r--r--
moving Pair_inject from legacy and duplicate section to general section, as Pair_inject was considered a duplicate in e8400e31528a by mistake (cf. communication on dev mailing list)
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 keywords "inductive_set" "coinductive_set" :: thy_decl
    11 begin
    12 
    13 subsection {* @{typ bool} is a datatype *}
    14 
    15 rep_datatype True False by (auto intro: bool_induct)
    16 
    17 declare case_split [cases type: bool]
    18   -- "prefer plain propositional version"
    19 
    20 lemma
    21   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    22     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    23     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P"
    24     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    25     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    26   by (simp_all add: equal)
    27 
    28 lemma If_case_cert:
    29   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
    30   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
    31   using assms by simp_all
    32 
    33 setup {*
    34   Code.add_case @{thm If_case_cert}
    35 *}
    36 
    37 code_const "HOL.equal \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    38   (Haskell infix 4 "==")
    39 
    40 code_instance bool :: equal
    41   (Haskell -)
    42 
    43 
    44 subsection {* The @{text unit} type *}
    45 
    46 typedef unit = "{True}"
    47   by auto
    48 
    49 definition Unity :: unit  ("'(')")
    50   where "() = Abs_unit True"
    51 
    52 lemma unit_eq [no_atp]: "u = ()"
    53   by (induct u) (simp add: Unity_def)
    54 
    55 text {*
    56   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    57   this rule directly --- it loops!
    58 *}
    59 
    60 simproc_setup unit_eq ("x::unit") = {*
    61   fn _ => fn _ => fn ct =>
    62     if HOLogic.is_unit (term_of ct) then NONE
    63     else SOME (mk_meta_eq @{thm unit_eq})
    64 *}
    65 
    66 rep_datatype "()" by simp
    67 
    68 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    69   by simp
    70 
    71 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    72   by (rule triv_forall_equality)
    73 
    74 text {*
    75   This rewrite counters the effect of simproc @{text unit_eq} on @{term
    76   [source] "%u::unit. f u"}, replacing it by @{term [source]
    77   f} rather than by @{term [source] "%u. f ()"}.
    78 *}
    79 
    80 lemma unit_abs_eta_conv [simp, no_atp]: "(%u::unit. f ()) = f"
    81   by (rule ext) simp
    82 
    83 lemma UNIV_unit [no_atp]:
    84   "UNIV = {()}" by auto
    85 
    86 instantiation unit :: default
    87 begin
    88 
    89 definition "default = ()"
    90 
    91 instance ..
    92 
    93 end
    94 
    95 lemma [code]:
    96   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
    97 
    98 code_type unit
    99   (SML "unit")
   100   (OCaml "unit")
   101   (Haskell "()")
   102   (Scala "Unit")
   103 
   104 code_const Unity
   105   (SML "()")
   106   (OCaml "()")
   107   (Haskell "()")
   108   (Scala "()")
   109 
   110 code_instance unit :: equal
   111   (Haskell -)
   112 
   113 code_const "HOL.equal \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   114   (Haskell infix 4 "==")
   115 
   116 code_reserved SML
   117   unit
   118 
   119 code_reserved OCaml
   120   unit
   121 
   122 code_reserved Scala
   123   Unit
   124 
   125 
   126 subsection {* The product type *}
   127 
   128 subsubsection {* Type definition *}
   129 
   130 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   131   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   132 
   133 definition "prod = {f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   134 
   135 typedef ('a, 'b) prod (infixr "*" 20) = "prod :: ('a \<Rightarrow> 'b \<Rightarrow> bool) set"
   136   unfolding prod_def by auto
   137 
   138 type_notation (xsymbols)
   139   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   140 type_notation (HTML output)
   141   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   142 
   143 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   144   "Pair a b = Abs_prod (Pair_Rep a b)"
   145 
   146 rep_datatype Pair proof -
   147   fix P :: "'a \<times> 'b \<Rightarrow> bool" and p
   148   assume "\<And>a b. P (Pair a b)"
   149   then show "P p" by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   150 next
   151   fix a c :: 'a and b d :: 'b
   152   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   153     by (auto simp add: Pair_Rep_def fun_eq_iff)
   154   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   155     by (auto simp add: prod_def)
   156   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   157     by (simp add: Pair_def Abs_prod_inject)
   158 qed
   159 
   160 declare prod.simps(2) [nitpick_simp del]
   161 
   162 declare prod.weak_case_cong [cong del]
   163 
   164 
   165 subsubsection {* Tuple syntax *}
   166 
   167 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   168   "split \<equiv> prod_case"
   169 
   170 text {*
   171   Patterns -- extends pre-defined type @{typ pttrn} used in
   172   abstractions.
   173 *}
   174 
   175 nonterminal tuple_args and patterns
   176 
   177 syntax
   178   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   179   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   180   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   181   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   182   ""            :: "pttrn => patterns"                  ("_")
   183   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   184 
   185 translations
   186   "(x, y)" == "CONST Pair x y"
   187   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   188   "%(x, y, zs). b" == "CONST prod_case (%x (y, zs). b)"
   189   "%(x, y). b" == "CONST prod_case (%x y. b)"
   190   "_abs (CONST Pair x y) t" => "%(x, y). t"
   191   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   192      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   193 
   194 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   195   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   196 print_translation {*
   197 let
   198   fun split_tr' [Abs (x, T, t as (Abs abs))] =
   199         (* split (%x y. t) => %(x,y) t *)
   200         let
   201           val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   202           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   203         in
   204           Syntax.const @{syntax_const "_abs"} $
   205             (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   206         end
   207     | split_tr' [Abs (x, T, (s as Const (@{const_syntax prod_case}, _) $ t))] =
   208         (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   209         let
   210           val Const (@{syntax_const "_abs"}, _) $
   211             (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   212           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   213         in
   214           Syntax.const @{syntax_const "_abs"} $
   215             (Syntax.const @{syntax_const "_pattern"} $ x' $
   216               (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   217         end
   218     | split_tr' [Const (@{const_syntax prod_case}, _) $ t] =
   219         (* split (split (%x y z. t)) => %((x, y), z). t *)
   220         split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   221     | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   222         (* split (%pttrn z. t) => %(pttrn,z). t *)
   223         let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   224           Syntax.const @{syntax_const "_abs"} $
   225             (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   226         end
   227     | split_tr' _ = raise Match;
   228 in [(@{const_syntax prod_case}, split_tr')] end
   229 *}
   230 
   231 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   232 typed_print_translation {*
   233 let
   234   fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   235     | split_guess_names_tr' T [Abs (x, xT, t)] =
   236         (case (head_of t) of
   237           Const (@{const_syntax prod_case}, _) => raise Match
   238         | _ =>
   239           let 
   240             val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   241             val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   242             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   243           in
   244             Syntax.const @{syntax_const "_abs"} $
   245               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   246           end)
   247     | split_guess_names_tr' T [t] =
   248         (case head_of t of
   249           Const (@{const_syntax prod_case}, _) => raise Match
   250         | _ =>
   251           let
   252             val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   253             val (y, t') =
   254               Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   255             val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   256           in
   257             Syntax.const @{syntax_const "_abs"} $
   258               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   259           end)
   260     | split_guess_names_tr' _ _ = raise Match;
   261 in [(@{const_syntax prod_case}, split_guess_names_tr')] end
   262 *}
   263 
   264 (* Force eta-contraction for terms of the form "Q A (%p. prod_case P p)"
   265    where Q is some bounded quantifier or set operator.
   266    Reason: the above prints as "Q p : A. case p of (x,y) \<Rightarrow> P x y"
   267    whereas we want "Q (x,y):A. P x y".
   268    Otherwise prevent eta-contraction.
   269 *)
   270 print_translation {*
   271 let
   272   fun contract Q f ts =
   273     case ts of
   274       [A, Abs(_, _, (s as Const (@{const_syntax prod_case},_) $ t) $ Bound 0)]
   275       => if Term.is_dependent t then f ts else Syntax.const Q $ A $ s
   276     | _ => f ts;
   277   fun contract2 (Q,f) = (Q, contract Q f);
   278   val pairs =
   279     [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   280      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"},
   281      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   282      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   283 in map contract2 pairs end
   284 *}
   285 
   286 subsubsection {* Code generator setup *}
   287 
   288 code_type prod
   289   (SML infix 2 "*")
   290   (OCaml infix 2 "*")
   291   (Haskell "!((_),/ (_))")
   292   (Scala "((_),/ (_))")
   293 
   294 code_const Pair
   295   (SML "!((_),/ (_))")
   296   (OCaml "!((_),/ (_))")
   297   (Haskell "!((_),/ (_))")
   298   (Scala "!((_),/ (_))")
   299 
   300 code_instance prod :: equal
   301   (Haskell -)
   302 
   303 code_const "HOL.equal \<Colon> 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   304   (Haskell infix 4 "==")
   305 
   306 
   307 subsubsection {* Fundamental operations and properties *}
   308 
   309 lemma Pair_inject:
   310   assumes "(a, b) = (a', b')"
   311     and "a = a' ==> b = b' ==> R"
   312   shows R
   313   using assms by simp
   314 
   315 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   316   by (cases p) simp
   317 
   318 definition fst :: "'a \<times> 'b \<Rightarrow> 'a" where
   319   "fst p = (case p of (a, b) \<Rightarrow> a)"
   320 
   321 definition snd :: "'a \<times> 'b \<Rightarrow> 'b" where
   322   "snd p = (case p of (a, b) \<Rightarrow> b)"
   323 
   324 lemma fst_conv [simp, code]: "fst (a, b) = a"
   325   unfolding fst_def by simp
   326 
   327 lemma snd_conv [simp, code]: "snd (a, b) = b"
   328   unfolding snd_def by simp
   329 
   330 code_const fst and snd
   331   (Haskell "fst" and "snd")
   332 
   333 lemma prod_case_unfold [nitpick_unfold]: "prod_case = (%c p. c (fst p) (snd p))"
   334   by (simp add: fun_eq_iff split: prod.split)
   335 
   336 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   337   by simp
   338 
   339 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   340   by simp
   341 
   342 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   343   by (cases p) simp
   344 
   345 lemmas surjective_pairing = pair_collapse [symmetric]
   346 
   347 lemma prod_eq_iff: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   348   by (cases s, cases t) simp
   349 
   350 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   351   by (simp add: prod_eq_iff)
   352 
   353 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   354   by (fact prod.cases)
   355 
   356 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   357   by (rule split_conv [THEN iffD2])
   358 
   359 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   360   by (rule split_conv [THEN iffD1])
   361 
   362 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   363   by (simp add: fun_eq_iff split: prod.split)
   364 
   365 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   366   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   367   by (simp add: fun_eq_iff split: prod.split)
   368 
   369 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   370   by (cases x) simp
   371 
   372 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   373   by (cases p) simp
   374 
   375 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   376   by (simp add: prod_case_unfold)
   377 
   378 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   379   -- {* Prevents simplification of @{term c}: much faster *}
   380   by (fact prod.weak_case_cong)
   381 
   382 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   383   by (simp add: split_eta)
   384 
   385 lemma split_paired_all [no_atp]: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   386 proof
   387   fix a b
   388   assume "!!x. PROP P x"
   389   then show "PROP P (a, b)" .
   390 next
   391   fix x
   392   assume "!!a b. PROP P (a, b)"
   393   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   394 qed
   395 
   396 text {*
   397   The rule @{thm [source] split_paired_all} does not work with the
   398   Simplifier because it also affects premises in congrence rules,
   399   where this can lead to premises of the form @{text "!!a b. ... =
   400   ?P(a, b)"} which cannot be solved by reflexivity.
   401 *}
   402 
   403 lemmas split_tupled_all = split_paired_all unit_all_eq2
   404 
   405 ML {*
   406   (* replace parameters of product type by individual component parameters *)
   407   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   408   local (* filtering with exists_paired_all is an essential optimization *)
   409     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   410           can HOLogic.dest_prodT T orelse exists_paired_all t
   411       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   412       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   413       | exists_paired_all _ = false;
   414     val ss = HOL_basic_ss
   415       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   416       addsimprocs [@{simproc unit_eq}];
   417   in
   418     val split_all_tac = SUBGOAL (fn (t, i) =>
   419       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   420     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   421       if exists_paired_all t then full_simp_tac ss i else no_tac);
   422     fun split_all th =
   423    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   424   end;
   425 *}
   426 
   427 declaration {* fn _ =>
   428   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   429 *}
   430 
   431 lemma split_paired_All [simp, no_atp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   432   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   433   by fast
   434 
   435 lemma split_paired_Ex [simp, no_atp]: "(EX x. P x) = (EX a b. P (a, b))"
   436   by fast
   437 
   438 lemma split_paired_The [no_atp]: "(THE x. P x) = (THE (a, b). P (a, b))"
   439   -- {* Can't be added to simpset: loops! *}
   440   by (simp add: split_eta)
   441 
   442 text {*
   443   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   444   @{thm [source] split_eta} as a rewrite rule is not general enough,
   445   and using @{thm [source] cond_split_eta} directly would render some
   446   existing proofs very inefficient; similarly for @{text
   447   split_beta}.
   448 *}
   449 
   450 ML {*
   451 local
   452   val cond_split_eta_ss = HOL_basic_ss addsimps @{thms cond_split_eta};
   453   fun Pair_pat k 0 (Bound m) = (m = k)
   454     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   455         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   456     | Pair_pat _ _ _ = false;
   457   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   458     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   459     | no_args k i (Bound m) = m < k orelse m > k + i
   460     | no_args _ _ _ = true;
   461   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   462     | split_pat tp i (Const (@{const_name prod_case}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   463     | split_pat tp i _ = NONE;
   464   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   465         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   466         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   467 
   468   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   469     | beta_term_pat k i (t $ u) =
   470         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   471     | beta_term_pat k i t = no_args k i t;
   472   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   473     | eta_term_pat _ _ _ = false;
   474   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   475     | subst arg k i (t $ u) =
   476         if Pair_pat k i (t $ u) then incr_boundvars k arg
   477         else (subst arg k i t $ subst arg k i u)
   478     | subst arg k i t = t;
   479 in
   480   fun beta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t) $ arg) =
   481         (case split_pat beta_term_pat 1 t of
   482           SOME (i, f) => SOME (metaeq ss s (subst arg 0 i f))
   483         | NONE => NONE)
   484     | beta_proc _ _ = NONE;
   485   fun eta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t)) =
   486         (case split_pat eta_term_pat 1 t of
   487           SOME (_, ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   488         | NONE => NONE)
   489     | eta_proc _ _ = NONE;
   490 end;
   491 *}
   492 simproc_setup split_beta ("split f z") = {* fn _ => fn ss => fn ct => beta_proc ss (term_of ct) *}
   493 simproc_setup split_eta ("split f") = {* fn _ => fn ss => fn ct => eta_proc ss (term_of ct) *}
   494 
   495 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   496   by (subst surjective_pairing, rule split_conv)
   497 
   498 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   499   -- {* For use with @{text split} and the Simplifier. *}
   500   by (insert surj_pair [of p], clarify, simp)
   501 
   502 text {*
   503   @{thm [source] split_split} could be declared as @{text "[split]"}
   504   done after the Splitter has been speeded up significantly;
   505   precompute the constants involved and don't do anything unless the
   506   current goal contains one of those constants.
   507 *}
   508 
   509 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   510 by (subst split_split, simp)
   511 
   512 text {*
   513   \medskip @{term split} used as a logical connective or set former.
   514 
   515   \medskip These rules are for use with @{text blast}; could instead
   516   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   517 
   518 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   519   apply (simp only: split_tupled_all)
   520   apply (simp (no_asm_simp))
   521   done
   522 
   523 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   524   apply (simp only: split_tupled_all)
   525   apply (simp (no_asm_simp))
   526   done
   527 
   528 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   529   by (induct p) auto
   530 
   531 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   532   by (induct p) auto
   533 
   534 lemma splitE2:
   535   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   536 proof -
   537   assume q: "Q (split P z)"
   538   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   539   show R
   540     apply (rule r surjective_pairing)+
   541     apply (rule split_beta [THEN subst], rule q)
   542     done
   543 qed
   544 
   545 lemma splitD': "split R (a,b) c ==> R a b c"
   546   by simp
   547 
   548 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   549   by simp
   550 
   551 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   552 by (simp only: split_tupled_all, simp)
   553 
   554 lemma mem_splitE:
   555   assumes major: "z \<in> split c p"
   556     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   557   shows Q
   558   by (rule major [unfolded prod_case_unfold] cases surjective_pairing)+
   559 
   560 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   561 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   562 
   563 ML {*
   564 local (* filtering with exists_p_split is an essential optimization *)
   565   fun exists_p_split (Const (@{const_name prod_case},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   566     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   567     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   568     | exists_p_split _ = false;
   569   val ss = HOL_basic_ss addsimps @{thms split_conv};
   570 in
   571 val split_conv_tac = SUBGOAL (fn (t, i) =>
   572     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   573 end;
   574 *}
   575 
   576 (* This prevents applications of splitE for already splitted arguments leading
   577    to quite time-consuming computations (in particular for nested tuples) *)
   578 declaration {* fn _ =>
   579   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   580 *}
   581 
   582 lemma split_eta_SetCompr [simp,no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   583   by (rule ext) fast
   584 
   585 lemma split_eta_SetCompr2 [simp,no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   586   by (rule ext) fast
   587 
   588 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   589   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   590   by (rule ext) blast
   591 
   592 (* Do NOT make this a simp rule as it
   593    a) only helps in special situations
   594    b) can lead to nontermination in the presence of split_def
   595 *)
   596 lemma split_comp_eq: 
   597   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   598   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   599   by (rule ext) auto
   600 
   601 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   602   apply (rule_tac x = "(a, b)" in image_eqI)
   603    apply auto
   604   done
   605 
   606 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   607   by blast
   608 
   609 (*
   610 the following  would be slightly more general,
   611 but cannot be used as rewrite rule:
   612 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   613 ### ?y = .x
   614 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   615 by (rtac some_equality 1)
   616 by ( Simp_tac 1)
   617 by (split_all_tac 1)
   618 by (Asm_full_simp_tac 1)
   619 qed "The_split_eq";
   620 *)
   621 
   622 text {*
   623   Setup of internal @{text split_rule}.
   624 *}
   625 
   626 lemmas prod_caseI = prod.cases [THEN iffD2]
   627 
   628 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   629   by (fact splitI2)
   630 
   631 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   632   by (fact splitI2')
   633 
   634 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   635   by (fact splitE)
   636 
   637 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   638   by (fact splitE')
   639 
   640 declare prod_caseI [intro!]
   641 
   642 lemma prod_case_beta:
   643   "prod_case f p = f (fst p) (snd p)"
   644   by (fact split_beta)
   645 
   646 lemma prod_cases3 [cases type]:
   647   obtains (fields) a b c where "y = (a, b, c)"
   648   by (cases y, case_tac b) blast
   649 
   650 lemma prod_induct3 [case_names fields, induct type]:
   651     "(!!a b c. P (a, b, c)) ==> P x"
   652   by (cases x) blast
   653 
   654 lemma prod_cases4 [cases type]:
   655   obtains (fields) a b c d where "y = (a, b, c, d)"
   656   by (cases y, case_tac c) blast
   657 
   658 lemma prod_induct4 [case_names fields, induct type]:
   659     "(!!a b c d. P (a, b, c, d)) ==> P x"
   660   by (cases x) blast
   661 
   662 lemma prod_cases5 [cases type]:
   663   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   664   by (cases y, case_tac d) blast
   665 
   666 lemma prod_induct5 [case_names fields, induct type]:
   667     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   668   by (cases x) blast
   669 
   670 lemma prod_cases6 [cases type]:
   671   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   672   by (cases y, case_tac e) blast
   673 
   674 lemma prod_induct6 [case_names fields, induct type]:
   675     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   676   by (cases x) blast
   677 
   678 lemma prod_cases7 [cases type]:
   679   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   680   by (cases y, case_tac f) blast
   681 
   682 lemma prod_induct7 [case_names fields, induct type]:
   683     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   684   by (cases x) blast
   685 
   686 lemma split_def:
   687   "split = (\<lambda>c p. c (fst p) (snd p))"
   688   by (fact prod_case_unfold)
   689 
   690 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   691   "internal_split == split"
   692 
   693 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   694   by (simp only: internal_split_def split_conv)
   695 
   696 ML_file "Tools/split_rule.ML"
   697 setup Split_Rule.setup
   698 
   699 hide_const internal_split
   700 
   701 
   702 subsubsection {* Derived operations *}
   703 
   704 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   705   "curry = (\<lambda>c x y. c (x, y))"
   706 
   707 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   708   by (simp add: curry_def)
   709 
   710 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   711   by (simp add: curry_def)
   712 
   713 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   714   by (simp add: curry_def)
   715 
   716 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   717   by (simp add: curry_def)
   718 
   719 lemma curry_split [simp]: "curry (split f) = f"
   720   by (simp add: curry_def split_def)
   721 
   722 lemma split_curry [simp]: "split (curry f) = f"
   723   by (simp add: curry_def split_def)
   724 
   725 text {*
   726   The composition-uncurry combinator.
   727 *}
   728 
   729 notation fcomp (infixl "\<circ>>" 60)
   730 
   731 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   732   "f \<circ>\<rightarrow> g = (\<lambda>x. prod_case g (f x))"
   733 
   734 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   735   by (simp add: fun_eq_iff scomp_def prod_case_unfold)
   736 
   737 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = prod_case g (f x)"
   738   by (simp add: scomp_unfold prod_case_unfold)
   739 
   740 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   741   by (simp add: fun_eq_iff)
   742 
   743 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   744   by (simp add: fun_eq_iff)
   745 
   746 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   747   by (simp add: fun_eq_iff scomp_unfold)
   748 
   749 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   750   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   751 
   752 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   753   by (simp add: fun_eq_iff scomp_unfold)
   754 
   755 code_const scomp
   756   (Eval infixl 3 "#->")
   757 
   758 no_notation fcomp (infixl "\<circ>>" 60)
   759 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   760 
   761 text {*
   762   @{term map_pair} --- action of the product functor upon
   763   functions.
   764 *}
   765 
   766 definition map_pair :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   767   "map_pair f g = (\<lambda>(x, y). (f x, g y))"
   768 
   769 lemma map_pair_simp [simp, code]:
   770   "map_pair f g (a, b) = (f a, g b)"
   771   by (simp add: map_pair_def)
   772 
   773 enriched_type map_pair: map_pair
   774   by (auto simp add: split_paired_all)
   775 
   776 lemma fst_map_pair [simp]:
   777   "fst (map_pair f g x) = f (fst x)"
   778   by (cases x) simp_all
   779 
   780 lemma snd_prod_fun [simp]:
   781   "snd (map_pair f g x) = g (snd x)"
   782   by (cases x) simp_all
   783 
   784 lemma fst_comp_map_pair [simp]:
   785   "fst \<circ> map_pair f g = f \<circ> fst"
   786   by (rule ext) simp_all
   787 
   788 lemma snd_comp_map_pair [simp]:
   789   "snd \<circ> map_pair f g = g \<circ> snd"
   790   by (rule ext) simp_all
   791 
   792 lemma map_pair_compose:
   793   "map_pair (f1 o f2) (g1 o g2) = (map_pair f1 g1 o map_pair f2 g2)"
   794   by (rule ext) (simp add: map_pair.compositionality comp_def)
   795 
   796 lemma map_pair_ident [simp]:
   797   "map_pair (%x. x) (%y. y) = (%z. z)"
   798   by (rule ext) (simp add: map_pair.identity)
   799 
   800 lemma map_pair_imageI [intro]:
   801   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_pair f g ` R"
   802   by (rule image_eqI) simp_all
   803 
   804 lemma prod_fun_imageE [elim!]:
   805   assumes major: "c \<in> map_pair f g ` R"
   806     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   807   shows P
   808   apply (rule major [THEN imageE])
   809   apply (case_tac x)
   810   apply (rule cases)
   811   apply simp_all
   812   done
   813 
   814 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   815   "apfst f = map_pair f id"
   816 
   817 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   818   "apsnd f = map_pair id f"
   819 
   820 lemma apfst_conv [simp, code]:
   821   "apfst f (x, y) = (f x, y)" 
   822   by (simp add: apfst_def)
   823 
   824 lemma apsnd_conv [simp, code]:
   825   "apsnd f (x, y) = (x, f y)" 
   826   by (simp add: apsnd_def)
   827 
   828 lemma fst_apfst [simp]:
   829   "fst (apfst f x) = f (fst x)"
   830   by (cases x) simp
   831 
   832 lemma fst_apsnd [simp]:
   833   "fst (apsnd f x) = fst x"
   834   by (cases x) simp
   835 
   836 lemma snd_apfst [simp]:
   837   "snd (apfst f x) = snd x"
   838   by (cases x) simp
   839 
   840 lemma snd_apsnd [simp]:
   841   "snd (apsnd f x) = f (snd x)"
   842   by (cases x) simp
   843 
   844 lemma apfst_compose:
   845   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   846   by (cases x) simp
   847 
   848 lemma apsnd_compose:
   849   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   850   by (cases x) simp
   851 
   852 lemma apfst_apsnd [simp]:
   853   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   854   by (cases x) simp
   855 
   856 lemma apsnd_apfst [simp]:
   857   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   858   by (cases x) simp
   859 
   860 lemma apfst_id [simp] :
   861   "apfst id = id"
   862   by (simp add: fun_eq_iff)
   863 
   864 lemma apsnd_id [simp] :
   865   "apsnd id = id"
   866   by (simp add: fun_eq_iff)
   867 
   868 lemma apfst_eq_conv [simp]:
   869   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   870   by (cases x) simp
   871 
   872 lemma apsnd_eq_conv [simp]:
   873   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   874   by (cases x) simp
   875 
   876 lemma apsnd_apfst_commute:
   877   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   878   by simp
   879 
   880 text {*
   881   Disjoint union of a family of sets -- Sigma.
   882 *}
   883 
   884 definition Sigma :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<times> 'b) set" where
   885   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   886 
   887 abbreviation
   888   Times :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set"
   889     (infixr "<*>" 80) where
   890   "A <*> B == Sigma A (%_. B)"
   891 
   892 notation (xsymbols)
   893   Times  (infixr "\<times>" 80)
   894 
   895 notation (HTML output)
   896   Times  (infixr "\<times>" 80)
   897 
   898 hide_const (open) Times
   899 
   900 syntax
   901   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   902 translations
   903   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
   904 
   905 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   906   by (unfold Sigma_def) blast
   907 
   908 lemma SigmaE [elim!]:
   909     "[| c: Sigma A B;
   910         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   911      |] ==> P"
   912   -- {* The general elimination rule. *}
   913   by (unfold Sigma_def) blast
   914 
   915 text {*
   916   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   917   eigenvariables.
   918 *}
   919 
   920 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   921   by blast
   922 
   923 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   924   by blast
   925 
   926 lemma SigmaE2:
   927     "[| (a, b) : Sigma A B;
   928         [| a:A;  b:B(a) |] ==> P
   929      |] ==> P"
   930   by blast
   931 
   932 lemma Sigma_cong:
   933      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   934       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
   935   by auto
   936 
   937 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
   938   by blast
   939 
   940 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
   941   by blast
   942 
   943 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
   944   by blast
   945 
   946 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
   947   by auto
   948 
   949 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
   950   by auto
   951 
   952 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
   953   by auto
   954 
   955 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
   956   by blast
   957 
   958 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
   959   by blast
   960 
   961 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
   962   by (blast elim: equalityE)
   963 
   964 lemma SetCompr_Sigma_eq:
   965     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
   966   by blast
   967 
   968 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
   969   by blast
   970 
   971 lemma UN_Times_distrib:
   972   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
   973   -- {* Suggested by Pierre Chartier *}
   974   by blast
   975 
   976 lemma split_paired_Ball_Sigma [simp, no_atp]:
   977     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
   978   by blast
   979 
   980 lemma split_paired_Bex_Sigma [simp, no_atp]:
   981     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
   982   by blast
   983 
   984 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
   985   by blast
   986 
   987 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
   988   by blast
   989 
   990 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
   991   by blast
   992 
   993 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
   994   by blast
   995 
   996 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
   997   by blast
   998 
   999 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1000   by blast
  1001 
  1002 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1003   by blast
  1004 
  1005 text {*
  1006   Non-dependent versions are needed to avoid the need for higher-order
  1007   matching, especially when the rules are re-oriented.
  1008 *}
  1009 
  1010 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1011 by blast
  1012 
  1013 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1014 by blast
  1015 
  1016 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1017 by blast
  1018 
  1019 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1020   by auto
  1021 
  1022 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1023   by force
  1024 
  1025 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1026   by force
  1027 
  1028 lemma insert_times_insert[simp]:
  1029   "insert a A \<times> insert b B =
  1030    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1031 by blast
  1032 
  1033 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1034   apply auto
  1035   apply (case_tac "f x")
  1036   apply auto
  1037   done
  1038 
  1039 lemma swap_inj_on:
  1040   "inj_on (\<lambda>(i, j). (j, i)) A"
  1041   by (auto intro!: inj_onI)
  1042 
  1043 lemma swap_product:
  1044   "(%(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1045   by (simp add: split_def image_def) blast
  1046 
  1047 lemma image_split_eq_Sigma:
  1048   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1049 proof (safe intro!: imageI)
  1050   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1051   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1052     using * eq[symmetric] by auto
  1053 qed simp_all
  1054 
  1055 definition product :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set" where
  1056   [code_abbrev]: "product A B = A \<times> B"
  1057 
  1058 hide_const (open) product
  1059 
  1060 lemma member_product:
  1061   "x \<in> Product_Type.product A B \<longleftrightarrow> x \<in> A \<times> B"
  1062   by (simp add: product_def)
  1063 
  1064 text {* The following @{const map_pair} lemmas are due to Joachim Breitner: *}
  1065 
  1066 lemma map_pair_inj_on:
  1067   assumes "inj_on f A" and "inj_on g B"
  1068   shows "inj_on (map_pair f g) (A \<times> B)"
  1069 proof (rule inj_onI)
  1070   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1071   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1072   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1073   assume "map_pair f g x = map_pair f g y"
  1074   hence "fst (map_pair f g x) = fst (map_pair f g y)" by (auto)
  1075   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1076   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1077   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1078   moreover from `map_pair f g x = map_pair f g y`
  1079   have "snd (map_pair f g x) = snd (map_pair f g y)" by (auto)
  1080   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1081   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1082   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1083   ultimately show "x = y" by(rule prod_eqI)
  1084 qed
  1085 
  1086 lemma map_pair_surj:
  1087   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1088   assumes "surj f" and "surj g"
  1089   shows "surj (map_pair f g)"
  1090 unfolding surj_def
  1091 proof
  1092   fix y :: "'b \<times> 'd"
  1093   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1094   moreover
  1095   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1096   ultimately have "(fst y, snd y) = map_pair f g (a,b)" by auto
  1097   thus "\<exists>x. y = map_pair f g x" by auto
  1098 qed
  1099 
  1100 lemma map_pair_surj_on:
  1101   assumes "f ` A = A'" and "g ` B = B'"
  1102   shows "map_pair f g ` (A \<times> B) = A' \<times> B'"
  1103 unfolding image_def
  1104 proof(rule set_eqI,rule iffI)
  1105   fix x :: "'a \<times> 'c"
  1106   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_pair f g x}"
  1107   then obtain y where "y \<in> A \<times> B" and "x = map_pair f g y" by blast
  1108   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1109   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1110   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1111   with `x = map_pair f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1112 next
  1113   fix x :: "'a \<times> 'c"
  1114   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1115   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1116   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1117   moreover from `image g B = B'` and `snd x \<in> B'`
  1118   obtain b where "b \<in> B" and "snd x = g b" by auto
  1119   ultimately have "(fst x, snd x) = map_pair f g (a,b)" by auto
  1120   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1121   ultimately have "\<exists>y \<in> A \<times> B. x = map_pair f g y" by auto
  1122   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_pair f g y}" by auto
  1123 qed
  1124 
  1125 
  1126 subsection {* Simproc for rewriting a set comprehension into a pointfree expression *}
  1127 
  1128 ML_file "Tools/set_comprehension_pointfree.ML"
  1129 
  1130 setup {*
  1131   Code_Preproc.map_pre (fn ss => ss addsimprocs
  1132     [Raw_Simplifier.make_simproc {name = "set comprehension", lhss = [@{cpat "Collect ?P"}],
  1133     proc = K Set_Comprehension_Pointfree.code_simproc, identifier = []}])
  1134 *}
  1135 
  1136 
  1137 subsection {* Inductively defined sets *}
  1138 
  1139 ML_file "Tools/inductive_set.ML"
  1140 setup Inductive_Set.setup
  1141 
  1142 
  1143 subsection {* Legacy theorem bindings and duplicates *}
  1144 
  1145 lemma PairE:
  1146   obtains x y where "p = (x, y)"
  1147   by (fact prod.exhaust)
  1148 
  1149 lemmas Pair_eq = prod.inject
  1150 
  1151 lemmas split = split_conv  -- {* for backwards compatibility *}
  1152 
  1153 lemmas Pair_fst_snd_eq = prod_eq_iff
  1154 
  1155 hide_const (open) prod
  1156 
  1157 end