src/Pure/context.ML
author wenzelm
Thu Jan 19 21:22:16 2006 +0100 (2006-01-19)
changeset 18711 cf020c54e2f5
parent 18678 dd0c569fa43d
child 18731 3989c3c41983
permissions -rw-r--r--
setup: theory -> theory;
use_output: Output.ML_errors;
     1 (*  Title:      Pure/context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Generic theory contexts with unique identity, arbitrarily typed data,
     6 development graph and history support.  Implicit theory contexts in ML.
     7 Generic proof contexts with arbitrarily typed data.
     8 *)
     9 
    10 signature BASIC_CONTEXT =
    11 sig
    12   type theory
    13   type theory_ref
    14   exception THEORY of string * theory list
    15   val context: theory -> unit
    16   val the_context: unit -> theory
    17 end;
    18 
    19 signature CONTEXT =
    20 sig
    21   include BASIC_CONTEXT
    22   (*theory context*)
    23   val theory_name: theory -> string
    24   val parents_of: theory -> theory list
    25   val ancestors_of: theory -> theory list
    26   val is_stale: theory -> bool
    27   val ProtoPureN: string
    28   val PureN: string
    29   val CPureN: string
    30   val draftN: string
    31   val exists_name: string -> theory -> bool
    32   val names_of: theory -> string list
    33   val pretty_thy: theory -> Pretty.T
    34   val string_of_thy: theory -> string
    35   val pprint_thy: theory -> pprint_args -> unit
    36   val pretty_abbrev_thy: theory -> Pretty.T
    37   val str_of_thy: theory -> string
    38   val check_thy: theory -> theory
    39   val eq_thy: theory * theory -> bool
    40   val subthy: theory * theory -> bool
    41   val joinable: theory * theory -> bool
    42   val merge: theory * theory -> theory                     (*exception TERM*)
    43   val merge_refs: theory_ref * theory_ref -> theory_ref    (*exception TERM*)
    44   val self_ref: theory -> theory_ref
    45   val deref: theory_ref -> theory
    46   val copy_thy: theory -> theory
    47   val checkpoint_thy: theory -> theory
    48   val finish_thy: theory -> theory
    49   val theory_data_of: theory -> string list
    50   val pre_pure_thy: theory
    51   val begin_thy: (theory -> Pretty.pp) -> string -> theory list -> theory
    52   (*ML theory context*)
    53   val get_context: unit -> theory option
    54   val set_context: theory option -> unit
    55   val reset_context: unit -> unit
    56   val setmp: theory option -> ('a -> 'b) -> 'a -> 'b
    57   val pass: theory option -> ('a -> 'b) -> 'a -> 'b * theory option
    58   val pass_theory: theory -> ('a -> 'b) -> 'a -> 'b * theory
    59   val save: ('a -> 'b) -> 'a -> 'b
    60   val >> : (theory -> theory) -> unit
    61   val ml_output: (string -> unit) * (string -> unit)
    62   val use_mltext: string -> bool -> theory option -> unit
    63   val use_mltext_theory: string -> bool -> theory -> theory
    64   val use_let: string -> string -> string -> theory -> theory
    65   val add_setup: (theory -> theory) -> unit
    66   val setup: unit -> theory -> theory
    67   (*proof context*)
    68   type proof
    69   val theory_of_proof: proof -> theory
    70   val transfer_proof: theory -> proof -> proof
    71   val init_proof: theory -> proof
    72   val proof_data_of: theory -> string list
    73   (*generic context*)
    74   datatype generic = Theory of theory | Proof of proof
    75   val cases: (theory -> 'a) -> (proof -> 'a) -> generic -> 'a
    76   val the_theory: generic -> theory
    77   val the_proof: generic -> proof
    78   val map_theory: (generic -> generic) -> theory -> theory
    79   val map_proof: (generic -> generic) -> proof -> proof
    80   val theory_of: generic -> theory   (*total*)
    81   val proof_of: generic -> proof     (*total*)
    82 end;
    83 
    84 signature PRIVATE_CONTEXT =
    85 sig
    86   include CONTEXT
    87   structure TheoryData:
    88   sig
    89     val declare: string -> Object.T -> (Object.T -> Object.T) -> (Object.T -> Object.T) ->
    90       (Pretty.pp -> Object.T * Object.T -> Object.T) -> serial
    91     val init: serial -> theory -> theory
    92     val get: serial -> (Object.T -> 'a) -> theory -> 'a
    93     val put: serial -> ('a -> Object.T) -> 'a -> theory -> theory
    94   end
    95   structure ProofData:
    96   sig
    97     val declare: string -> (theory -> Object.T) -> serial
    98     val init: serial -> theory -> theory
    99     val get: serial -> (Object.T -> 'a) -> proof -> 'a
   100     val put: serial -> ('a -> Object.T) -> 'a -> proof -> proof
   101   end
   102 end;
   103 
   104 structure Context: PRIVATE_CONTEXT =
   105 struct
   106 
   107 (*** theory context ***)
   108 
   109 (** theory data **)
   110 
   111 (* data kinds and access methods *)
   112 
   113 local
   114 
   115 type kind =
   116  {name: string,
   117   empty: Object.T,
   118   copy: Object.T -> Object.T,
   119   extend: Object.T -> Object.T,
   120   merge: Pretty.pp -> Object.T * Object.T -> Object.T};
   121 
   122 val kinds = ref (Inttab.empty: kind Inttab.table);
   123 
   124 fun invoke meth_name meth_fn k =
   125   (case Inttab.lookup (! kinds) k of
   126     SOME kind => meth_fn kind |> transform_failure (fn exn =>
   127       EXCEPTION (exn, "Theory data method " ^ #name kind ^ "." ^ meth_name ^ " failed"))
   128   | NONE => sys_error ("Invalid theory data identifier " ^ string_of_int k));
   129 
   130 in
   131 
   132 fun invoke_name k    = invoke "name" (K o #name) k ();
   133 fun invoke_empty k   = invoke "empty" (K o #empty) k ();
   134 val invoke_copy      = invoke "copy" #copy;
   135 val invoke_extend    = invoke "extend" #extend;
   136 fun invoke_merge pp  = invoke "merge" (fn kind => #merge kind pp);
   137 
   138 fun declare_theory_data name empty copy extend merge =
   139   let
   140     val k = serial ();
   141     val kind = {name = name, empty = empty, copy = copy, extend = extend, merge = merge};
   142     val _ = conditional (Inttab.exists (equal name o #name o #2) (! kinds)) (fn () =>
   143       warning ("Duplicate declaration of theory data " ^ quote name));
   144     val _ = change kinds (Inttab.update (k, kind));
   145   in k end;
   146 
   147 val copy_data = Inttab.map' invoke_copy;
   148 val extend_data = Inttab.map' invoke_extend;
   149 fun merge_data pp = Inttab.join (SOME oo invoke_merge pp) o pairself extend_data;
   150 
   151 end;
   152 
   153 
   154 
   155 (** datatype theory **)
   156 
   157 datatype theory =
   158   Theory of
   159    (*identity*)
   160    {self: theory ref option,            (*dynamic self reference -- follows theory changes*)
   161     id: serial * string,                (*identifier of this theory*)
   162     ids: string Inttab.table,           (*identifiers of ancestors*)
   163     iids: string Inttab.table} *        (*identifiers of intermediate checkpoints*)
   164    (*data*)
   165    {theory: Object.T Inttab.table,      (*theory data record*)
   166     proof: unit Inttab.table} *         (*proof data kinds*)
   167    (*ancestry*)
   168    {parents: theory list,               (*immediate predecessors*)
   169     ancestors: theory list} *           (*all predecessors*)
   170    (*history*)
   171    {name: string,                       (*prospective name of finished theory*)
   172     version: int,                       (*checkpoint counter*)
   173     intermediates: theory list};        (*intermediate checkpoints*)
   174 
   175 exception THEORY of string * theory list;
   176 
   177 fun rep_theory (Theory args) = args;
   178 
   179 val identity_of = #1 o rep_theory;
   180 val data_of     = #2 o rep_theory;
   181 val ancestry_of = #3 o rep_theory;
   182 val history_of  = #4 o rep_theory;
   183 
   184 fun make_identity self id ids iids = {self = self, id = id, ids = ids, iids = iids};
   185 fun make_data theory proof = {theory = theory, proof = proof};
   186 fun make_ancestry parents ancestors = {parents = parents, ancestors = ancestors};
   187 fun make_history name vers ints = {name = name, version = vers, intermediates = ints};
   188 
   189 fun map_theory f {theory, proof} = make_data (f theory) proof;
   190 fun map_proof f {theory, proof} = make_data theory (f proof);
   191 
   192 val the_self = the o #self o identity_of;
   193 val parents_of = #parents o ancestry_of;
   194 val ancestors_of = #ancestors o ancestry_of;
   195 val theory_name = #name o history_of;
   196 
   197 
   198 (* staleness *)
   199 
   200 fun eq_id ((i: int, _), (j, _)) = (i = j);
   201 
   202 fun is_stale
   203     (Theory ({self = SOME (ref (Theory ({id = id', ...}, _, _, _))), id, ...}, _, _, _)) =
   204       not (eq_id (id, id'))
   205   | is_stale (Theory ({self = NONE, ...}, _, _, _)) = true;
   206 
   207 fun vitalize (thy as Theory ({self = SOME r, ...}, _, _, _)) = (r := thy; thy)
   208   | vitalize (thy as Theory ({self = NONE, id, ids, iids}, data, ancestry, history)) =
   209       let
   210         val r = ref thy;
   211         val thy' = Theory (make_identity (SOME r) id ids iids, data, ancestry, history);
   212       in r := thy'; thy' end;
   213 
   214 
   215 (* names *)
   216 
   217 val ProtoPureN = "ProtoPure";
   218 val PureN = "Pure";
   219 val CPureN = "CPure";
   220 
   221 val draftN = "#";
   222 fun draft_id (_, name) = (name = draftN);
   223 val is_draft = draft_id o #id o identity_of;
   224 
   225 fun exists_name name (Theory ({id, ids, iids, ...}, _, _, _)) =
   226   name = #2 id orelse
   227   Inttab.exists (equal name o #2) ids orelse
   228   Inttab.exists (equal name o #2) iids;
   229 
   230 fun names_of (Theory ({id, ids, iids, ...}, _, _, _)) =
   231   rev (#2 id :: Inttab.fold (cons o #2) iids (Inttab.fold (cons o #2) ids []));
   232 
   233 fun pretty_thy thy =
   234   Pretty.str_list "{" "}" (names_of thy @ (if is_stale thy then ["!"] else []));
   235 
   236 val string_of_thy = Pretty.string_of o pretty_thy;
   237 val pprint_thy = Pretty.pprint o pretty_thy;
   238 
   239 fun pretty_abbrev_thy thy =
   240   let
   241     val names = names_of thy;
   242     val n = length names;
   243     val abbrev = if n > 5 then "..." :: List.drop (names, n - 5) else names;
   244   in Pretty.str_list "{" "}" abbrev end;
   245 
   246 val str_of_thy = Pretty.str_of o pretty_abbrev_thy;
   247 
   248 
   249 (* consistency *)    (*exception TERM*)
   250 
   251 fun check_thy thy =
   252   if is_stale thy then
   253     raise TERM ("Stale theory encountered:\n" ^ string_of_thy thy, [])
   254   else thy;
   255 
   256 fun check_ins id ids =
   257   if draft_id id orelse Inttab.defined ids (#1 id) then ids
   258   else if Inttab.exists (equal (#2 id) o #2) ids then
   259     raise TERM ("Different versions of theory component " ^ quote (#2 id), [])
   260   else Inttab.update id ids;
   261 
   262 fun check_insert intermediate id (ids, iids) =
   263   let val ids' = check_ins id ids and iids' = check_ins id iids
   264   in if intermediate then (ids, iids') else (ids', iids) end;
   265 
   266 fun check_merge
   267     (Theory ({id = id1, ids = ids1, iids = iids1, ...}, _, _, history1))
   268     (Theory ({id = id2, ids = ids2, iids = iids2, ...}, _, _, history2)) =
   269   (Inttab.fold check_ins ids2 ids1, Inttab.fold check_ins iids2 iids1)
   270   |> check_insert (#version history1 > 0) id1
   271   |> check_insert (#version history2 > 0) id2;
   272 
   273 
   274 (* equality and inclusion *)
   275 
   276 val eq_thy = eq_id o pairself (#id o identity_of o check_thy);
   277 
   278 fun proper_subthy
   279     (Theory ({id = (i, _), ...}, _, _, _), Theory ({ids, iids, ...}, _, _, _)) =
   280   Inttab.defined ids i orelse Inttab.defined iids i;
   281 
   282 fun subthy thys = eq_thy thys orelse proper_subthy thys;
   283 
   284 fun joinable (thy1, thy2) = subthy (thy1, thy2) orelse subthy (thy2, thy1);
   285 
   286 
   287 (* theory references *)
   288 
   289 (*theory_ref provides a safe way to store dynamic references to a
   290   theory in external data structures -- a plain theory value would
   291   become stale as the self reference moves on*)
   292 
   293 datatype theory_ref = TheoryRef of theory ref;
   294 
   295 val self_ref = TheoryRef o the_self o check_thy;
   296 fun deref (TheoryRef (ref thy)) = thy;
   297 
   298 
   299 (* trivial merge *)    (*exception TERM*)
   300 
   301 fun merge (thy1, thy2) =
   302   if eq_thy (thy1, thy2) then thy1
   303   else if proper_subthy (thy2, thy1) then thy1
   304   else if proper_subthy (thy1, thy2) then thy2
   305   else (check_merge thy1 thy2;
   306     raise TERM (cat_lines ["Attempt to perform non-trivial merge of theories:",
   307       str_of_thy thy1, str_of_thy thy2], []));
   308 
   309 fun merge_refs (ref1, ref2) =
   310   if ref1 = ref2 then ref1
   311   else self_ref (merge (deref ref1, deref ref2));
   312 
   313 
   314 
   315 (** build theories **)
   316 
   317 (* primitives *)
   318 
   319 fun create_thy name self id ids iids data ancestry history =
   320   let
   321     val {version, name = _, intermediates = _} = history;
   322     val intermediate = version > 0;
   323     val (ids', iids') = check_insert intermediate id (ids, iids);
   324     val id' = (serial (), name);
   325     val _ = check_insert intermediate id' (ids', iids');
   326     val identity' = make_identity self id' ids' iids';
   327   in vitalize (Theory (identity', data, ancestry, history)) end;
   328 
   329 fun change_thy name f (thy as Theory ({self, id, ids, iids}, data, ancestry, history)) =
   330   let
   331     val _ = check_thy thy;
   332     val (self', data', ancestry') =
   333       if is_draft thy then (self, data, ancestry)    (*destructive change!*)
   334       else if #version history > 0
   335       then (NONE, map_theory copy_data data, ancestry)
   336       else (NONE, map_theory extend_data data, make_ancestry [thy] (thy :: #ancestors ancestry));
   337     val data'' = f data';
   338   in create_thy name self' id ids iids data'' ancestry' history end;
   339 
   340 fun name_thy name = change_thy name I;
   341 val modify_thy = change_thy draftN;
   342 val extend_thy = modify_thy I;
   343 
   344 fun copy_thy (thy as Theory ({id, ids, iids, ...}, data, ancestry, history)) =
   345   (check_thy thy;
   346     create_thy draftN NONE id ids iids (map_theory copy_data data) ancestry history);
   347 
   348 val pre_pure_thy = create_thy draftN NONE (serial (), draftN) Inttab.empty Inttab.empty
   349   (make_data Inttab.empty Inttab.empty) (make_ancestry [] []) (make_history ProtoPureN 0 []);
   350 
   351 
   352 (* named theory nodes *)
   353 
   354 fun merge_thys pp (thy1, thy2) =
   355   if exists_name CPureN thy1 <> exists_name CPureN thy2 then
   356     error "Cannot merge Pure and CPure developments"
   357   else
   358     let
   359       val (ids, iids) = check_merge thy1 thy2;
   360       val data1 = data_of thy1 and data2 = data_of thy2;
   361       val data = make_data
   362         (merge_data (pp thy1) (#theory data1, #theory data2))
   363         (Inttab.merge (K true) (#proof data1, #proof data2));
   364       val ancestry = make_ancestry [] [];
   365       val history = make_history "" 0 [];
   366     in create_thy draftN NONE (serial (), draftN) ids iids data ancestry history end;
   367 
   368 fun maximal_thys thys =
   369   thys |> filter (fn thy => not (exists (fn thy' => proper_subthy (thy, thy')) thys));
   370 
   371 fun begin_thy pp name imports =
   372   if name = draftN then error ("Illegal theory name: " ^ quote draftN)
   373   else
   374     let
   375       val parents =
   376         maximal_thys (gen_distinct eq_thy (map check_thy imports));
   377       val ancestors = gen_distinct eq_thy (parents @ List.concat (map ancestors_of parents));
   378       val Theory ({id, ids, iids, ...}, data, _, _) =
   379         (case parents of
   380           [] => error "No parent theories"
   381         | [thy] => extend_thy thy
   382         | thy :: thys => Library.foldl (merge_thys pp) (thy, thys));
   383       val ancestry = make_ancestry parents ancestors;
   384       val history = make_history name 0 [];
   385     in create_thy draftN NONE id ids iids data ancestry history end;
   386 
   387 
   388 (* undoable checkpoints *)
   389 
   390 fun checkpoint_thy thy =
   391   if not (is_draft thy) then thy
   392   else
   393     let
   394       val {name, version, intermediates} = history_of thy;
   395       val thy' as Theory (identity', data', ancestry', _) =
   396         name_thy (name ^ ":" ^ string_of_int version) thy;
   397       val history' = make_history name (version + 1) (thy' :: intermediates);
   398     in vitalize (Theory (identity', data', ancestry', history')) end;
   399 
   400 fun finish_thy thy =
   401   let
   402     val {name, version, intermediates} = history_of thy;
   403     val rs = map (the_self o check_thy) intermediates;
   404     val thy' as Theory ({self, id, ids, ...}, data', ancestry', _) = name_thy name thy;
   405     val identity' = make_identity self id ids Inttab.empty;
   406     val history' = make_history name 0 [];
   407     val thy'' = vitalize (Theory (identity', data', ancestry', history'));
   408     val _ = List.app (fn r => r := thy'') rs;
   409   in thy'' end;
   410 
   411 
   412 (* theory data *)
   413 
   414 fun dest_data name_of tab =
   415   map name_of (Inttab.keys tab)
   416   |> map (rpair ()) |> Symtab.make_multi |> Symtab.dest
   417   |> map (apsnd length)
   418   |> map (fn (name, 1) => name | (name, n) => name ^ enclose "[" "]" (string_of_int n));
   419 
   420 val theory_data_of = dest_data invoke_name o #theory o data_of;
   421 
   422 structure TheoryData =
   423 struct
   424 
   425 val declare = declare_theory_data;
   426 
   427 fun get k dest thy =
   428   (case Inttab.lookup (#theory (data_of thy)) k of
   429     SOME x => (dest x handle Match =>
   430       error ("Failed to access theory data " ^ quote (invoke_name k)))
   431   | NONE => error ("Uninitialized theory data " ^ quote (invoke_name k)));
   432 
   433 fun put k mk x = modify_thy (map_theory (Inttab.update (k, mk x)));
   434 fun init k = put k I (invoke_empty k);
   435 
   436 end;
   437 
   438 
   439 
   440 (*** ML theory context ***)
   441 
   442 local
   443   val current_theory = ref (NONE: theory option);
   444 in
   445   fun get_context () = ! current_theory;
   446   fun set_context opt_thy = current_theory := opt_thy;
   447   fun setmp opt_thy f x = Library.setmp current_theory opt_thy f x;
   448 end;
   449 
   450 fun the_context () =
   451   (case get_context () of
   452     SOME thy => thy
   453   | _ => error "Unknown theory context");
   454 
   455 fun context thy = set_context (SOME thy);
   456 fun reset_context () = set_context NONE;
   457 
   458 fun pass opt_thy f x =
   459   setmp opt_thy (fn x => let val y = f x in (y, get_context ()) end) x;
   460 
   461 fun pass_theory thy f x =
   462   (case pass (SOME thy) f x of
   463     (y, SOME thy') => (y, thy')
   464   | (_, NONE) => error "Lost theory context in ML");
   465 
   466 fun save f x = setmp (get_context ()) f x;
   467 
   468 
   469 (* map context *)
   470 
   471 nonfix >>;
   472 fun >> f = set_context (SOME (f (the_context ())));
   473 
   474 
   475 (* use ML text *)
   476 
   477 val ml_output = (writeln, Output.error_msg);
   478 
   479 fun use_output verbose txt =
   480   Output.ML_errors (use_text ml_output verbose) (Symbol.escape txt);
   481 
   482 fun use_mltext txt verbose opt_thy = setmp opt_thy (fn () => use_output verbose txt) ();
   483 fun use_mltext_theory txt verbose thy = #2 (pass_theory thy (use_output verbose) txt);
   484 
   485 fun use_context txt = use_mltext_theory ("Context.>> (" ^ txt ^ ");") false;
   486 
   487 fun use_let bind body txt =
   488   use_context ("let " ^ bind ^ " = " ^ txt ^ " in\n" ^ body ^ " end");
   489 
   490 
   491 (* delayed theory setup *)
   492 
   493 local
   494   val setup_fn = ref (I: theory -> theory);
   495 in
   496   fun add_setup f = setup_fn := (! setup_fn #> f);
   497   fun setup () = let val f = ! setup_fn in setup_fn := I; f end;
   498 end;
   499 
   500 
   501 
   502 (*** proof context ***)
   503 
   504 (* datatype proof *)
   505 
   506 datatype proof = Proof of theory_ref * Object.T Inttab.table;
   507 
   508 fun theory_of_proof (Proof (thy_ref, _)) = deref thy_ref;
   509 fun data_of_proof (Proof (_, data)) = data;
   510 fun map_prf f (Proof (thy_ref, data)) = Proof (thy_ref, f data);
   511 
   512 fun transfer_proof thy' (prf as Proof (thy_ref, data)) =
   513   if not (subthy (deref thy_ref, thy')) then
   514     error "transfer proof context: no a super theory"
   515   else Proof (self_ref thy', data);
   516 
   517 
   518 (* proof data kinds *)
   519 
   520 local
   521 
   522 type kind =
   523  {name: string,
   524   init: theory -> Object.T};
   525 
   526 val kinds = ref (Inttab.empty: kind Inttab.table);
   527 
   528 fun invoke meth_name meth_fn k =
   529   (case Inttab.lookup (! kinds) k of
   530     SOME kind => meth_fn kind |> transform_failure (fn exn =>
   531       EXCEPTION (exn, "Proof data method " ^ #name kind ^ "." ^ meth_name ^ " failed"))
   532   | NONE => sys_error ("Invalid proof data identifier " ^ string_of_int k));
   533 
   534 fun invoke_name k = invoke "name" (K o #name) k ();
   535 val invoke_init   = invoke "init" #init;
   536 
   537 in
   538 
   539 val proof_data_of = dest_data invoke_name o #proof o data_of;
   540 
   541 fun init_proof thy =
   542   Proof (self_ref thy, Inttab.map' (fn k => fn _ => invoke_init k thy) (#proof (data_of thy)));
   543 
   544 structure ProofData =
   545 struct
   546 
   547 fun declare name init =
   548   let
   549     val k = serial ();
   550     val kind = {name = name, init = init};
   551     val _ = conditional (Inttab.exists (equal name o #name o #2) (! kinds)) (fn () =>
   552       warning ("Duplicate declaration of proof data " ^ quote name));
   553     val _ = change kinds (Inttab.update (k, kind));
   554   in k end;
   555 
   556 fun init k = modify_thy (map_proof (Inttab.update (k, ())));
   557 
   558 fun get k dest prf =
   559   (case Inttab.lookup (data_of_proof prf) k of
   560     SOME x => (dest x handle Match =>
   561       error ("Failed to access proof data " ^ quote (invoke_name k)))
   562   | NONE => error ("Uninitialized proof data " ^ quote (invoke_name k)));
   563 
   564 fun put k mk x = map_prf (Inttab.update (k, mk x));
   565 
   566 end;
   567 
   568 end;
   569 
   570 
   571 
   572 (*** generic context ***)
   573 
   574 datatype generic = Theory of theory | Proof of proof;
   575 
   576 fun cases f _ (Theory thy) = f thy
   577   | cases _ g (Proof prf) = g prf;
   578 
   579 val the_theory = cases I (fn _ => raise Fail "Bad generic context: theory expected");
   580 val the_proof = cases (fn _ => raise Fail "Bad generic context: proof context expected") I;
   581 
   582 fun map_theory f = the_theory o f o Theory;
   583 fun map_proof f = the_proof o f o Proof;
   584 
   585 val theory_of = cases I theory_of_proof;
   586 val proof_of = cases init_proof I;
   587 
   588 end;
   589 
   590 structure BasicContext: BASIC_CONTEXT = Context;
   591 open BasicContext;
   592 
   593 
   594 
   595 (*** type-safe interfaces for data declarations ***)
   596 
   597 (** theory data **)
   598 
   599 signature THEORY_DATA_ARGS =
   600 sig
   601   val name: string
   602   type T
   603   val empty: T
   604   val copy: T -> T
   605   val extend: T -> T
   606   val merge: Pretty.pp -> T * T -> T
   607   val print: theory -> T -> unit
   608 end;
   609 
   610 signature THEORY_DATA =
   611 sig
   612   type T
   613   val init: theory -> theory
   614   val print: theory -> unit
   615   val get: theory -> T
   616   val get_sg: theory -> T    (*obsolete*)
   617   val put: T -> theory -> theory
   618   val map: (T -> T) -> theory -> theory
   619 end;
   620 
   621 functor TheoryDataFun(Data: THEORY_DATA_ARGS): THEORY_DATA =
   622 struct
   623 
   624 structure TheoryData = Context.TheoryData;
   625 
   626 type T = Data.T;
   627 exception Data of T;
   628 
   629 val kind = TheoryData.declare Data.name
   630   (Data Data.empty)
   631   (fn Data x => Data (Data.copy x))
   632   (fn Data x => Data (Data.extend x))
   633   (fn pp => fn (Data x1, Data x2) => Data (Data.merge pp (x1, x2)));
   634 
   635 val init = TheoryData.init kind;
   636 val get = TheoryData.get kind (fn Data x => x);
   637 val get_sg = get;
   638 fun print thy = Data.print thy (get thy);
   639 val put = TheoryData.put kind Data;
   640 fun map f thy = put (f (get thy)) thy;
   641 
   642 end;
   643 
   644 
   645 
   646 (** proof data **)
   647 
   648 signature PROOF_DATA_ARGS =
   649 sig
   650   val name: string
   651   type T
   652   val init: theory -> T
   653   val print: Context.proof -> T -> unit
   654 end;
   655 
   656 signature PROOF_DATA =
   657 sig
   658   type T
   659   val init: theory -> theory
   660   val print: Context.proof -> unit
   661   val get: Context.proof -> T
   662   val put: T -> Context.proof -> Context.proof
   663   val map: (T -> T) -> Context.proof -> Context.proof
   664 end;
   665 
   666 functor ProofDataFun(Data: PROOF_DATA_ARGS): PROOF_DATA =
   667 struct
   668 
   669 structure ProofData = Context.ProofData;
   670 
   671 type T = Data.T;
   672 exception Data of T;
   673 
   674 val kind = ProofData.declare Data.name (Data o Data.init);
   675 
   676 val init = ProofData.init kind;
   677 val get = ProofData.get kind (fn Data x => x);
   678 fun print prf = Data.print prf (get prf);
   679 val put = ProofData.put kind Data;
   680 fun map f prf = put (f (get prf)) prf;
   681 
   682 end;
   683 
   684 
   685 
   686 (** generic data **)
   687 
   688 signature GENERIC_DATA_ARGS =
   689 sig
   690   val name: string
   691   type T
   692   val empty: T
   693   val extend: T -> T
   694   val merge: Pretty.pp -> T * T -> T
   695   val print: Context.generic -> T -> unit
   696 end;
   697 
   698 signature GENERIC_DATA =
   699 sig
   700   type T
   701   val init: theory -> theory
   702   val get: Context.generic -> T
   703   val put: T -> Context.generic -> Context.generic
   704   val map: (T -> T) -> Context.generic -> Context.generic
   705   val print: Context.generic -> unit
   706 end;
   707 
   708 functor GenericDataFun(Data: GENERIC_DATA_ARGS): GENERIC_DATA =
   709 struct
   710 
   711 structure ThyData = TheoryDataFun(open Data val copy = I fun print _ _ = ());
   712 structure PrfData =
   713   ProofDataFun(val name = Data.name type T = Data.T val init = ThyData.get fun print _ _ = ());
   714 
   715 type T = Data.T;
   716 val init = ThyData.init #> PrfData.init;
   717 
   718 fun get (Context.Theory thy) = ThyData.get thy
   719   | get (Context.Proof prf) = PrfData.get prf;
   720 
   721 fun put x (Context.Theory thy) = Context.Theory (ThyData.put x thy)
   722   | put x (Context.Proof prf) = Context.Proof (PrfData.put x prf);
   723 
   724 fun map f ctxt = put (f (get ctxt)) ctxt;
   725 
   726 fun print ctxt = Data.print ctxt (get ctxt);
   727 
   728 end;
   729 
   730 
   731 (*hide private interface*)
   732 structure Context: CONTEXT = Context;