src/HOL/Hilbert_Choice.thy
author wenzelm
Wed Dec 05 03:07:44 2001 +0100 (2001-12-05)
changeset 12372 cd3a09c7dac9
parent 12298 b344486c33e2
child 13585 db4005b40cc6
permissions -rw-r--r--
tuned declarations;
     1 (*  Title:      HOL/Hilbert_Choice.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson
     4     Copyright   2001  University of Cambridge
     5 *)
     6 
     7 header {* Hilbert's epsilon-operator and everything to do with the Axiom of Choice *}
     8 
     9 theory Hilbert_Choice = NatArith
    10 files ("Hilbert_Choice_lemmas.ML") ("meson_lemmas.ML") ("Tools/meson.ML"):
    11 
    12 
    13 subsection {* Hilbert's epsilon *}
    14 
    15 consts
    16   Eps           :: "('a => bool) => 'a"
    17 
    18 syntax (input)
    19   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3\<epsilon>_./ _)" [0, 10] 10)
    20 syntax (HOL)
    21   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3@ _./ _)" [0, 10] 10)
    22 syntax
    23   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3SOME _./ _)" [0, 10] 10)
    24 translations
    25   "SOME x. P" == "Eps (%x. P)"
    26 
    27 axioms
    28   someI: "P (x::'a) ==> P (SOME x. P x)"
    29 
    30 
    31 constdefs
    32   inv :: "('a => 'b) => ('b => 'a)"
    33   "inv(f :: 'a => 'b) == %y. SOME x. f x = y"
    34 
    35   Inv :: "'a set => ('a => 'b) => ('b => 'a)"
    36   "Inv A f == %x. SOME y. y : A & f y = x"
    37 
    38 
    39 use "Hilbert_Choice_lemmas.ML"
    40 declare someI_ex [elim?];
    41 
    42 
    43 lemma tfl_some: "\<forall>P x. P x --> P (Eps P)"
    44   -- {* dynamically-scoped fact for TFL *}
    45   by (blast intro: someI)
    46 
    47 
    48 subsection {* Least value operator *}
    49 
    50 constdefs
    51   LeastM :: "['a => 'b::ord, 'a => bool] => 'a"
    52   "LeastM m P == SOME x. P x & (ALL y. P y --> m x <= m y)"
    53 
    54 syntax
    55   "_LeastM" :: "[pttrn, 'a => 'b::ord, bool] => 'a"    ("LEAST _ WRT _. _" [0, 4, 10] 10)
    56 translations
    57   "LEAST x WRT m. P" == "LeastM m (%x. P)"
    58 
    59 lemma LeastMI2:
    60   "P x ==> (!!y. P y ==> m x <= m y)
    61     ==> (!!x. P x ==> \<forall>y. P y --> m x \<le> m y ==> Q x)
    62     ==> Q (LeastM m P)"
    63   apply (unfold LeastM_def)
    64   apply (rule someI2_ex)
    65    apply blast
    66   apply blast
    67   done
    68 
    69 lemma LeastM_equality:
    70   "P k ==> (!!x. P x ==> m k <= m x)
    71     ==> m (LEAST x WRT m. P x) = (m k::'a::order)"
    72   apply (rule LeastMI2)
    73     apply assumption
    74    apply blast
    75   apply (blast intro!: order_antisym)
    76   done
    77 
    78 lemma wf_linord_ex_has_least:
    79   "wf r ==> ALL x y. ((x,y):r^+) = ((y,x)~:r^*) ==> P k
    80     ==> EX x. P x & (!y. P y --> (m x,m y):r^*)"
    81   apply (drule wf_trancl [THEN wf_eq_minimal [THEN iffD1]])
    82   apply (drule_tac x = "m`Collect P" in spec)
    83   apply force
    84   done
    85 
    86 lemma ex_has_least_nat:
    87     "P k ==> EX x. P x & (ALL y. P y --> m x <= (m y::nat))"
    88   apply (simp only: pred_nat_trancl_eq_le [symmetric])
    89   apply (rule wf_pred_nat [THEN wf_linord_ex_has_least])
    90    apply (simp add: less_eq not_le_iff_less pred_nat_trancl_eq_le)
    91   apply assumption
    92   done
    93 
    94 lemma LeastM_nat_lemma:
    95     "P k ==> P (LeastM m P) & (ALL y. P y --> m (LeastM m P) <= (m y::nat))"
    96   apply (unfold LeastM_def)
    97   apply (rule someI_ex)
    98   apply (erule ex_has_least_nat)
    99   done
   100 
   101 lemmas LeastM_natI = LeastM_nat_lemma [THEN conjunct1, standard]
   102 
   103 lemma LeastM_nat_le: "P x ==> m (LeastM m P) <= (m x::nat)"
   104   apply (rule LeastM_nat_lemma [THEN conjunct2, THEN spec, THEN mp])
   105    apply assumption
   106   apply assumption
   107   done
   108 
   109 
   110 subsection {* Greatest value operator *}
   111 
   112 constdefs
   113   GreatestM :: "['a => 'b::ord, 'a => bool] => 'a"
   114   "GreatestM m P == SOME x. P x & (ALL y. P y --> m y <= m x)"
   115 
   116   Greatest :: "('a::ord => bool) => 'a"    (binder "GREATEST " 10)
   117   "Greatest == GreatestM (%x. x)"
   118 
   119 syntax
   120   "_GreatestM" :: "[pttrn, 'a=>'b::ord, bool] => 'a"
   121       ("GREATEST _ WRT _. _" [0, 4, 10] 10)
   122 
   123 translations
   124   "GREATEST x WRT m. P" == "GreatestM m (%x. P)"
   125 
   126 lemma GreatestMI2:
   127   "P x ==> (!!y. P y ==> m y <= m x)
   128     ==> (!!x. P x ==> \<forall>y. P y --> m y \<le> m x ==> Q x)
   129     ==> Q (GreatestM m P)"
   130   apply (unfold GreatestM_def)
   131   apply (rule someI2_ex)
   132    apply blast
   133   apply blast
   134   done
   135 
   136 lemma GreatestM_equality:
   137  "P k ==> (!!x. P x ==> m x <= m k)
   138     ==> m (GREATEST x WRT m. P x) = (m k::'a::order)"
   139   apply (rule_tac m = m in GreatestMI2)
   140     apply assumption
   141    apply blast
   142   apply (blast intro!: order_antisym)
   143   done
   144 
   145 lemma Greatest_equality:
   146   "P (k::'a::order) ==> (!!x. P x ==> x <= k) ==> (GREATEST x. P x) = k"
   147   apply (unfold Greatest_def)
   148   apply (erule GreatestM_equality)
   149   apply blast
   150   done
   151 
   152 lemma ex_has_greatest_nat_lemma:
   153   "P k ==> ALL x. P x --> (EX y. P y & ~ ((m y::nat) <= m x))
   154     ==> EX y. P y & ~ (m y < m k + n)"
   155   apply (induct_tac n)
   156    apply force
   157   apply (force simp add: le_Suc_eq)
   158   done
   159 
   160 lemma ex_has_greatest_nat:
   161   "P k ==> ALL y. P y --> m y < b
   162     ==> EX x. P x & (ALL y. P y --> (m y::nat) <= m x)"
   163   apply (rule ccontr)
   164   apply (cut_tac P = P and n = "b - m k" in ex_has_greatest_nat_lemma)
   165     apply (subgoal_tac [3] "m k <= b")
   166      apply auto
   167   done
   168 
   169 lemma GreatestM_nat_lemma:
   170   "P k ==> ALL y. P y --> m y < b
   171     ==> P (GreatestM m P) & (ALL y. P y --> (m y::nat) <= m (GreatestM m P))"
   172   apply (unfold GreatestM_def)
   173   apply (rule someI_ex)
   174   apply (erule ex_has_greatest_nat)
   175   apply assumption
   176   done
   177 
   178 lemmas GreatestM_natI = GreatestM_nat_lemma [THEN conjunct1, standard]
   179 
   180 lemma GreatestM_nat_le:
   181   "P x ==> ALL y. P y --> m y < b
   182     ==> (m x::nat) <= m (GreatestM m P)"
   183   apply (blast dest: GreatestM_nat_lemma [THEN conjunct2, THEN spec])
   184   done
   185 
   186 
   187 text {* \medskip Specialization to @{text GREATEST}. *}
   188 
   189 lemma GreatestI: "P (k::nat) ==> ALL y. P y --> y < b ==> P (GREATEST x. P x)"
   190   apply (unfold Greatest_def)
   191   apply (rule GreatestM_natI)
   192    apply auto
   193   done
   194 
   195 lemma Greatest_le:
   196     "P x ==> ALL y. P y --> y < b ==> (x::nat) <= (GREATEST x. P x)"
   197   apply (unfold Greatest_def)
   198   apply (rule GreatestM_nat_le)
   199    apply auto
   200   done
   201 
   202 
   203 subsection {* The Meson proof procedure *}
   204 
   205 subsubsection {* Negation Normal Form *}
   206 
   207 text {* de Morgan laws *}
   208 
   209 lemma meson_not_conjD: "~(P&Q) ==> ~P | ~Q"
   210   and meson_not_disjD: "~(P|Q) ==> ~P & ~Q"
   211   and meson_not_notD: "~~P ==> P"
   212   and meson_not_allD: "!!P. ~(ALL x. P(x)) ==> EX x. ~P(x)"
   213   and meson_not_exD: "!!P. ~(EX x. P(x)) ==> ALL x. ~P(x)"
   214   by fast+
   215 
   216 text {* Removal of @{text "-->"} and @{text "<->"} (positive and
   217 negative occurrences) *}
   218 
   219 lemma meson_imp_to_disjD: "P-->Q ==> ~P | Q"
   220   and meson_not_impD: "~(P-->Q) ==> P & ~Q"
   221   and meson_iff_to_disjD: "P=Q ==> (~P | Q) & (~Q | P)"
   222   and meson_not_iffD: "~(P=Q) ==> (P | Q) & (~P | ~Q)"
   223     -- {* Much more efficient than @{prop "(P & ~Q) | (Q & ~P)"} for computing CNF *}
   224   by fast+
   225 
   226 
   227 subsubsection {* Pulling out the existential quantifiers *}
   228 
   229 text {* Conjunction *}
   230 
   231 lemma meson_conj_exD1: "!!P Q. (EX x. P(x)) & Q ==> EX x. P(x) & Q"
   232   and meson_conj_exD2: "!!P Q. P & (EX x. Q(x)) ==> EX x. P & Q(x)"
   233   by fast+
   234 
   235 
   236 text {* Disjunction *}
   237 
   238 lemma meson_disj_exD: "!!P Q. (EX x. P(x)) | (EX x. Q(x)) ==> EX x. P(x) | Q(x)"
   239   -- {* DO NOT USE with forall-Skolemization: makes fewer schematic variables!! *}
   240   -- {* With ex-Skolemization, makes fewer Skolem constants *}
   241   and meson_disj_exD1: "!!P Q. (EX x. P(x)) | Q ==> EX x. P(x) | Q"
   242   and meson_disj_exD2: "!!P Q. P | (EX x. Q(x)) ==> EX x. P | Q(x)"
   243   by fast+
   244 
   245 
   246 subsubsection {* Generating clauses for the Meson Proof Procedure *}
   247 
   248 text {* Disjunctions *}
   249 
   250 lemma meson_disj_assoc: "(P|Q)|R ==> P|(Q|R)"
   251   and meson_disj_comm: "P|Q ==> Q|P"
   252   and meson_disj_FalseD1: "False|P ==> P"
   253   and meson_disj_FalseD2: "P|False ==> P"
   254   by fast+
   255 
   256 use "meson_lemmas.ML"
   257 use "Tools/meson.ML"
   258 setup meson_setup
   259 
   260 end