src/HOL/Deriv.thy
author haftmann
Fri Oct 10 19:55:32 2014 +0200 (2014-10-10)
changeset 58646 cd63a4b12a33
parent 57953 69728243a614
child 58729 e8ecc79aee43
permissions -rw-r--r--
specialized specification: avoid trivial instances
     1 (*  Title       : Deriv.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4     Author      : Brian Huffman
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     6     GMVT by Benjamin Porter, 2005
     7 *)
     8 
     9 header{* Differentiation *}
    10 
    11 theory Deriv
    12 imports Limits
    13 begin
    14 
    15 subsection {* Frechet derivative *}
    16 
    17 definition
    18   has_derivative :: "('a::real_normed_vector \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow>  bool"
    19   (infix "(has'_derivative)" 50)
    20 where
    21   "(f has_derivative f') F \<longleftrightarrow>
    22     (bounded_linear f' \<and>
    23      ((\<lambda>y. ((f y - f (Lim F (\<lambda>x. x))) - f' (y - Lim F (\<lambda>x. x))) /\<^sub>R norm (y - Lim F (\<lambda>x. x))) ---> 0) F)"
    24 
    25 text {*
    26   Usually the filter @{term F} is @{term "at x within s"}.  @{term "(f has_derivative D)
    27   (at x within s)"} means: @{term D} is the derivative of function @{term f} at point @{term x}
    28   within the set @{term s}. Where @{term s} is used to express left or right sided derivatives. In
    29   most cases @{term s} is either a variable or @{term UNIV}.
    30 *}
    31 
    32 lemma has_derivative_eq_rhs: "(f has_derivative f') F \<Longrightarrow> f' = g' \<Longrightarrow> (f has_derivative g') F"
    33   by simp
    34 
    35 definition 
    36   has_field_derivative :: "('a::real_normed_field \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a filter \<Rightarrow> bool"
    37   (infix "(has'_field'_derivative)" 50)
    38 where
    39   "(f has_field_derivative D) F \<longleftrightarrow> (f has_derivative op * D) F"
    40 
    41 lemma DERIV_cong: "(f has_field_derivative X) F \<Longrightarrow> X = Y \<Longrightarrow> (f has_field_derivative Y) F"
    42   by simp
    43 
    44 definition
    45   has_vector_derivative :: "(real \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'b \<Rightarrow> real filter \<Rightarrow> bool"
    46   (infix "has'_vector'_derivative" 50)
    47 where
    48   "(f has_vector_derivative f') net \<longleftrightarrow> (f has_derivative (\<lambda>x. x *\<^sub>R f')) net"
    49 
    50 lemma has_vector_derivative_eq_rhs: "(f has_vector_derivative X) F \<Longrightarrow> X = Y \<Longrightarrow> (f has_vector_derivative Y) F"
    51   by simp
    52 
    53 named_theorems derivative_intros "structural introduction rules for derivatives"
    54 setup {*
    55   let
    56     val eq_thms = @{thms has_derivative_eq_rhs DERIV_cong has_vector_derivative_eq_rhs}
    57     fun eq_rule thm = get_first (try (fn eq_thm => eq_thm OF [thm])) eq_thms
    58   in
    59     Global_Theory.add_thms_dynamic
    60       (@{binding derivative_eq_intros},
    61         fn context =>
    62           Named_Theorems.get (Context.proof_of context) @{named_theorems derivative_intros}
    63           |> map_filter eq_rule)
    64   end;
    65 *}
    66 
    67 text {*
    68   The following syntax is only used as a legacy syntax.
    69 *}
    70 abbreviation (input)
    71   FDERIV :: "('a::real_normed_vector \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a \<Rightarrow>  ('a \<Rightarrow> 'b) \<Rightarrow> bool"
    72   ("(FDERIV (_)/ (_)/ :> (_))" [1000, 1000, 60] 60)
    73 where
    74   "FDERIV f x :> f' \<equiv> (f has_derivative f') (at x)"
    75 
    76 lemma has_derivative_bounded_linear: "(f has_derivative f') F \<Longrightarrow> bounded_linear f'"
    77   by (simp add: has_derivative_def)
    78 
    79 lemma has_derivative_linear: "(f has_derivative f') F \<Longrightarrow> linear f'"
    80   using bounded_linear.linear[OF has_derivative_bounded_linear] .
    81 
    82 lemma has_derivative_ident[derivative_intros, simp]: "((\<lambda>x. x) has_derivative (\<lambda>x. x)) F"
    83   by (simp add: has_derivative_def tendsto_const)
    84 
    85 lemma has_derivative_const[derivative_intros, simp]: "((\<lambda>x. c) has_derivative (\<lambda>x. 0)) F"
    86   by (simp add: has_derivative_def tendsto_const)
    87 
    88 lemma (in bounded_linear) bounded_linear: "bounded_linear f" ..
    89 
    90 lemma (in bounded_linear) has_derivative:
    91   "(g has_derivative g') F \<Longrightarrow> ((\<lambda>x. f (g x)) has_derivative (\<lambda>x. f (g' x))) F"
    92   using assms unfolding has_derivative_def
    93   apply safe
    94   apply (erule bounded_linear_compose [OF bounded_linear])
    95   apply (drule tendsto)
    96   apply (simp add: scaleR diff add zero)
    97   done
    98 
    99 lemmas has_derivative_scaleR_right [derivative_intros] =
   100   bounded_linear.has_derivative [OF bounded_linear_scaleR_right]
   101 
   102 lemmas has_derivative_scaleR_left [derivative_intros] =
   103   bounded_linear.has_derivative [OF bounded_linear_scaleR_left]
   104 
   105 lemmas has_derivative_mult_right [derivative_intros] =
   106   bounded_linear.has_derivative [OF bounded_linear_mult_right]
   107 
   108 lemmas has_derivative_mult_left [derivative_intros] =
   109   bounded_linear.has_derivative [OF bounded_linear_mult_left]
   110 
   111 lemma has_derivative_add[simp, derivative_intros]:
   112   assumes f: "(f has_derivative f') F" and g: "(g has_derivative g') F"
   113   shows "((\<lambda>x. f x + g x) has_derivative (\<lambda>x. f' x + g' x)) F"
   114   unfolding has_derivative_def
   115 proof safe
   116   let ?x = "Lim F (\<lambda>x. x)"
   117   let ?D = "\<lambda>f f' y. ((f y - f ?x) - f' (y - ?x)) /\<^sub>R norm (y - ?x)"
   118   have "((\<lambda>x. ?D f f' x + ?D g g' x) ---> (0 + 0)) F"
   119     using f g by (intro tendsto_add) (auto simp: has_derivative_def)
   120   then show "(?D (\<lambda>x. f x + g x) (\<lambda>x. f' x + g' x) ---> 0) F"
   121     by (simp add: field_simps scaleR_add_right scaleR_diff_right)
   122 qed (blast intro: bounded_linear_add f g has_derivative_bounded_linear)
   123 
   124 lemma has_derivative_setsum[simp, derivative_intros]:
   125   assumes f: "\<And>i. i \<in> I \<Longrightarrow> (f i has_derivative f' i) F"
   126   shows "((\<lambda>x. \<Sum>i\<in>I. f i x) has_derivative (\<lambda>x. \<Sum>i\<in>I. f' i x)) F"
   127 proof cases
   128   assume "finite I" from this f show ?thesis
   129     by induct (simp_all add: f)
   130 qed simp
   131 
   132 lemma has_derivative_minus[simp, derivative_intros]: "(f has_derivative f') F \<Longrightarrow> ((\<lambda>x. - f x) has_derivative (\<lambda>x. - f' x)) F"
   133   using has_derivative_scaleR_right[of f f' F "-1"] by simp
   134 
   135 lemma has_derivative_diff[simp, derivative_intros]:
   136   "(f has_derivative f') F \<Longrightarrow> (g has_derivative g') F \<Longrightarrow> ((\<lambda>x. f x - g x) has_derivative (\<lambda>x. f' x - g' x)) F"
   137   by (simp only: diff_conv_add_uminus has_derivative_add has_derivative_minus)
   138 
   139 lemma has_derivative_at_within:
   140   "(f has_derivative f') (at x within s) \<longleftrightarrow>
   141     (bounded_linear f' \<and> ((\<lambda>y. ((f y - f x) - f' (y - x)) /\<^sub>R norm (y - x)) ---> 0) (at x within s))"
   142   by (cases "at x within s = bot") (simp_all add: has_derivative_def Lim_ident_at)
   143 
   144 lemma has_derivative_iff_norm:
   145   "(f has_derivative f') (at x within s) \<longleftrightarrow>
   146     (bounded_linear f' \<and> ((\<lambda>y. norm ((f y - f x) - f' (y - x)) / norm (y - x)) ---> 0) (at x within s))"
   147   using tendsto_norm_zero_iff[of _ "at x within s", where 'b="'b", symmetric]
   148   by (simp add: has_derivative_at_within divide_inverse ac_simps)
   149 
   150 lemma has_derivative_at:
   151   "(f has_derivative D) (at x) \<longleftrightarrow> (bounded_linear D \<and> (\<lambda>h. norm (f (x + h) - f x - D h) / norm h) -- 0 --> 0)"
   152   unfolding has_derivative_iff_norm LIM_offset_zero_iff[of _ _ x] by simp
   153 
   154 lemma field_has_derivative_at:
   155   fixes x :: "'a::real_normed_field"
   156   shows "(f has_derivative op * D) (at x) \<longleftrightarrow> (\<lambda>h. (f (x + h) - f x) / h) -- 0 --> D"
   157   apply (unfold has_derivative_at)
   158   apply (simp add: bounded_linear_mult_right)
   159   apply (simp cong: LIM_cong add: nonzero_norm_divide [symmetric])
   160   apply (subst diff_divide_distrib)
   161   apply (subst times_divide_eq_left [symmetric])
   162   apply (simp cong: LIM_cong)
   163   apply (simp add: tendsto_norm_zero_iff LIM_zero_iff)
   164   done
   165 
   166 lemma has_derivativeI:
   167   "bounded_linear f' \<Longrightarrow> ((\<lambda>y. ((f y - f x) - f' (y - x)) /\<^sub>R norm (y - x)) ---> 0) (at x within s) \<Longrightarrow>
   168   (f has_derivative f') (at x within s)"
   169   by (simp add: has_derivative_at_within)
   170 
   171 lemma has_derivativeI_sandwich:
   172   assumes e: "0 < e" and bounded: "bounded_linear f'"
   173     and sandwich: "(\<And>y. y \<in> s \<Longrightarrow> y \<noteq> x \<Longrightarrow> dist y x < e \<Longrightarrow> norm ((f y - f x) - f' (y - x)) / norm (y - x) \<le> H y)"
   174     and "(H ---> 0) (at x within s)"
   175   shows "(f has_derivative f') (at x within s)"
   176   unfolding has_derivative_iff_norm
   177 proof safe
   178   show "((\<lambda>y. norm (f y - f x - f' (y - x)) / norm (y - x)) ---> 0) (at x within s)"
   179   proof (rule tendsto_sandwich[where f="\<lambda>x. 0"])
   180     show "(H ---> 0) (at x within s)" by fact
   181     show "eventually (\<lambda>n. norm (f n - f x - f' (n - x)) / norm (n - x) \<le> H n) (at x within s)"
   182       unfolding eventually_at using e sandwich by auto
   183   qed (auto simp: le_divide_eq tendsto_const)
   184 qed fact
   185 
   186 lemma has_derivative_subset: "(f has_derivative f') (at x within s) \<Longrightarrow> t \<subseteq> s \<Longrightarrow> (f has_derivative f') (at x within t)"
   187   by (auto simp add: has_derivative_iff_norm intro: tendsto_within_subset)
   188 
   189 lemmas has_derivative_within_subset = has_derivative_subset 
   190 
   191 
   192 subsection {* Continuity *}
   193 
   194 lemma has_derivative_continuous:
   195   assumes f: "(f has_derivative f') (at x within s)"
   196   shows "continuous (at x within s) f"
   197 proof -
   198   from f interpret F: bounded_linear f' by (rule has_derivative_bounded_linear)
   199   note F.tendsto[tendsto_intros]
   200   let ?L = "\<lambda>f. (f ---> 0) (at x within s)"
   201   have "?L (\<lambda>y. norm ((f y - f x) - f' (y - x)) / norm (y - x))"
   202     using f unfolding has_derivative_iff_norm by blast
   203   then have "?L (\<lambda>y. norm ((f y - f x) - f' (y - x)) / norm (y - x) * norm (y - x))" (is ?m)
   204     by (rule tendsto_mult_zero) (auto intro!: tendsto_eq_intros)
   205   also have "?m \<longleftrightarrow> ?L (\<lambda>y. norm ((f y - f x) - f' (y - x)))"
   206     by (intro filterlim_cong) (simp_all add: eventually_at_filter)
   207   finally have "?L (\<lambda>y. (f y - f x) - f' (y - x))"
   208     by (rule tendsto_norm_zero_cancel)
   209   then have "?L (\<lambda>y. ((f y - f x) - f' (y - x)) + f' (y - x))"
   210     by (rule tendsto_eq_intros) (auto intro!: tendsto_eq_intros simp: F.zero)
   211   then have "?L (\<lambda>y. f y - f x)"
   212     by simp
   213   from tendsto_add[OF this tendsto_const, of "f x"] show ?thesis
   214     by (simp add: continuous_within)
   215 qed
   216 
   217 subsection {* Composition *}
   218 
   219 lemma tendsto_at_iff_tendsto_nhds_within: "f x = y \<Longrightarrow> (f ---> y) (at x within s) \<longleftrightarrow> (f ---> y) (inf (nhds x) (principal s))"
   220   unfolding tendsto_def eventually_inf_principal eventually_at_filter
   221   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
   222 
   223 lemma has_derivative_in_compose:
   224   assumes f: "(f has_derivative f') (at x within s)"
   225   assumes g: "(g has_derivative g') (at (f x) within (f`s))"
   226   shows "((\<lambda>x. g (f x)) has_derivative (\<lambda>x. g' (f' x))) (at x within s)"
   227 proof -
   228   from f interpret F: bounded_linear f' by (rule has_derivative_bounded_linear)
   229   from g interpret G: bounded_linear g' by (rule has_derivative_bounded_linear)
   230   from F.bounded obtain kF where kF: "\<And>x. norm (f' x) \<le> norm x * kF" by fast
   231   from G.bounded obtain kG where kG: "\<And>x. norm (g' x) \<le> norm x * kG" by fast
   232   note G.tendsto[tendsto_intros]
   233 
   234   let ?L = "\<lambda>f. (f ---> 0) (at x within s)"
   235   let ?D = "\<lambda>f f' x y. (f y - f x) - f' (y - x)"
   236   let ?N = "\<lambda>f f' x y. norm (?D f f' x y) / norm (y - x)"
   237   let ?gf = "\<lambda>x. g (f x)" and ?gf' = "\<lambda>x. g' (f' x)"
   238   def Nf \<equiv> "?N f f' x"
   239   def Ng \<equiv> "\<lambda>y. ?N g g' (f x) (f y)"
   240 
   241   show ?thesis
   242   proof (rule has_derivativeI_sandwich[of 1])
   243     show "bounded_linear (\<lambda>x. g' (f' x))"
   244       using f g by (blast intro: bounded_linear_compose has_derivative_bounded_linear)
   245   next
   246     fix y::'a assume neq: "y \<noteq> x"
   247     have "?N ?gf ?gf' x y = norm (g' (?D f f' x y) + ?D g g' (f x) (f y)) / norm (y - x)"
   248       by (simp add: G.diff G.add field_simps)
   249     also have "\<dots> \<le> norm (g' (?D f f' x y)) / norm (y - x) + Ng y * (norm (f y - f x) / norm (y - x))"
   250       by (simp add: add_divide_distrib[symmetric] divide_right_mono norm_triangle_ineq G.zero Ng_def)
   251     also have "\<dots> \<le> Nf y * kG + Ng y * (Nf y + kF)"
   252     proof (intro add_mono mult_left_mono)
   253       have "norm (f y - f x) = norm (?D f f' x y + f' (y - x))"
   254         by simp
   255       also have "\<dots> \<le> norm (?D f f' x y) + norm (f' (y - x))"
   256         by (rule norm_triangle_ineq)
   257       also have "\<dots> \<le> norm (?D f f' x y) + norm (y - x) * kF"
   258         using kF by (intro add_mono) simp
   259       finally show "norm (f y - f x) / norm (y - x) \<le> Nf y + kF"
   260         by (simp add: neq Nf_def field_simps)
   261     qed (insert kG, simp_all add: Ng_def Nf_def neq zero_le_divide_iff field_simps)
   262     finally show "?N ?gf ?gf' x y \<le> Nf y * kG + Ng y * (Nf y + kF)" .
   263   next
   264     have [tendsto_intros]: "?L Nf"
   265       using f unfolding has_derivative_iff_norm Nf_def ..
   266     from f have "(f ---> f x) (at x within s)"
   267       by (blast intro: has_derivative_continuous continuous_within[THEN iffD1])
   268     then have f': "LIM x at x within s. f x :> inf (nhds (f x)) (principal (f`s))"
   269       unfolding filterlim_def
   270       by (simp add: eventually_filtermap eventually_at_filter le_principal)
   271 
   272     have "((?N g  g' (f x)) ---> 0) (at (f x) within f`s)"
   273       using g unfolding has_derivative_iff_norm ..
   274     then have g': "((?N g  g' (f x)) ---> 0) (inf (nhds (f x)) (principal (f`s)))"
   275       by (rule tendsto_at_iff_tendsto_nhds_within[THEN iffD1, rotated]) simp
   276 
   277     have [tendsto_intros]: "?L Ng"
   278       unfolding Ng_def by (rule filterlim_compose[OF g' f'])
   279     show "((\<lambda>y. Nf y * kG + Ng y * (Nf y + kF)) ---> 0) (at x within s)"
   280       by (intro tendsto_eq_intros) auto
   281   qed simp
   282 qed
   283 
   284 lemma has_derivative_compose:
   285   "(f has_derivative f') (at x within s) \<Longrightarrow> (g has_derivative g') (at (f x)) \<Longrightarrow>
   286   ((\<lambda>x. g (f x)) has_derivative (\<lambda>x. g' (f' x))) (at x within s)"
   287   by (blast intro: has_derivative_in_compose has_derivative_subset)
   288 
   289 lemma (in bounded_bilinear) FDERIV:
   290   assumes f: "(f has_derivative f') (at x within s)" and g: "(g has_derivative g') (at x within s)"
   291   shows "((\<lambda>x. f x ** g x) has_derivative (\<lambda>h. f x ** g' h + f' h ** g x)) (at x within s)"
   292 proof -
   293   from bounded_linear.bounded [OF has_derivative_bounded_linear [OF f]]
   294   obtain KF where norm_F: "\<And>x. norm (f' x) \<le> norm x * KF" by fast
   295 
   296   from pos_bounded obtain K where K: "0 < K" and norm_prod:
   297     "\<And>a b. norm (a ** b) \<le> norm a * norm b * K" by fast
   298   let ?D = "\<lambda>f f' y. f y - f x - f' (y - x)"
   299   let ?N = "\<lambda>f f' y. norm (?D f f' y) / norm (y - x)"
   300   def Ng =="?N g g'" and Nf =="?N f f'"
   301 
   302   let ?fun1 = "\<lambda>y. norm (f y ** g y - f x ** g x - (f x ** g' (y - x) + f' (y - x) ** g x)) / norm (y - x)"
   303   let ?fun2 = "\<lambda>y. norm (f x) * Ng y * K + Nf y * norm (g y) * K + KF * norm (g y - g x) * K"
   304   let ?F = "at x within s"
   305 
   306   show ?thesis
   307   proof (rule has_derivativeI_sandwich[of 1])
   308     show "bounded_linear (\<lambda>h. f x ** g' h + f' h ** g x)"
   309       by (intro bounded_linear_add
   310         bounded_linear_compose [OF bounded_linear_right] bounded_linear_compose [OF bounded_linear_left]
   311         has_derivative_bounded_linear [OF g] has_derivative_bounded_linear [OF f])
   312   next
   313     from g have "(g ---> g x) ?F"
   314       by (intro continuous_within[THEN iffD1] has_derivative_continuous)
   315     moreover from f g have "(Nf ---> 0) ?F" "(Ng ---> 0) ?F"
   316       by (simp_all add: has_derivative_iff_norm Ng_def Nf_def)
   317     ultimately have "(?fun2 ---> norm (f x) * 0 * K + 0 * norm (g x) * K + KF * norm (0::'b) * K) ?F"
   318       by (intro tendsto_intros) (simp_all add: LIM_zero_iff)
   319     then show "(?fun2 ---> 0) ?F"
   320       by simp
   321   next
   322     fix y::'d assume "y \<noteq> x"
   323     have "?fun1 y = norm (f x ** ?D g g' y + ?D f f' y ** g y + f' (y - x) ** (g y - g x)) / norm (y - x)"
   324       by (simp add: diff_left diff_right add_left add_right field_simps)
   325     also have "\<dots> \<le> (norm (f x) * norm (?D g g' y) * K + norm (?D f f' y) * norm (g y) * K +
   326         norm (y - x) * KF * norm (g y - g x) * K) / norm (y - x)"
   327       by (intro divide_right_mono mult_mono'
   328                 order_trans [OF norm_triangle_ineq add_mono]
   329                 order_trans [OF norm_prod mult_right_mono]
   330                 mult_nonneg_nonneg order_refl norm_ge_zero norm_F
   331                 K [THEN order_less_imp_le])
   332     also have "\<dots> = ?fun2 y"
   333       by (simp add: add_divide_distrib Ng_def Nf_def)
   334     finally show "?fun1 y \<le> ?fun2 y" .
   335   qed simp
   336 qed
   337 
   338 lemmas has_derivative_mult[simp, derivative_intros] = bounded_bilinear.FDERIV[OF bounded_bilinear_mult]
   339 lemmas has_derivative_scaleR[simp, derivative_intros] = bounded_bilinear.FDERIV[OF bounded_bilinear_scaleR]
   340 
   341 lemma has_derivative_setprod[simp, derivative_intros]:
   342   fixes f :: "'i \<Rightarrow> 'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   343   assumes f: "\<And>i. i \<in> I \<Longrightarrow> (f i has_derivative f' i) (at x within s)"
   344   shows "((\<lambda>x. \<Prod>i\<in>I. f i x) has_derivative (\<lambda>y. \<Sum>i\<in>I. f' i y * (\<Prod>j\<in>I - {i}. f j x))) (at x within s)"
   345 proof cases
   346   assume "finite I" from this f show ?thesis
   347   proof induct
   348     case (insert i I)
   349     let ?P = "\<lambda>y. f i x * (\<Sum>i\<in>I. f' i y * (\<Prod>j\<in>I - {i}. f j x)) + (f' i y) * (\<Prod>i\<in>I. f i x)"
   350     have "((\<lambda>x. f i x * (\<Prod>i\<in>I. f i x)) has_derivative ?P) (at x within s)"
   351       using insert by (intro has_derivative_mult) auto
   352     also have "?P = (\<lambda>y. \<Sum>i'\<in>insert i I. f' i' y * (\<Prod>j\<in>insert i I - {i'}. f j x))"
   353       using insert(1,2) by (auto simp add: setsum_right_distrib insert_Diff_if intro!: ext setsum.cong)
   354     finally show ?case
   355       using insert by simp
   356   qed simp  
   357 qed simp
   358 
   359 lemma has_derivative_power[simp, derivative_intros]:
   360   fixes f :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   361   assumes f: "(f has_derivative f') (at x within s)"
   362   shows "((\<lambda>x. f x^n) has_derivative (\<lambda>y. of_nat n * f' y * f x^(n - 1))) (at x within s)"
   363   using has_derivative_setprod[OF f, of "{..< n}"] by (simp add: setprod_constant ac_simps)
   364 
   365 lemma has_derivative_inverse':
   366   fixes x :: "'a::real_normed_div_algebra"
   367   assumes x: "x \<noteq> 0"
   368   shows "(inverse has_derivative (\<lambda>h. - (inverse x * h * inverse x))) (at x within s)"
   369         (is "(?inv has_derivative ?f) _")
   370 proof (rule has_derivativeI_sandwich)
   371   show "bounded_linear (\<lambda>h. - (?inv x * h * ?inv x))"
   372     apply (rule bounded_linear_minus)
   373     apply (rule bounded_linear_mult_const)
   374     apply (rule bounded_linear_const_mult)
   375     apply (rule bounded_linear_ident)
   376     done
   377 next
   378   show "0 < norm x" using x by simp
   379 next
   380   show "((\<lambda>y. norm (?inv y - ?inv x) * norm (?inv x)) ---> 0) (at x within s)"
   381     apply (rule tendsto_mult_left_zero)
   382     apply (rule tendsto_norm_zero)
   383     apply (rule LIM_zero)
   384     apply (rule tendsto_inverse)
   385     apply (rule tendsto_ident_at)
   386     apply (rule x)
   387     done
   388 next
   389   fix y::'a assume h: "y \<noteq> x" "dist y x < norm x"
   390   then have "y \<noteq> 0"
   391     by (auto simp: norm_conv_dist dist_commute)
   392   have "norm (?inv y - ?inv x - ?f (y -x)) / norm (y - x) = norm ((?inv y - ?inv x) * (y - x) * ?inv x) / norm (y - x)"
   393     apply (subst inverse_diff_inverse [OF `y \<noteq> 0` x])
   394     apply (subst minus_diff_minus)
   395     apply (subst norm_minus_cancel)
   396     apply (simp add: left_diff_distrib)
   397     done
   398   also have "\<dots> \<le> norm (?inv y - ?inv x) * norm (y - x) * norm (?inv x) / norm (y - x)"
   399     apply (rule divide_right_mono [OF _ norm_ge_zero])
   400     apply (rule order_trans [OF norm_mult_ineq])
   401     apply (rule mult_right_mono [OF _ norm_ge_zero])
   402     apply (rule norm_mult_ineq)
   403     done
   404   also have "\<dots> = norm (?inv y - ?inv x) * norm (?inv x)"
   405     by simp
   406   finally show "norm (?inv y - ?inv x - ?f (y -x)) / norm (y - x) \<le>
   407       norm (?inv y - ?inv x) * norm (?inv x)" .
   408 qed
   409 
   410 lemma has_derivative_inverse[simp, derivative_intros]:
   411   fixes f :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
   412   assumes x:  "f x \<noteq> 0" and f: "(f has_derivative f') (at x within s)"
   413   shows "((\<lambda>x. inverse (f x)) has_derivative (\<lambda>h. - (inverse (f x) * f' h * inverse (f x)))) (at x within s)"
   414   using has_derivative_compose[OF f has_derivative_inverse', OF x] .
   415 
   416 lemma has_derivative_divide[simp, derivative_intros]:
   417   fixes f :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
   418   assumes f: "(f has_derivative f') (at x within s)" and g: "(g has_derivative g') (at x within s)" 
   419   assumes x: "g x \<noteq> 0"
   420   shows "((\<lambda>x. f x / g x) has_derivative
   421                 (\<lambda>h. - f x * (inverse (g x) * g' h * inverse (g x)) + f' h / g x)) (at x within s)"
   422   using has_derivative_mult[OF f has_derivative_inverse[OF x g]]
   423   by (simp add: field_simps)
   424 
   425 text{*Conventional form requires mult-AC laws. Types real and complex only.*}
   426 
   427 lemma has_derivative_divide'[derivative_intros]: 
   428   fixes f :: "_ \<Rightarrow> 'a::real_normed_field"
   429   assumes f: "(f has_derivative f') (at x within s)" and g: "(g has_derivative g') (at x within s)" and x: "g x \<noteq> 0"
   430   shows "((\<lambda>x. f x / g x) has_derivative (\<lambda>h. (f' h * g x - f x * g' h) / (g x * g x))) (at x within s)"
   431 proof -
   432   { fix h
   433     have "f' h / g x - f x * (inverse (g x) * g' h * inverse (g x)) =
   434           (f' h * g x - f x * g' h) / (g x * g x)"
   435       by (simp add: field_simps x)
   436    }
   437   then show ?thesis
   438     using has_derivative_divide [OF f g] x
   439     by simp
   440 qed
   441 
   442 subsection {* Uniqueness *}
   443 
   444 text {*
   445 
   446 This can not generally shown for @{const has_derivative}, as we need to approach the point from
   447 all directions. There is a proof in @{text Multivariate_Analysis} for @{text euclidean_space}.
   448 
   449 *}
   450 
   451 lemma has_derivative_zero_unique:
   452   assumes "((\<lambda>x. 0) has_derivative F) (at x)" shows "F = (\<lambda>h. 0)"
   453 proof -
   454   interpret F: bounded_linear F
   455     using assms by (rule has_derivative_bounded_linear)
   456   let ?r = "\<lambda>h. norm (F h) / norm h"
   457   have *: "?r -- 0 --> 0"
   458     using assms unfolding has_derivative_at by simp
   459   show "F = (\<lambda>h. 0)"
   460   proof
   461     fix h show "F h = 0"
   462     proof (rule ccontr)
   463       assume **: "F h \<noteq> 0"
   464       hence h: "h \<noteq> 0" by (clarsimp simp add: F.zero)
   465       with ** have "0 < ?r h" by simp
   466       from LIM_D [OF * this] obtain s where s: "0 < s"
   467         and r: "\<And>x. x \<noteq> 0 \<Longrightarrow> norm x < s \<Longrightarrow> ?r x < ?r h" by auto
   468       from dense [OF s] obtain t where t: "0 < t \<and> t < s" ..
   469       let ?x = "scaleR (t / norm h) h"
   470       have "?x \<noteq> 0" and "norm ?x < s" using t h by simp_all
   471       hence "?r ?x < ?r h" by (rule r)
   472       thus "False" using t h by (simp add: F.scaleR)
   473     qed
   474   qed
   475 qed
   476 
   477 lemma has_derivative_unique:
   478   assumes "(f has_derivative F) (at x)" and "(f has_derivative F') (at x)" shows "F = F'"
   479 proof -
   480   have "((\<lambda>x. 0) has_derivative (\<lambda>h. F h - F' h)) (at x)"
   481     using has_derivative_diff [OF assms] by simp
   482   hence "(\<lambda>h. F h - F' h) = (\<lambda>h. 0)"
   483     by (rule has_derivative_zero_unique)
   484   thus "F = F'"
   485     unfolding fun_eq_iff right_minus_eq .
   486 qed
   487 
   488 subsection {* Differentiability predicate *}
   489 
   490 definition
   491   differentiable :: "('a::real_normed_vector \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   492   (infix "differentiable" 50)
   493 where
   494   "f differentiable F \<longleftrightarrow> (\<exists>D. (f has_derivative D) F)"
   495 
   496 lemma differentiable_subset: "f differentiable (at x within s) \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f differentiable (at x within t)"
   497   unfolding differentiable_def by (blast intro: has_derivative_subset)
   498 
   499 lemmas differentiable_within_subset = differentiable_subset
   500 
   501 lemma differentiable_ident [simp, derivative_intros]: "(\<lambda>x. x) differentiable F"
   502   unfolding differentiable_def by (blast intro: has_derivative_ident)
   503 
   504 lemma differentiable_const [simp, derivative_intros]: "(\<lambda>z. a) differentiable F"
   505   unfolding differentiable_def by (blast intro: has_derivative_const)
   506 
   507 lemma differentiable_in_compose:
   508   "f differentiable (at (g x) within (g`s)) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f (g x)) differentiable (at x within s)"
   509   unfolding differentiable_def by (blast intro: has_derivative_in_compose)
   510 
   511 lemma differentiable_compose:
   512   "f differentiable (at (g x)) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f (g x)) differentiable (at x within s)"
   513   by (blast intro: differentiable_in_compose differentiable_subset)
   514 
   515 lemma differentiable_sum [simp, derivative_intros]:
   516   "f differentiable F \<Longrightarrow> g differentiable F \<Longrightarrow> (\<lambda>x. f x + g x) differentiable F"
   517   unfolding differentiable_def by (blast intro: has_derivative_add)
   518 
   519 lemma differentiable_minus [simp, derivative_intros]:
   520   "f differentiable F \<Longrightarrow> (\<lambda>x. - f x) differentiable F"
   521   unfolding differentiable_def by (blast intro: has_derivative_minus)
   522 
   523 lemma differentiable_diff [simp, derivative_intros]:
   524   "f differentiable F \<Longrightarrow> g differentiable F \<Longrightarrow> (\<lambda>x. f x - g x) differentiable F"
   525   unfolding differentiable_def by (blast intro: has_derivative_diff)
   526 
   527 lemma differentiable_mult [simp, derivative_intros]:
   528   fixes f g :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_algebra"
   529   shows "f differentiable (at x within s) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f x * g x) differentiable (at x within s)"
   530   unfolding differentiable_def by (blast intro: has_derivative_mult)
   531 
   532 lemma differentiable_inverse [simp, derivative_intros]:
   533   fixes f :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   534   shows "f differentiable (at x within s) \<Longrightarrow> f x \<noteq> 0 \<Longrightarrow> (\<lambda>x. inverse (f x)) differentiable (at x within s)"
   535   unfolding differentiable_def by (blast intro: has_derivative_inverse)
   536 
   537 lemma differentiable_divide [simp, derivative_intros]:
   538   fixes f g :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   539   shows "f differentiable (at x within s) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow> g x \<noteq> 0 \<Longrightarrow> (\<lambda>x. f x / g x) differentiable (at x within s)"
   540   unfolding divide_inverse using assms by simp
   541 
   542 lemma differentiable_power [simp, derivative_intros]:
   543   fixes f g :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   544   shows "f differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f x ^ n) differentiable (at x within s)"
   545   unfolding differentiable_def by (blast intro: has_derivative_power)
   546 
   547 lemma differentiable_scaleR [simp, derivative_intros]:
   548   "f differentiable (at x within s) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f x *\<^sub>R g x) differentiable (at x within s)"
   549   unfolding differentiable_def by (blast intro: has_derivative_scaleR)
   550 
   551 lemma has_derivative_imp_has_field_derivative:
   552   "(f has_derivative D) F \<Longrightarrow> (\<And>x. x * D' = D x) \<Longrightarrow> (f has_field_derivative D') F"
   553   unfolding has_field_derivative_def 
   554   by (rule has_derivative_eq_rhs[of f D]) (simp_all add: fun_eq_iff mult.commute)
   555 
   556 lemma has_field_derivative_imp_has_derivative: "(f has_field_derivative D) F \<Longrightarrow> (f has_derivative op * D) F"
   557   by (simp add: has_field_derivative_def)
   558 
   559 lemma DERIV_subset: 
   560   "(f has_field_derivative f') (at x within s) \<Longrightarrow> t \<subseteq> s 
   561    \<Longrightarrow> (f has_field_derivative f') (at x within t)"
   562   by (simp add: has_field_derivative_def has_derivative_within_subset)
   563 
   564 abbreviation (input)
   565   DERIV :: "('a::real_normed_field \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
   566   ("(DERIV (_)/ (_)/ :> (_))" [1000, 1000, 60] 60)
   567 where
   568   "DERIV f x :> D \<equiv> (f has_field_derivative D) (at x)"
   569 
   570 abbreviation 
   571   has_real_derivative :: "(real \<Rightarrow> real) \<Rightarrow> real \<Rightarrow> real filter \<Rightarrow> bool"
   572   (infix "(has'_real'_derivative)" 50)
   573 where
   574   "(f has_real_derivative D) F \<equiv> (f has_field_derivative D) F"
   575 
   576 lemma real_differentiable_def:
   577   "f differentiable at x within s \<longleftrightarrow> (\<exists>D. (f has_real_derivative D) (at x within s))"
   578 proof safe
   579   assume "f differentiable at x within s"
   580   then obtain f' where *: "(f has_derivative f') (at x within s)"
   581     unfolding differentiable_def by auto
   582   then obtain c where "f' = (op * c)"
   583     by (metis real_bounded_linear has_derivative_bounded_linear mult.commute fun_eq_iff)
   584   with * show "\<exists>D. (f has_real_derivative D) (at x within s)"
   585     unfolding has_field_derivative_def by auto
   586 qed (auto simp: differentiable_def has_field_derivative_def)
   587 
   588 lemma real_differentiableE [elim?]:
   589   assumes f: "f differentiable (at x within s)" obtains df where "(f has_real_derivative df) (at x within s)"
   590   using assms by (auto simp: real_differentiable_def)
   591 
   592 lemma differentiableD: "f differentiable (at x within s) \<Longrightarrow> \<exists>D. (f has_real_derivative D) (at x within s)"
   593   by (auto elim: real_differentiableE)
   594 
   595 lemma differentiableI: "(f has_real_derivative D) (at x within s) \<Longrightarrow> f differentiable (at x within s)"
   596   by (force simp add: real_differentiable_def)
   597 
   598 lemma DERIV_def: "DERIV f x :> D \<longleftrightarrow> (\<lambda>h. (f (x + h) - f x) / h) -- 0 --> D"
   599   apply (simp add: has_field_derivative_def has_derivative_at bounded_linear_mult_right LIM_zero_iff[symmetric, of _ D])
   600   apply (subst (2) tendsto_norm_zero_iff[symmetric])
   601   apply (rule filterlim_cong)
   602   apply (simp_all add: eventually_at_filter field_simps nonzero_norm_divide)
   603   done
   604 
   605 lemma mult_commute_abs: "(\<lambda>x. x * c) = op * (c::'a::ab_semigroup_mult)"
   606   by (simp add: fun_eq_iff mult.commute)
   607 
   608 subsection {* Derivatives *}
   609 
   610 lemma DERIV_D: "DERIV f x :> D \<Longrightarrow> (\<lambda>h. (f (x + h) - f x) / h) -- 0 --> D"
   611   by (simp add: DERIV_def)
   612 
   613 lemma DERIV_const [simp, derivative_intros]: "((\<lambda>x. k) has_field_derivative 0) F"
   614   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_const]) auto
   615 
   616 lemma DERIV_ident [simp, derivative_intros]: "((\<lambda>x. x) has_field_derivative 1) F"
   617   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_ident]) auto
   618 
   619 lemma field_differentiable_add[derivative_intros]:
   620   "(f has_field_derivative f') F \<Longrightarrow> (g has_field_derivative g') F \<Longrightarrow> 
   621     ((\<lambda>z. f z + g z) has_field_derivative f' + g') F"
   622   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_add])
   623      (auto simp: has_field_derivative_def field_simps mult_commute_abs)
   624 
   625 corollary DERIV_add:
   626   "(f has_field_derivative D) (at x within s) \<Longrightarrow> (g has_field_derivative E) (at x within s) \<Longrightarrow>
   627   ((\<lambda>x. f x + g x) has_field_derivative D + E) (at x within s)"
   628   by (rule field_differentiable_add)
   629 
   630 lemma field_differentiable_minus[derivative_intros]:
   631   "(f has_field_derivative f') F \<Longrightarrow> ((\<lambda>z. - (f z)) has_field_derivative -f') F"
   632   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_minus])
   633      (auto simp: has_field_derivative_def field_simps mult_commute_abs)
   634 
   635 corollary DERIV_minus: "(f has_field_derivative D) (at x within s) \<Longrightarrow> ((\<lambda>x. - f x) has_field_derivative -D) (at x within s)"
   636   by (rule field_differentiable_minus)
   637 
   638 lemma field_differentiable_diff[derivative_intros]:
   639   "(f has_field_derivative f') F \<Longrightarrow> (g has_field_derivative g') F \<Longrightarrow> ((\<lambda>z. f z - g z) has_field_derivative f' - g') F"
   640   by (simp only: assms diff_conv_add_uminus field_differentiable_add field_differentiable_minus)
   641 
   642 corollary DERIV_diff:
   643   "(f has_field_derivative D) (at x within s) \<Longrightarrow> (g has_field_derivative E) (at x within s) \<Longrightarrow>
   644   ((\<lambda>x. f x - g x) has_field_derivative D - E) (at x within s)"
   645   by (rule field_differentiable_diff)
   646 
   647 lemma DERIV_continuous: "(f has_field_derivative D) (at x within s) \<Longrightarrow> continuous (at x within s) f"
   648   by (drule has_derivative_continuous[OF has_field_derivative_imp_has_derivative]) simp
   649 
   650 corollary DERIV_isCont: "DERIV f x :> D \<Longrightarrow> isCont f x"
   651   by (rule DERIV_continuous)
   652 
   653 lemma DERIV_continuous_on:
   654   "(\<And>x. x \<in> s \<Longrightarrow> (f has_field_derivative D) (at x)) \<Longrightarrow> continuous_on s f"
   655   by (metis DERIV_continuous continuous_at_imp_continuous_on)
   656 
   657 lemma DERIV_mult':
   658   "(f has_field_derivative D) (at x within s) \<Longrightarrow> (g has_field_derivative E) (at x within s) \<Longrightarrow>
   659   ((\<lambda>x. f x * g x) has_field_derivative f x * E + D * g x) (at x within s)"
   660   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_mult])
   661      (auto simp: field_simps mult_commute_abs dest: has_field_derivative_imp_has_derivative)
   662 
   663 lemma DERIV_mult[derivative_intros]:
   664   "(f has_field_derivative Da) (at x within s) \<Longrightarrow> (g has_field_derivative Db) (at x within s) \<Longrightarrow>
   665   ((\<lambda>x. f x * g x) has_field_derivative Da * g x + Db * f x) (at x within s)"
   666   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_mult])
   667      (auto simp: field_simps dest: has_field_derivative_imp_has_derivative)
   668 
   669 text {* Derivative of linear multiplication *}
   670 
   671 lemma DERIV_cmult:
   672   "(f has_field_derivative D) (at x within s) ==> ((\<lambda>x. c * f x) has_field_derivative c * D) (at x within s)"
   673   by (drule DERIV_mult' [OF DERIV_const], simp)
   674 
   675 lemma DERIV_cmult_right:
   676   "(f has_field_derivative D) (at x within s) ==> ((\<lambda>x. f x * c) has_field_derivative D * c) (at x within s)"
   677   using DERIV_cmult by (force simp add: ac_simps)
   678 
   679 lemma DERIV_cmult_Id [simp]: "(op * c has_field_derivative c) (at x within s)"
   680   by (cut_tac c = c and x = x in DERIV_ident [THEN DERIV_cmult], simp)
   681 
   682 lemma DERIV_cdivide:
   683   "(f has_field_derivative D) (at x within s) \<Longrightarrow> ((\<lambda>x. f x / c) has_field_derivative D / c) (at x within s)"
   684   using DERIV_cmult_right[of f D x s "1 / c"] by simp
   685 
   686 lemma DERIV_unique:
   687   "DERIV f x :> D \<Longrightarrow> DERIV f x :> E \<Longrightarrow> D = E"
   688   unfolding DERIV_def by (rule LIM_unique) 
   689 
   690 lemma DERIV_setsum[derivative_intros]:
   691   "(\<And> n. n \<in> S \<Longrightarrow> ((\<lambda>x. f x n) has_field_derivative (f' x n)) F) \<Longrightarrow> 
   692     ((\<lambda>x. setsum (f x) S) has_field_derivative setsum (f' x) S) F"
   693   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_setsum])
   694      (auto simp: setsum_right_distrib mult_commute_abs dest: has_field_derivative_imp_has_derivative)
   695 
   696 lemma DERIV_inverse'[derivative_intros]:
   697   "(f has_field_derivative D) (at x within s) \<Longrightarrow> f x \<noteq> 0 \<Longrightarrow>
   698   ((\<lambda>x. inverse (f x)) has_field_derivative - (inverse (f x) * D * inverse (f x))) (at x within s)"
   699   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_inverse])
   700      (auto dest: has_field_derivative_imp_has_derivative)
   701 
   702 text {* Power of @{text "-1"} *}
   703 
   704 lemma DERIV_inverse:
   705   "x \<noteq> 0 \<Longrightarrow> ((\<lambda>x. inverse(x)) has_field_derivative - (inverse x ^ Suc (Suc 0))) (at x within s)"
   706   by (drule DERIV_inverse' [OF DERIV_ident]) simp
   707 
   708 text {* Derivative of inverse *}
   709 
   710 lemma DERIV_inverse_fun:
   711   "(f has_field_derivative d) (at x within s) \<Longrightarrow> f x \<noteq> 0 \<Longrightarrow>
   712   ((\<lambda>x. inverse (f x)) has_field_derivative (- (d * inverse(f x ^ Suc (Suc 0))))) (at x within s)"
   713   by (drule (1) DERIV_inverse') (simp add: ac_simps nonzero_inverse_mult_distrib)
   714 
   715 text {* Derivative of quotient *}
   716 
   717 lemma DERIV_divide[derivative_intros]:
   718   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   719   (g has_field_derivative E) (at x within s) \<Longrightarrow> g x \<noteq> 0 \<Longrightarrow>
   720   ((\<lambda>x. f x / g x) has_field_derivative (D * g x - f x * E) / (g x * g x)) (at x within s)"
   721   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_divide])
   722      (auto dest: has_field_derivative_imp_has_derivative simp: field_simps)
   723 
   724 lemma DERIV_quotient:
   725   "(f has_field_derivative d) (at x within s) \<Longrightarrow>
   726   (g has_field_derivative e) (at x within s)\<Longrightarrow> g x \<noteq> 0 \<Longrightarrow> 
   727   ((\<lambda>y. f y / g y) has_field_derivative (d * g x - (e * f x)) / (g x ^ Suc (Suc 0))) (at x within s)"
   728   by (drule (2) DERIV_divide) (simp add: mult.commute)
   729 
   730 lemma DERIV_power_Suc:
   731   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   732   ((\<lambda>x. f x ^ Suc n) has_field_derivative (1 + of_nat n) * (D * f x ^ n)) (at x within s)"
   733   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_power])
   734      (auto simp: has_field_derivative_def)
   735 
   736 lemma DERIV_power[derivative_intros]:
   737   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   738   ((\<lambda>x. f x ^ n) has_field_derivative of_nat n * (D * f x ^ (n - Suc 0))) (at x within s)"
   739   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_power])
   740      (auto simp: has_field_derivative_def)
   741 
   742 lemma DERIV_pow: "((\<lambda>x. x ^ n) has_field_derivative real n * (x ^ (n - Suc 0))) (at x within s)"
   743   apply (cut_tac DERIV_power [OF DERIV_ident])
   744   apply (simp add: real_of_nat_def)
   745   done
   746 
   747 lemma DERIV_chain': "(f has_field_derivative D) (at x within s) \<Longrightarrow> DERIV g (f x) :> E \<Longrightarrow> 
   748   ((\<lambda>x. g (f x)) has_field_derivative E * D) (at x within s)"
   749   using has_derivative_compose[of f "op * D" x s g "op * E"]
   750   unfolding has_field_derivative_def mult_commute_abs ac_simps .
   751 
   752 corollary DERIV_chain2: "DERIV f (g x) :> Da \<Longrightarrow> (g has_field_derivative Db) (at x within s) \<Longrightarrow>
   753   ((\<lambda>x. f (g x)) has_field_derivative Da * Db) (at x within s)"
   754   by (rule DERIV_chain')
   755 
   756 text {* Standard version *}
   757 
   758 lemma DERIV_chain:
   759   "DERIV f (g x) :> Da \<Longrightarrow> (g has_field_derivative Db) (at x within s) \<Longrightarrow> 
   760   (f o g has_field_derivative Da * Db) (at x within s)"
   761   by (drule (1) DERIV_chain', simp add: o_def mult.commute)
   762 
   763 lemma DERIV_image_chain: 
   764   "(f has_field_derivative Da) (at (g x) within (g ` s)) \<Longrightarrow> (g has_field_derivative Db) (at x within s) \<Longrightarrow>
   765   (f o g has_field_derivative Da * Db) (at x within s)"
   766   using has_derivative_in_compose [of g "op * Db" x s f "op * Da "]
   767   by (simp add: has_field_derivative_def o_def mult_commute_abs ac_simps)
   768 
   769 (*These two are from HOL Light: HAS_COMPLEX_DERIVATIVE_CHAIN*)
   770 lemma DERIV_chain_s:
   771   assumes "(\<And>x. x \<in> s \<Longrightarrow> DERIV g x :> g'(x))"
   772       and "DERIV f x :> f'" 
   773       and "f x \<in> s"
   774     shows "DERIV (\<lambda>x. g(f x)) x :> f' * g'(f x)"
   775   by (metis (full_types) DERIV_chain' mult.commute assms)
   776 
   777 lemma DERIV_chain3: (*HAS_COMPLEX_DERIVATIVE_CHAIN_UNIV*)
   778   assumes "(\<And>x. DERIV g x :> g'(x))"
   779       and "DERIV f x :> f'" 
   780     shows "DERIV (\<lambda>x. g(f x)) x :> f' * g'(f x)"
   781   by (metis UNIV_I DERIV_chain_s [of UNIV] assms)
   782 
   783 declare
   784   DERIV_power[where 'a=real, unfolded real_of_nat_def[symmetric], derivative_intros]
   785 
   786 text{*Alternative definition for differentiability*}
   787 
   788 lemma DERIV_LIM_iff:
   789   fixes f :: "'a::{real_normed_vector,inverse} \<Rightarrow> 'a" shows
   790      "((%h. (f(a + h) - f(a)) / h) -- 0 --> D) =
   791       ((%x. (f(x)-f(a)) / (x-a)) -- a --> D)"
   792 apply (rule iffI)
   793 apply (drule_tac k="- a" in LIM_offset)
   794 apply simp
   795 apply (drule_tac k="a" in LIM_offset)
   796 apply (simp add: add.commute)
   797 done
   798 
   799 lemma DERIV_iff2: "(DERIV f x :> D) \<longleftrightarrow> (\<lambda>z. (f z - f x) / (z - x)) --x --> D"
   800   by (simp add: DERIV_def DERIV_LIM_iff)
   801 
   802 lemma DERIV_cong_ev: "x = y \<Longrightarrow> eventually (\<lambda>x. f x = g x) (nhds x) \<Longrightarrow> u = v \<Longrightarrow>
   803     DERIV f x :> u \<longleftrightarrow> DERIV g y :> v"
   804   unfolding DERIV_iff2
   805 proof (rule filterlim_cong)
   806   assume *: "eventually (\<lambda>x. f x = g x) (nhds x)"
   807   moreover from * have "f x = g x" by (auto simp: eventually_nhds)
   808   moreover assume "x = y" "u = v"
   809   ultimately show "eventually (\<lambda>xa. (f xa - f x) / (xa - x) = (g xa - g y) / (xa - y)) (at x)"
   810     by (auto simp: eventually_at_filter elim: eventually_elim1)
   811 qed simp_all
   812 
   813 lemma DERIV_shift:
   814   "(DERIV f (x + z) :> y) \<longleftrightarrow> (DERIV (\<lambda>x. f (x + z)) x :> y)"
   815   by (simp add: DERIV_def field_simps)
   816 
   817 lemma DERIV_mirror:
   818   "(DERIV f (- x) :> y) \<longleftrightarrow> (DERIV (\<lambda>x. f (- x::real) :: real) x :> - y)"
   819   by (simp add: DERIV_def filterlim_at_split filterlim_at_left_to_right
   820                 tendsto_minus_cancel_left field_simps conj_commute)
   821 
   822 text {* Caratheodory formulation of derivative at a point *}
   823 
   824 lemma CARAT_DERIV: (*FIXME: SUPERSEDED BY THE ONE IN Deriv.thy. But still used by NSA/HDeriv.thy*)
   825   "(DERIV f x :> l) \<longleftrightarrow> (\<exists>g. (\<forall>z. f z - f x = g z * (z - x)) \<and> isCont g x \<and> g x = l)"
   826       (is "?lhs = ?rhs")
   827 proof
   828   assume der: "DERIV f x :> l"
   829   show "\<exists>g. (\<forall>z. f z - f x = g z * (z-x)) \<and> isCont g x \<and> g x = l"
   830   proof (intro exI conjI)
   831     let ?g = "(%z. if z = x then l else (f z - f x) / (z-x))"
   832     show "\<forall>z. f z - f x = ?g z * (z-x)" by simp
   833     show "isCont ?g x" using der
   834       by (simp add: isCont_iff DERIV_def cong: LIM_equal [rule_format])
   835     show "?g x = l" by simp
   836   qed
   837 next
   838   assume "?rhs"
   839   then obtain g where
   840     "(\<forall>z. f z - f x = g z * (z-x))" and "isCont g x" and "g x = l" by blast
   841   thus "(DERIV f x :> l)"
   842      by (auto simp add: isCont_iff DERIV_def cong: LIM_cong)
   843 qed
   844 
   845 text {*
   846  Let's do the standard proof, though theorem
   847  @{text "LIM_mult2"} follows from a NS proof
   848 *}
   849 
   850 subsection {* Local extrema *}
   851 
   852 text{*If @{term "0 < f'(x)"} then @{term x} is Locally Strictly Increasing At The Right*}
   853 
   854 lemma DERIV_pos_inc_right:
   855   fixes f :: "real => real"
   856   assumes der: "DERIV f x :> l"
   857       and l:   "0 < l"
   858   shows "\<exists>d > 0. \<forall>h > 0. h < d --> f(x) < f(x + h)"
   859 proof -
   860   from l der [THEN DERIV_D, THEN LIM_D [where r = "l"]]
   861   have "\<exists>s > 0. (\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < l)"
   862     by simp
   863   then obtain s
   864         where s:   "0 < s"
   865           and all: "!!z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < l"
   866     by auto
   867   thus ?thesis
   868   proof (intro exI conjI strip)
   869     show "0<s" using s .
   870     fix h::real
   871     assume "0 < h" "h < s"
   872     with all [of h] show "f x < f (x+h)"
   873     proof (simp add: abs_if pos_less_divide_eq split add: split_if_asm)
   874       assume "~ (f (x+h) - f x) / h < l" and h: "0 < h"
   875       with l
   876       have "0 < (f (x+h) - f x) / h" by arith
   877       thus "f x < f (x+h)"
   878   by (simp add: pos_less_divide_eq h)
   879     qed
   880   qed
   881 qed
   882 
   883 lemma DERIV_neg_dec_left:
   884   fixes f :: "real => real"
   885   assumes der: "DERIV f x :> l"
   886       and l:   "l < 0"
   887   shows "\<exists>d > 0. \<forall>h > 0. h < d --> f(x) < f(x-h)"
   888 proof -
   889   from l der [THEN DERIV_D, THEN LIM_D [where r = "-l"]]
   890   have "\<exists>s > 0. (\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < -l)"
   891     by simp
   892   then obtain s
   893         where s:   "0 < s"
   894           and all: "!!z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < -l"
   895     by auto
   896   thus ?thesis
   897   proof (intro exI conjI strip)
   898     show "0<s" using s .
   899     fix h::real
   900     assume "0 < h" "h < s"
   901     with all [of "-h"] show "f x < f (x-h)"
   902     proof (simp add: abs_if pos_less_divide_eq split add: split_if_asm)
   903       assume " - ((f (x-h) - f x) / h) < l" and h: "0 < h"
   904       with l
   905       have "0 < (f (x-h) - f x) / h" by arith
   906       thus "f x < f (x-h)"
   907   by (simp add: pos_less_divide_eq h)
   908     qed
   909   qed
   910 qed
   911 
   912 lemma DERIV_pos_inc_left:
   913   fixes f :: "real => real"
   914   shows "DERIV f x :> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>d > 0. \<forall>h > 0. h < d --> f(x - h) < f(x)"
   915   apply (rule DERIV_neg_dec_left [of "%x. - f x" "-l" x, simplified])
   916   apply (auto simp add: DERIV_minus)
   917   done
   918 
   919 lemma DERIV_neg_dec_right:
   920   fixes f :: "real => real"
   921   shows "DERIV f x :> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>d > 0. \<forall>h > 0. h < d --> f(x) > f(x + h)"
   922   apply (rule DERIV_pos_inc_right [of "%x. - f x" "-l" x, simplified])
   923   apply (auto simp add: DERIV_minus)
   924   done
   925 
   926 lemma DERIV_local_max:
   927   fixes f :: "real => real"
   928   assumes der: "DERIV f x :> l"
   929       and d:   "0 < d"
   930       and le:  "\<forall>y. \<bar>x-y\<bar> < d --> f(y) \<le> f(x)"
   931   shows "l = 0"
   932 proof (cases rule: linorder_cases [of l 0])
   933   case equal thus ?thesis .
   934 next
   935   case less
   936   from DERIV_neg_dec_left [OF der less]
   937   obtain d' where d': "0 < d'"
   938              and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x-h)" by blast
   939   from real_lbound_gt_zero [OF d d']
   940   obtain e where "0 < e \<and> e < d \<and> e < d'" ..
   941   with lt le [THEN spec [where x="x-e"]]
   942   show ?thesis by (auto simp add: abs_if)
   943 next
   944   case greater
   945   from DERIV_pos_inc_right [OF der greater]
   946   obtain d' where d': "0 < d'"
   947              and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x + h)" by blast
   948   from real_lbound_gt_zero [OF d d']
   949   obtain e where "0 < e \<and> e < d \<and> e < d'" ..
   950   with lt le [THEN spec [where x="x+e"]]
   951   show ?thesis by (auto simp add: abs_if)
   952 qed
   953 
   954 
   955 text{*Similar theorem for a local minimum*}
   956 lemma DERIV_local_min:
   957   fixes f :: "real => real"
   958   shows "[| DERIV f x :> l; 0 < d; \<forall>y. \<bar>x-y\<bar> < d --> f(x) \<le> f(y) |] ==> l = 0"
   959 by (drule DERIV_minus [THEN DERIV_local_max], auto)
   960 
   961 
   962 text{*In particular, if a function is locally flat*}
   963 lemma DERIV_local_const:
   964   fixes f :: "real => real"
   965   shows "[| DERIV f x :> l; 0 < d; \<forall>y. \<bar>x-y\<bar> < d --> f(x) = f(y) |] ==> l = 0"
   966 by (auto dest!: DERIV_local_max)
   967 
   968 
   969 subsection {* Rolle's Theorem *}
   970 
   971 text{*Lemma about introducing open ball in open interval*}
   972 lemma lemma_interval_lt:
   973      "[| a < x;  x < b |]
   974       ==> \<exists>d::real. 0 < d & (\<forall>y. \<bar>x-y\<bar> < d --> a < y & y < b)"
   975 
   976 apply (simp add: abs_less_iff)
   977 apply (insert linorder_linear [of "x-a" "b-x"], safe)
   978 apply (rule_tac x = "x-a" in exI)
   979 apply (rule_tac [2] x = "b-x" in exI, auto)
   980 done
   981 
   982 lemma lemma_interval: "[| a < x;  x < b |] ==>
   983         \<exists>d::real. 0 < d &  (\<forall>y. \<bar>x-y\<bar> < d --> a \<le> y & y \<le> b)"
   984 apply (drule lemma_interval_lt, auto)
   985 apply force
   986 done
   987 
   988 text{*Rolle's Theorem.
   989    If @{term f} is defined and continuous on the closed interval
   990    @{text "[a,b]"} and differentiable on the open interval @{text "(a,b)"},
   991    and @{term "f(a) = f(b)"},
   992    then there exists @{text "x0 \<in> (a,b)"} such that @{term "f'(x0) = 0"}*}
   993 theorem Rolle:
   994   assumes lt: "a < b"
   995       and eq: "f(a) = f(b)"
   996       and con: "\<forall>x. a \<le> x & x \<le> b --> isCont f x"
   997       and dif [rule_format]: "\<forall>x. a < x & x < b --> f differentiable (at x)"
   998   shows "\<exists>z::real. a < z & z < b & DERIV f z :> 0"
   999 proof -
  1000   have le: "a \<le> b" using lt by simp
  1001   from isCont_eq_Ub [OF le con]
  1002   obtain x where x_max: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f z \<le> f x"
  1003              and alex: "a \<le> x" and xleb: "x \<le> b"
  1004     by blast
  1005   from isCont_eq_Lb [OF le con]
  1006   obtain x' where x'_min: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f x' \<le> f z"
  1007               and alex': "a \<le> x'" and x'leb: "x' \<le> b"
  1008     by blast
  1009   show ?thesis
  1010   proof cases
  1011     assume axb: "a < x & x < b"
  1012         --{*@{term f} attains its maximum within the interval*}
  1013     hence ax: "a<x" and xb: "x<b" by arith + 
  1014     from lemma_interval [OF ax xb]
  1015     obtain d where d: "0<d" and bound: "\<forall>y. \<bar>x-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
  1016       by blast
  1017     hence bound': "\<forall>y. \<bar>x-y\<bar> < d \<longrightarrow> f y \<le> f x" using x_max
  1018       by blast
  1019     from differentiableD [OF dif [OF axb]]
  1020     obtain l where der: "DERIV f x :> l" ..
  1021     have "l=0" by (rule DERIV_local_max [OF der d bound'])
  1022         --{*the derivative at a local maximum is zero*}
  1023     thus ?thesis using ax xb der by auto
  1024   next
  1025     assume notaxb: "~ (a < x & x < b)"
  1026     hence xeqab: "x=a | x=b" using alex xleb by arith
  1027     hence fb_eq_fx: "f b = f x" by (auto simp add: eq)
  1028     show ?thesis
  1029     proof cases
  1030       assume ax'b: "a < x' & x' < b"
  1031         --{*@{term f} attains its minimum within the interval*}
  1032       hence ax': "a<x'" and x'b: "x'<b" by arith+ 
  1033       from lemma_interval [OF ax' x'b]
  1034       obtain d where d: "0<d" and bound: "\<forall>y. \<bar>x'-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
  1035   by blast
  1036       hence bound': "\<forall>y. \<bar>x'-y\<bar> < d \<longrightarrow> f x' \<le> f y" using x'_min
  1037   by blast
  1038       from differentiableD [OF dif [OF ax'b]]
  1039       obtain l where der: "DERIV f x' :> l" ..
  1040       have "l=0" by (rule DERIV_local_min [OF der d bound'])
  1041         --{*the derivative at a local minimum is zero*}
  1042       thus ?thesis using ax' x'b der by auto
  1043     next
  1044       assume notax'b: "~ (a < x' & x' < b)"
  1045         --{*@{term f} is constant througout the interval*}
  1046       hence x'eqab: "x'=a | x'=b" using alex' x'leb by arith
  1047       hence fb_eq_fx': "f b = f x'" by (auto simp add: eq)
  1048       from dense [OF lt]
  1049       obtain r where ar: "a < r" and rb: "r < b" by blast
  1050       from lemma_interval [OF ar rb]
  1051       obtain d where d: "0<d" and bound: "\<forall>y. \<bar>r-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
  1052   by blast
  1053       have eq_fb: "\<forall>z. a \<le> z --> z \<le> b --> f z = f b"
  1054       proof (clarify)
  1055         fix z::real
  1056         assume az: "a \<le> z" and zb: "z \<le> b"
  1057         show "f z = f b"
  1058         proof (rule order_antisym)
  1059           show "f z \<le> f b" by (simp add: fb_eq_fx x_max az zb)
  1060           show "f b \<le> f z" by (simp add: fb_eq_fx' x'_min az zb)
  1061         qed
  1062       qed
  1063       have bound': "\<forall>y. \<bar>r-y\<bar> < d \<longrightarrow> f r = f y"
  1064       proof (intro strip)
  1065         fix y::real
  1066         assume lt: "\<bar>r-y\<bar> < d"
  1067         hence "f y = f b" by (simp add: eq_fb bound)
  1068         thus "f r = f y" by (simp add: eq_fb ar rb order_less_imp_le)
  1069       qed
  1070       from differentiableD [OF dif [OF conjI [OF ar rb]]]
  1071       obtain l where der: "DERIV f r :> l" ..
  1072       have "l=0" by (rule DERIV_local_const [OF der d bound'])
  1073         --{*the derivative of a constant function is zero*}
  1074       thus ?thesis using ar rb der by auto
  1075     qed
  1076   qed
  1077 qed
  1078 
  1079 
  1080 subsection{*Mean Value Theorem*}
  1081 
  1082 lemma lemma_MVT:
  1083      "f a - (f b - f a)/(b-a) * a = f b - (f b - f a)/(b-a) * (b::real)"
  1084   by (cases "a = b") (simp_all add: field_simps)
  1085 
  1086 theorem MVT:
  1087   assumes lt:  "a < b"
  1088       and con: "\<forall>x. a \<le> x & x \<le> b --> isCont f x"
  1089       and dif [rule_format]: "\<forall>x. a < x & x < b --> f differentiable (at x)"
  1090   shows "\<exists>l z::real. a < z & z < b & DERIV f z :> l &
  1091                    (f(b) - f(a) = (b-a) * l)"
  1092 proof -
  1093   let ?F = "%x. f x - ((f b - f a) / (b-a)) * x"
  1094   have contF: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?F x"
  1095     using con by (fast intro: continuous_intros)
  1096   have difF: "\<forall>x. a < x \<and> x < b \<longrightarrow> ?F differentiable (at x)"
  1097   proof (clarify)
  1098     fix x::real
  1099     assume ax: "a < x" and xb: "x < b"
  1100     from differentiableD [OF dif [OF conjI [OF ax xb]]]
  1101     obtain l where der: "DERIV f x :> l" ..
  1102     show "?F differentiable (at x)"
  1103       by (rule differentiableI [where D = "l - (f b - f a)/(b-a)"],
  1104           blast intro: DERIV_diff DERIV_cmult_Id der)
  1105   qed
  1106   from Rolle [where f = ?F, OF lt lemma_MVT contF difF]
  1107   obtain z where az: "a < z" and zb: "z < b" and der: "DERIV ?F z :> 0"
  1108     by blast
  1109   have "DERIV (%x. ((f b - f a)/(b-a)) * x) z :> (f b - f a)/(b-a)"
  1110     by (rule DERIV_cmult_Id)
  1111   hence derF: "DERIV (\<lambda>x. ?F x + (f b - f a) / (b - a) * x) z
  1112                    :> 0 + (f b - f a) / (b - a)"
  1113     by (rule DERIV_add [OF der])
  1114   show ?thesis
  1115   proof (intro exI conjI)
  1116     show "a < z" using az .
  1117     show "z < b" using zb .
  1118     show "f b - f a = (b - a) * ((f b - f a)/(b-a))" by (simp)
  1119     show "DERIV f z :> ((f b - f a)/(b-a))"  using derF by simp
  1120   qed
  1121 qed
  1122 
  1123 lemma MVT2:
  1124      "[| a < b; \<forall>x. a \<le> x & x \<le> b --> DERIV f x :> f'(x) |]
  1125       ==> \<exists>z::real. a < z & z < b & (f b - f a = (b - a) * f'(z))"
  1126 apply (drule MVT)
  1127 apply (blast intro: DERIV_isCont)
  1128 apply (force dest: order_less_imp_le simp add: real_differentiable_def)
  1129 apply (blast dest: DERIV_unique order_less_imp_le)
  1130 done
  1131 
  1132 
  1133 text{*A function is constant if its derivative is 0 over an interval.*}
  1134 
  1135 lemma DERIV_isconst_end:
  1136   fixes f :: "real => real"
  1137   shows "[| a < b;
  1138          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1139          \<forall>x. a < x & x < b --> DERIV f x :> 0 |]
  1140         ==> f b = f a"
  1141 apply (drule MVT, assumption)
  1142 apply (blast intro: differentiableI)
  1143 apply (auto dest!: DERIV_unique simp add: diff_eq_eq)
  1144 done
  1145 
  1146 lemma DERIV_isconst1:
  1147   fixes f :: "real => real"
  1148   shows "[| a < b;
  1149          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1150          \<forall>x. a < x & x < b --> DERIV f x :> 0 |]
  1151         ==> \<forall>x. a \<le> x & x \<le> b --> f x = f a"
  1152 apply safe
  1153 apply (drule_tac x = a in order_le_imp_less_or_eq, safe)
  1154 apply (drule_tac b = x in DERIV_isconst_end, auto)
  1155 done
  1156 
  1157 lemma DERIV_isconst2:
  1158   fixes f :: "real => real"
  1159   shows "[| a < b;
  1160          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1161          \<forall>x. a < x & x < b --> DERIV f x :> 0;
  1162          a \<le> x; x \<le> b |]
  1163         ==> f x = f a"
  1164 apply (blast dest: DERIV_isconst1)
  1165 done
  1166 
  1167 lemma DERIV_isconst3: fixes a b x y :: real
  1168   assumes "a < b" and "x \<in> {a <..< b}" and "y \<in> {a <..< b}"
  1169   assumes derivable: "\<And>x. x \<in> {a <..< b} \<Longrightarrow> DERIV f x :> 0"
  1170   shows "f x = f y"
  1171 proof (cases "x = y")
  1172   case False
  1173   let ?a = "min x y"
  1174   let ?b = "max x y"
  1175   
  1176   have "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> DERIV f z :> 0"
  1177   proof (rule allI, rule impI)
  1178     fix z :: real assume "?a \<le> z \<and> z \<le> ?b"
  1179     hence "a < z" and "z < b" using `x \<in> {a <..< b}` and `y \<in> {a <..< b}` by auto
  1180     hence "z \<in> {a<..<b}" by auto
  1181     thus "DERIV f z :> 0" by (rule derivable)
  1182   qed
  1183   hence isCont: "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> isCont f z"
  1184     and DERIV: "\<forall>z. ?a < z \<and> z < ?b \<longrightarrow> DERIV f z :> 0" using DERIV_isCont by auto
  1185 
  1186   have "?a < ?b" using `x \<noteq> y` by auto
  1187   from DERIV_isconst2[OF this isCont DERIV, of x] and DERIV_isconst2[OF this isCont DERIV, of y]
  1188   show ?thesis by auto
  1189 qed auto
  1190 
  1191 lemma DERIV_isconst_all:
  1192   fixes f :: "real => real"
  1193   shows "\<forall>x. DERIV f x :> 0 ==> f(x) = f(y)"
  1194 apply (rule linorder_cases [of x y])
  1195 apply (blast intro: sym DERIV_isCont DERIV_isconst_end)+
  1196 done
  1197 
  1198 lemma DERIV_const_ratio_const:
  1199   fixes f :: "real => real"
  1200   shows "[|a \<noteq> b; \<forall>x. DERIV f x :> k |] ==> (f(b) - f(a)) = (b-a) * k"
  1201 apply (rule linorder_cases [of a b], auto)
  1202 apply (drule_tac [!] f = f in MVT)
  1203 apply (auto dest: DERIV_isCont DERIV_unique simp add: real_differentiable_def)
  1204 apply (auto dest: DERIV_unique simp add: ring_distribs)
  1205 done
  1206 
  1207 lemma DERIV_const_ratio_const2:
  1208   fixes f :: "real => real"
  1209   shows "[|a \<noteq> b; \<forall>x. DERIV f x :> k |] ==> (f(b) - f(a))/(b-a) = k"
  1210 apply (rule_tac c1 = "b-a" in mult_right_cancel [THEN iffD1])
  1211 apply (auto dest!: DERIV_const_ratio_const simp add: mult.assoc)
  1212 done
  1213 
  1214 lemma real_average_minus_first [simp]: "((a + b) /2 - a) = (b-a)/(2::real)"
  1215 by (simp)
  1216 
  1217 lemma real_average_minus_second [simp]: "((b + a)/2 - a) = (b-a)/(2::real)"
  1218 by (simp)
  1219 
  1220 text{*Gallileo's "trick": average velocity = av. of end velocities*}
  1221 
  1222 lemma DERIV_const_average:
  1223   fixes v :: "real => real"
  1224   assumes neq: "a \<noteq> (b::real)"
  1225       and der: "\<forall>x. DERIV v x :> k"
  1226   shows "v ((a + b)/2) = (v a + v b)/2"
  1227 proof (cases rule: linorder_cases [of a b])
  1228   case equal with neq show ?thesis by simp
  1229 next
  1230   case less
  1231   have "(v b - v a) / (b - a) = k"
  1232     by (rule DERIV_const_ratio_const2 [OF neq der])
  1233   hence "(b-a) * ((v b - v a) / (b-a)) = (b-a) * k" by simp
  1234   moreover have "(v ((a + b) / 2) - v a) / ((a + b) / 2 - a) = k"
  1235     by (rule DERIV_const_ratio_const2 [OF _ der], simp add: neq)
  1236   ultimately show ?thesis using neq by force
  1237 next
  1238   case greater
  1239   have "(v b - v a) / (b - a) = k"
  1240     by (rule DERIV_const_ratio_const2 [OF neq der])
  1241   hence "(b-a) * ((v b - v a) / (b-a)) = (b-a) * k" by simp
  1242   moreover have " (v ((b + a) / 2) - v a) / ((b + a) / 2 - a) = k"
  1243     by (rule DERIV_const_ratio_const2 [OF _ der], simp add: neq)
  1244   ultimately show ?thesis using neq by (force simp add: add.commute)
  1245 qed
  1246 
  1247 (* A function with positive derivative is increasing. 
  1248    A simple proof using the MVT, by Jeremy Avigad. And variants.
  1249 *)
  1250 lemma DERIV_pos_imp_increasing_open:
  1251   fixes a::real and b::real and f::"real => real"
  1252   assumes "a < b" and "\<And>x. a < x \<Longrightarrow> x < b \<Longrightarrow> (EX y. DERIV f x :> y & y > 0)"
  1253       and con: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> isCont f x"
  1254   shows "f a < f b"
  1255 proof (rule ccontr)
  1256   assume f: "~ f a < f b"
  1257   have "EX l z. a < z & z < b & DERIV f z :> l
  1258       & f b - f a = (b - a) * l"
  1259     apply (rule MVT)
  1260       using assms Deriv.differentiableI
  1261       apply force+
  1262     done
  1263   then obtain l z where z: "a < z" "z < b" "DERIV f z :> l"
  1264       and "f b - f a = (b - a) * l"
  1265     by auto
  1266   with assms f have "~(l > 0)"
  1267     by (metis linorder_not_le mult_le_0_iff diff_le_0_iff_le)
  1268   with assms z show False
  1269     by (metis DERIV_unique)
  1270 qed
  1271 
  1272 lemma DERIV_pos_imp_increasing:
  1273   fixes a::real and b::real and f::"real => real"
  1274   assumes "a < b" and "\<forall>x. a \<le> x & x \<le> b --> (EX y. DERIV f x :> y & y > 0)"
  1275   shows "f a < f b"
  1276 by (metis DERIV_pos_imp_increasing_open [of a b f] assms DERIV_continuous less_imp_le)
  1277 
  1278 lemma DERIV_nonneg_imp_nondecreasing:
  1279   fixes a::real and b::real and f::"real => real"
  1280   assumes "a \<le> b" and
  1281     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y \<ge> 0)"
  1282   shows "f a \<le> f b"
  1283 proof (rule ccontr, cases "a = b")
  1284   assume "~ f a \<le> f b" and "a = b"
  1285   then show False by auto
  1286 next
  1287   assume A: "~ f a \<le> f b"
  1288   assume B: "a ~= b"
  1289   with assms have "EX l z. a < z & z < b & DERIV f z :> l
  1290       & f b - f a = (b - a) * l"
  1291     apply -
  1292     apply (rule MVT)
  1293       apply auto
  1294       apply (metis DERIV_isCont)
  1295      apply (metis differentiableI less_le)
  1296     done
  1297   then obtain l z where z: "a < z" "z < b" "DERIV f z :> l"
  1298       and C: "f b - f a = (b - a) * l"
  1299     by auto
  1300   with A have "a < b" "f b < f a" by auto
  1301   with C have "\<not> l \<ge> 0" by (auto simp add: not_le algebra_simps)
  1302     (metis A add_le_cancel_right assms(1) less_eq_real_def mult_right_mono add_left_mono linear order_refl)
  1303   with assms z show False
  1304     by (metis DERIV_unique order_less_imp_le)
  1305 qed
  1306 
  1307 lemma DERIV_neg_imp_decreasing_open:
  1308   fixes a::real and b::real and f::"real => real"
  1309   assumes "a < b" and "\<And>x. a < x \<Longrightarrow> x < b \<Longrightarrow> (EX y. DERIV f x :> y & y < 0)"
  1310       and con: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> isCont f x"
  1311   shows "f a > f b"
  1312 proof -
  1313   have "(%x. -f x) a < (%x. -f x) b"
  1314     apply (rule DERIV_pos_imp_increasing_open [of a b "%x. -f x"])
  1315     using assms
  1316     apply auto
  1317     apply (metis field_differentiable_minus neg_0_less_iff_less)
  1318     done
  1319   thus ?thesis
  1320     by simp
  1321 qed
  1322 
  1323 lemma DERIV_neg_imp_decreasing:
  1324   fixes a::real and b::real and f::"real => real"
  1325   assumes "a < b" and
  1326     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y < 0)"
  1327   shows "f a > f b"
  1328 by (metis DERIV_neg_imp_decreasing_open [of a b f] assms DERIV_continuous less_imp_le)
  1329 
  1330 lemma DERIV_nonpos_imp_nonincreasing:
  1331   fixes a::real and b::real and f::"real => real"
  1332   assumes "a \<le> b" and
  1333     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y \<le> 0)"
  1334   shows "f a \<ge> f b"
  1335 proof -
  1336   have "(%x. -f x) a \<le> (%x. -f x) b"
  1337     apply (rule DERIV_nonneg_imp_nondecreasing [of a b "%x. -f x"])
  1338     using assms
  1339     apply auto
  1340     apply (metis DERIV_minus neg_0_le_iff_le)
  1341     done
  1342   thus ?thesis
  1343     by simp
  1344 qed
  1345 
  1346 lemma DERIV_pos_imp_increasing_at_bot:
  1347   fixes f :: "real => real"
  1348   assumes "\<And>x. x \<le> b \<Longrightarrow> (EX y. DERIV f x :> y & y > 0)"
  1349       and lim: "(f ---> flim) at_bot"
  1350   shows "flim < f b"
  1351 proof -
  1352   have "flim \<le> f (b - 1)"
  1353     apply (rule tendsto_ge_const [OF _ lim])
  1354     apply (auto simp: trivial_limit_at_bot_linorder eventually_at_bot_linorder)
  1355     apply (rule_tac x="b - 2" in exI)
  1356     apply (force intro: order.strict_implies_order DERIV_pos_imp_increasing [where f=f] assms)
  1357     done
  1358   also have "... < f b"
  1359     by (force intro: DERIV_pos_imp_increasing [where f=f] assms)
  1360   finally show ?thesis .
  1361 qed
  1362 
  1363 lemma DERIV_neg_imp_decreasing_at_top:
  1364   fixes f :: "real => real"
  1365   assumes der: "\<And>x. x \<ge> b \<Longrightarrow> (EX y. DERIV f x :> y & y < 0)"
  1366       and lim: "(f ---> flim) at_top"
  1367   shows "flim < f b"
  1368   apply (rule DERIV_pos_imp_increasing_at_bot [where f = "\<lambda>i. f (-i)" and b = "-b", simplified])
  1369   apply (metis DERIV_mirror der le_minus_iff neg_0_less_iff_less)
  1370   apply (metis filterlim_at_top_mirror lim)
  1371   done
  1372 
  1373 text {* Derivative of inverse function *}
  1374 
  1375 lemma DERIV_inverse_function:
  1376   fixes f g :: "real \<Rightarrow> real"
  1377   assumes der: "DERIV f (g x) :> D"
  1378   assumes neq: "D \<noteq> 0"
  1379   assumes a: "a < x" and b: "x < b"
  1380   assumes inj: "\<forall>y. a < y \<and> y < b \<longrightarrow> f (g y) = y"
  1381   assumes cont: "isCont g x"
  1382   shows "DERIV g x :> inverse D"
  1383 unfolding DERIV_iff2
  1384 proof (rule LIM_equal2)
  1385   show "0 < min (x - a) (b - x)"
  1386     using a b by arith 
  1387 next
  1388   fix y
  1389   assume "norm (y - x) < min (x - a) (b - x)"
  1390   hence "a < y" and "y < b" 
  1391     by (simp_all add: abs_less_iff)
  1392   thus "(g y - g x) / (y - x) =
  1393         inverse ((f (g y) - x) / (g y - g x))"
  1394     by (simp add: inj)
  1395 next
  1396   have "(\<lambda>z. (f z - f (g x)) / (z - g x)) -- g x --> D"
  1397     by (rule der [unfolded DERIV_iff2])
  1398   hence 1: "(\<lambda>z. (f z - x) / (z - g x)) -- g x --> D"
  1399     using inj a b by simp
  1400   have 2: "\<exists>d>0. \<forall>y. y \<noteq> x \<and> norm (y - x) < d \<longrightarrow> g y \<noteq> g x"
  1401   proof (rule exI, safe)
  1402     show "0 < min (x - a) (b - x)"
  1403       using a b by simp
  1404   next
  1405     fix y
  1406     assume "norm (y - x) < min (x - a) (b - x)"
  1407     hence y: "a < y" "y < b"
  1408       by (simp_all add: abs_less_iff)
  1409     assume "g y = g x"
  1410     hence "f (g y) = f (g x)" by simp
  1411     hence "y = x" using inj y a b by simp
  1412     also assume "y \<noteq> x"
  1413     finally show False by simp
  1414   qed
  1415   have "(\<lambda>y. (f (g y) - x) / (g y - g x)) -- x --> D"
  1416     using cont 1 2 by (rule isCont_LIM_compose2)
  1417   thus "(\<lambda>y. inverse ((f (g y) - x) / (g y - g x)))
  1418         -- x --> inverse D"
  1419     using neq by (rule tendsto_inverse)
  1420 qed
  1421 
  1422 subsection {* Generalized Mean Value Theorem *}
  1423 
  1424 theorem GMVT:
  1425   fixes a b :: real
  1426   assumes alb: "a < b"
  1427     and fc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1428     and fd: "\<forall>x. a < x \<and> x < b \<longrightarrow> f differentiable (at x)"
  1429     and gc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont g x"
  1430     and gd: "\<forall>x. a < x \<and> x < b \<longrightarrow> g differentiable (at x)"
  1431   shows "\<exists>g'c f'c c.
  1432     DERIV g c :> g'c \<and> DERIV f c :> f'c \<and> a < c \<and> c < b \<and> ((f b - f a) * g'c) = ((g b - g a) * f'c)"
  1433 proof -
  1434   let ?h = "\<lambda>x. (f b - f a)*(g x) - (g b - g a)*(f x)"
  1435   from assms have "a < b" by simp
  1436   moreover have "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?h x"
  1437     using fc gc by simp
  1438   moreover have "\<forall>x. a < x \<and> x < b \<longrightarrow> ?h differentiable (at x)"
  1439     using fd gd by simp
  1440   ultimately have "\<exists>l z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l" by (rule MVT)
  1441   then obtain l where ldef: "\<exists>z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1442   then obtain c where cdef: "a < c \<and> c < b \<and> DERIV ?h c :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1443 
  1444   from cdef have cint: "a < c \<and> c < b" by auto
  1445   with gd have "g differentiable (at c)" by simp
  1446   hence "\<exists>D. DERIV g c :> D" by (rule differentiableD)
  1447   then obtain g'c where g'cdef: "DERIV g c :> g'c" ..
  1448 
  1449   from cdef have "a < c \<and> c < b" by auto
  1450   with fd have "f differentiable (at c)" by simp
  1451   hence "\<exists>D. DERIV f c :> D" by (rule differentiableD)
  1452   then obtain f'c where f'cdef: "DERIV f c :> f'c" ..
  1453 
  1454   from cdef have "DERIV ?h c :> l" by auto
  1455   moreover have "DERIV ?h c :>  g'c * (f b - f a) - f'c * (g b - g a)"
  1456     using g'cdef f'cdef by (auto intro!: derivative_eq_intros)
  1457   ultimately have leq: "l =  g'c * (f b - f a) - f'c * (g b - g a)" by (rule DERIV_unique)
  1458 
  1459   {
  1460     from cdef have "?h b - ?h a = (b - a) * l" by auto
  1461     also from leq have "\<dots> = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))" by simp
  1462     finally have "?h b - ?h a = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))" by simp
  1463   }
  1464   moreover
  1465   {
  1466     have "?h b - ?h a =
  1467          ((f b)*(g b) - (f a)*(g b) - (g b)*(f b) + (g a)*(f b)) -
  1468           ((f b)*(g a) - (f a)*(g a) - (g b)*(f a) + (g a)*(f a))"
  1469       by (simp add: algebra_simps)
  1470     hence "?h b - ?h a = 0" by auto
  1471   }
  1472   ultimately have "(b - a) * (g'c * (f b - f a) - f'c * (g b - g a)) = 0" by auto
  1473   with alb have "g'c * (f b - f a) - f'c * (g b - g a) = 0" by simp
  1474   hence "g'c * (f b - f a) = f'c * (g b - g a)" by simp
  1475   hence "(f b - f a) * g'c = (g b - g a) * f'c" by (simp add: ac_simps)
  1476 
  1477   with g'cdef f'cdef cint show ?thesis by auto
  1478 qed
  1479 
  1480 lemma GMVT':
  1481   fixes f g :: "real \<Rightarrow> real"
  1482   assumes "a < b"
  1483   assumes isCont_f: "\<And>z. a \<le> z \<Longrightarrow> z \<le> b \<Longrightarrow> isCont f z"
  1484   assumes isCont_g: "\<And>z. a \<le> z \<Longrightarrow> z \<le> b \<Longrightarrow> isCont g z"
  1485   assumes DERIV_g: "\<And>z. a < z \<Longrightarrow> z < b \<Longrightarrow> DERIV g z :> (g' z)"
  1486   assumes DERIV_f: "\<And>z. a < z \<Longrightarrow> z < b \<Longrightarrow> DERIV f z :> (f' z)"
  1487   shows "\<exists>c. a < c \<and> c < b \<and> (f b - f a) * g' c = (g b - g a) * f' c"
  1488 proof -
  1489   have "\<exists>g'c f'c c. DERIV g c :> g'c \<and> DERIV f c :> f'c \<and>
  1490     a < c \<and> c < b \<and> (f b - f a) * g'c = (g b - g a) * f'c"
  1491     using assms by (intro GMVT) (force simp: real_differentiable_def)+
  1492   then obtain c where "a < c" "c < b" "(f b - f a) * g' c = (g b - g a) * f' c"
  1493     using DERIV_f DERIV_g by (force dest: DERIV_unique)
  1494   then show ?thesis
  1495     by auto
  1496 qed
  1497 
  1498 
  1499 subsection {* L'Hopitals rule *}
  1500 
  1501 lemma isCont_If_ge:
  1502   fixes a :: "'a :: linorder_topology"
  1503   shows "continuous (at_left a) g \<Longrightarrow> (f ---> g a) (at_right a) \<Longrightarrow> isCont (\<lambda>x. if x \<le> a then g x else f x) a"
  1504   unfolding isCont_def continuous_within
  1505   apply (intro filterlim_split_at)
  1506   apply (subst filterlim_cong[OF refl refl, where g=g])
  1507   apply (simp_all add: eventually_at_filter less_le)
  1508   apply (subst filterlim_cong[OF refl refl, where g=f])
  1509   apply (simp_all add: eventually_at_filter less_le)
  1510   done
  1511 
  1512 lemma lhopital_right_0:
  1513   fixes f0 g0 :: "real \<Rightarrow> real"
  1514   assumes f_0: "(f0 ---> 0) (at_right 0)"
  1515   assumes g_0: "(g0 ---> 0) (at_right 0)"
  1516   assumes ev:
  1517     "eventually (\<lambda>x. g0 x \<noteq> 0) (at_right 0)"
  1518     "eventually (\<lambda>x. g' x \<noteq> 0) (at_right 0)"
  1519     "eventually (\<lambda>x. DERIV f0 x :> f' x) (at_right 0)"
  1520     "eventually (\<lambda>x. DERIV g0 x :> g' x) (at_right 0)"
  1521   assumes lim: "((\<lambda> x. (f' x / g' x)) ---> x) (at_right 0)"
  1522   shows "((\<lambda> x. f0 x / g0 x) ---> x) (at_right 0)"
  1523 proof -
  1524   def f \<equiv> "\<lambda>x. if x \<le> 0 then 0 else f0 x"
  1525   then have "f 0 = 0" by simp
  1526 
  1527   def g \<equiv> "\<lambda>x. if x \<le> 0 then 0 else g0 x"
  1528   then have "g 0 = 0" by simp
  1529 
  1530   have "eventually (\<lambda>x. g0 x \<noteq> 0 \<and> g' x \<noteq> 0 \<and>
  1531       DERIV f0 x :> (f' x) \<and> DERIV g0 x :> (g' x)) (at_right 0)"
  1532     using ev by eventually_elim auto
  1533   then obtain a where [arith]: "0 < a"
  1534     and g0_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g0 x \<noteq> 0"
  1535     and g'_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g' x \<noteq> 0"
  1536     and f0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> DERIV f0 x :> (f' x)"
  1537     and g0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> DERIV g0 x :> (g' x)"
  1538     unfolding eventually_at by (auto simp: dist_real_def)
  1539 
  1540   have g_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g x \<noteq> 0"
  1541     using g0_neq_0 by (simp add: g_def)
  1542 
  1543   { fix x assume x: "0 < x" "x < a" then have "DERIV f x :> (f' x)"
  1544       by (intro DERIV_cong_ev[THEN iffD1, OF _ _ _ f0[OF x]])
  1545          (auto simp: f_def eventually_nhds_metric dist_real_def intro!: exI[of _ x]) }
  1546   note f = this
  1547 
  1548   { fix x assume x: "0 < x" "x < a" then have "DERIV g x :> (g' x)"
  1549       by (intro DERIV_cong_ev[THEN iffD1, OF _ _ _ g0[OF x]])
  1550          (auto simp: g_def eventually_nhds_metric dist_real_def intro!: exI[of _ x]) }
  1551   note g = this
  1552 
  1553   have "isCont f 0"
  1554     unfolding f_def by (intro isCont_If_ge f_0 continuous_const)
  1555 
  1556   have "isCont g 0"
  1557     unfolding g_def by (intro isCont_If_ge g_0 continuous_const)
  1558 
  1559   have "\<exists>\<zeta>. \<forall>x\<in>{0 <..< a}. 0 < \<zeta> x \<and> \<zeta> x < x \<and> f x / g x = f' (\<zeta> x) / g' (\<zeta> x)"
  1560   proof (rule bchoice, rule)
  1561     fix x assume "x \<in> {0 <..< a}"
  1562     then have x[arith]: "0 < x" "x < a" by auto
  1563     with g'_neq_0 g_neq_0 `g 0 = 0` have g': "\<And>x. 0 < x \<Longrightarrow> x < a  \<Longrightarrow> 0 \<noteq> g' x" "g 0 \<noteq> g x"
  1564       by auto
  1565     have "\<And>x. 0 \<le> x \<Longrightarrow> x < a \<Longrightarrow> isCont f x"
  1566       using `isCont f 0` f by (auto intro: DERIV_isCont simp: le_less)
  1567     moreover have "\<And>x. 0 \<le> x \<Longrightarrow> x < a \<Longrightarrow> isCont g x"
  1568       using `isCont g 0` g by (auto intro: DERIV_isCont simp: le_less)
  1569     ultimately have "\<exists>c. 0 < c \<and> c < x \<and> (f x - f 0) * g' c = (g x - g 0) * f' c"
  1570       using f g `x < a` by (intro GMVT') auto
  1571     then obtain c where *: "0 < c" "c < x" "(f x - f 0) * g' c = (g x - g 0) * f' c"
  1572       by blast
  1573     moreover
  1574     from * g'(1)[of c] g'(2) have "(f x - f 0)  / (g x - g 0) = f' c / g' c"
  1575       by (simp add: field_simps)
  1576     ultimately show "\<exists>y. 0 < y \<and> y < x \<and> f x / g x = f' y / g' y"
  1577       using `f 0 = 0` `g 0 = 0` by (auto intro!: exI[of _ c])
  1578   qed
  1579   then obtain \<zeta> where "\<forall>x\<in>{0 <..< a}. 0 < \<zeta> x \<and> \<zeta> x < x \<and> f x / g x = f' (\<zeta> x) / g' (\<zeta> x)" ..
  1580   then have \<zeta>: "eventually (\<lambda>x. 0 < \<zeta> x \<and> \<zeta> x < x \<and> f x / g x = f' (\<zeta> x) / g' (\<zeta> x)) (at_right 0)"
  1581     unfolding eventually_at by (intro exI[of _ a]) (auto simp: dist_real_def)
  1582   moreover
  1583   from \<zeta> have "eventually (\<lambda>x. norm (\<zeta> x) \<le> x) (at_right 0)"
  1584     by eventually_elim auto
  1585   then have "((\<lambda>x. norm (\<zeta> x)) ---> 0) (at_right 0)"
  1586     by (rule_tac real_tendsto_sandwich[where f="\<lambda>x. 0" and h="\<lambda>x. x"])
  1587        (auto intro: tendsto_const tendsto_ident_at)
  1588   then have "(\<zeta> ---> 0) (at_right 0)"
  1589     by (rule tendsto_norm_zero_cancel)
  1590   with \<zeta> have "filterlim \<zeta> (at_right 0) (at_right 0)"
  1591     by (auto elim!: eventually_elim1 simp: filterlim_at)
  1592   from this lim have "((\<lambda>t. f' (\<zeta> t) / g' (\<zeta> t)) ---> x) (at_right 0)"
  1593     by (rule_tac filterlim_compose[of _ _ _ \<zeta>])
  1594   ultimately have "((\<lambda>t. f t / g t) ---> x) (at_right 0)" (is ?P)
  1595     by (rule_tac filterlim_cong[THEN iffD1, OF refl refl])
  1596        (auto elim: eventually_elim1)
  1597   also have "?P \<longleftrightarrow> ?thesis"
  1598     by (rule filterlim_cong) (auto simp: f_def g_def eventually_at_filter)
  1599   finally show ?thesis .
  1600 qed
  1601 
  1602 lemma lhopital_right:
  1603   "((f::real \<Rightarrow> real) ---> 0) (at_right x) \<Longrightarrow> (g ---> 0) (at_right x) \<Longrightarrow>
  1604     eventually (\<lambda>x. g x \<noteq> 0) (at_right x) \<Longrightarrow>
  1605     eventually (\<lambda>x. g' x \<noteq> 0) (at_right x) \<Longrightarrow>
  1606     eventually (\<lambda>x. DERIV f x :> f' x) (at_right x) \<Longrightarrow>
  1607     eventually (\<lambda>x. DERIV g x :> g' x) (at_right x) \<Longrightarrow>
  1608     ((\<lambda> x. (f' x / g' x)) ---> y) (at_right x) \<Longrightarrow>
  1609   ((\<lambda> x. f x / g x) ---> y) (at_right x)"
  1610   unfolding eventually_at_right_to_0[of _ x] filterlim_at_right_to_0[of _ _ x] DERIV_shift
  1611   by (rule lhopital_right_0)
  1612 
  1613 lemma lhopital_left:
  1614   "((f::real \<Rightarrow> real) ---> 0) (at_left x) \<Longrightarrow> (g ---> 0) (at_left x) \<Longrightarrow>
  1615     eventually (\<lambda>x. g x \<noteq> 0) (at_left x) \<Longrightarrow>
  1616     eventually (\<lambda>x. g' x \<noteq> 0) (at_left x) \<Longrightarrow>
  1617     eventually (\<lambda>x. DERIV f x :> f' x) (at_left x) \<Longrightarrow>
  1618     eventually (\<lambda>x. DERIV g x :> g' x) (at_left x) \<Longrightarrow>
  1619     ((\<lambda> x. (f' x / g' x)) ---> y) (at_left x) \<Longrightarrow>
  1620   ((\<lambda> x. f x / g x) ---> y) (at_left x)"
  1621   unfolding eventually_at_left_to_right filterlim_at_left_to_right DERIV_mirror
  1622   by (rule lhopital_right[where f'="\<lambda>x. - f' (- x)"]) (auto simp: DERIV_mirror)
  1623 
  1624 lemma lhopital:
  1625   "((f::real \<Rightarrow> real) ---> 0) (at x) \<Longrightarrow> (g ---> 0) (at x) \<Longrightarrow>
  1626     eventually (\<lambda>x. g x \<noteq> 0) (at x) \<Longrightarrow>
  1627     eventually (\<lambda>x. g' x \<noteq> 0) (at x) \<Longrightarrow>
  1628     eventually (\<lambda>x. DERIV f x :> f' x) (at x) \<Longrightarrow>
  1629     eventually (\<lambda>x. DERIV g x :> g' x) (at x) \<Longrightarrow>
  1630     ((\<lambda> x. (f' x / g' x)) ---> y) (at x) \<Longrightarrow>
  1631   ((\<lambda> x. f x / g x) ---> y) (at x)"
  1632   unfolding eventually_at_split filterlim_at_split
  1633   by (auto intro!: lhopital_right[of f x g g' f'] lhopital_left[of f x g g' f'])
  1634 
  1635 lemma lhopital_right_0_at_top:
  1636   fixes f g :: "real \<Rightarrow> real"
  1637   assumes g_0: "LIM x at_right 0. g x :> at_top"
  1638   assumes ev:
  1639     "eventually (\<lambda>x. g' x \<noteq> 0) (at_right 0)"
  1640     "eventually (\<lambda>x. DERIV f x :> f' x) (at_right 0)"
  1641     "eventually (\<lambda>x. DERIV g x :> g' x) (at_right 0)"
  1642   assumes lim: "((\<lambda> x. (f' x / g' x)) ---> x) (at_right 0)"
  1643   shows "((\<lambda> x. f x / g x) ---> x) (at_right 0)"
  1644   unfolding tendsto_iff
  1645 proof safe
  1646   fix e :: real assume "0 < e"
  1647 
  1648   with lim[unfolded tendsto_iff, rule_format, of "e / 4"]
  1649   have "eventually (\<lambda>t. dist (f' t / g' t) x < e / 4) (at_right 0)" by simp
  1650   from eventually_conj[OF eventually_conj[OF ev(1) ev(2)] eventually_conj[OF ev(3) this]]
  1651   obtain a where [arith]: "0 < a"
  1652     and g'_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g' x \<noteq> 0"
  1653     and f0: "\<And>x. 0 < x \<Longrightarrow> x \<le> a \<Longrightarrow> DERIV f x :> (f' x)"
  1654     and g0: "\<And>x. 0 < x \<Longrightarrow> x \<le> a \<Longrightarrow> DERIV g x :> (g' x)"
  1655     and Df: "\<And>t. 0 < t \<Longrightarrow> t < a \<Longrightarrow> dist (f' t / g' t) x < e / 4"
  1656     unfolding eventually_at_le by (auto simp: dist_real_def)
  1657     
  1658 
  1659   from Df have
  1660     "eventually (\<lambda>t. t < a) (at_right 0)" "eventually (\<lambda>t::real. 0 < t) (at_right 0)"
  1661     unfolding eventually_at by (auto intro!: exI[of _ a] simp: dist_real_def)
  1662 
  1663   moreover
  1664   have "eventually (\<lambda>t. 0 < g t) (at_right 0)" "eventually (\<lambda>t. g a < g t) (at_right 0)"
  1665     using g_0 by (auto elim: eventually_elim1 simp: filterlim_at_top_dense)
  1666 
  1667   moreover
  1668   have inv_g: "((\<lambda>x. inverse (g x)) ---> 0) (at_right 0)"
  1669     using tendsto_inverse_0 filterlim_mono[OF g_0 at_top_le_at_infinity order_refl]
  1670     by (rule filterlim_compose)
  1671   then have "((\<lambda>x. norm (1 - g a * inverse (g x))) ---> norm (1 - g a * 0)) (at_right 0)"
  1672     by (intro tendsto_intros)
  1673   then have "((\<lambda>x. norm (1 - g a / g x)) ---> 1) (at_right 0)"
  1674     by (simp add: inverse_eq_divide)
  1675   from this[unfolded tendsto_iff, rule_format, of 1]
  1676   have "eventually (\<lambda>x. norm (1 - g a / g x) < 2) (at_right 0)"
  1677     by (auto elim!: eventually_elim1 simp: dist_real_def)
  1678 
  1679   moreover
  1680   from inv_g have "((\<lambda>t. norm ((f a - x * g a) * inverse (g t))) ---> norm ((f a - x * g a) * 0)) (at_right 0)"
  1681     by (intro tendsto_intros)
  1682   then have "((\<lambda>t. norm (f a - x * g a) / norm (g t)) ---> 0) (at_right 0)"
  1683     by (simp add: inverse_eq_divide)
  1684   from this[unfolded tendsto_iff, rule_format, of "e / 2"] `0 < e`
  1685   have "eventually (\<lambda>t. norm (f a - x * g a) / norm (g t) < e / 2) (at_right 0)"
  1686     by (auto simp: dist_real_def)
  1687 
  1688   ultimately show "eventually (\<lambda>t. dist (f t / g t) x < e) (at_right 0)"
  1689   proof eventually_elim
  1690     fix t assume t[arith]: "0 < t" "t < a" "g a < g t" "0 < g t"
  1691     assume ineq: "norm (1 - g a / g t) < 2" "norm (f a - x * g a) / norm (g t) < e / 2"
  1692 
  1693     have "\<exists>y. t < y \<and> y < a \<and> (g a - g t) * f' y = (f a - f t) * g' y"
  1694       using f0 g0 t(1,2) by (intro GMVT') (force intro!: DERIV_isCont)+
  1695     then obtain y where [arith]: "t < y" "y < a"
  1696       and D_eq0: "(g a - g t) * f' y = (f a - f t) * g' y"
  1697       by blast
  1698     from D_eq0 have D_eq: "(f t - f a) / (g t - g a) = f' y / g' y"
  1699       using `g a < g t` g'_neq_0[of y] by (auto simp add: field_simps)
  1700 
  1701     have *: "f t / g t - x = ((f t - f a) / (g t - g a) - x) * (1 - g a / g t) + (f a - x * g a) / g t"
  1702       by (simp add: field_simps)
  1703     have "norm (f t / g t - x) \<le>
  1704         norm (((f t - f a) / (g t - g a) - x) * (1 - g a / g t)) + norm ((f a - x * g a) / g t)"
  1705       unfolding * by (rule norm_triangle_ineq)
  1706     also have "\<dots> = dist (f' y / g' y) x * norm (1 - g a / g t) + norm (f a - x * g a) / norm (g t)"
  1707       by (simp add: abs_mult D_eq dist_real_def)
  1708     also have "\<dots> < (e / 4) * 2 + e / 2"
  1709       using ineq Df[of y] `0 < e` by (intro add_le_less_mono mult_mono) auto
  1710     finally show "dist (f t / g t) x < e"
  1711       by (simp add: dist_real_def)
  1712   qed
  1713 qed
  1714 
  1715 lemma lhopital_right_at_top:
  1716   "LIM x at_right x. (g::real \<Rightarrow> real) x :> at_top \<Longrightarrow>
  1717     eventually (\<lambda>x. g' x \<noteq> 0) (at_right x) \<Longrightarrow>
  1718     eventually (\<lambda>x. DERIV f x :> f' x) (at_right x) \<Longrightarrow>
  1719     eventually (\<lambda>x. DERIV g x :> g' x) (at_right x) \<Longrightarrow>
  1720     ((\<lambda> x. (f' x / g' x)) ---> y) (at_right x) \<Longrightarrow>
  1721     ((\<lambda> x. f x / g x) ---> y) (at_right x)"
  1722   unfolding eventually_at_right_to_0[of _ x] filterlim_at_right_to_0[of _ _ x] DERIV_shift
  1723   by (rule lhopital_right_0_at_top)
  1724 
  1725 lemma lhopital_left_at_top:
  1726   "LIM x at_left x. (g::real \<Rightarrow> real) x :> at_top \<Longrightarrow>
  1727     eventually (\<lambda>x. g' x \<noteq> 0) (at_left x) \<Longrightarrow>
  1728     eventually (\<lambda>x. DERIV f x :> f' x) (at_left x) \<Longrightarrow>
  1729     eventually (\<lambda>x. DERIV g x :> g' x) (at_left x) \<Longrightarrow>
  1730     ((\<lambda> x. (f' x / g' x)) ---> y) (at_left x) \<Longrightarrow>
  1731     ((\<lambda> x. f x / g x) ---> y) (at_left x)"
  1732   unfolding eventually_at_left_to_right filterlim_at_left_to_right DERIV_mirror
  1733   by (rule lhopital_right_at_top[where f'="\<lambda>x. - f' (- x)"]) (auto simp: DERIV_mirror)
  1734 
  1735 lemma lhopital_at_top:
  1736   "LIM x at x. (g::real \<Rightarrow> real) x :> at_top \<Longrightarrow>
  1737     eventually (\<lambda>x. g' x \<noteq> 0) (at x) \<Longrightarrow>
  1738     eventually (\<lambda>x. DERIV f x :> f' x) (at x) \<Longrightarrow>
  1739     eventually (\<lambda>x. DERIV g x :> g' x) (at x) \<Longrightarrow>
  1740     ((\<lambda> x. (f' x / g' x)) ---> y) (at x) \<Longrightarrow>
  1741     ((\<lambda> x. f x / g x) ---> y) (at x)"
  1742   unfolding eventually_at_split filterlim_at_split
  1743   by (auto intro!: lhopital_right_at_top[of g x g' f f'] lhopital_left_at_top[of g x g' f f'])
  1744 
  1745 lemma lhospital_at_top_at_top:
  1746   fixes f g :: "real \<Rightarrow> real"
  1747   assumes g_0: "LIM x at_top. g x :> at_top"
  1748   assumes g': "eventually (\<lambda>x. g' x \<noteq> 0) at_top"
  1749   assumes Df: "eventually (\<lambda>x. DERIV f x :> f' x) at_top"
  1750   assumes Dg: "eventually (\<lambda>x. DERIV g x :> g' x) at_top"
  1751   assumes lim: "((\<lambda> x. (f' x / g' x)) ---> x) at_top"
  1752   shows "((\<lambda> x. f x / g x) ---> x) at_top"
  1753   unfolding filterlim_at_top_to_right
  1754 proof (rule lhopital_right_0_at_top)
  1755   let ?F = "\<lambda>x. f (inverse x)"
  1756   let ?G = "\<lambda>x. g (inverse x)"
  1757   let ?R = "at_right (0::real)"
  1758   let ?D = "\<lambda>f' x. f' (inverse x) * - (inverse x ^ Suc (Suc 0))"
  1759 
  1760   show "LIM x ?R. ?G x :> at_top"
  1761     using g_0 unfolding filterlim_at_top_to_right .
  1762 
  1763   show "eventually (\<lambda>x. DERIV ?G x  :> ?D g' x) ?R"
  1764     unfolding eventually_at_right_to_top
  1765     using Dg eventually_ge_at_top[where c="1::real"]
  1766     apply eventually_elim
  1767     apply (rule DERIV_cong)
  1768     apply (rule DERIV_chain'[where f=inverse])
  1769     apply (auto intro!:  DERIV_inverse)
  1770     done
  1771 
  1772   show "eventually (\<lambda>x. DERIV ?F x  :> ?D f' x) ?R"
  1773     unfolding eventually_at_right_to_top
  1774     using Df eventually_ge_at_top[where c="1::real"]
  1775     apply eventually_elim
  1776     apply (rule DERIV_cong)
  1777     apply (rule DERIV_chain'[where f=inverse])
  1778     apply (auto intro!:  DERIV_inverse)
  1779     done
  1780 
  1781   show "eventually (\<lambda>x. ?D g' x \<noteq> 0) ?R"
  1782     unfolding eventually_at_right_to_top
  1783     using g' eventually_ge_at_top[where c="1::real"]
  1784     by eventually_elim auto
  1785     
  1786   show "((\<lambda>x. ?D f' x / ?D g' x) ---> x) ?R"
  1787     unfolding filterlim_at_right_to_top
  1788     apply (intro filterlim_cong[THEN iffD2, OF refl refl _ lim])
  1789     using eventually_ge_at_top[where c="1::real"]
  1790     by eventually_elim simp
  1791 qed
  1792 
  1793 end