src/HOL/Library/Dlist.thy
author haftmann
Wed Mar 10 15:29:22 2010 +0100 (2010-03-10)
changeset 35688 cfe0accda6e3
parent 35303 816e48d60b13
child 36112 7fa17a225852
permissions -rw-r--r--
avoid confusion
     1 (* Author: Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Lists with elements distinct as canonical example for datatype invariants *}
     4 
     5 theory Dlist
     6 imports Main Fset
     7 begin
     8 
     9 section {* Prelude *}
    10 
    11 text {* Without canonical argument order, higher-order things tend to get confusing quite fast: *}
    12 
    13 setup {* Sign.map_naming (Name_Space.add_path "List") *}
    14 
    15 primrec member :: "'a list \<Rightarrow> 'a \<Rightarrow> bool" where
    16     "member [] y \<longleftrightarrow> False"
    17   | "member (x#xs) y \<longleftrightarrow> x = y \<or> member xs y"
    18 
    19 lemma member_set:
    20   "member = set"
    21 proof (rule ext)+
    22   fix xs :: "'a list" and x :: 'a
    23   have "member xs x \<longleftrightarrow> x \<in> set xs" by (induct xs) auto
    24   then show "member xs x = set xs x" by (simp add: mem_def)
    25 qed
    26 
    27 lemma not_set_compl:
    28   "Not \<circ> set xs = - set xs"
    29   by (simp add: fun_Compl_def bool_Compl_def comp_def expand_fun_eq)
    30 
    31 primrec fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a list \<Rightarrow> 'b \<Rightarrow> 'b" where
    32     "fold f [] s = s"
    33   | "fold f (x#xs) s = fold f xs (f x s)"
    34 
    35 lemma foldl_fold:
    36   "foldl f s xs = List.fold (\<lambda>x s. f s x) xs s"
    37   by (induct xs arbitrary: s) simp_all
    38 
    39 setup {* Sign.map_naming Name_Space.parent_path *}
    40 
    41 
    42 section {* The type of distinct lists *}
    43 
    44 typedef (open) 'a dlist = "{xs::'a list. distinct xs}"
    45   morphisms list_of_dlist Abs_dlist
    46 proof
    47   show "[] \<in> ?dlist" by simp
    48 qed
    49 
    50 text {* Formal, totalized constructor for @{typ "'a dlist"}: *}
    51 
    52 definition Dlist :: "'a list \<Rightarrow> 'a dlist" where
    53   [code del]: "Dlist xs = Abs_dlist (remdups xs)"
    54 
    55 lemma distinct_list_of_dlist [simp]:
    56   "distinct (list_of_dlist dxs)"
    57   using list_of_dlist [of dxs] by simp
    58 
    59 lemma list_of_dlist_Dlist [simp]:
    60   "list_of_dlist (Dlist xs) = remdups xs"
    61   by (simp add: Dlist_def Abs_dlist_inverse)
    62 
    63 lemma Dlist_list_of_dlist [simp]:
    64   "Dlist (list_of_dlist dxs) = dxs"
    65   by (simp add: Dlist_def list_of_dlist_inverse distinct_remdups_id)
    66 
    67 
    68 text {* Fundamental operations: *}
    69 
    70 definition empty :: "'a dlist" where
    71   "empty = Dlist []"
    72 
    73 definition insert :: "'a \<Rightarrow> 'a dlist \<Rightarrow> 'a dlist" where
    74   "insert x dxs = Dlist (List.insert x (list_of_dlist dxs))"
    75 
    76 definition remove :: "'a \<Rightarrow> 'a dlist \<Rightarrow> 'a dlist" where
    77   "remove x dxs = Dlist (remove1 x (list_of_dlist dxs))"
    78 
    79 definition map :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a dlist \<Rightarrow> 'b dlist" where
    80   "map f dxs = Dlist (remdups (List.map f (list_of_dlist dxs)))"
    81 
    82 definition filter :: "('a \<Rightarrow> bool) \<Rightarrow> 'a dlist \<Rightarrow> 'a dlist" where
    83   "filter P dxs = Dlist (List.filter P (list_of_dlist dxs))"
    84 
    85 
    86 text {* Derived operations: *}
    87 
    88 definition null :: "'a dlist \<Rightarrow> bool" where
    89   "null dxs = List.null (list_of_dlist dxs)"
    90 
    91 definition member :: "'a dlist \<Rightarrow> 'a \<Rightarrow> bool" where
    92   "member dxs = List.member (list_of_dlist dxs)"
    93 
    94 definition length :: "'a dlist \<Rightarrow> nat" where
    95   "length dxs = List.length (list_of_dlist dxs)"
    96 
    97 definition fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a dlist \<Rightarrow> 'b \<Rightarrow> 'b" where
    98   "fold f dxs = List.fold f (list_of_dlist dxs)"
    99 
   100 
   101 section {* Executable version obeying invariant *}
   102 
   103 code_abstype Dlist list_of_dlist
   104   by simp
   105 
   106 lemma list_of_dlist_empty [simp, code abstract]:
   107   "list_of_dlist empty = []"
   108   by (simp add: empty_def)
   109 
   110 lemma list_of_dlist_insert [simp, code abstract]:
   111   "list_of_dlist (insert x dxs) = List.insert x (list_of_dlist dxs)"
   112   by (simp add: insert_def)
   113 
   114 lemma list_of_dlist_remove [simp, code abstract]:
   115   "list_of_dlist (remove x dxs) = remove1 x (list_of_dlist dxs)"
   116   by (simp add: remove_def)
   117 
   118 lemma list_of_dlist_map [simp, code abstract]:
   119   "list_of_dlist (map f dxs) = remdups (List.map f (list_of_dlist dxs))"
   120   by (simp add: map_def)
   121 
   122 lemma list_of_dlist_filter [simp, code abstract]:
   123   "list_of_dlist (filter P dxs) = List.filter P (list_of_dlist dxs)"
   124   by (simp add: filter_def)
   125 
   126 
   127 section {* Implementation of sets by distinct lists -- canonical! *}
   128 
   129 definition Set :: "'a dlist \<Rightarrow> 'a fset" where
   130   "Set dxs = Fset.Set (list_of_dlist dxs)"
   131 
   132 definition Coset :: "'a dlist \<Rightarrow> 'a fset" where
   133   "Coset dxs = Fset.Coset (list_of_dlist dxs)"
   134 
   135 code_datatype Set Coset
   136 
   137 declare member_code [code del]
   138 declare is_empty_Set [code del]
   139 declare empty_Set [code del]
   140 declare UNIV_Set [code del]
   141 declare insert_Set [code del]
   142 declare remove_Set [code del]
   143 declare map_Set [code del]
   144 declare filter_Set [code del]
   145 declare forall_Set [code del]
   146 declare exists_Set [code del]
   147 declare card_Set [code del]
   148 declare subfset_eq_forall [code del]
   149 declare subfset_subfset_eq [code del]
   150 declare eq_fset_subfset_eq [code del]
   151 declare inter_project [code del]
   152 declare subtract_remove [code del]
   153 declare union_insert [code del]
   154 declare Infimum_inf [code del]
   155 declare Supremum_sup [code del]
   156 
   157 lemma Set_Dlist [simp]:
   158   "Set (Dlist xs) = Fset (set xs)"
   159   by (simp add: Set_def Fset.Set_def)
   160 
   161 lemma Coset_Dlist [simp]:
   162   "Coset (Dlist xs) = Fset (- set xs)"
   163   by (simp add: Coset_def Fset.Coset_def)
   164 
   165 lemma member_Set [simp]:
   166   "Fset.member (Set dxs) = List.member (list_of_dlist dxs)"
   167   by (simp add: Set_def member_set)
   168 
   169 lemma member_Coset [simp]:
   170   "Fset.member (Coset dxs) = Not \<circ> List.member (list_of_dlist dxs)"
   171   by (simp add: Coset_def member_set not_set_compl)
   172 
   173 lemma is_empty_Set [code]:
   174   "Fset.is_empty (Set dxs) \<longleftrightarrow> null dxs"
   175   by (simp add: null_def null_empty member_set)
   176 
   177 lemma bot_code [code]:
   178   "bot = Set empty"
   179   by (simp add: empty_def)
   180 
   181 lemma top_code [code]:
   182   "top = Coset empty"
   183   by (simp add: empty_def)
   184 
   185 lemma insert_code [code]:
   186   "Fset.insert x (Set dxs) = Set (insert x dxs)"
   187   "Fset.insert x (Coset dxs) = Coset (remove x dxs)"
   188   by (simp_all add: insert_def remove_def member_set not_set_compl)
   189 
   190 lemma remove_code [code]:
   191   "Fset.remove x (Set dxs) = Set (remove x dxs)"
   192   "Fset.remove x (Coset dxs) = Coset (insert x dxs)"
   193   by (auto simp add: insert_def remove_def member_set not_set_compl)
   194 
   195 lemma member_code [code]:
   196   "Fset.member (Set dxs) = member dxs"
   197   "Fset.member (Coset dxs) = Not \<circ> member dxs"
   198   by (simp_all add: member_def)
   199 
   200 lemma map_code [code]:
   201   "Fset.map f (Set dxs) = Set (map f dxs)"
   202   by (simp add: member_set)
   203   
   204 lemma filter_code [code]:
   205   "Fset.filter f (Set dxs) = Set (filter f dxs)"
   206   by (simp add: member_set)
   207 
   208 lemma forall_Set [code]:
   209   "Fset.forall P (Set xs) \<longleftrightarrow> list_all P (list_of_dlist xs)"
   210   by (simp add: member_set list_all_iff)
   211 
   212 lemma exists_Set [code]:
   213   "Fset.exists P (Set xs) \<longleftrightarrow> list_ex P (list_of_dlist xs)"
   214   by (simp add: member_set list_ex_iff)
   215 
   216 lemma card_code [code]:
   217   "Fset.card (Set dxs) = length dxs"
   218   by (simp add: length_def member_set distinct_card)
   219 
   220 lemma foldl_list_of_dlist:
   221   "foldl f s (list_of_dlist dxs) = fold (\<lambda>x s. f s x) dxs s"
   222   by (simp add: foldl_fold fold_def)
   223 
   224 lemma inter_code [code]:
   225   "inf A (Set xs) = Set (filter (Fset.member A) xs)"
   226   "inf A (Coset xs) = fold Fset.remove xs A"
   227   by (simp_all only: Set_def Coset_def foldl_list_of_dlist inter_project list_of_dlist_filter)
   228 
   229 lemma subtract_code [code]:
   230   "A - Set xs = fold Fset.remove xs A"
   231   "A - Coset xs = Set (filter (Fset.member A) xs)"
   232   by (simp_all only: Set_def Coset_def foldl_list_of_dlist subtract_remove list_of_dlist_filter)
   233 
   234 lemma union_code [code]:
   235   "sup (Set xs) A = fold Fset.insert xs A"
   236   "sup (Coset xs) A = Coset (filter (Not \<circ> Fset.member A) xs)"
   237   by (simp_all only: Set_def Coset_def foldl_list_of_dlist union_insert list_of_dlist_filter)
   238 
   239 context complete_lattice
   240 begin
   241 
   242 lemma Infimum_code [code]:
   243   "Infimum (Set As) = fold inf As top"
   244   by (simp only: Set_def Infimum_inf foldl_list_of_dlist inf.commute)
   245 
   246 lemma Supremum_code [code]:
   247   "Supremum (Set As) = fold sup As bot"
   248   by (simp only: Set_def Supremum_sup foldl_list_of_dlist sup.commute)
   249 
   250 end
   251 
   252 hide (open) const member fold empty insert remove map filter null member length fold
   253 
   254 end