src/Pure/drule.ML
author obua
Sun May 29 12:39:12 2005 +0200 (2005-05-29)
changeset 16108 cf468b93a02e
parent 15949 fd02dd265b78
child 16425 2427be27cc60
permissions -rw-r--r--
Implement cycle-free overloading, so that definitions cannot harm consistency any more (except of course via interaction with axioms).
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies        : cterm * cterm -> cterm
    14   val list_implies      : cterm list * cterm -> cterm
    15   val dest_implies      : cterm -> cterm * cterm
    16   val dest_equals       : cterm -> cterm * cterm
    17   val strip_imp_prems   : cterm -> cterm list
    18   val strip_imp_concl   : cterm -> cterm
    19   val cprems_of         : thm -> cterm list
    20   val cterm_fun         : (term -> term) -> (cterm -> cterm)
    21   val ctyp_fun          : (typ -> typ) -> (ctyp -> ctyp)
    22   val read_insts        :
    23           Sign.sg -> (indexname -> typ option) * (indexname -> sort option)
    24                   -> (indexname -> typ option) * (indexname -> sort option)
    25                   -> string list -> (indexname * string) list
    26                   -> (ctyp * ctyp) list * (cterm * cterm) list
    27   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    28   val strip_shyps_warning : thm -> thm
    29   val forall_intr_list  : cterm list -> thm -> thm
    30   val forall_intr_frees : thm -> thm
    31   val forall_intr_vars  : thm -> thm
    32   val forall_elim_list  : cterm list -> thm -> thm
    33   val forall_elim_var   : int -> thm -> thm
    34   val forall_elim_vars  : int -> thm -> thm
    35   val gen_all           : thm -> thm
    36   val freeze_thaw       : thm -> thm * (thm -> thm)
    37   val freeze_thaw_robust: thm -> thm * (int -> thm -> thm)
    38   val implies_elim_list : thm -> thm list -> thm
    39   val implies_intr_list : cterm list -> thm -> thm
    40   val instantiate       :
    41     (ctyp * ctyp) list * (cterm * cterm) list -> thm -> thm
    42   val zero_var_indexes  : thm -> thm
    43   val standard          : thm -> thm
    44   val standard'         : thm -> thm
    45   val rotate_prems      : int -> thm -> thm
    46   val rearrange_prems   : int list -> thm -> thm
    47   val assume_ax         : theory -> string -> thm
    48   val RSN               : thm * (int * thm) -> thm
    49   val RS                : thm * thm -> thm
    50   val RLN               : thm list * (int * thm list) -> thm list
    51   val RL                : thm list * thm list -> thm list
    52   val MRS               : thm list * thm -> thm
    53   val MRL               : thm list list * thm list -> thm list
    54   val OF                : thm * thm list -> thm
    55   val compose           : thm * int * thm -> thm list
    56   val COMP              : thm * thm -> thm
    57   val read_instantiate_sg: Sign.sg -> (string*string)list -> thm -> thm
    58   val read_instantiate  : (string*string)list -> thm -> thm
    59   val cterm_instantiate : (cterm*cterm)list -> thm -> thm
    60   val eq_thm_sg         : thm * thm -> bool
    61   val eq_thm_prop	: thm * thm -> bool
    62   val weak_eq_thm       : thm * thm -> bool
    63   val size_of_thm       : thm -> int
    64   val reflexive_thm     : thm
    65   val symmetric_thm     : thm
    66   val transitive_thm    : thm
    67   val symmetric_fun     : thm -> thm
    68   val extensional       : thm -> thm
    69   val imp_cong          : thm
    70   val swap_prems_eq     : thm
    71   val equal_abs_elim    : cterm  -> thm -> thm
    72   val equal_abs_elim_list: cterm list -> thm -> thm
    73   val asm_rl            : thm
    74   val cut_rl            : thm
    75   val revcut_rl         : thm
    76   val thin_rl           : thm
    77   val triv_forall_equality: thm
    78   val swap_prems_rl     : thm
    79   val equal_intr_rule   : thm
    80   val equal_elim_rule1  : thm
    81   val inst              : string -> string -> thm -> thm
    82   val instantiate'      : ctyp option list -> cterm option list -> thm -> thm
    83   val incr_indexes_wrt  : int list -> ctyp list -> cterm list -> thm list -> thm -> thm
    84 end;
    85 
    86 signature DRULE =
    87 sig
    88   include BASIC_DRULE
    89   val list_comb: cterm * cterm list -> cterm
    90   val strip_comb: cterm -> cterm * cterm list
    91   val strip_type: ctyp -> ctyp list * ctyp
    92   val beta_conv: cterm -> cterm -> cterm
    93   val plain_prop_of: thm -> term
    94   val add_used: thm -> string list -> string list
    95   val rule_attribute: ('a -> thm -> thm) -> 'a attribute
    96   val tag_rule: tag -> thm -> thm
    97   val untag_rule: string -> thm -> thm
    98   val tag: tag -> 'a attribute
    99   val untag: string -> 'a attribute
   100   val get_kind: thm -> string
   101   val kind: string -> 'a attribute
   102   val theoremK: string
   103   val lemmaK: string
   104   val corollaryK: string
   105   val internalK: string
   106   val kind_internal: 'a attribute
   107   val has_internal: tag list -> bool
   108   val impose_hyps: cterm list -> thm -> thm
   109   val satisfy_hyps: thm list -> thm -> thm
   110   val close_derivation: thm -> thm
   111   val local_standard: thm -> thm
   112   val compose_single: thm * int * thm -> thm
   113   val add_rule: thm -> thm list -> thm list
   114   val del_rule: thm -> thm list -> thm list
   115   val add_rules: thm list -> thm list -> thm list
   116   val del_rules: thm list -> thm list -> thm list
   117   val merge_rules: thm list * thm list -> thm list
   118   val imp_cong'         : thm -> thm -> thm
   119   val beta_eta_conversion: cterm -> thm
   120   val eta_long_conversion: cterm -> thm
   121   val goals_conv        : (int -> bool) -> (cterm -> thm) -> cterm -> thm
   122   val forall_conv       : (cterm -> thm) -> cterm -> thm
   123   val fconv_rule        : (cterm -> thm) -> thm -> thm
   124   val norm_hhf_eq: thm
   125   val is_norm_hhf: term -> bool
   126   val norm_hhf: Sign.sg -> term -> term
   127   val triv_goal: thm
   128   val rev_triv_goal: thm
   129   val implies_intr_goals: cterm list -> thm -> thm
   130   val freeze_all: thm -> thm
   131   val mk_triv_goal: cterm -> thm
   132   val tvars_of_terms: term list -> (indexname * sort) list
   133   val vars_of_terms: term list -> (indexname * typ) list
   134   val tvars_of: thm -> (indexname * sort) list
   135   val vars_of: thm -> (indexname * typ) list
   136   val rename_bvars: (string * string) list -> thm -> thm
   137   val rename_bvars': string option list -> thm -> thm
   138   val unvarifyT: thm -> thm
   139   val unvarify: thm -> thm
   140   val tvars_intr_list: string list -> thm -> thm * (string * (indexname * sort)) list
   141   val remdups_rl: thm
   142   val conj_intr: thm -> thm -> thm
   143   val conj_intr_list: thm list -> thm
   144   val conj_elim: thm -> thm * thm
   145   val conj_elim_list: thm -> thm list
   146   val conj_elim_precise: int -> thm -> thm list
   147   val conj_intr_thm: thm
   148   val abs_def: thm -> thm
   149   val read_instantiate_sg': Sign.sg -> (indexname * string) list -> thm -> thm
   150   val read_instantiate': (indexname * string) list -> thm -> thm
   151 end;
   152 
   153 structure Drule: DRULE =
   154 struct
   155 
   156 
   157 (** some cterm->cterm operations: much faster than calling cterm_of! **)
   158 
   159 (** SAME NAMES as in structure Logic: use compound identifiers! **)
   160 
   161 (*dest_implies for cterms. Note T=prop below*)
   162 fun dest_implies ct =
   163     case term_of ct of
   164         (Const("==>", _) $ _ $ _) =>
   165             let val (ct1,ct2) = Thm.dest_comb ct
   166             in  (#2 (Thm.dest_comb ct1), ct2)  end
   167       | _ => raise TERM ("dest_implies", [term_of ct]) ;
   168 
   169 fun dest_equals ct =
   170     case term_of ct of
   171         (Const("==", _) $ _ $ _) =>
   172             let val (ct1,ct2) = Thm.dest_comb ct
   173             in  (#2 (Thm.dest_comb ct1), ct2)  end
   174       | _ => raise TERM ("dest_equals", [term_of ct]) ;
   175 
   176 
   177 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   178 fun strip_imp_prems ct =
   179     let val (cA,cB) = dest_implies ct
   180     in  cA :: strip_imp_prems cB  end
   181     handle TERM _ => [];
   182 
   183 (* A1==>...An==>B  goes to B, where B is not an implication *)
   184 fun strip_imp_concl ct =
   185     case term_of ct of (Const("==>", _) $ _ $ _) =>
   186         strip_imp_concl (#2 (Thm.dest_comb ct))
   187   | _ => ct;
   188 
   189 (*The premises of a theorem, as a cterm list*)
   190 val cprems_of = strip_imp_prems o cprop_of;
   191 
   192 fun cterm_fun f ct =
   193   let val {t, sign, ...} = Thm.rep_cterm ct
   194   in Thm.cterm_of sign (f t) end;
   195 
   196 fun ctyp_fun f cT =
   197   let val {T, sign, ...} = Thm.rep_ctyp cT
   198   in Thm.ctyp_of sign (f T) end;
   199 
   200 val proto_sign = Theory.sign_of ProtoPure.thy;
   201 
   202 val implies = cterm_of proto_sign Term.implies;
   203 
   204 (*cterm version of mk_implies*)
   205 fun mk_implies(A,B) = Thm.capply (Thm.capply implies A) B;
   206 
   207 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   208 fun list_implies([], B) = B
   209   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   210 
   211 (*cterm version of list_comb: maps  (f, [t1,...,tn])  to  f(t1,...,tn) *)
   212 fun list_comb (f, []) = f
   213   | list_comb (f, t::ts) = list_comb (Thm.capply f t, ts);
   214 
   215 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   216 fun strip_comb ct = 
   217   let
   218     fun stripc (p as (ct, cts)) =
   219       let val (ct1, ct2) = Thm.dest_comb ct
   220       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   221   in stripc (ct, []) end;
   222 
   223 (* cterm version of strip_type: maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T) *)
   224 fun strip_type cT = (case Thm.typ_of cT of
   225     Type ("fun", _) =>
   226       let
   227         val [cT1, cT2] = Thm.dest_ctyp cT;
   228         val (cTs, cT') = strip_type cT2
   229       in (cT1 :: cTs, cT') end
   230   | _ => ([], cT));
   231 
   232 (*Beta-conversion for cterms, where x is an abstraction. Simply returns the rhs
   233   of the meta-equality returned by the beta_conversion rule.*)
   234 fun beta_conv x y = 
   235     #2 (Thm.dest_comb (cprop_of (Thm.beta_conversion false (Thm.capply x y))));
   236 
   237 fun plain_prop_of raw_thm =
   238   let
   239     val thm = Thm.strip_shyps raw_thm;
   240     fun err msg = raise THM ("plain_prop_of: " ^ msg, 0, [thm]);
   241     val {hyps, prop, tpairs, ...} = Thm.rep_thm thm;
   242   in
   243     if not (null hyps) then
   244       err "theorem may not contain hypotheses"
   245     else if not (null (Thm.extra_shyps thm)) then
   246       err "theorem may not contain sort hypotheses"
   247     else if not (null tpairs) then
   248       err "theorem may not contain flex-flex pairs"
   249     else prop
   250   end;
   251 
   252 
   253 
   254 (** reading of instantiations **)
   255 
   256 fun absent ixn =
   257   error("No such variable in term: " ^ Syntax.string_of_vname ixn);
   258 
   259 fun inst_failure ixn =
   260   error("Instantiation of " ^ Syntax.string_of_vname ixn ^ " fails");
   261 
   262 fun read_insts sign (rtypes,rsorts) (types,sorts) used insts =
   263 let
   264     fun is_tv ((a, _), _) =
   265       (case Symbol.explode a of "'" :: _ => true | _ => false);
   266     val (tvs, vs) = List.partition is_tv insts;
   267     fun sort_of ixn = case rsorts ixn of SOME S => S | NONE => absent ixn;
   268     fun readT (ixn, st) =
   269         let val S = sort_of ixn;
   270             val T = Sign.read_typ (sign,sorts) st;
   271         in if Sign.typ_instance sign (T, TVar(ixn,S)) then (ixn,T)
   272            else inst_failure ixn
   273         end
   274     val tye = map readT tvs;
   275     fun mkty(ixn,st) = (case rtypes ixn of
   276                           SOME T => (ixn,(st,typ_subst_TVars tye T))
   277                         | NONE => absent ixn);
   278     val ixnsTs = map mkty vs;
   279     val ixns = map fst ixnsTs
   280     and sTs  = map snd ixnsTs
   281     val (cts,tye2) = read_def_cterms(sign,types,sorts) used false sTs;
   282     fun mkcVar(ixn,T) =
   283         let val U = typ_subst_TVars tye2 T
   284         in cterm_of sign (Var(ixn,U)) end
   285     val ixnTs = ListPair.zip(ixns, map snd sTs)
   286 in (map (fn (ixn, T) => (ctyp_of sign (TVar (ixn, sort_of ixn)),
   287       ctyp_of sign T)) (tye2 @ tye),
   288     ListPair.zip(map mkcVar ixnTs,cts))
   289 end;
   290 
   291 
   292 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   293      Used for establishing default types (of variables) and sorts (of
   294      type variables) when reading another term.
   295      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   296 ***)
   297 
   298 fun types_sorts thm =
   299     let val {prop, hyps, tpairs, ...} = Thm.rep_thm thm;
   300         (* bogus term! *)
   301         val big = Term.list_comb 
   302                     (Term.list_comb (prop, hyps), Thm.terms_of_tpairs tpairs);
   303         val vars = map dest_Var (term_vars big);
   304         val frees = map dest_Free (term_frees big);
   305         val tvars = term_tvars big;
   306         val tfrees = term_tfrees big;
   307         fun typ(a,i) = if i<0 then assoc(frees,a) else assoc(vars,(a,i));
   308         fun sort(a,i) = if i<0 then assoc(tfrees,a) else assoc(tvars,(a,i));
   309     in (typ,sort) end;
   310 
   311 fun add_used thm used =
   312   let val {prop, hyps, tpairs, ...} = Thm.rep_thm thm in
   313     add_term_tvarnames (prop, used)
   314     |> fold (curry add_term_tvarnames) hyps
   315     |> fold (curry add_term_tvarnames) (Thm.terms_of_tpairs tpairs)
   316   end;
   317 
   318 
   319 
   320 (** basic attributes **)
   321 
   322 (* dependent rules *)
   323 
   324 fun rule_attribute f (x, thm) = (x, (f x thm));
   325 
   326 
   327 (* add / delete tags *)
   328 
   329 fun map_tags f thm =
   330   Thm.put_name_tags (Thm.name_of_thm thm, f (#2 (Thm.get_name_tags thm))) thm;
   331 
   332 fun tag_rule tg = map_tags (fn tgs => if tg mem tgs then tgs else tgs @ [tg]);
   333 fun untag_rule s = map_tags (filter_out (equal s o #1));
   334 
   335 fun tag tg x = rule_attribute (K (tag_rule tg)) x;
   336 fun untag s x = rule_attribute (K (untag_rule s)) x;
   337 
   338 fun simple_tag name x = tag (name, []) x;
   339 
   340 
   341 (* theorem kinds *)
   342 
   343 val theoremK = "theorem";
   344 val lemmaK = "lemma";
   345 val corollaryK = "corollary";
   346 val internalK = "internal";
   347 
   348 fun get_kind thm =
   349   (case Library.assoc (#2 (Thm.get_name_tags thm), "kind") of
   350     SOME (k :: _) => k
   351   | _ => "unknown");
   352 
   353 fun kind_rule k = tag_rule ("kind", [k]) o untag_rule "kind";
   354 fun kind k x = if k = "" then x else rule_attribute (K (kind_rule k)) x;
   355 fun kind_internal x = kind internalK x;
   356 fun has_internal tags = exists (equal internalK o fst) tags;
   357 
   358 
   359 
   360 (** Standardization of rules **)
   361 
   362 (*Strip extraneous shyps as far as possible*)
   363 fun strip_shyps_warning thm =
   364   let
   365     val str_of_sort = Pretty.str_of o Sign.pretty_sort (Thm.sign_of_thm thm);
   366     val thm' = Thm.strip_shyps thm;
   367     val xshyps = Thm.extra_shyps thm';
   368   in
   369     if null xshyps then ()
   370     else warning ("Pending sort hypotheses: " ^ commas (map str_of_sort xshyps));
   371     thm'
   372   end;
   373 
   374 (*Generalization over a list of variables, IGNORING bad ones*)
   375 fun forall_intr_list [] th = th
   376   | forall_intr_list (y::ys) th =
   377         let val gth = forall_intr_list ys th
   378         in  forall_intr y gth   handle THM _ =>  gth  end;
   379 
   380 (*Generalization over all suitable Free variables*)
   381 fun forall_intr_frees th =
   382     let val {prop,sign,...} = rep_thm th
   383     in  forall_intr_list
   384          (map (cterm_of sign) (sort (make_ord atless) (term_frees prop)))
   385          th
   386     end;
   387 
   388 val forall_elim_var = PureThy.forall_elim_var;
   389 val forall_elim_vars = PureThy.forall_elim_vars;
   390 
   391 fun gen_all thm =
   392   let
   393     val {sign, prop, maxidx, ...} = Thm.rep_thm thm;
   394     fun elim (th, (x, T)) = Thm.forall_elim (Thm.cterm_of sign (Var ((x, maxidx + 1), T))) th;
   395     val vs = Term.strip_all_vars prop;
   396   in Library.foldl elim (thm, Term.variantlist (map #1 vs, []) ~~ map #2 vs) end;
   397 
   398 (*Specialization over a list of cterms*)
   399 fun forall_elim_list cts th = foldr (uncurry forall_elim) th (rev cts);
   400 
   401 (* maps A1,...,An |- B   to   [| A1;...;An |] ==> B  *)
   402 fun implies_intr_list cAs th = foldr (uncurry implies_intr) th cAs;
   403 
   404 (* maps [| A1;...;An |] ==> B and [A1,...,An]   to   B *)
   405 fun implies_elim_list impth ths = Library.foldl (uncurry implies_elim) (impth,ths);
   406 
   407 (* maps |- B to A1,...,An |- B *)
   408 fun impose_hyps chyps th =
   409   let val chyps' = gen_rems (op aconv o apfst Thm.term_of) (chyps, #hyps (Thm.rep_thm th))
   410   in implies_elim_list (implies_intr_list chyps' th) (map Thm.assume chyps') end;
   411 
   412 (* maps A1,...,An and A1,...,An |- B to |- B *)
   413 fun satisfy_hyps ths th =
   414   implies_elim_list (implies_intr_list (map (#prop o Thm.crep_thm) ths) th) ths;
   415 
   416 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   417 fun zero_var_indexes th =
   418     let val {prop,sign,tpairs,...} = rep_thm th;
   419         val (tpair_l, tpair_r) = Library.split_list tpairs;
   420         val vars = foldr add_term_vars 
   421                          (foldr add_term_vars (term_vars prop) tpair_l) tpair_r;
   422         val bs = Library.foldl add_new_id ([], map (fn Var((a,_),_)=>a) vars)
   423         val inrs = 
   424             foldr add_term_tvars 
   425                   (foldr add_term_tvars (term_tvars prop) tpair_l) tpair_r;
   426         val nms' = rev(Library.foldl add_new_id ([], map (#1 o #1) inrs));
   427         val tye = ListPair.map (fn ((v, rs), a) => (TVar (v, rs), TVar ((a, 0), rs)))
   428                      (inrs, nms')
   429         val ctye = map (pairself (ctyp_of sign)) tye;
   430         fun varpairs([],[]) = []
   431           | varpairs((var as Var(v,T)) :: vars, b::bs) =
   432                 let val T' = typ_subst_atomic tye T
   433                 in (cterm_of sign (Var(v,T')),
   434                     cterm_of sign (Var((b,0),T'))) :: varpairs(vars,bs)
   435                 end
   436           | varpairs _ = raise TERM("varpairs", []);
   437     in Thm.instantiate (ctye, varpairs(vars,rev bs)) th end;
   438 
   439 
   440 (** Standard form of object-rule: no hypotheses, flexflex constraints,
   441     Frees, or outer quantifiers; all generality expressed by Vars of index 0.**)
   442 
   443 (*Squash a theorem's flexflex constraints provided it can be done uniquely.
   444   This step can lose information.*)
   445 fun flexflex_unique th =
   446     case Seq.chop (2, flexflex_rule th) of
   447       ([th],_) => th
   448     | ([],_)   => raise THM("flexflex_unique: impossible constraints", 0, [th])
   449     |      _   => raise THM("flexflex_unique: multiple unifiers", 0, [th]);
   450 
   451 fun close_derivation thm =
   452   if Thm.get_name_tags thm = ("", []) then Thm.name_thm ("", thm)
   453   else thm;
   454 
   455 fun standard' th =
   456   let val {maxidx,...} = rep_thm th in
   457     th
   458     |> implies_intr_hyps
   459     |> forall_intr_frees |> forall_elim_vars (maxidx + 1)
   460     |> strip_shyps_warning
   461     |> zero_var_indexes |> Thm.varifyT |> Thm.compress
   462   end;
   463 
   464 val standard = close_derivation o standard' o flexflex_unique;
   465 
   466 fun local_standard th =
   467   th |> strip_shyps |> zero_var_indexes
   468   |> Thm.compress |> close_derivation;
   469 
   470 
   471 (*Convert all Vars in a theorem to Frees.  Also return a function for
   472   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   473   Similar code in type/freeze_thaw*)
   474 
   475 fun freeze_thaw_robust th =
   476  let val fth = freezeT th
   477      val {prop, tpairs, sign, ...} = rep_thm fth
   478  in
   479    case foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   480        [] => (fth, fn i => fn x => x)   (*No vars: nothing to do!*)
   481      | vars =>
   482          let fun newName (Var(ix,_), pairs) =
   483                    let val v = gensym (string_of_indexname ix)
   484                    in  ((ix,v)::pairs)  end;
   485              val alist = foldr newName [] vars
   486              fun mk_inst (Var(v,T)) =
   487                  (cterm_of sign (Var(v,T)),
   488                   cterm_of sign (Free(valOf (assoc(alist,v)), T)))
   489              val insts = map mk_inst vars
   490              fun thaw i th' = (*i is non-negative increment for Var indexes*)
   491                  th' |> forall_intr_list (map #2 insts)
   492                      |> forall_elim_list (map (Thm.cterm_incr_indexes i o #1) insts)
   493          in  (Thm.instantiate ([],insts) fth, thaw)  end
   494  end;
   495 
   496 (*Basic version of the function above. No option to rename Vars apart in thaw.
   497   The Frees created from Vars have nice names.*)
   498 fun freeze_thaw th =
   499  let val fth = freezeT th
   500      val {prop, tpairs, sign, ...} = rep_thm fth
   501  in
   502    case foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   503        [] => (fth, fn x => x)
   504      | vars =>
   505          let fun newName (Var(ix,_), (pairs,used)) =
   506                    let val v = variant used (string_of_indexname ix)
   507                    in  ((ix,v)::pairs, v::used)  end;
   508              val (alist, _) = foldr newName ([], Library.foldr add_term_names
   509                (prop :: Thm.terms_of_tpairs tpairs, [])) vars
   510              fun mk_inst (Var(v,T)) =
   511                  (cterm_of sign (Var(v,T)),
   512                   cterm_of sign (Free(valOf (assoc(alist,v)), T)))
   513              val insts = map mk_inst vars
   514              fun thaw th' =
   515                  th' |> forall_intr_list (map #2 insts)
   516                      |> forall_elim_list (map #1 insts)
   517          in  (Thm.instantiate ([],insts) fth, thaw)  end
   518  end;
   519 
   520 (*Rotates a rule's premises to the left by k*)
   521 val rotate_prems = permute_prems 0;
   522 
   523 (* permute prems, where the i-th position in the argument list (counting from 0)
   524    gives the position within the original thm to be transferred to position i.
   525    Any remaining trailing positions are left unchanged. *)
   526 val rearrange_prems = let
   527   fun rearr new []      thm = thm
   528   |   rearr new (p::ps) thm = rearr (new+1)
   529      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   530      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   531   in rearr 0 end;
   532 
   533 (*Assume a new formula, read following the same conventions as axioms.
   534   Generalizes over Free variables,
   535   creates the assumption, and then strips quantifiers.
   536   Example is [| ALL x:?A. ?P(x) |] ==> [| ?P(?a) |]
   537              [ !(A,P,a)[| ALL x:A. P(x) |] ==> [| P(a) |] ]    *)
   538 fun assume_ax thy sP =
   539     let val sign = Theory.sign_of thy
   540         val prop = Logic.close_form (term_of (read_cterm sign (sP, propT)))
   541     in forall_elim_vars 0 (assume (cterm_of sign prop))  end;
   542 
   543 (*Resolution: exactly one resolvent must be produced.*)
   544 fun tha RSN (i,thb) =
   545   case Seq.chop (2, biresolution false [(false,tha)] i thb) of
   546       ([th],_) => th
   547     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   548     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   549 
   550 (*resolution: P==>Q, Q==>R gives P==>R. *)
   551 fun tha RS thb = tha RSN (1,thb);
   552 
   553 (*For joining lists of rules*)
   554 fun thas RLN (i,thbs) =
   555   let val resolve = biresolution false (map (pair false) thas) i
   556       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   557   in  List.concat (map resb thbs)  end;
   558 
   559 fun thas RL thbs = thas RLN (1,thbs);
   560 
   561 (*Resolve a list of rules against bottom_rl from right to left;
   562   makes proof trees*)
   563 fun rls MRS bottom_rl =
   564   let fun rs_aux i [] = bottom_rl
   565         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   566   in  rs_aux 1 rls  end;
   567 
   568 (*As above, but for rule lists*)
   569 fun rlss MRL bottom_rls =
   570   let fun rs_aux i [] = bottom_rls
   571         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   572   in  rs_aux 1 rlss  end;
   573 
   574 (*A version of MRS with more appropriate argument order*)
   575 fun bottom_rl OF rls = rls MRS bottom_rl;
   576 
   577 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   578   with no lifting or renaming!  Q may contain ==> or meta-quants
   579   ALWAYS deletes premise i *)
   580 fun compose(tha,i,thb) =
   581     Seq.list_of (bicompose false (false,tha,0) i thb);
   582 
   583 fun compose_single (tha,i,thb) =
   584   (case compose (tha,i,thb) of
   585     [th] => th
   586   | _ => raise THM ("compose: unique result expected", i, [tha,thb]));
   587 
   588 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   589 fun tha COMP thb =
   590     case compose(tha,1,thb) of
   591         [th] => th
   592       | _ =>   raise THM("COMP", 1, [tha,thb]);
   593 
   594 
   595 (** theorem equality **)
   596 
   597 (*True if the two theorems have the same signature.*)
   598 val eq_thm_sg = Sign.eq_sg o pairself Thm.sign_of_thm;
   599 
   600 (*True if the two theorems have the same prop field, ignoring hyps, der, etc.*)
   601 val eq_thm_prop = op aconv o pairself Thm.prop_of;
   602 
   603 (*Useful "distance" function for BEST_FIRST*)
   604 val size_of_thm = size_of_term o prop_of;
   605 
   606 (*maintain lists of theorems --- preserving canonical order*)
   607 fun del_rules rs rules = Library.gen_rems eq_thm_prop (rules, rs);
   608 fun add_rules rs rules = rs @ del_rules rs rules;
   609 val del_rule = del_rules o single;
   610 val add_rule = add_rules o single;
   611 fun merge_rules (rules1, rules2) = gen_merge_lists' eq_thm_prop rules1 rules2;
   612 
   613 (** Mark Staples's weaker version of eq_thm: ignores variable renaming and
   614     (some) type variable renaming **)
   615 
   616  (* Can't use term_vars, because it sorts the resulting list of variable names.
   617     We instead need the unique list noramlised by the order of appearance
   618     in the term. *)
   619 fun term_vars' (t as Var(v,T)) = [t]
   620   | term_vars' (Abs(_,_,b)) = term_vars' b
   621   | term_vars' (f$a) = (term_vars' f) @ (term_vars' a)
   622   | term_vars' _ = [];
   623 
   624 fun forall_intr_vars th =
   625   let val {prop,sign,...} = rep_thm th;
   626       val vars = distinct (term_vars' prop);
   627   in forall_intr_list (map (cterm_of sign) vars) th end;
   628 
   629 val weak_eq_thm = Thm.eq_thm o pairself (forall_intr_vars o freezeT);
   630 
   631 
   632 (*** Meta-Rewriting Rules ***)
   633 
   634 fun read_prop s = read_cterm proto_sign (s, propT);
   635 
   636 fun store_thm name thm = hd (PureThy.smart_store_thms (name, [thm]));
   637 fun store_standard_thm name thm = store_thm name (standard thm);
   638 fun store_thm_open name thm = hd (PureThy.smart_store_thms_open (name, [thm]));
   639 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   640 
   641 val reflexive_thm =
   642   let val cx = cterm_of proto_sign (Var(("x",0),TVar(("'a",0),[])))
   643   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   644 
   645 val symmetric_thm =
   646   let val xy = read_prop "x == y"
   647   in store_standard_thm_open "symmetric" (Thm.implies_intr_hyps (Thm.symmetric (Thm.assume xy))) end;
   648 
   649 val transitive_thm =
   650   let val xy = read_prop "x == y"
   651       val yz = read_prop "y == z"
   652       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   653   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   654 
   655 fun symmetric_fun thm = thm RS symmetric_thm;
   656 
   657 fun extensional eq =
   658   let val eq' =
   659     abstract_rule "x" (snd (Thm.dest_comb (fst (dest_equals (cprop_of eq))))) eq
   660   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   661 
   662 val imp_cong =
   663   let
   664     val ABC = read_prop "PROP A ==> PROP B == PROP C"
   665     val AB = read_prop "PROP A ==> PROP B"
   666     val AC = read_prop "PROP A ==> PROP C"
   667     val A = read_prop "PROP A"
   668   in
   669     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   670       (implies_intr AB (implies_intr A
   671         (equal_elim (implies_elim (assume ABC) (assume A))
   672           (implies_elim (assume AB) (assume A)))))
   673       (implies_intr AC (implies_intr A
   674         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   675           (implies_elim (assume AC) (assume A)))))))
   676   end;
   677 
   678 val swap_prems_eq =
   679   let
   680     val ABC = read_prop "PROP A ==> PROP B ==> PROP C"
   681     val BAC = read_prop "PROP B ==> PROP A ==> PROP C"
   682     val A = read_prop "PROP A"
   683     val B = read_prop "PROP B"
   684   in
   685     store_standard_thm_open "swap_prems_eq" (equal_intr
   686       (implies_intr ABC (implies_intr B (implies_intr A
   687         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   688       (implies_intr BAC (implies_intr A (implies_intr B
   689         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   690   end;
   691 
   692 val imp_cong' = combination o combination (reflexive implies)
   693 
   694 fun abs_def thm =
   695   let
   696     val (_, cvs) = strip_comb (fst (dest_equals (cprop_of thm)));
   697     val thm' = foldr (fn (ct, thm) => Thm.abstract_rule
   698       (case term_of ct of Var ((a, _), _) => a | Free (a, _) => a | _ => "x")
   699         ct thm) thm cvs
   700   in transitive
   701     (symmetric (eta_conversion (fst (dest_equals (cprop_of thm'))))) thm'
   702   end;
   703 
   704 
   705 local
   706   val dest_eq = dest_equals o cprop_of
   707   val rhs_of = snd o dest_eq
   708 in
   709 fun beta_eta_conversion t =
   710   let val thm = beta_conversion true t
   711   in transitive thm (eta_conversion (rhs_of thm)) end
   712 end;
   713 
   714 fun eta_long_conversion ct = transitive (beta_eta_conversion ct)
   715   (symmetric (beta_eta_conversion (cterm_fun (Pattern.eta_long []) ct)));
   716 
   717 (*In [A1,...,An]==>B, rewrite the selected A's only -- for rewrite_goals_tac*)
   718 fun goals_conv pred cv =
   719   let fun gconv i ct =
   720         let val (A,B) = dest_implies ct
   721         in imp_cong' (if pred i then cv A else reflexive A) (gconv (i+1) B) end
   722         handle TERM _ => reflexive ct
   723   in gconv 1 end
   724 
   725 (* Rewrite A in !!x1,...,xn. A *)
   726 fun forall_conv cv ct =
   727   let val p as (ct1, ct2) = Thm.dest_comb ct
   728   in (case pairself term_of p of
   729       (Const ("all", _), Abs (s, _, _)) =>
   730          let val (v, ct') = Thm.dest_abs (SOME "@") ct2;
   731          in Thm.combination (Thm.reflexive ct1)
   732            (Thm.abstract_rule s v (forall_conv cv ct'))
   733          end
   734     | _ => cv ct)
   735   end handle TERM _ => cv ct;
   736 
   737 (*Use a conversion to transform a theorem*)
   738 fun fconv_rule cv th = equal_elim (cv (cprop_of th)) th;
   739 
   740 (*** Some useful meta-theorems ***)
   741 
   742 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   743 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "PROP ?psi"));
   744 val _ = store_thm "_" asm_rl;
   745 
   746 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   747 val cut_rl =
   748   store_standard_thm_open "cut_rl"
   749     (Thm.trivial (read_prop "PROP ?psi ==> PROP ?theta"));
   750 
   751 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   752      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   753 val revcut_rl =
   754   let val V = read_prop "PROP V"
   755       and VW = read_prop "PROP V ==> PROP W";
   756   in
   757     store_standard_thm_open "revcut_rl"
   758       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   759   end;
   760 
   761 (*for deleting an unwanted assumption*)
   762 val thin_rl =
   763   let val V = read_prop "PROP V"
   764       and W = read_prop "PROP W";
   765   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   766 
   767 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   768 val triv_forall_equality =
   769   let val V  = read_prop "PROP V"
   770       and QV = read_prop "!!x::'a. PROP V"
   771       and x  = read_cterm proto_sign ("x", TypeInfer.logicT);
   772   in
   773     store_standard_thm_open "triv_forall_equality"
   774       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   775         (implies_intr V  (forall_intr x (assume V))))
   776   end;
   777 
   778 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   779    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   780    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   781 *)
   782 val swap_prems_rl =
   783   let val cmajor = read_prop "PROP PhiA ==> PROP PhiB ==> PROP Psi";
   784       val major = assume cmajor;
   785       val cminor1 = read_prop "PROP PhiA";
   786       val minor1 = assume cminor1;
   787       val cminor2 = read_prop "PROP PhiB";
   788       val minor2 = assume cminor2;
   789   in store_standard_thm_open "swap_prems_rl"
   790        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   791          (implies_elim (implies_elim major minor1) minor2))))
   792   end;
   793 
   794 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   795    ==> PROP ?phi == PROP ?psi
   796    Introduction rule for == as a meta-theorem.
   797 *)
   798 val equal_intr_rule =
   799   let val PQ = read_prop "PROP phi ==> PROP psi"
   800       and QP = read_prop "PROP psi ==> PROP phi"
   801   in
   802     store_standard_thm_open "equal_intr_rule"
   803       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   804   end;
   805 
   806 (* [| PROP ?phi == PROP ?psi; PROP ?phi |] ==> PROP ?psi *)
   807 val equal_elim_rule1 =
   808   let val eq = read_prop "PROP phi == PROP psi"
   809       and P = read_prop "PROP phi"
   810   in store_standard_thm_open "equal_elim_rule1"
   811     (Thm.equal_elim (assume eq) (assume P) |> implies_intr_list [eq, P])
   812   end;
   813 
   814 (* "[| PROP ?phi; PROP ?phi; PROP ?psi |] ==> PROP ?psi" *)
   815 
   816 val remdups_rl =
   817   let val P = read_prop "PROP phi" and Q = read_prop "PROP psi";
   818   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   819 
   820 
   821 (*(PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x))
   822   Rewrite rule for HHF normalization.*)
   823 
   824 val norm_hhf_eq =
   825   let
   826     val cert = Thm.cterm_of proto_sign;
   827     val aT = TFree ("'a", []);
   828     val all = Term.all aT;
   829     val x = Free ("x", aT);
   830     val phi = Free ("phi", propT);
   831     val psi = Free ("psi", aT --> propT);
   832 
   833     val cx = cert x;
   834     val cphi = cert phi;
   835     val lhs = cert (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   836     val rhs = cert (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   837   in
   838     Thm.equal_intr
   839       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   840         |> Thm.forall_elim cx
   841         |> Thm.implies_intr cphi
   842         |> Thm.forall_intr cx
   843         |> Thm.implies_intr lhs)
   844       (Thm.implies_elim
   845           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   846         |> Thm.forall_intr cx
   847         |> Thm.implies_intr cphi
   848         |> Thm.implies_intr rhs)
   849     |> store_standard_thm_open "norm_hhf_eq"
   850   end;
   851 
   852 fun is_norm_hhf tm =
   853   let
   854     fun is_norm (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   855       | is_norm (t $ u) = is_norm t andalso is_norm u
   856       | is_norm (Abs (_, _, t)) = is_norm t
   857       | is_norm _ = true;
   858   in is_norm (Pattern.beta_eta_contract tm) end;
   859 
   860 fun norm_hhf sg t =
   861   if is_norm_hhf t then t
   862   else Pattern.rewrite_term (Sign.tsig_of sg) [Logic.dest_equals (prop_of norm_hhf_eq)] [] t;
   863 
   864 
   865 (*** Instantiate theorem th, reading instantiations under signature sg ****)
   866 
   867 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   868 fun instantiate instpair th = Thm.instantiate instpair th  COMP   asm_rl;
   869 
   870 fun read_instantiate_sg' sg sinsts th =
   871     let val ts = types_sorts th;
   872         val used = add_used th [];
   873     in  instantiate (read_insts sg ts ts used sinsts) th  end;
   874 
   875 fun read_instantiate_sg sg sinsts th =
   876   read_instantiate_sg' sg (map (apfst Syntax.indexname) sinsts) th;
   877 
   878 (*Instantiate theorem th, reading instantiations under theory of th*)
   879 fun read_instantiate sinsts th =
   880     read_instantiate_sg (Thm.sign_of_thm th) sinsts th;
   881 
   882 fun read_instantiate' sinsts th =
   883     read_instantiate_sg' (Thm.sign_of_thm th) sinsts th;
   884 
   885 
   886 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   887   Instantiates distinct Vars by terms, inferring type instantiations. *)
   888 local
   889   fun add_types ((ct,cu), (sign,tye,maxidx)) =
   890     let val {sign=signt, t=t, T= T, maxidx=maxt,...} = rep_cterm ct
   891         and {sign=signu, t=u, T= U, maxidx=maxu,...} = rep_cterm cu;
   892         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   893         val sign' = Sign.merge(sign, Sign.merge(signt, signu))
   894         val (tye',maxi') = Type.unify (Sign.tsig_of sign') (tye, maxi) (T, U)
   895           handle Type.TUNIFY => raise TYPE("Ill-typed instantiation", [T,U], [t,u])
   896     in  (sign', tye', maxi')  end;
   897 in
   898 fun cterm_instantiate ctpairs0 th =
   899   let val (sign,tye,_) = foldr add_types (Thm.sign_of_thm th, Vartab.empty, 0) ctpairs0
   900       fun instT(ct,cu) = 
   901         let val inst = cterm_of sign o Envir.subst_TVars tye o term_of
   902         in (inst ct, inst cu) end
   903       fun ctyp2 (ixn, (S, T)) = (ctyp_of sign (TVar (ixn, S)), ctyp_of sign T)
   904   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   905   handle TERM _ =>
   906            raise THM("cterm_instantiate: incompatible signatures",0,[th])
   907        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   908 end;
   909 
   910 
   911 (** Derived rules mainly for METAHYPS **)
   912 
   913 (*Given the term "a", takes (%x.t)==(%x.u) to t[a/x]==u[a/x]*)
   914 fun equal_abs_elim ca eqth =
   915   let val {sign=signa, t=a, ...} = rep_cterm ca
   916       and combth = combination eqth (reflexive ca)
   917       val {sign,prop,...} = rep_thm eqth
   918       val (abst,absu) = Logic.dest_equals prop
   919       val cterm = cterm_of (Sign.merge (sign,signa))
   920   in  transitive (symmetric (beta_conversion false (cterm (abst$a))))
   921            (transitive combth (beta_conversion false (cterm (absu$a))))
   922   end
   923   handle THM _ => raise THM("equal_abs_elim", 0, [eqth]);
   924 
   925 (*Calling equal_abs_elim with multiple terms*)
   926 fun equal_abs_elim_list cts th = foldr (uncurry equal_abs_elim) th (rev cts);
   927 
   928 
   929 (*** Goal (PROP A) <==> PROP A ***)
   930 
   931 local
   932   val cert = Thm.cterm_of proto_sign;
   933   val A = Free ("A", propT);
   934   val G = Logic.mk_goal A;
   935   val (G_def, _) = freeze_thaw ProtoPure.Goal_def;
   936 in
   937   val triv_goal = store_thm "triv_goal" (kind_rule internalK (standard
   938       (Thm.equal_elim (Thm.symmetric G_def) (Thm.assume (cert A)))));
   939   val rev_triv_goal = store_thm "rev_triv_goal" (kind_rule internalK (standard
   940       (Thm.equal_elim G_def (Thm.assume (cert G)))));
   941 end;
   942 
   943 val mk_cgoal = Thm.capply (Thm.cterm_of proto_sign Logic.goal_const);
   944 fun assume_goal ct = Thm.assume (mk_cgoal ct) RS rev_triv_goal;
   945 
   946 fun implies_intr_goals cprops thm =
   947   implies_elim_list (implies_intr_list cprops thm) (map assume_goal cprops)
   948   |> implies_intr_list (map mk_cgoal cprops);
   949 
   950 
   951 
   952 (** variations on instantiate **)
   953 
   954 (*shorthand for instantiating just one variable in the current theory*)
   955 fun inst x t = read_instantiate_sg (sign_of (the_context())) [(x,t)];
   956 
   957 
   958 (* collect vars in left-to-right order *)
   959 
   960 fun tvars_of_terms ts = rev (Library.foldl Term.add_tvars ([], ts));
   961 fun vars_of_terms ts = rev (Library.foldl Term.add_vars ([], ts));
   962 
   963 fun tvars_of thm = tvars_of_terms [prop_of thm];
   964 fun vars_of thm = vars_of_terms [prop_of thm];
   965 
   966 
   967 (* instantiate by left-to-right occurrence of variables *)
   968 
   969 fun instantiate' cTs cts thm =
   970   let
   971     fun err msg =
   972       raise TYPE ("instantiate': " ^ msg,
   973         List.mapPartial (Option.map Thm.typ_of) cTs,
   974         List.mapPartial (Option.map Thm.term_of) cts);
   975 
   976     fun inst_of (v, ct) =
   977       (Thm.cterm_of (#sign (Thm.rep_cterm ct)) (Var v), ct)
   978         handle TYPE (msg, _, _) => err msg;
   979 
   980     fun tyinst_of (v, cT) =
   981       (Thm.ctyp_of (#sign (Thm.rep_ctyp cT)) (TVar v), cT)
   982         handle TYPE (msg, _, _) => err msg;
   983 
   984     fun zip_vars _ [] = []
   985       | zip_vars (_ :: vs) (NONE :: opt_ts) = zip_vars vs opt_ts
   986       | zip_vars (v :: vs) (SOME t :: opt_ts) = (v, t) :: zip_vars vs opt_ts
   987       | zip_vars [] _ = err "more instantiations than variables in thm";
   988 
   989     (*instantiate types first!*)
   990     val thm' =
   991       if forall is_none cTs then thm
   992       else Thm.instantiate (map tyinst_of (zip_vars (tvars_of thm) cTs), []) thm;
   993     in
   994       if forall is_none cts then thm'
   995       else Thm.instantiate ([], map inst_of (zip_vars (vars_of thm') cts)) thm'
   996     end;
   997 
   998 
   999 
  1000 (** renaming of bound variables **)
  1001 
  1002 (* replace bound variables x_i in thm by y_i *)
  1003 (* where vs = [(x_1, y_1), ..., (x_n, y_n)]  *)
  1004 
  1005 fun rename_bvars [] thm = thm
  1006   | rename_bvars vs thm =
  1007     let
  1008       val {sign, prop, ...} = rep_thm thm;
  1009       fun ren (Abs (x, T, t)) = Abs (getOpt (assoc (vs, x), x), T, ren t)
  1010         | ren (t $ u) = ren t $ ren u
  1011         | ren t = t;
  1012     in equal_elim (reflexive (cterm_of sign (ren prop))) thm end;
  1013 
  1014 
  1015 (* renaming in left-to-right order *)
  1016 
  1017 fun rename_bvars' xs thm =
  1018   let
  1019     val {sign, prop, ...} = rep_thm thm;
  1020     fun rename [] t = ([], t)
  1021       | rename (x' :: xs) (Abs (x, T, t)) =
  1022           let val (xs', t') = rename xs t
  1023           in (xs', Abs (getOpt (x',x), T, t')) end
  1024       | rename xs (t $ u) =
  1025           let
  1026             val (xs', t') = rename xs t;
  1027             val (xs'', u') = rename xs' u
  1028           in (xs'', t' $ u') end
  1029       | rename xs t = (xs, t);
  1030   in case rename xs prop of
  1031       ([], prop') => equal_elim (reflexive (cterm_of sign prop')) thm
  1032     | _ => error "More names than abstractions in theorem"
  1033   end;
  1034 
  1035 
  1036 
  1037 (* unvarify(T) *)
  1038 
  1039 (*assume thm in standard form, i.e. no frees, 0 var indexes*)
  1040 
  1041 fun unvarifyT thm =
  1042   let
  1043     val cT = Thm.ctyp_of (Thm.sign_of_thm thm);
  1044     val tfrees = map (fn ((x, _), S) => SOME (cT (TFree (x, S)))) (tvars_of thm);
  1045   in instantiate' tfrees [] thm end;
  1046 
  1047 fun unvarify raw_thm =
  1048   let
  1049     val thm = unvarifyT raw_thm;
  1050     val ct = Thm.cterm_of (Thm.sign_of_thm thm);
  1051     val frees = map (fn ((x, _), T) => SOME (ct (Free (x, T)))) (vars_of thm);
  1052   in instantiate' [] frees thm end;
  1053 
  1054 
  1055 (* tvars_intr_list *)
  1056 
  1057 fun tfrees_of thm =
  1058   let val {hyps, prop, ...} = Thm.rep_thm thm
  1059   in foldr Term.add_term_tfrees [] (prop :: hyps) end;
  1060 
  1061 fun tvars_intr_list tfrees thm =
  1062   apsnd (map (fn ((s, S), ixn) => (s, (ixn, S)))) (Thm.varifyT'
  1063     (gen_rems (op = o apfst fst) (tfrees_of thm, tfrees)) thm);
  1064 
  1065 
  1066 (* increment var indexes *)
  1067 
  1068 fun incr_indexes_wrt is cTs cts thms =
  1069   let
  1070     val maxidx =
  1071       Library.foldl Int.max (~1, is @
  1072         map (maxidx_of_typ o #T o Thm.rep_ctyp) cTs @
  1073         map (#maxidx o Thm.rep_cterm) cts @
  1074         map (#maxidx o Thm.rep_thm) thms);
  1075   in Thm.incr_indexes (maxidx + 1) end;
  1076 
  1077 
  1078 (* freeze_all *)
  1079 
  1080 (*freeze all (T)Vars; assumes thm in standard form*)
  1081 
  1082 fun freeze_all_TVars thm =
  1083   (case tvars_of thm of
  1084     [] => thm
  1085   | tvars =>
  1086       let val cert = Thm.ctyp_of (Thm.sign_of_thm thm)
  1087       in instantiate' (map (fn ((x, _), S) => SOME (cert (TFree (x, S)))) tvars) [] thm end);
  1088 
  1089 fun freeze_all_Vars thm =
  1090   (case vars_of thm of
  1091     [] => thm
  1092   | vars =>
  1093       let val cert = Thm.cterm_of (Thm.sign_of_thm thm)
  1094       in instantiate' [] (map (fn ((x, _), T) => SOME (cert (Free (x, T)))) vars) thm end);
  1095 
  1096 val freeze_all = freeze_all_Vars o freeze_all_TVars;
  1097 
  1098 
  1099 (* mk_triv_goal *)
  1100 
  1101 (*make an initial proof state, "PROP A ==> (PROP A)" *)
  1102 fun mk_triv_goal ct = instantiate' [] [SOME ct] triv_goal;
  1103 
  1104 
  1105 
  1106 (** meta-level conjunction **)
  1107 
  1108 local
  1109   val A = read_prop "PROP A";
  1110   val B = read_prop "PROP B";
  1111   val C = read_prop "PROP C";
  1112   val ABC = read_prop "PROP A ==> PROP B ==> PROP C";
  1113 
  1114   val proj1 =
  1115     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume A))
  1116     |> forall_elim_vars 0;
  1117 
  1118   val proj2 =
  1119     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume B))
  1120     |> forall_elim_vars 0;
  1121 
  1122   val conj_intr_rule =
  1123     forall_intr_list [A, B] (implies_intr_list [A, B]
  1124       (Thm.forall_intr C (Thm.implies_intr ABC
  1125         (implies_elim_list (Thm.assume ABC) [Thm.assume A, Thm.assume B]))))
  1126     |> forall_elim_vars 0;
  1127 
  1128   val incr = incr_indexes_wrt [] [] [];
  1129 in
  1130 
  1131 fun conj_intr tha thb = thb COMP (tha COMP incr [tha, thb] conj_intr_rule);
  1132 
  1133 fun conj_intr_list [] = asm_rl
  1134   | conj_intr_list ths = foldr1 (uncurry conj_intr) ths;
  1135 
  1136 fun conj_elim th =
  1137   let val th' = forall_elim_var (#maxidx (Thm.rep_thm th) + 1) th
  1138   in (incr [th'] proj1 COMP th', incr [th'] proj2 COMP th') end;
  1139 
  1140 fun conj_elim_list th =
  1141   let val (th1, th2) = conj_elim th
  1142   in conj_elim_list th1 @ conj_elim_list th2 end handle THM _ => [th];
  1143 
  1144 fun conj_elim_precise 0 _ = []
  1145   | conj_elim_precise 1 th = [th]
  1146   | conj_elim_precise n th =
  1147       let val (th1, th2) = conj_elim th
  1148       in th1 :: conj_elim_precise (n - 1) th2 end;
  1149 
  1150 val conj_intr_thm = store_standard_thm_open "conjunctionI"
  1151   (implies_intr_list [A, B] (conj_intr (Thm.assume A) (Thm.assume B)));
  1152 
  1153 end;
  1154 
  1155 end;
  1156 
  1157 structure BasicDrule: BASIC_DRULE = Drule;
  1158 open BasicDrule;