src/HOL/Orderings.thy
author haftmann
Wed May 09 07:53:06 2007 +0200 (2007-05-09)
changeset 22886 cdff6ef76009
parent 22841 83b9f2d3fb3c
child 22916 8caf6da610e2
permissions -rw-r--r--
moved recfun_codegen.ML to Code_Generator.thy
     1 (*  Title:      HOL/Orderings.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* Syntactic and abstract orders *}
     7 
     8 theory Orderings
     9 imports Code_Generator
    10 begin
    11 
    12 subsection {* Order syntax *}
    13 
    14 class ord = type +
    15   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"  (infix "\<sqsubseteq>" 50)
    16     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"  (infix "\<sqsubset>" 50)
    17 begin
    18 
    19 notation
    20   less_eq  ("op \<^loc><=") and
    21   less_eq  ("(_/ \<^loc><= _)" [51, 51] 50) and
    22   less  ("op \<^loc><") and
    23   less  ("(_/ \<^loc>< _)"  [51, 51] 50)
    24   
    25 notation (xsymbols)
    26   less_eq  ("op \<^loc>\<le>") and
    27   less_eq  ("(_/ \<^loc>\<le> _)"  [51, 51] 50)
    28 
    29 notation (HTML output)
    30   less_eq  ("op \<^loc>\<le>") and
    31   less_eq  ("(_/ \<^loc>\<le> _)"  [51, 51] 50)
    32 
    33 abbreviation (input)
    34   greater  (infix "\<^loc>>" 50) where
    35   "x \<^loc>> y \<equiv> y \<^loc>< x"
    36 
    37 abbreviation (input)
    38   greater_eq  (infix "\<^loc>>=" 50) where
    39   "x \<^loc>>= y \<equiv> y \<^loc><= x"
    40 
    41 notation (input)
    42   greater_eq  (infix "\<^loc>\<ge>" 50)
    43 
    44 text {*
    45   syntactic min/max -- these definitions reach
    46   their usual semantics in class linorder ahead.
    47 *}
    48 
    49 definition
    50   min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
    51   "min a b = (if a \<^loc>\<le> b then a else b)"
    52 
    53 definition
    54   max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
    55   "max a b = (if a \<^loc>\<le> b then b else a)"
    56 
    57 end
    58 
    59 notation
    60   less_eq  ("op <=") and
    61   less_eq  ("(_/ <= _)" [51, 51] 50) and
    62   less  ("op <") and
    63   less  ("(_/ < _)"  [51, 51] 50)
    64   
    65 notation (xsymbols)
    66   less_eq  ("op \<le>") and
    67   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    68 
    69 notation (HTML output)
    70   less_eq  ("op \<le>") and
    71   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    72 
    73 abbreviation (input)
    74   greater  (infix ">" 50) where
    75   "x > y \<equiv> y < x"
    76 
    77 abbreviation (input)
    78   greater_eq  (infix ">=" 50) where
    79   "x >= y \<equiv> y <= x"
    80 
    81 notation (input)
    82   greater_eq  (infix "\<ge>" 50)
    83 
    84 definition
    85   min :: "'a\<Colon>ord \<Rightarrow> 'a \<Rightarrow> 'a" where
    86   "min a b = (if a \<le> b then a else b)"
    87 
    88 definition
    89   max :: "'a\<Colon>ord \<Rightarrow> 'a \<Rightarrow> 'a" where
    90   "max a b = (if a \<le> b then b else a)"
    91 
    92 lemma min_linorder:
    93   "ord.min (op \<le> \<Colon> 'a\<Colon>ord \<Rightarrow> 'a \<Rightarrow> bool) = min"
    94   by rule+ (simp add: min_def ord_class.min_def)
    95 
    96 lemma max_linorder:
    97   "ord.max (op \<le> \<Colon> 'a\<Colon>ord \<Rightarrow> 'a \<Rightarrow> bool) = max"
    98   by rule+ (simp add: max_def ord_class.max_def)
    99 
   100 
   101 subsection {* Partial orders *}
   102 
   103 class order = ord +
   104   assumes less_le: "x \<sqsubset> y \<longleftrightarrow> x \<sqsubseteq> y \<and> x \<noteq> y"
   105   and order_refl [iff]: "x \<sqsubseteq> x"
   106   and order_trans: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> z"
   107   assumes antisym: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> x \<Longrightarrow> x = y"
   108 
   109 begin
   110 
   111 text {* Reflexivity. *}
   112 
   113 lemma eq_refl: "x = y \<Longrightarrow> x \<^loc>\<le> y"
   114     -- {* This form is useful with the classical reasoner. *}
   115   by (erule ssubst) (rule order_refl)
   116 
   117 lemma less_irrefl [iff]: "\<not> x \<^loc>< x"
   118   by (simp add: less_le)
   119 
   120 lemma le_less: "x \<^loc>\<le> y \<longleftrightarrow> x \<^loc>< y \<or> x = y"
   121     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
   122   by (simp add: less_le) blast
   123 
   124 lemma le_imp_less_or_eq: "x \<^loc>\<le> y \<Longrightarrow> x \<^loc>< y \<or> x = y"
   125   unfolding less_le by blast
   126 
   127 lemma less_imp_le: "x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y"
   128   unfolding less_le by blast
   129 
   130 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
   131   by (erule contrapos_pn, erule subst, rule less_irrefl)
   132 
   133 
   134 text {* Useful for simplification, but too risky to include by default. *}
   135 
   136 lemma less_imp_not_eq: "x \<^loc>< y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   137   by auto
   138 
   139 lemma less_imp_not_eq2: "x \<^loc>< y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   140   by auto
   141 
   142 
   143 text {* Transitivity rules for calculational reasoning *}
   144 
   145 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<^loc>\<le> b \<Longrightarrow> a \<^loc>< b"
   146   by (simp add: less_le)
   147 
   148 lemma le_neq_trans: "a \<^loc>\<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a \<^loc>< b"
   149   by (simp add: less_le)
   150 
   151 
   152 text {* Asymmetry. *}
   153 
   154 lemma less_not_sym: "x \<^loc>< y \<Longrightarrow> \<not> (y \<^loc>< x)"
   155   by (simp add: less_le antisym)
   156 
   157 lemma less_asym: "x \<^loc>< y \<Longrightarrow> (\<not> P \<Longrightarrow> y \<^loc>< x) \<Longrightarrow> P"
   158   by (drule less_not_sym, erule contrapos_np) simp
   159 
   160 lemma eq_iff: "x = y \<longleftrightarrow> x \<^loc>\<le> y \<and> y \<^loc>\<le> x"
   161   by (blast intro: antisym)
   162 
   163 lemma antisym_conv: "y \<^loc>\<le> x \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
   164   by (blast intro: antisym)
   165 
   166 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
   167   by (erule contrapos_pn, erule subst, rule less_irrefl)
   168 
   169 
   170 text {* Transitivity. *}
   171 
   172 lemma less_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
   173   by (simp add: less_le) (blast intro: order_trans antisym)
   174 
   175 lemma le_less_trans: "x \<^loc>\<le> y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
   176   by (simp add: less_le) (blast intro: order_trans antisym)
   177 
   178 lemma less_le_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> z \<Longrightarrow> x \<^loc>< z"
   179   by (simp add: less_le) (blast intro: order_trans antisym)
   180 
   181 
   182 text {* Useful for simplification, but too risky to include by default. *}
   183 
   184 lemma less_imp_not_less: "x \<^loc>< y \<Longrightarrow> (\<not> y \<^loc>< x) \<longleftrightarrow> True"
   185   by (blast elim: less_asym)
   186 
   187 lemma less_imp_triv: "x \<^loc>< y \<Longrightarrow> (y \<^loc>< x \<longrightarrow> P) \<longleftrightarrow> True"
   188   by (blast elim: less_asym)
   189 
   190 
   191 text {* Transitivity rules for calculational reasoning *}
   192 
   193 lemma less_asym': "a \<^loc>< b \<Longrightarrow> b \<^loc>< a \<Longrightarrow> P"
   194   by (rule less_asym)
   195 
   196 end
   197 
   198 
   199 subsection {* Linear (total) orders *}
   200 
   201 class linorder = order +
   202   assumes linear: "x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
   203 begin
   204 
   205 lemma less_linear: "x \<^loc>< y \<or> x = y \<or> y \<^loc>< x"
   206   unfolding less_le using less_le linear by blast 
   207 
   208 lemma le_less_linear: "x \<^loc>\<le> y \<or> y \<^loc>< x"
   209   by (simp add: le_less less_linear)
   210 
   211 lemma le_cases [case_names le ge]:
   212   "(x \<^loc>\<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>\<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   213   using linear by blast
   214 
   215 lemma linorder_cases [case_names less equal greater]:
   216     "(x \<^loc>< y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> P) \<Longrightarrow> P"
   217   using less_linear by blast
   218 
   219 lemma not_less: "\<not> x \<^loc>< y \<longleftrightarrow> y \<^loc>\<le> x"
   220   apply (simp add: less_le)
   221   using linear apply (blast intro: antisym)
   222   done
   223 
   224 lemma not_le: "\<not> x \<^loc>\<le> y \<longleftrightarrow> y \<^loc>< x"
   225   apply (simp add: less_le)
   226   using linear apply (blast intro: antisym)
   227   done
   228 
   229 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x \<^loc>< y \<or> y \<^loc>< x"
   230   by (cut_tac x = x and y = y in less_linear, auto)
   231 
   232 lemma neqE: "x \<noteq> y \<Longrightarrow> (x \<^loc>< y \<Longrightarrow> R) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> R) \<Longrightarrow> R"
   233   by (simp add: neq_iff) blast
   234 
   235 lemma antisym_conv1: "\<not> x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
   236   by (blast intro: antisym dest: not_less [THEN iffD1])
   237 
   238 lemma antisym_conv2: "x \<^loc>\<le> y \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   239   by (blast intro: antisym dest: not_less [THEN iffD1])
   240 
   241 lemma antisym_conv3: "\<not> y \<^loc>< x \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   242   by (blast intro: antisym dest: not_less [THEN iffD1])
   243 
   244 text{*Replacing the old Nat.leI*}
   245 lemma leI: "\<not> x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> x"
   246   unfolding not_less .
   247 
   248 lemma leD: "y \<^loc>\<le> x \<Longrightarrow> \<not> x \<^loc>< y"
   249   unfolding not_less .
   250 
   251 (*FIXME inappropriate name (or delete altogether)*)
   252 lemma not_leE: "\<not> y \<^loc>\<le> x \<Longrightarrow> x \<^loc>< y"
   253   unfolding not_le .
   254 
   255 text {* min/max properties *}
   256 
   257 lemma min_le_iff_disj:
   258   "min x y \<^loc>\<le> z \<longleftrightarrow> x \<^loc>\<le> z \<or> y \<^loc>\<le> z"
   259   unfolding min_def using linear by (auto intro: order_trans)
   260 
   261 lemma le_max_iff_disj:
   262   "z \<^loc>\<le> max x y \<longleftrightarrow> z \<^loc>\<le> x \<or> z \<^loc>\<le> y"
   263   unfolding max_def using linear by (auto intro: order_trans)
   264 
   265 lemma min_less_iff_disj:
   266   "min x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<or> y \<^loc>< z"
   267   unfolding min_def le_less using less_linear by (auto intro: less_trans)
   268 
   269 lemma less_max_iff_disj:
   270   "z \<^loc>< max x y \<longleftrightarrow> z \<^loc>< x \<or> z \<^loc>< y"
   271   unfolding max_def le_less using less_linear by (auto intro: less_trans)
   272 
   273 lemma min_less_iff_conj [simp]:
   274   "z \<^loc>< min x y \<longleftrightarrow> z \<^loc>< x \<and> z \<^loc>< y"
   275   unfolding min_def le_less using less_linear by (auto intro: less_trans)
   276 
   277 lemma max_less_iff_conj [simp]:
   278   "max x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<and> y \<^loc>< z"
   279   unfolding max_def le_less using less_linear by (auto intro: less_trans)
   280 
   281 lemma split_min:
   282   "P (min i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P i) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P j)"
   283   by (simp add: min_def)
   284 
   285 lemma split_max:
   286   "P (max i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P j) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P i)"
   287   by (simp add: max_def)
   288 
   289 end
   290 
   291 
   292 subsection {* Name duplicates *}
   293 
   294 lemmas order_less_le = less_le
   295 lemmas order_eq_refl = order_class.eq_refl
   296 lemmas order_less_irrefl = order_class.less_irrefl
   297 lemmas order_le_less = order_class.le_less
   298 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
   299 lemmas order_less_imp_le = order_class.less_imp_le
   300 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
   301 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
   302 lemmas order_neq_le_trans = order_class.neq_le_trans
   303 lemmas order_le_neq_trans = order_class.le_neq_trans
   304 
   305 lemmas order_antisym = antisym
   306 lemmas order_less_not_sym = order_class.less_not_sym
   307 lemmas order_less_asym = order_class.less_asym
   308 lemmas order_eq_iff = order_class.eq_iff
   309 lemmas order_antisym_conv = order_class.antisym_conv
   310 lemmas less_imp_neq = order_class.less_imp_neq
   311 lemmas order_less_trans = order_class.less_trans
   312 lemmas order_le_less_trans = order_class.le_less_trans
   313 lemmas order_less_le_trans = order_class.less_le_trans
   314 lemmas order_less_imp_not_less = order_class.less_imp_not_less
   315 lemmas order_less_imp_triv = order_class.less_imp_triv
   316 lemmas order_less_asym' = order_class.less_asym'
   317 
   318 lemmas linorder_linear = linear
   319 lemmas linorder_less_linear = linorder_class.less_linear
   320 lemmas linorder_le_less_linear = linorder_class.le_less_linear
   321 lemmas linorder_le_cases = linorder_class.le_cases
   322 lemmas linorder_not_less = linorder_class.not_less
   323 lemmas linorder_not_le = linorder_class.not_le
   324 lemmas linorder_neq_iff = linorder_class.neq_iff
   325 lemmas linorder_neqE = linorder_class.neqE
   326 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
   327 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
   328 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
   329 lemmas leI = linorder_class.leI
   330 lemmas leD = linorder_class.leD
   331 lemmas not_leE = linorder_class.not_leE
   332 
   333 
   334 subsection {* Reasoning tools setup *}
   335 
   336 ML {*
   337 local
   338 
   339 fun decomp_gen sort thy (Trueprop $ t) =
   340   let
   341     fun of_sort t =
   342       let
   343         val T = type_of t
   344       in
   345         (* exclude numeric types: linear arithmetic subsumes transitivity *)
   346         T <> HOLogic.natT andalso T <> HOLogic.intT
   347           andalso T <> HOLogic.realT andalso Sign.of_sort thy (T, sort)
   348       end;
   349     fun dec (Const ("Not", _) $ t) = (case dec t
   350           of NONE => NONE
   351            | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   352       | dec (Const ("op =",  _) $ t1 $ t2) =
   353           if of_sort t1
   354           then SOME (t1, "=", t2)
   355           else NONE
   356       | dec (Const ("Orderings.less_eq",  _) $ t1 $ t2) =
   357           if of_sort t1
   358           then SOME (t1, "<=", t2)
   359           else NONE
   360       | dec (Const ("Orderings.less",  _) $ t1 $ t2) =
   361           if of_sort t1
   362           then SOME (t1, "<", t2)
   363           else NONE
   364       | dec _ = NONE;
   365   in dec t end;
   366 
   367 in
   368 
   369 (* sorry - there is no preorder class
   370 structure Quasi_Tac = Quasi_Tac_Fun (
   371 struct
   372   val le_trans = thm "order_trans";
   373   val le_refl = thm "order_refl";
   374   val eqD1 = thm "order_eq_refl";
   375   val eqD2 = thm "sym" RS thm "order_eq_refl";
   376   val less_reflE = thm "order_less_irrefl" RS thm "notE";
   377   val less_imp_le = thm "order_less_imp_le";
   378   val le_neq_trans = thm "order_le_neq_trans";
   379   val neq_le_trans = thm "order_neq_le_trans";
   380   val less_imp_neq = thm "less_imp_neq";
   381   val decomp_trans = decomp_gen ["Orderings.preorder"];
   382   val decomp_quasi = decomp_gen ["Orderings.preorder"];
   383 end);*)
   384 
   385 structure Order_Tac = Order_Tac_Fun (
   386 struct
   387   val less_reflE = thm "order_less_irrefl" RS thm "notE";
   388   val le_refl = thm "order_refl";
   389   val less_imp_le = thm "order_less_imp_le";
   390   val not_lessI = thm "linorder_not_less" RS thm "iffD2";
   391   val not_leI = thm "linorder_not_le" RS thm "iffD2";
   392   val not_lessD = thm "linorder_not_less" RS thm "iffD1";
   393   val not_leD = thm "linorder_not_le" RS thm "iffD1";
   394   val eqI = thm "order_antisym";
   395   val eqD1 = thm "order_eq_refl";
   396   val eqD2 = thm "sym" RS thm "order_eq_refl";
   397   val less_trans = thm "order_less_trans";
   398   val less_le_trans = thm "order_less_le_trans";
   399   val le_less_trans = thm "order_le_less_trans";
   400   val le_trans = thm "order_trans";
   401   val le_neq_trans = thm "order_le_neq_trans";
   402   val neq_le_trans = thm "order_neq_le_trans";
   403   val less_imp_neq = thm "less_imp_neq";
   404   val eq_neq_eq_imp_neq = thm "eq_neq_eq_imp_neq";
   405   val not_sym = thm "not_sym";
   406   val decomp_part = decomp_gen ["Orderings.order"];
   407   val decomp_lin = decomp_gen ["Orderings.linorder"];
   408 end);
   409 
   410 end;
   411 *}
   412 
   413 setup {*
   414 let
   415 
   416 fun prp t thm = (#prop (rep_thm thm) = t);
   417 
   418 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   419   let val prems = prems_of_ss ss;
   420       val less = Const("Orderings.less",T);
   421       val t = HOLogic.mk_Trueprop(le $ s $ r);
   422   in case find_first (prp t) prems of
   423        NONE =>
   424          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   425          in case find_first (prp t) prems of
   426               NONE => NONE
   427             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_antisym_conv1}))
   428          end
   429      | SOME thm => SOME(mk_meta_eq(thm RS @{thm order_antisym_conv}))
   430   end
   431   handle THM _ => NONE;
   432 
   433 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   434   let val prems = prems_of_ss ss;
   435       val le = Const("Orderings.less_eq",T);
   436       val t = HOLogic.mk_Trueprop(le $ r $ s);
   437   in case find_first (prp t) prems of
   438        NONE =>
   439          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   440          in case find_first (prp t) prems of
   441               NONE => NONE
   442             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_antisym_conv3}))
   443          end
   444      | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_antisym_conv2}))
   445   end
   446   handle THM _ => NONE;
   447 
   448 fun add_simprocs procs thy =
   449   (Simplifier.change_simpset_of thy (fn ss => ss
   450     addsimprocs (map (fn (name, raw_ts, proc) =>
   451       Simplifier.simproc thy name raw_ts proc)) procs); thy);
   452 fun add_solver name tac thy =
   453   (Simplifier.change_simpset_of thy (fn ss => ss addSolver
   454     (mk_solver name (K tac))); thy);
   455 
   456 in
   457   add_simprocs [
   458        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   459        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   460      ]
   461   #> add_solver "Trans_linear" Order_Tac.linear_tac
   462   #> add_solver "Trans_partial" Order_Tac.partial_tac
   463   (* Adding the transitivity reasoners also as safe solvers showed a slight
   464      speed up, but the reasoning strength appears to be not higher (at least
   465      no breaking of additional proofs in the entire HOL distribution, as
   466      of 5 March 2004, was observed). *)
   467 end
   468 *}
   469 
   470 
   471 subsection {* Bounded quantifiers *}
   472 
   473 syntax
   474   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   475   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   476   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   477   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   478 
   479   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   480   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   481   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   482   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   483 
   484 syntax (xsymbols)
   485   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   486   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   487   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   488   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   489 
   490   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   491   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   492   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   493   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   494 
   495 syntax (HOL)
   496   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   497   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   498   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   499   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   500 
   501 syntax (HTML output)
   502   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   503   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   504   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   505   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   506 
   507   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   508   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   509   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   510   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   511 
   512 translations
   513   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   514   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   515   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   516   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   517   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   518   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   519   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   520   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   521 
   522 print_translation {*
   523 let
   524   val All_binder = Syntax.binder_name @{const_syntax "All"};
   525   val Ex_binder = Syntax.binder_name @{const_syntax "Ex"};
   526   val impl = @{const_syntax "op -->"};
   527   val conj = @{const_syntax "op &"};
   528   val less = @{const_syntax "less"};
   529   val less_eq = @{const_syntax "less_eq"};
   530 
   531   val trans =
   532    [((All_binder, impl, less), ("_All_less", "_All_greater")),
   533     ((All_binder, impl, less_eq), ("_All_less_eq", "_All_greater_eq")),
   534     ((Ex_binder, conj, less), ("_Ex_less", "_Ex_greater")),
   535     ((Ex_binder, conj, less_eq), ("_Ex_less_eq", "_Ex_greater_eq"))];
   536 
   537   fun matches_bound v t = 
   538      case t of (Const ("_bound", _) $ Free (v', _)) => (v = v')
   539               | _ => false
   540   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false)
   541   fun mk v c n P = Syntax.const c $ Syntax.mark_bound v $ n $ P
   542 
   543   fun tr' q = (q,
   544     fn [Const ("_bound", _) $ Free (v, _), Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   545       (case AList.lookup (op =) trans (q, c, d) of
   546         NONE => raise Match
   547       | SOME (l, g) =>
   548           if matches_bound v t andalso not (contains_var v u) then mk v l u P
   549           else if matches_bound v u andalso not (contains_var v t) then mk v g t P
   550           else raise Match)
   551      | _ => raise Match);
   552 in [tr' All_binder, tr' Ex_binder] end
   553 *}
   554 
   555 
   556 subsection {* Transitivity reasoning *}
   557 
   558 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
   559   by (rule subst)
   560 
   561 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
   562   by (rule ssubst)
   563 
   564 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
   565   by (rule subst)
   566 
   567 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
   568   by (rule ssubst)
   569 
   570 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   571   (!!x y. x < y ==> f x < f y) ==> f a < c"
   572 proof -
   573   assume r: "!!x y. x < y ==> f x < f y"
   574   assume "a < b" hence "f a < f b" by (rule r)
   575   also assume "f b < c"
   576   finally (order_less_trans) show ?thesis .
   577 qed
   578 
   579 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   580   (!!x y. x < y ==> f x < f y) ==> a < f c"
   581 proof -
   582   assume r: "!!x y. x < y ==> f x < f y"
   583   assume "a < f b"
   584   also assume "b < c" hence "f b < f c" by (rule r)
   585   finally (order_less_trans) show ?thesis .
   586 qed
   587 
   588 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   589   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   590 proof -
   591   assume r: "!!x y. x <= y ==> f x <= f y"
   592   assume "a <= b" hence "f a <= f b" by (rule r)
   593   also assume "f b < c"
   594   finally (order_le_less_trans) show ?thesis .
   595 qed
   596 
   597 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   598   (!!x y. x < y ==> f x < f y) ==> a < f c"
   599 proof -
   600   assume r: "!!x y. x < y ==> f x < f y"
   601   assume "a <= f b"
   602   also assume "b < c" hence "f b < f c" by (rule r)
   603   finally (order_le_less_trans) show ?thesis .
   604 qed
   605 
   606 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   607   (!!x y. x < y ==> f x < f y) ==> f a < c"
   608 proof -
   609   assume r: "!!x y. x < y ==> f x < f y"
   610   assume "a < b" hence "f a < f b" by (rule r)
   611   also assume "f b <= c"
   612   finally (order_less_le_trans) show ?thesis .
   613 qed
   614 
   615 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   616   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   617 proof -
   618   assume r: "!!x y. x <= y ==> f x <= f y"
   619   assume "a < f b"
   620   also assume "b <= c" hence "f b <= f c" by (rule r)
   621   finally (order_less_le_trans) show ?thesis .
   622 qed
   623 
   624 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   625   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   626 proof -
   627   assume r: "!!x y. x <= y ==> f x <= f y"
   628   assume "a <= f b"
   629   also assume "b <= c" hence "f b <= f c" by (rule r)
   630   finally (order_trans) show ?thesis .
   631 qed
   632 
   633 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   634   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   635 proof -
   636   assume r: "!!x y. x <= y ==> f x <= f y"
   637   assume "a <= b" hence "f a <= f b" by (rule r)
   638   also assume "f b <= c"
   639   finally (order_trans) show ?thesis .
   640 qed
   641 
   642 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   643   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   644 proof -
   645   assume r: "!!x y. x <= y ==> f x <= f y"
   646   assume "a <= b" hence "f a <= f b" by (rule r)
   647   also assume "f b = c"
   648   finally (ord_le_eq_trans) show ?thesis .
   649 qed
   650 
   651 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   652   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   653 proof -
   654   assume r: "!!x y. x <= y ==> f x <= f y"
   655   assume "a = f b"
   656   also assume "b <= c" hence "f b <= f c" by (rule r)
   657   finally (ord_eq_le_trans) show ?thesis .
   658 qed
   659 
   660 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   661   (!!x y. x < y ==> f x < f y) ==> f a < c"
   662 proof -
   663   assume r: "!!x y. x < y ==> f x < f y"
   664   assume "a < b" hence "f a < f b" by (rule r)
   665   also assume "f b = c"
   666   finally (ord_less_eq_trans) show ?thesis .
   667 qed
   668 
   669 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   670   (!!x y. x < y ==> f x < f y) ==> a < f c"
   671 proof -
   672   assume r: "!!x y. x < y ==> f x < f y"
   673   assume "a = f b"
   674   also assume "b < c" hence "f b < f c" by (rule r)
   675   finally (ord_eq_less_trans) show ?thesis .
   676 qed
   677 
   678 text {*
   679   Note that this list of rules is in reverse order of priorities.
   680 *}
   681 
   682 lemmas order_trans_rules [trans] =
   683   order_less_subst2
   684   order_less_subst1
   685   order_le_less_subst2
   686   order_le_less_subst1
   687   order_less_le_subst2
   688   order_less_le_subst1
   689   order_subst2
   690   order_subst1
   691   ord_le_eq_subst
   692   ord_eq_le_subst
   693   ord_less_eq_subst
   694   ord_eq_less_subst
   695   forw_subst
   696   back_subst
   697   rev_mp
   698   mp
   699   order_neq_le_trans
   700   order_le_neq_trans
   701   order_less_trans
   702   order_less_asym'
   703   order_le_less_trans
   704   order_less_le_trans
   705   order_trans
   706   order_antisym
   707   ord_le_eq_trans
   708   ord_eq_le_trans
   709   ord_less_eq_trans
   710   ord_eq_less_trans
   711   trans
   712 
   713 
   714 (* FIXME cleanup *)
   715 
   716 text {* These support proving chains of decreasing inequalities
   717     a >= b >= c ... in Isar proofs. *}
   718 
   719 lemma xt1:
   720   "a = b ==> b > c ==> a > c"
   721   "a > b ==> b = c ==> a > c"
   722   "a = b ==> b >= c ==> a >= c"
   723   "a >= b ==> b = c ==> a >= c"
   724   "(x::'a::order) >= y ==> y >= x ==> x = y"
   725   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   726   "(x::'a::order) > y ==> y >= z ==> x > z"
   727   "(x::'a::order) >= y ==> y > z ==> x > z"
   728   "(a::'a::order) > b ==> b > a ==> ?P"
   729   "(x::'a::order) > y ==> y > z ==> x > z"
   730   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   731   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   732   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   733   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   734   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   735   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   736 by auto
   737 
   738 lemma xt2:
   739   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   740 by (subgoal_tac "f b >= f c", force, force)
   741 
   742 lemma xt3: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==> 
   743     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   744 by (subgoal_tac "f a >= f b", force, force)
   745 
   746 lemma xt4: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   747   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   748 by (subgoal_tac "f b >= f c", force, force)
   749 
   750 lemma xt5: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   751     (!!x y. x > y ==> f x > f y) ==> f a > c"
   752 by (subgoal_tac "f a > f b", force, force)
   753 
   754 lemma xt6: "(a::'a::order) >= f b ==> b > c ==>
   755     (!!x y. x > y ==> f x > f y) ==> a > f c"
   756 by (subgoal_tac "f b > f c", force, force)
   757 
   758 lemma xt7: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   759     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   760 by (subgoal_tac "f a >= f b", force, force)
   761 
   762 lemma xt8: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   763     (!!x y. x > y ==> f x > f y) ==> a > f c"
   764 by (subgoal_tac "f b > f c", force, force)
   765 
   766 lemma xt9: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   767     (!!x y. x > y ==> f x > f y) ==> f a > c"
   768 by (subgoal_tac "f a > f b", force, force)
   769 
   770 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
   771 
   772 (* 
   773   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   774   for the wrong thing in an Isar proof.
   775 
   776   The extra transitivity rules can be used as follows: 
   777 
   778 lemma "(a::'a::order) > z"
   779 proof -
   780   have "a >= b" (is "_ >= ?rhs")
   781     sorry
   782   also have "?rhs >= c" (is "_ >= ?rhs")
   783     sorry
   784   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   785     sorry
   786   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   787     sorry
   788   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   789     sorry
   790   also (xtrans) have "?rhs > z"
   791     sorry
   792   finally (xtrans) show ?thesis .
   793 qed
   794 
   795   Alternatively, one can use "declare xtrans [trans]" and then
   796   leave out the "(xtrans)" above.
   797 *)
   798 
   799 subsection {* Order on bool *}
   800 
   801 instance bool :: order 
   802   le_bool_def: "P \<le> Q \<equiv> P \<longrightarrow> Q"
   803   less_bool_def: "P < Q \<equiv> P \<le> Q \<and> P \<noteq> Q"
   804   by default (auto simp add: le_bool_def less_bool_def)
   805 
   806 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
   807   by (simp add: le_bool_def)
   808 
   809 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
   810   by (simp add: le_bool_def)
   811 
   812 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
   813   by (simp add: le_bool_def)
   814 
   815 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
   816   by (simp add: le_bool_def)
   817 
   818 lemma [code func]:
   819   "False \<le> b \<longleftrightarrow> True"
   820   "True \<le> b \<longleftrightarrow> b"
   821   "False < b \<longleftrightarrow> b"
   822   "True < b \<longleftrightarrow> False"
   823   unfolding le_bool_def less_bool_def by simp_all
   824 
   825 
   826 subsection {* Monotonicity, syntactic least value operator and min/max *}
   827 
   828 locale mono =
   829   fixes f
   830   assumes mono: "A \<le> B \<Longrightarrow> f A \<le> f B"
   831 
   832 lemmas monoI [intro?] = mono.intro
   833   and monoD [dest?] = mono.mono
   834 
   835 constdefs
   836   Least :: "('a::ord => bool) => 'a"               (binder "LEAST " 10)
   837   "Least P == THE x. P x & (ALL y. P y --> x <= y)"
   838     -- {* We can no longer use LeastM because the latter requires Hilbert-AC. *}
   839 
   840 lemma LeastI2_order:
   841   "[| P (x::'a::order);
   842       !!y. P y ==> x <= y;
   843       !!x. [| P x; ALL y. P y --> x \<le> y |] ==> Q x |]
   844    ==> Q (Least P)"
   845   apply (unfold Least_def)
   846   apply (rule theI2)
   847     apply (blast intro: order_antisym)+
   848   done
   849 
   850 lemma Least_equality:
   851     "[| P (k::'a::order); !!x. P x ==> k <= x |] ==> (LEAST x. P x) = k"
   852   apply (simp add: Least_def)
   853   apply (rule the_equality)
   854   apply (auto intro!: order_antisym)
   855   done
   856 
   857 lemmas min_le_iff_disj = linorder_class.min_le_iff_disj [unfolded min_linorder]
   858 lemmas le_max_iff_disj = linorder_class.le_max_iff_disj [unfolded max_linorder]
   859 lemmas min_less_iff_disj = linorder_class.min_less_iff_disj [unfolded min_linorder]
   860 lemmas less_max_iff_disj = linorder_class.less_max_iff_disj [unfolded max_linorder]
   861 lemmas min_less_iff_conj [simp] = linorder_class.min_less_iff_conj [unfolded min_linorder]
   862 lemmas max_less_iff_conj [simp] = linorder_class.max_less_iff_conj [unfolded max_linorder]
   863 lemmas split_min = linorder_class.split_min [unfolded min_linorder]
   864 lemmas split_max = linorder_class.split_max [unfolded max_linorder]
   865 
   866 lemma min_leastL: "(!!x. least <= x) ==> min least x = least"
   867   by (simp add: min_def)
   868 
   869 lemma max_leastL: "(!!x. least <= x) ==> max least x = x"
   870   by (simp add: max_def)
   871 
   872 lemma min_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> min x least = least"
   873   apply (simp add: min_def)
   874   apply (blast intro: order_antisym)
   875   done
   876 
   877 lemma max_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> max x least = x"
   878   apply (simp add: max_def)
   879   apply (blast intro: order_antisym)
   880   done
   881 
   882 lemma min_of_mono:
   883     "(!!x y. (f x <= f y) = (x <= y)) ==> min (f m) (f n) = f (min m n)"
   884   by (simp add: min_def)
   885 
   886 lemma max_of_mono:
   887     "(!!x y. (f x <= f y) = (x <= y)) ==> max (f m) (f n) = f (max m n)"
   888   by (simp add: max_def)
   889 
   890 
   891 subsection {* legacy ML bindings *}
   892 
   893 ML {*
   894 val monoI = @{thm monoI};
   895 *}
   896 
   897 end