src/Pure/library.ML
author wenzelm
Tue Jun 19 23:15:54 2007 +0200 (2007-06-19)
changeset 23424 d0580634f128
parent 23251 471b576aad25
child 23718 8ff68cb5860c
permissions -rw-r--r--
moved balanced tree operations to General/balanced_tree.ML;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, orders, current directory, misc.
     8 
     9 See also General/basics.ML for the most fundamental concepts.
    10 *)
    11 
    12 infix 1 |>>>
    13 infix 2 ?
    14 infix 3 o oo ooo oooo
    15 infix 4 ~~ upto downto
    16 infix orf andf \ \\ mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val flip: ('a -> 'b -> 'c) -> 'b -> 'a -> 'c
    25   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    26   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    27   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    28   val ? : bool * ('a -> 'a) -> 'a -> 'a
    29   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    30   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    31   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    32   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    33 
    34   (*exceptions*)
    35   exception EXCEPTION of exn * string
    36   val do_transform_failure: bool ref
    37   val transform_failure: (exn -> exn) -> ('a -> 'b) -> 'a -> 'b
    38   datatype 'a result = Result of 'a | Exn of exn
    39   val capture: ('a -> 'b) -> 'a -> 'b result
    40   val release: 'a result -> 'a
    41   val get_result: 'a result -> 'a option
    42   val get_exn: 'a result -> exn option
    43 
    44   (*errors*)
    45   exception SYS_ERROR of string
    46   val sys_error: string -> 'a
    47   exception ERROR of string
    48   val error: string -> 'a
    49   val cat_error: string -> string -> 'a
    50   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    51 
    52   (*pairs*)
    53   val pair: 'a -> 'b -> 'a * 'b
    54   val rpair: 'a -> 'b -> 'b * 'a
    55   val fst: 'a * 'b -> 'a
    56   val snd: 'a * 'b -> 'b
    57   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    58   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    59   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    60   val swap: 'a * 'b -> 'b * 'a
    61   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    62   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    63   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    64 
    65   (*booleans*)
    66   val equal: ''a -> ''a -> bool
    67   val not_equal: ''a -> ''a -> bool
    68   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    69   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    70   val exists: ('a -> bool) -> 'a list -> bool
    71   val forall: ('a -> bool) -> 'a list -> bool
    72   val set: bool ref -> bool
    73   val reset: bool ref -> bool
    74   val toggle: bool ref -> bool
    75   val change: 'a ref -> ('a -> 'a) -> unit
    76   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    77 
    78   (*lists*)
    79   exception UnequalLengths
    80   val single: 'a -> 'a list
    81   val the_single: 'a list -> 'a
    82   val singleton: ('a list -> 'b list) -> 'a -> 'b
    83   val apply: ('a -> 'a) list -> 'a -> 'a
    84   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    85   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    86   val flat: 'a list list -> 'a list
    87   val unflat: 'a list list -> 'b list -> 'b list list
    88   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    89   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    90   val maps: ('a -> 'b list) -> 'a list -> 'b list
    91   val chop: int -> 'a list -> 'a list * 'a list
    92   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    93   val nth: 'a list -> int -> 'a
    94   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    95   val nth_list: 'a list list -> int -> 'a list
    96   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    97   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    98   val split_last: 'a list -> 'a list * 'a
    99   val find_index: ('a -> bool) -> 'a list -> int
   100   val find_index_eq: ''a -> ''a list -> int
   101   val find_first: ('a -> bool) -> 'a list -> 'a option
   102   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   103   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   104   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   105   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   106   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   107   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   108   val ~~ : 'a list * 'b list -> ('a * 'b) list
   109   val split_list: ('a * 'b) list -> 'a list * 'b list
   110   val separate: 'a -> 'a list -> 'a list
   111   val replicate: int -> 'a -> 'a list
   112   val multiply: 'a list -> 'a list list -> 'a list list
   113   val product: 'a list -> 'b list -> ('a * 'b) list
   114   val filter: ('a -> bool) -> 'a list -> 'a list
   115   val filter_out: ('a -> bool) -> 'a list -> 'a list
   116   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
   117   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   118   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   119   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   120   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   121   val prefixes1: 'a list -> 'a list list
   122   val prefixes: 'a list -> 'a list list
   123   val suffixes1: 'a list -> 'a list list
   124   val suffixes: 'a list -> 'a list list
   125 
   126   (*integers*)
   127   val inc: int ref -> int
   128   val dec: int ref -> int
   129   val upto: int * int -> int list
   130   val downto: int * int -> int list
   131   val radixpand: int * int -> int list
   132   val radixstring: int * string * int -> string
   133   val string_of_int: int -> string
   134   val signed_string_of_int: int -> string
   135   val string_of_indexname: string * int -> string
   136   val read_intinf: int -> string list -> IntInf.int * string list
   137   val read_int: string list -> int * string list
   138   val oct_char: string -> string
   139 
   140   (*strings*)
   141   val nth_string: string -> int -> string
   142   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   143   val exists_string: (string -> bool) -> string -> bool
   144   val forall_string: (string -> bool) -> string -> bool
   145   val enclose: string -> string -> string -> string
   146   val unenclose: string -> string
   147   val quote: string -> string
   148   val space_implode: string -> string list -> string
   149   val commas: string list -> string
   150   val commas_quote: string list -> string
   151   val cat_lines: string list -> string
   152   val space_explode: string -> string -> string list
   153   val split_lines: string -> string list
   154   val prefix_lines: string -> string -> string
   155   val untabify: string list -> string list
   156   val prefix: string -> string -> string
   157   val suffix: string -> string -> string
   158   val unprefix: string -> string -> string
   159   val unsuffix: string -> string -> string
   160   val replicate_string: int -> string -> string
   161   val translate_string: (string -> string) -> string -> string
   162 
   163   (*lists as sets -- see also Pure/General/ord_list.ML*)
   164   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   165   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   166   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   167   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   168   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   169   val mem: ''a * ''a list -> bool
   170   val mem_int: int * int list -> bool
   171   val mem_string: string * string list -> bool
   172   val union: ''a list * ''a list -> ''a list
   173   val union_int: int list * int list -> int list
   174   val union_string: string list * string list -> string list
   175   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   176   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   177   val inter: ''a list * ''a list -> ''a list
   178   val inter_int: int list * int list -> int list
   179   val inter_string: string list * string list -> string list
   180   val subset: ''a list * ''a list -> bool
   181   val subset_int: int list * int list -> bool
   182   val subset_string: string list * string list -> bool
   183   val eq_set: ''a list * ''a list -> bool
   184   val eq_set_string: string list * string list -> bool
   185   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   186   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   187   val \ : ''a list * ''a -> ''a list
   188   val \\ : ''a list * ''a list -> ''a list
   189   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   190   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   191   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   192 
   193   (*lists as multisets*)
   194   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   195   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   196 
   197   (*orders*)
   198   val is_equal: order -> bool
   199   val rev_order: order -> order
   200   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   201   val int_ord: int * int -> order
   202   val string_ord: string * string -> order
   203   val fast_string_ord: string * string -> order
   204   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   205   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   206   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   207   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   208   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   209   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   210   val sort_strings: string list -> string list
   211   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   212 
   213   (*random numbers*)
   214   exception RANDOM
   215   val random: unit -> real
   216   val random_range: int -> int -> int
   217   val one_of: 'a list -> 'a
   218   val frequency: (int * 'a) list -> 'a
   219 
   220   (*current directory*)
   221   val cd: string -> unit
   222   val pwd: unit -> string
   223 
   224   (*misc*)
   225   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   226   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   227   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   228   val gensym: string -> string
   229   type stamp
   230   val stamp: unit -> stamp
   231   type serial
   232   val serial: unit -> serial
   233   val serial_string: unit -> string
   234   structure Object: sig type T end
   235 end;
   236 
   237 signature LIBRARY =
   238 sig
   239   include BASIC_LIBRARY
   240   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   241   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   242   val take: int * 'a list -> 'a list
   243   val drop: int * 'a list -> 'a list
   244   val last_elem: 'a list -> 'a
   245 end;
   246 
   247 structure Library: LIBRARY =
   248 struct
   249 
   250 (* functions *)
   251 
   252 fun I x = x;
   253 fun K x = fn _ => x;
   254 fun flip f x y = f y x;
   255 fun curry f x y = f (x, y);
   256 fun uncurry f (x, y) = f x y;
   257 
   258 (*application and structured results -- old version*)
   259 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   260 
   261 (*conditional application*)
   262 fun b ? f = fn x => if b then f x else x;
   263 
   264 (*composition with multiple args*)
   265 fun (f oo g) x y = f (g x y);
   266 fun (f ooo g) x y z = f (g x y z);
   267 fun (f oooo g) x y z w = f (g x y z w);
   268 
   269 (*function exponentiation: f(...(f x)...) with n applications of f*)
   270 fun funpow n f x =
   271   let fun rep (0, x) = x
   272         | rep (n, x) = rep (n - 1, f x)
   273   in rep (n, x) end;
   274 
   275 
   276 (* exceptions *)
   277 
   278 val do_transform_failure = ref true;
   279 
   280 fun transform_failure exn f x =
   281   if ! do_transform_failure then
   282     f x handle Interrupt => raise Interrupt | e => raise exn e
   283   else f x;
   284 
   285 exception EXCEPTION of exn * string;
   286 
   287 datatype 'a result =
   288   Result of 'a |
   289   Exn of exn;
   290 
   291 fun capture f x = Result (f x) handle e => Exn e;
   292 
   293 fun release (Result y) = y
   294   | release (Exn e) = raise e;
   295 
   296 fun get_result (Result x) = SOME x
   297   | get_result _ = NONE;
   298 
   299 fun get_exn (Exn exn) = SOME exn
   300   | get_exn _ = NONE;
   301 
   302 
   303 (* errors *)
   304 
   305 exception SYS_ERROR of string;
   306 fun sys_error msg = raise SYS_ERROR msg;
   307 
   308 exception ERROR of string;
   309 fun error msg = raise ERROR msg;
   310 
   311 fun cat_error "" msg = error msg
   312   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   313 
   314 fun assert_all pred list msg =
   315   let
   316     fun ass [] = ()
   317       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   318   in ass list end;
   319 
   320 
   321 (* pairs *)
   322 
   323 fun pair x y = (x, y);
   324 fun rpair x y = (y, x);
   325 
   326 fun fst (x, y) = x;
   327 fun snd (x, y) = y;
   328 
   329 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   330 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   331 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   332 
   333 fun swap (x, y) = (y, x);
   334 
   335 fun apfst f (x, y) = (f x, y);
   336 fun apsnd f (x, y) = (x, f y);
   337 fun pairself f (x, y) = (f x, f y);
   338 
   339 
   340 (* booleans *)
   341 
   342 (*polymorphic equality*)
   343 fun equal x y = x = y;
   344 fun not_equal x y = x <> y;
   345 
   346 (*combining predicates*)
   347 fun p orf q = fn x => p x orelse q x;
   348 fun p andf q = fn x => p x andalso q x;
   349 
   350 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   351 fun exists (pred: 'a -> bool) : 'a list -> bool =
   352   let fun boolf [] = false
   353         | boolf (x :: xs) = pred x orelse boolf xs
   354   in boolf end;
   355 
   356 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   357 fun forall (pred: 'a -> bool) : 'a list -> bool =
   358   let fun boolf [] = true
   359         | boolf (x :: xs) = pred x andalso boolf xs
   360   in boolf end;
   361 
   362 
   363 (* flags *)
   364 
   365 fun set flag = (flag := true; true);
   366 fun reset flag = (flag := false; false);
   367 fun toggle flag = (flag := not (! flag); ! flag);
   368 
   369 fun change r f = r := f (! r);
   370 
   371 (*temporarily set flag during execution*)
   372 fun setmp flag value f x =
   373   let
   374     val orig_value = ! flag;
   375     val _ = flag := value;
   376     val result = capture f x;
   377     val _ = flag := orig_value;
   378   in release result end;
   379 
   380 
   381 
   382 (** lists **)
   383 
   384 exception UnequalLengths;
   385 
   386 fun single x = [x];
   387 
   388 fun the_single [x] = x
   389   | the_single _ = raise Empty;
   390 
   391 fun singleton f x = the_single (f [x]);
   392 
   393 fun apply [] x = x
   394   | apply (f :: fs) x = apply fs (f x);
   395 
   396 
   397 (* fold -- old versions *)
   398 
   399 (*the following versions of fold are designed to fit nicely with infixes*)
   400 
   401 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   402     for operators that associate to the left (TAIL RECURSIVE)*)
   403 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   404   let fun itl (e, [])  = e
   405         | itl (e, a::l) = itl (f(e, a), l)
   406   in  itl end;
   407 
   408 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   409     for operators that associate to the right (not tail recursive)*)
   410 fun foldr f (l, e) =
   411   let fun itr [] = e
   412         | itr (a::l) = f(a, itr l)
   413   in  itr l  end;
   414 
   415 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   416     for n > 0, operators that associate to the right (not tail recursive)*)
   417 fun foldr1 f [] = raise Empty
   418   | foldr1 f l =
   419       let fun itr [x] = x
   420             | itr (x::l) = f(x, itr l)
   421       in  itr l  end;
   422 
   423 fun foldl_map f =
   424   let
   425     fun fold_aux (x, []) = (x, [])
   426       | fold_aux (x, y :: ys) =
   427           let
   428             val (x', y') = f (x, y);
   429             val (x'', ys') = fold_aux (x', ys);
   430           in (x'', y' :: ys') end;
   431   in fold_aux end;
   432 
   433 
   434 (* basic list functions *)
   435 
   436 fun eq_list eq (list1, list2) =
   437   let
   438     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   439       | eq_lst _ = true;
   440   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   441 
   442 fun maps f [] = []
   443   | maps f (x :: xs) = f x @ maps f xs;
   444 
   445 fun chop 0 xs = ([], xs)
   446   | chop _ [] = ([], [])
   447   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   448 
   449 (*take the first n elements from a list*)
   450 fun take (n, []) = []
   451   | take (n, x :: xs) =
   452       if n > 0 then x :: take (n - 1, xs) else [];
   453 
   454 (*drop the first n elements from a list*)
   455 fun drop (n, []) = []
   456   | drop (n, x :: xs) =
   457       if n > 0 then drop (n - 1, xs) else x :: xs;
   458 
   459 fun dropwhile P [] = []
   460   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   461 
   462 (*return nth element of a list, where 0 designates the first element;
   463   raise Subscript if list too short*)
   464 fun nth xs i = List.nth (xs, i);
   465 
   466 fun nth_list xss i = nth xss i handle Subscript => [];
   467 
   468 fun nth_map 0 f (x :: xs) = f x :: xs
   469   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   470   | nth_map _ _ [] = raise Subscript;
   471 
   472 fun map_index f =
   473   let
   474     fun mapp _ [] = []
   475       | mapp i (x :: xs) = f (i, x) :: mapp (i+1) xs
   476   in mapp 0 end;
   477 
   478 fun fold_index f =
   479   let
   480     fun fold_aux _ [] y = y
   481       | fold_aux i (x :: xs) y = fold_aux (i+1) xs (f (i, x) y);
   482   in fold_aux 0 end;
   483 
   484 val last_elem = List.last;
   485 
   486 (*rear decomposition*)
   487 fun split_last [] = raise Empty
   488   | split_last [x] = ([], x)
   489   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   490 
   491 (*find the position of an element in a list*)
   492 fun find_index pred =
   493   let fun find _ [] = ~1
   494         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   495   in find 0 end;
   496 
   497 fun find_index_eq x = find_index (equal x);
   498 
   499 (*find first element satisfying predicate*)
   500 val find_first = List.find;
   501 
   502 (*get first element by lookup function*)
   503 fun get_first _ [] = NONE
   504   | get_first f (x :: xs) =
   505       (case f x of
   506         NONE => get_first f xs
   507       | some => some);
   508 
   509 fun get_index f =
   510   let
   511     fun get _ [] = NONE
   512       | get i (x :: xs) =
   513           case f x
   514            of NONE => get (i + 1) xs
   515             | SOME y => SOME (i, y)
   516   in get 0 end;
   517 
   518 val flat = List.concat;
   519 
   520 fun unflat (xs :: xss) ys =
   521       let val (ps, qs) = chop (length xs) ys
   522       in ps :: unflat xss qs end
   523   | unflat [] [] = []
   524   | unflat _ _ = raise UnequalLengths;
   525 
   526 fun burrow f xss = unflat xss (f (flat xss));
   527 
   528 fun fold_burrow f xss s =
   529   apfst (unflat xss) (f (flat xss) s);
   530 
   531 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   532 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   533   | separate _ xs = xs;
   534 
   535 (*make the list [x, x, ..., x] of length n*)
   536 fun replicate n (x: 'a) : 'a list =
   537   let fun rep (0, xs) = xs
   538         | rep (n, xs) = rep (n - 1, x :: xs)
   539   in
   540     if n < 0 then raise Subscript
   541     else rep (n, [])
   542   end;
   543 
   544 fun translate_string f = String.translate (f o String.str);
   545 
   546 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   547 fun multiply [] _ = []
   548   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   549 
   550 (*direct product*)
   551 fun product _ [] = []
   552   | product [] _ = []
   553   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   554 
   555 
   556 (* filter *)
   557 
   558 (*copy the list preserving elements that satisfy the predicate*)
   559 val filter = List.filter;
   560 fun filter_out f = filter (not o f);
   561 val map_filter = List.mapPartial;
   562 
   563 
   564 (* lists of pairs *)
   565 
   566 exception UnequalLengths;
   567 
   568 fun map2 _ [] [] = []
   569   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   570   | map2 _ _ _ = raise UnequalLengths;
   571 
   572 fun fold2 f [] [] z = z
   573   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   574   | fold2 f _ _ _ = raise UnequalLengths;
   575 
   576 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   577   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   578   | zip_options _ [] = []
   579   | zip_options [] _ = raise UnequalLengths;
   580 
   581 (*combine two lists forming a list of pairs:
   582   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   583 fun [] ~~ [] = []
   584   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   585   | _ ~~ _ = raise UnequalLengths;
   586 
   587 (*inverse of ~~; the old 'split':
   588   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   589 val split_list = ListPair.unzip;
   590 
   591 
   592 (* prefixes, suffixes *)
   593 
   594 fun is_prefix _ [] _ = true
   595   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   596   | is_prefix eq _ _ = false;
   597 
   598 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   599    where xi is the first element that does not satisfy the predicate*)
   600 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   601   let fun take (rxs, []) = (rev rxs, [])
   602         | take (rxs, x :: xs) =
   603             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   604   in  take([], xs)  end;
   605 
   606 fun chop_prefix eq ([], ys) = ([], ([], ys))
   607   | chop_prefix eq (xs, []) = ([], (xs, []))
   608   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   609       if eq (x, y) then
   610         let val (ps', xys'') = chop_prefix eq (xs', ys')
   611         in (x :: ps', xys'') end
   612       else ([], (xs, ys));
   613 
   614 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   615    where xi is the last element that does not satisfy the predicate*)
   616 fun take_suffix _ [] = ([], [])
   617   | take_suffix pred (x :: xs) =
   618       (case take_suffix pred xs of
   619         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   620       | (prfx, sffx) => (x :: prfx, sffx));
   621 
   622 fun prefixes1 [] = []
   623   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   624 
   625 fun prefixes xs = [] :: prefixes1 xs;
   626 
   627 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   628 fun suffixes xs = [] :: suffixes1 xs;
   629 
   630 
   631 
   632 (** integers **)
   633 
   634 fun inc i = (i := ! i + 1; ! i);
   635 fun dec i = (i := ! i - 1; ! i);
   636 
   637 
   638 (* lists of integers *)
   639 
   640 (*make the list [from, from + 1, ..., to]*)
   641 fun (i upto j) =
   642   if i > j then [] else i :: (i + 1 upto j);
   643 
   644 (*make the list [from, from - 1, ..., to]*)
   645 fun (i downto j) =
   646   if i < j then [] else i :: (i - 1 downto j);
   647 
   648 
   649 (* convert integers to strings *)
   650 
   651 (*expand the number in the given base;
   652   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   653 fun radixpand (base, num) : int list =
   654   let
   655     fun radix (n, tail) =
   656       if n < base then n :: tail
   657       else radix (n div base, (n mod base) :: tail)
   658   in radix (num, []) end;
   659 
   660 (*expands a number into a string of characters starting from "zerochar";
   661   example: radixstring (2, "0", 8) gives "1000"*)
   662 fun radixstring (base, zerochar, num) =
   663   let val offset = ord zerochar;
   664       fun chrof n = chr (offset + n)
   665   in implode (map chrof (radixpand (base, num))) end;
   666 
   667 
   668 val string_of_int = Int.toString;
   669 
   670 fun signed_string_of_int i =
   671   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   672 
   673 fun string_of_indexname (a, 0) = a
   674   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   675 
   676 
   677 (* read integers *)
   678 
   679 fun read_intinf radix cs =
   680   let
   681     val zero = ord "0";
   682     val limit = zero + radix;
   683     fun scan (num, []) = (num, [])
   684       | scan (num, c :: cs) =
   685         if zero <= ord c andalso ord c < limit then
   686           scan (IntInf.fromInt radix * num + IntInf.fromInt (ord c - zero), cs)
   687         else (num, c :: cs);
   688   in scan (IntInf.fromInt 0, cs) end;
   689 
   690 fun read_int cs = apfst IntInf.toInt (read_intinf 10 cs);
   691 
   692 fun oct_char s = chr (IntInf.toInt (#1 (read_intinf 8 (explode s))));
   693 
   694 
   695 
   696 (** strings **)
   697 
   698 (* functions tuned for strings, avoiding explode *)
   699 
   700 fun nth_string str i =
   701   (case try String.substring (str, i, 1) of
   702     SOME s => s
   703   | NONE => raise Subscript);
   704 
   705 fun fold_string f str x0 =
   706   let
   707     val n = size str;
   708     fun iter (x, i) =
   709       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   710   in iter (x0, 0) end;
   711 
   712 fun exists_string pred str =
   713   let
   714     val n = size str;
   715     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   716   in ex 0 end;
   717 
   718 fun forall_string pred = not o exists_string (not o pred);
   719 
   720 (*enclose in brackets*)
   721 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   722 fun unenclose str = String.substring (str, 1, size str - 2);
   723 
   724 (*simple quoting (does not escape special chars)*)
   725 val quote = enclose "\"" "\"";
   726 
   727 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   728 fun space_implode a bs = implode (separate a bs);
   729 
   730 val commas = space_implode ", ";
   731 val commas_quote = commas o map quote;
   732 
   733 (*concatenate messages, one per line, into a string*)
   734 val cat_lines = space_implode "\n";
   735 
   736 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   737 fun space_explode _ "" = []
   738   | space_explode sep s = String.fields (fn c => str c = sep) s;
   739 
   740 val split_lines = space_explode "\n";
   741 
   742 fun prefix_lines "" txt = txt
   743   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   744 
   745 fun untabify chs =
   746   let
   747     val tab_width = 8;
   748 
   749     fun untab pos [] ys = rev ys
   750       | untab pos ("\n" :: xs) ys = untab 0 xs ("\n" :: ys)
   751       | untab pos ("\t" :: xs) ys =
   752           let val d = tab_width - (pos mod tab_width)
   753           in untab (pos + d) xs (replicate d " " @ ys) end
   754       | untab pos (c :: xs) ys = untab (pos + 1) xs (c :: ys);
   755   in
   756     if not (exists (fn c => c = "\t") chs) then chs
   757     else untab 0 chs []
   758   end;
   759 
   760 fun prefix prfx s = prfx ^ s;
   761 fun suffix sffx s = s ^ sffx;
   762 
   763 fun unprefix prfx s =
   764   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   765   else raise Fail "unprefix";
   766 
   767 fun unsuffix sffx s =
   768   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   769   else raise Fail "unsuffix";
   770 
   771 fun replicate_string 0 _ = ""
   772   | replicate_string 1 a = a
   773   | replicate_string k a =
   774       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   775       else replicate_string (k div 2) (a ^ a) ^ a;
   776 
   777 
   778 
   779 (** lists as sets -- see also Pure/General/ord_list.ML **)
   780 
   781 (*canonical member, insert, remove*)
   782 fun member eq list x =
   783   let
   784     fun memb [] = false
   785       | memb (y :: ys) = eq (x, y) orelse memb ys;
   786   in memb list end;
   787 
   788 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   789 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   790 
   791 fun subtract eq = fold (remove eq);
   792 
   793 fun merge _ ([], ys) = ys
   794   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   795 
   796 (*old-style infixes*)
   797 fun x mem xs = member (op =) xs x;
   798 fun (x: int) mem_int xs = member (op =) xs x;
   799 fun (x: string) mem_string xs = member (op =) xs x;
   800 
   801 
   802 (*union of sets represented as lists: no repetitions*)
   803 fun xs union [] = xs
   804   | [] union ys = ys
   805   | (x :: xs) union ys = xs union (insert (op =) x ys);
   806 
   807 (*union of sets, optimized version for ints*)
   808 fun (xs:int list) union_int [] = xs
   809   | [] union_int ys = ys
   810   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   811 
   812 (*union of sets, optimized version for strings*)
   813 fun (xs:string list) union_string [] = xs
   814   | [] union_string ys = ys
   815   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   816 
   817 (*generalized union*)
   818 fun gen_union eq (xs, []) = xs
   819   | gen_union eq ([], ys) = ys
   820   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   821 
   822 
   823 (*intersection*)
   824 fun [] inter ys = []
   825   | (x :: xs) inter ys =
   826       if x mem ys then x :: (xs inter ys) else xs inter ys;
   827 
   828 (*intersection, optimized version for ints*)
   829 fun ([]:int list) inter_int ys = []
   830   | (x :: xs) inter_int ys =
   831       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   832 
   833 (*intersection, optimized version for strings *)
   834 fun ([]:string list) inter_string ys = []
   835   | (x :: xs) inter_string ys =
   836       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   837 
   838 (*generalized intersection*)
   839 fun gen_inter eq ([], ys) = []
   840   | gen_inter eq (x::xs, ys) =
   841       if member eq ys x then x :: gen_inter eq (xs, ys)
   842       else gen_inter eq (xs, ys);
   843 
   844 
   845 (*subset*)
   846 fun [] subset ys = true
   847   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   848 
   849 (*subset, optimized version for ints*)
   850 fun ([]: int list) subset_int ys = true
   851   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   852 
   853 (*subset, optimized version for strings*)
   854 fun ([]: string list) subset_string ys = true
   855   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   856 
   857 (*set equality*)
   858 fun eq_set (xs, ys) =
   859   xs = ys orelse (xs subset ys andalso ys subset xs);
   860 
   861 (*set equality for strings*)
   862 fun eq_set_string ((xs: string list), ys) =
   863   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   864 
   865 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
   866 
   867 fun gen_eq_set eq (xs, ys) =
   868   eq_list eq (xs, ys) orelse
   869     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
   870 
   871 
   872 (*removing an element from a list WITHOUT duplicates*)
   873 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   874   | [] \ x = [];
   875 fun ys \\ xs = foldl (op \) (ys,xs);
   876 
   877 
   878 (*makes a list of the distinct members of the input; preserves order, takes
   879   first of equal elements*)
   880 fun distinct eq lst =
   881   let
   882     fun dist (rev_seen, []) = rev rev_seen
   883       | dist (rev_seen, x :: xs) =
   884           if member eq rev_seen x then dist (rev_seen, xs)
   885           else dist (x :: rev_seen, xs);
   886   in dist ([], lst) end;
   887 
   888 (*returns a list containing all repeated elements exactly once; preserves
   889   order, takes first of equal elements*)
   890 fun duplicates eq lst =
   891   let
   892     fun dups (rev_dups, []) = rev rev_dups
   893       | dups (rev_dups, x :: xs) =
   894           if member eq rev_dups x orelse not (member eq xs x) then
   895             dups (rev_dups, xs)
   896           else dups (x :: rev_dups, xs);
   897   in dups ([], lst) end;
   898 
   899 fun has_duplicates eq =
   900   let
   901     fun dups [] = false
   902       | dups (x :: xs) = member eq xs x orelse dups xs;
   903   in dups end;
   904 
   905 
   906 
   907 (** lists as multisets **)
   908 
   909 fun remove1 _ _ [] = raise Empty
   910   | remove1 eq y (x::xs) = if eq (y, x) then xs else x :: remove1 eq y xs;
   911 
   912 fun submultiset _ ([], _)  = true
   913   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   914 
   915 
   916 
   917 (** orders **)
   918 
   919 fun is_equal EQUAL = true
   920   | is_equal _ = false;
   921 
   922 fun rev_order LESS = GREATER
   923   | rev_order EQUAL = EQUAL
   924   | rev_order GREATER = LESS;
   925 
   926 (*assume rel is a linear strict order*)
   927 fun make_ord rel (x, y) =
   928   if rel (x, y) then LESS
   929   else if rel (y, x) then GREATER
   930   else EQUAL;
   931 
   932 val int_ord = Int.compare;
   933 val string_ord = String.compare;
   934 
   935 fun fast_string_ord (s1, s2) =
   936   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   937 
   938 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   939   | option_ord _ (NONE, NONE) = EQUAL
   940   | option_ord _ (NONE, SOME _) = LESS
   941   | option_ord _ (SOME _, NONE) = GREATER;
   942 
   943 (*lexicographic product*)
   944 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   945   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   946 
   947 (*dictionary order -- in general NOT well-founded!*)
   948 fun dict_ord elem_ord (x :: xs, y :: ys) =
   949       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   950   | dict_ord _ ([], []) = EQUAL
   951   | dict_ord _ ([], _ :: _) = LESS
   952   | dict_ord _ (_ :: _, []) = GREATER;
   953 
   954 (*lexicographic product of lists*)
   955 fun list_ord elem_ord (xs, ys) =
   956   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   957 
   958 
   959 (* sorting *)
   960 
   961 (*quicksort -- stable, i.e. does not reorder equal elements*)
   962 fun quicksort unique ord =
   963   let
   964     fun qsort [] = []
   965       | qsort (xs as [_]) = xs
   966       | qsort (xs as [x, y]) =
   967           (case ord (x, y) of
   968             LESS => xs
   969           | EQUAL => if unique then [x] else xs
   970           | GREATER => [y, x])
   971       | qsort xs =
   972           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   973           in qsort lts @ eqs @ qsort gts end
   974     and part _ [] = ([], [], [])
   975       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   976     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   977       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   978       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   979       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   980   in qsort end;
   981 
   982 fun sort ord = quicksort false ord;
   983 fun sort_distinct ord = quicksort true ord;
   984 
   985 val sort_strings = sort string_ord;
   986 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   987 
   988 
   989 
   990 (** random numbers **)
   991 
   992 exception RANDOM;
   993 
   994 fun rmod x y = x - y * Real.realFloor (x / y);
   995 
   996 local
   997   val a = 16807.0;
   998   val m = 2147483647.0;
   999   val random_seed = ref 1.0;
  1000 in
  1001 
  1002 fun random () =
  1003   let val r = rmod (a * !random_seed) m
  1004   in (random_seed := r; r) end;
  1005 
  1006 end;
  1007 
  1008 fun random_range l h =
  1009   if h < l orelse l < 0 then raise RANDOM
  1010   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1011 
  1012 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1013 
  1014 fun frequency xs =
  1015   let
  1016     val sum = foldl op + (0, map fst xs);
  1017     fun pick n ((k: int, x) :: xs) =
  1018       if n <= k then x else pick (n - k) xs
  1019   in pick (random_range 1 sum) xs end;
  1020 
  1021 
  1022 
  1023 (** current directory **)
  1024 
  1025 val cd = OS.FileSys.chDir;
  1026 val pwd = OS.FileSys.getDir;
  1027 
  1028 
  1029 
  1030 (** misc **)
  1031 
  1032 fun divide_and_conquer decomp x =
  1033   let val (ys, recomb) = decomp x
  1034   in recomb (map (divide_and_conquer decomp) ys) end;
  1035 
  1036 
  1037 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1038    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1039 fun partition_list p i j =
  1040   let fun part k xs =
  1041             if k>j then
  1042               (case xs of [] => []
  1043                          | _ => raise Fail "partition_list")
  1044             else
  1045             let val (ns, rest) = List.partition (p k) xs;
  1046             in  ns :: part(k+1)rest  end
  1047   in  part i end;
  1048 
  1049 fun partition_eq (eq:'a * 'a -> bool) =
  1050   let
  1051     fun part [] = []
  1052       | part (x :: ys) =
  1053           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1054           in (x::xs)::(part xs') end
  1055   in part end;
  1056 
  1057 
  1058 
  1059 (* generating identifiers *)
  1060 
  1061 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1062 local
  1063 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1064 fun gensym_char i =
  1065   if i<26 then chr (ord "A" + i)
  1066   else if i<52 then chr (ord "a" + i - 26)
  1067   else chr (ord "0" + i - 52);
  1068 
  1069 val char_vec = Vector.tabulate (62, gensym_char);
  1070 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1071 
  1072 val gensym_seed = ref 0;
  1073 
  1074 in
  1075   fun gensym pre = pre ^ newid (inc gensym_seed);
  1076 end;
  1077 
  1078 
  1079 (* stamps and serial numbers *)
  1080 
  1081 type stamp = unit ref;
  1082 val stamp: unit -> stamp = ref;
  1083 
  1084 type serial = int;
  1085 local val count = ref 0
  1086 in fun serial () = inc count end;
  1087 
  1088 val serial_string = string_of_int o serial;
  1089 
  1090 
  1091 (* generic objects *)
  1092 
  1093 (*note that the builtin exception datatype may be extended by new
  1094   constructors at any time*)
  1095 structure Object = struct type T = exn end;
  1096 
  1097 end;
  1098 
  1099 structure BasicLibrary: BASIC_LIBRARY = Library;
  1100 open BasicLibrary;