src/HOL/Probability/Sigma_Algebra.thy
author hoelzl
Fri Nov 02 14:23:40 2012 +0100 (2012-11-02)
changeset 50002 ce0d316b5b44
parent 49834 b27bbb021df1
child 50003 8c213922ed49
permissions -rw-r--r--
add measurability prover; add support for Borel sets
     1 (*  Title:      HOL/Probability/Sigma_Algebra.thy
     2     Author:     Stefan Richter, Markus Wenzel, TU München
     3     Author:     Johannes Hölzl, TU München
     4     Plus material from the Hurd/Coble measure theory development,
     5     translated by Lawrence Paulson.
     6 *)
     7 
     8 header {* Sigma Algebras *}
     9 
    10 theory Sigma_Algebra
    11 imports
    12   Complex_Main
    13   "~~/src/HOL/Library/Countable"
    14   "~~/src/HOL/Library/FuncSet"
    15   "~~/src/HOL/Library/Indicator_Function"
    16   "~~/src/HOL/Library/Extended_Real"
    17 begin
    18 
    19 text {* Sigma algebras are an elementary concept in measure
    20   theory. To measure --- that is to integrate --- functions, we first have
    21   to measure sets. Unfortunately, when dealing with a large universe,
    22   it is often not possible to consistently assign a measure to every
    23   subset. Therefore it is necessary to define the set of measurable
    24   subsets of the universe. A sigma algebra is such a set that has
    25   three very natural and desirable properties. *}
    26 
    27 subsection {* Families of sets *}
    28 
    29 locale subset_class =
    30   fixes \<Omega> :: "'a set" and M :: "'a set set"
    31   assumes space_closed: "M \<subseteq> Pow \<Omega>"
    32 
    33 lemma (in subset_class) sets_into_space: "x \<in> M \<Longrightarrow> x \<subseteq> \<Omega>"
    34   by (metis PowD contra_subsetD space_closed)
    35 
    36 subsection {* Semiring of sets *}
    37 
    38 subsubsection {* Disjoint sets *}
    39 
    40 definition "disjoint A \<longleftrightarrow> (\<forall>a\<in>A. \<forall>b\<in>A. a \<noteq> b \<longrightarrow> a \<inter> b = {})"
    41 
    42 lemma disjointI:
    43   "(\<And>a b. a \<in> A \<Longrightarrow> b \<in> A \<Longrightarrow> a \<noteq> b \<Longrightarrow> a \<inter> b = {}) \<Longrightarrow> disjoint A"
    44   unfolding disjoint_def by auto
    45 
    46 lemma disjointD:
    47   "disjoint A \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> A \<Longrightarrow> a \<noteq> b \<Longrightarrow> a \<inter> b = {}"
    48   unfolding disjoint_def by auto
    49 
    50 lemma disjoint_empty[iff]: "disjoint {}"
    51   by (auto simp: disjoint_def)
    52 
    53 lemma disjoint_union: 
    54   assumes C: "disjoint C" and B: "disjoint B" and disj: "\<Union>C \<inter> \<Union>B = {}"
    55   shows "disjoint (C \<union> B)"
    56 proof (rule disjointI)
    57   fix c d assume sets: "c \<in> C \<union> B" "d \<in> C \<union> B" and "c \<noteq> d"
    58   show "c \<inter> d = {}"
    59   proof cases
    60     assume "(c \<in> C \<and> d \<in> C) \<or> (c \<in> B \<and> d \<in> B)"
    61     then show ?thesis
    62     proof 
    63       assume "c \<in> C \<and> d \<in> C" with `c \<noteq> d` C show "c \<inter> d = {}"
    64         by (auto simp: disjoint_def)
    65     next
    66       assume "c \<in> B \<and> d \<in> B" with `c \<noteq> d` B show "c \<inter> d = {}"
    67         by (auto simp: disjoint_def)
    68     qed
    69   next
    70     assume "\<not> ((c \<in> C \<and> d \<in> C) \<or> (c \<in> B \<and> d \<in> B))"
    71     with sets have "(c \<subseteq> \<Union>C \<and> d \<subseteq> \<Union>B) \<or> (c \<subseteq> \<Union>B \<and> d \<subseteq> \<Union>C)"
    72       by auto
    73     with disj show "c \<inter> d = {}" by auto
    74   qed
    75 qed
    76 
    77 locale semiring_of_sets = subset_class +
    78   assumes empty_sets[iff]: "{} \<in> M"
    79   assumes Int[intro]: "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a \<inter> b \<in> M"
    80   assumes Diff_cover:
    81     "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> \<exists>C\<subseteq>M. finite C \<and> disjoint C \<and> a - b = \<Union>C"
    82 
    83 lemma (in semiring_of_sets) finite_INT[intro]:
    84   assumes "finite I" "I \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> A i \<in> M"
    85   shows "(\<Inter>i\<in>I. A i) \<in> M"
    86   using assms by (induct rule: finite_ne_induct) auto
    87 
    88 lemma (in semiring_of_sets) Int_space_eq1 [simp]: "x \<in> M \<Longrightarrow> \<Omega> \<inter> x = x"
    89   by (metis Int_absorb1 sets_into_space)
    90 
    91 lemma (in semiring_of_sets) Int_space_eq2 [simp]: "x \<in> M \<Longrightarrow> x \<inter> \<Omega> = x"
    92   by (metis Int_absorb2 sets_into_space)
    93 
    94 lemma (in semiring_of_sets) sets_Collect_conj:
    95   assumes "{x\<in>\<Omega>. P x} \<in> M" "{x\<in>\<Omega>. Q x} \<in> M"
    96   shows "{x\<in>\<Omega>. Q x \<and> P x} \<in> M"
    97 proof -
    98   have "{x\<in>\<Omega>. Q x \<and> P x} = {x\<in>\<Omega>. Q x} \<inter> {x\<in>\<Omega>. P x}"
    99     by auto
   100   with assms show ?thesis by auto
   101 qed
   102 
   103 lemma (in semiring_of_sets) sets_Collect_finite_All':
   104   assumes "\<And>i. i \<in> S \<Longrightarrow> {x\<in>\<Omega>. P i x} \<in> M" "finite S" "S \<noteq> {}"
   105   shows "{x\<in>\<Omega>. \<forall>i\<in>S. P i x} \<in> M"
   106 proof -
   107   have "{x\<in>\<Omega>. \<forall>i\<in>S. P i x} = (\<Inter>i\<in>S. {x\<in>\<Omega>. P i x})"
   108     using `S \<noteq> {}` by auto
   109   with assms show ?thesis by auto
   110 qed
   111 
   112 locale ring_of_sets = semiring_of_sets +
   113   assumes Un [intro]: "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a \<union> b \<in> M"
   114 
   115 lemma (in ring_of_sets) finite_Union [intro]:
   116   "finite X \<Longrightarrow> X \<subseteq> M \<Longrightarrow> Union X \<in> M"
   117   by (induct set: finite) (auto simp add: Un)
   118 
   119 lemma (in ring_of_sets) finite_UN[intro]:
   120   assumes "finite I" and "\<And>i. i \<in> I \<Longrightarrow> A i \<in> M"
   121   shows "(\<Union>i\<in>I. A i) \<in> M"
   122   using assms by induct auto
   123 
   124 lemma (in ring_of_sets) Diff [intro]:
   125   assumes "a \<in> M" "b \<in> M" shows "a - b \<in> M"
   126   using Diff_cover[OF assms] by auto
   127 
   128 lemma ring_of_setsI:
   129   assumes space_closed: "M \<subseteq> Pow \<Omega>"
   130   assumes empty_sets[iff]: "{} \<in> M"
   131   assumes Un[intro]: "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a \<union> b \<in> M"
   132   assumes Diff[intro]: "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a - b \<in> M"
   133   shows "ring_of_sets \<Omega> M"
   134 proof
   135   fix a b assume ab: "a \<in> M" "b \<in> M"
   136   from ab show "\<exists>C\<subseteq>M. finite C \<and> disjoint C \<and> a - b = \<Union>C"
   137     by (intro exI[of _ "{a - b}"]) (auto simp: disjoint_def)
   138   have "a \<inter> b = a - (a - b)" by auto
   139   also have "\<dots> \<in> M" using ab by auto
   140   finally show "a \<inter> b \<in> M" .
   141 qed fact+
   142 
   143 lemma ring_of_sets_iff: "ring_of_sets \<Omega> M \<longleftrightarrow> M \<subseteq> Pow \<Omega> \<and> {} \<in> M \<and> (\<forall>a\<in>M. \<forall>b\<in>M. a \<union> b \<in> M) \<and> (\<forall>a\<in>M. \<forall>b\<in>M. a - b \<in> M)"
   144 proof
   145   assume "ring_of_sets \<Omega> M"
   146   then interpret ring_of_sets \<Omega> M .
   147   show "M \<subseteq> Pow \<Omega> \<and> {} \<in> M \<and> (\<forall>a\<in>M. \<forall>b\<in>M. a \<union> b \<in> M) \<and> (\<forall>a\<in>M. \<forall>b\<in>M. a - b \<in> M)"
   148     using space_closed by auto
   149 qed (auto intro!: ring_of_setsI)
   150 
   151 lemma (in ring_of_sets) insert_in_sets:
   152   assumes "{x} \<in> M" "A \<in> M" shows "insert x A \<in> M"
   153 proof -
   154   have "{x} \<union> A \<in> M" using assms by (rule Un)
   155   thus ?thesis by auto
   156 qed
   157 
   158 lemma (in ring_of_sets) sets_Collect_disj:
   159   assumes "{x\<in>\<Omega>. P x} \<in> M" "{x\<in>\<Omega>. Q x} \<in> M"
   160   shows "{x\<in>\<Omega>. Q x \<or> P x} \<in> M"
   161 proof -
   162   have "{x\<in>\<Omega>. Q x \<or> P x} = {x\<in>\<Omega>. Q x} \<union> {x\<in>\<Omega>. P x}"
   163     by auto
   164   with assms show ?thesis by auto
   165 qed
   166 
   167 lemma (in ring_of_sets) sets_Collect_finite_Ex:
   168   assumes "\<And>i. i \<in> S \<Longrightarrow> {x\<in>\<Omega>. P i x} \<in> M" "finite S"
   169   shows "{x\<in>\<Omega>. \<exists>i\<in>S. P i x} \<in> M"
   170 proof -
   171   have "{x\<in>\<Omega>. \<exists>i\<in>S. P i x} = (\<Union>i\<in>S. {x\<in>\<Omega>. P i x})"
   172     by auto
   173   with assms show ?thesis by auto
   174 qed
   175 
   176 locale algebra = ring_of_sets +
   177   assumes top [iff]: "\<Omega> \<in> M"
   178 
   179 lemma (in algebra) compl_sets [intro]:
   180   "a \<in> M \<Longrightarrow> \<Omega> - a \<in> M"
   181   by auto
   182 
   183 lemma algebra_iff_Un:
   184   "algebra \<Omega> M \<longleftrightarrow>
   185     M \<subseteq> Pow \<Omega> \<and>
   186     {} \<in> M \<and>
   187     (\<forall>a \<in> M. \<Omega> - a \<in> M) \<and>
   188     (\<forall>a \<in> M. \<forall> b \<in> M. a \<union> b \<in> M)" (is "_ \<longleftrightarrow> ?Un")
   189 proof
   190   assume "algebra \<Omega> M"
   191   then interpret algebra \<Omega> M .
   192   show ?Un using sets_into_space by auto
   193 next
   194   assume ?Un
   195   then have "\<Omega> \<in> M" by auto
   196   interpret ring_of_sets \<Omega> M
   197   proof (rule ring_of_setsI)
   198     show \<Omega>: "M \<subseteq> Pow \<Omega>" "{} \<in> M"
   199       using `?Un` by auto
   200     fix a b assume a: "a \<in> M" and b: "b \<in> M"
   201     then show "a \<union> b \<in> M" using `?Un` by auto
   202     have "a - b = \<Omega> - ((\<Omega> - a) \<union> b)"
   203       using \<Omega> a b by auto
   204     then show "a - b \<in> M"
   205       using a b  `?Un` by auto
   206   qed
   207   show "algebra \<Omega> M" proof qed fact
   208 qed
   209 
   210 lemma algebra_iff_Int:
   211      "algebra \<Omega> M \<longleftrightarrow>
   212        M \<subseteq> Pow \<Omega> & {} \<in> M &
   213        (\<forall>a \<in> M. \<Omega> - a \<in> M) &
   214        (\<forall>a \<in> M. \<forall> b \<in> M. a \<inter> b \<in> M)" (is "_ \<longleftrightarrow> ?Int")
   215 proof
   216   assume "algebra \<Omega> M"
   217   then interpret algebra \<Omega> M .
   218   show ?Int using sets_into_space by auto
   219 next
   220   assume ?Int
   221   show "algebra \<Omega> M"
   222   proof (unfold algebra_iff_Un, intro conjI ballI)
   223     show \<Omega>: "M \<subseteq> Pow \<Omega>" "{} \<in> M"
   224       using `?Int` by auto
   225     from `?Int` show "\<And>a. a \<in> M \<Longrightarrow> \<Omega> - a \<in> M" by auto
   226     fix a b assume M: "a \<in> M" "b \<in> M"
   227     hence "a \<union> b = \<Omega> - ((\<Omega> - a) \<inter> (\<Omega> - b))"
   228       using \<Omega> by blast
   229     also have "... \<in> M"
   230       using M `?Int` by auto
   231     finally show "a \<union> b \<in> M" .
   232   qed
   233 qed
   234 
   235 lemma (in algebra) sets_Collect_neg:
   236   assumes "{x\<in>\<Omega>. P x} \<in> M"
   237   shows "{x\<in>\<Omega>. \<not> P x} \<in> M"
   238 proof -
   239   have "{x\<in>\<Omega>. \<not> P x} = \<Omega> - {x\<in>\<Omega>. P x}" by auto
   240   with assms show ?thesis by auto
   241 qed
   242 
   243 lemma (in algebra) sets_Collect_imp:
   244   "{x\<in>\<Omega>. P x} \<in> M \<Longrightarrow> {x\<in>\<Omega>. Q x} \<in> M \<Longrightarrow> {x\<in>\<Omega>. Q x \<longrightarrow> P x} \<in> M"
   245   unfolding imp_conv_disj by (intro sets_Collect_disj sets_Collect_neg)
   246 
   247 lemma (in algebra) sets_Collect_const:
   248   "{x\<in>\<Omega>. P} \<in> M"
   249   by (cases P) auto
   250 
   251 lemma algebra_single_set:
   252   "X \<subseteq> S \<Longrightarrow> algebra S { {}, X, S - X, S }"
   253   by (auto simp: algebra_iff_Int)
   254 
   255 section {* Restricted algebras *}
   256 
   257 abbreviation (in algebra)
   258   "restricted_space A \<equiv> (op \<inter> A) ` M"
   259 
   260 lemma (in algebra) restricted_algebra:
   261   assumes "A \<in> M" shows "algebra A (restricted_space A)"
   262   using assms by (auto simp: algebra_iff_Int)
   263 
   264 subsection {* Sigma Algebras *}
   265 
   266 locale sigma_algebra = algebra +
   267   assumes countable_nat_UN [intro]: "\<And>A. range A \<subseteq> M \<Longrightarrow> (\<Union>i::nat. A i) \<in> M"
   268 
   269 lemma (in algebra) is_sigma_algebra:
   270   assumes "finite M"
   271   shows "sigma_algebra \<Omega> M"
   272 proof
   273   fix A :: "nat \<Rightarrow> 'a set" assume "range A \<subseteq> M"
   274   then have "(\<Union>i. A i) = (\<Union>s\<in>M \<inter> range A. s)"
   275     by auto
   276   also have "(\<Union>s\<in>M \<inter> range A. s) \<in> M"
   277     using `finite M` by auto
   278   finally show "(\<Union>i. A i) \<in> M" .
   279 qed
   280 
   281 lemma countable_UN_eq:
   282   fixes A :: "'i::countable \<Rightarrow> 'a set"
   283   shows "(range A \<subseteq> M \<longrightarrow> (\<Union>i. A i) \<in> M) \<longleftrightarrow>
   284     (range (A \<circ> from_nat) \<subseteq> M \<longrightarrow> (\<Union>i. (A \<circ> from_nat) i) \<in> M)"
   285 proof -
   286   let ?A' = "A \<circ> from_nat"
   287   have *: "(\<Union>i. ?A' i) = (\<Union>i. A i)" (is "?l = ?r")
   288   proof safe
   289     fix x i assume "x \<in> A i" thus "x \<in> ?l"
   290       by (auto intro!: exI[of _ "to_nat i"])
   291   next
   292     fix x i assume "x \<in> ?A' i" thus "x \<in> ?r"
   293       by (auto intro!: exI[of _ "from_nat i"])
   294   qed
   295   have **: "range ?A' = range A"
   296     using surj_from_nat
   297     by (auto simp: image_compose intro!: imageI)
   298   show ?thesis unfolding * ** ..
   299 qed
   300 
   301 lemma (in sigma_algebra) countable_UN[intro]:
   302   fixes A :: "'i::countable \<Rightarrow> 'a set"
   303   assumes "A`X \<subseteq> M"
   304   shows  "(\<Union>x\<in>X. A x) \<in> M"
   305 proof -
   306   let ?A = "\<lambda>i. if i \<in> X then A i else {}"
   307   from assms have "range ?A \<subseteq> M" by auto
   308   with countable_nat_UN[of "?A \<circ> from_nat"] countable_UN_eq[of ?A M]
   309   have "(\<Union>x. ?A x) \<in> M" by auto
   310   moreover have "(\<Union>x. ?A x) = (\<Union>x\<in>X. A x)" by (auto split: split_if_asm)
   311   ultimately show ?thesis by simp
   312 qed
   313 
   314 lemma (in sigma_algebra) countable_INT [intro]:
   315   fixes A :: "'i::countable \<Rightarrow> 'a set"
   316   assumes A: "A`X \<subseteq> M" "X \<noteq> {}"
   317   shows "(\<Inter>i\<in>X. A i) \<in> M"
   318 proof -
   319   from A have "\<forall>i\<in>X. A i \<in> M" by fast
   320   hence "\<Omega> - (\<Union>i\<in>X. \<Omega> - A i) \<in> M" by blast
   321   moreover
   322   have "(\<Inter>i\<in>X. A i) = \<Omega> - (\<Union>i\<in>X. \<Omega> - A i)" using space_closed A
   323     by blast
   324   ultimately show ?thesis by metis
   325 qed
   326 
   327 lemma ring_of_sets_Pow: "ring_of_sets sp (Pow sp)"
   328   by (auto simp: ring_of_sets_iff)
   329 
   330 lemma algebra_Pow: "algebra sp (Pow sp)"
   331   by (auto simp: algebra_iff_Un)
   332 
   333 lemma sigma_algebra_iff:
   334   "sigma_algebra \<Omega> M \<longleftrightarrow>
   335     algebra \<Omega> M \<and> (\<forall>A. range A \<subseteq> M \<longrightarrow> (\<Union>i::nat. A i) \<in> M)"
   336   by (simp add: sigma_algebra_def sigma_algebra_axioms_def)
   337 
   338 lemma sigma_algebra_Pow: "sigma_algebra sp (Pow sp)"
   339   by (auto simp: sigma_algebra_iff algebra_iff_Int)
   340 
   341 lemma (in sigma_algebra) sets_Collect_countable_All:
   342   assumes "\<And>i. {x\<in>\<Omega>. P i x} \<in> M"
   343   shows "{x\<in>\<Omega>. \<forall>i::'i::countable. P i x} \<in> M"
   344 proof -
   345   have "{x\<in>\<Omega>. \<forall>i::'i::countable. P i x} = (\<Inter>i. {x\<in>\<Omega>. P i x})" by auto
   346   with assms show ?thesis by auto
   347 qed
   348 
   349 lemma (in sigma_algebra) sets_Collect_countable_Ex:
   350   assumes "\<And>i. {x\<in>\<Omega>. P i x} \<in> M"
   351   shows "{x\<in>\<Omega>. \<exists>i::'i::countable. P i x} \<in> M"
   352 proof -
   353   have "{x\<in>\<Omega>. \<exists>i::'i::countable. P i x} = (\<Union>i. {x\<in>\<Omega>. P i x})" by auto
   354   with assms show ?thesis by auto
   355 qed
   356 
   357 lemmas (in sigma_algebra) sets_Collect =
   358   sets_Collect_imp sets_Collect_disj sets_Collect_conj sets_Collect_neg sets_Collect_const
   359   sets_Collect_countable_All sets_Collect_countable_Ex sets_Collect_countable_All
   360 
   361 lemma (in sigma_algebra) sets_Collect_countable_Ball:
   362   assumes "\<And>i. {x\<in>\<Omega>. P i x} \<in> M"
   363   shows "{x\<in>\<Omega>. \<forall>i::'i::countable\<in>X. P i x} \<in> M"
   364   unfolding Ball_def by (intro sets_Collect assms)
   365 
   366 lemma (in sigma_algebra) sets_Collect_countable_Bex:
   367   assumes "\<And>i. {x\<in>\<Omega>. P i x} \<in> M"
   368   shows "{x\<in>\<Omega>. \<exists>i::'i::countable\<in>X. P i x} \<in> M"
   369   unfolding Bex_def by (intro sets_Collect assms)
   370 
   371 lemma sigma_algebra_single_set:
   372   assumes "X \<subseteq> S"
   373   shows "sigma_algebra S { {}, X, S - X, S }"
   374   using algebra.is_sigma_algebra[OF algebra_single_set[OF `X \<subseteq> S`]] by simp
   375 
   376 subsection {* Binary Unions *}
   377 
   378 definition binary :: "'a \<Rightarrow> 'a \<Rightarrow> nat \<Rightarrow> 'a"
   379   where "binary a b =  (\<lambda>\<^isup>x. b)(0 := a)"
   380 
   381 lemma range_binary_eq: "range(binary a b) = {a,b}"
   382   by (auto simp add: binary_def)
   383 
   384 lemma Un_range_binary: "a \<union> b = (\<Union>i::nat. binary a b i)"
   385   by (simp add: SUP_def range_binary_eq)
   386 
   387 lemma Int_range_binary: "a \<inter> b = (\<Inter>i::nat. binary a b i)"
   388   by (simp add: INF_def range_binary_eq)
   389 
   390 lemma sigma_algebra_iff2:
   391      "sigma_algebra \<Omega> M \<longleftrightarrow>
   392        M \<subseteq> Pow \<Omega> \<and>
   393        {} \<in> M \<and> (\<forall>s \<in> M. \<Omega> - s \<in> M) \<and>
   394        (\<forall>A. range A \<subseteq> M \<longrightarrow> (\<Union>i::nat. A i) \<in> M)"
   395   by (auto simp add: range_binary_eq sigma_algebra_def sigma_algebra_axioms_def
   396          algebra_iff_Un Un_range_binary)
   397 
   398 subsection {* Initial Sigma Algebra *}
   399 
   400 text {*Sigma algebras can naturally be created as the closure of any set of
   401   M with regard to the properties just postulated.  *}
   402 
   403 inductive_set
   404   sigma_sets :: "'a set \<Rightarrow> 'a set set \<Rightarrow> 'a set set"
   405   for sp :: "'a set" and A :: "'a set set"
   406   where
   407     Basic[intro, simp]: "a \<in> A \<Longrightarrow> a \<in> sigma_sets sp A"
   408   | Empty: "{} \<in> sigma_sets sp A"
   409   | Compl: "a \<in> sigma_sets sp A \<Longrightarrow> sp - a \<in> sigma_sets sp A"
   410   | Union: "(\<And>i::nat. a i \<in> sigma_sets sp A) \<Longrightarrow> (\<Union>i. a i) \<in> sigma_sets sp A"
   411 
   412 lemma (in sigma_algebra) sigma_sets_subset:
   413   assumes a: "a \<subseteq> M"
   414   shows "sigma_sets \<Omega> a \<subseteq> M"
   415 proof
   416   fix x
   417   assume "x \<in> sigma_sets \<Omega> a"
   418   from this show "x \<in> M"
   419     by (induct rule: sigma_sets.induct, auto) (metis a subsetD)
   420 qed
   421 
   422 lemma sigma_sets_into_sp: "A \<subseteq> Pow sp \<Longrightarrow> x \<in> sigma_sets sp A \<Longrightarrow> x \<subseteq> sp"
   423   by (erule sigma_sets.induct, auto)
   424 
   425 lemma sigma_algebra_sigma_sets:
   426      "a \<subseteq> Pow \<Omega> \<Longrightarrow> sigma_algebra \<Omega> (sigma_sets \<Omega> a)"
   427   by (auto simp add: sigma_algebra_iff2 dest: sigma_sets_into_sp
   428            intro!: sigma_sets.Union sigma_sets.Empty sigma_sets.Compl)
   429 
   430 lemma sigma_sets_least_sigma_algebra:
   431   assumes "A \<subseteq> Pow S"
   432   shows "sigma_sets S A = \<Inter>{B. A \<subseteq> B \<and> sigma_algebra S B}"
   433 proof safe
   434   fix B X assume "A \<subseteq> B" and sa: "sigma_algebra S B"
   435     and X: "X \<in> sigma_sets S A"
   436   from sigma_algebra.sigma_sets_subset[OF sa, simplified, OF `A \<subseteq> B`] X
   437   show "X \<in> B" by auto
   438 next
   439   fix X assume "X \<in> \<Inter>{B. A \<subseteq> B \<and> sigma_algebra S B}"
   440   then have [intro!]: "\<And>B. A \<subseteq> B \<Longrightarrow> sigma_algebra S B \<Longrightarrow> X \<in> B"
   441      by simp
   442   have "A \<subseteq> sigma_sets S A" using assms by auto
   443   moreover have "sigma_algebra S (sigma_sets S A)"
   444     using assms by (intro sigma_algebra_sigma_sets[of A]) auto
   445   ultimately show "X \<in> sigma_sets S A" by auto
   446 qed
   447 
   448 lemma sigma_sets_top: "sp \<in> sigma_sets sp A"
   449   by (metis Diff_empty sigma_sets.Compl sigma_sets.Empty)
   450 
   451 lemma sigma_sets_Un:
   452   "a \<in> sigma_sets sp A \<Longrightarrow> b \<in> sigma_sets sp A \<Longrightarrow> a \<union> b \<in> sigma_sets sp A"
   453 apply (simp add: Un_range_binary range_binary_eq)
   454 apply (rule Union, simp add: binary_def)
   455 done
   456 
   457 lemma sigma_sets_Inter:
   458   assumes Asb: "A \<subseteq> Pow sp"
   459   shows "(\<And>i::nat. a i \<in> sigma_sets sp A) \<Longrightarrow> (\<Inter>i. a i) \<in> sigma_sets sp A"
   460 proof -
   461   assume ai: "\<And>i::nat. a i \<in> sigma_sets sp A"
   462   hence "\<And>i::nat. sp-(a i) \<in> sigma_sets sp A"
   463     by (rule sigma_sets.Compl)
   464   hence "(\<Union>i. sp-(a i)) \<in> sigma_sets sp A"
   465     by (rule sigma_sets.Union)
   466   hence "sp-(\<Union>i. sp-(a i)) \<in> sigma_sets sp A"
   467     by (rule sigma_sets.Compl)
   468   also have "sp-(\<Union>i. sp-(a i)) = sp Int (\<Inter>i. a i)"
   469     by auto
   470   also have "... = (\<Inter>i. a i)" using ai
   471     by (blast dest: sigma_sets_into_sp [OF Asb])
   472   finally show ?thesis .
   473 qed
   474 
   475 lemma sigma_sets_INTER:
   476   assumes Asb: "A \<subseteq> Pow sp"
   477       and ai: "\<And>i::nat. i \<in> S \<Longrightarrow> a i \<in> sigma_sets sp A" and non: "S \<noteq> {}"
   478   shows "(\<Inter>i\<in>S. a i) \<in> sigma_sets sp A"
   479 proof -
   480   from ai have "\<And>i. (if i\<in>S then a i else sp) \<in> sigma_sets sp A"
   481     by (simp add: sigma_sets.intros(2-) sigma_sets_top)
   482   hence "(\<Inter>i. (if i\<in>S then a i else sp)) \<in> sigma_sets sp A"
   483     by (rule sigma_sets_Inter [OF Asb])
   484   also have "(\<Inter>i. (if i\<in>S then a i else sp)) = (\<Inter>i\<in>S. a i)"
   485     by auto (metis ai non sigma_sets_into_sp subset_empty subset_iff Asb)+
   486   finally show ?thesis .
   487 qed
   488 
   489 lemma (in sigma_algebra) sigma_sets_eq:
   490      "sigma_sets \<Omega> M = M"
   491 proof
   492   show "M \<subseteq> sigma_sets \<Omega> M"
   493     by (metis Set.subsetI sigma_sets.Basic)
   494   next
   495   show "sigma_sets \<Omega> M \<subseteq> M"
   496     by (metis sigma_sets_subset subset_refl)
   497 qed
   498 
   499 lemma sigma_sets_eqI:
   500   assumes A: "\<And>a. a \<in> A \<Longrightarrow> a \<in> sigma_sets M B"
   501   assumes B: "\<And>b. b \<in> B \<Longrightarrow> b \<in> sigma_sets M A"
   502   shows "sigma_sets M A = sigma_sets M B"
   503 proof (intro set_eqI iffI)
   504   fix a assume "a \<in> sigma_sets M A"
   505   from this A show "a \<in> sigma_sets M B"
   506     by induct (auto intro!: sigma_sets.intros(2-) del: sigma_sets.Basic)
   507 next
   508   fix b assume "b \<in> sigma_sets M B"
   509   from this B show "b \<in> sigma_sets M A"
   510     by induct (auto intro!: sigma_sets.intros(2-) del: sigma_sets.Basic)
   511 qed
   512 
   513 lemma sigma_sets_subseteq: assumes "A \<subseteq> B" shows "sigma_sets X A \<subseteq> sigma_sets X B"
   514 proof
   515   fix x assume "x \<in> sigma_sets X A" then show "x \<in> sigma_sets X B"
   516     by induct (insert `A \<subseteq> B`, auto intro: sigma_sets.intros(2-))
   517 qed
   518 
   519 lemma sigma_sets_mono: assumes "A \<subseteq> sigma_sets X B" shows "sigma_sets X A \<subseteq> sigma_sets X B"
   520 proof
   521   fix x assume "x \<in> sigma_sets X A" then show "x \<in> sigma_sets X B"
   522     by induct (insert `A \<subseteq> sigma_sets X B`, auto intro: sigma_sets.intros(2-))
   523 qed
   524 
   525 lemma sigma_sets_mono': assumes "A \<subseteq> B" shows "sigma_sets X A \<subseteq> sigma_sets X B"
   526 proof
   527   fix x assume "x \<in> sigma_sets X A" then show "x \<in> sigma_sets X B"
   528     by induct (insert `A \<subseteq> B`, auto intro: sigma_sets.intros(2-))
   529 qed
   530 
   531 lemma sigma_sets_superset_generator: "A \<subseteq> sigma_sets X A"
   532   by (auto intro: sigma_sets.Basic)
   533 
   534 lemma (in sigma_algebra) restriction_in_sets:
   535   fixes A :: "nat \<Rightarrow> 'a set"
   536   assumes "S \<in> M"
   537   and *: "range A \<subseteq> (\<lambda>A. S \<inter> A) ` M" (is "_ \<subseteq> ?r")
   538   shows "range A \<subseteq> M" "(\<Union>i. A i) \<in> (\<lambda>A. S \<inter> A) ` M"
   539 proof -
   540   { fix i have "A i \<in> ?r" using * by auto
   541     hence "\<exists>B. A i = B \<inter> S \<and> B \<in> M" by auto
   542     hence "A i \<subseteq> S" "A i \<in> M" using `S \<in> M` by auto }
   543   thus "range A \<subseteq> M" "(\<Union>i. A i) \<in> (\<lambda>A. S \<inter> A) ` M"
   544     by (auto intro!: image_eqI[of _ _ "(\<Union>i. A i)"])
   545 qed
   546 
   547 lemma (in sigma_algebra) restricted_sigma_algebra:
   548   assumes "S \<in> M"
   549   shows "sigma_algebra S (restricted_space S)"
   550   unfolding sigma_algebra_def sigma_algebra_axioms_def
   551 proof safe
   552   show "algebra S (restricted_space S)" using restricted_algebra[OF assms] .
   553 next
   554   fix A :: "nat \<Rightarrow> 'a set" assume "range A \<subseteq> restricted_space S"
   555   from restriction_in_sets[OF assms this[simplified]]
   556   show "(\<Union>i. A i) \<in> restricted_space S" by simp
   557 qed
   558 
   559 lemma sigma_sets_Int:
   560   assumes "A \<in> sigma_sets sp st" "A \<subseteq> sp"
   561   shows "op \<inter> A ` sigma_sets sp st = sigma_sets A (op \<inter> A ` st)"
   562 proof (intro equalityI subsetI)
   563   fix x assume "x \<in> op \<inter> A ` sigma_sets sp st"
   564   then obtain y where "y \<in> sigma_sets sp st" "x = y \<inter> A" by auto
   565   then have "x \<in> sigma_sets (A \<inter> sp) (op \<inter> A ` st)"
   566   proof (induct arbitrary: x)
   567     case (Compl a)
   568     then show ?case
   569       by (force intro!: sigma_sets.Compl simp: Diff_Int_distrib ac_simps)
   570   next
   571     case (Union a)
   572     then show ?case
   573       by (auto intro!: sigma_sets.Union
   574                simp add: UN_extend_simps simp del: UN_simps)
   575   qed (auto intro!: sigma_sets.intros(2-))
   576   then show "x \<in> sigma_sets A (op \<inter> A ` st)"
   577     using `A \<subseteq> sp` by (simp add: Int_absorb2)
   578 next
   579   fix x assume "x \<in> sigma_sets A (op \<inter> A ` st)"
   580   then show "x \<in> op \<inter> A ` sigma_sets sp st"
   581   proof induct
   582     case (Compl a)
   583     then obtain x where "a = A \<inter> x" "x \<in> sigma_sets sp st" by auto
   584     then show ?case using `A \<subseteq> sp`
   585       by (force simp add: image_iff intro!: bexI[of _ "sp - x"] sigma_sets.Compl)
   586   next
   587     case (Union a)
   588     then have "\<forall>i. \<exists>x. x \<in> sigma_sets sp st \<and> a i = A \<inter> x"
   589       by (auto simp: image_iff Bex_def)
   590     from choice[OF this] guess f ..
   591     then show ?case
   592       by (auto intro!: bexI[of _ "(\<Union>x. f x)"] sigma_sets.Union
   593                simp add: image_iff)
   594   qed (auto intro!: sigma_sets.intros(2-))
   595 qed
   596 
   597 lemma sigma_sets_empty_eq: "sigma_sets A {} = {{}, A}"
   598 proof (intro set_eqI iffI)
   599   fix a assume "a \<in> sigma_sets A {}" then show "a \<in> {{}, A}"
   600     by induct blast+
   601 qed (auto intro: sigma_sets.Empty sigma_sets_top)
   602 
   603 lemma sigma_sets_single[simp]: "sigma_sets A {A} = {{}, A}"
   604 proof (intro set_eqI iffI)
   605   fix x assume "x \<in> sigma_sets A {A}"
   606   then show "x \<in> {{}, A}"
   607     by induct blast+
   608 next
   609   fix x assume "x \<in> {{}, A}"
   610   then show "x \<in> sigma_sets A {A}"
   611     by (auto intro: sigma_sets.Empty sigma_sets_top)
   612 qed
   613 
   614 lemma sigma_sets_sigma_sets_eq:
   615   "M \<subseteq> Pow S \<Longrightarrow> sigma_sets S (sigma_sets S M) = sigma_sets S M"
   616   by (rule sigma_algebra.sigma_sets_eq[OF sigma_algebra_sigma_sets, of M S]) auto
   617 
   618 lemma sigma_sets_singleton:
   619   assumes "X \<subseteq> S"
   620   shows "sigma_sets S { X } = { {}, X, S - X, S }"
   621 proof -
   622   interpret sigma_algebra S "{ {}, X, S - X, S }"
   623     by (rule sigma_algebra_single_set) fact
   624   have "sigma_sets S { X } \<subseteq> sigma_sets S { {}, X, S - X, S }"
   625     by (rule sigma_sets_subseteq) simp
   626   moreover have "\<dots> = { {}, X, S - X, S }"
   627     using sigma_sets_eq by simp
   628   moreover
   629   { fix A assume "A \<in> { {}, X, S - X, S }"
   630     then have "A \<in> sigma_sets S { X }"
   631       by (auto intro: sigma_sets.intros(2-) sigma_sets_top) }
   632   ultimately have "sigma_sets S { X } = sigma_sets S { {}, X, S - X, S }"
   633     by (intro antisym) auto
   634   with sigma_sets_eq show ?thesis by simp
   635 qed
   636 
   637 lemma restricted_sigma:
   638   assumes S: "S \<in> sigma_sets \<Omega> M" and M: "M \<subseteq> Pow \<Omega>"
   639   shows "algebra.restricted_space (sigma_sets \<Omega> M) S =
   640     sigma_sets S (algebra.restricted_space M S)"
   641 proof -
   642   from S sigma_sets_into_sp[OF M]
   643   have "S \<in> sigma_sets \<Omega> M" "S \<subseteq> \<Omega>" by auto
   644   from sigma_sets_Int[OF this]
   645   show ?thesis by simp
   646 qed
   647 
   648 lemma sigma_sets_vimage_commute:
   649   assumes X: "X \<in> \<Omega> \<rightarrow> \<Omega>'"
   650   shows "{X -` A \<inter> \<Omega> |A. A \<in> sigma_sets \<Omega>' M'}
   651        = sigma_sets \<Omega> {X -` A \<inter> \<Omega> |A. A \<in> M'}" (is "?L = ?R")
   652 proof
   653   show "?L \<subseteq> ?R"
   654   proof clarify
   655     fix A assume "A \<in> sigma_sets \<Omega>' M'"
   656     then show "X -` A \<inter> \<Omega> \<in> ?R"
   657     proof induct
   658       case Empty then show ?case
   659         by (auto intro!: sigma_sets.Empty)
   660     next
   661       case (Compl B)
   662       have [simp]: "X -` (\<Omega>' - B) \<inter> \<Omega> = \<Omega> - (X -` B \<inter> \<Omega>)"
   663         by (auto simp add: funcset_mem [OF X])
   664       with Compl show ?case
   665         by (auto intro!: sigma_sets.Compl)
   666     next
   667       case (Union F)
   668       then show ?case
   669         by (auto simp add: vimage_UN UN_extend_simps(4) simp del: UN_simps
   670                  intro!: sigma_sets.Union)
   671     qed auto
   672   qed
   673   show "?R \<subseteq> ?L"
   674   proof clarify
   675     fix A assume "A \<in> ?R"
   676     then show "\<exists>B. A = X -` B \<inter> \<Omega> \<and> B \<in> sigma_sets \<Omega>' M'"
   677     proof induct
   678       case (Basic B) then show ?case by auto
   679     next
   680       case Empty then show ?case
   681         by (auto intro!: sigma_sets.Empty exI[of _ "{}"])
   682     next
   683       case (Compl B)
   684       then obtain A where A: "B = X -` A \<inter> \<Omega>" "A \<in> sigma_sets \<Omega>' M'" by auto
   685       then have [simp]: "\<Omega> - B = X -` (\<Omega>' - A) \<inter> \<Omega>"
   686         by (auto simp add: funcset_mem [OF X])
   687       with A(2) show ?case
   688         by (auto intro: sigma_sets.Compl)
   689     next
   690       case (Union F)
   691       then have "\<forall>i. \<exists>B. F i = X -` B \<inter> \<Omega> \<and> B \<in> sigma_sets \<Omega>' M'" by auto
   692       from choice[OF this] guess A .. note A = this
   693       with A show ?case
   694         by (auto simp: vimage_UN[symmetric] intro: sigma_sets.Union)
   695     qed
   696   qed
   697 qed
   698 
   699 section "Disjoint families"
   700 
   701 definition
   702   disjoint_family_on  where
   703   "disjoint_family_on A S \<longleftrightarrow> (\<forall>m\<in>S. \<forall>n\<in>S. m \<noteq> n \<longrightarrow> A m \<inter> A n = {})"
   704 
   705 abbreviation
   706   "disjoint_family A \<equiv> disjoint_family_on A UNIV"
   707 
   708 lemma range_subsetD: "range f \<subseteq> B \<Longrightarrow> f i \<in> B"
   709   by blast
   710 
   711 lemma Int_Diff_disjoint: "A \<inter> B \<inter> (A - B) = {}"
   712   by blast
   713 
   714 lemma Int_Diff_Un: "A \<inter> B \<union> (A - B) = A"
   715   by blast
   716 
   717 lemma disjoint_family_subset:
   718      "disjoint_family A \<Longrightarrow> (!!x. B x \<subseteq> A x) \<Longrightarrow> disjoint_family B"
   719   by (force simp add: disjoint_family_on_def)
   720 
   721 lemma disjoint_family_on_bisimulation:
   722   assumes "disjoint_family_on f S"
   723   and "\<And>n m. n \<in> S \<Longrightarrow> m \<in> S \<Longrightarrow> n \<noteq> m \<Longrightarrow> f n \<inter> f m = {} \<Longrightarrow> g n \<inter> g m = {}"
   724   shows "disjoint_family_on g S"
   725   using assms unfolding disjoint_family_on_def by auto
   726 
   727 lemma disjoint_family_on_mono:
   728   "A \<subseteq> B \<Longrightarrow> disjoint_family_on f B \<Longrightarrow> disjoint_family_on f A"
   729   unfolding disjoint_family_on_def by auto
   730 
   731 lemma disjoint_family_Suc:
   732   assumes Suc: "!!n. A n \<subseteq> A (Suc n)"
   733   shows "disjoint_family (\<lambda>i. A (Suc i) - A i)"
   734 proof -
   735   {
   736     fix m
   737     have "!!n. A n \<subseteq> A (m+n)"
   738     proof (induct m)
   739       case 0 show ?case by simp
   740     next
   741       case (Suc m) thus ?case
   742         by (metis Suc_eq_plus1 assms nat_add_commute nat_add_left_commute subset_trans)
   743     qed
   744   }
   745   hence "!!m n. m < n \<Longrightarrow> A m \<subseteq> A n"
   746     by (metis add_commute le_add_diff_inverse nat_less_le)
   747   thus ?thesis
   748     by (auto simp add: disjoint_family_on_def)
   749       (metis insert_absorb insert_subset le_SucE le_antisym not_leE)
   750 qed
   751 
   752 lemma setsum_indicator_disjoint_family:
   753   fixes f :: "'d \<Rightarrow> 'e::semiring_1"
   754   assumes d: "disjoint_family_on A P" and "x \<in> A j" and "finite P" and "j \<in> P"
   755   shows "(\<Sum>i\<in>P. f i * indicator (A i) x) = f j"
   756 proof -
   757   have "P \<inter> {i. x \<in> A i} = {j}"
   758     using d `x \<in> A j` `j \<in> P` unfolding disjoint_family_on_def
   759     by auto
   760   thus ?thesis
   761     unfolding indicator_def
   762     by (simp add: if_distrib setsum_cases[OF `finite P`])
   763 qed
   764 
   765 definition disjointed :: "(nat \<Rightarrow> 'a set) \<Rightarrow> nat \<Rightarrow> 'a set "
   766   where "disjointed A n = A n - (\<Union>i\<in>{0..<n}. A i)"
   767 
   768 lemma finite_UN_disjointed_eq: "(\<Union>i\<in>{0..<n}. disjointed A i) = (\<Union>i\<in>{0..<n}. A i)"
   769 proof (induct n)
   770   case 0 show ?case by simp
   771 next
   772   case (Suc n)
   773   thus ?case by (simp add: atLeastLessThanSuc disjointed_def)
   774 qed
   775 
   776 lemma UN_disjointed_eq: "(\<Union>i. disjointed A i) = (\<Union>i. A i)"
   777   apply (rule UN_finite2_eq [where k=0])
   778   apply (simp add: finite_UN_disjointed_eq)
   779   done
   780 
   781 lemma less_disjoint_disjointed: "m<n \<Longrightarrow> disjointed A m \<inter> disjointed A n = {}"
   782   by (auto simp add: disjointed_def)
   783 
   784 lemma disjoint_family_disjointed: "disjoint_family (disjointed A)"
   785   by (simp add: disjoint_family_on_def)
   786      (metis neq_iff Int_commute less_disjoint_disjointed)
   787 
   788 lemma disjointed_subset: "disjointed A n \<subseteq> A n"
   789   by (auto simp add: disjointed_def)
   790 
   791 lemma (in ring_of_sets) UNION_in_sets:
   792   fixes A:: "nat \<Rightarrow> 'a set"
   793   assumes A: "range A \<subseteq> M"
   794   shows  "(\<Union>i\<in>{0..<n}. A i) \<in> M"
   795 proof (induct n)
   796   case 0 show ?case by simp
   797 next
   798   case (Suc n)
   799   thus ?case
   800     by (simp add: atLeastLessThanSuc) (metis A Un UNIV_I image_subset_iff)
   801 qed
   802 
   803 lemma (in ring_of_sets) range_disjointed_sets:
   804   assumes A: "range A \<subseteq> M"
   805   shows  "range (disjointed A) \<subseteq> M"
   806 proof (auto simp add: disjointed_def)
   807   fix n
   808   show "A n - (\<Union>i\<in>{0..<n}. A i) \<in> M" using UNION_in_sets
   809     by (metis A Diff UNIV_I image_subset_iff)
   810 qed
   811 
   812 lemma (in algebra) range_disjointed_sets':
   813   "range A \<subseteq> M \<Longrightarrow> range (disjointed A) \<subseteq> M"
   814   using range_disjointed_sets .
   815 
   816 lemma disjointed_0[simp]: "disjointed A 0 = A 0"
   817   by (simp add: disjointed_def)
   818 
   819 lemma incseq_Un:
   820   "incseq A \<Longrightarrow> (\<Union>i\<le>n. A i) = A n"
   821   unfolding incseq_def by auto
   822 
   823 lemma disjointed_incseq:
   824   "incseq A \<Longrightarrow> disjointed A (Suc n) = A (Suc n) - A n"
   825   using incseq_Un[of A]
   826   by (simp add: disjointed_def atLeastLessThanSuc_atLeastAtMost atLeast0AtMost)
   827 
   828 lemma sigma_algebra_disjoint_iff:
   829   "sigma_algebra \<Omega> M \<longleftrightarrow> algebra \<Omega> M \<and>
   830     (\<forall>A. range A \<subseteq> M \<longrightarrow> disjoint_family A \<longrightarrow> (\<Union>i::nat. A i) \<in> M)"
   831 proof (auto simp add: sigma_algebra_iff)
   832   fix A :: "nat \<Rightarrow> 'a set"
   833   assume M: "algebra \<Omega> M"
   834      and A: "range A \<subseteq> M"
   835      and UnA: "\<forall>A. range A \<subseteq> M \<longrightarrow> disjoint_family A \<longrightarrow> (\<Union>i::nat. A i) \<in> M"
   836   hence "range (disjointed A) \<subseteq> M \<longrightarrow>
   837          disjoint_family (disjointed A) \<longrightarrow>
   838          (\<Union>i. disjointed A i) \<in> M" by blast
   839   hence "(\<Union>i. disjointed A i) \<in> M"
   840     by (simp add: algebra.range_disjointed_sets'[of \<Omega>] M A disjoint_family_disjointed)
   841   thus "(\<Union>i::nat. A i) \<in> M" by (simp add: UN_disjointed_eq)
   842 qed
   843 
   844 lemma disjoint_family_on_disjoint_image:
   845   "disjoint_family_on A I \<Longrightarrow> disjoint (A ` I)"
   846   unfolding disjoint_family_on_def disjoint_def by force
   847 
   848 lemma disjoint_image_disjoint_family_on:
   849   assumes d: "disjoint (A ` I)" and i: "inj_on A I"
   850   shows "disjoint_family_on A I"
   851   unfolding disjoint_family_on_def
   852 proof (intro ballI impI)
   853   fix n m assume nm: "m \<in> I" "n \<in> I" and "n \<noteq> m"
   854   with i[THEN inj_onD, of n m] show "A n \<inter> A m = {}"
   855     by (intro disjointD[OF d]) auto
   856 qed
   857 
   858 section {* Ring generated by a semiring *}
   859 
   860 definition (in semiring_of_sets)
   861   "generated_ring = { \<Union>C | C. C \<subseteq> M \<and> finite C \<and> disjoint C }"
   862 
   863 lemma (in semiring_of_sets) generated_ringE[elim?]:
   864   assumes "a \<in> generated_ring"
   865   obtains C where "finite C" "disjoint C" "C \<subseteq> M" "a = \<Union>C"
   866   using assms unfolding generated_ring_def by auto
   867 
   868 lemma (in semiring_of_sets) generated_ringI[intro?]:
   869   assumes "finite C" "disjoint C" "C \<subseteq> M" "a = \<Union>C"
   870   shows "a \<in> generated_ring"
   871   using assms unfolding generated_ring_def by auto
   872 
   873 lemma (in semiring_of_sets) generated_ringI_Basic:
   874   "A \<in> M \<Longrightarrow> A \<in> generated_ring"
   875   by (rule generated_ringI[of "{A}"]) (auto simp: disjoint_def)
   876 
   877 lemma (in semiring_of_sets) generated_ring_disjoint_Un[intro]:
   878   assumes a: "a \<in> generated_ring" and b: "b \<in> generated_ring"
   879   and "a \<inter> b = {}"
   880   shows "a \<union> b \<in> generated_ring"
   881 proof -
   882   from a guess Ca .. note Ca = this
   883   from b guess Cb .. note Cb = this
   884   show ?thesis
   885   proof
   886     show "disjoint (Ca \<union> Cb)"
   887       using `a \<inter> b = {}` Ca Cb by (auto intro!: disjoint_union)
   888   qed (insert Ca Cb, auto)
   889 qed
   890 
   891 lemma (in semiring_of_sets) generated_ring_empty: "{} \<in> generated_ring"
   892   by (auto simp: generated_ring_def disjoint_def)
   893 
   894 lemma (in semiring_of_sets) generated_ring_disjoint_Union:
   895   assumes "finite A" shows "A \<subseteq> generated_ring \<Longrightarrow> disjoint A \<Longrightarrow> \<Union>A \<in> generated_ring"
   896   using assms by (induct A) (auto simp: disjoint_def intro!: generated_ring_disjoint_Un generated_ring_empty)
   897 
   898 lemma (in semiring_of_sets) generated_ring_disjoint_UNION:
   899   "finite I \<Longrightarrow> disjoint (A ` I) \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> A i \<in> generated_ring) \<Longrightarrow> UNION I A \<in> generated_ring"
   900   unfolding SUP_def by (intro generated_ring_disjoint_Union) auto
   901 
   902 lemma (in semiring_of_sets) generated_ring_Int:
   903   assumes a: "a \<in> generated_ring" and b: "b \<in> generated_ring"
   904   shows "a \<inter> b \<in> generated_ring"
   905 proof -
   906   from a guess Ca .. note Ca = this
   907   from b guess Cb .. note Cb = this
   908   def C \<equiv> "(\<lambda>(a,b). a \<inter> b)` (Ca\<times>Cb)"
   909   show ?thesis
   910   proof
   911     show "disjoint C"
   912     proof (simp add: disjoint_def C_def, intro ballI impI)
   913       fix a1 b1 a2 b2 assume sets: "a1 \<in> Ca" "b1 \<in> Cb" "a2 \<in> Ca" "b2 \<in> Cb"
   914       assume "a1 \<inter> b1 \<noteq> a2 \<inter> b2"
   915       then have "a1 \<noteq> a2 \<or> b1 \<noteq> b2" by auto
   916       then show "(a1 \<inter> b1) \<inter> (a2 \<inter> b2) = {}"
   917       proof
   918         assume "a1 \<noteq> a2"
   919         with sets Ca have "a1 \<inter> a2 = {}"
   920           by (auto simp: disjoint_def)
   921         then show ?thesis by auto
   922       next
   923         assume "b1 \<noteq> b2"
   924         with sets Cb have "b1 \<inter> b2 = {}"
   925           by (auto simp: disjoint_def)
   926         then show ?thesis by auto
   927       qed
   928     qed
   929   qed (insert Ca Cb, auto simp: C_def)
   930 qed
   931 
   932 lemma (in semiring_of_sets) generated_ring_Inter:
   933   assumes "finite A" "A \<noteq> {}" shows "A \<subseteq> generated_ring \<Longrightarrow> \<Inter>A \<in> generated_ring"
   934   using assms by (induct A rule: finite_ne_induct) (auto intro: generated_ring_Int)
   935 
   936 lemma (in semiring_of_sets) generated_ring_INTER:
   937   "finite I \<Longrightarrow> I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> A i \<in> generated_ring) \<Longrightarrow> INTER I A \<in> generated_ring"
   938   unfolding INF_def by (intro generated_ring_Inter) auto
   939 
   940 lemma (in semiring_of_sets) generating_ring:
   941   "ring_of_sets \<Omega> generated_ring"
   942 proof (rule ring_of_setsI)
   943   let ?R = generated_ring
   944   show "?R \<subseteq> Pow \<Omega>"
   945     using sets_into_space by (auto simp: generated_ring_def generated_ring_empty)
   946   show "{} \<in> ?R" by (rule generated_ring_empty)
   947 
   948   { fix a assume a: "a \<in> ?R" then guess Ca .. note Ca = this
   949     fix b assume b: "b \<in> ?R" then guess Cb .. note Cb = this
   950   
   951     show "a - b \<in> ?R"
   952     proof cases
   953       assume "Cb = {}" with Cb `a \<in> ?R` show ?thesis
   954         by simp
   955     next
   956       assume "Cb \<noteq> {}"
   957       with Ca Cb have "a - b = (\<Union>a'\<in>Ca. \<Inter>b'\<in>Cb. a' - b')" by auto
   958       also have "\<dots> \<in> ?R"
   959       proof (intro generated_ring_INTER generated_ring_disjoint_UNION)
   960         fix a b assume "a \<in> Ca" "b \<in> Cb"
   961         with Ca Cb Diff_cover[of a b] show "a - b \<in> ?R"
   962           by (auto simp add: generated_ring_def)
   963       next
   964         show "disjoint ((\<lambda>a'. \<Inter>b'\<in>Cb. a' - b')`Ca)"
   965           using Ca by (auto simp add: disjoint_def `Cb \<noteq> {}`)
   966       next
   967         show "finite Ca" "finite Cb" "Cb \<noteq> {}" by fact+
   968       qed
   969       finally show "a - b \<in> ?R" .
   970     qed }
   971   note Diff = this
   972 
   973   fix a b assume sets: "a \<in> ?R" "b \<in> ?R"
   974   have "a \<union> b = (a - b) \<union> (a \<inter> b) \<union> (b - a)" by auto
   975   also have "\<dots> \<in> ?R"
   976     by (intro sets generated_ring_disjoint_Un generated_ring_Int Diff) auto
   977   finally show "a \<union> b \<in> ?R" .
   978 qed
   979 
   980 lemma (in semiring_of_sets) sigma_sets_generated_ring_eq: "sigma_sets \<Omega> generated_ring = sigma_sets \<Omega> M"
   981 proof
   982   interpret M: sigma_algebra \<Omega> "sigma_sets \<Omega> M"
   983     using space_closed by (rule sigma_algebra_sigma_sets)
   984   show "sigma_sets \<Omega> generated_ring \<subseteq> sigma_sets \<Omega> M"
   985     by (blast intro!: sigma_sets_mono elim: generated_ringE)
   986 qed (auto intro!: generated_ringI_Basic sigma_sets_mono)
   987 
   988 section {* Measure type *}
   989 
   990 definition positive :: "'a set set \<Rightarrow> ('a set \<Rightarrow> ereal) \<Rightarrow> bool" where
   991   "positive M \<mu> \<longleftrightarrow> \<mu> {} = 0 \<and> (\<forall>A\<in>M. 0 \<le> \<mu> A)"
   992 
   993 definition countably_additive :: "'a set set \<Rightarrow> ('a set \<Rightarrow> ereal) \<Rightarrow> bool" where
   994   "countably_additive M f \<longleftrightarrow> (\<forall>A. range A \<subseteq> M \<longrightarrow> disjoint_family A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow>
   995     (\<Sum>i. f (A i)) = f (\<Union>i. A i))"
   996 
   997 definition measure_space :: "'a set \<Rightarrow> 'a set set \<Rightarrow> ('a set \<Rightarrow> ereal) \<Rightarrow> bool" where
   998   "measure_space \<Omega> A \<mu> \<longleftrightarrow> sigma_algebra \<Omega> A \<and> positive A \<mu> \<and> countably_additive A \<mu>"
   999 
  1000 typedef 'a measure = "{(\<Omega>::'a set, A, \<mu>). (\<forall>a\<in>-A. \<mu> a = 0) \<and> measure_space \<Omega> A \<mu> }"
  1001 proof
  1002   have "sigma_algebra UNIV {{}, UNIV}"
  1003     by (auto simp: sigma_algebra_iff2)
  1004   then show "(UNIV, {{}, UNIV}, \<lambda>A. 0) \<in> {(\<Omega>, A, \<mu>). (\<forall>a\<in>-A. \<mu> a = 0) \<and> measure_space \<Omega> A \<mu>} "
  1005     by (auto simp: measure_space_def positive_def countably_additive_def)
  1006 qed
  1007 
  1008 definition space :: "'a measure \<Rightarrow> 'a set" where
  1009   "space M = fst (Rep_measure M)"
  1010 
  1011 definition sets :: "'a measure \<Rightarrow> 'a set set" where
  1012   "sets M = fst (snd (Rep_measure M))"
  1013 
  1014 definition emeasure :: "'a measure \<Rightarrow> 'a set \<Rightarrow> ereal" where
  1015   "emeasure M = snd (snd (Rep_measure M))"
  1016 
  1017 definition measure :: "'a measure \<Rightarrow> 'a set \<Rightarrow> real" where
  1018   "measure M A = real (emeasure M A)"
  1019 
  1020 declare [[coercion sets]]
  1021 
  1022 declare [[coercion measure]]
  1023 
  1024 declare [[coercion emeasure]]
  1025 
  1026 lemma measure_space: "measure_space (space M) (sets M) (emeasure M)"
  1027   by (cases M) (auto simp: space_def sets_def emeasure_def Abs_measure_inverse)
  1028 
  1029 interpretation sigma_algebra "space M" "sets M" for M :: "'a measure"
  1030   using measure_space[of M] by (auto simp: measure_space_def)
  1031 
  1032 definition measure_of :: "'a set \<Rightarrow> 'a set set \<Rightarrow> ('a set \<Rightarrow> ereal) \<Rightarrow> 'a measure" where
  1033   "measure_of \<Omega> A \<mu> = Abs_measure (\<Omega>, sigma_sets \<Omega> A,
  1034     \<lambda>a. if a \<in> sigma_sets \<Omega> A \<and> measure_space \<Omega> (sigma_sets \<Omega> A) \<mu> then \<mu> a else 0)"
  1035 
  1036 abbreviation "sigma \<Omega> A \<equiv> measure_of \<Omega> A (\<lambda>x. 0)"
  1037 
  1038 lemma measure_space_0: "A \<subseteq> Pow \<Omega> \<Longrightarrow> measure_space \<Omega> (sigma_sets \<Omega> A) (\<lambda>x. 0)"
  1039   unfolding measure_space_def
  1040   by (auto intro!: sigma_algebra_sigma_sets simp: positive_def countably_additive_def)
  1041 
  1042 lemma (in ring_of_sets) positive_cong_eq:
  1043   "(\<And>a. a \<in> M \<Longrightarrow> \<mu>' a = \<mu> a) \<Longrightarrow> positive M \<mu>' = positive M \<mu>"
  1044   by (auto simp add: positive_def)
  1045 
  1046 lemma (in sigma_algebra) countably_additive_eq:
  1047   "(\<And>a. a \<in> M \<Longrightarrow> \<mu>' a = \<mu> a) \<Longrightarrow> countably_additive M \<mu>' = countably_additive M \<mu>"
  1048   unfolding countably_additive_def
  1049   by (intro arg_cong[where f=All] ext) (auto simp add: countably_additive_def subset_eq)
  1050 
  1051 lemma measure_space_eq:
  1052   assumes closed: "A \<subseteq> Pow \<Omega>" and eq: "\<And>a. a \<in> sigma_sets \<Omega> A \<Longrightarrow> \<mu> a = \<mu>' a"
  1053   shows "measure_space \<Omega> (sigma_sets \<Omega> A) \<mu> = measure_space \<Omega> (sigma_sets \<Omega> A) \<mu>'"
  1054 proof -
  1055   interpret sigma_algebra \<Omega> "sigma_sets \<Omega> A" using closed by (rule sigma_algebra_sigma_sets)
  1056   from positive_cong_eq[OF eq, of "\<lambda>i. i"] countably_additive_eq[OF eq, of "\<lambda>i. i"] show ?thesis
  1057     by (auto simp: measure_space_def)
  1058 qed
  1059 
  1060 lemma measure_of_eq:
  1061   assumes closed: "A \<subseteq> Pow \<Omega>" and eq: "(\<And>a. a \<in> sigma_sets \<Omega> A \<Longrightarrow> \<mu> a = \<mu>' a)"
  1062   shows "measure_of \<Omega> A \<mu> = measure_of \<Omega> A \<mu>'"
  1063 proof -
  1064   have "measure_space \<Omega> (sigma_sets \<Omega> A) \<mu> = measure_space \<Omega> (sigma_sets \<Omega> A) \<mu>'"
  1065     using assms by (rule measure_space_eq)
  1066   with eq show ?thesis
  1067     by (auto simp add: measure_of_def intro!: arg_cong[where f=Abs_measure])
  1068 qed
  1069 
  1070 lemma
  1071   assumes A: "A \<subseteq> Pow \<Omega>"
  1072   shows sets_measure_of[simp]: "sets (measure_of \<Omega> A \<mu>) = sigma_sets \<Omega> A" (is ?sets)
  1073     and space_measure_of[simp]: "space (measure_of \<Omega> A \<mu>) = \<Omega>" (is ?space)
  1074 proof -
  1075   have "?sets \<and> ?space"
  1076   proof cases
  1077     assume "measure_space \<Omega> (sigma_sets \<Omega> A) \<mu>"
  1078     moreover have "measure_space \<Omega> (sigma_sets \<Omega> A) \<mu> = measure_space \<Omega> (sigma_sets \<Omega> A)
  1079        (\<lambda>a. if a \<in> sigma_sets \<Omega> A then \<mu> a else 0)"
  1080       using A by (rule measure_space_eq) auto
  1081     ultimately show "?sets \<and> ?space"
  1082       by (auto simp: Abs_measure_inverse measure_of_def sets_def space_def)
  1083   next
  1084     assume "\<not> measure_space \<Omega> (sigma_sets \<Omega> A) \<mu>"
  1085     with A show "?sets \<and> ?space"
  1086       by (auto simp: Abs_measure_inverse measure_of_def sets_def space_def measure_space_0)
  1087   qed
  1088   then show ?sets ?space by auto
  1089 qed
  1090 
  1091 lemma (in sigma_algebra) sets_measure_of_eq[simp]:
  1092   "sets (measure_of \<Omega> M \<mu>) = M"
  1093   using space_closed by (auto intro!: sigma_sets_eq)
  1094 
  1095 lemma (in sigma_algebra) space_measure_of_eq[simp]:
  1096   "space (measure_of \<Omega> M \<mu>) = \<Omega>"
  1097   using space_closed by (auto intro!: sigma_sets_eq)
  1098 
  1099 lemma measure_of_subset:
  1100   "M \<subseteq> Pow \<Omega> \<Longrightarrow> M' \<subseteq> M \<Longrightarrow> sets (measure_of \<Omega> M' \<mu>) \<subseteq> sets (measure_of \<Omega> M \<mu>')"
  1101   by (auto intro!: sigma_sets_subseteq)
  1102 
  1103 lemma in_measure_of[intro, simp]: "M \<subseteq> Pow \<Omega> \<Longrightarrow> A \<in> M \<Longrightarrow> A \<in> sets (measure_of \<Omega> M \<mu>)"
  1104   by auto
  1105 
  1106 section {* Constructing simple @{typ "'a measure"} *}
  1107 
  1108 lemma emeasure_measure_of:
  1109   assumes M: "M = measure_of \<Omega> A \<mu>"
  1110   assumes ms: "A \<subseteq> Pow \<Omega>" "positive (sets M) \<mu>" "countably_additive (sets M) \<mu>"
  1111   assumes X: "X \<in> sets M"
  1112   shows "emeasure M X = \<mu> X"
  1113 proof -
  1114   interpret sigma_algebra \<Omega> "sigma_sets \<Omega> A" by (rule sigma_algebra_sigma_sets) fact
  1115   have "measure_space \<Omega> (sigma_sets \<Omega> A) \<mu>"
  1116     using ms M by (simp add: measure_space_def sigma_algebra_sigma_sets)
  1117   moreover have "measure_space \<Omega> (sigma_sets \<Omega> A) (\<lambda>a. if a \<in> sigma_sets \<Omega> A then \<mu> a else 0)
  1118     = measure_space \<Omega> (sigma_sets \<Omega> A) \<mu>"
  1119     using ms(1) by (rule measure_space_eq) auto
  1120   moreover have "X \<in> sigma_sets \<Omega> A"
  1121     using X M ms by simp
  1122   ultimately show ?thesis
  1123     unfolding emeasure_def measure_of_def M
  1124     by (subst Abs_measure_inverse) (simp_all add: sigma_sets_eq)
  1125 qed
  1126 
  1127 lemma emeasure_measure_of_sigma:
  1128   assumes ms: "sigma_algebra \<Omega> M" "positive M \<mu>" "countably_additive M \<mu>"
  1129   assumes A: "A \<in> M"
  1130   shows "emeasure (measure_of \<Omega> M \<mu>) A = \<mu> A"
  1131 proof -
  1132   interpret sigma_algebra \<Omega> M by fact
  1133   have "measure_space \<Omega> (sigma_sets \<Omega> M) \<mu>"
  1134     using ms sigma_sets_eq by (simp add: measure_space_def)
  1135   moreover have "measure_space \<Omega> (sigma_sets \<Omega> M) (\<lambda>a. if a \<in> sigma_sets \<Omega> M then \<mu> a else 0)
  1136     = measure_space \<Omega> (sigma_sets \<Omega> M) \<mu>"
  1137     using space_closed by (rule measure_space_eq) auto
  1138   ultimately show ?thesis using A
  1139     unfolding emeasure_def measure_of_def
  1140     by (subst Abs_measure_inverse) (simp_all add: sigma_sets_eq)
  1141 qed
  1142 
  1143 lemma measure_cases[cases type: measure]:
  1144   obtains (measure) \<Omega> A \<mu> where "x = Abs_measure (\<Omega>, A, \<mu>)" "\<forall>a\<in>-A. \<mu> a = 0" "measure_space \<Omega> A \<mu>"
  1145   by atomize_elim (cases x, auto)
  1146 
  1147 lemma sets_eq_imp_space_eq:
  1148   "sets M = sets M' \<Longrightarrow> space M = space M'"
  1149   using top[of M] top[of M'] space_closed[of M] space_closed[of M']
  1150   by blast
  1151 
  1152 lemma emeasure_notin_sets: "A \<notin> sets M \<Longrightarrow> emeasure M A = 0"
  1153   by (cases M) (auto simp: sets_def emeasure_def Abs_measure_inverse measure_space_def)
  1154 
  1155 lemma measure_notin_sets: "A \<notin> sets M \<Longrightarrow> measure M A = 0"
  1156   by (simp add: measure_def emeasure_notin_sets)
  1157 
  1158 lemma measure_eqI:
  1159   fixes M N :: "'a measure"
  1160   assumes "sets M = sets N" and eq: "\<And>A. A \<in> sets M \<Longrightarrow> emeasure M A = emeasure N A"
  1161   shows "M = N"
  1162 proof (cases M N rule: measure_cases[case_product measure_cases])
  1163   case (measure_measure \<Omega> A \<mu> \<Omega>' A' \<mu>')
  1164   interpret M: sigma_algebra \<Omega> A using measure_measure by (auto simp: measure_space_def)
  1165   interpret N: sigma_algebra \<Omega>' A' using measure_measure by (auto simp: measure_space_def)
  1166   have "A = sets M" "A' = sets N"
  1167     using measure_measure by (simp_all add: sets_def Abs_measure_inverse)
  1168   with `sets M = sets N` have "A = A'" by simp
  1169   moreover with M.top N.top M.space_closed N.space_closed have "\<Omega> = \<Omega>'" by auto
  1170   moreover { fix B have "\<mu> B = \<mu>' B"
  1171     proof cases
  1172       assume "B \<in> A"
  1173       with eq `A = sets M` have "emeasure M B = emeasure N B" by simp
  1174       with measure_measure show "\<mu> B = \<mu>' B"
  1175         by (simp add: emeasure_def Abs_measure_inverse)
  1176     next
  1177       assume "B \<notin> A"
  1178       with `A = sets M` `A' = sets N` `A = A'` have "B \<notin> sets M" "B \<notin> sets N"
  1179         by auto
  1180       then have "emeasure M B = 0" "emeasure N B = 0"
  1181         by (simp_all add: emeasure_notin_sets)
  1182       with measure_measure show "\<mu> B = \<mu>' B"
  1183         by (simp add: emeasure_def Abs_measure_inverse)
  1184     qed }
  1185   then have "\<mu> = \<mu>'" by auto
  1186   ultimately show "M = N"
  1187     by (simp add: measure_measure)
  1188 qed
  1189 
  1190 lemma emeasure_sigma: "A \<subseteq> Pow \<Omega> \<Longrightarrow> emeasure (sigma \<Omega> A) = (\<lambda>_. 0)"
  1191   using measure_space_0[of A \<Omega>]
  1192   by (simp add: measure_of_def emeasure_def Abs_measure_inverse)
  1193 
  1194 lemma sigma_eqI:
  1195   assumes [simp]: "M \<subseteq> Pow \<Omega>" "N \<subseteq> Pow \<Omega>" "sigma_sets \<Omega> M = sigma_sets \<Omega> N"
  1196   shows "sigma \<Omega> M = sigma \<Omega> N"
  1197   by (rule measure_eqI) (simp_all add: emeasure_sigma)
  1198 
  1199 section {* Measurable functions *}
  1200 
  1201 definition measurable :: "'a measure \<Rightarrow> 'b measure \<Rightarrow> ('a \<Rightarrow> 'b) set" where
  1202   "measurable A B = {f \<in> space A -> space B. \<forall>y \<in> sets B. f -` y \<inter> space A \<in> sets A}"
  1203 
  1204 lemma measurable_space:
  1205   "f \<in> measurable M A \<Longrightarrow> x \<in> space M \<Longrightarrow> f x \<in> space A"
  1206    unfolding measurable_def by auto
  1207 
  1208 lemma measurable_sets:
  1209   "f \<in> measurable M A \<Longrightarrow> S \<in> sets A \<Longrightarrow> f -` S \<inter> space M \<in> sets M"
  1210    unfolding measurable_def by auto
  1211 
  1212 lemma measurable_sets_Collect:
  1213   assumes f: "f \<in> measurable M N" and P: "{x\<in>space N. P x} \<in> sets N" shows "{x\<in>space M. P (f x)} \<in> sets M"
  1214 proof -
  1215   have "f -` {x \<in> space N. P x} \<inter> space M = {x\<in>space M. P (f x)}"
  1216     using measurable_space[OF f] by auto
  1217   with measurable_sets[OF f P] show ?thesis
  1218     by simp
  1219 qed
  1220 
  1221 lemma measurable_sigma_sets:
  1222   assumes B: "sets N = sigma_sets \<Omega> A" "A \<subseteq> Pow \<Omega>"
  1223       and f: "f \<in> space M \<rightarrow> \<Omega>"
  1224       and ba: "\<And>y. y \<in> A \<Longrightarrow> (f -` y) \<inter> space M \<in> sets M"
  1225   shows "f \<in> measurable M N"
  1226 proof -
  1227   interpret A: sigma_algebra \<Omega> "sigma_sets \<Omega> A" using B(2) by (rule sigma_algebra_sigma_sets)
  1228   from B top[of N] A.top space_closed[of N] A.space_closed have \<Omega>: "\<Omega> = space N" by force
  1229   
  1230   { fix X assume "X \<in> sigma_sets \<Omega> A"
  1231     then have "f -` X \<inter> space M \<in> sets M \<and> X \<subseteq> \<Omega>"
  1232       proof induct
  1233         case (Basic a) then show ?case
  1234           by (auto simp add: ba) (metis B(2) subsetD PowD)
  1235       next
  1236         case (Compl a)
  1237         have [simp]: "f -` \<Omega> \<inter> space M = space M"
  1238           by (auto simp add: funcset_mem [OF f])
  1239         then show ?case
  1240           by (auto simp add: vimage_Diff Diff_Int_distrib2 compl_sets Compl)
  1241       next
  1242         case (Union a)
  1243         then show ?case
  1244           by (simp add: vimage_UN, simp only: UN_extend_simps(4)) blast
  1245       qed auto }
  1246   with f show ?thesis
  1247     by (auto simp add: measurable_def B \<Omega>)
  1248 qed
  1249 
  1250 lemma measurable_measure_of:
  1251   assumes B: "N \<subseteq> Pow \<Omega>"
  1252       and f: "f \<in> space M \<rightarrow> \<Omega>"
  1253       and ba: "\<And>y. y \<in> N \<Longrightarrow> (f -` y) \<inter> space M \<in> sets M"
  1254   shows "f \<in> measurable M (measure_of \<Omega> N \<mu>)"
  1255 proof -
  1256   have "sets (measure_of \<Omega> N \<mu>) = sigma_sets \<Omega> N"
  1257     using B by (rule sets_measure_of)
  1258   from this assms show ?thesis by (rule measurable_sigma_sets)
  1259 qed
  1260 
  1261 lemma measurable_iff_measure_of:
  1262   assumes "N \<subseteq> Pow \<Omega>" "f \<in> space M \<rightarrow> \<Omega>"
  1263   shows "f \<in> measurable M (measure_of \<Omega> N \<mu>) \<longleftrightarrow> (\<forall>A\<in>N. f -` A \<inter> space M \<in> sets M)"
  1264   by (metis assms in_measure_of measurable_measure_of assms measurable_sets)
  1265 
  1266 lemma measurable_cong:
  1267   assumes "\<And> w. w \<in> space M \<Longrightarrow> f w = g w"
  1268   shows "f \<in> measurable M M' \<longleftrightarrow> g \<in> measurable M M'"
  1269   unfolding measurable_def using assms
  1270   by (simp cong: vimage_inter_cong Pi_cong)
  1271 
  1272 lemma measurable_eqI:
  1273      "\<lbrakk> space m1 = space m1' ; space m2 = space m2' ;
  1274         sets m1 = sets m1' ; sets m2 = sets m2' \<rbrakk>
  1275       \<Longrightarrow> measurable m1 m2 = measurable m1' m2'"
  1276   by (simp add: measurable_def sigma_algebra_iff2)
  1277 
  1278 lemma measurable_const[intro, simp]:
  1279   "c \<in> space M' \<Longrightarrow> (\<lambda>x. c) \<in> measurable M M'"
  1280   by (auto simp add: measurable_def)
  1281 
  1282 lemma measurable_If:
  1283   assumes measure: "f \<in> measurable M M'" "g \<in> measurable M M'"
  1284   assumes P: "{x\<in>space M. P x} \<in> sets M"
  1285   shows "(\<lambda>x. if P x then f x else g x) \<in> measurable M M'"
  1286   unfolding measurable_def
  1287 proof safe
  1288   fix x assume "x \<in> space M"
  1289   thus "(if P x then f x else g x) \<in> space M'"
  1290     using measure unfolding measurable_def by auto
  1291 next
  1292   fix A assume "A \<in> sets M'"
  1293   hence *: "(\<lambda>x. if P x then f x else g x) -` A \<inter> space M =
  1294     ((f -` A \<inter> space M) \<inter> {x\<in>space M. P x}) \<union>
  1295     ((g -` A \<inter> space M) \<inter> (space M - {x\<in>space M. P x}))"
  1296     using measure unfolding measurable_def by (auto split: split_if_asm)
  1297   show "(\<lambda>x. if P x then f x else g x) -` A \<inter> space M \<in> sets M"
  1298     using `A \<in> sets M'` measure P unfolding * measurable_def
  1299     by (auto intro!: Un)
  1300 qed
  1301 
  1302 lemma measurable_If_set:
  1303   assumes measure: "f \<in> measurable M M'" "g \<in> measurable M M'"
  1304   assumes P: "A \<inter> space M \<in> sets M"
  1305   shows "(\<lambda>x. if x \<in> A then f x else g x) \<in> measurable M M'"
  1306 proof (rule measurable_If[OF measure])
  1307   have "{x \<in> space M. x \<in> A} = A \<inter> space M" by auto
  1308   thus "{x \<in> space M. x \<in> A} \<in> sets M" using `A \<inter> space M \<in> sets M` by auto
  1309 qed
  1310 
  1311 lemma measurable_ident[intro, simp]: "id \<in> measurable M M"
  1312   by (auto simp add: measurable_def)
  1313 
  1314 lemma measurable_ident'[intro, simp]: "(\<lambda>x. x) \<in> measurable M M"
  1315   by (auto simp add: measurable_def)
  1316 
  1317 lemma measurable_comp[intro]:
  1318   fixes f :: "'a \<Rightarrow> 'b" and g :: "'b \<Rightarrow> 'c"
  1319   shows "f \<in> measurable a b \<Longrightarrow> g \<in> measurable b c \<Longrightarrow> (g o f) \<in> measurable a c"
  1320   apply (auto simp add: measurable_def vimage_compose)
  1321   apply (subgoal_tac "f -` g -` y \<inter> space a = f -` (g -` y \<inter> space b) \<inter> space a")
  1322   apply force+
  1323   done
  1324 
  1325 lemma measurable_compose:
  1326   "f \<in> measurable M N \<Longrightarrow> g \<in> measurable N L \<Longrightarrow> (\<lambda>x. g (f x)) \<in> measurable M L"
  1327   using measurable_comp[of f M N g L] by (simp add: comp_def)
  1328 
  1329 lemma sets_Least:
  1330   assumes meas: "\<And>i::nat. {x\<in>space M. P i x} \<in> M"
  1331   shows "(\<lambda>x. LEAST j. P j x) -` A \<inter> space M \<in> sets M"
  1332 proof -
  1333   { fix i have "(\<lambda>x. LEAST j. P j x) -` {i} \<inter> space M \<in> sets M"
  1334     proof cases
  1335       assume i: "(LEAST j. False) = i"
  1336       have "(\<lambda>x. LEAST j. P j x) -` {i} \<inter> space M =
  1337         {x\<in>space M. P i x} \<inter> (space M - (\<Union>j<i. {x\<in>space M. P j x})) \<union> (space M - (\<Union>i. {x\<in>space M. P i x}))"
  1338         by (simp add: set_eq_iff, safe)
  1339            (insert i, auto dest: Least_le intro: LeastI intro!: Least_equality)
  1340       with meas show ?thesis
  1341         by (auto intro!: Int)
  1342     next
  1343       assume i: "(LEAST j. False) \<noteq> i"
  1344       then have "(\<lambda>x. LEAST j. P j x) -` {i} \<inter> space M =
  1345         {x\<in>space M. P i x} \<inter> (space M - (\<Union>j<i. {x\<in>space M. P j x}))"
  1346       proof (simp add: set_eq_iff, safe)
  1347         fix x assume neq: "(LEAST j. False) \<noteq> (LEAST j. P j x)"
  1348         have "\<exists>j. P j x"
  1349           by (rule ccontr) (insert neq, auto)
  1350         then show "P (LEAST j. P j x) x" by (rule LeastI_ex)
  1351       qed (auto dest: Least_le intro!: Least_equality)
  1352       with meas show ?thesis
  1353         by auto
  1354     qed }
  1355   then have "(\<Union>i\<in>A. (\<lambda>x. LEAST j. P j x) -` {i} \<inter> space M) \<in> sets M"
  1356     by (intro countable_UN) auto
  1357   moreover have "(\<Union>i\<in>A. (\<lambda>x. LEAST j. P j x) -` {i} \<inter> space M) =
  1358     (\<lambda>x. LEAST j. P j x) -` A \<inter> space M" by auto
  1359   ultimately show ?thesis by auto
  1360 qed
  1361 
  1362 lemma measurable_strong:
  1363   fixes f :: "'a \<Rightarrow> 'b" and g :: "'b \<Rightarrow> 'c"
  1364   assumes f: "f \<in> measurable a b" and g: "g \<in> space b \<rightarrow> space c"
  1365       and t: "f ` (space a) \<subseteq> t"
  1366       and cb: "\<And>s. s \<in> sets c \<Longrightarrow> (g -` s) \<inter> t \<in> sets b"
  1367   shows "(g o f) \<in> measurable a c"
  1368 proof -
  1369   have fab: "f \<in> (space a -> space b)"
  1370    and ba: "\<And>y. y \<in> sets b \<Longrightarrow> (f -` y) \<inter> (space a) \<in> sets a" using f
  1371      by (auto simp add: measurable_def)
  1372   have eq: "\<And>y. f -` g -` y \<inter> space a = f -` (g -` y \<inter> t) \<inter> space a" using t
  1373     by force
  1374   show ?thesis
  1375     apply (auto simp add: measurable_def vimage_compose)
  1376     apply (metis funcset_mem fab g)
  1377     apply (subst eq, metis ba cb)
  1378     done
  1379 qed
  1380 
  1381 lemma measurable_mono1:
  1382   "M' \<subseteq> Pow \<Omega> \<Longrightarrow> M \<subseteq> M' \<Longrightarrow>
  1383     measurable (measure_of \<Omega> M \<mu>) N \<subseteq> measurable (measure_of \<Omega> M' \<mu>') N"
  1384   using measure_of_subset[of M' \<Omega> M] by (auto simp add: measurable_def)
  1385 
  1386 section {* Counting space *}
  1387 
  1388 definition count_space :: "'a set \<Rightarrow> 'a measure" where
  1389   "count_space \<Omega> = measure_of \<Omega> (Pow \<Omega>) (\<lambda>A. if finite A then ereal (card A) else \<infinity>)"
  1390 
  1391 lemma 
  1392   shows space_count_space[simp]: "space (count_space \<Omega>) = \<Omega>"
  1393     and sets_count_space[simp]: "sets (count_space \<Omega>) = Pow \<Omega>"
  1394   using sigma_sets_into_sp[of "Pow \<Omega>" \<Omega>]
  1395   by (auto simp: count_space_def)
  1396 
  1397 lemma measurable_count_space_eq1[simp]:
  1398   "f \<in> measurable (count_space A) M \<longleftrightarrow> f \<in> A \<rightarrow> space M"
  1399  unfolding measurable_def by simp
  1400 
  1401 lemma measurable_count_space_eq2:
  1402   assumes "finite A"
  1403   shows "f \<in> measurable M (count_space A) \<longleftrightarrow> (f \<in> space M \<rightarrow> A \<and> (\<forall>a\<in>A. f -` {a} \<inter> space M \<in> sets M))"
  1404 proof -
  1405   { fix X assume "X \<subseteq> A" "f \<in> space M \<rightarrow> A"
  1406     with `finite A` have "f -` X \<inter> space M = (\<Union>a\<in>X. f -` {a} \<inter> space M)" "finite X"
  1407       by (auto dest: finite_subset)
  1408     moreover assume "\<forall>a\<in>A. f -` {a} \<inter> space M \<in> sets M"
  1409     ultimately have "f -` X \<inter> space M \<in> sets M"
  1410       using `X \<subseteq> A` by (auto intro!: finite_UN simp del: UN_simps) }
  1411   then show ?thesis
  1412     unfolding measurable_def by auto
  1413 qed
  1414 
  1415 lemma measurable_compose_countable:
  1416   assumes f: "\<And>i::'i::countable. (\<lambda>x. f i x) \<in> measurable M N" and g: "g \<in> measurable M (count_space UNIV)"
  1417   shows "(\<lambda>x. f (g x) x) \<in> measurable M N"
  1418   unfolding measurable_def
  1419 proof safe
  1420   fix x assume "x \<in> space M" then show "f (g x) x \<in> space N"
  1421     using f[THEN measurable_space] g[THEN measurable_space] by auto
  1422 next
  1423   fix A assume A: "A \<in> sets N"
  1424   have "(\<lambda>x. f (g x) x) -` A \<inter> space M = (\<Union>i. (g -` {i} \<inter> space M) \<inter> (f i -` A \<inter> space M))"
  1425     by auto
  1426   also have "\<dots> \<in> sets M" using f[THEN measurable_sets, OF A] g[THEN measurable_sets]
  1427     by (auto intro!: countable_UN measurable_sets)
  1428   finally show "(\<lambda>x. f (g x) x) -` A \<inter> space M \<in> sets M" .
  1429 qed
  1430 
  1431 subsection {* Measurable method *}
  1432 
  1433 lemma (in algebra) sets_Collect_finite_All:
  1434   assumes "\<And>i. i \<in> S \<Longrightarrow> {x\<in>\<Omega>. P i x} \<in> M" "finite S"
  1435   shows "{x\<in>\<Omega>. \<forall>i\<in>S. P i x} \<in> M"
  1436 proof -
  1437   have "{x\<in>\<Omega>. \<forall>i\<in>S. P i x} = (if S = {} then \<Omega> else \<Inter>i\<in>S. {x\<in>\<Omega>. P i x})"
  1438     by auto
  1439   with assms show ?thesis by (auto intro!: sets_Collect_finite_All')
  1440 qed
  1441 
  1442 abbreviation "pred M P \<equiv> P \<in> measurable M (count_space (UNIV::bool set))"
  1443 
  1444 lemma pred_def: "pred M P \<longleftrightarrow> {x\<in>space M. P x} \<in> sets M"
  1445 proof
  1446   assume "pred M P"
  1447   then have "P -` {True} \<inter> space M \<in> sets M"
  1448     by (auto simp: measurable_count_space_eq2)
  1449   also have "P -` {True} \<inter> space M = {x\<in>space M. P x}" by auto
  1450   finally show "{x\<in>space M. P x} \<in> sets M" .
  1451 next
  1452   assume P: "{x\<in>space M. P x} \<in> sets M"
  1453   moreover
  1454   { fix X
  1455     have "X \<in> Pow (UNIV :: bool set)" by simp
  1456     then have "P -` X \<inter> space M = {x\<in>space M. ((X = {True} \<longrightarrow> P x) \<and> (X = {False} \<longrightarrow> \<not> P x) \<and> X \<noteq> {})}"
  1457       unfolding UNIV_bool Pow_insert Pow_empty by auto
  1458     then have "P -` X \<inter> space M \<in> sets M"
  1459       by (auto intro!: sets_Collect_neg sets_Collect_imp sets_Collect_conj sets_Collect_const P) }
  1460   then show "pred M P"
  1461     by (auto simp: measurable_def)
  1462 qed
  1463 
  1464 lemma pred_sets1: "{x\<in>space M. P x} \<in> sets M \<Longrightarrow> f \<in> measurable N M \<Longrightarrow> pred N (\<lambda>x. P (f x))"
  1465   by (rule measurable_compose[where f=f and N=M]) (auto simp: pred_def)
  1466 
  1467 lemma pred_sets2: "A \<in> sets N \<Longrightarrow> f \<in> measurable M N \<Longrightarrow> pred M (\<lambda>x. f x \<in> A)"
  1468   by (rule measurable_compose[where f=f and N=N]) (auto simp: pred_def Int_def[symmetric])
  1469 
  1470 lemma measurable_count_space_const:
  1471   "(\<lambda>x. c) \<in> measurable M (count_space UNIV)"
  1472   by auto
  1473 
  1474 lemma measurable_count_space:
  1475   "f \<in> measurable (count_space A) (count_space UNIV)"
  1476   by simp
  1477 
  1478 lemma measurable_compose_rev:
  1479   assumes f: "f \<in> measurable L N" and g: "g \<in> measurable M L"
  1480   shows "(\<lambda>x. f (g x)) \<in> measurable M N"
  1481   using measurable_compose[OF g f] .
  1482 
  1483 ML {*
  1484 
  1485 structure Measurable =
  1486 struct
  1487 
  1488 datatype level = Concrete | Generic;
  1489 
  1490 structure Data = Generic_Data
  1491 (
  1492   type T = thm list * thm list;
  1493   val empty = ([], []);
  1494   val extend = I;
  1495   val merge = fn ((a, b), (c, d)) => (a @ c, b @ d);
  1496 );
  1497 
  1498 val debug =
  1499   Attrib.setup_config_bool @{binding measurable_debug} (K false)
  1500 
  1501 val backtrack =
  1502   Attrib.setup_config_int @{binding measurable_backtrack} (K 40)
  1503 
  1504 fun get lv = (case lv of Concrete => fst | Generic => snd) o Data.get o Context.Proof; 
  1505 fun get_all ctxt = get Concrete ctxt @ get Generic ctxt;
  1506 
  1507 fun update f lv = Data.map (case lv of Concrete => apfst f | Generic => apsnd f);
  1508 fun add thms' = update (fn thms => thms @ thms');
  1509 
  1510 fun TRYALL' tacs = fold_rev (curry op APPEND') tacs (K no_tac);
  1511 
  1512 fun is_too_generic thm =
  1513   let 
  1514     val concl = concl_of thm
  1515     val concl' = HOLogic.dest_Trueprop concl handle TERM _ => concl
  1516   in is_Var (head_of concl') end
  1517 
  1518 fun import_theorem thm = if is_too_generic thm then [] else
  1519   [thm] @ map_filter (try (fn th' => thm RS th'))
  1520     [@{thm measurable_compose_rev}, @{thm pred_sets1}, @{thm pred_sets2}, @{thm sets_into_space}];
  1521 
  1522 fun add_thm (raw, lv) thm = add (if raw then [thm] else import_theorem thm) lv;
  1523 
  1524 fun debug_tac ctxt msg f = if Config.get ctxt debug then K (print_tac (msg ())) THEN' f else f
  1525 
  1526 fun TAKE n f thm = Seq.take n (f thm)
  1527 
  1528 fun nth_hol_goal thm i =
  1529   HOLogic.dest_Trueprop (Logic.strip_imp_concl (strip_all_body (nth (prems_of thm) (i - 1))))
  1530 
  1531 fun dest_measurable_fun t =
  1532   (case t of
  1533     (Const (@{const_name "Set.member"}, _) $ f $ (Const (@{const_name "measurable"}, _) $ _ $ _)) => f
  1534   | _ => raise (TERM ("not a measurability predicate", [t])))
  1535 
  1536 fun indep (Bound i) t b = i < b orelse t <= i
  1537   | indep (f $ t) top bot = indep f top bot andalso indep t top bot
  1538   | indep (Abs (_,_,t)) top bot = indep t (top + 1) (bot + 1)
  1539   | indep _ _ _ = true;
  1540 
  1541 fun cnt_prefixes ctxt (Abs (n, T, t)) = let
  1542       fun is_countable t = Type.of_sort (Proof_Context.tsig_of ctxt) (t, @{sort countable})
  1543       fun cnt_walk (Abs (ns, T, t)) Ts =
  1544           map (fn (t', t'') => (Abs (ns, T, t'), t'')) (cnt_walk t (T::Ts))
  1545         | cnt_walk (f $ g) Ts = let
  1546             val n = length Ts - 1
  1547           in
  1548             map (fn (f', t) => (f' $ g, t)) (cnt_walk f Ts) @
  1549             map (fn (g', t) => (f $ g', t)) (cnt_walk g Ts) @
  1550             (if is_countable (fastype_of1 (Ts, g)) andalso loose_bvar1 (g, n)
  1551                 andalso indep g n 0 andalso g <> Bound n
  1552               then [(f $ Bound (n + 1), incr_boundvars (~ n) g)]
  1553               else [])
  1554           end
  1555         | cnt_walk _ _ = []
  1556     in map (fn (t1, t2) => let
  1557         val T1 = fastype_of1 ([T], t2)
  1558         val T2 = fastype_of1 ([T], t)
  1559       in ([SOME (Abs (n, T1, Abs (n, T, t1))), NONE, NONE, SOME (Abs (n, T, t2))],
  1560         [SOME T1, SOME T, SOME T2])
  1561       end) (cnt_walk t [T])
  1562     end
  1563   | cnt_prefixes _ _ = []
  1564 
  1565 val split_fun_tac =
  1566   Subgoal.FOCUS (fn {context = ctxt, ...} => SUBGOAL (fn (t, i) =>
  1567     let
  1568       val f = dest_measurable_fun (HOLogic.dest_Trueprop t)
  1569       fun cert f = map (Option.map (f (Proof_Context.theory_of ctxt)))
  1570       fun inst t (ts, Ts) = Drule.instantiate' (cert ctyp_of Ts) (cert cterm_of ts) t
  1571       val cps = cnt_prefixes ctxt f |> map (inst @{thm measurable_compose_countable})
  1572     in if null cps then no_tac else debug_tac ctxt (K "split fun") (resolve_tac cps) i end
  1573     handle TERM _ => no_tac) 1)
  1574 
  1575 fun single_measurable_tac ctxt facts =
  1576   debug_tac ctxt (fn () => "single + " ^ Pretty.str_of (Pretty.block (map (Syntax.pretty_term ctxt o prop_of) facts)))
  1577   (resolve_tac ((maps (import_theorem o Simplifier.norm_hhf) facts) @ get_all ctxt)
  1578     APPEND' (split_fun_tac ctxt));
  1579 
  1580 fun is_cond_formlua n thm = if length (prems_of thm) < n then false else
  1581   (case nth_hol_goal thm n of
  1582     (Const (@{const_name "Set.member"}, _) $ _ $ (Const (@{const_name "sets"}, _) $ _)) => false
  1583   | (Const (@{const_name "Set.member"}, _) $ _ $ (Const (@{const_name "measurable"}, _) $ _ $ _)) => false
  1584   | _ => true)
  1585   handle TERM _ => true;
  1586 
  1587 fun measurable_tac' ctxt ss facts n =
  1588   TAKE (Config.get ctxt backtrack)
  1589   ((single_measurable_tac ctxt facts THEN'
  1590    REPEAT o (single_measurable_tac ctxt facts APPEND'
  1591              SOLVED' (fn n => COND (is_cond_formlua n) (debug_tac ctxt (K "simp") (asm_full_simp_tac ss) n) no_tac))) n);
  1592 
  1593 fun measurable_tac ctxt = measurable_tac' ctxt (simpset_of ctxt);
  1594 
  1595 val attr_add = Thm.declaration_attribute o add_thm;
  1596 
  1597 val attr : attribute context_parser =
  1598   Scan.lift (Scan.optional (Args.parens (Scan.optional (Args.$$$ "raw" >> K true) false --
  1599      Scan.optional (Args.$$$ "generic" >> K Generic) Concrete)) (false, Concrete) >> attr_add);
  1600 
  1601 val method : (Proof.context -> Method.method) context_parser =
  1602   Scan.lift (Scan.succeed (fn ctxt => METHOD (fn facts => measurable_tac ctxt facts 1)));
  1603 
  1604 fun simproc ss redex = let
  1605     val ctxt = Simplifier.the_context ss;
  1606     val t = HOLogic.mk_Trueprop (term_of redex);
  1607     fun tac {context = ctxt, ...} =
  1608       SOLVE (measurable_tac' ctxt ss (Simplifier.prems_of ss) 1);
  1609   in try (fn () => Goal.prove ctxt [] [] t tac RS @{thm Eq_TrueI}) () end;
  1610 
  1611 end
  1612 
  1613 *}
  1614 
  1615 attribute_setup measurable = {* Measurable.attr *} "declaration of measurability theorems"
  1616 method_setup measurable = {* Measurable.method *} "measurability prover"
  1617 simproc_setup measurable ("A \<in> sets M" | "f \<in> measurable M N") = {* K Measurable.simproc *}
  1618 
  1619 declare
  1620   top[measurable]
  1621   empty_sets[measurable (raw)]
  1622   Un[measurable (raw)]
  1623   Diff[measurable (raw)]
  1624 
  1625 declare
  1626   measurable_count_space[measurable (raw)]
  1627   measurable_ident[measurable (raw)]
  1628   measurable_ident'[measurable (raw)]
  1629   measurable_count_space_const[measurable (raw)]
  1630   measurable_const[measurable (raw)]
  1631   measurable_If[measurable (raw)]
  1632   measurable_comp[measurable (raw)]
  1633   measurable_sets[measurable (raw)]
  1634 
  1635 lemma predE[measurable (raw)]: 
  1636   "pred M P \<Longrightarrow> {x\<in>space M. P x} \<in> sets M"
  1637   unfolding pred_def .
  1638 
  1639 lemma pred_intros_imp'[measurable (raw)]:
  1640   "(K \<Longrightarrow> pred M (\<lambda>x. P x)) \<Longrightarrow> pred M (\<lambda>x. K \<longrightarrow> P x)"
  1641   by (cases K) auto
  1642 
  1643 lemma pred_intros_conj1'[measurable (raw)]:
  1644   "(K \<Longrightarrow> pred M (\<lambda>x. P x)) \<Longrightarrow> pred M (\<lambda>x. K \<and> P x)"
  1645   by (cases K) auto
  1646 
  1647 lemma pred_intros_conj2'[measurable (raw)]:
  1648   "(K \<Longrightarrow> pred M (\<lambda>x. P x)) \<Longrightarrow> pred M (\<lambda>x. P x \<and> K)"
  1649   by (cases K) auto
  1650 
  1651 lemma pred_intros_disj1'[measurable (raw)]:
  1652   "(\<not> K \<Longrightarrow> pred M (\<lambda>x. P x)) \<Longrightarrow> pred M (\<lambda>x. K \<or> P x)"
  1653   by (cases K) auto
  1654 
  1655 lemma pred_intros_disj2'[measurable (raw)]:
  1656   "(\<not> K \<Longrightarrow> pred M (\<lambda>x. P x)) \<Longrightarrow> pred M (\<lambda>x. P x \<or> K)"
  1657   by (cases K) auto
  1658 
  1659 lemma pred_intros_logic[measurable (raw)]:
  1660   "pred M (\<lambda>x. x \<in> space M)"
  1661   "pred M (\<lambda>x. P x) \<Longrightarrow> pred M (\<lambda>x. \<not> P x)"
  1662   "pred M (\<lambda>x. Q x) \<Longrightarrow> pred M (\<lambda>x. P x) \<Longrightarrow> pred M (\<lambda>x. Q x \<and> P x)"
  1663   "pred M (\<lambda>x. Q x) \<Longrightarrow> pred M (\<lambda>x. P x) \<Longrightarrow> pred M (\<lambda>x. Q x \<longrightarrow> P x)"
  1664   "pred M (\<lambda>x. Q x) \<Longrightarrow> pred M (\<lambda>x. P x) \<Longrightarrow> pred M (\<lambda>x. Q x \<or> P x)"
  1665   "pred M (\<lambda>x. Q x) \<Longrightarrow> pred M (\<lambda>x. P x) \<Longrightarrow> pred M (\<lambda>x. Q x = P x)"
  1666   "pred M (\<lambda>x. f x \<in> UNIV)"
  1667   "pred M (\<lambda>x. f x \<in> {})"
  1668   "pred M (\<lambda>x. f x \<in> (B x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> - (B x))"
  1669   "pred M (\<lambda>x. f x \<in> (A x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> (B x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> (A x) - (B x))"
  1670   "pred M (\<lambda>x. f x \<in> (A x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> (B x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> (A x) \<inter> (B x))"
  1671   "pred M (\<lambda>x. f x \<in> (A x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> (B x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> (A x) \<union> (B x))"
  1672   "pred M (\<lambda>x. g x (f x) \<in> (X x)) \<Longrightarrow> pred M (\<lambda>x. f x \<in> (g x) -` (X x))"
  1673   by (auto intro!: sets_Collect simp: iff_conv_conj_imp pred_def)
  1674 
  1675 lemma pred_intros_countable[measurable (raw)]:
  1676   fixes P :: "'a \<Rightarrow> 'i :: countable \<Rightarrow> bool"
  1677   shows 
  1678     "(\<And>i. pred M (\<lambda>x. P x i)) \<Longrightarrow> pred M (\<lambda>x. \<forall>i. P x i)"
  1679     "(\<And>i. pred M (\<lambda>x. P x i)) \<Longrightarrow> pred M (\<lambda>x. \<exists>i. P x i)"
  1680   by (auto intro!: sets_Collect_countable_All sets_Collect_countable_Ex simp: pred_def)
  1681 
  1682 lemma pred_intros_countable_bounded[measurable (raw)]:
  1683   fixes X :: "'i :: countable set"
  1684   shows 
  1685     "(\<And>i. i \<in> X \<Longrightarrow> pred M (\<lambda>x. x \<in> N x i)) \<Longrightarrow> pred M (\<lambda>x. x \<in> (\<Inter>i\<in>X. N x i))"
  1686     "(\<And>i. i \<in> X \<Longrightarrow> pred M (\<lambda>x. x \<in> N x i)) \<Longrightarrow> pred M (\<lambda>x. x \<in> (\<Union>i\<in>X. N x i))"
  1687     "(\<And>i. i \<in> X \<Longrightarrow> pred M (\<lambda>x. P x i)) \<Longrightarrow> pred M (\<lambda>x. \<forall>i\<in>X. P x i)"
  1688     "(\<And>i. i \<in> X \<Longrightarrow> pred M (\<lambda>x. P x i)) \<Longrightarrow> pred M (\<lambda>x. \<exists>i\<in>X. P x i)"
  1689   by (auto simp: Bex_def Ball_def)
  1690 
  1691 lemma pred_intros_finite[measurable (raw)]:
  1692   "finite I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> pred M (\<lambda>x. x \<in> N x i)) \<Longrightarrow> pred M (\<lambda>x. x \<in> (\<Inter>i\<in>I. N x i))"
  1693   "finite I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> pred M (\<lambda>x. x \<in> N x i)) \<Longrightarrow> pred M (\<lambda>x. x \<in> (\<Union>i\<in>I. N x i))"
  1694   "finite I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> pred M (\<lambda>x. P x i)) \<Longrightarrow> pred M (\<lambda>x. \<forall>i\<in>I. P x i)"
  1695   "finite I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> pred M (\<lambda>x. P x i)) \<Longrightarrow> pred M (\<lambda>x. \<exists>i\<in>I. P x i)"
  1696   by (auto intro!: sets_Collect_finite_Ex sets_Collect_finite_All simp: iff_conv_conj_imp pred_def)
  1697 
  1698 lemma countable_Un_Int[measurable (raw)]:
  1699   "(\<And>i :: 'i :: countable. i \<in> I \<Longrightarrow> N i \<in> sets M) \<Longrightarrow> (\<Union>i\<in>I. N i) \<in> sets M"
  1700   "I \<noteq> {} \<Longrightarrow> (\<And>i :: 'i :: countable. i \<in> I \<Longrightarrow> N i \<in> sets M) \<Longrightarrow> (\<Inter>i\<in>I. N i) \<in> sets M"
  1701   by auto
  1702 
  1703 declare
  1704   finite_UN[measurable (raw)]
  1705   finite_INT[measurable (raw)]
  1706 
  1707 lemma sets_Int_pred[measurable (raw)]:
  1708   assumes space: "A \<inter> B \<subseteq> space M" and [measurable]: "pred M (\<lambda>x. x \<in> A)" "pred M (\<lambda>x. x \<in> B)"
  1709   shows "A \<inter> B \<in> sets M"
  1710 proof -
  1711   have "{x\<in>space M. x \<in> A \<inter> B} \<in> sets M" by auto
  1712   also have "{x\<in>space M. x \<in> A \<inter> B} = A \<inter> B"
  1713     using space by auto
  1714   finally show ?thesis .
  1715 qed
  1716 
  1717 lemma [measurable (raw generic)]:
  1718   assumes f: "f \<in> measurable M N" and c: "{c} \<in> sets N"
  1719   shows pred_eq_const1: "pred M (\<lambda>x. f x = c)"
  1720     and pred_eq_const2: "pred M (\<lambda>x. c = f x)"
  1721   using measurable_sets[OF f c] by (auto simp: Int_def conj_commute eq_commute pred_def)
  1722 
  1723 lemma pred_le_const[measurable (raw generic)]:
  1724   assumes f: "f \<in> measurable M N" and c: "{.. c} \<in> sets N" shows "pred M (\<lambda>x. f x \<le> c)"
  1725   using measurable_sets[OF f c]
  1726   by (auto simp: Int_def conj_commute eq_commute pred_def)
  1727 
  1728 lemma pred_const_le[measurable (raw generic)]:
  1729   assumes f: "f \<in> measurable M N" and c: "{c ..} \<in> sets N" shows "pred M (\<lambda>x. c \<le> f x)"
  1730   using measurable_sets[OF f c]
  1731   by (auto simp: Int_def conj_commute eq_commute pred_def)
  1732 
  1733 lemma pred_less_const[measurable (raw generic)]:
  1734   assumes f: "f \<in> measurable M N" and c: "{..< c} \<in> sets N" shows "pred M (\<lambda>x. f x < c)"
  1735   using measurable_sets[OF f c]
  1736   by (auto simp: Int_def conj_commute eq_commute pred_def)
  1737 
  1738 lemma pred_const_less[measurable (raw generic)]:
  1739   assumes f: "f \<in> measurable M N" and c: "{c <..} \<in> sets N" shows "pred M (\<lambda>x. c < f x)"
  1740   using measurable_sets[OF f c]
  1741   by (auto simp: Int_def conj_commute eq_commute pred_def)
  1742 
  1743 declare
  1744   Int[measurable (raw)]
  1745 
  1746 hide_const (open) pred
  1747 
  1748 subsection {* Extend measure *}
  1749 
  1750 definition "extend_measure \<Omega> I G \<mu> =
  1751   (if (\<exists>\<mu>'. (\<forall>i\<in>I. \<mu>' (G i) = \<mu> i) \<and> measure_space \<Omega> (sigma_sets \<Omega> (G`I)) \<mu>') \<and> \<not> (\<forall>i\<in>I. \<mu> i = 0)
  1752       then measure_of \<Omega> (G`I) (SOME \<mu>'. (\<forall>i\<in>I. \<mu>' (G i) = \<mu> i) \<and> measure_space \<Omega> (sigma_sets \<Omega> (G`I)) \<mu>')
  1753       else measure_of \<Omega> (G`I) (\<lambda>_. 0))"
  1754 
  1755 lemma space_extend_measure: "G ` I \<subseteq> Pow \<Omega> \<Longrightarrow> space (extend_measure \<Omega> I G \<mu>) = \<Omega>"
  1756   unfolding extend_measure_def by simp
  1757 
  1758 lemma sets_extend_measure: "G ` I \<subseteq> Pow \<Omega> \<Longrightarrow> sets (extend_measure \<Omega> I G \<mu>) = sigma_sets \<Omega> (G`I)"
  1759   unfolding extend_measure_def by simp
  1760 
  1761 lemma emeasure_extend_measure:
  1762   assumes M: "M = extend_measure \<Omega> I G \<mu>"
  1763     and eq: "\<And>i. i \<in> I \<Longrightarrow> \<mu>' (G i) = \<mu> i"
  1764     and ms: "G ` I \<subseteq> Pow \<Omega>" "positive (sets M) \<mu>'" "countably_additive (sets M) \<mu>'"
  1765     and "i \<in> I"
  1766   shows "emeasure M (G i) = \<mu> i"
  1767 proof cases
  1768   assume *: "(\<forall>i\<in>I. \<mu> i = 0)"
  1769   with M have M_eq: "M = measure_of \<Omega> (G`I) (\<lambda>_. 0)"
  1770    by (simp add: extend_measure_def)
  1771   from measure_space_0[OF ms(1)] ms `i\<in>I`
  1772   have "emeasure M (G i) = 0"
  1773     by (intro emeasure_measure_of[OF M_eq]) (auto simp add: M measure_space_def sets_extend_measure)
  1774   with `i\<in>I` * show ?thesis
  1775     by simp
  1776 next
  1777   def P \<equiv> "\<lambda>\<mu>'. (\<forall>i\<in>I. \<mu>' (G i) = \<mu> i) \<and> measure_space \<Omega> (sigma_sets \<Omega> (G`I)) \<mu>'"
  1778   assume "\<not> (\<forall>i\<in>I. \<mu> i = 0)"
  1779   moreover
  1780   have "measure_space (space M) (sets M) \<mu>'"
  1781     using ms unfolding measure_space_def by auto default
  1782   with ms eq have "\<exists>\<mu>'. P \<mu>'"
  1783     unfolding P_def
  1784     by (intro exI[of _ \<mu>']) (auto simp add: M space_extend_measure sets_extend_measure)
  1785   ultimately have M_eq: "M = measure_of \<Omega> (G`I) (Eps P)"
  1786     by (simp add: M extend_measure_def P_def[symmetric])
  1787 
  1788   from `\<exists>\<mu>'. P \<mu>'` have P: "P (Eps P)" by (rule someI_ex)
  1789   show "emeasure M (G i) = \<mu> i"
  1790   proof (subst emeasure_measure_of[OF M_eq])
  1791     have sets_M: "sets M = sigma_sets \<Omega> (G`I)"
  1792       using M_eq ms by (auto simp: sets_extend_measure)
  1793     then show "G i \<in> sets M" using `i \<in> I` by auto
  1794     show "positive (sets M) (Eps P)" "countably_additive (sets M) (Eps P)" "Eps P (G i) = \<mu> i"
  1795       using P `i\<in>I` by (auto simp add: sets_M measure_space_def P_def)
  1796   qed fact
  1797 qed
  1798 
  1799 lemma emeasure_extend_measure_Pair:
  1800   assumes M: "M = extend_measure \<Omega> {(i, j). I i j} (\<lambda>(i, j). G i j) (\<lambda>(i, j). \<mu> i j)"
  1801     and eq: "\<And>i j. I i j \<Longrightarrow> \<mu>' (G i j) = \<mu> i j"
  1802     and ms: "\<And>i j. I i j \<Longrightarrow> G i j \<in> Pow \<Omega>" "positive (sets M) \<mu>'" "countably_additive (sets M) \<mu>'"
  1803     and "I i j"
  1804   shows "emeasure M (G i j) = \<mu> i j"
  1805   using emeasure_extend_measure[OF M _ _ ms(2,3), of "(i,j)"] eq ms(1) `I i j`
  1806   by (auto simp: subset_eq)
  1807 
  1808 subsection {* Sigma algebra generated by function preimages *}
  1809 
  1810 definition
  1811   "vimage_algebra M S f = sigma S ((\<lambda>A. f -` A \<inter> S) ` sets M)"
  1812 
  1813 lemma sigma_algebra_preimages:
  1814   fixes f :: "'x \<Rightarrow> 'a"
  1815   assumes "f \<in> S \<rightarrow> space M"
  1816   shows "sigma_algebra S ((\<lambda>A. f -` A \<inter> S) ` sets M)"
  1817     (is "sigma_algebra _ (?F ` sets M)")
  1818 proof (simp add: sigma_algebra_iff2, safe)
  1819   show "{} \<in> ?F ` sets M" by blast
  1820 next
  1821   fix A assume "A \<in> sets M"
  1822   moreover have "S - ?F A = ?F (space M - A)"
  1823     using assms by auto
  1824   ultimately show "S - ?F A \<in> ?F ` sets M"
  1825     by blast
  1826 next
  1827   fix A :: "nat \<Rightarrow> 'x set" assume *: "range A \<subseteq> ?F ` M"
  1828   have "\<forall>i. \<exists>b. b \<in> M \<and> A i = ?F b"
  1829   proof safe
  1830     fix i
  1831     have "A i \<in> ?F ` M" using * by auto
  1832     then show "\<exists>b. b \<in> M \<and> A i = ?F b" by auto
  1833   qed
  1834   from choice[OF this] obtain b where b: "range b \<subseteq> M" "\<And>i. A i = ?F (b i)"
  1835     by auto
  1836   then have "(\<Union>i. A i) = ?F (\<Union>i. b i)" by auto
  1837   then show "(\<Union>i. A i) \<in> ?F ` M" using b(1) by blast
  1838 qed
  1839 
  1840 lemma sets_vimage_algebra[simp]:
  1841   "f \<in> S \<rightarrow> space M \<Longrightarrow> sets (vimage_algebra M S f) = (\<lambda>A. f -` A \<inter> S) ` sets M"
  1842   using sigma_algebra.sets_measure_of_eq[OF sigma_algebra_preimages, of f S M]
  1843   by (simp add: vimage_algebra_def)
  1844 
  1845 lemma space_vimage_algebra[simp]:
  1846   "f \<in> S \<rightarrow> space M \<Longrightarrow> space (vimage_algebra M S f) = S"
  1847   using sigma_algebra.space_measure_of_eq[OF sigma_algebra_preimages, of f S M]
  1848   by (simp add: vimage_algebra_def)
  1849 
  1850 lemma in_vimage_algebra[simp]:
  1851   "f \<in> S \<rightarrow> space M \<Longrightarrow> A \<in> sets (vimage_algebra M S f) \<longleftrightarrow> (\<exists>B\<in>sets M. A = f -` B \<inter> S)"
  1852   by (simp add: image_iff)
  1853 
  1854 lemma measurable_vimage_algebra:
  1855   fixes S :: "'c set" assumes "f \<in> S \<rightarrow> space M"
  1856   shows "f \<in> measurable (vimage_algebra M S f) M"
  1857   unfolding measurable_def using assms by force
  1858 
  1859 lemma measurable_vimage:
  1860   fixes g :: "'a \<Rightarrow> 'c" and f :: "'d \<Rightarrow> 'a"
  1861   assumes "g \<in> measurable M M2" "f \<in> S \<rightarrow> space M"
  1862   shows "(\<lambda>x. g (f x)) \<in> measurable (vimage_algebra M S f) M2"
  1863 proof -
  1864   note measurable_vimage_algebra[OF assms(2)]
  1865   from measurable_comp[OF this assms(1)]
  1866   show ?thesis by (simp add: comp_def)
  1867 qed
  1868 
  1869 lemma sigma_sets_vimage:
  1870   assumes "f \<in> S' \<rightarrow> S" and "A \<subseteq> Pow S"
  1871   shows "sigma_sets S' ((\<lambda>X. f -` X \<inter> S') ` A) = (\<lambda>X. f -` X \<inter> S') ` sigma_sets S A"
  1872 proof (intro set_eqI iffI)
  1873   let ?F = "\<lambda>X. f -` X \<inter> S'"
  1874   fix X assume "X \<in> sigma_sets S' (?F ` A)"
  1875   then show "X \<in> ?F ` sigma_sets S A"
  1876   proof induct
  1877     case (Basic X) then obtain X' where "X = ?F X'" "X' \<in> A"
  1878       by auto
  1879     then show ?case by auto
  1880   next
  1881     case Empty then show ?case
  1882       by (auto intro!: image_eqI[of _ _ "{}"] sigma_sets.Empty)
  1883   next
  1884     case (Compl X) then obtain X' where X: "X = ?F X'" and "X' \<in> sigma_sets S A"
  1885       by auto
  1886     then have "S - X' \<in> sigma_sets S A"
  1887       by (auto intro!: sigma_sets.Compl)
  1888     then show ?case
  1889       using X assms by (auto intro!: image_eqI[where x="S - X'"])
  1890   next
  1891     case (Union F)
  1892     then have "\<forall>i. \<exists>F'.  F' \<in> sigma_sets S A \<and> F i = f -` F' \<inter> S'"
  1893       by (auto simp: image_iff Bex_def)
  1894     from choice[OF this] obtain F' where
  1895       "\<And>i. F' i \<in> sigma_sets S A" and "\<And>i. F i = f -` F' i \<inter> S'"
  1896       by auto
  1897     then show ?case
  1898       by (auto intro!: sigma_sets.Union image_eqI[where x="\<Union>i. F' i"])
  1899   qed
  1900 next
  1901   let ?F = "\<lambda>X. f -` X \<inter> S'"
  1902   fix X assume "X \<in> ?F ` sigma_sets S A"
  1903   then obtain X' where "X' \<in> sigma_sets S A" "X = ?F X'" by auto
  1904   then show "X \<in> sigma_sets S' (?F ` A)"
  1905   proof (induct arbitrary: X)
  1906     case Empty then show ?case by (auto intro: sigma_sets.Empty)
  1907   next
  1908     case (Compl X')
  1909     have "S' - (S' - X) \<in> sigma_sets S' (?F ` A)"
  1910       apply (rule sigma_sets.Compl)
  1911       using assms by (auto intro!: Compl.hyps simp: Compl.prems)
  1912     also have "S' - (S' - X) = X"
  1913       using assms Compl by auto
  1914     finally show ?case .
  1915   next
  1916     case (Union F)
  1917     have "(\<Union>i. f -` F i \<inter> S') \<in> sigma_sets S' (?F ` A)"
  1918       by (intro sigma_sets.Union Union.hyps) simp
  1919     also have "(\<Union>i. f -` F i \<inter> S') = X"
  1920       using assms Union by auto
  1921     finally show ?case .
  1922   qed auto
  1923 qed
  1924 
  1925 subsection {* A Two-Element Series *}
  1926 
  1927 definition binaryset :: "'a set \<Rightarrow> 'a set \<Rightarrow> nat \<Rightarrow> 'a set "
  1928   where "binaryset A B = (\<lambda>\<^isup>x. {})(0 := A, Suc 0 := B)"
  1929 
  1930 lemma range_binaryset_eq: "range(binaryset A B) = {A,B,{}}"
  1931   apply (simp add: binaryset_def)
  1932   apply (rule set_eqI)
  1933   apply (auto simp add: image_iff)
  1934   done
  1935 
  1936 lemma UN_binaryset_eq: "(\<Union>i. binaryset A B i) = A \<union> B"
  1937   by (simp add: SUP_def range_binaryset_eq)
  1938 
  1939 section {* Closed CDI *}
  1940 
  1941 definition closed_cdi where
  1942   "closed_cdi \<Omega> M \<longleftrightarrow>
  1943    M \<subseteq> Pow \<Omega> &
  1944    (\<forall>s \<in> M. \<Omega> - s \<in> M) &
  1945    (\<forall>A. (range A \<subseteq> M) & (A 0 = {}) & (\<forall>n. A n \<subseteq> A (Suc n)) \<longrightarrow>
  1946         (\<Union>i. A i) \<in> M) &
  1947    (\<forall>A. (range A \<subseteq> M) & disjoint_family A \<longrightarrow> (\<Union>i::nat. A i) \<in> M)"
  1948 
  1949 inductive_set
  1950   smallest_ccdi_sets :: "'a set \<Rightarrow> 'a set set \<Rightarrow> 'a set set"
  1951   for \<Omega> M
  1952   where
  1953     Basic [intro]:
  1954       "a \<in> M \<Longrightarrow> a \<in> smallest_ccdi_sets \<Omega> M"
  1955   | Compl [intro]:
  1956       "a \<in> smallest_ccdi_sets \<Omega> M \<Longrightarrow> \<Omega> - a \<in> smallest_ccdi_sets \<Omega> M"
  1957   | Inc:
  1958       "range A \<in> Pow(smallest_ccdi_sets \<Omega> M) \<Longrightarrow> A 0 = {} \<Longrightarrow> (\<And>n. A n \<subseteq> A (Suc n))
  1959        \<Longrightarrow> (\<Union>i. A i) \<in> smallest_ccdi_sets \<Omega> M"
  1960   | Disj:
  1961       "range A \<in> Pow(smallest_ccdi_sets \<Omega> M) \<Longrightarrow> disjoint_family A
  1962        \<Longrightarrow> (\<Union>i::nat. A i) \<in> smallest_ccdi_sets \<Omega> M"
  1963 
  1964 lemma (in subset_class) smallest_closed_cdi1: "M \<subseteq> smallest_ccdi_sets \<Omega> M"
  1965   by auto
  1966 
  1967 lemma (in subset_class) smallest_ccdi_sets: "smallest_ccdi_sets \<Omega> M \<subseteq> Pow \<Omega>"
  1968   apply (rule subsetI)
  1969   apply (erule smallest_ccdi_sets.induct)
  1970   apply (auto intro: range_subsetD dest: sets_into_space)
  1971   done
  1972 
  1973 lemma (in subset_class) smallest_closed_cdi2: "closed_cdi \<Omega> (smallest_ccdi_sets \<Omega> M)"
  1974   apply (auto simp add: closed_cdi_def smallest_ccdi_sets)
  1975   apply (blast intro: smallest_ccdi_sets.Inc smallest_ccdi_sets.Disj) +
  1976   done
  1977 
  1978 lemma closed_cdi_subset: "closed_cdi \<Omega> M \<Longrightarrow> M \<subseteq> Pow \<Omega>"
  1979   by (simp add: closed_cdi_def)
  1980 
  1981 lemma closed_cdi_Compl: "closed_cdi \<Omega> M \<Longrightarrow> s \<in> M \<Longrightarrow> \<Omega> - s \<in> M"
  1982   by (simp add: closed_cdi_def)
  1983 
  1984 lemma closed_cdi_Inc:
  1985   "closed_cdi \<Omega> M \<Longrightarrow> range A \<subseteq> M \<Longrightarrow> A 0 = {} \<Longrightarrow> (!!n. A n \<subseteq> A (Suc n)) \<Longrightarrow> (\<Union>i. A i) \<in> M"
  1986   by (simp add: closed_cdi_def)
  1987 
  1988 lemma closed_cdi_Disj:
  1989   "closed_cdi \<Omega> M \<Longrightarrow> range A \<subseteq> M \<Longrightarrow> disjoint_family A \<Longrightarrow> (\<Union>i::nat. A i) \<in> M"
  1990   by (simp add: closed_cdi_def)
  1991 
  1992 lemma closed_cdi_Un:
  1993   assumes cdi: "closed_cdi \<Omega> M" and empty: "{} \<in> M"
  1994       and A: "A \<in> M" and B: "B \<in> M"
  1995       and disj: "A \<inter> B = {}"
  1996     shows "A \<union> B \<in> M"
  1997 proof -
  1998   have ra: "range (binaryset A B) \<subseteq> M"
  1999    by (simp add: range_binaryset_eq empty A B)
  2000  have di:  "disjoint_family (binaryset A B)" using disj
  2001    by (simp add: disjoint_family_on_def binaryset_def Int_commute)
  2002  from closed_cdi_Disj [OF cdi ra di]
  2003  show ?thesis
  2004    by (simp add: UN_binaryset_eq)
  2005 qed
  2006 
  2007 lemma (in algebra) smallest_ccdi_sets_Un:
  2008   assumes A: "A \<in> smallest_ccdi_sets \<Omega> M" and B: "B \<in> smallest_ccdi_sets \<Omega> M"
  2009       and disj: "A \<inter> B = {}"
  2010     shows "A \<union> B \<in> smallest_ccdi_sets \<Omega> M"
  2011 proof -
  2012   have ra: "range (binaryset A B) \<in> Pow (smallest_ccdi_sets \<Omega> M)"
  2013     by (simp add: range_binaryset_eq  A B smallest_ccdi_sets.Basic)
  2014   have di:  "disjoint_family (binaryset A B)" using disj
  2015     by (simp add: disjoint_family_on_def binaryset_def Int_commute)
  2016   from Disj [OF ra di]
  2017   show ?thesis
  2018     by (simp add: UN_binaryset_eq)
  2019 qed
  2020 
  2021 lemma (in algebra) smallest_ccdi_sets_Int1:
  2022   assumes a: "a \<in> M"
  2023   shows "b \<in> smallest_ccdi_sets \<Omega> M \<Longrightarrow> a \<inter> b \<in> smallest_ccdi_sets \<Omega> M"
  2024 proof (induct rule: smallest_ccdi_sets.induct)
  2025   case (Basic x)
  2026   thus ?case
  2027     by (metis a Int smallest_ccdi_sets.Basic)
  2028 next
  2029   case (Compl x)
  2030   have "a \<inter> (\<Omega> - x) = \<Omega> - ((\<Omega> - a) \<union> (a \<inter> x))"
  2031     by blast
  2032   also have "... \<in> smallest_ccdi_sets \<Omega> M"
  2033     by (metis smallest_ccdi_sets.Compl a Compl(2) Diff_Int2 Diff_Int_distrib2
  2034            Diff_disjoint Int_Diff Int_empty_right smallest_ccdi_sets_Un
  2035            smallest_ccdi_sets.Basic smallest_ccdi_sets.Compl)
  2036   finally show ?case .
  2037 next
  2038   case (Inc A)
  2039   have 1: "(\<Union>i. (\<lambda>i. a \<inter> A i) i) = a \<inter> (\<Union>i. A i)"
  2040     by blast
  2041   have "range (\<lambda>i. a \<inter> A i) \<in> Pow(smallest_ccdi_sets \<Omega> M)" using Inc
  2042     by blast
  2043   moreover have "(\<lambda>i. a \<inter> A i) 0 = {}"
  2044     by (simp add: Inc)
  2045   moreover have "!!n. (\<lambda>i. a \<inter> A i) n \<subseteq> (\<lambda>i. a \<inter> A i) (Suc n)" using Inc
  2046     by blast
  2047   ultimately have 2: "(\<Union>i. (\<lambda>i. a \<inter> A i) i) \<in> smallest_ccdi_sets \<Omega> M"
  2048     by (rule smallest_ccdi_sets.Inc)
  2049   show ?case
  2050     by (metis 1 2)
  2051 next
  2052   case (Disj A)
  2053   have 1: "(\<Union>i. (\<lambda>i. a \<inter> A i) i) = a \<inter> (\<Union>i. A i)"
  2054     by blast
  2055   have "range (\<lambda>i. a \<inter> A i) \<in> Pow(smallest_ccdi_sets \<Omega> M)" using Disj
  2056     by blast
  2057   moreover have "disjoint_family (\<lambda>i. a \<inter> A i)" using Disj
  2058     by (auto simp add: disjoint_family_on_def)
  2059   ultimately have 2: "(\<Union>i. (\<lambda>i. a \<inter> A i) i) \<in> smallest_ccdi_sets \<Omega> M"
  2060     by (rule smallest_ccdi_sets.Disj)
  2061   show ?case
  2062     by (metis 1 2)
  2063 qed
  2064 
  2065 
  2066 lemma (in algebra) smallest_ccdi_sets_Int:
  2067   assumes b: "b \<in> smallest_ccdi_sets \<Omega> M"
  2068   shows "a \<in> smallest_ccdi_sets \<Omega> M \<Longrightarrow> a \<inter> b \<in> smallest_ccdi_sets \<Omega> M"
  2069 proof (induct rule: smallest_ccdi_sets.induct)
  2070   case (Basic x)
  2071   thus ?case
  2072     by (metis b smallest_ccdi_sets_Int1)
  2073 next
  2074   case (Compl x)
  2075   have "(\<Omega> - x) \<inter> b = \<Omega> - (x \<inter> b \<union> (\<Omega> - b))"
  2076     by blast
  2077   also have "... \<in> smallest_ccdi_sets \<Omega> M"
  2078     by (metis Compl(2) Diff_disjoint Int_Diff Int_commute Int_empty_right b
  2079            smallest_ccdi_sets.Compl smallest_ccdi_sets_Un)
  2080   finally show ?case .
  2081 next
  2082   case (Inc A)
  2083   have 1: "(\<Union>i. (\<lambda>i. A i \<inter> b) i) = (\<Union>i. A i) \<inter> b"
  2084     by blast
  2085   have "range (\<lambda>i. A i \<inter> b) \<in> Pow(smallest_ccdi_sets \<Omega> M)" using Inc
  2086     by blast
  2087   moreover have "(\<lambda>i. A i \<inter> b) 0 = {}"
  2088     by (simp add: Inc)
  2089   moreover have "!!n. (\<lambda>i. A i \<inter> b) n \<subseteq> (\<lambda>i. A i \<inter> b) (Suc n)" using Inc
  2090     by blast
  2091   ultimately have 2: "(\<Union>i. (\<lambda>i. A i \<inter> b) i) \<in> smallest_ccdi_sets \<Omega> M"
  2092     by (rule smallest_ccdi_sets.Inc)
  2093   show ?case
  2094     by (metis 1 2)
  2095 next
  2096   case (Disj A)
  2097   have 1: "(\<Union>i. (\<lambda>i. A i \<inter> b) i) = (\<Union>i. A i) \<inter> b"
  2098     by blast
  2099   have "range (\<lambda>i. A i \<inter> b) \<in> Pow(smallest_ccdi_sets \<Omega> M)" using Disj
  2100     by blast
  2101   moreover have "disjoint_family (\<lambda>i. A i \<inter> b)" using Disj
  2102     by (auto simp add: disjoint_family_on_def)
  2103   ultimately have 2: "(\<Union>i. (\<lambda>i. A i \<inter> b) i) \<in> smallest_ccdi_sets \<Omega> M"
  2104     by (rule smallest_ccdi_sets.Disj)
  2105   show ?case
  2106     by (metis 1 2)
  2107 qed
  2108 
  2109 lemma (in algebra) sigma_property_disjoint_lemma:
  2110   assumes sbC: "M \<subseteq> C"
  2111       and ccdi: "closed_cdi \<Omega> C"
  2112   shows "sigma_sets \<Omega> M \<subseteq> C"
  2113 proof -
  2114   have "smallest_ccdi_sets \<Omega> M \<in> {B . M \<subseteq> B \<and> sigma_algebra \<Omega> B}"
  2115     apply (auto simp add: sigma_algebra_disjoint_iff algebra_iff_Int
  2116             smallest_ccdi_sets_Int)
  2117     apply (metis Union_Pow_eq Union_upper subsetD smallest_ccdi_sets)
  2118     apply (blast intro: smallest_ccdi_sets.Disj)
  2119     done
  2120   hence "sigma_sets (\<Omega>) (M) \<subseteq> smallest_ccdi_sets \<Omega> M"
  2121     by clarsimp
  2122        (drule sigma_algebra.sigma_sets_subset [where a="M"], auto)
  2123   also have "...  \<subseteq> C"
  2124     proof
  2125       fix x
  2126       assume x: "x \<in> smallest_ccdi_sets \<Omega> M"
  2127       thus "x \<in> C"
  2128         proof (induct rule: smallest_ccdi_sets.induct)
  2129           case (Basic x)
  2130           thus ?case
  2131             by (metis Basic subsetD sbC)
  2132         next
  2133           case (Compl x)
  2134           thus ?case
  2135             by (blast intro: closed_cdi_Compl [OF ccdi, simplified])
  2136         next
  2137           case (Inc A)
  2138           thus ?case
  2139                by (auto intro: closed_cdi_Inc [OF ccdi, simplified])
  2140         next
  2141           case (Disj A)
  2142           thus ?case
  2143                by (auto intro: closed_cdi_Disj [OF ccdi, simplified])
  2144         qed
  2145     qed
  2146   finally show ?thesis .
  2147 qed
  2148 
  2149 lemma (in algebra) sigma_property_disjoint:
  2150   assumes sbC: "M \<subseteq> C"
  2151       and compl: "!!s. s \<in> C \<inter> sigma_sets (\<Omega>) (M) \<Longrightarrow> \<Omega> - s \<in> C"
  2152       and inc: "!!A. range A \<subseteq> C \<inter> sigma_sets (\<Omega>) (M)
  2153                      \<Longrightarrow> A 0 = {} \<Longrightarrow> (!!n. A n \<subseteq> A (Suc n))
  2154                      \<Longrightarrow> (\<Union>i. A i) \<in> C"
  2155       and disj: "!!A. range A \<subseteq> C \<inter> sigma_sets (\<Omega>) (M)
  2156                       \<Longrightarrow> disjoint_family A \<Longrightarrow> (\<Union>i::nat. A i) \<in> C"
  2157   shows "sigma_sets (\<Omega>) (M) \<subseteq> C"
  2158 proof -
  2159   have "sigma_sets (\<Omega>) (M) \<subseteq> C \<inter> sigma_sets (\<Omega>) (M)"
  2160     proof (rule sigma_property_disjoint_lemma)
  2161       show "M \<subseteq> C \<inter> sigma_sets (\<Omega>) (M)"
  2162         by (metis Int_greatest Set.subsetI sbC sigma_sets.Basic)
  2163     next
  2164       show "closed_cdi \<Omega> (C \<inter> sigma_sets (\<Omega>) (M))"
  2165         by (simp add: closed_cdi_def compl inc disj)
  2166            (metis PowI Set.subsetI le_infI2 sigma_sets_into_sp space_closed
  2167              IntE sigma_sets.Compl range_subsetD sigma_sets.Union)
  2168     qed
  2169   thus ?thesis
  2170     by blast
  2171 qed
  2172 
  2173 section {* Dynkin systems *}
  2174 
  2175 locale dynkin_system = subset_class +
  2176   assumes space: "\<Omega> \<in> M"
  2177     and   compl[intro!]: "\<And>A. A \<in> M \<Longrightarrow> \<Omega> - A \<in> M"
  2178     and   UN[intro!]: "\<And>A. disjoint_family A \<Longrightarrow> range A \<subseteq> M
  2179                            \<Longrightarrow> (\<Union>i::nat. A i) \<in> M"
  2180 
  2181 lemma (in dynkin_system) empty[intro, simp]: "{} \<in> M"
  2182   using space compl[of "\<Omega>"] by simp
  2183 
  2184 lemma (in dynkin_system) diff:
  2185   assumes sets: "D \<in> M" "E \<in> M" and "D \<subseteq> E"
  2186   shows "E - D \<in> M"
  2187 proof -
  2188   let ?f = "\<lambda>x. if x = 0 then D else if x = Suc 0 then \<Omega> - E else {}"
  2189   have "range ?f = {D, \<Omega> - E, {}}"
  2190     by (auto simp: image_iff)
  2191   moreover have "D \<union> (\<Omega> - E) = (\<Union>i. ?f i)"
  2192     by (auto simp: image_iff split: split_if_asm)
  2193   moreover
  2194   then have "disjoint_family ?f" unfolding disjoint_family_on_def
  2195     using `D \<in> M`[THEN sets_into_space] `D \<subseteq> E` by auto
  2196   ultimately have "\<Omega> - (D \<union> (\<Omega> - E)) \<in> M"
  2197     using sets by auto
  2198   also have "\<Omega> - (D \<union> (\<Omega> - E)) = E - D"
  2199     using assms sets_into_space by auto
  2200   finally show ?thesis .
  2201 qed
  2202 
  2203 lemma dynkin_systemI:
  2204   assumes "\<And> A. A \<in> M \<Longrightarrow> A \<subseteq> \<Omega>" "\<Omega> \<in> M"
  2205   assumes "\<And> A. A \<in> M \<Longrightarrow> \<Omega> - A \<in> M"
  2206   assumes "\<And> A. disjoint_family A \<Longrightarrow> range A \<subseteq> M
  2207           \<Longrightarrow> (\<Union>i::nat. A i) \<in> M"
  2208   shows "dynkin_system \<Omega> M"
  2209   using assms by (auto simp: dynkin_system_def dynkin_system_axioms_def subset_class_def)
  2210 
  2211 lemma dynkin_systemI':
  2212   assumes 1: "\<And> A. A \<in> M \<Longrightarrow> A \<subseteq> \<Omega>"
  2213   assumes empty: "{} \<in> M"
  2214   assumes Diff: "\<And> A. A \<in> M \<Longrightarrow> \<Omega> - A \<in> M"
  2215   assumes 2: "\<And> A. disjoint_family A \<Longrightarrow> range A \<subseteq> M
  2216           \<Longrightarrow> (\<Union>i::nat. A i) \<in> M"
  2217   shows "dynkin_system \<Omega> M"
  2218 proof -
  2219   from Diff[OF empty] have "\<Omega> \<in> M" by auto
  2220   from 1 this Diff 2 show ?thesis
  2221     by (intro dynkin_systemI) auto
  2222 qed
  2223 
  2224 lemma dynkin_system_trivial:
  2225   shows "dynkin_system A (Pow A)"
  2226   by (rule dynkin_systemI) auto
  2227 
  2228 lemma sigma_algebra_imp_dynkin_system:
  2229   assumes "sigma_algebra \<Omega> M" shows "dynkin_system \<Omega> M"
  2230 proof -
  2231   interpret sigma_algebra \<Omega> M by fact
  2232   show ?thesis using sets_into_space by (fastforce intro!: dynkin_systemI)
  2233 qed
  2234 
  2235 subsection "Intersection stable algebras"
  2236 
  2237 definition "Int_stable M \<longleftrightarrow> (\<forall> a \<in> M. \<forall> b \<in> M. a \<inter> b \<in> M)"
  2238 
  2239 lemma (in algebra) Int_stable: "Int_stable M"
  2240   unfolding Int_stable_def by auto
  2241 
  2242 lemma Int_stableI:
  2243   "(\<And>a b. a \<in> A \<Longrightarrow> b \<in> A \<Longrightarrow> a \<inter> b \<in> A) \<Longrightarrow> Int_stable A"
  2244   unfolding Int_stable_def by auto
  2245 
  2246 lemma Int_stableD:
  2247   "Int_stable M \<Longrightarrow> a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a \<inter> b \<in> M"
  2248   unfolding Int_stable_def by auto
  2249 
  2250 lemma (in dynkin_system) sigma_algebra_eq_Int_stable:
  2251   "sigma_algebra \<Omega> M \<longleftrightarrow> Int_stable M"
  2252 proof
  2253   assume "sigma_algebra \<Omega> M" then show "Int_stable M"
  2254     unfolding sigma_algebra_def using algebra.Int_stable by auto
  2255 next
  2256   assume "Int_stable M"
  2257   show "sigma_algebra \<Omega> M"
  2258     unfolding sigma_algebra_disjoint_iff algebra_iff_Un
  2259   proof (intro conjI ballI allI impI)
  2260     show "M \<subseteq> Pow (\<Omega>)" using sets_into_space by auto
  2261   next
  2262     fix A B assume "A \<in> M" "B \<in> M"
  2263     then have "A \<union> B = \<Omega> - ((\<Omega> - A) \<inter> (\<Omega> - B))"
  2264               "\<Omega> - A \<in> M" "\<Omega> - B \<in> M"
  2265       using sets_into_space by auto
  2266     then show "A \<union> B \<in> M"
  2267       using `Int_stable M` unfolding Int_stable_def by auto
  2268   qed auto
  2269 qed
  2270 
  2271 subsection "Smallest Dynkin systems"
  2272 
  2273 definition dynkin where
  2274   "dynkin \<Omega> M =  (\<Inter>{D. dynkin_system \<Omega> D \<and> M \<subseteq> D})"
  2275 
  2276 lemma dynkin_system_dynkin:
  2277   assumes "M \<subseteq> Pow (\<Omega>)"
  2278   shows "dynkin_system \<Omega> (dynkin \<Omega> M)"
  2279 proof (rule dynkin_systemI)
  2280   fix A assume "A \<in> dynkin \<Omega> M"
  2281   moreover
  2282   { fix D assume "A \<in> D" and d: "dynkin_system \<Omega> D"
  2283     then have "A \<subseteq> \<Omega>" by (auto simp: dynkin_system_def subset_class_def) }
  2284   moreover have "{D. dynkin_system \<Omega> D \<and> M \<subseteq> D} \<noteq> {}"
  2285     using assms dynkin_system_trivial by fastforce
  2286   ultimately show "A \<subseteq> \<Omega>"
  2287     unfolding dynkin_def using assms
  2288     by auto
  2289 next
  2290   show "\<Omega> \<in> dynkin \<Omega> M"
  2291     unfolding dynkin_def using dynkin_system.space by fastforce
  2292 next
  2293   fix A assume "A \<in> dynkin \<Omega> M"
  2294   then show "\<Omega> - A \<in> dynkin \<Omega> M"
  2295     unfolding dynkin_def using dynkin_system.compl by force
  2296 next
  2297   fix A :: "nat \<Rightarrow> 'a set"
  2298   assume A: "disjoint_family A" "range A \<subseteq> dynkin \<Omega> M"
  2299   show "(\<Union>i. A i) \<in> dynkin \<Omega> M" unfolding dynkin_def
  2300   proof (simp, safe)
  2301     fix D assume "dynkin_system \<Omega> D" "M \<subseteq> D"
  2302     with A have "(\<Union>i. A i) \<in> D"
  2303       by (intro dynkin_system.UN) (auto simp: dynkin_def)
  2304     then show "(\<Union>i. A i) \<in> D" by auto
  2305   qed
  2306 qed
  2307 
  2308 lemma dynkin_Basic[intro]: "A \<in> M \<Longrightarrow> A \<in> dynkin \<Omega> M"
  2309   unfolding dynkin_def by auto
  2310 
  2311 lemma (in dynkin_system) restricted_dynkin_system:
  2312   assumes "D \<in> M"
  2313   shows "dynkin_system \<Omega> {Q. Q \<subseteq> \<Omega> \<and> Q \<inter> D \<in> M}"
  2314 proof (rule dynkin_systemI, simp_all)
  2315   have "\<Omega> \<inter> D = D"
  2316     using `D \<in> M` sets_into_space by auto
  2317   then show "\<Omega> \<inter> D \<in> M"
  2318     using `D \<in> M` by auto
  2319 next
  2320   fix A assume "A \<subseteq> \<Omega> \<and> A \<inter> D \<in> M"
  2321   moreover have "(\<Omega> - A) \<inter> D = (\<Omega> - (A \<inter> D)) - (\<Omega> - D)"
  2322     by auto
  2323   ultimately show "\<Omega> - A \<subseteq> \<Omega> \<and> (\<Omega> - A) \<inter> D \<in> M"
  2324     using  `D \<in> M` by (auto intro: diff)
  2325 next
  2326   fix A :: "nat \<Rightarrow> 'a set"
  2327   assume "disjoint_family A" "range A \<subseteq> {Q. Q \<subseteq> \<Omega> \<and> Q \<inter> D \<in> M}"
  2328   then have "\<And>i. A i \<subseteq> \<Omega>" "disjoint_family (\<lambda>i. A i \<inter> D)"
  2329     "range (\<lambda>i. A i \<inter> D) \<subseteq> M" "(\<Union>x. A x) \<inter> D = (\<Union>x. A x \<inter> D)"
  2330     by ((fastforce simp: disjoint_family_on_def)+)
  2331   then show "(\<Union>x. A x) \<subseteq> \<Omega> \<and> (\<Union>x. A x) \<inter> D \<in> M"
  2332     by (auto simp del: UN_simps)
  2333 qed
  2334 
  2335 lemma (in dynkin_system) dynkin_subset:
  2336   assumes "N \<subseteq> M"
  2337   shows "dynkin \<Omega> N \<subseteq> M"
  2338 proof -
  2339   have "dynkin_system \<Omega> M" by default
  2340   then have "dynkin_system \<Omega> M"
  2341     using assms unfolding dynkin_system_def dynkin_system_axioms_def subset_class_def by simp
  2342   with `N \<subseteq> M` show ?thesis by (auto simp add: dynkin_def)
  2343 qed
  2344 
  2345 lemma sigma_eq_dynkin:
  2346   assumes sets: "M \<subseteq> Pow \<Omega>"
  2347   assumes "Int_stable M"
  2348   shows "sigma_sets \<Omega> M = dynkin \<Omega> M"
  2349 proof -
  2350   have "dynkin \<Omega> M \<subseteq> sigma_sets (\<Omega>) (M)"
  2351     using sigma_algebra_imp_dynkin_system
  2352     unfolding dynkin_def sigma_sets_least_sigma_algebra[OF sets] by auto
  2353   moreover
  2354   interpret dynkin_system \<Omega> "dynkin \<Omega> M"
  2355     using dynkin_system_dynkin[OF sets] .
  2356   have "sigma_algebra \<Omega> (dynkin \<Omega> M)"
  2357     unfolding sigma_algebra_eq_Int_stable Int_stable_def
  2358   proof (intro ballI)
  2359     fix A B assume "A \<in> dynkin \<Omega> M" "B \<in> dynkin \<Omega> M"
  2360     let ?D = "\<lambda>E. {Q. Q \<subseteq> \<Omega> \<and> Q \<inter> E \<in> dynkin \<Omega> M}"
  2361     have "M \<subseteq> ?D B"
  2362     proof
  2363       fix E assume "E \<in> M"
  2364       then have "M \<subseteq> ?D E" "E \<in> dynkin \<Omega> M"
  2365         using sets_into_space `Int_stable M` by (auto simp: Int_stable_def)
  2366       then have "dynkin \<Omega> M \<subseteq> ?D E"
  2367         using restricted_dynkin_system `E \<in> dynkin \<Omega> M`
  2368         by (intro dynkin_system.dynkin_subset) simp_all
  2369       then have "B \<in> ?D E"
  2370         using `B \<in> dynkin \<Omega> M` by auto
  2371       then have "E \<inter> B \<in> dynkin \<Omega> M"
  2372         by (subst Int_commute) simp
  2373       then show "E \<in> ?D B"
  2374         using sets `E \<in> M` by auto
  2375     qed
  2376     then have "dynkin \<Omega> M \<subseteq> ?D B"
  2377       using restricted_dynkin_system `B \<in> dynkin \<Omega> M`
  2378       by (intro dynkin_system.dynkin_subset) simp_all
  2379     then show "A \<inter> B \<in> dynkin \<Omega> M"
  2380       using `A \<in> dynkin \<Omega> M` sets_into_space by auto
  2381   qed
  2382   from sigma_algebra.sigma_sets_subset[OF this, of "M"]
  2383   have "sigma_sets (\<Omega>) (M) \<subseteq> dynkin \<Omega> M" by auto
  2384   ultimately have "sigma_sets (\<Omega>) (M) = dynkin \<Omega> M" by auto
  2385   then show ?thesis
  2386     by (auto simp: dynkin_def)
  2387 qed
  2388 
  2389 lemma (in dynkin_system) dynkin_idem:
  2390   "dynkin \<Omega> M = M"
  2391 proof -
  2392   have "dynkin \<Omega> M = M"
  2393   proof
  2394     show "M \<subseteq> dynkin \<Omega> M"
  2395       using dynkin_Basic by auto
  2396     show "dynkin \<Omega> M \<subseteq> M"
  2397       by (intro dynkin_subset) auto
  2398   qed
  2399   then show ?thesis
  2400     by (auto simp: dynkin_def)
  2401 qed
  2402 
  2403 lemma (in dynkin_system) dynkin_lemma:
  2404   assumes "Int_stable E"
  2405   and E: "E \<subseteq> M" "M \<subseteq> sigma_sets \<Omega> E"
  2406   shows "sigma_sets \<Omega> E = M"
  2407 proof -
  2408   have "E \<subseteq> Pow \<Omega>"
  2409     using E sets_into_space by force
  2410   then have "sigma_sets \<Omega> E = dynkin \<Omega> E"
  2411     using `Int_stable E` by (rule sigma_eq_dynkin)
  2412   moreover then have "dynkin \<Omega> E = M"
  2413     using assms dynkin_subset[OF E(1)] by simp
  2414   ultimately show ?thesis
  2415     using assms by (auto simp: dynkin_def)
  2416 qed
  2417 
  2418 lemma sigma_sets_induct_disjoint[consumes 3, case_names basic empty compl union]:
  2419   assumes "Int_stable G"
  2420     and closed: "G \<subseteq> Pow \<Omega>"
  2421     and A: "A \<in> sigma_sets \<Omega> G"
  2422   assumes basic: "\<And>A. A \<in> G \<Longrightarrow> P A"
  2423     and empty: "P {}"
  2424     and compl: "\<And>A. A \<in> sigma_sets \<Omega> G \<Longrightarrow> P A \<Longrightarrow> P (\<Omega> - A)"
  2425     and union: "\<And>A. disjoint_family A \<Longrightarrow> range A \<subseteq> sigma_sets \<Omega> G \<Longrightarrow> (\<And>i. P (A i)) \<Longrightarrow> P (\<Union>i::nat. A i)"
  2426   shows "P A"
  2427 proof -
  2428   let ?D = "{ A \<in> sigma_sets \<Omega> G. P A }"
  2429   interpret sigma_algebra \<Omega> "sigma_sets \<Omega> G"
  2430     using closed by (rule sigma_algebra_sigma_sets)
  2431   from compl[OF _ empty] closed have space: "P \<Omega>" by simp
  2432   interpret dynkin_system \<Omega> ?D
  2433     by default (auto dest: sets_into_space intro!: space compl union)
  2434   have "sigma_sets \<Omega> G = ?D"
  2435     by (rule dynkin_lemma) (auto simp: basic `Int_stable G`)
  2436   with A show ?thesis by auto
  2437 qed
  2438 
  2439 end