src/HOL/Orderings.thy
author haftmann
Wed Feb 10 14:12:04 2010 +0100 (2010-02-10)
changeset 35092 cfe605c54e50
parent 35028 108662d50512
child 35115 446c5063e4fd
permissions -rw-r--r--
moved less_eq, less to Orderings.thy; moved abs, sgn to Groups.thy
     1 (*  Title:      HOL/Orderings.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 header {* Abstract orderings *}
     6 
     7 theory Orderings
     8 imports Algebras
     9 uses
    10   "~~/src/Provers/order.ML"
    11   "~~/src/Provers/quasi.ML"  (* FIXME unused? *)
    12 begin
    13 
    14 subsection {* Syntactic orders *}
    15 
    16 class ord =
    17   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
    18     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
    19 begin
    20 
    21 notation
    22   less_eq  ("op <=") and
    23   less_eq  ("(_/ <= _)" [51, 51] 50) and
    24   less  ("op <") and
    25   less  ("(_/ < _)"  [51, 51] 50)
    26   
    27 notation (xsymbols)
    28   less_eq  ("op \<le>") and
    29   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    30 
    31 notation (HTML output)
    32   less_eq  ("op \<le>") and
    33   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    34 
    35 abbreviation (input)
    36   greater_eq  (infix ">=" 50) where
    37   "x >= y \<equiv> y <= x"
    38 
    39 notation (input)
    40   greater_eq  (infix "\<ge>" 50)
    41 
    42 abbreviation (input)
    43   greater  (infix ">" 50) where
    44   "x > y \<equiv> y < x"
    45 
    46 end
    47 
    48 
    49 subsection {* Quasi orders *}
    50 
    51 class preorder = ord +
    52   assumes less_le_not_le: "x < y \<longleftrightarrow> x \<le> y \<and> \<not> (y \<le> x)"
    53   and order_refl [iff]: "x \<le> x"
    54   and order_trans: "x \<le> y \<Longrightarrow> y \<le> z \<Longrightarrow> x \<le> z"
    55 begin
    56 
    57 text {* Reflexivity. *}
    58 
    59 lemma eq_refl: "x = y \<Longrightarrow> x \<le> y"
    60     -- {* This form is useful with the classical reasoner. *}
    61 by (erule ssubst) (rule order_refl)
    62 
    63 lemma less_irrefl [iff]: "\<not> x < x"
    64 by (simp add: less_le_not_le)
    65 
    66 lemma less_imp_le: "x < y \<Longrightarrow> x \<le> y"
    67 unfolding less_le_not_le by blast
    68 
    69 
    70 text {* Asymmetry. *}
    71 
    72 lemma less_not_sym: "x < y \<Longrightarrow> \<not> (y < x)"
    73 by (simp add: less_le_not_le)
    74 
    75 lemma less_asym: "x < y \<Longrightarrow> (\<not> P \<Longrightarrow> y < x) \<Longrightarrow> P"
    76 by (drule less_not_sym, erule contrapos_np) simp
    77 
    78 
    79 text {* Transitivity. *}
    80 
    81 lemma less_trans: "x < y \<Longrightarrow> y < z \<Longrightarrow> x < z"
    82 by (auto simp add: less_le_not_le intro: order_trans) 
    83 
    84 lemma le_less_trans: "x \<le> y \<Longrightarrow> y < z \<Longrightarrow> x < z"
    85 by (auto simp add: less_le_not_le intro: order_trans) 
    86 
    87 lemma less_le_trans: "x < y \<Longrightarrow> y \<le> z \<Longrightarrow> x < z"
    88 by (auto simp add: less_le_not_le intro: order_trans) 
    89 
    90 
    91 text {* Useful for simplification, but too risky to include by default. *}
    92 
    93 lemma less_imp_not_less: "x < y \<Longrightarrow> (\<not> y < x) \<longleftrightarrow> True"
    94 by (blast elim: less_asym)
    95 
    96 lemma less_imp_triv: "x < y \<Longrightarrow> (y < x \<longrightarrow> P) \<longleftrightarrow> True"
    97 by (blast elim: less_asym)
    98 
    99 
   100 text {* Transitivity rules for calculational reasoning *}
   101 
   102 lemma less_asym': "a < b \<Longrightarrow> b < a \<Longrightarrow> P"
   103 by (rule less_asym)
   104 
   105 
   106 text {* Dual order *}
   107 
   108 lemma dual_preorder:
   109   "preorder (op \<ge>) (op >)"
   110 proof qed (auto simp add: less_le_not_le intro: order_trans)
   111 
   112 end
   113 
   114 
   115 subsection {* Partial orders *}
   116 
   117 class order = preorder +
   118   assumes antisym: "x \<le> y \<Longrightarrow> y \<le> x \<Longrightarrow> x = y"
   119 begin
   120 
   121 text {* Reflexivity. *}
   122 
   123 lemma less_le: "x < y \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
   124 by (auto simp add: less_le_not_le intro: antisym)
   125 
   126 lemma le_less: "x \<le> y \<longleftrightarrow> x < y \<or> x = y"
   127     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
   128 by (simp add: less_le) blast
   129 
   130 lemma le_imp_less_or_eq: "x \<le> y \<Longrightarrow> x < y \<or> x = y"
   131 unfolding less_le by blast
   132 
   133 
   134 text {* Useful for simplification, but too risky to include by default. *}
   135 
   136 lemma less_imp_not_eq: "x < y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   137 by auto
   138 
   139 lemma less_imp_not_eq2: "x < y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   140 by auto
   141 
   142 
   143 text {* Transitivity rules for calculational reasoning *}
   144 
   145 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<le> b \<Longrightarrow> a < b"
   146 by (simp add: less_le)
   147 
   148 lemma le_neq_trans: "a \<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a < b"
   149 by (simp add: less_le)
   150 
   151 
   152 text {* Asymmetry. *}
   153 
   154 lemma eq_iff: "x = y \<longleftrightarrow> x \<le> y \<and> y \<le> x"
   155 by (blast intro: antisym)
   156 
   157 lemma antisym_conv: "y \<le> x \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   158 by (blast intro: antisym)
   159 
   160 lemma less_imp_neq: "x < y \<Longrightarrow> x \<noteq> y"
   161 by (erule contrapos_pn, erule subst, rule less_irrefl)
   162 
   163 
   164 text {* Least value operator *}
   165 
   166 definition (in ord)
   167   Least :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "LEAST " 10) where
   168   "Least P = (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> x \<le> y))"
   169 
   170 lemma Least_equality:
   171   assumes "P x"
   172     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   173   shows "Least P = x"
   174 unfolding Least_def by (rule the_equality)
   175   (blast intro: assms antisym)+
   176 
   177 lemma LeastI2_order:
   178   assumes "P x"
   179     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   180     and "\<And>x. P x \<Longrightarrow> \<forall>y. P y \<longrightarrow> x \<le> y \<Longrightarrow> Q x"
   181   shows "Q (Least P)"
   182 unfolding Least_def by (rule theI2)
   183   (blast intro: assms antisym)+
   184 
   185 
   186 text {* Dual order *}
   187 
   188 lemma dual_order:
   189   "order (op \<ge>) (op >)"
   190 by (intro_locales, rule dual_preorder) (unfold_locales, rule antisym)
   191 
   192 end
   193 
   194 
   195 subsection {* Linear (total) orders *}
   196 
   197 class linorder = order +
   198   assumes linear: "x \<le> y \<or> y \<le> x"
   199 begin
   200 
   201 lemma less_linear: "x < y \<or> x = y \<or> y < x"
   202 unfolding less_le using less_le linear by blast
   203 
   204 lemma le_less_linear: "x \<le> y \<or> y < x"
   205 by (simp add: le_less less_linear)
   206 
   207 lemma le_cases [case_names le ge]:
   208   "(x \<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   209 using linear by blast
   210 
   211 lemma linorder_cases [case_names less equal greater]:
   212   "(x < y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y < x \<Longrightarrow> P) \<Longrightarrow> P"
   213 using less_linear by blast
   214 
   215 lemma not_less: "\<not> x < y \<longleftrightarrow> y \<le> x"
   216 apply (simp add: less_le)
   217 using linear apply (blast intro: antisym)
   218 done
   219 
   220 lemma not_less_iff_gr_or_eq:
   221  "\<not>(x < y) \<longleftrightarrow> (x > y | x = y)"
   222 apply(simp add:not_less le_less)
   223 apply blast
   224 done
   225 
   226 lemma not_le: "\<not> x \<le> y \<longleftrightarrow> y < x"
   227 apply (simp add: less_le)
   228 using linear apply (blast intro: antisym)
   229 done
   230 
   231 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x < y \<or> y < x"
   232 by (cut_tac x = x and y = y in less_linear, auto)
   233 
   234 lemma neqE: "x \<noteq> y \<Longrightarrow> (x < y \<Longrightarrow> R) \<Longrightarrow> (y < x \<Longrightarrow> R) \<Longrightarrow> R"
   235 by (simp add: neq_iff) blast
   236 
   237 lemma antisym_conv1: "\<not> x < y \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   238 by (blast intro: antisym dest: not_less [THEN iffD1])
   239 
   240 lemma antisym_conv2: "x \<le> y \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   241 by (blast intro: antisym dest: not_less [THEN iffD1])
   242 
   243 lemma antisym_conv3: "\<not> y < x \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   244 by (blast intro: antisym dest: not_less [THEN iffD1])
   245 
   246 lemma leI: "\<not> x < y \<Longrightarrow> y \<le> x"
   247 unfolding not_less .
   248 
   249 lemma leD: "y \<le> x \<Longrightarrow> \<not> x < y"
   250 unfolding not_less .
   251 
   252 (*FIXME inappropriate name (or delete altogether)*)
   253 lemma not_leE: "\<not> y \<le> x \<Longrightarrow> x < y"
   254 unfolding not_le .
   255 
   256 
   257 text {* Dual order *}
   258 
   259 lemma dual_linorder:
   260   "linorder (op \<ge>) (op >)"
   261 by (rule linorder.intro, rule dual_order) (unfold_locales, rule linear)
   262 
   263 
   264 text {* min/max *}
   265 
   266 definition (in ord) min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   267   [code del]: "min a b = (if a \<le> b then a else b)"
   268 
   269 definition (in ord) max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   270   [code del]: "max a b = (if a \<le> b then b else a)"
   271 
   272 lemma min_le_iff_disj:
   273   "min x y \<le> z \<longleftrightarrow> x \<le> z \<or> y \<le> z"
   274 unfolding min_def using linear by (auto intro: order_trans)
   275 
   276 lemma le_max_iff_disj:
   277   "z \<le> max x y \<longleftrightarrow> z \<le> x \<or> z \<le> y"
   278 unfolding max_def using linear by (auto intro: order_trans)
   279 
   280 lemma min_less_iff_disj:
   281   "min x y < z \<longleftrightarrow> x < z \<or> y < z"
   282 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   283 
   284 lemma less_max_iff_disj:
   285   "z < max x y \<longleftrightarrow> z < x \<or> z < y"
   286 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   287 
   288 lemma min_less_iff_conj [simp]:
   289   "z < min x y \<longleftrightarrow> z < x \<and> z < y"
   290 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   291 
   292 lemma max_less_iff_conj [simp]:
   293   "max x y < z \<longleftrightarrow> x < z \<and> y < z"
   294 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   295 
   296 lemma split_min [noatp]:
   297   "P (min i j) \<longleftrightarrow> (i \<le> j \<longrightarrow> P i) \<and> (\<not> i \<le> j \<longrightarrow> P j)"
   298 by (simp add: min_def)
   299 
   300 lemma split_max [noatp]:
   301   "P (max i j) \<longleftrightarrow> (i \<le> j \<longrightarrow> P j) \<and> (\<not> i \<le> j \<longrightarrow> P i)"
   302 by (simp add: max_def)
   303 
   304 end
   305 
   306 text {* Explicit dictionaries for code generation *}
   307 
   308 lemma min_ord_min [code, code_unfold, code_inline del]:
   309   "min = ord.min (op \<le>)"
   310   by (rule ext)+ (simp add: min_def ord.min_def)
   311 
   312 declare ord.min_def [code]
   313 
   314 lemma max_ord_max [code, code_unfold, code_inline del]:
   315   "max = ord.max (op \<le>)"
   316   by (rule ext)+ (simp add: max_def ord.max_def)
   317 
   318 declare ord.max_def [code]
   319 
   320 
   321 subsection {* Reasoning tools setup *}
   322 
   323 ML {*
   324 
   325 signature ORDERS =
   326 sig
   327   val print_structures: Proof.context -> unit
   328   val setup: theory -> theory
   329   val order_tac: Proof.context -> thm list -> int -> tactic
   330 end;
   331 
   332 structure Orders: ORDERS =
   333 struct
   334 
   335 (** Theory and context data **)
   336 
   337 fun struct_eq ((s1: string, ts1), (s2, ts2)) =
   338   (s1 = s2) andalso eq_list (op aconv) (ts1, ts2);
   339 
   340 structure Data = Generic_Data
   341 (
   342   type T = ((string * term list) * Order_Tac.less_arith) list;
   343     (* Order structures:
   344        identifier of the structure, list of operations and record of theorems
   345        needed to set up the transitivity reasoner,
   346        identifier and operations identify the structure uniquely. *)
   347   val empty = [];
   348   val extend = I;
   349   fun merge data = AList.join struct_eq (K fst) data;
   350 );
   351 
   352 fun print_structures ctxt =
   353   let
   354     val structs = Data.get (Context.Proof ctxt);
   355     fun pretty_term t = Pretty.block
   356       [Pretty.quote (Syntax.pretty_term ctxt t), Pretty.brk 1,
   357         Pretty.str "::", Pretty.brk 1,
   358         Pretty.quote (Syntax.pretty_typ ctxt (type_of t))];
   359     fun pretty_struct ((s, ts), _) = Pretty.block
   360       [Pretty.str s, Pretty.str ":", Pretty.brk 1,
   361        Pretty.enclose "(" ")" (Pretty.breaks (map pretty_term ts))];
   362   in
   363     Pretty.writeln (Pretty.big_list "Order structures:" (map pretty_struct structs))
   364   end;
   365 
   366 
   367 (** Method **)
   368 
   369 fun struct_tac ((s, [eq, le, less]), thms) ctxt prems =
   370   let
   371     fun decomp thy (@{const Trueprop} $ t) =
   372       let
   373         fun excluded t =
   374           (* exclude numeric types: linear arithmetic subsumes transitivity *)
   375           let val T = type_of t
   376           in
   377             T = HOLogic.natT orelse T = HOLogic.intT orelse T = HOLogic.realT
   378           end;
   379         fun rel (bin_op $ t1 $ t2) =
   380               if excluded t1 then NONE
   381               else if Pattern.matches thy (eq, bin_op) then SOME (t1, "=", t2)
   382               else if Pattern.matches thy (le, bin_op) then SOME (t1, "<=", t2)
   383               else if Pattern.matches thy (less, bin_op) then SOME (t1, "<", t2)
   384               else NONE
   385           | rel _ = NONE;
   386         fun dec (Const (@{const_name Not}, _) $ t) = (case rel t
   387               of NONE => NONE
   388                | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   389           | dec x = rel x;
   390       in dec t end
   391       | decomp thy _ = NONE;
   392   in
   393     case s of
   394       "order" => Order_Tac.partial_tac decomp thms ctxt prems
   395     | "linorder" => Order_Tac.linear_tac decomp thms ctxt prems
   396     | _ => error ("Unknown kind of order `" ^ s ^ "' encountered in transitivity reasoner.")
   397   end
   398 
   399 fun order_tac ctxt prems =
   400   FIRST' (map (fn s => CHANGED o struct_tac s ctxt prems) (Data.get (Context.Proof ctxt)));
   401 
   402 
   403 (** Attribute **)
   404 
   405 fun add_struct_thm s tag =
   406   Thm.declaration_attribute
   407     (fn thm => Data.map (AList.map_default struct_eq (s, Order_Tac.empty TrueI) (Order_Tac.update tag thm)));
   408 fun del_struct s =
   409   Thm.declaration_attribute
   410     (fn _ => Data.map (AList.delete struct_eq s));
   411 
   412 val attrib_setup =
   413   Attrib.setup @{binding order}
   414     (Scan.lift ((Args.add -- Args.name >> (fn (_, s) => SOME s) || Args.del >> K NONE) --|
   415       Args.colon (* FIXME || Scan.succeed true *) ) -- Scan.lift Args.name --
   416       Scan.repeat Args.term
   417       >> (fn ((SOME tag, n), ts) => add_struct_thm (n, ts) tag
   418            | ((NONE, n), ts) => del_struct (n, ts)))
   419     "theorems controlling transitivity reasoner";
   420 
   421 
   422 (** Diagnostic command **)
   423 
   424 val _ =
   425   OuterSyntax.improper_command "print_orders"
   426     "print order structures available to transitivity reasoner" OuterKeyword.diag
   427     (Scan.succeed (Toplevel.no_timing o Toplevel.unknown_context o
   428         Toplevel.keep (print_structures o Toplevel.context_of)));
   429 
   430 
   431 (** Setup **)
   432 
   433 val setup =
   434   Method.setup @{binding order} (Scan.succeed (fn ctxt => SIMPLE_METHOD' (order_tac ctxt [])))
   435     "transitivity reasoner" #>
   436   attrib_setup;
   437 
   438 end;
   439 
   440 *}
   441 
   442 setup Orders.setup
   443 
   444 
   445 text {* Declarations to set up transitivity reasoner of partial and linear orders. *}
   446 
   447 context order
   448 begin
   449 
   450 (* The type constraint on @{term op =} below is necessary since the operation
   451    is not a parameter of the locale. *)
   452 
   453 declare less_irrefl [THEN notE, order add less_reflE: order "op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool" "op <=" "op <"]
   454   
   455 declare order_refl  [order add le_refl: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   456   
   457 declare less_imp_le [order add less_imp_le: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   458   
   459 declare antisym [order add eqI: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   460 
   461 declare eq_refl [order add eqD1: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   462 
   463 declare sym [THEN eq_refl, order add eqD2: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   464 
   465 declare less_trans [order add less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   466   
   467 declare less_le_trans [order add less_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   468   
   469 declare le_less_trans [order add le_less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   470 
   471 declare order_trans [order add le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   472 
   473 declare le_neq_trans [order add le_neq_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   474 
   475 declare neq_le_trans [order add neq_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   476 
   477 declare less_imp_neq [order add less_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   478 
   479 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   480 
   481 declare not_sym [order add not_sym: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   482 
   483 end
   484 
   485 context linorder
   486 begin
   487 
   488 declare [[order del: order "op = :: 'a => 'a => bool" "op <=" "op <"]]
   489 
   490 declare less_irrefl [THEN notE, order add less_reflE: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   491 
   492 declare order_refl [order add le_refl: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   493 
   494 declare less_imp_le [order add less_imp_le: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   495 
   496 declare not_less [THEN iffD2, order add not_lessI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   497 
   498 declare not_le [THEN iffD2, order add not_leI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   499 
   500 declare not_less [THEN iffD1, order add not_lessD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   501 
   502 declare not_le [THEN iffD1, order add not_leD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   503 
   504 declare antisym [order add eqI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   505 
   506 declare eq_refl [order add eqD1: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   507 
   508 declare sym [THEN eq_refl, order add eqD2: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   509 
   510 declare less_trans [order add less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   511 
   512 declare less_le_trans [order add less_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   513 
   514 declare le_less_trans [order add le_less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   515 
   516 declare order_trans [order add le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   517 
   518 declare le_neq_trans [order add le_neq_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   519 
   520 declare neq_le_trans [order add neq_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   521 
   522 declare less_imp_neq [order add less_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   523 
   524 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   525 
   526 declare not_sym [order add not_sym: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   527 
   528 end
   529 
   530 
   531 setup {*
   532 let
   533 
   534 fun prp t thm = (#prop (rep_thm thm) = t);
   535 
   536 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   537   let val prems = prems_of_ss ss;
   538       val less = Const (@{const_name less}, T);
   539       val t = HOLogic.mk_Trueprop(le $ s $ r);
   540   in case find_first (prp t) prems of
   541        NONE =>
   542          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   543          in case find_first (prp t) prems of
   544               NONE => NONE
   545             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv1}))
   546          end
   547      | SOME thm => SOME(mk_meta_eq(thm RS @{thm order_class.antisym_conv}))
   548   end
   549   handle THM _ => NONE;
   550 
   551 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   552   let val prems = prems_of_ss ss;
   553       val le = Const (@{const_name less_eq}, T);
   554       val t = HOLogic.mk_Trueprop(le $ r $ s);
   555   in case find_first (prp t) prems of
   556        NONE =>
   557          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   558          in case find_first (prp t) prems of
   559               NONE => NONE
   560             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv3}))
   561          end
   562      | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv2}))
   563   end
   564   handle THM _ => NONE;
   565 
   566 fun add_simprocs procs thy =
   567   Simplifier.map_simpset (fn ss => ss
   568     addsimprocs (map (fn (name, raw_ts, proc) =>
   569       Simplifier.simproc thy name raw_ts proc) procs)) thy;
   570 fun add_solver name tac =
   571   Simplifier.map_simpset (fn ss => ss addSolver
   572     mk_solver' name (fn ss => tac (Simplifier.the_context ss) (Simplifier.prems_of_ss ss)));
   573 
   574 in
   575   add_simprocs [
   576        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   577        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   578      ]
   579   #> add_solver "Transitivity" Orders.order_tac
   580   (* Adding the transitivity reasoners also as safe solvers showed a slight
   581      speed up, but the reasoning strength appears to be not higher (at least
   582      no breaking of additional proofs in the entire HOL distribution, as
   583      of 5 March 2004, was observed). *)
   584 end
   585 *}
   586 
   587 
   588 subsection {* Bounded quantifiers *}
   589 
   590 syntax
   591   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   592   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   593   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   594   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   595 
   596   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   597   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   598   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   599   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   600 
   601 syntax (xsymbols)
   602   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   603   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   604   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   605   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   606 
   607   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   608   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   609   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   610   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   611 
   612 syntax (HOL)
   613   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   614   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   615   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   616   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   617 
   618 syntax (HTML output)
   619   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   620   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   621   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   622   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   623 
   624   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   625   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   626   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   627   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   628 
   629 translations
   630   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   631   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   632   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   633   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   634   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   635   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   636   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   637   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   638 
   639 print_translation {*
   640 let
   641   val All_binder = Syntax.binder_name @{const_syntax All};
   642   val Ex_binder = Syntax.binder_name @{const_syntax Ex};
   643   val impl = @{const_syntax "op -->"};
   644   val conj = @{const_syntax "op &"};
   645   val less = @{const_syntax less};
   646   val less_eq = @{const_syntax less_eq};
   647 
   648   val trans =
   649    [((All_binder, impl, less), ("_All_less", "_All_greater")),
   650     ((All_binder, impl, less_eq), ("_All_less_eq", "_All_greater_eq")),
   651     ((Ex_binder, conj, less), ("_Ex_less", "_Ex_greater")),
   652     ((Ex_binder, conj, less_eq), ("_Ex_less_eq", "_Ex_greater_eq"))];
   653 
   654   fun matches_bound v t = 
   655      case t of (Const ("_bound", _) $ Free (v', _)) => (v = v')
   656               | _ => false
   657   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false)
   658   fun mk v c n P = Syntax.const c $ Syntax.mark_bound v $ n $ P
   659 
   660   fun tr' q = (q,
   661     fn [Const ("_bound", _) $ Free (v, _), Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   662       (case AList.lookup (op =) trans (q, c, d) of
   663         NONE => raise Match
   664       | SOME (l, g) =>
   665           if matches_bound v t andalso not (contains_var v u) then mk v l u P
   666           else if matches_bound v u andalso not (contains_var v t) then mk v g t P
   667           else raise Match)
   668      | _ => raise Match);
   669 in [tr' All_binder, tr' Ex_binder] end
   670 *}
   671 
   672 
   673 subsection {* Transitivity reasoning *}
   674 
   675 context ord
   676 begin
   677 
   678 lemma ord_le_eq_trans: "a \<le> b \<Longrightarrow> b = c \<Longrightarrow> a \<le> c"
   679   by (rule subst)
   680 
   681 lemma ord_eq_le_trans: "a = b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   682   by (rule ssubst)
   683 
   684 lemma ord_less_eq_trans: "a < b \<Longrightarrow> b = c \<Longrightarrow> a < c"
   685   by (rule subst)
   686 
   687 lemma ord_eq_less_trans: "a = b \<Longrightarrow> b < c \<Longrightarrow> a < c"
   688   by (rule ssubst)
   689 
   690 end
   691 
   692 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   693   (!!x y. x < y ==> f x < f y) ==> f a < c"
   694 proof -
   695   assume r: "!!x y. x < y ==> f x < f y"
   696   assume "a < b" hence "f a < f b" by (rule r)
   697   also assume "f b < c"
   698   finally (less_trans) show ?thesis .
   699 qed
   700 
   701 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   702   (!!x y. x < y ==> f x < f y) ==> a < f c"
   703 proof -
   704   assume r: "!!x y. x < y ==> f x < f y"
   705   assume "a < f b"
   706   also assume "b < c" hence "f b < f c" by (rule r)
   707   finally (less_trans) show ?thesis .
   708 qed
   709 
   710 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   711   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   712 proof -
   713   assume r: "!!x y. x <= y ==> f x <= f y"
   714   assume "a <= b" hence "f a <= f b" by (rule r)
   715   also assume "f b < c"
   716   finally (le_less_trans) show ?thesis .
   717 qed
   718 
   719 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   720   (!!x y. x < y ==> f x < f y) ==> a < f c"
   721 proof -
   722   assume r: "!!x y. x < y ==> f x < f y"
   723   assume "a <= f b"
   724   also assume "b < c" hence "f b < f c" by (rule r)
   725   finally (le_less_trans) show ?thesis .
   726 qed
   727 
   728 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   729   (!!x y. x < y ==> f x < f y) ==> f a < c"
   730 proof -
   731   assume r: "!!x y. x < y ==> f x < f y"
   732   assume "a < b" hence "f a < f b" by (rule r)
   733   also assume "f b <= c"
   734   finally (less_le_trans) show ?thesis .
   735 qed
   736 
   737 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   738   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   739 proof -
   740   assume r: "!!x y. x <= y ==> f x <= f y"
   741   assume "a < f b"
   742   also assume "b <= c" hence "f b <= f c" by (rule r)
   743   finally (less_le_trans) show ?thesis .
   744 qed
   745 
   746 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   747   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   748 proof -
   749   assume r: "!!x y. x <= y ==> f x <= f y"
   750   assume "a <= f b"
   751   also assume "b <= c" hence "f b <= f c" by (rule r)
   752   finally (order_trans) show ?thesis .
   753 qed
   754 
   755 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   756   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   757 proof -
   758   assume r: "!!x y. x <= y ==> f x <= f y"
   759   assume "a <= b" hence "f a <= f b" by (rule r)
   760   also assume "f b <= c"
   761   finally (order_trans) show ?thesis .
   762 qed
   763 
   764 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   765   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   766 proof -
   767   assume r: "!!x y. x <= y ==> f x <= f y"
   768   assume "a <= b" hence "f a <= f b" by (rule r)
   769   also assume "f b = c"
   770   finally (ord_le_eq_trans) show ?thesis .
   771 qed
   772 
   773 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   774   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   775 proof -
   776   assume r: "!!x y. x <= y ==> f x <= f y"
   777   assume "a = f b"
   778   also assume "b <= c" hence "f b <= f c" by (rule r)
   779   finally (ord_eq_le_trans) show ?thesis .
   780 qed
   781 
   782 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   783   (!!x y. x < y ==> f x < f y) ==> f a < c"
   784 proof -
   785   assume r: "!!x y. x < y ==> f x < f y"
   786   assume "a < b" hence "f a < f b" by (rule r)
   787   also assume "f b = c"
   788   finally (ord_less_eq_trans) show ?thesis .
   789 qed
   790 
   791 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   792   (!!x y. x < y ==> f x < f y) ==> a < f c"
   793 proof -
   794   assume r: "!!x y. x < y ==> f x < f y"
   795   assume "a = f b"
   796   also assume "b < c" hence "f b < f c" by (rule r)
   797   finally (ord_eq_less_trans) show ?thesis .
   798 qed
   799 
   800 text {*
   801   Note that this list of rules is in reverse order of priorities.
   802 *}
   803 
   804 lemmas [trans] =
   805   order_less_subst2
   806   order_less_subst1
   807   order_le_less_subst2
   808   order_le_less_subst1
   809   order_less_le_subst2
   810   order_less_le_subst1
   811   order_subst2
   812   order_subst1
   813   ord_le_eq_subst
   814   ord_eq_le_subst
   815   ord_less_eq_subst
   816   ord_eq_less_subst
   817   forw_subst
   818   back_subst
   819   rev_mp
   820   mp
   821 
   822 lemmas (in order) [trans] =
   823   neq_le_trans
   824   le_neq_trans
   825 
   826 lemmas (in preorder) [trans] =
   827   less_trans
   828   less_asym'
   829   le_less_trans
   830   less_le_trans
   831   order_trans
   832 
   833 lemmas (in order) [trans] =
   834   antisym
   835 
   836 lemmas (in ord) [trans] =
   837   ord_le_eq_trans
   838   ord_eq_le_trans
   839   ord_less_eq_trans
   840   ord_eq_less_trans
   841 
   842 lemmas [trans] =
   843   trans
   844 
   845 lemmas order_trans_rules =
   846   order_less_subst2
   847   order_less_subst1
   848   order_le_less_subst2
   849   order_le_less_subst1
   850   order_less_le_subst2
   851   order_less_le_subst1
   852   order_subst2
   853   order_subst1
   854   ord_le_eq_subst
   855   ord_eq_le_subst
   856   ord_less_eq_subst
   857   ord_eq_less_subst
   858   forw_subst
   859   back_subst
   860   rev_mp
   861   mp
   862   neq_le_trans
   863   le_neq_trans
   864   less_trans
   865   less_asym'
   866   le_less_trans
   867   less_le_trans
   868   order_trans
   869   antisym
   870   ord_le_eq_trans
   871   ord_eq_le_trans
   872   ord_less_eq_trans
   873   ord_eq_less_trans
   874   trans
   875 
   876 text {* These support proving chains of decreasing inequalities
   877     a >= b >= c ... in Isar proofs. *}
   878 
   879 lemma xt1:
   880   "a = b ==> b > c ==> a > c"
   881   "a > b ==> b = c ==> a > c"
   882   "a = b ==> b >= c ==> a >= c"
   883   "a >= b ==> b = c ==> a >= c"
   884   "(x::'a::order) >= y ==> y >= x ==> x = y"
   885   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   886   "(x::'a::order) > y ==> y >= z ==> x > z"
   887   "(x::'a::order) >= y ==> y > z ==> x > z"
   888   "(a::'a::order) > b ==> b > a ==> P"
   889   "(x::'a::order) > y ==> y > z ==> x > z"
   890   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   891   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   892   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   893   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   894   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   895   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   896   by auto
   897 
   898 lemma xt2:
   899   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   900 by (subgoal_tac "f b >= f c", force, force)
   901 
   902 lemma xt3: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==> 
   903     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   904 by (subgoal_tac "f a >= f b", force, force)
   905 
   906 lemma xt4: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   907   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   908 by (subgoal_tac "f b >= f c", force, force)
   909 
   910 lemma xt5: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   911     (!!x y. x > y ==> f x > f y) ==> f a > c"
   912 by (subgoal_tac "f a > f b", force, force)
   913 
   914 lemma xt6: "(a::'a::order) >= f b ==> b > c ==>
   915     (!!x y. x > y ==> f x > f y) ==> a > f c"
   916 by (subgoal_tac "f b > f c", force, force)
   917 
   918 lemma xt7: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   919     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   920 by (subgoal_tac "f a >= f b", force, force)
   921 
   922 lemma xt8: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   923     (!!x y. x > y ==> f x > f y) ==> a > f c"
   924 by (subgoal_tac "f b > f c", force, force)
   925 
   926 lemma xt9: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   927     (!!x y. x > y ==> f x > f y) ==> f a > c"
   928 by (subgoal_tac "f a > f b", force, force)
   929 
   930 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
   931 
   932 (* 
   933   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   934   for the wrong thing in an Isar proof.
   935 
   936   The extra transitivity rules can be used as follows: 
   937 
   938 lemma "(a::'a::order) > z"
   939 proof -
   940   have "a >= b" (is "_ >= ?rhs")
   941     sorry
   942   also have "?rhs >= c" (is "_ >= ?rhs")
   943     sorry
   944   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   945     sorry
   946   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   947     sorry
   948   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   949     sorry
   950   also (xtrans) have "?rhs > z"
   951     sorry
   952   finally (xtrans) show ?thesis .
   953 qed
   954 
   955   Alternatively, one can use "declare xtrans [trans]" and then
   956   leave out the "(xtrans)" above.
   957 *)
   958 
   959 
   960 subsection {* Monotonicity, least value operator and min/max *}
   961 
   962 context order
   963 begin
   964 
   965 definition mono :: "('a \<Rightarrow> 'b\<Colon>order) \<Rightarrow> bool" where
   966   "mono f \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> f x \<le> f y)"
   967 
   968 lemma monoI [intro?]:
   969   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
   970   shows "(\<And>x y. x \<le> y \<Longrightarrow> f x \<le> f y) \<Longrightarrow> mono f"
   971   unfolding mono_def by iprover
   972 
   973 lemma monoD [dest?]:
   974   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
   975   shows "mono f \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   976   unfolding mono_def by iprover
   977 
   978 definition strict_mono :: "('a \<Rightarrow> 'b\<Colon>order) \<Rightarrow> bool" where
   979   "strict_mono f \<longleftrightarrow> (\<forall>x y. x < y \<longrightarrow> f x < f y)"
   980 
   981 lemma strict_monoI [intro?]:
   982   assumes "\<And>x y. x < y \<Longrightarrow> f x < f y"
   983   shows "strict_mono f"
   984   using assms unfolding strict_mono_def by auto
   985 
   986 lemma strict_monoD [dest?]:
   987   "strict_mono f \<Longrightarrow> x < y \<Longrightarrow> f x < f y"
   988   unfolding strict_mono_def by auto
   989 
   990 lemma strict_mono_mono [dest?]:
   991   assumes "strict_mono f"
   992   shows "mono f"
   993 proof (rule monoI)
   994   fix x y
   995   assume "x \<le> y"
   996   show "f x \<le> f y"
   997   proof (cases "x = y")
   998     case True then show ?thesis by simp
   999   next
  1000     case False with `x \<le> y` have "x < y" by simp
  1001     with assms strict_monoD have "f x < f y" by auto
  1002     then show ?thesis by simp
  1003   qed
  1004 qed
  1005 
  1006 end
  1007 
  1008 context linorder
  1009 begin
  1010 
  1011 lemma strict_mono_eq:
  1012   assumes "strict_mono f"
  1013   shows "f x = f y \<longleftrightarrow> x = y"
  1014 proof
  1015   assume "f x = f y"
  1016   show "x = y" proof (cases x y rule: linorder_cases)
  1017     case less with assms strict_monoD have "f x < f y" by auto
  1018     with `f x = f y` show ?thesis by simp
  1019   next
  1020     case equal then show ?thesis .
  1021   next
  1022     case greater with assms strict_monoD have "f y < f x" by auto
  1023     with `f x = f y` show ?thesis by simp
  1024   qed
  1025 qed simp
  1026 
  1027 lemma strict_mono_less_eq:
  1028   assumes "strict_mono f"
  1029   shows "f x \<le> f y \<longleftrightarrow> x \<le> y"
  1030 proof
  1031   assume "x \<le> y"
  1032   with assms strict_mono_mono monoD show "f x \<le> f y" by auto
  1033 next
  1034   assume "f x \<le> f y"
  1035   show "x \<le> y" proof (rule ccontr)
  1036     assume "\<not> x \<le> y" then have "y < x" by simp
  1037     with assms strict_monoD have "f y < f x" by auto
  1038     with `f x \<le> f y` show False by simp
  1039   qed
  1040 qed
  1041   
  1042 lemma strict_mono_less:
  1043   assumes "strict_mono f"
  1044   shows "f x < f y \<longleftrightarrow> x < y"
  1045   using assms
  1046     by (auto simp add: less_le Orderings.less_le strict_mono_eq strict_mono_less_eq)
  1047 
  1048 lemma min_of_mono:
  1049   fixes f :: "'a \<Rightarrow> 'b\<Colon>linorder"
  1050   shows "mono f \<Longrightarrow> min (f m) (f n) = f (min m n)"
  1051   by (auto simp: mono_def Orderings.min_def min_def intro: Orderings.antisym)
  1052 
  1053 lemma max_of_mono:
  1054   fixes f :: "'a \<Rightarrow> 'b\<Colon>linorder"
  1055   shows "mono f \<Longrightarrow> max (f m) (f n) = f (max m n)"
  1056   by (auto simp: mono_def Orderings.max_def max_def intro: Orderings.antisym)
  1057 
  1058 end
  1059 
  1060 lemma min_leastL: "(!!x. least <= x) ==> min least x = least"
  1061 by (simp add: min_def)
  1062 
  1063 lemma max_leastL: "(!!x. least <= x) ==> max least x = x"
  1064 by (simp add: max_def)
  1065 
  1066 lemma min_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> min x least = least"
  1067 apply (simp add: min_def)
  1068 apply (blast intro: antisym)
  1069 done
  1070 
  1071 lemma max_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> max x least = x"
  1072 apply (simp add: max_def)
  1073 apply (blast intro: antisym)
  1074 done
  1075 
  1076 
  1077 subsection {* Top and bottom elements *}
  1078 
  1079 class top = preorder +
  1080   fixes top :: 'a
  1081   assumes top_greatest [simp]: "x \<le> top"
  1082 
  1083 class bot = preorder +
  1084   fixes bot :: 'a
  1085   assumes bot_least [simp]: "bot \<le> x"
  1086 
  1087 
  1088 subsection {* Dense orders *}
  1089 
  1090 class dense_linorder = linorder + 
  1091   assumes gt_ex: "\<exists>y. x < y" 
  1092   and lt_ex: "\<exists>y. y < x"
  1093   and dense: "x < y \<Longrightarrow> (\<exists>z. x < z \<and> z < y)"
  1094 
  1095 
  1096 subsection {* Wellorders *}
  1097 
  1098 class wellorder = linorder +
  1099   assumes less_induct [case_names less]: "(\<And>x. (\<And>y. y < x \<Longrightarrow> P y) \<Longrightarrow> P x) \<Longrightarrow> P a"
  1100 begin
  1101 
  1102 lemma wellorder_Least_lemma:
  1103   fixes k :: 'a
  1104   assumes "P k"
  1105   shows LeastI: "P (LEAST x. P x)" and Least_le: "(LEAST x. P x) \<le> k"
  1106 proof -
  1107   have "P (LEAST x. P x) \<and> (LEAST x. P x) \<le> k"
  1108   using assms proof (induct k rule: less_induct)
  1109     case (less x) then have "P x" by simp
  1110     show ?case proof (rule classical)
  1111       assume assm: "\<not> (P (LEAST a. P a) \<and> (LEAST a. P a) \<le> x)"
  1112       have "\<And>y. P y \<Longrightarrow> x \<le> y"
  1113       proof (rule classical)
  1114         fix y
  1115         assume "P y" and "\<not> x \<le> y" 
  1116         with less have "P (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1117           by (auto simp add: not_le)
  1118         with assm have "x < (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1119           by auto
  1120         then show "x \<le> y" by auto
  1121       qed
  1122       with `P x` have Least: "(LEAST a. P a) = x"
  1123         by (rule Least_equality)
  1124       with `P x` show ?thesis by simp
  1125     qed
  1126   qed
  1127   then show "P (LEAST x. P x)" and "(LEAST x. P x) \<le> k" by auto
  1128 qed
  1129 
  1130 -- "The following 3 lemmas are due to Brian Huffman"
  1131 lemma LeastI_ex: "\<exists>x. P x \<Longrightarrow> P (Least P)"
  1132   by (erule exE) (erule LeastI)
  1133 
  1134 lemma LeastI2:
  1135   "P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1136   by (blast intro: LeastI)
  1137 
  1138 lemma LeastI2_ex:
  1139   "\<exists>a. P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1140   by (blast intro: LeastI_ex)
  1141 
  1142 lemma not_less_Least: "k < (LEAST x. P x) \<Longrightarrow> \<not> P k"
  1143 apply (simp (no_asm_use) add: not_le [symmetric])
  1144 apply (erule contrapos_nn)
  1145 apply (erule Least_le)
  1146 done
  1147 
  1148 end  
  1149 
  1150 
  1151 subsection {* Order on bool *}
  1152 
  1153 instantiation bool :: "{order, top, bot}"
  1154 begin
  1155 
  1156 definition
  1157   le_bool_def [code del]: "P \<le> Q \<longleftrightarrow> P \<longrightarrow> Q"
  1158 
  1159 definition
  1160   less_bool_def [code del]: "(P\<Colon>bool) < Q \<longleftrightarrow> \<not> P \<and> Q"
  1161 
  1162 definition
  1163   top_bool_eq: "top = True"
  1164 
  1165 definition
  1166   bot_bool_eq: "bot = False"
  1167 
  1168 instance proof
  1169 qed (auto simp add: bot_bool_eq top_bool_eq less_bool_def, auto simp add: le_bool_def)
  1170 
  1171 end
  1172 
  1173 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
  1174   by (simp add: le_bool_def)
  1175 
  1176 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
  1177   by (simp add: le_bool_def)
  1178 
  1179 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
  1180   by (simp add: le_bool_def)
  1181 
  1182 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
  1183   by (simp add: le_bool_def)
  1184 
  1185 lemma bot_boolE: "bot \<Longrightarrow> P"
  1186   by (simp add: bot_bool_eq)
  1187 
  1188 lemma top_boolI: top
  1189   by (simp add: top_bool_eq)
  1190 
  1191 lemma [code]:
  1192   "False \<le> b \<longleftrightarrow> True"
  1193   "True \<le> b \<longleftrightarrow> b"
  1194   "False < b \<longleftrightarrow> b"
  1195   "True < b \<longleftrightarrow> False"
  1196   unfolding le_bool_def less_bool_def by simp_all
  1197 
  1198 
  1199 subsection {* Order on functions *}
  1200 
  1201 instantiation "fun" :: (type, ord) ord
  1202 begin
  1203 
  1204 definition
  1205   le_fun_def [code del]: "f \<le> g \<longleftrightarrow> (\<forall>x. f x \<le> g x)"
  1206 
  1207 definition
  1208   less_fun_def [code del]: "(f\<Colon>'a \<Rightarrow> 'b) < g \<longleftrightarrow> f \<le> g \<and> \<not> (g \<le> f)"
  1209 
  1210 instance ..
  1211 
  1212 end
  1213 
  1214 instance "fun" :: (type, preorder) preorder proof
  1215 qed (auto simp add: le_fun_def less_fun_def
  1216   intro: order_trans antisym intro!: ext)
  1217 
  1218 instance "fun" :: (type, order) order proof
  1219 qed (auto simp add: le_fun_def intro: antisym ext)
  1220 
  1221 instantiation "fun" :: (type, top) top
  1222 begin
  1223 
  1224 definition
  1225   top_fun_eq: "top = (\<lambda>x. top)"
  1226 
  1227 instance proof
  1228 qed (simp add: top_fun_eq le_fun_def)
  1229 
  1230 end
  1231 
  1232 instantiation "fun" :: (type, bot) bot
  1233 begin
  1234 
  1235 definition
  1236   bot_fun_eq: "bot = (\<lambda>x. bot)"
  1237 
  1238 instance proof
  1239 qed (simp add: bot_fun_eq le_fun_def)
  1240 
  1241 end
  1242 
  1243 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
  1244   unfolding le_fun_def by simp
  1245 
  1246 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
  1247   unfolding le_fun_def by simp
  1248 
  1249 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
  1250   unfolding le_fun_def by simp
  1251 
  1252 
  1253 subsection {* Name duplicates *}
  1254 
  1255 lemmas order_eq_refl = preorder_class.eq_refl
  1256 lemmas order_less_irrefl = preorder_class.less_irrefl
  1257 lemmas order_less_imp_le = preorder_class.less_imp_le
  1258 lemmas order_less_not_sym = preorder_class.less_not_sym
  1259 lemmas order_less_asym = preorder_class.less_asym
  1260 lemmas order_less_trans = preorder_class.less_trans
  1261 lemmas order_le_less_trans = preorder_class.le_less_trans
  1262 lemmas order_less_le_trans = preorder_class.less_le_trans
  1263 lemmas order_less_imp_not_less = preorder_class.less_imp_not_less
  1264 lemmas order_less_imp_triv = preorder_class.less_imp_triv
  1265 lemmas order_less_asym' = preorder_class.less_asym'
  1266 
  1267 lemmas order_less_le = order_class.less_le
  1268 lemmas order_le_less = order_class.le_less
  1269 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
  1270 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
  1271 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
  1272 lemmas order_neq_le_trans = order_class.neq_le_trans
  1273 lemmas order_le_neq_trans = order_class.le_neq_trans
  1274 lemmas order_antisym = order_class.antisym
  1275 lemmas order_eq_iff = order_class.eq_iff
  1276 lemmas order_antisym_conv = order_class.antisym_conv
  1277 
  1278 lemmas linorder_linear = linorder_class.linear
  1279 lemmas linorder_less_linear = linorder_class.less_linear
  1280 lemmas linorder_le_less_linear = linorder_class.le_less_linear
  1281 lemmas linorder_le_cases = linorder_class.le_cases
  1282 lemmas linorder_not_less = linorder_class.not_less
  1283 lemmas linorder_not_le = linorder_class.not_le
  1284 lemmas linorder_neq_iff = linorder_class.neq_iff
  1285 lemmas linorder_neqE = linorder_class.neqE
  1286 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
  1287 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
  1288 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
  1289 
  1290 end