src/Pure/sign.ML
author wenzelm
Fri Feb 10 02:22:32 2006 +0100 (2006-02-10)
changeset 18994 ce724d5bada2
parent 18967 ea42ab6c08d1
child 19013 19ad0c59fb1f
permissions -rw-r--r--
tuned extern_term, pretty_term';
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_arities: (xstring * string list * string) list -> theory -> theory
    19   val add_arities_i: (string * sort list * sort) list -> theory -> theory
    20   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    21   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    22   val add_modesyntax: (string * bool) -> (bstring * string * mixfix) list -> theory -> theory
    23   val add_modesyntax_i: (string * bool) -> (bstring * typ * mixfix) list -> theory -> theory
    24   val del_modesyntax: (string * bool) -> (bstring * string * mixfix) list -> theory -> theory
    25   val del_modesyntax_i: (string * bool) -> (bstring * typ * mixfix) list -> theory -> theory
    26   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    27   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    28   val add_abbrevs: bool -> (bstring * string * mixfix) list -> theory -> theory
    29   val add_abbrevs_i: bool -> (bstring * term * mixfix) list -> theory -> theory
    30   val add_const_constraint: xstring * string -> theory -> theory
    31   val add_const_constraint_i: string * typ -> theory -> theory
    32   val add_classes: (bstring * xstring list) list -> theory -> theory
    33   val add_classes_i: (bstring * class list) list -> theory -> theory
    34   val add_classrel: (xstring * xstring) list -> theory -> theory
    35   val add_classrel_i: (class * class) list -> theory -> theory
    36   val add_trfuns:
    37     (string * (ast list -> ast)) list *
    38     (string * (term list -> term)) list *
    39     (string * (term list -> term)) list *
    40     (string * (ast list -> ast)) list -> theory -> theory
    41   val add_trfunsT:
    42     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    43   val add_advanced_trfuns:
    44     (string * (Context.generic -> ast list -> ast)) list *
    45     (string * (Context.generic -> term list -> term)) list *
    46     (string * (Context.generic -> term list -> term)) list *
    47     (string * (Context.generic -> ast list -> ast)) list -> theory -> theory
    48   val add_advanced_trfunsT:
    49     (string * (Context.generic -> bool -> typ -> term list -> term)) list -> theory -> theory
    50   val add_tokentrfuns:
    51     (string * string * (string -> string * real)) list -> theory -> theory
    52   val add_mode_tokentrfuns: string -> (string * (string -> string * real)) list
    53     -> theory -> theory
    54   val parse_ast_translation: bool * string -> theory -> theory
    55   val parse_translation: bool * string -> theory -> theory
    56   val print_translation: bool * string -> theory -> theory
    57   val typed_print_translation: bool * string -> theory -> theory
    58   val print_ast_translation: bool * string -> theory -> theory
    59   val token_translation: string -> theory -> theory
    60   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    61   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    62   val add_path: string -> theory -> theory
    63   val parent_path: theory -> theory
    64   val root_path: theory -> theory
    65   val absolute_path: theory -> theory
    66   val local_path: theory -> theory
    67   val qualified_names: theory -> theory
    68   val no_base_names: theory -> theory
    69   val custom_accesses: (string list -> string list list) -> theory -> theory
    70   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    71     theory -> theory
    72   val restore_naming: theory -> theory -> theory
    73   val hide_classes: bool -> xstring list -> theory -> theory
    74   val hide_classes_i: bool -> string list -> theory -> theory
    75   val hide_types: bool -> xstring list -> theory -> theory
    76   val hide_types_i: bool -> string list -> theory -> theory
    77   val hide_consts: bool -> xstring list -> theory -> theory
    78   val hide_consts_i: bool -> string list -> theory -> theory
    79   val hide_names: bool -> string * xstring list -> theory -> theory
    80   val hide_names_i: bool -> string * string list -> theory -> theory
    81 end
    82 
    83 signature SIGN =
    84 sig
    85   type sg    (*obsolete*)
    86   val init_data: theory -> theory
    87   val rep_sg: theory ->
    88    {naming: NameSpace.naming,
    89     syn: Syntax.syntax,
    90     tsig: Type.tsig,
    91     consts: Consts.T}
    92   val naming_of: theory -> NameSpace.naming
    93   val base_name: string -> bstring
    94   val full_name: theory -> bstring -> string
    95   val full_name_path: theory -> string -> bstring -> string
    96   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    97   val syn_of: theory -> Syntax.syntax
    98   val tsig_of: theory -> Type.tsig
    99   val classes_of: theory -> Sorts.classes
   100   val classes_arities_of: theory -> Sorts.classes * Sorts.arities
   101   val classes: theory -> class list
   102   val defaultS: theory -> sort
   103   val subsort: theory -> sort * sort -> bool
   104   val of_sort: theory -> typ * sort -> bool
   105   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
   106   val universal_witness: theory -> (typ * sort) option
   107   val all_sorts_nonempty: theory -> bool
   108   val typ_instance: theory -> typ * typ -> bool
   109   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
   110   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
   111   val is_logtype: theory -> string -> bool
   112   val consts_of: theory -> Consts.T
   113   val const_constraint: theory -> string -> typ option
   114   val the_const_constraint: theory -> string -> typ
   115   val const_type: theory -> string -> typ option
   116   val the_const_type: theory -> string -> typ
   117   val declared_tyname: theory -> string -> bool
   118   val declared_const: theory -> string -> bool
   119   val const_monomorphic: theory -> string -> bool
   120   val const_typargs: theory -> string * typ -> typ list
   121   val const_instance: theory -> string * typ list -> typ
   122   val class_space: theory -> NameSpace.T
   123   val type_space: theory -> NameSpace.T
   124   val const_space: theory -> NameSpace.T
   125   val intern_class: theory -> xstring -> string
   126   val extern_class: theory -> string -> xstring
   127   val intern_type: theory -> xstring -> string
   128   val extern_type: theory -> string -> xstring
   129   val intern_const: theory -> xstring -> string
   130   val extern_const: theory -> string -> xstring
   131   val intern_sort: theory -> sort -> sort
   132   val extern_sort: theory -> sort -> sort
   133   val intern_typ: theory -> typ -> typ
   134   val extern_typ: theory -> typ -> typ
   135   val intern_term: theory -> term -> term
   136   val extern_term: (string -> xstring) -> theory -> term -> term
   137   val intern_tycons: theory -> typ -> typ
   138   val pretty_term': Syntax.syntax -> Context.generic -> term -> Pretty.T
   139   val pretty_term: theory -> term -> Pretty.T
   140   val pretty_typ: theory -> typ -> Pretty.T
   141   val pretty_sort: theory -> sort -> Pretty.T
   142   val pretty_classrel: theory -> class list -> Pretty.T
   143   val pretty_arity: theory -> arity -> Pretty.T
   144   val string_of_term: theory -> term -> string
   145   val string_of_typ: theory -> typ -> string
   146   val string_of_sort: theory -> sort -> string
   147   val string_of_classrel: theory -> class list -> string
   148   val string_of_arity: theory -> arity -> string
   149   val pprint_term: theory -> term -> pprint_args -> unit
   150   val pprint_typ: theory -> typ -> pprint_args -> unit
   151   val pp: theory -> Pretty.pp
   152   val certify_class: theory -> class -> class
   153   val certify_sort: theory -> sort -> sort
   154   val certify_typ: theory -> typ -> typ
   155   val certify_typ_syntax: theory -> typ -> typ
   156   val certify_typ_abbrev: theory -> typ -> typ
   157   val certify: bool -> bool -> Pretty.pp -> theory -> term -> term * typ * int
   158   val certify_term: theory -> term -> term * typ * int
   159   val certify_prop: theory -> term -> term * typ * int
   160   val cert_term: theory -> term -> term
   161   val cert_prop: theory -> term -> term
   162   val no_vars: Pretty.pp -> term -> term
   163   val cert_def: Pretty.pp -> term -> (string * typ) * term
   164   val read_sort': Syntax.syntax -> Context.generic -> string -> sort
   165   val read_sort: theory -> string -> sort
   166   val read_typ': Syntax.syntax -> Context.generic ->
   167     (indexname -> sort option) -> string -> typ
   168   val read_typ_syntax': Syntax.syntax -> Context.generic ->
   169     (indexname -> sort option) -> string -> typ
   170   val read_typ_abbrev': Syntax.syntax -> Context.generic ->
   171     (indexname -> sort option) -> string -> typ
   172   val read_typ: theory * (indexname -> sort option) -> string -> typ
   173   val read_typ_syntax: theory * (indexname -> sort option) -> string -> typ
   174   val read_typ_abbrev: theory * (indexname -> sort option) -> string -> typ
   175   val read_tyname: theory -> string -> typ
   176   val read_const: theory -> string -> term
   177   val infer_types_simult: Pretty.pp -> theory -> Consts.T -> (indexname -> typ option) ->
   178     (indexname -> sort option) -> string list -> bool
   179     -> (term list * typ) list -> term list * (indexname * typ) list
   180   val infer_types: Pretty.pp -> theory -> Consts.T -> (indexname -> typ option) ->
   181     (indexname -> sort option) -> string list -> bool
   182     -> term list * typ -> term * (indexname * typ) list
   183   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax -> Consts.T ->
   184     Context.generic -> (indexname -> typ option) * (indexname -> sort option) ->
   185     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   186   val read_def_terms:
   187     theory * (indexname -> typ option) * (indexname -> sort option) ->
   188     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   189   val simple_read_term: theory -> typ -> string -> term
   190   val read_term: theory -> string -> term
   191   val read_prop: theory -> string -> term
   192   include SIGN_THEORY
   193 end
   194 
   195 structure Sign: SIGN =
   196 struct
   197 
   198 type sg = theory;
   199 
   200 
   201 (** datatype sign **)
   202 
   203 datatype sign = Sign of
   204  {naming: NameSpace.naming,     (*common naming conventions*)
   205   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   206   tsig: Type.tsig,              (*order-sorted signature of types*)
   207   consts: Consts.T};            (*polymorphic constants*)
   208 
   209 fun make_sign (naming, syn, tsig, consts) =
   210   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   211 
   212 structure SignData = TheoryDataFun
   213 (struct
   214   val name = "Pure/sign";
   215   type T = sign;
   216   val copy = I;
   217   fun extend (Sign {syn, tsig, consts, ...}) =
   218     make_sign (NameSpace.default_naming, syn, tsig, consts);
   219 
   220   val empty =
   221     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   222 
   223   fun merge pp (sign1, sign2) =
   224     let
   225       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   226       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   227 
   228       val naming = NameSpace.default_naming;
   229       val syn = Syntax.merge_syntaxes syn1 syn2;
   230       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   231       val consts = Consts.merge (consts1, consts2);
   232     in make_sign (naming, syn, tsig, consts) end;
   233 
   234   fun print _ _ = ();
   235 end);
   236 
   237 val init_data = SignData.init;
   238 
   239 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   240 
   241 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   242   make_sign (f (naming, syn, tsig, consts)));
   243 
   244 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   245 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   246 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   247 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   248 
   249 
   250 (* naming *)
   251 
   252 val naming_of = #naming o rep_sg;
   253 val base_name = NameSpace.base;
   254 val full_name = NameSpace.full o naming_of;
   255 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   256 val declare_name = NameSpace.declare o naming_of;
   257 
   258 
   259 (* syntax *)
   260 
   261 val syn_of = #syn o rep_sg;
   262 
   263 
   264 (* type signature *)
   265 
   266 val tsig_of = #tsig o rep_sg;
   267 val classes_of = snd o #classes o Type.rep_tsig o tsig_of;
   268 fun classes_arities_of thy = (classes_of thy, #arities (Type.rep_tsig (tsig_of thy)));
   269 val classes = Type.classes o tsig_of;
   270 val defaultS = Type.defaultS o tsig_of;
   271 val subsort = Type.subsort o tsig_of;
   272 val of_sort = Type.of_sort o tsig_of;
   273 val witness_sorts = Type.witness_sorts o tsig_of;
   274 val universal_witness = Type.universal_witness o tsig_of;
   275 val all_sorts_nonempty = is_some o universal_witness;
   276 val typ_instance = Type.typ_instance o tsig_of;
   277 val typ_match = Type.typ_match o tsig_of;
   278 val typ_unify = Type.unify o tsig_of;
   279 fun is_logtype thy c = c mem_string Type.logical_types (tsig_of thy);
   280 
   281 
   282 (* polymorphic constants *)
   283 
   284 val consts_of = #consts o rep_sg;
   285 val the_const_constraint = Consts.constraint o consts_of;
   286 val const_constraint = try o the_const_constraint;
   287 val the_const_type = Consts.declaration o consts_of;
   288 val const_type = try o the_const_type;
   289 val const_monomorphic = Consts.monomorphic o consts_of;
   290 val const_typargs = Consts.typargs o consts_of;
   291 val const_instance = Consts.instance o consts_of;
   292 
   293 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   294 val declared_const = is_some oo const_type;
   295 
   296 
   297 
   298 (** intern / extern names **)
   299 
   300 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   301 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   302 val const_space = Consts.space_of o consts_of;
   303 
   304 val intern_class = NameSpace.intern o class_space;
   305 val extern_class = NameSpace.extern o class_space;
   306 val intern_type = NameSpace.intern o type_space;
   307 val extern_type = NameSpace.extern o type_space;
   308 val intern_const = NameSpace.intern o const_space;
   309 val extern_const = NameSpace.extern o const_space;
   310 
   311 val intern_sort = map o intern_class;
   312 val extern_sort = map o extern_class;
   313 
   314 local
   315 
   316 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   317   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   318   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   319 
   320 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   321   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   322   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   323   | map_term _ _ _ (t as Bound _) = t
   324   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   325   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   326 
   327 val add_classesT = Term.fold_atyps
   328   (fn TFree (_, S) => fold (insert (op =)) S
   329     | TVar (_, S) => fold (insert (op =)) S
   330     | _ => I);
   331 
   332 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   333   | add_tyconsT _ = I;
   334 
   335 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   336 
   337 fun mapping add_names f t =
   338   let
   339     fun f' x = let val y = f x in if x = y then NONE else SOME (x, y) end;
   340     val tab = List.mapPartial f' (add_names t []);
   341     fun get x = the_default x (AList.lookup (op =) tab x);
   342   in get end;
   343 
   344 fun typ_mapping f g thy T =
   345   T |> map_typ
   346     (mapping add_classesT (f thy) T)
   347     (mapping add_tyconsT (g thy) T);
   348 
   349 fun term_mapping f g h thy t =
   350   t |> map_term
   351     (mapping (Term.fold_types add_classesT) (f thy) t)
   352     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   353     (mapping add_consts (h thy) t);
   354 
   355 in
   356 
   357 val intern_typ = typ_mapping intern_class intern_type;
   358 val extern_typ = typ_mapping extern_class extern_type;
   359 val intern_term = term_mapping intern_class intern_type intern_const;
   360 fun extern_term h = term_mapping extern_class extern_type (K h);
   361 val intern_tycons = typ_mapping (K I) intern_type;
   362 
   363 end;
   364 
   365 
   366 
   367 (** pretty printing of terms, types etc. **)
   368 
   369 fun pretty_term' syn context t =
   370   let val curried = Context.exists_name Context.CPureN (Context.theory_of context)
   371   in Syntax.pretty_term context syn curried t end;
   372 
   373 fun pretty_term thy t =
   374   pretty_term' (syn_of thy) (Context.Theory thy)
   375     (extern_term (NameSpace.extern (Consts.space_of (consts_of thy))) thy t);
   376 
   377 fun pretty_typ thy T = Syntax.pretty_typ (Context.Theory thy) (syn_of thy) (extern_typ thy T);
   378 fun pretty_sort thy S = Syntax.pretty_sort (Context.Theory thy) (syn_of thy) (extern_sort thy S);
   379 
   380 fun pretty_classrel thy cs = Pretty.block (List.concat
   381   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   382 
   383 fun pretty_arity thy (a, Ss, S) =
   384   let
   385     val a' = extern_type thy a;
   386     val dom =
   387       if null Ss then []
   388       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   389   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   390 
   391 val string_of_term = Pretty.string_of oo pretty_term;
   392 val string_of_typ = Pretty.string_of oo pretty_typ;
   393 val string_of_sort = Pretty.string_of oo pretty_sort;
   394 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   395 val string_of_arity = Pretty.string_of oo pretty_arity;
   396 
   397 val pprint_term = (Pretty.pprint o Pretty.quote) oo pretty_term;
   398 val pprint_typ = (Pretty.pprint o Pretty.quote) oo pretty_typ;
   399 
   400 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   401   pretty_classrel thy, pretty_arity thy);
   402 
   403 
   404 
   405 (** certify entities **)    (*exception TYPE*)
   406 
   407 (* certify wrt. type signature *)
   408 
   409 fun certify cert = cert o tsig_of o Context.check_thy;
   410 
   411 val certify_class      = certify Type.cert_class;
   412 val certify_sort       = certify Type.cert_sort;
   413 val certify_typ        = certify Type.cert_typ;
   414 val certify_typ_syntax = certify Type.cert_typ_syntax;
   415 val certify_typ_abbrev = certify Type.cert_typ_abbrev;
   416 
   417 
   418 (* certify term/prop *)
   419 
   420 local
   421 
   422 fun type_check pp tm =
   423   let
   424     fun err_appl why bs t T u U =
   425       let
   426         val xs = map Free bs;           (*we do not rename here*)
   427         val t' = subst_bounds (xs, t);
   428         val u' = subst_bounds (xs, u);
   429         val msg = cat_lines
   430           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   431       in raise TYPE (msg, [T, U], [t', u']) end;
   432 
   433     fun typ_of (_, Const (_, T)) = T
   434       | typ_of (_, Free  (_, T)) = T
   435       | typ_of (_, Var (_, T)) = T
   436       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   437           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   438       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   439       | typ_of (bs, t $ u) =
   440           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   441             (case T of
   442               Type ("fun", [T1, T2]) =>
   443                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   444             | _ => err_appl "Operator not of function type" bs t T u U)
   445           end;
   446   in typ_of ([], tm) end;
   447 
   448 fun err msg = raise TYPE (msg, [], []);
   449 
   450 fun check_vars (t $ u) = (check_vars t; check_vars u)
   451   | check_vars (Abs (_, _, t)) = check_vars t
   452   | check_vars (Var (xi as (_, i), _)) =
   453       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   454   | check_vars _ = ();
   455 
   456 in
   457 
   458 fun certify normalize prop pp thy tm =
   459   let
   460     val _ = Context.check_thy thy;
   461     val _ = check_vars tm;
   462     val tm' = Term.map_term_types (certify_typ thy) tm;
   463     val T = type_check pp tm';
   464     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   465     val tm'' = Consts.certify pp (tsig_of thy) (consts_of thy) tm';
   466     val tm'' = if normalize then tm'' else tm';
   467   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   468 
   469 fun certify_term thy = certify true false (pp thy) thy;
   470 fun certify_prop thy = certify true true (pp thy) thy;
   471 
   472 val cert_term = #1 oo certify_term;
   473 val cert_prop = #1 oo certify_prop;
   474 
   475 end;
   476 
   477 
   478 (* specifications *)
   479 
   480 fun no_vars pp tm =
   481   (case (Term.term_vars tm, Term.term_tvars tm) of
   482     ([], []) => tm
   483   | (ts, ixns) => error (Pretty.string_of (Pretty.block (Pretty.breaks
   484       (Pretty.str "Illegal schematic variable(s) in term:" ::
   485        map (Pretty.term pp) ts @ map (Pretty.typ pp o TVar) ixns)))));
   486 
   487 fun cert_def pp tm =
   488   let val ((lhs, rhs), _) = tm
   489     |> no_vars pp
   490     |> Logic.strip_imp_concl
   491     |> Logic.dest_def pp Term.is_Const (K false) (K false)
   492   in (Term.dest_Const (Term.head_of lhs), rhs) end
   493   handle TERM (msg, _) => error msg;
   494 
   495 
   496 
   497 (** read and certify entities **)    (*exception ERROR*)
   498 
   499 (* sorts *)
   500 
   501 fun read_sort' syn context str =
   502   let
   503     val thy = Context.theory_of context;
   504     val _ = Context.check_thy thy;
   505     val S = intern_sort thy (Syntax.read_sort context syn str);
   506   in certify_sort thy S handle TYPE (msg, _, _) => error msg end;
   507 
   508 fun read_sort thy str = read_sort' (syn_of thy) (Context.Theory thy) str;
   509 
   510 
   511 (* types *)
   512 
   513 local
   514 
   515 fun gen_read_typ' cert syn context def_sort str =
   516   let
   517     val thy = Context.theory_of context;
   518     val _ = Context.check_thy thy;
   519     val get_sort = TypeInfer.get_sort (tsig_of thy) def_sort (intern_sort thy);
   520     val T = intern_tycons thy (Syntax.read_typ context syn get_sort (intern_sort thy) str);
   521   in cert thy T handle TYPE (msg, _, _) => error msg end
   522   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   523 
   524 fun gen_read_typ cert (thy, def_sort) str =
   525   gen_read_typ' cert (syn_of thy) (Context.Theory thy) def_sort str;
   526 
   527 in
   528 
   529 fun no_def_sort thy = (thy: theory, K NONE);
   530 
   531 val read_typ'        = gen_read_typ' certify_typ;
   532 val read_typ_syntax' = gen_read_typ' certify_typ_syntax;
   533 val read_typ_abbrev' = gen_read_typ' certify_typ_abbrev;
   534 val read_typ         = gen_read_typ certify_typ;
   535 val read_typ_syntax  = gen_read_typ certify_typ_syntax;
   536 val read_typ_abbrev  = gen_read_typ certify_typ_abbrev;
   537 
   538 end;
   539 
   540 
   541 (* type and constant names *)
   542 
   543 fun read_tyname thy raw_c =
   544   let val c = intern_type thy raw_c in
   545     (case Symtab.lookup (#2 (#types (Type.rep_tsig (tsig_of thy)))) c of
   546       SOME (Type.LogicalType n, _) => Type (c, replicate n dummyT)
   547     | _ => error ("Undeclared type constructor: " ^ quote c))
   548   end;
   549 
   550 val read_const = Consts.read_const o consts_of;
   551 
   552 
   553 
   554 (** infer_types **)         (*exception ERROR*)
   555 
   556 (*
   557   def_type: partial map from indexnames to types (constrains Frees and Vars)
   558   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   559   used: list of already used type variables
   560   freeze: if true then generated parameters are turned into TFrees, else TVars
   561 
   562   termss: lists of alternative parses (only one combination should be type-correct)
   563   typs: expected types
   564 *)
   565 
   566 fun infer_types_simult pp thy consts def_type def_sort used freeze args =
   567   let
   568     val termss = fold_rev (multiply o fst) args [[]];
   569     val typs =
   570       map (fn (_, T) => certify_typ thy T handle TYPE (msg, _, _) => error msg) args;
   571 
   572     fun infer ts = Result (TypeInfer.infer_types (Syntax.pp_show_brackets pp) (tsig_of thy)
   573         (try (Consts.constraint consts)) def_type def_sort
   574         (NameSpace.intern (Consts.space_of consts))
   575         (intern_tycons thy) (intern_sort thy) used freeze typs ts)
   576       handle TYPE (msg, _, _) => Exn (ERROR msg);
   577 
   578     val err_results = map infer termss;
   579     val errs = List.mapPartial (fn Exn (ERROR msg) => SOME msg | _ => NONE) err_results;
   580     val results = List.mapPartial get_result err_results;
   581 
   582     val ambiguity = length termss;
   583     fun ambig_msg () =
   584       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level then
   585         "Got more than one parse tree.\n\
   586         \Retry with smaller Syntax.ambiguity_level for more information."
   587       else "";
   588   in
   589     if null results then (cat_error (ambig_msg ()) (cat_lines errs))
   590     else if length results = 1 then
   591       (if ambiguity > ! Syntax.ambiguity_level then
   592         warning "Fortunately, only one parse tree is type correct.\n\
   593           \You may still want to disambiguate your grammar or your input."
   594       else (); hd results)
   595     else (cat_error (ambig_msg ()) ("More than one term is type correct:\n" ^
   596       cat_lines (map (Pretty.string_of_term pp) (List.concat (map fst results)))))
   597   end;
   598 
   599 fun infer_types pp thy consts def_type def_sort used freeze tsT =
   600   apfst hd (infer_types_simult pp thy consts def_type def_sort used freeze [tsT]);
   601 
   602 
   603 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   604 
   605 fun read_def_terms' pp is_logtype syn consts context (types, sorts) used freeze sTs =
   606   let
   607     val thy = Context.theory_of context;
   608     fun read (s, T) =
   609       let val T' = certify_typ thy T handle TYPE (msg, _, _) => error msg
   610       in (Syntax.read context is_logtype syn T' s, T') end;
   611   in infer_types_simult pp thy consts types sorts used freeze (map read sTs) end;
   612 
   613 fun read_def_terms (thy, types, sorts) =
   614   read_def_terms' (pp thy) (is_logtype thy) (syn_of thy) (consts_of thy)
   615     (Context.Theory thy) (types, sorts);
   616 
   617 fun simple_read_term thy T s =
   618   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   619   in t end
   620   handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   621 
   622 fun read_term thy = simple_read_term thy TypeInfer.logicT;
   623 fun read_prop thy = simple_read_term thy propT;
   624 
   625 
   626 
   627 (** signature extension functions **)  (*exception ERROR/TYPE*)
   628 
   629 (* add default sort *)
   630 
   631 fun gen_add_defsort prep_sort s thy =
   632   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   633 
   634 val add_defsort = gen_add_defsort read_sort;
   635 val add_defsort_i = gen_add_defsort certify_sort;
   636 
   637 
   638 (* add type constructors *)
   639 
   640 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   641   let
   642     val syn' = Syntax.extend_type_gram types syn;
   643     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   644     val tsig' = Type.add_types naming decls tsig;
   645   in (naming, syn', tsig', consts) end);
   646 
   647 fun add_typedecls decls thy =
   648   let
   649     fun type_of (a, vs, mx) =
   650       if not (has_duplicates (op =) vs) then (a, length vs, mx)
   651       else error ("Duplicate parameters in type declaration: " ^ quote a);
   652   in add_types (map type_of decls) thy end;
   653 
   654 
   655 (* add nonterminals *)
   656 
   657 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   658   let
   659     val syn' = Syntax.extend_consts ns syn;
   660     val tsig' = Type.add_nonterminals naming ns tsig;
   661   in (naming, syn', tsig', consts) end);
   662 
   663 
   664 (* add type abbreviations *)
   665 
   666 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   667   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   668     let
   669       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   670       val a' = Syntax.type_name a mx;
   671       val abbr = (a', vs, prep_typ thy rhs)
   672         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   673       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   674     in (naming, syn', tsig', consts) end);
   675 
   676 val add_tyabbrs = fold (gen_add_tyabbr (read_typ_syntax o no_def_sort));
   677 val add_tyabbrs_i = fold (gen_add_tyabbr certify_typ_syntax);
   678 
   679 
   680 (* add type arities *)
   681 
   682 fun gen_add_arities int_type prep_sort arities thy = thy |> map_tsig (fn tsig =>
   683   let
   684     fun prep_arity (a, Ss, S) = (int_type thy a, map (prep_sort thy) Ss, prep_sort thy S)
   685       handle ERROR msg => cat_error msg ("in arity for type " ^ quote a);
   686     val tsig' = Type.add_arities (pp thy) (map prep_arity arities) tsig;
   687   in tsig' end);
   688 
   689 val add_arities = gen_add_arities intern_type read_sort;
   690 val add_arities_i = gen_add_arities (K I) certify_sort;
   691 
   692 
   693 (* modify syntax *)
   694 
   695 fun gen_syntax change_gram prep_typ prmode args thy =
   696   let
   697     fun prep (c, T, mx) = (c, prep_typ thy T, mx) handle ERROR msg =>
   698       cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   699   in thy |> map_syn (change_gram (is_logtype thy) prmode (map prep args)) end;
   700 
   701 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   702 
   703 val add_modesyntax = gen_add_syntax (read_typ_syntax o no_def_sort);
   704 val add_modesyntax_i = gen_add_syntax certify_typ_syntax;
   705 val add_syntax = add_modesyntax Syntax.default_mode;
   706 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   707 val del_modesyntax = gen_syntax Syntax.remove_const_gram (read_typ_syntax o no_def_sort);
   708 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram certify_typ_syntax;
   709 
   710 
   711 (* add constants *)
   712 
   713 local
   714 
   715 fun gen_add_consts prep_typ raw_args thy =
   716   let
   717     val prepT = Compress.typ thy o Type.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   718     fun prep (c, T, mx) = ((c, prepT T, mx) handle TYPE (msg, _, _) => error msg)
   719       handle ERROR msg =>
   720         cat_error msg ("in declaration of constant " ^ quote (Syntax.const_name c mx));
   721     val args = map prep raw_args;
   722     val decls = args |> map (fn (c, T, mx) => (Syntax.const_name c mx, T));
   723   in
   724     thy
   725     |> map_consts (fold (Consts.declare (naming_of thy)) decls)
   726     |> add_syntax_i args
   727   end;
   728 
   729 in
   730 
   731 val add_consts = gen_add_consts (read_typ o no_def_sort);
   732 val add_consts_i = gen_add_consts certify_typ;
   733 
   734 end;
   735 
   736 
   737 (* add abbreviations *)
   738 
   739 local
   740 
   741 fun gen_add_abbrevs prep_term revert raw_args thy =
   742   let
   743     val prep_tm =
   744       Compress.term thy o Logic.varify o no_vars (pp thy) o Term.no_dummy_patterns o prep_term thy;
   745     fun prep (raw_c, raw_t, mx) =
   746       let
   747         val c = Syntax.const_name raw_c mx;
   748         val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg)
   749           handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   750       in ((c, t), (raw_c, Term.fastype_of t, mx)) end;
   751     val (abbrs, syn) = split_list (map prep raw_args);
   752   in
   753     thy
   754     |> map_consts (fold (Consts.abbreviate (pp thy) (tsig_of thy) (naming_of thy) revert) abbrs)
   755     |> add_syntax_i syn
   756   end;
   757 
   758 in
   759 
   760 val add_abbrevs = gen_add_abbrevs read_term;
   761 val add_abbrevs_i = gen_add_abbrevs cert_term;
   762 
   763 end;
   764 
   765 
   766 (* add constraints *)
   767 
   768 fun gen_add_constraint int_const prep_typ (raw_c, raw_T) thy =
   769   let
   770     val c = int_const thy raw_c;
   771     val T = Term.zero_var_indexesT (Term.no_dummyT (prep_typ thy raw_T))
   772       handle TYPE (msg, _, _) => error msg;
   773     val _ = cert_term thy (Const (c, T))
   774       handle TYPE (msg, _, _) => error msg;
   775   in thy |> map_consts (Consts.constrain (c, T)) end;
   776 
   777 val add_const_constraint = gen_add_constraint intern_const (read_typ o no_def_sort);
   778 val add_const_constraint_i = gen_add_constraint (K I) certify_typ;
   779 
   780 
   781 (* add type classes *)
   782 
   783 fun gen_add_class int_class (bclass, raw_classes) thy =
   784   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   785     let
   786       val classes = map (int_class thy) raw_classes;
   787       val syn' = Syntax.extend_consts [bclass] syn;
   788       val tsig' = Type.add_classes (pp thy) naming [(bclass, classes)] tsig;
   789     in (naming, syn', tsig', consts) end)
   790   |> add_consts_i [(Logic.const_of_class bclass, a_itselfT --> propT, NoSyn)];
   791 
   792 val add_classes = fold (gen_add_class intern_class);
   793 val add_classes_i = fold (gen_add_class (K I));
   794 
   795 
   796 (* add to classrel *)
   797 
   798 fun gen_add_classrel int_class raw_pairs thy = thy |> map_tsig (fn tsig =>
   799   let
   800     val pairs = map (pairself (int_class thy)) raw_pairs;
   801     val tsig' = Type.add_classrel (pp thy) pairs tsig;
   802   in tsig' end);
   803 
   804 val add_classrel = gen_add_classrel intern_class;
   805 val add_classrel_i = gen_add_classrel (K I);
   806 
   807 
   808 (* add translation functions *)
   809 
   810 local
   811 
   812 fun mk trs = map Syntax.mk_trfun trs;
   813 
   814 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   815   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   816 
   817 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   818 
   819 in
   820 
   821 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   822 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   823 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   824 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   825 
   826 end;
   827 
   828 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   829 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   830 
   831 
   832 (* compile translation functions *)
   833 
   834 local
   835 
   836 fun advancedT false = ""
   837   | advancedT true = "Context.generic -> ";
   838 
   839 fun advancedN false = ""
   840   | advancedN true = "advanced_";
   841 
   842 in
   843 
   844 fun parse_ast_translation (a, txt) =
   845   txt |> Context.use_let ("val parse_ast_translation: (string * (" ^ advancedT a ^
   846       "Syntax.ast list -> Syntax.ast)) list")
   847     ("Sign.add_" ^ advancedN a ^ "trfuns (parse_ast_translation, [], [], [])");
   848 
   849 fun parse_translation (a, txt) =
   850   txt |> Context.use_let ("val parse_translation: (string * (" ^ advancedT a ^
   851       "term list -> term)) list")
   852     ("Sign.add_" ^ advancedN a ^ "trfuns ([], parse_translation, [], [])");
   853 
   854 fun print_translation (a, txt) =
   855   txt |> Context.use_let ("val print_translation: (string * (" ^ advancedT a ^
   856       "term list -> term)) list")
   857     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], print_translation, [])");
   858 
   859 fun print_ast_translation (a, txt) =
   860   txt |> Context.use_let ("val print_ast_translation: (string * (" ^ advancedT a ^
   861       "Syntax.ast list -> Syntax.ast)) list")
   862     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], [], print_ast_translation)");
   863 
   864 fun typed_print_translation (a, txt) =
   865   txt |> Context.use_let ("val typed_print_translation: (string * (" ^ advancedT a ^
   866       "bool -> typ -> term list -> term)) list")
   867     ("Sign.add_" ^ advancedN a ^ "trfunsT typed_print_translation");
   868 
   869 val token_translation =
   870   Context.use_let "val token_translation: (string * string * (string -> string * real)) list"
   871     "Sign.add_tokentrfuns token_translation";
   872 
   873 end;
   874 
   875 
   876 (* add translation rules *)
   877 
   878 fun add_trrules args thy = thy |> map_syn (fn syn =>
   879   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   880   in Syntax.extend_trrules (Context.Theory thy) (is_logtype thy) syn rules syn end);
   881 
   882 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   883 
   884 
   885 (* modify naming *)
   886 
   887 val add_path        = map_naming o NameSpace.add_path;
   888 val qualified_names = map_naming NameSpace.qualified_names;
   889 val no_base_names   = map_naming NameSpace.no_base_names;
   890 val custom_accesses = map_naming o NameSpace.custom_accesses;
   891 val set_policy      = map_naming o NameSpace.set_policy;
   892 val restore_naming  = map_naming o K o naming_of;
   893 
   894 val parent_path     = add_path "..";
   895 val root_path       = add_path "/";
   896 val absolute_path   = add_path "//";
   897 
   898 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   899 
   900 
   901 (* hide names *)
   902 
   903 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   904 val hide_classes_i = map_tsig oo Type.hide_classes;
   905 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   906 val hide_types_i = map_tsig oo Type.hide_types;
   907 fun hide_consts b xs thy = thy |> map_consts (fold (Consts.hide b o intern_const thy) xs);
   908 val hide_consts_i = map_consts oo (fold o Consts.hide);
   909 
   910 local
   911 
   912 val kinds =
   913  [("class", (intern_class, can o certify_class, hide_classes_i)),
   914   ("type", (intern_type, declared_tyname, hide_types_i)),
   915   ("const", (intern_const, declared_const, hide_consts_i))];
   916 
   917 fun gen_hide int b (kind, xnames) thy =
   918   (case AList.lookup (op =) kinds kind of
   919     SOME (intern, check, hide) =>
   920       let
   921         val names = if int then map (intern thy) xnames else xnames;
   922         val bads = filter_out (check thy) names;
   923       in
   924         if null bads then hide b names thy
   925         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   926       end
   927   | NONE => error ("Bad name space specification: " ^ quote kind));
   928 
   929 in
   930 
   931 val hide_names = gen_hide true;
   932 val hide_names_i = gen_hide false;
   933 
   934 end;
   935 
   936 end;