src/HOL/Set.ML
author paulson
Wed Jun 28 10:41:16 2000 +0200 (2000-06-28)
changeset 9161 cee6d5aee7c8
parent 9108 9fff97d29837
child 9186 7b2f4e6538b4
permissions -rw-r--r--
deleted a redundant bind_thm
     1 (*  Title:      HOL/set
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 section "Relating predicates and sets";
    10 
    11 Addsimps [Collect_mem_eq];
    12 AddIffs  [mem_Collect_eq];
    13 
    14 Goal "P(a) ==> a : {x. P(x)}";
    15 by (Asm_simp_tac 1);
    16 qed "CollectI";
    17 
    18 Goal "a : {x. P(x)} ==> P(a)";
    19 by (Asm_full_simp_tac 1);
    20 qed "CollectD";
    21 
    22 val [prem] = Goal "[| !!x. (x:A) = (x:B) |] ==> A = B";
    23 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    24 by (rtac Collect_mem_eq 1);
    25 by (rtac Collect_mem_eq 1);
    26 qed "set_ext";
    27 
    28 val [prem] = Goal "[| !!x. P(x)=Q(x) |] ==> {x. P(x)} = {x. Q(x)}";
    29 by (rtac (prem RS ext RS arg_cong) 1);
    30 qed "Collect_cong";
    31 
    32 bind_thm ("CollectE", make_elim CollectD);
    33 
    34 AddSIs [CollectI];
    35 AddSEs [CollectE];
    36 
    37 
    38 section "Bounded quantifiers";
    39 
    40 val prems = Goalw [Ball_def]
    41     "[| !!x. x:A ==> P(x) |] ==> ALL x:A. P(x)";
    42 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    43 qed "ballI";
    44 
    45 bind_thms ("strip", [impI, allI, ballI]);
    46 
    47 Goalw [Ball_def] "[| ALL x:A. P(x);  x:A |] ==> P(x)";
    48 by (Blast_tac 1);
    49 qed "bspec";
    50 
    51 val major::prems = Goalw [Ball_def]
    52     "[| ALL x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    53 by (rtac (major RS spec RS impCE) 1);
    54 by (REPEAT (eresolve_tac prems 1));
    55 qed "ballE";
    56 
    57 (*Takes assumptions ALL x:A.P(x) and a:A; creates assumption P(a)*)
    58 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    59 
    60 AddSIs [ballI];
    61 AddEs  [ballE];
    62 AddXDs [bspec];
    63 (* gives better instantiation for bound: *)
    64 claset_ref() := claset() addWrapper ("bspec", fn tac2 =>
    65 			 (dtac bspec THEN' atac) APPEND' tac2);
    66 
    67 (*Normally the best argument order: P(x) constrains the choice of x:A*)
    68 Goalw [Bex_def] "[| P(x);  x:A |] ==> EX x:A. P(x)";
    69 by (Blast_tac 1);
    70 qed "bexI";
    71 
    72 (*The best argument order when there is only one x:A*)
    73 Goalw [Bex_def] "[| x:A;  P(x) |] ==> EX x:A. P(x)";
    74 by (Blast_tac 1);
    75 qed "rev_bexI";
    76 
    77 val prems = Goal 
    78    "[| ALL x:A. ~P(x) ==> P(a);  a:A |] ==> EX x:A. P(x)";
    79 by (rtac classical 1);
    80 by (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ;
    81 qed "bexCI";
    82 
    83 val major::prems = Goalw [Bex_def]
    84     "[| EX x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    85 by (rtac (major RS exE) 1);
    86 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    87 qed "bexE";
    88 
    89 AddIs  [bexI];
    90 AddSEs [bexE];
    91 
    92 (*Trival rewrite rule*)
    93 Goal "(ALL x:A. P) = ((EX x. x:A) --> P)";
    94 by (simp_tac (simpset() addsimps [Ball_def]) 1);
    95 qed "ball_triv";
    96 
    97 (*Dual form for existentials*)
    98 Goal "(EX x:A. P) = ((EX x. x:A) & P)";
    99 by (simp_tac (simpset() addsimps [Bex_def]) 1);
   100 qed "bex_triv";
   101 
   102 Addsimps [ball_triv, bex_triv];
   103 
   104 (** Congruence rules **)
   105 
   106 val prems = Goalw [Ball_def]
   107     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   108 \    (ALL x:A. P(x)) = (ALL x:B. Q(x))";
   109 by (asm_simp_tac (simpset() addsimps prems) 1);
   110 qed "ball_cong";
   111 
   112 val prems = Goalw [Bex_def]
   113     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   114 \    (EX x:A. P(x)) = (EX x:B. Q(x))";
   115 by (asm_simp_tac (simpset() addcongs [conj_cong] addsimps prems) 1);
   116 qed "bex_cong";
   117 
   118 Addcongs [ball_cong,bex_cong];
   119 
   120 section "Subsets";
   121 
   122 val prems = Goalw [subset_def] "(!!x. x:A ==> x:B) ==> A <= B";
   123 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   124 qed "subsetI";
   125 
   126 (*Map the type ('a set => anything) to just 'a.
   127   For overloading constants whose first argument has type "'a set" *)
   128 fun overload_1st_set s = Blast.overloaded (s, HOLogic.dest_setT o domain_type);
   129 
   130 (*While (:) is not, its type must be kept
   131   for overloading of = to work.*)
   132 Blast.overloaded ("op :", domain_type);
   133 
   134 overload_1st_set "Ball";		(*need UNION, INTER also?*)
   135 overload_1st_set "Bex";
   136 
   137 (*Image: retain the type of the set being expressed*)
   138 Blast.overloaded ("image", domain_type);
   139 
   140 (*Rule in Modus Ponens style*)
   141 Goalw [subset_def] "[| A <= B;  c:A |] ==> c:B";
   142 by (Blast_tac 1);
   143 qed "subsetD";
   144 AddXIs [subsetD];
   145 
   146 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   147 Goal "[| c:A;  A <= B |] ==> c:B";
   148 by (REPEAT (ares_tac [subsetD] 1)) ;
   149 qed "rev_subsetD";
   150 AddXIs [rev_subsetD];
   151 
   152 (*Converts A<=B to x:A ==> x:B*)
   153 fun impOfSubs th = th RSN (2, rev_subsetD);
   154 
   155 Goal "[| A <= B; c ~: B |] ==> c ~: A";
   156 by (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ;
   157 qed "contra_subsetD";
   158 
   159 Goal "[| c ~: B;  A <= B |] ==> c ~: A";
   160 by (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ;
   161 qed "rev_contra_subsetD";
   162 
   163 (*Classical elimination rule*)
   164 val major::prems = Goalw [subset_def] 
   165     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   166 by (rtac (major RS ballE) 1);
   167 by (REPEAT (eresolve_tac prems 1));
   168 qed "subsetCE";
   169 
   170 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   171 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   172 
   173 AddSIs [subsetI];
   174 AddEs  [subsetD, subsetCE];
   175 
   176 Goal "A <= (A::'a set)";
   177 by (Fast_tac 1);
   178 qed "subset_refl";		(*Blast_tac would try order_refl and fail*)
   179 
   180 Goal "[| A<=B;  B<=C |] ==> A<=(C::'a set)";
   181 by (Blast_tac 1);
   182 qed "subset_trans";
   183 
   184 
   185 section "Equality";
   186 
   187 (*Anti-symmetry of the subset relation*)
   188 Goal "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   189 by (rtac set_ext 1);
   190 by (blast_tac (claset() addIs [subsetD]) 1);
   191 qed "subset_antisym";
   192 bind_thm ("equalityI", subset_antisym);
   193 
   194 AddSIs [equalityI];
   195 
   196 (* Equality rules from ZF set theory -- are they appropriate here? *)
   197 Goal "A = B ==> A<=(B::'a set)";
   198 by (etac ssubst 1);
   199 by (rtac subset_refl 1);
   200 qed "equalityD1";
   201 
   202 Goal "A = B ==> B<=(A::'a set)";
   203 by (etac ssubst 1);
   204 by (rtac subset_refl 1);
   205 qed "equalityD2";
   206 
   207 val prems = Goal
   208     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   209 by (resolve_tac prems 1);
   210 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   211 qed "equalityE";
   212 
   213 AddEs [equalityE];
   214 
   215 val major::prems = Goal
   216     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   217 by (rtac (major RS equalityE) 1);
   218 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   219 qed "equalityCE";
   220 
   221 (*Lemma for creating induction formulae -- for "pattern matching" on p
   222   To make the induction hypotheses usable, apply "spec" or "bspec" to
   223   put universal quantifiers over the free variables in p. *)
   224 val prems = Goal 
   225     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   226 by (rtac mp 1);
   227 by (REPEAT (resolve_tac (refl::prems) 1));
   228 qed "setup_induction";
   229 
   230 Goal "A = B ==> (x : A) = (x : B)";
   231 by (Asm_simp_tac 1);
   232 qed "eqset_imp_iff";
   233 
   234 
   235 section "The universal set -- UNIV";
   236 
   237 Goalw [UNIV_def] "x : UNIV";
   238 by (rtac CollectI 1);
   239 by (rtac TrueI 1);
   240 qed "UNIV_I";
   241 
   242 Addsimps [UNIV_I];
   243 AddIs    [UNIV_I];  (*unsafe makes it less likely to cause problems*)
   244 
   245 Goal "A <= UNIV";
   246 by (rtac subsetI 1);
   247 by (rtac UNIV_I 1);
   248 qed "subset_UNIV";
   249 
   250 (** Eta-contracting these two rules (to remove P) causes them to be ignored
   251     because of their interaction with congruence rules. **)
   252 
   253 Goalw [Ball_def] "Ball UNIV P = All P";
   254 by (Simp_tac 1);
   255 qed "ball_UNIV";
   256 
   257 Goalw [Bex_def] "Bex UNIV P = Ex P";
   258 by (Simp_tac 1);
   259 qed "bex_UNIV";
   260 Addsimps [ball_UNIV, bex_UNIV];
   261 
   262 
   263 section "The empty set -- {}";
   264 
   265 Goalw [empty_def] "(c : {}) = False";
   266 by (Blast_tac 1) ;
   267 qed "empty_iff";
   268 
   269 Addsimps [empty_iff];
   270 
   271 Goal "a:{} ==> P";
   272 by (Full_simp_tac 1);
   273 qed "emptyE";
   274 
   275 AddSEs [emptyE];
   276 
   277 Goal "{} <= A";
   278 by (Blast_tac 1) ;
   279 qed "empty_subsetI";
   280 
   281 (*One effect is to delete the ASSUMPTION {} <= A*)
   282 AddIffs [empty_subsetI];
   283 
   284 val [prem]= Goal "[| !!y. y:A ==> False |] ==> A={}";
   285 by (blast_tac (claset() addIs [prem RS FalseE]) 1) ;
   286 qed "equals0I";
   287 
   288 (*Use for reasoning about disjointness: A Int B = {} *)
   289 Goal "A={} ==> a ~: A";
   290 by (Blast_tac 1) ;
   291 qed "equals0D";
   292 
   293 Goalw [Ball_def] "Ball {} P = True";
   294 by (Simp_tac 1);
   295 qed "ball_empty";
   296 
   297 Goalw [Bex_def] "Bex {} P = False";
   298 by (Simp_tac 1);
   299 qed "bex_empty";
   300 Addsimps [ball_empty, bex_empty];
   301 
   302 Goal "UNIV ~= {}";
   303 by (blast_tac (claset() addEs [equalityE]) 1);
   304 qed "UNIV_not_empty";
   305 AddIffs [UNIV_not_empty];
   306 
   307 
   308 
   309 section "The Powerset operator -- Pow";
   310 
   311 Goalw [Pow_def] "(A : Pow(B)) = (A <= B)";
   312 by (Asm_simp_tac 1);
   313 qed "Pow_iff";
   314 
   315 AddIffs [Pow_iff]; 
   316 
   317 Goalw [Pow_def] "A <= B ==> A : Pow(B)";
   318 by (etac CollectI 1);
   319 qed "PowI";
   320 
   321 Goalw [Pow_def] "A : Pow(B)  ==>  A<=B";
   322 by (etac CollectD 1);
   323 qed "PowD";
   324 
   325 
   326 bind_thm ("Pow_bottom", empty_subsetI RS PowI);        (* {}: Pow(B) *)
   327 bind_thm ("Pow_top", subset_refl RS PowI);             (* A : Pow(A) *)
   328 
   329 
   330 section "Set complement";
   331 
   332 Goalw [Compl_def] "(c : -A) = (c~:A)";
   333 by (Blast_tac 1);
   334 qed "Compl_iff";
   335 
   336 Addsimps [Compl_iff];
   337 
   338 val prems = Goalw [Compl_def] "[| c:A ==> False |] ==> c : -A";
   339 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   340 qed "ComplI";
   341 
   342 (*This form, with negated conclusion, works well with the Classical prover.
   343   Negated assumptions behave like formulae on the right side of the notional
   344   turnstile...*)
   345 Goalw [Compl_def] "c : -A ==> c~:A";
   346 by (etac CollectD 1);
   347 qed "ComplD";
   348 
   349 bind_thm ("ComplE", make_elim ComplD);
   350 
   351 AddSIs [ComplI];
   352 AddSEs [ComplE];
   353 
   354 
   355 section "Binary union -- Un";
   356 
   357 Goalw [Un_def] "(c : A Un B) = (c:A | c:B)";
   358 by (Blast_tac 1);
   359 qed "Un_iff";
   360 Addsimps [Un_iff];
   361 
   362 Goal "c:A ==> c : A Un B";
   363 by (Asm_simp_tac 1);
   364 qed "UnI1";
   365 
   366 Goal "c:B ==> c : A Un B";
   367 by (Asm_simp_tac 1);
   368 qed "UnI2";
   369 
   370 (*Classical introduction rule: no commitment to A vs B*)
   371 
   372 val prems = Goal "(c~:B ==> c:A) ==> c : A Un B";
   373 by (Simp_tac 1);
   374 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   375 qed "UnCI";
   376 
   377 val major::prems = Goalw [Un_def]
   378     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   379 by (rtac (major RS CollectD RS disjE) 1);
   380 by (REPEAT (eresolve_tac prems 1));
   381 qed "UnE";
   382 
   383 AddSIs [UnCI];
   384 AddSEs [UnE];
   385 
   386 
   387 section "Binary intersection -- Int";
   388 
   389 Goalw [Int_def] "(c : A Int B) = (c:A & c:B)";
   390 by (Blast_tac 1);
   391 qed "Int_iff";
   392 Addsimps [Int_iff];
   393 
   394 Goal "[| c:A;  c:B |] ==> c : A Int B";
   395 by (Asm_simp_tac 1);
   396 qed "IntI";
   397 
   398 Goal "c : A Int B ==> c:A";
   399 by (Asm_full_simp_tac 1);
   400 qed "IntD1";
   401 
   402 Goal "c : A Int B ==> c:B";
   403 by (Asm_full_simp_tac 1);
   404 qed "IntD2";
   405 
   406 val [major,minor] = Goal
   407     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   408 by (rtac minor 1);
   409 by (rtac (major RS IntD1) 1);
   410 by (rtac (major RS IntD2) 1);
   411 qed "IntE";
   412 
   413 AddSIs [IntI];
   414 AddSEs [IntE];
   415 
   416 section "Set difference";
   417 
   418 Goalw [set_diff_def] "(c : A-B) = (c:A & c~:B)";
   419 by (Blast_tac 1);
   420 qed "Diff_iff";
   421 Addsimps [Diff_iff];
   422 
   423 Goal "[| c : A;  c ~: B |] ==> c : A - B";
   424 by (Asm_simp_tac 1) ;
   425 qed "DiffI";
   426 
   427 Goal "c : A - B ==> c : A";
   428 by (Asm_full_simp_tac 1) ;
   429 qed "DiffD1";
   430 
   431 Goal "[| c : A - B;  c : B |] ==> P";
   432 by (Asm_full_simp_tac 1) ;
   433 qed "DiffD2";
   434 
   435 val prems = Goal "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P";
   436 by (resolve_tac prems 1);
   437 by (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ;
   438 qed "DiffE";
   439 
   440 AddSIs [DiffI];
   441 AddSEs [DiffE];
   442 
   443 
   444 section "Augmenting a set -- insert";
   445 
   446 Goalw [insert_def] "a : insert b A = (a=b | a:A)";
   447 by (Blast_tac 1);
   448 qed "insert_iff";
   449 Addsimps [insert_iff];
   450 
   451 Goal "a : insert a B";
   452 by (Simp_tac 1);
   453 qed "insertI1";
   454 
   455 Goal "!!a. a : B ==> a : insert b B";
   456 by (Asm_simp_tac 1);
   457 qed "insertI2";
   458 
   459 val major::prems = Goalw [insert_def]
   460     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P";
   461 by (rtac (major RS UnE) 1);
   462 by (REPEAT (eresolve_tac (prems @ [CollectE]) 1));
   463 qed "insertE";
   464 
   465 (*Classical introduction rule*)
   466 val prems = Goal "(a~:B ==> a=b) ==> a: insert b B";
   467 by (Simp_tac 1);
   468 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   469 qed "insertCI";
   470 
   471 AddSIs [insertCI]; 
   472 AddSEs [insertE];
   473 
   474 Goal "(A <= insert x B) = (if x:A then A-{x} <= B else A<=B)";
   475 by Auto_tac; 
   476 qed "subset_insert_iff";
   477 
   478 section "Singletons, using insert";
   479 
   480 Goal "a : {a}";
   481 by (rtac insertI1 1) ;
   482 qed "singletonI";
   483 
   484 Goal "b : {a} ==> b=a";
   485 by (Blast_tac 1);
   486 qed "singletonD";
   487 
   488 bind_thm ("singletonE", make_elim singletonD);
   489 
   490 Goal "(b : {a}) = (b=a)";
   491 by (Blast_tac 1);
   492 qed "singleton_iff";
   493 
   494 Goal "{a}={b} ==> a=b";
   495 by (blast_tac (claset() addEs [equalityE]) 1);
   496 qed "singleton_inject";
   497 
   498 (*Redundant? But unlike insertCI, it proves the subgoal immediately!*)
   499 AddSIs [singletonI];   
   500 AddSDs [singleton_inject];
   501 AddSEs [singletonE];
   502 
   503 Goal "{b} = insert a A = (a = b & A <= {b})";
   504 by (blast_tac (claset() addSEs [equalityE]) 1);
   505 qed "singleton_insert_inj_eq";
   506 
   507 Goal "(insert a A = {b}) = (a = b & A <= {b})";
   508 by (blast_tac (claset() addSEs [equalityE]) 1);
   509 qed "singleton_insert_inj_eq'";
   510 
   511 AddIffs [singleton_insert_inj_eq, singleton_insert_inj_eq'];
   512 
   513 Goal "A <= {x} ==> A={} | A = {x}";
   514 by (Fast_tac 1);
   515 qed "subset_singletonD";
   516 
   517 Goal "{x. x=a} = {a}";
   518 by (Blast_tac 1);
   519 qed "singleton_conv";
   520 Addsimps [singleton_conv];
   521 
   522 Goal "{x. a=x} = {a}";
   523 by (Blast_tac 1);
   524 qed "singleton_conv2";
   525 Addsimps [singleton_conv2];
   526 
   527 
   528 section "Unions of families -- UNION x:A. B(x) is Union(B``A)";
   529 
   530 Goalw [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   531 by (Blast_tac 1);
   532 qed "UN_iff";
   533 
   534 Addsimps [UN_iff];
   535 
   536 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   537 Goal "[| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   538 by Auto_tac;
   539 qed "UN_I";
   540 
   541 val major::prems = Goalw [UNION_def]
   542     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   543 by (rtac (major RS CollectD RS bexE) 1);
   544 by (REPEAT (ares_tac prems 1));
   545 qed "UN_E";
   546 
   547 AddIs  [UN_I];
   548 AddSEs [UN_E];
   549 
   550 val prems = Goalw [UNION_def]
   551     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   552 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   553 by (asm_simp_tac (simpset() addsimps prems) 1);
   554 qed "UN_cong";
   555 
   556 
   557 section "Intersections of families -- INTER x:A. B(x) is Inter(B``A)";
   558 
   559 Goalw [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   560 by Auto_tac;
   561 qed "INT_iff";
   562 
   563 Addsimps [INT_iff];
   564 
   565 val prems = Goalw [INTER_def]
   566     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   567 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   568 qed "INT_I";
   569 
   570 Goal "[| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   571 by Auto_tac;
   572 qed "INT_D";
   573 
   574 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   575 val major::prems = Goalw [INTER_def]
   576     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   577 by (rtac (major RS CollectD RS ballE) 1);
   578 by (REPEAT (eresolve_tac prems 1));
   579 qed "INT_E";
   580 
   581 AddSIs [INT_I];
   582 AddEs  [INT_D, INT_E];
   583 
   584 val prems = Goalw [INTER_def]
   585     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   586 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   587 by (asm_simp_tac (simpset() addsimps prems) 1);
   588 qed "INT_cong";
   589 
   590 
   591 section "Union";
   592 
   593 Goalw [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   594 by (Blast_tac 1);
   595 qed "Union_iff";
   596 
   597 Addsimps [Union_iff];
   598 
   599 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   600 Goal "[| X:C;  A:X |] ==> A : Union(C)";
   601 by Auto_tac;
   602 qed "UnionI";
   603 
   604 val major::prems = Goalw [Union_def]
   605     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   606 by (rtac (major RS UN_E) 1);
   607 by (REPEAT (ares_tac prems 1));
   608 qed "UnionE";
   609 
   610 AddIs  [UnionI];
   611 AddSEs [UnionE];
   612 
   613 
   614 section "Inter";
   615 
   616 Goalw [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   617 by (Blast_tac 1);
   618 qed "Inter_iff";
   619 
   620 Addsimps [Inter_iff];
   621 
   622 val prems = Goalw [Inter_def]
   623     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   624 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   625 qed "InterI";
   626 
   627 (*A "destruct" rule -- every X in C contains A as an element, but
   628   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   629 Goal "[| A : Inter(C);  X:C |] ==> A:X";
   630 by Auto_tac;
   631 qed "InterD";
   632 
   633 (*"Classical" elimination rule -- does not require proving X:C *)
   634 val major::prems = Goalw [Inter_def]
   635     "[| A : Inter(C);  X~:C ==> R;  A:X ==> R |] ==> R";
   636 by (rtac (major RS INT_E) 1);
   637 by (REPEAT (eresolve_tac prems 1));
   638 qed "InterE";
   639 
   640 AddSIs [InterI];
   641 AddEs  [InterD, InterE];
   642 
   643 
   644 (*** Image of a set under a function ***)
   645 
   646 (*Frequently b does not have the syntactic form of f(x).*)
   647 Goalw [image_def] "[| b=f(x);  x:A |] ==> b : f``A";
   648 by (Blast_tac 1);
   649 qed "image_eqI";
   650 Addsimps [image_eqI];
   651 
   652 bind_thm ("imageI", refl RS image_eqI);
   653 
   654 (*This version's more effective when we already have the required x*)
   655 Goalw [image_def] "[| x:A;  b=f(x) |] ==> b : f``A";
   656 by (Blast_tac 1);
   657 qed "rev_image_eqI";
   658 
   659 (*The eta-expansion gives variable-name preservation.*)
   660 val major::prems = Goalw [image_def]
   661     "[| b : (%x. f(x))``A;  !!x.[| b=f(x);  x:A |] ==> P |] ==> P"; 
   662 by (rtac (major RS CollectD RS bexE) 1);
   663 by (REPEAT (ares_tac prems 1));
   664 qed "imageE";
   665 
   666 AddIs  [image_eqI];
   667 AddSEs [imageE]; 
   668 
   669 Goal "f``(A Un B) = f``A Un f``B";
   670 by (Blast_tac 1);
   671 qed "image_Un";
   672 
   673 Goal "(z : f``A) = (EX x:A. z = f x)";
   674 by (Blast_tac 1);
   675 qed "image_iff";
   676 
   677 (*This rewrite rule would confuse users if made default.*)
   678 Goal "(f``A <= B) = (ALL x:A. f(x): B)";
   679 by (Blast_tac 1);
   680 qed "image_subset_iff";
   681 
   682 (*Replaces the three steps subsetI, imageE, hyp_subst_tac, but breaks too
   683   many existing proofs.*)
   684 val prems = Goal "(!!x. x:A ==> f(x) : B) ==> f``A <= B";
   685 by (blast_tac (claset() addIs prems) 1);
   686 qed "image_subsetI";
   687 
   688 
   689 (*** Range of a function -- just a translation for image! ***)
   690 
   691 Goal "b=f(x) ==> b : range(f)";
   692 by (EVERY1 [etac image_eqI, rtac UNIV_I]);
   693 bind_thm ("range_eqI", UNIV_I RSN (2,image_eqI));
   694 
   695 bind_thm ("rangeI", UNIV_I RS imageI);
   696 
   697 val [major,minor] = Goal 
   698     "[| b : range(%x. f(x));  !!x. b=f(x) ==> P |] ==> P"; 
   699 by (rtac (major RS imageE) 1);
   700 by (etac minor 1);
   701 qed "rangeE";
   702 
   703 
   704 (*** Set reasoning tools ***)
   705 
   706 
   707 (** Rewrite rules for boolean case-splitting: faster than 
   708 	addsplits[split_if]
   709 **)
   710 
   711 bind_thm ("split_if_eq1", read_instantiate [("P", "%x. x = ?b")] split_if);
   712 bind_thm ("split_if_eq2", read_instantiate [("P", "%x. ?a = x")] split_if);
   713 
   714 (*Split ifs on either side of the membership relation.
   715 	Not for Addsimps -- can cause goals to blow up!*)
   716 bind_thm ("split_if_mem1", 
   717     read_instantiate_sg (Theory.sign_of Set.thy) [("P", "%x. x : ?b")] split_if);
   718 bind_thm ("split_if_mem2", 
   719     read_instantiate_sg (Theory.sign_of Set.thy) [("P", "%x. ?a : x")] split_if);
   720 
   721 bind_thms ("split_ifs", [if_bool_eq_conj, split_if_eq1, split_if_eq2,
   722 		  split_if_mem1, split_if_mem2]);
   723 
   724 
   725 (*Each of these has ALREADY been added to simpset() above.*)
   726 bind_thms ("mem_simps", [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   727                  mem_Collect_eq, UN_iff, Union_iff, INT_iff, Inter_iff]);
   728 
   729 (*Would like to add these, but the existing code only searches for the 
   730   outer-level constant, which in this case is just "op :"; we instead need
   731   to use term-nets to associate patterns with rules.  Also, if a rule fails to
   732   apply, then the formula should be kept.
   733   [("uminus", Compl_iff RS iffD1), ("op -", [Diff_iff RS iffD1]), 
   734    ("op Int", [IntD1,IntD2]),
   735    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
   736  *)
   737 val mksimps_pairs =
   738   [("Ball",[bspec])] @ mksimps_pairs;
   739 
   740 simpset_ref() := simpset() setmksimps (mksimps mksimps_pairs);
   741 
   742 Addsimps[subset_UNIV, subset_refl];
   743 
   744 
   745 (*** The 'proper subset' relation (<) ***)
   746 
   747 Goalw [psubset_def] "!!A::'a set. [| A <= B; A ~= B |] ==> A<B";
   748 by (Blast_tac 1);
   749 qed "psubsetI";
   750 AddSIs [psubsetI];
   751 
   752 Goalw [psubset_def]
   753   "(A < insert x B) = (if x:B then A<B else if x:A then A-{x} < B else A<=B)";
   754 by (asm_simp_tac (simpset() addsimps [subset_insert_iff]) 1);
   755 by (Blast_tac 1); 
   756 qed "psubset_insert_iff";
   757 
   758 bind_thm ("psubset_eq", psubset_def RS meta_eq_to_obj_eq);
   759 
   760 bind_thm ("psubset_imp_subset", psubset_eq RS iffD1 RS conjunct1);
   761 
   762 Goal"[| (A::'a set) < B; B <= C |] ==> A < C";
   763 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   764 qed "psubset_subset_trans";
   765 
   766 Goal"[| (A::'a set) <= B; B < C|] ==> A < C";
   767 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   768 qed "subset_psubset_trans";
   769 
   770 Goalw [psubset_def] "A < B ==> EX b. b : (B - A)";
   771 by (Blast_tac 1);
   772 qed "psubset_imp_ex_mem";
   773 
   774 
   775 (* attributes *)
   776 
   777 local
   778 
   779 fun gen_rulify_prems x =
   780   Attrib.no_args (Drule.rule_attribute (fn _ => (standard o
   781     rule_by_tactic (REPEAT (ALLGOALS (resolve_tac [allI, ballI, impI])))))) x;
   782 
   783 in
   784 
   785 val rulify_prems_attrib_setup =
   786  [Attrib.add_attributes
   787   [("rulify_prems", (gen_rulify_prems, gen_rulify_prems), "put theorem into standard rule form")]];
   788 
   789 end;