src/HOL/Enum.thy
author haftmann
Fri Oct 10 19:55:32 2014 +0200 (2014-10-10)
changeset 58646 cd63a4b12a33
parent 58350 919149921e46
child 58659 6c9821c32dd5
permissions -rw-r--r--
specialized specification: avoid trivial instances
     1 (* Author: Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Finite types as explicit enumerations *}
     4 
     5 theory Enum
     6 imports Map Groups_List
     7 begin
     8 
     9 subsection {* Class @{text enum} *}
    10 
    11 class enum =
    12   fixes enum :: "'a list"
    13   fixes enum_all :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    14   fixes enum_ex :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    15   assumes UNIV_enum: "UNIV = set enum"
    16     and enum_distinct: "distinct enum"
    17   assumes enum_all_UNIV: "enum_all P \<longleftrightarrow> Ball UNIV P"
    18   assumes enum_ex_UNIV: "enum_ex P \<longleftrightarrow> Bex UNIV P" 
    19    -- {* tailored towards simple instantiation *}
    20 begin
    21 
    22 subclass finite proof
    23 qed (simp add: UNIV_enum)
    24 
    25 lemma enum_UNIV:
    26   "set enum = UNIV"
    27   by (simp only: UNIV_enum)
    28 
    29 lemma in_enum: "x \<in> set enum"
    30   by (simp add: enum_UNIV)
    31 
    32 lemma enum_eq_I:
    33   assumes "\<And>x. x \<in> set xs"
    34   shows "set enum = set xs"
    35 proof -
    36   from assms UNIV_eq_I have "UNIV = set xs" by auto
    37   with enum_UNIV show ?thesis by simp
    38 qed
    39 
    40 lemma card_UNIV_length_enum:
    41   "card (UNIV :: 'a set) = length enum"
    42   by (simp add: UNIV_enum distinct_card enum_distinct)
    43 
    44 lemma enum_all [simp]:
    45   "enum_all = HOL.All"
    46   by (simp add: fun_eq_iff enum_all_UNIV)
    47 
    48 lemma enum_ex [simp]:
    49   "enum_ex = HOL.Ex" 
    50   by (simp add: fun_eq_iff enum_ex_UNIV)
    51 
    52 end
    53 
    54 
    55 subsection {* Implementations using @{class enum} *}
    56 
    57 subsubsection {* Unbounded operations and quantifiers *}
    58 
    59 lemma Collect_code [code]:
    60   "Collect P = set (filter P enum)"
    61   by (simp add: enum_UNIV)
    62 
    63 lemma vimage_code [code]:
    64   "f -` B = set (filter (%x. f x : B) enum_class.enum)"
    65   unfolding vimage_def Collect_code ..
    66 
    67 definition card_UNIV :: "'a itself \<Rightarrow> nat"
    68 where
    69   [code del]: "card_UNIV TYPE('a) = card (UNIV :: 'a set)"
    70 
    71 lemma [code]:
    72   "card_UNIV TYPE('a :: enum) = card (set (Enum.enum :: 'a list))"
    73   by (simp only: card_UNIV_def enum_UNIV)
    74 
    75 lemma all_code [code]: "(\<forall>x. P x) \<longleftrightarrow> enum_all P"
    76   by simp
    77 
    78 lemma exists_code [code]: "(\<exists>x. P x) \<longleftrightarrow> enum_ex P"
    79   by simp
    80 
    81 lemma exists1_code [code]: "(\<exists>!x. P x) \<longleftrightarrow> list_ex1 P enum"
    82   by (auto simp add: list_ex1_iff enum_UNIV)
    83 
    84 
    85 subsubsection {* An executable choice operator *}
    86 
    87 definition
    88   [code del]: "enum_the = The"
    89 
    90 lemma [code]:
    91   "The P = (case filter P enum of [x] => x | _ => enum_the P)"
    92 proof -
    93   {
    94     fix a
    95     assume filter_enum: "filter P enum = [a]"
    96     have "The P = a"
    97     proof (rule the_equality)
    98       fix x
    99       assume "P x"
   100       show "x = a"
   101       proof (rule ccontr)
   102         assume "x \<noteq> a"
   103         from filter_enum obtain us vs
   104           where enum_eq: "enum = us @ [a] @ vs"
   105           and "\<forall> x \<in> set us. \<not> P x"
   106           and "\<forall> x \<in> set vs. \<not> P x"
   107           and "P a"
   108           by (auto simp add: filter_eq_Cons_iff) (simp only: filter_empty_conv[symmetric])
   109         with `P x` in_enum[of x, unfolded enum_eq] `x \<noteq> a` show "False" by auto
   110       qed
   111     next
   112       from filter_enum show "P a" by (auto simp add: filter_eq_Cons_iff)
   113     qed
   114   }
   115   from this show ?thesis
   116     unfolding enum_the_def by (auto split: list.split)
   117 qed
   118 
   119 declare [[code abort: enum_the]]
   120 
   121 code_printing
   122   constant enum_the \<rightharpoonup> (Eval) "(fn '_ => raise Match)"
   123 
   124 
   125 subsubsection {* Equality and order on functions *}
   126 
   127 instantiation "fun" :: (enum, equal) equal
   128 begin
   129 
   130 definition
   131   "HOL.equal f g \<longleftrightarrow> (\<forall>x \<in> set enum. f x = g x)"
   132 
   133 instance proof
   134 qed (simp_all add: equal_fun_def fun_eq_iff enum_UNIV)
   135 
   136 end
   137 
   138 lemma [code]:
   139   "HOL.equal f g \<longleftrightarrow> enum_all (%x. f x = g x)"
   140   by (auto simp add: equal fun_eq_iff)
   141 
   142 lemma [code nbe]:
   143   "HOL.equal (f :: _ \<Rightarrow> _) f \<longleftrightarrow> True"
   144   by (fact equal_refl)
   145 
   146 lemma order_fun [code]:
   147   fixes f g :: "'a\<Colon>enum \<Rightarrow> 'b\<Colon>order"
   148   shows "f \<le> g \<longleftrightarrow> enum_all (\<lambda>x. f x \<le> g x)"
   149     and "f < g \<longleftrightarrow> f \<le> g \<and> enum_ex (\<lambda>x. f x \<noteq> g x)"
   150   by (simp_all add: fun_eq_iff le_fun_def order_less_le)
   151 
   152 
   153 subsubsection {* Operations on relations *}
   154 
   155 lemma [code]:
   156   "Id = image (\<lambda>x. (x, x)) (set Enum.enum)"
   157   by (auto intro: imageI in_enum)
   158 
   159 lemma tranclp_unfold [code]:
   160   "tranclp r a b \<longleftrightarrow> (a, b) \<in> trancl {(x, y). r x y}"
   161   by (simp add: trancl_def)
   162 
   163 lemma rtranclp_rtrancl_eq [code]:
   164   "rtranclp r x y \<longleftrightarrow> (x, y) \<in> rtrancl {(x, y). r x y}"
   165   by (simp add: rtrancl_def)
   166 
   167 lemma max_ext_eq [code]:
   168   "max_ext R = {(X, Y). finite X \<and> finite Y \<and> Y \<noteq> {} \<and> (\<forall>x. x \<in> X \<longrightarrow> (\<exists>xa \<in> Y. (x, xa) \<in> R))}"
   169   by (auto simp add: max_ext.simps)
   170 
   171 lemma max_extp_eq [code]:
   172   "max_extp r x y \<longleftrightarrow> (x, y) \<in> max_ext {(x, y). r x y}"
   173   by (simp add: max_ext_def)
   174 
   175 lemma mlex_eq [code]:
   176   "f <*mlex*> R = {(x, y). f x < f y \<or> (f x \<le> f y \<and> (x, y) \<in> R)}"
   177   by (auto simp add: mlex_prod_def)
   178 
   179 
   180 subsubsection {* Bounded accessible part *}
   181 
   182 primrec bacc :: "('a \<times> 'a) set \<Rightarrow> nat \<Rightarrow> 'a set" 
   183 where
   184   "bacc r 0 = {x. \<forall> y. (y, x) \<notin> r}"
   185 | "bacc r (Suc n) = (bacc r n \<union> {x. \<forall>y. (y, x) \<in> r \<longrightarrow> y \<in> bacc r n})"
   186 
   187 lemma bacc_subseteq_acc:
   188   "bacc r n \<subseteq> Wellfounded.acc r"
   189   by (induct n) (auto intro: acc.intros)
   190 
   191 lemma bacc_mono:
   192   "n \<le> m \<Longrightarrow> bacc r n \<subseteq> bacc r m"
   193   by (induct rule: dec_induct) auto
   194   
   195 lemma bacc_upper_bound:
   196   "bacc (r :: ('a \<times> 'a) set)  (card (UNIV :: 'a::finite set)) = (\<Union>n. bacc r n)"
   197 proof -
   198   have "mono (bacc r)" unfolding mono_def by (simp add: bacc_mono)
   199   moreover have "\<forall>n. bacc r n = bacc r (Suc n) \<longrightarrow> bacc r (Suc n) = bacc r (Suc (Suc n))" by auto
   200   moreover have "finite (range (bacc r))" by auto
   201   ultimately show ?thesis
   202    by (intro finite_mono_strict_prefix_implies_finite_fixpoint)
   203      (auto intro: finite_mono_remains_stable_implies_strict_prefix)
   204 qed
   205 
   206 lemma acc_subseteq_bacc:
   207   assumes "finite r"
   208   shows "Wellfounded.acc r \<subseteq> (\<Union>n. bacc r n)"
   209 proof
   210   fix x
   211   assume "x : Wellfounded.acc r"
   212   then have "\<exists> n. x : bacc r n"
   213   proof (induct x arbitrary: rule: acc.induct)
   214     case (accI x)
   215     then have "\<forall>y. \<exists> n. (y, x) \<in> r --> y : bacc r n" by simp
   216     from choice[OF this] obtain n where n: "\<forall>y. (y, x) \<in> r \<longrightarrow> y \<in> bacc r (n y)" ..
   217     obtain n where "\<And>y. (y, x) : r \<Longrightarrow> y : bacc r n"
   218     proof
   219       fix y assume y: "(y, x) : r"
   220       with n have "y : bacc r (n y)" by auto
   221       moreover have "n y <= Max ((%(y, x). n y) ` r)"
   222         using y `finite r` by (auto intro!: Max_ge)
   223       note bacc_mono[OF this, of r]
   224       ultimately show "y : bacc r (Max ((%(y, x). n y) ` r))" by auto
   225     qed
   226     then show ?case
   227       by (auto simp add: Let_def intro!: exI[of _ "Suc n"])
   228   qed
   229   then show "x : (UN n. bacc r n)" by auto
   230 qed
   231 
   232 lemma acc_bacc_eq:
   233   fixes A :: "('a :: finite \<times> 'a) set"
   234   assumes "finite A"
   235   shows "Wellfounded.acc A = bacc A (card (UNIV :: 'a set))"
   236   using assms by (metis acc_subseteq_bacc bacc_subseteq_acc bacc_upper_bound order_eq_iff)
   237 
   238 lemma [code]:
   239   fixes xs :: "('a::finite \<times> 'a) list"
   240   shows "Wellfounded.acc (set xs) = bacc (set xs) (card_UNIV TYPE('a))"
   241   by (simp add: card_UNIV_def acc_bacc_eq)
   242 
   243 
   244 subsection {* Default instances for @{class enum} *}
   245 
   246 lemma map_of_zip_enum_is_Some:
   247   assumes "length ys = length (enum \<Colon> 'a\<Colon>enum list)"
   248   shows "\<exists>y. map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x = Some y"
   249 proof -
   250   from assms have "x \<in> set (enum \<Colon> 'a\<Colon>enum list) \<longleftrightarrow>
   251     (\<exists>y. map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x = Some y)"
   252     by (auto intro!: map_of_zip_is_Some)
   253   then show ?thesis using enum_UNIV by auto
   254 qed
   255 
   256 lemma map_of_zip_enum_inject:
   257   fixes xs ys :: "'b\<Colon>enum list"
   258   assumes length: "length xs = length (enum \<Colon> 'a\<Colon>enum list)"
   259       "length ys = length (enum \<Colon> 'a\<Colon>enum list)"
   260     and map_of: "the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) xs) = the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys)"
   261   shows "xs = ys"
   262 proof -
   263   have "map_of (zip (enum \<Colon> 'a list) xs) = map_of (zip (enum \<Colon> 'a list) ys)"
   264   proof
   265     fix x :: 'a
   266     from length map_of_zip_enum_is_Some obtain y1 y2
   267       where "map_of (zip (enum \<Colon> 'a list) xs) x = Some y1"
   268         and "map_of (zip (enum \<Colon> 'a list) ys) x = Some y2" by blast
   269     moreover from map_of
   270       have "the (map_of (zip (enum \<Colon> 'a\<Colon>enum list) xs) x) = the (map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x)"
   271       by (auto dest: fun_cong)
   272     ultimately show "map_of (zip (enum \<Colon> 'a\<Colon>enum list) xs) x = map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x"
   273       by simp
   274   qed
   275   with length enum_distinct show "xs = ys" by (rule map_of_zip_inject)
   276 qed
   277 
   278 definition all_n_lists :: "(('a :: enum) list \<Rightarrow> bool) \<Rightarrow> nat \<Rightarrow> bool"
   279 where
   280   "all_n_lists P n \<longleftrightarrow> (\<forall>xs \<in> set (List.n_lists n enum). P xs)"
   281 
   282 lemma [code]:
   283   "all_n_lists P n \<longleftrightarrow> (if n = 0 then P [] else enum_all (%x. all_n_lists (%xs. P (x # xs)) (n - 1)))"
   284   unfolding all_n_lists_def enum_all
   285   by (cases n) (auto simp add: enum_UNIV)
   286 
   287 definition ex_n_lists :: "(('a :: enum) list \<Rightarrow> bool) \<Rightarrow> nat \<Rightarrow> bool"
   288 where
   289   "ex_n_lists P n \<longleftrightarrow> (\<exists>xs \<in> set (List.n_lists n enum). P xs)"
   290 
   291 lemma [code]:
   292   "ex_n_lists P n \<longleftrightarrow> (if n = 0 then P [] else enum_ex (%x. ex_n_lists (%xs. P (x # xs)) (n - 1)))"
   293   unfolding ex_n_lists_def enum_ex
   294   by (cases n) (auto simp add: enum_UNIV)
   295 
   296 instantiation "fun" :: (enum, enum) enum
   297 begin
   298 
   299 definition
   300   "enum = map (\<lambda>ys. the o map_of (zip (enum\<Colon>'a list) ys)) (List.n_lists (length (enum\<Colon>'a\<Colon>enum list)) enum)"
   301 
   302 definition
   303   "enum_all P = all_n_lists (\<lambda>bs. P (the o map_of (zip enum bs))) (length (enum :: 'a list))"
   304 
   305 definition
   306   "enum_ex P = ex_n_lists (\<lambda>bs. P (the o map_of (zip enum bs))) (length (enum :: 'a list))"
   307 
   308 instance proof
   309   show "UNIV = set (enum \<Colon> ('a \<Rightarrow> 'b) list)"
   310   proof (rule UNIV_eq_I)
   311     fix f :: "'a \<Rightarrow> 'b"
   312     have "f = the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) (map f enum))"
   313       by (auto simp add: map_of_zip_map fun_eq_iff intro: in_enum)
   314     then show "f \<in> set enum"
   315       by (auto simp add: enum_fun_def set_n_lists intro: in_enum)
   316   qed
   317 next
   318   from map_of_zip_enum_inject
   319   show "distinct (enum \<Colon> ('a \<Rightarrow> 'b) list)"
   320     by (auto intro!: inj_onI simp add: enum_fun_def
   321       distinct_map distinct_n_lists enum_distinct set_n_lists)
   322 next
   323   fix P
   324   show "enum_all (P :: ('a \<Rightarrow> 'b) \<Rightarrow> bool) = Ball UNIV P"
   325   proof
   326     assume "enum_all P"
   327     show "Ball UNIV P"
   328     proof
   329       fix f :: "'a \<Rightarrow> 'b"
   330       have f: "f = the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) (map f enum))"
   331         by (auto simp add: map_of_zip_map fun_eq_iff intro: in_enum)
   332       from `enum_all P` have "P (the \<circ> map_of (zip enum (map f enum)))"
   333         unfolding enum_all_fun_def all_n_lists_def
   334         apply (simp add: set_n_lists)
   335         apply (erule_tac x="map f enum" in allE)
   336         apply (auto intro!: in_enum)
   337         done
   338       from this f show "P f" by auto
   339     qed
   340   next
   341     assume "Ball UNIV P"
   342     from this show "enum_all P"
   343       unfolding enum_all_fun_def all_n_lists_def by auto
   344   qed
   345 next
   346   fix P
   347   show "enum_ex (P :: ('a \<Rightarrow> 'b) \<Rightarrow> bool) = Bex UNIV P"
   348   proof
   349     assume "enum_ex P"
   350     from this show "Bex UNIV P"
   351       unfolding enum_ex_fun_def ex_n_lists_def by auto
   352   next
   353     assume "Bex UNIV P"
   354     from this obtain f where "P f" ..
   355     have f: "f = the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) (map f enum))"
   356       by (auto simp add: map_of_zip_map fun_eq_iff intro: in_enum) 
   357     from `P f` this have "P (the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) (map f enum)))"
   358       by auto
   359     from  this show "enum_ex P"
   360       unfolding enum_ex_fun_def ex_n_lists_def
   361       apply (auto simp add: set_n_lists)
   362       apply (rule_tac x="map f enum" in exI)
   363       apply (auto intro!: in_enum)
   364       done
   365   qed
   366 qed
   367 
   368 end
   369 
   370 lemma enum_fun_code [code]: "enum = (let enum_a = (enum \<Colon> 'a\<Colon>{enum, equal} list)
   371   in map (\<lambda>ys. the o map_of (zip enum_a ys)) (List.n_lists (length enum_a) enum))"
   372   by (simp add: enum_fun_def Let_def)
   373 
   374 lemma enum_all_fun_code [code]:
   375   "enum_all P = (let enum_a = (enum :: 'a::{enum, equal} list)
   376    in all_n_lists (\<lambda>bs. P (the o map_of (zip enum_a bs))) (length enum_a))"
   377   by (simp only: enum_all_fun_def Let_def)
   378 
   379 lemma enum_ex_fun_code [code]:
   380   "enum_ex P = (let enum_a = (enum :: 'a::{enum, equal} list)
   381    in ex_n_lists (\<lambda>bs. P (the o map_of (zip enum_a bs))) (length enum_a))"
   382   by (simp only: enum_ex_fun_def Let_def)
   383 
   384 instantiation set :: (enum) enum
   385 begin
   386 
   387 definition
   388   "enum = map set (sublists enum)"
   389 
   390 definition
   391   "enum_all P \<longleftrightarrow> (\<forall>A\<in>set enum. P (A::'a set))"
   392 
   393 definition
   394   "enum_ex P \<longleftrightarrow> (\<exists>A\<in>set enum. P (A::'a set))"
   395 
   396 instance proof
   397 qed (simp_all add: enum_set_def enum_all_set_def enum_ex_set_def sublists_powset distinct_set_sublists
   398   enum_distinct enum_UNIV)
   399 
   400 end
   401 
   402 instantiation unit :: enum
   403 begin
   404 
   405 definition
   406   "enum = [()]"
   407 
   408 definition
   409   "enum_all P = P ()"
   410 
   411 definition
   412   "enum_ex P = P ()"
   413 
   414 instance proof
   415 qed (auto simp add: enum_unit_def enum_all_unit_def enum_ex_unit_def)
   416 
   417 end
   418 
   419 instantiation bool :: enum
   420 begin
   421 
   422 definition
   423   "enum = [False, True]"
   424 
   425 definition
   426   "enum_all P \<longleftrightarrow> P False \<and> P True"
   427 
   428 definition
   429   "enum_ex P \<longleftrightarrow> P False \<or> P True"
   430 
   431 instance proof
   432 qed (simp_all only: enum_bool_def enum_all_bool_def enum_ex_bool_def UNIV_bool, simp_all)
   433 
   434 end
   435 
   436 instantiation prod :: (enum, enum) enum
   437 begin
   438 
   439 definition
   440   "enum = List.product enum enum"
   441 
   442 definition
   443   "enum_all P = enum_all (%x. enum_all (%y. P (x, y)))"
   444 
   445 definition
   446   "enum_ex P = enum_ex (%x. enum_ex (%y. P (x, y)))"
   447 
   448  
   449 instance by default
   450   (simp_all add: enum_prod_def distinct_product
   451     enum_UNIV enum_distinct enum_all_prod_def enum_ex_prod_def)
   452 
   453 end
   454 
   455 instantiation sum :: (enum, enum) enum
   456 begin
   457 
   458 definition
   459   "enum = map Inl enum @ map Inr enum"
   460 
   461 definition
   462   "enum_all P \<longleftrightarrow> enum_all (\<lambda>x. P (Inl x)) \<and> enum_all (\<lambda>x. P (Inr x))"
   463 
   464 definition
   465   "enum_ex P \<longleftrightarrow> enum_ex (\<lambda>x. P (Inl x)) \<or> enum_ex (\<lambda>x. P (Inr x))"
   466 
   467 instance proof
   468 qed (simp_all only: enum_sum_def enum_all_sum_def enum_ex_sum_def UNIV_sum,
   469   auto simp add: enum_UNIV distinct_map enum_distinct)
   470 
   471 end
   472 
   473 instantiation option :: (enum) enum
   474 begin
   475 
   476 definition
   477   "enum = None # map Some enum"
   478 
   479 definition
   480   "enum_all P \<longleftrightarrow> P None \<and> enum_all (\<lambda>x. P (Some x))"
   481 
   482 definition
   483   "enum_ex P \<longleftrightarrow> P None \<or> enum_ex (\<lambda>x. P (Some x))"
   484 
   485 instance proof
   486 qed (simp_all only: enum_option_def enum_all_option_def enum_ex_option_def UNIV_option_conv,
   487   auto simp add: distinct_map enum_UNIV enum_distinct)
   488 
   489 end
   490 
   491 
   492 subsection {* Small finite types *}
   493 
   494 text {* We define small finite types for use in Quickcheck *}
   495 
   496 datatype (plugins only: code "quickcheck*" extraction) finite_1 =
   497   a\<^sub>1
   498 
   499 notation (output) a\<^sub>1  ("a\<^sub>1")
   500 
   501 lemma UNIV_finite_1:
   502   "UNIV = {a\<^sub>1}"
   503   by (auto intro: finite_1.exhaust)
   504 
   505 instantiation finite_1 :: enum
   506 begin
   507 
   508 definition
   509   "enum = [a\<^sub>1]"
   510 
   511 definition
   512   "enum_all P = P a\<^sub>1"
   513 
   514 definition
   515   "enum_ex P = P a\<^sub>1"
   516 
   517 instance proof
   518 qed (simp_all only: enum_finite_1_def enum_all_finite_1_def enum_ex_finite_1_def UNIV_finite_1, simp_all)
   519 
   520 end
   521 
   522 instantiation finite_1 :: linorder
   523 begin
   524 
   525 definition less_finite_1 :: "finite_1 \<Rightarrow> finite_1 \<Rightarrow> bool"
   526 where
   527   "x < (y :: finite_1) \<longleftrightarrow> False"
   528 
   529 definition less_eq_finite_1 :: "finite_1 \<Rightarrow> finite_1 \<Rightarrow> bool"
   530 where
   531   "x \<le> (y :: finite_1) \<longleftrightarrow> True"
   532 
   533 instance
   534 apply (intro_classes)
   535 apply (auto simp add: less_finite_1_def less_eq_finite_1_def)
   536 apply (metis finite_1.exhaust)
   537 done
   538 
   539 end
   540 
   541 instance finite_1 :: "{dense_linorder, wellorder}"
   542 by intro_classes (simp_all add: less_finite_1_def)
   543 
   544 instantiation finite_1 :: complete_lattice
   545 begin
   546 
   547 definition [simp]: "Inf = (\<lambda>_. a\<^sub>1)"
   548 definition [simp]: "Sup = (\<lambda>_. a\<^sub>1)"
   549 definition [simp]: "bot = a\<^sub>1"
   550 definition [simp]: "top = a\<^sub>1"
   551 definition [simp]: "inf = (\<lambda>_ _. a\<^sub>1)"
   552 definition [simp]: "sup = (\<lambda>_ _. a\<^sub>1)"
   553 
   554 instance by intro_classes(simp_all add: less_eq_finite_1_def)
   555 end
   556 
   557 instance finite_1 :: complete_distrib_lattice
   558 by intro_classes(simp_all add: INF_def SUP_def)
   559 
   560 instance finite_1 :: complete_linorder ..
   561 
   562 lemma finite_1_eq: "x = a\<^sub>1"
   563 by(cases x) simp
   564 
   565 simproc_setup finite_1_eq ("x::finite_1") = {*
   566   fn _ => fn _ => fn ct => case term_of ct of
   567     Const (@{const_name a\<^sub>1}, _) => NONE
   568   | _ => SOME (mk_meta_eq @{thm finite_1_eq})
   569 *}
   570 
   571 instantiation finite_1 :: complete_boolean_algebra begin
   572 definition [simp]: "op - = (\<lambda>_ _. a\<^sub>1)"
   573 definition [simp]: "uminus = (\<lambda>_. a\<^sub>1)"
   574 instance by intro_classes simp_all
   575 end
   576 
   577 instantiation finite_1 :: 
   578   "{linordered_ring_strict, linordered_comm_semiring_strict, ordered_comm_ring,
   579     ordered_cancel_comm_monoid_diff, comm_monoid_mult, ordered_ring_abs,
   580     one, Divides.div, sgn_if, inverse}"
   581 begin
   582 definition [simp]: "Groups.zero = a\<^sub>1"
   583 definition [simp]: "Groups.one = a\<^sub>1"
   584 definition [simp]: "op + = (\<lambda>_ _. a\<^sub>1)"
   585 definition [simp]: "op * = (\<lambda>_ _. a\<^sub>1)"
   586 definition [simp]: "op div = (\<lambda>_ _. a\<^sub>1)" 
   587 definition [simp]: "op mod = (\<lambda>_ _. a\<^sub>1)" 
   588 definition [simp]: "abs = (\<lambda>_. a\<^sub>1)"
   589 definition [simp]: "sgn = (\<lambda>_. a\<^sub>1)"
   590 definition [simp]: "inverse = (\<lambda>_. a\<^sub>1)"
   591 definition [simp]: "op / = (\<lambda>_ _. a\<^sub>1)"
   592 
   593 instance by intro_classes(simp_all add: less_finite_1_def)
   594 end
   595 
   596 declare [[simproc del: finite_1_eq]]
   597 hide_const (open) a\<^sub>1
   598 
   599 datatype (plugins only: code "quickcheck*" extraction) finite_2 =
   600   a\<^sub>1 | a\<^sub>2
   601 
   602 notation (output) a\<^sub>1  ("a\<^sub>1")
   603 notation (output) a\<^sub>2  ("a\<^sub>2")
   604 
   605 lemma UNIV_finite_2:
   606   "UNIV = {a\<^sub>1, a\<^sub>2}"
   607   by (auto intro: finite_2.exhaust)
   608 
   609 instantiation finite_2 :: enum
   610 begin
   611 
   612 definition
   613   "enum = [a\<^sub>1, a\<^sub>2]"
   614 
   615 definition
   616   "enum_all P \<longleftrightarrow> P a\<^sub>1 \<and> P a\<^sub>2"
   617 
   618 definition
   619   "enum_ex P \<longleftrightarrow> P a\<^sub>1 \<or> P a\<^sub>2"
   620 
   621 instance proof
   622 qed (simp_all only: enum_finite_2_def enum_all_finite_2_def enum_ex_finite_2_def UNIV_finite_2, simp_all)
   623 
   624 end
   625 
   626 instantiation finite_2 :: linorder
   627 begin
   628 
   629 definition less_finite_2 :: "finite_2 \<Rightarrow> finite_2 \<Rightarrow> bool"
   630 where
   631   "x < y \<longleftrightarrow> x = a\<^sub>1 \<and> y = a\<^sub>2"
   632 
   633 definition less_eq_finite_2 :: "finite_2 \<Rightarrow> finite_2 \<Rightarrow> bool"
   634 where
   635   "x \<le> y \<longleftrightarrow> x = y \<or> x < (y :: finite_2)"
   636 
   637 instance
   638 apply (intro_classes)
   639 apply (auto simp add: less_finite_2_def less_eq_finite_2_def)
   640 apply (metis finite_2.nchotomy)+
   641 done
   642 
   643 end
   644 
   645 instance finite_2 :: wellorder
   646 by(rule wf_wellorderI)(simp add: less_finite_2_def, intro_classes)
   647 
   648 instantiation finite_2 :: complete_lattice
   649 begin
   650 
   651 definition "\<Sqinter>A = (if a\<^sub>1 \<in> A then a\<^sub>1 else a\<^sub>2)"
   652 definition "\<Squnion>A = (if a\<^sub>2 \<in> A then a\<^sub>2 else a\<^sub>1)"
   653 definition [simp]: "bot = a\<^sub>1"
   654 definition [simp]: "top = a\<^sub>2"
   655 definition "x \<sqinter> y = (if x = a\<^sub>1 \<or> y = a\<^sub>1 then a\<^sub>1 else a\<^sub>2)"
   656 definition "x \<squnion> y = (if x = a\<^sub>2 \<or> y = a\<^sub>2 then a\<^sub>2 else a\<^sub>1)"
   657 
   658 lemma neq_finite_2_a\<^sub>1_iff [simp]: "x \<noteq> a\<^sub>1 \<longleftrightarrow> x = a\<^sub>2"
   659 by(cases x) simp_all
   660 
   661 lemma neq_finite_2_a\<^sub>1_iff' [simp]: "a\<^sub>1 \<noteq> x \<longleftrightarrow> x = a\<^sub>2"
   662 by(cases x) simp_all
   663 
   664 lemma neq_finite_2_a\<^sub>2_iff [simp]: "x \<noteq> a\<^sub>2 \<longleftrightarrow> x = a\<^sub>1"
   665 by(cases x) simp_all
   666 
   667 lemma neq_finite_2_a\<^sub>2_iff' [simp]: "a\<^sub>2 \<noteq> x \<longleftrightarrow> x = a\<^sub>1"
   668 by(cases x) simp_all
   669 
   670 instance
   671 proof
   672   fix x :: finite_2 and A
   673   assume "x \<in> A"
   674   then show "\<Sqinter>A \<le> x" "x \<le> \<Squnion>A"
   675     by(case_tac [!] x)(auto simp add: less_eq_finite_2_def less_finite_2_def Inf_finite_2_def Sup_finite_2_def)
   676 qed(auto simp add: less_eq_finite_2_def less_finite_2_def inf_finite_2_def sup_finite_2_def Inf_finite_2_def Sup_finite_2_def)
   677 end
   678 
   679 instance finite_2 :: complete_distrib_lattice
   680 by(intro_classes)(auto simp add: INF_def SUP_def sup_finite_2_def inf_finite_2_def Inf_finite_2_def Sup_finite_2_def)
   681 
   682 instance finite_2 :: complete_linorder ..
   683 
   684 instantiation finite_2 :: "{field_inverse_zero, abs_if, ring_div, sgn_if, semiring_div}" begin
   685 definition [simp]: "0 = a\<^sub>1"
   686 definition [simp]: "1 = a\<^sub>2"
   687 definition "x + y = (case (x, y) of (a\<^sub>1, a\<^sub>1) \<Rightarrow> a\<^sub>1 | (a\<^sub>2, a\<^sub>2) \<Rightarrow> a\<^sub>1 | _ \<Rightarrow> a\<^sub>2)"
   688 definition "uminus = (\<lambda>x :: finite_2. x)"
   689 definition "op - = (op + :: finite_2 \<Rightarrow> _)"
   690 definition "x * y = (case (x, y) of (a\<^sub>2, a\<^sub>2) \<Rightarrow> a\<^sub>2 | _ \<Rightarrow> a\<^sub>1)"
   691 definition "inverse = (\<lambda>x :: finite_2. x)"
   692 definition "op / = (op * :: finite_2 \<Rightarrow> _)"
   693 definition "abs = (\<lambda>x :: finite_2. x)"
   694 definition "op div = (op / :: finite_2 \<Rightarrow> _)"
   695 definition "x mod y = (case (x, y) of (a\<^sub>2, a\<^sub>1) \<Rightarrow> a\<^sub>2 | _ \<Rightarrow> a\<^sub>1)"
   696 definition "sgn = (\<lambda>x :: finite_2. x)"
   697 instance
   698 by intro_classes
   699   (simp_all add: plus_finite_2_def uminus_finite_2_def minus_finite_2_def times_finite_2_def
   700        inverse_finite_2_def divide_finite_2_def abs_finite_2_def div_finite_2_def mod_finite_2_def sgn_finite_2_def
   701      split: finite_2.splits)
   702 end
   703 
   704 lemma two_finite_2 [simp]:
   705   "2 = a\<^sub>1"
   706   by (simp add: numeral.simps plus_finite_2_def)
   707   
   708 instance finite_2 :: semiring_div_parity
   709 by intro_classes (simp_all add: mod_finite_2_def split: finite_2.splits)
   710 
   711 
   712 hide_const (open) a\<^sub>1 a\<^sub>2
   713 
   714 datatype (plugins only: code "quickcheck*" extraction) finite_3 =
   715   a\<^sub>1 | a\<^sub>2 | a\<^sub>3
   716 
   717 notation (output) a\<^sub>1  ("a\<^sub>1")
   718 notation (output) a\<^sub>2  ("a\<^sub>2")
   719 notation (output) a\<^sub>3  ("a\<^sub>3")
   720 
   721 lemma UNIV_finite_3:
   722   "UNIV = {a\<^sub>1, a\<^sub>2, a\<^sub>3}"
   723   by (auto intro: finite_3.exhaust)
   724 
   725 instantiation finite_3 :: enum
   726 begin
   727 
   728 definition
   729   "enum = [a\<^sub>1, a\<^sub>2, a\<^sub>3]"
   730 
   731 definition
   732   "enum_all P \<longleftrightarrow> P a\<^sub>1 \<and> P a\<^sub>2 \<and> P a\<^sub>3"
   733 
   734 definition
   735   "enum_ex P \<longleftrightarrow> P a\<^sub>1 \<or> P a\<^sub>2 \<or> P a\<^sub>3"
   736 
   737 instance proof
   738 qed (simp_all only: enum_finite_3_def enum_all_finite_3_def enum_ex_finite_3_def UNIV_finite_3, simp_all)
   739 
   740 end
   741 
   742 instantiation finite_3 :: linorder
   743 begin
   744 
   745 definition less_finite_3 :: "finite_3 \<Rightarrow> finite_3 \<Rightarrow> bool"
   746 where
   747   "x < y = (case x of a\<^sub>1 \<Rightarrow> y \<noteq> a\<^sub>1 | a\<^sub>2 \<Rightarrow> y = a\<^sub>3 | a\<^sub>3 \<Rightarrow> False)"
   748 
   749 definition less_eq_finite_3 :: "finite_3 \<Rightarrow> finite_3 \<Rightarrow> bool"
   750 where
   751   "x \<le> y \<longleftrightarrow> x = y \<or> x < (y :: finite_3)"
   752 
   753 instance proof (intro_classes)
   754 qed (auto simp add: less_finite_3_def less_eq_finite_3_def split: finite_3.split_asm)
   755 
   756 end
   757 
   758 instance finite_3 :: wellorder
   759 proof(rule wf_wellorderI)
   760   have "inv_image less_than (case_finite_3 0 1 2) = {(x, y). x < y}"
   761     by(auto simp add: less_finite_3_def split: finite_3.splits)
   762   from this[symmetric] show "wf \<dots>" by simp
   763 qed intro_classes
   764 
   765 instantiation finite_3 :: complete_lattice
   766 begin
   767 
   768 definition "\<Sqinter>A = (if a\<^sub>1 \<in> A then a\<^sub>1 else if a\<^sub>2 \<in> A then a\<^sub>2 else a\<^sub>3)"
   769 definition "\<Squnion>A = (if a\<^sub>3 \<in> A then a\<^sub>3 else if a\<^sub>2 \<in> A then a\<^sub>2 else a\<^sub>1)"
   770 definition [simp]: "bot = a\<^sub>1"
   771 definition [simp]: "top = a\<^sub>3"
   772 definition [simp]: "inf = (min :: finite_3 \<Rightarrow> _)"
   773 definition [simp]: "sup = (max :: finite_3 \<Rightarrow> _)"
   774 
   775 instance
   776 proof
   777   fix x :: finite_3 and A
   778   assume "x \<in> A"
   779   then show "\<Sqinter>A \<le> x" "x \<le> \<Squnion>A"
   780     by(case_tac [!] x)(auto simp add: Inf_finite_3_def Sup_finite_3_def less_eq_finite_3_def less_finite_3_def)
   781 next
   782   fix A and z :: finite_3
   783   assume "\<And>x. x \<in> A \<Longrightarrow> z \<le> x"
   784   then show "z \<le> \<Sqinter>A"
   785     by(cases z)(auto simp add: Inf_finite_3_def less_eq_finite_3_def less_finite_3_def)
   786 next
   787   fix A and z :: finite_3
   788   assume *: "\<And>x. x \<in> A \<Longrightarrow> x \<le> z"
   789   show "\<Squnion>A \<le> z"
   790     by(auto simp add: Sup_finite_3_def less_eq_finite_3_def less_finite_3_def dest: *)
   791 qed(auto simp add: Inf_finite_3_def Sup_finite_3_def)
   792 end
   793 
   794 instance finite_3 :: complete_distrib_lattice
   795 proof
   796   fix a :: finite_3 and B
   797   show "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)"
   798   proof(cases a "\<Sqinter>B" rule: finite_3.exhaust[case_product finite_3.exhaust])
   799     case a\<^sub>2_a\<^sub>3
   800     then have "\<And>x. x \<in> B \<Longrightarrow> x = a\<^sub>3"
   801       by(case_tac x)(auto simp add: Inf_finite_3_def split: split_if_asm)
   802     then show ?thesis using a\<^sub>2_a\<^sub>3
   803       by(auto simp add: INF_def Inf_finite_3_def max_def less_eq_finite_3_def less_finite_3_def split: split_if_asm)
   804   qed(auto simp add: INF_def Inf_finite_3_def max_def less_finite_3_def less_eq_finite_3_def split: split_if_asm)
   805   show "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   806     by(cases a "\<Squnion>B" rule: finite_3.exhaust[case_product finite_3.exhaust])
   807       (auto simp add: SUP_def Sup_finite_3_def min_def less_finite_3_def less_eq_finite_3_def split: split_if_asm)
   808 qed
   809 
   810 instance finite_3 :: complete_linorder ..
   811 
   812 instantiation finite_3 :: "{field_inverse_zero, abs_if, ring_div, semiring_div, sgn_if}" begin
   813 definition [simp]: "0 = a\<^sub>1"
   814 definition [simp]: "1 = a\<^sub>2"
   815 definition
   816   "x + y = (case (x, y) of
   817      (a\<^sub>1, a\<^sub>1) \<Rightarrow> a\<^sub>1 | (a\<^sub>2, a\<^sub>3) \<Rightarrow> a\<^sub>1 | (a\<^sub>3, a\<^sub>2) \<Rightarrow> a\<^sub>1
   818    | (a\<^sub>1, a\<^sub>2) \<Rightarrow> a\<^sub>2 | (a\<^sub>2, a\<^sub>1) \<Rightarrow> a\<^sub>2 | (a\<^sub>3, a\<^sub>3) \<Rightarrow> a\<^sub>2
   819    | _ \<Rightarrow> a\<^sub>3)"
   820 definition "- x = (case x of a\<^sub>1 \<Rightarrow> a\<^sub>1 | a\<^sub>2 \<Rightarrow> a\<^sub>3 | a\<^sub>3 \<Rightarrow> a\<^sub>2)"
   821 definition "x - y = x + (- y :: finite_3)"
   822 definition "x * y = (case (x, y) of (a\<^sub>2, a\<^sub>2) \<Rightarrow> a\<^sub>2 | (a\<^sub>3, a\<^sub>3) \<Rightarrow> a\<^sub>2 | (a\<^sub>2, a\<^sub>3) \<Rightarrow> a\<^sub>3 | (a\<^sub>3, a\<^sub>2) \<Rightarrow> a\<^sub>3 | _ \<Rightarrow> a\<^sub>1)"
   823 definition "inverse = (\<lambda>x :: finite_3. x)" 
   824 definition "x / y = x * inverse (y :: finite_3)"
   825 definition "abs = (\<lambda>x :: finite_3. x)"
   826 definition "op div = (op / :: finite_3 \<Rightarrow> _)"
   827 definition "x mod y = (case (x, y) of (a\<^sub>2, a\<^sub>1) \<Rightarrow> a\<^sub>2 | (a\<^sub>3, a\<^sub>1) \<Rightarrow> a\<^sub>3 | _ \<Rightarrow> a\<^sub>1)"
   828 definition "sgn = (\<lambda>x. case x of a\<^sub>1 \<Rightarrow> a\<^sub>1 | _ \<Rightarrow> a\<^sub>2)"
   829 instance
   830 by intro_classes
   831   (simp_all add: plus_finite_3_def uminus_finite_3_def minus_finite_3_def times_finite_3_def
   832        inverse_finite_3_def divide_finite_3_def abs_finite_3_def div_finite_3_def mod_finite_3_def sgn_finite_3_def
   833        less_finite_3_def
   834      split: finite_3.splits)
   835 end
   836 
   837 
   838 
   839 hide_const (open) a\<^sub>1 a\<^sub>2 a\<^sub>3
   840 
   841 datatype (plugins only: code "quickcheck*" extraction) finite_4 =
   842   a\<^sub>1 | a\<^sub>2 | a\<^sub>3 | a\<^sub>4
   843 
   844 notation (output) a\<^sub>1  ("a\<^sub>1")
   845 notation (output) a\<^sub>2  ("a\<^sub>2")
   846 notation (output) a\<^sub>3  ("a\<^sub>3")
   847 notation (output) a\<^sub>4  ("a\<^sub>4")
   848 
   849 lemma UNIV_finite_4:
   850   "UNIV = {a\<^sub>1, a\<^sub>2, a\<^sub>3, a\<^sub>4}"
   851   by (auto intro: finite_4.exhaust)
   852 
   853 instantiation finite_4 :: enum
   854 begin
   855 
   856 definition
   857   "enum = [a\<^sub>1, a\<^sub>2, a\<^sub>3, a\<^sub>4]"
   858 
   859 definition
   860   "enum_all P \<longleftrightarrow> P a\<^sub>1 \<and> P a\<^sub>2 \<and> P a\<^sub>3 \<and> P a\<^sub>4"
   861 
   862 definition
   863   "enum_ex P \<longleftrightarrow> P a\<^sub>1 \<or> P a\<^sub>2 \<or> P a\<^sub>3 \<or> P a\<^sub>4"
   864 
   865 instance proof
   866 qed (simp_all only: enum_finite_4_def enum_all_finite_4_def enum_ex_finite_4_def UNIV_finite_4, simp_all)
   867 
   868 end
   869 
   870 instantiation finite_4 :: complete_lattice begin
   871 
   872 text {* @{term a\<^sub>1} $<$ @{term a\<^sub>2},@{term a\<^sub>3} $<$ @{term a\<^sub>4},
   873   but @{term a\<^sub>2} and @{term a\<^sub>3} are incomparable. *}
   874 
   875 definition
   876   "x < y \<longleftrightarrow> (case (x, y) of
   877      (a\<^sub>1, a\<^sub>1) \<Rightarrow> False | (a\<^sub>1, _) \<Rightarrow> True
   878    |  (a\<^sub>2, a\<^sub>4) \<Rightarrow> True
   879    |  (a\<^sub>3, a\<^sub>4) \<Rightarrow> True  | _ \<Rightarrow> False)"
   880 
   881 definition 
   882   "x \<le> y \<longleftrightarrow> (case (x, y) of
   883      (a\<^sub>1, _) \<Rightarrow> True
   884    | (a\<^sub>2, a\<^sub>2) \<Rightarrow> True | (a\<^sub>2, a\<^sub>4) \<Rightarrow> True
   885    | (a\<^sub>3, a\<^sub>3) \<Rightarrow> True | (a\<^sub>3, a\<^sub>4) \<Rightarrow> True
   886    | (a\<^sub>4, a\<^sub>4) \<Rightarrow> True | _ \<Rightarrow> False)"
   887 
   888 definition
   889   "\<Sqinter>A = (if a\<^sub>1 \<in> A \<or> a\<^sub>2 \<in> A \<and> a\<^sub>3 \<in> A then a\<^sub>1 else if a\<^sub>2 \<in> A then a\<^sub>2 else if a\<^sub>3 \<in> A then a\<^sub>3 else a\<^sub>4)"
   890 definition
   891   "\<Squnion>A = (if a\<^sub>4 \<in> A \<or> a\<^sub>2 \<in> A \<and> a\<^sub>3 \<in> A then a\<^sub>4 else if a\<^sub>2 \<in> A then a\<^sub>2 else if a\<^sub>3 \<in> A then a\<^sub>3 else a\<^sub>1)"
   892 definition [simp]: "bot = a\<^sub>1"
   893 definition [simp]: "top = a\<^sub>4"
   894 definition
   895   "x \<sqinter> y = (case (x, y) of
   896      (a\<^sub>1, _) \<Rightarrow> a\<^sub>1 | (_, a\<^sub>1) \<Rightarrow> a\<^sub>1 | (a\<^sub>2, a\<^sub>3) \<Rightarrow> a\<^sub>1 | (a\<^sub>3, a\<^sub>2) \<Rightarrow> a\<^sub>1
   897    | (a\<^sub>2, _) \<Rightarrow> a\<^sub>2 | (_, a\<^sub>2) \<Rightarrow> a\<^sub>2
   898    | (a\<^sub>3, _) \<Rightarrow> a\<^sub>3 | (_, a\<^sub>3) \<Rightarrow> a\<^sub>3
   899    | _ \<Rightarrow> a\<^sub>4)"
   900 definition
   901   "x \<squnion> y = (case (x, y) of
   902      (a\<^sub>4, _) \<Rightarrow> a\<^sub>4 | (_, a\<^sub>4) \<Rightarrow> a\<^sub>4 | (a\<^sub>2, a\<^sub>3) \<Rightarrow> a\<^sub>4 | (a\<^sub>3, a\<^sub>2) \<Rightarrow> a\<^sub>4
   903   | (a\<^sub>2, _) \<Rightarrow> a\<^sub>2 | (_, a\<^sub>2) \<Rightarrow> a\<^sub>2
   904   | (a\<^sub>3, _) \<Rightarrow> a\<^sub>3 | (_, a\<^sub>3) \<Rightarrow> a\<^sub>3
   905   | _ \<Rightarrow> a\<^sub>1)"
   906 
   907 instance
   908 proof
   909   fix A and z :: finite_4
   910   assume *: "\<And>x. x \<in> A \<Longrightarrow> x \<le> z"
   911   show "\<Squnion>A \<le> z"
   912     by(auto simp add: Sup_finite_4_def less_eq_finite_4_def dest!: * split: finite_4.splits)
   913 next
   914   fix A and z :: finite_4
   915   assume *: "\<And>x. x \<in> A \<Longrightarrow> z \<le> x"
   916   show "z \<le> \<Sqinter>A"
   917     by(auto simp add: Inf_finite_4_def less_eq_finite_4_def dest!: * split: finite_4.splits)
   918 qed(auto simp add: less_finite_4_def less_eq_finite_4_def Inf_finite_4_def Sup_finite_4_def inf_finite_4_def sup_finite_4_def split: finite_4.splits)
   919 
   920 end
   921 
   922 instance finite_4 :: complete_distrib_lattice
   923 proof
   924   fix a :: finite_4 and B
   925   show "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)"
   926     by(cases a "\<Sqinter>B" rule: finite_4.exhaust[case_product finite_4.exhaust])
   927       (auto simp add: sup_finite_4_def Inf_finite_4_def INF_def split: finite_4.splits split_if_asm)
   928   show "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   929     by(cases a "\<Squnion>B" rule: finite_4.exhaust[case_product finite_4.exhaust])
   930       (auto simp add: inf_finite_4_def Sup_finite_4_def SUP_def split: finite_4.splits split_if_asm)
   931 qed
   932 
   933 instantiation finite_4 :: complete_boolean_algebra begin
   934 definition "- x = (case x of a\<^sub>1 \<Rightarrow> a\<^sub>4 | a\<^sub>2 \<Rightarrow> a\<^sub>3 | a\<^sub>3 \<Rightarrow> a\<^sub>2 | a\<^sub>4 \<Rightarrow> a\<^sub>1)"
   935 definition "x - y = x \<sqinter> - (y :: finite_4)"
   936 instance
   937 by intro_classes
   938   (simp_all add: inf_finite_4_def sup_finite_4_def uminus_finite_4_def minus_finite_4_def split: finite_4.splits)
   939 end
   940 
   941 hide_const (open) a\<^sub>1 a\<^sub>2 a\<^sub>3 a\<^sub>4
   942 
   943 datatype (plugins only: code "quickcheck*" extraction) finite_5 =
   944   a\<^sub>1 | a\<^sub>2 | a\<^sub>3 | a\<^sub>4 | a\<^sub>5
   945 
   946 notation (output) a\<^sub>1  ("a\<^sub>1")
   947 notation (output) a\<^sub>2  ("a\<^sub>2")
   948 notation (output) a\<^sub>3  ("a\<^sub>3")
   949 notation (output) a\<^sub>4  ("a\<^sub>4")
   950 notation (output) a\<^sub>5  ("a\<^sub>5")
   951 
   952 lemma UNIV_finite_5:
   953   "UNIV = {a\<^sub>1, a\<^sub>2, a\<^sub>3, a\<^sub>4, a\<^sub>5}"
   954   by (auto intro: finite_5.exhaust)
   955 
   956 instantiation finite_5 :: enum
   957 begin
   958 
   959 definition
   960   "enum = [a\<^sub>1, a\<^sub>2, a\<^sub>3, a\<^sub>4, a\<^sub>5]"
   961 
   962 definition
   963   "enum_all P \<longleftrightarrow> P a\<^sub>1 \<and> P a\<^sub>2 \<and> P a\<^sub>3 \<and> P a\<^sub>4 \<and> P a\<^sub>5"
   964 
   965 definition
   966   "enum_ex P \<longleftrightarrow> P a\<^sub>1 \<or> P a\<^sub>2 \<or> P a\<^sub>3 \<or> P a\<^sub>4 \<or> P a\<^sub>5"
   967 
   968 instance proof
   969 qed (simp_all only: enum_finite_5_def enum_all_finite_5_def enum_ex_finite_5_def UNIV_finite_5, simp_all)
   970 
   971 end
   972 
   973 instantiation finite_5 :: complete_lattice
   974 begin
   975 
   976 text {* The non-distributive pentagon lattice $N_5$ *}
   977 
   978 definition
   979   "x < y \<longleftrightarrow> (case (x, y) of
   980      (a\<^sub>1, a\<^sub>1) \<Rightarrow> False | (a\<^sub>1, _) \<Rightarrow> True
   981    | (a\<^sub>2, a\<^sub>3) \<Rightarrow> True  | (a\<^sub>2, a\<^sub>5) \<Rightarrow> True
   982    | (a\<^sub>3, a\<^sub>5) \<Rightarrow> True
   983    | (a\<^sub>4, a\<^sub>5) \<Rightarrow> True  | _ \<Rightarrow> False)"
   984 
   985 definition
   986   "x \<le> y \<longleftrightarrow> (case (x, y) of
   987      (a\<^sub>1, _) \<Rightarrow> True
   988    | (a\<^sub>2, a\<^sub>2) \<Rightarrow> True | (a\<^sub>2, a\<^sub>3) \<Rightarrow> True | (a\<^sub>2, a\<^sub>5) \<Rightarrow> True
   989    | (a\<^sub>3, a\<^sub>3) \<Rightarrow> True | (a\<^sub>3, a\<^sub>5) \<Rightarrow> True
   990    | (a\<^sub>4, a\<^sub>4) \<Rightarrow> True | (a\<^sub>4, a\<^sub>5) \<Rightarrow> True
   991    | (a\<^sub>5, a\<^sub>5) \<Rightarrow> True | _ \<Rightarrow> False)"
   992 
   993 definition
   994   "\<Sqinter>A = 
   995   (if a\<^sub>1 \<in> A \<or> a\<^sub>4 \<in> A \<and> (a\<^sub>2 \<in> A \<or> a\<^sub>3 \<in> A) then a\<^sub>1
   996    else if a\<^sub>2 \<in> A then a\<^sub>2
   997    else if a\<^sub>3 \<in> A then a\<^sub>3
   998    else if a\<^sub>4 \<in> A then a\<^sub>4
   999    else a\<^sub>5)"
  1000 definition
  1001   "\<Squnion>A = 
  1002   (if a\<^sub>5 \<in> A \<or> a\<^sub>4 \<in> A \<and> (a\<^sub>2 \<in> A \<or> a\<^sub>3 \<in> A) then a\<^sub>5
  1003    else if a\<^sub>3 \<in> A then a\<^sub>3
  1004    else if a\<^sub>2 \<in> A then a\<^sub>2
  1005    else if a\<^sub>4 \<in> A then a\<^sub>4
  1006    else a\<^sub>1)"
  1007 definition [simp]: "bot = a\<^sub>1"
  1008 definition [simp]: "top = a\<^sub>5"
  1009 definition
  1010   "x \<sqinter> y = (case (x, y) of
  1011      (a\<^sub>1, _) \<Rightarrow> a\<^sub>1 | (_, a\<^sub>1) \<Rightarrow> a\<^sub>1 | (a\<^sub>2, a\<^sub>4) \<Rightarrow> a\<^sub>1 | (a\<^sub>4, a\<^sub>2) \<Rightarrow> a\<^sub>1 | (a\<^sub>3, a\<^sub>4) \<Rightarrow> a\<^sub>1 | (a\<^sub>4, a\<^sub>3) \<Rightarrow> a\<^sub>1
  1012    | (a\<^sub>2, _) \<Rightarrow> a\<^sub>2 | (_, a\<^sub>2) \<Rightarrow> a\<^sub>2
  1013    | (a\<^sub>3, _) \<Rightarrow> a\<^sub>3 | (_, a\<^sub>3) \<Rightarrow> a\<^sub>3
  1014    | (a\<^sub>4, _) \<Rightarrow> a\<^sub>4 | (_, a\<^sub>4) \<Rightarrow> a\<^sub>4
  1015    | _ \<Rightarrow> a\<^sub>5)"
  1016 definition
  1017   "x \<squnion> y = (case (x, y) of
  1018      (a\<^sub>5, _) \<Rightarrow> a\<^sub>5 | (_, a\<^sub>5) \<Rightarrow> a\<^sub>5 | (a\<^sub>2, a\<^sub>4) \<Rightarrow> a\<^sub>5 | (a\<^sub>4, a\<^sub>2) \<Rightarrow> a\<^sub>5 | (a\<^sub>3, a\<^sub>4) \<Rightarrow> a\<^sub>5 | (a\<^sub>4, a\<^sub>3) \<Rightarrow> a\<^sub>5
  1019    | (a\<^sub>3, _) \<Rightarrow> a\<^sub>3 | (_, a\<^sub>3) \<Rightarrow> a\<^sub>3
  1020    | (a\<^sub>2, _) \<Rightarrow> a\<^sub>2 | (_, a\<^sub>2) \<Rightarrow> a\<^sub>2
  1021    | (a\<^sub>4, _) \<Rightarrow> a\<^sub>4 | (_, a\<^sub>4) \<Rightarrow> a\<^sub>4
  1022    | _ \<Rightarrow> a\<^sub>1)"
  1023 
  1024 instance 
  1025 proof intro_classes
  1026   fix A and z :: finite_5
  1027   assume *: "\<And>x. x \<in> A \<Longrightarrow> z \<le> x"
  1028   show "z \<le> \<Sqinter>A"
  1029     by(auto simp add: less_eq_finite_5_def Inf_finite_5_def split: finite_5.splits split_if_asm dest!: *)
  1030 next
  1031   fix A and z :: finite_5
  1032   assume *: "\<And>x. x \<in> A \<Longrightarrow> x \<le> z"
  1033   show "\<Squnion>A \<le> z"
  1034     by(auto simp add: less_eq_finite_5_def Sup_finite_5_def split: finite_5.splits split_if_asm dest!: *)
  1035 qed(auto simp add: less_eq_finite_5_def less_finite_5_def inf_finite_5_def sup_finite_5_def Inf_finite_5_def Sup_finite_5_def split: finite_5.splits split_if_asm)
  1036 
  1037 end
  1038 
  1039 hide_const (open) a\<^sub>1 a\<^sub>2 a\<^sub>3 a\<^sub>4 a\<^sub>5
  1040 
  1041 
  1042 subsection {* Closing up *}
  1043 
  1044 hide_type (open) finite_1 finite_2 finite_3 finite_4 finite_5
  1045 hide_const (open) enum enum_all enum_ex all_n_lists ex_n_lists ntrancl
  1046 
  1047 end