src/HOL/Product_Type.thy
author haftmann
Fri Oct 10 19:55:32 2014 +0200 (2014-10-10)
changeset 58646 cd63a4b12a33
parent 58469 66ddc5ad4f63
child 58820 3ad2759acc52
permissions -rw-r--r--
specialized specification: avoid trivial instances
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 keywords "inductive_set" "coinductive_set" :: thy_decl
    11 begin
    12 
    13 subsection {* @{typ bool} is a datatype *}
    14 
    15 free_constructors case_bool for True | False
    16   by auto
    17 
    18 text {* Avoid name clashes by prefixing the output of @{text old_rep_datatype} with @{text old}. *}
    19 
    20 setup {* Sign.mandatory_path "old" *}
    21 
    22 old_rep_datatype True False by (auto intro: bool_induct)
    23 
    24 setup {* Sign.parent_path *}
    25 
    26 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
    27 
    28 setup {* Sign.mandatory_path "bool" *}
    29 
    30 lemmas induct = old.bool.induct
    31 lemmas inducts = old.bool.inducts
    32 lemmas rec = old.bool.rec
    33 lemmas simps = bool.distinct bool.case bool.rec
    34 
    35 setup {* Sign.parent_path *}
    36 
    37 declare case_split [cases type: bool]
    38   -- "prefer plain propositional version"
    39 
    40 lemma
    41   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    42     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    43     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P"
    44     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    45     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    46   by (simp_all add: equal)
    47 
    48 lemma If_case_cert:
    49   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
    50   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
    51   using assms by simp_all
    52 
    53 setup {*
    54   Code.add_case @{thm If_case_cert}
    55 *}
    56 
    57 code_printing
    58   constant "HOL.equal :: bool \<Rightarrow> bool \<Rightarrow> bool" \<rightharpoonup> (Haskell) infix 4 "=="
    59 | class_instance "bool" :: "equal" \<rightharpoonup> (Haskell) -
    60 
    61 
    62 subsection {* The @{text unit} type *}
    63 
    64 typedef unit = "{True}"
    65   by auto
    66 
    67 definition Unity :: unit  ("'(')")
    68   where "() = Abs_unit True"
    69 
    70 lemma unit_eq [no_atp]: "u = ()"
    71   by (induct u) (simp add: Unity_def)
    72 
    73 text {*
    74   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    75   this rule directly --- it loops!
    76 *}
    77 
    78 simproc_setup unit_eq ("x::unit") = {*
    79   fn _ => fn _ => fn ct =>
    80     if HOLogic.is_unit (term_of ct) then NONE
    81     else SOME (mk_meta_eq @{thm unit_eq})
    82 *}
    83 
    84 free_constructors case_unit for "()"
    85   by auto
    86 
    87 text {* Avoid name clashes by prefixing the output of @{text old_rep_datatype} with @{text old}. *}
    88 
    89 setup {* Sign.mandatory_path "old" *}
    90 
    91 old_rep_datatype "()" by simp
    92 
    93 setup {* Sign.parent_path *}
    94 
    95 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
    96 
    97 setup {* Sign.mandatory_path "unit" *}
    98 
    99 lemmas induct = old.unit.induct
   100 lemmas inducts = old.unit.inducts
   101 lemmas rec = old.unit.rec
   102 lemmas simps = unit.case unit.rec
   103 
   104 setup {* Sign.parent_path *}
   105 
   106 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
   107   by simp
   108 
   109 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
   110   by (rule triv_forall_equality)
   111 
   112 text {*
   113   This rewrite counters the effect of simproc @{text unit_eq} on @{term
   114   [source] "%u::unit. f u"}, replacing it by @{term [source]
   115   f} rather than by @{term [source] "%u. f ()"}.
   116 *}
   117 
   118 lemma unit_abs_eta_conv [simp]: "(%u::unit. f ()) = f"
   119   by (rule ext) simp
   120 
   121 lemma UNIV_unit:
   122   "UNIV = {()}" by auto
   123 
   124 instantiation unit :: default
   125 begin
   126 
   127 definition "default = ()"
   128 
   129 instance ..
   130 
   131 end
   132 
   133 instantiation unit :: "{complete_boolean_algebra, complete_linorder, wellorder}"
   134 begin
   135 
   136 definition less_eq_unit :: "unit \<Rightarrow> unit \<Rightarrow> bool"
   137 where
   138   "(_::unit) \<le> _ \<longleftrightarrow> True"
   139 
   140 lemma less_eq_unit [iff]:
   141   "(u::unit) \<le> v"
   142   by (simp add: less_eq_unit_def)
   143 
   144 definition less_unit :: "unit \<Rightarrow> unit \<Rightarrow> bool"
   145 where
   146   "(_::unit) < _ \<longleftrightarrow> False"
   147 
   148 lemma less_unit [iff]:
   149   "\<not> (u::unit) < v"
   150   by (simp_all add: less_eq_unit_def less_unit_def)
   151 
   152 definition bot_unit :: unit
   153 where
   154   [code_unfold]: "\<bottom> = ()"
   155 
   156 definition top_unit :: unit
   157 where
   158   [code_unfold]: "\<top> = ()"
   159 
   160 definition inf_unit :: "unit \<Rightarrow> unit \<Rightarrow> unit"
   161 where
   162   [simp]: "_ \<sqinter> _ = ()"
   163 
   164 definition sup_unit :: "unit \<Rightarrow> unit \<Rightarrow> unit"
   165 where
   166   [simp]: "_ \<squnion> _ = ()"
   167 
   168 definition Inf_unit :: "unit set \<Rightarrow> unit"
   169 where
   170   [simp]: "\<Sqinter>_ = ()"
   171 
   172 definition Sup_unit :: "unit set \<Rightarrow> unit"
   173 where
   174   [simp]: "\<Squnion>_ = ()"
   175 
   176 definition uminus_unit :: "unit \<Rightarrow> unit"
   177 where
   178   [simp]: "- _ = ()"
   179 
   180 declare less_eq_unit_def [abs_def, code_unfold]
   181   less_unit_def [abs_def, code_unfold]
   182   inf_unit_def [abs_def, code_unfold]
   183   sup_unit_def [abs_def, code_unfold]
   184   Inf_unit_def [abs_def, code_unfold]
   185   Sup_unit_def [abs_def, code_unfold]
   186   uminus_unit_def [abs_def, code_unfold]
   187 
   188 instance
   189   by intro_classes auto
   190 
   191 end
   192 
   193 lemma [code]:
   194   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
   195 
   196 code_printing
   197   type_constructor unit \<rightharpoonup>
   198     (SML) "unit"
   199     and (OCaml) "unit"
   200     and (Haskell) "()"
   201     and (Scala) "Unit"
   202 | constant Unity \<rightharpoonup>
   203     (SML) "()"
   204     and (OCaml) "()"
   205     and (Haskell) "()"
   206     and (Scala) "()"
   207 | class_instance unit :: equal \<rightharpoonup>
   208     (Haskell) -
   209 | constant "HOL.equal :: unit \<Rightarrow> unit \<Rightarrow> bool" \<rightharpoonup>
   210     (Haskell) infix 4 "=="
   211 
   212 code_reserved SML
   213   unit
   214 
   215 code_reserved OCaml
   216   unit
   217 
   218 code_reserved Scala
   219   Unit
   220 
   221 
   222 subsection {* The product type *}
   223 
   224 subsubsection {* Type definition *}
   225 
   226 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   227   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   228 
   229 definition "prod = {f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   230 
   231 typedef ('a, 'b) prod (infixr "*" 20) = "prod :: ('a \<Rightarrow> 'b \<Rightarrow> bool) set"
   232   unfolding prod_def by auto
   233 
   234 type_notation (xsymbols)
   235   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   236 type_notation (HTML output)
   237   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   238 
   239 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   240   "Pair a b = Abs_prod (Pair_Rep a b)"
   241 
   242 lemma prod_cases: "(\<And>a b. P (Pair a b)) \<Longrightarrow> P p"
   243   by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   244 
   245 free_constructors case_prod for Pair fst snd
   246 proof -
   247   fix P :: bool and p :: "'a \<times> 'b"
   248   show "(\<And>x1 x2. p = Pair x1 x2 \<Longrightarrow> P) \<Longrightarrow> P"
   249     by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   250 next
   251   fix a c :: 'a and b d :: 'b
   252   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   253     by (auto simp add: Pair_Rep_def fun_eq_iff)
   254   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   255     by (auto simp add: prod_def)
   256   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   257     by (simp add: Pair_def Abs_prod_inject)
   258 qed
   259 
   260 text {* Avoid name clashes by prefixing the output of @{text old_rep_datatype} with @{text old}. *}
   261 
   262 setup {* Sign.mandatory_path "old" *}
   263 
   264 old_rep_datatype Pair
   265 by (erule prod_cases) (rule prod.inject)
   266 
   267 setup {* Sign.parent_path *}
   268 
   269 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
   270 
   271 setup {* Sign.mandatory_path "prod" *}
   272 
   273 declare
   274   old.prod.inject[iff del]
   275 
   276 lemmas induct = old.prod.induct
   277 lemmas inducts = old.prod.inducts
   278 lemmas rec = old.prod.rec
   279 lemmas simps = prod.inject prod.case prod.rec
   280 
   281 setup {* Sign.parent_path *}
   282 
   283 declare prod.case [nitpick_simp del]
   284 declare prod.case_cong_weak [cong del]
   285 
   286 
   287 subsubsection {* Tuple syntax *}
   288 
   289 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   290   "split \<equiv> case_prod"
   291 
   292 text {*
   293   Patterns -- extends pre-defined type @{typ pttrn} used in
   294   abstractions.
   295 *}
   296 
   297 nonterminal tuple_args and patterns
   298 
   299 syntax
   300   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   301   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   302   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   303   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   304   ""            :: "pttrn => patterns"                  ("_")
   305   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   306 
   307 translations
   308   "(x, y)" == "CONST Pair x y"
   309   "_pattern x y" => "CONST Pair x y"
   310   "_patterns x y" => "CONST Pair x y"
   311   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   312   "%(x, y, zs). b" == "CONST case_prod (%x (y, zs). b)"
   313   "%(x, y). b" == "CONST case_prod (%x y. b)"
   314   "_abs (CONST Pair x y) t" => "%(x, y). t"
   315   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   316      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   317 
   318 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   319   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   320 print_translation {*
   321   let
   322     fun split_tr' [Abs (x, T, t as (Abs abs))] =
   323           (* split (%x y. t) => %(x,y) t *)
   324           let
   325             val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   326             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   327           in
   328             Syntax.const @{syntax_const "_abs"} $
   329               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   330           end
   331       | split_tr' [Abs (x, T, (s as Const (@{const_syntax case_prod}, _) $ t))] =
   332           (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   333           let
   334             val Const (@{syntax_const "_abs"}, _) $
   335               (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   336             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   337           in
   338             Syntax.const @{syntax_const "_abs"} $
   339               (Syntax.const @{syntax_const "_pattern"} $ x' $
   340                 (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   341           end
   342       | split_tr' [Const (@{const_syntax case_prod}, _) $ t] =
   343           (* split (split (%x y z. t)) => %((x, y), z). t *)
   344           split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   345       | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   346           (* split (%pttrn z. t) => %(pttrn,z). t *)
   347           let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   348             Syntax.const @{syntax_const "_abs"} $
   349               (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   350           end
   351       | split_tr' _ = raise Match;
   352   in [(@{const_syntax case_prod}, K split_tr')] end
   353 *}
   354 
   355 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   356 typed_print_translation {*
   357   let
   358     fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   359       | split_guess_names_tr' T [Abs (x, xT, t)] =
   360           (case (head_of t) of
   361             Const (@{const_syntax case_prod}, _) => raise Match
   362           | _ =>
   363             let 
   364               val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   365               val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   366               val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   367             in
   368               Syntax.const @{syntax_const "_abs"} $
   369                 (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   370             end)
   371       | split_guess_names_tr' T [t] =
   372           (case head_of t of
   373             Const (@{const_syntax case_prod}, _) => raise Match
   374           | _ =>
   375             let
   376               val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   377               val (y, t') =
   378                 Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   379               val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   380             in
   381               Syntax.const @{syntax_const "_abs"} $
   382                 (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   383             end)
   384       | split_guess_names_tr' _ _ = raise Match;
   385   in [(@{const_syntax case_prod}, K split_guess_names_tr')] end
   386 *}
   387 
   388 
   389 subsubsection {* Code generator setup *}
   390 
   391 code_printing
   392   type_constructor prod \<rightharpoonup>
   393     (SML) infix 2 "*"
   394     and (OCaml) infix 2 "*"
   395     and (Haskell) "!((_),/ (_))"
   396     and (Scala) "((_),/ (_))"
   397 | constant Pair \<rightharpoonup>
   398     (SML) "!((_),/ (_))"
   399     and (OCaml) "!((_),/ (_))"
   400     and (Haskell) "!((_),/ (_))"
   401     and (Scala) "!((_),/ (_))"
   402 | class_instance  prod :: equal \<rightharpoonup>
   403     (Haskell) -
   404 | constant "HOL.equal :: 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool" \<rightharpoonup>
   405     (Haskell) infix 4 "=="
   406 
   407 
   408 subsubsection {* Fundamental operations and properties *}
   409 
   410 lemma Pair_inject:
   411   assumes "(a, b) = (a', b')"
   412     and "a = a' ==> b = b' ==> R"
   413   shows R
   414   using assms by simp
   415 
   416 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   417   by (cases p) simp
   418 
   419 code_printing
   420   constant fst \<rightharpoonup> (Haskell) "fst"
   421 | constant snd \<rightharpoonup> (Haskell) "snd"
   422 
   423 lemma case_prod_unfold [nitpick_unfold]: "case_prod = (%c p. c (fst p) (snd p))"
   424   by (simp add: fun_eq_iff split: prod.split)
   425 
   426 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   427   by simp
   428 
   429 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   430   by simp
   431 
   432 lemmas surjective_pairing = prod.collapse [symmetric]
   433 
   434 lemma prod_eq_iff: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   435   by (cases s, cases t) simp
   436 
   437 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   438   by (simp add: prod_eq_iff)
   439 
   440 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   441   by (fact prod.case)
   442 
   443 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   444   by (rule split_conv [THEN iffD2])
   445 
   446 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   447   by (rule split_conv [THEN iffD1])
   448 
   449 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   450   by (simp add: fun_eq_iff split: prod.split)
   451 
   452 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   453   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   454   by (simp add: fun_eq_iff split: prod.split)
   455 
   456 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   457   by (cases x) simp
   458 
   459 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   460   by (cases p) simp
   461 
   462 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   463   by (simp add: case_prod_unfold)
   464 
   465 lemmas split_weak_cong = prod.case_cong_weak
   466   -- {* Prevents simplification of @{term c}: much faster *}
   467 
   468 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   469   by (simp add: split_eta)
   470 
   471 lemma split_paired_all [no_atp]: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   472 proof
   473   fix a b
   474   assume "!!x. PROP P x"
   475   then show "PROP P (a, b)" .
   476 next
   477   fix x
   478   assume "!!a b. PROP P (a, b)"
   479   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   480 qed
   481 
   482 lemma case_prod_distrib: "f (case x of (x, y) \<Rightarrow> g x y) = (case x of (x, y) \<Rightarrow> f (g x y))"
   483   by (cases x) simp
   484 
   485 text {*
   486   The rule @{thm [source] split_paired_all} does not work with the
   487   Simplifier because it also affects premises in congrence rules,
   488   where this can lead to premises of the form @{text "!!a b. ... =
   489   ?P(a, b)"} which cannot be solved by reflexivity.
   490 *}
   491 
   492 lemmas split_tupled_all = split_paired_all unit_all_eq2
   493 
   494 ML {*
   495   (* replace parameters of product type by individual component parameters *)
   496   local (* filtering with exists_paired_all is an essential optimization *)
   497     fun exists_paired_all (Const (@{const_name Pure.all}, _) $ Abs (_, T, t)) =
   498           can HOLogic.dest_prodT T orelse exists_paired_all t
   499       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   500       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   501       | exists_paired_all _ = false;
   502     val ss =
   503       simpset_of
   504        (put_simpset HOL_basic_ss @{context}
   505         addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   506         addsimprocs [@{simproc unit_eq}]);
   507   in
   508     fun split_all_tac ctxt = SUBGOAL (fn (t, i) =>
   509       if exists_paired_all t then safe_full_simp_tac (put_simpset ss ctxt) i else no_tac);
   510 
   511     fun unsafe_split_all_tac ctxt = SUBGOAL (fn (t, i) =>
   512       if exists_paired_all t then full_simp_tac (put_simpset ss ctxt) i else no_tac);
   513 
   514     fun split_all ctxt th =
   515       if exists_paired_all (Thm.prop_of th)
   516       then full_simplify (put_simpset ss ctxt) th else th;
   517   end;
   518 *}
   519 
   520 setup {* map_theory_claset (fn ctxt => ctxt addSbefore ("split_all_tac", split_all_tac)) *}
   521 
   522 lemma split_paired_All [simp, no_atp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   523   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   524   by fast
   525 
   526 lemma split_paired_Ex [simp, no_atp]: "(EX x. P x) = (EX a b. P (a, b))"
   527   by fast
   528 
   529 lemma split_paired_The [no_atp]: "(THE x. P x) = (THE (a, b). P (a, b))"
   530   -- {* Can't be added to simpset: loops! *}
   531   by (simp add: split_eta)
   532 
   533 text {*
   534   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   535   @{thm [source] split_eta} as a rewrite rule is not general enough,
   536   and using @{thm [source] cond_split_eta} directly would render some
   537   existing proofs very inefficient; similarly for @{text
   538   split_beta}.
   539 *}
   540 
   541 ML {*
   542 local
   543   val cond_split_eta_ss =
   544     simpset_of (put_simpset HOL_basic_ss @{context} addsimps @{thms cond_split_eta});
   545   fun Pair_pat k 0 (Bound m) = (m = k)
   546     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   547         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   548     | Pair_pat _ _ _ = false;
   549   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   550     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   551     | no_args k i (Bound m) = m < k orelse m > k + i
   552     | no_args _ _ _ = true;
   553   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   554     | split_pat tp i (Const (@{const_name case_prod}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   555     | split_pat tp i _ = NONE;
   556   fun metaeq ctxt lhs rhs = mk_meta_eq (Goal.prove ctxt [] []
   557         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   558         (K (simp_tac (put_simpset cond_split_eta_ss ctxt) 1)));
   559 
   560   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   561     | beta_term_pat k i (t $ u) =
   562         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   563     | beta_term_pat k i t = no_args k i t;
   564   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   565     | eta_term_pat _ _ _ = false;
   566   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   567     | subst arg k i (t $ u) =
   568         if Pair_pat k i (t $ u) then incr_boundvars k arg
   569         else (subst arg k i t $ subst arg k i u)
   570     | subst arg k i t = t;
   571 in
   572   fun beta_proc ctxt (s as Const (@{const_name case_prod}, _) $ Abs (_, _, t) $ arg) =
   573         (case split_pat beta_term_pat 1 t of
   574           SOME (i, f) => SOME (metaeq ctxt s (subst arg 0 i f))
   575         | NONE => NONE)
   576     | beta_proc _ _ = NONE;
   577   fun eta_proc ctxt (s as Const (@{const_name case_prod}, _) $ Abs (_, _, t)) =
   578         (case split_pat eta_term_pat 1 t of
   579           SOME (_, ft) => SOME (metaeq ctxt s (let val f $ _ = ft in f end))
   580         | NONE => NONE)
   581     | eta_proc _ _ = NONE;
   582 end;
   583 *}
   584 simproc_setup split_beta ("split f z") = {* fn _ => fn ctxt => fn ct => beta_proc ctxt (term_of ct) *}
   585 simproc_setup split_eta ("split f") = {* fn _ => fn ctxt => fn ct => eta_proc ctxt (term_of ct) *}
   586 
   587 lemmas split_beta [mono] = prod.case_eq_if
   588 
   589 lemma split_beta': "(\<lambda>(x,y). f x y) = (\<lambda>x. f (fst x) (snd x))"
   590   by (auto simp: fun_eq_iff)
   591 
   592 lemmas split_split [no_atp] = prod.split
   593   -- {* For use with @{text split} and the Simplifier. *}
   594 
   595 text {*
   596   @{thm [source] split_split} could be declared as @{text "[split]"}
   597   done after the Splitter has been speeded up significantly;
   598   precompute the constants involved and don't do anything unless the
   599   current goal contains one of those constants.
   600 *}
   601 
   602 lemmas split_split_asm [no_atp] = prod.split_asm
   603 
   604 text {*
   605   \medskip @{term split} used as a logical connective or set former.
   606 
   607   \medskip These rules are for use with @{text blast}; could instead
   608   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   609 
   610 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   611   apply (simp only: split_tupled_all)
   612   apply (simp (no_asm_simp))
   613   done
   614 
   615 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   616   apply (simp only: split_tupled_all)
   617   apply (simp (no_asm_simp))
   618   done
   619 
   620 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   621   by (induct p) auto
   622 
   623 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   624   by (induct p) auto
   625 
   626 lemma splitE2:
   627   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   628 proof -
   629   assume q: "Q (split P z)"
   630   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   631   show R
   632     apply (rule r surjective_pairing)+
   633     apply (rule split_beta [THEN subst], rule q)
   634     done
   635 qed
   636 
   637 lemma splitD': "split R (a,b) c ==> R a b c"
   638   by simp
   639 
   640 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   641   by simp
   642 
   643 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   644 by (simp only: split_tupled_all, simp)
   645 
   646 lemma mem_splitE:
   647   assumes "z \<in> split c p"
   648   obtains x y where "p = (x, y)" and "z \<in> c x y"
   649   using assms by (rule splitE2)
   650 
   651 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   652 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   653 
   654 ML {*
   655 local (* filtering with exists_p_split is an essential optimization *)
   656   fun exists_p_split (Const (@{const_name case_prod},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   657     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   658     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   659     | exists_p_split _ = false;
   660 in
   661 fun split_conv_tac ctxt = SUBGOAL (fn (t, i) =>
   662   if exists_p_split t
   663   then safe_full_simp_tac (put_simpset HOL_basic_ss ctxt addsimps @{thms split_conv}) i
   664   else no_tac);
   665 end;
   666 *}
   667 
   668 (* This prevents applications of splitE for already splitted arguments leading
   669    to quite time-consuming computations (in particular for nested tuples) *)
   670 setup {* map_theory_claset (fn ctxt => ctxt addSbefore ("split_conv_tac", split_conv_tac)) *}
   671 
   672 lemma split_eta_SetCompr [simp, no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   673   by (rule ext) fast
   674 
   675 lemma split_eta_SetCompr2 [simp, no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   676   by (rule ext) fast
   677 
   678 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   679   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   680   by (rule ext) blast
   681 
   682 (* Do NOT make this a simp rule as it
   683    a) only helps in special situations
   684    b) can lead to nontermination in the presence of split_def
   685 *)
   686 lemma split_comp_eq: 
   687   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   688   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   689   by (rule ext) auto
   690 
   691 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   692   apply (rule_tac x = "(a, b)" in image_eqI)
   693    apply auto
   694   done
   695 
   696 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   697   by blast
   698 
   699 (*
   700 the following  would be slightly more general,
   701 but cannot be used as rewrite rule:
   702 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   703 ### ?y = .x
   704 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   705 by (rtac some_equality 1)
   706 by ( Simp_tac 1)
   707 by (split_all_tac 1)
   708 by (Asm_full_simp_tac 1)
   709 qed "The_split_eq";
   710 *)
   711 
   712 text {*
   713   Setup of internal @{text split_rule}.
   714 *}
   715 
   716 lemmas case_prodI = prod.case [THEN iffD2]
   717 
   718 lemma case_prodI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> case_prod c p"
   719   by (fact splitI2)
   720 
   721 lemma case_prodI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> case_prod c p x"
   722   by (fact splitI2')
   723 
   724 lemma case_prodE: "case_prod c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   725   by (fact splitE)
   726 
   727 lemma case_prodE': "case_prod c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   728   by (fact splitE')
   729 
   730 declare case_prodI [intro!]
   731 
   732 lemma case_prod_beta:
   733   "case_prod f p = f (fst p) (snd p)"
   734   by (fact split_beta)
   735 
   736 lemma prod_cases3 [cases type]:
   737   obtains (fields) a b c where "y = (a, b, c)"
   738   by (cases y, case_tac b) blast
   739 
   740 lemma prod_induct3 [case_names fields, induct type]:
   741     "(!!a b c. P (a, b, c)) ==> P x"
   742   by (cases x) blast
   743 
   744 lemma prod_cases4 [cases type]:
   745   obtains (fields) a b c d where "y = (a, b, c, d)"
   746   by (cases y, case_tac c) blast
   747 
   748 lemma prod_induct4 [case_names fields, induct type]:
   749     "(!!a b c d. P (a, b, c, d)) ==> P x"
   750   by (cases x) blast
   751 
   752 lemma prod_cases5 [cases type]:
   753   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   754   by (cases y, case_tac d) blast
   755 
   756 lemma prod_induct5 [case_names fields, induct type]:
   757     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   758   by (cases x) blast
   759 
   760 lemma prod_cases6 [cases type]:
   761   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   762   by (cases y, case_tac e) blast
   763 
   764 lemma prod_induct6 [case_names fields, induct type]:
   765     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   766   by (cases x) blast
   767 
   768 lemma prod_cases7 [cases type]:
   769   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   770   by (cases y, case_tac f) blast
   771 
   772 lemma prod_induct7 [case_names fields, induct type]:
   773     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   774   by (cases x) blast
   775 
   776 lemma split_def:
   777   "split = (\<lambda>c p. c (fst p) (snd p))"
   778   by (fact case_prod_unfold)
   779 
   780 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   781   "internal_split == split"
   782 
   783 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   784   by (simp only: internal_split_def split_conv)
   785 
   786 ML_file "Tools/split_rule.ML"
   787 setup Split_Rule.setup
   788 
   789 hide_const internal_split
   790 
   791 
   792 subsubsection {* Derived operations *}
   793 
   794 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   795   "curry = (\<lambda>c x y. c (x, y))"
   796 
   797 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   798   by (simp add: curry_def)
   799 
   800 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   801   by (simp add: curry_def)
   802 
   803 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   804   by (simp add: curry_def)
   805 
   806 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   807   by (simp add: curry_def)
   808 
   809 lemma curry_split [simp]: "curry (split f) = f"
   810   by (simp add: curry_def split_def)
   811 
   812 lemma split_curry [simp]: "split (curry f) = f"
   813   by (simp add: curry_def split_def)
   814 
   815 lemma curry_K: "curry (\<lambda>x. c) = (\<lambda>x y. c)"
   816 by(simp add: fun_eq_iff)
   817 
   818 text {*
   819   The composition-uncurry combinator.
   820 *}
   821 
   822 notation fcomp (infixl "\<circ>>" 60)
   823 
   824 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   825   "f \<circ>\<rightarrow> g = (\<lambda>x. case_prod g (f x))"
   826 
   827 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   828   by (simp add: fun_eq_iff scomp_def case_prod_unfold)
   829 
   830 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = case_prod g (f x)"
   831   by (simp add: scomp_unfold case_prod_unfold)
   832 
   833 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   834   by (simp add: fun_eq_iff)
   835 
   836 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   837   by (simp add: fun_eq_iff)
   838 
   839 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   840   by (simp add: fun_eq_iff scomp_unfold)
   841 
   842 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   843   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   844 
   845 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   846   by (simp add: fun_eq_iff scomp_unfold)
   847 
   848 code_printing
   849   constant scomp \<rightharpoonup> (Eval) infixl 3 "#->"
   850 
   851 no_notation fcomp (infixl "\<circ>>" 60)
   852 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   853 
   854 text {*
   855   @{term map_prod} --- action of the product functor upon
   856   functions.
   857 *}
   858 
   859 definition map_prod :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   860   "map_prod f g = (\<lambda>(x, y). (f x, g y))"
   861 
   862 lemma map_prod_simp [simp, code]:
   863   "map_prod f g (a, b) = (f a, g b)"
   864   by (simp add: map_prod_def)
   865 
   866 functor map_prod: map_prod
   867   by (auto simp add: split_paired_all)
   868 
   869 lemma fst_map_prod [simp]:
   870   "fst (map_prod f g x) = f (fst x)"
   871   by (cases x) simp_all
   872 
   873 lemma snd_prod_fun [simp]:
   874   "snd (map_prod f g x) = g (snd x)"
   875   by (cases x) simp_all
   876 
   877 lemma fst_comp_map_prod [simp]:
   878   "fst \<circ> map_prod f g = f \<circ> fst"
   879   by (rule ext) simp_all
   880 
   881 lemma snd_comp_map_prod [simp]:
   882   "snd \<circ> map_prod f g = g \<circ> snd"
   883   by (rule ext) simp_all
   884 
   885 lemma map_prod_compose:
   886   "map_prod (f1 o f2) (g1 o g2) = (map_prod f1 g1 o map_prod f2 g2)"
   887   by (rule ext) (simp add: map_prod.compositionality comp_def)
   888 
   889 lemma map_prod_ident [simp]:
   890   "map_prod (%x. x) (%y. y) = (%z. z)"
   891   by (rule ext) (simp add: map_prod.identity)
   892 
   893 lemma map_prod_imageI [intro]:
   894   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_prod f g ` R"
   895   by (rule image_eqI) simp_all
   896 
   897 lemma prod_fun_imageE [elim!]:
   898   assumes major: "c \<in> map_prod f g ` R"
   899     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   900   shows P
   901   apply (rule major [THEN imageE])
   902   apply (case_tac x)
   903   apply (rule cases)
   904   apply simp_all
   905   done
   906 
   907 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   908   "apfst f = map_prod f id"
   909 
   910 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   911   "apsnd f = map_prod id f"
   912 
   913 lemma apfst_conv [simp, code]:
   914   "apfst f (x, y) = (f x, y)" 
   915   by (simp add: apfst_def)
   916 
   917 lemma apsnd_conv [simp, code]:
   918   "apsnd f (x, y) = (x, f y)" 
   919   by (simp add: apsnd_def)
   920 
   921 lemma fst_apfst [simp]:
   922   "fst (apfst f x) = f (fst x)"
   923   by (cases x) simp
   924 
   925 lemma fst_comp_apfst [simp]:
   926   "fst \<circ> apfst f = f \<circ> fst"
   927   by (simp add: fun_eq_iff)
   928 
   929 lemma fst_apsnd [simp]:
   930   "fst (apsnd f x) = fst x"
   931   by (cases x) simp
   932 
   933 lemma fst_comp_apsnd [simp]:
   934   "fst \<circ> apsnd f = fst"
   935   by (simp add: fun_eq_iff)
   936 
   937 lemma snd_apfst [simp]:
   938   "snd (apfst f x) = snd x"
   939   by (cases x) simp
   940 
   941 lemma snd_comp_apfst [simp]:
   942   "snd \<circ> apfst f = snd"
   943   by (simp add: fun_eq_iff)
   944 
   945 lemma snd_apsnd [simp]:
   946   "snd (apsnd f x) = f (snd x)"
   947   by (cases x) simp
   948 
   949 lemma snd_comp_apsnd [simp]:
   950   "snd \<circ> apsnd f = f \<circ> snd"
   951   by (simp add: fun_eq_iff)
   952 
   953 lemma apfst_compose:
   954   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   955   by (cases x) simp
   956 
   957 lemma apsnd_compose:
   958   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   959   by (cases x) simp
   960 
   961 lemma apfst_apsnd [simp]:
   962   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   963   by (cases x) simp
   964 
   965 lemma apsnd_apfst [simp]:
   966   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   967   by (cases x) simp
   968 
   969 lemma apfst_id [simp] :
   970   "apfst id = id"
   971   by (simp add: fun_eq_iff)
   972 
   973 lemma apsnd_id [simp] :
   974   "apsnd id = id"
   975   by (simp add: fun_eq_iff)
   976 
   977 lemma apfst_eq_conv [simp]:
   978   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   979   by (cases x) simp
   980 
   981 lemma apsnd_eq_conv [simp]:
   982   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   983   by (cases x) simp
   984 
   985 lemma apsnd_apfst_commute:
   986   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   987   by simp
   988 
   989 context
   990 begin
   991 
   992 local_setup {* Local_Theory.map_naming (Name_Space.mandatory_path "prod") *}
   993 
   994 definition swap :: "'a \<times> 'b \<Rightarrow> 'b \<times> 'a"
   995 where
   996   "swap p = (snd p, fst p)"
   997 
   998 end
   999 
  1000 lemma swap_simp [simp]:
  1001   "prod.swap (x, y) = (y, x)"
  1002   by (simp add: prod.swap_def)
  1003 
  1004 lemma swap_swap [simp]:
  1005   "prod.swap (prod.swap p) = p"
  1006   by (cases p) simp
  1007 
  1008 lemma swap_comp_swap [simp]:
  1009   "prod.swap \<circ> prod.swap = id"
  1010   by (simp add: fun_eq_iff)
  1011 
  1012 lemma pair_in_swap_image [simp]:
  1013   "(y, x) \<in> prod.swap ` A \<longleftrightarrow> (x, y) \<in> A"
  1014   by (auto intro!: image_eqI)
  1015 
  1016 lemma inj_swap [simp]:
  1017   "inj_on prod.swap A"
  1018   by (rule inj_onI) auto
  1019 
  1020 lemma swap_inj_on:
  1021   "inj_on (\<lambda>(i, j). (j, i)) A"
  1022   by (rule inj_onI) auto
  1023 
  1024 lemma surj_swap [simp]:
  1025   "surj prod.swap"
  1026   by (rule surjI [of _ prod.swap]) simp
  1027 
  1028 lemma bij_swap [simp]:
  1029   "bij prod.swap"
  1030   by (simp add: bij_def)
  1031 
  1032 lemma case_swap [simp]:
  1033   "(case prod.swap p of (y, x) \<Rightarrow> f x y) = (case p of (x, y) \<Rightarrow> f x y)"
  1034   by (cases p) simp
  1035 
  1036 text {*
  1037   Disjoint union of a family of sets -- Sigma.
  1038 *}
  1039 
  1040 definition Sigma :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<times> 'b) set" where
  1041   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
  1042 
  1043 abbreviation
  1044   Times :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set"
  1045     (infixr "<*>" 80) where
  1046   "A <*> B == Sigma A (%_. B)"
  1047 
  1048 notation (xsymbols)
  1049   Times  (infixr "\<times>" 80)
  1050 
  1051 notation (HTML output)
  1052   Times  (infixr "\<times>" 80)
  1053 
  1054 hide_const (open) Times
  1055 
  1056 syntax
  1057   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
  1058 translations
  1059   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
  1060 
  1061 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
  1062   by (unfold Sigma_def) blast
  1063 
  1064 lemma SigmaE [elim!]:
  1065     "[| c: Sigma A B;
  1066         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
  1067      |] ==> P"
  1068   -- {* The general elimination rule. *}
  1069   by (unfold Sigma_def) blast
  1070 
  1071 text {*
  1072   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
  1073   eigenvariables.
  1074 *}
  1075 
  1076 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
  1077   by blast
  1078 
  1079 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
  1080   by blast
  1081 
  1082 lemma SigmaE2:
  1083     "[| (a, b) : Sigma A B;
  1084         [| a:A;  b:B(a) |] ==> P
  1085      |] ==> P"
  1086   by blast
  1087 
  1088 lemma Sigma_cong:
  1089      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
  1090       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
  1091   by auto
  1092 
  1093 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
  1094   by blast
  1095 
  1096 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
  1097   by blast
  1098 
  1099 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
  1100   by blast
  1101 
  1102 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
  1103   by auto
  1104 
  1105 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
  1106   by auto
  1107 
  1108 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
  1109   by auto
  1110 
  1111 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
  1112   by blast
  1113 
  1114 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
  1115   by blast
  1116 
  1117 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
  1118   by (blast elim: equalityE)
  1119 
  1120 lemma SetCompr_Sigma_eq:
  1121     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
  1122   by blast
  1123 
  1124 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
  1125   by blast
  1126 
  1127 lemma UN_Times_distrib:
  1128   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
  1129   -- {* Suggested by Pierre Chartier *}
  1130   by blast
  1131 
  1132 lemma split_paired_Ball_Sigma [simp, no_atp]:
  1133     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
  1134   by blast
  1135 
  1136 lemma split_paired_Bex_Sigma [simp, no_atp]:
  1137     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
  1138   by blast
  1139 
  1140 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
  1141   by blast
  1142 
  1143 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
  1144   by blast
  1145 
  1146 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
  1147   by blast
  1148 
  1149 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
  1150   by blast
  1151 
  1152 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
  1153   by blast
  1154 
  1155 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1156   by blast
  1157 
  1158 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1159   by blast
  1160 
  1161 text {*
  1162   Non-dependent versions are needed to avoid the need for higher-order
  1163   matching, especially when the rules are re-oriented.
  1164 *}
  1165 
  1166 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1167   by (fact Sigma_Un_distrib1)
  1168 
  1169 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1170   by (fact Sigma_Int_distrib1)
  1171 
  1172 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1173   by (fact Sigma_Diff_distrib1)
  1174 
  1175 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1176   by auto
  1177 
  1178 lemma times_eq_iff: "A \<times> B = C \<times> D \<longleftrightarrow> A = C \<and> B = D \<or> ((A = {} \<or> B = {}) \<and> (C = {} \<or> D = {}))"
  1179   by auto
  1180 
  1181 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1182   by force
  1183 
  1184 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1185   by force
  1186 
  1187 lemma vimage_fst:
  1188   "fst -` A = A \<times> UNIV"
  1189   by auto
  1190 
  1191 lemma vimage_snd:
  1192   "snd -` A = UNIV \<times> A"
  1193   by auto
  1194 
  1195 lemma insert_times_insert[simp]:
  1196   "insert a A \<times> insert b B =
  1197    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1198 by blast
  1199 
  1200 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1201   apply auto
  1202   apply (case_tac "f x")
  1203   apply auto
  1204   done
  1205 
  1206 lemma times_Int_times: "A \<times> B \<inter> C \<times> D = (A \<inter> C) \<times> (B \<inter> D)"
  1207   by auto
  1208 
  1209 lemma product_swap:
  1210   "prod.swap ` (A \<times> B) = B \<times> A"
  1211   by (auto simp add: set_eq_iff)
  1212 
  1213 lemma swap_product:
  1214   "(\<lambda>(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1215   by (auto simp add: set_eq_iff)
  1216 
  1217 lemma image_split_eq_Sigma:
  1218   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1219 proof (safe intro!: imageI)
  1220   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1221   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1222     using * eq[symmetric] by auto
  1223 qed simp_all
  1224 
  1225 definition product :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set" where
  1226   [code_abbrev]: "product A B = A \<times> B"
  1227 
  1228 hide_const (open) product
  1229 
  1230 lemma member_product:
  1231   "x \<in> Product_Type.product A B \<longleftrightarrow> x \<in> A \<times> B"
  1232   by (simp add: product_def)
  1233 
  1234 text {* The following @{const map_prod} lemmas are due to Joachim Breitner: *}
  1235 
  1236 lemma map_prod_inj_on:
  1237   assumes "inj_on f A" and "inj_on g B"
  1238   shows "inj_on (map_prod f g) (A \<times> B)"
  1239 proof (rule inj_onI)
  1240   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1241   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1242   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1243   assume "map_prod f g x = map_prod f g y"
  1244   hence "fst (map_prod f g x) = fst (map_prod f g y)" by (auto)
  1245   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1246   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1247   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1248   moreover from `map_prod f g x = map_prod f g y`
  1249   have "snd (map_prod f g x) = snd (map_prod f g y)" by (auto)
  1250   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1251   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1252   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1253   ultimately show "x = y" by(rule prod_eqI)
  1254 qed
  1255 
  1256 lemma map_prod_surj:
  1257   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1258   assumes "surj f" and "surj g"
  1259   shows "surj (map_prod f g)"
  1260 unfolding surj_def
  1261 proof
  1262   fix y :: "'b \<times> 'd"
  1263   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1264   moreover
  1265   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1266   ultimately have "(fst y, snd y) = map_prod f g (a,b)" by auto
  1267   thus "\<exists>x. y = map_prod f g x" by auto
  1268 qed
  1269 
  1270 lemma map_prod_surj_on:
  1271   assumes "f ` A = A'" and "g ` B = B'"
  1272   shows "map_prod f g ` (A \<times> B) = A' \<times> B'"
  1273 unfolding image_def
  1274 proof(rule set_eqI,rule iffI)
  1275   fix x :: "'a \<times> 'c"
  1276   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_prod f g x}"
  1277   then obtain y where "y \<in> A \<times> B" and "x = map_prod f g y" by blast
  1278   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1279   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1280   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1281   with `x = map_prod f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1282 next
  1283   fix x :: "'a \<times> 'c"
  1284   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1285   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1286   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1287   moreover from `image g B = B'` and `snd x \<in> B'`
  1288   obtain b where "b \<in> B" and "snd x = g b" by auto
  1289   ultimately have "(fst x, snd x) = map_prod f g (a,b)" by auto
  1290   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1291   ultimately have "\<exists>y \<in> A \<times> B. x = map_prod f g y" by auto
  1292   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_prod f g y}" by auto
  1293 qed
  1294 
  1295 
  1296 subsection {* Simproc for rewriting a set comprehension into a pointfree expression *}
  1297 
  1298 ML_file "Tools/set_comprehension_pointfree.ML"
  1299 
  1300 setup {*
  1301   Code_Preproc.map_pre (fn ctxt => ctxt addsimprocs
  1302     [Raw_Simplifier.make_simproc {name = "set comprehension", lhss = [@{cpat "Collect ?P"}],
  1303     proc = K Set_Comprehension_Pointfree.code_simproc, identifier = []}])
  1304 *}
  1305 
  1306 
  1307 subsection {* Inductively defined sets *}
  1308 
  1309 (* simplify {(x1, ..., xn). (x1, ..., xn) : S} to S *)
  1310 simproc_setup Collect_mem ("Collect t") = {*
  1311   fn _ => fn ctxt => fn ct =>
  1312     (case term_of ct of
  1313       S as Const (@{const_name Collect}, Type (@{type_name fun}, [_, T])) $ t =>
  1314         let val (u, _, ps) = HOLogic.strip_psplits t in
  1315           (case u of
  1316             (c as Const (@{const_name Set.member}, _)) $ q $ S' =>
  1317               (case try (HOLogic.strip_ptuple ps) q of
  1318                 NONE => NONE
  1319               | SOME ts =>
  1320                   if not (Term.is_open S') andalso
  1321                     ts = map Bound (length ps downto 0)
  1322                   then
  1323                     let val simp =
  1324                       full_simp_tac (put_simpset HOL_basic_ss ctxt
  1325                         addsimps [@{thm split_paired_all}, @{thm split_conv}]) 1
  1326                     in
  1327                       SOME (Goal.prove ctxt [] []
  1328                         (Const (@{const_name Pure.eq}, T --> T --> propT) $ S $ S')
  1329                         (K (EVERY
  1330                           [rtac eq_reflection 1, rtac @{thm subset_antisym} 1,
  1331                            rtac subsetI 1, dtac CollectD 1, simp,
  1332                            rtac subsetI 1, rtac CollectI 1, simp])))
  1333                     end
  1334                   else NONE)
  1335           | _ => NONE)
  1336         end
  1337     | _ => NONE)
  1338 *}
  1339 
  1340 ML_file "Tools/inductive_set.ML"
  1341 
  1342 
  1343 subsection {* Legacy theorem bindings and duplicates *}
  1344 
  1345 lemma PairE:
  1346   obtains x y where "p = (x, y)"
  1347   by (fact prod.exhaust)
  1348 
  1349 lemmas Pair_eq = prod.inject
  1350 lemmas fst_conv = prod.sel(1)
  1351 lemmas snd_conv = prod.sel(2)
  1352 lemmas pair_collapse = prod.collapse
  1353 lemmas split = split_conv
  1354 lemmas Pair_fst_snd_eq = prod_eq_iff
  1355 
  1356 hide_const (open) prod
  1357 
  1358 end