src/HOL/Complete_Lattices.thy
author haftmann
Fri Oct 10 19:55:32 2014 +0200 (2014-10-10)
changeset 58646 cd63a4b12a33
parent 57448 159e45728ceb
child 58889 5b7a9633cfa8
permissions -rw-r--r--
specialized specification: avoid trivial instances
     1 (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices *}
     4 
     5 theory Complete_Lattices
     6 imports Fun
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50)
    12 
    13 
    14 subsection {* Syntactic infimum and supremum operations *}
    15 
    16 class Inf =
    17   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    18 begin
    19 
    20 definition INFIMUM :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
    21   INF_def: "INFIMUM A f = \<Sqinter>(f ` A)"
    22 
    23 lemma Inf_image_eq [simp]:
    24   "\<Sqinter>(f ` A) = INFIMUM A f"
    25   by (simp add: INF_def)
    26 
    27 lemma INF_image [simp]:
    28   "INFIMUM (f ` A) g = INFIMUM A (g \<circ> f)"
    29   by (simp only: INF_def image_comp)
    30 
    31 lemma INF_identity_eq [simp]:
    32   "INFIMUM A (\<lambda>x. x) = \<Sqinter>A"
    33   by (simp add: INF_def)
    34 
    35 lemma INF_id_eq [simp]:
    36   "INFIMUM A id = \<Sqinter>A"
    37   by (simp add: id_def)
    38 
    39 lemma INF_cong:
    40   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> INFIMUM A C = INFIMUM B D"
    41   by (simp add: INF_def image_def)
    42 
    43 lemma strong_INF_cong [cong]:
    44   "A = B \<Longrightarrow> (\<And>x. x \<in> B =simp=> C x = D x) \<Longrightarrow> INFIMUM A C = INFIMUM B D"
    45   unfolding simp_implies_def by (fact INF_cong)
    46 
    47 end
    48 
    49 class Sup =
    50   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    51 begin
    52 
    53 definition SUPREMUM :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
    54   SUP_def: "SUPREMUM A f = \<Squnion>(f ` A)"
    55 
    56 lemma Sup_image_eq [simp]:
    57   "\<Squnion>(f ` A) = SUPREMUM A f"
    58   by (simp add: SUP_def)
    59 
    60 lemma SUP_image [simp]:
    61   "SUPREMUM (f ` A) g = SUPREMUM A (g \<circ> f)"
    62   by (simp only: SUP_def image_comp)
    63 
    64 lemma SUP_identity_eq [simp]:
    65   "SUPREMUM A (\<lambda>x. x) = \<Squnion>A"
    66   by (simp add: SUP_def)
    67 
    68 lemma SUP_id_eq [simp]:
    69   "SUPREMUM A id = \<Squnion>A"
    70   by (simp add: id_def)
    71 
    72 lemma SUP_cong:
    73   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> SUPREMUM A C = SUPREMUM B D"
    74   by (simp add: SUP_def image_def)
    75 
    76 lemma strong_SUP_cong [cong]:
    77   "A = B \<Longrightarrow> (\<And>x. x \<in> B =simp=> C x = D x) \<Longrightarrow> SUPREMUM A C = SUPREMUM B D"
    78   unfolding simp_implies_def by (fact SUP_cong)
    79 
    80 end
    81 
    82 text {*
    83   Note: must use names @{const INFIMUM} and @{const SUPREMUM} here instead of
    84   @{text INF} and @{text SUP} to allow the following syntax coexist
    85   with the plain constant names.
    86 *}
    87 
    88 syntax
    89   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
    90   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
    91   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
    92   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
    93 
    94 syntax (xsymbols)
    95   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
    96   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
    97   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
    98   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
    99 
   100 translations
   101   "INF x y. B"   == "INF x. INF y. B"
   102   "INF x. B"     == "CONST INFIMUM CONST UNIV (%x. B)"
   103   "INF x. B"     == "INF x:CONST UNIV. B"
   104   "INF x:A. B"   == "CONST INFIMUM A (%x. B)"
   105   "SUP x y. B"   == "SUP x. SUP y. B"
   106   "SUP x. B"     == "CONST SUPREMUM CONST UNIV (%x. B)"
   107   "SUP x. B"     == "SUP x:CONST UNIV. B"
   108   "SUP x:A. B"   == "CONST SUPREMUM A (%x. B)"
   109 
   110 print_translation {*
   111   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFIMUM} @{syntax_const "_INF"},
   112     Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPREMUM} @{syntax_const "_SUP"}]
   113 *} -- {* to avoid eta-contraction of body *}
   114 
   115 subsection {* Abstract complete lattices *}
   116 
   117 text {* A complete lattice always has a bottom and a top,
   118 so we include them into the following type class,
   119 along with assumptions that define bottom and top
   120 in terms of infimum and supremum. *}
   121 
   122 class complete_lattice = lattice + Inf + Sup + bot + top +
   123   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
   124      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
   125   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
   126      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
   127   assumes Inf_empty [simp]: "\<Sqinter>{} = \<top>"
   128   assumes Sup_empty [simp]: "\<Squnion>{} = \<bottom>"
   129 begin
   130 
   131 subclass bounded_lattice
   132 proof
   133   fix a
   134   show "\<bottom> \<le> a" by (auto intro: Sup_least simp only: Sup_empty [symmetric])
   135   show "a \<le> \<top>" by (auto intro: Inf_greatest simp only: Inf_empty [symmetric])
   136 qed
   137 
   138 lemma dual_complete_lattice:
   139   "class.complete_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   140   by (auto intro!: class.complete_lattice.intro dual_lattice)
   141     (unfold_locales, (fact Inf_empty Sup_empty
   142         Sup_upper Sup_least Inf_lower Inf_greatest)+)
   143 
   144 end
   145 
   146 context complete_lattice
   147 begin
   148 
   149 lemma INF_foundation_dual:
   150   "Sup.SUPREMUM Inf = INFIMUM"
   151   by (simp add: fun_eq_iff Sup.SUP_def)
   152 
   153 lemma SUP_foundation_dual:
   154   "Inf.INFIMUM Sup = SUPREMUM"
   155   by (simp add: fun_eq_iff Inf.INF_def)
   156 
   157 lemma Sup_eqI:
   158   "(\<And>y. y \<in> A \<Longrightarrow> y \<le> x) \<Longrightarrow> (\<And>y. (\<And>z. z \<in> A \<Longrightarrow> z \<le> y) \<Longrightarrow> x \<le> y) \<Longrightarrow> \<Squnion>A = x"
   159   by (blast intro: antisym Sup_least Sup_upper)
   160 
   161 lemma Inf_eqI:
   162   "(\<And>i. i \<in> A \<Longrightarrow> x \<le> i) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> y \<le> i) \<Longrightarrow> y \<le> x) \<Longrightarrow> \<Sqinter>A = x"
   163   by (blast intro: antisym Inf_greatest Inf_lower)
   164 
   165 lemma SUP_eqI:
   166   "(\<And>i. i \<in> A \<Longrightarrow> f i \<le> x) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> f i \<le> y) \<Longrightarrow> x \<le> y) \<Longrightarrow> (\<Squnion>i\<in>A. f i) = x"
   167   using Sup_eqI [of "f ` A" x] by auto
   168 
   169 lemma INF_eqI:
   170   "(\<And>i. i \<in> A \<Longrightarrow> x \<le> f i) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> f i \<ge> y) \<Longrightarrow> x \<ge> y) \<Longrightarrow> (\<Sqinter>i\<in>A. f i) = x"
   171   using Inf_eqI [of "f ` A" x] by auto
   172 
   173 lemma INF_lower: "i \<in> A \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> f i"
   174   using Inf_lower [of _ "f ` A"] by simp
   175 
   176 lemma INF_greatest: "(\<And>i. i \<in> A \<Longrightarrow> u \<sqsubseteq> f i) \<Longrightarrow> u \<sqsubseteq> (\<Sqinter>i\<in>A. f i)"
   177   using Inf_greatest [of "f ` A"] by auto
   178 
   179 lemma SUP_upper: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   180   using Sup_upper [of _ "f ` A"] by simp
   181 
   182 lemma SUP_least: "(\<And>i. i \<in> A \<Longrightarrow> f i \<sqsubseteq> u) \<Longrightarrow> (\<Squnion>i\<in>A. f i) \<sqsubseteq> u"
   183   using Sup_least [of "f ` A"] by auto
   184 
   185 lemma Inf_lower2: "u \<in> A \<Longrightarrow> u \<sqsubseteq> v \<Longrightarrow> \<Sqinter>A \<sqsubseteq> v"
   186   using Inf_lower [of u A] by auto
   187 
   188 lemma INF_lower2: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> u \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> u"
   189   using INF_lower [of i A f] by auto
   190 
   191 lemma Sup_upper2: "u \<in> A \<Longrightarrow> v \<sqsubseteq> u \<Longrightarrow> v \<sqsubseteq> \<Squnion>A"
   192   using Sup_upper [of u A] by auto
   193 
   194 lemma SUP_upper2: "i \<in> A \<Longrightarrow> u \<sqsubseteq> f i \<Longrightarrow> u \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   195   using SUP_upper [of i A f] by auto
   196 
   197 lemma le_Inf_iff: "b \<sqsubseteq> \<Sqinter>A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
   198   by (auto intro: Inf_greatest dest: Inf_lower)
   199 
   200 lemma le_INF_iff: "u \<sqsubseteq> (\<Sqinter>i\<in>A. f i) \<longleftrightarrow> (\<forall>i\<in>A. u \<sqsubseteq> f i)"
   201   using le_Inf_iff [of _ "f ` A"] by simp
   202 
   203 lemma Sup_le_iff: "\<Squnion>A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
   204   by (auto intro: Sup_least dest: Sup_upper)
   205 
   206 lemma SUP_le_iff: "(\<Squnion>i\<in>A. f i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i\<in>A. f i \<sqsubseteq> u)"
   207   using Sup_le_iff [of "f ` A"] by simp
   208 
   209 lemma Inf_insert [simp]: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
   210   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
   211 
   212 lemma INF_insert [simp]: "(\<Sqinter>x\<in>insert a A. f x) = f a \<sqinter> INFIMUM A f"
   213   unfolding INF_def Inf_insert by simp
   214 
   215 lemma Sup_insert [simp]: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
   216   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
   217 
   218 lemma SUP_insert [simp]: "(\<Squnion>x\<in>insert a A. f x) = f a \<squnion> SUPREMUM A f"
   219   unfolding SUP_def Sup_insert by simp
   220 
   221 lemma INF_empty [simp]: "(\<Sqinter>x\<in>{}. f x) = \<top>"
   222   by (simp add: INF_def)
   223 
   224 lemma SUP_empty [simp]: "(\<Squnion>x\<in>{}. f x) = \<bottom>"
   225   by (simp add: SUP_def)
   226 
   227 lemma Inf_UNIV [simp]:
   228   "\<Sqinter>UNIV = \<bottom>"
   229   by (auto intro!: antisym Inf_lower)
   230 
   231 lemma Sup_UNIV [simp]:
   232   "\<Squnion>UNIV = \<top>"
   233   by (auto intro!: antisym Sup_upper)
   234 
   235 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
   236   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   237 
   238 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
   239   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   240 
   241 lemma Inf_superset_mono: "B \<subseteq> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   242   by (auto intro: Inf_greatest Inf_lower)
   243 
   244 lemma Sup_subset_mono: "A \<subseteq> B \<Longrightarrow> \<Squnion>A \<sqsubseteq> \<Squnion>B"
   245   by (auto intro: Sup_least Sup_upper)
   246 
   247 lemma Inf_mono:
   248   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<sqsubseteq> b"
   249   shows "\<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   250 proof (rule Inf_greatest)
   251   fix b assume "b \<in> B"
   252   with assms obtain a where "a \<in> A" and "a \<sqsubseteq> b" by blast
   253   from `a \<in> A` have "\<Sqinter>A \<sqsubseteq> a" by (rule Inf_lower)
   254   with `a \<sqsubseteq> b` show "\<Sqinter>A \<sqsubseteq> b" by auto
   255 qed
   256 
   257 lemma INF_mono:
   258   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Sqinter>n\<in>A. f n) \<sqsubseteq> (\<Sqinter>n\<in>B. g n)"
   259   using Inf_mono [of "g ` B" "f ` A"] by auto
   260 
   261 lemma Sup_mono:
   262   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<sqsubseteq> b"
   263   shows "\<Squnion>A \<sqsubseteq> \<Squnion>B"
   264 proof (rule Sup_least)
   265   fix a assume "a \<in> A"
   266   with assms obtain b where "b \<in> B" and "a \<sqsubseteq> b" by blast
   267   from `b \<in> B` have "b \<sqsubseteq> \<Squnion>B" by (rule Sup_upper)
   268   with `a \<sqsubseteq> b` show "a \<sqsubseteq> \<Squnion>B" by auto
   269 qed
   270 
   271 lemma SUP_mono:
   272   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Squnion>n\<in>A. f n) \<sqsubseteq> (\<Squnion>n\<in>B. g n)"
   273   using Sup_mono [of "f ` A" "g ` B"] by auto
   274 
   275 lemma INF_superset_mono:
   276   "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Sqinter>x\<in>A. f x) \<sqsubseteq> (\<Sqinter>x\<in>B. g x)"
   277   -- {* The last inclusion is POSITIVE! *}
   278   by (blast intro: INF_mono dest: subsetD)
   279 
   280 lemma SUP_subset_mono:
   281   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Squnion>x\<in>A. f x) \<sqsubseteq> (\<Squnion>x\<in>B. g x)"
   282   by (blast intro: SUP_mono dest: subsetD)
   283 
   284 lemma Inf_less_eq:
   285   assumes "\<And>v. v \<in> A \<Longrightarrow> v \<sqsubseteq> u"
   286     and "A \<noteq> {}"
   287   shows "\<Sqinter>A \<sqsubseteq> u"
   288 proof -
   289   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   290   moreover from `v \<in> A` assms(1) have "v \<sqsubseteq> u" by blast
   291   ultimately show ?thesis by (rule Inf_lower2)
   292 qed
   293 
   294 lemma less_eq_Sup:
   295   assumes "\<And>v. v \<in> A \<Longrightarrow> u \<sqsubseteq> v"
   296     and "A \<noteq> {}"
   297   shows "u \<sqsubseteq> \<Squnion>A"
   298 proof -
   299   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   300   moreover from `v \<in> A` assms(1) have "u \<sqsubseteq> v" by blast
   301   ultimately show ?thesis by (rule Sup_upper2)
   302 qed
   303 
   304 lemma SUP_eq:
   305   assumes "\<And>i. i \<in> A \<Longrightarrow> \<exists>j\<in>B. f i \<le> g j"
   306   assumes "\<And>j. j \<in> B \<Longrightarrow> \<exists>i\<in>A. g j \<le> f i"
   307   shows "(\<Squnion>i\<in>A. f i) = (\<Squnion>j\<in>B. g j)"
   308   by (intro antisym SUP_least) (blast intro: SUP_upper2 dest: assms)+
   309 
   310 lemma INF_eq:
   311   assumes "\<And>i. i \<in> A \<Longrightarrow> \<exists>j\<in>B. f i \<ge> g j"
   312   assumes "\<And>j. j \<in> B \<Longrightarrow> \<exists>i\<in>A. g j \<ge> f i"
   313   shows "(\<Sqinter>i\<in>A. f i) = (\<Sqinter>j\<in>B. g j)"
   314   by (intro antisym INF_greatest) (blast intro: INF_lower2 dest: assms)+
   315 
   316 lemma less_eq_Inf_inter: "\<Sqinter>A \<squnion> \<Sqinter>B \<sqsubseteq> \<Sqinter>(A \<inter> B)"
   317   by (auto intro: Inf_greatest Inf_lower)
   318 
   319 lemma Sup_inter_less_eq: "\<Squnion>(A \<inter> B) \<sqsubseteq> \<Squnion>A \<sqinter> \<Squnion>B "
   320   by (auto intro: Sup_least Sup_upper)
   321 
   322 lemma Inf_union_distrib: "\<Sqinter>(A \<union> B) = \<Sqinter>A \<sqinter> \<Sqinter>B"
   323   by (rule antisym) (auto intro: Inf_greatest Inf_lower le_infI1 le_infI2)
   324 
   325 lemma INF_union:
   326   "(\<Sqinter>i \<in> A \<union> B. M i) = (\<Sqinter>i \<in> A. M i) \<sqinter> (\<Sqinter>i\<in>B. M i)"
   327   by (auto intro!: antisym INF_mono intro: le_infI1 le_infI2 INF_greatest INF_lower)
   328 
   329 lemma Sup_union_distrib: "\<Squnion>(A \<union> B) = \<Squnion>A \<squnion> \<Squnion>B"
   330   by (rule antisym) (auto intro: Sup_least Sup_upper le_supI1 le_supI2)
   331 
   332 lemma SUP_union:
   333   "(\<Squnion>i \<in> A \<union> B. M i) = (\<Squnion>i \<in> A. M i) \<squnion> (\<Squnion>i\<in>B. M i)"
   334   by (auto intro!: antisym SUP_mono intro: le_supI1 le_supI2 SUP_least SUP_upper)
   335 
   336 lemma INF_inf_distrib: "(\<Sqinter>a\<in>A. f a) \<sqinter> (\<Sqinter>a\<in>A. g a) = (\<Sqinter>a\<in>A. f a \<sqinter> g a)"
   337   by (rule antisym) (rule INF_greatest, auto intro: le_infI1 le_infI2 INF_lower INF_mono)
   338 
   339 lemma SUP_sup_distrib: "(\<Squnion>a\<in>A. f a) \<squnion> (\<Squnion>a\<in>A. g a) = (\<Squnion>a\<in>A. f a \<squnion> g a)" (is "?L = ?R")
   340 proof (rule antisym)
   341   show "?L \<le> ?R" by (auto intro: le_supI1 le_supI2 SUP_upper SUP_mono)
   342 next
   343   show "?R \<le> ?L" by (rule SUP_least) (auto intro: le_supI1 le_supI2 SUP_upper)
   344 qed
   345 
   346 lemma Inf_top_conv [simp]:
   347   "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   348   "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   349 proof -
   350   show "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   351   proof
   352     assume "\<forall>x\<in>A. x = \<top>"
   353     then have "A = {} \<or> A = {\<top>}" by auto
   354     then show "\<Sqinter>A = \<top>" by auto
   355   next
   356     assume "\<Sqinter>A = \<top>"
   357     show "\<forall>x\<in>A. x = \<top>"
   358     proof (rule ccontr)
   359       assume "\<not> (\<forall>x\<in>A. x = \<top>)"
   360       then obtain x where "x \<in> A" and "x \<noteq> \<top>" by blast
   361       then obtain B where "A = insert x B" by blast
   362       with `\<Sqinter>A = \<top>` `x \<noteq> \<top>` show False by simp
   363     qed
   364   qed
   365   then show "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)" by auto
   366 qed
   367 
   368 lemma INF_top_conv [simp]:
   369   "(\<Sqinter>x\<in>A. B x) = \<top> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   370   "\<top> = (\<Sqinter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   371   using Inf_top_conv [of "B ` A"] by simp_all
   372 
   373 lemma Sup_bot_conv [simp]:
   374   "\<Squnion>A = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?P)
   375   "\<bottom> = \<Squnion>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?Q)
   376   using dual_complete_lattice
   377   by (rule complete_lattice.Inf_top_conv)+
   378 
   379 lemma SUP_bot_conv [simp]:
   380  "(\<Squnion>x\<in>A. B x) = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   381  "\<bottom> = (\<Squnion>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   382   using Sup_bot_conv [of "B ` A"] by simp_all
   383 
   384 lemma INF_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Sqinter>i\<in>A. f) = f"
   385   by (auto intro: antisym INF_lower INF_greatest)
   386 
   387 lemma SUP_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Squnion>i\<in>A. f) = f"
   388   by (auto intro: antisym SUP_upper SUP_least)
   389 
   390 lemma INF_top [simp]: "(\<Sqinter>x\<in>A. \<top>) = \<top>"
   391   by (cases "A = {}") simp_all
   392 
   393 lemma SUP_bot [simp]: "(\<Squnion>x\<in>A. \<bottom>) = \<bottom>"
   394   by (cases "A = {}") simp_all
   395 
   396 lemma INF_commute: "(\<Sqinter>i\<in>A. \<Sqinter>j\<in>B. f i j) = (\<Sqinter>j\<in>B. \<Sqinter>i\<in>A. f i j)"
   397   by (iprover intro: INF_lower INF_greatest order_trans antisym)
   398 
   399 lemma SUP_commute: "(\<Squnion>i\<in>A. \<Squnion>j\<in>B. f i j) = (\<Squnion>j\<in>B. \<Squnion>i\<in>A. f i j)"
   400   by (iprover intro: SUP_upper SUP_least order_trans antisym)
   401 
   402 lemma INF_absorb:
   403   assumes "k \<in> I"
   404   shows "A k \<sqinter> (\<Sqinter>i\<in>I. A i) = (\<Sqinter>i\<in>I. A i)"
   405 proof -
   406   from assms obtain J where "I = insert k J" by blast
   407   then show ?thesis by simp
   408 qed
   409 
   410 lemma SUP_absorb:
   411   assumes "k \<in> I"
   412   shows "A k \<squnion> (\<Squnion>i\<in>I. A i) = (\<Squnion>i\<in>I. A i)"
   413 proof -
   414   from assms obtain J where "I = insert k J" by blast
   415   then show ?thesis by simp
   416 qed
   417 
   418 lemma INF_inf_const1:
   419   "I \<noteq> {} \<Longrightarrow> (INF i:I. inf x (f i)) = inf x (INF i:I. f i)"
   420   by (intro antisym INF_greatest inf_mono order_refl INF_lower)
   421      (auto intro: INF_lower2 le_infI2 intro!: INF_mono)
   422 
   423 lemma INF_inf_const2:
   424   "I \<noteq> {} \<Longrightarrow> (INF i:I. inf (f i) x) = inf (INF i:I. f i) x"
   425   using INF_inf_const1[of I x f] by (simp add: inf_commute)
   426 
   427 lemma INF_constant:
   428   "(\<Sqinter>y\<in>A. c) = (if A = {} then \<top> else c)"
   429   by simp
   430 
   431 lemma SUP_constant:
   432   "(\<Squnion>y\<in>A. c) = (if A = {} then \<bottom> else c)"
   433   by simp
   434 
   435 lemma less_INF_D:
   436   assumes "y < (\<Sqinter>i\<in>A. f i)" "i \<in> A" shows "y < f i"
   437 proof -
   438   note `y < (\<Sqinter>i\<in>A. f i)`
   439   also have "(\<Sqinter>i\<in>A. f i) \<le> f i" using `i \<in> A`
   440     by (rule INF_lower)
   441   finally show "y < f i" .
   442 qed
   443 
   444 lemma SUP_lessD:
   445   assumes "(\<Squnion>i\<in>A. f i) < y" "i \<in> A" shows "f i < y"
   446 proof -
   447   have "f i \<le> (\<Squnion>i\<in>A. f i)" using `i \<in> A`
   448     by (rule SUP_upper)
   449   also note `(\<Squnion>i\<in>A. f i) < y`
   450   finally show "f i < y" .
   451 qed
   452 
   453 lemma INF_UNIV_bool_expand:
   454   "(\<Sqinter>b. A b) = A True \<sqinter> A False"
   455   by (simp add: UNIV_bool inf_commute)
   456 
   457 lemma SUP_UNIV_bool_expand:
   458   "(\<Squnion>b. A b) = A True \<squnion> A False"
   459   by (simp add: UNIV_bool sup_commute)
   460 
   461 lemma Inf_le_Sup: "A \<noteq> {} \<Longrightarrow> Inf A \<le> Sup A"
   462   by (blast intro: Sup_upper2 Inf_lower ex_in_conv)
   463 
   464 lemma INF_le_SUP: "A \<noteq> {} \<Longrightarrow> INFIMUM A f \<le> SUPREMUM A f"
   465   using Inf_le_Sup [of "f ` A"] by simp
   466 
   467 lemma INF_eq_const:
   468   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f i = x) \<Longrightarrow> INFIMUM I f = x"
   469   by (auto intro: INF_eqI)
   470 
   471 lemma SUP_eq_const:
   472   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f i = x) \<Longrightarrow> SUPREMUM I f = x"
   473   by (auto intro: SUP_eqI)
   474 
   475 lemma INF_eq_iff:
   476   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f i \<le> c) \<Longrightarrow> (INFIMUM I f = c) \<longleftrightarrow> (\<forall>i\<in>I. f i = c)"
   477   using INF_eq_const [of I f c] INF_lower [of _ I f]
   478   by (auto intro: antisym cong del: strong_INF_cong)
   479 
   480 lemma SUP_eq_iff:
   481   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> c \<le> f i) \<Longrightarrow> (SUPREMUM I f = c) \<longleftrightarrow> (\<forall>i\<in>I. f i = c)"
   482   using SUP_eq_const [of I f c] SUP_upper [of _ I f]
   483   by (auto intro: antisym cong del: strong_SUP_cong)
   484 
   485 end
   486 
   487 class complete_distrib_lattice = complete_lattice +
   488   assumes sup_Inf: "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)"
   489   assumes inf_Sup: "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   490 begin
   491 
   492 lemma sup_INF:
   493   "a \<squnion> (\<Sqinter>b\<in>B. f b) = (\<Sqinter>b\<in>B. a \<squnion> f b)"
   494   by (simp only: INF_def sup_Inf image_image)
   495 
   496 lemma inf_SUP:
   497   "a \<sqinter> (\<Squnion>b\<in>B. f b) = (\<Squnion>b\<in>B. a \<sqinter> f b)"
   498   by (simp only: SUP_def inf_Sup image_image)
   499 
   500 lemma dual_complete_distrib_lattice:
   501   "class.complete_distrib_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   502   apply (rule class.complete_distrib_lattice.intro)
   503   apply (fact dual_complete_lattice)
   504   apply (rule class.complete_distrib_lattice_axioms.intro)
   505   apply (simp_all only: INF_foundation_dual SUP_foundation_dual inf_Sup sup_Inf)
   506   done
   507 
   508 subclass distrib_lattice proof
   509   fix a b c
   510   from sup_Inf have "a \<squnion> \<Sqinter>{b, c} = (\<Sqinter>d\<in>{b, c}. a \<squnion> d)" .
   511   then show "a \<squnion> b \<sqinter> c = (a \<squnion> b) \<sqinter> (a \<squnion> c)" by (simp add: INF_def)
   512 qed
   513 
   514 lemma Inf_sup:
   515   "\<Sqinter>B \<squnion> a = (\<Sqinter>b\<in>B. b \<squnion> a)"
   516   by (simp add: sup_Inf sup_commute)
   517 
   518 lemma Sup_inf:
   519   "\<Squnion>B \<sqinter> a = (\<Squnion>b\<in>B. b \<sqinter> a)"
   520   by (simp add: inf_Sup inf_commute)
   521 
   522 lemma INF_sup: 
   523   "(\<Sqinter>b\<in>B. f b) \<squnion> a = (\<Sqinter>b\<in>B. f b \<squnion> a)"
   524   by (simp add: sup_INF sup_commute)
   525 
   526 lemma SUP_inf:
   527   "(\<Squnion>b\<in>B. f b) \<sqinter> a = (\<Squnion>b\<in>B. f b \<sqinter> a)"
   528   by (simp add: inf_SUP inf_commute)
   529 
   530 lemma Inf_sup_eq_top_iff:
   531   "(\<Sqinter>B \<squnion> a = \<top>) \<longleftrightarrow> (\<forall>b\<in>B. b \<squnion> a = \<top>)"
   532   by (simp only: Inf_sup INF_top_conv)
   533 
   534 lemma Sup_inf_eq_bot_iff:
   535   "(\<Squnion>B \<sqinter> a = \<bottom>) \<longleftrightarrow> (\<forall>b\<in>B. b \<sqinter> a = \<bottom>)"
   536   by (simp only: Sup_inf SUP_bot_conv)
   537 
   538 lemma INF_sup_distrib2:
   539   "(\<Sqinter>a\<in>A. f a) \<squnion> (\<Sqinter>b\<in>B. g b) = (\<Sqinter>a\<in>A. \<Sqinter>b\<in>B. f a \<squnion> g b)"
   540   by (subst INF_commute) (simp add: sup_INF INF_sup)
   541 
   542 lemma SUP_inf_distrib2:
   543   "(\<Squnion>a\<in>A. f a) \<sqinter> (\<Squnion>b\<in>B. g b) = (\<Squnion>a\<in>A. \<Squnion>b\<in>B. f a \<sqinter> g b)"
   544   by (subst SUP_commute) (simp add: inf_SUP SUP_inf)
   545 
   546 context
   547   fixes f :: "'a \<Rightarrow> 'b::complete_lattice"
   548   assumes "mono f"
   549 begin
   550 
   551 lemma mono_Inf:
   552   shows "f (\<Sqinter>A) \<le> (\<Sqinter>x\<in>A. f x)"
   553   using `mono f` by (auto intro: complete_lattice_class.INF_greatest Inf_lower dest: monoD)
   554 
   555 lemma mono_Sup:
   556   shows "(\<Squnion>x\<in>A. f x) \<le> f (\<Squnion>A)"
   557   using `mono f` by (auto intro: complete_lattice_class.SUP_least Sup_upper dest: monoD)
   558 
   559 end
   560 
   561 end
   562 
   563 class complete_boolean_algebra = boolean_algebra + complete_distrib_lattice
   564 begin
   565 
   566 lemma dual_complete_boolean_algebra:
   567   "class.complete_boolean_algebra Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom> (\<lambda>x y. x \<squnion> - y) uminus"
   568   by (rule class.complete_boolean_algebra.intro, rule dual_complete_distrib_lattice, rule dual_boolean_algebra)
   569 
   570 lemma uminus_Inf:
   571   "- (\<Sqinter>A) = \<Squnion>(uminus ` A)"
   572 proof (rule antisym)
   573   show "- \<Sqinter>A \<le> \<Squnion>(uminus ` A)"
   574     by (rule compl_le_swap2, rule Inf_greatest, rule compl_le_swap2, rule Sup_upper) simp
   575   show "\<Squnion>(uminus ` A) \<le> - \<Sqinter>A"
   576     by (rule Sup_least, rule compl_le_swap1, rule Inf_lower) auto
   577 qed
   578 
   579 lemma uminus_INF: "- (\<Sqinter>x\<in>A. B x) = (\<Squnion>x\<in>A. - B x)"
   580   by (simp only: INF_def SUP_def uminus_Inf image_image)
   581 
   582 lemma uminus_Sup:
   583   "- (\<Squnion>A) = \<Sqinter>(uminus ` A)"
   584 proof -
   585   have "\<Squnion>A = - \<Sqinter>(uminus ` A)" by (simp add: image_image uminus_INF)
   586   then show ?thesis by simp
   587 qed
   588   
   589 lemma uminus_SUP: "- (\<Squnion>x\<in>A. B x) = (\<Sqinter>x\<in>A. - B x)"
   590   by (simp only: INF_def SUP_def uminus_Sup image_image)
   591 
   592 end
   593 
   594 class complete_linorder = linorder + complete_lattice
   595 begin
   596 
   597 lemma dual_complete_linorder:
   598   "class.complete_linorder Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   599   by (rule class.complete_linorder.intro, rule dual_complete_lattice, rule dual_linorder)
   600 
   601 lemma complete_linorder_inf_min: "inf = min"
   602   by (auto intro: antisym simp add: min_def fun_eq_iff)
   603 
   604 lemma complete_linorder_sup_max: "sup = max"
   605   by (auto intro: antisym simp add: max_def fun_eq_iff)
   606 
   607 lemma Inf_less_iff:
   608   "\<Sqinter>S \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>S. x \<sqsubset> a)"
   609   unfolding not_le [symmetric] le_Inf_iff by auto
   610 
   611 lemma INF_less_iff:
   612   "(\<Sqinter>i\<in>A. f i) \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>A. f x \<sqsubset> a)"
   613   using Inf_less_iff [of "f ` A"] by simp
   614 
   615 lemma less_Sup_iff:
   616   "a \<sqsubset> \<Squnion>S \<longleftrightarrow> (\<exists>x\<in>S. a \<sqsubset> x)"
   617   unfolding not_le [symmetric] Sup_le_iff by auto
   618 
   619 lemma less_SUP_iff:
   620   "a \<sqsubset> (\<Squnion>i\<in>A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a \<sqsubset> f x)"
   621   using less_Sup_iff [of _ "f ` A"] by simp
   622 
   623 lemma Sup_eq_top_iff [simp]:
   624   "\<Squnion>A = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < i)"
   625 proof
   626   assume *: "\<Squnion>A = \<top>"
   627   show "(\<forall>x<\<top>. \<exists>i\<in>A. x < i)" unfolding * [symmetric]
   628   proof (intro allI impI)
   629     fix x assume "x < \<Squnion>A" then show "\<exists>i\<in>A. x < i"
   630       unfolding less_Sup_iff by auto
   631   qed
   632 next
   633   assume *: "\<forall>x<\<top>. \<exists>i\<in>A. x < i"
   634   show "\<Squnion>A = \<top>"
   635   proof (rule ccontr)
   636     assume "\<Squnion>A \<noteq> \<top>"
   637     with top_greatest [of "\<Squnion>A"]
   638     have "\<Squnion>A < \<top>" unfolding le_less by auto
   639     then have "\<Squnion>A < \<Squnion>A"
   640       using * unfolding less_Sup_iff by auto
   641     then show False by auto
   642   qed
   643 qed
   644 
   645 lemma SUP_eq_top_iff [simp]:
   646   "(\<Squnion>i\<in>A. f i) = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < f i)"
   647   using Sup_eq_top_iff [of "f ` A"] by simp
   648 
   649 lemma Inf_eq_bot_iff [simp]:
   650   "\<Sqinter>A = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. i < x)"
   651   using dual_complete_linorder
   652   by (rule complete_linorder.Sup_eq_top_iff)
   653 
   654 lemma INF_eq_bot_iff [simp]:
   655   "(\<Sqinter>i\<in>A. f i) = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. f i < x)"
   656   using Inf_eq_bot_iff [of "f ` A"] by simp
   657 
   658 lemma Inf_le_iff: "\<Sqinter>A \<le> x \<longleftrightarrow> (\<forall>y>x. \<exists>a\<in>A. y > a)"
   659 proof safe
   660   fix y assume "x \<ge> \<Sqinter>A" "y > x"
   661   then have "y > \<Sqinter>A" by auto
   662   then show "\<exists>a\<in>A. y > a"
   663     unfolding Inf_less_iff .
   664 qed (auto elim!: allE[of _ "\<Sqinter>A"] simp add: not_le[symmetric] Inf_lower)
   665 
   666 lemma INF_le_iff:
   667   "INFIMUM A f \<le> x \<longleftrightarrow> (\<forall>y>x. \<exists>i\<in>A. y > f i)"
   668   using Inf_le_iff [of "f ` A"] by simp
   669 
   670 lemma le_Sup_iff: "x \<le> \<Squnion>A \<longleftrightarrow> (\<forall>y<x. \<exists>a\<in>A. y < a)"
   671 proof safe
   672   fix y assume "x \<le> \<Squnion>A" "y < x"
   673   then have "y < \<Squnion>A" by auto
   674   then show "\<exists>a\<in>A. y < a"
   675     unfolding less_Sup_iff .
   676 qed (auto elim!: allE[of _ "\<Squnion>A"] simp add: not_le[symmetric] Sup_upper)
   677 
   678 lemma le_SUP_iff: "x \<le> SUPREMUM A f \<longleftrightarrow> (\<forall>y<x. \<exists>i\<in>A. y < f i)"
   679   using le_Sup_iff [of _ "f ` A"] by simp
   680 
   681 subclass complete_distrib_lattice
   682 proof
   683   fix a and B
   684   show "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)" and "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   685     by (safe intro!: INF_eqI [symmetric] sup_mono Inf_lower SUP_eqI [symmetric] inf_mono Sup_upper)
   686       (auto simp: not_less [symmetric] Inf_less_iff less_Sup_iff
   687         le_max_iff_disj complete_linorder_sup_max min_le_iff_disj complete_linorder_inf_min)
   688 qed
   689 
   690 end
   691 
   692 
   693 subsection {* Complete lattice on @{typ bool} *}
   694 
   695 instantiation bool :: complete_lattice
   696 begin
   697 
   698 definition
   699   [simp, code]: "\<Sqinter>A \<longleftrightarrow> False \<notin> A"
   700 
   701 definition
   702   [simp, code]: "\<Squnion>A \<longleftrightarrow> True \<in> A"
   703 
   704 instance proof
   705 qed (auto intro: bool_induct)
   706 
   707 end
   708 
   709 lemma not_False_in_image_Ball [simp]:
   710   "False \<notin> P ` A \<longleftrightarrow> Ball A P"
   711   by auto
   712 
   713 lemma True_in_image_Bex [simp]:
   714   "True \<in> P ` A \<longleftrightarrow> Bex A P"
   715   by auto
   716 
   717 lemma INF_bool_eq [simp]:
   718   "INFIMUM = Ball"
   719   by (simp add: fun_eq_iff INF_def)
   720 
   721 lemma SUP_bool_eq [simp]:
   722   "SUPREMUM = Bex"
   723   by (simp add: fun_eq_iff SUP_def)
   724 
   725 instance bool :: complete_boolean_algebra proof
   726 qed (auto intro: bool_induct)
   727 
   728 
   729 subsection {* Complete lattice on @{typ "_ \<Rightarrow> _"} *}
   730 
   731 instantiation "fun" :: (type, Inf) Inf
   732 begin
   733 
   734 definition
   735   "\<Sqinter>A = (\<lambda>x. \<Sqinter>f\<in>A. f x)"
   736 
   737 lemma Inf_apply [simp, code]:
   738   "(\<Sqinter>A) x = (\<Sqinter>f\<in>A. f x)"
   739   by (simp add: Inf_fun_def)
   740 
   741 instance ..
   742 
   743 end
   744 
   745 instantiation "fun" :: (type, Sup) Sup
   746 begin
   747 
   748 definition
   749   "\<Squnion>A = (\<lambda>x. \<Squnion>f\<in>A. f x)"
   750 
   751 lemma Sup_apply [simp, code]:
   752   "(\<Squnion>A) x = (\<Squnion>f\<in>A. f x)"
   753   by (simp add: Sup_fun_def)
   754 
   755 instance ..
   756 
   757 end
   758 
   759 instantiation "fun" :: (type, complete_lattice) complete_lattice
   760 begin
   761 
   762 instance proof
   763 qed (auto simp add: le_fun_def intro: INF_lower INF_greatest SUP_upper SUP_least)
   764 
   765 end
   766 
   767 lemma INF_apply [simp]:
   768   "(\<Sqinter>y\<in>A. f y) x = (\<Sqinter>y\<in>A. f y x)"
   769   using Inf_apply [of "f ` A"] by (simp add: comp_def)
   770 
   771 lemma SUP_apply [simp]:
   772   "(\<Squnion>y\<in>A. f y) x = (\<Squnion>y\<in>A. f y x)"
   773   using Sup_apply [of "f ` A"] by (simp add: comp_def)
   774 
   775 instance "fun" :: (type, complete_distrib_lattice) complete_distrib_lattice proof
   776 qed (auto simp add: INF_def SUP_def inf_Sup sup_Inf fun_eq_iff image_image
   777   simp del: Inf_image_eq Sup_image_eq)
   778 
   779 instance "fun" :: (type, complete_boolean_algebra) complete_boolean_algebra ..
   780 
   781 
   782 subsection {* Complete lattice on unary and binary predicates *}
   783 
   784 lemma Inf1_I: 
   785   "(\<And>P. P \<in> A \<Longrightarrow> P a) \<Longrightarrow> (\<Sqinter>A) a"
   786   by auto
   787 
   788 lemma INF1_I:
   789   "(\<And>x. x \<in> A \<Longrightarrow> B x b) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b"
   790   by simp
   791 
   792 lemma INF2_I:
   793   "(\<And>x. x \<in> A \<Longrightarrow> B x b c) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b c"
   794   by simp
   795 
   796 lemma Inf2_I: 
   797   "(\<And>r. r \<in> A \<Longrightarrow> r a b) \<Longrightarrow> (\<Sqinter>A) a b"
   798   by auto
   799 
   800 lemma Inf1_D:
   801   "(\<Sqinter>A) a \<Longrightarrow> P \<in> A \<Longrightarrow> P a"
   802   by auto
   803 
   804 lemma INF1_D:
   805   "(\<Sqinter>x\<in>A. B x) b \<Longrightarrow> a \<in> A \<Longrightarrow> B a b"
   806   by simp
   807 
   808 lemma Inf2_D:
   809   "(\<Sqinter>A) a b \<Longrightarrow> r \<in> A \<Longrightarrow> r a b"
   810   by auto
   811 
   812 lemma INF2_D:
   813   "(\<Sqinter>x\<in>A. B x) b c \<Longrightarrow> a \<in> A \<Longrightarrow> B a b c"
   814   by simp
   815 
   816 lemma Inf1_E:
   817   assumes "(\<Sqinter>A) a"
   818   obtains "P a" | "P \<notin> A"
   819   using assms by auto
   820 
   821 lemma INF1_E:
   822   assumes "(\<Sqinter>x\<in>A. B x) b"
   823   obtains "B a b" | "a \<notin> A"
   824   using assms by auto
   825 
   826 lemma Inf2_E:
   827   assumes "(\<Sqinter>A) a b"
   828   obtains "r a b" | "r \<notin> A"
   829   using assms by auto
   830 
   831 lemma INF2_E:
   832   assumes "(\<Sqinter>x\<in>A. B x) b c"
   833   obtains "B a b c" | "a \<notin> A"
   834   using assms by auto
   835 
   836 lemma Sup1_I:
   837   "P \<in> A \<Longrightarrow> P a \<Longrightarrow> (\<Squnion>A) a"
   838   by auto
   839 
   840 lemma SUP1_I:
   841   "a \<in> A \<Longrightarrow> B a b \<Longrightarrow> (\<Squnion>x\<in>A. B x) b"
   842   by auto
   843 
   844 lemma Sup2_I:
   845   "r \<in> A \<Longrightarrow> r a b \<Longrightarrow> (\<Squnion>A) a b"
   846   by auto
   847 
   848 lemma SUP2_I:
   849   "a \<in> A \<Longrightarrow> B a b c \<Longrightarrow> (\<Squnion>x\<in>A. B x) b c"
   850   by auto
   851 
   852 lemma Sup1_E:
   853   assumes "(\<Squnion>A) a"
   854   obtains P where "P \<in> A" and "P a"
   855   using assms by auto
   856 
   857 lemma SUP1_E:
   858   assumes "(\<Squnion>x\<in>A. B x) b"
   859   obtains x where "x \<in> A" and "B x b"
   860   using assms by auto
   861 
   862 lemma Sup2_E:
   863   assumes "(\<Squnion>A) a b"
   864   obtains r where "r \<in> A" "r a b"
   865   using assms by auto
   866 
   867 lemma SUP2_E:
   868   assumes "(\<Squnion>x\<in>A. B x) b c"
   869   obtains x where "x \<in> A" "B x b c"
   870   using assms by auto
   871 
   872 
   873 subsection {* Complete lattice on @{typ "_ set"} *}
   874 
   875 instantiation "set" :: (type) complete_lattice
   876 begin
   877 
   878 definition
   879   "\<Sqinter>A = {x. \<Sqinter>((\<lambda>B. x \<in> B) ` A)}"
   880 
   881 definition
   882   "\<Squnion>A = {x. \<Squnion>((\<lambda>B. x \<in> B) ` A)}"
   883 
   884 instance proof
   885 qed (auto simp add: less_eq_set_def Inf_set_def Sup_set_def le_fun_def)
   886 
   887 end
   888 
   889 instance "set" :: (type) complete_boolean_algebra
   890 proof
   891 qed (auto simp add: INF_def SUP_def Inf_set_def Sup_set_def image_def)
   892   
   893 
   894 subsubsection {* Inter *}
   895 
   896 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   897   "Inter S \<equiv> \<Sqinter>S"
   898   
   899 notation (xsymbols)
   900   Inter  ("\<Inter>_" [900] 900)
   901 
   902 lemma Inter_eq:
   903   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   904 proof (rule set_eqI)
   905   fix x
   906   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   907     by auto
   908   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   909     by (simp add: Inf_set_def image_def)
   910 qed
   911 
   912 lemma Inter_iff [simp]: "A \<in> \<Inter>C \<longleftrightarrow> (\<forall>X\<in>C. A \<in> X)"
   913   by (unfold Inter_eq) blast
   914 
   915 lemma InterI [intro!]: "(\<And>X. X \<in> C \<Longrightarrow> A \<in> X) \<Longrightarrow> A \<in> \<Inter>C"
   916   by (simp add: Inter_eq)
   917 
   918 text {*
   919   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   920   contains @{term A} as an element, but @{prop "A \<in> X"} can hold when
   921   @{prop "X \<in> C"} does not!  This rule is analogous to @{text spec}.
   922 *}
   923 
   924 lemma InterD [elim, Pure.elim]: "A \<in> \<Inter>C \<Longrightarrow> X \<in> C \<Longrightarrow> A \<in> X"
   925   by auto
   926 
   927 lemma InterE [elim]: "A \<in> \<Inter>C \<Longrightarrow> (X \<notin> C \<Longrightarrow> R) \<Longrightarrow> (A \<in> X \<Longrightarrow> R) \<Longrightarrow> R"
   928   -- {* ``Classical'' elimination rule -- does not require proving
   929     @{prop "X \<in> C"}. *}
   930   by (unfold Inter_eq) blast
   931 
   932 lemma Inter_lower: "B \<in> A \<Longrightarrow> \<Inter>A \<subseteq> B"
   933   by (fact Inf_lower)
   934 
   935 lemma Inter_subset:
   936   "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> B) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> \<Inter>A \<subseteq> B"
   937   by (fact Inf_less_eq)
   938 
   939 lemma Inter_greatest: "(\<And>X. X \<in> A \<Longrightarrow> C \<subseteq> X) \<Longrightarrow> C \<subseteq> Inter A"
   940   by (fact Inf_greatest)
   941 
   942 lemma Inter_empty: "\<Inter>{} = UNIV"
   943   by (fact Inf_empty) (* already simp *)
   944 
   945 lemma Inter_UNIV: "\<Inter>UNIV = {}"
   946   by (fact Inf_UNIV) (* already simp *)
   947 
   948 lemma Inter_insert: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   949   by (fact Inf_insert) (* already simp *)
   950 
   951 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   952   by (fact less_eq_Inf_inter)
   953 
   954 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   955   by (fact Inf_union_distrib)
   956 
   957 lemma Inter_UNIV_conv [simp]:
   958   "\<Inter>A = UNIV \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   959   "UNIV = \<Inter>A \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   960   by (fact Inf_top_conv)+
   961 
   962 lemma Inter_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Inter>A \<subseteq> \<Inter>B"
   963   by (fact Inf_superset_mono)
   964 
   965 
   966 subsubsection {* Intersections of families *}
   967 
   968 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   969   "INTER \<equiv> INFIMUM"
   970 
   971 text {*
   972   Note: must use name @{const INTER} here instead of @{text INT}
   973   to allow the following syntax coexist with the plain constant name.
   974 *}
   975 
   976 syntax
   977   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   978   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   979 
   980 syntax (xsymbols)
   981   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   982   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   983 
   984 syntax (latex output)
   985   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   986   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   987 
   988 translations
   989   "INT x y. B"  == "INT x. INT y. B"
   990   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   991   "INT x. B"    == "INT x:CONST UNIV. B"
   992   "INT x:A. B"  == "CONST INTER A (%x. B)"
   993 
   994 print_translation {*
   995   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   996 *} -- {* to avoid eta-contraction of body *}
   997 
   998 lemma INTER_eq:
   999   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
  1000   by (auto intro!: INF_eqI)
  1001 
  1002 lemma Inter_image_eq:
  1003   "\<Inter>(B ` A) = (\<Inter>x\<in>A. B x)"
  1004   by (fact Inf_image_eq)
  1005 
  1006 lemma INT_iff [simp]: "b \<in> (\<Inter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. b \<in> B x)"
  1007   using Inter_iff [of _ "B ` A"] by simp
  1008 
  1009 lemma INT_I [intro!]: "(\<And>x. x \<in> A \<Longrightarrow> b \<in> B x) \<Longrightarrow> b \<in> (\<Inter>x\<in>A. B x)"
  1010   by (auto simp add: INF_def image_def)
  1011 
  1012 lemma INT_D [elim, Pure.elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> B a"
  1013   by auto
  1014 
  1015 lemma INT_E [elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> (b \<in> B a \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
  1016   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a\<in>A"}. *}
  1017   by (auto simp add: INF_def image_def)
  1018 
  1019 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
  1020   by blast
  1021 
  1022 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
  1023   by blast
  1024 
  1025 lemma INT_lower: "a \<in> A \<Longrightarrow> (\<Inter>x\<in>A. B x) \<subseteq> B a"
  1026   by (fact INF_lower)
  1027 
  1028 lemma INT_greatest: "(\<And>x. x \<in> A \<Longrightarrow> C \<subseteq> B x) \<Longrightarrow> C \<subseteq> (\<Inter>x\<in>A. B x)"
  1029   by (fact INF_greatest)
  1030 
  1031 lemma INT_empty: "(\<Inter>x\<in>{}. B x) = UNIV"
  1032   by (fact INF_empty)
  1033 
  1034 lemma INT_absorb: "k \<in> I \<Longrightarrow> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
  1035   by (fact INF_absorb)
  1036 
  1037 lemma INT_subset_iff: "B \<subseteq> (\<Inter>i\<in>I. A i) \<longleftrightarrow> (\<forall>i\<in>I. B \<subseteq> A i)"
  1038   by (fact le_INF_iff)
  1039 
  1040 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
  1041   by (fact INF_insert)
  1042 
  1043 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
  1044   by (fact INF_union)
  1045 
  1046 lemma INT_insert_distrib:
  1047   "u \<in> A \<Longrightarrow> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
  1048   by blast
  1049 
  1050 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
  1051   by (fact INF_constant)
  1052 
  1053 lemma INTER_UNIV_conv:
  1054  "(UNIV = (\<Inter>x\<in>A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
  1055  "((\<Inter>x\<in>A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
  1056   by (fact INF_top_conv)+ (* already simp *)
  1057 
  1058 lemma INT_bool_eq: "(\<Inter>b. A b) = A True \<inter> A False"
  1059   by (fact INF_UNIV_bool_expand)
  1060 
  1061 lemma INT_anti_mono:
  1062   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow> (\<Inter>x\<in>B. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
  1063   -- {* The last inclusion is POSITIVE! *}
  1064   by (fact INF_superset_mono)
  1065 
  1066 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
  1067   by blast
  1068 
  1069 lemma vimage_INT: "f -` (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. f -` B x)"
  1070   by blast
  1071 
  1072 
  1073 subsubsection {* Union *}
  1074 
  1075 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
  1076   "Union S \<equiv> \<Squnion>S"
  1077 
  1078 notation (xsymbols)
  1079   Union  ("\<Union>_" [900] 900)
  1080 
  1081 lemma Union_eq:
  1082   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
  1083 proof (rule set_eqI)
  1084   fix x
  1085   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
  1086     by auto
  1087   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
  1088     by (simp add: Sup_set_def image_def)
  1089 qed
  1090 
  1091 lemma Union_iff [simp]:
  1092   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
  1093   by (unfold Union_eq) blast
  1094 
  1095 lemma UnionI [intro]:
  1096   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
  1097   -- {* The order of the premises presupposes that @{term C} is rigid;
  1098     @{term A} may be flexible. *}
  1099   by auto
  1100 
  1101 lemma UnionE [elim!]:
  1102   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A \<in> X \<Longrightarrow> X \<in> C \<Longrightarrow> R) \<Longrightarrow> R"
  1103   by auto
  1104 
  1105 lemma Union_upper: "B \<in> A \<Longrightarrow> B \<subseteq> \<Union>A"
  1106   by (fact Sup_upper)
  1107 
  1108 lemma Union_least: "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> C) \<Longrightarrow> \<Union>A \<subseteq> C"
  1109   by (fact Sup_least)
  1110 
  1111 lemma Union_empty: "\<Union>{} = {}"
  1112   by (fact Sup_empty) (* already simp *)
  1113 
  1114 lemma Union_UNIV: "\<Union>UNIV = UNIV"
  1115   by (fact Sup_UNIV) (* already simp *)
  1116 
  1117 lemma Union_insert: "\<Union>insert a B = a \<union> \<Union>B"
  1118   by (fact Sup_insert) (* already simp *)
  1119 
  1120 lemma Union_Un_distrib [simp]: "\<Union>(A \<union> B) = \<Union>A \<union> \<Union>B"
  1121   by (fact Sup_union_distrib)
  1122 
  1123 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1124   by (fact Sup_inter_less_eq)
  1125 
  1126 lemma Union_empty_conv: "(\<Union>A = {}) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
  1127   by (fact Sup_bot_conv) (* already simp *)
  1128 
  1129 lemma empty_Union_conv: "({} = \<Union>A) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
  1130   by (fact Sup_bot_conv) (* already simp *)
  1131 
  1132 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1133   by blast
  1134 
  1135 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1136   by blast
  1137 
  1138 lemma Union_mono: "A \<subseteq> B \<Longrightarrow> \<Union>A \<subseteq> \<Union>B"
  1139   by (fact Sup_subset_mono)
  1140 
  1141 
  1142 subsubsection {* Unions of families *}
  1143 
  1144 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
  1145   "UNION \<equiv> SUPREMUM"
  1146 
  1147 text {*
  1148   Note: must use name @{const UNION} here instead of @{text UN}
  1149   to allow the following syntax coexist with the plain constant name.
  1150 *}
  1151 
  1152 syntax
  1153   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
  1154   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
  1155 
  1156 syntax (xsymbols)
  1157   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
  1158   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
  1159 
  1160 syntax (latex output)
  1161   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
  1162   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
  1163 
  1164 translations
  1165   "UN x y. B"   == "UN x. UN y. B"
  1166   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
  1167   "UN x. B"     == "UN x:CONST UNIV. B"
  1168   "UN x:A. B"   == "CONST UNION A (%x. B)"
  1169 
  1170 text {*
  1171   Note the difference between ordinary xsymbol syntax of indexed
  1172   unions and intersections (e.g.\ @{text"\<Union>a\<^sub>1\<in>A\<^sub>1. B"})
  1173   and their \LaTeX\ rendition: @{term"\<Union>a\<^sub>1\<in>A\<^sub>1. B"}. The
  1174   former does not make the index expression a subscript of the
  1175   union/intersection symbol because this leads to problems with nested
  1176   subscripts in Proof General.
  1177 *}
  1178 
  1179 print_translation {*
  1180   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
  1181 *} -- {* to avoid eta-contraction of body *}
  1182 
  1183 lemma UNION_eq:
  1184   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
  1185   by (auto intro!: SUP_eqI)
  1186 
  1187 lemma bind_UNION [code]:
  1188   "Set.bind A f = UNION A f"
  1189   by (simp add: bind_def UNION_eq)
  1190 
  1191 lemma member_bind [simp]:
  1192   "x \<in> Set.bind P f \<longleftrightarrow> x \<in> UNION P f "
  1193   by (simp add: bind_UNION)
  1194 
  1195 lemma Union_image_eq:
  1196   "\<Union>(B ` A) = (\<Union>x\<in>A. B x)"
  1197   by (fact Sup_image_eq)
  1198 
  1199 lemma UN_iff [simp]: "b \<in> (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<exists>x\<in>A. b \<in> B x)"
  1200   using Union_iff [of _ "B ` A"] by simp
  1201 
  1202 lemma UN_I [intro]: "a \<in> A \<Longrightarrow> b \<in> B a \<Longrightarrow> b \<in> (\<Union>x\<in>A. B x)"
  1203   -- {* The order of the premises presupposes that @{term A} is rigid;
  1204     @{term b} may be flexible. *}
  1205   by auto
  1206 
  1207 lemma UN_E [elim!]: "b \<in> (\<Union>x\<in>A. B x) \<Longrightarrow> (\<And>x. x\<in>A \<Longrightarrow> b \<in> B x \<Longrightarrow> R) \<Longrightarrow> R"
  1208   by (auto simp add: SUP_def image_def)
  1209 
  1210 lemma image_eq_UN: "f ` A = (\<Union>x\<in>A. {f x})"
  1211   by blast
  1212 
  1213 lemma UN_upper: "a \<in> A \<Longrightarrow> B a \<subseteq> (\<Union>x\<in>A. B x)"
  1214   by (fact SUP_upper)
  1215 
  1216 lemma UN_least: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C) \<Longrightarrow> (\<Union>x\<in>A. B x) \<subseteq> C"
  1217   by (fact SUP_least)
  1218 
  1219 lemma Collect_bex_eq: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1220   by blast
  1221 
  1222 lemma UN_insert_distrib: "u \<in> A \<Longrightarrow> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1223   by blast
  1224 
  1225 lemma UN_empty: "(\<Union>x\<in>{}. B x) = {}"
  1226   by (fact SUP_empty)
  1227 
  1228 lemma UN_empty2: "(\<Union>x\<in>A. {}) = {}"
  1229   by (fact SUP_bot) (* already simp *)
  1230 
  1231 lemma UN_absorb: "k \<in> I \<Longrightarrow> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1232   by (fact SUP_absorb)
  1233 
  1234 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1235   by (fact SUP_insert)
  1236 
  1237 lemma UN_Un [simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1238   by (fact SUP_union)
  1239 
  1240 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1241   by blast
  1242 
  1243 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1244   by (fact SUP_le_iff)
  1245 
  1246 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1247   by (fact SUP_constant)
  1248 
  1249 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1250   by blast
  1251 
  1252 lemma UNION_empty_conv:
  1253   "{} = (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1254   "(\<Union>x\<in>A. B x) = {} \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1255   by (fact SUP_bot_conv)+ (* already simp *)
  1256 
  1257 lemma Collect_ex_eq: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1258   by blast
  1259 
  1260 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) \<longleftrightarrow> (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1261   by blast
  1262 
  1263 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) \<longleftrightarrow> (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1264   by blast
  1265 
  1266 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1267   by (auto simp add: split_if_mem2)
  1268 
  1269 lemma UN_bool_eq: "(\<Union>b. A b) = (A True \<union> A False)"
  1270   by (fact SUP_UNIV_bool_expand)
  1271 
  1272 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1273   by blast
  1274 
  1275 lemma UN_mono:
  1276   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow>
  1277     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1278   by (fact SUP_subset_mono)
  1279 
  1280 lemma vimage_Union: "f -` (\<Union>A) = (\<Union>X\<in>A. f -` X)"
  1281   by blast
  1282 
  1283 lemma vimage_UN: "f -` (\<Union>x\<in>A. B x) = (\<Union>x\<in>A. f -` B x)"
  1284   by blast
  1285 
  1286 lemma vimage_eq_UN: "f -` B = (\<Union>y\<in>B. f -` {y})"
  1287   -- {* NOT suitable for rewriting *}
  1288   by blast
  1289 
  1290 lemma image_UN: "f ` UNION A B = (\<Union>x\<in>A. f ` B x)"
  1291   by blast
  1292 
  1293 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1294   by blast
  1295 
  1296 
  1297 subsubsection {* Distributive laws *}
  1298 
  1299 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1300   by (fact inf_Sup)
  1301 
  1302 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1303   by (fact sup_Inf)
  1304 
  1305 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1306   by (fact Sup_inf)
  1307 
  1308 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1309   by (rule sym) (rule INF_inf_distrib)
  1310 
  1311 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1312   by (rule sym) (rule SUP_sup_distrib)
  1313 
  1314 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A ` C) \<inter> \<Inter>(B ` C)" -- {* FIXME drop *}
  1315   by (simp add: INT_Int_distrib)
  1316 
  1317 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A ` C) \<union> \<Union>(B ` C)" -- {* FIXME drop *}
  1318   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1319   -- {* Union of a family of unions *}
  1320   by (simp add: UN_Un_distrib)
  1321 
  1322 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1323   by (fact sup_INF)
  1324 
  1325 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1326   -- {* Halmos, Naive Set Theory, page 35. *}
  1327   by (fact inf_SUP)
  1328 
  1329 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1330   by (fact SUP_inf_distrib2)
  1331 
  1332 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1333   by (fact INF_sup_distrib2)
  1334 
  1335 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) \<longleftrightarrow> (\<forall>B\<in>C. B \<inter> A = {})"
  1336   by (fact Sup_inf_eq_bot_iff)
  1337 
  1338 
  1339 subsection {* Injections and bijections *}
  1340 
  1341 lemma inj_on_Inter:
  1342   "S \<noteq> {} \<Longrightarrow> (\<And>A. A \<in> S \<Longrightarrow> inj_on f A) \<Longrightarrow> inj_on f (\<Inter>S)"
  1343   unfolding inj_on_def by blast
  1344 
  1345 lemma inj_on_INTER:
  1346   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> inj_on f (A i)) \<Longrightarrow> inj_on f (\<Inter>i \<in> I. A i)"
  1347   unfolding inj_on_def by blast
  1348 
  1349 lemma inj_on_UNION_chain:
  1350   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
  1351          INJ: "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
  1352   shows "inj_on f (\<Union> i \<in> I. A i)"
  1353 proof -
  1354   {
  1355     fix i j x y
  1356     assume *: "i \<in> I" "j \<in> I" and **: "x \<in> A i" "y \<in> A j"
  1357       and ***: "f x = f y"
  1358     have "x = y"
  1359     proof -
  1360       {
  1361         assume "A i \<le> A j"
  1362         with ** have "x \<in> A j" by auto
  1363         with INJ * ** *** have ?thesis
  1364         by(auto simp add: inj_on_def)
  1365       }
  1366       moreover
  1367       {
  1368         assume "A j \<le> A i"
  1369         with ** have "y \<in> A i" by auto
  1370         with INJ * ** *** have ?thesis
  1371         by(auto simp add: inj_on_def)
  1372       }
  1373       ultimately show ?thesis using CH * by blast
  1374     qed
  1375   }
  1376   then show ?thesis by (unfold inj_on_def UNION_eq) auto
  1377 qed
  1378 
  1379 lemma bij_betw_UNION_chain:
  1380   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
  1381          BIJ: "\<And> i. i \<in> I \<Longrightarrow> bij_betw f (A i) (A' i)"
  1382   shows "bij_betw f (\<Union> i \<in> I. A i) (\<Union> i \<in> I. A' i)"
  1383 proof (unfold bij_betw_def, auto)
  1384   have "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
  1385   using BIJ bij_betw_def[of f] by auto
  1386   thus "inj_on f (\<Union> i \<in> I. A i)"
  1387   using CH inj_on_UNION_chain[of I A f] by auto
  1388 next
  1389   fix i x
  1390   assume *: "i \<in> I" "x \<in> A i"
  1391   hence "f x \<in> A' i" using BIJ bij_betw_def[of f] by auto
  1392   thus "\<exists>j \<in> I. f x \<in> A' j" using * by blast
  1393 next
  1394   fix i x'
  1395   assume *: "i \<in> I" "x' \<in> A' i"
  1396   hence "\<exists>x \<in> A i. x' = f x" using BIJ bij_betw_def[of f] by blast
  1397   then have "\<exists>j \<in> I. \<exists>x \<in> A j. x' = f x"
  1398     using * by blast
  1399   then show "x' \<in> f ` (\<Union>x\<in>I. A x)" by blast
  1400 qed
  1401 
  1402 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
  1403 lemma image_INT:
  1404    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
  1405     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
  1406 apply (simp add: inj_on_def, blast)
  1407 done
  1408 
  1409 (*Compare with image_INT: no use of inj_on, and if f is surjective then
  1410   it doesn't matter whether A is empty*)
  1411 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
  1412 apply (simp add: bij_def)
  1413 apply (simp add: inj_on_def surj_def, blast)
  1414 done
  1415 
  1416 lemma UNION_fun_upd:
  1417   "UNION J (A(i:=B)) = (UNION (J-{i}) A \<union> (if i\<in>J then B else {}))"
  1418 by (auto split: if_splits)
  1419 
  1420 
  1421 subsubsection {* Complement *}
  1422 
  1423 lemma Compl_INT [simp]: "- (\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1424   by (fact uminus_INF)
  1425 
  1426 lemma Compl_UN [simp]: "- (\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1427   by (fact uminus_SUP)
  1428 
  1429 
  1430 subsubsection {* Miniscoping and maxiscoping *}
  1431 
  1432 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1433            and Intersections. *}
  1434 
  1435 lemma UN_simps [simp]:
  1436   "\<And>a B C. (\<Union>x\<in>C. insert a (B x)) = (if C={} then {} else insert a (\<Union>x\<in>C. B x))"
  1437   "\<And>A B C. (\<Union>x\<in>C. A x \<union> B) = ((if C={} then {} else (\<Union>x\<in>C. A x) \<union> B))"
  1438   "\<And>A B C. (\<Union>x\<in>C. A \<union> B x) = ((if C={} then {} else A \<union> (\<Union>x\<in>C. B x)))"
  1439   "\<And>A B C. (\<Union>x\<in>C. A x \<inter> B) = ((\<Union>x\<in>C. A x) \<inter> B)"
  1440   "\<And>A B C. (\<Union>x\<in>C. A \<inter> B x) = (A \<inter>(\<Union>x\<in>C. B x))"
  1441   "\<And>A B C. (\<Union>x\<in>C. A x - B) = ((\<Union>x\<in>C. A x) - B)"
  1442   "\<And>A B C. (\<Union>x\<in>C. A - B x) = (A - (\<Inter>x\<in>C. B x))"
  1443   "\<And>A B. (\<Union>x\<in>\<Union>A. B x) = (\<Union>y\<in>A. \<Union>x\<in>y. B x)"
  1444   "\<And>A B C. (\<Union>z\<in>UNION A B. C z) = (\<Union>x\<in>A. \<Union>z\<in>B x. C z)"
  1445   "\<And>A B f. (\<Union>x\<in>f`A. B x) = (\<Union>a\<in>A. B (f a))"
  1446   by auto
  1447 
  1448 lemma INT_simps [simp]:
  1449   "\<And>A B C. (\<Inter>x\<in>C. A x \<inter> B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) \<inter> B)"
  1450   "\<And>A B C. (\<Inter>x\<in>C. A \<inter> B x) = (if C={} then UNIV else A \<inter>(\<Inter>x\<in>C. B x))"
  1451   "\<And>A B C. (\<Inter>x\<in>C. A x - B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) - B)"
  1452   "\<And>A B C. (\<Inter>x\<in>C. A - B x) = (if C={} then UNIV else A - (\<Union>x\<in>C. B x))"
  1453   "\<And>a B C. (\<Inter>x\<in>C. insert a (B x)) = insert a (\<Inter>x\<in>C. B x)"
  1454   "\<And>A B C. (\<Inter>x\<in>C. A x \<union> B) = ((\<Inter>x\<in>C. A x) \<union> B)"
  1455   "\<And>A B C. (\<Inter>x\<in>C. A \<union> B x) = (A \<union> (\<Inter>x\<in>C. B x))"
  1456   "\<And>A B. (\<Inter>x\<in>\<Union>A. B x) = (\<Inter>y\<in>A. \<Inter>x\<in>y. B x)"
  1457   "\<And>A B C. (\<Inter>z\<in>UNION A B. C z) = (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z)"
  1458   "\<And>A B f. (\<Inter>x\<in>f`A. B x) = (\<Inter>a\<in>A. B (f a))"
  1459   by auto
  1460 
  1461 lemma UN_ball_bex_simps [simp]:
  1462   "\<And>A P. (\<forall>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<forall>y\<in>A. \<forall>x\<in>y. P x)"
  1463   "\<And>A B P. (\<forall>x\<in>UNION A B. P x) = (\<forall>a\<in>A. \<forall>x\<in> B a. P x)"
  1464   "\<And>A P. (\<exists>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>x\<in>y. P x)"
  1465   "\<And>A B P. (\<exists>x\<in>UNION A B. P x) \<longleftrightarrow> (\<exists>a\<in>A. \<exists>x\<in>B a. P x)"
  1466   by auto
  1467 
  1468 
  1469 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1470 
  1471 lemma UN_extend_simps:
  1472   "\<And>a B C. insert a (\<Union>x\<in>C. B x) = (if C={} then {a} else (\<Union>x\<in>C. insert a (B x)))"
  1473   "\<And>A B C. (\<Union>x\<in>C. A x) \<union> B = (if C={} then B else (\<Union>x\<in>C. A x \<union> B))"
  1474   "\<And>A B C. A \<union> (\<Union>x\<in>C. B x) = (if C={} then A else (\<Union>x\<in>C. A \<union> B x))"
  1475   "\<And>A B C. ((\<Union>x\<in>C. A x) \<inter> B) = (\<Union>x\<in>C. A x \<inter> B)"
  1476   "\<And>A B C. (A \<inter> (\<Union>x\<in>C. B x)) = (\<Union>x\<in>C. A \<inter> B x)"
  1477   "\<And>A B C. ((\<Union>x\<in>C. A x) - B) = (\<Union>x\<in>C. A x - B)"
  1478   "\<And>A B C. (A - (\<Inter>x\<in>C. B x)) = (\<Union>x\<in>C. A - B x)"
  1479   "\<And>A B. (\<Union>y\<in>A. \<Union>x\<in>y. B x) = (\<Union>x\<in>\<Union>A. B x)"
  1480   "\<And>A B C. (\<Union>x\<in>A. \<Union>z\<in>B x. C z) = (\<Union>z\<in>UNION A B. C z)"
  1481   "\<And>A B f. (\<Union>a\<in>A. B (f a)) = (\<Union>x\<in>f`A. B x)"
  1482   by auto
  1483 
  1484 lemma INT_extend_simps:
  1485   "\<And>A B C. (\<Inter>x\<in>C. A x) \<inter> B = (if C={} then B else (\<Inter>x\<in>C. A x \<inter> B))"
  1486   "\<And>A B C. A \<inter> (\<Inter>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A \<inter> B x))"
  1487   "\<And>A B C. (\<Inter>x\<in>C. A x) - B = (if C={} then UNIV - B else (\<Inter>x\<in>C. A x - B))"
  1488   "\<And>A B C. A - (\<Union>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A - B x))"
  1489   "\<And>a B C. insert a (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. insert a (B x))"
  1490   "\<And>A B C. ((\<Inter>x\<in>C. A x) \<union> B) = (\<Inter>x\<in>C. A x \<union> B)"
  1491   "\<And>A B C. A \<union> (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. A \<union> B x)"
  1492   "\<And>A B. (\<Inter>y\<in>A. \<Inter>x\<in>y. B x) = (\<Inter>x\<in>\<Union>A. B x)"
  1493   "\<And>A B C. (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z) = (\<Inter>z\<in>UNION A B. C z)"
  1494   "\<And>A B f. (\<Inter>a\<in>A. B (f a)) = (\<Inter>x\<in>f`A. B x)"
  1495   by auto
  1496 
  1497 text {* Finally *}
  1498 
  1499 no_notation
  1500   less_eq (infix "\<sqsubseteq>" 50) and
  1501   less (infix "\<sqsubset>" 50)
  1502 
  1503 lemmas mem_simps =
  1504   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
  1505   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
  1506   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
  1507 
  1508 end
  1509