author hoelzl
Fri Nov 02 14:23:40 2012 +0100 (2012-11-02)
changeset 50002 ce0d316b5b44
parent 50001 382bd3173584
child 50087 635d73673b5e
permissions -rw-r--r--
add measurability prover; add support for Borel sets
     1 (*  Title:      HOL/Probability/Measure_Space.thy
     2     Author:     Lawrence C Paulson
     3     Author:     Johannes Hölzl, TU München
     4     Author:     Armin Heller, TU München
     5 *)
     7 header {* Measure spaces and their properties *}
     9 theory Measure_Space
    10 imports
    11   Sigma_Algebra
    12   "~~/src/HOL/Multivariate_Analysis/Extended_Real_Limits"
    13 begin
    15 lemma sums_def2:
    16   "f sums x \<longleftrightarrow> (\<lambda>n. (\<Sum>i\<le>n. f i)) ----> x"
    17   unfolding sums_def
    18   apply (subst LIMSEQ_Suc_iff[symmetric])
    19   unfolding atLeastLessThanSuc_atLeastAtMost atLeast0AtMost ..
    21 lemma suminf_cmult_indicator:
    22   fixes f :: "nat \<Rightarrow> ereal"
    23   assumes "disjoint_family A" "x \<in> A i" "\<And>i. 0 \<le> f i"
    24   shows "(\<Sum>n. f n * indicator (A n) x) = f i"
    25 proof -
    26   have **: "\<And>n. f n * indicator (A n) x = (if n = i then f n else 0 :: ereal)"
    27     using `x \<in> A i` assms unfolding disjoint_family_on_def indicator_def by auto
    28   then have "\<And>n. (\<Sum>j<n. f j * indicator (A j) x) = (if i < n then f i else 0 :: ereal)"
    29     by (auto simp: setsum_cases)
    30   moreover have "(SUP n. if i < n then f i else 0) = (f i :: ereal)"
    31   proof (rule ereal_SUPI)
    32     fix y :: ereal assume "\<And>n. n \<in> UNIV \<Longrightarrow> (if i < n then f i else 0) \<le> y"
    33     from this[of "Suc i"] show "f i \<le> y" by auto
    34   qed (insert assms, simp)
    35   ultimately show ?thesis using assms
    36     by (subst suminf_ereal_eq_SUPR) (auto simp: indicator_def)
    37 qed
    39 lemma suminf_indicator:
    40   assumes "disjoint_family A"
    41   shows "(\<Sum>n. indicator (A n) x :: ereal) = indicator (\<Union>i. A i) x"
    42 proof cases
    43   assume *: "x \<in> (\<Union>i. A i)"
    44   then obtain i where "x \<in> A i" by auto
    45   from suminf_cmult_indicator[OF assms(1), OF `x \<in> A i`, of "\<lambda>k. 1"]
    46   show ?thesis using * by simp
    47 qed simp
    49 text {*
    50   The type for emeasure spaces is already defined in @{theory Sigma_Algebra}, as it is also used to
    51   represent sigma algebras (with an arbitrary emeasure).
    52 *}
    54 section "Extend binary sets"
    56 lemma LIMSEQ_binaryset:
    57   assumes f: "f {} = 0"
    58   shows  "(\<lambda>n. \<Sum>i<n. f (binaryset A B i)) ----> f A + f B"
    59 proof -
    60   have "(\<lambda>n. \<Sum>i < Suc (Suc n). f (binaryset A B i)) = (\<lambda>n. f A + f B)"
    61     proof
    62       fix n
    63       show "(\<Sum>i < Suc (Suc n). f (binaryset A B i)) = f A + f B"
    64         by (induct n)  (auto simp add: binaryset_def f)
    65     qed
    66   moreover
    67   have "... ----> f A + f B" by (rule tendsto_const)
    68   ultimately
    69   have "(\<lambda>n. \<Sum>i< Suc (Suc n). f (binaryset A B i)) ----> f A + f B"
    70     by metis
    71   hence "(\<lambda>n. \<Sum>i< n+2. f (binaryset A B i)) ----> f A + f B"
    72     by simp
    73   thus ?thesis by (rule LIMSEQ_offset [where k=2])
    74 qed
    76 lemma binaryset_sums:
    77   assumes f: "f {} = 0"
    78   shows  "(\<lambda>n. f (binaryset A B n)) sums (f A + f B)"
    79     by (simp add: sums_def LIMSEQ_binaryset [where f=f, OF f] atLeast0LessThan)
    81 lemma suminf_binaryset_eq:
    82   fixes f :: "'a set \<Rightarrow> 'b::{comm_monoid_add, t2_space}"
    83   shows "f {} = 0 \<Longrightarrow> (\<Sum>n. f (binaryset A B n)) = f A + f B"
    84   by (metis binaryset_sums sums_unique)
    86 section {* Properties of a premeasure @{term \<mu>} *}
    88 text {*
    89   The definitions for @{const positive} and @{const countably_additive} should be here, by they are
    90   necessary to define @{typ "'a measure"} in @{theory Sigma_Algebra}.
    91 *}
    93 definition additive where
    94   "additive M \<mu> \<longleftrightarrow> (\<forall>x\<in>M. \<forall>y\<in>M. x \<inter> y = {} \<longrightarrow> \<mu> (x \<union> y) = \<mu> x + \<mu> y)"
    96 definition increasing where
    97   "increasing M \<mu> \<longleftrightarrow> (\<forall>x\<in>M. \<forall>y\<in>M. x \<subseteq> y \<longrightarrow> \<mu> x \<le> \<mu> y)"
    99 lemma positiveD1: "positive M f \<Longrightarrow> f {} = 0" by (auto simp: positive_def)
   100 lemma positiveD2: "positive M f \<Longrightarrow> A \<in> M \<Longrightarrow> 0 \<le> f A" by (auto simp: positive_def)
   102 lemma positiveD_empty:
   103   "positive M f \<Longrightarrow> f {} = 0"
   104   by (auto simp add: positive_def)
   106 lemma additiveD:
   107   "additive M f \<Longrightarrow> x \<inter> y = {} \<Longrightarrow> x \<in> M \<Longrightarrow> y \<in> M \<Longrightarrow> f (x \<union> y) = f x + f y"
   108   by (auto simp add: additive_def)
   110 lemma increasingD:
   111   "increasing M f \<Longrightarrow> x \<subseteq> y \<Longrightarrow> x\<in>M \<Longrightarrow> y\<in>M \<Longrightarrow> f x \<le> f y"
   112   by (auto simp add: increasing_def)
   114 lemma countably_additiveI:
   115   "(\<And>A. range A \<subseteq> M \<Longrightarrow> disjoint_family A \<Longrightarrow> (\<Union>i. A i) \<in> M \<Longrightarrow> (\<Sum>i. f (A i)) = f (\<Union>i. A i))
   116   \<Longrightarrow> countably_additive M f"
   117   by (simp add: countably_additive_def)
   119 lemma (in ring_of_sets) disjointed_additive:
   120   assumes f: "positive M f" "additive M f" and A: "range A \<subseteq> M" "incseq A"
   121   shows "(\<Sum>i\<le>n. f (disjointed A i)) = f (A n)"
   122 proof (induct n)
   123   case (Suc n)
   124   then have "(\<Sum>i\<le>Suc n. f (disjointed A i)) = f (A n) + f (disjointed A (Suc n))"
   125     by simp
   126   also have "\<dots> = f (A n \<union> disjointed A (Suc n))"
   127     using A by (subst f(2)[THEN additiveD]) (auto simp: disjointed_incseq)
   128   also have "A n \<union> disjointed A (Suc n) = A (Suc n)"
   129     using `incseq A` by (auto dest: incseq_SucD simp: disjointed_incseq)
   130   finally show ?case .
   131 qed simp
   133 lemma (in ring_of_sets) additive_sum:
   134   fixes A:: "'i \<Rightarrow> 'a set"
   135   assumes f: "positive M f" and ad: "additive M f" and "finite S"
   136       and A: "A`S \<subseteq> M"
   137       and disj: "disjoint_family_on A S"
   138   shows  "(\<Sum>i\<in>S. f (A i)) = f (\<Union>i\<in>S. A i)"
   139 using `finite S` disj A proof induct
   140   case empty show ?case using f by (simp add: positive_def)
   141 next
   142   case (insert s S)
   143   then have "A s \<inter> (\<Union>i\<in>S. A i) = {}"
   144     by (auto simp add: disjoint_family_on_def neq_iff)
   145   moreover
   146   have "A s \<in> M" using insert by blast
   147   moreover have "(\<Union>i\<in>S. A i) \<in> M"
   148     using insert `finite S` by auto
   149   moreover
   150   ultimately have "f (A s \<union> (\<Union>i\<in>S. A i)) = f (A s) + f(\<Union>i\<in>S. A i)"
   151     using ad UNION_in_sets A by (auto simp add: additive_def)
   152   with insert show ?case using ad disjoint_family_on_mono[of S "insert s S" A]
   153     by (auto simp add: additive_def subset_insertI)
   154 qed
   156 lemma (in ring_of_sets) additive_increasing:
   157   assumes posf: "positive M f" and addf: "additive M f"
   158   shows "increasing M f"
   159 proof (auto simp add: increasing_def)
   160   fix x y
   161   assume xy: "x \<in> M" "y \<in> M" "x \<subseteq> y"
   162   then have "y - x \<in> M" by auto
   163   then have "0 \<le> f (y-x)" using posf[unfolded positive_def] by auto
   164   then have "f x + 0 \<le> f x + f (y-x)" by (intro add_left_mono) auto
   165   also have "... = f (x \<union> (y-x))" using addf
   166     by (auto simp add: additive_def) (metis Diff_disjoint Un_Diff_cancel Diff xy(1,2))
   167   also have "... = f y"
   168     by (metis Un_Diff_cancel Un_absorb1 xy(3))
   169   finally show "f x \<le> f y" by simp
   170 qed
   172 lemma (in ring_of_sets) countably_additive_additive:
   173   assumes posf: "positive M f" and ca: "countably_additive M f"
   174   shows "additive M f"
   175 proof (auto simp add: additive_def)
   176   fix x y
   177   assume x: "x \<in> M" and y: "y \<in> M" and "x \<inter> y = {}"
   178   hence "disjoint_family (binaryset x y)"
   179     by (auto simp add: disjoint_family_on_def binaryset_def)
   180   hence "range (binaryset x y) \<subseteq> M \<longrightarrow>
   181          (\<Union>i. binaryset x y i) \<in> M \<longrightarrow>
   182          f (\<Union>i. binaryset x y i) = (\<Sum> n. f (binaryset x y n))"
   183     using ca
   184     by (simp add: countably_additive_def)
   185   hence "{x,y,{}} \<subseteq> M \<longrightarrow> x \<union> y \<in> M \<longrightarrow>
   186          f (x \<union> y) = (\<Sum>n. f (binaryset x y n))"
   187     by (simp add: range_binaryset_eq UN_binaryset_eq)
   188   thus "f (x \<union> y) = f x + f y" using posf x y
   189     by (auto simp add: Un suminf_binaryset_eq positive_def)
   190 qed
   192 lemma (in algebra) increasing_additive_bound:
   193   fixes A:: "nat \<Rightarrow> 'a set" and  f :: "'a set \<Rightarrow> ereal"
   194   assumes f: "positive M f" and ad: "additive M f"
   195       and inc: "increasing M f"
   196       and A: "range A \<subseteq> M"
   197       and disj: "disjoint_family A"
   198   shows  "(\<Sum>i. f (A i)) \<le> f \<Omega>"
   199 proof (safe intro!: suminf_bound)
   200   fix N
   201   note disj_N = disjoint_family_on_mono[OF _ disj, of "{..<N}"]
   202   have "(\<Sum>i<N. f (A i)) = f (\<Union>i\<in>{..<N}. A i)"
   203     using A by (intro additive_sum [OF f ad _ _]) (auto simp: disj_N)
   204   also have "... \<le> f \<Omega>" using space_closed A
   205     by (intro increasingD[OF inc] finite_UN) auto
   206   finally show "(\<Sum>i<N. f (A i)) \<le> f \<Omega>" by simp
   207 qed (insert f A, auto simp: positive_def)
   209 lemma (in ring_of_sets) countably_additiveI_finite:
   210   assumes "finite \<Omega>" "positive M \<mu>" "additive M \<mu>"
   211   shows "countably_additive M \<mu>"
   212 proof (rule countably_additiveI)
   213   fix F :: "nat \<Rightarrow> 'a set" assume F: "range F \<subseteq> M" "(\<Union>i. F i) \<in> M" and disj: "disjoint_family F"
   215   have "\<forall>i\<in>{i. F i \<noteq> {}}. \<exists>x. x \<in> F i" by auto
   216   from bchoice[OF this] obtain f where f: "\<And>i. F i \<noteq> {} \<Longrightarrow> f i \<in> F i" by auto
   218   have inj_f: "inj_on f {i. F i \<noteq> {}}"
   219   proof (rule inj_onI, simp)
   220     fix i j a b assume *: "f i = f j" "F i \<noteq> {}" "F j \<noteq> {}"
   221     then have "f i \<in> F i" "f j \<in> F j" using f by force+
   222     with disj * show "i = j" by (auto simp: disjoint_family_on_def)
   223   qed
   224   have "finite (\<Union>i. F i)"
   225     by (metis F(2) assms(1) infinite_super sets_into_space)
   227   have F_subset: "{i. \<mu> (F i) \<noteq> 0} \<subseteq> {i. F i \<noteq> {}}"
   228     by (auto simp: positiveD_empty[OF `positive M \<mu>`])
   229   moreover have fin_not_empty: "finite {i. F i \<noteq> {}}"
   230   proof (rule finite_imageD)
   231     from f have "f`{i. F i \<noteq> {}} \<subseteq> (\<Union>i. F i)" by auto
   232     then show "finite (f`{i. F i \<noteq> {}})"
   233       by (rule finite_subset) fact
   234   qed fact
   235   ultimately have fin_not_0: "finite {i. \<mu> (F i) \<noteq> 0}"
   236     by (rule finite_subset)
   238   have disj_not_empty: "disjoint_family_on F {i. F i \<noteq> {}}"
   239     using disj by (auto simp: disjoint_family_on_def)
   241   from fin_not_0 have "(\<Sum>i. \<mu> (F i)) = (\<Sum>i | \<mu> (F i) \<noteq> 0. \<mu> (F i))"
   242     by (rule suminf_finite) auto
   243   also have "\<dots> = (\<Sum>i | F i \<noteq> {}. \<mu> (F i))"
   244     using fin_not_empty F_subset by (rule setsum_mono_zero_left) auto
   245   also have "\<dots> = \<mu> (\<Union>i\<in>{i. F i \<noteq> {}}. F i)"
   246     using `positive M \<mu>` `additive M \<mu>` fin_not_empty disj_not_empty F by (intro additive_sum) auto
   247   also have "\<dots> = \<mu> (\<Union>i. F i)"
   248     by (rule arg_cong[where f=\<mu>]) auto
   249   finally show "(\<Sum>i. \<mu> (F i)) = \<mu> (\<Union>i. F i)" .
   250 qed
   252 lemma (in ring_of_sets) countably_additive_iff_continuous_from_below:
   253   assumes f: "positive M f" "additive M f"
   254   shows "countably_additive M f \<longleftrightarrow>
   255     (\<forall>A. range A \<subseteq> M \<longrightarrow> incseq A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow> (\<lambda>i. f (A i)) ----> f (\<Union>i. A i))"
   256   unfolding countably_additive_def
   257 proof safe
   258   assume count_sum: "\<forall>A. range A \<subseteq> M \<longrightarrow> disjoint_family A \<longrightarrow> UNION UNIV A \<in> M \<longrightarrow> (\<Sum>i. f (A i)) = f (UNION UNIV A)"
   259   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "incseq A" "(\<Union>i. A i) \<in> M"
   260   then have dA: "range (disjointed A) \<subseteq> M" by (auto simp: range_disjointed_sets)
   261   with count_sum[THEN spec, of "disjointed A"] A(3)
   262   have f_UN: "(\<Sum>i. f (disjointed A i)) = f (\<Union>i. A i)"
   263     by (auto simp: UN_disjointed_eq disjoint_family_disjointed)
   264   moreover have "(\<lambda>n. (\<Sum>i=0..<n. f (disjointed A i))) ----> (\<Sum>i. f (disjointed A i))"
   265     using f(1)[unfolded positive_def] dA
   266     by (auto intro!: summable_sumr_LIMSEQ_suminf summable_ereal_pos)
   267   from LIMSEQ_Suc[OF this]
   268   have "(\<lambda>n. (\<Sum>i\<le>n. f (disjointed A i))) ----> (\<Sum>i. f (disjointed A i))"
   269     unfolding atLeastLessThanSuc_atLeastAtMost atLeast0AtMost .
   270   moreover have "\<And>n. (\<Sum>i\<le>n. f (disjointed A i)) = f (A n)"
   271     using disjointed_additive[OF f A(1,2)] .
   272   ultimately show "(\<lambda>i. f (A i)) ----> f (\<Union>i. A i)" by simp
   273 next
   274   assume cont: "\<forall>A. range A \<subseteq> M \<longrightarrow> incseq A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow> (\<lambda>i. f (A i)) ----> f (\<Union>i. A i)"
   275   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "disjoint_family A" "(\<Union>i. A i) \<in> M"
   276   have *: "(\<Union>n. (\<Union>i\<le>n. A i)) = (\<Union>i. A i)" by auto
   277   have "(\<lambda>n. f (\<Union>i\<le>n. A i)) ----> f (\<Union>i. A i)"
   278   proof (unfold *[symmetric], intro cont[rule_format])
   279     show "range (\<lambda>i. \<Union> i\<le>i. A i) \<subseteq> M" "(\<Union>i. \<Union> i\<le>i. A i) \<in> M"
   280       using A * by auto
   281   qed (force intro!: incseq_SucI)
   282   moreover have "\<And>n. f (\<Union>i\<le>n. A i) = (\<Sum>i\<le>n. f (A i))"
   283     using A
   284     by (intro additive_sum[OF f, of _ A, symmetric])
   285        (auto intro: disjoint_family_on_mono[where B=UNIV])
   286   ultimately
   287   have "(\<lambda>i. f (A i)) sums f (\<Union>i. A i)"
   288     unfolding sums_def2 by simp
   289   from sums_unique[OF this]
   290   show "(\<Sum>i. f (A i)) = f (\<Union>i. A i)" by simp
   291 qed
   293 lemma (in ring_of_sets) continuous_from_above_iff_empty_continuous:
   294   assumes f: "positive M f" "additive M f"
   295   shows "(\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) \<in> M \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) ----> f (\<Inter>i. A i))
   296      \<longleftrightarrow> (\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) = {} \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) ----> 0)"
   297 proof safe
   298   assume cont: "(\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) \<in> M \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) ----> f (\<Inter>i. A i))"
   299   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "decseq A" "(\<Inter>i. A i) = {}" "\<forall>i. f (A i) \<noteq> \<infinity>"
   300   with cont[THEN spec, of A] show "(\<lambda>i. f (A i)) ----> 0"
   301     using `positive M f`[unfolded positive_def] by auto
   302 next
   303   assume cont: "\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) = {} \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) ----> 0"
   304   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "decseq A" "(\<Inter>i. A i) \<in> M" "\<forall>i. f (A i) \<noteq> \<infinity>"
   306   have f_mono: "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a \<subseteq> b \<Longrightarrow> f a \<le> f b"
   307     using additive_increasing[OF f] unfolding increasing_def by simp
   309   have decseq_fA: "decseq (\<lambda>i. f (A i))"
   310     using A by (auto simp: decseq_def intro!: f_mono)
   311   have decseq: "decseq (\<lambda>i. A i - (\<Inter>i. A i))"
   312     using A by (auto simp: decseq_def)
   313   then have decseq_f: "decseq (\<lambda>i. f (A i - (\<Inter>i. A i)))"
   314     using A unfolding decseq_def by (auto intro!: f_mono Diff)
   315   have "f (\<Inter>x. A x) \<le> f (A 0)"
   316     using A by (auto intro!: f_mono)
   317   then have f_Int_fin: "f (\<Inter>x. A x) \<noteq> \<infinity>"
   318     using A by auto
   319   { fix i
   320     have "f (A i - (\<Inter>i. A i)) \<le> f (A i)" using A by (auto intro!: f_mono)
   321     then have "f (A i - (\<Inter>i. A i)) \<noteq> \<infinity>"
   322       using A by auto }
   323   note f_fin = this
   324   have "(\<lambda>i. f (A i - (\<Inter>i. A i))) ----> 0"
   325   proof (intro cont[rule_format, OF _ decseq _ f_fin])
   326     show "range (\<lambda>i. A i - (\<Inter>i. A i)) \<subseteq> M" "(\<Inter>i. A i - (\<Inter>i. A i)) = {}"
   327       using A by auto
   328   qed
   329   from INF_Lim_ereal[OF decseq_f this]
   330   have "(INF n. f (A n - (\<Inter>i. A i))) = 0" .
   331   moreover have "(INF n. f (\<Inter>i. A i)) = f (\<Inter>i. A i)"
   332     by auto
   333   ultimately have "(INF n. f (A n - (\<Inter>i. A i)) + f (\<Inter>i. A i)) = 0 + f (\<Inter>i. A i)"
   334     using A(4) f_fin f_Int_fin
   335     by (subst INFI_ereal_add) (auto simp: decseq_f)
   336   moreover {
   337     fix n
   338     have "f (A n - (\<Inter>i. A i)) + f (\<Inter>i. A i) = f ((A n - (\<Inter>i. A i)) \<union> (\<Inter>i. A i))"
   339       using A by (subst f(2)[THEN additiveD]) auto
   340     also have "(A n - (\<Inter>i. A i)) \<union> (\<Inter>i. A i) = A n"
   341       by auto
   342     finally have "f (A n - (\<Inter>i. A i)) + f (\<Inter>i. A i) = f (A n)" . }
   343   ultimately have "(INF n. f (A n)) = f (\<Inter>i. A i)"
   344     by simp
   345   with LIMSEQ_ereal_INFI[OF decseq_fA]
   346   show "(\<lambda>i. f (A i)) ----> f (\<Inter>i. A i)" by simp
   347 qed
   349 lemma (in ring_of_sets) empty_continuous_imp_continuous_from_below:
   350   assumes f: "positive M f" "additive M f" "\<forall>A\<in>M. f A \<noteq> \<infinity>"
   351   assumes cont: "\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) = {} \<longrightarrow> (\<lambda>i. f (A i)) ----> 0"
   352   assumes A: "range A \<subseteq> M" "incseq A" "(\<Union>i. A i) \<in> M"
   353   shows "(\<lambda>i. f (A i)) ----> f (\<Union>i. A i)"
   354 proof -
   355   have "\<forall>A\<in>M. \<exists>x. f A = ereal x"
   356   proof
   357     fix A assume "A \<in> M" with f show "\<exists>x. f A = ereal x"
   358       unfolding positive_def by (cases "f A") auto
   359   qed
   360   from bchoice[OF this] guess f' .. note f' = this[rule_format]
   361   from A have "(\<lambda>i. f ((\<Union>i. A i) - A i)) ----> 0"
   362     by (intro cont[rule_format]) (auto simp: decseq_def incseq_def)
   363   moreover
   364   { fix i
   365     have "f ((\<Union>i. A i) - A i) + f (A i) = f ((\<Union>i. A i) - A i \<union> A i)"
   366       using A by (intro f(2)[THEN additiveD, symmetric]) auto
   367     also have "(\<Union>i. A i) - A i \<union> A i = (\<Union>i. A i)"
   368       by auto
   369     finally have "f' (\<Union>i. A i) - f' (A i) = f' ((\<Union>i. A i) - A i)"
   370       using A by (subst (asm) (1 2 3) f') auto
   371     then have "f ((\<Union>i. A i) - A i) = ereal (f' (\<Union>i. A i) - f' (A i))"
   372       using A f' by auto }
   373   ultimately have "(\<lambda>i. f' (\<Union>i. A i) - f' (A i)) ----> 0"
   374     by (simp add: zero_ereal_def)
   375   then have "(\<lambda>i. f' (A i)) ----> f' (\<Union>i. A i)"
   376     by (rule LIMSEQ_diff_approach_zero2[OF tendsto_const])
   377   then show "(\<lambda>i. f (A i)) ----> f (\<Union>i. A i)"
   378     using A by (subst (1 2) f') auto
   379 qed
   381 lemma (in ring_of_sets) empty_continuous_imp_countably_additive:
   382   assumes f: "positive M f" "additive M f" and fin: "\<forall>A\<in>M. f A \<noteq> \<infinity>"
   383   assumes cont: "\<And>A. range A \<subseteq> M \<Longrightarrow> decseq A \<Longrightarrow> (\<Inter>i. A i) = {} \<Longrightarrow> (\<lambda>i. f (A i)) ----> 0"
   384   shows "countably_additive M f"
   385   using countably_additive_iff_continuous_from_below[OF f]
   386   using empty_continuous_imp_continuous_from_below[OF f fin] cont
   387   by blast
   389 section {* Properties of @{const emeasure} *}
   391 lemma emeasure_positive: "positive (sets M) (emeasure M)"
   392   by (cases M) (auto simp: sets_def emeasure_def Abs_measure_inverse measure_space_def)
   394 lemma emeasure_empty[simp, intro]: "emeasure M {} = 0"
   395   using emeasure_positive[of M] by (simp add: positive_def)
   397 lemma emeasure_nonneg[intro!]: "0 \<le> emeasure M A"
   398   using emeasure_notin_sets[of A M] emeasure_positive[of M]
   399   by (cases "A \<in> sets M") (auto simp: positive_def)
   401 lemma emeasure_not_MInf[simp]: "emeasure M A \<noteq> - \<infinity>"
   402   using emeasure_nonneg[of M A] by auto
   404 lemma emeasure_countably_additive: "countably_additive (sets M) (emeasure M)"
   405   by (cases M) (auto simp: sets_def emeasure_def Abs_measure_inverse measure_space_def)
   407 lemma suminf_emeasure:
   408   "range A \<subseteq> sets M \<Longrightarrow> disjoint_family A \<Longrightarrow> (\<Sum>i. emeasure M (A i)) = emeasure M (\<Union>i. A i)"
   409   using countable_UN[of A UNIV M] emeasure_countably_additive[of M]
   410   by (simp add: countably_additive_def)
   412 lemma emeasure_additive: "additive (sets M) (emeasure M)"
   413   by (metis countably_additive_additive emeasure_positive emeasure_countably_additive)
   415 lemma plus_emeasure:
   416   "a \<in> sets M \<Longrightarrow> b \<in> sets M \<Longrightarrow> a \<inter> b = {} \<Longrightarrow> emeasure M a + emeasure M b = emeasure M (a \<union> b)"
   417   using additiveD[OF emeasure_additive] ..
   419 lemma setsum_emeasure:
   420   "F`I \<subseteq> sets M \<Longrightarrow> disjoint_family_on F I \<Longrightarrow> finite I \<Longrightarrow>
   421     (\<Sum>i\<in>I. emeasure M (F i)) = emeasure M (\<Union>i\<in>I. F i)"
   422   by (metis additive_sum emeasure_positive emeasure_additive)
   424 lemma emeasure_mono:
   425   "a \<subseteq> b \<Longrightarrow> b \<in> sets M \<Longrightarrow> emeasure M a \<le> emeasure M b"
   426   by (metis additive_increasing emeasure_additive emeasure_nonneg emeasure_notin_sets
   427             emeasure_positive increasingD)
   429 lemma emeasure_space:
   430   "emeasure M A \<le> emeasure M (space M)"
   431   by (metis emeasure_mono emeasure_nonneg emeasure_notin_sets sets_into_space top)
   433 lemma emeasure_compl:
   434   assumes s: "s \<in> sets M" and fin: "emeasure M s \<noteq> \<infinity>"
   435   shows "emeasure M (space M - s) = emeasure M (space M) - emeasure M s"
   436 proof -
   437   from s have "0 \<le> emeasure M s" by auto
   438   have "emeasure M (space M) = emeasure M (s \<union> (space M - s))" using s
   439     by (metis Un_Diff_cancel Un_absorb1 s sets_into_space)
   440   also have "... = emeasure M s + emeasure M (space M - s)"
   441     by (rule plus_emeasure[symmetric]) (auto simp add: s)
   442   finally have "emeasure M (space M) = emeasure M s + emeasure M (space M - s)" .
   443   then show ?thesis
   444     using fin `0 \<le> emeasure M s`
   445     unfolding ereal_eq_minus_iff by (auto simp: ac_simps)
   446 qed
   448 lemma emeasure_Diff:
   449   assumes finite: "emeasure M B \<noteq> \<infinity>"
   450   and [measurable]: "A \<in> sets M" "B \<in> sets M" and "B \<subseteq> A"
   451   shows "emeasure M (A - B) = emeasure M A - emeasure M B"
   452 proof -
   453   have "0 \<le> emeasure M B" using assms by auto
   454   have "(A - B) \<union> B = A" using `B \<subseteq> A` by auto
   455   then have "emeasure M A = emeasure M ((A - B) \<union> B)" by simp
   456   also have "\<dots> = emeasure M (A - B) + emeasure M B"
   457     by (subst plus_emeasure[symmetric]) auto
   458   finally show "emeasure M (A - B) = emeasure M A - emeasure M B"
   459     unfolding ereal_eq_minus_iff
   460     using finite `0 \<le> emeasure M B` by auto
   461 qed
   463 lemma Lim_emeasure_incseq:
   464   "range A \<subseteq> sets M \<Longrightarrow> incseq A \<Longrightarrow> (\<lambda>i. (emeasure M (A i))) ----> emeasure M (\<Union>i. A i)"
   465   using emeasure_countably_additive
   466   by (auto simp add: countably_additive_iff_continuous_from_below emeasure_positive emeasure_additive)
   468 lemma incseq_emeasure:
   469   assumes "range B \<subseteq> sets M" "incseq B"
   470   shows "incseq (\<lambda>i. emeasure M (B i))"
   471   using assms by (auto simp: incseq_def intro!: emeasure_mono)
   473 lemma SUP_emeasure_incseq:
   474   assumes A: "range A \<subseteq> sets M" "incseq A"
   475   shows "(SUP n. emeasure M (A n)) = emeasure M (\<Union>i. A i)"
   476   using LIMSEQ_ereal_SUPR[OF incseq_emeasure, OF A] Lim_emeasure_incseq[OF A]
   477   by (simp add: LIMSEQ_unique)
   479 lemma decseq_emeasure:
   480   assumes "range B \<subseteq> sets M" "decseq B"
   481   shows "decseq (\<lambda>i. emeasure M (B i))"
   482   using assms by (auto simp: decseq_def intro!: emeasure_mono)
   484 lemma INF_emeasure_decseq:
   485   assumes A: "range A \<subseteq> sets M" and "decseq A"
   486   and finite: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
   487   shows "(INF n. emeasure M (A n)) = emeasure M (\<Inter>i. A i)"
   488 proof -
   489   have le_MI: "emeasure M (\<Inter>i. A i) \<le> emeasure M (A 0)"
   490     using A by (auto intro!: emeasure_mono)
   491   hence *: "emeasure M (\<Inter>i. A i) \<noteq> \<infinity>" using finite[of 0] by auto
   493   have A0: "0 \<le> emeasure M (A 0)" using A by auto
   495   have "emeasure M (A 0) - (INF n. emeasure M (A n)) = emeasure M (A 0) + (SUP n. - emeasure M (A n))"
   496     by (simp add: ereal_SUPR_uminus minus_ereal_def)
   497   also have "\<dots> = (SUP n. emeasure M (A 0) - emeasure M (A n))"
   498     unfolding minus_ereal_def using A0 assms
   499     by (subst SUPR_ereal_add) (auto simp add: decseq_emeasure)
   500   also have "\<dots> = (SUP n. emeasure M (A 0 - A n))"
   501     using A finite `decseq A`[unfolded decseq_def] by (subst emeasure_Diff) auto
   502   also have "\<dots> = emeasure M (\<Union>i. A 0 - A i)"
   503   proof (rule SUP_emeasure_incseq)
   504     show "range (\<lambda>n. A 0 - A n) \<subseteq> sets M"
   505       using A by auto
   506     show "incseq (\<lambda>n. A 0 - A n)"
   507       using `decseq A` by (auto simp add: incseq_def decseq_def)
   508   qed
   509   also have "\<dots> = emeasure M (A 0) - emeasure M (\<Inter>i. A i)"
   510     using A finite * by (simp, subst emeasure_Diff) auto
   511   finally show ?thesis
   512     unfolding ereal_minus_eq_minus_iff using finite A0 by auto
   513 qed
   515 lemma Lim_emeasure_decseq:
   516   assumes A: "range A \<subseteq> sets M" "decseq A" and fin: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
   517   shows "(\<lambda>i. emeasure M (A i)) ----> emeasure M (\<Inter>i. A i)"
   518   using LIMSEQ_ereal_INFI[OF decseq_emeasure, OF A]
   519   using INF_emeasure_decseq[OF A fin] by simp
   521 lemma emeasure_subadditive:
   522   assumes [measurable]: "A \<in> sets M" "B \<in> sets M"
   523   shows "emeasure M (A \<union> B) \<le> emeasure M A + emeasure M B"
   524 proof -
   525   from plus_emeasure[of A M "B - A"]
   526   have "emeasure M (A \<union> B) = emeasure M A + emeasure M (B - A)" by simp
   527   also have "\<dots> \<le> emeasure M A + emeasure M B"
   528     using assms by (auto intro!: add_left_mono emeasure_mono)
   529   finally show ?thesis .
   530 qed
   532 lemma emeasure_subadditive_finite:
   533   assumes "finite I" "A ` I \<subseteq> sets M"
   534   shows "emeasure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. emeasure M (A i))"
   535 using assms proof induct
   536   case (insert i I)
   537   then have "emeasure M (\<Union>i\<in>insert i I. A i) = emeasure M (A i \<union> (\<Union>i\<in>I. A i))"
   538     by simp
   539   also have "\<dots> \<le> emeasure M (A i) + emeasure M (\<Union>i\<in>I. A i)"
   540     using insert by (intro emeasure_subadditive) auto
   541   also have "\<dots> \<le> emeasure M (A i) + (\<Sum>i\<in>I. emeasure M (A i))"
   542     using insert by (intro add_mono) auto
   543   also have "\<dots> = (\<Sum>i\<in>insert i I. emeasure M (A i))"
   544     using insert by auto
   545   finally show ?case .
   546 qed simp
   548 lemma emeasure_subadditive_countably:
   549   assumes "range f \<subseteq> sets M"
   550   shows "emeasure M (\<Union>i. f i) \<le> (\<Sum>i. emeasure M (f i))"
   551 proof -
   552   have "emeasure M (\<Union>i. f i) = emeasure M (\<Union>i. disjointed f i)"
   553     unfolding UN_disjointed_eq ..
   554   also have "\<dots> = (\<Sum>i. emeasure M (disjointed f i))"
   555     using range_disjointed_sets[OF assms] suminf_emeasure[of "disjointed f"]
   556     by (simp add:  disjoint_family_disjointed comp_def)
   557   also have "\<dots> \<le> (\<Sum>i. emeasure M (f i))"
   558     using range_disjointed_sets[OF assms] assms
   559     by (auto intro!: suminf_le_pos emeasure_mono disjointed_subset)
   560   finally show ?thesis .
   561 qed
   563 lemma emeasure_insert:
   564   assumes sets: "{x} \<in> sets M" "A \<in> sets M" and "x \<notin> A"
   565   shows "emeasure M (insert x A) = emeasure M {x} + emeasure M A"
   566 proof -
   567   have "{x} \<inter> A = {}" using `x \<notin> A` by auto
   568   from plus_emeasure[OF sets this] show ?thesis by simp
   569 qed
   571 lemma emeasure_eq_setsum_singleton:
   572   assumes "finite S" "\<And>x. x \<in> S \<Longrightarrow> {x} \<in> sets M"
   573   shows "emeasure M S = (\<Sum>x\<in>S. emeasure M {x})"
   574   using setsum_emeasure[of "\<lambda>x. {x}" S M] assms
   575   by (auto simp: disjoint_family_on_def subset_eq)
   577 lemma setsum_emeasure_cover:
   578   assumes "finite S" and "A \<in> sets M" and br_in_M: "B ` S \<subseteq> sets M"
   579   assumes A: "A \<subseteq> (\<Union>i\<in>S. B i)"
   580   assumes disj: "disjoint_family_on B S"
   581   shows "emeasure M A = (\<Sum>i\<in>S. emeasure M (A \<inter> (B i)))"
   582 proof -
   583   have "(\<Sum>i\<in>S. emeasure M (A \<inter> (B i))) = emeasure M (\<Union>i\<in>S. A \<inter> (B i))"
   584   proof (rule setsum_emeasure)
   585     show "disjoint_family_on (\<lambda>i. A \<inter> B i) S"
   586       using `disjoint_family_on B S`
   587       unfolding disjoint_family_on_def by auto
   588   qed (insert assms, auto)
   589   also have "(\<Union>i\<in>S. A \<inter> (B i)) = A"
   590     using A by auto
   591   finally show ?thesis by simp
   592 qed
   594 lemma emeasure_eq_0:
   595   "N \<in> sets M \<Longrightarrow> emeasure M N = 0 \<Longrightarrow> K \<subseteq> N \<Longrightarrow> emeasure M K = 0"
   596   by (metis emeasure_mono emeasure_nonneg order_eq_iff)
   598 lemma emeasure_UN_eq_0:
   599   assumes "\<And>i::nat. emeasure M (N i) = 0" and "range N \<subseteq> sets M"
   600   shows "emeasure M (\<Union> i. N i) = 0"
   601 proof -
   602   have "0 \<le> emeasure M (\<Union> i. N i)" using assms by auto
   603   moreover have "emeasure M (\<Union> i. N i) \<le> 0"
   604     using emeasure_subadditive_countably[OF assms(2)] assms(1) by simp
   605   ultimately show ?thesis by simp
   606 qed
   608 lemma measure_eqI_finite:
   609   assumes [simp]: "sets M = Pow A" "sets N = Pow A" and "finite A"
   610   assumes eq: "\<And>a. a \<in> A \<Longrightarrow> emeasure M {a} = emeasure N {a}"
   611   shows "M = N"
   612 proof (rule measure_eqI)
   613   fix X assume "X \<in> sets M"
   614   then have X: "X \<subseteq> A" by auto
   615   then have "emeasure M X = (\<Sum>a\<in>X. emeasure M {a})"
   616     using `finite A` by (subst emeasure_eq_setsum_singleton) (auto dest: finite_subset)
   617   also have "\<dots> = (\<Sum>a\<in>X. emeasure N {a})"
   618     using X eq by (auto intro!: setsum_cong)
   619   also have "\<dots> = emeasure N X"
   620     using X `finite A` by (subst emeasure_eq_setsum_singleton) (auto dest: finite_subset)
   621   finally show "emeasure M X = emeasure N X" .
   622 qed simp
   624 lemma measure_eqI_generator_eq:
   625   fixes M N :: "'a measure" and E :: "'a set set" and A :: "nat \<Rightarrow> 'a set"
   626   assumes "Int_stable E" "E \<subseteq> Pow \<Omega>"
   627   and eq: "\<And>X. X \<in> E \<Longrightarrow> emeasure M X = emeasure N X"
   628   and M: "sets M = sigma_sets \<Omega> E"
   629   and N: "sets N = sigma_sets \<Omega> E"
   630   and A: "range A \<subseteq> E" "(\<Union>i. A i) = \<Omega>" "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
   631   shows "M = N"
   632 proof -
   633   let ?\<mu>  = "emeasure M" and ?\<nu> = "emeasure N"
   634   interpret S: sigma_algebra \<Omega> "sigma_sets \<Omega> E" by (rule sigma_algebra_sigma_sets) fact
   635   have "space M = \<Omega>"
   636     using top[of M] space_closed[of M] S.space_closed `sets M = sigma_sets \<Omega> E` by blast
   638   { fix F D assume "F \<in> E" and "?\<mu> F \<noteq> \<infinity>"
   639     then have [intro]: "F \<in> sigma_sets \<Omega> E" by auto
   640     have "?\<nu> F \<noteq> \<infinity>" using `?\<mu> F \<noteq> \<infinity>` `F \<in> E` eq by simp
   641     assume "D \<in> sets M"
   642     with `Int_stable E` `E \<subseteq> Pow \<Omega>` have "emeasure M (F \<inter> D) = emeasure N (F \<inter> D)"
   643       unfolding M
   644     proof (induct rule: sigma_sets_induct_disjoint)
   645       case (basic A)
   646       then have "F \<inter> A \<in> E" using `Int_stable E` `F \<in> E` by (auto simp: Int_stable_def)
   647       then show ?case using eq by auto
   648     next
   649       case empty then show ?case by simp
   650     next
   651       case (compl A)
   652       then have **: "F \<inter> (\<Omega> - A) = F - (F \<inter> A)"
   653         and [intro]: "F \<inter> A \<in> sigma_sets \<Omega> E"
   654         using `F \<in> E` S.sets_into_space by (auto simp: M)
   655       have "?\<nu> (F \<inter> A) \<le> ?\<nu> F" by (auto intro!: emeasure_mono simp: M N)
   656       then have "?\<nu> (F \<inter> A) \<noteq> \<infinity>" using `?\<nu> F \<noteq> \<infinity>` by auto
   657       have "?\<mu> (F \<inter> A) \<le> ?\<mu> F" by (auto intro!: emeasure_mono simp: M N)
   658       then have "?\<mu> (F \<inter> A) \<noteq> \<infinity>" using `?\<mu> F \<noteq> \<infinity>` by auto
   659       then have "?\<mu> (F \<inter> (\<Omega> - A)) = ?\<mu> F - ?\<mu> (F \<inter> A)" unfolding **
   660         using `F \<inter> A \<in> sigma_sets \<Omega> E` by (auto intro!: emeasure_Diff simp: M N)
   661       also have "\<dots> = ?\<nu> F - ?\<nu> (F \<inter> A)" using eq `F \<in> E` compl by simp
   662       also have "\<dots> = ?\<nu> (F \<inter> (\<Omega> - A))" unfolding **
   663         using `F \<inter> A \<in> sigma_sets \<Omega> E` `?\<nu> (F \<inter> A) \<noteq> \<infinity>`
   664         by (auto intro!: emeasure_Diff[symmetric] simp: M N)
   665       finally show ?case
   666         using `space M = \<Omega>` by auto
   667     next
   668       case (union A)
   669       then have "?\<mu> (\<Union>x. F \<inter> A x) = ?\<nu> (\<Union>x. F \<inter> A x)"
   670         by (subst (1 2) suminf_emeasure[symmetric]) (auto simp: disjoint_family_on_def subset_eq M N)
   671       with A show ?case
   672         by auto
   673     qed }
   674   note * = this
   675   show "M = N"
   676   proof (rule measure_eqI)
   677     show "sets M = sets N"
   678       using M N by simp
   679     have [simp, intro]: "\<And>i. A i \<in> sets M"
   680       using A(1) by (auto simp: subset_eq M)
   681     fix F assume "F \<in> sets M"
   682     let ?D = "disjointed (\<lambda>i. F \<inter> A i)"
   683     from `space M = \<Omega>` have F_eq: "F = (\<Union>i. ?D i)"
   684       using `F \<in> sets M`[THEN sets_into_space] A(2)[symmetric] by (auto simp: UN_disjointed_eq)
   685     have [simp, intro]: "\<And>i. ?D i \<in> sets M"
   686       using range_disjointed_sets[of "\<lambda>i. F \<inter> A i" M] `F \<in> sets M`
   687       by (auto simp: subset_eq)
   688     have "disjoint_family ?D"
   689       by (auto simp: disjoint_family_disjointed)
   690     moreover
   691     have "(\<Sum>i. emeasure M (?D i)) = (\<Sum>i. emeasure N (?D i))"
   692     proof (intro arg_cong[where f=suminf] ext)
   693       fix i
   694       have "A i \<inter> ?D i = ?D i"
   695         by (auto simp: disjointed_def)
   696       then show "emeasure M (?D i) = emeasure N (?D i)"
   697         using *[of "A i" "?D i", OF _ A(3)] A(1) by auto
   698     qed
   699     ultimately show "emeasure M F = emeasure N F"
   700       by (simp add: image_subset_iff `sets M = sets N`[symmetric] F_eq[symmetric] suminf_emeasure)
   701   qed
   702 qed
   704 lemma measure_of_of_measure: "measure_of (space M) (sets M) (emeasure M) = M"
   705 proof (intro measure_eqI emeasure_measure_of_sigma)
   706   show "sigma_algebra (space M) (sets M)" ..
   707   show "positive (sets M) (emeasure M)"
   708     by (simp add: positive_def emeasure_nonneg)
   709   show "countably_additive (sets M) (emeasure M)"
   710     by (simp add: emeasure_countably_additive)
   711 qed simp_all
   713 section "@{text \<mu>}-null sets"
   715 definition null_sets :: "'a measure \<Rightarrow> 'a set set" where
   716   "null_sets M = {N\<in>sets M. emeasure M N = 0}"
   718 lemma null_setsD1[dest]: "A \<in> null_sets M \<Longrightarrow> emeasure M A = 0"
   719   by (simp add: null_sets_def)
   721 lemma null_setsD2[dest]: "A \<in> null_sets M \<Longrightarrow> A \<in> sets M"
   722   unfolding null_sets_def by simp
   724 lemma null_setsI[intro]: "emeasure M A = 0 \<Longrightarrow> A \<in> sets M \<Longrightarrow> A \<in> null_sets M"
   725   unfolding null_sets_def by simp
   727 interpretation null_sets: ring_of_sets "space M" "null_sets M" for M
   728 proof (rule ring_of_setsI)
   729   show "null_sets M \<subseteq> Pow (space M)"
   730     using sets_into_space by auto
   731   show "{} \<in> null_sets M"
   732     by auto
   733   fix A B assume sets: "A \<in> null_sets M" "B \<in> null_sets M"
   734   then have "A \<in> sets M" "B \<in> sets M"
   735     by auto
   736   moreover then have "emeasure M (A \<union> B) \<le> emeasure M A + emeasure M B"
   737     "emeasure M (A - B) \<le> emeasure M A"
   738     by (auto intro!: emeasure_subadditive emeasure_mono)
   739   moreover have "emeasure M B = 0" "emeasure M A = 0"
   740     using sets by auto
   741   ultimately show "A - B \<in> null_sets M" "A \<union> B \<in> null_sets M"
   742     by (auto intro!: antisym)
   743 qed
   745 lemma UN_from_nat: "(\<Union>i. N i) = (\<Union>i. N (Countable.from_nat i))"
   746 proof -
   747   have "(\<Union>i. N i) = (\<Union>i. (N \<circ> Countable.from_nat) i)"
   748     unfolding SUP_def image_compose
   749     unfolding surj_from_nat ..
   750   then show ?thesis by simp
   751 qed
   753 lemma null_sets_UN[intro]:
   754   assumes "\<And>i::'i::countable. N i \<in> null_sets M"
   755   shows "(\<Union>i. N i) \<in> null_sets M"
   756 proof (intro conjI CollectI null_setsI)
   757   show "(\<Union>i. N i) \<in> sets M" using assms by auto
   758   have "0 \<le> emeasure M (\<Union>i. N i)" by (rule emeasure_nonneg)
   759   moreover have "emeasure M (\<Union>i. N i) \<le> (\<Sum>n. emeasure M (N (Countable.from_nat n)))"
   760     unfolding UN_from_nat[of N]
   761     using assms by (intro emeasure_subadditive_countably) auto
   762   ultimately show "emeasure M (\<Union>i. N i) = 0"
   763     using assms by (auto simp: null_setsD1)
   764 qed
   766 lemma null_set_Int1:
   767   assumes "B \<in> null_sets M" "A \<in> sets M" shows "A \<inter> B \<in> null_sets M"
   768 proof (intro CollectI conjI null_setsI)
   769   show "emeasure M (A \<inter> B) = 0" using assms
   770     by (intro emeasure_eq_0[of B _ "A \<inter> B"]) auto
   771 qed (insert assms, auto)
   773 lemma null_set_Int2:
   774   assumes "B \<in> null_sets M" "A \<in> sets M" shows "B \<inter> A \<in> null_sets M"
   775   using assms by (subst Int_commute) (rule null_set_Int1)
   777 lemma emeasure_Diff_null_set:
   778   assumes "B \<in> null_sets M" "A \<in> sets M"
   779   shows "emeasure M (A - B) = emeasure M A"
   780 proof -
   781   have *: "A - B = (A - (A \<inter> B))" by auto
   782   have "A \<inter> B \<in> null_sets M" using assms by (rule null_set_Int1)
   783   then show ?thesis
   784     unfolding * using assms
   785     by (subst emeasure_Diff) auto
   786 qed
   788 lemma null_set_Diff:
   789   assumes "B \<in> null_sets M" "A \<in> sets M" shows "B - A \<in> null_sets M"
   790 proof (intro CollectI conjI null_setsI)
   791   show "emeasure M (B - A) = 0" using assms by (intro emeasure_eq_0[of B _ "B - A"]) auto
   792 qed (insert assms, auto)
   794 lemma emeasure_Un_null_set:
   795   assumes "A \<in> sets M" "B \<in> null_sets M"
   796   shows "emeasure M (A \<union> B) = emeasure M A"
   797 proof -
   798   have *: "A \<union> B = A \<union> (B - A)" by auto
   799   have "B - A \<in> null_sets M" using assms(2,1) by (rule null_set_Diff)
   800   then show ?thesis
   801     unfolding * using assms
   802     by (subst plus_emeasure[symmetric]) auto
   803 qed
   805 section "Formalize almost everywhere"
   807 definition ae_filter :: "'a measure \<Rightarrow> 'a filter" where
   808   "ae_filter M = Abs_filter (\<lambda>P. \<exists>N\<in>null_sets M. {x \<in> space M. \<not> P x} \<subseteq> N)"
   810 abbreviation
   811   almost_everywhere :: "'a measure \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool" where
   812   "almost_everywhere M P \<equiv> eventually P (ae_filter M)"
   814 syntax
   815   "_almost_everywhere" :: "pttrn \<Rightarrow> 'a \<Rightarrow> bool \<Rightarrow> bool" ("AE _ in _. _" [0,0,10] 10)
   817 translations
   818   "AE x in M. P" == "CONST almost_everywhere M (%x. P)"
   820 lemma eventually_ae_filter:
   821   fixes M P
   822   defines [simp]: "F \<equiv> \<lambda>P. \<exists>N\<in>null_sets M. {x \<in> space M. \<not> P x} \<subseteq> N" 
   823   shows "eventually P (ae_filter M) \<longleftrightarrow> F P"
   824   unfolding ae_filter_def F_def[symmetric]
   825 proof (rule eventually_Abs_filter)
   826   show "is_filter F"
   827   proof
   828     fix P Q assume "F P" "F Q"
   829     then obtain N L where N: "N \<in> null_sets M" "{x \<in> space M. \<not> P x} \<subseteq> N"
   830       and L: "L \<in> null_sets M" "{x \<in> space M. \<not> Q x} \<subseteq> L"
   831       by auto
   832     then have "L \<union> N \<in> null_sets M" "{x \<in> space M. \<not> (P x \<and> Q x)} \<subseteq> L \<union> N" by auto
   833     then show "F (\<lambda>x. P x \<and> Q x)" by auto
   834   next
   835     fix P Q assume "F P"
   836     then obtain N where N: "N \<in> null_sets M" "{x \<in> space M. \<not> P x} \<subseteq> N" by auto
   837     moreover assume "\<forall>x. P x \<longrightarrow> Q x"
   838     ultimately have "N \<in> null_sets M" "{x \<in> space M. \<not> Q x} \<subseteq> N" by auto
   839     then show "F Q" by auto
   840   qed auto
   841 qed
   843 lemma AE_I':
   844   "N \<in> null_sets M \<Longrightarrow> {x\<in>space M. \<not> P x} \<subseteq> N \<Longrightarrow> (AE x in M. P x)"
   845   unfolding eventually_ae_filter by auto
   847 lemma AE_iff_null:
   848   assumes "{x\<in>space M. \<not> P x} \<in> sets M" (is "?P \<in> sets M")
   849   shows "(AE x in M. P x) \<longleftrightarrow> {x\<in>space M. \<not> P x} \<in> null_sets M"
   850 proof
   851   assume "AE x in M. P x" then obtain N where N: "N \<in> sets M" "?P \<subseteq> N" "emeasure M N = 0"
   852     unfolding eventually_ae_filter by auto
   853   have "0 \<le> emeasure M ?P" by auto
   854   moreover have "emeasure M ?P \<le> emeasure M N"
   855     using assms N(1,2) by (auto intro: emeasure_mono)
   856   ultimately have "emeasure M ?P = 0" unfolding `emeasure M N = 0` by auto
   857   then show "?P \<in> null_sets M" using assms by auto
   858 next
   859   assume "?P \<in> null_sets M" with assms show "AE x in M. P x" by (auto intro: AE_I')
   860 qed
   862 lemma AE_iff_null_sets:
   863   "N \<in> sets M \<Longrightarrow> N \<in> null_sets M \<longleftrightarrow> (AE x in M. x \<notin> N)"
   864   using Int_absorb1[OF sets_into_space, of N M]
   865   by (subst AE_iff_null) (auto simp: Int_def[symmetric])
   867 lemma AE_not_in:
   868   "N \<in> null_sets M \<Longrightarrow> AE x in M. x \<notin> N"
   869   by (metis AE_iff_null_sets null_setsD2)
   871 lemma AE_iff_measurable:
   872   "N \<in> sets M \<Longrightarrow> {x\<in>space M. \<not> P x} = N \<Longrightarrow> (AE x in M. P x) \<longleftrightarrow> emeasure M N = 0"
   873   using AE_iff_null[of _ P] by auto
   875 lemma AE_E[consumes 1]:
   876   assumes "AE x in M. P x"
   877   obtains N where "{x \<in> space M. \<not> P x} \<subseteq> N" "emeasure M N = 0" "N \<in> sets M"
   878   using assms unfolding eventually_ae_filter by auto
   880 lemma AE_E2:
   881   assumes "AE x in M. P x" "{x\<in>space M. P x} \<in> sets M"
   882   shows "emeasure M {x\<in>space M. \<not> P x} = 0" (is "emeasure M ?P = 0")
   883 proof -
   884   have "{x\<in>space M. \<not> P x} = space M - {x\<in>space M. P x}" by auto
   885   with AE_iff_null[of M P] assms show ?thesis by auto
   886 qed
   888 lemma AE_I:
   889   assumes "{x \<in> space M. \<not> P x} \<subseteq> N" "emeasure M N = 0" "N \<in> sets M"
   890   shows "AE x in M. P x"
   891   using assms unfolding eventually_ae_filter by auto
   893 lemma AE_mp[elim!]:
   894   assumes AE_P: "AE x in M. P x" and AE_imp: "AE x in M. P x \<longrightarrow> Q x"
   895   shows "AE x in M. Q x"
   896 proof -
   897   from AE_P obtain A where P: "{x\<in>space M. \<not> P x} \<subseteq> A"
   898     and A: "A \<in> sets M" "emeasure M A = 0"
   899     by (auto elim!: AE_E)
   901   from AE_imp obtain B where imp: "{x\<in>space M. P x \<and> \<not> Q x} \<subseteq> B"
   902     and B: "B \<in> sets M" "emeasure M B = 0"
   903     by (auto elim!: AE_E)
   905   show ?thesis
   906   proof (intro AE_I)
   907     have "0 \<le> emeasure M (A \<union> B)" using A B by auto
   908     moreover have "emeasure M (A \<union> B) \<le> 0"
   909       using emeasure_subadditive[of A M B] A B by auto
   910     ultimately show "A \<union> B \<in> sets M" "emeasure M (A \<union> B) = 0" using A B by auto
   911     show "{x\<in>space M. \<not> Q x} \<subseteq> A \<union> B"
   912       using P imp by auto
   913   qed
   914 qed
   916 (* depricated replace by laws about eventually *)
   917 lemma
   918   shows AE_iffI: "AE x in M. P x \<Longrightarrow> AE x in M. P x \<longleftrightarrow> Q x \<Longrightarrow> AE x in M. Q x"
   919     and AE_disjI1: "AE x in M. P x \<Longrightarrow> AE x in M. P x \<or> Q x"
   920     and AE_disjI2: "AE x in M. Q x \<Longrightarrow> AE x in M. P x \<or> Q x"
   921     and AE_conjI: "AE x in M. P x \<Longrightarrow> AE x in M. Q x \<Longrightarrow> AE x in M. P x \<and> Q x"
   922     and AE_conj_iff[simp]: "(AE x in M. P x \<and> Q x) \<longleftrightarrow> (AE x in M. P x) \<and> (AE x in M. Q x)"
   923   by auto
   925 lemma AE_impI:
   926   "(P \<Longrightarrow> AE x in M. Q x) \<Longrightarrow> AE x in M. P \<longrightarrow> Q x"
   927   by (cases P) auto
   929 lemma AE_measure:
   930   assumes AE: "AE x in M. P x" and sets: "{x\<in>space M. P x} \<in> sets M" (is "?P \<in> sets M")
   931   shows "emeasure M {x\<in>space M. P x} = emeasure M (space M)"
   932 proof -
   933   from AE_E[OF AE] guess N . note N = this
   934   with sets have "emeasure M (space M) \<le> emeasure M (?P \<union> N)"
   935     by (intro emeasure_mono) auto
   936   also have "\<dots> \<le> emeasure M ?P + emeasure M N"
   937     using sets N by (intro emeasure_subadditive) auto
   938   also have "\<dots> = emeasure M ?P" using N by simp
   939   finally show "emeasure M ?P = emeasure M (space M)"
   940     using emeasure_space[of M "?P"] by auto
   941 qed
   943 lemma AE_space: "AE x in M. x \<in> space M"
   944   by (rule AE_I[where N="{}"]) auto
   946 lemma AE_I2[simp, intro]:
   947   "(\<And>x. x \<in> space M \<Longrightarrow> P x) \<Longrightarrow> AE x in M. P x"
   948   using AE_space by force
   950 lemma AE_Ball_mp:
   951   "\<forall>x\<in>space M. P x \<Longrightarrow> AE x in M. P x \<longrightarrow> Q x \<Longrightarrow> AE x in M. Q x"
   952   by auto
   954 lemma AE_cong[cong]:
   955   "(\<And>x. x \<in> space M \<Longrightarrow> P x \<longleftrightarrow> Q x) \<Longrightarrow> (AE x in M. P x) \<longleftrightarrow> (AE x in M. Q x)"
   956   by auto
   958 lemma AE_all_countable:
   959   "(AE x in M. \<forall>i. P i x) \<longleftrightarrow> (\<forall>i::'i::countable. AE x in M. P i x)"
   960 proof
   961   assume "\<forall>i. AE x in M. P i x"
   962   from this[unfolded eventually_ae_filter Bex_def, THEN choice]
   963   obtain N where N: "\<And>i. N i \<in> null_sets M" "\<And>i. {x\<in>space M. \<not> P i x} \<subseteq> N i" by auto
   964   have "{x\<in>space M. \<not> (\<forall>i. P i x)} \<subseteq> (\<Union>i. {x\<in>space M. \<not> P i x})" by auto
   965   also have "\<dots> \<subseteq> (\<Union>i. N i)" using N by auto
   966   finally have "{x\<in>space M. \<not> (\<forall>i. P i x)} \<subseteq> (\<Union>i. N i)" .
   967   moreover from N have "(\<Union>i. N i) \<in> null_sets M"
   968     by (intro null_sets_UN) auto
   969   ultimately show "AE x in M. \<forall>i. P i x"
   970     unfolding eventually_ae_filter by auto
   971 qed auto
   973 lemma AE_finite_all:
   974   assumes f: "finite S" shows "(AE x in M. \<forall>i\<in>S. P i x) \<longleftrightarrow> (\<forall>i\<in>S. AE x in M. P i x)"
   975   using f by induct auto
   977 lemma AE_finite_allI:
   978   assumes "finite S"
   979   shows "(\<And>s. s \<in> S \<Longrightarrow> AE x in M. Q s x) \<Longrightarrow> AE x in M. \<forall>s\<in>S. Q s x"
   980   using AE_finite_all[OF `finite S`] by auto
   982 lemma emeasure_mono_AE:
   983   assumes imp: "AE x in M. x \<in> A \<longrightarrow> x \<in> B"
   984     and B: "B \<in> sets M"
   985   shows "emeasure M A \<le> emeasure M B"
   986 proof cases
   987   assume A: "A \<in> sets M"
   988   from imp obtain N where N: "{x\<in>space M. \<not> (x \<in> A \<longrightarrow> x \<in> B)} \<subseteq> N" "N \<in> null_sets M"
   989     by (auto simp: eventually_ae_filter)
   990   have "emeasure M A = emeasure M (A - N)"
   991     using N A by (subst emeasure_Diff_null_set) auto
   992   also have "emeasure M (A - N) \<le> emeasure M (B - N)"
   993     using N A B sets_into_space by (auto intro!: emeasure_mono)
   994   also have "emeasure M (B - N) = emeasure M B"
   995     using N B by (subst emeasure_Diff_null_set) auto
   996   finally show ?thesis .
   997 qed (simp add: emeasure_nonneg emeasure_notin_sets)
   999 lemma emeasure_eq_AE:
  1000   assumes iff: "AE x in M. x \<in> A \<longleftrightarrow> x \<in> B"
  1001   assumes A: "A \<in> sets M" and B: "B \<in> sets M"
  1002   shows "emeasure M A = emeasure M B"
  1003   using assms by (safe intro!: antisym emeasure_mono_AE) auto
  1005 section {* @{text \<sigma>}-finite Measures *}
  1007 locale sigma_finite_measure =
  1008   fixes M :: "'a measure"
  1009   assumes sigma_finite: "\<exists>A::nat \<Rightarrow> 'a set.
  1010     range A \<subseteq> sets M \<and> (\<Union>i. A i) = space M \<and> (\<forall>i. emeasure M (A i) \<noteq> \<infinity>)"
  1012 lemma (in sigma_finite_measure) sigma_finite_disjoint:
  1013   obtains A :: "nat \<Rightarrow> 'a set"
  1014   where "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" "\<And>i. emeasure M (A i) \<noteq> \<infinity>" "disjoint_family A"
  1015 proof atomize_elim
  1016   case goal1
  1017   obtain A :: "nat \<Rightarrow> 'a set" where
  1018     range: "range A \<subseteq> sets M" and
  1019     space: "(\<Union>i. A i) = space M" and
  1020     measure: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
  1021     using sigma_finite by auto
  1022   note range' = range_disjointed_sets[OF range] range
  1023   { fix i
  1024     have "emeasure M (disjointed A i) \<le> emeasure M (A i)"
  1025       using range' disjointed_subset[of A i] by (auto intro!: emeasure_mono)
  1026     then have "emeasure M (disjointed A i) \<noteq> \<infinity>"
  1027       using measure[of i] by auto }
  1028   with disjoint_family_disjointed UN_disjointed_eq[of A] space range'
  1029   show ?case by (auto intro!: exI[of _ "disjointed A"])
  1030 qed
  1032 lemma (in sigma_finite_measure) sigma_finite_incseq:
  1033   obtains A :: "nat \<Rightarrow> 'a set"
  1034   where "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" "\<And>i. emeasure M (A i) \<noteq> \<infinity>" "incseq A"
  1035 proof atomize_elim
  1036   case goal1
  1037   obtain F :: "nat \<Rightarrow> 'a set" where
  1038     F: "range F \<subseteq> sets M" "(\<Union>i. F i) = space M" "\<And>i. emeasure M (F i) \<noteq> \<infinity>"
  1039     using sigma_finite by auto
  1040   then show ?case
  1041   proof (intro exI[of _ "\<lambda>n. \<Union>i\<le>n. F i"] conjI allI)
  1042     from F have "\<And>x. x \<in> space M \<Longrightarrow> \<exists>i. x \<in> F i" by auto
  1043     then show "(\<Union>n. \<Union> i\<le>n. F i) = space M"
  1044       using F by fastforce
  1045   next
  1046     fix n
  1047     have "emeasure M (\<Union> i\<le>n. F i) \<le> (\<Sum>i\<le>n. emeasure M (F i))" using F
  1048       by (auto intro!: emeasure_subadditive_finite)
  1049     also have "\<dots> < \<infinity>"
  1050       using F by (auto simp: setsum_Pinfty)
  1051     finally show "emeasure M (\<Union> i\<le>n. F i) \<noteq> \<infinity>" by simp
  1052   qed (force simp: incseq_def)+
  1053 qed
  1055 section {* Measure space induced by distribution of @{const measurable}-functions *}
  1057 definition distr :: "'a measure \<Rightarrow> 'b measure \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b measure" where
  1058   "distr M N f = measure_of (space N) (sets N) (\<lambda>A. emeasure M (f -` A \<inter> space M))"
  1060 lemma
  1061   shows sets_distr[simp]: "sets (distr M N f) = sets N"
  1062     and space_distr[simp]: "space (distr M N f) = space N"
  1063   by (auto simp: distr_def)
  1065 lemma
  1066   shows measurable_distr_eq1[simp]: "measurable (distr Mf Nf f) Mf' = measurable Nf Mf'"
  1067     and measurable_distr_eq2[simp]: "measurable Mg' (distr Mg Ng g) = measurable Mg' Ng"
  1068   by (auto simp: measurable_def)
  1070 lemma emeasure_distr:
  1071   fixes f :: "'a \<Rightarrow> 'b"
  1072   assumes f: "f \<in> measurable M N" and A: "A \<in> sets N"
  1073   shows "emeasure (distr M N f) A = emeasure M (f -` A \<inter> space M)" (is "_ = ?\<mu> A")
  1074   unfolding distr_def
  1075 proof (rule emeasure_measure_of_sigma)
  1076   show "positive (sets N) ?\<mu>"
  1077     by (auto simp: positive_def)
  1079   show "countably_additive (sets N) ?\<mu>"
  1080   proof (intro countably_additiveI)
  1081     fix A :: "nat \<Rightarrow> 'b set" assume "range A \<subseteq> sets N" "disjoint_family A"
  1082     then have A: "\<And>i. A i \<in> sets N" "(\<Union>i. A i) \<in> sets N" by auto
  1083     then have *: "range (\<lambda>i. f -` (A i) \<inter> space M) \<subseteq> sets M"
  1084       using f by (auto simp: measurable_def)
  1085     moreover have "(\<Union>i. f -`  A i \<inter> space M) \<in> sets M"
  1086       using * by blast
  1087     moreover have **: "disjoint_family (\<lambda>i. f -` A i \<inter> space M)"
  1088       using `disjoint_family A` by (auto simp: disjoint_family_on_def)
  1089     ultimately show "(\<Sum>i. ?\<mu> (A i)) = ?\<mu> (\<Union>i. A i)"
  1090       using suminf_emeasure[OF _ **] A f
  1091       by (auto simp: comp_def vimage_UN)
  1092   qed
  1093   show "sigma_algebra (space N) (sets N)" ..
  1094 qed fact
  1096 lemma measure_distr:
  1097   "f \<in> measurable M N \<Longrightarrow> S \<in> sets N \<Longrightarrow> measure (distr M N f) S = measure M (f -` S \<inter> space M)"
  1098   by (simp add: emeasure_distr measure_def)
  1100 lemma AE_distrD:
  1101   assumes f: "f \<in> measurable M M'"
  1102     and AE: "AE x in distr M M' f. P x"
  1103   shows "AE x in M. P (f x)"
  1104 proof -
  1105   from AE[THEN AE_E] guess N .
  1106   with f show ?thesis
  1107     unfolding eventually_ae_filter
  1108     by (intro bexI[of _ "f -` N \<inter> space M"])
  1109        (auto simp: emeasure_distr measurable_def)
  1110 qed
  1112 lemma AE_distr_iff:
  1113   assumes f[measurable]: "f \<in> measurable M N" and P[measurable]: "{x \<in> space N. P x} \<in> sets N"
  1114   shows "(AE x in distr M N f. P x) \<longleftrightarrow> (AE x in M. P (f x))"
  1115 proof (subst (1 2) AE_iff_measurable[OF _ refl])
  1116   have "f -` {x\<in>space N. \<not> P x} \<inter> space M = {x \<in> space M. \<not> P (f x)}"
  1117     using f[THEN measurable_space] by auto
  1118   then show "(emeasure (distr M N f) {x \<in> space (distr M N f). \<not> P x} = 0) =
  1119     (emeasure M {x \<in> space M. \<not> P (f x)} = 0)"
  1120     by (simp add: emeasure_distr)
  1121 qed auto
  1123 lemma null_sets_distr_iff:
  1124   "f \<in> measurable M N \<Longrightarrow> A \<in> null_sets (distr M N f) \<longleftrightarrow> f -` A \<inter> space M \<in> null_sets M \<and> A \<in> sets N"
  1125   by (auto simp add: null_sets_def emeasure_distr)
  1127 lemma distr_distr:
  1128   "g \<in> measurable N L \<Longrightarrow> f \<in> measurable M N \<Longrightarrow> distr (distr M N f) L g = distr M L (g \<circ> f)"
  1129   by (auto simp add: emeasure_distr measurable_space
  1130            intro!: arg_cong[where f="emeasure M"] measure_eqI)
  1132 section {* Real measure values *}
  1134 lemma measure_nonneg: "0 \<le> measure M A"
  1135   using emeasure_nonneg[of M A] unfolding measure_def by (auto intro: real_of_ereal_pos)
  1137 lemma measure_empty[simp]: "measure M {} = 0"
  1138   unfolding measure_def by simp
  1140 lemma emeasure_eq_ereal_measure:
  1141   "emeasure M A \<noteq> \<infinity> \<Longrightarrow> emeasure M A = ereal (measure M A)"
  1142   using emeasure_nonneg[of M A]
  1143   by (cases "emeasure M A") (auto simp: measure_def)
  1145 lemma measure_Union:
  1146   assumes finite: "emeasure M A \<noteq> \<infinity>" "emeasure M B \<noteq> \<infinity>"
  1147   and measurable: "A \<in> sets M" "B \<in> sets M" "A \<inter> B = {}"
  1148   shows "measure M (A \<union> B) = measure M A + measure M B"
  1149   unfolding measure_def
  1150   using plus_emeasure[OF measurable, symmetric] finite
  1151   by (simp add: emeasure_eq_ereal_measure)
  1153 lemma measure_finite_Union:
  1154   assumes measurable: "A`S \<subseteq> sets M" "disjoint_family_on A S" "finite S"
  1155   assumes finite: "\<And>i. i \<in> S \<Longrightarrow> emeasure M (A i) \<noteq> \<infinity>"
  1156   shows "measure M (\<Union>i\<in>S. A i) = (\<Sum>i\<in>S. measure M (A i))"
  1157   unfolding measure_def
  1158   using setsum_emeasure[OF measurable, symmetric] finite
  1159   by (simp add: emeasure_eq_ereal_measure)
  1161 lemma measure_Diff:
  1162   assumes finite: "emeasure M A \<noteq> \<infinity>"
  1163   and measurable: "A \<in> sets M" "B \<in> sets M" "B \<subseteq> A"
  1164   shows "measure M (A - B) = measure M A - measure M B"
  1165 proof -
  1166   have "emeasure M (A - B) \<le> emeasure M A" "emeasure M B \<le> emeasure M A"
  1167     using measurable by (auto intro!: emeasure_mono)
  1168   hence "measure M ((A - B) \<union> B) = measure M (A - B) + measure M B"
  1169     using measurable finite by (rule_tac measure_Union) auto
  1170   thus ?thesis using `B \<subseteq> A` by (auto simp: Un_absorb2)
  1171 qed
  1173 lemma measure_UNION:
  1174   assumes measurable: "range A \<subseteq> sets M" "disjoint_family A"
  1175   assumes finite: "emeasure M (\<Union>i. A i) \<noteq> \<infinity>"
  1176   shows "(\<lambda>i. measure M (A i)) sums (measure M (\<Union>i. A i))"
  1177 proof -
  1178   from summable_sums[OF summable_ereal_pos, of "\<lambda>i. emeasure M (A i)"]
  1179        suminf_emeasure[OF measurable] emeasure_nonneg[of M]
  1180   have "(\<lambda>i. emeasure M (A i)) sums (emeasure M (\<Union>i. A i))" by simp
  1181   moreover
  1182   { fix i
  1183     have "emeasure M (A i) \<le> emeasure M (\<Union>i. A i)"
  1184       using measurable by (auto intro!: emeasure_mono)
  1185     then have "emeasure M (A i) = ereal ((measure M (A i)))"
  1186       using finite by (intro emeasure_eq_ereal_measure) auto }
  1187   ultimately show ?thesis using finite
  1188     unfolding sums_ereal[symmetric] by (simp add: emeasure_eq_ereal_measure)
  1189 qed
  1191 lemma measure_subadditive:
  1192   assumes measurable: "A \<in> sets M" "B \<in> sets M"
  1193   and fin: "emeasure M A \<noteq> \<infinity>" "emeasure M B \<noteq> \<infinity>"
  1194   shows "(measure M (A \<union> B)) \<le> (measure M A) + (measure M B)"
  1195 proof -
  1196   have "emeasure M (A \<union> B) \<noteq> \<infinity>"
  1197     using emeasure_subadditive[OF measurable] fin by auto
  1198   then show "(measure M (A \<union> B)) \<le> (measure M A) + (measure M B)"
  1199     using emeasure_subadditive[OF measurable] fin
  1200     by (auto simp: emeasure_eq_ereal_measure)
  1201 qed
  1203 lemma measure_subadditive_finite:
  1204   assumes A: "finite I" "A`I \<subseteq> sets M" and fin: "\<And>i. i \<in> I \<Longrightarrow> emeasure M (A i) \<noteq> \<infinity>"
  1205   shows "measure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. measure M (A i))"
  1206 proof -
  1207   { have "emeasure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. emeasure M (A i))"
  1208       using emeasure_subadditive_finite[OF A] .
  1209     also have "\<dots> < \<infinity>"
  1210       using fin by (simp add: setsum_Pinfty)
  1211     finally have "emeasure M (\<Union>i\<in>I. A i) \<noteq> \<infinity>" by simp }
  1212   then show ?thesis
  1213     using emeasure_subadditive_finite[OF A] fin
  1214     unfolding measure_def by (simp add: emeasure_eq_ereal_measure suminf_ereal measure_nonneg)
  1215 qed
  1217 lemma measure_subadditive_countably:
  1218   assumes A: "range A \<subseteq> sets M" and fin: "(\<Sum>i. emeasure M (A i)) \<noteq> \<infinity>"
  1219   shows "measure M (\<Union>i. A i) \<le> (\<Sum>i. measure M (A i))"
  1220 proof -
  1221   from emeasure_nonneg fin have "\<And>i. emeasure M (A i) \<noteq> \<infinity>" by (rule suminf_PInfty)
  1222   moreover
  1223   { have "emeasure M (\<Union>i. A i) \<le> (\<Sum>i. emeasure M (A i))"
  1224       using emeasure_subadditive_countably[OF A] .
  1225     also have "\<dots> < \<infinity>"
  1226       using fin by simp
  1227     finally have "emeasure M (\<Union>i. A i) \<noteq> \<infinity>" by simp }
  1228   ultimately  show ?thesis
  1229     using emeasure_subadditive_countably[OF A] fin
  1230     unfolding measure_def by (simp add: emeasure_eq_ereal_measure suminf_ereal measure_nonneg)
  1231 qed
  1233 lemma measure_eq_setsum_singleton:
  1234   assumes S: "finite S" "\<And>x. x \<in> S \<Longrightarrow> {x} \<in> sets M"
  1235   and fin: "\<And>x. x \<in> S \<Longrightarrow> emeasure M {x} \<noteq> \<infinity>"
  1236   shows "(measure M S) = (\<Sum>x\<in>S. (measure M {x}))"
  1237   unfolding measure_def
  1238   using emeasure_eq_setsum_singleton[OF S] fin
  1239   by simp (simp add: emeasure_eq_ereal_measure)
  1241 lemma Lim_measure_incseq:
  1242   assumes A: "range A \<subseteq> sets M" "incseq A" and fin: "emeasure M (\<Union>i. A i) \<noteq> \<infinity>"
  1243   shows "(\<lambda>i. (measure M (A i))) ----> (measure M (\<Union>i. A i))"
  1244 proof -
  1245   have "ereal ((measure M (\<Union>i. A i))) = emeasure M (\<Union>i. A i)"
  1246     using fin by (auto simp: emeasure_eq_ereal_measure)
  1247   then show ?thesis
  1248     using Lim_emeasure_incseq[OF A]
  1249     unfolding measure_def
  1250     by (intro lim_real_of_ereal) simp
  1251 qed
  1253 lemma Lim_measure_decseq:
  1254   assumes A: "range A \<subseteq> sets M" "decseq A" and fin: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
  1255   shows "(\<lambda>n. measure M (A n)) ----> measure M (\<Inter>i. A i)"
  1256 proof -
  1257   have "emeasure M (\<Inter>i. A i) \<le> emeasure M (A 0)"
  1258     using A by (auto intro!: emeasure_mono)
  1259   also have "\<dots> < \<infinity>"
  1260     using fin[of 0] by auto
  1261   finally have "ereal ((measure M (\<Inter>i. A i))) = emeasure M (\<Inter>i. A i)"
  1262     by (auto simp: emeasure_eq_ereal_measure)
  1263   then show ?thesis
  1264     unfolding measure_def
  1265     using Lim_emeasure_decseq[OF A fin]
  1266     by (intro lim_real_of_ereal) simp
  1267 qed
  1269 section {* Measure spaces with @{term "emeasure M (space M) < \<infinity>"} *}
  1271 locale finite_measure = sigma_finite_measure M for M +
  1272   assumes finite_emeasure_space: "emeasure M (space M) \<noteq> \<infinity>"
  1274 lemma finite_measureI[Pure.intro!]:
  1275   assumes *: "emeasure M (space M) \<noteq> \<infinity>"
  1276   shows "finite_measure M"
  1277 proof
  1278   show "\<exists>A. range A \<subseteq> sets M \<and> (\<Union>i. A i) = space M \<and> (\<forall>i. emeasure M (A i) \<noteq> \<infinity>)"
  1279     using * by (auto intro!: exI[of _ "\<lambda>_. space M"])
  1280 qed fact
  1282 lemma (in finite_measure) emeasure_finite[simp, intro]: "emeasure M A \<noteq> \<infinity>"
  1283   using finite_emeasure_space emeasure_space[of M A] by auto
  1285 lemma (in finite_measure) emeasure_eq_measure: "emeasure M A = ereal (measure M A)"
  1286   unfolding measure_def by (simp add: emeasure_eq_ereal_measure)
  1288 lemma (in finite_measure) emeasure_real: "\<exists>r. 0 \<le> r \<and> emeasure M A = ereal r"
  1289   using emeasure_finite[of A] emeasure_nonneg[of M A] by (cases "emeasure M A") auto
  1291 lemma (in finite_measure) bounded_measure: "measure M A \<le> measure M (space M)"
  1292   using emeasure_space[of M A] emeasure_real[of A] emeasure_real[of "space M"] by (auto simp: measure_def)
  1294 lemma (in finite_measure) finite_measure_Diff:
  1295   assumes sets: "A \<in> sets M" "B \<in> sets M" and "B \<subseteq> A"
  1296   shows "measure M (A - B) = measure M A - measure M B"
  1297   using measure_Diff[OF _ assms] by simp
  1299 lemma (in finite_measure) finite_measure_Union:
  1300   assumes sets: "A \<in> sets M" "B \<in> sets M" and "A \<inter> B = {}"
  1301   shows "measure M (A \<union> B) = measure M A + measure M B"
  1302   using measure_Union[OF _ _ assms] by simp
  1304 lemma (in finite_measure) finite_measure_finite_Union:
  1305   assumes measurable: "A`S \<subseteq> sets M" "disjoint_family_on A S" "finite S"
  1306   shows "measure M (\<Union>i\<in>S. A i) = (\<Sum>i\<in>S. measure M (A i))"
  1307   using measure_finite_Union[OF assms] by simp
  1309 lemma (in finite_measure) finite_measure_UNION:
  1310   assumes A: "range A \<subseteq> sets M" "disjoint_family A"
  1311   shows "(\<lambda>i. measure M (A i)) sums (measure M (\<Union>i. A i))"
  1312   using measure_UNION[OF A] by simp
  1314 lemma (in finite_measure) finite_measure_mono:
  1315   assumes "A \<subseteq> B" "B \<in> sets M" shows "measure M A \<le> measure M B"
  1316   using emeasure_mono[OF assms] emeasure_real[of A] emeasure_real[of B] by (auto simp: measure_def)
  1318 lemma (in finite_measure) finite_measure_subadditive:
  1319   assumes m: "A \<in> sets M" "B \<in> sets M"
  1320   shows "measure M (A \<union> B) \<le> measure M A + measure M B"
  1321   using measure_subadditive[OF m] by simp
  1323 lemma (in finite_measure) finite_measure_subadditive_finite:
  1324   assumes "finite I" "A`I \<subseteq> sets M" shows "measure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. measure M (A i))"
  1325   using measure_subadditive_finite[OF assms] by simp
  1327 lemma (in finite_measure) finite_measure_subadditive_countably:
  1328   assumes A: "range A \<subseteq> sets M" and sum: "summable (\<lambda>i. measure M (A i))"
  1329   shows "measure M (\<Union>i. A i) \<le> (\<Sum>i. measure M (A i))"
  1330 proof -
  1331   from `summable (\<lambda>i. measure M (A i))`
  1332   have "(\<lambda>i. ereal (measure M (A i))) sums ereal (\<Sum>i. measure M (A i))"
  1333     by (simp add: sums_ereal) (rule summable_sums)
  1334   from sums_unique[OF this, symmetric]
  1335        measure_subadditive_countably[OF A]
  1336   show ?thesis by (simp add: emeasure_eq_measure)
  1337 qed
  1339 lemma (in finite_measure) finite_measure_eq_setsum_singleton:
  1340   assumes "finite S" and *: "\<And>x. x \<in> S \<Longrightarrow> {x} \<in> sets M"
  1341   shows "measure M S = (\<Sum>x\<in>S. measure M {x})"
  1342   using measure_eq_setsum_singleton[OF assms] by simp
  1344 lemma (in finite_measure) finite_Lim_measure_incseq:
  1345   assumes A: "range A \<subseteq> sets M" "incseq A"
  1346   shows "(\<lambda>i. measure M (A i)) ----> measure M (\<Union>i. A i)"
  1347   using Lim_measure_incseq[OF A] by simp
  1349 lemma (in finite_measure) finite_Lim_measure_decseq:
  1350   assumes A: "range A \<subseteq> sets M" "decseq A"
  1351   shows "(\<lambda>n. measure M (A n)) ----> measure M (\<Inter>i. A i)"
  1352   using Lim_measure_decseq[OF A] by simp
  1354 lemma (in finite_measure) finite_measure_compl:
  1355   assumes S: "S \<in> sets M"
  1356   shows "measure M (space M - S) = measure M (space M) - measure M S"
  1357   using measure_Diff[OF _ top S sets_into_space] S by simp
  1359 lemma (in finite_measure) finite_measure_mono_AE:
  1360   assumes imp: "AE x in M. x \<in> A \<longrightarrow> x \<in> B" and B: "B \<in> sets M"
  1361   shows "measure M A \<le> measure M B"
  1362   using assms emeasure_mono_AE[OF imp B]
  1363   by (simp add: emeasure_eq_measure)
  1365 lemma (in finite_measure) finite_measure_eq_AE:
  1366   assumes iff: "AE x in M. x \<in> A \<longleftrightarrow> x \<in> B"
  1367   assumes A: "A \<in> sets M" and B: "B \<in> sets M"
  1368   shows "measure M A = measure M B"
  1369   using assms emeasure_eq_AE[OF assms] by (simp add: emeasure_eq_measure)
  1371 section {* Counting space *}
  1373 lemma strict_monoI_Suc:
  1374   assumes ord [simp]: "(\<And>n. f n < f (Suc n))" shows "strict_mono f"
  1375   unfolding strict_mono_def
  1376 proof safe
  1377   fix n m :: nat assume "n < m" then show "f n < f m"
  1378     by (induct m) (auto simp: less_Suc_eq intro: less_trans ord)
  1379 qed
  1381 lemma emeasure_count_space:
  1382   assumes "X \<subseteq> A" shows "emeasure (count_space A) X = (if finite X then ereal (card X) else \<infinity>)"
  1383     (is "_ = ?M X")
  1384   unfolding count_space_def
  1385 proof (rule emeasure_measure_of_sigma)
  1386   show "X \<in> Pow A" using `X \<subseteq> A` by auto
  1387   show "sigma_algebra A (Pow A)" by (rule sigma_algebra_Pow)
  1388   show positive: "positive (Pow A) ?M"
  1389     by (auto simp: positive_def)
  1390   have additive: "additive (Pow A) ?M"
  1391     by (auto simp: card_Un_disjoint additive_def)
  1393   interpret ring_of_sets A "Pow A"
  1394     by (rule ring_of_setsI) auto
  1395   show "countably_additive (Pow A) ?M" 
  1396     unfolding countably_additive_iff_continuous_from_below[OF positive additive]
  1397   proof safe
  1398     fix F :: "nat \<Rightarrow> 'a set" assume "incseq F"
  1399     show "(\<lambda>i. ?M (F i)) ----> ?M (\<Union>i. F i)"
  1400     proof cases
  1401       assume "\<exists>i. \<forall>j\<ge>i. F i = F j"
  1402       then guess i .. note i = this
  1403       { fix j from i `incseq F` have "F j \<subseteq> F i"
  1404           by (cases "i \<le> j") (auto simp: incseq_def) }
  1405       then have eq: "(\<Union>i. F i) = F i"
  1406         by auto
  1407       with i show ?thesis
  1408         by (auto intro!: Lim_eventually eventually_sequentiallyI[where c=i])
  1409     next
  1410       assume "\<not> (\<exists>i. \<forall>j\<ge>i. F i = F j)"
  1411       then obtain f where "\<And>i. i \<le> f i" "\<And>i. F i \<noteq> F (f i)" by metis
  1412       moreover then have "\<And>i. F i \<subseteq> F (f i)" using `incseq F` by (auto simp: incseq_def)
  1413       ultimately have *: "\<And>i. F i \<subset> F (f i)" by auto
  1415       have "incseq (\<lambda>i. ?M (F i))"
  1416         using `incseq F` unfolding incseq_def by (auto simp: card_mono dest: finite_subset)
  1417       then have "(\<lambda>i. ?M (F i)) ----> (SUP n. ?M (F n))"
  1418         by (rule LIMSEQ_ereal_SUPR)
  1420       moreover have "(SUP n. ?M (F n)) = \<infinity>"
  1421       proof (rule SUP_PInfty)
  1422         fix n :: nat show "\<exists>k::nat\<in>UNIV. ereal n \<le> ?M (F k)"
  1423         proof (induct n)
  1424           case (Suc n)
  1425           then guess k .. note k = this
  1426           moreover have "finite (F k) \<Longrightarrow> finite (F (f k)) \<Longrightarrow> card (F k) < card (F (f k))"
  1427             using `F k \<subset> F (f k)` by (simp add: psubset_card_mono)
  1428           moreover have "finite (F (f k)) \<Longrightarrow> finite (F k)"
  1429             using `k \<le> f k` `incseq F` by (auto simp: incseq_def dest: finite_subset)
  1430           ultimately show ?case
  1431             by (auto intro!: exI[of _ "f k"])
  1432         qed auto
  1433       qed
  1435       moreover
  1436       have "inj (\<lambda>n. F ((f ^^ n) 0))"
  1437         by (intro strict_mono_imp_inj_on strict_monoI_Suc) (simp add: *)
  1438       then have 1: "infinite (range (\<lambda>i. F ((f ^^ i) 0)))"
  1439         by (rule range_inj_infinite)
  1440       have "infinite (Pow (\<Union>i. F i))"
  1441         by (rule infinite_super[OF _ 1]) auto
  1442       then have "infinite (\<Union>i. F i)"
  1443         by auto
  1445       ultimately show ?thesis by auto
  1446     qed
  1447   qed
  1448 qed
  1450 lemma emeasure_count_space_finite[simp]:
  1451   "X \<subseteq> A \<Longrightarrow> finite X \<Longrightarrow> emeasure (count_space A) X = ereal (card X)"
  1452   using emeasure_count_space[of X A] by simp
  1454 lemma emeasure_count_space_infinite[simp]:
  1455   "X \<subseteq> A \<Longrightarrow> infinite X \<Longrightarrow> emeasure (count_space A) X = \<infinity>"
  1456   using emeasure_count_space[of X A] by simp
  1458 lemma emeasure_count_space_eq_0:
  1459   "emeasure (count_space A) X = 0 \<longleftrightarrow> (X \<subseteq> A \<longrightarrow> X = {})"
  1460 proof cases
  1461   assume X: "X \<subseteq> A"
  1462   then show ?thesis
  1463   proof (intro iffI impI)
  1464     assume "emeasure (count_space A) X = 0"
  1465     with X show "X = {}"
  1466       by (subst (asm) emeasure_count_space) (auto split: split_if_asm)
  1467   qed simp
  1468 qed (simp add: emeasure_notin_sets)
  1470 lemma null_sets_count_space: "null_sets (count_space A) = { {} }"
  1471   unfolding null_sets_def by (auto simp add: emeasure_count_space_eq_0)
  1473 lemma AE_count_space: "(AE x in count_space A. P x) \<longleftrightarrow> (\<forall>x\<in>A. P x)"
  1474   unfolding eventually_ae_filter by (auto simp add: null_sets_count_space)
  1476 lemma sigma_finite_measure_count_space:
  1477   fixes A :: "'a::countable set"
  1478   shows "sigma_finite_measure (count_space A)"
  1479 proof
  1480   show "\<exists>F::nat \<Rightarrow> 'a set. range F \<subseteq> sets (count_space A) \<and> (\<Union>i. F i) = space (count_space A) \<and>
  1481      (\<forall>i. emeasure (count_space A) (F i) \<noteq> \<infinity>)"
  1482      using surj_from_nat by (intro exI[of _ "\<lambda>i. {from_nat i} \<inter> A"]) (auto simp del: surj_from_nat)
  1483 qed
  1485 lemma finite_measure_count_space:
  1486   assumes [simp]: "finite A"
  1487   shows "finite_measure (count_space A)"
  1488   by rule simp
  1490 lemma sigma_finite_measure_count_space_finite:
  1491   assumes A: "finite A" shows "sigma_finite_measure (count_space A)"
  1492 proof -
  1493   interpret finite_measure "count_space A" using A by (rule finite_measure_count_space)
  1494   show "sigma_finite_measure (count_space A)" ..
  1495 qed
  1497 end