src/HOL/Finite_Set.thy
author haftmann
Fri May 20 12:35:44 2011 +0200 (2011-05-20)
changeset 42875 d1aad0957eb2
parent 42873 da1253ff1764
child 43866 8a50dc70cbff
permissions -rw-r--r--
tuned proofs
     1 (*  Title:      HOL/Finite_Set.thy
     2     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     3                 with contributions by Jeremy Avigad
     4 *)
     5 
     6 header {* Finite sets *}
     7 
     8 theory Finite_Set
     9 imports Option Power
    10 begin
    11 
    12 subsection {* Predicate for finite sets *}
    13 
    14 inductive finite :: "'a set \<Rightarrow> bool"
    15   where
    16     emptyI [simp, intro!]: "finite {}"
    17   | insertI [simp, intro!]: "finite A \<Longrightarrow> finite (insert a A)"
    18 
    19 lemma finite_induct [case_names empty insert, induct set: finite]:
    20   -- {* Discharging @{text "x \<notin> F"} entails extra work. *}
    21   assumes "finite F"
    22   assumes "P {}"
    23     and insert: "\<And>x F. finite F \<Longrightarrow> x \<notin> F \<Longrightarrow> P F \<Longrightarrow> P (insert x F)"
    24   shows "P F"
    25 using `finite F` proof induct
    26   show "P {}" by fact
    27   fix x F assume F: "finite F" and P: "P F"
    28   show "P (insert x F)"
    29   proof cases
    30     assume "x \<in> F"
    31     hence "insert x F = F" by (rule insert_absorb)
    32     with P show ?thesis by (simp only:)
    33   next
    34     assume "x \<notin> F"
    35     from F this P show ?thesis by (rule insert)
    36   qed
    37 qed
    38 
    39 
    40 subsubsection {* Choice principles *}
    41 
    42 lemma ex_new_if_finite: -- "does not depend on def of finite at all"
    43   assumes "\<not> finite (UNIV :: 'a set)" and "finite A"
    44   shows "\<exists>a::'a. a \<notin> A"
    45 proof -
    46   from assms have "A \<noteq> UNIV" by blast
    47   then show ?thesis by blast
    48 qed
    49 
    50 text {* A finite choice principle. Does not need the SOME choice operator. *}
    51 
    52 lemma finite_set_choice:
    53   "finite A \<Longrightarrow> \<forall>x\<in>A. \<exists>y. P x y \<Longrightarrow> \<exists>f. \<forall>x\<in>A. P x (f x)"
    54 proof (induct rule: finite_induct)
    55   case empty then show ?case by simp
    56 next
    57   case (insert a A)
    58   then obtain f b where f: "ALL x:A. P x (f x)" and ab: "P a b" by auto
    59   show ?case (is "EX f. ?P f")
    60   proof
    61     show "?P(%x. if x = a then b else f x)" using f ab by auto
    62   qed
    63 qed
    64 
    65 
    66 subsubsection {* Finite sets are the images of initial segments of natural numbers *}
    67 
    68 lemma finite_imp_nat_seg_image_inj_on:
    69   assumes "finite A" 
    70   shows "\<exists>(n::nat) f. A = f ` {i. i < n} \<and> inj_on f {i. i < n}"
    71 using assms proof induct
    72   case empty
    73   show ?case
    74   proof
    75     show "\<exists>f. {} = f ` {i::nat. i < 0} \<and> inj_on f {i. i < 0}" by simp 
    76   qed
    77 next
    78   case (insert a A)
    79   have notinA: "a \<notin> A" by fact
    80   from insert.hyps obtain n f
    81     where "A = f ` {i::nat. i < n}" "inj_on f {i. i < n}" by blast
    82   hence "insert a A = f(n:=a) ` {i. i < Suc n}"
    83         "inj_on (f(n:=a)) {i. i < Suc n}" using notinA
    84     by (auto simp add: image_def Ball_def inj_on_def less_Suc_eq)
    85   thus ?case by blast
    86 qed
    87 
    88 lemma nat_seg_image_imp_finite:
    89   "A = f ` {i::nat. i < n} \<Longrightarrow> finite A"
    90 proof (induct n arbitrary: A)
    91   case 0 thus ?case by simp
    92 next
    93   case (Suc n)
    94   let ?B = "f ` {i. i < n}"
    95   have finB: "finite ?B" by(rule Suc.hyps[OF refl])
    96   show ?case
    97   proof cases
    98     assume "\<exists>k<n. f n = f k"
    99     hence "A = ?B" using Suc.prems by(auto simp:less_Suc_eq)
   100     thus ?thesis using finB by simp
   101   next
   102     assume "\<not>(\<exists> k<n. f n = f k)"
   103     hence "A = insert (f n) ?B" using Suc.prems by(auto simp:less_Suc_eq)
   104     thus ?thesis using finB by simp
   105   qed
   106 qed
   107 
   108 lemma finite_conv_nat_seg_image:
   109   "finite A \<longleftrightarrow> (\<exists>(n::nat) f. A = f ` {i::nat. i < n})"
   110   by (blast intro: nat_seg_image_imp_finite dest: finite_imp_nat_seg_image_inj_on)
   111 
   112 lemma finite_imp_inj_to_nat_seg:
   113   assumes "finite A"
   114   shows "\<exists>f n::nat. f ` A = {i. i < n} \<and> inj_on f A"
   115 proof -
   116   from finite_imp_nat_seg_image_inj_on[OF `finite A`]
   117   obtain f and n::nat where bij: "bij_betw f {i. i<n} A"
   118     by (auto simp:bij_betw_def)
   119   let ?f = "the_inv_into {i. i<n} f"
   120   have "inj_on ?f A & ?f ` A = {i. i<n}"
   121     by (fold bij_betw_def) (rule bij_betw_the_inv_into[OF bij])
   122   thus ?thesis by blast
   123 qed
   124 
   125 lemma finite_Collect_less_nat [iff]:
   126   "finite {n::nat. n < k}"
   127   by (fastsimp simp: finite_conv_nat_seg_image)
   128 
   129 lemma finite_Collect_le_nat [iff]:
   130   "finite {n::nat. n \<le> k}"
   131   by (simp add: le_eq_less_or_eq Collect_disj_eq)
   132 
   133 
   134 subsubsection {* Finiteness and common set operations *}
   135 
   136 lemma rev_finite_subset:
   137   "finite B \<Longrightarrow> A \<subseteq> B \<Longrightarrow> finite A"
   138 proof (induct arbitrary: A rule: finite_induct)
   139   case empty
   140   then show ?case by simp
   141 next
   142   case (insert x F A)
   143   have A: "A \<subseteq> insert x F" and r: "A - {x} \<subseteq> F \<Longrightarrow> finite (A - {x})" by fact+
   144   show "finite A"
   145   proof cases
   146     assume x: "x \<in> A"
   147     with A have "A - {x} \<subseteq> F" by (simp add: subset_insert_iff)
   148     with r have "finite (A - {x})" .
   149     hence "finite (insert x (A - {x}))" ..
   150     also have "insert x (A - {x}) = A" using x by (rule insert_Diff)
   151     finally show ?thesis .
   152   next
   153     show "A \<subseteq> F ==> ?thesis" by fact
   154     assume "x \<notin> A"
   155     with A show "A \<subseteq> F" by (simp add: subset_insert_iff)
   156   qed
   157 qed
   158 
   159 lemma finite_subset:
   160   "A \<subseteq> B \<Longrightarrow> finite B \<Longrightarrow> finite A"
   161   by (rule rev_finite_subset)
   162 
   163 lemma finite_UnI:
   164   assumes "finite F" and "finite G"
   165   shows "finite (F \<union> G)"
   166   using assms by induct simp_all
   167 
   168 lemma finite_Un [iff]:
   169   "finite (F \<union> G) \<longleftrightarrow> finite F \<and> finite G"
   170   by (blast intro: finite_UnI finite_subset [of _ "F \<union> G"])
   171 
   172 lemma finite_insert [simp]: "finite (insert a A) \<longleftrightarrow> finite A"
   173 proof -
   174   have "finite {a} \<and> finite A \<longleftrightarrow> finite A" by simp
   175   then have "finite ({a} \<union> A) \<longleftrightarrow> finite A" by (simp only: finite_Un)
   176   then show ?thesis by simp
   177 qed
   178 
   179 lemma finite_Int [simp, intro]:
   180   "finite F \<or> finite G \<Longrightarrow> finite (F \<inter> G)"
   181   by (blast intro: finite_subset)
   182 
   183 lemma finite_Collect_conjI [simp, intro]:
   184   "finite {x. P x} \<or> finite {x. Q x} \<Longrightarrow> finite {x. P x \<and> Q x}"
   185   by (simp add: Collect_conj_eq)
   186 
   187 lemma finite_Collect_disjI [simp]:
   188   "finite {x. P x \<or> Q x} \<longleftrightarrow> finite {x. P x} \<and> finite {x. Q x}"
   189   by (simp add: Collect_disj_eq)
   190 
   191 lemma finite_Diff [simp, intro]:
   192   "finite A \<Longrightarrow> finite (A - B)"
   193   by (rule finite_subset, rule Diff_subset)
   194 
   195 lemma finite_Diff2 [simp]:
   196   assumes "finite B"
   197   shows "finite (A - B) \<longleftrightarrow> finite A"
   198 proof -
   199   have "finite A \<longleftrightarrow> finite((A - B) \<union> (A \<inter> B))" by (simp add: Un_Diff_Int)
   200   also have "\<dots> \<longleftrightarrow> finite (A - B)" using `finite B` by simp
   201   finally show ?thesis ..
   202 qed
   203 
   204 lemma finite_Diff_insert [iff]:
   205   "finite (A - insert a B) \<longleftrightarrow> finite (A - B)"
   206 proof -
   207   have "finite (A - B) \<longleftrightarrow> finite (A - B - {a})" by simp
   208   moreover have "A - insert a B = A - B - {a}" by auto
   209   ultimately show ?thesis by simp
   210 qed
   211 
   212 lemma finite_compl[simp]:
   213   "finite (A :: 'a set) \<Longrightarrow> finite (- A) \<longleftrightarrow> finite (UNIV :: 'a set)"
   214   by (simp add: Compl_eq_Diff_UNIV)
   215 
   216 lemma finite_Collect_not[simp]:
   217   "finite {x :: 'a. P x} \<Longrightarrow> finite {x. \<not> P x} \<longleftrightarrow> finite (UNIV :: 'a set)"
   218   by (simp add: Collect_neg_eq)
   219 
   220 lemma finite_Union [simp, intro]:
   221   "finite A \<Longrightarrow> (\<And>M. M \<in> A \<Longrightarrow> finite M) \<Longrightarrow> finite(\<Union>A)"
   222   by (induct rule: finite_induct) simp_all
   223 
   224 lemma finite_UN_I [intro]:
   225   "finite A \<Longrightarrow> (\<And>a. a \<in> A \<Longrightarrow> finite (B a)) \<Longrightarrow> finite (\<Union>a\<in>A. B a)"
   226   by (induct rule: finite_induct) simp_all
   227 
   228 lemma finite_UN [simp]:
   229   "finite A \<Longrightarrow> finite (UNION A B) \<longleftrightarrow> (\<forall>x\<in>A. finite (B x))"
   230   by (blast intro: finite_subset)
   231 
   232 lemma finite_Inter [intro]:
   233   "\<exists>A\<in>M. finite A \<Longrightarrow> finite (\<Inter>M)"
   234   by (blast intro: Inter_lower finite_subset)
   235 
   236 lemma finite_INT [intro]:
   237   "\<exists>x\<in>I. finite (A x) \<Longrightarrow> finite (\<Inter>x\<in>I. A x)"
   238   by (blast intro: INT_lower finite_subset)
   239 
   240 lemma finite_imageI [simp, intro]:
   241   "finite F \<Longrightarrow> finite (h ` F)"
   242   by (induct rule: finite_induct) simp_all
   243 
   244 lemma finite_image_set [simp]:
   245   "finite {x. P x} \<Longrightarrow> finite { f x | x. P x }"
   246   by (simp add: image_Collect [symmetric])
   247 
   248 lemma finite_imageD:
   249   assumes "finite (f ` A)" and "inj_on f A"
   250   shows "finite A"
   251 using assms proof (induct "f ` A" arbitrary: A)
   252   case empty then show ?case by simp
   253 next
   254   case (insert x B)
   255   then have B_A: "insert x B = f ` A" by simp
   256   then obtain y where "x = f y" and "y \<in> A" by blast
   257   from B_A `x \<notin> B` have "B = f ` A - {x}" by blast
   258   with B_A `x \<notin> B` `x = f y` `inj_on f A` `y \<in> A` have "B = f ` (A - {y})" by (simp add: inj_on_image_set_diff)
   259   moreover from `inj_on f A` have "inj_on f (A - {y})" by (rule inj_on_diff)
   260   ultimately have "finite (A - {y})" by (rule insert.hyps)
   261   then show "finite A" by simp
   262 qed
   263 
   264 lemma finite_surj:
   265   "finite A \<Longrightarrow> B \<subseteq> f ` A \<Longrightarrow> finite B"
   266   by (erule finite_subset) (rule finite_imageI)
   267 
   268 lemma finite_range_imageI:
   269   "finite (range g) \<Longrightarrow> finite (range (\<lambda>x. f (g x)))"
   270   by (drule finite_imageI) (simp add: range_composition)
   271 
   272 lemma finite_subset_image:
   273   assumes "finite B"
   274   shows "B \<subseteq> f ` A \<Longrightarrow> \<exists>C\<subseteq>A. finite C \<and> B = f ` C"
   275 using assms proof induct
   276   case empty then show ?case by simp
   277 next
   278   case insert then show ?case
   279     by (clarsimp simp del: image_insert simp add: image_insert [symmetric])
   280        blast
   281 qed
   282 
   283 lemma finite_vimageI:
   284   "finite F \<Longrightarrow> inj h \<Longrightarrow> finite (h -` F)"
   285   apply (induct rule: finite_induct)
   286    apply simp_all
   287   apply (subst vimage_insert)
   288   apply (simp add: finite_subset [OF inj_vimage_singleton])
   289   done
   290 
   291 lemma finite_vimageD:
   292   assumes fin: "finite (h -` F)" and surj: "surj h"
   293   shows "finite F"
   294 proof -
   295   have "finite (h ` (h -` F))" using fin by (rule finite_imageI)
   296   also have "h ` (h -` F) = F" using surj by (rule surj_image_vimage_eq)
   297   finally show "finite F" .
   298 qed
   299 
   300 lemma finite_vimage_iff: "bij h \<Longrightarrow> finite (h -` F) \<longleftrightarrow> finite F"
   301   unfolding bij_def by (auto elim: finite_vimageD finite_vimageI)
   302 
   303 lemma finite_Collect_bex [simp]:
   304   assumes "finite A"
   305   shows "finite {x. \<exists>y\<in>A. Q x y} \<longleftrightarrow> (\<forall>y\<in>A. finite {x. Q x y})"
   306 proof -
   307   have "{x. \<exists>y\<in>A. Q x y} = (\<Union>y\<in>A. {x. Q x y})" by auto
   308   with assms show ?thesis by simp
   309 qed
   310 
   311 lemma finite_Collect_bounded_ex [simp]:
   312   assumes "finite {y. P y}"
   313   shows "finite {x. \<exists>y. P y \<and> Q x y} \<longleftrightarrow> (\<forall>y. P y \<longrightarrow> finite {x. Q x y})"
   314 proof -
   315   have "{x. EX y. P y & Q x y} = (\<Union>y\<in>{y. P y}. {x. Q x y})" by auto
   316   with assms show ?thesis by simp
   317 qed
   318 
   319 lemma finite_Plus:
   320   "finite A \<Longrightarrow> finite B \<Longrightarrow> finite (A <+> B)"
   321   by (simp add: Plus_def)
   322 
   323 lemma finite_PlusD: 
   324   fixes A :: "'a set" and B :: "'b set"
   325   assumes fin: "finite (A <+> B)"
   326   shows "finite A" "finite B"
   327 proof -
   328   have "Inl ` A \<subseteq> A <+> B" by auto
   329   then have "finite (Inl ` A :: ('a + 'b) set)" using fin by (rule finite_subset)
   330   then show "finite A" by (rule finite_imageD) (auto intro: inj_onI)
   331 next
   332   have "Inr ` B \<subseteq> A <+> B" by auto
   333   then have "finite (Inr ` B :: ('a + 'b) set)" using fin by (rule finite_subset)
   334   then show "finite B" by (rule finite_imageD) (auto intro: inj_onI)
   335 qed
   336 
   337 lemma finite_Plus_iff [simp]:
   338   "finite (A <+> B) \<longleftrightarrow> finite A \<and> finite B"
   339   by (auto intro: finite_PlusD finite_Plus)
   340 
   341 lemma finite_Plus_UNIV_iff [simp]:
   342   "finite (UNIV :: ('a + 'b) set) \<longleftrightarrow> finite (UNIV :: 'a set) \<and> finite (UNIV :: 'b set)"
   343   by (subst UNIV_Plus_UNIV [symmetric]) (rule finite_Plus_iff)
   344 
   345 lemma finite_SigmaI [simp, intro]:
   346   "finite A \<Longrightarrow> (\<And>a. a\<in>A \<Longrightarrow> finite (B a)) ==> finite (SIGMA a:A. B a)"
   347   by (unfold Sigma_def) blast
   348 
   349 lemma finite_cartesian_product:
   350   "finite A \<Longrightarrow> finite B \<Longrightarrow> finite (A \<times> B)"
   351   by (rule finite_SigmaI)
   352 
   353 lemma finite_Prod_UNIV:
   354   "finite (UNIV :: 'a set) \<Longrightarrow> finite (UNIV :: 'b set) \<Longrightarrow> finite (UNIV :: ('a \<times> 'b) set)"
   355   by (simp only: UNIV_Times_UNIV [symmetric] finite_cartesian_product)
   356 
   357 lemma finite_cartesian_productD1:
   358   assumes "finite (A \<times> B)" and "B \<noteq> {}"
   359   shows "finite A"
   360 proof -
   361   from assms obtain n f where "A \<times> B = f ` {i::nat. i < n}"
   362     by (auto simp add: finite_conv_nat_seg_image)
   363   then have "fst ` (A \<times> B) = fst ` f ` {i::nat. i < n}" by simp
   364   with `B \<noteq> {}` have "A = (fst \<circ> f) ` {i::nat. i < n}"
   365     by (simp add: image_compose)
   366   then have "\<exists>n f. A = f ` {i::nat. i < n}" by blast
   367   then show ?thesis
   368     by (auto simp add: finite_conv_nat_seg_image)
   369 qed
   370 
   371 lemma finite_cartesian_productD2:
   372   assumes "finite (A \<times> B)" and "A \<noteq> {}"
   373   shows "finite B"
   374 proof -
   375   from assms obtain n f where "A \<times> B = f ` {i::nat. i < n}"
   376     by (auto simp add: finite_conv_nat_seg_image)
   377   then have "snd ` (A \<times> B) = snd ` f ` {i::nat. i < n}" by simp
   378   with `A \<noteq> {}` have "B = (snd \<circ> f) ` {i::nat. i < n}"
   379     by (simp add: image_compose)
   380   then have "\<exists>n f. B = f ` {i::nat. i < n}" by blast
   381   then show ?thesis
   382     by (auto simp add: finite_conv_nat_seg_image)
   383 qed
   384 
   385 lemma finite_Pow_iff [iff]:
   386   "finite (Pow A) \<longleftrightarrow> finite A"
   387 proof
   388   assume "finite (Pow A)"
   389   then have "finite ((%x. {x}) ` A)" by (blast intro: finite_subset)
   390   then show "finite A" by (rule finite_imageD [unfolded inj_on_def]) simp
   391 next
   392   assume "finite A"
   393   then show "finite (Pow A)"
   394     by induct (simp_all add: Pow_insert)
   395 qed
   396 
   397 corollary finite_Collect_subsets [simp, intro]:
   398   "finite A \<Longrightarrow> finite {B. B \<subseteq> A}"
   399   by (simp add: Pow_def [symmetric])
   400 
   401 lemma finite_UnionD: "finite(\<Union>A) \<Longrightarrow> finite A"
   402   by (blast intro: finite_subset [OF subset_Pow_Union])
   403 
   404 
   405 subsubsection {* Further induction rules on finite sets *}
   406 
   407 lemma finite_ne_induct [case_names singleton insert, consumes 2]:
   408   assumes "finite F" and "F \<noteq> {}"
   409   assumes "\<And>x. P {x}"
   410     and "\<And>x F. finite F \<Longrightarrow> F \<noteq> {} \<Longrightarrow> x \<notin> F \<Longrightarrow> P F  \<Longrightarrow> P (insert x F)"
   411   shows "P F"
   412 using assms proof induct
   413   case empty then show ?case by simp
   414 next
   415   case (insert x F) then show ?case by cases auto
   416 qed
   417 
   418 lemma finite_subset_induct [consumes 2, case_names empty insert]:
   419   assumes "finite F" and "F \<subseteq> A"
   420   assumes empty: "P {}"
   421     and insert: "\<And>a F. finite F \<Longrightarrow> a \<in> A \<Longrightarrow> a \<notin> F \<Longrightarrow> P F \<Longrightarrow> P (insert a F)"
   422   shows "P F"
   423 using `finite F` `F \<subseteq> A` proof induct
   424   show "P {}" by fact
   425 next
   426   fix x F
   427   assume "finite F" and "x \<notin> F" and
   428     P: "F \<subseteq> A \<Longrightarrow> P F" and i: "insert x F \<subseteq> A"
   429   show "P (insert x F)"
   430   proof (rule insert)
   431     from i show "x \<in> A" by blast
   432     from i have "F \<subseteq> A" by blast
   433     with P show "P F" .
   434     show "finite F" by fact
   435     show "x \<notin> F" by fact
   436   qed
   437 qed
   438 
   439 lemma finite_empty_induct:
   440   assumes "finite A"
   441   assumes "P A"
   442     and remove: "\<And>a A. finite A \<Longrightarrow> a \<in> A \<Longrightarrow> P A \<Longrightarrow> P (A - {a})"
   443   shows "P {}"
   444 proof -
   445   have "\<And>B. B \<subseteq> A \<Longrightarrow> P (A - B)"
   446   proof -
   447     fix B :: "'a set"
   448     assume "B \<subseteq> A"
   449     with `finite A` have "finite B" by (rule rev_finite_subset)
   450     from this `B \<subseteq> A` show "P (A - B)"
   451     proof induct
   452       case empty
   453       from `P A` show ?case by simp
   454     next
   455       case (insert b B)
   456       have "P (A - B - {b})"
   457       proof (rule remove)
   458         from `finite A` show "finite (A - B)" by induct auto
   459         from insert show "b \<in> A - B" by simp
   460         from insert show "P (A - B)" by simp
   461       qed
   462       also have "A - B - {b} = A - insert b B" by (rule Diff_insert [symmetric])
   463       finally show ?case .
   464     qed
   465   qed
   466   then have "P (A - A)" by blast
   467   then show ?thesis by simp
   468 qed
   469 
   470 
   471 subsection {* Class @{text finite}  *}
   472 
   473 class finite =
   474   assumes finite_UNIV: "finite (UNIV \<Colon> 'a set)"
   475 begin
   476 
   477 lemma finite [simp]: "finite (A \<Colon> 'a set)"
   478   by (rule subset_UNIV finite_UNIV finite_subset)+
   479 
   480 lemma finite_code [code]: "finite (A \<Colon> 'a set) = True"
   481   by simp
   482 
   483 end
   484 
   485 lemma UNIV_unit [no_atp]:
   486   "UNIV = {()}" by auto
   487 
   488 instance unit :: finite proof
   489 qed (simp add: UNIV_unit)
   490 
   491 lemma UNIV_bool [no_atp]:
   492   "UNIV = {False, True}" by auto
   493 
   494 instance bool :: finite proof
   495 qed (simp add: UNIV_bool)
   496 
   497 instance prod :: (finite, finite) finite proof
   498 qed (simp only: UNIV_Times_UNIV [symmetric] finite_cartesian_product finite)
   499 
   500 lemma finite_option_UNIV [simp]:
   501   "finite (UNIV :: 'a option set) = finite (UNIV :: 'a set)"
   502   by (auto simp add: UNIV_option_conv elim: finite_imageD intro: inj_Some)
   503 
   504 instance option :: (finite) finite proof
   505 qed (simp add: UNIV_option_conv)
   506 
   507 lemma inj_graph: "inj (%f. {(x, y). y = f x})"
   508   by (rule inj_onI, auto simp add: set_eq_iff fun_eq_iff)
   509 
   510 instance "fun" :: (finite, finite) finite
   511 proof
   512   show "finite (UNIV :: ('a => 'b) set)"
   513   proof (rule finite_imageD)
   514     let ?graph = "%f::'a => 'b. {(x, y). y = f x}"
   515     have "range ?graph \<subseteq> Pow UNIV" by simp
   516     moreover have "finite (Pow (UNIV :: ('a * 'b) set))"
   517       by (simp only: finite_Pow_iff finite)
   518     ultimately show "finite (range ?graph)"
   519       by (rule finite_subset)
   520     show "inj ?graph" by (rule inj_graph)
   521   qed
   522 qed
   523 
   524 instance sum :: (finite, finite) finite proof
   525 qed (simp only: UNIV_Plus_UNIV [symmetric] finite_Plus finite)
   526 
   527 
   528 subsection {* A basic fold functional for finite sets *}
   529 
   530 text {* The intended behaviour is
   531 @{text "fold f z {x\<^isub>1, ..., x\<^isub>n} = f x\<^isub>1 (\<dots> (f x\<^isub>n z)\<dots>)"}
   532 if @{text f} is ``left-commutative'':
   533 *}
   534 
   535 locale comp_fun_commute =
   536   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b"
   537   assumes comp_fun_commute: "f y \<circ> f x = f x \<circ> f y"
   538 begin
   539 
   540 lemma fun_left_comm: "f x (f y z) = f y (f x z)"
   541   using comp_fun_commute by (simp add: fun_eq_iff)
   542 
   543 end
   544 
   545 inductive fold_graph :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> bool"
   546 for f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b" and z :: 'b where
   547   emptyI [intro]: "fold_graph f z {} z" |
   548   insertI [intro]: "x \<notin> A \<Longrightarrow> fold_graph f z A y
   549       \<Longrightarrow> fold_graph f z (insert x A) (f x y)"
   550 
   551 inductive_cases empty_fold_graphE [elim!]: "fold_graph f z {} x"
   552 
   553 definition fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b" where
   554   "fold f z A = (THE y. fold_graph f z A y)"
   555 
   556 text{*A tempting alternative for the definiens is
   557 @{term "if finite A then THE y. fold_graph f z A y else e"}.
   558 It allows the removal of finiteness assumptions from the theorems
   559 @{text fold_comm}, @{text fold_reindex} and @{text fold_distrib}.
   560 The proofs become ugly. It is not worth the effort. (???) *}
   561 
   562 lemma finite_imp_fold_graph: "finite A \<Longrightarrow> \<exists>x. fold_graph f z A x"
   563 by (induct rule: finite_induct) auto
   564 
   565 
   566 subsubsection{*From @{const fold_graph} to @{term fold}*}
   567 
   568 context comp_fun_commute
   569 begin
   570 
   571 lemma fold_graph_insertE_aux:
   572   "fold_graph f z A y \<Longrightarrow> a \<in> A \<Longrightarrow> \<exists>y'. y = f a y' \<and> fold_graph f z (A - {a}) y'"
   573 proof (induct set: fold_graph)
   574   case (insertI x A y) show ?case
   575   proof (cases "x = a")
   576     assume "x = a" with insertI show ?case by auto
   577   next
   578     assume "x \<noteq> a"
   579     then obtain y' where y: "y = f a y'" and y': "fold_graph f z (A - {a}) y'"
   580       using insertI by auto
   581     have "f x y = f a (f x y')"
   582       unfolding y by (rule fun_left_comm)
   583     moreover have "fold_graph f z (insert x A - {a}) (f x y')"
   584       using y' and `x \<noteq> a` and `x \<notin> A`
   585       by (simp add: insert_Diff_if fold_graph.insertI)
   586     ultimately show ?case by fast
   587   qed
   588 qed simp
   589 
   590 lemma fold_graph_insertE:
   591   assumes "fold_graph f z (insert x A) v" and "x \<notin> A"
   592   obtains y where "v = f x y" and "fold_graph f z A y"
   593 using assms by (auto dest: fold_graph_insertE_aux [OF _ insertI1])
   594 
   595 lemma fold_graph_determ:
   596   "fold_graph f z A x \<Longrightarrow> fold_graph f z A y \<Longrightarrow> y = x"
   597 proof (induct arbitrary: y set: fold_graph)
   598   case (insertI x A y v)
   599   from `fold_graph f z (insert x A) v` and `x \<notin> A`
   600   obtain y' where "v = f x y'" and "fold_graph f z A y'"
   601     by (rule fold_graph_insertE)
   602   from `fold_graph f z A y'` have "y' = y" by (rule insertI)
   603   with `v = f x y'` show "v = f x y" by simp
   604 qed fast
   605 
   606 lemma fold_equality:
   607   "fold_graph f z A y \<Longrightarrow> fold f z A = y"
   608 by (unfold fold_def) (blast intro: fold_graph_determ)
   609 
   610 lemma fold_graph_fold:
   611   assumes "finite A"
   612   shows "fold_graph f z A (fold f z A)"
   613 proof -
   614   from assms have "\<exists>x. fold_graph f z A x" by (rule finite_imp_fold_graph)
   615   moreover note fold_graph_determ
   616   ultimately have "\<exists>!x. fold_graph f z A x" by (rule ex_ex1I)
   617   then have "fold_graph f z A (The (fold_graph f z A))" by (rule theI')
   618   then show ?thesis by (unfold fold_def)
   619 qed
   620 
   621 text{* The base case for @{text fold}: *}
   622 
   623 lemma (in -) fold_empty [simp]: "fold f z {} = z"
   624 by (unfold fold_def) blast
   625 
   626 text{* The various recursion equations for @{const fold}: *}
   627 
   628 lemma fold_insert [simp]:
   629   assumes "finite A" and "x \<notin> A"
   630   shows "fold f z (insert x A) = f x (fold f z A)"
   631 proof (rule fold_equality)
   632   from `finite A` have "fold_graph f z A (fold f z A)" by (rule fold_graph_fold)
   633   with `x \<notin> A`show "fold_graph f z (insert x A) (f x (fold f z A))" by (rule fold_graph.insertI)
   634 qed
   635 
   636 lemma fold_fun_comm:
   637   "finite A \<Longrightarrow> f x (fold f z A) = fold f (f x z) A"
   638 proof (induct rule: finite_induct)
   639   case empty then show ?case by simp
   640 next
   641   case (insert y A) then show ?case
   642     by (simp add: fun_left_comm[of x])
   643 qed
   644 
   645 lemma fold_insert2:
   646   "finite A \<Longrightarrow> x \<notin> A \<Longrightarrow> fold f z (insert x A) = fold f (f x z) A"
   647 by (simp add: fold_fun_comm)
   648 
   649 lemma fold_rec:
   650   assumes "finite A" and "x \<in> A"
   651   shows "fold f z A = f x (fold f z (A - {x}))"
   652 proof -
   653   have A: "A = insert x (A - {x})" using `x \<in> A` by blast
   654   then have "fold f z A = fold f z (insert x (A - {x}))" by simp
   655   also have "\<dots> = f x (fold f z (A - {x}))"
   656     by (rule fold_insert) (simp add: `finite A`)+
   657   finally show ?thesis .
   658 qed
   659 
   660 lemma fold_insert_remove:
   661   assumes "finite A"
   662   shows "fold f z (insert x A) = f x (fold f z (A - {x}))"
   663 proof -
   664   from `finite A` have "finite (insert x A)" by auto
   665   moreover have "x \<in> insert x A" by auto
   666   ultimately have "fold f z (insert x A) = f x (fold f z (insert x A - {x}))"
   667     by (rule fold_rec)
   668   then show ?thesis by simp
   669 qed
   670 
   671 end
   672 
   673 text{* A simplified version for idempotent functions: *}
   674 
   675 locale comp_fun_idem = comp_fun_commute +
   676   assumes comp_fun_idem: "f x o f x = f x"
   677 begin
   678 
   679 lemma fun_left_idem: "f x (f x z) = f x z"
   680   using comp_fun_idem by (simp add: fun_eq_iff)
   681 
   682 lemma fold_insert_idem:
   683   assumes fin: "finite A"
   684   shows "fold f z (insert x A) = f x (fold f z A)"
   685 proof cases
   686   assume "x \<in> A"
   687   then obtain B where "A = insert x B" and "x \<notin> B" by (rule set_insert)
   688   then show ?thesis using assms by (simp add:fun_left_idem)
   689 next
   690   assume "x \<notin> A" then show ?thesis using assms by simp
   691 qed
   692 
   693 declare fold_insert[simp del] fold_insert_idem[simp]
   694 
   695 lemma fold_insert_idem2:
   696   "finite A \<Longrightarrow> fold f z (insert x A) = fold f (f x z) A"
   697 by(simp add:fold_fun_comm)
   698 
   699 end
   700 
   701 
   702 subsubsection {* Expressing set operations via @{const fold} *}
   703 
   704 lemma (in comp_fun_commute) comp_comp_fun_commute:
   705   "comp_fun_commute (f \<circ> g)"
   706 proof
   707 qed (simp_all add: comp_fun_commute)
   708 
   709 lemma (in comp_fun_idem) comp_comp_fun_idem:
   710   "comp_fun_idem (f \<circ> g)"
   711   by (rule comp_fun_idem.intro, rule comp_comp_fun_commute, unfold_locales)
   712     (simp_all add: comp_fun_idem)
   713 
   714 lemma comp_fun_idem_insert:
   715   "comp_fun_idem insert"
   716 proof
   717 qed auto
   718 
   719 lemma comp_fun_idem_remove:
   720   "comp_fun_idem (\<lambda>x A. A - {x})"
   721 proof
   722 qed auto
   723 
   724 lemma (in semilattice_inf) comp_fun_idem_inf:
   725   "comp_fun_idem inf"
   726 proof
   727 qed (auto simp add: inf_left_commute)
   728 
   729 lemma (in semilattice_sup) comp_fun_idem_sup:
   730   "comp_fun_idem sup"
   731 proof
   732 qed (auto simp add: sup_left_commute)
   733 
   734 lemma union_fold_insert:
   735   assumes "finite A"
   736   shows "A \<union> B = fold insert B A"
   737 proof -
   738   interpret comp_fun_idem insert by (fact comp_fun_idem_insert)
   739   from `finite A` show ?thesis by (induct A arbitrary: B) simp_all
   740 qed
   741 
   742 lemma minus_fold_remove:
   743   assumes "finite A"
   744   shows "B - A = fold (\<lambda>x A. A - {x}) B A"
   745 proof -
   746   interpret comp_fun_idem "\<lambda>x A. A - {x}" by (fact comp_fun_idem_remove)
   747   from `finite A` show ?thesis by (induct A arbitrary: B) auto
   748 qed
   749 
   750 context complete_lattice
   751 begin
   752 
   753 lemma inf_Inf_fold_inf:
   754   assumes "finite A"
   755   shows "inf B (Inf A) = fold inf B A"
   756 proof -
   757   interpret comp_fun_idem inf by (fact comp_fun_idem_inf)
   758   from `finite A` show ?thesis by (induct A arbitrary: B)
   759     (simp_all add: Inf_insert inf_commute fold_fun_comm)
   760 qed
   761 
   762 lemma sup_Sup_fold_sup:
   763   assumes "finite A"
   764   shows "sup B (Sup A) = fold sup B A"
   765 proof -
   766   interpret comp_fun_idem sup by (fact comp_fun_idem_sup)
   767   from `finite A` show ?thesis by (induct A arbitrary: B)
   768     (simp_all add: Sup_insert sup_commute fold_fun_comm)
   769 qed
   770 
   771 lemma Inf_fold_inf:
   772   assumes "finite A"
   773   shows "Inf A = fold inf top A"
   774   using assms inf_Inf_fold_inf [of A top] by (simp add: inf_absorb2)
   775 
   776 lemma Sup_fold_sup:
   777   assumes "finite A"
   778   shows "Sup A = fold sup bot A"
   779   using assms sup_Sup_fold_sup [of A bot] by (simp add: sup_absorb2)
   780 
   781 lemma inf_INFI_fold_inf:
   782   assumes "finite A"
   783   shows "inf B (INFI A f) = fold (inf \<circ> f) B A" (is "?inf = ?fold") 
   784 proof (rule sym)
   785   interpret comp_fun_idem inf by (fact comp_fun_idem_inf)
   786   interpret comp_fun_idem "inf \<circ> f" by (fact comp_comp_fun_idem)
   787   from `finite A` show "?fold = ?inf"
   788     by (induct A arbitrary: B)
   789       (simp_all add: INFI_def Inf_insert inf_left_commute)
   790 qed
   791 
   792 lemma sup_SUPR_fold_sup:
   793   assumes "finite A"
   794   shows "sup B (SUPR A f) = fold (sup \<circ> f) B A" (is "?sup = ?fold") 
   795 proof (rule sym)
   796   interpret comp_fun_idem sup by (fact comp_fun_idem_sup)
   797   interpret comp_fun_idem "sup \<circ> f" by (fact comp_comp_fun_idem)
   798   from `finite A` show "?fold = ?sup"
   799     by (induct A arbitrary: B)
   800       (simp_all add: SUPR_def Sup_insert sup_left_commute)
   801 qed
   802 
   803 lemma INFI_fold_inf:
   804   assumes "finite A"
   805   shows "INFI A f = fold (inf \<circ> f) top A"
   806   using assms inf_INFI_fold_inf [of A top] by simp
   807 
   808 lemma SUPR_fold_sup:
   809   assumes "finite A"
   810   shows "SUPR A f = fold (sup \<circ> f) bot A"
   811   using assms sup_SUPR_fold_sup [of A bot] by simp
   812 
   813 end
   814 
   815 
   816 subsection {* The derived combinator @{text fold_image} *}
   817 
   818 definition fold_image :: "('b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b"
   819   where "fold_image f g = fold (\<lambda>x y. f (g x) y)"
   820 
   821 lemma fold_image_empty[simp]: "fold_image f g z {} = z"
   822   by (simp add:fold_image_def)
   823 
   824 context ab_semigroup_mult
   825 begin
   826 
   827 lemma fold_image_insert[simp]:
   828   assumes "finite A" and "a \<notin> A"
   829   shows "fold_image times g z (insert a A) = g a * (fold_image times g z A)"
   830 proof -
   831   interpret comp_fun_commute "%x y. (g x) * y" proof
   832   qed (simp add: fun_eq_iff mult_ac)
   833   show ?thesis using assms by (simp add: fold_image_def)
   834 qed
   835 
   836 lemma fold_image_reindex:
   837   assumes "finite A"
   838   shows "inj_on h A \<Longrightarrow> fold_image times g z (h ` A) = fold_image times (g \<circ> h) z A"
   839   using assms by induct auto
   840 
   841 lemma fold_image_cong:
   842   assumes "finite A" and g_h: "\<And>x. x\<in>A \<Longrightarrow> g x = h x"
   843   shows "fold_image times g z A = fold_image times h z A"
   844 proof -
   845   from `finite A`
   846   have "\<And>C. C <= A --> (ALL x:C. g x = h x) --> fold_image times g z C = fold_image times h z C"
   847   proof (induct arbitrary: C)
   848     case empty then show ?case by simp
   849   next
   850     case (insert x F) then show ?case apply -
   851     apply (simp add: subset_insert_iff, clarify)
   852     apply (subgoal_tac "finite C")
   853       prefer 2 apply (blast dest: finite_subset [COMP swap_prems_rl])
   854     apply (subgoal_tac "C = insert x (C - {x})")
   855       prefer 2 apply blast
   856     apply (erule ssubst)
   857     apply (simp add: Ball_def del: insert_Diff_single)
   858     done
   859   qed
   860   with g_h show ?thesis by simp
   861 qed
   862 
   863 end
   864 
   865 context comm_monoid_mult
   866 begin
   867 
   868 lemma fold_image_1:
   869   "finite S \<Longrightarrow> (\<forall>x\<in>S. f x = 1) \<Longrightarrow> fold_image op * f 1 S = 1"
   870   apply (induct rule: finite_induct)
   871   apply simp by auto
   872 
   873 lemma fold_image_Un_Int:
   874   "finite A ==> finite B ==>
   875     fold_image times g 1 A * fold_image times g 1 B =
   876     fold_image times g 1 (A Un B) * fold_image times g 1 (A Int B)"
   877   apply (induct rule: finite_induct)
   878 by (induct set: finite) 
   879    (auto simp add: mult_ac insert_absorb Int_insert_left)
   880 
   881 lemma fold_image_Un_one:
   882   assumes fS: "finite S" and fT: "finite T"
   883   and I0: "\<forall>x \<in> S\<inter>T. f x = 1"
   884   shows "fold_image (op *) f 1 (S \<union> T) = fold_image (op *) f 1 S * fold_image (op *) f 1 T"
   885 proof-
   886   have "fold_image op * f 1 (S \<inter> T) = 1" 
   887     apply (rule fold_image_1)
   888     using fS fT I0 by auto 
   889   with fold_image_Un_Int[OF fS fT] show ?thesis by simp
   890 qed
   891 
   892 corollary fold_Un_disjoint:
   893   "finite A ==> finite B ==> A Int B = {} ==>
   894    fold_image times g 1 (A Un B) =
   895    fold_image times g 1 A * fold_image times g 1 B"
   896 by (simp add: fold_image_Un_Int)
   897 
   898 lemma fold_image_UN_disjoint:
   899   "\<lbrakk> finite I; ALL i:I. finite (A i);
   900      ALL i:I. ALL j:I. i \<noteq> j --> A i Int A j = {} \<rbrakk>
   901    \<Longrightarrow> fold_image times g 1 (UNION I A) =
   902        fold_image times (%i. fold_image times g 1 (A i)) 1 I"
   903 apply (induct rule: finite_induct)
   904 apply simp
   905 apply atomize
   906 apply (subgoal_tac "ALL i:F. x \<noteq> i")
   907  prefer 2 apply blast
   908 apply (subgoal_tac "A x Int UNION F A = {}")
   909  prefer 2 apply blast
   910 apply (simp add: fold_Un_disjoint)
   911 done
   912 
   913 lemma fold_image_Sigma: "finite A ==> ALL x:A. finite (B x) ==>
   914   fold_image times (%x. fold_image times (g x) 1 (B x)) 1 A =
   915   fold_image times (split g) 1 (SIGMA x:A. B x)"
   916 apply (subst Sigma_def)
   917 apply (subst fold_image_UN_disjoint, assumption, simp)
   918  apply blast
   919 apply (erule fold_image_cong)
   920 apply (subst fold_image_UN_disjoint, simp, simp)
   921  apply blast
   922 apply simp
   923 done
   924 
   925 lemma fold_image_distrib: "finite A \<Longrightarrow>
   926    fold_image times (%x. g x * h x) 1 A =
   927    fold_image times g 1 A *  fold_image times h 1 A"
   928 by (erule finite_induct) (simp_all add: mult_ac)
   929 
   930 lemma fold_image_related: 
   931   assumes Re: "R e e" 
   932   and Rop: "\<forall>x1 y1 x2 y2. R x1 x2 \<and> R y1 y2 \<longrightarrow> R (x1 * y1) (x2 * y2)" 
   933   and fS: "finite S" and Rfg: "\<forall>x\<in>S. R (h x) (g x)"
   934   shows "R (fold_image (op *) h e S) (fold_image (op *) g e S)"
   935   using fS by (rule finite_subset_induct) (insert assms, auto)
   936 
   937 lemma  fold_image_eq_general:
   938   assumes fS: "finite S"
   939   and h: "\<forall>y\<in>S'. \<exists>!x. x\<in> S \<and> h(x) = y" 
   940   and f12:  "\<forall>x\<in>S. h x \<in> S' \<and> f2(h x) = f1 x"
   941   shows "fold_image (op *) f1 e S = fold_image (op *) f2 e S'"
   942 proof-
   943   from h f12 have hS: "h ` S = S'" by auto
   944   {fix x y assume H: "x \<in> S" "y \<in> S" "h x = h y"
   945     from f12 h H  have "x = y" by auto }
   946   hence hinj: "inj_on h S" unfolding inj_on_def Ex1_def by blast
   947   from f12 have th: "\<And>x. x \<in> S \<Longrightarrow> (f2 \<circ> h) x = f1 x" by auto 
   948   from hS have "fold_image (op *) f2 e S' = fold_image (op *) f2 e (h ` S)" by simp
   949   also have "\<dots> = fold_image (op *) (f2 o h) e S" 
   950     using fold_image_reindex[OF fS hinj, of f2 e] .
   951   also have "\<dots> = fold_image (op *) f1 e S " using th fold_image_cong[OF fS, of "f2 o h" f1 e]
   952     by blast
   953   finally show ?thesis ..
   954 qed
   955 
   956 lemma fold_image_eq_general_inverses:
   957   assumes fS: "finite S" 
   958   and kh: "\<And>y. y \<in> T \<Longrightarrow> k y \<in> S \<and> h (k y) = y"
   959   and hk: "\<And>x. x \<in> S \<Longrightarrow> h x \<in> T \<and> k (h x) = x  \<and> g (h x) = f x"
   960   shows "fold_image (op *) f e S = fold_image (op *) g e T"
   961   (* metis solves it, but not yet available here *)
   962   apply (rule fold_image_eq_general[OF fS, of T h g f e])
   963   apply (rule ballI)
   964   apply (frule kh)
   965   apply (rule ex1I[])
   966   apply blast
   967   apply clarsimp
   968   apply (drule hk) apply simp
   969   apply (rule sym)
   970   apply (erule conjunct1[OF conjunct2[OF hk]])
   971   apply (rule ballI)
   972   apply (drule  hk)
   973   apply blast
   974   done
   975 
   976 end
   977 
   978 
   979 subsection {* A fold functional for non-empty sets *}
   980 
   981 text{* Does not require start value. *}
   982 
   983 inductive
   984   fold1Set :: "('a => 'a => 'a) => 'a set => 'a => bool"
   985   for f :: "'a => 'a => 'a"
   986 where
   987   fold1Set_insertI [intro]:
   988    "\<lbrakk> fold_graph f a A x; a \<notin> A \<rbrakk> \<Longrightarrow> fold1Set f (insert a A) x"
   989 
   990 definition fold1 :: "('a => 'a => 'a) => 'a set => 'a" where
   991   "fold1 f A == THE x. fold1Set f A x"
   992 
   993 lemma fold1Set_nonempty:
   994   "fold1Set f A x \<Longrightarrow> A \<noteq> {}"
   995 by(erule fold1Set.cases, simp_all)
   996 
   997 inductive_cases empty_fold1SetE [elim!]: "fold1Set f {} x"
   998 
   999 inductive_cases insert_fold1SetE [elim!]: "fold1Set f (insert a X) x"
  1000 
  1001 
  1002 lemma fold1Set_sing [iff]: "(fold1Set f {a} b) = (a = b)"
  1003 by (blast elim: fold_graph.cases)
  1004 
  1005 lemma fold1_singleton [simp]: "fold1 f {a} = a"
  1006 by (unfold fold1_def) blast
  1007 
  1008 lemma finite_nonempty_imp_fold1Set:
  1009   "\<lbrakk> finite A; A \<noteq> {} \<rbrakk> \<Longrightarrow> EX x. fold1Set f A x"
  1010 apply (induct A rule: finite_induct)
  1011 apply (auto dest: finite_imp_fold_graph [of _ f])
  1012 done
  1013 
  1014 text{*First, some lemmas about @{const fold_graph}.*}
  1015 
  1016 context ab_semigroup_mult
  1017 begin
  1018 
  1019 lemma comp_fun_commute: "comp_fun_commute (op *)" proof
  1020 qed (simp add: fun_eq_iff mult_ac)
  1021 
  1022 lemma fold_graph_insert_swap:
  1023 assumes fold: "fold_graph times (b::'a) A y" and "b \<notin> A"
  1024 shows "fold_graph times z (insert b A) (z * y)"
  1025 proof -
  1026   interpret comp_fun_commute "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule comp_fun_commute)
  1027 from assms show ?thesis
  1028 proof (induct rule: fold_graph.induct)
  1029   case emptyI show ?case by (subst mult_commute [of z b], fast)
  1030 next
  1031   case (insertI x A y)
  1032     have "fold_graph times z (insert x (insert b A)) (x * (z * y))"
  1033       using insertI by force  --{*how does @{term id} get unfolded?*}
  1034     thus ?case by (simp add: insert_commute mult_ac)
  1035 qed
  1036 qed
  1037 
  1038 lemma fold_graph_permute_diff:
  1039 assumes fold: "fold_graph times b A x"
  1040 shows "!!a. \<lbrakk>a \<in> A; b \<notin> A\<rbrakk> \<Longrightarrow> fold_graph times a (insert b (A-{a})) x"
  1041 using fold
  1042 proof (induct rule: fold_graph.induct)
  1043   case emptyI thus ?case by simp
  1044 next
  1045   case (insertI x A y)
  1046   have "a = x \<or> a \<in> A" using insertI by simp
  1047   thus ?case
  1048   proof
  1049     assume "a = x"
  1050     with insertI show ?thesis
  1051       by (simp add: id_def [symmetric], blast intro: fold_graph_insert_swap)
  1052   next
  1053     assume ainA: "a \<in> A"
  1054     hence "fold_graph times a (insert x (insert b (A - {a}))) (x * y)"
  1055       using insertI by force
  1056     moreover
  1057     have "insert x (insert b (A - {a})) = insert b (insert x A - {a})"
  1058       using ainA insertI by blast
  1059     ultimately show ?thesis by simp
  1060   qed
  1061 qed
  1062 
  1063 lemma fold1_eq_fold:
  1064 assumes "finite A" "a \<notin> A" shows "fold1 times (insert a A) = fold times a A"
  1065 proof -
  1066   interpret comp_fun_commute "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule comp_fun_commute)
  1067   from assms show ?thesis
  1068 apply (simp add: fold1_def fold_def)
  1069 apply (rule the_equality)
  1070 apply (best intro: fold_graph_determ theI dest: finite_imp_fold_graph [of _ times])
  1071 apply (rule sym, clarify)
  1072 apply (case_tac "Aa=A")
  1073  apply (best intro: fold_graph_determ)
  1074 apply (subgoal_tac "fold_graph times a A x")
  1075  apply (best intro: fold_graph_determ)
  1076 apply (subgoal_tac "insert aa (Aa - {a}) = A")
  1077  prefer 2 apply (blast elim: equalityE)
  1078 apply (auto dest: fold_graph_permute_diff [where a=a])
  1079 done
  1080 qed
  1081 
  1082 lemma nonempty_iff: "(A \<noteq> {}) = (\<exists>x B. A = insert x B & x \<notin> B)"
  1083 apply safe
  1084  apply simp
  1085  apply (drule_tac x=x in spec)
  1086  apply (drule_tac x="A-{x}" in spec, auto)
  1087 done
  1088 
  1089 lemma fold1_insert:
  1090   assumes nonempty: "A \<noteq> {}" and A: "finite A" "x \<notin> A"
  1091   shows "fold1 times (insert x A) = x * fold1 times A"
  1092 proof -
  1093   interpret comp_fun_commute "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule comp_fun_commute)
  1094   from nonempty obtain a A' where "A = insert a A' & a ~: A'"
  1095     by (auto simp add: nonempty_iff)
  1096   with A show ?thesis
  1097     by (simp add: insert_commute [of x] fold1_eq_fold eq_commute)
  1098 qed
  1099 
  1100 end
  1101 
  1102 context ab_semigroup_idem_mult
  1103 begin
  1104 
  1105 lemma comp_fun_idem: "comp_fun_idem (op *)" proof
  1106 qed (simp_all add: fun_eq_iff mult_left_commute)
  1107 
  1108 lemma fold1_insert_idem [simp]:
  1109   assumes nonempty: "A \<noteq> {}" and A: "finite A" 
  1110   shows "fold1 times (insert x A) = x * fold1 times A"
  1111 proof -
  1112   interpret comp_fun_idem "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a"
  1113     by (rule comp_fun_idem)
  1114   from nonempty obtain a A' where A': "A = insert a A' & a ~: A'"
  1115     by (auto simp add: nonempty_iff)
  1116   show ?thesis
  1117   proof cases
  1118     assume a: "a = x"
  1119     show ?thesis
  1120     proof cases
  1121       assume "A' = {}"
  1122       with A' a show ?thesis by simp
  1123     next
  1124       assume "A' \<noteq> {}"
  1125       with A A' a show ?thesis
  1126         by (simp add: fold1_insert mult_assoc [symmetric])
  1127     qed
  1128   next
  1129     assume "a \<noteq> x"
  1130     with A A' show ?thesis
  1131       by (simp add: insert_commute fold1_eq_fold)
  1132   qed
  1133 qed
  1134 
  1135 lemma hom_fold1_commute:
  1136 assumes hom: "!!x y. h (x * y) = h x * h y"
  1137 and N: "finite N" "N \<noteq> {}" shows "h (fold1 times N) = fold1 times (h ` N)"
  1138 using N proof (induct rule: finite_ne_induct)
  1139   case singleton thus ?case by simp
  1140 next
  1141   case (insert n N)
  1142   then have "h (fold1 times (insert n N)) = h (n * fold1 times N)" by simp
  1143   also have "\<dots> = h n * h (fold1 times N)" by(rule hom)
  1144   also have "h (fold1 times N) = fold1 times (h ` N)" by(rule insert)
  1145   also have "times (h n) \<dots> = fold1 times (insert (h n) (h ` N))"
  1146     using insert by(simp)
  1147   also have "insert (h n) (h ` N) = h ` insert n N" by simp
  1148   finally show ?case .
  1149 qed
  1150 
  1151 lemma fold1_eq_fold_idem:
  1152   assumes "finite A"
  1153   shows "fold1 times (insert a A) = fold times a A"
  1154 proof (cases "a \<in> A")
  1155   case False
  1156   with assms show ?thesis by (simp add: fold1_eq_fold)
  1157 next
  1158   interpret comp_fun_idem times by (fact comp_fun_idem)
  1159   case True then obtain b B
  1160     where A: "A = insert a B" and "a \<notin> B" by (rule set_insert)
  1161   with assms have "finite B" by auto
  1162   then have "fold times a (insert a B) = fold times (a * a) B"
  1163     using `a \<notin> B` by (rule fold_insert2)
  1164   then show ?thesis
  1165     using `a \<notin> B` `finite B` by (simp add: fold1_eq_fold A)
  1166 qed
  1167 
  1168 end
  1169 
  1170 
  1171 text{* Now the recursion rules for definitions: *}
  1172 
  1173 lemma fold1_singleton_def: "g = fold1 f \<Longrightarrow> g {a} = a"
  1174 by simp
  1175 
  1176 lemma (in ab_semigroup_mult) fold1_insert_def:
  1177   "\<lbrakk> g = fold1 times; finite A; x \<notin> A; A \<noteq> {} \<rbrakk> \<Longrightarrow> g (insert x A) = x * g A"
  1178 by (simp add:fold1_insert)
  1179 
  1180 lemma (in ab_semigroup_idem_mult) fold1_insert_idem_def:
  1181   "\<lbrakk> g = fold1 times; finite A; A \<noteq> {} \<rbrakk> \<Longrightarrow> g (insert x A) = x * g A"
  1182 by simp
  1183 
  1184 subsubsection{* Determinacy for @{term fold1Set} *}
  1185 
  1186 (*Not actually used!!*)
  1187 (*
  1188 context ab_semigroup_mult
  1189 begin
  1190 
  1191 lemma fold_graph_permute:
  1192   "[|fold_graph times id b (insert a A) x; a \<notin> A; b \<notin> A|]
  1193    ==> fold_graph times id a (insert b A) x"
  1194 apply (cases "a=b") 
  1195 apply (auto dest: fold_graph_permute_diff) 
  1196 done
  1197 
  1198 lemma fold1Set_determ:
  1199   "fold1Set times A x ==> fold1Set times A y ==> y = x"
  1200 proof (clarify elim!: fold1Set.cases)
  1201   fix A x B y a b
  1202   assume Ax: "fold_graph times id a A x"
  1203   assume By: "fold_graph times id b B y"
  1204   assume anotA:  "a \<notin> A"
  1205   assume bnotB:  "b \<notin> B"
  1206   assume eq: "insert a A = insert b B"
  1207   show "y=x"
  1208   proof cases
  1209     assume same: "a=b"
  1210     hence "A=B" using anotA bnotB eq by (blast elim!: equalityE)
  1211     thus ?thesis using Ax By same by (blast intro: fold_graph_determ)
  1212   next
  1213     assume diff: "a\<noteq>b"
  1214     let ?D = "B - {a}"
  1215     have B: "B = insert a ?D" and A: "A = insert b ?D"
  1216      and aB: "a \<in> B" and bA: "b \<in> A"
  1217       using eq anotA bnotB diff by (blast elim!:equalityE)+
  1218     with aB bnotB By
  1219     have "fold_graph times id a (insert b ?D) y" 
  1220       by (auto intro: fold_graph_permute simp add: insert_absorb)
  1221     moreover
  1222     have "fold_graph times id a (insert b ?D) x"
  1223       by (simp add: A [symmetric] Ax) 
  1224     ultimately show ?thesis by (blast intro: fold_graph_determ) 
  1225   qed
  1226 qed
  1227 
  1228 lemma fold1Set_equality: "fold1Set times A y ==> fold1 times A = y"
  1229   by (unfold fold1_def) (blast intro: fold1Set_determ)
  1230 
  1231 end
  1232 *)
  1233 
  1234 declare
  1235   empty_fold_graphE [rule del]  fold_graph.intros [rule del]
  1236   empty_fold1SetE [rule del]  insert_fold1SetE [rule del]
  1237   -- {* No more proofs involve these relations. *}
  1238 
  1239 subsubsection {* Lemmas about @{text fold1} *}
  1240 
  1241 context ab_semigroup_mult
  1242 begin
  1243 
  1244 lemma fold1_Un:
  1245 assumes A: "finite A" "A \<noteq> {}"
  1246 shows "finite B \<Longrightarrow> B \<noteq> {} \<Longrightarrow> A Int B = {} \<Longrightarrow>
  1247        fold1 times (A Un B) = fold1 times A * fold1 times B"
  1248 using A by (induct rule: finite_ne_induct)
  1249   (simp_all add: fold1_insert mult_assoc)
  1250 
  1251 lemma fold1_in:
  1252   assumes A: "finite (A)" "A \<noteq> {}" and elem: "\<And>x y. x * y \<in> {x,y}"
  1253   shows "fold1 times A \<in> A"
  1254 using A
  1255 proof (induct rule:finite_ne_induct)
  1256   case singleton thus ?case by simp
  1257 next
  1258   case insert thus ?case using elem by (force simp add:fold1_insert)
  1259 qed
  1260 
  1261 end
  1262 
  1263 lemma (in ab_semigroup_idem_mult) fold1_Un2:
  1264 assumes A: "finite A" "A \<noteq> {}"
  1265 shows "finite B \<Longrightarrow> B \<noteq> {} \<Longrightarrow>
  1266        fold1 times (A Un B) = fold1 times A * fold1 times B"
  1267 using A
  1268 proof(induct rule:finite_ne_induct)
  1269   case singleton thus ?case by simp
  1270 next
  1271   case insert thus ?case by (simp add: mult_assoc)
  1272 qed
  1273 
  1274 
  1275 subsection {* Locales as mini-packages for fold operations *}
  1276 
  1277 subsubsection {* The natural case *}
  1278 
  1279 locale folding =
  1280   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1281   fixes F :: "'a set \<Rightarrow> 'b \<Rightarrow> 'b"
  1282   assumes comp_fun_commute: "f y \<circ> f x = f x \<circ> f y"
  1283   assumes eq_fold: "finite A \<Longrightarrow> F A s = fold f s A"
  1284 begin
  1285 
  1286 lemma empty [simp]:
  1287   "F {} = id"
  1288   by (simp add: eq_fold fun_eq_iff)
  1289 
  1290 lemma insert [simp]:
  1291   assumes "finite A" and "x \<notin> A"
  1292   shows "F (insert x A) = F A \<circ> f x"
  1293 proof -
  1294   interpret comp_fun_commute f proof
  1295   qed (insert comp_fun_commute, simp add: fun_eq_iff)
  1296   from fold_insert2 assms
  1297   have "\<And>s. fold f s (insert x A) = fold f (f x s) A" .
  1298   with `finite A` show ?thesis by (simp add: eq_fold fun_eq_iff)
  1299 qed
  1300 
  1301 lemma remove:
  1302   assumes "finite A" and "x \<in> A"
  1303   shows "F A = F (A - {x}) \<circ> f x"
  1304 proof -
  1305   from `x \<in> A` obtain B where A: "A = insert x B" and "x \<notin> B"
  1306     by (auto dest: mk_disjoint_insert)
  1307   moreover from `finite A` this have "finite B" by simp
  1308   ultimately show ?thesis by simp
  1309 qed
  1310 
  1311 lemma insert_remove:
  1312   assumes "finite A"
  1313   shows "F (insert x A) = F (A - {x}) \<circ> f x"
  1314   using assms by (cases "x \<in> A") (simp_all add: remove insert_absorb)
  1315 
  1316 lemma commute_left_comp:
  1317   "f y \<circ> (f x \<circ> g) = f x \<circ> (f y \<circ> g)"
  1318   by (simp add: o_assoc comp_fun_commute)
  1319 
  1320 lemma comp_fun_commute':
  1321   assumes "finite A"
  1322   shows "f x \<circ> F A = F A \<circ> f x"
  1323   using assms by (induct A)
  1324     (simp, simp del: o_apply add: o_assoc, simp del: o_apply add: o_assoc [symmetric] comp_fun_commute)
  1325 
  1326 lemma commute_left_comp':
  1327   assumes "finite A"
  1328   shows "f x \<circ> (F A \<circ> g) = F A \<circ> (f x \<circ> g)"
  1329   using assms by (simp add: o_assoc comp_fun_commute')
  1330 
  1331 lemma comp_fun_commute'':
  1332   assumes "finite A" and "finite B"
  1333   shows "F B \<circ> F A = F A \<circ> F B"
  1334   using assms by (induct A)
  1335     (simp_all add: o_assoc, simp add: o_assoc [symmetric] comp_fun_commute')
  1336 
  1337 lemma commute_left_comp'':
  1338   assumes "finite A" and "finite B"
  1339   shows "F B \<circ> (F A \<circ> g) = F A \<circ> (F B \<circ> g)"
  1340   using assms by (simp add: o_assoc comp_fun_commute'')
  1341 
  1342 lemmas comp_fun_commutes = o_assoc [symmetric] comp_fun_commute commute_left_comp
  1343   comp_fun_commute' commute_left_comp' comp_fun_commute'' commute_left_comp''
  1344 
  1345 lemma union_inter:
  1346   assumes "finite A" and "finite B"
  1347   shows "F (A \<union> B) \<circ> F (A \<inter> B) = F A \<circ> F B"
  1348   using assms by (induct A)
  1349     (simp_all del: o_apply add: insert_absorb Int_insert_left comp_fun_commutes,
  1350       simp add: o_assoc)
  1351 
  1352 lemma union:
  1353   assumes "finite A" and "finite B"
  1354   and "A \<inter> B = {}"
  1355   shows "F (A \<union> B) = F A \<circ> F B"
  1356 proof -
  1357   from union_inter `finite A` `finite B` have "F (A \<union> B) \<circ> F (A \<inter> B) = F A \<circ> F B" .
  1358   with `A \<inter> B = {}` show ?thesis by simp
  1359 qed
  1360 
  1361 end
  1362 
  1363 
  1364 subsubsection {* The natural case with idempotency *}
  1365 
  1366 locale folding_idem = folding +
  1367   assumes idem_comp: "f x \<circ> f x = f x"
  1368 begin
  1369 
  1370 lemma idem_left_comp:
  1371   "f x \<circ> (f x \<circ> g) = f x \<circ> g"
  1372   by (simp add: o_assoc idem_comp)
  1373 
  1374 lemma in_comp_idem:
  1375   assumes "finite A" and "x \<in> A"
  1376   shows "F A \<circ> f x = F A"
  1377 using assms by (induct A)
  1378   (auto simp add: comp_fun_commutes idem_comp, simp add: commute_left_comp' [symmetric] comp_fun_commute')
  1379 
  1380 lemma subset_comp_idem:
  1381   assumes "finite A" and "B \<subseteq> A"
  1382   shows "F A \<circ> F B = F A"
  1383 proof -
  1384   from assms have "finite B" by (blast dest: finite_subset)
  1385   then show ?thesis using `B \<subseteq> A` by (induct B)
  1386     (simp_all add: o_assoc in_comp_idem `finite A`)
  1387 qed
  1388 
  1389 declare insert [simp del]
  1390 
  1391 lemma insert_idem [simp]:
  1392   assumes "finite A"
  1393   shows "F (insert x A) = F A \<circ> f x"
  1394   using assms by (cases "x \<in> A") (simp_all add: insert in_comp_idem insert_absorb)
  1395 
  1396 lemma union_idem:
  1397   assumes "finite A" and "finite B"
  1398   shows "F (A \<union> B) = F A \<circ> F B"
  1399 proof -
  1400   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1401   then have "F (A \<union> B) \<circ> F (A \<inter> B) = F (A \<union> B)" by (rule subset_comp_idem)
  1402   with assms show ?thesis by (simp add: union_inter)
  1403 qed
  1404 
  1405 end
  1406 
  1407 
  1408 subsubsection {* The image case with fixed function *}
  1409 
  1410 no_notation times (infixl "*" 70)
  1411 no_notation Groups.one ("1")
  1412 
  1413 locale folding_image_simple = comm_monoid +
  1414   fixes g :: "('b \<Rightarrow> 'a)"
  1415   fixes F :: "'b set \<Rightarrow> 'a"
  1416   assumes eq_fold_g: "finite A \<Longrightarrow> F A = fold_image f g 1 A"
  1417 begin
  1418 
  1419 lemma empty [simp]:
  1420   "F {} = 1"
  1421   by (simp add: eq_fold_g)
  1422 
  1423 lemma insert [simp]:
  1424   assumes "finite A" and "x \<notin> A"
  1425   shows "F (insert x A) = g x * F A"
  1426 proof -
  1427   interpret comp_fun_commute "%x y. (g x) * y" proof
  1428   qed (simp add: ac_simps fun_eq_iff)
  1429   with assms have "fold_image (op *) g 1 (insert x A) = g x * fold_image (op *) g 1 A"
  1430     by (simp add: fold_image_def)
  1431   with `finite A` show ?thesis by (simp add: eq_fold_g)
  1432 qed
  1433 
  1434 lemma remove:
  1435   assumes "finite A" and "x \<in> A"
  1436   shows "F A = g x * F (A - {x})"
  1437 proof -
  1438   from `x \<in> A` obtain B where A: "A = insert x B" and "x \<notin> B"
  1439     by (auto dest: mk_disjoint_insert)
  1440   moreover from `finite A` this have "finite B" by simp
  1441   ultimately show ?thesis by simp
  1442 qed
  1443 
  1444 lemma insert_remove:
  1445   assumes "finite A"
  1446   shows "F (insert x A) = g x * F (A - {x})"
  1447   using assms by (cases "x \<in> A") (simp_all add: remove insert_absorb)
  1448 
  1449 lemma neutral:
  1450   assumes "finite A" and "\<forall>x\<in>A. g x = 1"
  1451   shows "F A = 1"
  1452   using assms by (induct A) simp_all
  1453 
  1454 lemma union_inter:
  1455   assumes "finite A" and "finite B"
  1456   shows "F (A \<union> B) * F (A \<inter> B) = F A * F B"
  1457 using assms proof (induct A)
  1458   case empty then show ?case by simp
  1459 next
  1460   case (insert x A) then show ?case
  1461     by (auto simp add: insert_absorb Int_insert_left commute [of _ "g x"] assoc left_commute)
  1462 qed
  1463 
  1464 corollary union_inter_neutral:
  1465   assumes "finite A" and "finite B"
  1466   and I0: "\<forall>x \<in> A\<inter>B. g x = 1"
  1467   shows "F (A \<union> B) = F A * F B"
  1468   using assms by (simp add: union_inter [symmetric] neutral)
  1469 
  1470 corollary union_disjoint:
  1471   assumes "finite A" and "finite B"
  1472   assumes "A \<inter> B = {}"
  1473   shows "F (A \<union> B) = F A * F B"
  1474   using assms by (simp add: union_inter_neutral)
  1475 
  1476 end
  1477 
  1478 
  1479 subsubsection {* The image case with flexible function *}
  1480 
  1481 locale folding_image = comm_monoid +
  1482   fixes F :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b set \<Rightarrow> 'a"
  1483   assumes eq_fold: "\<And>g. finite A \<Longrightarrow> F g A = fold_image f g 1 A"
  1484 
  1485 sublocale folding_image < folding_image_simple "op *" 1 g "F g" proof
  1486 qed (fact eq_fold)
  1487 
  1488 context folding_image
  1489 begin
  1490 
  1491 lemma reindex: (* FIXME polymorhism *)
  1492   assumes "finite A" and "inj_on h A"
  1493   shows "F g (h ` A) = F (g \<circ> h) A"
  1494   using assms by (induct A) auto
  1495 
  1496 lemma cong:
  1497   assumes "finite A" and "\<And>x. x \<in> A \<Longrightarrow> g x = h x"
  1498   shows "F g A = F h A"
  1499 proof -
  1500   from assms have "ALL C. C <= A --> (ALL x:C. g x = h x) --> F g C = F h C"
  1501   apply - apply (erule finite_induct) apply simp
  1502   apply (simp add: subset_insert_iff, clarify)
  1503   apply (subgoal_tac "finite C")
  1504   prefer 2 apply (blast dest: finite_subset [COMP swap_prems_rl])
  1505   apply (subgoal_tac "C = insert x (C - {x})")
  1506   prefer 2 apply blast
  1507   apply (erule ssubst)
  1508   apply (drule spec)
  1509   apply (erule (1) notE impE)
  1510   apply (simp add: Ball_def del: insert_Diff_single)
  1511   done
  1512   with assms show ?thesis by simp
  1513 qed
  1514 
  1515 lemma UNION_disjoint:
  1516   assumes "finite I" and "\<forall>i\<in>I. finite (A i)"
  1517   and "\<forall>i\<in>I. \<forall>j\<in>I. i \<noteq> j \<longrightarrow> A i \<inter> A j = {}"
  1518   shows "F g (UNION I A) = F (F g \<circ> A) I"
  1519 apply (insert assms)
  1520 apply (induct rule: finite_induct)
  1521 apply simp
  1522 apply atomize
  1523 apply (subgoal_tac "\<forall>i\<in>Fa. x \<noteq> i")
  1524  prefer 2 apply blast
  1525 apply (subgoal_tac "A x Int UNION Fa A = {}")
  1526  prefer 2 apply blast
  1527 apply (simp add: union_disjoint)
  1528 done
  1529 
  1530 lemma distrib:
  1531   assumes "finite A"
  1532   shows "F (\<lambda>x. g x * h x) A = F g A * F h A"
  1533   using assms by (rule finite_induct) (simp_all add: assoc commute left_commute)
  1534 
  1535 lemma related: 
  1536   assumes Re: "R 1 1" 
  1537   and Rop: "\<forall>x1 y1 x2 y2. R x1 x2 \<and> R y1 y2 \<longrightarrow> R (x1 * y1) (x2 * y2)" 
  1538   and fS: "finite S" and Rfg: "\<forall>x\<in>S. R (h x) (g x)"
  1539   shows "R (F h S) (F g S)"
  1540   using fS by (rule finite_subset_induct) (insert assms, auto)
  1541 
  1542 lemma eq_general:
  1543   assumes fS: "finite S"
  1544   and h: "\<forall>y\<in>S'. \<exists>!x. x \<in> S \<and> h x = y" 
  1545   and f12:  "\<forall>x\<in>S. h x \<in> S' \<and> f2 (h x) = f1 x"
  1546   shows "F f1 S = F f2 S'"
  1547 proof-
  1548   from h f12 have hS: "h ` S = S'" by blast
  1549   {fix x y assume H: "x \<in> S" "y \<in> S" "h x = h y"
  1550     from f12 h H  have "x = y" by auto }
  1551   hence hinj: "inj_on h S" unfolding inj_on_def Ex1_def by blast
  1552   from f12 have th: "\<And>x. x \<in> S \<Longrightarrow> (f2 \<circ> h) x = f1 x" by auto 
  1553   from hS have "F f2 S' = F f2 (h ` S)" by simp
  1554   also have "\<dots> = F (f2 o h) S" using reindex [OF fS hinj, of f2] .
  1555   also have "\<dots> = F f1 S " using th cong [OF fS, of "f2 o h" f1]
  1556     by blast
  1557   finally show ?thesis ..
  1558 qed
  1559 
  1560 lemma eq_general_inverses:
  1561   assumes fS: "finite S" 
  1562   and kh: "\<And>y. y \<in> T \<Longrightarrow> k y \<in> S \<and> h (k y) = y"
  1563   and hk: "\<And>x. x \<in> S \<Longrightarrow> h x \<in> T \<and> k (h x) = x \<and> g (h x) = j x"
  1564   shows "F j S = F g T"
  1565   (* metis solves it, but not yet available here *)
  1566   apply (rule eq_general [OF fS, of T h g j])
  1567   apply (rule ballI)
  1568   apply (frule kh)
  1569   apply (rule ex1I[])
  1570   apply blast
  1571   apply clarsimp
  1572   apply (drule hk) apply simp
  1573   apply (rule sym)
  1574   apply (erule conjunct1[OF conjunct2[OF hk]])
  1575   apply (rule ballI)
  1576   apply (drule hk)
  1577   apply blast
  1578   done
  1579 
  1580 end
  1581 
  1582 
  1583 subsubsection {* The image case with fixed function and idempotency *}
  1584 
  1585 locale folding_image_simple_idem = folding_image_simple +
  1586   assumes idem: "x * x = x"
  1587 
  1588 sublocale folding_image_simple_idem < semilattice proof
  1589 qed (fact idem)
  1590 
  1591 context folding_image_simple_idem
  1592 begin
  1593 
  1594 lemma in_idem:
  1595   assumes "finite A" and "x \<in> A"
  1596   shows "g x * F A = F A"
  1597   using assms by (induct A) (auto simp add: left_commute)
  1598 
  1599 lemma subset_idem:
  1600   assumes "finite A" and "B \<subseteq> A"
  1601   shows "F B * F A = F A"
  1602 proof -
  1603   from assms have "finite B" by (blast dest: finite_subset)
  1604   then show ?thesis using `B \<subseteq> A` by (induct B)
  1605     (auto simp add: assoc in_idem `finite A`)
  1606 qed
  1607 
  1608 declare insert [simp del]
  1609 
  1610 lemma insert_idem [simp]:
  1611   assumes "finite A"
  1612   shows "F (insert x A) = g x * F A"
  1613   using assms by (cases "x \<in> A") (simp_all add: insert in_idem insert_absorb)
  1614 
  1615 lemma union_idem:
  1616   assumes "finite A" and "finite B"
  1617   shows "F (A \<union> B) = F A * F B"
  1618 proof -
  1619   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1620   then have "F (A \<inter> B) * F (A \<union> B) = F (A \<union> B)" by (rule subset_idem)
  1621   with assms show ?thesis by (simp add: union_inter [of A B, symmetric] commute)
  1622 qed
  1623 
  1624 end
  1625 
  1626 
  1627 subsubsection {* The image case with flexible function and idempotency *}
  1628 
  1629 locale folding_image_idem = folding_image +
  1630   assumes idem: "x * x = x"
  1631 
  1632 sublocale folding_image_idem < folding_image_simple_idem "op *" 1 g "F g" proof
  1633 qed (fact idem)
  1634 
  1635 
  1636 subsubsection {* The neutral-less case *}
  1637 
  1638 locale folding_one = abel_semigroup +
  1639   fixes F :: "'a set \<Rightarrow> 'a"
  1640   assumes eq_fold: "finite A \<Longrightarrow> F A = fold1 f A"
  1641 begin
  1642 
  1643 lemma singleton [simp]:
  1644   "F {x} = x"
  1645   by (simp add: eq_fold)
  1646 
  1647 lemma eq_fold':
  1648   assumes "finite A" and "x \<notin> A"
  1649   shows "F (insert x A) = fold (op *) x A"
  1650 proof -
  1651   interpret ab_semigroup_mult "op *" proof qed (simp_all add: ac_simps)
  1652   with assms show ?thesis by (simp add: eq_fold fold1_eq_fold)
  1653 qed
  1654 
  1655 lemma insert [simp]:
  1656   assumes "finite A" and "x \<notin> A" and "A \<noteq> {}"
  1657   shows "F (insert x A) = x * F A"
  1658 proof -
  1659   from `A \<noteq> {}` obtain b where "b \<in> A" by blast
  1660   then obtain B where *: "A = insert b B" "b \<notin> B" by (blast dest: mk_disjoint_insert)
  1661   with `finite A` have "finite B" by simp
  1662   interpret fold: folding "op *" "\<lambda>a b. fold (op *) b a" proof
  1663   qed (simp_all add: fun_eq_iff ac_simps)
  1664   thm fold.comp_fun_commute' [of B b, simplified fun_eq_iff, simplified]
  1665   from `finite B` fold.comp_fun_commute' [of B x]
  1666     have "op * x \<circ> (\<lambda>b. fold op * b B) = (\<lambda>b. fold op * b B) \<circ> op * x" by simp
  1667   then have A: "x * fold op * b B = fold op * (b * x) B" by (simp add: fun_eq_iff commute)
  1668   from `finite B` * fold.insert [of B b]
  1669     have "(\<lambda>x. fold op * x (insert b B)) = (\<lambda>x. fold op * x B) \<circ> op * b" by simp
  1670   then have B: "fold op * x (insert b B) = fold op * (b * x) B" by (simp add: fun_eq_iff)
  1671   from A B assms * show ?thesis by (simp add: eq_fold' del: fold.insert)
  1672 qed
  1673 
  1674 lemma remove:
  1675   assumes "finite A" and "x \<in> A"
  1676   shows "F A = (if A - {x} = {} then x else x * F (A - {x}))"
  1677 proof -
  1678   from assms obtain B where "A = insert x B" and "x \<notin> B" by (blast dest: mk_disjoint_insert)
  1679   with assms show ?thesis by simp
  1680 qed
  1681 
  1682 lemma insert_remove:
  1683   assumes "finite A"
  1684   shows "F (insert x A) = (if A - {x} = {} then x else x * F (A - {x}))"
  1685   using assms by (cases "x \<in> A") (simp_all add: insert_absorb remove)
  1686 
  1687 lemma union_disjoint:
  1688   assumes "finite A" "A \<noteq> {}" and "finite B" "B \<noteq> {}" and "A \<inter> B = {}"
  1689   shows "F (A \<union> B) = F A * F B"
  1690   using assms by (induct A rule: finite_ne_induct) (simp_all add: ac_simps)
  1691 
  1692 lemma union_inter:
  1693   assumes "finite A" and "finite B" and "A \<inter> B \<noteq> {}"
  1694   shows "F (A \<union> B) * F (A \<inter> B) = F A * F B"
  1695 proof -
  1696   from assms have "A \<noteq> {}" and "B \<noteq> {}" by auto
  1697   from `finite A` `A \<noteq> {}` `A \<inter> B \<noteq> {}` show ?thesis proof (induct A rule: finite_ne_induct)
  1698     case (singleton x) then show ?case by (simp add: insert_absorb ac_simps)
  1699   next
  1700     case (insert x A) show ?case proof (cases "x \<in> B")
  1701       case True then have "B \<noteq> {}" by auto
  1702       with insert True `finite B` show ?thesis by (cases "A \<inter> B = {}")
  1703         (simp_all add: insert_absorb ac_simps union_disjoint)
  1704     next
  1705       case False with insert have "F (A \<union> B) * F (A \<inter> B) = F A * F B" by simp
  1706       moreover from False `finite B` insert have "finite (A \<union> B)" "x \<notin> A \<union> B" "A \<union> B \<noteq> {}"
  1707         by auto
  1708       ultimately show ?thesis using False `finite A` `x \<notin> A` `A \<noteq> {}` by (simp add: assoc)
  1709     qed
  1710   qed
  1711 qed
  1712 
  1713 lemma closed:
  1714   assumes "finite A" "A \<noteq> {}" and elem: "\<And>x y. x * y \<in> {x, y}"
  1715   shows "F A \<in> A"
  1716 using `finite A` `A \<noteq> {}` proof (induct rule: finite_ne_induct)
  1717   case singleton then show ?case by simp
  1718 next
  1719   case insert with elem show ?case by force
  1720 qed
  1721 
  1722 end
  1723 
  1724 
  1725 subsubsection {* The neutral-less case with idempotency *}
  1726 
  1727 locale folding_one_idem = folding_one +
  1728   assumes idem: "x * x = x"
  1729 
  1730 sublocale folding_one_idem < semilattice proof
  1731 qed (fact idem)
  1732 
  1733 context folding_one_idem
  1734 begin
  1735 
  1736 lemma in_idem:
  1737   assumes "finite A" and "x \<in> A"
  1738   shows "x * F A = F A"
  1739 proof -
  1740   from assms have "A \<noteq> {}" by auto
  1741   with `finite A` show ?thesis using `x \<in> A` by (induct A rule: finite_ne_induct) (auto simp add: ac_simps)
  1742 qed
  1743 
  1744 lemma subset_idem:
  1745   assumes "finite A" "B \<noteq> {}" and "B \<subseteq> A"
  1746   shows "F B * F A = F A"
  1747 proof -
  1748   from assms have "finite B" by (blast dest: finite_subset)
  1749   then show ?thesis using `B \<noteq> {}` `B \<subseteq> A` by (induct B rule: finite_ne_induct)
  1750     (simp_all add: assoc in_idem `finite A`)
  1751 qed
  1752 
  1753 lemma eq_fold_idem':
  1754   assumes "finite A"
  1755   shows "F (insert a A) = fold (op *) a A"
  1756 proof -
  1757   interpret ab_semigroup_idem_mult "op *" proof qed (simp_all add: ac_simps)
  1758   with assms show ?thesis by (simp add: eq_fold fold1_eq_fold_idem)
  1759 qed
  1760 
  1761 lemma insert_idem [simp]:
  1762   assumes "finite A" and "A \<noteq> {}"
  1763   shows "F (insert x A) = x * F A"
  1764 proof (cases "x \<in> A")
  1765   case False from `finite A` `x \<notin> A` `A \<noteq> {}` show ?thesis by (rule insert)
  1766 next
  1767   case True
  1768   from `finite A` `A \<noteq> {}` show ?thesis by (simp add: in_idem insert_absorb True)
  1769 qed
  1770   
  1771 lemma union_idem:
  1772   assumes "finite A" "A \<noteq> {}" and "finite B" "B \<noteq> {}"
  1773   shows "F (A \<union> B) = F A * F B"
  1774 proof (cases "A \<inter> B = {}")
  1775   case True with assms show ?thesis by (simp add: union_disjoint)
  1776 next
  1777   case False
  1778   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1779   with False have "F (A \<inter> B) * F (A \<union> B) = F (A \<union> B)" by (auto intro: subset_idem)
  1780   with assms False show ?thesis by (simp add: union_inter [of A B, symmetric] commute)
  1781 qed
  1782 
  1783 lemma hom_commute:
  1784   assumes hom: "\<And>x y. h (x * y) = h x * h y"
  1785   and N: "finite N" "N \<noteq> {}" shows "h (F N) = F (h ` N)"
  1786 using N proof (induct rule: finite_ne_induct)
  1787   case singleton thus ?case by simp
  1788 next
  1789   case (insert n N)
  1790   then have "h (F (insert n N)) = h (n * F N)" by simp
  1791   also have "\<dots> = h n * h (F N)" by (rule hom)
  1792   also have "h (F N) = F (h ` N)" by(rule insert)
  1793   also have "h n * \<dots> = F (insert (h n) (h ` N))"
  1794     using insert by(simp)
  1795   also have "insert (h n) (h ` N) = h ` insert n N" by simp
  1796   finally show ?case .
  1797 qed
  1798 
  1799 end
  1800 
  1801 notation times (infixl "*" 70)
  1802 notation Groups.one ("1")
  1803 
  1804 
  1805 subsection {* Finite cardinality *}
  1806 
  1807 text {* This definition, although traditional, is ugly to work with:
  1808 @{text "card A == LEAST n. EX f. A = {f i | i. i < n}"}.
  1809 But now that we have @{text fold_image} things are easy:
  1810 *}
  1811 
  1812 definition card :: "'a set \<Rightarrow> nat" where
  1813   "card A = (if finite A then fold_image (op +) (\<lambda>x. 1) 0 A else 0)"
  1814 
  1815 interpretation card: folding_image_simple "op +" 0 "\<lambda>x. 1" card proof
  1816 qed (simp add: card_def)
  1817 
  1818 lemma card_infinite [simp]:
  1819   "\<not> finite A \<Longrightarrow> card A = 0"
  1820   by (simp add: card_def)
  1821 
  1822 lemma card_empty:
  1823   "card {} = 0"
  1824   by (fact card.empty)
  1825 
  1826 lemma card_insert_disjoint:
  1827   "finite A ==> x \<notin> A ==> card (insert x A) = Suc (card A)"
  1828   by simp
  1829 
  1830 lemma card_insert_if:
  1831   "finite A ==> card (insert x A) = (if x \<in> A then card A else Suc (card A))"
  1832   by auto (simp add: card.insert_remove card.remove)
  1833 
  1834 lemma card_ge_0_finite:
  1835   "card A > 0 \<Longrightarrow> finite A"
  1836   by (rule ccontr) simp
  1837 
  1838 lemma card_0_eq [simp, no_atp]:
  1839   "finite A \<Longrightarrow> card A = 0 \<longleftrightarrow> A = {}"
  1840   by (auto dest: mk_disjoint_insert)
  1841 
  1842 lemma finite_UNIV_card_ge_0:
  1843   "finite (UNIV :: 'a set) \<Longrightarrow> card (UNIV :: 'a set) > 0"
  1844   by (rule ccontr) simp
  1845 
  1846 lemma card_eq_0_iff:
  1847   "card A = 0 \<longleftrightarrow> A = {} \<or> \<not> finite A"
  1848   by auto
  1849 
  1850 lemma card_gt_0_iff:
  1851   "0 < card A \<longleftrightarrow> A \<noteq> {} \<and> finite A"
  1852   by (simp add: neq0_conv [symmetric] card_eq_0_iff) 
  1853 
  1854 lemma card_Suc_Diff1: "finite A ==> x: A ==> Suc (card (A - {x})) = card A"
  1855 apply(rule_tac t = A in insert_Diff [THEN subst], assumption)
  1856 apply(simp del:insert_Diff_single)
  1857 done
  1858 
  1859 lemma card_Diff_singleton:
  1860   "finite A ==> x: A ==> card (A - {x}) = card A - 1"
  1861 by (simp add: card_Suc_Diff1 [symmetric])
  1862 
  1863 lemma card_Diff_singleton_if:
  1864   "finite A ==> card (A-{x}) = (if x : A then card A - 1 else card A)"
  1865 by (simp add: card_Diff_singleton)
  1866 
  1867 lemma card_Diff_insert[simp]:
  1868 assumes "finite A" and "a:A" and "a ~: B"
  1869 shows "card(A - insert a B) = card(A - B) - 1"
  1870 proof -
  1871   have "A - insert a B = (A - B) - {a}" using assms by blast
  1872   then show ?thesis using assms by(simp add:card_Diff_singleton)
  1873 qed
  1874 
  1875 lemma card_insert: "finite A ==> card (insert x A) = Suc (card (A - {x}))"
  1876 by (simp add: card_insert_if card_Suc_Diff1 del:card_Diff_insert)
  1877 
  1878 lemma card_insert_le: "finite A ==> card A <= card (insert x A)"
  1879 by (simp add: card_insert_if)
  1880 
  1881 lemma card_Collect_less_nat[simp]: "card{i::nat. i < n} = n"
  1882 by (induct n) (simp_all add:less_Suc_eq Collect_disj_eq)
  1883 
  1884 lemma card_Collect_le_nat[simp]: "card{i::nat. i <= n} = Suc n"
  1885 using card_Collect_less_nat[of "Suc n"] by(simp add: less_Suc_eq_le)
  1886 
  1887 lemma card_mono:
  1888   assumes "finite B" and "A \<subseteq> B"
  1889   shows "card A \<le> card B"
  1890 proof -
  1891   from assms have "finite A" by (auto intro: finite_subset)
  1892   then show ?thesis using assms proof (induct A arbitrary: B)
  1893     case empty then show ?case by simp
  1894   next
  1895     case (insert x A)
  1896     then have "x \<in> B" by simp
  1897     from insert have "A \<subseteq> B - {x}" and "finite (B - {x})" by auto
  1898     with insert.hyps have "card A \<le> card (B - {x})" by auto
  1899     with `finite A` `x \<notin> A` `finite B` `x \<in> B` show ?case by simp (simp only: card.remove)
  1900   qed
  1901 qed
  1902 
  1903 lemma card_seteq: "finite B ==> (!!A. A <= B ==> card B <= card A ==> A = B)"
  1904 apply (induct rule: finite_induct)
  1905 apply simp
  1906 apply clarify
  1907 apply (subgoal_tac "finite A & A - {x} <= F")
  1908  prefer 2 apply (blast intro: finite_subset, atomize)
  1909 apply (drule_tac x = "A - {x}" in spec)
  1910 apply (simp add: card_Diff_singleton_if split add: split_if_asm)
  1911 apply (case_tac "card A", auto)
  1912 done
  1913 
  1914 lemma psubset_card_mono: "finite B ==> A < B ==> card A < card B"
  1915 apply (simp add: psubset_eq linorder_not_le [symmetric])
  1916 apply (blast dest: card_seteq)
  1917 done
  1918 
  1919 lemma card_Un_Int: "finite A ==> finite B
  1920     ==> card A + card B = card (A Un B) + card (A Int B)"
  1921   by (fact card.union_inter [symmetric])
  1922 
  1923 lemma card_Un_disjoint: "finite A ==> finite B
  1924     ==> A Int B = {} ==> card (A Un B) = card A + card B"
  1925   by (fact card.union_disjoint)
  1926 
  1927 lemma card_Diff_subset:
  1928   assumes "finite B" and "B \<subseteq> A"
  1929   shows "card (A - B) = card A - card B"
  1930 proof (cases "finite A")
  1931   case False with assms show ?thesis by simp
  1932 next
  1933   case True with assms show ?thesis by (induct B arbitrary: A) simp_all
  1934 qed
  1935 
  1936 lemma card_Diff_subset_Int:
  1937   assumes AB: "finite (A \<inter> B)" shows "card (A - B) = card A - card (A \<inter> B)"
  1938 proof -
  1939   have "A - B = A - A \<inter> B" by auto
  1940   thus ?thesis
  1941     by (simp add: card_Diff_subset AB) 
  1942 qed
  1943 
  1944 lemma diff_card_le_card_Diff:
  1945 assumes "finite B" shows "card A - card B \<le> card(A - B)"
  1946 proof-
  1947   have "card A - card B \<le> card A - card (A \<inter> B)"
  1948     using card_mono[OF assms Int_lower2, of A] by arith
  1949   also have "\<dots> = card(A-B)" using assms by(simp add: card_Diff_subset_Int)
  1950   finally show ?thesis .
  1951 qed
  1952 
  1953 lemma card_Diff1_less: "finite A ==> x: A ==> card (A - {x}) < card A"
  1954 apply (rule Suc_less_SucD)
  1955 apply (simp add: card_Suc_Diff1 del:card_Diff_insert)
  1956 done
  1957 
  1958 lemma card_Diff2_less:
  1959   "finite A ==> x: A ==> y: A ==> card (A - {x} - {y}) < card A"
  1960 apply (case_tac "x = y")
  1961  apply (simp add: card_Diff1_less del:card_Diff_insert)
  1962 apply (rule less_trans)
  1963  prefer 2 apply (auto intro!: card_Diff1_less simp del:card_Diff_insert)
  1964 done
  1965 
  1966 lemma card_Diff1_le: "finite A ==> card (A - {x}) <= card A"
  1967 apply (case_tac "x : A")
  1968  apply (simp_all add: card_Diff1_less less_imp_le)
  1969 done
  1970 
  1971 lemma card_psubset: "finite B ==> A \<subseteq> B ==> card A < card B ==> A < B"
  1972 by (erule psubsetI, blast)
  1973 
  1974 lemma insert_partition:
  1975   "\<lbrakk> x \<notin> F; \<forall>c1 \<in> insert x F. \<forall>c2 \<in> insert x F. c1 \<noteq> c2 \<longrightarrow> c1 \<inter> c2 = {} \<rbrakk>
  1976   \<Longrightarrow> x \<inter> \<Union> F = {}"
  1977 by auto
  1978 
  1979 lemma finite_psubset_induct[consumes 1, case_names psubset]:
  1980   assumes fin: "finite A" 
  1981   and     major: "\<And>A. finite A \<Longrightarrow> (\<And>B. B \<subset> A \<Longrightarrow> P B) \<Longrightarrow> P A" 
  1982   shows "P A"
  1983 using fin
  1984 proof (induct A taking: card rule: measure_induct_rule)
  1985   case (less A)
  1986   have fin: "finite A" by fact
  1987   have ih: "\<And>B. \<lbrakk>card B < card A; finite B\<rbrakk> \<Longrightarrow> P B" by fact
  1988   { fix B 
  1989     assume asm: "B \<subset> A"
  1990     from asm have "card B < card A" using psubset_card_mono fin by blast
  1991     moreover
  1992     from asm have "B \<subseteq> A" by auto
  1993     then have "finite B" using fin finite_subset by blast
  1994     ultimately 
  1995     have "P B" using ih by simp
  1996   }
  1997   with fin show "P A" using major by blast
  1998 qed
  1999 
  2000 text{* main cardinality theorem *}
  2001 lemma card_partition [rule_format]:
  2002   "finite C ==>
  2003      finite (\<Union> C) -->
  2004      (\<forall>c\<in>C. card c = k) -->
  2005      (\<forall>c1 \<in> C. \<forall>c2 \<in> C. c1 \<noteq> c2 --> c1 \<inter> c2 = {}) -->
  2006      k * card(C) = card (\<Union> C)"
  2007 apply (erule finite_induct, simp)
  2008 apply (simp add: card_Un_disjoint insert_partition 
  2009        finite_subset [of _ "\<Union> (insert x F)"])
  2010 done
  2011 
  2012 lemma card_eq_UNIV_imp_eq_UNIV:
  2013   assumes fin: "finite (UNIV :: 'a set)"
  2014   and card: "card A = card (UNIV :: 'a set)"
  2015   shows "A = (UNIV :: 'a set)"
  2016 proof
  2017   show "A \<subseteq> UNIV" by simp
  2018   show "UNIV \<subseteq> A"
  2019   proof
  2020     fix x
  2021     show "x \<in> A"
  2022     proof (rule ccontr)
  2023       assume "x \<notin> A"
  2024       then have "A \<subset> UNIV" by auto
  2025       with fin have "card A < card (UNIV :: 'a set)" by (fact psubset_card_mono)
  2026       with card show False by simp
  2027     qed
  2028   qed
  2029 qed
  2030 
  2031 text{*The form of a finite set of given cardinality*}
  2032 
  2033 lemma card_eq_SucD:
  2034 assumes "card A = Suc k"
  2035 shows "\<exists>b B. A = insert b B & b \<notin> B & card B = k & (k=0 \<longrightarrow> B={})"
  2036 proof -
  2037   have fin: "finite A" using assms by (auto intro: ccontr)
  2038   moreover have "card A \<noteq> 0" using assms by auto
  2039   ultimately obtain b where b: "b \<in> A" by auto
  2040   show ?thesis
  2041   proof (intro exI conjI)
  2042     show "A = insert b (A-{b})" using b by blast
  2043     show "b \<notin> A - {b}" by blast
  2044     show "card (A - {b}) = k" and "k = 0 \<longrightarrow> A - {b} = {}"
  2045       using assms b fin by(fastsimp dest:mk_disjoint_insert)+
  2046   qed
  2047 qed
  2048 
  2049 lemma card_Suc_eq:
  2050   "(card A = Suc k) =
  2051    (\<exists>b B. A = insert b B & b \<notin> B & card B = k & (k=0 \<longrightarrow> B={}))"
  2052 apply(rule iffI)
  2053  apply(erule card_eq_SucD)
  2054 apply(auto)
  2055 apply(subst card_insert)
  2056  apply(auto intro:ccontr)
  2057 done
  2058 
  2059 lemma finite_fun_UNIVD2:
  2060   assumes fin: "finite (UNIV :: ('a \<Rightarrow> 'b) set)"
  2061   shows "finite (UNIV :: 'b set)"
  2062 proof -
  2063   from fin have "finite (range (\<lambda>f :: 'a \<Rightarrow> 'b. f arbitrary))"
  2064     by(rule finite_imageI)
  2065   moreover have "UNIV = range (\<lambda>f :: 'a \<Rightarrow> 'b. f arbitrary)"
  2066     by(rule UNIV_eq_I) auto
  2067   ultimately show "finite (UNIV :: 'b set)" by simp
  2068 qed
  2069 
  2070 lemma card_UNIV_unit: "card (UNIV :: unit set) = 1"
  2071   unfolding UNIV_unit by simp
  2072 
  2073 
  2074 subsubsection {* Cardinality of image *}
  2075 
  2076 lemma card_image_le: "finite A ==> card (f ` A) <= card A"
  2077 apply (induct rule: finite_induct)
  2078  apply simp
  2079 apply (simp add: le_SucI card_insert_if)
  2080 done
  2081 
  2082 lemma card_image:
  2083   assumes "inj_on f A"
  2084   shows "card (f ` A) = card A"
  2085 proof (cases "finite A")
  2086   case True then show ?thesis using assms by (induct A) simp_all
  2087 next
  2088   case False then have "\<not> finite (f ` A)" using assms by (auto dest: finite_imageD)
  2089   with False show ?thesis by simp
  2090 qed
  2091 
  2092 lemma bij_betw_same_card: "bij_betw f A B \<Longrightarrow> card A = card B"
  2093 by(auto simp: card_image bij_betw_def)
  2094 
  2095 lemma endo_inj_surj: "finite A ==> f ` A \<subseteq> A ==> inj_on f A ==> f ` A = A"
  2096 by (simp add: card_seteq card_image)
  2097 
  2098 lemma eq_card_imp_inj_on:
  2099   "[| finite A; card(f ` A) = card A |] ==> inj_on f A"
  2100 apply (induct rule:finite_induct)
  2101 apply simp
  2102 apply(frule card_image_le[where f = f])
  2103 apply(simp add:card_insert_if split:if_splits)
  2104 done
  2105 
  2106 lemma inj_on_iff_eq_card:
  2107   "finite A ==> inj_on f A = (card(f ` A) = card A)"
  2108 by(blast intro: card_image eq_card_imp_inj_on)
  2109 
  2110 
  2111 lemma card_inj_on_le:
  2112   "[|inj_on f A; f ` A \<subseteq> B; finite B |] ==> card A \<le> card B"
  2113 apply (subgoal_tac "finite A") 
  2114  apply (force intro: card_mono simp add: card_image [symmetric])
  2115 apply (blast intro: finite_imageD dest: finite_subset) 
  2116 done
  2117 
  2118 lemma card_bij_eq:
  2119   "[|inj_on f A; f ` A \<subseteq> B; inj_on g B; g ` B \<subseteq> A;
  2120      finite A; finite B |] ==> card A = card B"
  2121 by (auto intro: le_antisym card_inj_on_le)
  2122 
  2123 lemma bij_betw_finite:
  2124   assumes "bij_betw f A B"
  2125   shows "finite A \<longleftrightarrow> finite B"
  2126 using assms unfolding bij_betw_def
  2127 using finite_imageD[of f A] by auto
  2128 
  2129 
  2130 subsubsection {* Pigeonhole Principles *}
  2131 
  2132 lemma pigeonhole: "card A > card(f ` A) \<Longrightarrow> ~ inj_on f A "
  2133 by (auto dest: card_image less_irrefl_nat)
  2134 
  2135 lemma pigeonhole_infinite:
  2136 assumes  "~ finite A" and "finite(f`A)"
  2137 shows "EX a0:A. ~finite{a:A. f a = f a0}"
  2138 proof -
  2139   have "finite(f`A) \<Longrightarrow> ~ finite A \<Longrightarrow> EX a0:A. ~finite{a:A. f a = f a0}"
  2140   proof(induct "f`A" arbitrary: A rule: finite_induct)
  2141     case empty thus ?case by simp
  2142   next
  2143     case (insert b F)
  2144     show ?case
  2145     proof cases
  2146       assume "finite{a:A. f a = b}"
  2147       hence "~ finite(A - {a:A. f a = b})" using `\<not> finite A` by simp
  2148       also have "A - {a:A. f a = b} = {a:A. f a \<noteq> b}" by blast
  2149       finally have "~ finite({a:A. f a \<noteq> b})" .
  2150       from insert(3)[OF _ this]
  2151       show ?thesis using insert(2,4) by simp (blast intro: rev_finite_subset)
  2152     next
  2153       assume 1: "~finite{a:A. f a = b}"
  2154       hence "{a \<in> A. f a = b} \<noteq> {}" by force
  2155       thus ?thesis using 1 by blast
  2156     qed
  2157   qed
  2158   from this[OF assms(2,1)] show ?thesis .
  2159 qed
  2160 
  2161 lemma pigeonhole_infinite_rel:
  2162 assumes "~finite A" and "finite B" and "ALL a:A. EX b:B. R a b"
  2163 shows "EX b:B. ~finite{a:A. R a b}"
  2164 proof -
  2165    let ?F = "%a. {b:B. R a b}"
  2166    from finite_Pow_iff[THEN iffD2, OF `finite B`]
  2167    have "finite(?F ` A)" by(blast intro: rev_finite_subset)
  2168    from pigeonhole_infinite[where f = ?F, OF assms(1) this]
  2169    obtain a0 where "a0\<in>A" and 1: "\<not> finite {a\<in>A. ?F a = ?F a0}" ..
  2170    obtain b0 where "b0 : B" and "R a0 b0" using `a0:A` assms(3) by blast
  2171    { assume "finite{a:A. R a b0}"
  2172      then have "finite {a\<in>A. ?F a = ?F a0}"
  2173        using `b0 : B` `R a0 b0` by(blast intro: rev_finite_subset)
  2174    }
  2175    with 1 `b0 : B` show ?thesis by blast
  2176 qed
  2177 
  2178 
  2179 subsubsection {* Cardinality of sums *}
  2180 
  2181 lemma card_Plus:
  2182   assumes "finite A" and "finite B"
  2183   shows "card (A <+> B) = card A + card B"
  2184 proof -
  2185   have "Inl`A \<inter> Inr`B = {}" by fast
  2186   with assms show ?thesis
  2187     unfolding Plus_def
  2188     by (simp add: card_Un_disjoint card_image)
  2189 qed
  2190 
  2191 lemma card_Plus_conv_if:
  2192   "card (A <+> B) = (if finite A \<and> finite B then card A + card B else 0)"
  2193   by (auto simp add: card_Plus)
  2194 
  2195 
  2196 subsubsection {* Cardinality of the Powerset *}
  2197 
  2198 lemma card_Pow: "finite A ==> card (Pow A) = Suc (Suc 0) ^ card A"  (* FIXME numeral 2 (!?) *)
  2199 apply (induct rule: finite_induct)
  2200  apply (simp_all add: Pow_insert)
  2201 apply (subst card_Un_disjoint, blast)
  2202   apply (blast, blast)
  2203 apply (subgoal_tac "inj_on (insert x) (Pow F)")
  2204  apply (simp add: card_image Pow_insert)
  2205 apply (unfold inj_on_def)
  2206 apply (blast elim!: equalityE)
  2207 done
  2208 
  2209 text {* Relates to equivalence classes.  Based on a theorem of F. Kamm\"uller.  *}
  2210 
  2211 lemma dvd_partition:
  2212   "finite (Union C) ==>
  2213     ALL c : C. k dvd card c ==>
  2214     (ALL c1: C. ALL c2: C. c1 \<noteq> c2 --> c1 Int c2 = {}) ==>
  2215   k dvd card (Union C)"
  2216 apply (frule finite_UnionD)
  2217 apply (rotate_tac -1)
  2218 apply (induct rule: finite_induct)
  2219 apply simp_all
  2220 apply clarify
  2221 apply (subst card_Un_disjoint)
  2222    apply (auto simp add: disjoint_eq_subset_Compl)
  2223 done
  2224 
  2225 
  2226 subsubsection {* Relating injectivity and surjectivity *}
  2227 
  2228 lemma finite_surj_inj: "finite A \<Longrightarrow> A \<subseteq> f ` A \<Longrightarrow> inj_on f A"
  2229 apply(rule eq_card_imp_inj_on, assumption)
  2230 apply(frule finite_imageI)
  2231 apply(drule (1) card_seteq)
  2232  apply(erule card_image_le)
  2233 apply simp
  2234 done
  2235 
  2236 lemma finite_UNIV_surj_inj: fixes f :: "'a \<Rightarrow> 'a"
  2237 shows "finite(UNIV:: 'a set) \<Longrightarrow> surj f \<Longrightarrow> inj f"
  2238 by (blast intro: finite_surj_inj subset_UNIV)
  2239 
  2240 lemma finite_UNIV_inj_surj: fixes f :: "'a \<Rightarrow> 'a"
  2241 shows "finite(UNIV:: 'a set) \<Longrightarrow> inj f \<Longrightarrow> surj f"
  2242 by(fastsimp simp:surj_def dest!: endo_inj_surj)
  2243 
  2244 corollary infinite_UNIV_nat[iff]: "~finite(UNIV::nat set)"
  2245 proof
  2246   assume "finite(UNIV::nat set)"
  2247   with finite_UNIV_inj_surj[of Suc]
  2248   show False by simp (blast dest: Suc_neq_Zero surjD)
  2249 qed
  2250 
  2251 (* Often leads to bogus ATP proofs because of reduced type information, hence no_atp *)
  2252 lemma infinite_UNIV_char_0[no_atp]:
  2253   "\<not> finite (UNIV::'a::semiring_char_0 set)"
  2254 proof
  2255   assume "finite (UNIV::'a set)"
  2256   with subset_UNIV have "finite (range of_nat::'a set)"
  2257     by (rule finite_subset)
  2258   moreover have "inj (of_nat::nat \<Rightarrow> 'a)"
  2259     by (simp add: inj_on_def)
  2260   ultimately have "finite (UNIV::nat set)"
  2261     by (rule finite_imageD)
  2262   then show "False"
  2263     by simp
  2264 qed
  2265 
  2266 end