src/Pure/Isar/proof.ML
author wenzelm
Thu Dec 07 19:36:48 2017 +0100 (7 months ago)
changeset 67157 d0657c8b7616
parent 67119 acb0807ddb56
child 67161 b762ed417ed9
permissions -rw-r--r--
clarified document preparation vs. skip_proofs;
     1 (*  Title:      Pure/Isar/proof.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 The Isar/VM proof language interpreter: maintains a structured flow of
     5 context elements, goals, refinements, and facts.
     6 *)
     7 
     8 signature PROOF =
     9 sig
    10   type context = Proof.context
    11   type method = Method.method
    12   type state
    13   val init: context -> state
    14   val level: state -> int
    15   val assert_bottom: bool -> state -> state
    16   val context_of: state -> context
    17   val theory_of: state -> theory
    18   val map_context: (context -> context) -> state -> state
    19   val map_context_result : (context -> 'a * context) -> state -> 'a * state
    20   val map_contexts: (context -> context) -> state -> state
    21   val propagate_ml_env: state -> state
    22   val report_improper: state -> unit
    23   val the_facts: state -> thm list
    24   val the_fact: state -> thm
    25   val set_facts: thm list -> state -> state
    26   val reset_facts: state -> state
    27   val improper_reset_facts: state -> state
    28   val assert_forward: state -> state
    29   val assert_chain: state -> state
    30   val assert_forward_or_chain: state -> state
    31   val assert_backward: state -> state
    32   val assert_no_chain: state -> state
    33   val enter_forward: state -> state
    34   val enter_chain: state -> state
    35   val enter_backward: state -> state
    36   val has_bottom_goal: state -> bool
    37   val using_facts: thm list -> state -> state
    38   val pretty_state: state -> Pretty.T list
    39   val refine: Method.text -> state -> state Seq.result Seq.seq
    40   val refine_end: Method.text -> state -> state Seq.result Seq.seq
    41   val refine_singleton: Method.text -> state -> state
    42   val refine_insert: thm list -> state -> state
    43   val refine_primitive: (Proof.context -> thm -> thm) -> state -> state
    44   val raw_goal: state -> {context: context, facts: thm list, goal: thm}
    45   val goal: state -> {context: context, facts: thm list, goal: thm}
    46   val simple_goal: state -> {context: context, goal: thm}
    47   val let_bind: (term list * term) list -> state -> state
    48   val let_bind_cmd: (string list * string) list -> state -> state
    49   val write: Syntax.mode -> (term * mixfix) list -> state -> state
    50   val write_cmd: Syntax.mode -> (string * mixfix) list -> state -> state
    51   val fix: (binding * typ option * mixfix) list -> state -> state
    52   val fix_cmd: (binding * string option * mixfix) list -> state -> state
    53   val assm: Assumption.export -> (binding * typ option * mixfix) list ->
    54     (term * term list) list list -> (Thm.binding * (term * term list) list) list ->
    55     state -> state
    56   val assm_cmd: Assumption.export -> (binding * string option * mixfix) list ->
    57     (string * string list) list list -> (Attrib.binding * (string * string list) list) list ->
    58     state -> state
    59   val assume: (binding * typ option * mixfix) list ->
    60     (term * term list) list list -> (Thm.binding * (term * term list) list) list ->
    61     state -> state
    62   val assume_cmd: (binding * string option * mixfix) list ->
    63     (string * string list) list list -> (Attrib.binding * (string * string list) list) list ->
    64     state -> state
    65   val presume: (binding * typ option * mixfix) list ->
    66     (term * term list) list list -> (Thm.binding * (term * term list) list) list ->
    67     state -> state
    68   val presume_cmd: (binding * string option * mixfix) list ->
    69     (string * string list) list list -> (Attrib.binding * (string * string list) list) list ->
    70     state -> state
    71   val chain: state -> state
    72   val chain_facts: thm list -> state -> state
    73   val note_thmss: (Thm.binding * (thm list * attribute list) list) list -> state -> state
    74   val note_thmss_cmd: (Attrib.binding * (Facts.ref * Token.src list) list) list -> state -> state
    75   val from_thmss: ((thm list * attribute list) list) list -> state -> state
    76   val from_thmss_cmd: ((Facts.ref * Token.src list) list) list -> state -> state
    77   val with_thmss: ((thm list * attribute list) list) list -> state -> state
    78   val with_thmss_cmd: ((Facts.ref * Token.src list) list) list -> state -> state
    79   val supply: (Thm.binding * (thm list * attribute list) list) list -> state -> state
    80   val supply_cmd: (Attrib.binding * (Facts.ref * Token.src list) list) list -> state -> state
    81   val using: ((thm list * attribute list) list) list -> state -> state
    82   val using_cmd: ((Facts.ref * Token.src list) list) list -> state -> state
    83   val unfolding: ((thm list * attribute list) list) list -> state -> state
    84   val unfolding_cmd: ((Facts.ref * Token.src list) list) list -> state -> state
    85   val case_: Thm.binding * ((string * Position.T) * binding option list) -> state -> state
    86   val case_cmd: Attrib.binding * ((string * Position.T) * binding option list) -> state -> state
    87   val define: (binding * typ option * mixfix) list ->
    88     (binding * typ option * mixfix) list ->
    89     (Thm.binding * (term * term list) list) list -> state -> state
    90   val define_cmd: (binding * string option * mixfix) list ->
    91     (binding * string option * mixfix) list ->
    92     (Attrib.binding * (string * string list) list) list -> state -> state
    93   val begin_block: state -> state
    94   val next_block: state -> state
    95   val end_block: state -> state
    96   val begin_notepad: context -> state
    97   val end_notepad: state -> context
    98   val proof: Method.text_range option -> state -> state Seq.result Seq.seq
    99   val defer: int -> state -> state
   100   val prefer: int -> state -> state
   101   val apply: Method.text_range -> state -> state Seq.result Seq.seq
   102   val apply_end: Method.text_range -> state -> state Seq.result Seq.seq
   103   val local_qed: Method.text_range option * bool -> state -> state
   104   val theorem: Method.text option -> (thm list list -> context -> context) ->
   105     (term * term list) list list -> context -> state
   106   val theorem_cmd: Method.text option -> (thm list list -> context -> context) ->
   107     (string * string list) list list -> context -> state
   108   val global_qed: Method.text_range option * bool -> state -> context
   109   val schematic_goal: state -> bool
   110   val is_relevant: state -> bool
   111   val local_terminal_proof: Method.text_range * Method.text_range option -> state -> state
   112   val local_default_proof: state -> state
   113   val local_immediate_proof: state -> state
   114   val local_skip_proof: bool -> state -> state
   115   val local_done_proof: state -> state
   116   val global_terminal_proof: Method.text_range * Method.text_range option -> state -> context
   117   val global_default_proof: state -> context
   118   val global_immediate_proof: state -> context
   119   val global_skip_proof: bool -> state -> context
   120   val global_done_proof: state -> context
   121   val internal_goal: (context -> (string * string) * (string * thm list) list -> unit) ->
   122     Proof_Context.mode -> bool -> string -> Method.text option ->
   123     (context * thm list list -> state -> state) ->
   124     (binding * typ option * mixfix) list ->
   125     (Thm.binding * (term * term list) list) list ->
   126     (Thm.binding * (term * term list) list) list -> state -> thm list * state
   127   val have: bool -> Method.text option -> (context * thm list list -> state -> state) ->
   128     (binding * typ option * mixfix) list ->
   129     (Thm.binding * (term * term list) list) list ->
   130     (Thm.binding * (term * term list) list) list -> bool -> state -> thm list * state
   131   val have_cmd: bool -> Method.text option -> (context * thm list list -> state -> state) ->
   132     (binding * string option * mixfix) list ->
   133     (Attrib.binding * (string * string list) list) list ->
   134     (Attrib.binding * (string * string list) list) list -> bool -> state -> thm list * state
   135   val show: bool -> Method.text option -> (context * thm list list -> state -> state) ->
   136     (binding * typ option * mixfix) list ->
   137     (Thm.binding * (term * term list) list) list ->
   138     (Thm.binding * (term * term list) list) list -> bool -> state -> thm list * state
   139   val show_cmd: bool -> Method.text option -> (context * thm list list -> state -> state) ->
   140     (binding * string option * mixfix) list ->
   141     (Attrib.binding * (string * string list) list) list ->
   142     (Attrib.binding * (string * string list) list) list -> bool -> state -> thm list * state
   143   val future_proof: (state -> ('a * context) future) -> state -> 'a future * state
   144   val local_future_terminal_proof: Method.text_range * Method.text_range option -> state -> state
   145   val global_future_terminal_proof: Method.text_range * Method.text_range option -> state -> context
   146 end;
   147 
   148 structure Proof: PROOF =
   149 struct
   150 
   151 type context = Proof.context;
   152 type method = Method.method;
   153 
   154 
   155 (** proof state **)
   156 
   157 (* datatype state *)
   158 
   159 datatype mode = Forward | Chain | Backward;
   160 
   161 datatype state =
   162   State of node Stack.T
   163 and node =
   164   Node of
   165    {context: context,
   166     facts: (thm list * bool) option,
   167     mode: mode,
   168     goal: goal option}
   169 and goal =
   170   Goal of
   171    {statement: (string * Position.T) * term list list * term,
   172       (*goal kind and statement (starting with vars), initial proposition*)
   173     using: thm list,                      (*goal facts*)
   174     goal: thm,                            (*subgoals ==> statement*)
   175     before_qed: Method.text option,
   176     after_qed:
   177       (context * thm list list -> state -> state) *
   178       (context * thm list list -> context -> context)};
   179 
   180 val _ =
   181   ML_system_pp (fn _ => fn _ => fn _: state =>
   182     Pretty.to_polyml (Pretty.str "<Proof.state>"));
   183 
   184 fun make_goal (statement, using, goal, before_qed, after_qed) =
   185   Goal {statement = statement, using = using, goal = goal,
   186     before_qed = before_qed, after_qed = after_qed};
   187 
   188 fun make_node (context, facts, mode, goal) =
   189   Node {context = context, facts = facts, mode = mode, goal = goal};
   190 
   191 fun map_node f (Node {context, facts, mode, goal}) =
   192   make_node (f (context, facts, mode, goal));
   193 
   194 val init_context =
   195   Proof_Context.set_stmt true #>
   196   Proof_Context.map_naming (K Name_Space.local_naming);
   197 
   198 fun init ctxt =
   199   State (Stack.init (make_node (init_context ctxt, NONE, Forward, NONE)));
   200 
   201 fun top (State stack) = Stack.top stack |> (fn Node node => node);
   202 fun map_top f (State stack) = State (Stack.map_top (map_node f) stack);
   203 fun map_all f (State stack) = State (Stack.map_all (map_node f) stack);
   204 
   205 
   206 
   207 (** basic proof state operations **)
   208 
   209 (* block structure *)
   210 
   211 fun open_block (State stack) = State (Stack.push stack);
   212 
   213 fun close_block (State stack) = State (Stack.pop stack)
   214   handle List.Empty => error "Unbalanced block parentheses";
   215 
   216 fun level (State stack) = Stack.level stack;
   217 
   218 fun assert_bottom b state =
   219   let val b' = level state <= 2 in
   220     if b andalso not b' then error "Not at bottom of proof"
   221     else if not b andalso b' then error "Already at bottom of proof"
   222     else state
   223   end;
   224 
   225 
   226 (* context *)
   227 
   228 val context_of = #context o top;
   229 val theory_of = Proof_Context.theory_of o context_of;
   230 
   231 fun map_context f =
   232   map_top (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   233 
   234 fun map_context_result f state =
   235   f (context_of state) ||> (fn ctxt => map_context (K ctxt) state);
   236 
   237 fun map_contexts f = map_all (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   238 
   239 fun propagate_ml_env state = map_contexts
   240   (Context.proof_map (ML_Env.inherit (Context.Proof (context_of state)))) state;
   241 
   242 
   243 (* facts *)
   244 
   245 fun report_improper state =
   246   Context_Position.report (context_of state) (Position.thread_data ()) Markup.improper;
   247 
   248 val get_facts = #facts o top;
   249 
   250 fun the_facts state =
   251   (case get_facts state of
   252     SOME (facts, proper) => (if proper then () else report_improper state; facts)
   253   | NONE => error "No current facts available");
   254 
   255 fun the_fact state =
   256   (case the_facts state of
   257     [thm] => thm
   258   | _ => error "Single theorem expected");
   259 
   260 fun put_facts index facts =
   261   map_top (fn (ctxt, _, mode, goal) => (ctxt, facts, mode, goal)) #>
   262   map_context (Proof_Context.put_thms index (Auto_Bind.thisN, Option.map #1 facts));
   263 
   264 fun set_facts thms = put_facts false (SOME (thms, true));
   265 val reset_facts = put_facts false NONE;
   266 
   267 fun improper_reset_facts state =
   268   (case get_facts state of
   269     SOME (thms, _) => put_facts false (SOME (thms, false)) state
   270   | NONE => state);
   271 
   272 fun these_factss more_facts (named_factss, state) =
   273   (named_factss, state |> set_facts (maps snd named_factss @ more_facts));
   274 
   275 fun export_facts inner outer =
   276   (case get_facts inner of
   277     NONE => reset_facts outer
   278   | SOME (thms, proper) =>
   279       let val thms' = Proof_Context.export (context_of inner) (context_of outer) thms
   280       in put_facts true (SOME (thms', proper)) outer end);
   281 
   282 
   283 (* mode *)
   284 
   285 val get_mode = #mode o top;
   286 fun put_mode mode = map_top (fn (ctxt, facts, _, goal) => (ctxt, facts, mode, goal));
   287 
   288 val mode_name = (fn Forward => "state" | Chain => "chain" | Backward => "prove");
   289 
   290 fun assert_mode pred state =
   291   let val mode = get_mode state in
   292     if pred mode then state
   293     else error ("Illegal application of proof command in " ^ quote (mode_name mode) ^ " mode")
   294   end;
   295 
   296 val assert_forward = assert_mode (fn mode => mode = Forward);
   297 val assert_chain = assert_mode (fn mode => mode = Chain);
   298 val assert_forward_or_chain = assert_mode (fn mode => mode = Forward orelse mode = Chain);
   299 val assert_backward = assert_mode (fn mode => mode = Backward);
   300 val assert_no_chain = assert_mode (fn mode => mode <> Chain);
   301 
   302 val enter_forward = put_mode Forward;
   303 val enter_chain = put_mode Chain;
   304 val enter_backward = put_mode Backward;
   305 
   306 
   307 (* current goal *)
   308 
   309 fun current_goal state =
   310   (case top state of
   311     {context = ctxt, goal = SOME (Goal goal), ...} => (ctxt, goal)
   312   | _ => error "No current goal");
   313 
   314 fun assert_current_goal g state =
   315   let val g' = can current_goal state in
   316     if g andalso not g' then error "No goal in this block"
   317     else if not g andalso g' then error "Goal present in this block"
   318     else state
   319   end;
   320 
   321 fun put_goal goal = map_top (fn (ctxt, facts, mode, _) => (ctxt, facts, mode, goal));
   322 
   323 val set_goal = put_goal o SOME;
   324 val reset_goal = put_goal NONE;
   325 
   326 val before_qed = #before_qed o #2 o current_goal;
   327 
   328 
   329 (* bottom goal *)
   330 
   331 fun has_bottom_goal (State stack) =
   332   let
   333     fun bottom [Node {goal = SOME _, ...}, Node {goal = NONE, ...}] = true
   334       | bottom [Node {goal, ...}] = is_some goal
   335       | bottom [] = false
   336       | bottom (_ :: rest) = bottom rest;
   337   in bottom (op :: (Stack.dest stack)) end;
   338 
   339 
   340 (* nested goal *)
   341 
   342 fun map_goal f (State stack) =
   343   (case Stack.dest stack of
   344     (Node {context = ctxt, facts, mode, goal = SOME goal}, node :: nodes) =>
   345       let
   346         val Goal {statement, using, goal, before_qed, after_qed} = goal;
   347         val (ctxt', statement', using', goal', before_qed', after_qed') =
   348           f (ctxt, statement, using, goal, before_qed, after_qed);
   349         val goal' = make_goal (statement', using', goal', before_qed', after_qed');
   350       in State (Stack.make (make_node (ctxt', facts, mode, SOME goal')) (node :: nodes)) end
   351   | (top_node, node :: nodes) =>
   352       let
   353         val State stack' = map_goal f (State (Stack.make node nodes));
   354         val (node', nodes') = Stack.dest stack';
   355       in State (Stack.make top_node (node' :: nodes')) end
   356   | _ => State stack);
   357 
   358 fun provide_goal goal =
   359   map_goal (fn (ctxt, statement, using, _, before_qed, after_qed) =>
   360     (ctxt, statement, using, goal, before_qed, after_qed));
   361 
   362 fun using_facts using =
   363   map_goal (fn (ctxt, statement, _, goal, before_qed, after_qed) =>
   364     (ctxt, statement, using, goal, before_qed, after_qed));
   365 
   366 fun find_goal state =
   367   (case try current_goal state of
   368     SOME ctxt_goal => ctxt_goal
   369   | NONE => find_goal (close_block state handle ERROR _ => error "No proof goal"));
   370 
   371 fun get_goal state =
   372   let val (ctxt, {using, goal, ...}) = find_goal state
   373   in (ctxt, (using, goal)) end;
   374 
   375 
   376 
   377 (** pretty_state **)
   378 
   379 local
   380 
   381 fun pretty_facts _ _ NONE = []
   382   | pretty_facts ctxt s (SOME ths) = [Proof_Display.pretty_goal_facts ctxt s ths];
   383 
   384 fun pretty_sep prts [] = prts
   385   | pretty_sep [] prts = prts
   386   | pretty_sep prts1 prts2 = prts1 @ [Pretty.str ""] @ prts2;
   387 
   388 in
   389 
   390 fun pretty_state state =
   391   let
   392     val {context = ctxt, facts, mode, goal = _} = top state;
   393     val verbose = Config.get ctxt Proof_Context.verbose;
   394 
   395     fun prt_goal (SOME (_, {statement = _, using, goal, before_qed = _, after_qed = _})) =
   396           pretty_sep
   397             (pretty_facts ctxt "using"
   398               (if mode <> Backward orelse null using then NONE else SOME using))
   399             ([Proof_Display.pretty_goal_header goal] @ Goal_Display.pretty_goals ctxt goal)
   400       | prt_goal NONE = [];
   401 
   402     val prt_ctxt =
   403       if verbose orelse mode = Forward then Proof_Context.pretty_context ctxt
   404       else if mode = Backward then Proof_Context.pretty_ctxt ctxt
   405       else [];
   406 
   407     val position_markup = Position.markup (Position.thread_data ()) Markup.position;
   408   in
   409     [Pretty.block
   410       [Pretty.mark_str (position_markup, "proof"), Pretty.str (" (" ^ mode_name mode ^ ")")]] @
   411     (if null prt_ctxt then [] else prt_ctxt @ [Pretty.str ""]) @
   412     (if verbose orelse mode = Forward then
   413        pretty_sep (pretty_facts ctxt "" (Option.map #1 facts)) (prt_goal (try find_goal state))
   414      else if mode = Chain then pretty_facts ctxt "picking" (Option.map #1 facts)
   415      else prt_goal (try find_goal state))
   416   end;
   417 
   418 end;
   419 
   420 
   421 
   422 (** proof steps **)
   423 
   424 (* refine via method *)
   425 
   426 local
   427 
   428 fun goalN i = "goal" ^ string_of_int i;
   429 fun goals st = map goalN (1 upto Thm.nprems_of st);
   430 
   431 fun no_goal_cases st = map (rpair NONE) (goals st);
   432 
   433 fun goal_cases ctxt st =
   434   Rule_Cases.make_common ctxt (Thm.prop_of st) (map (rpair [] o rpair []) (goals st));
   435 
   436 fun apply_method text ctxt state =
   437   find_goal state |> (fn (goal_ctxt, {statement, using, goal, before_qed, after_qed}) =>
   438     Method.evaluate text ctxt using (goal_ctxt, goal)
   439     |> Seq.map_result (fn (goal_ctxt', goal') =>
   440       let
   441         val goal_ctxt'' = goal_ctxt'
   442           |> Proof_Context.update_cases_legacy (no_goal_cases goal @ goal_cases ctxt goal');
   443         val state' = state
   444           |> map_goal (K (goal_ctxt'', statement, using, goal', before_qed, after_qed));
   445       in state' end));
   446 
   447 in
   448 
   449 fun refine text state = apply_method text (context_of state) state;
   450 fun refine_end text state = apply_method text (#1 (find_goal state)) state;
   451 
   452 fun refine_singleton text = refine text #> Seq.the_result "";
   453 
   454 fun refine_insert ths =
   455   refine_singleton (Method.Basic (K (Method.insert ths)));
   456 
   457 fun refine_primitive r =
   458   refine_singleton (Method.Basic (fn ctxt => fn _ => Method.CONTEXT_TACTIC (PRIMITIVE (r ctxt))));
   459 
   460 end;
   461 
   462 
   463 (* refine via sub-proof *)
   464 
   465 local
   466 
   467 fun finish_tac _ 0 = K all_tac
   468   | finish_tac ctxt n =
   469       Goal.norm_hhf_tac ctxt THEN'
   470       SUBGOAL (fn (goal, i) =>
   471         if can Logic.unprotect (Logic.strip_assums_concl goal) then
   472           eresolve_tac ctxt [Drule.protectI] i THEN finish_tac ctxt (n - 1) i
   473         else finish_tac ctxt (n - 1) (i + 1));
   474 
   475 fun goal_tac ctxt rule =
   476   Goal.norm_hhf_tac ctxt THEN'
   477   resolve_tac ctxt [rule] THEN'
   478   finish_tac ctxt (Thm.nprems_of rule);
   479 
   480 fun FINDGOAL tac st =
   481   let fun find i n = if i > n then Seq.fail else Seq.APPEND (tac i, find (i + 1) n)
   482   in find 1 (Thm.nprems_of st) st end;
   483 
   484 fun protect_prem i th =
   485   Thm.bicompose NONE {flatten = false, match = false, incremented = true}
   486     (false, Drule.incr_indexes th Drule.protectD, 1) i th
   487   |> Seq.hd;
   488 
   489 fun protect_prems th =
   490   fold_rev protect_prem (1 upto Thm.nprems_of th) th;
   491 
   492 in
   493 
   494 fun refine_goals print_rule result_ctxt result state =
   495   let
   496     val (goal_ctxt, (_, goal)) = get_goal state;
   497     fun refine rule st =
   498       (print_rule goal_ctxt rule; FINDGOAL (goal_tac goal_ctxt rule) st);
   499   in
   500     result
   501     |> map (Raw_Simplifier.norm_hhf result_ctxt #> protect_prems)
   502     |> Proof_Context.goal_export result_ctxt goal_ctxt
   503     |> (fn rules => Seq.lift provide_goal (EVERY (map refine rules) goal) state)
   504   end;
   505 
   506 end;
   507 
   508 
   509 (* conclude goal *)
   510 
   511 fun conclude_goal ctxt goal propss =
   512   let
   513     val thy = Proof_Context.theory_of ctxt;
   514 
   515     val _ =
   516       Context.subthy_id (Thm.theory_id goal, Context.theory_id thy) orelse
   517         error "Bad background theory of goal state";
   518     val _ = Thm.no_prems goal orelse error (Proof_Display.string_of_goal ctxt goal);
   519 
   520     fun err_lost () = error ("Lost goal structure:\n" ^ Thm.string_of_thm ctxt goal);
   521 
   522     val th =
   523       (Goal.conclude (Thm.close_derivation goal) handle THM _ => err_lost ())
   524       |> Drule.flexflex_unique (SOME ctxt)
   525       |> Thm.check_shyps ctxt
   526       |> Thm.check_hyps (Context.Proof ctxt);
   527 
   528     val goal_propss = filter_out null propss;
   529     val results =
   530       Conjunction.elim_balanced (length goal_propss) th
   531       |> map2 Conjunction.elim_balanced (map length goal_propss)
   532       handle THM _ => err_lost ();
   533     val _ =
   534       Unify.matches_list (Context.Proof ctxt) (flat goal_propss) (map Thm.prop_of (flat results))
   535         orelse error ("Proved a different theorem:\n" ^ Thm.string_of_thm ctxt th);
   536 
   537     fun recover_result ([] :: pss) thss = [] :: recover_result pss thss
   538       | recover_result (_ :: pss) (ths :: thss) = ths :: recover_result pss thss
   539       | recover_result [] [] = []
   540       | recover_result _ _ = err_lost ();
   541   in recover_result propss results end;
   542 
   543 val finished_goal_error = "Failed to finish proof";
   544 
   545 fun finished_goal pos state =
   546   let val (ctxt, (_, goal)) = get_goal state in
   547     if Thm.no_prems goal then Seq.Result state
   548     else
   549       Seq.Error (fn () =>
   550         finished_goal_error ^ Position.here pos ^ ":\n" ^
   551           Proof_Display.string_of_goal ctxt goal)
   552   end;
   553 
   554 
   555 (* goal views -- corresponding to methods *)
   556 
   557 fun raw_goal state =
   558   let val (ctxt, (using, goal)) = get_goal state
   559   in {context = ctxt, facts = using, goal = goal} end;
   560 
   561 val goal = raw_goal o refine_insert [];
   562 
   563 fun simple_goal state =
   564   let
   565     val (_, (using, _)) = get_goal state;
   566     val (ctxt, (_, goal)) = get_goal (refine_insert using state);
   567   in {context = ctxt, goal = goal} end;
   568 
   569 fun method_error kind pos state =
   570   Seq.single (Proof_Display.method_error kind pos (raw_goal state));
   571 
   572 
   573 
   574 (*** structured proof commands ***)
   575 
   576 (** context elements **)
   577 
   578 (* let bindings *)
   579 
   580 local
   581 
   582 fun gen_bind bind args state =
   583   state
   584   |> assert_forward
   585   |> map_context (bind true args #> snd)
   586   |> reset_facts;
   587 
   588 in
   589 
   590 val let_bind = gen_bind Proof_Context.match_bind;
   591 val let_bind_cmd = gen_bind Proof_Context.match_bind_cmd;
   592 
   593 end;
   594 
   595 
   596 (* concrete syntax *)
   597 
   598 local
   599 
   600 fun read_arg (c, mx) ctxt =
   601   (case Proof_Context.read_const {proper = false, strict = false} ctxt c of
   602     Free (x, _) =>
   603       let
   604         val ctxt' =
   605           ctxt |> is_none (Variable.default_type ctxt x) ?
   606             Variable.declare_constraints (Free (x, Mixfix.default_constraint mx));
   607         val t = Free (#1 (Proof_Context.inferred_param x ctxt'));
   608       in ((t, mx), ctxt') end
   609   | t => ((t, mx), ctxt));
   610 
   611 fun gen_write prep_arg mode args =
   612   assert_forward
   613   #> map_context (fold_map prep_arg args #-> Proof_Context.notation true mode)
   614   #> reset_facts;
   615 
   616 in
   617 
   618 val write = gen_write pair;
   619 val write_cmd = gen_write read_arg;
   620 
   621 end;
   622 
   623 
   624 (* fix *)
   625 
   626 local
   627 
   628 fun gen_fix add_fixes raw_fixes =
   629   assert_forward
   630   #> map_context (snd o add_fixes raw_fixes)
   631   #> reset_facts;
   632 
   633 in
   634 
   635 val fix = gen_fix Proof_Context.add_fixes;
   636 val fix_cmd = gen_fix Proof_Context.add_fixes_cmd;
   637 
   638 end;
   639 
   640 
   641 (* assume *)
   642 
   643 local
   644 
   645 fun gen_assume prep_statement prep_att export raw_fixes raw_prems raw_concls state =
   646   let
   647     val ctxt = context_of state;
   648 
   649     val bindings = map (apsnd (map (prep_att ctxt)) o fst) raw_concls;
   650     val ((params, prems_propss, concl_propss, result_binds), _) =
   651       prep_statement raw_fixes raw_prems (map snd raw_concls) ctxt;
   652     val propss = (map o map) (Logic.close_prop params (flat prems_propss)) concl_propss;
   653   in
   654     state
   655     |> assert_forward
   656     |> map_context_result (fn ctxt =>
   657       ctxt
   658       |> (fold o fold) Variable.declare_term propss
   659       |> fold Variable.maybe_bind_term result_binds
   660       |> fold_burrow (Assumption.add_assms export o map (Thm.cterm_of ctxt)) propss
   661       |-> (fn premss =>
   662         Proof_Context.note_thmss "" (bindings ~~ (map o map) (fn th => ([th], [])) premss)))
   663     |> these_factss [] |> #2
   664   end;
   665 
   666 in
   667 
   668 val assm = gen_assume Proof_Context.cert_statement (K I);
   669 val assm_cmd = gen_assume Proof_Context.read_statement Attrib.attribute_cmd;
   670 
   671 val assume = assm Assumption.assume_export;
   672 val assume_cmd = assm_cmd Assumption.assume_export;
   673 
   674 val presume = assm Assumption.presume_export;
   675 val presume_cmd = assm_cmd Assumption.presume_export;
   676 
   677 end;
   678 
   679 
   680 
   681 (** facts **)
   682 
   683 (* chain *)
   684 
   685 val chain =
   686   assert_forward
   687   #> (fn state => set_facts (Method.clean_facts (the_facts state)) state)
   688   #> enter_chain;
   689 
   690 fun chain_facts facts =
   691   set_facts facts
   692   #> chain;
   693 
   694 
   695 (* note etc. *)
   696 
   697 fun empty_bindings args = map (pair Binding.empty_atts) args;
   698 
   699 local
   700 
   701 fun gen_thmss more_facts opt_chain opt_result prep_atts prep_fact args state =
   702   state
   703   |> assert_forward
   704   |> map_context_result (fn ctxt => ctxt |> Proof_Context.note_thmss ""
   705     (Attrib.map_facts_refs (map (prep_atts ctxt)) (prep_fact ctxt) args))
   706   |> these_factss (more_facts state)
   707   ||> opt_chain
   708   |> opt_result;
   709 
   710 in
   711 
   712 val note_thmss = gen_thmss (K []) I #2 (K I) (K I);
   713 val note_thmss_cmd = gen_thmss (K []) I #2 Attrib.attribute_cmd Proof_Context.get_fact;
   714 
   715 val from_thmss = gen_thmss (K []) chain #2 (K I) (K I) o empty_bindings;
   716 val from_thmss_cmd =
   717   gen_thmss (K []) chain #2 Attrib.attribute_cmd Proof_Context.get_fact o empty_bindings;
   718 
   719 val with_thmss = gen_thmss the_facts chain #2 (K I) (K I) o empty_bindings;
   720 val with_thmss_cmd =
   721   gen_thmss the_facts chain #2 Attrib.attribute_cmd Proof_Context.get_fact o empty_bindings;
   722 
   723 val local_results = gen_thmss (K []) I I (K I) (K I) o map (apsnd Thm.simple_fact);
   724 
   725 end;
   726 
   727 
   728 (* facts during goal refinement *)
   729 
   730 local
   731 
   732 fun gen_supply prep_att prep_fact args state =
   733   state
   734   |> assert_backward
   735   |> map_context (fn ctxt => ctxt |> Proof_Context.note_thmss ""
   736        (Attrib.map_facts_refs (map (prep_att ctxt)) (prep_fact ctxt) args) |> snd);
   737 
   738 in
   739 
   740 val supply = gen_supply (K I) (K I);
   741 val supply_cmd = gen_supply Attrib.attribute_cmd Proof_Context.get_fact;
   742 
   743 end;
   744 
   745 
   746 (* using/unfolding *)
   747 
   748 local
   749 
   750 fun gen_using f g prep_att prep_fact args state =
   751   state
   752   |> assert_backward
   753   |> map_context_result
   754     (fn ctxt => ctxt |> Proof_Context.note_thmss ""
   755       (Attrib.map_facts_refs (map (prep_att ctxt)) (prep_fact ctxt) (empty_bindings args)))
   756   |> (fn (named_facts, state') =>
   757     state' |> map_goal (fn (goal_ctxt, statement, using, goal, before_qed, after_qed) =>
   758       let
   759         val ctxt = context_of state';
   760         val ths = maps snd named_facts;
   761       in (goal_ctxt, statement, f ctxt ths using, g ctxt ths goal, before_qed, after_qed) end));
   762 
   763 fun append_using _ ths using = using @ filter_out Thm.is_dummy ths;
   764 fun unfold_using ctxt ths = map (Local_Defs.unfold ctxt ths);
   765 val unfold_goals = Local_Defs.unfold_goals;
   766 
   767 in
   768 
   769 val using = gen_using append_using (K (K I)) (K I) (K I);
   770 val using_cmd = gen_using append_using (K (K I)) Attrib.attribute_cmd Proof_Context.get_fact;
   771 val unfolding = gen_using unfold_using unfold_goals (K I) (K I);
   772 val unfolding_cmd = gen_using unfold_using unfold_goals Attrib.attribute_cmd Proof_Context.get_fact;
   773 
   774 end;
   775 
   776 
   777 (* case *)
   778 
   779 local
   780 
   781 fun gen_case internal prep_att ((raw_binding, raw_atts), ((name, pos), xs)) state =
   782   let
   783     val ctxt = context_of state;
   784 
   785     val binding = if Binding.is_empty raw_binding then Binding.make (name, pos) else raw_binding;
   786     val atts = map (prep_att ctxt) raw_atts;
   787 
   788     val (asms, state') = state |> map_context_result (fn ctxt =>
   789       ctxt |> Proof_Context.apply_case (Proof_Context.check_case ctxt internal (name, pos) xs));
   790     val assumptions =
   791       asms |> map (fn (a, ts) => ((Binding.qualify_name true binding a, []), map (rpair []) ts));
   792   in
   793     state'
   794     |> assume [] [] assumptions
   795     |> map_context (fold Variable.unbind_term Auto_Bind.no_facts)
   796     |> `the_facts |-> (fn thms => note_thmss [((binding, atts), [(thms, [])])])
   797   end;
   798 
   799 in
   800 
   801 val case_ = gen_case true (K I);
   802 val case_cmd = gen_case false Attrib.attribute_cmd;
   803 
   804 end;
   805 
   806 
   807 (* define *)
   808 
   809 local
   810 
   811 fun gen_define prep_stmt prep_att raw_decls raw_fixes raw_defs state =
   812   let
   813     val _ = assert_forward state;
   814     val ctxt = context_of state;
   815 
   816     (*vars*)
   817     val ((vars, propss, _, binds'), vars_ctxt) =
   818       prep_stmt (raw_decls @ raw_fixes) (map snd raw_defs) ctxt;
   819     val (decls, fixes) = chop (length raw_decls) vars;
   820     val show_term = Syntax.string_of_term vars_ctxt;
   821 
   822     (*defs*)
   823     fun match_defs (((b, _, mx), (_, Free (x, T))) :: more_decls) ((((y, U), t), _) :: more_defs) =
   824           if x = y then ((b, mx), (Binding.empty_atts, t)) :: match_defs more_decls more_defs
   825           else
   826             error ("Mismatch of declaration " ^ show_term (Free (x, T)) ^ " wrt. definition " ^
   827               show_term (Free (y, U)))
   828       | match_defs [] [] = []
   829       | match_defs more_decls more_defs =
   830           error ("Mismatch of declarations " ^ commas (map (show_term o #2 o #2) more_decls) ^
   831             (if null more_decls then "" else " ") ^
   832             "wrt. definitions " ^ commas (map (show_term o Free o #1 o #1) more_defs));
   833 
   834     val derived_def = Local_Defs.derived_def ctxt (K  []) {conditional = false};
   835     val defs1 = map (derived_def o Logic.close_prop (map #2 fixes) []) (flat propss);
   836     val defs2 = match_defs decls defs1;
   837     val (defs3, defs_ctxt) = Local_Defs.define defs2 ctxt;
   838 
   839     (*notes*)
   840     val def_thmss =
   841       map (fn (((_, prove), ((b, _), _)), (_, (_, th))) => (b, prove defs_ctxt th))
   842         (defs1 ~~ defs2 ~~ defs3)
   843       |> unflat (map snd raw_defs);
   844     val notes =
   845       map2 (fn ((a, raw_atts), _) => fn def_thms =>
   846         ((Thm.def_binding_optional (Binding.conglomerate (map #1 def_thms)) a,
   847           map (prep_att defs_ctxt) raw_atts), map (fn (_, th) => ([th], [])) def_thms))
   848         raw_defs def_thmss;
   849   in
   850     state
   851     |> map_context (K defs_ctxt #> fold Variable.bind_term binds')
   852     |> note_thmss notes
   853   end;
   854 
   855 in
   856 
   857 val define = gen_define Proof_Context.cert_stmt (K I);
   858 val define_cmd = gen_define Proof_Context.read_stmt Attrib.attribute_cmd;
   859 
   860 end;
   861 
   862 
   863 
   864 (** proof structure **)
   865 
   866 (* blocks *)
   867 
   868 val begin_block =
   869   assert_forward
   870   #> open_block
   871   #> reset_goal
   872   #> open_block;
   873 
   874 val next_block =
   875   assert_forward
   876   #> close_block
   877   #> open_block
   878   #> reset_goal
   879   #> reset_facts;
   880 
   881 fun end_block state =
   882   state
   883   |> assert_forward
   884   |> assert_bottom false
   885   |> close_block
   886   |> assert_current_goal false
   887   |> close_block
   888   |> export_facts state;
   889 
   890 
   891 (* global notepad *)
   892 
   893 val begin_notepad =
   894   init
   895   #> open_block
   896   #> map_context (Variable.set_body true)
   897   #> open_block;
   898 
   899 val end_notepad =
   900   assert_forward
   901   #> assert_bottom true
   902   #> close_block
   903   #> assert_current_goal false
   904   #> close_block
   905   #> context_of;
   906 
   907 
   908 (* sub-proofs *)
   909 
   910 fun proof opt_text =
   911   Seq.APPEND
   912     (assert_backward
   913       #> refine (the_default Method.standard_text (Method.text opt_text))
   914       #> Seq.map_result
   915         (using_facts []
   916           #> enter_forward
   917           #> open_block
   918           #> reset_goal),
   919      method_error "initial" (Method.position opt_text));
   920 
   921 fun end_proof bot (prev_pos, (opt_text, immed)) =
   922   let
   923     val (finish_text, terminal_pos, finished_pos) =
   924       (case opt_text of
   925         NONE => (Method.finish_text (NONE, immed), Position.none, prev_pos)
   926       | SOME (text, (pos, end_pos)) => (Method.finish_text (SOME text, immed), pos, end_pos));
   927   in
   928     Seq.APPEND (fn state =>
   929       state
   930       |> assert_forward
   931       |> assert_bottom bot
   932       |> close_block
   933       |> assert_current_goal true
   934       |> using_facts []
   935       |> `before_qed |-> (refine o the_default Method.succeed_text)
   936       |> Seq.maps_results (refine finish_text),
   937       method_error "terminal" terminal_pos)
   938     #> Seq.maps_results (Seq.single o finished_goal finished_pos)
   939   end;
   940 
   941 fun check_result msg sq =
   942   (case Seq.pull sq of
   943     NONE => error msg
   944   | SOME (s, _) => s);
   945 
   946 
   947 (* unstructured refinement *)
   948 
   949 fun defer i =
   950   assert_no_chain #>
   951   refine_singleton (Method.Basic (fn _ => METHOD (fn _ => ASSERT_SUBGOAL defer_tac i)));
   952 
   953 fun prefer i =
   954   assert_no_chain #>
   955   refine_singleton (Method.Basic (fn _ => METHOD (fn _ => ASSERT_SUBGOAL prefer_tac i)));
   956 
   957 fun apply (text, (pos, _)) =
   958   Seq.APPEND (assert_backward #> refine text #> Seq.map_result (using_facts []),
   959     method_error "" pos);
   960 
   961 fun apply_end (text, (pos, _)) =
   962   Seq.APPEND (assert_forward #> refine_end text, method_error "" pos);
   963 
   964 
   965 
   966 (** goals **)
   967 
   968 (* generic goals *)
   969 
   970 local
   971 
   972 val is_var =
   973   can (dest_TVar o Logic.dest_type o Logic.dest_term) orf
   974   can (dest_Var o Logic.dest_term);
   975 
   976 fun implicit_vars props =
   977   let
   978     val (var_props, _) = take_prefix is_var props;
   979     val explicit_vars = fold Term.add_vars var_props [];
   980     val vars = filter_out (member (op =) explicit_vars) (fold Term.add_vars props []);
   981   in map (Logic.mk_term o Var) vars end;
   982 
   983 fun refine_terms n =
   984   refine_singleton (Method.Basic (fn ctxt => Method.CONTEXT_TACTIC o
   985     K (HEADGOAL (PRECISE_CONJUNCTS n
   986       (HEADGOAL (CONJUNCTS (ALLGOALS (resolve_tac ctxt [Drule.termI]))))))));
   987 
   988 in
   989 
   990 fun generic_goal kind before_qed after_qed goal_ctxt goal_propss result_binds state =
   991   let
   992     val chaining = can assert_chain state;
   993     val pos = Position.thread_data ();
   994 
   995     val goal_props = flat goal_propss;
   996     val vars = implicit_vars goal_props;
   997     val propss' = vars :: goal_propss;
   998     val goal_propss = filter_out null propss';
   999 
  1000     val goal =
  1001       Logic.mk_conjunction_balanced (map Logic.mk_conjunction_balanced goal_propss)
  1002       |> Thm.cterm_of goal_ctxt
  1003       |> Thm.weaken_sorts' goal_ctxt;
  1004     val statement = ((kind, pos), propss', Thm.term_of goal);
  1005 
  1006     val after_qed' = after_qed |>> (fn after_local => fn results =>
  1007       map_context (fold Variable.maybe_bind_term result_binds) #> after_local results);
  1008   in
  1009     state
  1010     |> assert_forward_or_chain
  1011     |> enter_forward
  1012     |> open_block
  1013     |> enter_backward
  1014     |> map_context
  1015       (K goal_ctxt
  1016         #> init_context
  1017         #> Variable.set_body true
  1018         #> Proof_Context.auto_bind_goal goal_props)
  1019     |> set_goal (make_goal (statement, [], Goal.init goal, before_qed, after_qed'))
  1020     |> chaining ? (`the_facts #-> using_facts)
  1021     |> reset_facts
  1022     |> not (null vars) ? refine_terms (length goal_propss)
  1023     |> null goal_props ? refine_singleton (Method.Basic Method.assumption)
  1024   end;
  1025 
  1026 fun generic_qed state =
  1027   let
  1028     val (goal_ctxt, {statement = (_, propss, _), goal, after_qed, ...}) =
  1029       current_goal state;
  1030     val results = tl (conclude_goal goal_ctxt goal propss);
  1031   in state |> close_block |> pair (after_qed, (goal_ctxt, results)) end;
  1032 
  1033 end;
  1034 
  1035 
  1036 (* local goals *)
  1037 
  1038 fun local_goal print_results prep_statement prep_att strict_asm
  1039     kind before_qed after_qed raw_fixes raw_assumes raw_shows state =
  1040   let
  1041     val ctxt = context_of state;
  1042 
  1043     val add_assumes =
  1044       Assumption.add_assms
  1045         (if strict_asm then Assumption.assume_export else Assumption.presume_export);
  1046 
  1047     (*params*)
  1048     val ((params, assumes_propss, shows_propss, result_binds), params_ctxt) = ctxt
  1049       |> prep_statement raw_fixes (map snd raw_assumes) (map snd raw_shows);
  1050 
  1051     (*prems*)
  1052     val (assumes_bindings, shows_bindings) =
  1053       apply2 (map (apsnd (map (prep_att ctxt)) o fst)) (raw_assumes, raw_shows);
  1054     val (that_fact, goal_ctxt) = params_ctxt
  1055       |> fold_burrow add_assumes ((map o map) (Thm.cterm_of params_ctxt) assumes_propss)
  1056       |> (fn (premss, ctxt') =>
  1057           let
  1058             val prems = Assumption.local_prems_of ctxt' ctxt;
  1059             val ctxt'' =
  1060               ctxt'
  1061               |> not (null assumes_propss) ?
  1062                 (snd o Proof_Context.note_thmss ""
  1063                   [((Binding.name Auto_Bind.thatN, []), [(prems, [])])])
  1064               |> (snd o Proof_Context.note_thmss ""
  1065                   (assumes_bindings ~~ map (map (fn th => ([th], []))) premss))
  1066           in (prems, ctxt'') end);
  1067 
  1068     (*result*)
  1069     val results_bindings = map (apfst Binding.default_pos) shows_bindings;
  1070     fun after_qed' (result_ctxt, results) state' =
  1071       let
  1072         val ctxt' = context_of state';
  1073         val export0 =
  1074           Assumption.export false result_ctxt ctxt' #>
  1075           fold_rev (fn (x, v) => Thm.forall_intr_name (x, Thm.cterm_of params_ctxt v)) params #>
  1076           Raw_Simplifier.norm_hhf_protect ctxt';
  1077         val export = map export0 #> Variable.export result_ctxt ctxt';
  1078       in
  1079         state'
  1080         |> local_results (results_bindings ~~ burrow export results)
  1081         |-> (fn res => tap (fn st => print_results (context_of st) ((kind, ""), res) : unit))
  1082         |> after_qed (result_ctxt, results)
  1083       end;
  1084   in
  1085     state
  1086     |> generic_goal kind before_qed (after_qed', K I) goal_ctxt shows_propss result_binds
  1087     |> pair that_fact
  1088   end;
  1089 
  1090 fun local_qeds arg =
  1091   end_proof false arg
  1092   #> Seq.map_result (generic_qed #-> (fn ((after_qed, _), results) => after_qed results));
  1093 
  1094 fun local_qed arg =
  1095   local_qeds (Position.none, arg) #> Seq.the_result finished_goal_error;
  1096 
  1097 
  1098 (* global goals *)
  1099 
  1100 fun global_goal prep_propp before_qed after_qed propp ctxt =
  1101   let
  1102     val (propss, binds) =
  1103       prep_propp (Proof_Context.set_mode Proof_Context.mode_schematic ctxt) propp;
  1104     val goal_ctxt = ctxt
  1105       |> (fold o fold) Variable.auto_fixes propss
  1106       |> fold Variable.bind_term binds;
  1107     fun after_qed' (result_ctxt, results) ctxt' = ctxt'
  1108       |> Proof_Context.restore_naming ctxt
  1109       |> after_qed (burrow (Proof_Context.export result_ctxt ctxt') results);
  1110   in
  1111     ctxt
  1112     |> init
  1113     |> generic_goal "" before_qed (K I, after_qed') goal_ctxt propss []
  1114   end;
  1115 
  1116 val theorem = global_goal Proof_Context.cert_propp;
  1117 val theorem_cmd = global_goal Proof_Context.read_propp;
  1118 
  1119 fun global_qeds arg =
  1120   end_proof true arg
  1121   #> Seq.map_result (generic_qed #> (fn (((_, after_qed), results), state) =>
  1122     after_qed results (context_of state)));
  1123 
  1124 fun global_qed arg =
  1125   global_qeds (Position.none, arg) #> Seq.the_result finished_goal_error;
  1126 
  1127 
  1128 (* relevant proof states *)
  1129 
  1130 fun schematic_goal state =
  1131   let val (_, {statement = (_, _, prop), ...}) = find_goal state
  1132   in Goal.is_schematic prop end;
  1133 
  1134 fun is_relevant state =
  1135   (case try find_goal state of
  1136     NONE => true
  1137   | SOME (_, {statement = (_, _, prop), goal, ...}) =>
  1138       Goal.is_schematic prop orelse not (Logic.protect prop aconv Thm.concl_of goal));
  1139 
  1140 
  1141 (* terminal proof steps *)
  1142 
  1143 local
  1144 
  1145 fun terminal_proof qeds initial terminal state =
  1146   let
  1147     val ctxt = context_of state;
  1148     val check_closure = Method.check_text ctxt #> Method.map_source (Method.method_closure ctxt);
  1149     val initial' = apfst check_closure initial;
  1150     val terminal' = (apfst o Option.map o apfst) check_closure terminal;
  1151   in
  1152     if Goal.skip_proofs_enabled () andalso not (is_relevant state) then
  1153       state
  1154       |> proof (SOME (Method.sorry_text false, #2 initial'))
  1155       |> Seq.maps_results (qeds (#2 (#2 initial), (NONE, #2 terminal)))
  1156     else
  1157       state
  1158       |> proof (SOME initial')
  1159       |> Seq.maps_results (qeds (#2 (#2 initial), terminal'))
  1160   end |> Seq.the_result "";
  1161 
  1162 in
  1163 
  1164 fun local_terminal_proof (text, opt_text) = terminal_proof local_qeds text (opt_text, true);
  1165 val local_default_proof = local_terminal_proof ((Method.standard_text, Position.no_range), NONE);
  1166 val local_immediate_proof = local_terminal_proof ((Method.this_text, Position.no_range), NONE);
  1167 val local_done_proof = terminal_proof local_qeds (Method.done_text, Position.no_range) (NONE, false);
  1168 
  1169 fun global_terminal_proof (text, opt_text) = terminal_proof global_qeds text (opt_text, true);
  1170 val global_default_proof = global_terminal_proof ((Method.standard_text, Position.no_range), NONE);
  1171 val global_immediate_proof = global_terminal_proof ((Method.this_text, Position.no_range), NONE);
  1172 val global_done_proof = terminal_proof global_qeds (Method.done_text, Position.no_range) (NONE, false);
  1173 
  1174 end;
  1175 
  1176 
  1177 (* skip proofs *)
  1178 
  1179 fun local_skip_proof int state =
  1180   local_terminal_proof ((Method.sorry_text int, Position.no_range), NONE) state before
  1181   Skip_Proof.report (context_of state);
  1182 
  1183 fun global_skip_proof int state =
  1184   global_terminal_proof ((Method.sorry_text int, Position.no_range), NONE) state before
  1185   Skip_Proof.report (context_of state);
  1186 
  1187 
  1188 (* common goal statements *)
  1189 
  1190 fun internal_goal print_results mode =
  1191   local_goal print_results
  1192     (fn a => fn b => fn c => Proof_Context.cert_statement a b c o Proof_Context.set_mode mode) (K I);
  1193 
  1194 local
  1195 
  1196 fun gen_have prep_statement prep_att strict_asm before_qed after_qed fixes assumes shows int =
  1197   local_goal (Proof_Display.print_results int (Position.thread_data ()))
  1198     prep_statement prep_att strict_asm "have" before_qed after_qed fixes assumes shows;
  1199 
  1200 fun gen_show prep_statement prep_att strict_asm before_qed after_qed fixes assumes shows int state =
  1201   let
  1202     val testing = Unsynchronized.ref false;
  1203     val rule = Unsynchronized.ref (NONE: thm option);
  1204     fun fail_msg ctxt =
  1205       "Local statement fails to refine any pending goal" ::
  1206       (case ! rule of NONE => [] | SOME th => [Proof_Display.string_of_rule ctxt "Failed" th])
  1207       |> cat_lines;
  1208 
  1209     val pos = Position.thread_data ();
  1210     fun print_results ctxt res =
  1211       if ! testing then ()
  1212       else Proof_Display.print_results int pos ctxt res;
  1213     fun print_rule ctxt th =
  1214       if ! testing then rule := SOME th
  1215       else if int then
  1216         Proof_Display.string_of_rule ctxt "Successful" th
  1217         |> Markup.markup Markup.text_fold
  1218         |> Output.state
  1219       else ();
  1220     val test_proof =
  1221       local_skip_proof true
  1222       |> Unsynchronized.setmp testing true
  1223       |> Exn.interruptible_capture;
  1224 
  1225     fun after_qed' (result_ctxt, results) state' = state'
  1226       |> refine_goals print_rule result_ctxt (flat results)
  1227       |> check_result "Failed to refine any pending goal"
  1228       |> after_qed (result_ctxt, results);
  1229   in
  1230     state
  1231     |> local_goal print_results prep_statement prep_att strict_asm
  1232       "show" before_qed after_qed' fixes assumes shows
  1233     ||> int ? (fn goal_state =>
  1234       (case test_proof (map_context (Context_Position.set_visible false) goal_state) of
  1235         Exn.Res _ => goal_state
  1236       | Exn.Exn exn => raise Exn.EXCEPTIONS ([exn, ERROR (fail_msg (context_of goal_state))])))
  1237   end;
  1238 
  1239 in
  1240 
  1241 val have = gen_have Proof_Context.cert_statement (K I);
  1242 val have_cmd = gen_have Proof_Context.read_statement Attrib.attribute_cmd;
  1243 val show = gen_show Proof_Context.cert_statement (K I);
  1244 val show_cmd = gen_show Proof_Context.read_statement Attrib.attribute_cmd;
  1245 
  1246 end;
  1247 
  1248 
  1249 
  1250 (** future proofs **)
  1251 
  1252 (* full proofs *)
  1253 
  1254 local
  1255 
  1256 structure Result = Proof_Data
  1257 (
  1258   type T = thm option;
  1259   fun init _ = NONE;
  1260 );
  1261 
  1262 fun the_result ctxt =
  1263   (case Result.get ctxt of
  1264     NONE => error "No result of forked proof"
  1265   | SOME th => th);
  1266 
  1267 val set_result = Result.put o SOME;
  1268 val reset_result = Result.put NONE;
  1269 
  1270 in
  1271 
  1272 fun future_proof fork_proof state =
  1273   let
  1274     val _ = assert_backward state;
  1275     val (goal_ctxt, goal_info) = find_goal state;
  1276     val {statement as (kind, _, prop), using, goal, before_qed, after_qed} = goal_info;
  1277 
  1278     val _ = is_relevant state andalso error "Cannot fork relevant proof";
  1279 
  1280     val after_qed' =
  1281       (fn (_, [[th]]) => map_context (set_result th),
  1282        fn (_, [[th]]) => set_result th);
  1283     val result_ctxt =
  1284       state
  1285       |> map_context reset_result
  1286       |> map_goal (K (goal_ctxt, (kind, [[], [prop]], prop), using, goal, before_qed, after_qed'))
  1287       |> fork_proof;
  1288 
  1289     val future_thm = Future.map (the_result o snd) result_ctxt;
  1290     val finished_goal = Goal.protect 0 (Goal.future_result goal_ctxt future_thm prop);
  1291     val state' =
  1292       state
  1293       |> map_goal (K (goal_ctxt, statement, using, finished_goal, NONE, after_qed));
  1294   in (Future.map fst result_ctxt, state') end;
  1295 
  1296 end;
  1297 
  1298 
  1299 (* terminal proofs *)  (* FIXME avoid toplevel imitation -- include in PIDE/document *)
  1300 
  1301 local
  1302 
  1303 fun future_terminal_proof proof1 proof2 done state =
  1304   if Goal.future_enabled 3 andalso not (is_relevant state) then
  1305     state |> future_proof (fn state' =>
  1306       let
  1307         val pos = Position.thread_data ();
  1308         val props = Markup.command_timing :: (Markup.nameN, "by") :: Position.properties_of pos;
  1309       in
  1310         Execution.fork {name = "Proof.future_terminal_proof", pos = pos, pri = ~1}
  1311           (fn () => ((), Timing.protocol props proof2 state'))
  1312       end) |> snd |> done
  1313   else proof1 state;
  1314 
  1315 in
  1316 
  1317 fun local_future_terminal_proof meths =
  1318   future_terminal_proof
  1319     (local_terminal_proof meths)
  1320     (local_terminal_proof meths #> context_of) local_done_proof;
  1321 
  1322 fun global_future_terminal_proof meths =
  1323   future_terminal_proof
  1324     (global_terminal_proof meths)
  1325     (global_terminal_proof meths) global_done_proof;
  1326 
  1327 end;
  1328 
  1329 end;