src/HOL/Algebra/FiniteProduct.thy
author wenzelm
Thu Feb 15 12:11:00 2018 +0100 (16 months ago)
changeset 67613 ce654b0e6d69
parent 67341 df79ef3b3a41
child 68445 c183a6a69f2d
permissions -rw-r--r--
more symbols;
     1 (*  Title:      HOL/Algebra/FiniteProduct.thy
     2     Author:     Clemens Ballarin, started 19 November 2002
     3 
     4 This file is largely based on HOL/Finite_Set.thy.
     5 *)
     6 
     7 theory FiniteProduct
     8 imports Group
     9 begin
    10 
    11 subsection \<open>Product Operator for Commutative Monoids\<close>
    12 
    13 subsubsection \<open>Inductive Definition of a Relation for Products over Sets\<close>
    14 
    15 text \<open>Instantiation of locale \<open>LC\<close> of theory \<open>Finite_Set\<close> is not
    16   possible, because here we have explicit typing rules like 
    17   \<open>x \<in> carrier G\<close>.  We introduce an explicit argument for the domain
    18   \<open>D\<close>.\<close>
    19 
    20 inductive_set
    21   foldSetD :: "['a set, 'b => 'a => 'a, 'a] => ('b set * 'a) set"
    22   for D :: "'a set" and f :: "'b => 'a => 'a" and e :: 'a
    23   where
    24     emptyI [intro]: "e \<in> D ==> ({}, e) \<in> foldSetD D f e"
    25   | insertI [intro]: "[| x \<notin> A; f x y \<in> D; (A, y) \<in> foldSetD D f e |] ==>
    26                       (insert x A, f x y) \<in> foldSetD D f e"
    27 
    28 inductive_cases empty_foldSetDE [elim!]: "({}, x) \<in> foldSetD D f e"
    29 
    30 definition
    31   foldD :: "['a set, 'b => 'a => 'a, 'a, 'b set] => 'a"
    32   where "foldD D f e A = (THE x. (A, x) \<in> foldSetD D f e)"
    33 
    34 lemma foldSetD_closed:
    35   "[| (A, z) \<in> foldSetD D f e ; e \<in> D; !!x y. [| x \<in> A; y \<in> D |] ==> f x y \<in> D 
    36       |] ==> z \<in> D"
    37   by (erule foldSetD.cases) auto
    38 
    39 lemma Diff1_foldSetD:
    40   "[| (A - {x}, y) \<in> foldSetD D f e; x \<in> A; f x y \<in> D |] ==>
    41    (A, f x y) \<in> foldSetD D f e"
    42   apply (erule insert_Diff [THEN subst], rule foldSetD.intros)
    43     apply auto
    44   done
    45 
    46 lemma foldSetD_imp_finite [simp]: "(A, x) \<in> foldSetD D f e ==> finite A"
    47   by (induct set: foldSetD) auto
    48 
    49 lemma finite_imp_foldSetD:
    50   "[| finite A; e \<in> D; !!x y. [| x \<in> A; y \<in> D |] ==> f x y \<in> D |] ==>
    51    \<exists>x. (A, x) \<in> foldSetD D f e"
    52 proof (induct set: finite)
    53   case empty then show ?case by auto
    54 next
    55   case (insert x F)
    56   then obtain y where y: "(F, y) \<in> foldSetD D f e" by auto
    57   with insert have "y \<in> D" by (auto dest: foldSetD_closed)
    58   with y and insert have "(insert x F, f x y) \<in> foldSetD D f e"
    59     by (intro foldSetD.intros) auto
    60   then show ?case ..
    61 qed
    62 
    63 
    64 text \<open>Left-Commutative Operations\<close>
    65 
    66 locale LCD =
    67   fixes B :: "'b set"
    68   and D :: "'a set"
    69   and f :: "'b => 'a => 'a"    (infixl "\<cdot>" 70)
    70   assumes left_commute:
    71     "[| x \<in> B; y \<in> B; z \<in> D |] ==> x \<cdot> (y \<cdot> z) = y \<cdot> (x \<cdot> z)"
    72   and f_closed [simp, intro!]: "!!x y. [| x \<in> B; y \<in> D |] ==> f x y \<in> D"
    73 
    74 lemma (in LCD) foldSetD_closed [dest]:
    75   "(A, z) \<in> foldSetD D f e ==> z \<in> D"
    76   by (erule foldSetD.cases) auto
    77 
    78 lemma (in LCD) Diff1_foldSetD:
    79   "[| (A - {x}, y) \<in> foldSetD D f e; x \<in> A; A \<subseteq> B |] ==>
    80   (A, f x y) \<in> foldSetD D f e"
    81   apply (subgoal_tac "x \<in> B")
    82    prefer 2 apply fast
    83   apply (erule insert_Diff [THEN subst], rule foldSetD.intros)
    84     apply auto
    85   done
    86 
    87 lemma (in LCD) foldSetD_imp_finite [simp]:
    88   "(A, x) \<in> foldSetD D f e ==> finite A"
    89   by (induct set: foldSetD) auto
    90 
    91 lemma (in LCD) finite_imp_foldSetD:
    92   "[| finite A; A \<subseteq> B; e \<in> D |] ==> \<exists>x. (A, x) \<in> foldSetD D f e"
    93 proof (induct set: finite)
    94   case empty then show ?case by auto
    95 next
    96   case (insert x F)
    97   then obtain y where y: "(F, y) \<in> foldSetD D f e" by auto
    98   with insert have "y \<in> D" by auto
    99   with y and insert have "(insert x F, f x y) \<in> foldSetD D f e"
   100     by (intro foldSetD.intros) auto
   101   then show ?case ..
   102 qed
   103 
   104 lemma (in LCD) foldSetD_determ_aux:
   105   "e \<in> D \<Longrightarrow> \<forall>A x. A \<subseteq> B \<and> card A < n \<longrightarrow> (A, x) \<in> foldSetD D f e \<longrightarrow>
   106     (\<forall>y. (A, y) \<in> foldSetD D f e \<longrightarrow> y = x)"
   107   apply (induct n)
   108    apply (auto simp add: less_Suc_eq) (* slow *)
   109   apply (erule foldSetD.cases)
   110    apply blast
   111   apply (erule foldSetD.cases)
   112    apply blast
   113   apply clarify
   114   txt \<open>force simplification of \<open>card A < card (insert ...)\<close>.\<close>
   115   apply (erule rev_mp)
   116   apply (simp add: less_Suc_eq_le)
   117   apply (rule impI)
   118   apply (rename_tac xa Aa ya xb Ab yb, case_tac "xa = xb")
   119    apply (subgoal_tac "Aa = Ab")
   120     prefer 2 apply (blast elim!: equalityE)
   121    apply blast
   122   txt \<open>case @{prop "xa \<notin> xb"}.\<close>
   123   apply (subgoal_tac "Aa - {xb} = Ab - {xa} \<and> xb \<in> Aa \<and> xa \<in> Ab")
   124    prefer 2 apply (blast elim!: equalityE)
   125   apply clarify
   126   apply (subgoal_tac "Aa = insert xb Ab - {xa}")
   127    prefer 2 apply blast
   128   apply (subgoal_tac "card Aa \<le> card Ab")
   129    prefer 2
   130    apply (rule Suc_le_mono [THEN subst])
   131    apply (simp add: card_Suc_Diff1)
   132   apply (rule_tac A1 = "Aa - {xb}" in finite_imp_foldSetD [THEN exE])
   133      apply (blast intro: foldSetD_imp_finite)
   134     apply best
   135    apply assumption
   136   apply (frule (1) Diff1_foldSetD)
   137    apply best
   138   apply (subgoal_tac "ya = f xb x")
   139    prefer 2
   140    apply (subgoal_tac "Aa \<subseteq> B")
   141     prefer 2 apply best (* slow *)
   142    apply (blast del: equalityCE)
   143   apply (subgoal_tac "(Ab - {xa}, x) \<in> foldSetD D f e")
   144    prefer 2 apply simp
   145   apply (subgoal_tac "yb = f xa x")
   146    prefer 2 
   147    apply (blast del: equalityCE dest: Diff1_foldSetD)
   148   apply (simp (no_asm_simp))
   149   apply (rule left_commute)
   150     apply assumption
   151    apply best (* slow *)
   152   apply best
   153   done
   154 
   155 lemma (in LCD) foldSetD_determ:
   156   "[| (A, x) \<in> foldSetD D f e; (A, y) \<in> foldSetD D f e; e \<in> D; A \<subseteq> B |]
   157   ==> y = x"
   158   by (blast intro: foldSetD_determ_aux [rule_format])
   159 
   160 lemma (in LCD) foldD_equality:
   161   "[| (A, y) \<in> foldSetD D f e; e \<in> D; A \<subseteq> B |] ==> foldD D f e A = y"
   162   by (unfold foldD_def) (blast intro: foldSetD_determ)
   163 
   164 lemma foldD_empty [simp]:
   165   "e \<in> D ==> foldD D f e {} = e"
   166   by (unfold foldD_def) blast
   167 
   168 lemma (in LCD) foldD_insert_aux:
   169   "[| x \<notin> A; x \<in> B; e \<in> D; A \<subseteq> B |] ==>
   170     ((insert x A, v) \<in> foldSetD D f e) =
   171     (\<exists>y. (A, y) \<in> foldSetD D f e \<and> v = f x y)"
   172   apply auto
   173   apply (rule_tac A1 = A in finite_imp_foldSetD [THEN exE])
   174      apply (fastforce dest: foldSetD_imp_finite)
   175     apply assumption
   176    apply assumption
   177   apply (blast intro: foldSetD_determ)
   178   done
   179 
   180 lemma (in LCD) foldD_insert:
   181     "[| finite A; x \<notin> A; x \<in> B; e \<in> D; A \<subseteq> B |] ==>
   182      foldD D f e (insert x A) = f x (foldD D f e A)"
   183   apply (unfold foldD_def)
   184   apply (simp add: foldD_insert_aux)
   185   apply (rule the_equality)
   186    apply (auto intro: finite_imp_foldSetD
   187      cong add: conj_cong simp add: foldD_def [symmetric] foldD_equality)
   188   done
   189 
   190 lemma (in LCD) foldD_closed [simp]:
   191   "[| finite A; e \<in> D; A \<subseteq> B |] ==> foldD D f e A \<in> D"
   192 proof (induct set: finite)
   193   case empty then show ?case by simp
   194 next
   195   case insert then show ?case by (simp add: foldD_insert)
   196 qed
   197 
   198 lemma (in LCD) foldD_commute:
   199   "[| finite A; x \<in> B; e \<in> D; A \<subseteq> B |] ==>
   200    f x (foldD D f e A) = foldD D f (f x e) A"
   201   apply (induct set: finite)
   202    apply simp
   203   apply (auto simp add: left_commute foldD_insert)
   204   done
   205 
   206 lemma Int_mono2:
   207   "[| A \<subseteq> C; B \<subseteq> C |] ==> A Int B \<subseteq> C"
   208   by blast
   209 
   210 lemma (in LCD) foldD_nest_Un_Int:
   211   "[| finite A; finite C; e \<in> D; A \<subseteq> B; C \<subseteq> B |] ==>
   212    foldD D f (foldD D f e C) A = foldD D f (foldD D f e (A Int C)) (A Un C)"
   213   apply (induct set: finite)
   214    apply simp
   215   apply (simp add: foldD_insert foldD_commute Int_insert_left insert_absorb
   216     Int_mono2)
   217   done
   218 
   219 lemma (in LCD) foldD_nest_Un_disjoint:
   220   "[| finite A; finite B; A Int B = {}; e \<in> D; A \<subseteq> B; C \<subseteq> B |]
   221     ==> foldD D f e (A Un B) = foldD D f (foldD D f e B) A"
   222   by (simp add: foldD_nest_Un_Int)
   223 
   224 \<comment> \<open>Delete rules to do with \<open>foldSetD\<close> relation.\<close>
   225 
   226 declare foldSetD_imp_finite [simp del]
   227   empty_foldSetDE [rule del]
   228   foldSetD.intros [rule del]
   229 declare (in LCD)
   230   foldSetD_closed [rule del]
   231 
   232 
   233 text \<open>Commutative Monoids\<close>
   234 
   235 text \<open>
   236   We enter a more restrictive context, with \<open>f :: 'a => 'a => 'a\<close>
   237   instead of \<open>'b => 'a => 'a\<close>.
   238 \<close>
   239 
   240 locale ACeD =
   241   fixes D :: "'a set"
   242     and f :: "'a => 'a => 'a"    (infixl "\<cdot>" 70)
   243     and e :: 'a
   244   assumes ident [simp]: "x \<in> D ==> x \<cdot> e = x"
   245     and commute: "[| x \<in> D; y \<in> D |] ==> x \<cdot> y = y \<cdot> x"
   246     and assoc: "[| x \<in> D; y \<in> D; z \<in> D |] ==> (x \<cdot> y) \<cdot> z = x \<cdot> (y \<cdot> z)"
   247     and e_closed [simp]: "e \<in> D"
   248     and f_closed [simp]: "[| x \<in> D; y \<in> D |] ==> x \<cdot> y \<in> D"
   249 
   250 lemma (in ACeD) left_commute:
   251   "[| x \<in> D; y \<in> D; z \<in> D |] ==> x \<cdot> (y \<cdot> z) = y \<cdot> (x \<cdot> z)"
   252 proof -
   253   assume D: "x \<in> D" "y \<in> D" "z \<in> D"
   254   then have "x \<cdot> (y \<cdot> z) = (y \<cdot> z) \<cdot> x" by (simp add: commute)
   255   also from D have "... = y \<cdot> (z \<cdot> x)" by (simp add: assoc)
   256   also from D have "z \<cdot> x = x \<cdot> z" by (simp add: commute)
   257   finally show ?thesis .
   258 qed
   259 
   260 lemmas (in ACeD) AC = assoc commute left_commute
   261 
   262 lemma (in ACeD) left_ident [simp]: "x \<in> D ==> e \<cdot> x = x"
   263 proof -
   264   assume "x \<in> D"
   265   then have "x \<cdot> e = x" by (rule ident)
   266   with \<open>x \<in> D\<close> show ?thesis by (simp add: commute)
   267 qed
   268 
   269 lemma (in ACeD) foldD_Un_Int:
   270   "[| finite A; finite B; A \<subseteq> D; B \<subseteq> D |] ==>
   271     foldD D f e A \<cdot> foldD D f e B =
   272     foldD D f e (A Un B) \<cdot> foldD D f e (A Int B)"
   273   apply (induct set: finite)
   274    apply (simp add: left_commute LCD.foldD_closed [OF LCD.intro [of D]])
   275   apply (simp add: AC insert_absorb Int_insert_left
   276     LCD.foldD_insert [OF LCD.intro [of D]]
   277     LCD.foldD_closed [OF LCD.intro [of D]]
   278     Int_mono2)
   279   done
   280 
   281 lemma (in ACeD) foldD_Un_disjoint:
   282   "[| finite A; finite B; A Int B = {}; A \<subseteq> D; B \<subseteq> D |] ==>
   283     foldD D f e (A Un B) = foldD D f e A \<cdot> foldD D f e B"
   284   by (simp add: foldD_Un_Int
   285     left_commute LCD.foldD_closed [OF LCD.intro [of D]])
   286 
   287 
   288 subsubsection \<open>Products over Finite Sets\<close>
   289 
   290 definition
   291   finprod :: "[('b, 'm) monoid_scheme, 'a => 'b, 'a set] => 'b"
   292   where "finprod G f A =
   293    (if finite A
   294     then foldD (carrier G) (mult G \<circ> f) \<one>\<^bsub>G\<^esub> A
   295     else \<one>\<^bsub>G\<^esub>)"
   296 
   297 syntax
   298   "_finprod" :: "index => idt => 'a set => 'b => 'b"
   299       ("(3\<Otimes>__\<in>_. _)" [1000, 0, 51, 10] 10)
   300 translations
   301   "\<Otimes>\<^bsub>G\<^esub>i\<in>A. b" \<rightleftharpoons> "CONST finprod G (%i. b) A"
   302   \<comment> \<open>Beware of argument permutation!\<close>
   303 
   304 lemma (in comm_monoid) finprod_empty [simp]: 
   305   "finprod G f {} = \<one>"
   306   by (simp add: finprod_def)
   307 
   308 lemma (in comm_monoid) finprod_infinite[simp]:
   309   "\<not> finite A \<Longrightarrow> finprod G f A = \<one>" 
   310   by (simp add: finprod_def)
   311 
   312 declare funcsetI [intro]
   313   funcset_mem [dest]
   314 
   315 context comm_monoid begin
   316 
   317 lemma finprod_insert [simp]:
   318   "[| finite F; a \<notin> F; f \<in> F \<rightarrow> carrier G; f a \<in> carrier G |] ==>
   319    finprod G f (insert a F) = f a \<otimes> finprod G f F"
   320   apply (rule trans)
   321    apply (simp add: finprod_def)
   322   apply (rule trans)
   323    apply (rule LCD.foldD_insert [OF LCD.intro [of "insert a F"]])
   324          apply simp
   325          apply (rule m_lcomm)
   326            apply fast
   327           apply fast
   328          apply assumption
   329         apply fastforce
   330        apply simp+
   331    apply fast
   332   apply (auto simp add: finprod_def)
   333   done
   334 
   335 lemma finprod_one [simp]: "(\<Otimes>i\<in>A. \<one>) = \<one>"
   336 proof (induct A rule: infinite_finite_induct)
   337   case empty show ?case by simp
   338 next
   339   case (insert a A)
   340   have "(%i. \<one>) \<in> A \<rightarrow> carrier G" by auto
   341   with insert show ?case by simp
   342 qed simp
   343 
   344 lemma finprod_closed [simp]:
   345   fixes A
   346   assumes f: "f \<in> A \<rightarrow> carrier G" 
   347   shows "finprod G f A \<in> carrier G"
   348 using f
   349 proof (induct A rule: infinite_finite_induct)
   350   case empty show ?case by simp
   351 next
   352   case (insert a A)
   353   then have a: "f a \<in> carrier G" by fast
   354   from insert have A: "f \<in> A \<rightarrow> carrier G" by fast
   355   from insert A a show ?case by simp
   356 qed simp
   357 
   358 lemma funcset_Int_left [simp, intro]:
   359   "[| f \<in> A \<rightarrow> C; f \<in> B \<rightarrow> C |] ==> f \<in> A Int B \<rightarrow> C"
   360   by fast
   361 
   362 lemma funcset_Un_left [iff]:
   363   "(f \<in> A Un B \<rightarrow> C) = (f \<in> A \<rightarrow> C \<and> f \<in> B \<rightarrow> C)"
   364   by fast
   365 
   366 lemma finprod_Un_Int:
   367   "[| finite A; finite B; g \<in> A \<rightarrow> carrier G; g \<in> B \<rightarrow> carrier G |] ==>
   368      finprod G g (A Un B) \<otimes> finprod G g (A Int B) =
   369      finprod G g A \<otimes> finprod G g B"
   370 \<comment> \<open>The reversed orientation looks more natural, but LOOPS as a simprule!\<close>
   371 proof (induct set: finite)
   372   case empty then show ?case by simp
   373 next
   374   case (insert a A)
   375   then have a: "g a \<in> carrier G" by fast
   376   from insert have A: "g \<in> A \<rightarrow> carrier G" by fast
   377   from insert A a show ?case
   378     by (simp add: m_ac Int_insert_left insert_absorb Int_mono2) 
   379 qed
   380 
   381 lemma finprod_Un_disjoint:
   382   "[| finite A; finite B; A Int B = {};
   383       g \<in> A \<rightarrow> carrier G; g \<in> B \<rightarrow> carrier G |]
   384    ==> finprod G g (A Un B) = finprod G g A \<otimes> finprod G g B"
   385   apply (subst finprod_Un_Int [symmetric])
   386       apply auto
   387   done
   388 
   389 lemma finprod_multf:
   390   "[| f \<in> A \<rightarrow> carrier G; g \<in> A \<rightarrow> carrier G |] ==>
   391    finprod G (%x. f x \<otimes> g x) A = (finprod G f A \<otimes> finprod G g A)"
   392 proof (induct A rule: infinite_finite_induct)
   393   case empty show ?case by simp
   394 next
   395   case (insert a A) then
   396   have fA: "f \<in> A \<rightarrow> carrier G" by fast
   397   from insert have fa: "f a \<in> carrier G" by fast
   398   from insert have gA: "g \<in> A \<rightarrow> carrier G" by fast
   399   from insert have ga: "g a \<in> carrier G" by fast
   400   from insert have fgA: "(%x. f x \<otimes> g x) \<in> A \<rightarrow> carrier G"
   401     by (simp add: Pi_def)
   402   show ?case
   403     by (simp add: insert fA fa gA ga fgA m_ac)
   404 qed simp
   405 
   406 lemma finprod_cong':
   407   "[| A = B; g \<in> B \<rightarrow> carrier G;
   408       !!i. i \<in> B ==> f i = g i |] ==> finprod G f A = finprod G g B"
   409 proof -
   410   assume prems: "A = B" "g \<in> B \<rightarrow> carrier G"
   411     "!!i. i \<in> B ==> f i = g i"
   412   show ?thesis
   413   proof (cases "finite B")
   414     case True
   415     then have "!!A. [| A = B; g \<in> B \<rightarrow> carrier G;
   416       !!i. i \<in> B ==> f i = g i |] ==> finprod G f A = finprod G g B"
   417     proof induct
   418       case empty thus ?case by simp
   419     next
   420       case (insert x B)
   421       then have "finprod G f A = finprod G f (insert x B)" by simp
   422       also from insert have "... = f x \<otimes> finprod G f B"
   423       proof (intro finprod_insert)
   424         show "finite B" by fact
   425       next
   426         show "x \<notin> B" by fact
   427       next
   428         assume "x \<notin> B" "!!i. i \<in> insert x B \<Longrightarrow> f i = g i"
   429           "g \<in> insert x B \<rightarrow> carrier G"
   430         thus "f \<in> B \<rightarrow> carrier G" by fastforce
   431       next
   432         assume "x \<notin> B" "!!i. i \<in> insert x B \<Longrightarrow> f i = g i"
   433           "g \<in> insert x B \<rightarrow> carrier G"
   434         thus "f x \<in> carrier G" by fastforce
   435       qed
   436       also from insert have "... = g x \<otimes> finprod G g B" by fastforce
   437       also from insert have "... = finprod G g (insert x B)"
   438       by (intro finprod_insert [THEN sym]) auto
   439       finally show ?case .
   440     qed
   441     with prems show ?thesis by simp
   442   next
   443     case False with prems show ?thesis by simp
   444   qed
   445 qed
   446 
   447 lemma finprod_cong:
   448   "[| A = B; f \<in> B \<rightarrow> carrier G = True;
   449       !!i. i \<in> B =simp=> f i = g i |] ==> finprod G f A = finprod G g B"
   450   (* This order of prems is slightly faster (3%) than the last two swapped. *)
   451   by (rule finprod_cong') (auto simp add: simp_implies_def)
   452 
   453 text \<open>Usually, if this rule causes a failed congruence proof error,
   454   the reason is that the premise \<open>g \<in> B \<rightarrow> carrier G\<close> cannot be shown.
   455   Adding @{thm [source] Pi_def} to the simpset is often useful.
   456   For this reason, @{thm [source] finprod_cong}
   457   is not added to the simpset by default.
   458 \<close>
   459 
   460 end
   461 
   462 declare funcsetI [rule del]
   463   funcset_mem [rule del]
   464 
   465 context comm_monoid begin
   466 
   467 lemma finprod_0 [simp]:
   468   "f \<in> {0::nat} \<rightarrow> carrier G ==> finprod G f {..0} = f 0"
   469 by (simp add: Pi_def)
   470 
   471 lemma finprod_Suc [simp]:
   472   "f \<in> {..Suc n} \<rightarrow> carrier G ==>
   473    finprod G f {..Suc n} = (f (Suc n) \<otimes> finprod G f {..n})"
   474 by (simp add: Pi_def atMost_Suc)
   475 
   476 lemma finprod_Suc2:
   477   "f \<in> {..Suc n} \<rightarrow> carrier G ==>
   478    finprod G f {..Suc n} = (finprod G (%i. f (Suc i)) {..n} \<otimes> f 0)"
   479 proof (induct n)
   480   case 0 thus ?case by (simp add: Pi_def)
   481 next
   482   case Suc thus ?case by (simp add: m_assoc Pi_def)
   483 qed
   484 
   485 lemma finprod_mult [simp]:
   486   "[| f \<in> {..n} \<rightarrow> carrier G; g \<in> {..n} \<rightarrow> carrier G |] ==>
   487      finprod G (%i. f i \<otimes> g i) {..n::nat} =
   488      finprod G f {..n} \<otimes> finprod G g {..n}"
   489   by (induct n) (simp_all add: m_ac Pi_def)
   490 
   491 (* The following two were contributed by Jeremy Avigad. *)
   492 
   493 lemma finprod_reindex:
   494   "f \<in> (h ` A) \<rightarrow> carrier G \<Longrightarrow> 
   495         inj_on h A \<Longrightarrow> finprod G f (h ` A) = finprod G (\<lambda>x. f (h x)) A"
   496 proof (induct A rule: infinite_finite_induct)
   497   case (infinite A)
   498   hence "\<not> finite (h ` A)"
   499     using finite_imageD by blast
   500   with \<open>\<not> finite A\<close> show ?case by simp
   501 qed (auto simp add: Pi_def)
   502 
   503 lemma finprod_const:
   504   assumes a [simp]: "a \<in> carrier G"
   505     shows "finprod G (\<lambda>x. a) A = a [^] card A"
   506 proof (induct A rule: infinite_finite_induct)
   507   case (insert b A)
   508   show ?case 
   509   proof (subst finprod_insert[OF insert(1-2)])
   510     show "a \<otimes> (\<Otimes>x\<in>A. a) = a [^] card (insert b A)"
   511       by (insert insert, auto, subst m_comm, auto)
   512   qed auto
   513 qed auto
   514 
   515 (* The following lemma was contributed by Jesus Aransay. *)
   516 
   517 lemma finprod_singleton:
   518   assumes i_in_A: "i \<in> A" and fin_A: "finite A" and f_Pi: "f \<in> A \<rightarrow> carrier G"
   519   shows "(\<Otimes>j\<in>A. if i = j then f j else \<one>) = f i"
   520   using i_in_A finprod_insert [of "A - {i}" i "(\<lambda>j. if i = j then f j else \<one>)"]
   521     fin_A f_Pi finprod_one [of "A - {i}"]
   522     finprod_cong [of "A - {i}" "A - {i}" "(\<lambda>j. if i = j then f j else \<one>)" "(\<lambda>i. \<one>)"] 
   523   unfolding Pi_def simp_implies_def by (force simp add: insert_absorb)
   524 
   525 end
   526 
   527 end