src/HOL/Topological_Spaces.thy
author hoelzl
Tue May 13 11:35:47 2014 +0200 (2014-05-13)
changeset 56949 d1a937cbf858
parent 56524 f4ba736040fa
child 57025 e7fd64f82876
permissions -rw-r--r--
clean up Lebesgue integration
     1 (*  Title:      HOL/Topological_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 header {* Topological Spaces *}
     7 
     8 theory Topological_Spaces
     9 imports Main Conditionally_Complete_Lattices
    10 begin
    11 
    12 ML {*
    13 
    14 structure Continuous_Intros = Named_Thms
    15 (
    16   val name = @{binding continuous_intros}
    17   val description = "Structural introduction rules for continuity"
    18 )
    19 
    20 *}
    21 
    22 setup Continuous_Intros.setup
    23 
    24 subsection {* Topological space *}
    25 
    26 class "open" =
    27   fixes "open" :: "'a set \<Rightarrow> bool"
    28 
    29 class topological_space = "open" +
    30   assumes open_UNIV [simp, intro]: "open UNIV"
    31   assumes open_Int [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<inter> T)"
    32   assumes open_Union [intro]: "\<forall>S\<in>K. open S \<Longrightarrow> open (\<Union> K)"
    33 begin
    34 
    35 definition
    36   closed :: "'a set \<Rightarrow> bool" where
    37   "closed S \<longleftrightarrow> open (- S)"
    38 
    39 lemma open_empty [continuous_intros, intro, simp]: "open {}"
    40   using open_Union [of "{}"] by simp
    41 
    42 lemma open_Un [continuous_intros, intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<union> T)"
    43   using open_Union [of "{S, T}"] by simp
    44 
    45 lemma open_UN [continuous_intros, intro]: "\<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Union>x\<in>A. B x)"
    46   using open_Union [of "B ` A"] by simp
    47 
    48 lemma open_Inter [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. open T \<Longrightarrow> open (\<Inter>S)"
    49   by (induct set: finite) auto
    50 
    51 lemma open_INT [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Inter>x\<in>A. B x)"
    52   using open_Inter [of "B ` A"] by simp
    53 
    54 lemma openI:
    55   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
    56   shows "open S"
    57 proof -
    58   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
    59   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
    60   ultimately show "open S" by simp
    61 qed
    62 
    63 lemma closed_empty [continuous_intros, intro, simp]:  "closed {}"
    64   unfolding closed_def by simp
    65 
    66 lemma closed_Un [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<union> T)"
    67   unfolding closed_def by auto
    68 
    69 lemma closed_UNIV [continuous_intros, intro, simp]: "closed UNIV"
    70   unfolding closed_def by simp
    71 
    72 lemma closed_Int [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<inter> T)"
    73   unfolding closed_def by auto
    74 
    75 lemma closed_INT [continuous_intros, intro]: "\<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Inter>x\<in>A. B x)"
    76   unfolding closed_def by auto
    77 
    78 lemma closed_Inter [continuous_intros, intro]: "\<forall>S\<in>K. closed S \<Longrightarrow> closed (\<Inter> K)"
    79   unfolding closed_def uminus_Inf by auto
    80 
    81 lemma closed_Union [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. closed T \<Longrightarrow> closed (\<Union>S)"
    82   by (induct set: finite) auto
    83 
    84 lemma closed_UN [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Union>x\<in>A. B x)"
    85   using closed_Union [of "B ` A"] by simp
    86 
    87 lemma open_closed: "open S \<longleftrightarrow> closed (- S)"
    88   unfolding closed_def by simp
    89 
    90 lemma closed_open: "closed S \<longleftrightarrow> open (- S)"
    91   unfolding closed_def by simp
    92 
    93 lemma open_Diff [continuous_intros, intro]: "open S \<Longrightarrow> closed T \<Longrightarrow> open (S - T)"
    94   unfolding closed_open Diff_eq by (rule open_Int)
    95 
    96 lemma closed_Diff [continuous_intros, intro]: "closed S \<Longrightarrow> open T \<Longrightarrow> closed (S - T)"
    97   unfolding open_closed Diff_eq by (rule closed_Int)
    98 
    99 lemma open_Compl [continuous_intros, intro]: "closed S \<Longrightarrow> open (- S)"
   100   unfolding closed_open .
   101 
   102 lemma closed_Compl [continuous_intros, intro]: "open S \<Longrightarrow> closed (- S)"
   103   unfolding open_closed .
   104 
   105 end
   106 
   107 subsection{* Hausdorff and other separation properties *}
   108 
   109 class t0_space = topological_space +
   110   assumes t0_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U)"
   111 
   112 class t1_space = topological_space +
   113   assumes t1_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   114 
   115 instance t1_space \<subseteq> t0_space
   116 proof qed (fast dest: t1_space)
   117 
   118 lemma separation_t1:
   119   fixes x y :: "'a::t1_space"
   120   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U)"
   121   using t1_space[of x y] by blast
   122 
   123 lemma closed_singleton:
   124   fixes a :: "'a::t1_space"
   125   shows "closed {a}"
   126 proof -
   127   let ?T = "\<Union>{S. open S \<and> a \<notin> S}"
   128   have "open ?T" by (simp add: open_Union)
   129   also have "?T = - {a}"
   130     by (simp add: set_eq_iff separation_t1, auto)
   131   finally show "closed {a}" unfolding closed_def .
   132 qed
   133 
   134 lemma closed_insert [continuous_intros, simp]:
   135   fixes a :: "'a::t1_space"
   136   assumes "closed S" shows "closed (insert a S)"
   137 proof -
   138   from closed_singleton assms
   139   have "closed ({a} \<union> S)" by (rule closed_Un)
   140   thus "closed (insert a S)" by simp
   141 qed
   142 
   143 lemma finite_imp_closed:
   144   fixes S :: "'a::t1_space set"
   145   shows "finite S \<Longrightarrow> closed S"
   146 by (induct set: finite, simp_all)
   147 
   148 text {* T2 spaces are also known as Hausdorff spaces. *}
   149 
   150 class t2_space = topological_space +
   151   assumes hausdorff: "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   152 
   153 instance t2_space \<subseteq> t1_space
   154 proof qed (fast dest: hausdorff)
   155 
   156 lemma separation_t2:
   157   fixes x y :: "'a::t2_space"
   158   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {})"
   159   using hausdorff[of x y] by blast
   160 
   161 lemma separation_t0:
   162   fixes x y :: "'a::t0_space"
   163   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> ~(x\<in>U \<longleftrightarrow> y\<in>U))"
   164   using t0_space[of x y] by blast
   165 
   166 text {* A perfect space is a topological space with no isolated points. *}
   167 
   168 class perfect_space = topological_space +
   169   assumes not_open_singleton: "\<not> open {x}"
   170 
   171 
   172 subsection {* Generators for toplogies *}
   173 
   174 inductive generate_topology for S where
   175   UNIV: "generate_topology S UNIV"
   176 | Int: "generate_topology S a \<Longrightarrow> generate_topology S b \<Longrightarrow> generate_topology S (a \<inter> b)"
   177 | UN: "(\<And>k. k \<in> K \<Longrightarrow> generate_topology S k) \<Longrightarrow> generate_topology S (\<Union>K)"
   178 | Basis: "s \<in> S \<Longrightarrow> generate_topology S s"
   179 
   180 hide_fact (open) UNIV Int UN Basis 
   181 
   182 lemma generate_topology_Union: 
   183   "(\<And>k. k \<in> I \<Longrightarrow> generate_topology S (K k)) \<Longrightarrow> generate_topology S (\<Union>k\<in>I. K k)"
   184   using generate_topology.UN [of "K ` I"] by auto
   185 
   186 lemma topological_space_generate_topology:
   187   "class.topological_space (generate_topology S)"
   188   by default (auto intro: generate_topology.intros)
   189 
   190 subsection {* Order topologies *}
   191 
   192 class order_topology = order + "open" +
   193   assumes open_generated_order: "open = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   194 begin
   195 
   196 subclass topological_space
   197   unfolding open_generated_order
   198   by (rule topological_space_generate_topology)
   199 
   200 lemma open_greaterThan [continuous_intros, simp]: "open {a <..}"
   201   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   202 
   203 lemma open_lessThan [continuous_intros, simp]: "open {..< a}"
   204   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   205 
   206 lemma open_greaterThanLessThan [continuous_intros, simp]: "open {a <..< b}"
   207    unfolding greaterThanLessThan_eq by (simp add: open_Int)
   208 
   209 end
   210 
   211 class linorder_topology = linorder + order_topology
   212 
   213 lemma closed_atMost [continuous_intros, simp]: "closed {.. a::'a::linorder_topology}"
   214   by (simp add: closed_open)
   215 
   216 lemma closed_atLeast [continuous_intros, simp]: "closed {a::'a::linorder_topology ..}"
   217   by (simp add: closed_open)
   218 
   219 lemma closed_atLeastAtMost [continuous_intros, simp]: "closed {a::'a::linorder_topology .. b}"
   220 proof -
   221   have "{a .. b} = {a ..} \<inter> {.. b}"
   222     by auto
   223   then show ?thesis
   224     by (simp add: closed_Int)
   225 qed
   226 
   227 lemma (in linorder) less_separate:
   228   assumes "x < y"
   229   shows "\<exists>a b. x \<in> {..< a} \<and> y \<in> {b <..} \<and> {..< a} \<inter> {b <..} = {}"
   230 proof (cases "\<exists>z. x < z \<and> z < y")
   231   case True
   232   then obtain z where "x < z \<and> z < y" ..
   233   then have "x \<in> {..< z} \<and> y \<in> {z <..} \<and> {z <..} \<inter> {..< z} = {}"
   234     by auto
   235   then show ?thesis by blast
   236 next
   237   case False
   238   with `x < y` have "x \<in> {..< y} \<and> y \<in> {x <..} \<and> {x <..} \<inter> {..< y} = {}"
   239     by auto
   240   then show ?thesis by blast
   241 qed
   242 
   243 instance linorder_topology \<subseteq> t2_space
   244 proof
   245   fix x y :: 'a
   246   from less_separate[of x y] less_separate[of y x]
   247   show "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   248     by (elim neqE) (metis open_lessThan open_greaterThan Int_commute)+
   249 qed
   250 
   251 lemma (in linorder_topology) open_right:
   252   assumes "open S" "x \<in> S" and gt_ex: "x < y" shows "\<exists>b>x. {x ..< b} \<subseteq> S"
   253   using assms unfolding open_generated_order
   254 proof induction
   255   case (Int A B)
   256   then obtain a b where "a > x" "{x ..< a} \<subseteq> A"  "b > x" "{x ..< b} \<subseteq> B" by auto
   257   then show ?case by (auto intro!: exI[of _ "min a b"])
   258 next
   259   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] gt_ex)
   260 qed blast+
   261 
   262 lemma (in linorder_topology) open_left:
   263   assumes "open S" "x \<in> S" and lt_ex: "y < x" shows "\<exists>b<x. {b <.. x} \<subseteq> S"
   264   using assms unfolding open_generated_order
   265 proof induction
   266   case (Int A B)
   267   then obtain a b where "a < x" "{a <.. x} \<subseteq> A"  "b < x" "{b <.. x} \<subseteq> B" by auto
   268   then show ?case by (auto intro!: exI[of _ "max a b"])
   269 next
   270   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] lt_ex)
   271 qed blast+
   272 
   273 subsection {* Filters *}
   274 
   275 text {*
   276   This definition also allows non-proper filters.
   277 *}
   278 
   279 locale is_filter =
   280   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
   281   assumes True: "F (\<lambda>x. True)"
   282   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
   283   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
   284 
   285 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
   286 proof
   287   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
   288 qed
   289 
   290 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
   291   using Rep_filter [of F] by simp
   292 
   293 lemma Abs_filter_inverse':
   294   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
   295   using assms by (simp add: Abs_filter_inverse)
   296 
   297 
   298 subsubsection {* Eventually *}
   299 
   300 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   301   where "eventually P F \<longleftrightarrow> Rep_filter F P"
   302 
   303 lemma eventually_Abs_filter:
   304   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
   305   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
   306 
   307 lemma filter_eq_iff:
   308   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
   309   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
   310 
   311 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
   312   unfolding eventually_def
   313   by (rule is_filter.True [OF is_filter_Rep_filter])
   314 
   315 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
   316 proof -
   317   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
   318   thus "eventually P F" by simp
   319 qed
   320 
   321 lemma eventually_mono:
   322   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
   323   unfolding eventually_def
   324   by (rule is_filter.mono [OF is_filter_Rep_filter])
   325 
   326 lemma eventually_conj:
   327   assumes P: "eventually (\<lambda>x. P x) F"
   328   assumes Q: "eventually (\<lambda>x. Q x) F"
   329   shows "eventually (\<lambda>x. P x \<and> Q x) F"
   330   using assms unfolding eventually_def
   331   by (rule is_filter.conj [OF is_filter_Rep_filter])
   332 
   333 lemma eventually_Ball_finite:
   334   assumes "finite A" and "\<forall>y\<in>A. eventually (\<lambda>x. P x y) net"
   335   shows "eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   336 using assms by (induct set: finite, simp, simp add: eventually_conj)
   337 
   338 lemma eventually_all_finite:
   339   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   340   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   341   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   342 using eventually_Ball_finite [of UNIV P] assms by simp
   343 
   344 lemma eventually_mp:
   345   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   346   assumes "eventually (\<lambda>x. P x) F"
   347   shows "eventually (\<lambda>x. Q x) F"
   348 proof (rule eventually_mono)
   349   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
   350   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
   351     using assms by (rule eventually_conj)
   352 qed
   353 
   354 lemma eventually_rev_mp:
   355   assumes "eventually (\<lambda>x. P x) F"
   356   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   357   shows "eventually (\<lambda>x. Q x) F"
   358 using assms(2) assms(1) by (rule eventually_mp)
   359 
   360 lemma eventually_conj_iff:
   361   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
   362   by (auto intro: eventually_conj elim: eventually_rev_mp)
   363 
   364 lemma eventually_elim1:
   365   assumes "eventually (\<lambda>i. P i) F"
   366   assumes "\<And>i. P i \<Longrightarrow> Q i"
   367   shows "eventually (\<lambda>i. Q i) F"
   368   using assms by (auto elim!: eventually_rev_mp)
   369 
   370 lemma eventually_elim2:
   371   assumes "eventually (\<lambda>i. P i) F"
   372   assumes "eventually (\<lambda>i. Q i) F"
   373   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   374   shows "eventually (\<lambda>i. R i) F"
   375   using assms by (auto elim!: eventually_rev_mp)
   376 
   377 lemma eventually_subst:
   378   assumes "eventually (\<lambda>n. P n = Q n) F"
   379   shows "eventually P F = eventually Q F" (is "?L = ?R")
   380 proof -
   381   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   382       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   383     by (auto elim: eventually_elim1)
   384   then show ?thesis by (auto elim: eventually_elim2)
   385 qed
   386 
   387 ML {*
   388   fun eventually_elim_tac ctxt thms = SUBGOAL_CASES (fn (_, _, st) =>
   389     let
   390       val thy = Proof_Context.theory_of ctxt
   391       val mp_thms = thms RL [@{thm eventually_rev_mp}]
   392       val raw_elim_thm =
   393         (@{thm allI} RS @{thm always_eventually})
   394         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   395         |> fold (fn _ => fn thm => @{thm impI} RS thm) thms
   396       val cases_prop = prop_of (raw_elim_thm RS st)
   397       val cases = (Rule_Cases.make_common (thy, cases_prop) [(("elim", []), [])])
   398     in
   399       CASES cases (rtac raw_elim_thm 1)
   400     end) 1
   401 *}
   402 
   403 method_setup eventually_elim = {*
   404   Scan.succeed (fn ctxt => METHOD_CASES (eventually_elim_tac ctxt))
   405 *} "elimination of eventually quantifiers"
   406 
   407 
   408 subsubsection {* Finer-than relation *}
   409 
   410 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   411 filter @{term F'}. *}
   412 
   413 instantiation filter :: (type) complete_lattice
   414 begin
   415 
   416 definition le_filter_def:
   417   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   418 
   419 definition
   420   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   421 
   422 definition
   423   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   424 
   425 definition
   426   "bot = Abs_filter (\<lambda>P. True)"
   427 
   428 definition
   429   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   430 
   431 definition
   432   "inf F F' = Abs_filter
   433       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   434 
   435 definition
   436   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   437 
   438 definition
   439   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   440 
   441 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   442   unfolding top_filter_def
   443   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   444 
   445 lemma eventually_bot [simp]: "eventually P bot"
   446   unfolding bot_filter_def
   447   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   448 
   449 lemma eventually_sup:
   450   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   451   unfolding sup_filter_def
   452   by (rule eventually_Abs_filter, rule is_filter.intro)
   453      (auto elim!: eventually_rev_mp)
   454 
   455 lemma eventually_inf:
   456   "eventually P (inf F F') \<longleftrightarrow>
   457    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   458   unfolding inf_filter_def
   459   apply (rule eventually_Abs_filter, rule is_filter.intro)
   460   apply (fast intro: eventually_True)
   461   apply clarify
   462   apply (intro exI conjI)
   463   apply (erule (1) eventually_conj)
   464   apply (erule (1) eventually_conj)
   465   apply simp
   466   apply auto
   467   done
   468 
   469 lemma eventually_Sup:
   470   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   471   unfolding Sup_filter_def
   472   apply (rule eventually_Abs_filter, rule is_filter.intro)
   473   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   474   done
   475 
   476 instance proof
   477   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   478   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   479     by (rule less_filter_def) }
   480   { show "F \<le> F"
   481     unfolding le_filter_def by simp }
   482   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   483     unfolding le_filter_def by simp }
   484   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   485     unfolding le_filter_def filter_eq_iff by fast }
   486   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   487     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   488   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   489     unfolding le_filter_def eventually_inf
   490     by (auto elim!: eventually_mono intro: eventually_conj) }
   491   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   492     unfolding le_filter_def eventually_sup by simp_all }
   493   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   494     unfolding le_filter_def eventually_sup by simp }
   495   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   496     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   497   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   498     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   499   { assume "F \<in> S" thus "F \<le> Sup S"
   500     unfolding le_filter_def eventually_Sup by simp }
   501   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   502     unfolding le_filter_def eventually_Sup by simp }
   503   { show "Inf {} = (top::'a filter)"
   504     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   505       (metis (full_types) top_filter_def always_eventually eventually_top) }
   506   { show "Sup {} = (bot::'a filter)"
   507     by (auto simp: bot_filter_def Sup_filter_def) }
   508 qed
   509 
   510 end
   511 
   512 lemma filter_leD:
   513   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   514   unfolding le_filter_def by simp
   515 
   516 lemma filter_leI:
   517   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   518   unfolding le_filter_def by simp
   519 
   520 lemma eventually_False:
   521   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   522   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   523 
   524 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   525   where "trivial_limit F \<equiv> F = bot"
   526 
   527 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   528   by (rule eventually_False [symmetric])
   529 
   530 lemma eventually_const: "\<not> trivial_limit net \<Longrightarrow> eventually (\<lambda>x. P) net \<longleftrightarrow> P"
   531   by (cases P) (simp_all add: eventually_False)
   532 
   533 
   534 subsubsection {* Map function for filters *}
   535 
   536 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   537   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   538 
   539 lemma eventually_filtermap:
   540   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   541   unfolding filtermap_def
   542   apply (rule eventually_Abs_filter)
   543   apply (rule is_filter.intro)
   544   apply (auto elim!: eventually_rev_mp)
   545   done
   546 
   547 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   548   by (simp add: filter_eq_iff eventually_filtermap)
   549 
   550 lemma filtermap_filtermap:
   551   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   552   by (simp add: filter_eq_iff eventually_filtermap)
   553 
   554 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   555   unfolding le_filter_def eventually_filtermap by simp
   556 
   557 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   558   by (simp add: filter_eq_iff eventually_filtermap)
   559 
   560 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   561   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   562 
   563 subsubsection {* Order filters *}
   564 
   565 definition at_top :: "('a::order) filter"
   566   where "at_top = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   567 
   568 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   569   unfolding at_top_def
   570 proof (rule eventually_Abs_filter, rule is_filter.intro)
   571   fix P Q :: "'a \<Rightarrow> bool"
   572   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
   573   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
   574   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
   575   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
   576 qed auto
   577 
   578 lemma eventually_ge_at_top:
   579   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   580   unfolding eventually_at_top_linorder by auto
   581 
   582 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::unbounded_dense_linorder. \<forall>n>N. P n)"
   583   unfolding eventually_at_top_linorder
   584 proof safe
   585   fix N assume "\<forall>n\<ge>N. P n"
   586   then show "\<exists>N. \<forall>n>N. P n" by (auto intro!: exI[of _ N])
   587 next
   588   fix N assume "\<forall>n>N. P n"
   589   moreover obtain y where "N < y" using gt_ex[of N] ..
   590   ultimately show "\<exists>N. \<forall>n\<ge>N. P n" by (auto intro!: exI[of _ y])
   591 qed
   592 
   593 lemma eventually_gt_at_top:
   594   "eventually (\<lambda>x. (c::_::unbounded_dense_linorder) < x) at_top"
   595   unfolding eventually_at_top_dense by auto
   596 
   597 definition at_bot :: "('a::order) filter"
   598   where "at_bot = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<le>k. P n)"
   599 
   600 lemma eventually_at_bot_linorder:
   601   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   602   unfolding at_bot_def
   603 proof (rule eventually_Abs_filter, rule is_filter.intro)
   604   fix P Q :: "'a \<Rightarrow> bool"
   605   assume "\<exists>i. \<forall>n\<le>i. P n" and "\<exists>j. \<forall>n\<le>j. Q n"
   606   then obtain i j where "\<forall>n\<le>i. P n" and "\<forall>n\<le>j. Q n" by auto
   607   then have "\<forall>n\<le>min i j. P n \<and> Q n" by simp
   608   then show "\<exists>k. \<forall>n\<le>k. P n \<and> Q n" ..
   609 qed auto
   610 
   611 lemma eventually_le_at_bot:
   612   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   613   unfolding eventually_at_bot_linorder by auto
   614 
   615 lemma eventually_at_bot_dense:
   616   fixes P :: "'a::unbounded_dense_linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n<N. P n)"
   617   unfolding eventually_at_bot_linorder
   618 proof safe
   619   fix N assume "\<forall>n\<le>N. P n" then show "\<exists>N. \<forall>n<N. P n" by (auto intro!: exI[of _ N])
   620 next
   621   fix N assume "\<forall>n<N. P n" 
   622   moreover obtain y where "y < N" using lt_ex[of N] ..
   623   ultimately show "\<exists>N. \<forall>n\<le>N. P n" by (auto intro!: exI[of _ y])
   624 qed
   625 
   626 lemma eventually_gt_at_bot:
   627   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
   628   unfolding eventually_at_bot_dense by auto
   629 
   630 lemma trivial_limit_at_bot_linorder: "\<not> trivial_limit (at_bot ::('a::linorder) filter)"
   631   unfolding trivial_limit_def
   632   by (metis eventually_at_bot_linorder order_refl)
   633 
   634 lemma trivial_limit_at_top_linorder: "\<not> trivial_limit (at_top ::('a::linorder) filter)"
   635   unfolding trivial_limit_def
   636   by (metis eventually_at_top_linorder order_refl)
   637 
   638 subsection {* Sequentially *}
   639 
   640 abbreviation sequentially :: "nat filter"
   641   where "sequentially == at_top"
   642 
   643 lemma sequentially_def: "sequentially = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   644   unfolding at_top_def by simp
   645 
   646 lemma eventually_sequentially:
   647   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   648   by (rule eventually_at_top_linorder)
   649 
   650 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   651   unfolding filter_eq_iff eventually_sequentially by auto
   652 
   653 lemmas trivial_limit_sequentially = sequentially_bot
   654 
   655 lemma eventually_False_sequentially [simp]:
   656   "\<not> eventually (\<lambda>n. False) sequentially"
   657   by (simp add: eventually_False)
   658 
   659 lemma le_sequentially:
   660   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   661   unfolding le_filter_def eventually_sequentially
   662   by (safe, fast, drule_tac x=N in spec, auto elim: eventually_rev_mp)
   663 
   664 lemma eventually_sequentiallyI:
   665   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   666   shows "eventually P sequentially"
   667 using assms by (auto simp: eventually_sequentially)
   668 
   669 lemma eventually_sequentially_seg:
   670   "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   671   unfolding eventually_sequentially
   672   apply safe
   673    apply (rule_tac x="N + k" in exI)
   674    apply rule
   675    apply (erule_tac x="n - k" in allE)
   676    apply auto []
   677   apply (rule_tac x=N in exI)
   678   apply auto []
   679   done
   680 
   681 subsubsection {* Standard filters *}
   682 
   683 definition principal :: "'a set \<Rightarrow> 'a filter" where
   684   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   685 
   686 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   687   unfolding principal_def
   688   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   689 
   690 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   691   unfolding eventually_inf eventually_principal by (auto elim: eventually_elim1)
   692 
   693 lemma principal_UNIV[simp]: "principal UNIV = top"
   694   by (auto simp: filter_eq_iff eventually_principal)
   695 
   696 lemma principal_empty[simp]: "principal {} = bot"
   697   by (auto simp: filter_eq_iff eventually_principal)
   698 
   699 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   700   by (auto simp: le_filter_def eventually_principal)
   701 
   702 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   703   unfolding le_filter_def eventually_principal
   704   apply safe
   705   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   706   apply (auto elim: eventually_elim1)
   707   done
   708 
   709 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   710   unfolding eq_iff by simp
   711 
   712 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   713   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   714 
   715 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   716   unfolding filter_eq_iff eventually_inf eventually_principal
   717   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   718 
   719 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   720   unfolding filter_eq_iff eventually_Sup SUP_def by (auto simp: eventually_principal)
   721 
   722 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   723   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   724 
   725 subsubsection {* Topological filters *}
   726 
   727 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   728   where "nhds a = Abs_filter (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   729 
   730 definition (in topological_space) at_within :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a filter" ("at (_) within (_)" [1000, 60] 60)
   731   where "at a within s = inf (nhds a) (principal (s - {a}))"
   732 
   733 abbreviation (in topological_space) at :: "'a \<Rightarrow> 'a filter" ("at") where
   734   "at x \<equiv> at x within (CONST UNIV)"
   735 
   736 abbreviation (in order_topology) at_right :: "'a \<Rightarrow> 'a filter" where
   737   "at_right x \<equiv> at x within {x <..}"
   738 
   739 abbreviation (in order_topology) at_left :: "'a \<Rightarrow> 'a filter" where
   740   "at_left x \<equiv> at x within {..< x}"
   741 
   742 lemma (in topological_space) eventually_nhds:
   743   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   744   unfolding nhds_def
   745 proof (rule eventually_Abs_filter, rule is_filter.intro)
   746   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. True)" by simp
   747   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. True)" ..
   748 next
   749   fix P Q
   750   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   751      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)"
   752   then obtain S T where
   753     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   754     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)" by auto
   755   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). P x \<and> Q x)"
   756     by (simp add: open_Int)
   757   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x \<and> Q x)" ..
   758 qed auto
   759 
   760 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   761   unfolding trivial_limit_def eventually_nhds by simp
   762 
   763 lemma eventually_at_filter:
   764   "eventually P (at a within s) \<longleftrightarrow> eventually (\<lambda>x. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x) (nhds a)"
   765   unfolding at_within_def eventually_inf_principal by (simp add: imp_conjL[symmetric] conj_commute)
   766 
   767 lemma at_le: "s \<subseteq> t \<Longrightarrow> at x within s \<le> at x within t"
   768   unfolding at_within_def by (intro inf_mono) auto
   769 
   770 lemma eventually_at_topological:
   771   "eventually P (at a within s) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x))"
   772   unfolding eventually_nhds eventually_at_filter by simp
   773 
   774 lemma at_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> at a within S = at a"
   775   unfolding filter_eq_iff eventually_at_topological by (metis open_Int Int_iff UNIV_I)
   776 
   777 lemma at_within_empty [simp]: "at a within {} = bot"
   778   unfolding at_within_def by simp
   779 
   780 lemma at_within_union: "at x within (S \<union> T) = sup (at x within S) (at x within T)"
   781   unfolding filter_eq_iff eventually_sup eventually_at_filter
   782   by (auto elim!: eventually_rev_mp)
   783 
   784 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   785   unfolding trivial_limit_def eventually_at_topological
   786   by (safe, case_tac "S = {a}", simp, fast, fast)
   787 
   788 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   789   by (simp add: at_eq_bot_iff not_open_singleton)
   790 
   791 lemma eventually_at_right:
   792   fixes x :: "'a :: {no_top, linorder_topology}"
   793   shows "eventually P (at_right x) \<longleftrightarrow> (\<exists>b. x < b \<and> (\<forall>z. x < z \<and> z < b \<longrightarrow> P z))"
   794   unfolding eventually_at_topological
   795 proof safe
   796   obtain y where "x < y" using gt_ex[of x] ..
   797   moreover fix S assume "open S" "x \<in> S" note open_right[OF this, of y]
   798   moreover note gt_ex[of x]
   799   moreover assume "\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {x<..} \<longrightarrow> P s"
   800   ultimately show "\<exists>b>x. \<forall>z. x < z \<and> z < b \<longrightarrow> P z"
   801     by (auto simp: subset_eq Ball_def)
   802 next
   803   fix b assume "x < b" "\<forall>z. x < z \<and> z < b \<longrightarrow> P z"
   804   then show "\<exists>S. open S \<and> x \<in> S \<and> (\<forall>xa\<in>S. xa \<noteq> x \<longrightarrow> xa \<in> {x<..} \<longrightarrow> P xa)"
   805     by (intro exI[of _ "{..< b}"]) auto
   806 qed
   807 
   808 lemma eventually_at_left:
   809   fixes x :: "'a :: {no_bot, linorder_topology}"
   810   shows "eventually P (at_left x) \<longleftrightarrow> (\<exists>b. x > b \<and> (\<forall>z. b < z \<and> z < x \<longrightarrow> P z))"
   811   unfolding eventually_at_topological
   812 proof safe
   813   obtain y where "y < x" using lt_ex[of x] ..
   814   moreover fix S assume "open S" "x \<in> S" note open_left[OF this, of y]
   815   moreover assume "\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {..<x} \<longrightarrow> P s"
   816   ultimately show "\<exists>b<x. \<forall>z. b < z \<and> z < x \<longrightarrow> P z"
   817     by (auto simp: subset_eq Ball_def)
   818 next
   819   fix b assume "b < x" "\<forall>z. b < z \<and> z < x \<longrightarrow> P z"
   820   then show "\<exists>S. open S \<and> x \<in> S \<and> (\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {..<x} \<longrightarrow> P s)"
   821     by (intro exI[of _ "{b <..}"]) auto
   822 qed
   823 
   824 lemma trivial_limit_at_left_real [simp]:
   825   "\<not> trivial_limit (at_left (x::'a::{no_bot, unbounded_dense_linorder, linorder_topology}))"
   826   unfolding trivial_limit_def eventually_at_left by (auto dest: dense)
   827 
   828 lemma trivial_limit_at_right_real [simp]:
   829   "\<not> trivial_limit (at_right (x::'a::{no_top, unbounded_dense_linorder, linorder_topology}))"
   830   unfolding trivial_limit_def eventually_at_right by (auto dest: dense)
   831 
   832 lemma at_eq_sup_left_right: "at (x::'a::linorder_topology) = sup (at_left x) (at_right x)"
   833   by (auto simp: eventually_at_filter filter_eq_iff eventually_sup 
   834            elim: eventually_elim2 eventually_elim1)
   835 
   836 lemma eventually_at_split:
   837   "eventually P (at (x::'a::linorder_topology)) \<longleftrightarrow> eventually P (at_left x) \<and> eventually P (at_right x)"
   838   by (subst at_eq_sup_left_right) (simp add: eventually_sup)
   839 
   840 subsection {* Limits *}
   841 
   842 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   843   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   844 
   845 syntax
   846   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   847 
   848 translations
   849   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   850 
   851 lemma filterlim_iff:
   852   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   853   unfolding filterlim_def le_filter_def eventually_filtermap ..
   854 
   855 lemma filterlim_compose:
   856   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
   857   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
   858 
   859 lemma filterlim_mono:
   860   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
   861   unfolding filterlim_def by (metis filtermap_mono order_trans)
   862 
   863 lemma filterlim_ident: "LIM x F. x :> F"
   864   by (simp add: filterlim_def filtermap_ident)
   865 
   866 lemma filterlim_cong:
   867   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
   868   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
   869 
   870 lemma filterlim_principal:
   871   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
   872   unfolding filterlim_def eventually_filtermap le_principal ..
   873 
   874 lemma filterlim_inf:
   875   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
   876   unfolding filterlim_def by simp
   877 
   878 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
   879   unfolding filterlim_def filtermap_filtermap ..
   880 
   881 lemma filterlim_sup:
   882   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
   883   unfolding filterlim_def filtermap_sup by auto
   884 
   885 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
   886   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
   887 
   888 subsubsection {* Tendsto *}
   889 
   890 abbreviation (in topological_space)
   891   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
   892   "(f ---> l) F \<equiv> filterlim f (nhds l) F"
   893 
   894 definition (in t2_space) Lim :: "'f filter \<Rightarrow> ('f \<Rightarrow> 'a) \<Rightarrow> 'a" where
   895   "Lim A f = (THE l. (f ---> l) A)"
   896 
   897 lemma tendsto_eq_rhs: "(f ---> x) F \<Longrightarrow> x = y \<Longrightarrow> (f ---> y) F"
   898   by simp
   899 
   900 ML {*
   901 
   902 structure Tendsto_Intros = Named_Thms
   903 (
   904   val name = @{binding tendsto_intros}
   905   val description = "introduction rules for tendsto"
   906 )
   907 
   908 *}
   909 
   910 setup {*
   911   Tendsto_Intros.setup #>
   912   Global_Theory.add_thms_dynamic (@{binding tendsto_eq_intros},
   913     map_filter (try (fn thm => @{thm tendsto_eq_rhs} OF [thm])) o Tendsto_Intros.get o Context.proof_of);
   914 *}
   915 
   916 lemma (in topological_space) tendsto_def:
   917    "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
   918   unfolding filterlim_def
   919 proof safe
   920   fix S assume "open S" "l \<in> S" "filtermap f F \<le> nhds l"
   921   then show "eventually (\<lambda>x. f x \<in> S) F"
   922     unfolding eventually_nhds eventually_filtermap le_filter_def
   923     by (auto elim!: allE[of _ "\<lambda>x. x \<in> S"] eventually_rev_mp)
   924 qed (auto elim!: eventually_rev_mp simp: eventually_nhds eventually_filtermap le_filter_def)
   925 
   926 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
   927   unfolding tendsto_def le_filter_def by fast
   928 
   929 lemma tendsto_within_subset: "(f ---> l) (at x within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f ---> l) (at x within T)"
   930   by (blast intro: tendsto_mono at_le)
   931 
   932 lemma filterlim_at:
   933   "(LIM x F. f x :> at b within s) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> s \<and> f x \<noteq> b) F \<and> (f ---> b) F)"
   934   by (simp add: at_within_def filterlim_inf filterlim_principal conj_commute)
   935 
   936 lemma (in topological_space) topological_tendstoI:
   937   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F) \<Longrightarrow> (f ---> l) F"
   938   unfolding tendsto_def by auto
   939 
   940 lemma (in topological_space) topological_tendstoD:
   941   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
   942   unfolding tendsto_def by auto
   943 
   944 lemma order_tendstoI:
   945   fixes y :: "_ :: order_topology"
   946   assumes "\<And>a. a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
   947   assumes "\<And>a. y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
   948   shows "(f ---> y) F"
   949 proof (rule topological_tendstoI)
   950   fix S assume "open S" "y \<in> S"
   951   then show "eventually (\<lambda>x. f x \<in> S) F"
   952     unfolding open_generated_order
   953   proof induct
   954     case (UN K)
   955     then obtain k where "y \<in> k" "k \<in> K" by auto
   956     with UN(2)[of k] show ?case
   957       by (auto elim: eventually_elim1)
   958   qed (insert assms, auto elim: eventually_elim2)
   959 qed
   960 
   961 lemma order_tendstoD:
   962   fixes y :: "_ :: order_topology"
   963   assumes y: "(f ---> y) F"
   964   shows "a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
   965     and "y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
   966   using topological_tendstoD[OF y, of "{..< a}"] topological_tendstoD[OF y, of "{a <..}"] by auto
   967 
   968 lemma order_tendsto_iff: 
   969   fixes f :: "_ \<Rightarrow> 'a :: order_topology"
   970   shows "(f ---> x) F \<longleftrightarrow>(\<forall>l<x. eventually (\<lambda>x. l < f x) F) \<and> (\<forall>u>x. eventually (\<lambda>x. f x < u) F)"
   971   by (metis order_tendstoI order_tendstoD)
   972 
   973 lemma tendsto_bot [simp]: "(f ---> a) bot"
   974   unfolding tendsto_def by simp
   975 
   976 lemma tendsto_max:
   977   fixes x y :: "'a::linorder_topology"
   978   assumes X: "(X ---> x) net"
   979   assumes Y: "(Y ---> y) net"
   980   shows "((\<lambda>x. max (X x) (Y x)) ---> max x y) net"
   981 proof (rule order_tendstoI)
   982   fix a assume "a < max x y"
   983   then show "eventually (\<lambda>x. a < max (X x) (Y x)) net"
   984     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
   985     by (auto simp: less_max_iff_disj elim: eventually_elim1)
   986 next
   987   fix a assume "max x y < a"
   988   then show "eventually (\<lambda>x. max (X x) (Y x) < a) net"
   989     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
   990     by (auto simp: eventually_conj_iff)
   991 qed
   992 
   993 lemma tendsto_min:
   994   fixes x y :: "'a::linorder_topology"
   995   assumes X: "(X ---> x) net"
   996   assumes Y: "(Y ---> y) net"
   997   shows "((\<lambda>x. min (X x) (Y x)) ---> min x y) net"
   998 proof (rule order_tendstoI)
   999   fix a assume "a < min x y"
  1000   then show "eventually (\<lambda>x. a < min (X x) (Y x)) net"
  1001     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
  1002     by (auto simp: eventually_conj_iff)
  1003 next
  1004   fix a assume "min x y < a"
  1005   then show "eventually (\<lambda>x. min (X x) (Y x) < a) net"
  1006     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
  1007     by (auto simp: min_less_iff_disj elim: eventually_elim1)
  1008 qed
  1009 
  1010 
  1011 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a within s)"
  1012   unfolding tendsto_def eventually_at_topological by auto
  1013 
  1014 lemma (in topological_space) tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) F"
  1015   by (simp add: tendsto_def)
  1016 
  1017 lemma (in t2_space) tendsto_unique:
  1018   assumes "\<not> trivial_limit F" and "(f ---> a) F" and "(f ---> b) F"
  1019   shows "a = b"
  1020 proof (rule ccontr)
  1021   assume "a \<noteq> b"
  1022   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
  1023     using hausdorff [OF `a \<noteq> b`] by fast
  1024   have "eventually (\<lambda>x. f x \<in> U) F"
  1025     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
  1026   moreover
  1027   have "eventually (\<lambda>x. f x \<in> V) F"
  1028     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
  1029   ultimately
  1030   have "eventually (\<lambda>x. False) F"
  1031   proof eventually_elim
  1032     case (elim x)
  1033     hence "f x \<in> U \<inter> V" by simp
  1034     with `U \<inter> V = {}` show ?case by simp
  1035   qed
  1036   with `\<not> trivial_limit F` show "False"
  1037     by (simp add: trivial_limit_def)
  1038 qed
  1039 
  1040 lemma (in t2_space) tendsto_const_iff:
  1041   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a :: 'a) ---> b) F \<longleftrightarrow> a = b"
  1042   by (safe intro!: tendsto_const tendsto_unique [OF assms tendsto_const])
  1043 
  1044 lemma increasing_tendsto:
  1045   fixes f :: "_ \<Rightarrow> 'a::order_topology"
  1046   assumes bdd: "eventually (\<lambda>n. f n \<le> l) F"
  1047       and en: "\<And>x. x < l \<Longrightarrow> eventually (\<lambda>n. x < f n) F"
  1048   shows "(f ---> l) F"
  1049   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
  1050 
  1051 lemma decreasing_tendsto:
  1052   fixes f :: "_ \<Rightarrow> 'a::order_topology"
  1053   assumes bdd: "eventually (\<lambda>n. l \<le> f n) F"
  1054       and en: "\<And>x. l < x \<Longrightarrow> eventually (\<lambda>n. f n < x) F"
  1055   shows "(f ---> l) F"
  1056   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
  1057 
  1058 lemma tendsto_sandwich:
  1059   fixes f g h :: "'a \<Rightarrow> 'b::order_topology"
  1060   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
  1061   assumes lim: "(f ---> c) net" "(h ---> c) net"
  1062   shows "(g ---> c) net"
  1063 proof (rule order_tendstoI)
  1064   fix a show "a < c \<Longrightarrow> eventually (\<lambda>x. a < g x) net"
  1065     using order_tendstoD[OF lim(1), of a] ev by (auto elim: eventually_elim2)
  1066 next
  1067   fix a show "c < a \<Longrightarrow> eventually (\<lambda>x. g x < a) net"
  1068     using order_tendstoD[OF lim(2), of a] ev by (auto elim: eventually_elim2)
  1069 qed
  1070 
  1071 lemma tendsto_le:
  1072   fixes f g :: "'a \<Rightarrow> 'b::linorder_topology"
  1073   assumes F: "\<not> trivial_limit F"
  1074   assumes x: "(f ---> x) F" and y: "(g ---> y) F"
  1075   assumes ev: "eventually (\<lambda>x. g x \<le> f x) F"
  1076   shows "y \<le> x"
  1077 proof (rule ccontr)
  1078   assume "\<not> y \<le> x"
  1079   with less_separate[of x y] obtain a b where xy: "x < a" "b < y" "{..<a} \<inter> {b<..} = {}"
  1080     by (auto simp: not_le)
  1081   then have "eventually (\<lambda>x. f x < a) F" "eventually (\<lambda>x. b < g x) F"
  1082     using x y by (auto intro: order_tendstoD)
  1083   with ev have "eventually (\<lambda>x. False) F"
  1084     by eventually_elim (insert xy, fastforce)
  1085   with F show False
  1086     by (simp add: eventually_False)
  1087 qed
  1088 
  1089 lemma tendsto_le_const:
  1090   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
  1091   assumes F: "\<not> trivial_limit F"
  1092   assumes x: "(f ---> x) F" and a: "eventually (\<lambda>i. a \<le> f i) F"
  1093   shows "a \<le> x"
  1094   using F x tendsto_const a by (rule tendsto_le)
  1095 
  1096 lemma tendsto_ge_const:
  1097   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
  1098   assumes F: "\<not> trivial_limit F"
  1099   assumes x: "(f ---> x) F" and a: "eventually (\<lambda>i. a \<ge> f i) F"
  1100   shows "a \<ge> x"
  1101   by (rule tendsto_le [OF F tendsto_const x a])
  1102 
  1103 subsubsection {* Rules about @{const Lim} *}
  1104 
  1105 lemma (in t2_space) tendsto_Lim:
  1106   "\<not>(trivial_limit net) \<Longrightarrow> (f ---> l) net \<Longrightarrow> Lim net f = l"
  1107   unfolding Lim_def using tendsto_unique[of net f] by auto
  1108 
  1109 lemma Lim_ident_at: "\<not> trivial_limit (at x within s) \<Longrightarrow> Lim (at x within s) (\<lambda>x. x) = x"
  1110   by (rule tendsto_Lim[OF _ tendsto_ident_at]) auto
  1111 
  1112 subsection {* Limits to @{const at_top} and @{const at_bot} *}
  1113 
  1114 lemma filterlim_at_top:
  1115   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1116   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
  1117   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_elim1)
  1118 
  1119 lemma filterlim_at_top_dense:
  1120   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
  1121   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
  1122   by (metis eventually_elim1[of _ F] eventually_gt_at_top order_less_imp_le
  1123             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
  1124 
  1125 lemma filterlim_at_top_ge:
  1126   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1127   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1128   unfolding filterlim_at_top
  1129 proof safe
  1130   fix Z assume *: "\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F"
  1131   with *[THEN spec, of "max Z c"] show "eventually (\<lambda>x. Z \<le> f x) F"
  1132     by (auto elim!: eventually_elim1)
  1133 qed simp
  1134 
  1135 lemma filterlim_at_top_at_top:
  1136   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
  1137   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1138   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1139   assumes Q: "eventually Q at_top"
  1140   assumes P: "eventually P at_top"
  1141   shows "filterlim f at_top at_top"
  1142 proof -
  1143   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1144     unfolding eventually_at_top_linorder by auto
  1145   show ?thesis
  1146   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1147     fix z assume "x \<le> z"
  1148     with x have "P z" by auto
  1149     have "eventually (\<lambda>x. g z \<le> x) at_top"
  1150       by (rule eventually_ge_at_top)
  1151     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
  1152       by eventually_elim (metis mono bij `P z`)
  1153   qed
  1154 qed
  1155 
  1156 lemma filterlim_at_top_gt:
  1157   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1158   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1159   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
  1160 
  1161 lemma filterlim_at_bot: 
  1162   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1163   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
  1164   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_elim1)
  1165 
  1166 lemma filterlim_at_bot_le:
  1167   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1168   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1169   unfolding filterlim_at_bot
  1170 proof safe
  1171   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
  1172   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
  1173     by (auto elim!: eventually_elim1)
  1174 qed simp
  1175 
  1176 lemma filterlim_at_bot_lt:
  1177   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1178   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1179   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
  1180 
  1181 lemma filterlim_at_bot_at_right:
  1182   fixes f :: "'a::{no_top, linorder_topology} \<Rightarrow> 'b::linorder"
  1183   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1184   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1185   assumes Q: "eventually Q (at_right a)" and bound: "\<And>b. Q b \<Longrightarrow> a < b"
  1186   assumes P: "eventually P at_bot"
  1187   shows "filterlim f at_bot (at_right a)"
  1188 proof -
  1189   from P obtain x where x: "\<And>y. y \<le> x \<Longrightarrow> P y"
  1190     unfolding eventually_at_bot_linorder by auto
  1191   show ?thesis
  1192   proof (intro filterlim_at_bot_le[THEN iffD2] allI impI)
  1193     fix z assume "z \<le> x"
  1194     with x have "P z" by auto
  1195     have "eventually (\<lambda>x. x \<le> g z) (at_right a)"
  1196       using bound[OF bij(2)[OF `P z`]]
  1197       unfolding eventually_at_right by (auto intro!: exI[of _ "g z"])
  1198     with Q show "eventually (\<lambda>x. f x \<le> z) (at_right a)"
  1199       by eventually_elim (metis bij `P z` mono)
  1200   qed
  1201 qed
  1202 
  1203 lemma filterlim_at_top_at_left:
  1204   fixes f :: "'a::{no_bot, linorder_topology} \<Rightarrow> 'b::linorder"
  1205   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1206   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1207   assumes Q: "eventually Q (at_left a)" and bound: "\<And>b. Q b \<Longrightarrow> b < a"
  1208   assumes P: "eventually P at_top"
  1209   shows "filterlim f at_top (at_left a)"
  1210 proof -
  1211   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1212     unfolding eventually_at_top_linorder by auto
  1213   show ?thesis
  1214   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1215     fix z assume "x \<le> z"
  1216     with x have "P z" by auto
  1217     have "eventually (\<lambda>x. g z \<le> x) (at_left a)"
  1218       using bound[OF bij(2)[OF `P z`]]
  1219       unfolding eventually_at_left by (auto intro!: exI[of _ "g z"])
  1220     with Q show "eventually (\<lambda>x. z \<le> f x) (at_left a)"
  1221       by eventually_elim (metis bij `P z` mono)
  1222   qed
  1223 qed
  1224 
  1225 lemma filterlim_split_at:
  1226   "filterlim f F (at_left x) \<Longrightarrow> filterlim f F (at_right x) \<Longrightarrow> filterlim f F (at (x::'a::linorder_topology))"
  1227   by (subst at_eq_sup_left_right) (rule filterlim_sup)
  1228 
  1229 lemma filterlim_at_split:
  1230   "filterlim f F (at (x::'a::linorder_topology)) \<longleftrightarrow> filterlim f F (at_left x) \<and> filterlim f F (at_right x)"
  1231   by (subst at_eq_sup_left_right) (simp add: filterlim_def filtermap_sup)
  1232 
  1233 
  1234 subsection {* Limits on sequences *}
  1235 
  1236 abbreviation (in topological_space)
  1237   LIMSEQ :: "[nat \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
  1238     ("((_)/ ----> (_))" [60, 60] 60) where
  1239   "X ----> L \<equiv> (X ---> L) sequentially"
  1240 
  1241 abbreviation (in t2_space) lim :: "(nat \<Rightarrow> 'a) \<Rightarrow> 'a" where
  1242   "lim X \<equiv> Lim sequentially X"
  1243 
  1244 definition (in topological_space) convergent :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1245   "convergent X = (\<exists>L. X ----> L)"
  1246 
  1247 lemma lim_def: "lim X = (THE L. X ----> L)"
  1248   unfolding Lim_def ..
  1249 
  1250 subsubsection {* Monotone sequences and subsequences *}
  1251 
  1252 definition
  1253   monoseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1254     --{*Definition of monotonicity.
  1255         The use of disjunction here complicates proofs considerably.
  1256         One alternative is to add a Boolean argument to indicate the direction.
  1257         Another is to develop the notions of increasing and decreasing first.*}
  1258   "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) \<or> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
  1259 
  1260 abbreviation incseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1261   "incseq X \<equiv> mono X"
  1262 
  1263 lemma incseq_def: "incseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<ge> X m)"
  1264   unfolding mono_def ..
  1265 
  1266 abbreviation decseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1267   "decseq X \<equiv> antimono X"
  1268 
  1269 lemma decseq_def: "decseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
  1270   unfolding antimono_def ..
  1271 
  1272 definition
  1273   subseq :: "(nat \<Rightarrow> nat) \<Rightarrow> bool" where
  1274     --{*Definition of subsequence*}
  1275   "subseq f \<longleftrightarrow> (\<forall>m. \<forall>n>m. f m < f n)"
  1276 
  1277 lemma incseq_SucI:
  1278   "(\<And>n. X n \<le> X (Suc n)) \<Longrightarrow> incseq X"
  1279   using lift_Suc_mono_le[of X]
  1280   by (auto simp: incseq_def)
  1281 
  1282 lemma incseqD: "\<And>i j. incseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f i \<le> f j"
  1283   by (auto simp: incseq_def)
  1284 
  1285 lemma incseq_SucD: "incseq A \<Longrightarrow> A i \<le> A (Suc i)"
  1286   using incseqD[of A i "Suc i"] by auto
  1287 
  1288 lemma incseq_Suc_iff: "incseq f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1289   by (auto intro: incseq_SucI dest: incseq_SucD)
  1290 
  1291 lemma incseq_const[simp, intro]: "incseq (\<lambda>x. k)"
  1292   unfolding incseq_def by auto
  1293 
  1294 lemma decseq_SucI:
  1295   "(\<And>n. X (Suc n) \<le> X n) \<Longrightarrow> decseq X"
  1296   using order.lift_Suc_mono_le[OF dual_order, of X]
  1297   by (auto simp: decseq_def)
  1298 
  1299 lemma decseqD: "\<And>i j. decseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f j \<le> f i"
  1300   by (auto simp: decseq_def)
  1301 
  1302 lemma decseq_SucD: "decseq A \<Longrightarrow> A (Suc i) \<le> A i"
  1303   using decseqD[of A i "Suc i"] by auto
  1304 
  1305 lemma decseq_Suc_iff: "decseq f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1306   by (auto intro: decseq_SucI dest: decseq_SucD)
  1307 
  1308 lemma decseq_const[simp, intro]: "decseq (\<lambda>x. k)"
  1309   unfolding decseq_def by auto
  1310 
  1311 lemma monoseq_iff: "monoseq X \<longleftrightarrow> incseq X \<or> decseq X"
  1312   unfolding monoseq_def incseq_def decseq_def ..
  1313 
  1314 lemma monoseq_Suc:
  1315   "monoseq X \<longleftrightarrow> (\<forall>n. X n \<le> X (Suc n)) \<or> (\<forall>n. X (Suc n) \<le> X n)"
  1316   unfolding monoseq_iff incseq_Suc_iff decseq_Suc_iff ..
  1317 
  1318 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
  1319 by (simp add: monoseq_def)
  1320 
  1321 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
  1322 by (simp add: monoseq_def)
  1323 
  1324 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
  1325 by (simp add: monoseq_Suc)
  1326 
  1327 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
  1328 by (simp add: monoseq_Suc)
  1329 
  1330 lemma monoseq_minus:
  1331   fixes a :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
  1332   assumes "monoseq a"
  1333   shows "monoseq (\<lambda> n. - a n)"
  1334 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
  1335   case True
  1336   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
  1337   thus ?thesis by (rule monoI2)
  1338 next
  1339   case False
  1340   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
  1341   thus ?thesis by (rule monoI1)
  1342 qed
  1343 
  1344 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
  1345 
  1346 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
  1347 apply (simp add: subseq_def)
  1348 apply (auto dest!: less_imp_Suc_add)
  1349 apply (induct_tac k)
  1350 apply (auto intro: less_trans)
  1351 done
  1352 
  1353 text{* for any sequence, there is a monotonic subsequence *}
  1354 lemma seq_monosub:
  1355   fixes s :: "nat => 'a::linorder"
  1356   shows "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
  1357 proof cases
  1358   let "?P p n" = "p > n \<and> (\<forall>m\<ge>p. s m \<le> s p)"
  1359   assume *: "\<forall>n. \<exists>p. ?P p n"
  1360   def f \<equiv> "rec_nat (SOME p. ?P p 0) (\<lambda>_ n. SOME p. ?P p n)"
  1361   have f_0: "f 0 = (SOME p. ?P p 0)" unfolding f_def by simp
  1362   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat.rec(2) ..
  1363   have P_0: "?P (f 0) 0" unfolding f_0 using *[rule_format] by (rule someI2_ex) auto
  1364   have P_Suc: "\<And>i. ?P (f (Suc i)) (f i)" unfolding f_Suc using *[rule_format] by (rule someI2_ex) auto
  1365   then have "subseq f" unfolding subseq_Suc_iff by auto
  1366   moreover have "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc
  1367   proof (intro disjI2 allI)
  1368     fix n show "s (f (Suc n)) \<le> s (f n)"
  1369     proof (cases n)
  1370       case 0 with P_Suc[of 0] P_0 show ?thesis by auto
  1371     next
  1372       case (Suc m)
  1373       from P_Suc[of n] Suc have "f (Suc m) \<le> f (Suc (Suc m))" by simp
  1374       with P_Suc Suc show ?thesis by simp
  1375     qed
  1376   qed
  1377   ultimately show ?thesis by auto
  1378 next
  1379   let "?P p m" = "m < p \<and> s m < s p"
  1380   assume "\<not> (\<forall>n. \<exists>p>n. (\<forall>m\<ge>p. s m \<le> s p))"
  1381   then obtain N where N: "\<And>p. p > N \<Longrightarrow> \<exists>m>p. s p < s m" by (force simp: not_le le_less)
  1382   def f \<equiv> "rec_nat (SOME p. ?P p (Suc N)) (\<lambda>_ n. SOME p. ?P p n)"
  1383   have f_0: "f 0 = (SOME p. ?P p (Suc N))" unfolding f_def by simp
  1384   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat.rec(2) ..
  1385   have P_0: "?P (f 0) (Suc N)"
  1386     unfolding f_0 some_eq_ex[of "\<lambda>p. ?P p (Suc N)"] using N[of "Suc N"] by auto
  1387   { fix i have "N < f i \<Longrightarrow> ?P (f (Suc i)) (f i)"
  1388       unfolding f_Suc some_eq_ex[of "\<lambda>p. ?P p (f i)"] using N[of "f i"] . }
  1389   note P' = this
  1390   { fix i have "N < f i \<and> ?P (f (Suc i)) (f i)"
  1391       by (induct i) (insert P_0 P', auto) }
  1392   then have "subseq f" "monoseq (\<lambda>x. s (f x))"
  1393     unfolding subseq_Suc_iff monoseq_Suc by (auto simp: not_le intro: less_imp_le)
  1394   then show ?thesis by auto
  1395 qed
  1396 
  1397 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
  1398 proof(induct n)
  1399   case 0 thus ?case by simp
  1400 next
  1401   case (Suc n)
  1402   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
  1403   have "n < f (Suc n)" by arith
  1404   thus ?case by arith
  1405 qed
  1406 
  1407 lemma eventually_subseq:
  1408   "subseq r \<Longrightarrow> eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  1409   unfolding eventually_sequentially by (metis seq_suble le_trans)
  1410 
  1411 lemma not_eventually_sequentiallyD:
  1412   assumes P: "\<not> eventually P sequentially"
  1413   shows "\<exists>r. subseq r \<and> (\<forall>n. \<not> P (r n))"
  1414 proof -
  1415   from P have "\<forall>n. \<exists>m\<ge>n. \<not> P m"
  1416     unfolding eventually_sequentially by (simp add: not_less)
  1417   then obtain r where "\<And>n. r n \<ge> n" "\<And>n. \<not> P (r n)"
  1418     by (auto simp: choice_iff)
  1419   then show ?thesis
  1420     by (auto intro!: exI[of _ "\<lambda>n. r (((Suc \<circ> r) ^^ Suc n) 0)"]
  1421              simp: less_eq_Suc_le subseq_Suc_iff)
  1422 qed
  1423 
  1424 lemma filterlim_subseq: "subseq f \<Longrightarrow> filterlim f sequentially sequentially"
  1425   unfolding filterlim_iff by (metis eventually_subseq)
  1426 
  1427 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  1428   unfolding subseq_def by simp
  1429 
  1430 lemma subseq_mono: assumes "subseq r" "m < n" shows "r m < r n"
  1431   using assms by (auto simp: subseq_def)
  1432 
  1433 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
  1434   by (simp add: incseq_def monoseq_def)
  1435 
  1436 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
  1437   by (simp add: decseq_def monoseq_def)
  1438 
  1439 lemma decseq_eq_incseq:
  1440   fixes X :: "nat \<Rightarrow> 'a::ordered_ab_group_add" shows "decseq X = incseq (\<lambda>n. - X n)" 
  1441   by (simp add: decseq_def incseq_def)
  1442 
  1443 lemma INT_decseq_offset:
  1444   assumes "decseq F"
  1445   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
  1446 proof safe
  1447   fix x i assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
  1448   show "x \<in> F i"
  1449   proof cases
  1450     from x have "x \<in> F n" by auto
  1451     also assume "i \<le> n" with `decseq F` have "F n \<subseteq> F i"
  1452       unfolding decseq_def by simp
  1453     finally show ?thesis .
  1454   qed (insert x, simp)
  1455 qed auto
  1456 
  1457 lemma LIMSEQ_const_iff:
  1458   fixes k l :: "'a::t2_space"
  1459   shows "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
  1460   using trivial_limit_sequentially by (rule tendsto_const_iff)
  1461 
  1462 lemma LIMSEQ_SUP:
  1463   "incseq X \<Longrightarrow> X ----> (SUP i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1464   by (intro increasing_tendsto)
  1465      (auto simp: SUP_upper less_SUP_iff incseq_def eventually_sequentially intro: less_le_trans)
  1466 
  1467 lemma LIMSEQ_INF:
  1468   "decseq X \<Longrightarrow> X ----> (INF i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1469   by (intro decreasing_tendsto)
  1470      (auto simp: INF_lower INF_less_iff decseq_def eventually_sequentially intro: le_less_trans)
  1471 
  1472 lemma LIMSEQ_ignore_initial_segment:
  1473   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
  1474   unfolding tendsto_def
  1475   by (subst eventually_sequentially_seg[where k=k])
  1476 
  1477 lemma LIMSEQ_offset:
  1478   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
  1479   unfolding tendsto_def
  1480   by (subst (asm) eventually_sequentially_seg[where k=k])
  1481 
  1482 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
  1483 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
  1484 
  1485 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
  1486 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
  1487 
  1488 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
  1489 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
  1490 
  1491 lemma LIMSEQ_unique:
  1492   fixes a b :: "'a::t2_space"
  1493   shows "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
  1494   using trivial_limit_sequentially by (rule tendsto_unique)
  1495 
  1496 lemma LIMSEQ_le_const:
  1497   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
  1498   using tendsto_le_const[of sequentially X x a] by (simp add: eventually_sequentially)
  1499 
  1500 lemma LIMSEQ_le:
  1501   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::'a::linorder_topology)"
  1502   using tendsto_le[of sequentially Y y X x] by (simp add: eventually_sequentially)
  1503 
  1504 lemma LIMSEQ_le_const2:
  1505   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
  1506   by (rule LIMSEQ_le[of X x "\<lambda>n. a"]) (auto simp: tendsto_const)
  1507 
  1508 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
  1509 by (simp add: convergent_def)
  1510 
  1511 lemma convergentI: "(X ----> L) ==> convergent X"
  1512 by (auto simp add: convergent_def)
  1513 
  1514 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
  1515 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
  1516 
  1517 lemma convergent_const: "convergent (\<lambda>n. c)"
  1518   by (rule convergentI, rule tendsto_const)
  1519 
  1520 lemma monoseq_le:
  1521   "monoseq a \<Longrightarrow> a ----> (x::'a::linorder_topology) \<Longrightarrow>
  1522     ((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
  1523   by (metis LIMSEQ_le_const LIMSEQ_le_const2 decseq_def incseq_def monoseq_iff)
  1524 
  1525 lemma LIMSEQ_subseq_LIMSEQ:
  1526   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
  1527   unfolding comp_def by (rule filterlim_compose[of X, OF _ filterlim_subseq])
  1528 
  1529 lemma convergent_subseq_convergent:
  1530   "\<lbrakk>convergent X; subseq f\<rbrakk> \<Longrightarrow> convergent (X o f)"
  1531   unfolding convergent_def by (auto intro: LIMSEQ_subseq_LIMSEQ)
  1532 
  1533 lemma limI: "X ----> L ==> lim X = L"
  1534 apply (simp add: lim_def)
  1535 apply (blast intro: LIMSEQ_unique)
  1536 done
  1537 
  1538 lemma lim_le: "convergent f \<Longrightarrow> (\<And>n. f n \<le> (x::'a::linorder_topology)) \<Longrightarrow> lim f \<le> x"
  1539   using LIMSEQ_le_const2[of f "lim f" x] by (simp add: convergent_LIMSEQ_iff)
  1540 
  1541 subsubsection{*Increasing and Decreasing Series*}
  1542 
  1543 lemma incseq_le: "incseq X \<Longrightarrow> X ----> L \<Longrightarrow> X n \<le> (L::'a::linorder_topology)"
  1544   by (metis incseq_def LIMSEQ_le_const)
  1545 
  1546 lemma decseq_le: "decseq X \<Longrightarrow> X ----> L \<Longrightarrow> (L::'a::linorder_topology) \<le> X n"
  1547   by (metis decseq_def LIMSEQ_le_const2)
  1548 
  1549 subsection {* First countable topologies *}
  1550 
  1551 class first_countable_topology = topological_space +
  1552   assumes first_countable_basis:
  1553     "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1554 
  1555 lemma (in first_countable_topology) countable_basis_at_decseq:
  1556   obtains A :: "nat \<Rightarrow> 'a set" where
  1557     "\<And>i. open (A i)" "\<And>i. x \<in> (A i)"
  1558     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1559 proof atomize_elim
  1560   from first_countable_basis[of x] obtain A :: "nat \<Rightarrow> 'a set" where
  1561     nhds: "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1562     and incl: "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"  by auto
  1563   def F \<equiv> "\<lambda>n. \<Inter>i\<le>n. A i"
  1564   show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and>
  1565       (\<forall>S. open S \<longrightarrow> x \<in> S \<longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially)"
  1566   proof (safe intro!: exI[of _ F])
  1567     fix i
  1568     show "open (F i)" using nhds(1) by (auto simp: F_def)
  1569     show "x \<in> F i" using nhds(2) by (auto simp: F_def)
  1570   next
  1571     fix S assume "open S" "x \<in> S"
  1572     from incl[OF this] obtain i where "F i \<subseteq> S" unfolding F_def by auto
  1573     moreover have "\<And>j. i \<le> j \<Longrightarrow> F j \<subseteq> F i"
  1574       by (auto simp: F_def)
  1575     ultimately show "eventually (\<lambda>i. F i \<subseteq> S) sequentially"
  1576       by (auto simp: eventually_sequentially)
  1577   qed
  1578 qed
  1579 
  1580 lemma (in first_countable_topology) countable_basis:
  1581   obtains A :: "nat \<Rightarrow> 'a set" where
  1582     "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1583     "\<And>F. (\<forall>n. F n \<in> A n) \<Longrightarrow> F ----> x"
  1584 proof atomize_elim
  1585   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1586     "\<And>i. open (A i)"
  1587     "\<And>i. x \<in> A i"
  1588     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1589     by (rule countable_basis_at_decseq) blast
  1590   {
  1591     fix F S assume "\<forall>n. F n \<in> A n" "open S" "x \<in> S"
  1592     with A(3)[of S] have "eventually (\<lambda>n. F n \<in> S) sequentially"
  1593       by (auto elim: eventually_elim1 simp: subset_eq)
  1594   }
  1595   with A show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and> (\<forall>F. (\<forall>n. F n \<in> A n) \<longrightarrow> F ----> x)"
  1596     by (intro exI[of _ A]) (auto simp: tendsto_def)
  1597 qed
  1598 
  1599 lemma (in first_countable_topology) sequentially_imp_eventually_nhds_within:
  1600   assumes "\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1601   shows "eventually P (inf (nhds a) (principal s))"
  1602 proof (rule ccontr)
  1603   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1604     "\<And>i. open (A i)"
  1605     "\<And>i. a \<in> A i"
  1606     "\<And>F. \<forall>n. F n \<in> A n \<Longrightarrow> F ----> a"
  1607     by (rule countable_basis) blast
  1608   assume "\<not> ?thesis"
  1609   with A have P: "\<exists>F. \<forall>n. F n \<in> s \<and> F n \<in> A n \<and> \<not> P (F n)"
  1610     unfolding eventually_inf_principal eventually_nhds by (intro choice) fastforce
  1611   then obtain F where F0: "\<forall>n. F n \<in> s" and F2: "\<forall>n. F n \<in> A n" and F3: "\<forall>n. \<not> P (F n)"
  1612     by blast
  1613   with A have "F ----> a" by auto
  1614   hence "eventually (\<lambda>n. P (F n)) sequentially"
  1615     using assms F0 by simp
  1616   thus "False" by (simp add: F3)
  1617 qed
  1618 
  1619 lemma (in first_countable_topology) eventually_nhds_within_iff_sequentially:
  1620   "eventually P (inf (nhds a) (principal s)) \<longleftrightarrow> 
  1621     (\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1622 proof (safe intro!: sequentially_imp_eventually_nhds_within)
  1623   assume "eventually P (inf (nhds a) (principal s))" 
  1624   then obtain S where "open S" "a \<in> S" "\<forall>x\<in>S. x \<in> s \<longrightarrow> P x"
  1625     by (auto simp: eventually_inf_principal eventually_nhds)
  1626   moreover fix f assume "\<forall>n. f n \<in> s" "f ----> a"
  1627   ultimately show "eventually (\<lambda>n. P (f n)) sequentially"
  1628     by (auto dest!: topological_tendstoD elim: eventually_elim1)
  1629 qed
  1630 
  1631 lemma (in first_countable_topology) eventually_nhds_iff_sequentially:
  1632   "eventually P (nhds a) \<longleftrightarrow> (\<forall>f. f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1633   using eventually_nhds_within_iff_sequentially[of P a UNIV] by simp
  1634 
  1635 subsection {* Function limit at a point *}
  1636 
  1637 abbreviation
  1638   LIM :: "('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
  1639         ("((_)/ -- (_)/ --> (_))" [60, 0, 60] 60) where
  1640   "f -- a --> L \<equiv> (f ---> L) (at a)"
  1641 
  1642 lemma tendsto_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> (f ---> l) (at a within S) \<longleftrightarrow> (f -- a --> l)"
  1643   unfolding tendsto_def by (simp add: at_within_open[where S=S])
  1644 
  1645 lemma LIM_const_not_eq[tendsto_intros]:
  1646   fixes a :: "'a::perfect_space"
  1647   fixes k L :: "'b::t2_space"
  1648   shows "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) -- a --> L"
  1649   by (simp add: tendsto_const_iff)
  1650 
  1651 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
  1652 
  1653 lemma LIM_const_eq:
  1654   fixes a :: "'a::perfect_space"
  1655   fixes k L :: "'b::t2_space"
  1656   shows "(\<lambda>x. k) -- a --> L \<Longrightarrow> k = L"
  1657   by (simp add: tendsto_const_iff)
  1658 
  1659 lemma LIM_unique:
  1660   fixes a :: "'a::perfect_space" and L M :: "'b::t2_space"
  1661   shows "f -- a --> L \<Longrightarrow> f -- a --> M \<Longrightarrow> L = M"
  1662   using at_neq_bot by (rule tendsto_unique)
  1663 
  1664 text {* Limits are equal for functions equal except at limit point *}
  1665 
  1666 lemma LIM_equal: "\<forall>x. x \<noteq> a --> (f x = g x) \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- a --> l)"
  1667   unfolding tendsto_def eventually_at_topological by simp
  1668 
  1669 lemma LIM_cong: "a = b \<Longrightarrow> (\<And>x. x \<noteq> b \<Longrightarrow> f x = g x) \<Longrightarrow> l = m \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- b --> m)"
  1670   by (simp add: LIM_equal)
  1671 
  1672 lemma LIM_cong_limit: "f -- x --> L \<Longrightarrow> K = L \<Longrightarrow> f -- x --> K"
  1673   by simp
  1674 
  1675 lemma tendsto_at_iff_tendsto_nhds:
  1676   "g -- l --> g l \<longleftrightarrow> (g ---> g l) (nhds l)"
  1677   unfolding tendsto_def eventually_at_filter
  1678   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
  1679 
  1680 lemma tendsto_compose:
  1681   "g -- l --> g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  1682   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
  1683 
  1684 lemma LIM_o: "\<lbrakk>g -- l --> g l; f -- a --> l\<rbrakk> \<Longrightarrow> (g \<circ> f) -- a --> g l"
  1685   unfolding o_def by (rule tendsto_compose)
  1686 
  1687 lemma tendsto_compose_eventually:
  1688   "g -- l --> m \<Longrightarrow> (f ---> l) F \<Longrightarrow> eventually (\<lambda>x. f x \<noteq> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> m) F"
  1689   by (rule filterlim_compose[of g _ "at l"]) (auto simp add: filterlim_at)
  1690 
  1691 lemma LIM_compose_eventually:
  1692   assumes f: "f -- a --> b"
  1693   assumes g: "g -- b --> c"
  1694   assumes inj: "eventually (\<lambda>x. f x \<noteq> b) (at a)"
  1695   shows "(\<lambda>x. g (f x)) -- a --> c"
  1696   using g f inj by (rule tendsto_compose_eventually)
  1697 
  1698 subsubsection {* Relation of LIM and LIMSEQ *}
  1699 
  1700 lemma (in first_countable_topology) sequentially_imp_eventually_within:
  1701   "(\<forall>f. (\<forall>n. f n \<in> s \<and> f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow>
  1702     eventually P (at a within s)"
  1703   unfolding at_within_def
  1704   by (intro sequentially_imp_eventually_nhds_within) auto
  1705 
  1706 lemma (in first_countable_topology) sequentially_imp_eventually_at:
  1707   "(\<forall>f. (\<forall>n. f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow> eventually P (at a)"
  1708   using assms sequentially_imp_eventually_within [where s=UNIV] by simp
  1709 
  1710 lemma LIMSEQ_SEQ_conv1:
  1711   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1712   assumes f: "f -- a --> l"
  1713   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1714   using tendsto_compose_eventually [OF f, where F=sequentially] by simp
  1715 
  1716 lemma LIMSEQ_SEQ_conv2:
  1717   fixes f :: "'a::first_countable_topology \<Rightarrow> 'b::topological_space"
  1718   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1719   shows "f -- a --> l"
  1720   using assms unfolding tendsto_def [where l=l] by (simp add: sequentially_imp_eventually_at)
  1721 
  1722 lemma LIMSEQ_SEQ_conv:
  1723   "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> (a::'a::first_countable_topology) \<longrightarrow> (\<lambda>n. X (S n)) ----> L) =
  1724    (X -- a --> (L::'b::topological_space))"
  1725   using LIMSEQ_SEQ_conv2 LIMSEQ_SEQ_conv1 ..
  1726 
  1727 subsection {* Continuity *}
  1728 
  1729 subsubsection {* Continuity on a set *}
  1730 
  1731 definition continuous_on :: "'a set \<Rightarrow> ('a :: topological_space \<Rightarrow> 'b :: topological_space) \<Rightarrow> bool" where
  1732   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f ---> f x) (at x within s))"
  1733 
  1734 lemma continuous_on_cong [cong]:
  1735   "s = t \<Longrightarrow> (\<And>x. x \<in> t \<Longrightarrow> f x = g x) \<Longrightarrow> continuous_on s f \<longleftrightarrow> continuous_on t g"
  1736   unfolding continuous_on_def by (intro ball_cong filterlim_cong) (auto simp: eventually_at_filter)
  1737 
  1738 lemma continuous_on_topological:
  1739   "continuous_on s f \<longleftrightarrow>
  1740     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1741   unfolding continuous_on_def tendsto_def eventually_at_topological by metis
  1742 
  1743 lemma continuous_on_open_invariant:
  1744   "continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s))"
  1745 proof safe
  1746   fix B :: "'b set" assume "continuous_on s f" "open B"
  1747   then have "\<forall>x\<in>f -` B \<inter> s. (\<exists>A. open A \<and> x \<in> A \<and> s \<inter> A \<subseteq> f -` B)"
  1748     by (auto simp: continuous_on_topological subset_eq Ball_def imp_conjL)
  1749   then obtain A where "\<forall>x\<in>f -` B \<inter> s. open (A x) \<and> x \<in> A x \<and> s \<inter> A x \<subseteq> f -` B"
  1750     unfolding bchoice_iff ..
  1751   then show "\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s"
  1752     by (intro exI[of _ "\<Union>x\<in>f -` B \<inter> s. A x"]) auto
  1753 next
  1754   assume B: "\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s)"
  1755   show "continuous_on s f"
  1756     unfolding continuous_on_topological
  1757   proof safe
  1758     fix x B assume "x \<in> s" "open B" "f x \<in> B"
  1759     with B obtain A where A: "open A" "A \<inter> s = f -` B \<inter> s" by auto
  1760     with `x \<in> s` `f x \<in> B` show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  1761       by (intro exI[of _ A]) auto
  1762   qed
  1763 qed
  1764 
  1765 lemma continuous_on_open_vimage:
  1766   "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> open (f -` B \<inter> s))"
  1767   unfolding continuous_on_open_invariant
  1768   by (metis open_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1769 
  1770 corollary continuous_imp_open_vimage:
  1771   assumes "continuous_on s f" "open s" "open B" "f -` B \<subseteq> s"
  1772     shows "open (f -` B)"
  1773 by (metis assms continuous_on_open_vimage le_iff_inf)
  1774 
  1775 corollary open_vimage[continuous_intros]:
  1776   assumes "open s" and "continuous_on UNIV f"
  1777   shows "open (f -` s)"
  1778   using assms unfolding continuous_on_open_vimage [OF open_UNIV]
  1779   by simp
  1780 
  1781 lemma continuous_on_closed_invariant:
  1782   "continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> (\<exists>A. closed A \<and> A \<inter> s = f -` B \<inter> s))"
  1783 proof -
  1784   have *: "\<And>P Q::'b set\<Rightarrow>bool. (\<And>A. P A \<longleftrightarrow> Q (- A)) \<Longrightarrow> (\<forall>A. P A) \<longleftrightarrow> (\<forall>A. Q A)"
  1785     by (metis double_compl)
  1786   show ?thesis
  1787     unfolding continuous_on_open_invariant by (intro *) (auto simp: open_closed[symmetric])
  1788 qed
  1789 
  1790 lemma continuous_on_closed_vimage:
  1791   "closed s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> closed (f -` B \<inter> s))"
  1792   unfolding continuous_on_closed_invariant
  1793   by (metis closed_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1794 
  1795 corollary closed_vimage[continuous_intros]:
  1796   assumes "closed s" and "continuous_on UNIV f"
  1797   shows "closed (f -` s)"
  1798   using assms unfolding continuous_on_closed_vimage [OF closed_UNIV]
  1799   by simp
  1800 
  1801 lemma continuous_on_open_Union:
  1802   "(\<And>s. s \<in> S \<Longrightarrow> open s) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on s f) \<Longrightarrow> continuous_on (\<Union>S) f"
  1803   unfolding continuous_on_def by safe (metis open_Union at_within_open UnionI)
  1804 
  1805 lemma continuous_on_open_UN:
  1806   "(\<And>s. s \<in> S \<Longrightarrow> open (A s)) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on (A s) f) \<Longrightarrow> continuous_on (\<Union>s\<in>S. A s) f"
  1807   unfolding Union_image_eq[symmetric] by (rule continuous_on_open_Union) auto
  1808 
  1809 lemma continuous_on_closed_Un:
  1810   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  1811   by (auto simp add: continuous_on_closed_vimage closed_Un Int_Un_distrib)
  1812 
  1813 lemma continuous_on_If:
  1814   assumes closed: "closed s" "closed t" and cont: "continuous_on s f" "continuous_on t g"
  1815     and P: "\<And>x. x \<in> s \<Longrightarrow> \<not> P x \<Longrightarrow> f x = g x" "\<And>x. x \<in> t \<Longrightarrow> P x \<Longrightarrow> f x = g x"
  1816   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)" (is "continuous_on _ ?h")
  1817 proof-
  1818   from P have "\<forall>x\<in>s. f x = ?h x" "\<forall>x\<in>t. g x = ?h x"
  1819     by auto
  1820   with cont have "continuous_on s ?h" "continuous_on t ?h"
  1821     by simp_all
  1822   with closed show ?thesis
  1823     by (rule continuous_on_closed_Un)
  1824 qed
  1825 
  1826 lemma continuous_on_id[continuous_intros]: "continuous_on s (\<lambda>x. x)"
  1827   unfolding continuous_on_def by (fast intro: tendsto_ident_at)
  1828 
  1829 lemma continuous_on_const[continuous_intros]: "continuous_on s (\<lambda>x. c)"
  1830   unfolding continuous_on_def by (auto intro: tendsto_const)
  1831 
  1832 lemma continuous_on_compose[continuous_intros]:
  1833   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g o f)"
  1834   unfolding continuous_on_topological by simp metis
  1835 
  1836 lemma continuous_on_compose2:
  1837   "continuous_on t g \<Longrightarrow> continuous_on s f \<Longrightarrow> t = f ` s \<Longrightarrow> continuous_on s (\<lambda>x. g (f x))"
  1838   using continuous_on_compose[of s f g] by (simp add: comp_def)
  1839 
  1840 subsubsection {* Continuity at a point *}
  1841 
  1842 definition continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool" where
  1843   "continuous F f \<longleftrightarrow> (f ---> f (Lim F (\<lambda>x. x))) F"
  1844 
  1845 lemma continuous_bot[continuous_intros, simp]: "continuous bot f"
  1846   unfolding continuous_def by auto
  1847 
  1848 lemma continuous_trivial_limit: "trivial_limit net \<Longrightarrow> continuous net f"
  1849   by simp
  1850 
  1851 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f ---> f x) (at x within s)"
  1852   by (cases "trivial_limit (at x within s)") (auto simp add: Lim_ident_at continuous_def)
  1853 
  1854 lemma continuous_within_topological:
  1855   "continuous (at x within s) f \<longleftrightarrow>
  1856     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1857   unfolding continuous_within tendsto_def eventually_at_topological by metis
  1858 
  1859 lemma continuous_within_compose[continuous_intros]:
  1860   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1861   continuous (at x within s) (g o f)"
  1862   by (simp add: continuous_within_topological) metis
  1863 
  1864 lemma continuous_within_compose2:
  1865   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1866   continuous (at x within s) (\<lambda>x. g (f x))"
  1867   using continuous_within_compose[of x s f g] by (simp add: comp_def)
  1868 
  1869 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> f -- x --> f x"
  1870   using continuous_within[of x UNIV f] by simp
  1871 
  1872 lemma continuous_ident[continuous_intros, simp]: "continuous (at x within S) (\<lambda>x. x)"
  1873   unfolding continuous_within by (rule tendsto_ident_at)
  1874 
  1875 lemma continuous_const[continuous_intros, simp]: "continuous F (\<lambda>x. c)"
  1876   unfolding continuous_def by (rule tendsto_const)
  1877 
  1878 lemma continuous_on_eq_continuous_within:
  1879   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. continuous (at x within s) f)"
  1880   unfolding continuous_on_def continuous_within ..
  1881 
  1882 abbreviation isCont :: "('a::t2_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> bool" where
  1883   "isCont f a \<equiv> continuous (at a) f"
  1884 
  1885 lemma isCont_def: "isCont f a \<longleftrightarrow> f -- a --> f a"
  1886   by (rule continuous_at)
  1887 
  1888 lemma continuous_at_within: "isCont f x \<Longrightarrow> continuous (at x within s) f"
  1889   by (auto intro: tendsto_mono at_le simp: continuous_at continuous_within)
  1890 
  1891 lemma continuous_on_eq_continuous_at: "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. isCont f x)"
  1892   by (simp add: continuous_on_def continuous_at at_within_open[of _ s])
  1893 
  1894 lemma continuous_on_subset: "continuous_on s f \<Longrightarrow> t \<subseteq> s \<Longrightarrow> continuous_on t f"
  1895   unfolding continuous_on_def by (metis subset_eq tendsto_within_subset)
  1896 
  1897 lemma continuous_at_imp_continuous_on: "\<forall>x\<in>s. isCont f x \<Longrightarrow> continuous_on s f"
  1898   by (auto intro: continuous_at_within simp: continuous_on_eq_continuous_within)
  1899 
  1900 lemma isContI_continuous: "continuous (at x within UNIV) f \<Longrightarrow> isCont f x"
  1901   by simp
  1902 
  1903 lemma isCont_ident[continuous_intros, simp]: "isCont (\<lambda>x. x) a"
  1904   using continuous_ident by (rule isContI_continuous)
  1905 
  1906 lemmas isCont_const = continuous_const
  1907 
  1908 lemma isCont_o2: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
  1909   unfolding isCont_def by (rule tendsto_compose)
  1910 
  1911 lemma isCont_o[continuous_intros]: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (g \<circ> f) a"
  1912   unfolding o_def by (rule isCont_o2)
  1913 
  1914 lemma isCont_tendsto_compose: "isCont g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  1915   unfolding isCont_def by (rule tendsto_compose)
  1916 
  1917 lemma continuous_within_compose3:
  1918   "isCont g (f x) \<Longrightarrow> continuous (at x within s) f \<Longrightarrow> continuous (at x within s) (\<lambda>x. g (f x))"
  1919   using continuous_within_compose2[of x s f g] by (simp add: continuous_at_within)
  1920 
  1921 subsubsection{* Open-cover compactness *}
  1922 
  1923 context topological_space
  1924 begin
  1925 
  1926 definition compact :: "'a set \<Rightarrow> bool" where
  1927   compact_eq_heine_borel: -- "This name is used for backwards compatibility"
  1928     "compact S \<longleftrightarrow> (\<forall>C. (\<forall>c\<in>C. open c) \<and> S \<subseteq> \<Union>C \<longrightarrow> (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D))"
  1929 
  1930 lemma compactI:
  1931   assumes "\<And>C. \<forall>t\<in>C. open t \<Longrightarrow> s \<subseteq> \<Union> C \<Longrightarrow> \<exists>C'. C' \<subseteq> C \<and> finite C' \<and> s \<subseteq> \<Union> C'"
  1932   shows "compact s"
  1933   unfolding compact_eq_heine_borel using assms by metis
  1934 
  1935 lemma compact_empty[simp]: "compact {}"
  1936   by (auto intro!: compactI)
  1937 
  1938 lemma compactE:
  1939   assumes "compact s" and "\<forall>t\<in>C. open t" and "s \<subseteq> \<Union>C"
  1940   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> \<Union>C'"
  1941   using assms unfolding compact_eq_heine_borel by metis
  1942 
  1943 lemma compactE_image:
  1944   assumes "compact s" and "\<forall>t\<in>C. open (f t)" and "s \<subseteq> (\<Union>c\<in>C. f c)"
  1945   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> (\<Union>c\<in>C'. f c)"
  1946   using assms unfolding ball_simps[symmetric] SUP_def
  1947   by (metis (lifting) finite_subset_image compact_eq_heine_borel[of s])
  1948 
  1949 lemma compact_inter_closed [intro]:
  1950   assumes "compact s" and "closed t"
  1951   shows "compact (s \<inter> t)"
  1952 proof (rule compactI)
  1953   fix C assume C: "\<forall>c\<in>C. open c" and cover: "s \<inter> t \<subseteq> \<Union>C"
  1954   from C `closed t` have "\<forall>c\<in>C \<union> {-t}. open c" by auto
  1955   moreover from cover have "s \<subseteq> \<Union>(C \<union> {-t})" by auto
  1956   ultimately have "\<exists>D\<subseteq>C \<union> {-t}. finite D \<and> s \<subseteq> \<Union>D"
  1957     using `compact s` unfolding compact_eq_heine_borel by auto
  1958   then obtain D where "D \<subseteq> C \<union> {- t} \<and> finite D \<and> s \<subseteq> \<Union>D" ..
  1959   then show "\<exists>D\<subseteq>C. finite D \<and> s \<inter> t \<subseteq> \<Union>D"
  1960     by (intro exI[of _ "D - {-t}"]) auto
  1961 qed
  1962 
  1963 lemma inj_setminus: "inj_on uminus (A::'a set set)"
  1964   by (auto simp: inj_on_def)
  1965 
  1966 lemma compact_fip:
  1967   "compact U \<longleftrightarrow>
  1968     (\<forall>A. (\<forall>a\<in>A. closed a) \<longrightarrow> (\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}) \<longrightarrow> U \<inter> \<Inter>A \<noteq> {})"
  1969   (is "_ \<longleftrightarrow> ?R")
  1970 proof (safe intro!: compact_eq_heine_borel[THEN iffD2])
  1971   fix A
  1972   assume "compact U"
  1973     and A: "\<forall>a\<in>A. closed a" "U \<inter> \<Inter>A = {}"
  1974     and fi: "\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}"
  1975   from A have "(\<forall>a\<in>uminus`A. open a) \<and> U \<subseteq> \<Union>(uminus`A)"
  1976     by auto
  1977   with `compact U` obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<subseteq> \<Union>(uminus`B)"
  1978     unfolding compact_eq_heine_borel by (metis subset_image_iff)
  1979   with fi[THEN spec, of B] show False
  1980     by (auto dest: finite_imageD intro: inj_setminus)
  1981 next
  1982   fix A
  1983   assume ?R
  1984   assume "\<forall>a\<in>A. open a" "U \<subseteq> \<Union>A"
  1985   then have "U \<inter> \<Inter>(uminus`A) = {}" "\<forall>a\<in>uminus`A. closed a"
  1986     by auto
  1987   with `?R` obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<inter> \<Inter>(uminus`B) = {}"
  1988     by (metis subset_image_iff)
  1989   then show "\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T"
  1990     by  (auto intro!: exI[of _ B] inj_setminus dest: finite_imageD)
  1991 qed
  1992 
  1993 lemma compact_imp_fip:
  1994   "compact s \<Longrightarrow> \<forall>t \<in> f. closed t \<Longrightarrow> \<forall>f'. finite f' \<and> f' \<subseteq> f \<longrightarrow> (s \<inter> (\<Inter> f') \<noteq> {}) \<Longrightarrow>
  1995     s \<inter> (\<Inter> f) \<noteq> {}"
  1996   unfolding compact_fip by auto
  1997 
  1998 lemma compact_imp_fip_image:
  1999   assumes "compact s"
  2000     and P: "\<And>i. i \<in> I \<Longrightarrow> closed (f i)"
  2001     and Q: "\<And>I'. finite I' \<Longrightarrow> I' \<subseteq> I \<Longrightarrow> (s \<inter> (\<Inter>i\<in>I'. f i) \<noteq> {})"
  2002   shows "s \<inter> (\<Inter>i\<in>I. f i) \<noteq> {}"
  2003 proof -
  2004   note `compact s`
  2005   moreover from P have "\<forall>i \<in> f ` I. closed i" by blast
  2006   moreover have "\<forall>A. finite A \<and> A \<subseteq> f ` I \<longrightarrow> (s \<inter> (\<Inter>A) \<noteq> {})"
  2007   proof (rule, rule, erule conjE)
  2008     fix A :: "'a set set"
  2009     assume "finite A"
  2010     moreover assume "A \<subseteq> f ` I"
  2011     ultimately obtain B where "B \<subseteq> I" and "finite B" and "A = f ` B"
  2012       using finite_subset_image [of A f I] by blast
  2013     with Q [of B] show "s \<inter> \<Inter>A \<noteq> {}" by simp
  2014   qed
  2015   ultimately have "s \<inter> (\<Inter>(f ` I)) \<noteq> {}" by (rule compact_imp_fip)
  2016   then show ?thesis by simp
  2017 qed
  2018 
  2019 end
  2020 
  2021 lemma (in t2_space) compact_imp_closed:
  2022   assumes "compact s" shows "closed s"
  2023 unfolding closed_def
  2024 proof (rule openI)
  2025   fix y assume "y \<in> - s"
  2026   let ?C = "\<Union>x\<in>s. {u. open u \<and> x \<in> u \<and> eventually (\<lambda>y. y \<notin> u) (nhds y)}"
  2027   note `compact s`
  2028   moreover have "\<forall>u\<in>?C. open u" by simp
  2029   moreover have "s \<subseteq> \<Union>?C"
  2030   proof
  2031     fix x assume "x \<in> s"
  2032     with `y \<in> - s` have "x \<noteq> y" by clarsimp
  2033     hence "\<exists>u v. open u \<and> open v \<and> x \<in> u \<and> y \<in> v \<and> u \<inter> v = {}"
  2034       by (rule hausdorff)
  2035     with `x \<in> s` show "x \<in> \<Union>?C"
  2036       unfolding eventually_nhds by auto
  2037   qed
  2038   ultimately obtain D where "D \<subseteq> ?C" and "finite D" and "s \<subseteq> \<Union>D"
  2039     by (rule compactE)
  2040   from `D \<subseteq> ?C` have "\<forall>x\<in>D. eventually (\<lambda>y. y \<notin> x) (nhds y)" by auto
  2041   with `finite D` have "eventually (\<lambda>y. y \<notin> \<Union>D) (nhds y)"
  2042     by (simp add: eventually_Ball_finite)
  2043   with `s \<subseteq> \<Union>D` have "eventually (\<lambda>y. y \<notin> s) (nhds y)"
  2044     by (auto elim!: eventually_mono [rotated])
  2045   thus "\<exists>t. open t \<and> y \<in> t \<and> t \<subseteq> - s"
  2046     by (simp add: eventually_nhds subset_eq)
  2047 qed
  2048 
  2049 lemma compact_continuous_image:
  2050   assumes f: "continuous_on s f" and s: "compact s"
  2051   shows "compact (f ` s)"
  2052 proof (rule compactI)
  2053   fix C assume "\<forall>c\<in>C. open c" and cover: "f`s \<subseteq> \<Union>C"
  2054   with f have "\<forall>c\<in>C. \<exists>A. open A \<and> A \<inter> s = f -` c \<inter> s"
  2055     unfolding continuous_on_open_invariant by blast
  2056   then obtain A where A: "\<forall>c\<in>C. open (A c) \<and> A c \<inter> s = f -` c \<inter> s"
  2057     unfolding bchoice_iff ..
  2058   with cover have "\<forall>c\<in>C. open (A c)" "s \<subseteq> (\<Union>c\<in>C. A c)"
  2059     by (fastforce simp add: subset_eq set_eq_iff)+
  2060   from compactE_image[OF s this] obtain D where "D \<subseteq> C" "finite D" "s \<subseteq> (\<Union>c\<in>D. A c)" .
  2061   with A show "\<exists>D \<subseteq> C. finite D \<and> f`s \<subseteq> \<Union>D"
  2062     by (intro exI[of _ D]) (fastforce simp add: subset_eq set_eq_iff)+
  2063 qed
  2064 
  2065 lemma continuous_on_inv:
  2066   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2067   assumes "continuous_on s f"  "compact s"  "\<forall>x\<in>s. g (f x) = x"
  2068   shows "continuous_on (f ` s) g"
  2069 unfolding continuous_on_topological
  2070 proof (clarsimp simp add: assms(3))
  2071   fix x :: 'a and B :: "'a set"
  2072   assume "x \<in> s" and "open B" and "x \<in> B"
  2073   have 1: "\<forall>x\<in>s. f x \<in> f ` (s - B) \<longleftrightarrow> x \<in> s - B"
  2074     using assms(3) by (auto, metis)
  2075   have "continuous_on (s - B) f"
  2076     using `continuous_on s f` Diff_subset
  2077     by (rule continuous_on_subset)
  2078   moreover have "compact (s - B)"
  2079     using `open B` and `compact s`
  2080     unfolding Diff_eq by (intro compact_inter_closed closed_Compl)
  2081   ultimately have "compact (f ` (s - B))"
  2082     by (rule compact_continuous_image)
  2083   hence "closed (f ` (s - B))"
  2084     by (rule compact_imp_closed)
  2085   hence "open (- f ` (s - B))"
  2086     by (rule open_Compl)
  2087   moreover have "f x \<in> - f ` (s - B)"
  2088     using `x \<in> s` and `x \<in> B` by (simp add: 1)
  2089   moreover have "\<forall>y\<in>s. f y \<in> - f ` (s - B) \<longrightarrow> y \<in> B"
  2090     by (simp add: 1)
  2091   ultimately show "\<exists>A. open A \<and> f x \<in> A \<and> (\<forall>y\<in>s. f y \<in> A \<longrightarrow> y \<in> B)"
  2092     by fast
  2093 qed
  2094 
  2095 lemma continuous_on_inv_into:
  2096   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2097   assumes s: "continuous_on s f" "compact s" and f: "inj_on f s"
  2098   shows "continuous_on (f ` s) (the_inv_into s f)"
  2099   by (rule continuous_on_inv[OF s]) (auto simp: the_inv_into_f_f[OF f])
  2100 
  2101 lemma (in linorder_topology) compact_attains_sup:
  2102   assumes "compact S" "S \<noteq> {}"
  2103   shows "\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s"
  2104 proof (rule classical)
  2105   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s)"
  2106   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. s < t s"
  2107     by (metis not_le)
  2108   then have "\<forall>s\<in>S. open {..< t s}" "S \<subseteq> (\<Union>s\<in>S. {..< t s})"
  2109     by auto
  2110   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {..< t s})"
  2111     by (erule compactE_image)
  2112   with `S \<noteq> {}` have Max: "Max (t`C) \<in> t`C" and "\<forall>s\<in>t`C. s \<le> Max (t`C)"
  2113     by (auto intro!: Max_in)
  2114   with C have "S \<subseteq> {..< Max (t`C)}"
  2115     by (auto intro: less_le_trans simp: subset_eq)
  2116   with t Max `C \<subseteq> S` show ?thesis
  2117     by fastforce
  2118 qed
  2119 
  2120 lemma (in linorder_topology) compact_attains_inf:
  2121   assumes "compact S" "S \<noteq> {}"
  2122   shows "\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t"
  2123 proof (rule classical)
  2124   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t)"
  2125   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. t s < s"
  2126     by (metis not_le)
  2127   then have "\<forall>s\<in>S. open {t s <..}" "S \<subseteq> (\<Union>s\<in>S. {t s <..})"
  2128     by auto
  2129   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {t s <..})"
  2130     by (erule compactE_image)
  2131   with `S \<noteq> {}` have Min: "Min (t`C) \<in> t`C" and "\<forall>s\<in>t`C. Min (t`C) \<le> s"
  2132     by (auto intro!: Min_in)
  2133   with C have "S \<subseteq> {Min (t`C) <..}"
  2134     by (auto intro: le_less_trans simp: subset_eq)
  2135   with t Min `C \<subseteq> S` show ?thesis
  2136     by fastforce
  2137 qed
  2138 
  2139 lemma continuous_attains_sup:
  2140   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2141   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s.  f y \<le> f x)"
  2142   using compact_attains_sup[of "f ` s"] compact_continuous_image[of s f] by auto
  2143 
  2144 lemma continuous_attains_inf:
  2145   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2146   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s. f x \<le> f y)"
  2147   using compact_attains_inf[of "f ` s"] compact_continuous_image[of s f] by auto
  2148 
  2149 
  2150 subsection {* Connectedness *}
  2151 
  2152 context topological_space
  2153 begin
  2154 
  2155 definition "connected S \<longleftrightarrow>
  2156   \<not> (\<exists>A B. open A \<and> open B \<and> S \<subseteq> A \<union> B \<and> A \<inter> B \<inter> S = {} \<and> A \<inter> S \<noteq> {} \<and> B \<inter> S \<noteq> {})"
  2157 
  2158 lemma connectedI:
  2159   "(\<And>A B. open A \<Longrightarrow> open B \<Longrightarrow> A \<inter> U \<noteq> {} \<Longrightarrow> B \<inter> U \<noteq> {} \<Longrightarrow> A \<inter> B \<inter> U = {} \<Longrightarrow> U \<subseteq> A \<union> B \<Longrightarrow> False)
  2160   \<Longrightarrow> connected U"
  2161   by (auto simp: connected_def)
  2162 
  2163 lemma connected_empty[simp]: "connected {}"
  2164   by (auto intro!: connectedI)
  2165 
  2166 lemma connectedD:
  2167   "connected A \<Longrightarrow> open U \<Longrightarrow> open V \<Longrightarrow> U \<inter> V \<inter> A = {} \<Longrightarrow> A \<subseteq> U \<union> V \<Longrightarrow> U \<inter> A = {} \<or> V \<inter> A = {}" 
  2168   by (auto simp: connected_def)
  2169 
  2170 end
  2171 
  2172 lemma connected_local_const:
  2173   assumes "connected A" "a \<in> A" "b \<in> A"
  2174   assumes *: "\<forall>a\<in>A. eventually (\<lambda>b. f a = f b) (at a within A)"
  2175   shows "f a = f b"
  2176 proof -
  2177   obtain S where S: "\<And>a. a \<in> A \<Longrightarrow> a \<in> S a" "\<And>a. a \<in> A \<Longrightarrow> open (S a)"
  2178     "\<And>a x. a \<in> A \<Longrightarrow> x \<in> S a \<Longrightarrow> x \<in> A \<Longrightarrow> f a = f x"
  2179     using * unfolding eventually_at_topological by metis
  2180 
  2181   let ?P = "\<Union>b\<in>{b\<in>A. f a = f b}. S b" and ?N = "\<Union>b\<in>{b\<in>A. f a \<noteq> f b}. S b"
  2182   have "?P \<inter> A = {} \<or> ?N \<inter> A = {}"
  2183     using `connected A` S `a\<in>A`
  2184     by (intro connectedD) (auto, metis)
  2185   then show "f a = f b"
  2186   proof
  2187     assume "?N \<inter> A = {}"
  2188     then have "\<forall>x\<in>A. f a = f x"
  2189       using S(1) by auto
  2190     with `b\<in>A` show ?thesis by auto
  2191   next
  2192     assume "?P \<inter> A = {}" then show ?thesis
  2193       using `a \<in> A` S(1)[of a] by auto
  2194   qed
  2195 qed
  2196 
  2197 lemma (in linorder_topology) connectedD_interval:
  2198   assumes "connected U" and xy: "x \<in> U" "y \<in> U" and "x \<le> z" "z \<le> y"
  2199   shows "z \<in> U"
  2200 proof -
  2201   have eq: "{..<z} \<union> {z<..} = - {z}"
  2202     by auto
  2203   { assume "z \<notin> U" "x < z" "z < y"
  2204     with xy have "\<not> connected U"
  2205       unfolding connected_def simp_thms
  2206       apply (rule_tac exI[of _ "{..< z}"])
  2207       apply (rule_tac exI[of _ "{z <..}"])
  2208       apply (auto simp add: eq)
  2209       done }
  2210   with assms show "z \<in> U"
  2211     by (metis less_le)
  2212 qed
  2213 
  2214 lemma connected_continuous_image:
  2215   assumes *: "continuous_on s f"
  2216   assumes "connected s"
  2217   shows "connected (f ` s)"
  2218 proof (rule connectedI)
  2219   fix A B assume A: "open A" "A \<inter> f ` s \<noteq> {}" and B: "open B" "B \<inter> f ` s \<noteq> {}" and
  2220     AB: "A \<inter> B \<inter> f ` s = {}" "f ` s \<subseteq> A \<union> B"
  2221   obtain A' where A': "open A'" "f -` A \<inter> s = A' \<inter> s"
  2222     using * `open A` unfolding continuous_on_open_invariant by metis
  2223   obtain B' where B': "open B'" "f -` B \<inter> s = B' \<inter> s"
  2224     using * `open B` unfolding continuous_on_open_invariant by metis
  2225 
  2226   have "\<exists>A B. open A \<and> open B \<and> s \<subseteq> A \<union> B \<and> A \<inter> B \<inter> s = {} \<and> A \<inter> s \<noteq> {} \<and> B \<inter> s \<noteq> {}"
  2227   proof (rule exI[of _ A'], rule exI[of _ B'], intro conjI)
  2228     have "s \<subseteq> (f -` A \<inter> s) \<union> (f -` B \<inter> s)" using AB by auto
  2229     then show "s \<subseteq> A' \<union> B'" using A' B' by auto
  2230   next
  2231     have "(f -` A \<inter> s) \<inter> (f -` B \<inter> s) = {}" using AB by auto
  2232     then show "A' \<inter> B' \<inter> s = {}" using A' B' by auto
  2233   qed (insert A' B' A B, auto)
  2234   with `connected s` show False
  2235     unfolding connected_def by blast
  2236 qed
  2237 
  2238 
  2239 section {* Connectedness *}
  2240 
  2241 class linear_continuum_topology = linorder_topology + linear_continuum
  2242 begin
  2243 
  2244 lemma Inf_notin_open:
  2245   assumes A: "open A" and bnd: "\<forall>a\<in>A. x < a"
  2246   shows "Inf A \<notin> A"
  2247 proof
  2248   assume "Inf A \<in> A"
  2249   then obtain b where "b < Inf A" "{b <.. Inf A} \<subseteq> A"
  2250     using open_left[of A "Inf A" x] assms by auto
  2251   with dense[of b "Inf A"] obtain c where "c < Inf A" "c \<in> A"
  2252     by (auto simp: subset_eq)
  2253   then show False
  2254     using cInf_lower[OF `c \<in> A`] bnd by (metis not_le less_imp_le bdd_belowI)
  2255 qed
  2256 
  2257 lemma Sup_notin_open:
  2258   assumes A: "open A" and bnd: "\<forall>a\<in>A. a < x"
  2259   shows "Sup A \<notin> A"
  2260 proof
  2261   assume "Sup A \<in> A"
  2262   then obtain b where "Sup A < b" "{Sup A ..< b} \<subseteq> A"
  2263     using open_right[of A "Sup A" x] assms by auto
  2264   with dense[of "Sup A" b] obtain c where "Sup A < c" "c \<in> A"
  2265     by (auto simp: subset_eq)
  2266   then show False
  2267     using cSup_upper[OF `c \<in> A`] bnd by (metis less_imp_le not_le bdd_aboveI)
  2268 qed
  2269 
  2270 end
  2271 
  2272 instance linear_continuum_topology \<subseteq> perfect_space
  2273 proof
  2274   fix x :: 'a
  2275   obtain y where "x < y \<or> y < x"
  2276     using ex_gt_or_lt [of x] ..
  2277   with Inf_notin_open[of "{x}" y] Sup_notin_open[of "{x}" y]
  2278   show "\<not> open {x}"
  2279     by auto
  2280 qed
  2281 
  2282 lemma connectedI_interval:
  2283   fixes U :: "'a :: linear_continuum_topology set"
  2284   assumes *: "\<And>x y z. x \<in> U \<Longrightarrow> y \<in> U \<Longrightarrow> x \<le> z \<Longrightarrow> z \<le> y \<Longrightarrow> z \<in> U"
  2285   shows "connected U"
  2286 proof (rule connectedI)
  2287   { fix A B assume "open A" "open B" "A \<inter> B \<inter> U = {}" "U \<subseteq> A \<union> B"
  2288     fix x y assume "x < y" "x \<in> A" "y \<in> B" "x \<in> U" "y \<in> U"
  2289 
  2290     let ?z = "Inf (B \<inter> {x <..})"
  2291 
  2292     have "x \<le> ?z" "?z \<le> y"
  2293       using `y \<in> B` `x < y` by (auto intro: cInf_lower cInf_greatest)
  2294     with `x \<in> U` `y \<in> U` have "?z \<in> U"
  2295       by (rule *)
  2296     moreover have "?z \<notin> B \<inter> {x <..}"
  2297       using `open B` by (intro Inf_notin_open) auto
  2298     ultimately have "?z \<in> A"
  2299       using `x \<le> ?z` `A \<inter> B \<inter> U = {}` `x \<in> A` `U \<subseteq> A \<union> B` by auto
  2300 
  2301     { assume "?z < y"
  2302       obtain a where "?z < a" "{?z ..< a} \<subseteq> A"
  2303         using open_right[OF `open A` `?z \<in> A` `?z < y`] by auto
  2304       moreover obtain b where "b \<in> B" "x < b" "b < min a y"
  2305         using cInf_less_iff[of "B \<inter> {x <..}" "min a y"] `?z < a` `?z < y` `x < y` `y \<in> B`
  2306         by (auto intro: less_imp_le)
  2307       moreover have "?z \<le> b"
  2308         using `b \<in> B` `x < b`
  2309         by (intro cInf_lower) auto
  2310       moreover have "b \<in> U"
  2311         using `x \<le> ?z` `?z \<le> b` `b < min a y`
  2312         by (intro *[OF `x \<in> U` `y \<in> U`]) (auto simp: less_imp_le)
  2313       ultimately have "\<exists>b\<in>B. b \<in> A \<and> b \<in> U"
  2314         by (intro bexI[of _ b]) auto }
  2315     then have False
  2316       using `?z \<le> y` `?z \<in> A` `y \<in> B` `y \<in> U` `A \<inter> B \<inter> U = {}` unfolding le_less by blast }
  2317   note not_disjoint = this
  2318 
  2319   fix A B assume AB: "open A" "open B" "U \<subseteq> A \<union> B" "A \<inter> B \<inter> U = {}"
  2320   moreover assume "A \<inter> U \<noteq> {}" then obtain x where x: "x \<in> U" "x \<in> A" by auto
  2321   moreover assume "B \<inter> U \<noteq> {}" then obtain y where y: "y \<in> U" "y \<in> B" by auto
  2322   moreover note not_disjoint[of B A y x] not_disjoint[of A B x y]
  2323   ultimately show False by (cases x y rule: linorder_cases) auto
  2324 qed
  2325 
  2326 lemma connected_iff_interval:
  2327   fixes U :: "'a :: linear_continuum_topology set"
  2328   shows "connected U \<longleftrightarrow> (\<forall>x\<in>U. \<forall>y\<in>U. \<forall>z. x \<le> z \<longrightarrow> z \<le> y \<longrightarrow> z \<in> U)"
  2329   by (auto intro: connectedI_interval dest: connectedD_interval)
  2330 
  2331 lemma connected_UNIV[simp]: "connected (UNIV::'a::linear_continuum_topology set)"
  2332   unfolding connected_iff_interval by auto
  2333 
  2334 lemma connected_Ioi[simp]: "connected {a::'a::linear_continuum_topology <..}"
  2335   unfolding connected_iff_interval by auto
  2336 
  2337 lemma connected_Ici[simp]: "connected {a::'a::linear_continuum_topology ..}"
  2338   unfolding connected_iff_interval by auto
  2339 
  2340 lemma connected_Iio[simp]: "connected {..< a::'a::linear_continuum_topology}"
  2341   unfolding connected_iff_interval by auto
  2342 
  2343 lemma connected_Iic[simp]: "connected {.. a::'a::linear_continuum_topology}"
  2344   unfolding connected_iff_interval by auto
  2345 
  2346 lemma connected_Ioo[simp]: "connected {a <..< b::'a::linear_continuum_topology}"
  2347   unfolding connected_iff_interval by auto
  2348 
  2349 lemma connected_Ioc[simp]: "connected {a <.. b::'a::linear_continuum_topology}"
  2350   unfolding connected_iff_interval by auto
  2351 
  2352 lemma connected_Ico[simp]: "connected {a ..< b::'a::linear_continuum_topology}"
  2353   unfolding connected_iff_interval by auto
  2354 
  2355 lemma connected_Icc[simp]: "connected {a .. b::'a::linear_continuum_topology}"
  2356   unfolding connected_iff_interval by auto
  2357 
  2358 lemma connected_contains_Ioo: 
  2359   fixes A :: "'a :: linorder_topology set"
  2360   assumes A: "connected A" "a \<in> A" "b \<in> A" shows "{a <..< b} \<subseteq> A"
  2361   using connectedD_interval[OF A] by (simp add: subset_eq Ball_def less_imp_le)
  2362 
  2363 subsection {* Intermediate Value Theorem *}
  2364 
  2365 lemma IVT':
  2366   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2367   assumes y: "f a \<le> y" "y \<le> f b" "a \<le> b"
  2368   assumes *: "continuous_on {a .. b} f"
  2369   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2370 proof -
  2371   have "connected {a..b}"
  2372     unfolding connected_iff_interval by auto
  2373   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f a" "f b" y] y
  2374   show ?thesis
  2375     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2376 qed
  2377 
  2378 lemma IVT2':
  2379   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2380   assumes y: "f b \<le> y" "y \<le> f a" "a \<le> b"
  2381   assumes *: "continuous_on {a .. b} f"
  2382   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2383 proof -
  2384   have "connected {a..b}"
  2385     unfolding connected_iff_interval by auto
  2386   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f b" "f a" y] y
  2387   show ?thesis
  2388     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2389 qed
  2390 
  2391 lemma IVT:
  2392   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2393   shows "f a \<le> y \<Longrightarrow> y \<le> f b \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2394   by (rule IVT') (auto intro: continuous_at_imp_continuous_on)
  2395 
  2396 lemma IVT2:
  2397   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2398   shows "f b \<le> y \<Longrightarrow> y \<le> f a \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2399   by (rule IVT2') (auto intro: continuous_at_imp_continuous_on)
  2400 
  2401 lemma continuous_inj_imp_mono:
  2402   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2403   assumes x: "a < x" "x < b"
  2404   assumes cont: "continuous_on {a..b} f"
  2405   assumes inj: "inj_on f {a..b}"
  2406   shows "(f a < f x \<and> f x < f b) \<or> (f b < f x \<and> f x < f a)"
  2407 proof -
  2408   note I = inj_on_iff[OF inj]
  2409   { assume "f x < f a" "f x < f b"
  2410     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f x < f s"
  2411       using IVT'[of f x "min (f a) (f b)" b] IVT2'[of f x "min (f a) (f b)" a] x
  2412       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2413     with x I have False by auto }
  2414   moreover
  2415   { assume "f a < f x" "f b < f x"
  2416     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f s < f x"
  2417       using IVT'[of f a "max (f a) (f b)" x] IVT2'[of f b "max (f a) (f b)" x] x
  2418       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2419     with x I have False by auto }
  2420   ultimately show ?thesis
  2421     using I[of a x] I[of x b] x less_trans[OF x] by (auto simp add: le_less less_imp_neq neq_iff)
  2422 qed
  2423 
  2424 subsection {* Setup @{typ "'a filter"} for lifting and transfer *}
  2425 
  2426 context begin interpretation lifting_syntax .
  2427 
  2428 definition rel_filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> 'b filter \<Rightarrow> bool"
  2429 where "rel_filter R F G = ((R ===> op =) ===> op =) (Rep_filter F) (Rep_filter G)"
  2430 
  2431 lemma rel_filter_eventually:
  2432   "rel_filter R F G \<longleftrightarrow> 
  2433   ((R ===> op =) ===> op =) (\<lambda>P. eventually P F) (\<lambda>P. eventually P G)"
  2434 by(simp add: rel_filter_def eventually_def)
  2435 
  2436 lemma filtermap_id [simp, id_simps]: "filtermap id = id"
  2437 by(simp add: fun_eq_iff id_def filtermap_ident)
  2438 
  2439 lemma filtermap_id' [simp]: "filtermap (\<lambda>x. x) = (\<lambda>F. F)"
  2440 using filtermap_id unfolding id_def .
  2441 
  2442 lemma Quotient_filter [quot_map]:
  2443   assumes Q: "Quotient R Abs Rep T"
  2444   shows "Quotient (rel_filter R) (filtermap Abs) (filtermap Rep) (rel_filter T)"
  2445 unfolding Quotient_alt_def
  2446 proof(intro conjI strip)
  2447   from Q have *: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
  2448     unfolding Quotient_alt_def by blast
  2449 
  2450   fix F G
  2451   assume "rel_filter T F G"
  2452   thus "filtermap Abs F = G" unfolding filter_eq_iff
  2453     by(auto simp add: eventually_filtermap rel_filter_eventually * rel_funI del: iffI elim!: rel_funD)
  2454 next
  2455   from Q have *: "\<And>x. T (Rep x) x" unfolding Quotient_alt_def by blast
  2456 
  2457   fix F
  2458   show "rel_filter T (filtermap Rep F) F" 
  2459     by(auto elim: rel_funD intro: * intro!: ext arg_cong[where f="\<lambda>P. eventually P F"] rel_funI
  2460             del: iffI simp add: eventually_filtermap rel_filter_eventually)
  2461 qed(auto simp add: map_fun_def o_def eventually_filtermap filter_eq_iff fun_eq_iff rel_filter_eventually
  2462          fun_quotient[OF fun_quotient[OF Q identity_quotient] identity_quotient, unfolded Quotient_alt_def])
  2463 
  2464 lemma eventually_parametric [transfer_rule]:
  2465   "((A ===> op =) ===> rel_filter A ===> op =) eventually eventually"
  2466 by(simp add: rel_fun_def rel_filter_eventually)
  2467 
  2468 lemma rel_filter_eq [relator_eq]: "rel_filter op = = op ="
  2469 by(auto simp add: rel_filter_eventually rel_fun_eq fun_eq_iff filter_eq_iff)
  2470 
  2471 lemma rel_filter_mono [relator_mono]:
  2472   "A \<le> B \<Longrightarrow> rel_filter A \<le> rel_filter B"
  2473 unfolding rel_filter_eventually[abs_def]
  2474 by(rule le_funI)+(intro fun_mono fun_mono[THEN le_funD, THEN le_funD] order.refl)
  2475 
  2476 lemma rel_filter_conversep [simp]: "rel_filter A\<inverse>\<inverse> = (rel_filter A)\<inverse>\<inverse>"
  2477 by(auto simp add: rel_filter_eventually fun_eq_iff rel_fun_def)
  2478 
  2479 lemma is_filter_parametric_aux:
  2480   assumes "is_filter F"
  2481   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  2482   and [transfer_rule]: "((A ===> op =) ===> op =) F G"
  2483   shows "is_filter G"
  2484 proof -
  2485   interpret is_filter F by fact
  2486   show ?thesis
  2487   proof
  2488     have "F (\<lambda>_. True) = G (\<lambda>x. True)" by transfer_prover
  2489     thus "G (\<lambda>x. True)" by(simp add: True)
  2490   next
  2491     fix P' Q'
  2492     assume "G P'" "G Q'"
  2493     moreover
  2494     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
  2495     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  2496     have "F P = G P'" "F Q = G Q'" by transfer_prover+
  2497     ultimately have "F (\<lambda>x. P x \<and> Q x)" by(simp add: conj)
  2498     moreover have "F (\<lambda>x. P x \<and> Q x) = G (\<lambda>x. P' x \<and> Q' x)" by transfer_prover
  2499     ultimately show "G (\<lambda>x. P' x \<and> Q' x)" by simp
  2500   next
  2501     fix P' Q'
  2502     assume "\<forall>x. P' x \<longrightarrow> Q' x" "G P'"
  2503     moreover
  2504     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
  2505     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  2506     have "F P = G P'" by transfer_prover
  2507     moreover have "(\<forall>x. P x \<longrightarrow> Q x) \<longleftrightarrow> (\<forall>x. P' x \<longrightarrow> Q' x)" by transfer_prover
  2508     ultimately have "F Q" by(simp add: mono)
  2509     moreover have "F Q = G Q'" by transfer_prover
  2510     ultimately show "G Q'" by simp
  2511   qed
  2512 qed
  2513 
  2514 lemma is_filter_parametric [transfer_rule]:
  2515   "\<lbrakk> bi_total A; bi_unique A \<rbrakk>
  2516   \<Longrightarrow> (((A ===> op =) ===> op =) ===> op =) is_filter is_filter"
  2517 apply(rule rel_funI)
  2518 apply(rule iffI)
  2519  apply(erule (3) is_filter_parametric_aux)
  2520 apply(erule is_filter_parametric_aux[where A="conversep A"])
  2521 apply(auto simp add: rel_fun_def)
  2522 done
  2523 
  2524 lemma left_total_rel_filter [transfer_rule]:
  2525   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  2526   shows "left_total (rel_filter A)"
  2527 proof(rule left_totalI)
  2528   fix F :: "'a filter"
  2529   from bi_total_fun[OF bi_unique_fun[OF `bi_total A` bi_unique_eq] bi_total_eq]
  2530   obtain G where [transfer_rule]: "((A ===> op =) ===> op =) (\<lambda>P. eventually P F) G" 
  2531     unfolding  bi_total_def by blast
  2532   moreover have "is_filter (\<lambda>P. eventually P F) \<longleftrightarrow> is_filter G" by transfer_prover
  2533   hence "is_filter G" by(simp add: eventually_def is_filter_Rep_filter)
  2534   ultimately have "rel_filter A F (Abs_filter G)"
  2535     by(simp add: rel_filter_eventually eventually_Abs_filter)
  2536   thus "\<exists>G. rel_filter A F G" ..
  2537 qed
  2538 
  2539 lemma right_total_rel_filter [transfer_rule]:
  2540   "\<lbrakk> bi_total A; bi_unique A \<rbrakk> \<Longrightarrow> right_total (rel_filter A)"
  2541 using left_total_rel_filter[of "A\<inverse>\<inverse>"] by simp
  2542 
  2543 lemma bi_total_rel_filter [transfer_rule]:
  2544   assumes "bi_total A" "bi_unique A"
  2545   shows "bi_total (rel_filter A)"
  2546 unfolding bi_total_alt_def using assms
  2547 by(simp add: left_total_rel_filter right_total_rel_filter)
  2548 
  2549 lemma left_unique_rel_filter [transfer_rule]:
  2550   assumes "left_unique A"
  2551   shows "left_unique (rel_filter A)"
  2552 proof(rule left_uniqueI)
  2553   fix F F' G
  2554   assume [transfer_rule]: "rel_filter A F G" "rel_filter A F' G"
  2555   show "F = F'"
  2556     unfolding filter_eq_iff
  2557   proof
  2558     fix P :: "'a \<Rightarrow> bool"
  2559     obtain P' where [transfer_rule]: "(A ===> op =) P P'"
  2560       using left_total_fun[OF assms left_total_eq] unfolding left_total_def by blast
  2561     have "eventually P F = eventually P' G" 
  2562       and "eventually P F' = eventually P' G" by transfer_prover+
  2563     thus "eventually P F = eventually P F'" by simp
  2564   qed
  2565 qed
  2566 
  2567 lemma right_unique_rel_filter [transfer_rule]:
  2568   "right_unique A \<Longrightarrow> right_unique (rel_filter A)"
  2569 using left_unique_rel_filter[of "A\<inverse>\<inverse>"] by simp
  2570 
  2571 lemma bi_unique_rel_filter [transfer_rule]:
  2572   "bi_unique A \<Longrightarrow> bi_unique (rel_filter A)"
  2573 by(simp add: bi_unique_alt_def left_unique_rel_filter right_unique_rel_filter)
  2574 
  2575 lemma top_filter_parametric [transfer_rule]:
  2576   "bi_total A \<Longrightarrow> (rel_filter A) top top"
  2577 by(simp add: rel_filter_eventually All_transfer)
  2578 
  2579 lemma bot_filter_parametric [transfer_rule]: "(rel_filter A) bot bot"
  2580 by(simp add: rel_filter_eventually rel_fun_def)
  2581 
  2582 lemma sup_filter_parametric [transfer_rule]:
  2583   "(rel_filter A ===> rel_filter A ===> rel_filter A) sup sup"
  2584 by(fastforce simp add: rel_filter_eventually[abs_def] eventually_sup dest: rel_funD)
  2585 
  2586 lemma Sup_filter_parametric [transfer_rule]:
  2587   "(rel_set (rel_filter A) ===> rel_filter A) Sup Sup"
  2588 proof(rule rel_funI)
  2589   fix S T
  2590   assume [transfer_rule]: "rel_set (rel_filter A) S T"
  2591   show "rel_filter A (Sup S) (Sup T)"
  2592     by(simp add: rel_filter_eventually eventually_Sup) transfer_prover
  2593 qed
  2594 
  2595 lemma principal_parametric [transfer_rule]:
  2596   "(rel_set A ===> rel_filter A) principal principal"
  2597 proof(rule rel_funI)
  2598   fix S S'
  2599   assume [transfer_rule]: "rel_set A S S'"
  2600   show "rel_filter A (principal S) (principal S')"
  2601     by(simp add: rel_filter_eventually eventually_principal) transfer_prover
  2602 qed
  2603 
  2604 context
  2605   fixes A :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
  2606   assumes [transfer_rule]: "bi_unique A" 
  2607 begin
  2608 
  2609 lemma le_filter_parametric [transfer_rule]:
  2610   "(rel_filter A ===> rel_filter A ===> op =) op \<le> op \<le>"
  2611 unfolding le_filter_def[abs_def] by transfer_prover
  2612 
  2613 lemma less_filter_parametric [transfer_rule]:
  2614   "(rel_filter A ===> rel_filter A ===> op =) op < op <"
  2615 unfolding less_filter_def[abs_def] by transfer_prover
  2616 
  2617 context
  2618   assumes [transfer_rule]: "bi_total A"
  2619 begin
  2620 
  2621 lemma Inf_filter_parametric [transfer_rule]:
  2622   "(rel_set (rel_filter A) ===> rel_filter A) Inf Inf"
  2623 unfolding Inf_filter_def[abs_def] by transfer_prover
  2624 
  2625 lemma inf_filter_parametric [transfer_rule]:
  2626   "(rel_filter A ===> rel_filter A ===> rel_filter A) inf inf"
  2627 proof(intro rel_funI)+
  2628   fix F F' G G'
  2629   assume [transfer_rule]: "rel_filter A F F'" "rel_filter A G G'"
  2630   have "rel_filter A (Inf {F, G}) (Inf {F', G'})" by transfer_prover
  2631   thus "rel_filter A (inf F G) (inf F' G')" by simp
  2632 qed
  2633 
  2634 end
  2635 
  2636 end
  2637 
  2638 end
  2639 
  2640 end