src/HOL/Fun.thy
author wenzelm
Thu Mar 15 22:08:53 2012 +0100 (2012-03-15)
changeset 46950 d0181abdbdac
parent 46586 abbec6fa25c8
child 47488 be6dd389639d
permissions -rw-r--r--
declare command keywords via theory header, including strict checking outside Pure;
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Copyright   1994  University of Cambridge
     4 *)
     5 
     6 header {* Notions about functions *}
     7 
     8 theory Fun
     9 imports Complete_Lattices
    10 keywords "enriched_type" :: thy_goal
    11 uses ("Tools/enriched_type.ML")
    12 begin
    13 
    14 lemma apply_inverse:
    15   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    16   by auto
    17 
    18 
    19 subsection {* The Identity Function @{text id} *}
    20 
    21 definition id :: "'a \<Rightarrow> 'a" where
    22   "id = (\<lambda>x. x)"
    23 
    24 lemma id_apply [simp]: "id x = x"
    25   by (simp add: id_def)
    26 
    27 lemma image_id [simp]: "id ` Y = Y"
    28   by (simp add: id_def)
    29 
    30 lemma vimage_id [simp]: "id -` A = A"
    31   by (simp add: id_def)
    32 
    33 
    34 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    35 
    36 definition comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55) where
    37   "f o g = (\<lambda>x. f (g x))"
    38 
    39 notation (xsymbols)
    40   comp  (infixl "\<circ>" 55)
    41 
    42 notation (HTML output)
    43   comp  (infixl "\<circ>" 55)
    44 
    45 lemma o_apply [simp]: "(f o g) x = f (g x)"
    46 by (simp add: comp_def)
    47 
    48 lemma o_assoc: "f o (g o h) = f o g o h"
    49 by (simp add: comp_def)
    50 
    51 lemma id_o [simp]: "id o g = g"
    52 by (simp add: comp_def)
    53 
    54 lemma o_id [simp]: "f o id = f"
    55 by (simp add: comp_def)
    56 
    57 lemma o_eq_dest:
    58   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    59   by (simp only: comp_def) (fact fun_cong)
    60 
    61 lemma o_eq_elim:
    62   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    63   by (erule meta_mp) (fact o_eq_dest) 
    64 
    65 lemma image_compose: "(f o g) ` r = f`(g`r)"
    66 by (simp add: comp_def, blast)
    67 
    68 lemma vimage_compose: "(g \<circ> f) -` x = f -` (g -` x)"
    69   by auto
    70 
    71 lemma UN_o: "UNION A (g o f) = UNION (f`A) g"
    72 by (unfold comp_def, blast)
    73 
    74 
    75 subsection {* The Forward Composition Operator @{text fcomp} *}
    76 
    77 definition fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60) where
    78   "f \<circ>> g = (\<lambda>x. g (f x))"
    79 
    80 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
    81   by (simp add: fcomp_def)
    82 
    83 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
    84   by (simp add: fcomp_def)
    85 
    86 lemma id_fcomp [simp]: "id \<circ>> g = g"
    87   by (simp add: fcomp_def)
    88 
    89 lemma fcomp_id [simp]: "f \<circ>> id = f"
    90   by (simp add: fcomp_def)
    91 
    92 code_const fcomp
    93   (Eval infixl 1 "#>")
    94 
    95 no_notation fcomp (infixl "\<circ>>" 60)
    96 
    97 
    98 subsection {* Mapping functions *}
    99 
   100 definition map_fun :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'c \<Rightarrow> 'd" where
   101   "map_fun f g h = g \<circ> h \<circ> f"
   102 
   103 lemma map_fun_apply [simp]:
   104   "map_fun f g h x = g (h (f x))"
   105   by (simp add: map_fun_def)
   106 
   107 
   108 subsection {* Injectivity and Bijectivity *}
   109 
   110 definition inj_on :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> bool" where -- "injective"
   111   "inj_on f A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. f x = f y \<longrightarrow> x = y)"
   112 
   113 definition bij_betw :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool" where -- "bijective"
   114   "bij_betw f A B \<longleftrightarrow> inj_on f A \<and> f ` A = B"
   115 
   116 text{*A common special case: functions injective, surjective or bijective over
   117 the entire domain type.*}
   118 
   119 abbreviation
   120   "inj f \<equiv> inj_on f UNIV"
   121 
   122 abbreviation surj :: "('a \<Rightarrow> 'b) \<Rightarrow> bool" where -- "surjective"
   123   "surj f \<equiv> (range f = UNIV)"
   124 
   125 abbreviation
   126   "bij f \<equiv> bij_betw f UNIV UNIV"
   127 
   128 text{* The negated case: *}
   129 translations
   130 "\<not> CONST surj f" <= "CONST range f \<noteq> CONST UNIV"
   131 
   132 lemma injI:
   133   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   134   shows "inj f"
   135   using assms unfolding inj_on_def by auto
   136 
   137 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   138   by (unfold inj_on_def, blast)
   139 
   140 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   141 by (simp add: inj_on_def)
   142 
   143 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   144 by (force simp add: inj_on_def)
   145 
   146 lemma inj_on_cong:
   147   "(\<And> a. a : A \<Longrightarrow> f a = g a) \<Longrightarrow> inj_on f A = inj_on g A"
   148 unfolding inj_on_def by auto
   149 
   150 lemma inj_on_strict_subset:
   151   "\<lbrakk> inj_on f B; A < B \<rbrakk> \<Longrightarrow> f`A < f`B"
   152 unfolding inj_on_def unfolding image_def by blast
   153 
   154 lemma inj_comp:
   155   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   156   by (simp add: inj_on_def)
   157 
   158 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   159   by (simp add: inj_on_def fun_eq_iff)
   160 
   161 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   162 by (simp add: inj_on_eq_iff)
   163 
   164 lemma inj_on_id[simp]: "inj_on id A"
   165   by (simp add: inj_on_def)
   166 
   167 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   168 by (simp add: inj_on_def)
   169 
   170 lemma inj_on_Int: "inj_on f A \<or> inj_on f B \<Longrightarrow> inj_on f (A \<inter> B)"
   171 unfolding inj_on_def by blast
   172 
   173 lemma inj_on_INTER:
   174   "\<lbrakk>I \<noteq> {}; \<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)\<rbrakk> \<Longrightarrow> inj_on f (\<Inter> i \<in> I. A i)"
   175 unfolding inj_on_def by blast
   176 
   177 lemma inj_on_Inter:
   178   "\<lbrakk>S \<noteq> {}; \<And> A. A \<in> S \<Longrightarrow> inj_on f A\<rbrakk> \<Longrightarrow> inj_on f (Inter S)"
   179 unfolding inj_on_def by blast
   180 
   181 lemma inj_on_UNION_chain:
   182   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
   183          INJ: "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
   184   shows "inj_on f (\<Union> i \<in> I. A i)"
   185 proof(unfold inj_on_def UNION_eq, auto)
   186   fix i j x y
   187   assume *: "i \<in> I" "j \<in> I" and **: "x \<in> A i" "y \<in> A j"
   188          and ***: "f x = f y"
   189   show "x = y"
   190   proof-
   191     {assume "A i \<le> A j"
   192      with ** have "x \<in> A j" by auto
   193      with INJ * ** *** have ?thesis
   194      by(auto simp add: inj_on_def)
   195     }
   196     moreover
   197     {assume "A j \<le> A i"
   198      with ** have "y \<in> A i" by auto
   199      with INJ * ** *** have ?thesis
   200      by(auto simp add: inj_on_def)
   201     }
   202     ultimately show ?thesis using  CH * by blast
   203   qed
   204 qed
   205 
   206 lemma surj_id: "surj id"
   207 by simp
   208 
   209 lemma bij_id[simp]: "bij id"
   210 by (simp add: bij_betw_def)
   211 
   212 lemma inj_onI:
   213     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   214 by (simp add: inj_on_def)
   215 
   216 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   217 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   218 
   219 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   220 by (unfold inj_on_def, blast)
   221 
   222 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   223 by (blast dest!: inj_onD)
   224 
   225 lemma comp_inj_on:
   226      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   227 by (simp add: comp_def inj_on_def)
   228 
   229 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   230 apply(simp add:inj_on_def image_def)
   231 apply blast
   232 done
   233 
   234 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   235   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   236 apply(unfold inj_on_def)
   237 apply blast
   238 done
   239 
   240 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   241 by (unfold inj_on_def, blast)
   242 
   243 lemma inj_singleton: "inj (%s. {s})"
   244 by (simp add: inj_on_def)
   245 
   246 lemma inj_on_empty[iff]: "inj_on f {}"
   247 by(simp add: inj_on_def)
   248 
   249 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   250 by (unfold inj_on_def, blast)
   251 
   252 lemma inj_on_Un:
   253  "inj_on f (A Un B) =
   254   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   255 apply(unfold inj_on_def)
   256 apply (blast intro:sym)
   257 done
   258 
   259 lemma inj_on_insert[iff]:
   260   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   261 apply(unfold inj_on_def)
   262 apply (blast intro:sym)
   263 done
   264 
   265 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   266 apply(unfold inj_on_def)
   267 apply (blast)
   268 done
   269 
   270 lemma comp_inj_on_iff:
   271   "inj_on f A \<Longrightarrow> inj_on f' (f ` A) \<longleftrightarrow> inj_on (f' o f) A"
   272 by(auto simp add: comp_inj_on inj_on_def)
   273 
   274 lemma inj_on_imageI2:
   275   "inj_on (f' o f) A \<Longrightarrow> inj_on f A"
   276 by(auto simp add: comp_inj_on inj_on_def)
   277 
   278 lemma surj_def: "surj f \<longleftrightarrow> (\<forall>y. \<exists>x. y = f x)"
   279   by auto
   280 
   281 lemma surjI: assumes *: "\<And> x. g (f x) = x" shows "surj g"
   282   using *[symmetric] by auto
   283 
   284 lemma surjD: "surj f \<Longrightarrow> \<exists>x. y = f x"
   285   by (simp add: surj_def)
   286 
   287 lemma surjE: "surj f \<Longrightarrow> (\<And>x. y = f x \<Longrightarrow> C) \<Longrightarrow> C"
   288   by (simp add: surj_def, blast)
   289 
   290 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   291 apply (simp add: comp_def surj_def, clarify)
   292 apply (drule_tac x = y in spec, clarify)
   293 apply (drule_tac x = x in spec, blast)
   294 done
   295 
   296 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
   297   unfolding bij_betw_def by auto
   298 
   299 lemma bij_betw_empty1:
   300   assumes "bij_betw f {} A"
   301   shows "A = {}"
   302 using assms unfolding bij_betw_def by blast
   303 
   304 lemma bij_betw_empty2:
   305   assumes "bij_betw f A {}"
   306   shows "A = {}"
   307 using assms unfolding bij_betw_def by blast
   308 
   309 lemma inj_on_imp_bij_betw:
   310   "inj_on f A \<Longrightarrow> bij_betw f A (f ` A)"
   311 unfolding bij_betw_def by simp
   312 
   313 lemma bij_def: "bij f \<longleftrightarrow> inj f \<and> surj f"
   314   unfolding bij_betw_def ..
   315 
   316 lemma bijI: "[| inj f; surj f |] ==> bij f"
   317 by (simp add: bij_def)
   318 
   319 lemma bij_is_inj: "bij f ==> inj f"
   320 by (simp add: bij_def)
   321 
   322 lemma bij_is_surj: "bij f ==> surj f"
   323 by (simp add: bij_def)
   324 
   325 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   326 by (simp add: bij_betw_def)
   327 
   328 lemma bij_betw_trans:
   329   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   330 by(auto simp add:bij_betw_def comp_inj_on)
   331 
   332 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   333   by (rule bij_betw_trans)
   334 
   335 lemma bij_betw_comp_iff:
   336   "bij_betw f A A' \<Longrightarrow> bij_betw f' A' A'' \<longleftrightarrow> bij_betw (f' o f) A A''"
   337 by(auto simp add: bij_betw_def inj_on_def)
   338 
   339 lemma bij_betw_comp_iff2:
   340   assumes BIJ: "bij_betw f' A' A''" and IM: "f ` A \<le> A'"
   341   shows "bij_betw f A A' \<longleftrightarrow> bij_betw (f' o f) A A''"
   342 using assms
   343 proof(auto simp add: bij_betw_comp_iff)
   344   assume *: "bij_betw (f' \<circ> f) A A''"
   345   thus "bij_betw f A A'"
   346   using IM
   347   proof(auto simp add: bij_betw_def)
   348     assume "inj_on (f' \<circ> f) A"
   349     thus "inj_on f A" using inj_on_imageI2 by blast
   350   next
   351     fix a' assume **: "a' \<in> A'"
   352     hence "f' a' \<in> A''" using BIJ unfolding bij_betw_def by auto
   353     then obtain a where 1: "a \<in> A \<and> f'(f a) = f' a'" using *
   354     unfolding bij_betw_def by force
   355     hence "f a \<in> A'" using IM by auto
   356     hence "f a = a'" using BIJ ** 1 unfolding bij_betw_def inj_on_def by auto
   357     thus "a' \<in> f ` A" using 1 by auto
   358   qed
   359 qed
   360 
   361 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   362 proof -
   363   have i: "inj_on f A" and s: "f ` A = B"
   364     using assms by(auto simp:bij_betw_def)
   365   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   366   { fix a b assume P: "?P b a"
   367     hence ex1: "\<exists>a. ?P b a" using s unfolding image_def by blast
   368     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   369     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   370   } note g = this
   371   have "inj_on ?g B"
   372   proof(rule inj_onI)
   373     fix x y assume "x:B" "y:B" "?g x = ?g y"
   374     from s `x:B` obtain a1 where a1: "?P x a1" unfolding image_def by blast
   375     from s `y:B` obtain a2 where a2: "?P y a2" unfolding image_def by blast
   376     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   377   qed
   378   moreover have "?g ` B = A"
   379   proof(auto simp:image_def)
   380     fix b assume "b:B"
   381     with s obtain a where P: "?P b a" unfolding image_def by blast
   382     thus "?g b \<in> A" using g[OF P] by auto
   383   next
   384     fix a assume "a:A"
   385     then obtain b where P: "?P b a" using s unfolding image_def by blast
   386     then have "b:B" using s unfolding image_def by blast
   387     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   388   qed
   389   ultimately show ?thesis by(auto simp:bij_betw_def)
   390 qed
   391 
   392 lemma bij_betw_cong:
   393   "(\<And> a. a \<in> A \<Longrightarrow> f a = g a) \<Longrightarrow> bij_betw f A A' = bij_betw g A A'"
   394 unfolding bij_betw_def inj_on_def by force
   395 
   396 lemma bij_betw_id[intro, simp]:
   397   "bij_betw id A A"
   398 unfolding bij_betw_def id_def by auto
   399 
   400 lemma bij_betw_id_iff:
   401   "bij_betw id A B \<longleftrightarrow> A = B"
   402 by(auto simp add: bij_betw_def)
   403 
   404 lemma bij_betw_combine:
   405   assumes "bij_betw f A B" "bij_betw f C D" "B \<inter> D = {}"
   406   shows "bij_betw f (A \<union> C) (B \<union> D)"
   407   using assms unfolding bij_betw_def inj_on_Un image_Un by auto
   408 
   409 lemma bij_betw_UNION_chain:
   410   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
   411          BIJ: "\<And> i. i \<in> I \<Longrightarrow> bij_betw f (A i) (A' i)"
   412   shows "bij_betw f (\<Union> i \<in> I. A i) (\<Union> i \<in> I. A' i)"
   413 proof(unfold bij_betw_def, auto simp add: image_def)
   414   have "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
   415   using BIJ bij_betw_def[of f] by auto
   416   thus "inj_on f (\<Union> i \<in> I. A i)"
   417   using CH inj_on_UNION_chain[of I A f] by auto
   418 next
   419   fix i x
   420   assume *: "i \<in> I" "x \<in> A i"
   421   hence "f x \<in> A' i" using BIJ bij_betw_def[of f] by auto
   422   thus "\<exists>j \<in> I. f x \<in> A' j" using * by blast
   423 next
   424   fix i x'
   425   assume *: "i \<in> I" "x' \<in> A' i"
   426   hence "\<exists>x \<in> A i. x' = f x" using BIJ bij_betw_def[of f] by blast
   427   thus "\<exists>j \<in> I. \<exists>x \<in> A j. x' = f x"
   428   using * by blast
   429 qed
   430 
   431 lemma bij_betw_subset:
   432   assumes BIJ: "bij_betw f A A'" and
   433           SUB: "B \<le> A" and IM: "f ` B = B'"
   434   shows "bij_betw f B B'"
   435 using assms
   436 by(unfold bij_betw_def inj_on_def, auto simp add: inj_on_def)
   437 
   438 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   439 by simp
   440 
   441 lemma surj_vimage_empty:
   442   assumes "surj f" shows "f -` A = {} \<longleftrightarrow> A = {}"
   443   using surj_image_vimage_eq[OF `surj f`, of A]
   444   by (intro iffI) fastforce+
   445 
   446 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   447 by (simp add: inj_on_def, blast)
   448 
   449 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   450 by (blast intro: sym)
   451 
   452 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   453 by (unfold inj_on_def, blast)
   454 
   455 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   456 apply (unfold bij_def)
   457 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   458 done
   459 
   460 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   461 by(blast dest: inj_onD)
   462 
   463 lemma inj_on_image_Int:
   464    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   465 apply (simp add: inj_on_def, blast)
   466 done
   467 
   468 lemma inj_on_image_set_diff:
   469    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   470 apply (simp add: inj_on_def, blast)
   471 done
   472 
   473 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   474 by (simp add: inj_on_def, blast)
   475 
   476 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   477 by (simp add: inj_on_def, blast)
   478 
   479 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   480 by (blast dest: injD)
   481 
   482 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   483 by (simp add: inj_on_def, blast)
   484 
   485 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   486 by (blast dest: injD)
   487 
   488 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
   489 lemma image_INT:
   490    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
   491     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   492 apply (simp add: inj_on_def, blast)
   493 done
   494 
   495 (*Compare with image_INT: no use of inj_on, and if f is surjective then
   496   it doesn't matter whether A is empty*)
   497 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   498 apply (simp add: bij_def)
   499 apply (simp add: inj_on_def surj_def, blast)
   500 done
   501 
   502 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   503 by auto
   504 
   505 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   506 by (auto simp add: inj_on_def)
   507 
   508 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   509 apply (simp add: bij_def)
   510 apply (rule equalityI)
   511 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   512 done
   513 
   514 lemma inj_vimage_singleton: "inj f \<Longrightarrow> f -` {a} \<subseteq> {THE x. f x = a}"
   515   -- {* The inverse image of a singleton under an injective function
   516          is included in a singleton. *}
   517   apply (auto simp add: inj_on_def)
   518   apply (blast intro: the_equality [symmetric])
   519   done
   520 
   521 lemma inj_on_vimage_singleton:
   522   "inj_on f A \<Longrightarrow> f -` {a} \<inter> A \<subseteq> {THE x. x \<in> A \<and> f x = a}"
   523   by (auto simp add: inj_on_def intro: the_equality [symmetric])
   524 
   525 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   526   by (auto intro!: inj_onI)
   527 
   528 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   529   by (auto intro!: inj_onI dest: strict_mono_eq)
   530 
   531 
   532 subsection{*Function Updating*}
   533 
   534 definition fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   535   "fun_upd f a b == % x. if x=a then b else f x"
   536 
   537 nonterminal updbinds and updbind
   538 
   539 syntax
   540   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   541   ""         :: "updbind => updbinds"             ("_")
   542   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   543   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   544 
   545 translations
   546   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   547   "f(x:=y)" == "CONST fun_upd f x y"
   548 
   549 (* Hint: to define the sum of two functions (or maps), use sum_case.
   550          A nice infix syntax could be defined (in Datatype.thy or below) by
   551 notation
   552   sum_case  (infixr "'(+')"80)
   553 *)
   554 
   555 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   556 apply (simp add: fun_upd_def, safe)
   557 apply (erule subst)
   558 apply (rule_tac [2] ext, auto)
   559 done
   560 
   561 lemma fun_upd_idem: "f x = y ==> f(x:=y) = f"
   562   by (simp only: fun_upd_idem_iff)
   563 
   564 lemma fun_upd_triv [iff]: "f(x := f x) = f"
   565   by (simp only: fun_upd_idem)
   566 
   567 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   568 by (simp add: fun_upd_def)
   569 
   570 (* fun_upd_apply supersedes these two,   but they are useful
   571    if fun_upd_apply is intentionally removed from the simpset *)
   572 lemma fun_upd_same: "(f(x:=y)) x = y"
   573 by simp
   574 
   575 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   576 by simp
   577 
   578 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   579 by (simp add: fun_eq_iff)
   580 
   581 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   582 by (rule ext, auto)
   583 
   584 lemma inj_on_fun_updI: "\<lbrakk> inj_on f A; y \<notin> f`A \<rbrakk> \<Longrightarrow> inj_on (f(x:=y)) A"
   585 by (fastforce simp:inj_on_def image_def)
   586 
   587 lemma fun_upd_image:
   588      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   589 by auto
   590 
   591 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   592   by auto
   593 
   594 lemma UNION_fun_upd:
   595   "UNION J (A(i:=B)) = (UNION (J-{i}) A \<union> (if i\<in>J then B else {}))"
   596 by (auto split: if_splits)
   597 
   598 
   599 subsection {* @{text override_on} *}
   600 
   601 definition override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b" where
   602   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   603 
   604 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   605 by(simp add:override_on_def)
   606 
   607 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   608 by(simp add:override_on_def)
   609 
   610 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   611 by(simp add:override_on_def)
   612 
   613 
   614 subsection {* @{text swap} *}
   615 
   616 definition swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)" where
   617   "swap a b f = f (a := f b, b:= f a)"
   618 
   619 lemma swap_self [simp]: "swap a a f = f"
   620 by (simp add: swap_def)
   621 
   622 lemma swap_commute: "swap a b f = swap b a f"
   623 by (rule ext, simp add: fun_upd_def swap_def)
   624 
   625 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
   626 by (rule ext, simp add: fun_upd_def swap_def)
   627 
   628 lemma swap_triple:
   629   assumes "a \<noteq> c" and "b \<noteq> c"
   630   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   631   using assms by (simp add: fun_eq_iff swap_def)
   632 
   633 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   634 by (rule ext, simp add: fun_upd_def swap_def)
   635 
   636 lemma swap_image_eq [simp]:
   637   assumes "a \<in> A" "b \<in> A" shows "swap a b f ` A = f ` A"
   638 proof -
   639   have subset: "\<And>f. swap a b f ` A \<subseteq> f ` A"
   640     using assms by (auto simp: image_iff swap_def)
   641   then have "swap a b (swap a b f) ` A \<subseteq> (swap a b f) ` A" .
   642   with subset[of f] show ?thesis by auto
   643 qed
   644 
   645 lemma inj_on_imp_inj_on_swap:
   646   "\<lbrakk>inj_on f A; a \<in> A; b \<in> A\<rbrakk> \<Longrightarrow> inj_on (swap a b f) A"
   647   by (simp add: inj_on_def swap_def, blast)
   648 
   649 lemma inj_on_swap_iff [simp]:
   650   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A \<longleftrightarrow> inj_on f A"
   651 proof
   652   assume "inj_on (swap a b f) A"
   653   with A have "inj_on (swap a b (swap a b f)) A"
   654     by (iprover intro: inj_on_imp_inj_on_swap)
   655   thus "inj_on f A" by simp
   656 next
   657   assume "inj_on f A"
   658   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   659 qed
   660 
   661 lemma surj_imp_surj_swap: "surj f \<Longrightarrow> surj (swap a b f)"
   662   by simp
   663 
   664 lemma surj_swap_iff [simp]: "surj (swap a b f) \<longleftrightarrow> surj f"
   665   by simp
   666 
   667 lemma bij_betw_swap_iff [simp]:
   668   "\<lbrakk> x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> bij_betw (swap x y f) A B \<longleftrightarrow> bij_betw f A B"
   669   by (auto simp: bij_betw_def)
   670 
   671 lemma bij_swap_iff [simp]: "bij (swap a b f) \<longleftrightarrow> bij f"
   672   by simp
   673 
   674 hide_const (open) swap
   675 
   676 subsection {* Inversion of injective functions *}
   677 
   678 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   679   "the_inv_into A f == %x. THE y. y : A & f y = x"
   680 
   681 lemma the_inv_into_f_f:
   682   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   683 apply (simp add: the_inv_into_def inj_on_def)
   684 apply blast
   685 done
   686 
   687 lemma f_the_inv_into_f:
   688   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   689 apply (simp add: the_inv_into_def)
   690 apply (rule the1I2)
   691  apply(blast dest: inj_onD)
   692 apply blast
   693 done
   694 
   695 lemma the_inv_into_into:
   696   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   697 apply (simp add: the_inv_into_def)
   698 apply (rule the1I2)
   699  apply(blast dest: inj_onD)
   700 apply blast
   701 done
   702 
   703 lemma the_inv_into_onto[simp]:
   704   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   705 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   706 
   707 lemma the_inv_into_f_eq:
   708   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   709   apply (erule subst)
   710   apply (erule the_inv_into_f_f, assumption)
   711   done
   712 
   713 lemma the_inv_into_comp:
   714   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   715   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   716 apply (rule the_inv_into_f_eq)
   717   apply (fast intro: comp_inj_on)
   718  apply (simp add: f_the_inv_into_f the_inv_into_into)
   719 apply (simp add: the_inv_into_into)
   720 done
   721 
   722 lemma inj_on_the_inv_into:
   723   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   724 by (auto intro: inj_onI simp: image_def the_inv_into_f_f)
   725 
   726 lemma bij_betw_the_inv_into:
   727   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   728 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   729 
   730 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   731   "the_inv f \<equiv> the_inv_into UNIV f"
   732 
   733 lemma the_inv_f_f:
   734   assumes "inj f"
   735   shows "the_inv f (f x) = x" using assms UNIV_I
   736   by (rule the_inv_into_f_f)
   737 
   738 
   739 text{*compatibility*}
   740 lemmas o_def = comp_def
   741 
   742 
   743 subsection {* Cantor's Paradox *}
   744 
   745 lemma Cantors_paradox [no_atp]:
   746   "\<not>(\<exists>f. f ` A = Pow A)"
   747 proof clarify
   748   fix f assume "f ` A = Pow A" hence *: "Pow A \<le> f ` A" by blast
   749   let ?X = "{a \<in> A. a \<notin> f a}"
   750   have "?X \<in> Pow A" unfolding Pow_def by auto
   751   with * obtain x where "x \<in> A \<and> f x = ?X" by blast
   752   thus False by best
   753 qed
   754 
   755 subsection {* Setup *} 
   756 
   757 subsubsection {* Proof tools *}
   758 
   759 text {* simplifies terms of the form
   760   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   761 
   762 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   763 let
   764   fun gen_fun_upd NONE T _ _ = NONE
   765     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   766   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   767   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   768     let
   769       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   770             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   771         | find t = NONE
   772     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   773 
   774   fun proc ss ct =
   775     let
   776       val ctxt = Simplifier.the_context ss
   777       val t = Thm.term_of ct
   778     in
   779       case find_double t of
   780         (T, NONE) => NONE
   781       | (T, SOME rhs) =>
   782           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   783             (fn _ =>
   784               rtac eq_reflection 1 THEN
   785               rtac ext 1 THEN
   786               simp_tac (Simplifier.inherit_context ss @{simpset}) 1))
   787     end
   788 in proc end
   789 *}
   790 
   791 
   792 subsubsection {* Code generator *}
   793 
   794 code_const "op \<circ>"
   795   (SML infixl 5 "o")
   796   (Haskell infixr 9 ".")
   797 
   798 code_const "id"
   799   (Haskell "id")
   800 
   801 
   802 subsubsection {* Functorial structure of types *}
   803 
   804 use "Tools/enriched_type.ML"
   805 
   806 end