author haftmann
Fri Oct 10 19:55:32 2014 +0200 (2014-10-10)
changeset 58646 cd63a4b12a33
parent 58184 db1381d811ab
child 58889 5b7a9633cfa8
permissions -rw-r--r--
specialized specification: avoid trivial instances
     1 (*  Title:      HOL/Zorn.thy
     2     Author:     Jacques D. Fleuriot
     3     Author:     Tobias Nipkow, TUM
     4     Author:     Christian Sternagel, JAIST
     6 Zorn's Lemma (ported from Larry Paulson's Zorn.thy in ZF).
     7 The well-ordering theorem.
     8 *)
    10 header {* Zorn's Lemma *}
    12 theory Zorn
    13 imports Order_Relation Hilbert_Choice
    14 begin
    16 subsection {* Zorn's Lemma for the Subset Relation *}
    18 subsubsection {* Results that do not require an order *}
    20 text {*Let @{text P} be a binary predicate on the set @{text A}.*}
    21 locale pred_on =
    22   fixes A :: "'a set"
    23     and P :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "\<sqsubset>" 50)
    24 begin
    26 abbreviation Peq :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "\<sqsubseteq>" 50) where
    27   "x \<sqsubseteq> y \<equiv> P\<^sup>=\<^sup>= x y"
    29 text {*A chain is a totally ordered subset of @{term A}.*}
    30 definition chain :: "'a set \<Rightarrow> bool" where
    31   "chain C \<longleftrightarrow> C \<subseteq> A \<and> (\<forall>x\<in>C. \<forall>y\<in>C. x \<sqsubseteq> y \<or> y \<sqsubseteq> x)"
    33 text {*We call a chain that is a proper superset of some set @{term X},
    34 but not necessarily a chain itself, a superchain of @{term X}.*}
    35 abbreviation superchain :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" (infix "<c" 50) where
    36   "X <c C \<equiv> chain C \<and> X \<subset> C"
    38 text {*A maximal chain is a chain that does not have a superchain.*}
    39 definition maxchain :: "'a set \<Rightarrow> bool" where
    40   "maxchain C \<longleftrightarrow> chain C \<and> \<not> (\<exists>S. C <c S)"
    42 text {*We define the successor of a set to be an arbitrary
    43 superchain, if such exists, or the set itself, otherwise.*}
    44 definition suc :: "'a set \<Rightarrow> 'a set" where
    45   "suc C = (if \<not> chain C \<or> maxchain C then C else (SOME D. C <c D))"
    47 lemma chainI [Pure.intro?]:
    48   "\<lbrakk>C \<subseteq> A; \<And>x y. \<lbrakk>x \<in> C; y \<in> C\<rbrakk> \<Longrightarrow> x \<sqsubseteq> y \<or> y \<sqsubseteq> x\<rbrakk> \<Longrightarrow> chain C"
    49   unfolding chain_def by blast
    51 lemma chain_total:
    52   "chain C \<Longrightarrow> x \<in> C \<Longrightarrow> y \<in> C \<Longrightarrow> x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
    53   by (simp add: chain_def)
    55 lemma not_chain_suc [simp]: "\<not> chain X \<Longrightarrow> suc X = X"
    56   by (simp add: suc_def)
    58 lemma maxchain_suc [simp]: "maxchain X \<Longrightarrow> suc X = X"
    59   by (simp add: suc_def)
    61 lemma suc_subset: "X \<subseteq> suc X"
    62   by (auto simp: suc_def maxchain_def intro: someI2)
    64 lemma chain_empty [simp]: "chain {}"
    65   by (auto simp: chain_def)
    67 lemma not_maxchain_Some:
    68   "chain C \<Longrightarrow> \<not> maxchain C \<Longrightarrow> C <c (SOME D. C <c D)"
    69   by (rule someI_ex) (auto simp: maxchain_def)
    71 lemma suc_not_equals:
    72   "chain C \<Longrightarrow> \<not> maxchain C \<Longrightarrow> suc C \<noteq> C"
    73   using not_maxchain_Some by (auto simp: suc_def)
    75 lemma subset_suc:
    76   assumes "X \<subseteq> Y" shows "X \<subseteq> suc Y"
    77   using assms by (rule subset_trans) (rule suc_subset)
    79 text {*We build a set @{term \<C>} that is closed under applications
    80 of @{term suc} and contains the union of all its subsets.*}
    81 inductive_set suc_Union_closed ("\<C>") where
    82   suc: "X \<in> \<C> \<Longrightarrow> suc X \<in> \<C>" |
    83   Union [unfolded Pow_iff]: "X \<in> Pow \<C> \<Longrightarrow> \<Union>X \<in> \<C>"
    85 text {*Since the empty set as well as the set itself is a subset of
    86 every set, @{term \<C>} contains at least @{term "{} \<in> \<C>"} and
    87 @{term "\<Union>\<C> \<in> \<C>"}.*}
    88 lemma
    89   suc_Union_closed_empty: "{} \<in> \<C>" and
    90   suc_Union_closed_Union: "\<Union>\<C> \<in> \<C>"
    91   using Union [of "{}"] and Union [of "\<C>"] by simp+
    92 text {*Thus closure under @{term suc} will hit a maximal chain
    93 eventually, as is shown below.*}
    95 lemma suc_Union_closed_induct [consumes 1, case_names suc Union,
    96   induct pred: suc_Union_closed]:
    97   assumes "X \<in> \<C>"
    98     and "\<And>X. \<lbrakk>X \<in> \<C>; Q X\<rbrakk> \<Longrightarrow> Q (suc X)"
    99     and "\<And>X. \<lbrakk>X \<subseteq> \<C>; \<forall>x\<in>X. Q x\<rbrakk> \<Longrightarrow> Q (\<Union>X)"
   100   shows "Q X"
   101   using assms by (induct) blast+
   103 lemma suc_Union_closed_cases [consumes 1, case_names suc Union,
   104   cases pred: suc_Union_closed]:
   105   assumes "X \<in> \<C>"
   106     and "\<And>Y. \<lbrakk>X = suc Y; Y \<in> \<C>\<rbrakk> \<Longrightarrow> Q"
   107     and "\<And>Y. \<lbrakk>X = \<Union>Y; Y \<subseteq> \<C>\<rbrakk> \<Longrightarrow> Q"
   108   shows "Q"
   109   using assms by (cases) simp+
   111 text {*On chains, @{term suc} yields a chain.*}
   112 lemma chain_suc:
   113   assumes "chain X" shows "chain (suc X)"
   114   using assms
   115   by (cases "\<not> chain X \<or> maxchain X")
   116      (force simp: suc_def dest: not_maxchain_Some)+
   118 lemma chain_sucD:
   119   assumes "chain X" shows "suc X \<subseteq> A \<and> chain (suc X)"
   120 proof -
   121   from `chain X` have *: "chain (suc X)" by (rule chain_suc)
   122   then have "suc X \<subseteq> A" unfolding chain_def by blast
   123   with * show ?thesis by blast
   124 qed
   126 lemma suc_Union_closed_total':
   127   assumes "X \<in> \<C>" and "Y \<in> \<C>"
   128     and *: "\<And>Z. Z \<in> \<C> \<Longrightarrow> Z \<subseteq> Y \<Longrightarrow> Z = Y \<or> suc Z \<subseteq> Y"
   129   shows "X \<subseteq> Y \<or> suc Y \<subseteq> X"
   130   using `X \<in> \<C>`
   131 proof (induct)
   132   case (suc X)
   133   with * show ?case by (blast del: subsetI intro: subset_suc)
   134 qed blast
   136 lemma suc_Union_closed_subsetD:
   137   assumes "Y \<subseteq> X" and "X \<in> \<C>" and "Y \<in> \<C>"
   138   shows "X = Y \<or> suc Y \<subseteq> X"
   139   using assms(2-, 1)
   140 proof (induct arbitrary: Y)
   141   case (suc X)
   142   note * = `\<And>Y. \<lbrakk>Y \<in> \<C>; Y \<subseteq> X\<rbrakk> \<Longrightarrow> X = Y \<or> suc Y \<subseteq> X`
   143   with suc_Union_closed_total' [OF `Y \<in> \<C>` `X \<in> \<C>`]
   144     have "Y \<subseteq> X \<or> suc X \<subseteq> Y" by blast
   145   then show ?case
   146   proof
   147     assume "Y \<subseteq> X"
   148     with * and `Y \<in> \<C>` have "X = Y \<or> suc Y \<subseteq> X" by blast
   149     then show ?thesis
   150     proof
   151       assume "X = Y" then show ?thesis by simp
   152     next
   153       assume "suc Y \<subseteq> X"
   154       then have "suc Y \<subseteq> suc X" by (rule subset_suc)
   155       then show ?thesis by simp
   156     qed
   157   next
   158     assume "suc X \<subseteq> Y"
   159     with `Y \<subseteq> suc X` show ?thesis by blast
   160   qed
   161 next
   162   case (Union X)
   163   show ?case
   164   proof (rule ccontr)
   165     assume "\<not> ?thesis"
   166     with `Y \<subseteq> \<Union>X` obtain x y z
   167     where "\<not> suc Y \<subseteq> \<Union>X"
   168       and "x \<in> X" and "y \<in> x" and "y \<notin> Y"
   169       and "z \<in> suc Y" and "\<forall>x\<in>X. z \<notin> x" by blast
   170     with `X \<subseteq> \<C>` have "x \<in> \<C>" by blast
   171     from Union and `x \<in> X`
   172       have *: "\<And>y. \<lbrakk>y \<in> \<C>; y \<subseteq> x\<rbrakk> \<Longrightarrow> x = y \<or> suc y \<subseteq> x" by blast
   173     with suc_Union_closed_total' [OF `Y \<in> \<C>` `x \<in> \<C>`]
   174       have "Y \<subseteq> x \<or> suc x \<subseteq> Y" by blast
   175     then show False
   176     proof
   177       assume "Y \<subseteq> x"
   178       with * [OF `Y \<in> \<C>`] have "x = Y \<or> suc Y \<subseteq> x" by blast
   179       then show False
   180       proof
   181         assume "x = Y" with `y \<in> x` and `y \<notin> Y` show False by blast
   182       next
   183         assume "suc Y \<subseteq> x"
   184         with `x \<in> X` have "suc Y \<subseteq> \<Union>X" by blast
   185         with `\<not> suc Y \<subseteq> \<Union>X` show False by contradiction
   186       qed
   187     next
   188       assume "suc x \<subseteq> Y"
   189       moreover from suc_subset and `y \<in> x` have "y \<in> suc x" by blast
   190       ultimately show False using `y \<notin> Y` by blast
   191     qed
   192   qed
   193 qed
   195 text {*The elements of @{term \<C>} are totally ordered by the subset relation.*}
   196 lemma suc_Union_closed_total:
   197   assumes "X \<in> \<C>" and "Y \<in> \<C>"
   198   shows "X \<subseteq> Y \<or> Y \<subseteq> X"
   199 proof (cases "\<forall>Z\<in>\<C>. Z \<subseteq> Y \<longrightarrow> Z = Y \<or> suc Z \<subseteq> Y")
   200   case True
   201   with suc_Union_closed_total' [OF assms]
   202     have "X \<subseteq> Y \<or> suc Y \<subseteq> X" by blast
   203   then show ?thesis using suc_subset [of Y] by blast
   204 next
   205   case False
   206   then obtain Z
   207     where "Z \<in> \<C>" and "Z \<subseteq> Y" and "Z \<noteq> Y" and "\<not> suc Z \<subseteq> Y" by blast
   208   with suc_Union_closed_subsetD and `Y \<in> \<C>` show ?thesis by blast
   209 qed
   211 text {*Once we hit a fixed point w.r.t. @{term suc}, all other elements
   212 of @{term \<C>} are subsets of this fixed point.*}
   213 lemma suc_Union_closed_suc:
   214   assumes "X \<in> \<C>" and "Y \<in> \<C>" and "suc Y = Y"
   215   shows "X \<subseteq> Y"
   216 using `X \<in> \<C>`
   217 proof (induct)
   218   case (suc X)
   219   with `Y \<in> \<C>` and suc_Union_closed_subsetD
   220     have "X = Y \<or> suc X \<subseteq> Y" by blast
   221   then show ?case by (auto simp: `suc Y = Y`)
   222 qed blast
   224 lemma eq_suc_Union:
   225   assumes "X \<in> \<C>"
   226   shows "suc X = X \<longleftrightarrow> X = \<Union>\<C>"
   227 proof
   228   assume "suc X = X"
   229   with suc_Union_closed_suc [OF suc_Union_closed_Union `X \<in> \<C>`]
   230     have "\<Union>\<C> \<subseteq> X" .
   231   with `X \<in> \<C>` show "X = \<Union>\<C>" by blast
   232 next
   233   from `X \<in> \<C>` have "suc X \<in> \<C>" by (rule suc)
   234   then have "suc X \<subseteq> \<Union>\<C>" by blast
   235   moreover assume "X = \<Union>\<C>"
   236   ultimately have "suc X \<subseteq> X" by simp
   237   moreover have "X \<subseteq> suc X" by (rule suc_subset)
   238   ultimately show "suc X = X" ..
   239 qed
   241 lemma suc_in_carrier:
   242   assumes "X \<subseteq> A"
   243   shows "suc X \<subseteq> A"
   244   using assms
   245   by (cases "\<not> chain X \<or> maxchain X")
   246      (auto dest: chain_sucD)
   248 lemma suc_Union_closed_in_carrier:
   249   assumes "X \<in> \<C>"
   250   shows "X \<subseteq> A"
   251   using assms
   252   by (induct) (auto dest: suc_in_carrier)
   254 text {*All elements of @{term \<C>} are chains.*}
   255 lemma suc_Union_closed_chain:
   256   assumes "X \<in> \<C>"
   257   shows "chain X"
   258 using assms
   259 proof (induct)
   260   case (suc X) then show ?case using not_maxchain_Some by (simp add: suc_def)
   261 next
   262   case (Union X)
   263   then have "\<Union>X \<subseteq> A" by (auto dest: suc_Union_closed_in_carrier)
   264   moreover have "\<forall>x\<in>\<Union>X. \<forall>y\<in>\<Union>X. x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
   265   proof (intro ballI)
   266     fix x y
   267     assume "x \<in> \<Union>X" and "y \<in> \<Union>X"
   268     then obtain u v where "x \<in> u" and "u \<in> X" and "y \<in> v" and "v \<in> X" by blast
   269     with Union have "u \<in> \<C>" and "v \<in> \<C>" and "chain u" and "chain v" by blast+
   270     with suc_Union_closed_total have "u \<subseteq> v \<or> v \<subseteq> u" by blast
   271     then show "x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
   272     proof
   273       assume "u \<subseteq> v"
   274       from `chain v` show ?thesis
   275       proof (rule chain_total)
   276         show "y \<in> v" by fact
   277         show "x \<in> v" using `u \<subseteq> v` and `x \<in> u` by blast
   278       qed
   279     next
   280       assume "v \<subseteq> u"
   281       from `chain u` show ?thesis
   282       proof (rule chain_total)
   283         show "x \<in> u" by fact
   284         show "y \<in> u" using `v \<subseteq> u` and `y \<in> v` by blast
   285       qed
   286     qed
   287   qed
   288   ultimately show ?case unfolding chain_def ..
   289 qed
   291 subsubsection {* Hausdorff's Maximum Principle *}
   293 text {*There exists a maximal totally ordered subset of @{term A}. (Note that we do not
   294 require @{term A} to be partially ordered.)*}
   296 theorem Hausdorff: "\<exists>C. maxchain C"
   297 proof -
   298   let ?M = "\<Union>\<C>"
   299   have "maxchain ?M"
   300   proof (rule ccontr)
   301     assume "\<not> maxchain ?M"
   302     then have "suc ?M \<noteq> ?M"
   303       using suc_not_equals and
   304       suc_Union_closed_chain [OF suc_Union_closed_Union] by simp
   305     moreover have "suc ?M = ?M"
   306       using eq_suc_Union [OF suc_Union_closed_Union] by simp
   307     ultimately show False by contradiction
   308   qed
   309   then show ?thesis by blast
   310 qed
   312 text {*Make notation @{term \<C>} available again.*}
   313 no_notation suc_Union_closed ("\<C>")
   315 lemma chain_extend:
   316   "chain C \<Longrightarrow> z \<in> A \<Longrightarrow> \<forall>x\<in>C. x \<sqsubseteq> z \<Longrightarrow> chain ({z} \<union> C)"
   317   unfolding chain_def by blast
   319 lemma maxchain_imp_chain:
   320   "maxchain C \<Longrightarrow> chain C"
   321   by (simp add: maxchain_def)
   323 end
   325 text {*Hide constant @{const pred_on.suc_Union_closed}, which was just needed
   326 for the proof of Hausforff's maximum principle.*}
   327 hide_const pred_on.suc_Union_closed
   329 lemma chain_mono:
   330   assumes "\<And>x y. \<lbrakk>x \<in> A; y \<in> A; P x y\<rbrakk> \<Longrightarrow> Q x y"
   331     and "pred_on.chain A P C"
   332   shows "pred_on.chain A Q C"
   333   using assms unfolding pred_on.chain_def by blast
   335 subsubsection {* Results for the proper subset relation *}
   337 interpretation subset: pred_on "A" "op \<subset>" for A .
   339 lemma subset_maxchain_max:
   340   assumes "subset.maxchain A C" and "X \<in> A" and "\<Union>C \<subseteq> X"
   341   shows "\<Union>C = X"
   342 proof (rule ccontr)
   343   let ?C = "{X} \<union> C"
   344   from `subset.maxchain A C` have "subset.chain A C"
   345     and *: "\<And>S. subset.chain A S \<Longrightarrow> \<not> C \<subset> S"
   346     by (auto simp: subset.maxchain_def)
   347   moreover have "\<forall>x\<in>C. x \<subseteq> X" using `\<Union>C \<subseteq> X` by auto
   348   ultimately have "subset.chain A ?C"
   349     using subset.chain_extend [of A C X] and `X \<in> A` by auto
   350   moreover assume **: "\<Union>C \<noteq> X"
   351   moreover from ** have "C \<subset> ?C" using `\<Union>C \<subseteq> X` by auto
   352   ultimately show False using * by blast
   353 qed
   355 subsubsection {* Zorn's lemma *}
   357 text {*If every chain has an upper bound, then there is a maximal set.*}
   358 lemma subset_Zorn:
   359   assumes "\<And>C. subset.chain A C \<Longrightarrow> \<exists>U\<in>A. \<forall>X\<in>C. X \<subseteq> U"
   360   shows "\<exists>M\<in>A. \<forall>X\<in>A. M \<subseteq> X \<longrightarrow> X = M"
   361 proof -
   362   from subset.Hausdorff [of A] obtain M where "subset.maxchain A M" ..
   363   then have "subset.chain A M" by (rule subset.maxchain_imp_chain)
   364   with assms obtain Y where "Y \<in> A" and "\<forall>X\<in>M. X \<subseteq> Y" by blast
   365   moreover have "\<forall>X\<in>A. Y \<subseteq> X \<longrightarrow> Y = X"
   366   proof (intro ballI impI)
   367     fix X
   368     assume "X \<in> A" and "Y \<subseteq> X"
   369     show "Y = X"
   370     proof (rule ccontr)
   371       assume "Y \<noteq> X"
   372       with `Y \<subseteq> X` have "\<not> X \<subseteq> Y" by blast
   373       from subset.chain_extend [OF `subset.chain A M` `X \<in> A`] and `\<forall>X\<in>M. X \<subseteq> Y`
   374         have "subset.chain A ({X} \<union> M)" using `Y \<subseteq> X` by auto
   375       moreover have "M \<subset> {X} \<union> M" using `\<forall>X\<in>M. X \<subseteq> Y` and `\<not> X \<subseteq> Y` by auto
   376       ultimately show False
   377         using `subset.maxchain A M` by (auto simp: subset.maxchain_def)
   378     qed
   379   qed
   380   ultimately show ?thesis by blast
   381 qed
   383 text{*Alternative version of Zorn's lemma for the subset relation.*}
   384 lemma subset_Zorn':
   385   assumes "\<And>C. subset.chain A C \<Longrightarrow> \<Union>C \<in> A"
   386   shows "\<exists>M\<in>A. \<forall>X\<in>A. M \<subseteq> X \<longrightarrow> X = M"
   387 proof -
   388   from subset.Hausdorff [of A] obtain M where "subset.maxchain A M" ..
   389   then have "subset.chain A M" by (rule subset.maxchain_imp_chain)
   390   with assms have "\<Union>M \<in> A" .
   391   moreover have "\<forall>Z\<in>A. \<Union>M \<subseteq> Z \<longrightarrow> \<Union>M = Z"
   392   proof (intro ballI impI)
   393     fix Z
   394     assume "Z \<in> A" and "\<Union>M \<subseteq> Z"
   395     with subset_maxchain_max [OF `subset.maxchain A M`]
   396       show "\<Union>M = Z" .
   397   qed
   398   ultimately show ?thesis by blast
   399 qed
   402 subsection {* Zorn's Lemma for Partial Orders *}
   404 text {*Relate old to new definitions.*}
   406 (* Define globally? In Set.thy? *)
   407 definition chain_subset :: "'a set set \<Rightarrow> bool" ("chain\<^sub>\<subseteq>") where
   408   "chain\<^sub>\<subseteq> C \<longleftrightarrow> (\<forall>A\<in>C. \<forall>B\<in>C. A \<subseteq> B \<or> B \<subseteq> A)"
   410 definition chains :: "'a set set \<Rightarrow> 'a set set set" where
   411   "chains A = {C. C \<subseteq> A \<and> chain\<^sub>\<subseteq> C}"
   413 (* Define globally? In Relation.thy? *)
   414 definition Chains :: "('a \<times> 'a) set \<Rightarrow> 'a set set" where
   415   "Chains r = {C. \<forall>a\<in>C. \<forall>b\<in>C. (a, b) \<in> r \<or> (b, a) \<in> r}"
   417 lemma chains_extend:
   418   "[| c \<in> chains S; z \<in> S; \<forall>x \<in> c. x \<subseteq> (z:: 'a set) |] ==> {z} Un c \<in> chains S"
   419   by (unfold chains_def chain_subset_def) blast
   421 lemma mono_Chains: "r \<subseteq> s \<Longrightarrow> Chains r \<subseteq> Chains s"
   422   unfolding Chains_def by blast
   424 lemma chain_subset_alt_def: "chain\<^sub>\<subseteq> C = subset.chain UNIV C"
   425   unfolding chain_subset_def subset.chain_def by fast
   427 lemma chains_alt_def: "chains A = {C. subset.chain A C}"
   428   by (simp add: chains_def chain_subset_alt_def subset.chain_def)
   430 lemma Chains_subset:
   431   "Chains r \<subseteq> {C. pred_on.chain UNIV (\<lambda>x y. (x, y) \<in> r) C}"
   432   by (force simp add: Chains_def pred_on.chain_def)
   434 lemma Chains_subset':
   435   assumes "refl r"
   436   shows "{C. pred_on.chain UNIV (\<lambda>x y. (x, y) \<in> r) C} \<subseteq> Chains r"
   437   using assms
   438   by (auto simp add: Chains_def pred_on.chain_def refl_on_def)
   440 lemma Chains_alt_def:
   441   assumes "refl r"
   442   shows "Chains r = {C. pred_on.chain UNIV (\<lambda>x y. (x, y) \<in> r) C}"
   443   using assms Chains_subset Chains_subset' by blast
   445 lemma Zorn_Lemma:
   446   "\<forall>C\<in>chains A. \<Union>C \<in> A \<Longrightarrow> \<exists>M\<in>A. \<forall>X\<in>A. M \<subseteq> X \<longrightarrow> X = M"
   447   using subset_Zorn' [of A] by (force simp: chains_alt_def)
   449 lemma Zorn_Lemma2:
   450   "\<forall>C\<in>chains A. \<exists>U\<in>A. \<forall>X\<in>C. X \<subseteq> U \<Longrightarrow> \<exists>M\<in>A. \<forall>X\<in>A. M \<subseteq> X \<longrightarrow> X = M"
   451   using subset_Zorn [of A] by (auto simp: chains_alt_def)
   453 text{*Various other lemmas*}
   455 lemma chainsD: "[| c \<in> chains S; x \<in> c; y \<in> c |] ==> x \<subseteq> y | y \<subseteq> x"
   456 by (unfold chains_def chain_subset_def) blast
   458 lemma chainsD2: "!!(c :: 'a set set). c \<in> chains S ==> c \<subseteq> S"
   459 by (unfold chains_def) blast
   461 lemma Zorns_po_lemma:
   462   assumes po: "Partial_order r"
   463     and u: "\<forall>C\<in>Chains r. \<exists>u\<in>Field r. \<forall>a\<in>C. (a, u) \<in> r"
   464   shows "\<exists>m\<in>Field r. \<forall>a\<in>Field r. (m, a) \<in> r \<longrightarrow> a = m"
   465 proof -
   466   have "Preorder r" using po by (simp add: partial_order_on_def)
   467 --{* Mirror r in the set of subsets below (wrt r) elements of A*}
   468   let ?B = "%x. r\<inverse> `` {x}" let ?S = "?B ` Field r"
   469   {
   470     fix C assume 1: "C \<subseteq> ?S" and 2: "\<forall>A\<in>C. \<forall>B\<in>C. A \<subseteq> B \<or> B \<subseteq> A"
   471     let ?A = "{x\<in>Field r. \<exists>M\<in>C. M = ?B x}"
   472     have "C = ?B ` ?A" using 1 by (auto simp: image_def)
   473     have "?A \<in> Chains r"
   474     proof (simp add: Chains_def, intro allI impI, elim conjE)
   475       fix a b
   476       assume "a \<in> Field r" and "?B a \<in> C" and "b \<in> Field r" and "?B b \<in> C"
   477       hence "?B a \<subseteq> ?B b \<or> ?B b \<subseteq> ?B a" using 2 by auto
   478       thus "(a, b) \<in> r \<or> (b, a) \<in> r"
   479         using `Preorder r` and `a \<in> Field r` and `b \<in> Field r`
   480         by (simp add:subset_Image1_Image1_iff)
   481     qed
   482     then obtain u where uA: "u \<in> Field r" "\<forall>a\<in>?A. (a, u) \<in> r" using u by auto
   483     have "\<forall>A\<in>C. A \<subseteq> r\<inverse> `` {u}" (is "?P u")
   484     proof auto
   485       fix a B assume aB: "B \<in> C" "a \<in> B"
   486       with 1 obtain x where "x \<in> Field r" and "B = r\<inverse> `` {x}" by auto
   487       thus "(a, u) \<in> r" using uA and aB and `Preorder r`
   488         unfolding preorder_on_def refl_on_def by simp (fast dest: transD)
   489     qed
   490     then have "\<exists>u\<in>Field r. ?P u" using `u \<in> Field r` by blast
   491   }
   492   then have "\<forall>C\<in>chains ?S. \<exists>U\<in>?S. \<forall>A\<in>C. A \<subseteq> U"
   493     by (auto simp: chains_def chain_subset_def)
   494   from Zorn_Lemma2 [OF this]
   495   obtain m B where "m \<in> Field r" and "B = r\<inverse> `` {m}"
   496     and "\<forall>x\<in>Field r. B \<subseteq> r\<inverse> `` {x} \<longrightarrow> r\<inverse> `` {x} = B"
   497     by auto
   498   hence "\<forall>a\<in>Field r. (m, a) \<in> r \<longrightarrow> a = m"
   499     using po and `Preorder r` and `m \<in> Field r`
   500     by (auto simp: subset_Image1_Image1_iff Partial_order_eq_Image1_Image1_iff)
   501   thus ?thesis using `m \<in> Field r` by blast
   502 qed
   505 subsection {* The Well Ordering Theorem *}
   507 (* The initial segment of a relation appears generally useful.
   508    Move to Relation.thy?
   509    Definition correct/most general?
   510    Naming?
   511 *)
   512 definition init_seg_of :: "(('a \<times> 'a) set \<times> ('a \<times> 'a) set) set" where
   513   "init_seg_of = {(r, s). r \<subseteq> s \<and> (\<forall>a b c. (a, b) \<in> s \<and> (b, c) \<in> r \<longrightarrow> (a, b) \<in> r)}"
   515 abbreviation
   516   initialSegmentOf :: "('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> bool" (infix "initial'_segment'_of" 55)
   517 where
   518   "r initial_segment_of s \<equiv> (r, s) \<in> init_seg_of"
   520 lemma refl_on_init_seg_of [simp]: "r initial_segment_of r"
   521   by (simp add: init_seg_of_def)
   523 lemma trans_init_seg_of:
   524   "r initial_segment_of s \<Longrightarrow> s initial_segment_of t \<Longrightarrow> r initial_segment_of t"
   525   by (simp (no_asm_use) add: init_seg_of_def) blast
   527 lemma antisym_init_seg_of:
   528   "r initial_segment_of s \<Longrightarrow> s initial_segment_of r \<Longrightarrow> r = s"
   529   unfolding init_seg_of_def by safe
   531 lemma Chains_init_seg_of_Union:
   532   "R \<in> Chains init_seg_of \<Longrightarrow> r\<in>R \<Longrightarrow> r initial_segment_of \<Union>R"
   533   by (auto simp: init_seg_of_def Ball_def Chains_def) blast
   535 lemma chain_subset_trans_Union:
   536   assumes "chain\<^sub>\<subseteq> R" "\<forall>r\<in>R. trans r"
   537   shows "trans (\<Union>R)"
   538 proof (intro transI, elim UnionE)
   539   fix  S1 S2 :: "'a rel" and x y z :: 'a
   540   assume "S1 \<in> R" "S2 \<in> R"
   541   with assms(1) have "S1 \<subseteq> S2 \<or> S2 \<subseteq> S1" unfolding chain_subset_def by blast
   542   moreover assume "(x, y) \<in> S1" "(y, z) \<in> S2"
   543   ultimately have "((x, y) \<in> S1 \<and> (y, z) \<in> S1) \<or> ((x, y) \<in> S2 \<and> (y, z) \<in> S2)" by blast
   544   with `S1 \<in> R` `S2 \<in> R` assms(2) show "(x, z) \<in> \<Union>R" by (auto elim: transE)
   545 qed
   547 lemma chain_subset_antisym_Union:
   548   assumes "chain\<^sub>\<subseteq> R" "\<forall>r\<in>R. antisym r"
   549   shows "antisym (\<Union>R)"
   550 proof (intro antisymI, elim UnionE)
   551   fix  S1 S2 :: "'a rel" and x y :: 'a
   552   assume "S1 \<in> R" "S2 \<in> R"
   553   with assms(1) have "S1 \<subseteq> S2 \<or> S2 \<subseteq> S1" unfolding chain_subset_def by blast
   554   moreover assume "(x, y) \<in> S1" "(y, x) \<in> S2"
   555   ultimately have "((x, y) \<in> S1 \<and> (y, x) \<in> S1) \<or> ((x, y) \<in> S2 \<and> (y, x) \<in> S2)" by blast
   556   with `S1 \<in> R` `S2 \<in> R` assms(2) show "x = y" unfolding antisym_def by auto
   557 qed
   559 lemma chain_subset_Total_Union:
   560   assumes "chain\<^sub>\<subseteq> R" and "\<forall>r\<in>R. Total r"
   561   shows "Total (\<Union>R)"
   562 proof (simp add: total_on_def Ball_def, auto del: disjCI)
   563   fix r s a b assume A: "r \<in> R" "s \<in> R" "a \<in> Field r" "b \<in> Field s" "a \<noteq> b"
   564   from `chain\<^sub>\<subseteq> R` and `r \<in> R` and `s \<in> R` have "r \<subseteq> s \<or> s \<subseteq> r"
   565     by (auto simp add: chain_subset_def)
   566   thus "(\<exists>r\<in>R. (a, b) \<in> r) \<or> (\<exists>r\<in>R. (b, a) \<in> r)"
   567   proof
   568     assume "r \<subseteq> s" hence "(a, b) \<in> s \<or> (b, a) \<in> s" using assms(2) A mono_Field[of r s]
   569       by (auto simp add: total_on_def)
   570     thus ?thesis using `s \<in> R` by blast
   571   next
   572     assume "s \<subseteq> r" hence "(a, b) \<in> r \<or> (b, a) \<in> r" using assms(2) A mono_Field[of s r]
   573       by (fastforce simp add: total_on_def)
   574     thus ?thesis using `r \<in> R` by blast
   575   qed
   576 qed
   578 lemma wf_Union_wf_init_segs:
   579   assumes "R \<in> Chains init_seg_of" and "\<forall>r\<in>R. wf r"
   580   shows "wf (\<Union>R)"
   581 proof(simp add: wf_iff_no_infinite_down_chain, rule ccontr, auto)
   582   fix f assume 1: "\<forall>i. \<exists>r\<in>R. (f (Suc i), f i) \<in> r"
   583   then obtain r where "r \<in> R" and "(f (Suc 0), f 0) \<in> r" by auto
   584   { fix i have "(f (Suc i), f i) \<in> r"
   585     proof (induct i)
   586       case 0 show ?case by fact
   587     next
   588       case (Suc i)
   589       then obtain s where s: "s \<in> R" "(f (Suc (Suc i)), f(Suc i)) \<in> s"
   590         using 1 by auto
   591       then have "s initial_segment_of r \<or> r initial_segment_of s"
   592         using assms(1) `r \<in> R` by (simp add: Chains_def)
   593       with Suc s show ?case by (simp add: init_seg_of_def) blast
   594     qed
   595   }
   596   thus False using assms(2) and `r \<in> R`
   597     by (simp add: wf_iff_no_infinite_down_chain) blast
   598 qed
   600 lemma initial_segment_of_Diff:
   601   "p initial_segment_of q \<Longrightarrow> p - s initial_segment_of q - s"
   602   unfolding init_seg_of_def by blast
   604 lemma Chains_inits_DiffI:
   605   "R \<in> Chains init_seg_of \<Longrightarrow> {r - s |r. r \<in> R} \<in> Chains init_seg_of"
   606   unfolding Chains_def by (blast intro: initial_segment_of_Diff)
   608 theorem well_ordering: "\<exists>r::'a rel. Well_order r \<and> Field r = UNIV"
   609 proof -
   610 -- {*The initial segment relation on well-orders: *}
   611   let ?WO = "{r::'a rel. Well_order r}"
   612   def I \<equiv> "init_seg_of \<inter> ?WO \<times> ?WO"
   613   have I_init: "I \<subseteq> init_seg_of" by (auto simp: I_def)
   614   hence subch: "\<And>R. R \<in> Chains I \<Longrightarrow> chain\<^sub>\<subseteq> R"
   615     unfolding init_seg_of_def chain_subset_def Chains_def by blast
   616   have Chains_wo: "\<And>R r. R \<in> Chains I \<Longrightarrow> r \<in> R \<Longrightarrow> Well_order r"
   617     by (simp add: Chains_def I_def) blast
   618   have FI: "Field I = ?WO" by (auto simp add: I_def init_seg_of_def Field_def)
   619   hence 0: "Partial_order I"
   620     by (auto simp: partial_order_on_def preorder_on_def antisym_def antisym_init_seg_of refl_on_def
   621       trans_def I_def elim!: trans_init_seg_of)
   622 -- {*I-chains have upper bounds in ?WO wrt I: their Union*}
   623   { fix R assume "R \<in> Chains I"
   624     hence Ris: "R \<in> Chains init_seg_of" using mono_Chains [OF I_init] by blast
   625     have subch: "chain\<^sub>\<subseteq> R" using `R : Chains I` I_init
   626       by (auto simp: init_seg_of_def chain_subset_def Chains_def)
   627     have "\<forall>r\<in>R. Refl r" and "\<forall>r\<in>R. trans r" and "\<forall>r\<in>R. antisym r"
   628       and "\<forall>r\<in>R. Total r" and "\<forall>r\<in>R. wf (r - Id)"
   629       using Chains_wo [OF `R \<in> Chains I`] by (simp_all add: order_on_defs)
   630     have "Refl (\<Union>R)" using `\<forall>r\<in>R. Refl r` unfolding refl_on_def by fastforce
   631     moreover have "trans (\<Union>R)"
   632       by (rule chain_subset_trans_Union [OF subch `\<forall>r\<in>R. trans r`])
   633     moreover have "antisym (\<Union>R)"
   634       by (rule chain_subset_antisym_Union [OF subch `\<forall>r\<in>R. antisym r`])
   635     moreover have "Total (\<Union>R)"
   636       by (rule chain_subset_Total_Union [OF subch `\<forall>r\<in>R. Total r`])
   637     moreover have "wf ((\<Union>R) - Id)"
   638     proof -
   639       have "(\<Union>R) - Id = \<Union>{r - Id | r. r \<in> R}" by blast
   640       with `\<forall>r\<in>R. wf (r - Id)` and wf_Union_wf_init_segs [OF Chains_inits_DiffI [OF Ris]]
   641       show ?thesis by fastforce
   642     qed
   643     ultimately have "Well_order (\<Union>R)" by(simp add:order_on_defs)
   644     moreover have "\<forall>r \<in> R. r initial_segment_of \<Union>R" using Ris
   645       by(simp add: Chains_init_seg_of_Union)
   646     ultimately have "\<Union>R \<in> ?WO \<and> (\<forall>r\<in>R. (r, \<Union>R) \<in> I)"
   647       using mono_Chains [OF I_init] Chains_wo[of R] and `R \<in> Chains I`
   648       unfolding I_def by blast
   649   }
   650   hence 1: "\<forall>R \<in> Chains I. \<exists>u\<in>Field I. \<forall>r\<in>R. (r, u) \<in> I" by (subst FI) blast
   651 --{*Zorn's Lemma yields a maximal well-order m:*}
   652   then obtain m::"'a rel" where "Well_order m" and
   653     max: "\<forall>r. Well_order r \<and> (m, r) \<in> I \<longrightarrow> r = m"
   654     using Zorns_po_lemma[OF 0 1] unfolding FI by fastforce
   655 --{*Now show by contradiction that m covers the whole type:*}
   656   { fix x::'a assume "x \<notin> Field m"
   657 --{*We assume that x is not covered and extend m at the top with x*}
   658     have "m \<noteq> {}"
   659     proof
   660       assume "m = {}"
   661       moreover have "Well_order {(x, x)}"
   662         by (simp add: order_on_defs refl_on_def trans_def antisym_def total_on_def Field_def)
   663       ultimately show False using max
   664         by (auto simp: I_def init_seg_of_def simp del: Field_insert)
   665     qed
   666     hence "Field m \<noteq> {}" by(auto simp:Field_def)
   667     moreover have "wf (m - Id)" using `Well_order m`
   668       by (simp add: well_order_on_def)
   669 --{*The extension of m by x:*}
   670     let ?s = "{(a, x) | a. a \<in> Field m}"
   671     let ?m = "insert (x, x) m \<union> ?s"
   672     have Fm: "Field ?m = insert x (Field m)"
   673       by (auto simp: Field_def)
   674     have "Refl m" and "trans m" and "antisym m" and "Total m" and "wf (m - Id)"
   675       using `Well_order m` by (simp_all add: order_on_defs)
   676 --{*We show that the extension is a well-order*}
   677     have "Refl ?m" using `Refl m` Fm unfolding refl_on_def by blast
   678     moreover have "trans ?m" using `trans m` and `x \<notin> Field m`
   679       unfolding trans_def Field_def by blast
   680     moreover have "antisym ?m" using `antisym m` and `x \<notin> Field m`
   681       unfolding antisym_def Field_def by blast
   682     moreover have "Total ?m" using `Total m` and Fm by (auto simp: total_on_def)
   683     moreover have "wf (?m - Id)"
   684     proof -
   685       have "wf ?s" using `x \<notin> Field m` unfolding wf_eq_minimal Field_def
   686         by (auto simp: Bex_def)
   687       thus ?thesis using `wf (m - Id)` and `x \<notin> Field m`
   688         wf_subset [OF `wf ?s` Diff_subset]
   689         unfolding Un_Diff Field_def by (auto intro: wf_Un)
   690     qed
   691     ultimately have "Well_order ?m" by (simp add: order_on_defs)
   692 --{*We show that the extension is above m*}
   693     moreover have "(m, ?m) \<in> I" using `Well_order ?m` and `Well_order m` and `x \<notin> Field m`
   694       by (fastforce simp: I_def init_seg_of_def Field_def)
   695     ultimately
   696 --{*This contradicts maximality of m:*}
   697     have False using max and `x \<notin> Field m` unfolding Field_def by blast
   698   }
   699   hence "Field m = UNIV" by auto
   700   with `Well_order m` show ?thesis by blast
   701 qed
   703 corollary well_order_on: "\<exists>r::'a rel. well_order_on A r"
   704 proof -
   705   obtain r::"'a rel" where wo: "Well_order r" and univ: "Field r = UNIV"
   706     using well_ordering [where 'a = "'a"] by blast
   707   let ?r = "{(x, y). x \<in> A \<and> y \<in> A \<and> (x, y) \<in> r}"
   708   have 1: "Field ?r = A" using wo univ
   709     by (fastforce simp: Field_def order_on_defs refl_on_def)
   710   have "Refl r" and "trans r" and "antisym r" and "Total r" and "wf (r - Id)"
   711     using `Well_order r` by (simp_all add: order_on_defs)
   712   have "Refl ?r" using `Refl r` by (auto simp: refl_on_def 1 univ)
   713   moreover have "trans ?r" using `trans r`
   714     unfolding trans_def by blast
   715   moreover have "antisym ?r" using `antisym r`
   716     unfolding antisym_def by blast
   717   moreover have "Total ?r" using `Total r` by (simp add:total_on_def 1 univ)
   718   moreover have "wf (?r - Id)" by (rule wf_subset [OF `wf (r - Id)`]) blast
   719   ultimately have "Well_order ?r" by (simp add: order_on_defs)
   720   with 1 show ?thesis by auto
   721 qed
   723 (* Move this to Hilbert Choice and wfrec to Wellfounded*)
   725 lemma wfrec_def_adm: "f \<equiv> wfrec R F \<Longrightarrow> wf R \<Longrightarrow> adm_wf R F \<Longrightarrow> f = F f"
   726   using wfrec_fixpoint by simp
   728 lemma dependent_wf_choice:
   729   fixes P :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
   730   assumes "wf R" and adm: "\<And>f g x r. (\<And>z. (z, x) \<in> R \<Longrightarrow> f z = g z) \<Longrightarrow> P f x r = P g x r"
   731   assumes P: "\<And>x f. (\<And>y. (y, x) \<in> R \<Longrightarrow> P f y (f y)) \<Longrightarrow> \<exists>r. P f x r"
   732   shows "\<exists>f. \<forall>x. P f x (f x)"
   733 proof (intro exI allI)
   734   fix x 
   735   def f \<equiv> "wfrec R (\<lambda>f x. SOME r. P f x r)"
   736   from `wf R` show "P f x (f x)"
   737   proof (induct x)
   738     fix x assume "\<And>y. (y, x) \<in> R \<Longrightarrow> P f y (f y)"
   739     show "P f x (f x)"
   740     proof (subst (2) wfrec_def_adm[OF f_def `wf R`])
   741       show "adm_wf R (\<lambda>f x. SOME r. P f x r)"
   742         by (auto simp add: adm_wf_def intro!: arg_cong[where f=Eps] ext adm)
   743       show "P f x (Eps (P f x))"
   744         using P by (rule someI_ex) fact
   745     qed
   746   qed
   747 qed
   749 lemma (in wellorder) dependent_wellorder_choice:
   750   assumes "\<And>r f g x. (\<And>y. y < x \<Longrightarrow> f y = g y) \<Longrightarrow> P f x r = P g x r"
   751   assumes P: "\<And>x f. (\<And>y. y < x \<Longrightarrow> P f y (f y)) \<Longrightarrow> \<exists>r. P f x r"
   752   shows "\<exists>f. \<forall>x. P f x (f x)"
   753   using wf by (rule dependent_wf_choice) (auto intro!: assms)
   755 end