src/Pure/pure_thy.ML
author obua
Sun May 29 12:39:12 2005 +0200 (2005-05-29)
changeset 16108 cf468b93a02e
parent 16023 66561f6814bd
child 16132 afd2d32c7d94
permissions -rw-r--r--
Implement cycle-free overloading, so that definitions cannot harm consistency any more (except of course via interaction with axioms).
     1 (*  Title:      Pure/pure_thy.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Theorem database, derived theory operations, and the ProtoPure theory.
     6 *)
     7 
     8 signature BASIC_PURE_THY =
     9 sig
    10   type thmref
    11   val print_theorems: theory -> unit
    12   val print_theory: theory -> unit
    13   val get_thm: theory -> thmref -> thm
    14   val get_thms: theory -> thmref -> thm list
    15   val get_thmss: theory -> thmref list -> thm list
    16   val thms_of: theory -> (string * thm) list
    17   structure ProtoPure:
    18     sig
    19       val thy: theory
    20       val Goal_def: thm
    21     end
    22 end;
    23 
    24 signature PURE_THY =
    25 sig
    26   include BASIC_PURE_THY
    27   datatype interval = FromTo of int * int | From of int | Single of int
    28   val string_of_thmref: thmref -> string
    29   val get_thm_closure: theory -> thmref -> thm
    30   val get_thms_closure: theory -> thmref -> thm list
    31   val single_thm: string -> thm list -> thm
    32   val select_thm: thmref -> thm list -> thm list
    33   val selections: string * thm list -> (thmref * thm) list
    34   val cond_extern_thm_sg: Sign.sg -> string -> xstring
    35   val fact_index_of: theory -> FactIndex.T
    36   val valid_thms: theory -> thmref * thm list -> bool
    37   val thms_containing: theory -> FactIndex.spec -> (string * thm list) list
    38   val thms_containing_consts: theory -> string list -> (string * thm) list
    39   val hide_thms: bool -> string list -> theory -> theory
    40   val store_thm: (bstring * thm) * theory attribute list -> theory -> theory * thm
    41   val smart_store_thms: (bstring * thm list) -> thm list
    42   val smart_store_thms_open: (bstring * thm list) -> thm list
    43   val forall_elim_var: int -> thm -> thm
    44   val forall_elim_vars: int -> thm -> thm
    45   val add_thms: ((bstring * thm) * theory attribute list) list -> theory -> theory * thm list
    46   val add_thmss: ((bstring * thm list) * theory attribute list) list -> theory
    47     -> theory * thm list list
    48   val note_thmss:
    49     theory attribute -> ((bstring * theory attribute list) *
    50     (thmref * theory attribute list) list) list -> theory ->
    51     theory * (bstring * thm list) list
    52   val note_thmss_i:
    53     theory attribute -> ((bstring * theory attribute list) *
    54     (thm list * theory attribute list) list) list -> theory ->
    55     theory * (bstring * thm list) list
    56   val note_thmss_accesses:
    57     (string -> string list) ->
    58     theory attribute -> ((bstring * theory attribute list) *
    59     (thmref * theory attribute list) list) list -> theory ->
    60     theory * (bstring * thm list) list
    61   val note_thmss_accesses_i:
    62     (string -> string list) ->
    63     theory attribute -> ((bstring * theory attribute list) *
    64     (thm list * theory attribute list) list) list -> theory ->
    65     theory * (bstring * thm list) list
    66   val add_axioms: ((bstring * string) * theory attribute list) list -> theory -> theory * thm list
    67   val add_axioms_i: ((bstring * term) * theory attribute list) list -> theory -> theory * thm list
    68   val add_axiomss: ((bstring * string list) * theory attribute list) list -> theory
    69     -> theory * thm list list
    70   val add_axiomss_i: ((bstring * term list) * theory attribute list) list -> theory
    71     -> theory * thm list list
    72   val add_defs: bool -> ((bstring * string) * theory attribute list) list
    73     -> theory -> theory * thm list
    74   val add_defs_i: bool -> ((bstring * term) * theory attribute list) list
    75     -> theory -> theory * thm list
    76   val add_defss: bool -> ((bstring * string list) * theory attribute list) list
    77     -> theory -> theory * thm list list
    78   val add_defss_i: bool -> ((bstring * term list) * theory attribute list) list
    79     -> theory -> theory * thm list list
    80   val get_name: theory -> string
    81   val put_name: string -> theory -> theory
    82   val global_path: theory -> theory
    83   val local_path: theory -> theory
    84   val begin_theory: string -> theory list -> theory
    85   val end_theory: theory -> theory
    86   val checkpoint: theory -> theory
    87   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    88 end;
    89 
    90 structure PureThy: PURE_THY =
    91 struct
    92 
    93 
    94 (*** theorem database ***)
    95 
    96 (** data kind 'Pure/theorems' **)
    97 
    98 structure TheoremsDataArgs =
    99 struct
   100   val name = "Pure/theorems";
   101 
   102   type T =
   103     {space: NameSpace.T,
   104       theorems: thm list Symtab.table,
   105       index: FactIndex.T} ref;
   106 
   107   fun mk_empty _ =
   108     ref {space = NameSpace.empty, theorems = Symtab.empty, index = FactIndex.empty}: T;
   109 
   110   val empty = mk_empty ();
   111   fun copy (ref x) = ref x;
   112   val prep_ext = mk_empty;
   113   val merge = mk_empty;
   114 
   115   fun pretty sg (ref {space, theorems, index = _}) =
   116     let
   117       val prt_thm = Display.pretty_thm_sg sg;
   118       fun prt_thms (name, [th]) =
   119             Pretty.block [Pretty.str (name ^ ":"), Pretty.brk 1, prt_thm th]
   120         | prt_thms (name, ths) = Pretty.big_list (name ^ ":") (map prt_thm ths);
   121 
   122       val thmss = NameSpace.cond_extern_table space theorems;
   123     in Pretty.big_list "theorems:" (map prt_thms thmss) end;
   124 
   125   fun print sg data = Pretty.writeln (pretty sg data);
   126 end;
   127 
   128 structure TheoremsData = TheoryDataFun(TheoremsDataArgs);
   129 val get_theorems_sg = TheoremsData.get_sg;
   130 val get_theorems = TheoremsData.get;
   131 
   132 val cond_extern_thm_sg = NameSpace.cond_extern o #space o ! o get_theorems_sg;
   133 val fact_index_of = #index o ! o get_theorems;
   134 
   135 
   136 
   137 (* print theory *)
   138 
   139 val print_theorems = TheoremsData.print;
   140 
   141 fun print_theory thy =
   142   Display.pretty_full_theory thy @
   143   [TheoremsDataArgs.pretty (Theory.sign_of thy) (get_theorems thy)]
   144   |> Pretty.chunks |> Pretty.writeln;
   145 
   146 
   147 
   148 (** retrieve theorems **)
   149 
   150 fun the_thms _ (SOME thms) = thms
   151   | the_thms name NONE = error ("Unknown theorem(s) " ^ quote name);
   152 
   153 fun single_thm _ [thm] = thm
   154   | single_thm name _ = error ("Single theorem expected " ^ quote name);
   155 
   156 
   157 (* datatype interval *)
   158 
   159 datatype interval =
   160   FromTo of int * int |
   161   From of int |
   162   Single of int;
   163 
   164 fun interval _ (FromTo (i, j)) = i upto j
   165   | interval n (From i) = i upto n
   166   | interval _ (Single i) = [i];
   167 
   168 fun string_of_interval (FromTo (i, j)) = string_of_int i ^ "-" ^ string_of_int j
   169   | string_of_interval (From i) = string_of_int i ^ "-"
   170   | string_of_interval (Single i) = string_of_int i;
   171 
   172 
   173 (* type thmref *)
   174 
   175 type thmref = xstring * interval list option;
   176 
   177 fun string_of_thmref (name, NONE) = name
   178   | string_of_thmref (name, SOME is) =
   179       name ^ enclose "(" ")" (commas (map string_of_interval is));
   180 
   181 
   182 (* select_thm *)
   183 
   184 fun select_thm (_, NONE) thms = thms
   185   | select_thm (name, SOME is) thms =
   186       let
   187         val n = length thms;
   188         fun select i =
   189           if i < 1 orelse i > n then
   190             error ("Bad subscript " ^ string_of_int i ^ " for " ^
   191               quote name ^ " (length " ^ string_of_int n ^ ")")
   192           else List.nth (thms, i - 1);
   193       in map select (List.concat (map (interval n) is)) end;
   194 
   195 
   196 (* selections *)
   197 
   198 fun selections (name, [thm]) = [((name, NONE), thm)]
   199   | selections (name, thms) = (1 upto length thms, thms) |> ListPair.map (fn (i, thm) =>
   200       ((name, SOME [Single i]), thm));
   201 
   202 
   203 (* get_thm(s)_closure -- statically scoped versions *)
   204 
   205 (*beware of proper order of evaluation!*)
   206 
   207 fun lookup_thms thy =
   208   let
   209     val sg_ref = Sign.self_ref (Theory.sign_of thy);
   210     val ref {space, theorems, ...} = get_theorems thy;
   211   in
   212     fn name =>
   213       Option.map (map (Thm.transfer_sg (Sign.deref sg_ref)))        (*semi-dynamic identity*)
   214       (Symtab.lookup (theorems, NameSpace.intern space name))   (*static content*)
   215   end;
   216 
   217 fun get_thms_closure thy =
   218   let val closures = map lookup_thms (thy :: Theory.ancestors_of thy)
   219   in fn namei as (name, _) => select_thm namei
   220     (the_thms name (get_first (fn f => f name) closures))
   221   end;
   222 
   223 fun get_thm_closure thy =
   224   let val get = get_thms_closure thy
   225   in fn namei as (name, _) => single_thm name (get namei) end;
   226 
   227 
   228 (* get_thm etc. *)
   229 
   230 fun get_thms theory (namei as (name, _)) =
   231   get_first (fn thy => lookup_thms thy name) (theory :: Theory.ancestors_of theory)
   232   |> the_thms name |> select_thm namei |> map (Thm.transfer theory);
   233 
   234 fun get_thmss thy names = List.concat (map (get_thms thy) names);
   235 fun get_thm thy (namei as (name, _)) = single_thm name (get_thms thy namei);
   236 
   237 
   238 (* thms_containing etc. *)
   239 
   240 fun valid_thms thy (thmref, ths) =
   241   (case try (transform_error (get_thms thy)) thmref of
   242     NONE => false
   243   | SOME ths' => Library.equal_lists Thm.eq_thm (ths, ths'));
   244 
   245 fun thms_containing theory spec =
   246   (theory :: Theory.ancestors_of theory)
   247   |> map (fn thy =>
   248       FactIndex.find (fact_index_of thy) spec
   249       |> List.filter (fn (name, ths) => valid_thms theory ((name, NONE), ths))
   250       |> gen_distinct eq_fst)
   251   |> List.concat;
   252 
   253 fun thms_containing_consts thy consts =
   254   thms_containing thy (consts, []) |> map #2 |> List.concat
   255   |> map (fn th => (Thm.name_of_thm th, th));
   256 
   257 
   258 (* thms_of *)
   259 
   260 fun thms_of thy =
   261   let val ref {theorems, ...} = get_theorems thy in
   262     map (fn th => (Thm.name_of_thm th, th)) (List.concat (map snd (Symtab.dest theorems)))
   263   end;
   264 
   265 
   266 
   267 (** store theorems **)                    (*DESTRUCTIVE*)
   268 
   269 (* hiding -- affects current theory node only! *)
   270 
   271 fun hide_thms fully names thy =
   272   let
   273     val r as ref {space, theorems, index} = get_theorems thy;
   274     val space' = NameSpace.hide fully (space, names);
   275   in r := {space = space', theorems = theorems, index = index}; thy end;
   276 
   277 
   278 (* naming *)
   279 
   280 fun gen_names j len name =
   281   map (fn i => name ^ "_" ^ string_of_int i) (j+1 upto j+len);
   282 
   283 fun name_multi name xs = gen_names 0 (length xs) name ~~ xs;
   284 
   285 fun name_thm pre (p as (_, thm)) =
   286   if Thm.name_of_thm thm <> "" andalso pre then thm else Thm.name_thm p;
   287 
   288 fun name_thms pre name [x] = [name_thm pre (name, x)]
   289   | name_thms pre name xs = map (name_thm pre) (name_multi name xs);
   290 
   291 fun name_thmss name xs = (case filter_out (null o fst) xs of
   292     [([x], z)] => [([name_thm true (name, x)], z)]
   293   | _ => snd (foldl_map (fn (i, (ys, z)) => (i + length ys,
   294   (map (name_thm true) (gen_names i (length ys) name ~~ ys), z))) (0, xs)));
   295 
   296 
   297 (* enter_thms *)
   298 
   299 fun warn_overwrite name = warning ("Replaced old copy of theorems " ^ quote name);
   300 fun warn_same name = warning ("Theorem database already contains a copy of " ^ quote name);
   301 
   302 fun gen_enter_thms _ _ _ _ _ app_att thy ("", thms) = app_att (thy, thms)
   303   | gen_enter_thms full acc sg pre_name post_name app_att thy (bname, thms) =
   304       let
   305         val name = full sg bname;
   306         val (thy', thms') = app_att (thy, pre_name name thms);
   307         val named_thms = post_name name thms';
   308 
   309         val r as ref {space, theorems, index} = get_theorems_sg sg;
   310         val space' = NameSpace.extend' acc (space, [name]);
   311         val theorems' = Symtab.update ((name, named_thms), theorems);
   312         val index' = FactIndex.add (K false) (name, named_thms) index;
   313       in
   314         (case Symtab.lookup (theorems, name) of
   315           NONE => ()
   316         | SOME thms' =>
   317             if Library.equal_lists Thm.eq_thm (thms', named_thms) then warn_same name
   318             else warn_overwrite name);
   319         r := {space = space', theorems = theorems', index = index'};
   320         (thy', named_thms)
   321       end;
   322 
   323 fun enter_thms sg = gen_enter_thms Sign.full_name NameSpace.accesses sg;
   324 
   325 
   326 (* add_thms(s) *)
   327 
   328 fun add_thms_atts pre_name ((bname, thms), atts) thy =
   329   enter_thms (Theory.sign_of thy) pre_name (name_thms false)
   330     (Thm.applys_attributes o rpair atts) thy (bname, thms);
   331 
   332 fun gen_add_thmss pre_name args theory =
   333   foldl_map (fn (thy, arg) => add_thms_atts pre_name arg thy) (theory, args);
   334 
   335 fun gen_add_thms pre_name args =
   336   apsnd (map hd) o gen_add_thmss pre_name (map (apfst (apsnd single)) args);
   337 
   338 val add_thmss = gen_add_thmss (name_thms true);
   339 val add_thms = gen_add_thms (name_thms true);
   340 
   341 
   342 (* note_thmss(_i) *)
   343 
   344 local
   345 
   346 fun gen_note_thss enter get kind_att (thy, ((bname, more_atts), ths_atts)) =
   347   let
   348     fun app (x, (ths, atts)) = Thm.applys_attributes ((x, ths), atts);
   349     val (thy', thms) = enter (Theory.sign_of thy)
   350       name_thmss (name_thms false) (apsnd List.concat o foldl_map app) thy
   351       (bname, map (fn (ths, atts) => (get thy ths, atts @ more_atts @ [kind_att])) ths_atts);
   352   in (thy', (bname, thms)) end;
   353 
   354 fun gen_note_thmss enter get kind_att args thy =
   355   foldl_map (gen_note_thss enter get kind_att) (thy, args);
   356 
   357 in
   358 
   359 (*if path is set, only permit unqualified names*)
   360 val note_thmss = gen_note_thmss enter_thms get_thms;
   361 val note_thmss_i = gen_note_thmss enter_thms (K I);
   362 
   363 (*always permit qualified names, clients may specify non-standard access policy*)
   364 fun note_thmss_accesses acc = gen_note_thmss (gen_enter_thms Sign.full_name' acc) get_thms;
   365 fun note_thmss_accesses_i acc = gen_note_thmss (gen_enter_thms Sign.full_name' acc) (K I);
   366 
   367 end;
   368 
   369 
   370 (* store_thm *)
   371 
   372 fun store_thm ((bname, thm), atts) thy =
   373   let val (thy', [th']) = add_thms_atts (name_thms true) ((bname, [thm]), atts) thy
   374   in (thy', th') end;
   375 
   376 
   377 (* smart_store_thms *)
   378 
   379 fun gen_smart_store_thms _ (name, []) =
   380       error ("Cannot store empty list of theorems: " ^ quote name)
   381   | gen_smart_store_thms name_thm (name, [thm]) =
   382       snd (enter_thms (Thm.sign_of_thm thm) (name_thm true) (name_thm false)
   383         I () (name, [thm]))
   384   | gen_smart_store_thms name_thm (name, thms) =
   385       let
   386         val merge_sg = Sign.merge_refs o apsnd (Sign.self_ref o Thm.sign_of_thm);
   387         val sg_ref = Library.foldl merge_sg (Sign.self_ref (Thm.sign_of_thm (hd thms)), tl thms);
   388       in snd (enter_thms (Sign.deref sg_ref) (name_thm true) (name_thm false)
   389         I () (name, thms))
   390       end;
   391 
   392 val smart_store_thms = gen_smart_store_thms name_thms;
   393 val smart_store_thms_open = gen_smart_store_thms (K (K I));
   394 
   395 
   396 (* forall_elim_vars (belongs to drule.ML) *)
   397 
   398 (*Replace outermost quantified variable by Var of given index.*)
   399 fun forall_elim_var i th =
   400     let val {prop,sign,...} = rep_thm th
   401     in case prop of
   402         Const ("all", _) $ Abs (a, T, _) =>
   403           let val used = map (fst o fst)
   404             (List.filter (equal i o snd o fst) (Term.add_vars ([], prop)))
   405           in forall_elim (cterm_of sign (Var ((variant used a, i), T))) th end
   406       | _ => raise THM ("forall_elim_var", i, [th])
   407     end;
   408 
   409 (*Repeat forall_elim_var until all outer quantifiers are removed*)
   410 fun forall_elim_vars i th =
   411     forall_elim_vars i (forall_elim_var i th)
   412         handle THM _ => th;
   413 
   414 
   415 (* store axioms as theorems *)
   416 
   417 local
   418   fun get_axs thy named_axs =
   419     map (forall_elim_vars 0 o Thm.get_axiom thy o fst) named_axs;
   420 
   421   fun add_single add (thy, ((name, ax), atts)) =
   422     let
   423       val named_ax = [(name, ax)];
   424       val thy' = add named_ax thy;
   425       val thm = hd (get_axs thy' named_ax);
   426     in apsnd hd (gen_add_thms (K I) [((name, thm), atts)] thy') end;
   427 
   428   fun add_multi add (thy, ((name, axs), atts)) =
   429     let
   430       val named_axs = name_multi name axs;
   431       val thy' = add named_axs thy;
   432       val thms = get_axs thy' named_axs;
   433     in apsnd hd (gen_add_thmss (K I) [((name, thms), atts)] thy') end;
   434 
   435   fun add_singles add args thy = foldl_map (add_single add) (thy, args);
   436   fun add_multis add args thy = foldl_map (add_multi add) (thy, args);
   437 in
   438   val add_axioms    = add_singles Theory.add_axioms;
   439   val add_axioms_i  = add_singles Theory.add_axioms_i;
   440   val add_axiomss   = add_multis Theory.add_axioms;
   441   val add_axiomss_i = add_multis Theory.add_axioms_i;
   442   val add_defs      = add_singles o Theory.add_defs;
   443   val add_defs_i    = add_singles o Theory.add_defs_i;
   444   val add_defss     = add_multis o Theory.add_defs;
   445   val add_defss_i   = add_multis o Theory.add_defs_i;
   446 end;
   447 
   448 
   449 
   450 (*** derived theory operations ***)
   451 
   452 (** theory management **)
   453 
   454 (* data kind 'Pure/theory_management' *)
   455 
   456 structure TheoryManagementDataArgs =
   457 struct
   458   val name = "Pure/theory_management";
   459   type T = {name: string, version: int};
   460 
   461   val empty = {name = "", version = 0};
   462   val copy = I;
   463   val prep_ext  = I;
   464   fun merge _ = empty;
   465   fun print _ _ = ();
   466 end;
   467 
   468 structure TheoryManagementData = TheoryDataFun(TheoryManagementDataArgs);
   469 val get_info = TheoryManagementData.get;
   470 val put_info = TheoryManagementData.put;
   471 
   472 
   473 (* get / put name *)
   474 
   475 val get_name = #name o get_info;
   476 fun put_name name = put_info {name = name, version = 0};
   477 
   478 
   479 (* control prefixing of theory name *)
   480 
   481 val global_path = Theory.root_path;
   482 
   483 fun local_path thy =
   484   thy |> Theory.root_path |> Theory.add_path (get_name thy);
   485 
   486 
   487 (* begin / end theory *)
   488 
   489 fun begin_theory name thys =
   490   Theory.prep_ext_merge thys
   491   |> put_name name
   492   |> local_path;
   493 
   494 fun end_theory thy =
   495   thy
   496   |> Theory.add_name (get_name thy);
   497 
   498 fun checkpoint thy =
   499   if is_draft thy then
   500     let val {name, version} = get_info thy in
   501       thy
   502       |> Theory.add_name (name ^ ":" ^ string_of_int version)
   503       |> put_info {name = name, version = version + 1}
   504     end
   505   else thy;
   506 
   507 
   508 
   509 (** add logical types **)
   510 
   511 fun add_typedecls decls thy =
   512   let
   513     val full = Sign.full_name (Theory.sign_of thy);
   514 
   515     fun type_of (raw_name, vs, mx) =
   516       if null (duplicates vs) then (raw_name, length vs, mx)
   517       else error ("Duplicate parameters in type declaration: " ^ quote raw_name);
   518   in thy |> Theory.add_types (map type_of decls) end;
   519 
   520 
   521 
   522 (*** the ProtoPure theory ***)
   523 
   524 val proto_pure =
   525   Theory.pre_pure
   526   |> TheoryManagementData.init |> put_name "ProtoPure"
   527   |> TheoremsData.init
   528   |> Proofterm.init
   529   |> global_path
   530   |> Theory.add_types
   531    [("fun", 2, NoSyn),
   532     ("prop", 0, NoSyn),
   533     ("itself", 1, NoSyn),
   534     ("dummy", 0, NoSyn)]
   535   |> Theory.add_nonterminals Syntax.pure_nonterms
   536   |> Theory.add_syntax Syntax.pure_syntax
   537   |> Theory.add_syntax Syntax.pure_appl_syntax
   538   |> Theory.add_modesyntax (Symbol.xsymbolsN, true) Syntax.pure_xsym_syntax
   539   |> Theory.add_syntax
   540    [("==>", "[prop, prop] => prop", Delimfix "op ==>"),
   541     (Term.dummy_patternN, "aprop", Delimfix "'_")]
   542   |> Theory.add_consts
   543    [("==", "['a, 'a] => prop", InfixrName ("==", 2)),
   544     ("==>", "[prop, prop] => prop", Mixfix ("(_/ ==> _)", [2, 1], 1)),
   545     ("all", "('a => prop) => prop", Binder ("!!", 0, 0)),
   546     ("Goal", "prop => prop", NoSyn),
   547     ("TYPE", "'a itself", NoSyn),
   548     (Term.dummy_patternN, "'a", Delimfix "'_")]
   549   |> Theory.add_finals_i false
   550     [Const("==", [TFree ("'a", []), TFree ("'a", [])] ---> propT),
   551      Const("==>", [propT, propT] ---> propT),
   552      Const("all", (TFree("'a", []) --> propT) --> propT),
   553      Const("TYPE", a_itselfT)]
   554   |> Theory.add_modesyntax ("", false)
   555     (Syntax.pure_syntax_output @ Syntax.pure_appl_syntax)
   556   |> Theory.add_trfuns Syntax.pure_trfuns
   557   |> Theory.add_trfunsT Syntax.pure_trfunsT
   558   |> local_path
   559   |> (#1 oo (add_defs_i false o map Thm.no_attributes))
   560    [("Goal_def", let val A = Free ("A", propT) in Logic.mk_equals (Logic.mk_goal A, A) end)]
   561   |> (#1 o add_thmss [(("nothing", []), [])])
   562   |> Theory.add_axioms_i Proofterm.equality_axms
   563   |> end_theory;
   564 
   565 structure ProtoPure =
   566 struct
   567   val thy = proto_pure;
   568   val Goal_def = get_axiom thy "Goal_def";
   569 end;
   570 
   571 end;
   572 
   573 structure BasicPureThy: BASIC_PURE_THY = PureThy;
   574 open BasicPureThy;