src/HOL/Rings.thy
author haftmann
Fri Jul 04 20:18:47 2014 +0200 (2014-07-04)
changeset 57512 cc97b347b301
parent 56544 b60d5d119489
child 57514 bdc2c6b40bf2
permissions -rw-r--r--
reduced name variants for assoc and commute on plus and mult
     1 (*  Title:      HOL/Rings.thy
     2     Author:     Gertrud Bauer
     3     Author:     Steven Obua
     4     Author:     Tobias Nipkow
     5     Author:     Lawrence C Paulson
     6     Author:     Markus Wenzel
     7     Author:     Jeremy Avigad
     8 *)
     9 
    10 header {* Rings *}
    11 
    12 theory Rings
    13 imports Groups
    14 begin
    15 
    16 class semiring = ab_semigroup_add + semigroup_mult +
    17   assumes distrib_right[algebra_simps, field_simps]: "(a + b) * c = a * c + b * c"
    18   assumes distrib_left[algebra_simps, field_simps]: "a * (b + c) = a * b + a * c"
    19 begin
    20 
    21 text{*For the @{text combine_numerals} simproc*}
    22 lemma combine_common_factor:
    23   "a * e + (b * e + c) = (a + b) * e + c"
    24 by (simp add: distrib_right add_ac)
    25 
    26 end
    27 
    28 class mult_zero = times + zero +
    29   assumes mult_zero_left [simp]: "0 * a = 0"
    30   assumes mult_zero_right [simp]: "a * 0 = 0"
    31 
    32 class semiring_0 = semiring + comm_monoid_add + mult_zero
    33 
    34 class semiring_0_cancel = semiring + cancel_comm_monoid_add
    35 begin
    36 
    37 subclass semiring_0
    38 proof
    39   fix a :: 'a
    40   have "0 * a + 0 * a = 0 * a + 0" by (simp add: distrib_right [symmetric])
    41   thus "0 * a = 0" by (simp only: add_left_cancel)
    42 next
    43   fix a :: 'a
    44   have "a * 0 + a * 0 = a * 0 + 0" by (simp add: distrib_left [symmetric])
    45   thus "a * 0 = 0" by (simp only: add_left_cancel)
    46 qed
    47 
    48 end
    49 
    50 class comm_semiring = ab_semigroup_add + ab_semigroup_mult +
    51   assumes distrib: "(a + b) * c = a * c + b * c"
    52 begin
    53 
    54 subclass semiring
    55 proof
    56   fix a b c :: 'a
    57   show "(a + b) * c = a * c + b * c" by (simp add: distrib)
    58   have "a * (b + c) = (b + c) * a" by (simp add: mult_ac)
    59   also have "... = b * a + c * a" by (simp only: distrib)
    60   also have "... = a * b + a * c" by (simp add: mult_ac)
    61   finally show "a * (b + c) = a * b + a * c" by blast
    62 qed
    63 
    64 end
    65 
    66 class comm_semiring_0 = comm_semiring + comm_monoid_add + mult_zero
    67 begin
    68 
    69 subclass semiring_0 ..
    70 
    71 end
    72 
    73 class comm_semiring_0_cancel = comm_semiring + cancel_comm_monoid_add
    74 begin
    75 
    76 subclass semiring_0_cancel ..
    77 
    78 subclass comm_semiring_0 ..
    79 
    80 end
    81 
    82 class zero_neq_one = zero + one +
    83   assumes zero_neq_one [simp]: "0 \<noteq> 1"
    84 begin
    85 
    86 lemma one_neq_zero [simp]: "1 \<noteq> 0"
    87 by (rule not_sym) (rule zero_neq_one)
    88 
    89 definition of_bool :: "bool \<Rightarrow> 'a"
    90 where
    91   "of_bool p = (if p then 1 else 0)" 
    92 
    93 lemma of_bool_eq [simp, code]:
    94   "of_bool False = 0"
    95   "of_bool True = 1"
    96   by (simp_all add: of_bool_def)
    97 
    98 lemma of_bool_eq_iff:
    99   "of_bool p = of_bool q \<longleftrightarrow> p = q"
   100   by (simp add: of_bool_def)
   101 
   102 lemma split_of_bool [split]:
   103   "P (of_bool p) \<longleftrightarrow> (p \<longrightarrow> P 1) \<and> (\<not> p \<longrightarrow> P 0)"
   104   by (cases p) simp_all
   105 
   106 lemma split_of_bool_asm:
   107   "P (of_bool p) \<longleftrightarrow> \<not> (p \<and> \<not> P 1 \<or> \<not> p \<and> \<not> P 0)"
   108   by (cases p) simp_all
   109   
   110 end  
   111 
   112 class semiring_1 = zero_neq_one + semiring_0 + monoid_mult
   113 
   114 text {* Abstract divisibility *}
   115 
   116 class dvd = times
   117 begin
   118 
   119 definition dvd :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "dvd" 50) where
   120   "b dvd a \<longleftrightarrow> (\<exists>k. a = b * k)"
   121 
   122 lemma dvdI [intro?]: "a = b * k \<Longrightarrow> b dvd a"
   123   unfolding dvd_def ..
   124 
   125 lemma dvdE [elim?]: "b dvd a \<Longrightarrow> (\<And>k. a = b * k \<Longrightarrow> P) \<Longrightarrow> P"
   126   unfolding dvd_def by blast 
   127 
   128 end
   129 
   130 class comm_semiring_1 = zero_neq_one + comm_semiring_0 + comm_monoid_mult + dvd
   131   (*previously almost_semiring*)
   132 begin
   133 
   134 subclass semiring_1 ..
   135 
   136 lemma dvd_refl[simp]: "a dvd a"
   137 proof
   138   show "a = a * 1" by simp
   139 qed
   140 
   141 lemma dvd_trans:
   142   assumes "a dvd b" and "b dvd c"
   143   shows "a dvd c"
   144 proof -
   145   from assms obtain v where "b = a * v" by (auto elim!: dvdE)
   146   moreover from assms obtain w where "c = b * w" by (auto elim!: dvdE)
   147   ultimately have "c = a * (v * w)" by (simp add: mult.assoc)
   148   then show ?thesis ..
   149 qed
   150 
   151 lemma dvd_0_left_iff [simp]: "0 dvd a \<longleftrightarrow> a = 0"
   152 by (auto intro: dvd_refl elim!: dvdE)
   153 
   154 lemma dvd_0_right [iff]: "a dvd 0"
   155 proof
   156   show "0 = a * 0" by simp
   157 qed
   158 
   159 lemma one_dvd [simp]: "1 dvd a"
   160 by (auto intro!: dvdI)
   161 
   162 lemma dvd_mult[simp]: "a dvd c \<Longrightarrow> a dvd (b * c)"
   163 by (auto intro!: mult.left_commute dvdI elim!: dvdE)
   164 
   165 lemma dvd_mult2[simp]: "a dvd b \<Longrightarrow> a dvd (b * c)"
   166   apply (subst mult.commute)
   167   apply (erule dvd_mult)
   168   done
   169 
   170 lemma dvd_triv_right [simp]: "a dvd b * a"
   171 by (rule dvd_mult) (rule dvd_refl)
   172 
   173 lemma dvd_triv_left [simp]: "a dvd a * b"
   174 by (rule dvd_mult2) (rule dvd_refl)
   175 
   176 lemma mult_dvd_mono:
   177   assumes "a dvd b"
   178     and "c dvd d"
   179   shows "a * c dvd b * d"
   180 proof -
   181   from `a dvd b` obtain b' where "b = a * b'" ..
   182   moreover from `c dvd d` obtain d' where "d = c * d'" ..
   183   ultimately have "b * d = (a * c) * (b' * d')" by (simp add: mult_ac)
   184   then show ?thesis ..
   185 qed
   186 
   187 lemma dvd_mult_left: "a * b dvd c \<Longrightarrow> a dvd c"
   188 by (simp add: dvd_def mult.assoc, blast)
   189 
   190 lemma dvd_mult_right: "a * b dvd c \<Longrightarrow> b dvd c"
   191   unfolding mult_ac [of a] by (rule dvd_mult_left)
   192 
   193 lemma dvd_0_left: "0 dvd a \<Longrightarrow> a = 0"
   194 by simp
   195 
   196 lemma dvd_add[simp]:
   197   assumes "a dvd b" and "a dvd c" shows "a dvd (b + c)"
   198 proof -
   199   from `a dvd b` obtain b' where "b = a * b'" ..
   200   moreover from `a dvd c` obtain c' where "c = a * c'" ..
   201   ultimately have "b + c = a * (b' + c')" by (simp add: distrib_left)
   202   then show ?thesis ..
   203 qed
   204 
   205 end
   206 
   207 class no_zero_divisors = zero + times +
   208   assumes no_zero_divisors: "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> a * b \<noteq> 0"
   209 begin
   210 
   211 lemma divisors_zero:
   212   assumes "a * b = 0"
   213   shows "a = 0 \<or> b = 0"
   214 proof (rule classical)
   215   assume "\<not> (a = 0 \<or> b = 0)"
   216   then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   217   with no_zero_divisors have "a * b \<noteq> 0" by blast
   218   with assms show ?thesis by simp
   219 qed
   220 
   221 end
   222 
   223 class semiring_1_cancel = semiring + cancel_comm_monoid_add
   224   + zero_neq_one + monoid_mult
   225 begin
   226 
   227 subclass semiring_0_cancel ..
   228 
   229 subclass semiring_1 ..
   230 
   231 end
   232 
   233 class comm_semiring_1_cancel = comm_semiring + cancel_comm_monoid_add
   234   + zero_neq_one + comm_monoid_mult
   235 begin
   236 
   237 subclass semiring_1_cancel ..
   238 subclass comm_semiring_0_cancel ..
   239 subclass comm_semiring_1 ..
   240 
   241 end
   242 
   243 class ring = semiring + ab_group_add
   244 begin
   245 
   246 subclass semiring_0_cancel ..
   247 
   248 text {* Distribution rules *}
   249 
   250 lemma minus_mult_left: "- (a * b) = - a * b"
   251 by (rule minus_unique) (simp add: distrib_right [symmetric]) 
   252 
   253 lemma minus_mult_right: "- (a * b) = a * - b"
   254 by (rule minus_unique) (simp add: distrib_left [symmetric]) 
   255 
   256 text{*Extract signs from products*}
   257 lemmas mult_minus_left [simp] = minus_mult_left [symmetric]
   258 lemmas mult_minus_right [simp] = minus_mult_right [symmetric]
   259 
   260 lemma minus_mult_minus [simp]: "- a * - b = a * b"
   261 by simp
   262 
   263 lemma minus_mult_commute: "- a * b = a * - b"
   264 by simp
   265 
   266 lemma right_diff_distrib [algebra_simps, field_simps]:
   267   "a * (b - c) = a * b - a * c"
   268   using distrib_left [of a b "-c "] by simp
   269 
   270 lemma left_diff_distrib [algebra_simps, field_simps]:
   271   "(a - b) * c = a * c - b * c"
   272   using distrib_right [of a "- b" c] by simp
   273 
   274 lemmas ring_distribs =
   275   distrib_left distrib_right left_diff_distrib right_diff_distrib
   276 
   277 lemma eq_add_iff1:
   278   "a * e + c = b * e + d \<longleftrightarrow> (a - b) * e + c = d"
   279 by (simp add: algebra_simps)
   280 
   281 lemma eq_add_iff2:
   282   "a * e + c = b * e + d \<longleftrightarrow> c = (b - a) * e + d"
   283 by (simp add: algebra_simps)
   284 
   285 end
   286 
   287 lemmas ring_distribs =
   288   distrib_left distrib_right left_diff_distrib right_diff_distrib
   289 
   290 class comm_ring = comm_semiring + ab_group_add
   291 begin
   292 
   293 subclass ring ..
   294 subclass comm_semiring_0_cancel ..
   295 
   296 lemma square_diff_square_factored:
   297   "x * x - y * y = (x + y) * (x - y)"
   298   by (simp add: algebra_simps)
   299 
   300 end
   301 
   302 class ring_1 = ring + zero_neq_one + monoid_mult
   303 begin
   304 
   305 subclass semiring_1_cancel ..
   306 
   307 lemma square_diff_one_factored:
   308   "x * x - 1 = (x + 1) * (x - 1)"
   309   by (simp add: algebra_simps)
   310 
   311 end
   312 
   313 class comm_ring_1 = comm_ring + zero_neq_one + comm_monoid_mult
   314   (*previously ring*)
   315 begin
   316 
   317 subclass ring_1 ..
   318 subclass comm_semiring_1_cancel ..
   319 
   320 lemma dvd_minus_iff [simp]: "x dvd - y \<longleftrightarrow> x dvd y"
   321 proof
   322   assume "x dvd - y"
   323   then have "x dvd - 1 * - y" by (rule dvd_mult)
   324   then show "x dvd y" by simp
   325 next
   326   assume "x dvd y"
   327   then have "x dvd - 1 * y" by (rule dvd_mult)
   328   then show "x dvd - y" by simp
   329 qed
   330 
   331 lemma minus_dvd_iff [simp]: "- x dvd y \<longleftrightarrow> x dvd y"
   332 proof
   333   assume "- x dvd y"
   334   then obtain k where "y = - x * k" ..
   335   then have "y = x * - k" by simp
   336   then show "x dvd y" ..
   337 next
   338   assume "x dvd y"
   339   then obtain k where "y = x * k" ..
   340   then have "y = - x * - k" by simp
   341   then show "- x dvd y" ..
   342 qed
   343 
   344 lemma dvd_diff [simp]:
   345   "x dvd y \<Longrightarrow> x dvd z \<Longrightarrow> x dvd (y - z)"
   346   using dvd_add [of x y "- z"] by simp
   347 
   348 end
   349 
   350 class ring_no_zero_divisors = ring + no_zero_divisors
   351 begin
   352 
   353 lemma mult_eq_0_iff [simp]:
   354   shows "a * b = 0 \<longleftrightarrow> (a = 0 \<or> b = 0)"
   355 proof (cases "a = 0 \<or> b = 0")
   356   case False then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   357     then show ?thesis using no_zero_divisors by simp
   358 next
   359   case True then show ?thesis by auto
   360 qed
   361 
   362 text{*Cancellation of equalities with a common factor*}
   363 lemma mult_cancel_right [simp]:
   364   "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b"
   365 proof -
   366   have "(a * c = b * c) = ((a - b) * c = 0)"
   367     by (simp add: algebra_simps)
   368   thus ?thesis by (simp add: disj_commute)
   369 qed
   370 
   371 lemma mult_cancel_left [simp]:
   372   "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b"
   373 proof -
   374   have "(c * a = c * b) = (c * (a - b) = 0)"
   375     by (simp add: algebra_simps)
   376   thus ?thesis by simp
   377 qed
   378 
   379 lemma mult_left_cancel: "c \<noteq> 0 \<Longrightarrow> (c*a=c*b) = (a=b)"
   380 by simp 
   381 
   382 lemma mult_right_cancel: "c \<noteq> 0 \<Longrightarrow> (a*c=b*c) = (a=b)"
   383 by simp 
   384 
   385 end
   386 
   387 class ring_1_no_zero_divisors = ring_1 + ring_no_zero_divisors
   388 begin
   389 
   390 lemma square_eq_1_iff:
   391   "x * x = 1 \<longleftrightarrow> x = 1 \<or> x = - 1"
   392 proof -
   393   have "(x - 1) * (x + 1) = x * x - 1"
   394     by (simp add: algebra_simps)
   395   hence "x * x = 1 \<longleftrightarrow> (x - 1) * (x + 1) = 0"
   396     by simp
   397   thus ?thesis
   398     by (simp add: eq_neg_iff_add_eq_0)
   399 qed
   400 
   401 lemma mult_cancel_right1 [simp]:
   402   "c = b * c \<longleftrightarrow> c = 0 \<or> b = 1"
   403 by (insert mult_cancel_right [of 1 c b], force)
   404 
   405 lemma mult_cancel_right2 [simp]:
   406   "a * c = c \<longleftrightarrow> c = 0 \<or> a = 1"
   407 by (insert mult_cancel_right [of a c 1], simp)
   408  
   409 lemma mult_cancel_left1 [simp]:
   410   "c = c * b \<longleftrightarrow> c = 0 \<or> b = 1"
   411 by (insert mult_cancel_left [of c 1 b], force)
   412 
   413 lemma mult_cancel_left2 [simp]:
   414   "c * a = c \<longleftrightarrow> c = 0 \<or> a = 1"
   415 by (insert mult_cancel_left [of c a 1], simp)
   416 
   417 end
   418 
   419 class idom = comm_ring_1 + no_zero_divisors
   420 begin
   421 
   422 subclass ring_1_no_zero_divisors ..
   423 
   424 lemma square_eq_iff: "a * a = b * b \<longleftrightarrow> (a = b \<or> a = - b)"
   425 proof
   426   assume "a * a = b * b"
   427   then have "(a - b) * (a + b) = 0"
   428     by (simp add: algebra_simps)
   429   then show "a = b \<or> a = - b"
   430     by (simp add: eq_neg_iff_add_eq_0)
   431 next
   432   assume "a = b \<or> a = - b"
   433   then show "a * a = b * b" by auto
   434 qed
   435 
   436 lemma dvd_mult_cancel_right [simp]:
   437   "a * c dvd b * c \<longleftrightarrow> c = 0 \<or> a dvd b"
   438 proof -
   439   have "a * c dvd b * c \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   440     unfolding dvd_def by (simp add: mult_ac)
   441   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   442     unfolding dvd_def by simp
   443   finally show ?thesis .
   444 qed
   445 
   446 lemma dvd_mult_cancel_left [simp]:
   447   "c * a dvd c * b \<longleftrightarrow> c = 0 \<or> a dvd b"
   448 proof -
   449   have "c * a dvd c * b \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   450     unfolding dvd_def by (simp add: mult_ac)
   451   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   452     unfolding dvd_def by simp
   453   finally show ?thesis .
   454 qed
   455 
   456 end
   457 
   458 text {*
   459   The theory of partially ordered rings is taken from the books:
   460   \begin{itemize}
   461   \item \emph{Lattice Theory} by Garret Birkhoff, American Mathematical Society 1979 
   462   \item \emph{Partially Ordered Algebraic Systems}, Pergamon Press 1963
   463   \end{itemize}
   464   Most of the used notions can also be looked up in 
   465   \begin{itemize}
   466   \item @{url "http://www.mathworld.com"} by Eric Weisstein et. al.
   467   \item \emph{Algebra I} by van der Waerden, Springer.
   468   \end{itemize}
   469 *}
   470 
   471 class ordered_semiring = semiring + comm_monoid_add + ordered_ab_semigroup_add +
   472   assumes mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
   473   assumes mult_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * c"
   474 begin
   475 
   476 lemma mult_mono:
   477   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   478 apply (erule mult_right_mono [THEN order_trans], assumption)
   479 apply (erule mult_left_mono, assumption)
   480 done
   481 
   482 lemma mult_mono':
   483   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   484 apply (rule mult_mono)
   485 apply (fast intro: order_trans)+
   486 done
   487 
   488 end
   489 
   490 class ordered_cancel_semiring = ordered_semiring + cancel_comm_monoid_add
   491 begin
   492 
   493 subclass semiring_0_cancel ..
   494 
   495 lemma mult_nonneg_nonneg[simp]: "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> a * b"
   496 using mult_left_mono [of 0 b a] by simp
   497 
   498 lemma mult_nonneg_nonpos: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> a * b \<le> 0"
   499 using mult_left_mono [of b 0 a] by simp
   500 
   501 lemma mult_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> b \<Longrightarrow> a * b \<le> 0"
   502 using mult_right_mono [of a 0 b] by simp
   503 
   504 text {* Legacy - use @{text mult_nonpos_nonneg} *}
   505 lemma mult_nonneg_nonpos2: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> b * a \<le> 0" 
   506 by (drule mult_right_mono [of b 0], auto)
   507 
   508 lemma split_mult_neg_le: "(0 \<le> a & b \<le> 0) | (a \<le> 0 & 0 \<le> b) \<Longrightarrow> a * b \<le> 0" 
   509 by (auto simp add: mult_nonneg_nonpos mult_nonneg_nonpos2)
   510 
   511 end
   512 
   513 class linordered_semiring = ordered_semiring + linordered_cancel_ab_semigroup_add
   514 begin
   515 
   516 subclass ordered_cancel_semiring ..
   517 
   518 subclass ordered_comm_monoid_add ..
   519 
   520 lemma mult_left_less_imp_less:
   521   "c * a < c * b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   522 by (force simp add: mult_left_mono not_le [symmetric])
   523  
   524 lemma mult_right_less_imp_less:
   525   "a * c < b * c \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   526 by (force simp add: mult_right_mono not_le [symmetric])
   527 
   528 end
   529 
   530 class linordered_semiring_1 = linordered_semiring + semiring_1
   531 begin
   532 
   533 lemma convex_bound_le:
   534   assumes "x \<le> a" "y \<le> a" "0 \<le> u" "0 \<le> v" "u + v = 1"
   535   shows "u * x + v * y \<le> a"
   536 proof-
   537   from assms have "u * x + v * y \<le> u * a + v * a"
   538     by (simp add: add_mono mult_left_mono)
   539   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
   540 qed
   541 
   542 end
   543 
   544 class linordered_semiring_strict = semiring + comm_monoid_add + linordered_cancel_ab_semigroup_add +
   545   assumes mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   546   assumes mult_strict_right_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> a * c < b * c"
   547 begin
   548 
   549 subclass semiring_0_cancel ..
   550 
   551 subclass linordered_semiring
   552 proof
   553   fix a b c :: 'a
   554   assume A: "a \<le> b" "0 \<le> c"
   555   from A show "c * a \<le> c * b"
   556     unfolding le_less
   557     using mult_strict_left_mono by (cases "c = 0") auto
   558   from A show "a * c \<le> b * c"
   559     unfolding le_less
   560     using mult_strict_right_mono by (cases "c = 0") auto
   561 qed
   562 
   563 lemma mult_left_le_imp_le:
   564   "c * a \<le> c * b \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   565 by (force simp add: mult_strict_left_mono _not_less [symmetric])
   566  
   567 lemma mult_right_le_imp_le:
   568   "a * c \<le> b * c \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   569 by (force simp add: mult_strict_right_mono not_less [symmetric])
   570 
   571 lemma mult_pos_pos[simp]: "0 < a \<Longrightarrow> 0 < b \<Longrightarrow> 0 < a * b"
   572 using mult_strict_left_mono [of 0 b a] by simp
   573 
   574 lemma mult_pos_neg: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> a * b < 0"
   575 using mult_strict_left_mono [of b 0 a] by simp
   576 
   577 lemma mult_neg_pos: "a < 0 \<Longrightarrow> 0 < b \<Longrightarrow> a * b < 0"
   578 using mult_strict_right_mono [of a 0 b] by simp
   579 
   580 text {* Legacy - use @{text mult_neg_pos} *}
   581 lemma mult_pos_neg2: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> b * a < 0" 
   582 by (drule mult_strict_right_mono [of b 0], auto)
   583 
   584 lemma zero_less_mult_pos:
   585   "0 < a * b \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
   586 apply (cases "b\<le>0")
   587  apply (auto simp add: le_less not_less)
   588 apply (drule_tac mult_pos_neg [of a b])
   589  apply (auto dest: less_not_sym)
   590 done
   591 
   592 lemma zero_less_mult_pos2:
   593   "0 < b * a \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
   594 apply (cases "b\<le>0")
   595  apply (auto simp add: le_less not_less)
   596 apply (drule_tac mult_pos_neg2 [of a b])
   597  apply (auto dest: less_not_sym)
   598 done
   599 
   600 text{*Strict monotonicity in both arguments*}
   601 lemma mult_strict_mono:
   602   assumes "a < b" and "c < d" and "0 < b" and "0 \<le> c"
   603   shows "a * c < b * d"
   604   using assms apply (cases "c=0")
   605   apply (simp)
   606   apply (erule mult_strict_right_mono [THEN less_trans])
   607   apply (force simp add: le_less)
   608   apply (erule mult_strict_left_mono, assumption)
   609   done
   610 
   611 text{*This weaker variant has more natural premises*}
   612 lemma mult_strict_mono':
   613   assumes "a < b" and "c < d" and "0 \<le> a" and "0 \<le> c"
   614   shows "a * c < b * d"
   615 by (rule mult_strict_mono) (insert assms, auto)
   616 
   617 lemma mult_less_le_imp_less:
   618   assumes "a < b" and "c \<le> d" and "0 \<le> a" and "0 < c"
   619   shows "a * c < b * d"
   620   using assms apply (subgoal_tac "a * c < b * c")
   621   apply (erule less_le_trans)
   622   apply (erule mult_left_mono)
   623   apply simp
   624   apply (erule mult_strict_right_mono)
   625   apply assumption
   626   done
   627 
   628 lemma mult_le_less_imp_less:
   629   assumes "a \<le> b" and "c < d" and "0 < a" and "0 \<le> c"
   630   shows "a * c < b * d"
   631   using assms apply (subgoal_tac "a * c \<le> b * c")
   632   apply (erule le_less_trans)
   633   apply (erule mult_strict_left_mono)
   634   apply simp
   635   apply (erule mult_right_mono)
   636   apply simp
   637   done
   638 
   639 lemma mult_less_imp_less_left:
   640   assumes less: "c * a < c * b" and nonneg: "0 \<le> c"
   641   shows "a < b"
   642 proof (rule ccontr)
   643   assume "\<not>  a < b"
   644   hence "b \<le> a" by (simp add: linorder_not_less)
   645   hence "c * b \<le> c * a" using nonneg by (rule mult_left_mono)
   646   with this and less show False by (simp add: not_less [symmetric])
   647 qed
   648 
   649 lemma mult_less_imp_less_right:
   650   assumes less: "a * c < b * c" and nonneg: "0 \<le> c"
   651   shows "a < b"
   652 proof (rule ccontr)
   653   assume "\<not> a < b"
   654   hence "b \<le> a" by (simp add: linorder_not_less)
   655   hence "b * c \<le> a * c" using nonneg by (rule mult_right_mono)
   656   with this and less show False by (simp add: not_less [symmetric])
   657 qed  
   658 
   659 end
   660 
   661 class linordered_semiring_1_strict = linordered_semiring_strict + semiring_1
   662 begin
   663 
   664 subclass linordered_semiring_1 ..
   665 
   666 lemma convex_bound_lt:
   667   assumes "x < a" "y < a" "0 \<le> u" "0 \<le> v" "u + v = 1"
   668   shows "u * x + v * y < a"
   669 proof -
   670   from assms have "u * x + v * y < u * a + v * a"
   671     by (cases "u = 0")
   672        (auto intro!: add_less_le_mono mult_strict_left_mono mult_left_mono)
   673   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
   674 qed
   675 
   676 end
   677 
   678 class ordered_comm_semiring = comm_semiring_0 + ordered_ab_semigroup_add + 
   679   assumes comm_mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
   680 begin
   681 
   682 subclass ordered_semiring
   683 proof
   684   fix a b c :: 'a
   685   assume "a \<le> b" "0 \<le> c"
   686   thus "c * a \<le> c * b" by (rule comm_mult_left_mono)
   687   thus "a * c \<le> b * c" by (simp only: mult.commute)
   688 qed
   689 
   690 end
   691 
   692 class ordered_cancel_comm_semiring = ordered_comm_semiring + cancel_comm_monoid_add
   693 begin
   694 
   695 subclass comm_semiring_0_cancel ..
   696 subclass ordered_comm_semiring ..
   697 subclass ordered_cancel_semiring ..
   698 
   699 end
   700 
   701 class linordered_comm_semiring_strict = comm_semiring_0 + linordered_cancel_ab_semigroup_add +
   702   assumes comm_mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   703 begin
   704 
   705 subclass linordered_semiring_strict
   706 proof
   707   fix a b c :: 'a
   708   assume "a < b" "0 < c"
   709   thus "c * a < c * b" by (rule comm_mult_strict_left_mono)
   710   thus "a * c < b * c" by (simp only: mult.commute)
   711 qed
   712 
   713 subclass ordered_cancel_comm_semiring
   714 proof
   715   fix a b c :: 'a
   716   assume "a \<le> b" "0 \<le> c"
   717   thus "c * a \<le> c * b"
   718     unfolding le_less
   719     using mult_strict_left_mono by (cases "c = 0") auto
   720 qed
   721 
   722 end
   723 
   724 class ordered_ring = ring + ordered_cancel_semiring 
   725 begin
   726 
   727 subclass ordered_ab_group_add ..
   728 
   729 lemma less_add_iff1:
   730   "a * e + c < b * e + d \<longleftrightarrow> (a - b) * e + c < d"
   731 by (simp add: algebra_simps)
   732 
   733 lemma less_add_iff2:
   734   "a * e + c < b * e + d \<longleftrightarrow> c < (b - a) * e + d"
   735 by (simp add: algebra_simps)
   736 
   737 lemma le_add_iff1:
   738   "a * e + c \<le> b * e + d \<longleftrightarrow> (a - b) * e + c \<le> d"
   739 by (simp add: algebra_simps)
   740 
   741 lemma le_add_iff2:
   742   "a * e + c \<le> b * e + d \<longleftrightarrow> c \<le> (b - a) * e + d"
   743 by (simp add: algebra_simps)
   744 
   745 lemma mult_left_mono_neg:
   746   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c * a \<le> c * b"
   747   apply (drule mult_left_mono [of _ _ "- c"])
   748   apply simp_all
   749   done
   750 
   751 lemma mult_right_mono_neg:
   752   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a * c \<le> b * c"
   753   apply (drule mult_right_mono [of _ _ "- c"])
   754   apply simp_all
   755   done
   756 
   757 lemma mult_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> b \<le> 0 \<Longrightarrow> 0 \<le> a * b"
   758 using mult_right_mono_neg [of a 0 b] by simp
   759 
   760 lemma split_mult_pos_le:
   761   "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a * b"
   762 by (auto simp add: mult_nonpos_nonpos)
   763 
   764 end
   765 
   766 class linordered_ring = ring + linordered_semiring + linordered_ab_group_add + abs_if
   767 begin
   768 
   769 subclass ordered_ring ..
   770 
   771 subclass ordered_ab_group_add_abs
   772 proof
   773   fix a b
   774   show "\<bar>a + b\<bar> \<le> \<bar>a\<bar> + \<bar>b\<bar>"
   775     by (auto simp add: abs_if not_le not_less algebra_simps simp del: add.commute dest: add_neg_neg add_nonneg_nonneg)
   776 qed (auto simp add: abs_if)
   777 
   778 lemma zero_le_square [simp]: "0 \<le> a * a"
   779   using linear [of 0 a]
   780   by (auto simp add: mult_nonpos_nonpos)
   781 
   782 lemma not_square_less_zero [simp]: "\<not> (a * a < 0)"
   783   by (simp add: not_less)
   784 
   785 end
   786 
   787 (* The "strict" suffix can be seen as describing the combination of linordered_ring and no_zero_divisors.
   788    Basically, linordered_ring + no_zero_divisors = linordered_ring_strict.
   789  *)
   790 class linordered_ring_strict = ring + linordered_semiring_strict
   791   + ordered_ab_group_add + abs_if
   792 begin
   793 
   794 subclass linordered_ring ..
   795 
   796 lemma mult_strict_left_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> c * a < c * b"
   797 using mult_strict_left_mono [of b a "- c"] by simp
   798 
   799 lemma mult_strict_right_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> a * c < b * c"
   800 using mult_strict_right_mono [of b a "- c"] by simp
   801 
   802 lemma mult_neg_neg: "a < 0 \<Longrightarrow> b < 0 \<Longrightarrow> 0 < a * b"
   803 using mult_strict_right_mono_neg [of a 0 b] by simp
   804 
   805 subclass ring_no_zero_divisors
   806 proof
   807   fix a b
   808   assume "a \<noteq> 0" then have A: "a < 0 \<or> 0 < a" by (simp add: neq_iff)
   809   assume "b \<noteq> 0" then have B: "b < 0 \<or> 0 < b" by (simp add: neq_iff)
   810   have "a * b < 0 \<or> 0 < a * b"
   811   proof (cases "a < 0")
   812     case True note A' = this
   813     show ?thesis proof (cases "b < 0")
   814       case True with A'
   815       show ?thesis by (auto dest: mult_neg_neg)
   816     next
   817       case False with B have "0 < b" by auto
   818       with A' show ?thesis by (auto dest: mult_strict_right_mono)
   819     qed
   820   next
   821     case False with A have A': "0 < a" by auto
   822     show ?thesis proof (cases "b < 0")
   823       case True with A'
   824       show ?thesis by (auto dest: mult_strict_right_mono_neg)
   825     next
   826       case False with B have "0 < b" by auto
   827       with A' show ?thesis by auto
   828     qed
   829   qed
   830   then show "a * b \<noteq> 0" by (simp add: neq_iff)
   831 qed
   832 
   833 lemma zero_less_mult_iff: "0 < a * b \<longleftrightarrow> 0 < a \<and> 0 < b \<or> a < 0 \<and> b < 0"
   834   by (cases a 0 b 0 rule: linorder_cases[case_product linorder_cases])
   835      (auto simp add: mult_neg_neg not_less le_less dest: zero_less_mult_pos zero_less_mult_pos2)
   836 
   837 lemma zero_le_mult_iff: "0 \<le> a * b \<longleftrightarrow> 0 \<le> a \<and> 0 \<le> b \<or> a \<le> 0 \<and> b \<le> 0"
   838   by (auto simp add: eq_commute [of 0] le_less not_less zero_less_mult_iff)
   839 
   840 lemma mult_less_0_iff:
   841   "a * b < 0 \<longleftrightarrow> 0 < a \<and> b < 0 \<or> a < 0 \<and> 0 < b"
   842   apply (insert zero_less_mult_iff [of "-a" b])
   843   apply force
   844   done
   845 
   846 lemma mult_le_0_iff:
   847   "a * b \<le> 0 \<longleftrightarrow> 0 \<le> a \<and> b \<le> 0 \<or> a \<le> 0 \<and> 0 \<le> b"
   848   apply (insert zero_le_mult_iff [of "-a" b]) 
   849   apply force
   850   done
   851 
   852 text{*Cancellation laws for @{term "c*a < c*b"} and @{term "a*c < b*c"},
   853    also with the relations @{text "\<le>"} and equality.*}
   854 
   855 text{*These ``disjunction'' versions produce two cases when the comparison is
   856  an assumption, but effectively four when the comparison is a goal.*}
   857 
   858 lemma mult_less_cancel_right_disj:
   859   "a * c < b * c \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
   860   apply (cases "c = 0")
   861   apply (auto simp add: neq_iff mult_strict_right_mono 
   862                       mult_strict_right_mono_neg)
   863   apply (auto simp add: not_less 
   864                       not_le [symmetric, of "a*c"]
   865                       not_le [symmetric, of a])
   866   apply (erule_tac [!] notE)
   867   apply (auto simp add: less_imp_le mult_right_mono 
   868                       mult_right_mono_neg)
   869   done
   870 
   871 lemma mult_less_cancel_left_disj:
   872   "c * a < c * b \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
   873   apply (cases "c = 0")
   874   apply (auto simp add: neq_iff mult_strict_left_mono 
   875                       mult_strict_left_mono_neg)
   876   apply (auto simp add: not_less 
   877                       not_le [symmetric, of "c*a"]
   878                       not_le [symmetric, of a])
   879   apply (erule_tac [!] notE)
   880   apply (auto simp add: less_imp_le mult_left_mono 
   881                       mult_left_mono_neg)
   882   done
   883 
   884 text{*The ``conjunction of implication'' lemmas produce two cases when the
   885 comparison is a goal, but give four when the comparison is an assumption.*}
   886 
   887 lemma mult_less_cancel_right:
   888   "a * c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
   889   using mult_less_cancel_right_disj [of a c b] by auto
   890 
   891 lemma mult_less_cancel_left:
   892   "c * a < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
   893   using mult_less_cancel_left_disj [of c a b] by auto
   894 
   895 lemma mult_le_cancel_right:
   896    "a * c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   897 by (simp add: not_less [symmetric] mult_less_cancel_right_disj)
   898 
   899 lemma mult_le_cancel_left:
   900   "c * a \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   901 by (simp add: not_less [symmetric] mult_less_cancel_left_disj)
   902 
   903 lemma mult_le_cancel_left_pos:
   904   "0 < c \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> a \<le> b"
   905 by (auto simp: mult_le_cancel_left)
   906 
   907 lemma mult_le_cancel_left_neg:
   908   "c < 0 \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> b \<le> a"
   909 by (auto simp: mult_le_cancel_left)
   910 
   911 lemma mult_less_cancel_left_pos:
   912   "0 < c \<Longrightarrow> c * a < c * b \<longleftrightarrow> a < b"
   913 by (auto simp: mult_less_cancel_left)
   914 
   915 lemma mult_less_cancel_left_neg:
   916   "c < 0 \<Longrightarrow> c * a < c * b \<longleftrightarrow> b < a"
   917 by (auto simp: mult_less_cancel_left)
   918 
   919 end
   920 
   921 lemmas mult_sign_intros =
   922   mult_nonneg_nonneg mult_nonneg_nonpos
   923   mult_nonpos_nonneg mult_nonpos_nonpos
   924   mult_pos_pos mult_pos_neg
   925   mult_neg_pos mult_neg_neg
   926 
   927 class ordered_comm_ring = comm_ring + ordered_comm_semiring
   928 begin
   929 
   930 subclass ordered_ring ..
   931 subclass ordered_cancel_comm_semiring ..
   932 
   933 end
   934 
   935 class linordered_semidom = comm_semiring_1_cancel + linordered_comm_semiring_strict +
   936   (*previously linordered_semiring*)
   937   assumes zero_less_one [simp]: "0 < 1"
   938 begin
   939 
   940 lemma pos_add_strict:
   941   shows "0 < a \<Longrightarrow> b < c \<Longrightarrow> b < a + c"
   942   using add_strict_mono [of 0 a b c] by simp
   943 
   944 lemma zero_le_one [simp]: "0 \<le> 1"
   945 by (rule zero_less_one [THEN less_imp_le]) 
   946 
   947 lemma not_one_le_zero [simp]: "\<not> 1 \<le> 0"
   948 by (simp add: not_le) 
   949 
   950 lemma not_one_less_zero [simp]: "\<not> 1 < 0"
   951 by (simp add: not_less) 
   952 
   953 lemma less_1_mult:
   954   assumes "1 < m" and "1 < n"
   955   shows "1 < m * n"
   956   using assms mult_strict_mono [of 1 m 1 n]
   957     by (simp add:  less_trans [OF zero_less_one]) 
   958 
   959 end
   960 
   961 class linordered_idom = comm_ring_1 +
   962   linordered_comm_semiring_strict + ordered_ab_group_add +
   963   abs_if + sgn_if
   964   (*previously linordered_ring*)
   965 begin
   966 
   967 subclass linordered_semiring_1_strict ..
   968 subclass linordered_ring_strict ..
   969 subclass ordered_comm_ring ..
   970 subclass idom ..
   971 
   972 subclass linordered_semidom
   973 proof
   974   have "0 \<le> 1 * 1" by (rule zero_le_square)
   975   thus "0 < 1" by (simp add: le_less)
   976 qed 
   977 
   978 lemma linorder_neqE_linordered_idom:
   979   assumes "x \<noteq> y" obtains "x < y" | "y < x"
   980   using assms by (rule neqE)
   981 
   982 text {* These cancellation simprules also produce two cases when the comparison is a goal. *}
   983 
   984 lemma mult_le_cancel_right1:
   985   "c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
   986 by (insert mult_le_cancel_right [of 1 c b], simp)
   987 
   988 lemma mult_le_cancel_right2:
   989   "a * c \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
   990 by (insert mult_le_cancel_right [of a c 1], simp)
   991 
   992 lemma mult_le_cancel_left1:
   993   "c \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
   994 by (insert mult_le_cancel_left [of c 1 b], simp)
   995 
   996 lemma mult_le_cancel_left2:
   997   "c * a \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
   998 by (insert mult_le_cancel_left [of c a 1], simp)
   999 
  1000 lemma mult_less_cancel_right1:
  1001   "c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1002 by (insert mult_less_cancel_right [of 1 c b], simp)
  1003 
  1004 lemma mult_less_cancel_right2:
  1005   "a * c < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1006 by (insert mult_less_cancel_right [of a c 1], simp)
  1007 
  1008 lemma mult_less_cancel_left1:
  1009   "c < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1010 by (insert mult_less_cancel_left [of c 1 b], simp)
  1011 
  1012 lemma mult_less_cancel_left2:
  1013   "c * a < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1014 by (insert mult_less_cancel_left [of c a 1], simp)
  1015 
  1016 lemma sgn_sgn [simp]:
  1017   "sgn (sgn a) = sgn a"
  1018 unfolding sgn_if by simp
  1019 
  1020 lemma sgn_0_0:
  1021   "sgn a = 0 \<longleftrightarrow> a = 0"
  1022 unfolding sgn_if by simp
  1023 
  1024 lemma sgn_1_pos:
  1025   "sgn a = 1 \<longleftrightarrow> a > 0"
  1026 unfolding sgn_if by simp
  1027 
  1028 lemma sgn_1_neg:
  1029   "sgn a = - 1 \<longleftrightarrow> a < 0"
  1030 unfolding sgn_if by auto
  1031 
  1032 lemma sgn_pos [simp]:
  1033   "0 < a \<Longrightarrow> sgn a = 1"
  1034 unfolding sgn_1_pos .
  1035 
  1036 lemma sgn_neg [simp]:
  1037   "a < 0 \<Longrightarrow> sgn a = - 1"
  1038 unfolding sgn_1_neg .
  1039 
  1040 lemma sgn_times:
  1041   "sgn (a * b) = sgn a * sgn b"
  1042 by (auto simp add: sgn_if zero_less_mult_iff)
  1043 
  1044 lemma abs_sgn: "\<bar>k\<bar> = k * sgn k"
  1045 unfolding sgn_if abs_if by auto
  1046 
  1047 lemma sgn_greater [simp]:
  1048   "0 < sgn a \<longleftrightarrow> 0 < a"
  1049   unfolding sgn_if by auto
  1050 
  1051 lemma sgn_less [simp]:
  1052   "sgn a < 0 \<longleftrightarrow> a < 0"
  1053   unfolding sgn_if by auto
  1054 
  1055 lemma abs_dvd_iff [simp]: "\<bar>m\<bar> dvd k \<longleftrightarrow> m dvd k"
  1056   by (simp add: abs_if)
  1057 
  1058 lemma dvd_abs_iff [simp]: "m dvd \<bar>k\<bar> \<longleftrightarrow> m dvd k"
  1059   by (simp add: abs_if)
  1060 
  1061 lemma dvd_if_abs_eq:
  1062   "\<bar>l\<bar> = \<bar>k\<bar> \<Longrightarrow> l dvd k"
  1063 by(subst abs_dvd_iff[symmetric]) simp
  1064 
  1065 text {* The following lemmas can be proven in more general structures, but
  1066 are dangerous as simp rules in absence of @{thm neg_equal_zero}, 
  1067 @{thm neg_less_pos}, @{thm neg_less_eq_nonneg}. *}
  1068 
  1069 lemma equation_minus_iff_1 [simp, no_atp]:
  1070   "1 = - a \<longleftrightarrow> a = - 1"
  1071   by (fact equation_minus_iff)
  1072 
  1073 lemma minus_equation_iff_1 [simp, no_atp]:
  1074   "- a = 1 \<longleftrightarrow> a = - 1"
  1075   by (subst minus_equation_iff, auto)
  1076 
  1077 lemma le_minus_iff_1 [simp, no_atp]:
  1078   "1 \<le> - b \<longleftrightarrow> b \<le> - 1"
  1079   by (fact le_minus_iff)
  1080 
  1081 lemma minus_le_iff_1 [simp, no_atp]:
  1082   "- a \<le> 1 \<longleftrightarrow> - 1 \<le> a"
  1083   by (fact minus_le_iff)
  1084 
  1085 lemma less_minus_iff_1 [simp, no_atp]:
  1086   "1 < - b \<longleftrightarrow> b < - 1"
  1087   by (fact less_minus_iff)
  1088 
  1089 lemma minus_less_iff_1 [simp, no_atp]:
  1090   "- a < 1 \<longleftrightarrow> - 1 < a"
  1091   by (fact minus_less_iff)
  1092 
  1093 end
  1094 
  1095 text {* Simprules for comparisons where common factors can be cancelled. *}
  1096 
  1097 lemmas mult_compare_simps =
  1098     mult_le_cancel_right mult_le_cancel_left
  1099     mult_le_cancel_right1 mult_le_cancel_right2
  1100     mult_le_cancel_left1 mult_le_cancel_left2
  1101     mult_less_cancel_right mult_less_cancel_left
  1102     mult_less_cancel_right1 mult_less_cancel_right2
  1103     mult_less_cancel_left1 mult_less_cancel_left2
  1104     mult_cancel_right mult_cancel_left
  1105     mult_cancel_right1 mult_cancel_right2
  1106     mult_cancel_left1 mult_cancel_left2
  1107 
  1108 text {* Reasoning about inequalities with division *}
  1109 
  1110 context linordered_semidom
  1111 begin
  1112 
  1113 lemma less_add_one: "a < a + 1"
  1114 proof -
  1115   have "a + 0 < a + 1"
  1116     by (blast intro: zero_less_one add_strict_left_mono)
  1117   thus ?thesis by simp
  1118 qed
  1119 
  1120 lemma zero_less_two: "0 < 1 + 1"
  1121 by (blast intro: less_trans zero_less_one less_add_one)
  1122 
  1123 end
  1124 
  1125 context linordered_idom
  1126 begin
  1127 
  1128 lemma mult_right_le_one_le:
  1129   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> x * y \<le> x"
  1130   by (auto simp add: mult_le_cancel_left2)
  1131 
  1132 lemma mult_left_le_one_le:
  1133   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> y * x \<le> x"
  1134   by (auto simp add: mult_le_cancel_right2)
  1135 
  1136 end
  1137 
  1138 text {* Absolute Value *}
  1139 
  1140 context linordered_idom
  1141 begin
  1142 
  1143 lemma mult_sgn_abs:
  1144   "sgn x * \<bar>x\<bar> = x"
  1145   unfolding abs_if sgn_if by auto
  1146 
  1147 lemma abs_one [simp]:
  1148   "\<bar>1\<bar> = 1"
  1149   by (simp add: abs_if)
  1150 
  1151 end
  1152 
  1153 class ordered_ring_abs = ordered_ring + ordered_ab_group_add_abs +
  1154   assumes abs_eq_mult:
  1155     "(0 \<le> a \<or> a \<le> 0) \<and> (0 \<le> b \<or> b \<le> 0) \<Longrightarrow> \<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>"
  1156 
  1157 context linordered_idom
  1158 begin
  1159 
  1160 subclass ordered_ring_abs proof
  1161 qed (auto simp add: abs_if not_less mult_less_0_iff)
  1162 
  1163 lemma abs_mult:
  1164   "\<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>" 
  1165   by (rule abs_eq_mult) auto
  1166 
  1167 lemma abs_mult_self:
  1168   "\<bar>a\<bar> * \<bar>a\<bar> = a * a"
  1169   by (simp add: abs_if) 
  1170 
  1171 lemma abs_mult_less:
  1172   "\<bar>a\<bar> < c \<Longrightarrow> \<bar>b\<bar> < d \<Longrightarrow> \<bar>a\<bar> * \<bar>b\<bar> < c * d"
  1173 proof -
  1174   assume ac: "\<bar>a\<bar> < c"
  1175   hence cpos: "0<c" by (blast intro: le_less_trans abs_ge_zero)
  1176   assume "\<bar>b\<bar> < d"
  1177   thus ?thesis by (simp add: ac cpos mult_strict_mono) 
  1178 qed
  1179 
  1180 lemma abs_less_iff:
  1181   "\<bar>a\<bar> < b \<longleftrightarrow> a < b \<and> - a < b" 
  1182   by (simp add: less_le abs_le_iff) (auto simp add: abs_if)
  1183 
  1184 lemma abs_mult_pos:
  1185   "0 \<le> x \<Longrightarrow> \<bar>y\<bar> * x = \<bar>y * x\<bar>"
  1186   by (simp add: abs_mult)
  1187 
  1188 lemma abs_diff_less_iff:
  1189   "\<bar>x - a\<bar> < r \<longleftrightarrow> a - r < x \<and> x < a + r"
  1190   by (auto simp add: diff_less_eq ac_simps abs_less_iff)
  1191 
  1192 end
  1193 
  1194 code_identifier
  1195   code_module Rings \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1196 
  1197 end
  1198