src/HOL/Fun.thy
author hoelzl
Mon Nov 22 10:34:33 2010 +0100 (2010-11-22)
changeset 40702 cf26dd7395e4
parent 40602 91e583511113
child 40703 d1fc454d6735
permissions -rw-r--r--
Replace surj by abbreviation; remove surj_on.
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Copyright   1994  University of Cambridge
     4 *)
     5 
     6 header {* Notions about functions *}
     7 
     8 theory Fun
     9 imports Complete_Lattice
    10 begin
    11 
    12 text{*As a simplification rule, it replaces all function equalities by
    13   first-order equalities.*}
    14 lemma fun_eq_iff: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
    15 apply (rule iffI)
    16 apply (simp (no_asm_simp))
    17 apply (rule ext)
    18 apply (simp (no_asm_simp))
    19 done
    20 
    21 lemma apply_inverse:
    22   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    23   by auto
    24 
    25 
    26 subsection {* The Identity Function @{text id} *}
    27 
    28 definition
    29   id :: "'a \<Rightarrow> 'a"
    30 where
    31   "id = (\<lambda>x. x)"
    32 
    33 lemma id_apply [simp]: "id x = x"
    34   by (simp add: id_def)
    35 
    36 lemma image_ident [simp]: "(%x. x) ` Y = Y"
    37 by blast
    38 
    39 lemma image_id [simp]: "id ` Y = Y"
    40 by (simp add: id_def)
    41 
    42 lemma vimage_ident [simp]: "(%x. x) -` Y = Y"
    43 by blast
    44 
    45 lemma vimage_id [simp]: "id -` A = A"
    46 by (simp add: id_def)
    47 
    48 
    49 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    50 
    51 definition
    52   comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55)
    53 where
    54   "f o g = (\<lambda>x. f (g x))"
    55 
    56 notation (xsymbols)
    57   comp  (infixl "\<circ>" 55)
    58 
    59 notation (HTML output)
    60   comp  (infixl "\<circ>" 55)
    61 
    62 text{*compatibility*}
    63 lemmas o_def = comp_def
    64 
    65 lemma o_apply [simp]: "(f o g) x = f (g x)"
    66 by (simp add: comp_def)
    67 
    68 lemma o_assoc: "f o (g o h) = f o g o h"
    69 by (simp add: comp_def)
    70 
    71 lemma id_o [simp]: "id o g = g"
    72 by (simp add: comp_def)
    73 
    74 lemma o_id [simp]: "f o id = f"
    75 by (simp add: comp_def)
    76 
    77 lemma o_eq_dest:
    78   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    79   by (simp only: o_def) (fact fun_cong)
    80 
    81 lemma o_eq_elim:
    82   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    83   by (erule meta_mp) (fact o_eq_dest) 
    84 
    85 lemma image_compose: "(f o g) ` r = f`(g`r)"
    86 by (simp add: comp_def, blast)
    87 
    88 lemma vimage_compose: "(g \<circ> f) -` x = f -` (g -` x)"
    89   by auto
    90 
    91 lemma UN_o: "UNION A (g o f) = UNION (f`A) g"
    92 by (unfold comp_def, blast)
    93 
    94 
    95 subsection {* The Forward Composition Operator @{text fcomp} *}
    96 
    97 definition
    98   fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60)
    99 where
   100   "f \<circ>> g = (\<lambda>x. g (f x))"
   101 
   102 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
   103   by (simp add: fcomp_def)
   104 
   105 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
   106   by (simp add: fcomp_def)
   107 
   108 lemma id_fcomp [simp]: "id \<circ>> g = g"
   109   by (simp add: fcomp_def)
   110 
   111 lemma fcomp_id [simp]: "f \<circ>> id = f"
   112   by (simp add: fcomp_def)
   113 
   114 code_const fcomp
   115   (Eval infixl 1 "#>")
   116 
   117 no_notation fcomp (infixl "\<circ>>" 60)
   118 
   119 
   120 subsection {* Mapping functions *}
   121 
   122 definition map_fun :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'c \<Rightarrow> 'd" where
   123   "map_fun f g h = g \<circ> h \<circ> f"
   124 
   125 lemma map_fun_apply [simp]:
   126   "map_fun f g h x = g (h (f x))"
   127   by (simp add: map_fun_def)
   128 
   129 type_mapper map_fun
   130   by (simp_all add: fun_eq_iff)
   131 
   132 
   133 subsection {* Injectivity and Bijectivity *}
   134 
   135 definition inj_on :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> bool" where -- "injective"
   136   "inj_on f A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. f x = f y \<longrightarrow> x = y)"
   137 
   138 definition bij_betw :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool" where -- "bijective"
   139   "bij_betw f A B \<longleftrightarrow> inj_on f A \<and> f ` A = B"
   140 
   141 text{*A common special case: functions injective, surjective or bijective over
   142 the entire domain type.*}
   143 
   144 abbreviation
   145   "inj f \<equiv> inj_on f UNIV"
   146 
   147 abbreviation surj :: "('a \<Rightarrow> 'b) \<Rightarrow> bool" where -- "surjective"
   148   "surj f \<equiv> (range f = UNIV)"
   149 
   150 abbreviation
   151   "bij f \<equiv> bij_betw f UNIV UNIV"
   152 
   153 lemma injI:
   154   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   155   shows "inj f"
   156   using assms unfolding inj_on_def by auto
   157 
   158 text{*For Proofs in @{text "Tools/Datatype/datatype_rep_proofs"}*}
   159 lemma datatype_injI:
   160     "(!! x. ALL y. f(x) = f(y) --> x=y) ==> inj(f)"
   161 by (simp add: inj_on_def)
   162 
   163 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   164   by (unfold inj_on_def, blast)
   165 
   166 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   167 by (simp add: inj_on_def)
   168 
   169 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   170 by (force simp add: inj_on_def)
   171 
   172 lemma inj_comp:
   173   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   174   by (simp add: inj_on_def)
   175 
   176 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   177   by (simp add: inj_on_def fun_eq_iff)
   178 
   179 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   180 by (simp add: inj_on_eq_iff)
   181 
   182 lemma inj_on_id[simp]: "inj_on id A"
   183   by (simp add: inj_on_def)
   184 
   185 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   186 by (simp add: inj_on_def)
   187 
   188 lemma surj_id: "surj id"
   189 by simp
   190 
   191 lemma bij_id[simp]: "bij id"
   192 by (simp add: bij_betw_def)
   193 
   194 lemma inj_onI:
   195     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   196 by (simp add: inj_on_def)
   197 
   198 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   199 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   200 
   201 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   202 by (unfold inj_on_def, blast)
   203 
   204 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   205 by (blast dest!: inj_onD)
   206 
   207 lemma comp_inj_on:
   208      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   209 by (simp add: comp_def inj_on_def)
   210 
   211 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   212 apply(simp add:inj_on_def image_def)
   213 apply blast
   214 done
   215 
   216 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   217   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   218 apply(unfold inj_on_def)
   219 apply blast
   220 done
   221 
   222 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   223 by (unfold inj_on_def, blast)
   224 
   225 lemma inj_singleton: "inj (%s. {s})"
   226 by (simp add: inj_on_def)
   227 
   228 lemma inj_on_empty[iff]: "inj_on f {}"
   229 by(simp add: inj_on_def)
   230 
   231 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   232 by (unfold inj_on_def, blast)
   233 
   234 lemma inj_on_Un:
   235  "inj_on f (A Un B) =
   236   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   237 apply(unfold inj_on_def)
   238 apply (blast intro:sym)
   239 done
   240 
   241 lemma inj_on_insert[iff]:
   242   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   243 apply(unfold inj_on_def)
   244 apply (blast intro:sym)
   245 done
   246 
   247 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   248 apply(unfold inj_on_def)
   249 apply (blast)
   250 done
   251 
   252 lemma surj_def: "surj f \<longleftrightarrow> (\<forall>y. \<exists>x. y = f x)"
   253   by auto
   254 
   255 lemma surjI: assumes *: "\<And> x. g (f x) = x" shows "surj g"
   256   using *[symmetric] by auto
   257 
   258 lemma surjD: "surj f \<Longrightarrow> \<exists>x. y = f x"
   259   by (simp add: surj_def)
   260 
   261 lemma surjE: "surj f \<Longrightarrow> (\<And>x. y = f x \<Longrightarrow> C) \<Longrightarrow> C"
   262   by (simp add: surj_def, blast)
   263 
   264 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   265 apply (simp add: comp_def surj_def, clarify)
   266 apply (drule_tac x = y in spec, clarify)
   267 apply (drule_tac x = x in spec, blast)
   268 done
   269 
   270 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
   271   unfolding bij_betw_def by auto
   272 
   273 lemma bij_def: "bij f \<longleftrightarrow> inj f \<and> surj f"
   274   unfolding bij_betw_def ..
   275 
   276 lemma bijI: "[| inj f; surj f |] ==> bij f"
   277 by (simp add: bij_def)
   278 
   279 lemma bij_is_inj: "bij f ==> inj f"
   280 by (simp add: bij_def)
   281 
   282 lemma bij_is_surj: "bij f ==> surj f"
   283 by (simp add: bij_def)
   284 
   285 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   286 by (simp add: bij_betw_def)
   287 
   288 lemma bij_betw_trans:
   289   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   290 by(auto simp add:bij_betw_def comp_inj_on)
   291 
   292 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   293   by (rule bij_betw_trans)
   294 
   295 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   296 proof -
   297   have i: "inj_on f A" and s: "f ` A = B"
   298     using assms by(auto simp:bij_betw_def)
   299   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   300   { fix a b assume P: "?P b a"
   301     hence ex1: "\<exists>a. ?P b a" using s unfolding image_def by blast
   302     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   303     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   304   } note g = this
   305   have "inj_on ?g B"
   306   proof(rule inj_onI)
   307     fix x y assume "x:B" "y:B" "?g x = ?g y"
   308     from s `x:B` obtain a1 where a1: "?P x a1" unfolding image_def by blast
   309     from s `y:B` obtain a2 where a2: "?P y a2" unfolding image_def by blast
   310     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   311   qed
   312   moreover have "?g ` B = A"
   313   proof(auto simp:image_def)
   314     fix b assume "b:B"
   315     with s obtain a where P: "?P b a" unfolding image_def by blast
   316     thus "?g b \<in> A" using g[OF P] by auto
   317   next
   318     fix a assume "a:A"
   319     then obtain b where P: "?P b a" using s unfolding image_def by blast
   320     then have "b:B" using s unfolding image_def by blast
   321     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   322   qed
   323   ultimately show ?thesis by(auto simp:bij_betw_def)
   324 qed
   325 
   326 lemma bij_betw_combine:
   327   assumes "bij_betw f A B" "bij_betw f C D" "B \<inter> D = {}"
   328   shows "bij_betw f (A \<union> C) (B \<union> D)"
   329   using assms unfolding bij_betw_def inj_on_Un image_Un by auto
   330 
   331 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   332 by simp
   333 
   334 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   335 by (simp add: inj_on_def, blast)
   336 
   337 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   338 by (blast intro: sym)
   339 
   340 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   341 by (unfold inj_on_def, blast)
   342 
   343 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   344 apply (unfold bij_def)
   345 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   346 done
   347 
   348 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   349 by(blast dest: inj_onD)
   350 
   351 lemma inj_on_image_Int:
   352    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   353 apply (simp add: inj_on_def, blast)
   354 done
   355 
   356 lemma inj_on_image_set_diff:
   357    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   358 apply (simp add: inj_on_def, blast)
   359 done
   360 
   361 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   362 by (simp add: inj_on_def, blast)
   363 
   364 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   365 by (simp add: inj_on_def, blast)
   366 
   367 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   368 by (blast dest: injD)
   369 
   370 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   371 by (simp add: inj_on_def, blast)
   372 
   373 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   374 by (blast dest: injD)
   375 
   376 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
   377 lemma image_INT:
   378    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
   379     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   380 apply (simp add: inj_on_def, blast)
   381 done
   382 
   383 (*Compare with image_INT: no use of inj_on, and if f is surjective then
   384   it doesn't matter whether A is empty*)
   385 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   386 apply (simp add: bij_def)
   387 apply (simp add: inj_on_def surj_def, blast)
   388 done
   389 
   390 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   391 by auto
   392 
   393 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   394 by (auto simp add: inj_on_def)
   395 
   396 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   397 apply (simp add: bij_def)
   398 apply (rule equalityI)
   399 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   400 done
   401 
   402 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   403   by (auto intro!: inj_onI)
   404 
   405 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   406   by (auto intro!: inj_onI dest: strict_mono_eq)
   407 
   408 subsection{*Function Updating*}
   409 
   410 definition
   411   fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   412   "fun_upd f a b == % x. if x=a then b else f x"
   413 
   414 nonterminals
   415   updbinds updbind
   416 syntax
   417   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   418   ""         :: "updbind => updbinds"             ("_")
   419   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   420   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   421 
   422 translations
   423   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   424   "f(x:=y)" == "CONST fun_upd f x y"
   425 
   426 (* Hint: to define the sum of two functions (or maps), use sum_case.
   427          A nice infix syntax could be defined (in Datatype.thy or below) by
   428 notation
   429   sum_case  (infixr "'(+')"80)
   430 *)
   431 
   432 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   433 apply (simp add: fun_upd_def, safe)
   434 apply (erule subst)
   435 apply (rule_tac [2] ext, auto)
   436 done
   437 
   438 (* f x = y ==> f(x:=y) = f *)
   439 lemmas fun_upd_idem = fun_upd_idem_iff [THEN iffD2, standard]
   440 
   441 (* f(x := f x) = f *)
   442 lemmas fun_upd_triv = refl [THEN fun_upd_idem]
   443 declare fun_upd_triv [iff]
   444 
   445 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   446 by (simp add: fun_upd_def)
   447 
   448 (* fun_upd_apply supersedes these two,   but they are useful
   449    if fun_upd_apply is intentionally removed from the simpset *)
   450 lemma fun_upd_same: "(f(x:=y)) x = y"
   451 by simp
   452 
   453 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   454 by simp
   455 
   456 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   457 by (simp add: fun_eq_iff)
   458 
   459 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   460 by (rule ext, auto)
   461 
   462 lemma inj_on_fun_updI: "\<lbrakk> inj_on f A; y \<notin> f`A \<rbrakk> \<Longrightarrow> inj_on (f(x:=y)) A"
   463 by (fastsimp simp:inj_on_def image_def)
   464 
   465 lemma fun_upd_image:
   466      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   467 by auto
   468 
   469 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   470 by (auto intro: ext)
   471 
   472 
   473 subsection {* @{text override_on} *}
   474 
   475 definition
   476   override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
   477 where
   478   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   479 
   480 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   481 by(simp add:override_on_def)
   482 
   483 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   484 by(simp add:override_on_def)
   485 
   486 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   487 by(simp add:override_on_def)
   488 
   489 
   490 subsection {* @{text swap} *}
   491 
   492 definition
   493   swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
   494 where
   495   "swap a b f = f (a := f b, b:= f a)"
   496 
   497 lemma swap_self [simp]: "swap a a f = f"
   498 by (simp add: swap_def)
   499 
   500 lemma swap_commute: "swap a b f = swap b a f"
   501 by (rule ext, simp add: fun_upd_def swap_def)
   502 
   503 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
   504 by (rule ext, simp add: fun_upd_def swap_def)
   505 
   506 lemma swap_triple:
   507   assumes "a \<noteq> c" and "b \<noteq> c"
   508   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   509   using assms by (simp add: fun_eq_iff swap_def)
   510 
   511 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   512 by (rule ext, simp add: fun_upd_def swap_def)
   513 
   514 lemma swap_image_eq [simp]:
   515   assumes "a \<in> A" "b \<in> A" shows "swap a b f ` A = f ` A"
   516 proof -
   517   have subset: "\<And>f. swap a b f ` A \<subseteq> f ` A"
   518     using assms by (auto simp: image_iff swap_def)
   519   then have "swap a b (swap a b f) ` A \<subseteq> (swap a b f) ` A" .
   520   with subset[of f] show ?thesis by auto
   521 qed
   522 
   523 lemma inj_on_imp_inj_on_swap:
   524   "\<lbrakk>inj_on f A; a \<in> A; b \<in> A\<rbrakk> \<Longrightarrow> inj_on (swap a b f) A"
   525   by (simp add: inj_on_def swap_def, blast)
   526 
   527 lemma inj_on_swap_iff [simp]:
   528   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A \<longleftrightarrow> inj_on f A"
   529 proof
   530   assume "inj_on (swap a b f) A"
   531   with A have "inj_on (swap a b (swap a b f)) A"
   532     by (iprover intro: inj_on_imp_inj_on_swap)
   533   thus "inj_on f A" by simp
   534 next
   535   assume "inj_on f A"
   536   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   537 qed
   538 
   539 lemma surj_imp_surj_swap: "surj f \<Longrightarrow> surj (swap a b f)"
   540   by simp
   541 
   542 lemma surj_swap_iff [simp]: "surj (swap a b f) \<longleftrightarrow> surj f"
   543   by simp
   544 
   545 lemma bij_betw_swap_iff [simp]:
   546   "\<lbrakk> x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> bij_betw (swap x y f) A B \<longleftrightarrow> bij_betw f A B"
   547   by (auto simp: bij_betw_def)
   548 
   549 lemma bij_swap_iff [simp]: "bij (swap a b f) \<longleftrightarrow> bij f"
   550   by simp
   551 
   552 hide_const (open) swap
   553 
   554 subsection {* Inversion of injective functions *}
   555 
   556 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   557 "the_inv_into A f == %x. THE y. y : A & f y = x"
   558 
   559 lemma the_inv_into_f_f:
   560   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   561 apply (simp add: the_inv_into_def inj_on_def)
   562 apply blast
   563 done
   564 
   565 lemma f_the_inv_into_f:
   566   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   567 apply (simp add: the_inv_into_def)
   568 apply (rule the1I2)
   569  apply(blast dest: inj_onD)
   570 apply blast
   571 done
   572 
   573 lemma the_inv_into_into:
   574   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   575 apply (simp add: the_inv_into_def)
   576 apply (rule the1I2)
   577  apply(blast dest: inj_onD)
   578 apply blast
   579 done
   580 
   581 lemma the_inv_into_onto[simp]:
   582   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   583 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   584 
   585 lemma the_inv_into_f_eq:
   586   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   587   apply (erule subst)
   588   apply (erule the_inv_into_f_f, assumption)
   589   done
   590 
   591 lemma the_inv_into_comp:
   592   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   593   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   594 apply (rule the_inv_into_f_eq)
   595   apply (fast intro: comp_inj_on)
   596  apply (simp add: f_the_inv_into_f the_inv_into_into)
   597 apply (simp add: the_inv_into_into)
   598 done
   599 
   600 lemma inj_on_the_inv_into:
   601   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   602 by (auto intro: inj_onI simp: image_def the_inv_into_f_f)
   603 
   604 lemma bij_betw_the_inv_into:
   605   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   606 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   607 
   608 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   609   "the_inv f \<equiv> the_inv_into UNIV f"
   610 
   611 lemma the_inv_f_f:
   612   assumes "inj f"
   613   shows "the_inv f (f x) = x" using assms UNIV_I
   614   by (rule the_inv_into_f_f)
   615 
   616 
   617 subsection {* Proof tool setup *} 
   618 
   619 text {* simplifies terms of the form
   620   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   621 
   622 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   623 let
   624   fun gen_fun_upd NONE T _ _ = NONE
   625     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   626   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   627   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   628     let
   629       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   630             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   631         | find t = NONE
   632     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   633 
   634   fun proc ss ct =
   635     let
   636       val ctxt = Simplifier.the_context ss
   637       val t = Thm.term_of ct
   638     in
   639       case find_double t of
   640         (T, NONE) => NONE
   641       | (T, SOME rhs) =>
   642           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   643             (fn _ =>
   644               rtac eq_reflection 1 THEN
   645               rtac ext 1 THEN
   646               simp_tac (Simplifier.inherit_context ss @{simpset}) 1))
   647     end
   648 in proc end
   649 *}
   650 
   651 
   652 subsection {* Code generator setup *}
   653 
   654 types_code
   655   "fun"  ("(_ ->/ _)")
   656 attach (term_of) {*
   657 fun term_of_fun_type _ aT _ bT _ = Free ("<function>", aT --> bT);
   658 *}
   659 attach (test) {*
   660 fun gen_fun_type aF aT bG bT i =
   661   let
   662     val tab = Unsynchronized.ref [];
   663     fun mk_upd (x, (_, y)) t = Const ("Fun.fun_upd",
   664       (aT --> bT) --> aT --> bT --> aT --> bT) $ t $ aF x $ y ()
   665   in
   666     (fn x =>
   667        case AList.lookup op = (!tab) x of
   668          NONE =>
   669            let val p as (y, _) = bG i
   670            in (tab := (x, p) :: !tab; y) end
   671        | SOME (y, _) => y,
   672      fn () => Basics.fold mk_upd (!tab) (Const ("HOL.undefined", aT --> bT)))
   673   end;
   674 *}
   675 
   676 code_const "op \<circ>"
   677   (SML infixl 5 "o")
   678   (Haskell infixr 9 ".")
   679 
   680 code_const "id"
   681   (Haskell "id")
   682 
   683 end