src/HOL/Fun.thy
author hoelzl
Tue Nov 23 14:14:17 2010 +0100 (2010-11-23)
changeset 40703 d1fc454d6735
parent 40702 cf26dd7395e4
child 40719 acb830207103
permissions -rw-r--r--
Move some missing lemmas from Andrei Popescus 'Ordinals and Cardinals' AFP entry to the HOL-image.
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Copyright   1994  University of Cambridge
     4 *)
     5 
     6 header {* Notions about functions *}
     7 
     8 theory Fun
     9 imports Complete_Lattice
    10 begin
    11 
    12 text{*As a simplification rule, it replaces all function equalities by
    13   first-order equalities.*}
    14 lemma fun_eq_iff: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
    15 apply (rule iffI)
    16 apply (simp (no_asm_simp))
    17 apply (rule ext)
    18 apply (simp (no_asm_simp))
    19 done
    20 
    21 lemma apply_inverse:
    22   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    23   by auto
    24 
    25 
    26 subsection {* The Identity Function @{text id} *}
    27 
    28 definition
    29   id :: "'a \<Rightarrow> 'a"
    30 where
    31   "id = (\<lambda>x. x)"
    32 
    33 lemma id_apply [simp]: "id x = x"
    34   by (simp add: id_def)
    35 
    36 lemma image_ident [simp]: "(%x. x) ` Y = Y"
    37 by blast
    38 
    39 lemma image_id [simp]: "id ` Y = Y"
    40 by (simp add: id_def)
    41 
    42 lemma vimage_ident [simp]: "(%x. x) -` Y = Y"
    43 by blast
    44 
    45 lemma vimage_id [simp]: "id -` A = A"
    46 by (simp add: id_def)
    47 
    48 
    49 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    50 
    51 definition
    52   comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55)
    53 where
    54   "f o g = (\<lambda>x. f (g x))"
    55 
    56 notation (xsymbols)
    57   comp  (infixl "\<circ>" 55)
    58 
    59 notation (HTML output)
    60   comp  (infixl "\<circ>" 55)
    61 
    62 text{*compatibility*}
    63 lemmas o_def = comp_def
    64 
    65 lemma o_apply [simp]: "(f o g) x = f (g x)"
    66 by (simp add: comp_def)
    67 
    68 lemma o_assoc: "f o (g o h) = f o g o h"
    69 by (simp add: comp_def)
    70 
    71 lemma id_o [simp]: "id o g = g"
    72 by (simp add: comp_def)
    73 
    74 lemma o_id [simp]: "f o id = f"
    75 by (simp add: comp_def)
    76 
    77 lemma o_eq_dest:
    78   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    79   by (simp only: o_def) (fact fun_cong)
    80 
    81 lemma o_eq_elim:
    82   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    83   by (erule meta_mp) (fact o_eq_dest) 
    84 
    85 lemma image_compose: "(f o g) ` r = f`(g`r)"
    86 by (simp add: comp_def, blast)
    87 
    88 lemma vimage_compose: "(g \<circ> f) -` x = f -` (g -` x)"
    89   by auto
    90 
    91 lemma UN_o: "UNION A (g o f) = UNION (f`A) g"
    92 by (unfold comp_def, blast)
    93 
    94 
    95 subsection {* The Forward Composition Operator @{text fcomp} *}
    96 
    97 definition
    98   fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60)
    99 where
   100   "f \<circ>> g = (\<lambda>x. g (f x))"
   101 
   102 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
   103   by (simp add: fcomp_def)
   104 
   105 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
   106   by (simp add: fcomp_def)
   107 
   108 lemma id_fcomp [simp]: "id \<circ>> g = g"
   109   by (simp add: fcomp_def)
   110 
   111 lemma fcomp_id [simp]: "f \<circ>> id = f"
   112   by (simp add: fcomp_def)
   113 
   114 code_const fcomp
   115   (Eval infixl 1 "#>")
   116 
   117 no_notation fcomp (infixl "\<circ>>" 60)
   118 
   119 
   120 subsection {* Mapping functions *}
   121 
   122 definition map_fun :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'c \<Rightarrow> 'd" where
   123   "map_fun f g h = g \<circ> h \<circ> f"
   124 
   125 lemma map_fun_apply [simp]:
   126   "map_fun f g h x = g (h (f x))"
   127   by (simp add: map_fun_def)
   128 
   129 type_mapper map_fun
   130   by (simp_all add: fun_eq_iff)
   131 
   132 
   133 subsection {* Injectivity and Bijectivity *}
   134 
   135 definition inj_on :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> bool" where -- "injective"
   136   "inj_on f A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. f x = f y \<longrightarrow> x = y)"
   137 
   138 definition bij_betw :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool" where -- "bijective"
   139   "bij_betw f A B \<longleftrightarrow> inj_on f A \<and> f ` A = B"
   140 
   141 text{*A common special case: functions injective, surjective or bijective over
   142 the entire domain type.*}
   143 
   144 abbreviation
   145   "inj f \<equiv> inj_on f UNIV"
   146 
   147 abbreviation surj :: "('a \<Rightarrow> 'b) \<Rightarrow> bool" where -- "surjective"
   148   "surj f \<equiv> (range f = UNIV)"
   149 
   150 abbreviation
   151   "bij f \<equiv> bij_betw f UNIV UNIV"
   152 
   153 lemma injI:
   154   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   155   shows "inj f"
   156   using assms unfolding inj_on_def by auto
   157 
   158 text{*For Proofs in @{text "Tools/Datatype/datatype_rep_proofs"}*}
   159 lemma datatype_injI:
   160     "(!! x. ALL y. f(x) = f(y) --> x=y) ==> inj(f)"
   161 by (simp add: inj_on_def)
   162 
   163 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   164   by (unfold inj_on_def, blast)
   165 
   166 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   167 by (simp add: inj_on_def)
   168 
   169 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   170 by (force simp add: inj_on_def)
   171 
   172 lemma inj_on_cong:
   173   "(\<And> a. a : A \<Longrightarrow> f a = g a) \<Longrightarrow> inj_on f A = inj_on g A"
   174 unfolding inj_on_def by auto
   175 
   176 lemma inj_on_strict_subset:
   177   "\<lbrakk> inj_on f B; A < B \<rbrakk> \<Longrightarrow> f`A < f`B"
   178 unfolding inj_on_def unfolding image_def by blast
   179 
   180 lemma inj_comp:
   181   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   182   by (simp add: inj_on_def)
   183 
   184 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   185   by (simp add: inj_on_def fun_eq_iff)
   186 
   187 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   188 by (simp add: inj_on_eq_iff)
   189 
   190 lemma inj_on_id[simp]: "inj_on id A"
   191   by (simp add: inj_on_def)
   192 
   193 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   194 by (simp add: inj_on_def)
   195 
   196 lemma inj_on_Int: "\<lbrakk>inj_on f A; inj_on f B\<rbrakk> \<Longrightarrow> inj_on f (A \<inter> B)"
   197 unfolding inj_on_def by blast
   198 
   199 lemma inj_on_INTER:
   200   "\<lbrakk>I \<noteq> {}; \<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)\<rbrakk> \<Longrightarrow> inj_on f (\<Inter> i \<in> I. A i)"
   201 unfolding inj_on_def by blast
   202 
   203 lemma inj_on_Inter:
   204   "\<lbrakk>S \<noteq> {}; \<And> A. A \<in> S \<Longrightarrow> inj_on f A\<rbrakk> \<Longrightarrow> inj_on f (Inter S)"
   205 unfolding inj_on_def by blast
   206 
   207 lemma inj_on_UNION_chain:
   208   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
   209          INJ: "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
   210   shows "inj_on f (\<Union> i \<in> I. A i)"
   211 proof(unfold inj_on_def UNION_def, auto)
   212   fix i j x y
   213   assume *: "i \<in> I" "j \<in> I" and **: "x \<in> A i" "y \<in> A j"
   214          and ***: "f x = f y"
   215   show "x = y"
   216   proof-
   217     {assume "A i \<le> A j"
   218      with ** have "x \<in> A j" by auto
   219      with INJ * ** *** have ?thesis
   220      by(auto simp add: inj_on_def)
   221     }
   222     moreover
   223     {assume "A j \<le> A i"
   224      with ** have "y \<in> A i" by auto
   225      with INJ * ** *** have ?thesis
   226      by(auto simp add: inj_on_def)
   227     }
   228     ultimately show ?thesis using  CH * by blast
   229   qed
   230 qed
   231 
   232 lemma surj_id: "surj id"
   233 by simp
   234 
   235 lemma bij_id[simp]: "bij id"
   236 by (simp add: bij_betw_def)
   237 
   238 lemma inj_onI:
   239     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   240 by (simp add: inj_on_def)
   241 
   242 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   243 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   244 
   245 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   246 by (unfold inj_on_def, blast)
   247 
   248 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   249 by (blast dest!: inj_onD)
   250 
   251 lemma comp_inj_on:
   252      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   253 by (simp add: comp_def inj_on_def)
   254 
   255 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   256 apply(simp add:inj_on_def image_def)
   257 apply blast
   258 done
   259 
   260 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   261   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   262 apply(unfold inj_on_def)
   263 apply blast
   264 done
   265 
   266 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   267 by (unfold inj_on_def, blast)
   268 
   269 lemma inj_singleton: "inj (%s. {s})"
   270 by (simp add: inj_on_def)
   271 
   272 lemma inj_on_empty[iff]: "inj_on f {}"
   273 by(simp add: inj_on_def)
   274 
   275 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   276 by (unfold inj_on_def, blast)
   277 
   278 lemma inj_on_Un:
   279  "inj_on f (A Un B) =
   280   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   281 apply(unfold inj_on_def)
   282 apply (blast intro:sym)
   283 done
   284 
   285 lemma inj_on_insert[iff]:
   286   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   287 apply(unfold inj_on_def)
   288 apply (blast intro:sym)
   289 done
   290 
   291 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   292 apply(unfold inj_on_def)
   293 apply (blast)
   294 done
   295 
   296 lemma comp_inj_on_iff:
   297   "inj_on f A \<Longrightarrow> inj_on f' (f ` A) \<longleftrightarrow> inj_on (f' o f) A"
   298 by(auto simp add: comp_inj_on inj_on_def)
   299 
   300 lemma inj_on_imageI2:
   301   "inj_on (f' o f) A \<Longrightarrow> inj_on f A"
   302 by(auto simp add: comp_inj_on inj_on_def)
   303 
   304 lemma surj_def: "surj f \<longleftrightarrow> (\<forall>y. \<exists>x. y = f x)"
   305   by auto
   306 
   307 lemma surjI: assumes *: "\<And> x. g (f x) = x" shows "surj g"
   308   using *[symmetric] by auto
   309 
   310 lemma surjD: "surj f \<Longrightarrow> \<exists>x. y = f x"
   311   by (simp add: surj_def)
   312 
   313 lemma surjE: "surj f \<Longrightarrow> (\<And>x. y = f x \<Longrightarrow> C) \<Longrightarrow> C"
   314   by (simp add: surj_def, blast)
   315 
   316 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   317 apply (simp add: comp_def surj_def, clarify)
   318 apply (drule_tac x = y in spec, clarify)
   319 apply (drule_tac x = x in spec, blast)
   320 done
   321 
   322 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
   323   unfolding bij_betw_def by auto
   324 
   325 lemma bij_betw_empty1:
   326   assumes "bij_betw f {} A"
   327   shows "A = {}"
   328 using assms unfolding bij_betw_def by blast
   329 
   330 lemma bij_betw_empty2:
   331   assumes "bij_betw f A {}"
   332   shows "A = {}"
   333 using assms unfolding bij_betw_def by blast
   334 
   335 lemma inj_on_imp_bij_betw:
   336   "inj_on f A \<Longrightarrow> bij_betw f A (f ` A)"
   337 unfolding bij_betw_def by simp
   338 
   339 lemma bij_def: "bij f \<longleftrightarrow> inj f \<and> surj f"
   340   unfolding bij_betw_def ..
   341 
   342 lemma bijI: "[| inj f; surj f |] ==> bij f"
   343 by (simp add: bij_def)
   344 
   345 lemma bij_is_inj: "bij f ==> inj f"
   346 by (simp add: bij_def)
   347 
   348 lemma bij_is_surj: "bij f ==> surj f"
   349 by (simp add: bij_def)
   350 
   351 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   352 by (simp add: bij_betw_def)
   353 
   354 lemma bij_betw_trans:
   355   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   356 by(auto simp add:bij_betw_def comp_inj_on)
   357 
   358 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   359   by (rule bij_betw_trans)
   360 
   361 lemma bij_betw_comp_iff:
   362   "bij_betw f A A' \<Longrightarrow> bij_betw f' A' A'' \<longleftrightarrow> bij_betw (f' o f) A A''"
   363 by(auto simp add: bij_betw_def inj_on_def)
   364 
   365 lemma bij_betw_comp_iff2:
   366   assumes BIJ: "bij_betw f' A' A''" and IM: "f ` A \<le> A'"
   367   shows "bij_betw f A A' \<longleftrightarrow> bij_betw (f' o f) A A''"
   368 using assms
   369 proof(auto simp add: bij_betw_comp_iff)
   370   assume *: "bij_betw (f' \<circ> f) A A''"
   371   thus "bij_betw f A A'"
   372   using IM
   373   proof(auto simp add: bij_betw_def)
   374     assume "inj_on (f' \<circ> f) A"
   375     thus "inj_on f A" using inj_on_imageI2 by blast
   376   next
   377     fix a' assume **: "a' \<in> A'"
   378     hence "f' a' \<in> A''" using BIJ unfolding bij_betw_def by auto
   379     then obtain a where 1: "a \<in> A \<and> f'(f a) = f' a'" using *
   380     unfolding bij_betw_def by force
   381     hence "f a \<in> A'" using IM by auto
   382     hence "f a = a'" using BIJ ** 1 unfolding bij_betw_def inj_on_def by auto
   383     thus "a' \<in> f ` A" using 1 by auto
   384   qed
   385 qed
   386 
   387 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   388 proof -
   389   have i: "inj_on f A" and s: "f ` A = B"
   390     using assms by(auto simp:bij_betw_def)
   391   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   392   { fix a b assume P: "?P b a"
   393     hence ex1: "\<exists>a. ?P b a" using s unfolding image_def by blast
   394     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   395     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   396   } note g = this
   397   have "inj_on ?g B"
   398   proof(rule inj_onI)
   399     fix x y assume "x:B" "y:B" "?g x = ?g y"
   400     from s `x:B` obtain a1 where a1: "?P x a1" unfolding image_def by blast
   401     from s `y:B` obtain a2 where a2: "?P y a2" unfolding image_def by blast
   402     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   403   qed
   404   moreover have "?g ` B = A"
   405   proof(auto simp:image_def)
   406     fix b assume "b:B"
   407     with s obtain a where P: "?P b a" unfolding image_def by blast
   408     thus "?g b \<in> A" using g[OF P] by auto
   409   next
   410     fix a assume "a:A"
   411     then obtain b where P: "?P b a" using s unfolding image_def by blast
   412     then have "b:B" using s unfolding image_def by blast
   413     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   414   qed
   415   ultimately show ?thesis by(auto simp:bij_betw_def)
   416 qed
   417 
   418 lemma bij_betw_cong:
   419   "(\<And> a. a \<in> A \<Longrightarrow> f a = g a) \<Longrightarrow> bij_betw f A A' = bij_betw g A A'"
   420 unfolding bij_betw_def inj_on_def by force
   421 
   422 lemma bij_betw_id[intro, simp]:
   423   "bij_betw id A A"
   424 unfolding bij_betw_def id_def by auto
   425 
   426 lemma bij_betw_id_iff:
   427   "bij_betw id A B \<longleftrightarrow> A = B"
   428 by(auto simp add: bij_betw_def)
   429 
   430 lemma bij_betw_combine:
   431   assumes "bij_betw f A B" "bij_betw f C D" "B \<inter> D = {}"
   432   shows "bij_betw f (A \<union> C) (B \<union> D)"
   433   using assms unfolding bij_betw_def inj_on_Un image_Un by auto
   434 
   435 lemma bij_betw_UNION_chain:
   436   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
   437          BIJ: "\<And> i. i \<in> I \<Longrightarrow> bij_betw f (A i) (A' i)"
   438   shows "bij_betw f (\<Union> i \<in> I. A i) (\<Union> i \<in> I. A' i)"
   439 proof(unfold bij_betw_def, auto simp add: image_def)
   440   have "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
   441   using BIJ bij_betw_def[of f] by auto
   442   thus "inj_on f (\<Union> i \<in> I. A i)"
   443   using CH inj_on_UNION_chain[of I A f] by auto
   444 next
   445   fix i x
   446   assume *: "i \<in> I" "x \<in> A i"
   447   hence "f x \<in> A' i" using BIJ bij_betw_def[of f] by auto
   448   thus "\<exists>j \<in> I. f x \<in> A' j" using * by blast
   449 next
   450   fix i x'
   451   assume *: "i \<in> I" "x' \<in> A' i"
   452   hence "\<exists>x \<in> A i. x' = f x" using BIJ bij_betw_def[of f] by blast
   453   thus "\<exists>j \<in> I. \<exists>x \<in> A j. x' = f x"
   454   using * by blast
   455 qed
   456 
   457 lemma bij_betw_Disj_Un:
   458   assumes DISJ: "A \<inter> B = {}" and DISJ': "A' \<inter> B' = {}" and
   459           B1: "bij_betw f A A'" and B2: "bij_betw f B B'"
   460   shows "bij_betw f (A \<union> B) (A' \<union> B')"
   461 proof-
   462   have 1: "inj_on f A \<and> inj_on f B"
   463   using B1 B2 by (auto simp add: bij_betw_def)
   464   have 2: "f`A = A' \<and> f`B = B'"
   465   using B1 B2 by (auto simp add: bij_betw_def)
   466   hence "f`(A - B) \<inter> f`(B - A) = {}"
   467   using DISJ DISJ' by blast
   468   hence "inj_on f (A \<union> B)"
   469   using 1 by (auto simp add: inj_on_Un)
   470   (*  *)
   471   moreover
   472   have "f`(A \<union> B) = A' \<union> B'"
   473   using 2 by auto
   474   ultimately show ?thesis
   475   unfolding bij_betw_def by auto
   476 qed
   477 
   478 lemma bij_betw_subset:
   479   assumes BIJ: "bij_betw f A A'" and
   480           SUB: "B \<le> A" and IM: "f ` B = B'"
   481   shows "bij_betw f B B'"
   482 using assms
   483 by(unfold bij_betw_def inj_on_def, auto simp add: inj_on_def)
   484 
   485 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   486 by simp
   487 
   488 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   489 by (simp add: inj_on_def, blast)
   490 
   491 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   492 by (blast intro: sym)
   493 
   494 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   495 by (unfold inj_on_def, blast)
   496 
   497 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   498 apply (unfold bij_def)
   499 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   500 done
   501 
   502 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   503 by(blast dest: inj_onD)
   504 
   505 lemma inj_on_image_Int:
   506    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   507 apply (simp add: inj_on_def, blast)
   508 done
   509 
   510 lemma inj_on_image_set_diff:
   511    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   512 apply (simp add: inj_on_def, blast)
   513 done
   514 
   515 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   516 by (simp add: inj_on_def, blast)
   517 
   518 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   519 by (simp add: inj_on_def, blast)
   520 
   521 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   522 by (blast dest: injD)
   523 
   524 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   525 by (simp add: inj_on_def, blast)
   526 
   527 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   528 by (blast dest: injD)
   529 
   530 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
   531 lemma image_INT:
   532    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
   533     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   534 apply (simp add: inj_on_def, blast)
   535 done
   536 
   537 (*Compare with image_INT: no use of inj_on, and if f is surjective then
   538   it doesn't matter whether A is empty*)
   539 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   540 apply (simp add: bij_def)
   541 apply (simp add: inj_on_def surj_def, blast)
   542 done
   543 
   544 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   545 by auto
   546 
   547 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   548 by (auto simp add: inj_on_def)
   549 
   550 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   551 apply (simp add: bij_def)
   552 apply (rule equalityI)
   553 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   554 done
   555 
   556 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   557   by (auto intro!: inj_onI)
   558 
   559 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   560   by (auto intro!: inj_onI dest: strict_mono_eq)
   561 
   562 subsection{*Function Updating*}
   563 
   564 definition
   565   fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   566   "fun_upd f a b == % x. if x=a then b else f x"
   567 
   568 nonterminals
   569   updbinds updbind
   570 syntax
   571   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   572   ""         :: "updbind => updbinds"             ("_")
   573   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   574   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   575 
   576 translations
   577   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   578   "f(x:=y)" == "CONST fun_upd f x y"
   579 
   580 (* Hint: to define the sum of two functions (or maps), use sum_case.
   581          A nice infix syntax could be defined (in Datatype.thy or below) by
   582 notation
   583   sum_case  (infixr "'(+')"80)
   584 *)
   585 
   586 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   587 apply (simp add: fun_upd_def, safe)
   588 apply (erule subst)
   589 apply (rule_tac [2] ext, auto)
   590 done
   591 
   592 (* f x = y ==> f(x:=y) = f *)
   593 lemmas fun_upd_idem = fun_upd_idem_iff [THEN iffD2, standard]
   594 
   595 (* f(x := f x) = f *)
   596 lemmas fun_upd_triv = refl [THEN fun_upd_idem]
   597 declare fun_upd_triv [iff]
   598 
   599 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   600 by (simp add: fun_upd_def)
   601 
   602 (* fun_upd_apply supersedes these two,   but they are useful
   603    if fun_upd_apply is intentionally removed from the simpset *)
   604 lemma fun_upd_same: "(f(x:=y)) x = y"
   605 by simp
   606 
   607 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   608 by simp
   609 
   610 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   611 by (simp add: fun_eq_iff)
   612 
   613 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   614 by (rule ext, auto)
   615 
   616 lemma inj_on_fun_updI: "\<lbrakk> inj_on f A; y \<notin> f`A \<rbrakk> \<Longrightarrow> inj_on (f(x:=y)) A"
   617 by (fastsimp simp:inj_on_def image_def)
   618 
   619 lemma fun_upd_image:
   620      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   621 by auto
   622 
   623 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   624 by (auto intro: ext)
   625 
   626 
   627 subsection {* @{text override_on} *}
   628 
   629 definition
   630   override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
   631 where
   632   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   633 
   634 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   635 by(simp add:override_on_def)
   636 
   637 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   638 by(simp add:override_on_def)
   639 
   640 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   641 by(simp add:override_on_def)
   642 
   643 
   644 subsection {* @{text swap} *}
   645 
   646 definition
   647   swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
   648 where
   649   "swap a b f = f (a := f b, b:= f a)"
   650 
   651 lemma swap_self [simp]: "swap a a f = f"
   652 by (simp add: swap_def)
   653 
   654 lemma swap_commute: "swap a b f = swap b a f"
   655 by (rule ext, simp add: fun_upd_def swap_def)
   656 
   657 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
   658 by (rule ext, simp add: fun_upd_def swap_def)
   659 
   660 lemma swap_triple:
   661   assumes "a \<noteq> c" and "b \<noteq> c"
   662   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   663   using assms by (simp add: fun_eq_iff swap_def)
   664 
   665 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   666 by (rule ext, simp add: fun_upd_def swap_def)
   667 
   668 lemma swap_image_eq [simp]:
   669   assumes "a \<in> A" "b \<in> A" shows "swap a b f ` A = f ` A"
   670 proof -
   671   have subset: "\<And>f. swap a b f ` A \<subseteq> f ` A"
   672     using assms by (auto simp: image_iff swap_def)
   673   then have "swap a b (swap a b f) ` A \<subseteq> (swap a b f) ` A" .
   674   with subset[of f] show ?thesis by auto
   675 qed
   676 
   677 lemma inj_on_imp_inj_on_swap:
   678   "\<lbrakk>inj_on f A; a \<in> A; b \<in> A\<rbrakk> \<Longrightarrow> inj_on (swap a b f) A"
   679   by (simp add: inj_on_def swap_def, blast)
   680 
   681 lemma inj_on_swap_iff [simp]:
   682   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A \<longleftrightarrow> inj_on f A"
   683 proof
   684   assume "inj_on (swap a b f) A"
   685   with A have "inj_on (swap a b (swap a b f)) A"
   686     by (iprover intro: inj_on_imp_inj_on_swap)
   687   thus "inj_on f A" by simp
   688 next
   689   assume "inj_on f A"
   690   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   691 qed
   692 
   693 lemma surj_imp_surj_swap: "surj f \<Longrightarrow> surj (swap a b f)"
   694   by simp
   695 
   696 lemma surj_swap_iff [simp]: "surj (swap a b f) \<longleftrightarrow> surj f"
   697   by simp
   698 
   699 lemma bij_betw_swap_iff [simp]:
   700   "\<lbrakk> x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> bij_betw (swap x y f) A B \<longleftrightarrow> bij_betw f A B"
   701   by (auto simp: bij_betw_def)
   702 
   703 lemma bij_swap_iff [simp]: "bij (swap a b f) \<longleftrightarrow> bij f"
   704   by simp
   705 
   706 hide_const (open) swap
   707 
   708 subsection {* Inversion of injective functions *}
   709 
   710 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   711 "the_inv_into A f == %x. THE y. y : A & f y = x"
   712 
   713 lemma the_inv_into_f_f:
   714   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   715 apply (simp add: the_inv_into_def inj_on_def)
   716 apply blast
   717 done
   718 
   719 lemma f_the_inv_into_f:
   720   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   721 apply (simp add: the_inv_into_def)
   722 apply (rule the1I2)
   723  apply(blast dest: inj_onD)
   724 apply blast
   725 done
   726 
   727 lemma the_inv_into_into:
   728   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   729 apply (simp add: the_inv_into_def)
   730 apply (rule the1I2)
   731  apply(blast dest: inj_onD)
   732 apply blast
   733 done
   734 
   735 lemma the_inv_into_onto[simp]:
   736   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   737 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   738 
   739 lemma the_inv_into_f_eq:
   740   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   741   apply (erule subst)
   742   apply (erule the_inv_into_f_f, assumption)
   743   done
   744 
   745 lemma the_inv_into_comp:
   746   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   747   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   748 apply (rule the_inv_into_f_eq)
   749   apply (fast intro: comp_inj_on)
   750  apply (simp add: f_the_inv_into_f the_inv_into_into)
   751 apply (simp add: the_inv_into_into)
   752 done
   753 
   754 lemma inj_on_the_inv_into:
   755   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   756 by (auto intro: inj_onI simp: image_def the_inv_into_f_f)
   757 
   758 lemma bij_betw_the_inv_into:
   759   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   760 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   761 
   762 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   763   "the_inv f \<equiv> the_inv_into UNIV f"
   764 
   765 lemma the_inv_f_f:
   766   assumes "inj f"
   767   shows "the_inv f (f x) = x" using assms UNIV_I
   768   by (rule the_inv_into_f_f)
   769 
   770 subsection {* Cantor's Paradox *}
   771 
   772 lemma Cantors_paradox:
   773   "\<not>(\<exists>f. f ` A = Pow A)"
   774 proof clarify
   775   fix f assume "f ` A = Pow A" hence *: "Pow A \<le> f ` A" by blast
   776   let ?X = "{a \<in> A. a \<notin> f a}"
   777   have "?X \<in> Pow A" unfolding Pow_def by auto
   778   with * obtain x where "x \<in> A \<and> f x = ?X" by blast
   779   thus False by best
   780 qed
   781 
   782 subsection {* Proof tool setup *} 
   783 
   784 text {* simplifies terms of the form
   785   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   786 
   787 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   788 let
   789   fun gen_fun_upd NONE T _ _ = NONE
   790     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   791   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   792   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   793     let
   794       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   795             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   796         | find t = NONE
   797     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   798 
   799   fun proc ss ct =
   800     let
   801       val ctxt = Simplifier.the_context ss
   802       val t = Thm.term_of ct
   803     in
   804       case find_double t of
   805         (T, NONE) => NONE
   806       | (T, SOME rhs) =>
   807           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   808             (fn _ =>
   809               rtac eq_reflection 1 THEN
   810               rtac ext 1 THEN
   811               simp_tac (Simplifier.inherit_context ss @{simpset}) 1))
   812     end
   813 in proc end
   814 *}
   815 
   816 
   817 subsection {* Code generator setup *}
   818 
   819 types_code
   820   "fun"  ("(_ ->/ _)")
   821 attach (term_of) {*
   822 fun term_of_fun_type _ aT _ bT _ = Free ("<function>", aT --> bT);
   823 *}
   824 attach (test) {*
   825 fun gen_fun_type aF aT bG bT i =
   826   let
   827     val tab = Unsynchronized.ref [];
   828     fun mk_upd (x, (_, y)) t = Const ("Fun.fun_upd",
   829       (aT --> bT) --> aT --> bT --> aT --> bT) $ t $ aF x $ y ()
   830   in
   831     (fn x =>
   832        case AList.lookup op = (!tab) x of
   833          NONE =>
   834            let val p as (y, _) = bG i
   835            in (tab := (x, p) :: !tab; y) end
   836        | SOME (y, _) => y,
   837      fn () => Basics.fold mk_upd (!tab) (Const ("HOL.undefined", aT --> bT)))
   838   end;
   839 *}
   840 
   841 code_const "op \<circ>"
   842   (SML infixl 5 "o")
   843   (Haskell infixr 9 ".")
   844 
   845 code_const "id"
   846   (Haskell "id")
   847 
   848 end