src/HOL/UNITY/Follows.thy
author haftmann
Fri Oct 10 19:55:32 2014 +0200 (2014-10-10)
changeset 58646 cd63a4b12a33
parent 56248 67dc9549fa15
child 58889 5b7a9633cfa8
permissions -rw-r--r--
specialized specification: avoid trivial instances
     1 (*  Title:      HOL/UNITY/Follows.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1998  University of Cambridge
     4 *)
     5 
     6 header{*The Follows Relation of Charpentier and Sivilotte*}
     7 
     8 theory Follows
     9 imports SubstAx ListOrder "~~/src/HOL/Library/Multiset"
    10 begin
    11 
    12 definition Follows :: "['a => 'b::{order}, 'a => 'b::{order}] => 'a program set" (infixl "Fols" 65) where
    13    "f Fols g == Increasing g \<inter> Increasing f Int
    14                 Always {s. f s \<le> g s} Int
    15                 (\<Inter>k. {s. k \<le> g s} LeadsTo {s. k \<le> f s})"
    16 
    17 
    18 (*Does this hold for "invariant"?*)
    19 lemma mono_Always_o:
    20      "mono h ==> Always {s. f s \<le> g s} \<subseteq> Always {s. h (f s) \<le> h (g s)}"
    21 apply (simp add: Always_eq_includes_reachable)
    22 apply (blast intro: monoD)
    23 done
    24 
    25 lemma mono_LeadsTo_o:
    26      "mono (h::'a::order => 'b::order)  
    27       ==> (\<Inter>j. {s. j \<le> g s} LeadsTo {s. j \<le> f s}) \<subseteq>  
    28           (\<Inter>k. {s. k \<le> h (g s)} LeadsTo {s. k \<le> h (f s)})"
    29 apply auto
    30 apply (rule single_LeadsTo_I)
    31 apply (drule_tac x = "g s" in spec)
    32 apply (erule LeadsTo_weaken)
    33 apply (blast intro: monoD order_trans)+
    34 done
    35 
    36 lemma Follows_constant [iff]: "F \<in> (%s. c) Fols (%s. c)"
    37 by (simp add: Follows_def)
    38 
    39 lemma mono_Follows_o: "mono h ==> f Fols g \<subseteq> (h o f) Fols (h o g)"
    40 by (auto simp add: Follows_def mono_Increasing_o [THEN [2] rev_subsetD]
    41                    mono_Always_o [THEN [2] rev_subsetD]
    42                    mono_LeadsTo_o [THEN [2] rev_subsetD, THEN INT_D])
    43 
    44 lemma mono_Follows_apply:
    45      "mono h ==> f Fols g \<subseteq> (%x. h (f x)) Fols (%x. h (g x))"
    46 apply (drule mono_Follows_o)
    47 apply (force simp add: o_def)
    48 done
    49 
    50 lemma Follows_trans: 
    51      "[| F \<in> f Fols g;  F \<in> g Fols h |] ==> F \<in> f Fols h"
    52 apply (simp add: Follows_def)
    53 apply (simp add: Always_eq_includes_reachable)
    54 apply (blast intro: order_trans LeadsTo_Trans)
    55 done
    56 
    57 
    58 subsection{*Destruction rules*}
    59 
    60 lemma Follows_Increasing1: "F \<in> f Fols g ==> F \<in> Increasing f"
    61 by (simp add: Follows_def)
    62 
    63 lemma Follows_Increasing2: "F \<in> f Fols g ==> F \<in> Increasing g"
    64 by (simp add: Follows_def)
    65 
    66 lemma Follows_Bounded: "F \<in> f Fols g ==> F \<in> Always {s. f s \<le> g s}"
    67 by (simp add: Follows_def)
    68 
    69 lemma Follows_LeadsTo: 
    70      "F \<in> f Fols g ==> F \<in> {s. k \<le> g s} LeadsTo {s. k \<le> f s}"
    71 by (simp add: Follows_def)
    72 
    73 lemma Follows_LeadsTo_pfixLe:
    74      "F \<in> f Fols g ==> F \<in> {s. k pfixLe g s} LeadsTo {s. k pfixLe f s}"
    75 apply (rule single_LeadsTo_I, clarify)
    76 apply (drule_tac k="g s" in Follows_LeadsTo)
    77 apply (erule LeadsTo_weaken)
    78  apply blast 
    79 apply (blast intro: pfixLe_trans prefix_imp_pfixLe)
    80 done
    81 
    82 lemma Follows_LeadsTo_pfixGe:
    83      "F \<in> f Fols g ==> F \<in> {s. k pfixGe g s} LeadsTo {s. k pfixGe f s}"
    84 apply (rule single_LeadsTo_I, clarify)
    85 apply (drule_tac k="g s" in Follows_LeadsTo)
    86 apply (erule LeadsTo_weaken)
    87  apply blast 
    88 apply (blast intro: pfixGe_trans prefix_imp_pfixGe)
    89 done
    90 
    91 
    92 lemma Always_Follows1: 
    93      "[| F \<in> Always {s. f s = f' s}; F \<in> f Fols g |] ==> F \<in> f' Fols g"
    94 
    95 apply (simp add: Follows_def Increasing_def Stable_def, auto)
    96 apply (erule_tac [3] Always_LeadsTo_weaken)
    97 apply (erule_tac A = "{s. x \<le> f s}" and A' = "{s. x \<le> f s}" 
    98        in Always_Constrains_weaken, auto)
    99 apply (drule Always_Int_I, assumption)
   100 apply (force intro: Always_weaken)
   101 done
   102 
   103 lemma Always_Follows2: 
   104      "[| F \<in> Always {s. g s = g' s}; F \<in> f Fols g |] ==> F \<in> f Fols g'"
   105 apply (simp add: Follows_def Increasing_def Stable_def, auto)
   106 apply (erule_tac [3] Always_LeadsTo_weaken)
   107 apply (erule_tac A = "{s. x \<le> g s}" and A' = "{s. x \<le> g s}"
   108        in Always_Constrains_weaken, auto)
   109 apply (drule Always_Int_I, assumption)
   110 apply (force intro: Always_weaken)
   111 done
   112 
   113 
   114 subsection{*Union properties (with the subset ordering)*}
   115 
   116 (*Can replace "Un" by any sup.  But existing max only works for linorders.*)
   117 
   118 lemma increasing_Un: 
   119     "[| F \<in> increasing f;  F \<in> increasing g |]  
   120      ==> F \<in> increasing (%s. (f s) \<union> (g s))"
   121 apply (simp add: increasing_def stable_def constrains_def, auto)
   122 apply (drule_tac x = "f xb" in spec)
   123 apply (drule_tac x = "g xb" in spec)
   124 apply (blast dest!: bspec)
   125 done
   126 
   127 lemma Increasing_Un: 
   128     "[| F \<in> Increasing f;  F \<in> Increasing g |]  
   129      ==> F \<in> Increasing (%s. (f s) \<union> (g s))"
   130 apply (auto simp add: Increasing_def Stable_def Constrains_def
   131                       stable_def constrains_def)
   132 apply (drule_tac x = "f xb" in spec)
   133 apply (drule_tac x = "g xb" in spec)
   134 apply (blast dest!: bspec)
   135 done
   136 
   137 
   138 lemma Always_Un:
   139      "[| F \<in> Always {s. f' s \<le> f s}; F \<in> Always {s. g' s \<le> g s} |]  
   140       ==> F \<in> Always {s. f' s \<union> g' s \<le> f s \<union> g s}"
   141 by (simp add: Always_eq_includes_reachable, blast)
   142 
   143 (*Lemma to re-use the argument that one variable increases (progress)
   144   while the other variable doesn't decrease (safety)*)
   145 lemma Follows_Un_lemma:
   146      "[| F \<in> Increasing f; F \<in> Increasing g;  
   147          F \<in> Increasing g'; F \<in> Always {s. f' s \<le> f s}; 
   148          \<forall>k. F \<in> {s. k \<le> f s} LeadsTo {s. k \<le> f' s} |] 
   149       ==> F \<in> {s. k \<le> f s \<union> g s} LeadsTo {s. k \<le> f' s \<union> g s}"
   150 apply (rule single_LeadsTo_I)
   151 apply (drule_tac x = "f s" in IncreasingD)
   152 apply (drule_tac x = "g s" in IncreasingD)
   153 apply (rule LeadsTo_weaken)
   154 apply (rule PSP_Stable)
   155 apply (erule_tac x = "f s" in spec)
   156 apply (erule Stable_Int, assumption, blast+)
   157 done
   158 
   159 lemma Follows_Un: 
   160     "[| F \<in> f' Fols f;  F \<in> g' Fols g |]  
   161      ==> F \<in> (%s. (f' s) \<union> (g' s)) Fols (%s. (f s) \<union> (g s))"
   162 apply (simp add: Follows_def Increasing_Un Always_Un del: Un_subset_iff sup.bounded_iff, auto)
   163 apply (rule LeadsTo_Trans)
   164 apply (blast intro: Follows_Un_lemma)
   165 (*Weakening is used to exchange Un's arguments*)
   166 apply (blast intro: Follows_Un_lemma [THEN LeadsTo_weaken])
   167 done
   168 
   169 
   170 subsection{*Multiset union properties (with the multiset ordering)*}
   171 
   172 lemma increasing_union: 
   173     "[| F \<in> increasing f;  F \<in> increasing g |]  
   174      ==> F \<in> increasing (%s. (f s) + (g s :: ('a::order) multiset))"
   175 apply (simp add: increasing_def stable_def constrains_def, auto)
   176 apply (drule_tac x = "f xb" in spec)
   177 apply (drule_tac x = "g xb" in spec)
   178 apply (drule bspec, assumption) 
   179 apply (blast intro: add_mono order_trans)
   180 done
   181 
   182 lemma Increasing_union: 
   183     "[| F \<in> Increasing f;  F \<in> Increasing g |]  
   184      ==> F \<in> Increasing (%s. (f s) + (g s :: ('a::order) multiset))"
   185 apply (auto simp add: Increasing_def Stable_def Constrains_def
   186                       stable_def constrains_def)
   187 apply (drule_tac x = "f xb" in spec)
   188 apply (drule_tac x = "g xb" in spec)
   189 apply (drule bspec, assumption) 
   190 apply (blast intro: add_mono order_trans)
   191 done
   192 
   193 lemma Always_union:
   194      "[| F \<in> Always {s. f' s \<le> f s}; F \<in> Always {s. g' s \<le> g s} |]  
   195       ==> F \<in> Always {s. f' s + g' s \<le> f s + (g s :: ('a::order) multiset)}"
   196 apply (simp add: Always_eq_includes_reachable)
   197 apply (blast intro: add_mono)
   198 done
   199 
   200 (*Except the last line, IDENTICAL to the proof script for Follows_Un_lemma*)
   201 lemma Follows_union_lemma:
   202      "[| F \<in> Increasing f; F \<in> Increasing g;  
   203          F \<in> Increasing g'; F \<in> Always {s. f' s \<le> f s}; 
   204          \<forall>k::('a::order) multiset.  
   205            F \<in> {s. k \<le> f s} LeadsTo {s. k \<le> f' s} |] 
   206       ==> F \<in> {s. k \<le> f s + g s} LeadsTo {s. k \<le> f' s + g s}"
   207 apply (rule single_LeadsTo_I)
   208 apply (drule_tac x = "f s" in IncreasingD)
   209 apply (drule_tac x = "g s" in IncreasingD)
   210 apply (rule LeadsTo_weaken)
   211 apply (rule PSP_Stable)
   212 apply (erule_tac x = "f s" in spec)
   213 apply (erule Stable_Int, assumption, blast)
   214 apply (blast intro: add_mono order_trans)
   215 done
   216 
   217 (*The !! is there to influence to effect of permutative rewriting at the end*)
   218 lemma Follows_union: 
   219      "!!g g' ::'b => ('a::order) multiset.  
   220         [| F \<in> f' Fols f;  F \<in> g' Fols g |]  
   221         ==> F \<in> (%s. (f' s) + (g' s)) Fols (%s. (f s) + (g s))"
   222 apply (simp add: Follows_def)
   223 apply (simp add: Increasing_union Always_union, auto)
   224 apply (rule LeadsTo_Trans)
   225 apply (blast intro: Follows_union_lemma)
   226 (*now exchange union's arguments*)
   227 apply (simp add: union_commute)
   228 apply (blast intro: Follows_union_lemma)
   229 done
   230 
   231 lemma Follows_setsum:
   232      "!!f ::['c,'b] => ('a::order) multiset.  
   233         [| \<forall>i \<in> I. F \<in> f' i Fols f i;  finite I |]  
   234         ==> F \<in> (%s. \<Sum>i \<in> I. f' i s) Fols (%s. \<Sum>i \<in> I. f i s)"
   235 apply (erule rev_mp)
   236 apply (erule finite_induct, simp) 
   237 apply (simp add: Follows_union)
   238 done
   239 
   240 
   241 (*Currently UNUSED, but possibly of interest*)
   242 lemma Increasing_imp_Stable_pfixGe:
   243      "F \<in> Increasing func ==> F \<in> Stable {s. h pfixGe (func s)}"
   244 apply (simp add: Increasing_def Stable_def Constrains_def constrains_def)
   245 apply (blast intro: trans_Ge [THEN trans_genPrefix, THEN transD] 
   246                     prefix_imp_pfixGe)
   247 done
   248 
   249 (*Currently UNUSED, but possibly of interest*)
   250 lemma LeadsTo_le_imp_pfixGe:
   251      "\<forall>z. F \<in> {s. z \<le> f s} LeadsTo {s. z \<le> g s}  
   252       ==> F \<in> {s. z pfixGe f s} LeadsTo {s. z pfixGe g s}"
   253 apply (rule single_LeadsTo_I)
   254 apply (drule_tac x = "f s" in spec)
   255 apply (erule LeadsTo_weaken)
   256  prefer 2
   257  apply (blast intro: trans_Ge [THEN trans_genPrefix, THEN transD] 
   258                      prefix_imp_pfixGe, blast)
   259 done
   260 
   261 end