src/HOL/Topological_Spaces.thy
author haftmann
Fri Oct 10 19:55:32 2014 +0200 (2014-10-10)
changeset 58646 cd63a4b12a33
parent 57953 69728243a614
child 58729 e8ecc79aee43
permissions -rw-r--r--
specialized specification: avoid trivial instances
     1 (*  Title:      HOL/Topological_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 header {* Topological Spaces *}
     7 
     8 theory Topological_Spaces
     9 imports Main Conditionally_Complete_Lattices
    10 begin
    11 
    12 named_theorems continuous_intros "structural introduction rules for continuity"
    13 
    14 
    15 subsection {* Topological space *}
    16 
    17 class "open" =
    18   fixes "open" :: "'a set \<Rightarrow> bool"
    19 
    20 class topological_space = "open" +
    21   assumes open_UNIV [simp, intro]: "open UNIV"
    22   assumes open_Int [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<inter> T)"
    23   assumes open_Union [intro]: "\<forall>S\<in>K. open S \<Longrightarrow> open (\<Union> K)"
    24 begin
    25 
    26 definition
    27   closed :: "'a set \<Rightarrow> bool" where
    28   "closed S \<longleftrightarrow> open (- S)"
    29 
    30 lemma open_empty [continuous_intros, intro, simp]: "open {}"
    31   using open_Union [of "{}"] by simp
    32 
    33 lemma open_Un [continuous_intros, intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<union> T)"
    34   using open_Union [of "{S, T}"] by simp
    35 
    36 lemma open_UN [continuous_intros, intro]: "\<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Union>x\<in>A. B x)"
    37   using open_Union [of "B ` A"] by simp
    38 
    39 lemma open_Inter [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. open T \<Longrightarrow> open (\<Inter>S)"
    40   by (induct set: finite) auto
    41 
    42 lemma open_INT [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Inter>x\<in>A. B x)"
    43   using open_Inter [of "B ` A"] by simp
    44 
    45 lemma openI:
    46   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
    47   shows "open S"
    48 proof -
    49   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
    50   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
    51   ultimately show "open S" by simp
    52 qed
    53 
    54 lemma closed_empty [continuous_intros, intro, simp]:  "closed {}"
    55   unfolding closed_def by simp
    56 
    57 lemma closed_Un [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<union> T)"
    58   unfolding closed_def by auto
    59 
    60 lemma closed_UNIV [continuous_intros, intro, simp]: "closed UNIV"
    61   unfolding closed_def by simp
    62 
    63 lemma closed_Int [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<inter> T)"
    64   unfolding closed_def by auto
    65 
    66 lemma closed_INT [continuous_intros, intro]: "\<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Inter>x\<in>A. B x)"
    67   unfolding closed_def by auto
    68 
    69 lemma closed_Inter [continuous_intros, intro]: "\<forall>S\<in>K. closed S \<Longrightarrow> closed (\<Inter> K)"
    70   unfolding closed_def uminus_Inf by auto
    71 
    72 lemma closed_Union [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. closed T \<Longrightarrow> closed (\<Union>S)"
    73   by (induct set: finite) auto
    74 
    75 lemma closed_UN [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Union>x\<in>A. B x)"
    76   using closed_Union [of "B ` A"] by simp
    77 
    78 lemma open_closed: "open S \<longleftrightarrow> closed (- S)"
    79   unfolding closed_def by simp
    80 
    81 lemma closed_open: "closed S \<longleftrightarrow> open (- S)"
    82   unfolding closed_def by simp
    83 
    84 lemma open_Diff [continuous_intros, intro]: "open S \<Longrightarrow> closed T \<Longrightarrow> open (S - T)"
    85   unfolding closed_open Diff_eq by (rule open_Int)
    86 
    87 lemma closed_Diff [continuous_intros, intro]: "closed S \<Longrightarrow> open T \<Longrightarrow> closed (S - T)"
    88   unfolding open_closed Diff_eq by (rule closed_Int)
    89 
    90 lemma open_Compl [continuous_intros, intro]: "closed S \<Longrightarrow> open (- S)"
    91   unfolding closed_open .
    92 
    93 lemma closed_Compl [continuous_intros, intro]: "open S \<Longrightarrow> closed (- S)"
    94   unfolding open_closed .
    95 
    96 lemma open_Collect_neg: "closed {x. P x} \<Longrightarrow> open {x. \<not> P x}"
    97   unfolding Collect_neg_eq by (rule open_Compl)
    98 
    99 lemma open_Collect_conj: assumes "open {x. P x}" "open {x. Q x}" shows "open {x. P x \<and> Q x}"
   100   using open_Int[OF assms] by (simp add: Int_def)
   101 
   102 lemma open_Collect_disj: assumes "open {x. P x}" "open {x. Q x}" shows "open {x. P x \<or> Q x}"
   103   using open_Un[OF assms] by (simp add: Un_def)
   104 
   105 lemma open_Collect_ex: "(\<And>i. open {x. P i x}) \<Longrightarrow> open {x. \<exists>i. P i x}"
   106   using open_UN[of UNIV "\<lambda>i. {x. P i x}"] unfolding Collect_ex_eq by simp 
   107 
   108 lemma open_Collect_imp: "closed {x. P x} \<Longrightarrow> open {x. Q x} \<Longrightarrow> open {x. P x \<longrightarrow> Q x}"
   109   unfolding imp_conv_disj by (intro open_Collect_disj open_Collect_neg)
   110 
   111 lemma open_Collect_const: "open {x. P}"
   112   by (cases P) auto
   113 
   114 lemma closed_Collect_neg: "open {x. P x} \<Longrightarrow> closed {x. \<not> P x}"
   115   unfolding Collect_neg_eq by (rule closed_Compl)
   116 
   117 lemma closed_Collect_conj: assumes "closed {x. P x}" "closed {x. Q x}" shows "closed {x. P x \<and> Q x}"
   118   using closed_Int[OF assms] by (simp add: Int_def)
   119 
   120 lemma closed_Collect_disj: assumes "closed {x. P x}" "closed {x. Q x}" shows "closed {x. P x \<or> Q x}"
   121   using closed_Un[OF assms] by (simp add: Un_def)
   122 
   123 lemma closed_Collect_all: "(\<And>i. closed {x. P i x}) \<Longrightarrow> closed {x. \<forall>i. P i x}"
   124   using closed_INT[of UNIV "\<lambda>i. {x. P i x}"] unfolding Collect_all_eq by simp 
   125 
   126 lemma closed_Collect_imp: "open {x. P x} \<Longrightarrow> closed {x. Q x} \<Longrightarrow> closed {x. P x \<longrightarrow> Q x}"
   127   unfolding imp_conv_disj by (intro closed_Collect_disj closed_Collect_neg)
   128 
   129 lemma closed_Collect_const: "closed {x. P}"
   130   by (cases P) auto
   131 
   132 end
   133 
   134 subsection{* Hausdorff and other separation properties *}
   135 
   136 class t0_space = topological_space +
   137   assumes t0_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U)"
   138 
   139 class t1_space = topological_space +
   140   assumes t1_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   141 
   142 instance t1_space \<subseteq> t0_space
   143 proof qed (fast dest: t1_space)
   144 
   145 lemma separation_t1:
   146   fixes x y :: "'a::t1_space"
   147   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U)"
   148   using t1_space[of x y] by blast
   149 
   150 lemma closed_singleton:
   151   fixes a :: "'a::t1_space"
   152   shows "closed {a}"
   153 proof -
   154   let ?T = "\<Union>{S. open S \<and> a \<notin> S}"
   155   have "open ?T" by (simp add: open_Union)
   156   also have "?T = - {a}"
   157     by (simp add: set_eq_iff separation_t1, auto)
   158   finally show "closed {a}" unfolding closed_def .
   159 qed
   160 
   161 lemma closed_insert [continuous_intros, simp]:
   162   fixes a :: "'a::t1_space"
   163   assumes "closed S" shows "closed (insert a S)"
   164 proof -
   165   from closed_singleton assms
   166   have "closed ({a} \<union> S)" by (rule closed_Un)
   167   thus "closed (insert a S)" by simp
   168 qed
   169 
   170 lemma finite_imp_closed:
   171   fixes S :: "'a::t1_space set"
   172   shows "finite S \<Longrightarrow> closed S"
   173 by (induct set: finite, simp_all)
   174 
   175 text {* T2 spaces are also known as Hausdorff spaces. *}
   176 
   177 class t2_space = topological_space +
   178   assumes hausdorff: "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   179 
   180 instance t2_space \<subseteq> t1_space
   181 proof qed (fast dest: hausdorff)
   182 
   183 lemma separation_t2:
   184   fixes x y :: "'a::t2_space"
   185   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {})"
   186   using hausdorff[of x y] by blast
   187 
   188 lemma separation_t0:
   189   fixes x y :: "'a::t0_space"
   190   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> ~(x\<in>U \<longleftrightarrow> y\<in>U))"
   191   using t0_space[of x y] by blast
   192 
   193 text {* A perfect space is a topological space with no isolated points. *}
   194 
   195 class perfect_space = topological_space +
   196   assumes not_open_singleton: "\<not> open {x}"
   197 
   198 
   199 subsection {* Generators for toplogies *}
   200 
   201 inductive generate_topology for S where
   202   UNIV: "generate_topology S UNIV"
   203 | Int: "generate_topology S a \<Longrightarrow> generate_topology S b \<Longrightarrow> generate_topology S (a \<inter> b)"
   204 | UN: "(\<And>k. k \<in> K \<Longrightarrow> generate_topology S k) \<Longrightarrow> generate_topology S (\<Union>K)"
   205 | Basis: "s \<in> S \<Longrightarrow> generate_topology S s"
   206 
   207 hide_fact (open) UNIV Int UN Basis 
   208 
   209 lemma generate_topology_Union: 
   210   "(\<And>k. k \<in> I \<Longrightarrow> generate_topology S (K k)) \<Longrightarrow> generate_topology S (\<Union>k\<in>I. K k)"
   211   using generate_topology.UN [of "K ` I"] by auto
   212 
   213 lemma topological_space_generate_topology:
   214   "class.topological_space (generate_topology S)"
   215   by default (auto intro: generate_topology.intros)
   216 
   217 subsection {* Order topologies *}
   218 
   219 class order_topology = order + "open" +
   220   assumes open_generated_order: "open = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   221 begin
   222 
   223 subclass topological_space
   224   unfolding open_generated_order
   225   by (rule topological_space_generate_topology)
   226 
   227 lemma open_greaterThan [continuous_intros, simp]: "open {a <..}"
   228   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   229 
   230 lemma open_lessThan [continuous_intros, simp]: "open {..< a}"
   231   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   232 
   233 lemma open_greaterThanLessThan [continuous_intros, simp]: "open {a <..< b}"
   234    unfolding greaterThanLessThan_eq by (simp add: open_Int)
   235 
   236 end
   237 
   238 class linorder_topology = linorder + order_topology
   239 
   240 lemma closed_atMost [continuous_intros, simp]: "closed {.. a::'a::linorder_topology}"
   241   by (simp add: closed_open)
   242 
   243 lemma closed_atLeast [continuous_intros, simp]: "closed {a::'a::linorder_topology ..}"
   244   by (simp add: closed_open)
   245 
   246 lemma closed_atLeastAtMost [continuous_intros, simp]: "closed {a::'a::linorder_topology .. b}"
   247 proof -
   248   have "{a .. b} = {a ..} \<inter> {.. b}"
   249     by auto
   250   then show ?thesis
   251     by (simp add: closed_Int)
   252 qed
   253 
   254 lemma (in linorder) less_separate:
   255   assumes "x < y"
   256   shows "\<exists>a b. x \<in> {..< a} \<and> y \<in> {b <..} \<and> {..< a} \<inter> {b <..} = {}"
   257 proof (cases "\<exists>z. x < z \<and> z < y")
   258   case True
   259   then obtain z where "x < z \<and> z < y" ..
   260   then have "x \<in> {..< z} \<and> y \<in> {z <..} \<and> {z <..} \<inter> {..< z} = {}"
   261     by auto
   262   then show ?thesis by blast
   263 next
   264   case False
   265   with `x < y` have "x \<in> {..< y} \<and> y \<in> {x <..} \<and> {x <..} \<inter> {..< y} = {}"
   266     by auto
   267   then show ?thesis by blast
   268 qed
   269 
   270 instance linorder_topology \<subseteq> t2_space
   271 proof
   272   fix x y :: 'a
   273   from less_separate[of x y] less_separate[of y x]
   274   show "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   275     by (elim neqE) (metis open_lessThan open_greaterThan Int_commute)+
   276 qed
   277 
   278 lemma (in linorder_topology) open_right:
   279   assumes "open S" "x \<in> S" and gt_ex: "x < y" shows "\<exists>b>x. {x ..< b} \<subseteq> S"
   280   using assms unfolding open_generated_order
   281 proof induction
   282   case (Int A B)
   283   then obtain a b where "a > x" "{x ..< a} \<subseteq> A"  "b > x" "{x ..< b} \<subseteq> B" by auto
   284   then show ?case by (auto intro!: exI[of _ "min a b"])
   285 next
   286   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] gt_ex)
   287 qed blast+
   288 
   289 lemma (in linorder_topology) open_left:
   290   assumes "open S" "x \<in> S" and lt_ex: "y < x" shows "\<exists>b<x. {b <.. x} \<subseteq> S"
   291   using assms unfolding open_generated_order
   292 proof induction
   293   case (Int A B)
   294   then obtain a b where "a < x" "{a <.. x} \<subseteq> A"  "b < x" "{b <.. x} \<subseteq> B" by auto
   295   then show ?case by (auto intro!: exI[of _ "max a b"])
   296 next
   297   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] lt_ex)
   298 qed blast+
   299 
   300 subsection {* Filters *}
   301 
   302 text {*
   303   This definition also allows non-proper filters.
   304 *}
   305 
   306 locale is_filter =
   307   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
   308   assumes True: "F (\<lambda>x. True)"
   309   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
   310   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
   311 
   312 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
   313 proof
   314   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
   315 qed
   316 
   317 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
   318   using Rep_filter [of F] by simp
   319 
   320 lemma Abs_filter_inverse':
   321   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
   322   using assms by (simp add: Abs_filter_inverse)
   323 
   324 
   325 subsubsection {* Eventually *}
   326 
   327 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   328   where "eventually P F \<longleftrightarrow> Rep_filter F P"
   329 
   330 lemma eventually_Abs_filter:
   331   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
   332   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
   333 
   334 lemma filter_eq_iff:
   335   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
   336   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
   337 
   338 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
   339   unfolding eventually_def
   340   by (rule is_filter.True [OF is_filter_Rep_filter])
   341 
   342 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
   343 proof -
   344   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
   345   thus "eventually P F" by simp
   346 qed
   347 
   348 lemma eventually_mono:
   349   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
   350   unfolding eventually_def
   351   by (rule is_filter.mono [OF is_filter_Rep_filter])
   352 
   353 lemma eventually_conj:
   354   assumes P: "eventually (\<lambda>x. P x) F"
   355   assumes Q: "eventually (\<lambda>x. Q x) F"
   356   shows "eventually (\<lambda>x. P x \<and> Q x) F"
   357   using assms unfolding eventually_def
   358   by (rule is_filter.conj [OF is_filter_Rep_filter])
   359 
   360 lemma eventually_Ball_finite:
   361   assumes "finite A" and "\<forall>y\<in>A. eventually (\<lambda>x. P x y) net"
   362   shows "eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   363 using assms by (induct set: finite, simp, simp add: eventually_conj)
   364 
   365 lemma eventually_all_finite:
   366   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   367   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   368   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   369 using eventually_Ball_finite [of UNIV P] assms by simp
   370 
   371 lemma eventually_mp:
   372   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   373   assumes "eventually (\<lambda>x. P x) F"
   374   shows "eventually (\<lambda>x. Q x) F"
   375 proof (rule eventually_mono)
   376   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
   377   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
   378     using assms by (rule eventually_conj)
   379 qed
   380 
   381 lemma eventually_rev_mp:
   382   assumes "eventually (\<lambda>x. P x) F"
   383   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   384   shows "eventually (\<lambda>x. Q x) F"
   385 using assms(2) assms(1) by (rule eventually_mp)
   386 
   387 lemma eventually_conj_iff:
   388   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
   389   by (auto intro: eventually_conj elim: eventually_rev_mp)
   390 
   391 lemma eventually_elim1:
   392   assumes "eventually (\<lambda>i. P i) F"
   393   assumes "\<And>i. P i \<Longrightarrow> Q i"
   394   shows "eventually (\<lambda>i. Q i) F"
   395   using assms by (auto elim!: eventually_rev_mp)
   396 
   397 lemma eventually_elim2:
   398   assumes "eventually (\<lambda>i. P i) F"
   399   assumes "eventually (\<lambda>i. Q i) F"
   400   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   401   shows "eventually (\<lambda>i. R i) F"
   402   using assms by (auto elim!: eventually_rev_mp)
   403 
   404 lemma not_eventually_impI: "eventually P F \<Longrightarrow> \<not> eventually Q F \<Longrightarrow> \<not> eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   405   by (auto intro: eventually_mp)
   406 
   407 lemma not_eventuallyD: "\<not> eventually P F \<Longrightarrow> \<exists>x. \<not> P x"
   408   by (metis always_eventually)
   409 
   410 lemma eventually_subst:
   411   assumes "eventually (\<lambda>n. P n = Q n) F"
   412   shows "eventually P F = eventually Q F" (is "?L = ?R")
   413 proof -
   414   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   415       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   416     by (auto elim: eventually_elim1)
   417   then show ?thesis by (auto elim: eventually_elim2)
   418 qed
   419 
   420 ML {*
   421   fun eventually_elim_tac ctxt thms = SUBGOAL_CASES (fn (_, _, st) =>
   422     let
   423       val thy = Proof_Context.theory_of ctxt
   424       val mp_thms = thms RL [@{thm eventually_rev_mp}]
   425       val raw_elim_thm =
   426         (@{thm allI} RS @{thm always_eventually})
   427         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   428         |> fold (fn _ => fn thm => @{thm impI} RS thm) thms
   429       val cases_prop = prop_of (raw_elim_thm RS st)
   430       val cases = (Rule_Cases.make_common (thy, cases_prop) [(("elim", []), [])])
   431     in
   432       CASES cases (rtac raw_elim_thm 1)
   433     end) 1
   434 *}
   435 
   436 method_setup eventually_elim = {*
   437   Scan.succeed (fn ctxt => METHOD_CASES (eventually_elim_tac ctxt))
   438 *} "elimination of eventually quantifiers"
   439 
   440 
   441 subsubsection {* Finer-than relation *}
   442 
   443 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   444 filter @{term F'}. *}
   445 
   446 instantiation filter :: (type) complete_lattice
   447 begin
   448 
   449 definition le_filter_def:
   450   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   451 
   452 definition
   453   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   454 
   455 definition
   456   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   457 
   458 definition
   459   "bot = Abs_filter (\<lambda>P. True)"
   460 
   461 definition
   462   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   463 
   464 definition
   465   "inf F F' = Abs_filter
   466       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   467 
   468 definition
   469   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   470 
   471 definition
   472   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   473 
   474 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   475   unfolding top_filter_def
   476   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   477 
   478 lemma eventually_bot [simp]: "eventually P bot"
   479   unfolding bot_filter_def
   480   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   481 
   482 lemma eventually_sup:
   483   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   484   unfolding sup_filter_def
   485   by (rule eventually_Abs_filter, rule is_filter.intro)
   486      (auto elim!: eventually_rev_mp)
   487 
   488 lemma eventually_inf:
   489   "eventually P (inf F F') \<longleftrightarrow>
   490    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   491   unfolding inf_filter_def
   492   apply (rule eventually_Abs_filter, rule is_filter.intro)
   493   apply (fast intro: eventually_True)
   494   apply clarify
   495   apply (intro exI conjI)
   496   apply (erule (1) eventually_conj)
   497   apply (erule (1) eventually_conj)
   498   apply simp
   499   apply auto
   500   done
   501 
   502 lemma eventually_Sup:
   503   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   504   unfolding Sup_filter_def
   505   apply (rule eventually_Abs_filter, rule is_filter.intro)
   506   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   507   done
   508 
   509 instance proof
   510   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   511   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   512     by (rule less_filter_def) }
   513   { show "F \<le> F"
   514     unfolding le_filter_def by simp }
   515   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   516     unfolding le_filter_def by simp }
   517   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   518     unfolding le_filter_def filter_eq_iff by fast }
   519   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   520     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   521   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   522     unfolding le_filter_def eventually_inf
   523     by (auto elim!: eventually_mono intro: eventually_conj) }
   524   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   525     unfolding le_filter_def eventually_sup by simp_all }
   526   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   527     unfolding le_filter_def eventually_sup by simp }
   528   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   529     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   530   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   531     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   532   { assume "F \<in> S" thus "F \<le> Sup S"
   533     unfolding le_filter_def eventually_Sup by simp }
   534   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   535     unfolding le_filter_def eventually_Sup by simp }
   536   { show "Inf {} = (top::'a filter)"
   537     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   538       (metis (full_types) top_filter_def always_eventually eventually_top) }
   539   { show "Sup {} = (bot::'a filter)"
   540     by (auto simp: bot_filter_def Sup_filter_def) }
   541 qed
   542 
   543 end
   544 
   545 lemma filter_leD:
   546   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   547   unfolding le_filter_def by simp
   548 
   549 lemma filter_leI:
   550   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   551   unfolding le_filter_def by simp
   552 
   553 lemma eventually_False:
   554   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   555   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   556 
   557 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   558   where "trivial_limit F \<equiv> F = bot"
   559 
   560 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   561   by (rule eventually_False [symmetric])
   562 
   563 lemma eventually_const: "\<not> trivial_limit net \<Longrightarrow> eventually (\<lambda>x. P) net \<longleftrightarrow> P"
   564   by (cases P) (simp_all add: eventually_False)
   565 
   566 lemma eventually_Inf: "eventually P (Inf B) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X))"
   567 proof -
   568   let ?F = "\<lambda>P. \<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X)"
   569   
   570   { fix P have "eventually P (Abs_filter ?F) \<longleftrightarrow> ?F P"
   571     proof (rule eventually_Abs_filter is_filter.intro)+
   572       show "?F (\<lambda>x. True)"
   573         by (rule exI[of _ "{}"]) (simp add: le_fun_def)
   574     next
   575       fix P Q
   576       assume "?F P" then guess X ..
   577       moreover
   578       assume "?F Q" then guess Y ..
   579       ultimately show "?F (\<lambda>x. P x \<and> Q x)"
   580         by (intro exI[of _ "X \<union> Y"])
   581            (auto simp: Inf_union_distrib eventually_inf)
   582     next
   583       fix P Q
   584       assume "?F P" then guess X ..
   585       moreover assume "\<forall>x. P x \<longrightarrow> Q x"
   586       ultimately show "?F Q"
   587         by (intro exI[of _ X]) (auto elim: eventually_elim1)
   588     qed }
   589   note eventually_F = this
   590 
   591   have "Inf B = Abs_filter ?F"
   592   proof (intro antisym Inf_greatest)
   593     show "Inf B \<le> Abs_filter ?F"
   594       by (auto simp: le_filter_def eventually_F dest: Inf_superset_mono)
   595   next
   596     fix F assume "F \<in> B" then show "Abs_filter ?F \<le> F"
   597       by (auto simp add: le_filter_def eventually_F intro!: exI[of _ "{F}"])
   598   qed
   599   then show ?thesis
   600     by (simp add: eventually_F)
   601 qed
   602 
   603 lemma eventually_INF: "eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (INF b:X. F b))"
   604   unfolding INF_def[of B] eventually_Inf[of P "F`B"]
   605   by (metis Inf_image_eq finite_imageI image_mono finite_subset_image)
   606 
   607 lemma Inf_filter_not_bot:
   608   fixes B :: "'a filter set"
   609   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> Inf X \<noteq> bot) \<Longrightarrow> Inf B \<noteq> bot"
   610   unfolding trivial_limit_def eventually_Inf[of _ B]
   611     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   612 
   613 lemma INF_filter_not_bot:
   614   fixes F :: "'i \<Rightarrow> 'a filter"
   615   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> (INF b:X. F b) \<noteq> bot) \<Longrightarrow> (INF b:B. F b) \<noteq> bot"
   616   unfolding trivial_limit_def eventually_INF[of _ B]
   617     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   618 
   619 lemma eventually_Inf_base:
   620   assumes "B \<noteq> {}" and base: "\<And>F G. F \<in> B \<Longrightarrow> G \<in> B \<Longrightarrow> \<exists>x\<in>B. x \<le> inf F G"
   621   shows "eventually P (Inf B) \<longleftrightarrow> (\<exists>b\<in>B. eventually P b)"
   622 proof (subst eventually_Inf, safe)
   623   fix X assume "finite X" "X \<subseteq> B"
   624   then have "\<exists>b\<in>B. \<forall>x\<in>X. b \<le> x"
   625   proof induct
   626     case empty then show ?case
   627       using `B \<noteq> {}` by auto
   628   next
   629     case (insert x X)
   630     then obtain b where "b \<in> B" "\<And>x. x \<in> X \<Longrightarrow> b \<le> x"
   631       by auto
   632     with `insert x X \<subseteq> B` base[of b x] show ?case
   633       by (auto intro: order_trans)
   634   qed
   635   then obtain b where "b \<in> B" "b \<le> Inf X"
   636     by (auto simp: le_Inf_iff)
   637   then show "eventually P (Inf X) \<Longrightarrow> Bex B (eventually P)"
   638     by (intro bexI[of _ b]) (auto simp: le_filter_def)
   639 qed (auto intro!: exI[of _ "{x}" for x])
   640 
   641 lemma eventually_INF_base:
   642   "B \<noteq> {} \<Longrightarrow> (\<And>a b. a \<in> B \<Longrightarrow> b \<in> B \<Longrightarrow> \<exists>x\<in>B. F x \<le> inf (F a) (F b)) \<Longrightarrow>
   643     eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>b\<in>B. eventually P (F b))"
   644   unfolding INF_def by (subst eventually_Inf_base) auto
   645 
   646 
   647 subsubsection {* Map function for filters *}
   648 
   649 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   650   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   651 
   652 lemma eventually_filtermap:
   653   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   654   unfolding filtermap_def
   655   apply (rule eventually_Abs_filter)
   656   apply (rule is_filter.intro)
   657   apply (auto elim!: eventually_rev_mp)
   658   done
   659 
   660 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   661   by (simp add: filter_eq_iff eventually_filtermap)
   662 
   663 lemma filtermap_filtermap:
   664   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   665   by (simp add: filter_eq_iff eventually_filtermap)
   666 
   667 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   668   unfolding le_filter_def eventually_filtermap by simp
   669 
   670 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   671   by (simp add: filter_eq_iff eventually_filtermap)
   672 
   673 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   674   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   675 
   676 lemma filtermap_inf: "filtermap f (inf F1 F2) \<le> inf (filtermap f F1) (filtermap f F2)"
   677   by (auto simp: le_filter_def eventually_filtermap eventually_inf)
   678 
   679 lemma filtermap_INF: "filtermap f (INF b:B. F b) \<le> (INF b:B. filtermap f (F b))"
   680 proof -
   681   { fix X :: "'c set" assume "finite X"
   682     then have "filtermap f (INFIMUM X F) \<le> (INF b:X. filtermap f (F b))"
   683     proof induct
   684       case (insert x X)
   685       have "filtermap f (INF a:insert x X. F a) \<le> inf (filtermap f (F x)) (filtermap f (INF a:X. F a))"
   686         by (rule order_trans[OF _ filtermap_inf]) simp
   687       also have "\<dots> \<le> inf (filtermap f (F x)) (INF a:X. filtermap f (F a))"
   688         by (intro inf_mono insert order_refl)
   689       finally show ?case
   690         by simp
   691     qed simp }
   692   then show ?thesis
   693     unfolding le_filter_def eventually_filtermap
   694     by (subst (1 2) eventually_INF) auto
   695 qed
   696 subsubsection {* Standard filters *}
   697 
   698 definition principal :: "'a set \<Rightarrow> 'a filter" where
   699   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   700 
   701 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   702   unfolding principal_def
   703   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   704 
   705 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   706   unfolding eventually_inf eventually_principal by (auto elim: eventually_elim1)
   707 
   708 lemma principal_UNIV[simp]: "principal UNIV = top"
   709   by (auto simp: filter_eq_iff eventually_principal)
   710 
   711 lemma principal_empty[simp]: "principal {} = bot"
   712   by (auto simp: filter_eq_iff eventually_principal)
   713 
   714 lemma principal_eq_bot_iff: "principal X = bot \<longleftrightarrow> X = {}"
   715   by (auto simp add: filter_eq_iff eventually_principal)
   716 
   717 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   718   by (auto simp: le_filter_def eventually_principal)
   719 
   720 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   721   unfolding le_filter_def eventually_principal
   722   apply safe
   723   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   724   apply (auto elim: eventually_elim1)
   725   done
   726 
   727 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   728   unfolding eq_iff by simp
   729 
   730 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   731   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   732 
   733 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   734   unfolding filter_eq_iff eventually_inf eventually_principal
   735   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   736 
   737 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   738   unfolding filter_eq_iff eventually_Sup SUP_def by (auto simp: eventually_principal)
   739 
   740 lemma INF_principal_finite: "finite X \<Longrightarrow> (INF x:X. principal (f x)) = principal (\<Inter>x\<in>X. f x)"
   741   by (induct X rule: finite_induct) auto
   742 
   743 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   744   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   745 
   746 subsubsection {* Order filters *}
   747 
   748 definition at_top :: "('a::order) filter"
   749   where "at_top = (INF k. principal {k ..})"
   750 
   751 lemma at_top_sub: "at_top = (INF k:{c::'a::linorder..}. principal {k ..})"
   752   by (auto intro!: INF_eq max.cobounded1 max.cobounded2 simp: at_top_def)
   753 
   754 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   755   unfolding at_top_def
   756   by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   757 
   758 lemma eventually_ge_at_top:
   759   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   760   unfolding eventually_at_top_linorder by auto
   761 
   762 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::{no_top, linorder}. \<forall>n>N. P n)"
   763 proof -
   764   have "eventually P (INF k. principal {k <..}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n>N. P n)"
   765     by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   766   also have "(INF k. principal {k::'a <..}) = at_top"
   767     unfolding at_top_def 
   768     by (intro INF_eq) (auto intro: less_imp_le simp: Ici_subset_Ioi_iff gt_ex)
   769   finally show ?thesis .
   770 qed
   771 
   772 lemma eventually_gt_at_top:
   773   "eventually (\<lambda>x. (c::_::unbounded_dense_linorder) < x) at_top"
   774   unfolding eventually_at_top_dense by auto
   775 
   776 definition at_bot :: "('a::order) filter"
   777   where "at_bot = (INF k. principal {.. k})"
   778 
   779 lemma at_bot_sub: "at_bot = (INF k:{.. c::'a::linorder}. principal {.. k})"
   780   by (auto intro!: INF_eq min.cobounded1 min.cobounded2 simp: at_bot_def)
   781 
   782 lemma eventually_at_bot_linorder:
   783   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   784   unfolding at_bot_def
   785   by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   786 
   787 lemma eventually_le_at_bot:
   788   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   789   unfolding eventually_at_bot_linorder by auto
   790 
   791 lemma eventually_at_bot_dense: "eventually P at_bot \<longleftrightarrow> (\<exists>N::'a::{no_bot, linorder}. \<forall>n<N. P n)"
   792 proof -
   793   have "eventually P (INF k. principal {..< k}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n<N. P n)"
   794     by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   795   also have "(INF k. principal {..< k::'a}) = at_bot"
   796     unfolding at_bot_def 
   797     by (intro INF_eq) (auto intro: less_imp_le simp: Iic_subset_Iio_iff lt_ex)
   798   finally show ?thesis .
   799 qed
   800 
   801 lemma eventually_gt_at_bot:
   802   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
   803   unfolding eventually_at_bot_dense by auto
   804 
   805 lemma trivial_limit_at_bot_linorder: "\<not> trivial_limit (at_bot ::('a::linorder) filter)"
   806   unfolding trivial_limit_def
   807   by (metis eventually_at_bot_linorder order_refl)
   808 
   809 lemma trivial_limit_at_top_linorder: "\<not> trivial_limit (at_top ::('a::linorder) filter)"
   810   unfolding trivial_limit_def
   811   by (metis eventually_at_top_linorder order_refl)
   812 
   813 subsection {* Sequentially *}
   814 
   815 abbreviation sequentially :: "nat filter"
   816   where "sequentially \<equiv> at_top"
   817 
   818 lemma eventually_sequentially:
   819   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   820   by (rule eventually_at_top_linorder)
   821 
   822 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   823   unfolding filter_eq_iff eventually_sequentially by auto
   824 
   825 lemmas trivial_limit_sequentially = sequentially_bot
   826 
   827 lemma eventually_False_sequentially [simp]:
   828   "\<not> eventually (\<lambda>n. False) sequentially"
   829   by (simp add: eventually_False)
   830 
   831 lemma le_sequentially:
   832   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   833   by (simp add: at_top_def le_INF_iff le_principal)
   834 
   835 lemma eventually_sequentiallyI:
   836   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   837   shows "eventually P sequentially"
   838 using assms by (auto simp: eventually_sequentially)
   839 
   840 lemma eventually_sequentially_seg:
   841   "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   842   unfolding eventually_sequentially
   843   apply safe
   844    apply (rule_tac x="N + k" in exI)
   845    apply rule
   846    apply (erule_tac x="n - k" in allE)
   847    apply auto []
   848   apply (rule_tac x=N in exI)
   849   apply auto []
   850   done
   851 
   852 subsubsection {* Topological filters *}
   853 
   854 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   855   where "nhds a = (INF S:{S. open S \<and> a \<in> S}. principal S)"
   856 
   857 definition (in topological_space) at_within :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a filter" ("at (_) within (_)" [1000, 60] 60)
   858   where "at a within s = inf (nhds a) (principal (s - {a}))"
   859 
   860 abbreviation (in topological_space) at :: "'a \<Rightarrow> 'a filter" ("at") where
   861   "at x \<equiv> at x within (CONST UNIV)"
   862 
   863 abbreviation (in order_topology) at_right :: "'a \<Rightarrow> 'a filter" where
   864   "at_right x \<equiv> at x within {x <..}"
   865 
   866 abbreviation (in order_topology) at_left :: "'a \<Rightarrow> 'a filter" where
   867   "at_left x \<equiv> at x within {..< x}"
   868 
   869 lemma (in topological_space) nhds_generated_topology:
   870   "open = generate_topology T \<Longrightarrow> nhds x = (INF S:{S\<in>T. x \<in> S}. principal S)"
   871   unfolding nhds_def
   872 proof (safe intro!: antisym INF_greatest)
   873   fix S assume "generate_topology T S" "x \<in> S"
   874   then show "(INF S:{S \<in> T. x \<in> S}. principal S) \<le> principal S"
   875     by induction 
   876        (auto intro: INF_lower order_trans simp add: inf_principal[symmetric] simp del: inf_principal)
   877 qed (auto intro!: INF_lower intro: generate_topology.intros)
   878 
   879 lemma (in topological_space) eventually_nhds:
   880   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   881   unfolding nhds_def by (subst eventually_INF_base) (auto simp: eventually_principal)
   882 
   883 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   884   unfolding trivial_limit_def eventually_nhds by simp
   885 
   886 lemma at_within_eq: "at x within s = (INF S:{S. open S \<and> x \<in> S}. principal (S \<inter> s - {x}))"
   887   unfolding nhds_def at_within_def by (subst INF_inf_const2[symmetric]) (auto simp add: Diff_Int_distrib)
   888 
   889 lemma eventually_at_filter:
   890   "eventually P (at a within s) \<longleftrightarrow> eventually (\<lambda>x. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x) (nhds a)"
   891   unfolding at_within_def eventually_inf_principal by (simp add: imp_conjL[symmetric] conj_commute)
   892 
   893 lemma at_le: "s \<subseteq> t \<Longrightarrow> at x within s \<le> at x within t"
   894   unfolding at_within_def by (intro inf_mono) auto
   895 
   896 lemma eventually_at_topological:
   897   "eventually P (at a within s) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x))"
   898   unfolding eventually_nhds eventually_at_filter by simp
   899 
   900 lemma at_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> at a within S = at a"
   901   unfolding filter_eq_iff eventually_at_topological by (metis open_Int Int_iff UNIV_I)
   902 
   903 lemma at_within_empty [simp]: "at a within {} = bot"
   904   unfolding at_within_def by simp
   905 
   906 lemma at_within_union: "at x within (S \<union> T) = sup (at x within S) (at x within T)"
   907   unfolding filter_eq_iff eventually_sup eventually_at_filter
   908   by (auto elim!: eventually_rev_mp)
   909 
   910 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   911   unfolding trivial_limit_def eventually_at_topological
   912   by (safe, case_tac "S = {a}", simp, fast, fast)
   913 
   914 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   915   by (simp add: at_eq_bot_iff not_open_singleton)
   916 
   917 lemma (in order_topology) nhds_order: "nhds x =
   918   inf (INF a:{x <..}. principal {..< a}) (INF a:{..< x}. principal {a <..})"
   919 proof -
   920   have 1: "{S \<in> range lessThan \<union> range greaterThan. x \<in> S} = 
   921       (\<lambda>a. {..< a}) ` {x <..} \<union> (\<lambda>a. {a <..}) ` {..< x}"
   922     by auto
   923   show ?thesis
   924     unfolding nhds_generated_topology[OF open_generated_order] INF_union 1 INF_image comp_def ..
   925 qed
   926 
   927 lemma (in linorder_topology) at_within_order: "UNIV \<noteq> {x} \<Longrightarrow> 
   928   at x within s = inf (INF a:{x <..}. principal ({..< a} \<inter> s - {x}))
   929                       (INF a:{..< x}. principal ({a <..} \<inter> s - {x}))"
   930 proof (cases "{x <..} = {}" "{..< x} = {}" rule: case_split[case_product case_split])
   931   assume "UNIV \<noteq> {x}" "{x<..} = {}" "{..< x} = {}"
   932   moreover have "UNIV = {..< x} \<union> {x} \<union> {x <..}"
   933     by auto
   934   ultimately show ?thesis
   935     by auto
   936 qed (auto simp: at_within_def nhds_order Int_Diff inf_principal[symmetric] INF_inf_const2
   937                 inf_sup_aci[where 'a="'a filter"]
   938           simp del: inf_principal)
   939 
   940 lemma (in linorder_topology) at_left_eq:
   941   "y < x \<Longrightarrow> at_left x = (INF a:{..< x}. principal {a <..< x})"
   942   by (subst at_within_order)
   943      (auto simp: greaterThan_Int_greaterThan greaterThanLessThan_eq[symmetric] min.absorb2 INF_constant
   944            intro!: INF_lower2 inf_absorb2)
   945 
   946 lemma (in linorder_topology) eventually_at_left:
   947   "y < x \<Longrightarrow> eventually P (at_left x) \<longleftrightarrow> (\<exists>b<x. \<forall>y>b. y < x \<longrightarrow> P y)"
   948   unfolding at_left_eq by (subst eventually_INF_base) (auto simp: eventually_principal Ball_def)
   949 
   950 lemma (in linorder_topology) at_right_eq:
   951   "x < y \<Longrightarrow> at_right x = (INF a:{x <..}. principal {x <..< a})"
   952   by (subst at_within_order)
   953      (auto simp: lessThan_Int_lessThan greaterThanLessThan_eq[symmetric] max.absorb2 INF_constant Int_commute
   954            intro!: INF_lower2 inf_absorb1)
   955 
   956 lemma (in linorder_topology) eventually_at_right:
   957   "x < y \<Longrightarrow> eventually P (at_right x) \<longleftrightarrow> (\<exists>b>x. \<forall>y>x. y < b \<longrightarrow> P y)"
   958   unfolding at_right_eq by (subst eventually_INF_base) (auto simp: eventually_principal Ball_def)
   959 
   960 lemma trivial_limit_at_right_top: "at_right (top::_::{order_top, linorder_topology}) = bot"
   961   unfolding filter_eq_iff eventually_at_topological by auto
   962 
   963 lemma trivial_limit_at_left_bot: "at_left (bot::_::{order_bot, linorder_topology}) = bot"
   964   unfolding filter_eq_iff eventually_at_topological by auto
   965 
   966 lemma trivial_limit_at_left_real [simp]:
   967   "\<not> trivial_limit (at_left (x::'a::{no_bot, dense_order, linorder_topology}))"
   968   using lt_ex[of x]
   969   by safe (auto simp add: trivial_limit_def eventually_at_left dest: dense)
   970 
   971 lemma trivial_limit_at_right_real [simp]:
   972   "\<not> trivial_limit (at_right (x::'a::{no_top, dense_order, linorder_topology}))"
   973   using gt_ex[of x]
   974   by safe (auto simp add: trivial_limit_def eventually_at_right dest: dense)
   975 
   976 lemma at_eq_sup_left_right: "at (x::'a::linorder_topology) = sup (at_left x) (at_right x)"
   977   by (auto simp: eventually_at_filter filter_eq_iff eventually_sup 
   978            elim: eventually_elim2 eventually_elim1)
   979 
   980 lemma eventually_at_split:
   981   "eventually P (at (x::'a::linorder_topology)) \<longleftrightarrow> eventually P (at_left x) \<and> eventually P (at_right x)"
   982   by (subst at_eq_sup_left_right) (simp add: eventually_sup)
   983 
   984 subsection {* Limits *}
   985 
   986 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   987   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   988 
   989 syntax
   990   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   991 
   992 translations
   993   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   994 
   995 lemma filterlim_iff:
   996   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   997   unfolding filterlim_def le_filter_def eventually_filtermap ..
   998 
   999 lemma filterlim_compose:
  1000   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
  1001   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
  1002 
  1003 lemma filterlim_mono:
  1004   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
  1005   unfolding filterlim_def by (metis filtermap_mono order_trans)
  1006 
  1007 lemma filterlim_ident: "LIM x F. x :> F"
  1008   by (simp add: filterlim_def filtermap_ident)
  1009 
  1010 lemma filterlim_cong:
  1011   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
  1012   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
  1013 
  1014 lemma filterlim_mono_eventually:
  1015   assumes "filterlim f F G" and ord: "F \<le> F'" "G' \<le> G"
  1016   assumes eq: "eventually (\<lambda>x. f x = f' x) G'"
  1017   shows "filterlim f' F' G'"
  1018   apply (rule filterlim_cong[OF refl refl eq, THEN iffD1])
  1019   apply (rule filterlim_mono[OF _ ord])
  1020   apply fact
  1021   done
  1022 
  1023 lemma filtermap_mono_strong: "inj f \<Longrightarrow> filtermap f F \<le> filtermap f G \<longleftrightarrow> F \<le> G"
  1024   apply (auto intro!: filtermap_mono) []
  1025   apply (auto simp: le_filter_def eventually_filtermap)
  1026   apply (erule_tac x="\<lambda>x. P (inv f x)" in allE)
  1027   apply auto
  1028   done
  1029 
  1030 lemma filtermap_eq_strong: "inj f \<Longrightarrow> filtermap f F = filtermap f G \<longleftrightarrow> F = G"
  1031   by (simp add: filtermap_mono_strong eq_iff)
  1032 
  1033 lemma filterlim_principal:
  1034   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
  1035   unfolding filterlim_def eventually_filtermap le_principal ..
  1036 
  1037 lemma filterlim_inf:
  1038   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
  1039   unfolding filterlim_def by simp
  1040 
  1041 lemma filterlim_INF:
  1042   "(LIM x F. f x :> (INF b:B. G b)) \<longleftrightarrow> (\<forall>b\<in>B. LIM x F. f x :> G b)"
  1043   unfolding filterlim_def le_INF_iff ..
  1044 
  1045 lemma filterlim_INF_INF:
  1046   "(\<And>m. m \<in> J \<Longrightarrow> \<exists>i\<in>I. filtermap f (F i) \<le> G m) \<Longrightarrow> LIM x (INF i:I. F i). f x :> (INF j:J. G j)"
  1047   unfolding filterlim_def by (rule order_trans[OF filtermap_INF INF_mono])
  1048 
  1049 lemma filterlim_base:
  1050   "(\<And>m x. m \<in> J \<Longrightarrow> i m \<in> I) \<Longrightarrow> (\<And>m x. m \<in> J \<Longrightarrow> x \<in> F (i m) \<Longrightarrow> f x \<in> G m) \<Longrightarrow> 
  1051     LIM x (INF i:I. principal (F i)). f x :> (INF j:J. principal (G j))"
  1052   by (force intro!: filterlim_INF_INF simp: image_subset_iff)
  1053 
  1054 lemma filterlim_base_iff: 
  1055   assumes "I \<noteq> {}" and chain: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> F i \<subseteq> F j \<or> F j \<subseteq> F i"
  1056   shows "(LIM x (INF i:I. principal (F i)). f x :> INF j:J. principal (G j)) \<longleftrightarrow>
  1057     (\<forall>j\<in>J. \<exists>i\<in>I. \<forall>x\<in>F i. f x \<in> G j)"
  1058   unfolding filterlim_INF filterlim_principal
  1059 proof (subst eventually_INF_base)
  1060   fix i j assume "i \<in> I" "j \<in> I"
  1061   with chain[OF this] show "\<exists>x\<in>I. principal (F x) \<le> inf (principal (F i)) (principal (F j))"
  1062     by auto
  1063 qed (auto simp: eventually_principal `I \<noteq> {}`)
  1064 
  1065 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
  1066   unfolding filterlim_def filtermap_filtermap ..
  1067 
  1068 lemma filterlim_sup:
  1069   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
  1070   unfolding filterlim_def filtermap_sup by auto
  1071 
  1072 lemma eventually_sequentially_Suc: "eventually (\<lambda>i. P (Suc i)) sequentially \<longleftrightarrow> eventually P sequentially"
  1073   unfolding eventually_sequentially by (metis Suc_le_D Suc_le_mono le_Suc_eq)
  1074 
  1075 lemma filterlim_sequentially_Suc:
  1076   "(LIM x sequentially. f (Suc x) :> F) \<longleftrightarrow> (LIM x sequentially. f x :> F)"
  1077   unfolding filterlim_iff by (subst eventually_sequentially_Suc) simp
  1078 
  1079 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
  1080   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
  1081 
  1082 subsubsection {* Tendsto *}
  1083 
  1084 abbreviation (in topological_space)
  1085   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
  1086   "(f ---> l) F \<equiv> filterlim f (nhds l) F"
  1087 
  1088 definition (in t2_space) Lim :: "'f filter \<Rightarrow> ('f \<Rightarrow> 'a) \<Rightarrow> 'a" where
  1089   "Lim A f = (THE l. (f ---> l) A)"
  1090 
  1091 lemma tendsto_eq_rhs: "(f ---> x) F \<Longrightarrow> x = y \<Longrightarrow> (f ---> y) F"
  1092   by simp
  1093 
  1094 named_theorems tendsto_intros "introduction rules for tendsto"
  1095 setup {*
  1096   Global_Theory.add_thms_dynamic (@{binding tendsto_eq_intros},
  1097     fn context =>
  1098       Named_Theorems.get (Context.proof_of context) @{named_theorems tendsto_intros}
  1099       |> map_filter (try (fn thm => @{thm tendsto_eq_rhs} OF [thm])))
  1100 *}
  1101 
  1102 lemma (in topological_space) tendsto_def:
  1103    "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
  1104    unfolding nhds_def filterlim_INF filterlim_principal by auto
  1105 
  1106 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
  1107   unfolding tendsto_def le_filter_def by fast
  1108 
  1109 lemma tendsto_within_subset: "(f ---> l) (at x within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f ---> l) (at x within T)"
  1110   by (blast intro: tendsto_mono at_le)
  1111 
  1112 lemma filterlim_at:
  1113   "(LIM x F. f x :> at b within s) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> s \<and> f x \<noteq> b) F \<and> (f ---> b) F)"
  1114   by (simp add: at_within_def filterlim_inf filterlim_principal conj_commute)
  1115 
  1116 lemma (in topological_space) topological_tendstoI:
  1117   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F) \<Longrightarrow> (f ---> l) F"
  1118   unfolding tendsto_def by auto
  1119 
  1120 lemma (in topological_space) topological_tendstoD:
  1121   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
  1122   unfolding tendsto_def by auto
  1123 
  1124 lemma (in order_topology) order_tendsto_iff:
  1125   "(f ---> x) F \<longleftrightarrow> (\<forall>l<x. eventually (\<lambda>x. l < f x) F) \<and> (\<forall>u>x. eventually (\<lambda>x. f x < u) F)"
  1126   unfolding nhds_order filterlim_inf filterlim_INF filterlim_principal by auto
  1127 
  1128 lemma (in order_topology) order_tendstoI:
  1129   "(\<And>a. a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F) \<Longrightarrow> (\<And>a. y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F) \<Longrightarrow>
  1130     (f ---> y) F"
  1131   unfolding order_tendsto_iff by auto
  1132 
  1133 lemma (in order_topology) order_tendstoD:
  1134   assumes "(f ---> y) F"
  1135   shows "a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
  1136     and "y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
  1137   using assms unfolding order_tendsto_iff by auto
  1138 
  1139 lemma tendsto_bot [simp]: "(f ---> a) bot"
  1140   unfolding tendsto_def by simp
  1141 
  1142 lemma (in linorder_topology) tendsto_max:
  1143   assumes X: "(X ---> x) net"
  1144   assumes Y: "(Y ---> y) net"
  1145   shows "((\<lambda>x. max (X x) (Y x)) ---> max x y) net"
  1146 proof (rule order_tendstoI)
  1147   fix a assume "a < max x y"
  1148   then show "eventually (\<lambda>x. a < max (X x) (Y x)) net"
  1149     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
  1150     by (auto simp: less_max_iff_disj elim: eventually_elim1)
  1151 next
  1152   fix a assume "max x y < a"
  1153   then show "eventually (\<lambda>x. max (X x) (Y x) < a) net"
  1154     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
  1155     by (auto simp: eventually_conj_iff)
  1156 qed
  1157 
  1158 lemma (in linorder_topology) tendsto_min:
  1159   assumes X: "(X ---> x) net"
  1160   assumes Y: "(Y ---> y) net"
  1161   shows "((\<lambda>x. min (X x) (Y x)) ---> min x y) net"
  1162 proof (rule order_tendstoI)
  1163   fix a assume "a < min x y"
  1164   then show "eventually (\<lambda>x. a < min (X x) (Y x)) net"
  1165     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
  1166     by (auto simp: eventually_conj_iff)
  1167 next
  1168   fix a assume "min x y < a"
  1169   then show "eventually (\<lambda>x. min (X x) (Y x) < a) net"
  1170     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
  1171     by (auto simp: min_less_iff_disj elim: eventually_elim1)
  1172 qed
  1173 
  1174 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a within s)"
  1175   unfolding tendsto_def eventually_at_topological by auto
  1176 
  1177 lemma (in topological_space) tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) F"
  1178   by (simp add: tendsto_def)
  1179 
  1180 lemma (in t2_space) tendsto_unique:
  1181   assumes "F \<noteq> bot" and "(f ---> a) F" and "(f ---> b) F"
  1182   shows "a = b"
  1183 proof (rule ccontr)
  1184   assume "a \<noteq> b"
  1185   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
  1186     using hausdorff [OF `a \<noteq> b`] by fast
  1187   have "eventually (\<lambda>x. f x \<in> U) F"
  1188     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
  1189   moreover
  1190   have "eventually (\<lambda>x. f x \<in> V) F"
  1191     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
  1192   ultimately
  1193   have "eventually (\<lambda>x. False) F"
  1194   proof eventually_elim
  1195     case (elim x)
  1196     hence "f x \<in> U \<inter> V" by simp
  1197     with `U \<inter> V = {}` show ?case by simp
  1198   qed
  1199   with `\<not> trivial_limit F` show "False"
  1200     by (simp add: trivial_limit_def)
  1201 qed
  1202 
  1203 lemma (in t2_space) tendsto_const_iff:
  1204   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a :: 'a) ---> b) F \<longleftrightarrow> a = b"
  1205   by (safe intro!: tendsto_const tendsto_unique [OF assms tendsto_const])
  1206 
  1207 lemma increasing_tendsto:
  1208   fixes f :: "_ \<Rightarrow> 'a::order_topology"
  1209   assumes bdd: "eventually (\<lambda>n. f n \<le> l) F"
  1210       and en: "\<And>x. x < l \<Longrightarrow> eventually (\<lambda>n. x < f n) F"
  1211   shows "(f ---> l) F"
  1212   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
  1213 
  1214 lemma decreasing_tendsto:
  1215   fixes f :: "_ \<Rightarrow> 'a::order_topology"
  1216   assumes bdd: "eventually (\<lambda>n. l \<le> f n) F"
  1217       and en: "\<And>x. l < x \<Longrightarrow> eventually (\<lambda>n. f n < x) F"
  1218   shows "(f ---> l) F"
  1219   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
  1220 
  1221 lemma tendsto_sandwich:
  1222   fixes f g h :: "'a \<Rightarrow> 'b::order_topology"
  1223   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
  1224   assumes lim: "(f ---> c) net" "(h ---> c) net"
  1225   shows "(g ---> c) net"
  1226 proof (rule order_tendstoI)
  1227   fix a show "a < c \<Longrightarrow> eventually (\<lambda>x. a < g x) net"
  1228     using order_tendstoD[OF lim(1), of a] ev by (auto elim: eventually_elim2)
  1229 next
  1230   fix a show "c < a \<Longrightarrow> eventually (\<lambda>x. g x < a) net"
  1231     using order_tendstoD[OF lim(2), of a] ev by (auto elim: eventually_elim2)
  1232 qed
  1233 
  1234 lemma tendsto_le:
  1235   fixes f g :: "'a \<Rightarrow> 'b::linorder_topology"
  1236   assumes F: "\<not> trivial_limit F"
  1237   assumes x: "(f ---> x) F" and y: "(g ---> y) F"
  1238   assumes ev: "eventually (\<lambda>x. g x \<le> f x) F"
  1239   shows "y \<le> x"
  1240 proof (rule ccontr)
  1241   assume "\<not> y \<le> x"
  1242   with less_separate[of x y] obtain a b where xy: "x < a" "b < y" "{..<a} \<inter> {b<..} = {}"
  1243     by (auto simp: not_le)
  1244   then have "eventually (\<lambda>x. f x < a) F" "eventually (\<lambda>x. b < g x) F"
  1245     using x y by (auto intro: order_tendstoD)
  1246   with ev have "eventually (\<lambda>x. False) F"
  1247     by eventually_elim (insert xy, fastforce)
  1248   with F show False
  1249     by (simp add: eventually_False)
  1250 qed
  1251 
  1252 lemma tendsto_le_const:
  1253   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
  1254   assumes F: "\<not> trivial_limit F"
  1255   assumes x: "(f ---> x) F" and a: "eventually (\<lambda>i. a \<le> f i) F"
  1256   shows "a \<le> x"
  1257   using F x tendsto_const a by (rule tendsto_le)
  1258 
  1259 lemma tendsto_ge_const:
  1260   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
  1261   assumes F: "\<not> trivial_limit F"
  1262   assumes x: "(f ---> x) F" and a: "eventually (\<lambda>i. a \<ge> f i) F"
  1263   shows "a \<ge> x"
  1264   by (rule tendsto_le [OF F tendsto_const x a])
  1265 
  1266 subsubsection {* Rules about @{const Lim} *}
  1267 
  1268 lemma tendsto_Lim:
  1269   "\<not>(trivial_limit net) \<Longrightarrow> (f ---> l) net \<Longrightarrow> Lim net f = l"
  1270   unfolding Lim_def using tendsto_unique[of net f] by auto
  1271 
  1272 lemma Lim_ident_at: "\<not> trivial_limit (at x within s) \<Longrightarrow> Lim (at x within s) (\<lambda>x. x) = x"
  1273   by (rule tendsto_Lim[OF _ tendsto_ident_at]) auto
  1274 
  1275 subsection {* Limits to @{const at_top} and @{const at_bot} *}
  1276 
  1277 lemma filterlim_at_top:
  1278   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1279   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
  1280   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_elim1)
  1281 
  1282 lemma filterlim_at_top_mono:
  1283   "LIM x F. f x :> at_top \<Longrightarrow> eventually (\<lambda>x. f x \<le> (g x::'a::linorder)) F \<Longrightarrow>
  1284     LIM x F. g x :> at_top"
  1285   by (auto simp: filterlim_at_top elim: eventually_elim2 intro: order_trans)
  1286 
  1287 lemma filterlim_at_top_dense:
  1288   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
  1289   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
  1290   by (metis eventually_elim1[of _ F] eventually_gt_at_top order_less_imp_le
  1291             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
  1292 
  1293 lemma filterlim_at_top_ge:
  1294   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1295   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1296   unfolding at_top_sub[of c] filterlim_INF by (auto simp add: filterlim_principal)
  1297 
  1298 lemma filterlim_at_top_at_top:
  1299   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
  1300   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1301   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1302   assumes Q: "eventually Q at_top"
  1303   assumes P: "eventually P at_top"
  1304   shows "filterlim f at_top at_top"
  1305 proof -
  1306   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1307     unfolding eventually_at_top_linorder by auto
  1308   show ?thesis
  1309   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1310     fix z assume "x \<le> z"
  1311     with x have "P z" by auto
  1312     have "eventually (\<lambda>x. g z \<le> x) at_top"
  1313       by (rule eventually_ge_at_top)
  1314     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
  1315       by eventually_elim (metis mono bij `P z`)
  1316   qed
  1317 qed
  1318 
  1319 lemma filterlim_at_top_gt:
  1320   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1321   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1322   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
  1323 
  1324 lemma filterlim_at_bot: 
  1325   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1326   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
  1327   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_elim1)
  1328 
  1329 lemma filterlim_at_bot_dense:
  1330   fixes f :: "'a \<Rightarrow> ('b::{dense_linorder, no_bot})"
  1331   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x < Z) F)"
  1332 proof (auto simp add: filterlim_at_bot[of f F])
  1333   fix Z :: 'b
  1334   from lt_ex [of Z] obtain Z' where 1: "Z' < Z" ..
  1335   assume "\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F"
  1336   hence "eventually (\<lambda>x. f x \<le> Z') F" by auto
  1337   thus "eventually (\<lambda>x. f x < Z) F"
  1338     apply (rule eventually_mono[rotated])
  1339     using 1 by auto
  1340   next 
  1341     fix Z :: 'b 
  1342     show "\<forall>Z. eventually (\<lambda>x. f x < Z) F \<Longrightarrow> eventually (\<lambda>x. f x \<le> Z) F"
  1343       by (drule spec [of _ Z], erule eventually_mono[rotated], auto simp add: less_imp_le)
  1344 qed
  1345 
  1346 lemma filterlim_at_bot_le:
  1347   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1348   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1349   unfolding filterlim_at_bot
  1350 proof safe
  1351   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
  1352   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
  1353     by (auto elim!: eventually_elim1)
  1354 qed simp
  1355 
  1356 lemma filterlim_at_bot_lt:
  1357   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1358   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1359   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
  1360 
  1361 lemma filterlim_at_bot_at_right:
  1362   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
  1363   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1364   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1365   assumes Q: "eventually Q (at_right a)" and bound: "\<And>b. Q b \<Longrightarrow> a < b"
  1366   assumes P: "eventually P at_bot"
  1367   shows "filterlim f at_bot (at_right a)"
  1368 proof -
  1369   from P obtain x where x: "\<And>y. y \<le> x \<Longrightarrow> P y"
  1370     unfolding eventually_at_bot_linorder by auto
  1371   show ?thesis
  1372   proof (intro filterlim_at_bot_le[THEN iffD2] allI impI)
  1373     fix z assume "z \<le> x"
  1374     with x have "P z" by auto
  1375     have "eventually (\<lambda>x. x \<le> g z) (at_right a)"
  1376       using bound[OF bij(2)[OF `P z`]]
  1377       unfolding eventually_at_right[OF bound[OF bij(2)[OF `P z`]]] by (auto intro!: exI[of _ "g z"])
  1378     with Q show "eventually (\<lambda>x. f x \<le> z) (at_right a)"
  1379       by eventually_elim (metis bij `P z` mono)
  1380   qed
  1381 qed
  1382 
  1383 lemma filterlim_at_top_at_left:
  1384   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
  1385   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1386   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1387   assumes Q: "eventually Q (at_left a)" and bound: "\<And>b. Q b \<Longrightarrow> b < a"
  1388   assumes P: "eventually P at_top"
  1389   shows "filterlim f at_top (at_left a)"
  1390 proof -
  1391   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1392     unfolding eventually_at_top_linorder by auto
  1393   show ?thesis
  1394   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1395     fix z assume "x \<le> z"
  1396     with x have "P z" by auto
  1397     have "eventually (\<lambda>x. g z \<le> x) (at_left a)"
  1398       using bound[OF bij(2)[OF `P z`]]
  1399       unfolding eventually_at_left[OF bound[OF bij(2)[OF `P z`]]] by (auto intro!: exI[of _ "g z"])
  1400     with Q show "eventually (\<lambda>x. z \<le> f x) (at_left a)"
  1401       by eventually_elim (metis bij `P z` mono)
  1402   qed
  1403 qed
  1404 
  1405 lemma filterlim_split_at:
  1406   "filterlim f F (at_left x) \<Longrightarrow> filterlim f F (at_right x) \<Longrightarrow> filterlim f F (at (x::'a::linorder_topology))"
  1407   by (subst at_eq_sup_left_right) (rule filterlim_sup)
  1408 
  1409 lemma filterlim_at_split:
  1410   "filterlim f F (at (x::'a::linorder_topology)) \<longleftrightarrow> filterlim f F (at_left x) \<and> filterlim f F (at_right x)"
  1411   by (subst at_eq_sup_left_right) (simp add: filterlim_def filtermap_sup)
  1412 
  1413 lemma eventually_nhds_top:
  1414   fixes P :: "'a :: {order_top, linorder_topology} \<Rightarrow> bool"
  1415   assumes "(b::'a) < top"
  1416   shows "eventually P (nhds top) \<longleftrightarrow> (\<exists>b<top. (\<forall>z. b < z \<longrightarrow> P z))"
  1417   unfolding eventually_nhds
  1418 proof safe
  1419   fix S :: "'a set" assume "open S" "top \<in> S"
  1420   note open_left[OF this `b < top`]
  1421   moreover assume "\<forall>s\<in>S. P s"
  1422   ultimately show "\<exists>b<top. \<forall>z>b. P z"
  1423     by (auto simp: subset_eq Ball_def)
  1424 next
  1425   fix b assume "b < top" "\<forall>z>b. P z"
  1426   then show "\<exists>S. open S \<and> top \<in> S \<and> (\<forall>xa\<in>S. P xa)"
  1427     by (intro exI[of _ "{b <..}"]) auto
  1428 qed
  1429 
  1430 lemma tendsto_at_within_iff_tendsto_nhds:
  1431   "(g ---> g l) (at l within S) \<longleftrightarrow> (g ---> g l) (inf (nhds l) (principal S))"
  1432   unfolding tendsto_def eventually_at_filter eventually_inf_principal
  1433   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
  1434 
  1435 subsection {* Limits on sequences *}
  1436 
  1437 abbreviation (in topological_space)
  1438   LIMSEQ :: "[nat \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
  1439     ("((_)/ ----> (_))" [60, 60] 60) where
  1440   "X ----> L \<equiv> (X ---> L) sequentially"
  1441 
  1442 abbreviation (in t2_space) lim :: "(nat \<Rightarrow> 'a) \<Rightarrow> 'a" where
  1443   "lim X \<equiv> Lim sequentially X"
  1444 
  1445 definition (in topological_space) convergent :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1446   "convergent X = (\<exists>L. X ----> L)"
  1447 
  1448 lemma lim_def: "lim X = (THE L. X ----> L)"
  1449   unfolding Lim_def ..
  1450 
  1451 subsubsection {* Monotone sequences and subsequences *}
  1452 
  1453 definition
  1454   monoseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1455     --{*Definition of monotonicity.
  1456         The use of disjunction here complicates proofs considerably.
  1457         One alternative is to add a Boolean argument to indicate the direction.
  1458         Another is to develop the notions of increasing and decreasing first.*}
  1459   "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) \<or> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
  1460 
  1461 abbreviation incseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1462   "incseq X \<equiv> mono X"
  1463 
  1464 lemma incseq_def: "incseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<ge> X m)"
  1465   unfolding mono_def ..
  1466 
  1467 abbreviation decseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1468   "decseq X \<equiv> antimono X"
  1469 
  1470 lemma decseq_def: "decseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
  1471   unfolding antimono_def ..
  1472 
  1473 definition
  1474   subseq :: "(nat \<Rightarrow> nat) \<Rightarrow> bool" where
  1475     --{*Definition of subsequence*}
  1476   "subseq f \<longleftrightarrow> (\<forall>m. \<forall>n>m. f m < f n)"
  1477 
  1478 lemma incseq_SucI:
  1479   "(\<And>n. X n \<le> X (Suc n)) \<Longrightarrow> incseq X"
  1480   using lift_Suc_mono_le[of X]
  1481   by (auto simp: incseq_def)
  1482 
  1483 lemma incseqD: "\<And>i j. incseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f i \<le> f j"
  1484   by (auto simp: incseq_def)
  1485 
  1486 lemma incseq_SucD: "incseq A \<Longrightarrow> A i \<le> A (Suc i)"
  1487   using incseqD[of A i "Suc i"] by auto
  1488 
  1489 lemma incseq_Suc_iff: "incseq f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1490   by (auto intro: incseq_SucI dest: incseq_SucD)
  1491 
  1492 lemma incseq_const[simp, intro]: "incseq (\<lambda>x. k)"
  1493   unfolding incseq_def by auto
  1494 
  1495 lemma decseq_SucI:
  1496   "(\<And>n. X (Suc n) \<le> X n) \<Longrightarrow> decseq X"
  1497   using order.lift_Suc_mono_le[OF dual_order, of X]
  1498   by (auto simp: decseq_def)
  1499 
  1500 lemma decseqD: "\<And>i j. decseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f j \<le> f i"
  1501   by (auto simp: decseq_def)
  1502 
  1503 lemma decseq_SucD: "decseq A \<Longrightarrow> A (Suc i) \<le> A i"
  1504   using decseqD[of A i "Suc i"] by auto
  1505 
  1506 lemma decseq_Suc_iff: "decseq f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1507   by (auto intro: decseq_SucI dest: decseq_SucD)
  1508 
  1509 lemma decseq_const[simp, intro]: "decseq (\<lambda>x. k)"
  1510   unfolding decseq_def by auto
  1511 
  1512 lemma monoseq_iff: "monoseq X \<longleftrightarrow> incseq X \<or> decseq X"
  1513   unfolding monoseq_def incseq_def decseq_def ..
  1514 
  1515 lemma monoseq_Suc:
  1516   "monoseq X \<longleftrightarrow> (\<forall>n. X n \<le> X (Suc n)) \<or> (\<forall>n. X (Suc n) \<le> X n)"
  1517   unfolding monoseq_iff incseq_Suc_iff decseq_Suc_iff ..
  1518 
  1519 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
  1520 by (simp add: monoseq_def)
  1521 
  1522 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
  1523 by (simp add: monoseq_def)
  1524 
  1525 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
  1526 by (simp add: monoseq_Suc)
  1527 
  1528 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
  1529 by (simp add: monoseq_Suc)
  1530 
  1531 lemma monoseq_minus:
  1532   fixes a :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
  1533   assumes "monoseq a"
  1534   shows "monoseq (\<lambda> n. - a n)"
  1535 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
  1536   case True
  1537   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
  1538   thus ?thesis by (rule monoI2)
  1539 next
  1540   case False
  1541   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
  1542   thus ?thesis by (rule monoI1)
  1543 qed
  1544 
  1545 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
  1546 
  1547 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
  1548 apply (simp add: subseq_def)
  1549 apply (auto dest!: less_imp_Suc_add)
  1550 apply (induct_tac k)
  1551 apply (auto intro: less_trans)
  1552 done
  1553 
  1554 text{* for any sequence, there is a monotonic subsequence *}
  1555 lemma seq_monosub:
  1556   fixes s :: "nat => 'a::linorder"
  1557   shows "\<exists>f. subseq f \<and> monoseq (\<lambda>n. (s (f n)))"
  1558 proof cases
  1559   assume "\<forall>n. \<exists>p>n. \<forall>m\<ge>p. s m \<le> s p"
  1560   then have "\<exists>f. \<forall>n. (\<forall>m\<ge>f n. s m \<le> s (f n)) \<and> f n < f (Suc n)"
  1561     by (intro dependent_nat_choice) (auto simp: conj_commute)
  1562   then obtain f where "subseq f" and mono: "\<And>n m. f n \<le> m \<Longrightarrow> s m \<le> s (f n)"
  1563     by (auto simp: subseq_Suc_iff)
  1564   moreover 
  1565   then have "incseq f"
  1566     unfolding subseq_Suc_iff incseq_Suc_iff by (auto intro: less_imp_le)
  1567   then have "monoseq (\<lambda>n. s (f n))"
  1568     by (auto simp add: incseq_def intro!: mono monoI2)
  1569   ultimately show ?thesis
  1570     by auto
  1571 next
  1572   assume "\<not> (\<forall>n. \<exists>p>n. (\<forall>m\<ge>p. s m \<le> s p))"
  1573   then obtain N where N: "\<And>p. p > N \<Longrightarrow> \<exists>m>p. s p < s m" by (force simp: not_le le_less)
  1574   have "\<exists>f. \<forall>n. N < f n \<and> f n < f (Suc n) \<and> s (f n) \<le> s (f (Suc n))"
  1575   proof (intro dependent_nat_choice)
  1576     fix x assume "N < x" with N[of x] show "\<exists>y>N. x < y \<and> s x \<le> s y"
  1577       by (auto intro: less_trans)
  1578   qed auto
  1579   then show ?thesis
  1580     by (auto simp: monoseq_iff incseq_Suc_iff subseq_Suc_iff)
  1581 qed
  1582 
  1583 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
  1584 proof(induct n)
  1585   case 0 thus ?case by simp
  1586 next
  1587   case (Suc n)
  1588   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
  1589   have "n < f (Suc n)" by arith
  1590   thus ?case by arith
  1591 qed
  1592 
  1593 lemma eventually_subseq:
  1594   "subseq r \<Longrightarrow> eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  1595   unfolding eventually_sequentially by (metis seq_suble le_trans)
  1596 
  1597 lemma not_eventually_sequentiallyD:
  1598   assumes P: "\<not> eventually P sequentially"
  1599   shows "\<exists>r. subseq r \<and> (\<forall>n. \<not> P (r n))"
  1600 proof -
  1601   from P have "\<forall>n. \<exists>m\<ge>n. \<not> P m"
  1602     unfolding eventually_sequentially by (simp add: not_less)
  1603   then obtain r where "\<And>n. r n \<ge> n" "\<And>n. \<not> P (r n)"
  1604     by (auto simp: choice_iff)
  1605   then show ?thesis
  1606     by (auto intro!: exI[of _ "\<lambda>n. r (((Suc \<circ> r) ^^ Suc n) 0)"]
  1607              simp: less_eq_Suc_le subseq_Suc_iff)
  1608 qed
  1609 
  1610 lemma filterlim_subseq: "subseq f \<Longrightarrow> filterlim f sequentially sequentially"
  1611   unfolding filterlim_iff by (metis eventually_subseq)
  1612 
  1613 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  1614   unfolding subseq_def by simp
  1615 
  1616 lemma subseq_mono: assumes "subseq r" "m < n" shows "r m < r n"
  1617   using assms by (auto simp: subseq_def)
  1618 
  1619 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
  1620   by (simp add: incseq_def monoseq_def)
  1621 
  1622 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
  1623   by (simp add: decseq_def monoseq_def)
  1624 
  1625 lemma decseq_eq_incseq:
  1626   fixes X :: "nat \<Rightarrow> 'a::ordered_ab_group_add" shows "decseq X = incseq (\<lambda>n. - X n)" 
  1627   by (simp add: decseq_def incseq_def)
  1628 
  1629 lemma INT_decseq_offset:
  1630   assumes "decseq F"
  1631   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
  1632 proof safe
  1633   fix x i assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
  1634   show "x \<in> F i"
  1635   proof cases
  1636     from x have "x \<in> F n" by auto
  1637     also assume "i \<le> n" with `decseq F` have "F n \<subseteq> F i"
  1638       unfolding decseq_def by simp
  1639     finally show ?thesis .
  1640   qed (insert x, simp)
  1641 qed auto
  1642 
  1643 lemma LIMSEQ_const_iff:
  1644   fixes k l :: "'a::t2_space"
  1645   shows "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
  1646   using trivial_limit_sequentially by (rule tendsto_const_iff)
  1647 
  1648 lemma LIMSEQ_SUP:
  1649   "incseq X \<Longrightarrow> X ----> (SUP i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1650   by (intro increasing_tendsto)
  1651      (auto simp: SUP_upper less_SUP_iff incseq_def eventually_sequentially intro: less_le_trans)
  1652 
  1653 lemma LIMSEQ_INF:
  1654   "decseq X \<Longrightarrow> X ----> (INF i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1655   by (intro decreasing_tendsto)
  1656      (auto simp: INF_lower INF_less_iff decseq_def eventually_sequentially intro: le_less_trans)
  1657 
  1658 lemma LIMSEQ_ignore_initial_segment:
  1659   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
  1660   unfolding tendsto_def
  1661   by (subst eventually_sequentially_seg[where k=k])
  1662 
  1663 lemma LIMSEQ_offset:
  1664   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
  1665   unfolding tendsto_def
  1666   by (subst (asm) eventually_sequentially_seg[where k=k])
  1667 
  1668 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
  1669 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
  1670 
  1671 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
  1672 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
  1673 
  1674 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
  1675 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
  1676 
  1677 lemma LIMSEQ_unique:
  1678   fixes a b :: "'a::t2_space"
  1679   shows "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
  1680   using trivial_limit_sequentially by (rule tendsto_unique)
  1681 
  1682 lemma LIMSEQ_le_const:
  1683   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
  1684   using tendsto_le_const[of sequentially X x a] by (simp add: eventually_sequentially)
  1685 
  1686 lemma LIMSEQ_le:
  1687   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::'a::linorder_topology)"
  1688   using tendsto_le[of sequentially Y y X x] by (simp add: eventually_sequentially)
  1689 
  1690 lemma LIMSEQ_le_const2:
  1691   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
  1692   by (rule LIMSEQ_le[of X x "\<lambda>n. a"]) (auto simp: tendsto_const)
  1693 
  1694 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
  1695 by (simp add: convergent_def)
  1696 
  1697 lemma convergentI: "(X ----> L) ==> convergent X"
  1698 by (auto simp add: convergent_def)
  1699 
  1700 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
  1701 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
  1702 
  1703 lemma convergent_const: "convergent (\<lambda>n. c)"
  1704   by (rule convergentI, rule tendsto_const)
  1705 
  1706 lemma monoseq_le:
  1707   "monoseq a \<Longrightarrow> a ----> (x::'a::linorder_topology) \<Longrightarrow>
  1708     ((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
  1709   by (metis LIMSEQ_le_const LIMSEQ_le_const2 decseq_def incseq_def monoseq_iff)
  1710 
  1711 lemma LIMSEQ_subseq_LIMSEQ:
  1712   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
  1713   unfolding comp_def by (rule filterlim_compose[of X, OF _ filterlim_subseq])
  1714 
  1715 lemma convergent_subseq_convergent:
  1716   "\<lbrakk>convergent X; subseq f\<rbrakk> \<Longrightarrow> convergent (X o f)"
  1717   unfolding convergent_def by (auto intro: LIMSEQ_subseq_LIMSEQ)
  1718 
  1719 lemma limI: "X ----> L ==> lim X = L"
  1720   by (rule tendsto_Lim) (rule trivial_limit_sequentially)
  1721 
  1722 lemma lim_le: "convergent f \<Longrightarrow> (\<And>n. f n \<le> (x::'a::linorder_topology)) \<Longrightarrow> lim f \<le> x"
  1723   using LIMSEQ_le_const2[of f "lim f" x] by (simp add: convergent_LIMSEQ_iff)
  1724 
  1725 subsubsection{*Increasing and Decreasing Series*}
  1726 
  1727 lemma incseq_le: "incseq X \<Longrightarrow> X ----> L \<Longrightarrow> X n \<le> (L::'a::linorder_topology)"
  1728   by (metis incseq_def LIMSEQ_le_const)
  1729 
  1730 lemma decseq_le: "decseq X \<Longrightarrow> X ----> L \<Longrightarrow> (L::'a::linorder_topology) \<le> X n"
  1731   by (metis decseq_def LIMSEQ_le_const2)
  1732 
  1733 subsection {* First countable topologies *}
  1734 
  1735 class first_countable_topology = topological_space +
  1736   assumes first_countable_basis:
  1737     "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1738 
  1739 lemma (in first_countable_topology) countable_basis_at_decseq:
  1740   obtains A :: "nat \<Rightarrow> 'a set" where
  1741     "\<And>i. open (A i)" "\<And>i. x \<in> (A i)"
  1742     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1743 proof atomize_elim
  1744   from first_countable_basis[of x] obtain A :: "nat \<Rightarrow> 'a set" where
  1745     nhds: "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1746     and incl: "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"  by auto
  1747   def F \<equiv> "\<lambda>n. \<Inter>i\<le>n. A i"
  1748   show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and>
  1749       (\<forall>S. open S \<longrightarrow> x \<in> S \<longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially)"
  1750   proof (safe intro!: exI[of _ F])
  1751     fix i
  1752     show "open (F i)" using nhds(1) by (auto simp: F_def)
  1753     show "x \<in> F i" using nhds(2) by (auto simp: F_def)
  1754   next
  1755     fix S assume "open S" "x \<in> S"
  1756     from incl[OF this] obtain i where "F i \<subseteq> S" unfolding F_def by auto
  1757     moreover have "\<And>j. i \<le> j \<Longrightarrow> F j \<subseteq> F i"
  1758       by (auto simp: F_def)
  1759     ultimately show "eventually (\<lambda>i. F i \<subseteq> S) sequentially"
  1760       by (auto simp: eventually_sequentially)
  1761   qed
  1762 qed
  1763 
  1764 lemma (in first_countable_topology) nhds_countable:
  1765   obtains X :: "nat \<Rightarrow> 'a set"
  1766   where "decseq X" "\<And>n. open (X n)" "\<And>n. x \<in> X n" "nhds x = (INF n. principal (X n))"
  1767 proof -
  1768   from first_countable_basis obtain A :: "nat \<Rightarrow> 'a set"
  1769     where A: "\<And>n. x \<in> A n" "\<And>n. open (A n)" "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"
  1770     by metis
  1771   show thesis
  1772   proof
  1773     show "decseq (\<lambda>n. \<Inter>i\<le>n. A i)"
  1774       by (auto simp: decseq_def)
  1775     show "\<And>n. x \<in> (\<Inter>i\<le>n. A i)" "\<And>n. open (\<Inter>i\<le>n. A i)"
  1776       using A by auto
  1777     show "nhds x = (INF n. principal (\<Inter> i\<le>n. A i))"
  1778       using A unfolding nhds_def
  1779       apply (intro INF_eq)
  1780       apply simp_all
  1781       apply force
  1782       apply (intro exI[of _ "\<Inter> i\<le>n. A i" for n] conjI open_INT)
  1783       apply auto
  1784       done
  1785   qed
  1786 qed
  1787 
  1788 lemma (in first_countable_topology) countable_basis:
  1789   obtains A :: "nat \<Rightarrow> 'a set" where
  1790     "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1791     "\<And>F. (\<forall>n. F n \<in> A n) \<Longrightarrow> F ----> x"
  1792 proof atomize_elim
  1793   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1794     "\<And>i. open (A i)"
  1795     "\<And>i. x \<in> A i"
  1796     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1797     by (rule countable_basis_at_decseq) blast
  1798   {
  1799     fix F S assume "\<forall>n. F n \<in> A n" "open S" "x \<in> S"
  1800     with A(3)[of S] have "eventually (\<lambda>n. F n \<in> S) sequentially"
  1801       by (auto elim: eventually_elim1 simp: subset_eq)
  1802   }
  1803   with A show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and> (\<forall>F. (\<forall>n. F n \<in> A n) \<longrightarrow> F ----> x)"
  1804     by (intro exI[of _ A]) (auto simp: tendsto_def)
  1805 qed
  1806 
  1807 lemma (in first_countable_topology) sequentially_imp_eventually_nhds_within:
  1808   assumes "\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1809   shows "eventually P (inf (nhds a) (principal s))"
  1810 proof (rule ccontr)
  1811   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1812     "\<And>i. open (A i)"
  1813     "\<And>i. a \<in> A i"
  1814     "\<And>F. \<forall>n. F n \<in> A n \<Longrightarrow> F ----> a"
  1815     by (rule countable_basis) blast
  1816   assume "\<not> ?thesis"
  1817   with A have P: "\<exists>F. \<forall>n. F n \<in> s \<and> F n \<in> A n \<and> \<not> P (F n)"
  1818     unfolding eventually_inf_principal eventually_nhds by (intro choice) fastforce
  1819   then obtain F where F0: "\<forall>n. F n \<in> s" and F2: "\<forall>n. F n \<in> A n" and F3: "\<forall>n. \<not> P (F n)"
  1820     by blast
  1821   with A have "F ----> a" by auto
  1822   hence "eventually (\<lambda>n. P (F n)) sequentially"
  1823     using assms F0 by simp
  1824   thus "False" by (simp add: F3)
  1825 qed
  1826 
  1827 lemma (in first_countable_topology) eventually_nhds_within_iff_sequentially:
  1828   "eventually P (inf (nhds a) (principal s)) \<longleftrightarrow> 
  1829     (\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1830 proof (safe intro!: sequentially_imp_eventually_nhds_within)
  1831   assume "eventually P (inf (nhds a) (principal s))" 
  1832   then obtain S where "open S" "a \<in> S" "\<forall>x\<in>S. x \<in> s \<longrightarrow> P x"
  1833     by (auto simp: eventually_inf_principal eventually_nhds)
  1834   moreover fix f assume "\<forall>n. f n \<in> s" "f ----> a"
  1835   ultimately show "eventually (\<lambda>n. P (f n)) sequentially"
  1836     by (auto dest!: topological_tendstoD elim: eventually_elim1)
  1837 qed
  1838 
  1839 lemma (in first_countable_topology) eventually_nhds_iff_sequentially:
  1840   "eventually P (nhds a) \<longleftrightarrow> (\<forall>f. f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1841   using eventually_nhds_within_iff_sequentially[of P a UNIV] by simp
  1842 
  1843 lemma tendsto_at_iff_sequentially:
  1844   fixes f :: "'a :: first_countable_topology \<Rightarrow> _"
  1845   shows "(f ---> a) (at x within s) \<longleftrightarrow> (\<forall>X. (\<forall>i. X i \<in> s - {x}) \<longrightarrow> X ----> x \<longrightarrow> ((f \<circ> X) ----> a))"
  1846   unfolding filterlim_def[of _ "nhds a"] le_filter_def eventually_filtermap at_within_def eventually_nhds_within_iff_sequentially comp_def
  1847   by metis
  1848 
  1849 subsection {* Function limit at a point *}
  1850 
  1851 abbreviation
  1852   LIM :: "('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
  1853         ("((_)/ -- (_)/ --> (_))" [60, 0, 60] 60) where
  1854   "f -- a --> L \<equiv> (f ---> L) (at a)"
  1855 
  1856 lemma tendsto_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> (f ---> l) (at a within S) \<longleftrightarrow> (f -- a --> l)"
  1857   unfolding tendsto_def by (simp add: at_within_open[where S=S])
  1858 
  1859 lemma LIM_const_not_eq[tendsto_intros]:
  1860   fixes a :: "'a::perfect_space"
  1861   fixes k L :: "'b::t2_space"
  1862   shows "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) -- a --> L"
  1863   by (simp add: tendsto_const_iff)
  1864 
  1865 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
  1866 
  1867 lemma LIM_const_eq:
  1868   fixes a :: "'a::perfect_space"
  1869   fixes k L :: "'b::t2_space"
  1870   shows "(\<lambda>x. k) -- a --> L \<Longrightarrow> k = L"
  1871   by (simp add: tendsto_const_iff)
  1872 
  1873 lemma LIM_unique:
  1874   fixes a :: "'a::perfect_space" and L M :: "'b::t2_space"
  1875   shows "f -- a --> L \<Longrightarrow> f -- a --> M \<Longrightarrow> L = M"
  1876   using at_neq_bot by (rule tendsto_unique)
  1877 
  1878 text {* Limits are equal for functions equal except at limit point *}
  1879 
  1880 lemma LIM_equal: "\<forall>x. x \<noteq> a --> (f x = g x) \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- a --> l)"
  1881   unfolding tendsto_def eventually_at_topological by simp
  1882 
  1883 lemma LIM_cong: "a = b \<Longrightarrow> (\<And>x. x \<noteq> b \<Longrightarrow> f x = g x) \<Longrightarrow> l = m \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- b --> m)"
  1884   by (simp add: LIM_equal)
  1885 
  1886 lemma LIM_cong_limit: "f -- x --> L \<Longrightarrow> K = L \<Longrightarrow> f -- x --> K"
  1887   by simp
  1888 
  1889 lemma tendsto_at_iff_tendsto_nhds:
  1890   "g -- l --> g l \<longleftrightarrow> (g ---> g l) (nhds l)"
  1891   unfolding tendsto_def eventually_at_filter
  1892   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
  1893 
  1894 lemma tendsto_compose:
  1895   "g -- l --> g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  1896   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
  1897 
  1898 lemma LIM_o: "\<lbrakk>g -- l --> g l; f -- a --> l\<rbrakk> \<Longrightarrow> (g \<circ> f) -- a --> g l"
  1899   unfolding o_def by (rule tendsto_compose)
  1900 
  1901 lemma tendsto_compose_eventually:
  1902   "g -- l --> m \<Longrightarrow> (f ---> l) F \<Longrightarrow> eventually (\<lambda>x. f x \<noteq> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> m) F"
  1903   by (rule filterlim_compose[of g _ "at l"]) (auto simp add: filterlim_at)
  1904 
  1905 lemma LIM_compose_eventually:
  1906   assumes f: "f -- a --> b"
  1907   assumes g: "g -- b --> c"
  1908   assumes inj: "eventually (\<lambda>x. f x \<noteq> b) (at a)"
  1909   shows "(\<lambda>x. g (f x)) -- a --> c"
  1910   using g f inj by (rule tendsto_compose_eventually)
  1911 
  1912 lemma tendsto_compose_filtermap: "((g \<circ> f) ---> T) F \<longleftrightarrow> (g ---> T) (filtermap f F)"
  1913   by (simp add: filterlim_def filtermap_filtermap comp_def)
  1914 
  1915 subsubsection {* Relation of LIM and LIMSEQ *}
  1916 
  1917 lemma (in first_countable_topology) sequentially_imp_eventually_within:
  1918   "(\<forall>f. (\<forall>n. f n \<in> s \<and> f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow>
  1919     eventually P (at a within s)"
  1920   unfolding at_within_def
  1921   by (intro sequentially_imp_eventually_nhds_within) auto
  1922 
  1923 lemma (in first_countable_topology) sequentially_imp_eventually_at:
  1924   "(\<forall>f. (\<forall>n. f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow> eventually P (at a)"
  1925   using assms sequentially_imp_eventually_within [where s=UNIV] by simp
  1926 
  1927 lemma LIMSEQ_SEQ_conv1:
  1928   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1929   assumes f: "f -- a --> l"
  1930   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1931   using tendsto_compose_eventually [OF f, where F=sequentially] by simp
  1932 
  1933 lemma LIMSEQ_SEQ_conv2:
  1934   fixes f :: "'a::first_countable_topology \<Rightarrow> 'b::topological_space"
  1935   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1936   shows "f -- a --> l"
  1937   using assms unfolding tendsto_def [where l=l] by (simp add: sequentially_imp_eventually_at)
  1938 
  1939 lemma LIMSEQ_SEQ_conv:
  1940   "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> (a::'a::first_countable_topology) \<longrightarrow> (\<lambda>n. X (S n)) ----> L) =
  1941    (X -- a --> (L::'b::topological_space))"
  1942   using LIMSEQ_SEQ_conv2 LIMSEQ_SEQ_conv1 ..
  1943 
  1944 lemma sequentially_imp_eventually_at_left:
  1945   fixes a :: "'a :: {dense_linorder, linorder_topology, first_countable_topology}"
  1946   assumes b[simp]: "b < a"
  1947   assumes *: "\<And>f. (\<And>n. b < f n) \<Longrightarrow> (\<And>n. f n < a) \<Longrightarrow> incseq f \<Longrightarrow> f ----> a \<Longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1948   shows "eventually P (at_left a)"
  1949 proof (safe intro!: sequentially_imp_eventually_within)
  1950   fix X assume X: "\<forall>n. X n \<in> {..< a} \<and> X n \<noteq> a" "X ----> a"
  1951   show "eventually (\<lambda>n. P (X n)) sequentially"
  1952   proof (rule ccontr)
  1953     assume neg: "\<not> eventually (\<lambda>n. P (X n)) sequentially"
  1954     have "\<exists>s. \<forall>n. (\<not> P (X (s n)) \<and> b < X (s n)) \<and> (X (s n) \<le> X (s (Suc n)) \<and> Suc (s n) \<le> s (Suc n))"
  1955     proof (rule dependent_nat_choice)
  1956       have "\<not> eventually (\<lambda>n. b < X n \<longrightarrow> P (X n)) sequentially"
  1957         by (intro not_eventually_impI neg order_tendstoD(1) [OF X(2) b])
  1958       then show "\<exists>x. \<not> P (X x) \<and> b < X x"
  1959         by (auto dest!: not_eventuallyD)
  1960     next
  1961       fix x n
  1962       have "\<not> eventually (\<lambda>n. Suc x \<le> n \<longrightarrow> b < X n \<longrightarrow> X x < X n \<longrightarrow> P (X n)) sequentially"
  1963         using X by (intro not_eventually_impI order_tendstoD(1)[OF X(2)] eventually_ge_at_top neg) auto
  1964       then show "\<exists>n. (\<not> P (X n) \<and> b < X n) \<and> (X x \<le> X n \<and> Suc x \<le> n)"
  1965         by (auto dest!: not_eventuallyD)
  1966     qed
  1967     then guess s ..
  1968     then have "\<And>n. b < X (s n)" "\<And>n. X (s n) < a" "incseq (\<lambda>n. X (s n))" "(\<lambda>n. X (s n)) ----> a" "\<And>n. \<not> P (X (s n))"
  1969       using X by (auto simp: subseq_Suc_iff Suc_le_eq incseq_Suc_iff intro!: LIMSEQ_subseq_LIMSEQ[OF `X ----> a`, unfolded comp_def])
  1970     from *[OF this(1,2,3,4)] this(5) show False by auto
  1971   qed
  1972 qed
  1973 
  1974 lemma tendsto_at_left_sequentially:
  1975   fixes a :: "_ :: {dense_linorder, linorder_topology, first_countable_topology}"
  1976   assumes "b < a"
  1977   assumes *: "\<And>S. (\<And>n. S n < a) \<Longrightarrow> (\<And>n. b < S n) \<Longrightarrow> incseq S \<Longrightarrow> S ----> a \<Longrightarrow> (\<lambda>n. X (S n)) ----> L"
  1978   shows "(X ---> L) (at_left a)"
  1979   using assms unfolding tendsto_def [where l=L]
  1980   by (simp add: sequentially_imp_eventually_at_left)
  1981 
  1982 lemma sequentially_imp_eventually_at_right:
  1983   fixes a :: "'a :: {dense_linorder, linorder_topology, first_countable_topology}"
  1984   assumes b[simp]: "a < b"
  1985   assumes *: "\<And>f. (\<And>n. a < f n) \<Longrightarrow> (\<And>n. f n < b) \<Longrightarrow> decseq f \<Longrightarrow> f ----> a \<Longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1986   shows "eventually P (at_right a)"
  1987 proof (safe intro!: sequentially_imp_eventually_within)
  1988   fix X assume X: "\<forall>n. X n \<in> {a <..} \<and> X n \<noteq> a" "X ----> a"
  1989   show "eventually (\<lambda>n. P (X n)) sequentially"
  1990   proof (rule ccontr)
  1991     assume neg: "\<not> eventually (\<lambda>n. P (X n)) sequentially"
  1992     have "\<exists>s. \<forall>n. (\<not> P (X (s n)) \<and> X (s n) < b) \<and> (X (s (Suc n)) \<le> X (s n) \<and> Suc (s n) \<le> s (Suc n))"
  1993     proof (rule dependent_nat_choice)
  1994       have "\<not> eventually (\<lambda>n. X n < b \<longrightarrow> P (X n)) sequentially"
  1995         by (intro not_eventually_impI neg order_tendstoD(2) [OF X(2) b])
  1996       then show "\<exists>x. \<not> P (X x) \<and> X x < b"
  1997         by (auto dest!: not_eventuallyD)
  1998     next
  1999       fix x n
  2000       have "\<not> eventually (\<lambda>n. Suc x \<le> n \<longrightarrow> X n < b \<longrightarrow> X n < X x \<longrightarrow> P (X n)) sequentially"
  2001         using X by (intro not_eventually_impI order_tendstoD(2)[OF X(2)] eventually_ge_at_top neg) auto
  2002       then show "\<exists>n. (\<not> P (X n) \<and> X n < b) \<and> (X n \<le> X x \<and> Suc x \<le> n)"
  2003         by (auto dest!: not_eventuallyD)
  2004     qed
  2005     then guess s ..
  2006     then have "\<And>n. a < X (s n)" "\<And>n. X (s n) < b" "decseq (\<lambda>n. X (s n))" "(\<lambda>n. X (s n)) ----> a" "\<And>n. \<not> P (X (s n))"
  2007       using X by (auto simp: subseq_Suc_iff Suc_le_eq decseq_Suc_iff intro!: LIMSEQ_subseq_LIMSEQ[OF `X ----> a`, unfolded comp_def])
  2008     from *[OF this(1,2,3,4)] this(5) show False by auto
  2009   qed
  2010 qed
  2011 
  2012 lemma tendsto_at_right_sequentially:
  2013   fixes a :: "_ :: {dense_linorder, linorder_topology, first_countable_topology}"
  2014   assumes "a < b"
  2015   assumes *: "\<And>S. (\<And>n. a < S n) \<Longrightarrow> (\<And>n. S n < b) \<Longrightarrow> decseq S \<Longrightarrow> S ----> a \<Longrightarrow> (\<lambda>n. X (S n)) ----> L"
  2016   shows "(X ---> L) (at_right a)"
  2017   using assms unfolding tendsto_def [where l=L]
  2018   by (simp add: sequentially_imp_eventually_at_right)
  2019 
  2020 subsection {* Continuity *}
  2021 
  2022 subsubsection {* Continuity on a set *}
  2023 
  2024 definition continuous_on :: "'a set \<Rightarrow> ('a :: topological_space \<Rightarrow> 'b :: topological_space) \<Rightarrow> bool" where
  2025   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f ---> f x) (at x within s))"
  2026 
  2027 lemma continuous_on_cong [cong]:
  2028   "s = t \<Longrightarrow> (\<And>x. x \<in> t \<Longrightarrow> f x = g x) \<Longrightarrow> continuous_on s f \<longleftrightarrow> continuous_on t g"
  2029   unfolding continuous_on_def by (intro ball_cong filterlim_cong) (auto simp: eventually_at_filter)
  2030 
  2031 lemma continuous_on_topological:
  2032   "continuous_on s f \<longleftrightarrow>
  2033     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  2034   unfolding continuous_on_def tendsto_def eventually_at_topological by metis
  2035 
  2036 lemma continuous_on_open_invariant:
  2037   "continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s))"
  2038 proof safe
  2039   fix B :: "'b set" assume "continuous_on s f" "open B"
  2040   then have "\<forall>x\<in>f -` B \<inter> s. (\<exists>A. open A \<and> x \<in> A \<and> s \<inter> A \<subseteq> f -` B)"
  2041     by (auto simp: continuous_on_topological subset_eq Ball_def imp_conjL)
  2042   then obtain A where "\<forall>x\<in>f -` B \<inter> s. open (A x) \<and> x \<in> A x \<and> s \<inter> A x \<subseteq> f -` B"
  2043     unfolding bchoice_iff ..
  2044   then show "\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s"
  2045     by (intro exI[of _ "\<Union>x\<in>f -` B \<inter> s. A x"]) auto
  2046 next
  2047   assume B: "\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s)"
  2048   show "continuous_on s f"
  2049     unfolding continuous_on_topological
  2050   proof safe
  2051     fix x B assume "x \<in> s" "open B" "f x \<in> B"
  2052     with B obtain A where A: "open A" "A \<inter> s = f -` B \<inter> s" by auto
  2053     with `x \<in> s` `f x \<in> B` show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  2054       by (intro exI[of _ A]) auto
  2055   qed
  2056 qed
  2057 
  2058 lemma continuous_on_open_vimage:
  2059   "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> open (f -` B \<inter> s))"
  2060   unfolding continuous_on_open_invariant
  2061   by (metis open_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  2062 
  2063 corollary continuous_imp_open_vimage:
  2064   assumes "continuous_on s f" "open s" "open B" "f -` B \<subseteq> s"
  2065     shows "open (f -` B)"
  2066 by (metis assms continuous_on_open_vimage le_iff_inf)
  2067 
  2068 corollary open_vimage[continuous_intros]:
  2069   assumes "open s" and "continuous_on UNIV f"
  2070   shows "open (f -` s)"
  2071   using assms unfolding continuous_on_open_vimage [OF open_UNIV]
  2072   by simp
  2073 
  2074 lemma continuous_on_closed_invariant:
  2075   "continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> (\<exists>A. closed A \<and> A \<inter> s = f -` B \<inter> s))"
  2076 proof -
  2077   have *: "\<And>P Q::'b set\<Rightarrow>bool. (\<And>A. P A \<longleftrightarrow> Q (- A)) \<Longrightarrow> (\<forall>A. P A) \<longleftrightarrow> (\<forall>A. Q A)"
  2078     by (metis double_compl)
  2079   show ?thesis
  2080     unfolding continuous_on_open_invariant by (intro *) (auto simp: open_closed[symmetric])
  2081 qed
  2082 
  2083 lemma continuous_on_closed_vimage:
  2084   "closed s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> closed (f -` B \<inter> s))"
  2085   unfolding continuous_on_closed_invariant
  2086   by (metis closed_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  2087 
  2088 corollary closed_vimage[continuous_intros]:
  2089   assumes "closed s" and "continuous_on UNIV f"
  2090   shows "closed (f -` s)"
  2091   using assms unfolding continuous_on_closed_vimage [OF closed_UNIV]
  2092   by simp
  2093 
  2094 lemma continuous_on_open_Union:
  2095   "(\<And>s. s \<in> S \<Longrightarrow> open s) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on s f) \<Longrightarrow> continuous_on (\<Union>S) f"
  2096   unfolding continuous_on_def by safe (metis open_Union at_within_open UnionI)
  2097 
  2098 lemma continuous_on_open_UN:
  2099   "(\<And>s. s \<in> S \<Longrightarrow> open (A s)) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on (A s) f) \<Longrightarrow> continuous_on (\<Union>s\<in>S. A s) f"
  2100   unfolding Union_image_eq[symmetric] by (rule continuous_on_open_Union) auto
  2101 
  2102 lemma continuous_on_closed_Un:
  2103   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  2104   by (auto simp add: continuous_on_closed_vimage closed_Un Int_Un_distrib)
  2105 
  2106 lemma continuous_on_If:
  2107   assumes closed: "closed s" "closed t" and cont: "continuous_on s f" "continuous_on t g"
  2108     and P: "\<And>x. x \<in> s \<Longrightarrow> \<not> P x \<Longrightarrow> f x = g x" "\<And>x. x \<in> t \<Longrightarrow> P x \<Longrightarrow> f x = g x"
  2109   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)" (is "continuous_on _ ?h")
  2110 proof-
  2111   from P have "\<forall>x\<in>s. f x = ?h x" "\<forall>x\<in>t. g x = ?h x"
  2112     by auto
  2113   with cont have "continuous_on s ?h" "continuous_on t ?h"
  2114     by simp_all
  2115   with closed show ?thesis
  2116     by (rule continuous_on_closed_Un)
  2117 qed
  2118 
  2119 lemma continuous_on_id[continuous_intros]: "continuous_on s (\<lambda>x. x)"
  2120   unfolding continuous_on_def by (fast intro: tendsto_ident_at)
  2121 
  2122 lemma continuous_on_const[continuous_intros]: "continuous_on s (\<lambda>x. c)"
  2123   unfolding continuous_on_def by (auto intro: tendsto_const)
  2124 
  2125 lemma continuous_on_compose[continuous_intros]:
  2126   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g o f)"
  2127   unfolding continuous_on_topological by simp metis
  2128 
  2129 lemma continuous_on_compose2:
  2130   "continuous_on t g \<Longrightarrow> continuous_on s f \<Longrightarrow> t = f ` s \<Longrightarrow> continuous_on s (\<lambda>x. g (f x))"
  2131   using continuous_on_compose[of s f g] by (simp add: comp_def)
  2132 
  2133 subsubsection {* Continuity at a point *}
  2134 
  2135 definition continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool" where
  2136   "continuous F f \<longleftrightarrow> (f ---> f (Lim F (\<lambda>x. x))) F"
  2137 
  2138 lemma continuous_bot[continuous_intros, simp]: "continuous bot f"
  2139   unfolding continuous_def by auto
  2140 
  2141 lemma continuous_trivial_limit: "trivial_limit net \<Longrightarrow> continuous net f"
  2142   by simp
  2143 
  2144 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f ---> f x) (at x within s)"
  2145   by (cases "trivial_limit (at x within s)") (auto simp add: Lim_ident_at continuous_def)
  2146 
  2147 lemma continuous_within_topological:
  2148   "continuous (at x within s) f \<longleftrightarrow>
  2149     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  2150   unfolding continuous_within tendsto_def eventually_at_topological by metis
  2151 
  2152 lemma continuous_within_compose[continuous_intros]:
  2153   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  2154   continuous (at x within s) (g o f)"
  2155   by (simp add: continuous_within_topological) metis
  2156 
  2157 lemma continuous_within_compose2:
  2158   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  2159   continuous (at x within s) (\<lambda>x. g (f x))"
  2160   using continuous_within_compose[of x s f g] by (simp add: comp_def)
  2161 
  2162 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> f -- x --> f x"
  2163   using continuous_within[of x UNIV f] by simp
  2164 
  2165 lemma continuous_ident[continuous_intros, simp]: "continuous (at x within S) (\<lambda>x. x)"
  2166   unfolding continuous_within by (rule tendsto_ident_at)
  2167 
  2168 lemma continuous_const[continuous_intros, simp]: "continuous F (\<lambda>x. c)"
  2169   unfolding continuous_def by (rule tendsto_const)
  2170 
  2171 lemma continuous_on_eq_continuous_within:
  2172   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. continuous (at x within s) f)"
  2173   unfolding continuous_on_def continuous_within ..
  2174 
  2175 abbreviation isCont :: "('a::t2_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> bool" where
  2176   "isCont f a \<equiv> continuous (at a) f"
  2177 
  2178 lemma isCont_def: "isCont f a \<longleftrightarrow> f -- a --> f a"
  2179   by (rule continuous_at)
  2180 
  2181 lemma continuous_at_within: "isCont f x \<Longrightarrow> continuous (at x within s) f"
  2182   by (auto intro: tendsto_mono at_le simp: continuous_at continuous_within)
  2183 
  2184 lemma continuous_on_eq_continuous_at: "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. isCont f x)"
  2185   by (simp add: continuous_on_def continuous_at at_within_open[of _ s])
  2186 
  2187 lemma continuous_on_subset: "continuous_on s f \<Longrightarrow> t \<subseteq> s \<Longrightarrow> continuous_on t f"
  2188   unfolding continuous_on_def by (metis subset_eq tendsto_within_subset)
  2189 
  2190 lemma continuous_at_imp_continuous_on: "\<forall>x\<in>s. isCont f x \<Longrightarrow> continuous_on s f"
  2191   by (auto intro: continuous_at_within simp: continuous_on_eq_continuous_within)
  2192 
  2193 lemma isContI_continuous: "continuous (at x within UNIV) f \<Longrightarrow> isCont f x"
  2194   by simp
  2195 
  2196 lemma isCont_ident[continuous_intros, simp]: "isCont (\<lambda>x. x) a"
  2197   using continuous_ident by (rule isContI_continuous)
  2198 
  2199 lemmas isCont_const = continuous_const
  2200 
  2201 lemma isCont_o2: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
  2202   unfolding isCont_def by (rule tendsto_compose)
  2203 
  2204 lemma isCont_o[continuous_intros]: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (g \<circ> f) a"
  2205   unfolding o_def by (rule isCont_o2)
  2206 
  2207 lemma isCont_tendsto_compose: "isCont g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  2208   unfolding isCont_def by (rule tendsto_compose)
  2209 
  2210 lemma continuous_within_compose3:
  2211   "isCont g (f x) \<Longrightarrow> continuous (at x within s) f \<Longrightarrow> continuous (at x within s) (\<lambda>x. g (f x))"
  2212   using continuous_within_compose2[of x s f g] by (simp add: continuous_at_within)
  2213 
  2214 lemma filtermap_nhds_open_map:
  2215   assumes cont: "isCont f a" and open_map: "\<And>S. open S \<Longrightarrow> open (f`S)"
  2216   shows "filtermap f (nhds a) = nhds (f a)"
  2217   unfolding filter_eq_iff
  2218 proof safe
  2219   fix P assume "eventually P (filtermap f (nhds a))"
  2220   then guess S unfolding eventually_filtermap eventually_nhds ..
  2221   then show "eventually P (nhds (f a))"
  2222     unfolding eventually_nhds by (intro exI[of _ "f`S"]) (auto intro!: open_map)
  2223 qed (metis filterlim_iff tendsto_at_iff_tendsto_nhds isCont_def eventually_filtermap cont)
  2224 
  2225 lemma continuous_at_split: 
  2226   "continuous (at (x::'a::linorder_topology)) f = (continuous (at_left x) f \<and> continuous (at_right x) f)"
  2227   by (simp add: continuous_within filterlim_at_split)
  2228 
  2229 subsubsection{* Open-cover compactness *}
  2230 
  2231 context topological_space
  2232 begin
  2233 
  2234 definition compact :: "'a set \<Rightarrow> bool" where
  2235   compact_eq_heine_borel: -- "This name is used for backwards compatibility"
  2236     "compact S \<longleftrightarrow> (\<forall>C. (\<forall>c\<in>C. open c) \<and> S \<subseteq> \<Union>C \<longrightarrow> (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D))"
  2237 
  2238 lemma compactI:
  2239   assumes "\<And>C. \<forall>t\<in>C. open t \<Longrightarrow> s \<subseteq> \<Union> C \<Longrightarrow> \<exists>C'. C' \<subseteq> C \<and> finite C' \<and> s \<subseteq> \<Union> C'"
  2240   shows "compact s"
  2241   unfolding compact_eq_heine_borel using assms by metis
  2242 
  2243 lemma compact_empty[simp]: "compact {}"
  2244   by (auto intro!: compactI)
  2245 
  2246 lemma compactE:
  2247   assumes "compact s" and "\<forall>t\<in>C. open t" and "s \<subseteq> \<Union>C"
  2248   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> \<Union>C'"
  2249   using assms unfolding compact_eq_heine_borel by metis
  2250 
  2251 lemma compactE_image:
  2252   assumes "compact s" and "\<forall>t\<in>C. open (f t)" and "s \<subseteq> (\<Union>c\<in>C. f c)"
  2253   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> (\<Union>c\<in>C'. f c)"
  2254   using assms unfolding ball_simps[symmetric] SUP_def
  2255   by (metis (lifting) finite_subset_image compact_eq_heine_borel[of s])
  2256 
  2257 lemma compact_inter_closed [intro]:
  2258   assumes "compact s" and "closed t"
  2259   shows "compact (s \<inter> t)"
  2260 proof (rule compactI)
  2261   fix C assume C: "\<forall>c\<in>C. open c" and cover: "s \<inter> t \<subseteq> \<Union>C"
  2262   from C `closed t` have "\<forall>c\<in>C \<union> {-t}. open c" by auto
  2263   moreover from cover have "s \<subseteq> \<Union>(C \<union> {-t})" by auto
  2264   ultimately have "\<exists>D\<subseteq>C \<union> {-t}. finite D \<and> s \<subseteq> \<Union>D"
  2265     using `compact s` unfolding compact_eq_heine_borel by auto
  2266   then obtain D where "D \<subseteq> C \<union> {- t} \<and> finite D \<and> s \<subseteq> \<Union>D" ..
  2267   then show "\<exists>D\<subseteq>C. finite D \<and> s \<inter> t \<subseteq> \<Union>D"
  2268     by (intro exI[of _ "D - {-t}"]) auto
  2269 qed
  2270 
  2271 lemma inj_setminus: "inj_on uminus (A::'a set set)"
  2272   by (auto simp: inj_on_def)
  2273 
  2274 lemma compact_fip:
  2275   "compact U \<longleftrightarrow>
  2276     (\<forall>A. (\<forall>a\<in>A. closed a) \<longrightarrow> (\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}) \<longrightarrow> U \<inter> \<Inter>A \<noteq> {})"
  2277   (is "_ \<longleftrightarrow> ?R")
  2278 proof (safe intro!: compact_eq_heine_borel[THEN iffD2])
  2279   fix A
  2280   assume "compact U"
  2281     and A: "\<forall>a\<in>A. closed a" "U \<inter> \<Inter>A = {}"
  2282     and fi: "\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}"
  2283   from A have "(\<forall>a\<in>uminus`A. open a) \<and> U \<subseteq> \<Union>(uminus`A)"
  2284     by auto
  2285   with `compact U` obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<subseteq> \<Union>(uminus`B)"
  2286     unfolding compact_eq_heine_borel by (metis subset_image_iff)
  2287   with fi[THEN spec, of B] show False
  2288     by (auto dest: finite_imageD intro: inj_setminus)
  2289 next
  2290   fix A
  2291   assume ?R
  2292   assume "\<forall>a\<in>A. open a" "U \<subseteq> \<Union>A"
  2293   then have "U \<inter> \<Inter>(uminus`A) = {}" "\<forall>a\<in>uminus`A. closed a"
  2294     by auto
  2295   with `?R` obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<inter> \<Inter>(uminus`B) = {}"
  2296     by (metis subset_image_iff)
  2297   then show "\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T"
  2298     by  (auto intro!: exI[of _ B] inj_setminus dest: finite_imageD)
  2299 qed
  2300 
  2301 lemma compact_imp_fip:
  2302   "compact s \<Longrightarrow> \<forall>t \<in> f. closed t \<Longrightarrow> \<forall>f'. finite f' \<and> f' \<subseteq> f \<longrightarrow> (s \<inter> (\<Inter> f') \<noteq> {}) \<Longrightarrow>
  2303     s \<inter> (\<Inter> f) \<noteq> {}"
  2304   unfolding compact_fip by auto
  2305 
  2306 lemma compact_imp_fip_image:
  2307   assumes "compact s"
  2308     and P: "\<And>i. i \<in> I \<Longrightarrow> closed (f i)"
  2309     and Q: "\<And>I'. finite I' \<Longrightarrow> I' \<subseteq> I \<Longrightarrow> (s \<inter> (\<Inter>i\<in>I'. f i) \<noteq> {})"
  2310   shows "s \<inter> (\<Inter>i\<in>I. f i) \<noteq> {}"
  2311 proof -
  2312   note `compact s`
  2313   moreover from P have "\<forall>i \<in> f ` I. closed i" by blast
  2314   moreover have "\<forall>A. finite A \<and> A \<subseteq> f ` I \<longrightarrow> (s \<inter> (\<Inter>A) \<noteq> {})"
  2315   proof (rule, rule, erule conjE)
  2316     fix A :: "'a set set"
  2317     assume "finite A"
  2318     moreover assume "A \<subseteq> f ` I"
  2319     ultimately obtain B where "B \<subseteq> I" and "finite B" and "A = f ` B"
  2320       using finite_subset_image [of A f I] by blast
  2321     with Q [of B] show "s \<inter> \<Inter>A \<noteq> {}" by simp
  2322   qed
  2323   ultimately have "s \<inter> (\<Inter>(f ` I)) \<noteq> {}" by (rule compact_imp_fip)
  2324   then show ?thesis by simp
  2325 qed
  2326 
  2327 end
  2328 
  2329 lemma (in t2_space) compact_imp_closed:
  2330   assumes "compact s" shows "closed s"
  2331 unfolding closed_def
  2332 proof (rule openI)
  2333   fix y assume "y \<in> - s"
  2334   let ?C = "\<Union>x\<in>s. {u. open u \<and> x \<in> u \<and> eventually (\<lambda>y. y \<notin> u) (nhds y)}"
  2335   note `compact s`
  2336   moreover have "\<forall>u\<in>?C. open u" by simp
  2337   moreover have "s \<subseteq> \<Union>?C"
  2338   proof
  2339     fix x assume "x \<in> s"
  2340     with `y \<in> - s` have "x \<noteq> y" by clarsimp
  2341     hence "\<exists>u v. open u \<and> open v \<and> x \<in> u \<and> y \<in> v \<and> u \<inter> v = {}"
  2342       by (rule hausdorff)
  2343     with `x \<in> s` show "x \<in> \<Union>?C"
  2344       unfolding eventually_nhds by auto
  2345   qed
  2346   ultimately obtain D where "D \<subseteq> ?C" and "finite D" and "s \<subseteq> \<Union>D"
  2347     by (rule compactE)
  2348   from `D \<subseteq> ?C` have "\<forall>x\<in>D. eventually (\<lambda>y. y \<notin> x) (nhds y)" by auto
  2349   with `finite D` have "eventually (\<lambda>y. y \<notin> \<Union>D) (nhds y)"
  2350     by (simp add: eventually_Ball_finite)
  2351   with `s \<subseteq> \<Union>D` have "eventually (\<lambda>y. y \<notin> s) (nhds y)"
  2352     by (auto elim!: eventually_mono [rotated])
  2353   thus "\<exists>t. open t \<and> y \<in> t \<and> t \<subseteq> - s"
  2354     by (simp add: eventually_nhds subset_eq)
  2355 qed
  2356 
  2357 lemma compact_continuous_image:
  2358   assumes f: "continuous_on s f" and s: "compact s"
  2359   shows "compact (f ` s)"
  2360 proof (rule compactI)
  2361   fix C assume "\<forall>c\<in>C. open c" and cover: "f`s \<subseteq> \<Union>C"
  2362   with f have "\<forall>c\<in>C. \<exists>A. open A \<and> A \<inter> s = f -` c \<inter> s"
  2363     unfolding continuous_on_open_invariant by blast
  2364   then obtain A where A: "\<forall>c\<in>C. open (A c) \<and> A c \<inter> s = f -` c \<inter> s"
  2365     unfolding bchoice_iff ..
  2366   with cover have "\<forall>c\<in>C. open (A c)" "s \<subseteq> (\<Union>c\<in>C. A c)"
  2367     by (fastforce simp add: subset_eq set_eq_iff)+
  2368   from compactE_image[OF s this] obtain D where "D \<subseteq> C" "finite D" "s \<subseteq> (\<Union>c\<in>D. A c)" .
  2369   with A show "\<exists>D \<subseteq> C. finite D \<and> f`s \<subseteq> \<Union>D"
  2370     by (intro exI[of _ D]) (fastforce simp add: subset_eq set_eq_iff)+
  2371 qed
  2372 
  2373 lemma continuous_on_inv:
  2374   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2375   assumes "continuous_on s f"  "compact s"  "\<forall>x\<in>s. g (f x) = x"
  2376   shows "continuous_on (f ` s) g"
  2377 unfolding continuous_on_topological
  2378 proof (clarsimp simp add: assms(3))
  2379   fix x :: 'a and B :: "'a set"
  2380   assume "x \<in> s" and "open B" and "x \<in> B"
  2381   have 1: "\<forall>x\<in>s. f x \<in> f ` (s - B) \<longleftrightarrow> x \<in> s - B"
  2382     using assms(3) by (auto, metis)
  2383   have "continuous_on (s - B) f"
  2384     using `continuous_on s f` Diff_subset
  2385     by (rule continuous_on_subset)
  2386   moreover have "compact (s - B)"
  2387     using `open B` and `compact s`
  2388     unfolding Diff_eq by (intro compact_inter_closed closed_Compl)
  2389   ultimately have "compact (f ` (s - B))"
  2390     by (rule compact_continuous_image)
  2391   hence "closed (f ` (s - B))"
  2392     by (rule compact_imp_closed)
  2393   hence "open (- f ` (s - B))"
  2394     by (rule open_Compl)
  2395   moreover have "f x \<in> - f ` (s - B)"
  2396     using `x \<in> s` and `x \<in> B` by (simp add: 1)
  2397   moreover have "\<forall>y\<in>s. f y \<in> - f ` (s - B) \<longrightarrow> y \<in> B"
  2398     by (simp add: 1)
  2399   ultimately show "\<exists>A. open A \<and> f x \<in> A \<and> (\<forall>y\<in>s. f y \<in> A \<longrightarrow> y \<in> B)"
  2400     by fast
  2401 qed
  2402 
  2403 lemma continuous_on_inv_into:
  2404   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2405   assumes s: "continuous_on s f" "compact s" and f: "inj_on f s"
  2406   shows "continuous_on (f ` s) (the_inv_into s f)"
  2407   by (rule continuous_on_inv[OF s]) (auto simp: the_inv_into_f_f[OF f])
  2408 
  2409 lemma (in linorder_topology) compact_attains_sup:
  2410   assumes "compact S" "S \<noteq> {}"
  2411   shows "\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s"
  2412 proof (rule classical)
  2413   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s)"
  2414   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. s < t s"
  2415     by (metis not_le)
  2416   then have "\<forall>s\<in>S. open {..< t s}" "S \<subseteq> (\<Union>s\<in>S. {..< t s})"
  2417     by auto
  2418   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {..< t s})"
  2419     by (erule compactE_image)
  2420   with `S \<noteq> {}` have Max: "Max (t`C) \<in> t`C" and "\<forall>s\<in>t`C. s \<le> Max (t`C)"
  2421     by (auto intro!: Max_in)
  2422   with C have "S \<subseteq> {..< Max (t`C)}"
  2423     by (auto intro: less_le_trans simp: subset_eq)
  2424   with t Max `C \<subseteq> S` show ?thesis
  2425     by fastforce
  2426 qed
  2427 
  2428 lemma (in linorder_topology) compact_attains_inf:
  2429   assumes "compact S" "S \<noteq> {}"
  2430   shows "\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t"
  2431 proof (rule classical)
  2432   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t)"
  2433   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. t s < s"
  2434     by (metis not_le)
  2435   then have "\<forall>s\<in>S. open {t s <..}" "S \<subseteq> (\<Union>s\<in>S. {t s <..})"
  2436     by auto
  2437   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {t s <..})"
  2438     by (erule compactE_image)
  2439   with `S \<noteq> {}` have Min: "Min (t`C) \<in> t`C" and "\<forall>s\<in>t`C. Min (t`C) \<le> s"
  2440     by (auto intro!: Min_in)
  2441   with C have "S \<subseteq> {Min (t`C) <..}"
  2442     by (auto intro: le_less_trans simp: subset_eq)
  2443   with t Min `C \<subseteq> S` show ?thesis
  2444     by fastforce
  2445 qed
  2446 
  2447 lemma continuous_attains_sup:
  2448   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2449   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s.  f y \<le> f x)"
  2450   using compact_attains_sup[of "f ` s"] compact_continuous_image[of s f] by auto
  2451 
  2452 lemma continuous_attains_inf:
  2453   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2454   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s. f x \<le> f y)"
  2455   using compact_attains_inf[of "f ` s"] compact_continuous_image[of s f] by auto
  2456 
  2457 subsection {* Connectedness *}
  2458 
  2459 context topological_space
  2460 begin
  2461 
  2462 definition "connected S \<longleftrightarrow>
  2463   \<not> (\<exists>A B. open A \<and> open B \<and> S \<subseteq> A \<union> B \<and> A \<inter> B \<inter> S = {} \<and> A \<inter> S \<noteq> {} \<and> B \<inter> S \<noteq> {})"
  2464 
  2465 lemma connectedI:
  2466   "(\<And>A B. open A \<Longrightarrow> open B \<Longrightarrow> A \<inter> U \<noteq> {} \<Longrightarrow> B \<inter> U \<noteq> {} \<Longrightarrow> A \<inter> B \<inter> U = {} \<Longrightarrow> U \<subseteq> A \<union> B \<Longrightarrow> False)
  2467   \<Longrightarrow> connected U"
  2468   by (auto simp: connected_def)
  2469 
  2470 lemma connected_empty[simp]: "connected {}"
  2471   by (auto intro!: connectedI)
  2472 
  2473 lemma connectedD:
  2474   "connected A \<Longrightarrow> open U \<Longrightarrow> open V \<Longrightarrow> U \<inter> V \<inter> A = {} \<Longrightarrow> A \<subseteq> U \<union> V \<Longrightarrow> U \<inter> A = {} \<or> V \<inter> A = {}" 
  2475   by (auto simp: connected_def)
  2476 
  2477 end
  2478 
  2479 lemma connected_local_const:
  2480   assumes "connected A" "a \<in> A" "b \<in> A"
  2481   assumes *: "\<forall>a\<in>A. eventually (\<lambda>b. f a = f b) (at a within A)"
  2482   shows "f a = f b"
  2483 proof -
  2484   obtain S where S: "\<And>a. a \<in> A \<Longrightarrow> a \<in> S a" "\<And>a. a \<in> A \<Longrightarrow> open (S a)"
  2485     "\<And>a x. a \<in> A \<Longrightarrow> x \<in> S a \<Longrightarrow> x \<in> A \<Longrightarrow> f a = f x"
  2486     using * unfolding eventually_at_topological by metis
  2487 
  2488   let ?P = "\<Union>b\<in>{b\<in>A. f a = f b}. S b" and ?N = "\<Union>b\<in>{b\<in>A. f a \<noteq> f b}. S b"
  2489   have "?P \<inter> A = {} \<or> ?N \<inter> A = {}"
  2490     using `connected A` S `a\<in>A`
  2491     by (intro connectedD) (auto, metis)
  2492   then show "f a = f b"
  2493   proof
  2494     assume "?N \<inter> A = {}"
  2495     then have "\<forall>x\<in>A. f a = f x"
  2496       using S(1) by auto
  2497     with `b\<in>A` show ?thesis by auto
  2498   next
  2499     assume "?P \<inter> A = {}" then show ?thesis
  2500       using `a \<in> A` S(1)[of a] by auto
  2501   qed
  2502 qed
  2503 
  2504 lemma (in linorder_topology) connectedD_interval:
  2505   assumes "connected U" and xy: "x \<in> U" "y \<in> U" and "x \<le> z" "z \<le> y"
  2506   shows "z \<in> U"
  2507 proof -
  2508   have eq: "{..<z} \<union> {z<..} = - {z}"
  2509     by auto
  2510   { assume "z \<notin> U" "x < z" "z < y"
  2511     with xy have "\<not> connected U"
  2512       unfolding connected_def simp_thms
  2513       apply (rule_tac exI[of _ "{..< z}"])
  2514       apply (rule_tac exI[of _ "{z <..}"])
  2515       apply (auto simp add: eq)
  2516       done }
  2517   with assms show "z \<in> U"
  2518     by (metis less_le)
  2519 qed
  2520 
  2521 lemma connected_continuous_image:
  2522   assumes *: "continuous_on s f"
  2523   assumes "connected s"
  2524   shows "connected (f ` s)"
  2525 proof (rule connectedI)
  2526   fix A B assume A: "open A" "A \<inter> f ` s \<noteq> {}" and B: "open B" "B \<inter> f ` s \<noteq> {}" and
  2527     AB: "A \<inter> B \<inter> f ` s = {}" "f ` s \<subseteq> A \<union> B"
  2528   obtain A' where A': "open A'" "f -` A \<inter> s = A' \<inter> s"
  2529     using * `open A` unfolding continuous_on_open_invariant by metis
  2530   obtain B' where B': "open B'" "f -` B \<inter> s = B' \<inter> s"
  2531     using * `open B` unfolding continuous_on_open_invariant by metis
  2532 
  2533   have "\<exists>A B. open A \<and> open B \<and> s \<subseteq> A \<union> B \<and> A \<inter> B \<inter> s = {} \<and> A \<inter> s \<noteq> {} \<and> B \<inter> s \<noteq> {}"
  2534   proof (rule exI[of _ A'], rule exI[of _ B'], intro conjI)
  2535     have "s \<subseteq> (f -` A \<inter> s) \<union> (f -` B \<inter> s)" using AB by auto
  2536     then show "s \<subseteq> A' \<union> B'" using A' B' by auto
  2537   next
  2538     have "(f -` A \<inter> s) \<inter> (f -` B \<inter> s) = {}" using AB by auto
  2539     then show "A' \<inter> B' \<inter> s = {}" using A' B' by auto
  2540   qed (insert A' B' A B, auto)
  2541   with `connected s` show False
  2542     unfolding connected_def by blast
  2543 qed
  2544 
  2545 
  2546 section {* Connectedness *}
  2547 
  2548 class linear_continuum_topology = linorder_topology + linear_continuum
  2549 begin
  2550 
  2551 lemma Inf_notin_open:
  2552   assumes A: "open A" and bnd: "\<forall>a\<in>A. x < a"
  2553   shows "Inf A \<notin> A"
  2554 proof
  2555   assume "Inf A \<in> A"
  2556   then obtain b where "b < Inf A" "{b <.. Inf A} \<subseteq> A"
  2557     using open_left[of A "Inf A" x] assms by auto
  2558   with dense[of b "Inf A"] obtain c where "c < Inf A" "c \<in> A"
  2559     by (auto simp: subset_eq)
  2560   then show False
  2561     using cInf_lower[OF `c \<in> A`] bnd by (metis not_le less_imp_le bdd_belowI)
  2562 qed
  2563 
  2564 lemma Sup_notin_open:
  2565   assumes A: "open A" and bnd: "\<forall>a\<in>A. a < x"
  2566   shows "Sup A \<notin> A"
  2567 proof
  2568   assume "Sup A \<in> A"
  2569   then obtain b where "Sup A < b" "{Sup A ..< b} \<subseteq> A"
  2570     using open_right[of A "Sup A" x] assms by auto
  2571   with dense[of "Sup A" b] obtain c where "Sup A < c" "c \<in> A"
  2572     by (auto simp: subset_eq)
  2573   then show False
  2574     using cSup_upper[OF `c \<in> A`] bnd by (metis less_imp_le not_le bdd_aboveI)
  2575 qed
  2576 
  2577 end
  2578 
  2579 instance linear_continuum_topology \<subseteq> perfect_space
  2580 proof
  2581   fix x :: 'a
  2582   obtain y where "x < y \<or> y < x"
  2583     using ex_gt_or_lt [of x] ..
  2584   with Inf_notin_open[of "{x}" y] Sup_notin_open[of "{x}" y]
  2585   show "\<not> open {x}"
  2586     by auto
  2587 qed
  2588 
  2589 lemma connectedI_interval:
  2590   fixes U :: "'a :: linear_continuum_topology set"
  2591   assumes *: "\<And>x y z. x \<in> U \<Longrightarrow> y \<in> U \<Longrightarrow> x \<le> z \<Longrightarrow> z \<le> y \<Longrightarrow> z \<in> U"
  2592   shows "connected U"
  2593 proof (rule connectedI)
  2594   { fix A B assume "open A" "open B" "A \<inter> B \<inter> U = {}" "U \<subseteq> A \<union> B"
  2595     fix x y assume "x < y" "x \<in> A" "y \<in> B" "x \<in> U" "y \<in> U"
  2596 
  2597     let ?z = "Inf (B \<inter> {x <..})"
  2598 
  2599     have "x \<le> ?z" "?z \<le> y"
  2600       using `y \<in> B` `x < y` by (auto intro: cInf_lower cInf_greatest)
  2601     with `x \<in> U` `y \<in> U` have "?z \<in> U"
  2602       by (rule *)
  2603     moreover have "?z \<notin> B \<inter> {x <..}"
  2604       using `open B` by (intro Inf_notin_open) auto
  2605     ultimately have "?z \<in> A"
  2606       using `x \<le> ?z` `A \<inter> B \<inter> U = {}` `x \<in> A` `U \<subseteq> A \<union> B` by auto
  2607 
  2608     { assume "?z < y"
  2609       obtain a where "?z < a" "{?z ..< a} \<subseteq> A"
  2610         using open_right[OF `open A` `?z \<in> A` `?z < y`] by auto
  2611       moreover obtain b where "b \<in> B" "x < b" "b < min a y"
  2612         using cInf_less_iff[of "B \<inter> {x <..}" "min a y"] `?z < a` `?z < y` `x < y` `y \<in> B`
  2613         by (auto intro: less_imp_le)
  2614       moreover have "?z \<le> b"
  2615         using `b \<in> B` `x < b`
  2616         by (intro cInf_lower) auto
  2617       moreover have "b \<in> U"
  2618         using `x \<le> ?z` `?z \<le> b` `b < min a y`
  2619         by (intro *[OF `x \<in> U` `y \<in> U`]) (auto simp: less_imp_le)
  2620       ultimately have "\<exists>b\<in>B. b \<in> A \<and> b \<in> U"
  2621         by (intro bexI[of _ b]) auto }
  2622     then have False
  2623       using `?z \<le> y` `?z \<in> A` `y \<in> B` `y \<in> U` `A \<inter> B \<inter> U = {}` unfolding le_less by blast }
  2624   note not_disjoint = this
  2625 
  2626   fix A B assume AB: "open A" "open B" "U \<subseteq> A \<union> B" "A \<inter> B \<inter> U = {}"
  2627   moreover assume "A \<inter> U \<noteq> {}" then obtain x where x: "x \<in> U" "x \<in> A" by auto
  2628   moreover assume "B \<inter> U \<noteq> {}" then obtain y where y: "y \<in> U" "y \<in> B" by auto
  2629   moreover note not_disjoint[of B A y x] not_disjoint[of A B x y]
  2630   ultimately show False by (cases x y rule: linorder_cases) auto
  2631 qed
  2632 
  2633 lemma connected_iff_interval:
  2634   fixes U :: "'a :: linear_continuum_topology set"
  2635   shows "connected U \<longleftrightarrow> (\<forall>x\<in>U. \<forall>y\<in>U. \<forall>z. x \<le> z \<longrightarrow> z \<le> y \<longrightarrow> z \<in> U)"
  2636   by (auto intro: connectedI_interval dest: connectedD_interval)
  2637 
  2638 lemma connected_UNIV[simp]: "connected (UNIV::'a::linear_continuum_topology set)"
  2639   unfolding connected_iff_interval by auto
  2640 
  2641 lemma connected_Ioi[simp]: "connected {a::'a::linear_continuum_topology <..}"
  2642   unfolding connected_iff_interval by auto
  2643 
  2644 lemma connected_Ici[simp]: "connected {a::'a::linear_continuum_topology ..}"
  2645   unfolding connected_iff_interval by auto
  2646 
  2647 lemma connected_Iio[simp]: "connected {..< a::'a::linear_continuum_topology}"
  2648   unfolding connected_iff_interval by auto
  2649 
  2650 lemma connected_Iic[simp]: "connected {.. a::'a::linear_continuum_topology}"
  2651   unfolding connected_iff_interval by auto
  2652 
  2653 lemma connected_Ioo[simp]: "connected {a <..< b::'a::linear_continuum_topology}"
  2654   unfolding connected_iff_interval by auto
  2655 
  2656 lemma connected_Ioc[simp]: "connected {a <.. b::'a::linear_continuum_topology}"
  2657   unfolding connected_iff_interval by auto
  2658 
  2659 lemma connected_Ico[simp]: "connected {a ..< b::'a::linear_continuum_topology}"
  2660   unfolding connected_iff_interval by auto
  2661 
  2662 lemma connected_Icc[simp]: "connected {a .. b::'a::linear_continuum_topology}"
  2663   unfolding connected_iff_interval by auto
  2664 
  2665 lemma connected_contains_Ioo: 
  2666   fixes A :: "'a :: linorder_topology set"
  2667   assumes A: "connected A" "a \<in> A" "b \<in> A" shows "{a <..< b} \<subseteq> A"
  2668   using connectedD_interval[OF A] by (simp add: subset_eq Ball_def less_imp_le)
  2669 
  2670 subsection {* Intermediate Value Theorem *}
  2671 
  2672 lemma IVT':
  2673   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2674   assumes y: "f a \<le> y" "y \<le> f b" "a \<le> b"
  2675   assumes *: "continuous_on {a .. b} f"
  2676   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2677 proof -
  2678   have "connected {a..b}"
  2679     unfolding connected_iff_interval by auto
  2680   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f a" "f b" y] y
  2681   show ?thesis
  2682     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2683 qed
  2684 
  2685 lemma IVT2':
  2686   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2687   assumes y: "f b \<le> y" "y \<le> f a" "a \<le> b"
  2688   assumes *: "continuous_on {a .. b} f"
  2689   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2690 proof -
  2691   have "connected {a..b}"
  2692     unfolding connected_iff_interval by auto
  2693   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f b" "f a" y] y
  2694   show ?thesis
  2695     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2696 qed
  2697 
  2698 lemma IVT:
  2699   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2700   shows "f a \<le> y \<Longrightarrow> y \<le> f b \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2701   by (rule IVT') (auto intro: continuous_at_imp_continuous_on)
  2702 
  2703 lemma IVT2:
  2704   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2705   shows "f b \<le> y \<Longrightarrow> y \<le> f a \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2706   by (rule IVT2') (auto intro: continuous_at_imp_continuous_on)
  2707 
  2708 lemma continuous_inj_imp_mono:
  2709   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2710   assumes x: "a < x" "x < b"
  2711   assumes cont: "continuous_on {a..b} f"
  2712   assumes inj: "inj_on f {a..b}"
  2713   shows "(f a < f x \<and> f x < f b) \<or> (f b < f x \<and> f x < f a)"
  2714 proof -
  2715   note I = inj_on_iff[OF inj]
  2716   { assume "f x < f a" "f x < f b"
  2717     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f x < f s"
  2718       using IVT'[of f x "min (f a) (f b)" b] IVT2'[of f x "min (f a) (f b)" a] x
  2719       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2720     with x I have False by auto }
  2721   moreover
  2722   { assume "f a < f x" "f b < f x"
  2723     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f s < f x"
  2724       using IVT'[of f a "max (f a) (f b)" x] IVT2'[of f b "max (f a) (f b)" x] x
  2725       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2726     with x I have False by auto }
  2727   ultimately show ?thesis
  2728     using I[of a x] I[of x b] x less_trans[OF x] by (auto simp add: le_less less_imp_neq neq_iff)
  2729 qed
  2730 
  2731 subsection {* Setup @{typ "'a filter"} for lifting and transfer *}
  2732 
  2733 context begin interpretation lifting_syntax .
  2734 
  2735 definition rel_filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> 'b filter \<Rightarrow> bool"
  2736 where "rel_filter R F G = ((R ===> op =) ===> op =) (Rep_filter F) (Rep_filter G)"
  2737 
  2738 lemma rel_filter_eventually:
  2739   "rel_filter R F G \<longleftrightarrow> 
  2740   ((R ===> op =) ===> op =) (\<lambda>P. eventually P F) (\<lambda>P. eventually P G)"
  2741 by(simp add: rel_filter_def eventually_def)
  2742 
  2743 lemma filtermap_id [simp, id_simps]: "filtermap id = id"
  2744 by(simp add: fun_eq_iff id_def filtermap_ident)
  2745 
  2746 lemma filtermap_id' [simp]: "filtermap (\<lambda>x. x) = (\<lambda>F. F)"
  2747 using filtermap_id unfolding id_def .
  2748 
  2749 lemma Quotient_filter [quot_map]:
  2750   assumes Q: "Quotient R Abs Rep T"
  2751   shows "Quotient (rel_filter R) (filtermap Abs) (filtermap Rep) (rel_filter T)"
  2752 unfolding Quotient_alt_def
  2753 proof(intro conjI strip)
  2754   from Q have *: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
  2755     unfolding Quotient_alt_def by blast
  2756 
  2757   fix F G
  2758   assume "rel_filter T F G"
  2759   thus "filtermap Abs F = G" unfolding filter_eq_iff
  2760     by(auto simp add: eventually_filtermap rel_filter_eventually * rel_funI del: iffI elim!: rel_funD)
  2761 next
  2762   from Q have *: "\<And>x. T (Rep x) x" unfolding Quotient_alt_def by blast
  2763 
  2764   fix F
  2765   show "rel_filter T (filtermap Rep F) F" 
  2766     by(auto elim: rel_funD intro: * intro!: ext arg_cong[where f="\<lambda>P. eventually P F"] rel_funI
  2767             del: iffI simp add: eventually_filtermap rel_filter_eventually)
  2768 qed(auto simp add: map_fun_def o_def eventually_filtermap filter_eq_iff fun_eq_iff rel_filter_eventually
  2769          fun_quotient[OF fun_quotient[OF Q identity_quotient] identity_quotient, unfolded Quotient_alt_def])
  2770 
  2771 lemma eventually_parametric [transfer_rule]:
  2772   "((A ===> op =) ===> rel_filter A ===> op =) eventually eventually"
  2773 by(simp add: rel_fun_def rel_filter_eventually)
  2774 
  2775 lemma rel_filter_eq [relator_eq]: "rel_filter op = = op ="
  2776 by(auto simp add: rel_filter_eventually rel_fun_eq fun_eq_iff filter_eq_iff)
  2777 
  2778 lemma rel_filter_mono [relator_mono]:
  2779   "A \<le> B \<Longrightarrow> rel_filter A \<le> rel_filter B"
  2780 unfolding rel_filter_eventually[abs_def]
  2781 by(rule le_funI)+(intro fun_mono fun_mono[THEN le_funD, THEN le_funD] order.refl)
  2782 
  2783 lemma rel_filter_conversep [simp]: "rel_filter A\<inverse>\<inverse> = (rel_filter A)\<inverse>\<inverse>"
  2784 by(auto simp add: rel_filter_eventually fun_eq_iff rel_fun_def)
  2785 
  2786 lemma is_filter_parametric_aux:
  2787   assumes "is_filter F"
  2788   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  2789   and [transfer_rule]: "((A ===> op =) ===> op =) F G"
  2790   shows "is_filter G"
  2791 proof -
  2792   interpret is_filter F by fact
  2793   show ?thesis
  2794   proof
  2795     have "F (\<lambda>_. True) = G (\<lambda>x. True)" by transfer_prover
  2796     thus "G (\<lambda>x. True)" by(simp add: True)
  2797   next
  2798     fix P' Q'
  2799     assume "G P'" "G Q'"
  2800     moreover
  2801     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
  2802     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  2803     have "F P = G P'" "F Q = G Q'" by transfer_prover+
  2804     ultimately have "F (\<lambda>x. P x \<and> Q x)" by(simp add: conj)
  2805     moreover have "F (\<lambda>x. P x \<and> Q x) = G (\<lambda>x. P' x \<and> Q' x)" by transfer_prover
  2806     ultimately show "G (\<lambda>x. P' x \<and> Q' x)" by simp
  2807   next
  2808     fix P' Q'
  2809     assume "\<forall>x. P' x \<longrightarrow> Q' x" "G P'"
  2810     moreover
  2811     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
  2812     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  2813     have "F P = G P'" by transfer_prover
  2814     moreover have "(\<forall>x. P x \<longrightarrow> Q x) \<longleftrightarrow> (\<forall>x. P' x \<longrightarrow> Q' x)" by transfer_prover
  2815     ultimately have "F Q" by(simp add: mono)
  2816     moreover have "F Q = G Q'" by transfer_prover
  2817     ultimately show "G Q'" by simp
  2818   qed
  2819 qed
  2820 
  2821 lemma is_filter_parametric [transfer_rule]:
  2822   "\<lbrakk> bi_total A; bi_unique A \<rbrakk>
  2823   \<Longrightarrow> (((A ===> op =) ===> op =) ===> op =) is_filter is_filter"
  2824 apply(rule rel_funI)
  2825 apply(rule iffI)
  2826  apply(erule (3) is_filter_parametric_aux)
  2827 apply(erule is_filter_parametric_aux[where A="conversep A"])
  2828 apply(auto simp add: rel_fun_def)
  2829 done
  2830 
  2831 lemma left_total_rel_filter [transfer_rule]:
  2832   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  2833   shows "left_total (rel_filter A)"
  2834 proof(rule left_totalI)
  2835   fix F :: "'a filter"
  2836   from bi_total_fun[OF bi_unique_fun[OF `bi_total A` bi_unique_eq] bi_total_eq]
  2837   obtain G where [transfer_rule]: "((A ===> op =) ===> op =) (\<lambda>P. eventually P F) G" 
  2838     unfolding  bi_total_def by blast
  2839   moreover have "is_filter (\<lambda>P. eventually P F) \<longleftrightarrow> is_filter G" by transfer_prover
  2840   hence "is_filter G" by(simp add: eventually_def is_filter_Rep_filter)
  2841   ultimately have "rel_filter A F (Abs_filter G)"
  2842     by(simp add: rel_filter_eventually eventually_Abs_filter)
  2843   thus "\<exists>G. rel_filter A F G" ..
  2844 qed
  2845 
  2846 lemma right_total_rel_filter [transfer_rule]:
  2847   "\<lbrakk> bi_total A; bi_unique A \<rbrakk> \<Longrightarrow> right_total (rel_filter A)"
  2848 using left_total_rel_filter[of "A\<inverse>\<inverse>"] by simp
  2849 
  2850 lemma bi_total_rel_filter [transfer_rule]:
  2851   assumes "bi_total A" "bi_unique A"
  2852   shows "bi_total (rel_filter A)"
  2853 unfolding bi_total_alt_def using assms
  2854 by(simp add: left_total_rel_filter right_total_rel_filter)
  2855 
  2856 lemma left_unique_rel_filter [transfer_rule]:
  2857   assumes "left_unique A"
  2858   shows "left_unique (rel_filter A)"
  2859 proof(rule left_uniqueI)
  2860   fix F F' G
  2861   assume [transfer_rule]: "rel_filter A F G" "rel_filter A F' G"
  2862   show "F = F'"
  2863     unfolding filter_eq_iff
  2864   proof
  2865     fix P :: "'a \<Rightarrow> bool"
  2866     obtain P' where [transfer_rule]: "(A ===> op =) P P'"
  2867       using left_total_fun[OF assms left_total_eq] unfolding left_total_def by blast
  2868     have "eventually P F = eventually P' G" 
  2869       and "eventually P F' = eventually P' G" by transfer_prover+
  2870     thus "eventually P F = eventually P F'" by simp
  2871   qed
  2872 qed
  2873 
  2874 lemma right_unique_rel_filter [transfer_rule]:
  2875   "right_unique A \<Longrightarrow> right_unique (rel_filter A)"
  2876 using left_unique_rel_filter[of "A\<inverse>\<inverse>"] by simp
  2877 
  2878 lemma bi_unique_rel_filter [transfer_rule]:
  2879   "bi_unique A \<Longrightarrow> bi_unique (rel_filter A)"
  2880 by(simp add: bi_unique_alt_def left_unique_rel_filter right_unique_rel_filter)
  2881 
  2882 lemma top_filter_parametric [transfer_rule]:
  2883   "bi_total A \<Longrightarrow> (rel_filter A) top top"
  2884 by(simp add: rel_filter_eventually All_transfer)
  2885 
  2886 lemma bot_filter_parametric [transfer_rule]: "(rel_filter A) bot bot"
  2887 by(simp add: rel_filter_eventually rel_fun_def)
  2888 
  2889 lemma sup_filter_parametric [transfer_rule]:
  2890   "(rel_filter A ===> rel_filter A ===> rel_filter A) sup sup"
  2891 by(fastforce simp add: rel_filter_eventually[abs_def] eventually_sup dest: rel_funD)
  2892 
  2893 lemma Sup_filter_parametric [transfer_rule]:
  2894   "(rel_set (rel_filter A) ===> rel_filter A) Sup Sup"
  2895 proof(rule rel_funI)
  2896   fix S T
  2897   assume [transfer_rule]: "rel_set (rel_filter A) S T"
  2898   show "rel_filter A (Sup S) (Sup T)"
  2899     by(simp add: rel_filter_eventually eventually_Sup) transfer_prover
  2900 qed
  2901 
  2902 lemma principal_parametric [transfer_rule]:
  2903   "(rel_set A ===> rel_filter A) principal principal"
  2904 proof(rule rel_funI)
  2905   fix S S'
  2906   assume [transfer_rule]: "rel_set A S S'"
  2907   show "rel_filter A (principal S) (principal S')"
  2908     by(simp add: rel_filter_eventually eventually_principal) transfer_prover
  2909 qed
  2910 
  2911 context
  2912   fixes A :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
  2913   assumes [transfer_rule]: "bi_unique A" 
  2914 begin
  2915 
  2916 lemma le_filter_parametric [transfer_rule]:
  2917   "(rel_filter A ===> rel_filter A ===> op =) op \<le> op \<le>"
  2918 unfolding le_filter_def[abs_def] by transfer_prover
  2919 
  2920 lemma less_filter_parametric [transfer_rule]:
  2921   "(rel_filter A ===> rel_filter A ===> op =) op < op <"
  2922 unfolding less_filter_def[abs_def] by transfer_prover
  2923 
  2924 context
  2925   assumes [transfer_rule]: "bi_total A"
  2926 begin
  2927 
  2928 lemma Inf_filter_parametric [transfer_rule]:
  2929   "(rel_set (rel_filter A) ===> rel_filter A) Inf Inf"
  2930 unfolding Inf_filter_def[abs_def] by transfer_prover
  2931 
  2932 lemma inf_filter_parametric [transfer_rule]:
  2933   "(rel_filter A ===> rel_filter A ===> rel_filter A) inf inf"
  2934 proof(intro rel_funI)+
  2935   fix F F' G G'
  2936   assume [transfer_rule]: "rel_filter A F F'" "rel_filter A G G'"
  2937   have "rel_filter A (Inf {F, G}) (Inf {F', G'})" by transfer_prover
  2938   thus "rel_filter A (inf F G) (inf F' G')" by simp
  2939 qed
  2940 
  2941 end
  2942 
  2943 end
  2944 
  2945 end
  2946 
  2947 end