src/Pure/type_infer.ML
author wenzelm
Mon Apr 23 20:44:10 2007 +0200 (2007-04-23)
changeset 22771 ce1fe6ca7dbb
parent 22698 7e6412e8d64b
child 24275 bbc3dab6d4fe
permissions -rw-r--r--
added paramify_vars;
infer: replace params uniformly (notably freeze);
     1 (*  Title:      Pure/type_infer.ML
     2     ID:         $Id$
     3     Author:     Stefan Berghofer and Markus Wenzel, TU Muenchen
     4 
     5 Simple type inference.
     6 *)
     7 
     8 signature TYPE_INFER =
     9 sig
    10   val anyT: sort -> typ
    11   val logicT: typ
    12   val polymorphicT: typ -> typ
    13   val constrain: term -> typ -> term
    14   val param: int -> string * sort -> typ
    15   val paramify_vars: typ -> typ
    16   val paramify_dummies: typ -> int -> typ * int
    17   val appl_error: Pretty.pp -> string -> term -> typ -> term -> typ -> string list
    18   val infer_types: Pretty.pp -> Type.tsig ->
    19     (string -> typ option) -> (indexname -> typ option) ->
    20     Name.context -> bool -> (term * typ) list -> (term * typ) list * (indexname * typ) list
    21 end;
    22 
    23 structure TypeInfer: TYPE_INFER =
    24 struct
    25 
    26 
    27 (** type parameters and constraints **)
    28 
    29 fun anyT S = TFree ("'_dummy_", S);
    30 val logicT = anyT [];
    31 
    32 (*indicate polymorphic Vars*)
    33 fun polymorphicT T = Type ("_polymorphic_", [T]);
    34 
    35 fun constrain t T =
    36   if T = dummyT then t
    37   else Const ("_type_constraint_", T --> T) $ t;
    38 
    39 
    40 (* user parameters *)
    41 
    42 fun is_param_default (x, _) = size x > 0 andalso ord x = ord "?";
    43 fun param i (x, S) = TVar (("?" ^ x, i), S);
    44 
    45 val paramify_vars = Term.map_atyps (fn TVar ((x, i), S) => param i (x, S) | T => T);
    46 
    47 val paramify_dummies =
    48   let
    49     fun dummy S maxidx = (param (maxidx + 1) ("'dummy", S), maxidx + 1);
    50 
    51     fun paramify (TFree ("'_dummy_", S)) maxidx = dummy S maxidx
    52       | paramify (Type ("dummy", _)) maxidx = dummy [] maxidx
    53       | paramify (Type (a, Ts)) maxidx =
    54           let val (Ts', maxidx') = fold_map paramify Ts maxidx
    55           in (Type (a, Ts'), maxidx') end
    56       | paramify T maxidx = (T, maxidx);
    57   in paramify end;
    58 
    59 
    60 
    61 (** pretyps and preterms **)
    62 
    63 (*links to parameters may get instantiated, anything else is rigid*)
    64 datatype pretyp =
    65   PType of string * pretyp list |
    66   PTFree of string * sort |
    67   PTVar of indexname * sort |
    68   Param of sort |
    69   Link of pretyp ref;
    70 
    71 datatype preterm =
    72   PConst of string * pretyp |
    73   PFree of string * pretyp |
    74   PVar of indexname * pretyp |
    75   PBound of int |
    76   PAbs of string * pretyp * preterm |
    77   PAppl of preterm * preterm |
    78   Constraint of preterm * pretyp;
    79 
    80 
    81 (* utils *)
    82 
    83 val mk_param = Link o ref o Param;
    84 
    85 fun deref (T as Link (ref (Param _))) = T
    86   | deref (Link (ref T)) = deref T
    87   | deref T = T;
    88 
    89 fun fold_pretyps f (PConst (_, T)) x = f T x
    90   | fold_pretyps f (PFree (_, T)) x = f T x
    91   | fold_pretyps f (PVar (_, T)) x = f T x
    92   | fold_pretyps _ (PBound _) x = x
    93   | fold_pretyps f (PAbs (_, T, t)) x = fold_pretyps f t (f T x)
    94   | fold_pretyps f (PAppl (t, u)) x = fold_pretyps f u (fold_pretyps f t x)
    95   | fold_pretyps f (Constraint (t, T)) x = f T (fold_pretyps f t x);
    96 
    97 
    98 
    99 (** raw typs/terms to pretyps/preterms **)
   100 
   101 (* pretyp_of *)
   102 
   103 fun pretyp_of is_param typ params =
   104   let
   105     val params' = fold_atyps
   106       (fn TVar (xi as (x, _), S) =>
   107           (fn ps =>
   108             if is_param xi andalso not (Vartab.defined ps xi)
   109             then Vartab.update (xi, mk_param S) ps else ps)
   110         | _ => I) typ params;
   111 
   112     fun pre_of (TVar (v as (xi, _))) =
   113           (case Vartab.lookup params' xi of
   114             NONE => PTVar v
   115           | SOME p => p)
   116       | pre_of (TFree ("'_dummy_", S)) = mk_param S
   117       | pre_of (TFree v) = PTFree v
   118       | pre_of (T as Type (a, Ts)) =
   119           if T = dummyT then mk_param []
   120           else PType (a, map pre_of Ts);
   121   in (pre_of typ, params') end;
   122 
   123 
   124 (* preterm_of *)
   125 
   126 fun preterm_of const_type is_param tm (vparams, params) =
   127   let
   128     fun add_vparm xi ps =
   129       if not (Vartab.defined ps xi) then
   130         Vartab.update (xi, mk_param []) ps
   131       else ps;
   132 
   133     val vparams' = fold_aterms
   134       (fn Var (_, Type ("_polymorphic_", _)) => I
   135         | Var (xi, _) => add_vparm xi
   136         | Free (x, _) => add_vparm (x, ~1)
   137         | _ => I)
   138       tm vparams;
   139     fun var_param xi = the (Vartab.lookup vparams' xi);
   140 
   141     val preT_of = pretyp_of is_param;
   142     fun polyT_of T = fst (pretyp_of (K true) T Vartab.empty);
   143 
   144     fun constraint T t ps =
   145       if T = dummyT then (t, ps)
   146       else
   147         let val (T', ps') = preT_of T ps
   148         in (Constraint (t, T'), ps') end;
   149 
   150     fun pre_of (Const (c, T)) ps =
   151           (case const_type c of
   152             SOME U => constraint T (PConst (c, polyT_of U)) ps
   153           | NONE => raise TYPE ("No such constant: " ^ quote c, [], []))
   154       | pre_of (Var (xi, Type ("_polymorphic_", [T]))) ps = (PVar (xi, polyT_of T), ps)
   155       | pre_of (Var (xi, T)) ps = constraint T (PVar (xi, var_param xi)) ps
   156       | pre_of (Free (x, T)) ps = constraint T (PFree (x, var_param (x, ~1))) ps
   157       | pre_of (Const ("_type_constraint_", Type ("fun", [T, _])) $ t) ps =
   158           pre_of t ps |-> constraint T
   159       | pre_of (Bound i) ps = (PBound i, ps)
   160       | pre_of (Abs (x, T, t)) ps =
   161           let
   162             val (T', ps') = preT_of T ps;
   163             val (t', ps'') = pre_of t ps';
   164           in (PAbs (x, T', t'), ps'') end
   165       | pre_of (t $ u) ps =
   166           let
   167             val (t', ps') = pre_of t ps;
   168             val (u', ps'') = pre_of u ps';
   169           in (PAppl (t', u'), ps'') end;
   170 
   171     val (tm', params') = pre_of tm params;
   172   in (tm', (vparams', params')) end;
   173 
   174 
   175 
   176 (** pretyps/terms to typs/terms **)
   177 
   178 (* add_parms *)
   179 
   180 fun add_parmsT (PType (_, Ts)) rs = fold add_parmsT Ts rs
   181   | add_parmsT (Link (r as ref (Param _))) rs = insert (op =) r rs
   182   | add_parmsT (Link (ref T)) rs = add_parmsT T rs
   183   | add_parmsT _ rs = rs;
   184 
   185 val add_parms = fold_pretyps add_parmsT;
   186 
   187 
   188 (* add_names *)
   189 
   190 fun add_namesT (PType (_, Ts)) = fold add_namesT Ts
   191   | add_namesT (PTFree (x, _)) = Name.declare x
   192   | add_namesT (PTVar ((x, _), _)) = Name.declare x
   193   | add_namesT (Link (ref T)) = add_namesT T
   194   | add_namesT (Param _) = I;
   195 
   196 val add_names = fold_pretyps add_namesT;
   197 
   198 
   199 (* simple_typ/term_of *)
   200 
   201 (*deref links, fail on params*)
   202 fun simple_typ_of (PType (a, Ts)) = Type (a, map simple_typ_of Ts)
   203   | simple_typ_of (PTFree v) = TFree v
   204   | simple_typ_of (PTVar v) = TVar v
   205   | simple_typ_of (Link (ref T)) = simple_typ_of T
   206   | simple_typ_of (Param _) = sys_error "simple_typ_of: illegal Param";
   207 
   208 (*convert types, drop constraints*)
   209 fun simple_term_of (PConst (c, T)) = Const (c, simple_typ_of T)
   210   | simple_term_of (PFree (x, T)) = Free (x, simple_typ_of T)
   211   | simple_term_of (PVar (xi, T)) = Var (xi, simple_typ_of T)
   212   | simple_term_of (PBound i) = Bound i
   213   | simple_term_of (PAbs (x, T, t)) = Abs (x, simple_typ_of T, simple_term_of t)
   214   | simple_term_of (PAppl (t, u)) = simple_term_of t $ simple_term_of u
   215   | simple_term_of (Constraint (t, _)) = simple_term_of t;
   216 
   217 
   218 (* typs_terms_of *)                             (*DESTRUCTIVE*)
   219 
   220 fun typs_terms_of used mk_var prfx (Ts, ts) =
   221   let
   222     fun elim (r as ref (Param S), x) = r := mk_var (x, S)
   223       | elim _ = ();
   224 
   225     val used' = fold add_names ts (fold add_namesT Ts used);
   226     val parms = rev (fold add_parms ts (fold add_parmsT Ts []));
   227     val names = Name.invents used' (prfx ^ "'a") (length parms);
   228   in
   229     ListPair.app elim (parms, names);
   230     (map simple_typ_of Ts, map simple_term_of ts)
   231   end;
   232 
   233 
   234 
   235 (** order-sorted unification of types **)       (*DESTRUCTIVE*)
   236 
   237 exception NO_UNIFIER of string;
   238 
   239 fun unify pp tsig =
   240   let
   241 
   242     (* adjust sorts of parameters *)
   243 
   244     fun not_of_sort x S' S =
   245       "Variable " ^ x ^ "::" ^ Pretty.string_of_sort pp S' ^ " not of sort " ^
   246         Pretty.string_of_sort pp S;
   247 
   248     fun meet (_, []) = ()
   249       | meet (Link (r as (ref (Param S'))), S) =
   250           if Type.subsort tsig (S', S) then ()
   251           else r := mk_param (Type.inter_sort tsig (S', S))
   252       | meet (Link (ref T), S) = meet (T, S)
   253       | meet (PType (a, Ts), S) =
   254           ListPair.app meet (Ts, Type.arity_sorts pp tsig a S
   255             handle ERROR msg => raise NO_UNIFIER msg)
   256       | meet (PTFree (x, S'), S) =
   257           if Type.subsort tsig (S', S) then ()
   258           else raise NO_UNIFIER (not_of_sort x S' S)
   259       | meet (PTVar (xi, S'), S) =
   260           if Type.subsort tsig (S', S) then ()
   261           else raise NO_UNIFIER (not_of_sort (Term.string_of_vname xi) S' S)
   262       | meet (Param _, _) = sys_error "meet";
   263 
   264 
   265     (* occurs check and assigment *)
   266 
   267     fun occurs_check r (Link (r' as ref T)) =
   268           if r = r' then raise NO_UNIFIER "Occurs check!"
   269           else occurs_check r T
   270       | occurs_check r (PType (_, Ts)) = List.app (occurs_check r) Ts
   271       | occurs_check _ _ = ();
   272 
   273     fun assign r T S =
   274       (case deref T of
   275         T' as Link (r' as ref (Param _)) =>
   276           if r = r' then () else (meet (T', S); r := T')
   277       | T' => (occurs_check r T'; meet (T', S); r := T'));
   278 
   279 
   280     (* unification *)
   281 
   282     fun unif (Link (r as ref (Param S)), T) = assign r T S
   283       | unif (T, Link (r as ref (Param S))) = assign r T S
   284       | unif (Link (ref T), U) = unif (T, U)
   285       | unif (T, Link (ref U)) = unif (T, U)
   286       | unif (PType (a, Ts), PType (b, Us)) =
   287           if a <> b then
   288             raise NO_UNIFIER ("Clash of types " ^ quote a ^ " and " ^ quote b)
   289           else ListPair.app unif (Ts, Us)
   290       | unif (T, U) = if T = U then () else raise NO_UNIFIER "";
   291 
   292   in unif end;
   293 
   294 
   295 
   296 (** type inference **)
   297 
   298 (* appl_error *)
   299 
   300 fun appl_error pp why t T u U =
   301  ["Type error in application: " ^ why,
   302   "",
   303   Pretty.string_of (Pretty.block
   304     [Pretty.str "Operator:", Pretty.brk 2, Pretty.term pp t,
   305       Pretty.str " ::", Pretty.brk 1, Pretty.typ pp T]),
   306   Pretty.string_of (Pretty.block
   307     [Pretty.str "Operand:", Pretty.brk 3, Pretty.term pp u,
   308       Pretty.str " ::", Pretty.brk 1, Pretty.typ pp U]),
   309   ""];
   310 
   311 
   312 (* infer *)                                     (*DESTRUCTIVE*)
   313 
   314 fun infer pp tsig =
   315   let
   316     (* errors *)
   317 
   318     fun unif_failed msg =
   319       "Type unification failed" ^ (if msg = "" then "" else ": " ^ msg) ^ "\n";
   320 
   321     fun prep_output bs ts Ts =
   322       let
   323         val (Ts_bTs', ts') = typs_terms_of Name.context PTFree "??" (Ts @ map snd bs, ts);
   324         val (Ts', Ts'') = chop (length Ts) Ts_bTs';
   325         val xs = map Free (map fst bs ~~ Ts'');
   326         val ts'' = map (fn t => subst_bounds (xs, t)) ts';
   327       in (ts'', Ts') end;
   328 
   329     fun err_loose i =
   330       raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], []);
   331 
   332     fun err_appl msg bs t T u U =
   333       let
   334         val ([t', u'], [T', U']) = prep_output bs [t, u] [T, U];
   335         val why =
   336           (case T' of
   337             Type ("fun", _) => "Incompatible operand type"
   338           | _ => "Operator not of function type");
   339         val text = unif_failed msg ^ cat_lines (appl_error pp why t' T' u' U');
   340       in raise TYPE (text, [T', U'], [t', u']) end;
   341 
   342     fun err_constraint msg bs t T U =
   343       let
   344         val ([t'], [T', U']) = prep_output bs [t] [T, U];
   345         val text = cat_lines
   346          [unif_failed msg,
   347           "Cannot meet type constraint:", "",
   348           Pretty.string_of (Pretty.block
   349            [Pretty.str "Term:", Pretty.brk 2, Pretty.term pp t',
   350             Pretty.str " ::", Pretty.brk 1, Pretty.typ pp T']),
   351           Pretty.string_of (Pretty.block
   352            [Pretty.str "Type:", Pretty.brk 2, Pretty.typ pp U']), ""];
   353       in raise TYPE (text, [T', U'], [t']) end;
   354 
   355 
   356     (* main *)
   357 
   358     val unif = unify pp tsig;
   359 
   360     fun inf _ (PConst (_, T)) = T
   361       | inf _ (PFree (_, T)) = T
   362       | inf _ (PVar (_, T)) = T
   363       | inf bs (PBound i) = snd (List.nth (bs, i) handle Subscript => err_loose i)
   364       | inf bs (PAbs (x, T, t)) = PType ("fun", [T, inf ((x, T) :: bs) t])
   365       | inf bs (PAppl (t, u)) =
   366           let
   367             val T = inf bs t;
   368             val U = inf bs u;
   369             val V = mk_param [];
   370             val U_to_V = PType ("fun", [U, V]);
   371             val _ = unif (U_to_V, T) handle NO_UNIFIER msg => err_appl msg bs t T u U;
   372           in V end
   373       | inf bs (Constraint (t, U)) =
   374           let val T = inf bs t in
   375             unif (T, U) handle NO_UNIFIER msg => err_constraint msg bs t T U;
   376             T
   377           end;
   378 
   379   in inf [] end;
   380 
   381 
   382 (* infer_types *)
   383 
   384 fun infer_types pp tsig const_type var_type used freeze args =
   385   let
   386     (*certify types*)
   387     val certT = Type.cert_typ tsig;
   388     val (raw_ts, raw_Ts) = split_list args;
   389     val ts = map (Term.map_types certT) raw_ts;
   390     val Ts = map certT raw_Ts;
   391 
   392     (*constrain vars*)
   393     val get_type = the_default dummyT o var_type;
   394     val constrain_vars = Term.map_aterms
   395       (fn Free (x, T) => constrain (Free (x, get_type (x, ~1))) T
   396         | Var (xi, T) => constrain (Var (xi, get_type xi)) T
   397         | t => t);
   398 
   399     (*convert to preterms/typs*)
   400     val (Ts', Tps) = fold_map (pretyp_of (K true)) Ts Vartab.empty;
   401     val (ts', (vps, ps)) =
   402       fold_map (preterm_of const_type is_param_default o constrain_vars) ts (Vartab.empty, Tps);
   403 
   404     (*run type inference*)
   405     val tTs' = ListPair.map Constraint (ts', Ts');
   406     val _ = List.app (fn t => (infer pp tsig t; ())) tTs';
   407 
   408     (*convert back to terms/typs*)
   409     val mk_var =
   410       if freeze then PTFree
   411       else (fn (x, S) => PTVar ((x, 0), S));
   412     val (final_Ts, final_ts) = typs_terms_of used mk_var "" (Ts', ts');
   413 
   414     (*collect result unifier*)
   415     val redundant = fn (xi, TVar (yi, _)) => xi = yi | _ => false;
   416     val env = filter_out redundant (map (apsnd simple_typ_of) (Vartab.dest Tps));
   417 
   418   in (final_ts ~~ final_Ts, env) end;
   419 
   420 end;