src/Pure/pattern.ML
author wenzelm
Wed Nov 28 00:46:26 2001 +0100 (2001-11-28)
changeset 12311 ce5f9e61c037
parent 12232 ff75ed08b3fb
child 12527 d6c91bc3e49c
permissions -rw-r--r--
theory data: removed obsolete finish method;
     1 (*  Title: 	pattern
     2     ID:         $Id$
     3     Author: 	Tobias Nipkow and Christine Heinzelmann, TU Muenchen
     4     Copyright   1993  TU Muenchen
     5 
     6 Unification of Higher-Order Patterns.
     7 
     8 See also:
     9 Tobias Nipkow. Functional Unification of Higher-Order Patterns.
    10 In Proceedings of the 8th IEEE Symposium Logic in Computer Science, 1993.
    11 
    12 TODO: optimize red by special-casing it
    13 *)
    14 
    15 infix aeconv;
    16 
    17 signature PATTERN =
    18   sig
    19   type type_sig
    20   type sg
    21   type env
    22   val aeconv            : term * term -> bool
    23   val eta_contract      : term -> term
    24   val eta_contract_atom : term -> term
    25   val match             : type_sig -> term * term
    26                           -> (indexname*typ)list * (indexname*term)list
    27   val first_order_match : type_sig -> term * term
    28                           -> (indexname*typ)list * (indexname*term)list
    29   val matches           : type_sig -> term * term -> bool
    30   val matches_subterm   : type_sig -> term * term -> bool
    31   val unify             : sg * env * (term * term)list -> env
    32   val first_order       : term -> bool
    33   val pattern           : term -> bool
    34   exception Unif
    35   exception MATCH
    36   exception Pattern
    37   end;
    38 
    39 structure Pattern : PATTERN =
    40 struct
    41 
    42 type type_sig = Type.type_sig
    43 type sg = Sign.sg
    44 type env = Envir.env
    45 
    46 exception Unif;
    47 exception Pattern;
    48 
    49 fun occurs(F,t,env) = 
    50     let fun occ(Var(G,_))   = (case Envir.lookup(env,G) of
    51                                  Some(t) => occ t
    52                                | None    => F=G)
    53           | occ(t1$t2)      = occ t1 orelse occ t2
    54           | occ(Abs(_,_,t)) = occ t
    55           | occ _           = false
    56     in occ t end;
    57 
    58 
    59 fun mapbnd f =
    60     let fun mpb d (Bound(i))     = if i < d then Bound(i) else Bound(f(i-d)+d)
    61           | mpb d (Abs(s,T,t))   = Abs(s,T,mpb(d+1) t)
    62           | mpb d ((u1 $ u2))    = (mpb d u1)$(mpb d u2)
    63           | mpb _ atom           = atom
    64     in mpb 0 end;
    65 
    66 fun idx [] j     = ~10000
    67   | idx(i::is) j = if i=j then length is else idx is j;
    68 
    69 fun at xs i = nth_elem (i,xs);
    70 
    71 fun mkabs (binders,is,t)  =
    72     let fun mk(i::is) = let val (x,T) = nth_elem(i,binders)
    73                         in Abs(x,T,mk is) end 
    74           | mk []     = t
    75     in mk is end;
    76 
    77 val incr = mapbnd (fn i => i+1);
    78 
    79 fun ints_of []             = []
    80   | ints_of (Bound i ::bs) = 
    81       let val is = ints_of bs
    82       in if i mem_int is then raise Pattern else i::is end
    83   | ints_of _              = raise Pattern;
    84 
    85 fun ints_of' env ts = ints_of (map (Envir.head_norm env) ts);
    86 
    87 
    88 fun app (s,(i::is)) = app (s$Bound(i),is)
    89   | app (s,[])      = s;
    90 
    91 fun red (Abs(_,_,s)) (i::is) js = red s is (i::js)
    92   | red t            []      [] = t
    93   | red t            is      jn = app (mapbnd (at jn) t,is);
    94 
    95 
    96 (* split_type ([T1,....,Tn]---> T,n,[]) = ([Tn,...,T1],T) *)
    97 fun split_type (T,0,Ts)                    = (Ts,T)
    98   | split_type (Type ("fun",[T1,T2]),n,Ts) = split_type (T2,n-1,T1::Ts)
    99   | split_type _                           = error("split_type");
   100 
   101 fun type_of_G (T,n,is) =
   102   let val (Ts,U) = split_type(T,n,[]) in map(at Ts)is ---> U end;
   103 
   104 fun mkhnf (binders,is,G,js) = mkabs (binders, is, app(G,js));
   105 
   106 fun mknewhnf(env,binders,is,F as (a,_),T,js) =
   107   let val (env',G) = Envir.genvar a (env,type_of_G(T,length is,js))
   108   in Envir.update((F,mkhnf(binders,is,G,js)),env') end;
   109 
   110 
   111 (* mk_proj_list(is) = [ |is| - k | 1 <= k <= |is| and is[k] >= 0 ] *)
   112 fun mk_proj_list is =
   113     let fun mk(i::is,j) = if i >= 0 then j :: mk(is,j-1) else mk(is,j-1)
   114           | mk([],_)    = []
   115     in mk(is,length is - 1) end;
   116 
   117 fun proj(s,env,binders,is) =
   118     let fun trans d i = if i<d then i else (idx is (i-d))+d;
   119         fun pr(s,env,d,binders) = (case Envir.head_norm env s of
   120               Abs(a,T,t) => let val (t',env') = pr(t,env,d+1,((a,T)::binders))
   121                             in (Abs(a,T,t'),env') end
   122             | t => (case strip_comb t of
   123                 (c as Const _,ts) =>
   124                          let val (ts',env') = prs(ts,env,d,binders)
   125                          in (list_comb(c,ts'),env') end
   126                  | (f as Free _,ts) =>
   127                          let val (ts',env') = prs(ts,env,d,binders)
   128                          in (list_comb(f,ts'),env') end
   129                  | (Bound(i),ts) =>
   130                          let val j = trans d i
   131                          in if j < 0 then raise Unif
   132                             else let val (ts',env') = prs(ts,env,d,binders)
   133                                  in (list_comb(Bound j,ts'),env') end
   134                          end
   135                  | (Var(F as (a,_),Fty),ts) =>
   136                       let val js = ints_of' env ts;
   137                           val js' = map (trans d) js;
   138                           val ks = mk_proj_list js';
   139                           val ls = filter (fn i => i >= 0) js'
   140                           val Hty = type_of_G(Fty,length js,ks)
   141                           val (env',H) = Envir.genvar a (env,Hty)
   142                           val env'' =
   143                                 Envir.update((F,mkhnf(binders,js,H,ks)),env')
   144                       in (app(H,ls),env'') end
   145                  | _  => raise Pattern))
   146         and prs(s::ss,env,d,binders) =
   147               let val (s',env1) = pr(s,env,d,binders)
   148                   val (ss',env2) = prs(ss,env1,d,binders)
   149               in (s'::ss',env2) end
   150           | prs([],env,_,_) = ([],env)
   151    in if downto0(is,length binders - 1) then (s,env)
   152       else pr(s,env,0,binders)
   153    end;
   154 
   155 
   156 (* mk_ff_list(is,js) = [ length(is) - k | 1 <= k <= |is| and is[k] = js[k] ] *)
   157 fun mk_ff_list(is,js) = 
   158     let fun mk([],[],_)        = [] 
   159           | mk(i::is,j::js, k) = if i=j then k :: mk(is,js,k-1)
   160                                         else mk(is,js,k-1)
   161           | mk _               = error"mk_ff_list"
   162     in mk(is,js,length is-1) end;
   163 
   164 fun flexflex1(env,binders,F,Fty,is,js) =
   165   if is=js then env
   166   else let val ks = mk_ff_list(is,js)
   167        in mknewhnf(env,binders,is,F,Fty,ks) end;
   168 
   169 fun flexflex2(env,binders,F,Fty,is,G,Gty,js) =
   170   let fun ff(F,Fty,is,G as (a,_),Gty,js) =
   171             if js subset_int is
   172             then let val t= mkabs(binders,is,app(Var(G,Gty),map (idx is) js))
   173                  in Envir.update((F,t),env) end
   174             else let val ks = is inter_int js
   175                      val Hty = type_of_G(Fty,length is,map (idx is) ks)
   176                      val (env',H) = Envir.genvar a (env,Hty)
   177                      fun lam(is) = mkabs(binders,is,app(H,map (idx is) ks));
   178                  in Envir.update((G,lam js), Envir.update((F,lam is),env'))
   179                  end;
   180   in if xless(G,F) then ff(F,Fty,is,G,Gty,js) else ff(G,Gty,js,F,Fty,is) end
   181 
   182 val tsgr = ref(Type.tsig0);
   183 
   184 fun unify_types(T,U, env as Envir.Envir{asol,iTs,maxidx}) =
   185   if T=U then env
   186   else let val (iTs',maxidx') = Type.unify (!tsgr) maxidx iTs (U,T)
   187        in Envir.Envir{asol=asol,maxidx=maxidx',iTs=iTs'} end
   188        handle Type.TUNIFY => raise Unif;
   189 
   190 fun unif binders (env,(s,t)) = case (Envir.head_norm env s, Envir.head_norm env t) of
   191       (Abs(ns,Ts,ts),Abs(nt,Tt,tt)) =>
   192          let val name = if ns = "" then nt else ns
   193          in unif ((name,Ts)::binders) (env,(ts,tt)) end
   194     | (Abs(ns,Ts,ts),t) => unif ((ns,Ts)::binders) (env,(ts,(incr t)$Bound(0)))
   195     | (t,Abs(nt,Tt,tt)) => unif ((nt,Tt)::binders) (env,((incr t)$Bound(0),tt))
   196     | p => cases(binders,env,p)
   197 
   198 and cases(binders,env,(s,t)) = case (strip_comb s,strip_comb t) of
   199        ((Var(F,Fty),ss),(Var(G,Gty),ts)) => 
   200          if F = G then flexflex1(env,binders,F,Fty,ints_of' env ss,ints_of' env ts)
   201                   else flexflex2(env,binders,F,Fty,ints_of' env ss,G,Gty,ints_of' env ts)
   202       | ((Var(F,_),ss),_)             => flexrigid(env,binders,F,ints_of' env ss,t)
   203       | (_,(Var(F,_),ts))             => flexrigid(env,binders,F,ints_of' env ts,s)
   204       | ((Const c,ss),(Const d,ts))   => rigidrigid(env,binders,c,d,ss,ts)
   205       | ((Free(f),ss),(Free(g),ts))   => rigidrigid(env,binders,f,g,ss,ts)
   206       | ((Bound(i),ss),(Bound(j),ts)) => rigidrigidB (env,binders,i,j,ss,ts) 
   207       | ((Abs(_),_),_)                => raise Pattern
   208       | (_,(Abs(_),_))                => raise Pattern
   209       | _                             => raise Unif
   210 
   211 and rigidrigid (env,binders,(a,Ta),(b,Tb),ss,ts) =
   212       if a<>b then raise Unif
   213       else foldl (unif binders) (unify_types(Ta,Tb,env), ss~~ts)
   214 
   215 and rigidrigidB (env,binders,i,j,ss,ts) =
   216      if i <> j then raise Unif else foldl (unif binders) (env ,ss~~ts)
   217 
   218 and flexrigid (env,binders,F,is,t) =
   219       if occurs(F,t,env) then raise Unif
   220       else let val (u,env') = proj(t,env,binders,is)
   221            in Envir.update((F,mkabs(binders,is,u)),env') end;
   222 
   223 fun unify(sg,env,tus) = (tsgr := #tsig(Sign.rep_sg sg);
   224                          foldl (unif []) (env,tus));
   225 
   226 
   227 (*Eta-contract a term (fully)*)
   228 
   229 (* copying: *)
   230 fun eta_contract (Abs(a,T,body)) = 
   231       (case  eta_contract body  of
   232         body' as (f $ Bound 0) => 
   233 	  if loose_bvar1(f,0) then Abs(a,T,body')
   234 	  else incr_boundvars ~1 f 
   235       | body' => Abs(a,T,body'))
   236   | eta_contract(f$t) = eta_contract f $ eta_contract t
   237   | eta_contract t = t;
   238 
   239 (*Eta-contract a term from outside: just enough to reduce it to an atom
   240 DOESN'T QUITE WORK!
   241 *)
   242 fun eta_contract_atom (t0 as Abs(a, T, body)) = 
   243       (case  eta_contract2 body  of
   244         body' as (f $ Bound 0) => 
   245 	    if loose_bvar1(f,0) then Abs(a,T,body')
   246 	    else eta_contract_atom (incr_boundvars ~1 f)
   247       | _ => t0)
   248   | eta_contract_atom t = t
   249 and eta_contract2 (f$t) = f $ eta_contract_atom t
   250   | eta_contract2 t     = eta_contract_atom t;
   251 
   252 
   253 (*Tests whether 2 terms are alpha/eta-convertible and have same type.
   254   Note that Consts and Vars may have more than one type.*)
   255 fun t aeconv u = aconv_aux (eta_contract_atom t, eta_contract_atom u)
   256 and aconv_aux (Const(a,T), Const(b,U)) = a=b  andalso  T=U
   257   | aconv_aux (Free(a,T),  Free(b,U))  = a=b  andalso  T=U
   258   | aconv_aux (Var(v,T),   Var(w,U))   = eq_ix(v,w) andalso  T=U
   259   | aconv_aux (Bound i,	   Bound j)    = i=j
   260   | aconv_aux (Abs(_,T,t), Abs(_,U,u)) = (t aeconv u)  andalso  T=U
   261   | aconv_aux (f$t,	   g$u)        = (f aeconv g)  andalso (t aeconv u)
   262   | aconv_aux _ =  false;
   263 
   264 
   265 (*** Matching ***)
   266 
   267 exception MATCH;
   268 
   269 fun typ_match tsig args = (Type.typ_match tsig args)
   270                           handle Type.TYPE_MATCH => raise MATCH;
   271 
   272 (*First-order matching;
   273   fomatch tsig (pattern, object) returns a (tyvar,typ)list and (var,term)list.
   274   The pattern and object may have variables in common.
   275   Instantiation does not affect the object, so matching ?a with ?a+1 works.
   276   Object is eta-contracted on the fly (by eta-expanding the pattern).
   277   Precondition: the pattern is already eta-contracted!
   278   Note: types are matched on the fly *)
   279 fun fomatch tsig =
   280   let
   281     fun mtch (instsp as (tyinsts,insts)) = fn
   282         (Var(ixn,T), t)  =>
   283 	  if loose_bvar(t,0) then raise MATCH
   284 	  else (case assoc_string_int(insts,ixn) of
   285 		  None => (typ_match tsig (tyinsts, (T, fastype_of t)), 
   286 			   (ixn,t)::insts)
   287 		| Some u => if t aeconv u then instsp else raise MATCH)
   288       | (Free (a,T), Free (b,U)) =>
   289 	  if a=b then (typ_match tsig (tyinsts,(T,U)), insts) else raise MATCH
   290       | (Const (a,T), Const (b,U))  =>
   291 	  if a=b then (typ_match tsig (tyinsts,(T,U)), insts) else raise MATCH
   292       | (Bound i, Bound j)  =>  if  i=j  then  instsp  else raise MATCH
   293       | (Abs(_,T,t), Abs(_,U,u))  =>
   294 	  mtch (typ_match tsig (tyinsts,(T,U)),insts) (t,u)
   295       | (f$t, g$u) => mtch (mtch instsp (f,g)) (t, u)
   296       | (t, Abs(_,U,u))  =>  mtch instsp ((incr t)$(Bound 0), u)
   297       | _ => raise MATCH
   298   in mtch end;
   299 
   300 fun first_order_match tsig = apfst Vartab.dest o fomatch tsig (Vartab.empty, []);
   301 
   302 (* Matching of higher-order patterns *)
   303 
   304 fun match_bind(itms,binders,ixn,is,t) =
   305   let val js = loose_bnos t
   306   in if null is
   307      then if null js then (ixn,t)::itms else raise MATCH
   308      else if js subset_int is
   309           then let val t' = if downto0(is,length binders - 1) then t
   310                             else mapbnd (idx is) t
   311                in (ixn, mkabs(binders,is,t')) :: itms end
   312           else raise MATCH
   313   end;
   314 
   315 fun match tsg (po as (pat,obj)) =
   316 let
   317   (* Pre: pat and obj have same type *)
   318   fun mtch binders (env as (iTs,itms),(pat,obj)) =
   319     case pat of
   320       Abs(ns,Ts,ts) =>
   321         (case obj of
   322            Abs(nt,Tt,tt) => mtch ((nt,Tt)::binders) (env,(ts,tt))
   323          | _ => let val Tt = typ_subst_TVars_Vartab iTs Ts
   324                 in mtch((ns,Tt)::binders)(env,(ts,(incr obj)$Bound(0))) end)
   325     | _ => (case obj of
   326               Abs(nt,Tt,tt) =>
   327                 mtch((nt,Tt)::binders)(env,((incr pat)$Bound(0),tt))
   328             | _ => cases(binders,env,pat,obj))
   329 
   330   and cases(binders,env as (iTs,itms),pat,obj) =
   331     let val (ph,pargs) = strip_comb pat
   332         fun rigrig1(iTs,oargs) =
   333               foldl (mtch binders) ((iTs,itms), pargs~~oargs)
   334         fun rigrig2((a,Ta),(b,Tb),oargs) =
   335               if a<> b then raise MATCH
   336               else rigrig1(typ_match tsg (iTs,(Ta,Tb)), oargs)
   337     in case ph of
   338          Var(ixn,_) =>
   339            let val is = ints_of pargs
   340            in case assoc_string_int(itms,ixn) of
   341                 None => (iTs,match_bind(itms,binders,ixn,is,obj))
   342               | Some u => if obj aeconv (red u is []) then env
   343                           else raise MATCH
   344            end
   345        | _ =>
   346            let val (oh,oargs) = strip_comb obj
   347            in case (ph,oh) of
   348                 (Const c,Const d) => rigrig2(c,d,oargs)
   349               | (Free f,Free g)   => rigrig2(f,g,oargs)
   350               | (Bound i,Bound j) => if i<>j then raise MATCH
   351                                      else rigrig1(iTs,oargs)
   352               | (Abs _, _)        => raise Pattern
   353               | (_, Abs _)        => raise Pattern
   354               | _                 => raise MATCH
   355            end
   356     end;
   357 
   358   val pT = fastype_of pat
   359   and oT = fastype_of obj
   360   val iTs = typ_match tsg (Vartab.empty, (pT,oT))
   361   val insts2 = (iTs,[])
   362 
   363 in apfst Vartab.dest (mtch [] (insts2, po)
   364    handle Pattern => fomatch tsg insts2 po)
   365 end;
   366 
   367 (*Predicate: does the pattern match the object?*)
   368 fun matches tsig po = (match tsig po; true) handle MATCH => false;
   369 
   370 (* Does pat match a subterm of obj? *)
   371 fun matches_subterm tsig (pat,obj) =
   372   let fun msub(bounds,obj) = matches tsig (pat,obj) orelse
   373             case obj of
   374               Abs(x,T,t) => let val y = variant bounds x
   375                                 val f = Free(":" ^ y,T)
   376                             in msub(x::bounds,subst_bound(f,t)) end
   377             | s$t => msub(bounds,s) orelse msub(bounds,t)
   378             | _ => false
   379   in msub([],obj) end;
   380 
   381 fun first_order(Abs(_,_,t)) = first_order t
   382   | first_order(t $ u) = first_order t andalso first_order u andalso
   383                          not(is_Var t)
   384   | first_order _ = true;
   385 
   386 fun pattern(Abs(_,_,t)) = pattern t
   387   | pattern(t) = let val (head,args) = strip_comb t
   388                  in if is_Var head
   389                     then let val _ = ints_of args in true end
   390                          handle Pattern => false
   391                     else forall pattern args
   392                  end;
   393 
   394 end;