src/HOL/Analysis/Lebesgue_Measure.thy
author immler
Fri Mar 10 23:16:40 2017 +0100 (2017-03-10)
changeset 65204 d23eded35a33
parent 64272 f76b6dda2e56
child 65585 a043de9ad41e
permissions -rw-r--r--
modernized construction of type bcontfun; base explicit theorems on Uniform_Limit.thy; added some lemmas
     1 (*  Title:      HOL/Analysis/Lebesgue_Measure.thy
     2     Author:     Johannes Hölzl, TU München
     3     Author:     Robert Himmelmann, TU München
     4     Author:     Jeremy Avigad
     5     Author:     Luke Serafin
     6 *)
     7 
     8 section \<open>Lebesgue measure\<close>
     9 
    10 theory Lebesgue_Measure
    11   imports Finite_Product_Measure Bochner_Integration Caratheodory Complete_Measure Summation_Tests Regularity
    12 begin
    13 
    14 lemma measure_eqI_lessThan:
    15   fixes M N :: "real measure"
    16   assumes sets: "sets M = sets borel" "sets N = sets borel"
    17   assumes fin: "\<And>x. emeasure M {x <..} < \<infinity>"
    18   assumes "\<And>x. emeasure M {x <..} = emeasure N {x <..}"
    19   shows "M = N"
    20 proof (rule measure_eqI_generator_eq_countable)
    21   let ?LT = "\<lambda>a::real. {a <..}" let ?E = "range ?LT"
    22   show "Int_stable ?E"
    23     by (auto simp: Int_stable_def lessThan_Int_lessThan)
    24 
    25   show "?E \<subseteq> Pow UNIV" "sets M = sigma_sets UNIV ?E" "sets N = sigma_sets UNIV ?E"
    26     unfolding sets borel_Ioi by auto
    27 
    28   show "?LT`Rats \<subseteq> ?E" "(\<Union>i\<in>Rats. ?LT i) = UNIV" "\<And>a. a \<in> ?LT`Rats \<Longrightarrow> emeasure M a \<noteq> \<infinity>"
    29     using fin by (auto intro: Rats_no_bot_less simp: less_top)
    30 qed (auto intro: assms countable_rat)
    31 
    32 subsection \<open>Every right continuous and nondecreasing function gives rise to a measure\<close>
    33 
    34 definition interval_measure :: "(real \<Rightarrow> real) \<Rightarrow> real measure" where
    35   "interval_measure F = extend_measure UNIV {(a, b). a \<le> b} (\<lambda>(a, b). {a <.. b}) (\<lambda>(a, b). ennreal (F b - F a))"
    36 
    37 lemma emeasure_interval_measure_Ioc:
    38   assumes "a \<le> b"
    39   assumes mono_F: "\<And>x y. x \<le> y \<Longrightarrow> F x \<le> F y"
    40   assumes right_cont_F : "\<And>a. continuous (at_right a) F"
    41   shows "emeasure (interval_measure F) {a <.. b} = F b - F a"
    42 proof (rule extend_measure_caratheodory_pair[OF interval_measure_def \<open>a \<le> b\<close>])
    43   show "semiring_of_sets UNIV {{a<..b} |a b :: real. a \<le> b}"
    44   proof (unfold_locales, safe)
    45     fix a b c d :: real assume *: "a \<le> b" "c \<le> d"
    46     then show "\<exists>C\<subseteq>{{a<..b} |a b. a \<le> b}. finite C \<and> disjoint C \<and> {a<..b} - {c<..d} = \<Union>C"
    47     proof cases
    48       let ?C = "{{a<..b}}"
    49       assume "b < c \<or> d \<le> a \<or> d \<le> c"
    50       with * have "?C \<subseteq> {{a<..b} |a b. a \<le> b} \<and> finite ?C \<and> disjoint ?C \<and> {a<..b} - {c<..d} = \<Union>?C"
    51         by (auto simp add: disjoint_def)
    52       thus ?thesis ..
    53     next
    54       let ?C = "{{a<..c}, {d<..b}}"
    55       assume "\<not> (b < c \<or> d \<le> a \<or> d \<le> c)"
    56       with * have "?C \<subseteq> {{a<..b} |a b. a \<le> b} \<and> finite ?C \<and> disjoint ?C \<and> {a<..b} - {c<..d} = \<Union>?C"
    57         by (auto simp add: disjoint_def Ioc_inj) (metis linear)+
    58       thus ?thesis ..
    59     qed
    60   qed (auto simp: Ioc_inj, metis linear)
    61 next
    62   fix l r :: "nat \<Rightarrow> real" and a b :: real
    63   assume l_r[simp]: "\<And>n. l n \<le> r n" and "a \<le> b" and disj: "disjoint_family (\<lambda>n. {l n<..r n})"
    64   assume lr_eq_ab: "(\<Union>i. {l i<..r i}) = {a<..b}"
    65 
    66   have [intro, simp]: "\<And>a b. a \<le> b \<Longrightarrow> F a \<le> F b"
    67     by (auto intro!: l_r mono_F)
    68 
    69   { fix S :: "nat set" assume "finite S"
    70     moreover note \<open>a \<le> b\<close>
    71     moreover have "\<And>i. i \<in> S \<Longrightarrow> {l i <.. r i} \<subseteq> {a <.. b}"
    72       unfolding lr_eq_ab[symmetric] by auto
    73     ultimately have "(\<Sum>i\<in>S. F (r i) - F (l i)) \<le> F b - F a"
    74     proof (induction S arbitrary: a rule: finite_psubset_induct)
    75       case (psubset S)
    76       show ?case
    77       proof cases
    78         assume "\<exists>i\<in>S. l i < r i"
    79         with \<open>finite S\<close> have "Min (l ` {i\<in>S. l i < r i}) \<in> l ` {i\<in>S. l i < r i}"
    80           by (intro Min_in) auto
    81         then obtain m where m: "m \<in> S" "l m < r m" "l m = Min (l ` {i\<in>S. l i < r i})"
    82           by fastforce
    83 
    84         have "(\<Sum>i\<in>S. F (r i) - F (l i)) = (F (r m) - F (l m)) + (\<Sum>i\<in>S - {m}. F (r i) - F (l i))"
    85           using m psubset by (intro sum.remove) auto
    86         also have "(\<Sum>i\<in>S - {m}. F (r i) - F (l i)) \<le> F b - F (r m)"
    87         proof (intro psubset.IH)
    88           show "S - {m} \<subset> S"
    89             using \<open>m\<in>S\<close> by auto
    90           show "r m \<le> b"
    91             using psubset.prems(2)[OF \<open>m\<in>S\<close>] \<open>l m < r m\<close> by auto
    92         next
    93           fix i assume "i \<in> S - {m}"
    94           then have i: "i \<in> S" "i \<noteq> m" by auto
    95           { assume i': "l i < r i" "l i < r m"
    96             with \<open>finite S\<close> i m have "l m \<le> l i"
    97               by auto
    98             with i' have "{l i <.. r i} \<inter> {l m <.. r m} \<noteq> {}"
    99               by auto
   100             then have False
   101               using disjoint_family_onD[OF disj, of i m] i by auto }
   102           then have "l i \<noteq> r i \<Longrightarrow> r m \<le> l i"
   103             unfolding not_less[symmetric] using l_r[of i] by auto
   104           then show "{l i <.. r i} \<subseteq> {r m <.. b}"
   105             using psubset.prems(2)[OF \<open>i\<in>S\<close>] by auto
   106         qed
   107         also have "F (r m) - F (l m) \<le> F (r m) - F a"
   108           using psubset.prems(2)[OF \<open>m \<in> S\<close>] \<open>l m < r m\<close>
   109           by (auto simp add: Ioc_subset_iff intro!: mono_F)
   110         finally show ?case
   111           by (auto intro: add_mono)
   112       qed (auto simp add: \<open>a \<le> b\<close> less_le)
   113     qed }
   114   note claim1 = this
   115 
   116   (* second key induction: a lower bound on the measures of any finite collection of Ai's
   117      that cover an interval {u..v} *)
   118 
   119   { fix S u v and l r :: "nat \<Rightarrow> real"
   120     assume "finite S" "\<And>i. i\<in>S \<Longrightarrow> l i < r i" "{u..v} \<subseteq> (\<Union>i\<in>S. {l i<..< r i})"
   121     then have "F v - F u \<le> (\<Sum>i\<in>S. F (r i) - F (l i))"
   122     proof (induction arbitrary: v u rule: finite_psubset_induct)
   123       case (psubset S)
   124       show ?case
   125       proof cases
   126         assume "S = {}" then show ?case
   127           using psubset by (simp add: mono_F)
   128       next
   129         assume "S \<noteq> {}"
   130         then obtain j where "j \<in> S"
   131           by auto
   132 
   133         let ?R = "r j < u \<or> l j > v \<or> (\<exists>i\<in>S-{j}. l i \<le> l j \<and> r j \<le> r i)"
   134         show ?case
   135         proof cases
   136           assume "?R"
   137           with \<open>j \<in> S\<close> psubset.prems have "{u..v} \<subseteq> (\<Union>i\<in>S-{j}. {l i<..< r i})"
   138             apply (auto simp: subset_eq Ball_def)
   139             apply (metis Diff_iff less_le_trans leD linear singletonD)
   140             apply (metis Diff_iff less_le_trans leD linear singletonD)
   141             apply (metis order_trans less_le_not_le linear)
   142             done
   143           with \<open>j \<in> S\<close> have "F v - F u \<le> (\<Sum>i\<in>S - {j}. F (r i) - F (l i))"
   144             by (intro psubset) auto
   145           also have "\<dots> \<le> (\<Sum>i\<in>S. F (r i) - F (l i))"
   146             using psubset.prems
   147             by (intro sum_mono2 psubset) (auto intro: less_imp_le)
   148           finally show ?thesis .
   149         next
   150           assume "\<not> ?R"
   151           then have j: "u \<le> r j" "l j \<le> v" "\<And>i. i \<in> S - {j} \<Longrightarrow> r i < r j \<or> l i > l j"
   152             by (auto simp: not_less)
   153           let ?S1 = "{i \<in> S. l i < l j}"
   154           let ?S2 = "{i \<in> S. r i > r j}"
   155 
   156           have "(\<Sum>i\<in>S. F (r i) - F (l i)) \<ge> (\<Sum>i\<in>?S1 \<union> ?S2 \<union> {j}. F (r i) - F (l i))"
   157             using \<open>j \<in> S\<close> \<open>finite S\<close> psubset.prems j
   158             by (intro sum_mono2) (auto intro: less_imp_le)
   159           also have "(\<Sum>i\<in>?S1 \<union> ?S2 \<union> {j}. F (r i) - F (l i)) =
   160             (\<Sum>i\<in>?S1. F (r i) - F (l i)) + (\<Sum>i\<in>?S2 . F (r i) - F (l i)) + (F (r j) - F (l j))"
   161             using psubset(1) psubset.prems(1) j
   162             apply (subst sum.union_disjoint)
   163             apply simp_all
   164             apply (subst sum.union_disjoint)
   165             apply auto
   166             apply (metis less_le_not_le)
   167             done
   168           also (xtrans) have "(\<Sum>i\<in>?S1. F (r i) - F (l i)) \<ge> F (l j) - F u"
   169             using \<open>j \<in> S\<close> \<open>finite S\<close> psubset.prems j
   170             apply (intro psubset.IH psubset)
   171             apply (auto simp: subset_eq Ball_def)
   172             apply (metis less_le_trans not_le)
   173             done
   174           also (xtrans) have "(\<Sum>i\<in>?S2. F (r i) - F (l i)) \<ge> F v - F (r j)"
   175             using \<open>j \<in> S\<close> \<open>finite S\<close> psubset.prems j
   176             apply (intro psubset.IH psubset)
   177             apply (auto simp: subset_eq Ball_def)
   178             apply (metis le_less_trans not_le)
   179             done
   180           finally (xtrans) show ?case
   181             by (auto simp: add_mono)
   182         qed
   183       qed
   184     qed }
   185   note claim2 = this
   186 
   187   (* now prove the inequality going the other way *)
   188   have "ennreal (F b - F a) \<le> (\<Sum>i. ennreal (F (r i) - F (l i)))"
   189   proof (rule ennreal_le_epsilon)
   190     fix epsilon :: real assume egt0: "epsilon > 0"
   191     have "\<forall>i. \<exists>d>0. F (r i + d) < F (r i) + epsilon / 2^(i+2)"
   192     proof
   193       fix i
   194       note right_cont_F [of "r i"]
   195       thus "\<exists>d>0. F (r i + d) < F (r i) + epsilon / 2^(i+2)"
   196         apply -
   197         apply (subst (asm) continuous_at_right_real_increasing)
   198         apply (rule mono_F, assumption)
   199         apply (drule_tac x = "epsilon / 2 ^ (i + 2)" in spec)
   200         apply (erule impE)
   201         using egt0 by (auto simp add: field_simps)
   202     qed
   203     then obtain delta where
   204         deltai_gt0: "\<And>i. delta i > 0" and
   205         deltai_prop: "\<And>i. F (r i + delta i) < F (r i) + epsilon / 2^(i+2)"
   206       by metis
   207     have "\<exists>a' > a. F a' - F a < epsilon / 2"
   208       apply (insert right_cont_F [of a])
   209       apply (subst (asm) continuous_at_right_real_increasing)
   210       using mono_F apply force
   211       apply (drule_tac x = "epsilon / 2" in spec)
   212       using egt0 unfolding mult.commute [of 2] by force
   213     then obtain a' where a'lea [arith]: "a' > a" and
   214       a_prop: "F a' - F a < epsilon / 2"
   215       by auto
   216     define S' where "S' = {i. l i < r i}"
   217     obtain S :: "nat set" where
   218       "S \<subseteq> S'" and finS: "finite S" and
   219       Sprop: "{a'..b} \<subseteq> (\<Union>i \<in> S. {l i<..<r i + delta i})"
   220     proof (rule compactE_image)
   221       show "compact {a'..b}"
   222         by (rule compact_Icc)
   223       show "\<forall>i \<in> S'. open ({l i<..<r i + delta i})" by auto
   224       have "{a'..b} \<subseteq> {a <.. b}"
   225         by auto
   226       also have "{a <.. b} = (\<Union>i\<in>S'. {l i<..r i})"
   227         unfolding lr_eq_ab[symmetric] by (fastforce simp add: S'_def intro: less_le_trans)
   228       also have "\<dots> \<subseteq> (\<Union>i \<in> S'. {l i<..<r i + delta i})"
   229         apply (intro UN_mono)
   230         apply (auto simp: S'_def)
   231         apply (cut_tac i=i in deltai_gt0)
   232         apply simp
   233         done
   234       finally show "{a'..b} \<subseteq> (\<Union>i \<in> S'. {l i<..<r i + delta i})" .
   235     qed
   236     with S'_def have Sprop2: "\<And>i. i \<in> S \<Longrightarrow> l i < r i" by auto
   237     from finS have "\<exists>n. \<forall>i \<in> S. i \<le> n"
   238       by (subst finite_nat_set_iff_bounded_le [symmetric])
   239     then obtain n where Sbound [rule_format]: "\<forall>i \<in> S. i \<le> n" ..
   240     have "F b - F a' \<le> (\<Sum>i\<in>S. F (r i + delta i) - F (l i))"
   241       apply (rule claim2 [rule_format])
   242       using finS Sprop apply auto
   243       apply (frule Sprop2)
   244       apply (subgoal_tac "delta i > 0")
   245       apply arith
   246       by (rule deltai_gt0)
   247     also have "... \<le> (\<Sum>i \<in> S. F(r i) - F(l i) + epsilon / 2^(i+2))"
   248       apply (rule sum_mono)
   249       apply simp
   250       apply (rule order_trans)
   251       apply (rule less_imp_le)
   252       apply (rule deltai_prop)
   253       by auto
   254     also have "... = (\<Sum>i \<in> S. F(r i) - F(l i)) +
   255         (epsilon / 4) * (\<Sum>i \<in> S. (1 / 2)^i)" (is "_ = ?t + _")
   256       by (subst sum.distrib) (simp add: field_simps sum_distrib_left)
   257     also have "... \<le> ?t + (epsilon / 4) * (\<Sum> i < Suc n. (1 / 2)^i)"
   258       apply (rule add_left_mono)
   259       apply (rule mult_left_mono)
   260       apply (rule sum_mono2)
   261       using egt0 apply auto
   262       by (frule Sbound, auto)
   263     also have "... \<le> ?t + (epsilon / 2)"
   264       apply (rule add_left_mono)
   265       apply (subst geometric_sum)
   266       apply auto
   267       apply (rule mult_left_mono)
   268       using egt0 apply auto
   269       done
   270     finally have aux2: "F b - F a' \<le> (\<Sum>i\<in>S. F (r i) - F (l i)) + epsilon / 2"
   271       by simp
   272 
   273     have "F b - F a = (F b - F a') + (F a' - F a)"
   274       by auto
   275     also have "... \<le> (F b - F a') + epsilon / 2"
   276       using a_prop by (intro add_left_mono) simp
   277     also have "... \<le> (\<Sum>i\<in>S. F (r i) - F (l i)) + epsilon / 2 + epsilon / 2"
   278       apply (intro add_right_mono)
   279       apply (rule aux2)
   280       done
   281     also have "... = (\<Sum>i\<in>S. F (r i) - F (l i)) + epsilon"
   282       by auto
   283     also have "... \<le> (\<Sum>i\<le>n. F (r i) - F (l i)) + epsilon"
   284       using finS Sbound Sprop by (auto intro!: add_right_mono sum_mono3)
   285     finally have "ennreal (F b - F a) \<le> (\<Sum>i\<le>n. ennreal (F (r i) - F (l i))) + epsilon"
   286       using egt0 by (simp add: ennreal_plus[symmetric] sum_nonneg del: ennreal_plus)
   287     then show "ennreal (F b - F a) \<le> (\<Sum>i. ennreal (F (r i) - F (l i))) + (epsilon :: real)"
   288       by (rule order_trans) (auto intro!: add_mono sum_le_suminf simp del: sum_ennreal)
   289   qed
   290   moreover have "(\<Sum>i. ennreal (F (r i) - F (l i))) \<le> ennreal (F b - F a)"
   291     using \<open>a \<le> b\<close> by (auto intro!: suminf_le_const ennreal_le_iff[THEN iffD2] claim1)
   292   ultimately show "(\<Sum>n. ennreal (F (r n) - F (l n))) = ennreal (F b - F a)"
   293     by (rule antisym[rotated])
   294 qed (auto simp: Ioc_inj mono_F)
   295 
   296 lemma measure_interval_measure_Ioc:
   297   assumes "a \<le> b"
   298   assumes mono_F: "\<And>x y. x \<le> y \<Longrightarrow> F x \<le> F y"
   299   assumes right_cont_F : "\<And>a. continuous (at_right a) F"
   300   shows "measure (interval_measure F) {a <.. b} = F b - F a"
   301   unfolding measure_def
   302   apply (subst emeasure_interval_measure_Ioc)
   303   apply fact+
   304   apply (simp add: assms)
   305   done
   306 
   307 lemma emeasure_interval_measure_Ioc_eq:
   308   "(\<And>x y. x \<le> y \<Longrightarrow> F x \<le> F y) \<Longrightarrow> (\<And>a. continuous (at_right a) F) \<Longrightarrow>
   309     emeasure (interval_measure F) {a <.. b} = (if a \<le> b then F b - F a else 0)"
   310   using emeasure_interval_measure_Ioc[of a b F] by auto
   311 
   312 lemma sets_interval_measure [simp, measurable_cong]: "sets (interval_measure F) = sets borel"
   313   apply (simp add: sets_extend_measure interval_measure_def borel_sigma_sets_Ioc)
   314   apply (rule sigma_sets_eqI)
   315   apply auto
   316   apply (case_tac "a \<le> ba")
   317   apply (auto intro: sigma_sets.Empty)
   318   done
   319 
   320 lemma space_interval_measure [simp]: "space (interval_measure F) = UNIV"
   321   by (simp add: interval_measure_def space_extend_measure)
   322 
   323 lemma emeasure_interval_measure_Icc:
   324   assumes "a \<le> b"
   325   assumes mono_F: "\<And>x y. x \<le> y \<Longrightarrow> F x \<le> F y"
   326   assumes cont_F : "continuous_on UNIV F"
   327   shows "emeasure (interval_measure F) {a .. b} = F b - F a"
   328 proof (rule tendsto_unique)
   329   { fix a b :: real assume "a \<le> b" then have "emeasure (interval_measure F) {a <.. b} = F b - F a"
   330       using cont_F
   331       by (subst emeasure_interval_measure_Ioc)
   332          (auto intro: mono_F continuous_within_subset simp: continuous_on_eq_continuous_within) }
   333   note * = this
   334 
   335   let ?F = "interval_measure F"
   336   show "((\<lambda>a. F b - F a) \<longlongrightarrow> emeasure ?F {a..b}) (at_left a)"
   337   proof (rule tendsto_at_left_sequentially)
   338     show "a - 1 < a" by simp
   339     fix X assume "\<And>n. X n < a" "incseq X" "X \<longlonglongrightarrow> a"
   340     with \<open>a \<le> b\<close> have "(\<lambda>n. emeasure ?F {X n<..b}) \<longlonglongrightarrow> emeasure ?F (\<Inter>n. {X n <..b})"
   341       apply (intro Lim_emeasure_decseq)
   342       apply (auto simp: decseq_def incseq_def emeasure_interval_measure_Ioc *)
   343       apply force
   344       apply (subst (asm ) *)
   345       apply (auto intro: less_le_trans less_imp_le)
   346       done
   347     also have "(\<Inter>n. {X n <..b}) = {a..b}"
   348       using \<open>\<And>n. X n < a\<close>
   349       apply auto
   350       apply (rule LIMSEQ_le_const2[OF \<open>X \<longlonglongrightarrow> a\<close>])
   351       apply (auto intro: less_imp_le)
   352       apply (auto intro: less_le_trans)
   353       done
   354     also have "(\<lambda>n. emeasure ?F {X n<..b}) = (\<lambda>n. F b - F (X n))"
   355       using \<open>\<And>n. X n < a\<close> \<open>a \<le> b\<close> by (subst *) (auto intro: less_imp_le less_le_trans)
   356     finally show "(\<lambda>n. F b - F (X n)) \<longlonglongrightarrow> emeasure ?F {a..b}" .
   357   qed
   358   show "((\<lambda>a. ennreal (F b - F a)) \<longlongrightarrow> F b - F a) (at_left a)"
   359     by (rule continuous_on_tendsto_compose[where g="\<lambda>x. x" and s=UNIV])
   360        (auto simp: continuous_on_ennreal continuous_on_diff cont_F continuous_on_const)
   361 qed (rule trivial_limit_at_left_real)
   362 
   363 lemma sigma_finite_interval_measure:
   364   assumes mono_F: "\<And>x y. x \<le> y \<Longrightarrow> F x \<le> F y"
   365   assumes right_cont_F : "\<And>a. continuous (at_right a) F"
   366   shows "sigma_finite_measure (interval_measure F)"
   367   apply unfold_locales
   368   apply (intro exI[of _ "(\<lambda>(a, b). {a <.. b}) ` (\<rat> \<times> \<rat>)"])
   369   apply (auto intro!: Rats_no_top_le Rats_no_bot_less countable_rat simp: emeasure_interval_measure_Ioc_eq[OF assms])
   370   done
   371 
   372 subsection \<open>Lebesgue-Borel measure\<close>
   373 
   374 definition lborel :: "('a :: euclidean_space) measure" where
   375   "lborel = distr (\<Pi>\<^sub>M b\<in>Basis. interval_measure (\<lambda>x. x)) borel (\<lambda>f. \<Sum>b\<in>Basis. f b *\<^sub>R b)"
   376 
   377 abbreviation lebesgue :: "'a::euclidean_space measure"
   378   where "lebesgue \<equiv> completion lborel"
   379 
   380 abbreviation lebesgue_on :: "'a set \<Rightarrow> 'a::euclidean_space measure"
   381   where "lebesgue_on \<Omega> \<equiv> restrict_space (completion lborel) \<Omega>"
   382 
   383 lemma
   384   shows sets_lborel[simp, measurable_cong]: "sets lborel = sets borel"
   385     and space_lborel[simp]: "space lborel = space borel"
   386     and measurable_lborel1[simp]: "measurable M lborel = measurable M borel"
   387     and measurable_lborel2[simp]: "measurable lborel M = measurable borel M"
   388   by (simp_all add: lborel_def)
   389 
   390 context
   391 begin
   392 
   393 interpretation sigma_finite_measure "interval_measure (\<lambda>x. x)"
   394   by (rule sigma_finite_interval_measure) auto
   395 interpretation finite_product_sigma_finite "\<lambda>_. interval_measure (\<lambda>x. x)" Basis
   396   proof qed simp
   397 
   398 lemma lborel_eq_real: "lborel = interval_measure (\<lambda>x. x)"
   399   unfolding lborel_def Basis_real_def
   400   using distr_id[of "interval_measure (\<lambda>x. x)"]
   401   by (subst distr_component[symmetric])
   402      (simp_all add: distr_distr comp_def del: distr_id cong: distr_cong)
   403 
   404 lemma lborel_eq: "lborel = distr (\<Pi>\<^sub>M b\<in>Basis. lborel) borel (\<lambda>f. \<Sum>b\<in>Basis. f b *\<^sub>R b)"
   405   by (subst lborel_def) (simp add: lborel_eq_real)
   406 
   407 lemma nn_integral_lborel_prod:
   408   assumes [measurable]: "\<And>b. b \<in> Basis \<Longrightarrow> f b \<in> borel_measurable borel"
   409   assumes nn[simp]: "\<And>b x. b \<in> Basis \<Longrightarrow> 0 \<le> f b x"
   410   shows "(\<integral>\<^sup>+x. (\<Prod>b\<in>Basis. f b (x \<bullet> b)) \<partial>lborel) = (\<Prod>b\<in>Basis. (\<integral>\<^sup>+x. f b x \<partial>lborel))"
   411   by (simp add: lborel_def nn_integral_distr product_nn_integral_prod
   412                 product_nn_integral_singleton)
   413 
   414 lemma emeasure_lborel_Icc[simp]:
   415   fixes l u :: real
   416   assumes [simp]: "l \<le> u"
   417   shows "emeasure lborel {l .. u} = u - l"
   418 proof -
   419   have "((\<lambda>f. f 1) -` {l..u} \<inter> space (Pi\<^sub>M {1} (\<lambda>b. interval_measure (\<lambda>x. x)))) = {1::real} \<rightarrow>\<^sub>E {l..u}"
   420     by (auto simp: space_PiM)
   421   then show ?thesis
   422     by (simp add: lborel_def emeasure_distr emeasure_PiM emeasure_interval_measure_Icc continuous_on_id)
   423 qed
   424 
   425 lemma emeasure_lborel_Icc_eq: "emeasure lborel {l .. u} = ennreal (if l \<le> u then u - l else 0)"
   426   by simp
   427 
   428 lemma emeasure_lborel_cbox[simp]:
   429   assumes [simp]: "\<And>b. b \<in> Basis \<Longrightarrow> l \<bullet> b \<le> u \<bullet> b"
   430   shows "emeasure lborel (cbox l u) = (\<Prod>b\<in>Basis. (u - l) \<bullet> b)"
   431 proof -
   432   have "(\<lambda>x. \<Prod>b\<in>Basis. indicator {l\<bullet>b .. u\<bullet>b} (x \<bullet> b) :: ennreal) = indicator (cbox l u)"
   433     by (auto simp: fun_eq_iff cbox_def split: split_indicator)
   434   then have "emeasure lborel (cbox l u) = (\<integral>\<^sup>+x. (\<Prod>b\<in>Basis. indicator {l\<bullet>b .. u\<bullet>b} (x \<bullet> b)) \<partial>lborel)"
   435     by simp
   436   also have "\<dots> = (\<Prod>b\<in>Basis. (u - l) \<bullet> b)"
   437     by (subst nn_integral_lborel_prod) (simp_all add: prod_ennreal inner_diff_left)
   438   finally show ?thesis .
   439 qed
   440 
   441 lemma AE_lborel_singleton: "AE x in lborel::'a::euclidean_space measure. x \<noteq> c"
   442   using SOME_Basis AE_discrete_difference [of "{c}" lborel] emeasure_lborel_cbox [of c c]
   443   by (auto simp add: cbox_sing prod_constant power_0_left)
   444 
   445 lemma emeasure_lborel_Ioo[simp]:
   446   assumes [simp]: "l \<le> u"
   447   shows "emeasure lborel {l <..< u} = ennreal (u - l)"
   448 proof -
   449   have "emeasure lborel {l <..< u} = emeasure lborel {l .. u}"
   450     using AE_lborel_singleton[of u] AE_lborel_singleton[of l] by (intro emeasure_eq_AE) auto
   451   then show ?thesis
   452     by simp
   453 qed
   454 
   455 lemma emeasure_lborel_Ioc[simp]:
   456   assumes [simp]: "l \<le> u"
   457   shows "emeasure lborel {l <.. u} = ennreal (u - l)"
   458 proof -
   459   have "emeasure lborel {l <.. u} = emeasure lborel {l .. u}"
   460     using AE_lborel_singleton[of u] AE_lborel_singleton[of l] by (intro emeasure_eq_AE) auto
   461   then show ?thesis
   462     by simp
   463 qed
   464 
   465 lemma emeasure_lborel_Ico[simp]:
   466   assumes [simp]: "l \<le> u"
   467   shows "emeasure lborel {l ..< u} = ennreal (u - l)"
   468 proof -
   469   have "emeasure lborel {l ..< u} = emeasure lborel {l .. u}"
   470     using AE_lborel_singleton[of u] AE_lborel_singleton[of l] by (intro emeasure_eq_AE) auto
   471   then show ?thesis
   472     by simp
   473 qed
   474 
   475 lemma emeasure_lborel_box[simp]:
   476   assumes [simp]: "\<And>b. b \<in> Basis \<Longrightarrow> l \<bullet> b \<le> u \<bullet> b"
   477   shows "emeasure lborel (box l u) = (\<Prod>b\<in>Basis. (u - l) \<bullet> b)"
   478 proof -
   479   have "(\<lambda>x. \<Prod>b\<in>Basis. indicator {l\<bullet>b <..< u\<bullet>b} (x \<bullet> b) :: ennreal) = indicator (box l u)"
   480     by (auto simp: fun_eq_iff box_def split: split_indicator)
   481   then have "emeasure lborel (box l u) = (\<integral>\<^sup>+x. (\<Prod>b\<in>Basis. indicator {l\<bullet>b <..< u\<bullet>b} (x \<bullet> b)) \<partial>lborel)"
   482     by simp
   483   also have "\<dots> = (\<Prod>b\<in>Basis. (u - l) \<bullet> b)"
   484     by (subst nn_integral_lborel_prod) (simp_all add: prod_ennreal inner_diff_left)
   485   finally show ?thesis .
   486 qed
   487 
   488 lemma emeasure_lborel_cbox_eq:
   489   "emeasure lborel (cbox l u) = (if \<forall>b\<in>Basis. l \<bullet> b \<le> u \<bullet> b then \<Prod>b\<in>Basis. (u - l) \<bullet> b else 0)"
   490   using box_eq_empty(2)[THEN iffD2, of u l] by (auto simp: not_le)
   491 
   492 lemma emeasure_lborel_box_eq:
   493   "emeasure lborel (box l u) = (if \<forall>b\<in>Basis. l \<bullet> b \<le> u \<bullet> b then \<Prod>b\<in>Basis. (u - l) \<bullet> b else 0)"
   494   using box_eq_empty(1)[THEN iffD2, of u l] by (auto simp: not_le dest!: less_imp_le) force
   495 
   496 lemma emeasure_lborel_singleton[simp]: "emeasure lborel {x} = 0"
   497   using emeasure_lborel_cbox[of x x] nonempty_Basis
   498   by (auto simp del: emeasure_lborel_cbox nonempty_Basis simp add: cbox_sing prod_constant)
   499 
   500 lemma
   501   fixes l u :: real
   502   assumes [simp]: "l \<le> u"
   503   shows measure_lborel_Icc[simp]: "measure lborel {l .. u} = u - l"
   504     and measure_lborel_Ico[simp]: "measure lborel {l ..< u} = u - l"
   505     and measure_lborel_Ioc[simp]: "measure lborel {l <.. u} = u - l"
   506     and measure_lborel_Ioo[simp]: "measure lborel {l <..< u} = u - l"
   507   by (simp_all add: measure_def)
   508 
   509 lemma
   510   assumes [simp]: "\<And>b. b \<in> Basis \<Longrightarrow> l \<bullet> b \<le> u \<bullet> b"
   511   shows measure_lborel_box[simp]: "measure lborel (box l u) = (\<Prod>b\<in>Basis. (u - l) \<bullet> b)"
   512     and measure_lborel_cbox[simp]: "measure lborel (cbox l u) = (\<Prod>b\<in>Basis. (u - l) \<bullet> b)"
   513   by (simp_all add: measure_def inner_diff_left prod_nonneg)
   514 
   515 lemma measure_lborel_cbox_eq:
   516   "measure lborel (cbox l u) = (if \<forall>b\<in>Basis. l \<bullet> b \<le> u \<bullet> b then \<Prod>b\<in>Basis. (u - l) \<bullet> b else 0)"
   517   using box_eq_empty(2)[THEN iffD2, of u l] by (auto simp: not_le)
   518 
   519 lemma measure_lborel_box_eq:
   520   "measure lborel (box l u) = (if \<forall>b\<in>Basis. l \<bullet> b \<le> u \<bullet> b then \<Prod>b\<in>Basis. (u - l) \<bullet> b else 0)"
   521   using box_eq_empty(1)[THEN iffD2, of u l] by (auto simp: not_le dest!: less_imp_le) force
   522 
   523 lemma measure_lborel_singleton[simp]: "measure lborel {x} = 0"
   524   by (simp add: measure_def)
   525 
   526 lemma sigma_finite_lborel: "sigma_finite_measure lborel"
   527 proof
   528   show "\<exists>A::'a set set. countable A \<and> A \<subseteq> sets lborel \<and> \<Union>A = space lborel \<and> (\<forall>a\<in>A. emeasure lborel a \<noteq> \<infinity>)"
   529     by (intro exI[of _ "range (\<lambda>n::nat. box (- real n *\<^sub>R One) (real n *\<^sub>R One))"])
   530        (auto simp: emeasure_lborel_cbox_eq UN_box_eq_UNIV)
   531 qed
   532 
   533 end
   534 
   535 lemma emeasure_lborel_UNIV: "emeasure lborel (UNIV::'a::euclidean_space set) = \<infinity>"
   536 proof -
   537   { fix n::nat
   538     let ?Ba = "Basis :: 'a set"
   539     have "real n \<le> (2::real) ^ card ?Ba * real n"
   540       by (simp add: mult_le_cancel_right1)
   541     also
   542     have "... \<le> (2::real) ^ card ?Ba * real (Suc n) ^ card ?Ba"
   543       apply (rule mult_left_mono)
   544       apply (metis DIM_positive One_nat_def less_eq_Suc_le less_imp_le of_nat_le_iff of_nat_power self_le_power zero_less_Suc)
   545       apply (simp add: DIM_positive)
   546       done
   547     finally have "real n \<le> (2::real) ^ card ?Ba * real (Suc n) ^ card ?Ba" .
   548   } note [intro!] = this
   549   show ?thesis
   550     unfolding UN_box_eq_UNIV[symmetric]
   551     apply (subst SUP_emeasure_incseq[symmetric])
   552     apply (auto simp: incseq_def subset_box inner_add_left prod_constant
   553       simp del: Sup_eq_top_iff SUP_eq_top_iff
   554       intro!: ennreal_SUP_eq_top)
   555     done
   556 qed
   557 
   558 lemma emeasure_lborel_countable:
   559   fixes A :: "'a::euclidean_space set"
   560   assumes "countable A"
   561   shows "emeasure lborel A = 0"
   562 proof -
   563   have "A \<subseteq> (\<Union>i. {from_nat_into A i})" using from_nat_into_surj assms by force
   564   then have "emeasure lborel A \<le> emeasure lborel (\<Union>i. {from_nat_into A i})"
   565     by (intro emeasure_mono) auto
   566   also have "emeasure lborel (\<Union>i. {from_nat_into A i}) = 0"
   567     by (rule emeasure_UN_eq_0) auto
   568   finally show ?thesis
   569     by (auto simp add: )
   570 qed
   571 
   572 lemma countable_imp_null_set_lborel: "countable A \<Longrightarrow> A \<in> null_sets lborel"
   573   by (simp add: null_sets_def emeasure_lborel_countable sets.countable)
   574 
   575 lemma finite_imp_null_set_lborel: "finite A \<Longrightarrow> A \<in> null_sets lborel"
   576   by (intro countable_imp_null_set_lborel countable_finite)
   577 
   578 lemma lborel_neq_count_space[simp]: "lborel \<noteq> count_space (A::('a::ordered_euclidean_space) set)"
   579 proof
   580   assume asm: "lborel = count_space A"
   581   have "space lborel = UNIV" by simp
   582   hence [simp]: "A = UNIV" by (subst (asm) asm) (simp only: space_count_space)
   583   have "emeasure lborel {undefined::'a} = 1"
   584       by (subst asm, subst emeasure_count_space_finite) auto
   585   moreover have "emeasure lborel {undefined} \<noteq> 1" by simp
   586   ultimately show False by contradiction
   587 qed
   588 
   589 lemma mem_closed_if_AE_lebesgue_open:
   590   assumes "open S" "closed C"
   591   assumes "AE x \<in> S in lebesgue. x \<in> C"
   592   assumes "x \<in> S"
   593   shows "x \<in> C"
   594 proof (rule ccontr)
   595   assume xC: "x \<notin> C"
   596   with openE[of "S - C"] assms
   597   obtain e where e: "0 < e" "ball x e \<subseteq> S - C"
   598     by blast
   599   then obtain a b where box: "x \<in> box a b" "box a b \<subseteq> S - C"
   600     by (metis rational_boxes order_trans)
   601   then have "0 < emeasure lebesgue (box a b)"
   602     by (auto simp: emeasure_lborel_box_eq mem_box algebra_simps intro!: prod_pos)
   603   also have "\<dots> \<le> emeasure lebesgue (S - C)"
   604     using assms box
   605     by (auto intro!: emeasure_mono)
   606   also have "\<dots> = 0"
   607     using assms
   608     by (auto simp: eventually_ae_filter completion.complete2 set_diff_eq null_setsD1)
   609   finally show False by simp
   610 qed
   611 
   612 lemma mem_closed_if_AE_lebesgue: "closed C \<Longrightarrow> (AE x in lebesgue. x \<in> C) \<Longrightarrow> x \<in> C"
   613   using mem_closed_if_AE_lebesgue_open[OF open_UNIV] by simp
   614 
   615 
   616 subsection \<open>Affine transformation on the Lebesgue-Borel\<close>
   617 
   618 lemma lborel_eqI:
   619   fixes M :: "'a::euclidean_space measure"
   620   assumes emeasure_eq: "\<And>l u. (\<And>b. b \<in> Basis \<Longrightarrow> l \<bullet> b \<le> u \<bullet> b) \<Longrightarrow> emeasure M (box l u) = (\<Prod>b\<in>Basis. (u - l) \<bullet> b)"
   621   assumes sets_eq: "sets M = sets borel"
   622   shows "lborel = M"
   623 proof (rule measure_eqI_generator_eq)
   624   let ?E = "range (\<lambda>(a, b). box a b::'a set)"
   625   show "Int_stable ?E"
   626     by (auto simp: Int_stable_def box_Int_box)
   627 
   628   show "?E \<subseteq> Pow UNIV" "sets lborel = sigma_sets UNIV ?E" "sets M = sigma_sets UNIV ?E"
   629     by (simp_all add: borel_eq_box sets_eq)
   630 
   631   let ?A = "\<lambda>n::nat. box (- (real n *\<^sub>R One)) (real n *\<^sub>R One) :: 'a set"
   632   show "range ?A \<subseteq> ?E" "(\<Union>i. ?A i) = UNIV"
   633     unfolding UN_box_eq_UNIV by auto
   634 
   635   { fix i show "emeasure lborel (?A i) \<noteq> \<infinity>" by auto }
   636   { fix X assume "X \<in> ?E" then show "emeasure lborel X = emeasure M X"
   637       apply (auto simp: emeasure_eq emeasure_lborel_box_eq)
   638       apply (subst box_eq_empty(1)[THEN iffD2])
   639       apply (auto intro: less_imp_le simp: not_le)
   640       done }
   641 qed
   642 
   643 lemma lborel_affine_euclidean:
   644   fixes c :: "'a::euclidean_space \<Rightarrow> real" and t
   645   defines "T x \<equiv> t + (\<Sum>j\<in>Basis. (c j * (x \<bullet> j)) *\<^sub>R j)"
   646   assumes c: "\<And>j. j \<in> Basis \<Longrightarrow> c j \<noteq> 0"
   647   shows "lborel = density (distr lborel borel T) (\<lambda>_. (\<Prod>j\<in>Basis. \<bar>c j\<bar>))" (is "_ = ?D")
   648 proof (rule lborel_eqI)
   649   let ?B = "Basis :: 'a set"
   650   fix l u assume le: "\<And>b. b \<in> ?B \<Longrightarrow> l \<bullet> b \<le> u \<bullet> b"
   651   have [measurable]: "T \<in> borel \<rightarrow>\<^sub>M borel"
   652     by (simp add: T_def[abs_def])
   653   have eq: "T -` box l u = box
   654     (\<Sum>j\<in>Basis. (((if 0 < c j then l - t else u - t) \<bullet> j) / c j) *\<^sub>R j)
   655     (\<Sum>j\<in>Basis. (((if 0 < c j then u - t else l - t) \<bullet> j) / c j) *\<^sub>R j)"
   656     using c by (auto simp: box_def T_def field_simps inner_simps divide_less_eq)
   657   with le c show "emeasure ?D (box l u) = (\<Prod>b\<in>?B. (u - l) \<bullet> b)"
   658     by (auto simp: emeasure_density emeasure_distr nn_integral_multc emeasure_lborel_box_eq inner_simps
   659                    field_simps divide_simps ennreal_mult'[symmetric] prod_nonneg prod.distrib[symmetric]
   660              intro!: prod.cong)
   661 qed simp
   662 
   663 lemma lborel_affine:
   664   fixes t :: "'a::euclidean_space"
   665   shows "c \<noteq> 0 \<Longrightarrow> lborel = density (distr lborel borel (\<lambda>x. t + c *\<^sub>R x)) (\<lambda>_. \<bar>c\<bar>^DIM('a))"
   666   using lborel_affine_euclidean[where c="\<lambda>_::'a. c" and t=t]
   667   unfolding scaleR_scaleR[symmetric] scaleR_sum_right[symmetric] euclidean_representation prod_constant by simp
   668 
   669 lemma lborel_real_affine:
   670   "c \<noteq> 0 \<Longrightarrow> lborel = density (distr lborel borel (\<lambda>x. t + c * x)) (\<lambda>_. ennreal (abs c))"
   671   using lborel_affine[of c t] by simp
   672 
   673 lemma AE_borel_affine:
   674   fixes P :: "real \<Rightarrow> bool"
   675   shows "c \<noteq> 0 \<Longrightarrow> Measurable.pred borel P \<Longrightarrow> AE x in lborel. P x \<Longrightarrow> AE x in lborel. P (t + c * x)"
   676   by (subst lborel_real_affine[where t="- t / c" and c="1 / c"])
   677      (simp_all add: AE_density AE_distr_iff field_simps)
   678 
   679 lemma nn_integral_real_affine:
   680   fixes c :: real assumes [measurable]: "f \<in> borel_measurable borel" and c: "c \<noteq> 0"
   681   shows "(\<integral>\<^sup>+x. f x \<partial>lborel) = \<bar>c\<bar> * (\<integral>\<^sup>+x. f (t + c * x) \<partial>lborel)"
   682   by (subst lborel_real_affine[OF c, of t])
   683      (simp add: nn_integral_density nn_integral_distr nn_integral_cmult)
   684 
   685 lemma lborel_integrable_real_affine:
   686   fixes f :: "real \<Rightarrow> 'a :: {banach, second_countable_topology}"
   687   assumes f: "integrable lborel f"
   688   shows "c \<noteq> 0 \<Longrightarrow> integrable lborel (\<lambda>x. f (t + c * x))"
   689   using f f[THEN borel_measurable_integrable] unfolding integrable_iff_bounded
   690   by (subst (asm) nn_integral_real_affine[where c=c and t=t]) (auto simp: ennreal_mult_less_top)
   691 
   692 lemma lborel_integrable_real_affine_iff:
   693   fixes f :: "real \<Rightarrow> 'a :: {banach, second_countable_topology}"
   694   shows "c \<noteq> 0 \<Longrightarrow> integrable lborel (\<lambda>x. f (t + c * x)) \<longleftrightarrow> integrable lborel f"
   695   using
   696     lborel_integrable_real_affine[of f c t]
   697     lborel_integrable_real_affine[of "\<lambda>x. f (t + c * x)" "1/c" "-t/c"]
   698   by (auto simp add: field_simps)
   699 
   700 lemma lborel_integral_real_affine:
   701   fixes f :: "real \<Rightarrow> 'a :: {banach, second_countable_topology}" and c :: real
   702   assumes c: "c \<noteq> 0" shows "(\<integral>x. f x \<partial> lborel) = \<bar>c\<bar> *\<^sub>R (\<integral>x. f (t + c * x) \<partial>lborel)"
   703 proof cases
   704   assume f[measurable]: "integrable lborel f" then show ?thesis
   705     using c f f[THEN borel_measurable_integrable] f[THEN lborel_integrable_real_affine, of c t]
   706     by (subst lborel_real_affine[OF c, of t])
   707        (simp add: integral_density integral_distr)
   708 next
   709   assume "\<not> integrable lborel f" with c show ?thesis
   710     by (simp add: lborel_integrable_real_affine_iff not_integrable_integral_eq)
   711 qed
   712 
   713 lemma
   714   fixes c :: "'a::euclidean_space \<Rightarrow> real" and t
   715   assumes c: "\<And>j. j \<in> Basis \<Longrightarrow> c j \<noteq> 0"
   716   defines "T == (\<lambda>x. t + (\<Sum>j\<in>Basis. (c j * (x \<bullet> j)) *\<^sub>R j))"
   717   shows lebesgue_affine_euclidean: "lebesgue = density (distr lebesgue lebesgue T) (\<lambda>_. (\<Prod>j\<in>Basis. \<bar>c j\<bar>))" (is "_ = ?D")
   718     and lebesgue_affine_measurable: "T \<in> lebesgue \<rightarrow>\<^sub>M lebesgue"
   719 proof -
   720   have T_borel[measurable]: "T \<in> borel \<rightarrow>\<^sub>M borel"
   721     by (auto simp: T_def[abs_def])
   722   { fix A :: "'a set" assume A: "A \<in> sets borel"
   723     then have "emeasure lborel A = 0 \<longleftrightarrow> emeasure (density (distr lborel borel T) (\<lambda>_. (\<Prod>j\<in>Basis. \<bar>c j\<bar>))) A = 0"
   724       unfolding T_def using c by (subst lborel_affine_euclidean[symmetric]) auto
   725     also have "\<dots> \<longleftrightarrow> emeasure (distr lebesgue lborel T) A = 0"
   726       using A c by (simp add: distr_completion emeasure_density nn_integral_cmult prod_nonneg cong: distr_cong)
   727     finally have "emeasure lborel A = 0 \<longleftrightarrow> emeasure (distr lebesgue lborel T) A = 0" . }
   728   then have eq: "null_sets lborel = null_sets (distr lebesgue lborel T)"
   729     by (auto simp: null_sets_def)
   730 
   731   show "T \<in> lebesgue \<rightarrow>\<^sub>M lebesgue"
   732     by (rule completion.measurable_completion2) (auto simp: eq measurable_completion)
   733 
   734   have "lebesgue = completion (density (distr lborel borel T) (\<lambda>_. (\<Prod>j\<in>Basis. \<bar>c j\<bar>)))"
   735     using c by (subst lborel_affine_euclidean[of c t]) (simp_all add: T_def[abs_def])
   736   also have "\<dots> = density (completion (distr lebesgue lborel T)) (\<lambda>_. (\<Prod>j\<in>Basis. \<bar>c j\<bar>))"
   737     using c by (auto intro!: always_eventually prod_pos completion_density_eq simp: distr_completion cong: distr_cong)
   738   also have "\<dots> = density (distr lebesgue lebesgue T) (\<lambda>_. (\<Prod>j\<in>Basis. \<bar>c j\<bar>))"
   739     by (subst completion.completion_distr_eq) (auto simp: eq measurable_completion)
   740   finally show "lebesgue = density (distr lebesgue lebesgue T) (\<lambda>_. (\<Prod>j\<in>Basis. \<bar>c j\<bar>))" .
   741 qed
   742 
   743 lemma lebesgue_measurable_scaling[measurable]: "op *\<^sub>R x \<in> lebesgue \<rightarrow>\<^sub>M lebesgue"
   744 proof cases
   745   assume "x = 0"
   746   then have "op *\<^sub>R x = (\<lambda>x. 0::'a)"
   747     by (auto simp: fun_eq_iff)
   748   then show ?thesis by auto
   749 next
   750   assume "x \<noteq> 0" then show ?thesis
   751     using lebesgue_affine_measurable[of "\<lambda>_. x" 0]
   752     unfolding scaleR_scaleR[symmetric] scaleR_sum_right[symmetric] euclidean_representation
   753     by (auto simp add: ac_simps)
   754 qed
   755 
   756 lemma
   757   fixes m :: real and \<delta> :: "'a::euclidean_space"
   758   defines "T r d x \<equiv> r *\<^sub>R x + d"
   759   shows emeasure_lebesgue_affine: "emeasure lebesgue (T m \<delta> ` S) = \<bar>m\<bar> ^ DIM('a) * emeasure lebesgue S" (is ?e)
   760     and measure_lebesgue_affine: "measure lebesgue (T m \<delta> ` S) = \<bar>m\<bar> ^ DIM('a) * measure lebesgue S" (is ?m)
   761 proof -
   762   show ?e
   763   proof cases
   764     assume "m = 0" then show ?thesis
   765       by (simp add: image_constant_conv T_def[abs_def])
   766   next
   767     let ?T = "T m \<delta>" and ?T' = "T (1 / m) (- ((1/m) *\<^sub>R \<delta>))"
   768     assume "m \<noteq> 0"
   769     then have s_comp_s: "?T' \<circ> ?T = id" "?T \<circ> ?T' = id"
   770       by (auto simp: T_def[abs_def] fun_eq_iff scaleR_add_right scaleR_diff_right)
   771     then have "inv ?T' = ?T" "bij ?T'"
   772       by (auto intro: inv_unique_comp o_bij)
   773     then have eq: "T m \<delta> ` S = T (1 / m) ((-1/m) *\<^sub>R \<delta>) -` S \<inter> space lebesgue"
   774       using bij_vimage_eq_inv_image[OF \<open>bij ?T'\<close>, of S] by auto
   775 
   776     have trans_eq_T: "(\<lambda>x. \<delta> + (\<Sum>j\<in>Basis. (m * (x \<bullet> j)) *\<^sub>R j)) = T m \<delta>" for m \<delta>
   777       unfolding T_def[abs_def] scaleR_scaleR[symmetric] scaleR_sum_right[symmetric]
   778       by (auto simp add: euclidean_representation ac_simps)
   779 
   780     have T[measurable]: "T r d \<in> lebesgue \<rightarrow>\<^sub>M lebesgue" for r d
   781       using lebesgue_affine_measurable[of "\<lambda>_. r" d]
   782       by (cases "r = 0") (auto simp: trans_eq_T T_def[abs_def])
   783 
   784     show ?thesis
   785     proof cases
   786       assume "S \<in> sets lebesgue" with \<open>m \<noteq> 0\<close> show ?thesis
   787         unfolding eq
   788         apply (subst lebesgue_affine_euclidean[of "\<lambda>_. m" \<delta>])
   789         apply (simp_all add: emeasure_density trans_eq_T nn_integral_cmult emeasure_distr
   790                         del: space_completion emeasure_completion)
   791         apply (simp add: vimage_comp s_comp_s prod_constant)
   792         done
   793     next
   794       assume "S \<notin> sets lebesgue"
   795       moreover have "?T ` S \<notin> sets lebesgue"
   796       proof
   797         assume "?T ` S \<in> sets lebesgue"
   798         then have "?T -` (?T ` S) \<inter> space lebesgue \<in> sets lebesgue"
   799           by (rule measurable_sets[OF T])
   800         also have "?T -` (?T ` S) \<inter> space lebesgue = S"
   801           by (simp add: vimage_comp s_comp_s eq)
   802         finally show False using \<open>S \<notin> sets lebesgue\<close> by auto
   803       qed
   804       ultimately show ?thesis
   805         by (simp add: emeasure_notin_sets)
   806     qed
   807   qed
   808   show ?m
   809     unfolding measure_def \<open>?e\<close> by (simp add: enn2real_mult prod_nonneg)
   810 qed
   811 
   812 lemma divideR_right:
   813   fixes x y :: "'a::real_normed_vector"
   814   shows "r \<noteq> 0 \<Longrightarrow> y = x /\<^sub>R r \<longleftrightarrow> r *\<^sub>R y = x"
   815   using scaleR_cancel_left[of r y "x /\<^sub>R r"] by simp
   816 
   817 lemma lborel_has_bochner_integral_real_affine_iff:
   818   fixes x :: "'a :: {banach, second_countable_topology}"
   819   shows "c \<noteq> 0 \<Longrightarrow>
   820     has_bochner_integral lborel f x \<longleftrightarrow>
   821     has_bochner_integral lborel (\<lambda>x. f (t + c * x)) (x /\<^sub>R \<bar>c\<bar>)"
   822   unfolding has_bochner_integral_iff lborel_integrable_real_affine_iff
   823   by (simp_all add: lborel_integral_real_affine[symmetric] divideR_right cong: conj_cong)
   824 
   825 lemma lborel_distr_uminus: "distr lborel borel uminus = (lborel :: real measure)"
   826   by (subst lborel_real_affine[of "-1" 0])
   827      (auto simp: density_1 one_ennreal_def[symmetric])
   828 
   829 lemma lborel_distr_mult:
   830   assumes "(c::real) \<noteq> 0"
   831   shows "distr lborel borel (op * c) = density lborel (\<lambda>_. inverse \<bar>c\<bar>)"
   832 proof-
   833   have "distr lborel borel (op * c) = distr lborel lborel (op * c)" by (simp cong: distr_cong)
   834   also from assms have "... = density lborel (\<lambda>_. inverse \<bar>c\<bar>)"
   835     by (subst lborel_real_affine[of "inverse c" 0]) (auto simp: o_def distr_density_distr)
   836   finally show ?thesis .
   837 qed
   838 
   839 lemma lborel_distr_mult':
   840   assumes "(c::real) \<noteq> 0"
   841   shows "lborel = density (distr lborel borel (op * c)) (\<lambda>_. \<bar>c\<bar>)"
   842 proof-
   843   have "lborel = density lborel (\<lambda>_. 1)" by (rule density_1[symmetric])
   844   also from assms have "(\<lambda>_. 1 :: ennreal) = (\<lambda>_. inverse \<bar>c\<bar> * \<bar>c\<bar>)" by (intro ext) simp
   845   also have "density lborel ... = density (density lborel (\<lambda>_. inverse \<bar>c\<bar>)) (\<lambda>_. \<bar>c\<bar>)"
   846     by (subst density_density_eq) (auto simp: ennreal_mult)
   847   also from assms have "density lborel (\<lambda>_. inverse \<bar>c\<bar>) = distr lborel borel (op * c)"
   848     by (rule lborel_distr_mult[symmetric])
   849   finally show ?thesis .
   850 qed
   851 
   852 lemma lborel_distr_plus: "distr lborel borel (op + c) = (lborel :: real measure)"
   853   by (subst lborel_real_affine[of 1 c]) (auto simp: density_1 one_ennreal_def[symmetric])
   854 
   855 interpretation lborel: sigma_finite_measure lborel
   856   by (rule sigma_finite_lborel)
   857 
   858 interpretation lborel_pair: pair_sigma_finite lborel lborel ..
   859 
   860 lemma lborel_prod:
   861   "lborel \<Otimes>\<^sub>M lborel = (lborel :: ('a::euclidean_space \<times> 'b::euclidean_space) measure)"
   862 proof (rule lborel_eqI[symmetric], clarify)
   863   fix la ua :: 'a and lb ub :: 'b
   864   assume lu: "\<And>a b. (a, b) \<in> Basis \<Longrightarrow> (la, lb) \<bullet> (a, b) \<le> (ua, ub) \<bullet> (a, b)"
   865   have [simp]:
   866     "\<And>b. b \<in> Basis \<Longrightarrow> la \<bullet> b \<le> ua \<bullet> b"
   867     "\<And>b. b \<in> Basis \<Longrightarrow> lb \<bullet> b \<le> ub \<bullet> b"
   868     "inj_on (\<lambda>u. (u, 0)) Basis" "inj_on (\<lambda>u. (0, u)) Basis"
   869     "(\<lambda>u. (u, 0)) ` Basis \<inter> (\<lambda>u. (0, u)) ` Basis = {}"
   870     "box (la, lb) (ua, ub) = box la ua \<times> box lb ub"
   871     using lu[of _ 0] lu[of 0] by (auto intro!: inj_onI simp add: Basis_prod_def ball_Un box_def)
   872   show "emeasure (lborel \<Otimes>\<^sub>M lborel) (box (la, lb) (ua, ub)) =
   873       ennreal (prod (op \<bullet> ((ua, ub) - (la, lb))) Basis)"
   874     by (simp add: lborel.emeasure_pair_measure_Times Basis_prod_def prod.union_disjoint
   875                   prod.reindex ennreal_mult inner_diff_left prod_nonneg)
   876 qed (simp add: borel_prod[symmetric])
   877 
   878 (* FIXME: conversion in measurable prover *)
   879 lemma lborelD_Collect[measurable (raw)]: "{x\<in>space borel. P x} \<in> sets borel \<Longrightarrow> {x\<in>space lborel. P x} \<in> sets lborel" by simp
   880 lemma lborelD[measurable (raw)]: "A \<in> sets borel \<Longrightarrow> A \<in> sets lborel" by simp
   881 
   882 lemma emeasure_bounded_finite:
   883   assumes "bounded A" shows "emeasure lborel A < \<infinity>"
   884 proof -
   885   from bounded_subset_cbox[OF \<open>bounded A\<close>] obtain a b where "A \<subseteq> cbox a b"
   886     by auto
   887   then have "emeasure lborel A \<le> emeasure lborel (cbox a b)"
   888     by (intro emeasure_mono) auto
   889   then show ?thesis
   890     by (auto simp: emeasure_lborel_cbox_eq prod_nonneg less_top[symmetric] top_unique split: if_split_asm)
   891 qed
   892 
   893 lemma emeasure_compact_finite: "compact A \<Longrightarrow> emeasure lborel A < \<infinity>"
   894   using emeasure_bounded_finite[of A] by (auto intro: compact_imp_bounded)
   895 
   896 lemma borel_integrable_compact:
   897   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::{banach, second_countable_topology}"
   898   assumes "compact S" "continuous_on S f"
   899   shows "integrable lborel (\<lambda>x. indicator S x *\<^sub>R f x)"
   900 proof cases
   901   assume "S \<noteq> {}"
   902   have "continuous_on S (\<lambda>x. norm (f x))"
   903     using assms by (intro continuous_intros)
   904   from continuous_attains_sup[OF \<open>compact S\<close> \<open>S \<noteq> {}\<close> this]
   905   obtain M where M: "\<And>x. x \<in> S \<Longrightarrow> norm (f x) \<le> M"
   906     by auto
   907 
   908   show ?thesis
   909   proof (rule integrable_bound)
   910     show "integrable lborel (\<lambda>x. indicator S x * M)"
   911       using assms by (auto intro!: emeasure_compact_finite borel_compact integrable_mult_left)
   912     show "(\<lambda>x. indicator S x *\<^sub>R f x) \<in> borel_measurable lborel"
   913       using assms by (auto intro!: borel_measurable_continuous_on_indicator borel_compact)
   914     show "AE x in lborel. norm (indicator S x *\<^sub>R f x) \<le> norm (indicator S x * M)"
   915       by (auto split: split_indicator simp: abs_real_def dest!: M)
   916   qed
   917 qed simp
   918 
   919 lemma borel_integrable_atLeastAtMost:
   920   fixes f :: "real \<Rightarrow> real"
   921   assumes f: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> isCont f x"
   922   shows "integrable lborel (\<lambda>x. f x * indicator {a .. b} x)" (is "integrable _ ?f")
   923 proof -
   924   have "integrable lborel (\<lambda>x. indicator {a .. b} x *\<^sub>R f x)"
   925   proof (rule borel_integrable_compact)
   926     from f show "continuous_on {a..b} f"
   927       by (auto intro: continuous_at_imp_continuous_on)
   928   qed simp
   929   then show ?thesis
   930     by (auto simp: mult.commute)
   931 qed
   932 
   933 abbreviation lmeasurable :: "'a::euclidean_space set set"
   934 where
   935   "lmeasurable \<equiv> fmeasurable lebesgue"
   936 
   937 lemma lmeasurable_iff_integrable:
   938   "S \<in> lmeasurable \<longleftrightarrow> integrable lebesgue (indicator S :: 'a::euclidean_space \<Rightarrow> real)"
   939   by (auto simp: fmeasurable_def integrable_iff_bounded borel_measurable_indicator_iff ennreal_indicator)
   940 
   941 lemma lmeasurable_cbox [iff]: "cbox a b \<in> lmeasurable"
   942   and lmeasurable_box [iff]: "box a b \<in> lmeasurable"
   943   by (auto simp: fmeasurable_def emeasure_lborel_box_eq emeasure_lborel_cbox_eq)
   944 
   945 lemma lmeasurable_compact: "compact S \<Longrightarrow> S \<in> lmeasurable"
   946   using emeasure_compact_finite[of S] by (intro fmeasurableI) (auto simp: borel_compact)
   947 
   948 lemma lmeasurable_open: "bounded S \<Longrightarrow> open S \<Longrightarrow> S \<in> lmeasurable"
   949   using emeasure_bounded_finite[of S] by (intro fmeasurableI) (auto simp: borel_open)
   950 
   951 lemma lmeasurable_ball: "ball a r \<in> lmeasurable"
   952   by (simp add: lmeasurable_open)
   953 
   954 lemma lmeasurable_interior: "bounded S \<Longrightarrow> interior S \<in> lmeasurable"
   955   by (simp add: bounded_interior lmeasurable_open)
   956 
   957 lemma null_sets_cbox_Diff_box: "cbox a b - box a b \<in> null_sets lborel"
   958 proof -
   959   have "emeasure lborel (cbox a b - box a b) = 0"
   960     by (subst emeasure_Diff) (auto simp: emeasure_lborel_cbox_eq emeasure_lborel_box_eq box_subset_cbox)
   961   then have "cbox a b - box a b \<in> null_sets lborel"
   962     by (auto simp: null_sets_def)
   963   then show ?thesis
   964     by (auto dest!: AE_not_in)
   965 qed
   966 subsection\<open> A nice lemma for negligibility proofs.\<close>
   967 
   968 lemma summable_iff_suminf_neq_top: "(\<And>n. f n \<ge> 0) \<Longrightarrow> \<not> summable f \<Longrightarrow> (\<Sum>i. ennreal (f i)) = top"
   969   by (metis summable_suminf_not_top)
   970 
   971 proposition starlike_negligible_bounded_gmeasurable:
   972   fixes S :: "'a :: euclidean_space set"
   973   assumes S: "S \<in> sets lebesgue" and "bounded S"
   974       and eq1: "\<And>c x. \<lbrakk>(c *\<^sub>R x) \<in> S; 0 \<le> c; x \<in> S\<rbrakk> \<Longrightarrow> c = 1"
   975     shows "S \<in> null_sets lebesgue"
   976 proof -
   977   obtain M where "0 < M" "S \<subseteq> ball 0 M"
   978     using \<open>bounded S\<close> by (auto dest: bounded_subset_ballD)
   979 
   980   let ?f = "\<lambda>n. root DIM('a) (Suc n)"
   981 
   982   have vimage_eq_image: "op *\<^sub>R (?f n) -` S = op *\<^sub>R (1 / ?f n) ` S" for n
   983     apply safe
   984     subgoal for x by (rule image_eqI[of _ _ "?f n *\<^sub>R x"]) auto
   985     subgoal by auto
   986     done
   987 
   988   have eq: "(1 / ?f n) ^ DIM('a) = 1 / Suc n" for n
   989     by (simp add: field_simps)
   990 
   991   { fix n x assume x: "root DIM('a) (1 + real n) *\<^sub>R x \<in> S"
   992     have "1 * norm x \<le> root DIM('a) (1 + real n) * norm x"
   993       by (rule mult_mono) auto
   994     also have "\<dots> < M"
   995       using x \<open>S \<subseteq> ball 0 M\<close> by auto
   996     finally have "norm x < M" by simp }
   997   note less_M = this
   998 
   999   have "(\<Sum>n. ennreal (1 / Suc n)) = top"
  1000     using not_summable_harmonic[where 'a=real] summable_Suc_iff[where f="\<lambda>n. 1 / (real n)"]
  1001     by (intro summable_iff_suminf_neq_top) (auto simp add: inverse_eq_divide)
  1002   then have "top * emeasure lebesgue S = (\<Sum>n. (1 / ?f n)^DIM('a) * emeasure lebesgue S)"
  1003     unfolding ennreal_suminf_multc eq by simp
  1004   also have "\<dots> = (\<Sum>n. emeasure lebesgue (op *\<^sub>R (?f n) -` S))"
  1005     unfolding vimage_eq_image using emeasure_lebesgue_affine[of "1 / ?f n" 0 S for n] by simp
  1006   also have "\<dots> = emeasure lebesgue (\<Union>n. op *\<^sub>R (?f n) -` S)"
  1007   proof (intro suminf_emeasure)
  1008     show "disjoint_family (\<lambda>n. op *\<^sub>R (?f n) -` S)"
  1009       unfolding disjoint_family_on_def
  1010     proof safe
  1011       fix m n :: nat and x assume "m \<noteq> n" "?f m *\<^sub>R x \<in> S" "?f n *\<^sub>R x \<in> S"
  1012       with eq1[of "?f m / ?f n" "?f n *\<^sub>R x"] show "x \<in> {}"
  1013         by auto
  1014     qed
  1015     have "op *\<^sub>R (?f i) -` S \<in> sets lebesgue" for i
  1016       using measurable_sets[OF lebesgue_measurable_scaling[of "?f i"] S] by auto
  1017     then show "range (\<lambda>i. op *\<^sub>R (?f i) -` S) \<subseteq> sets lebesgue"
  1018       by auto
  1019   qed
  1020   also have "\<dots> \<le> emeasure lebesgue (ball 0 M :: 'a set)"
  1021     using less_M by (intro emeasure_mono) auto
  1022   also have "\<dots> < top"
  1023     using lmeasurable_ball by (auto simp: fmeasurable_def)
  1024   finally have "emeasure lebesgue S = 0"
  1025     by (simp add: ennreal_top_mult split: if_split_asm)
  1026   then show "S \<in> null_sets lebesgue"
  1027     unfolding null_sets_def using \<open>S \<in> sets lebesgue\<close> by auto
  1028 qed
  1029 
  1030 corollary starlike_negligible_compact:
  1031   "compact S \<Longrightarrow> (\<And>c x. \<lbrakk>(c *\<^sub>R x) \<in> S; 0 \<le> c; x \<in> S\<rbrakk> \<Longrightarrow> c = 1) \<Longrightarrow> S \<in> null_sets lebesgue"
  1032   using starlike_negligible_bounded_gmeasurable[of S] by (auto simp: compact_eq_bounded_closed)
  1033 
  1034 lemma outer_regular_lborel:
  1035   assumes B: "B \<in> fmeasurable lborel" "0 < (e::real)"
  1036   shows "\<exists>U. open U \<and> B \<subseteq> U \<and> emeasure lborel U \<le> emeasure lborel B + e"
  1037 proof -
  1038   let ?\<mu> = "emeasure lborel"
  1039   let ?B = "\<lambda>n::nat. ball 0 n :: 'a set"
  1040   have B[measurable]: "B \<in> sets borel"
  1041     using B by auto
  1042   let ?e = "\<lambda>n. e*((1/2)^Suc n)"
  1043   have "\<forall>n. \<exists>U. open U \<and> ?B n \<inter> B \<subseteq> U \<and> ?\<mu> (U - B) < ?e n"
  1044   proof
  1045     fix n :: nat
  1046     let ?A = "density lborel (indicator (?B n))"
  1047     have emeasure_A: "X \<in> sets borel \<Longrightarrow> emeasure ?A X = ?\<mu> (?B n \<inter> X)" for X
  1048       by (auto simp add: emeasure_density borel_measurable_indicator indicator_inter_arith[symmetric])
  1049 
  1050     have finite_A: "emeasure ?A (space ?A) \<noteq> \<infinity>"
  1051       using emeasure_bounded_finite[of "?B n"] by (auto simp add: emeasure_A)
  1052     interpret A: finite_measure ?A
  1053       by rule fact
  1054     have "emeasure ?A B + ?e n > (INF U:{U. B \<subseteq> U \<and> open U}. emeasure ?A U)"
  1055       using \<open>0<e\<close> by (auto simp: outer_regular[OF _ finite_A B, symmetric])
  1056     then obtain U where U: "B \<subseteq> U" "open U" "?\<mu> (?B n \<inter> B) + ?e n > ?\<mu> (?B n \<inter> U)"
  1057       unfolding INF_less_iff by (auto simp: emeasure_A)
  1058     moreover
  1059     { have "?\<mu> ((?B n \<inter> U) - B) = ?\<mu> ((?B n \<inter> U) - (?B n \<inter> B))"
  1060         using U by (intro arg_cong[where f="?\<mu>"]) auto
  1061       also have "\<dots> = ?\<mu> (?B n \<inter> U) - ?\<mu> (?B n \<inter> B)"
  1062         using U A.emeasure_finite[of B]
  1063         by (intro emeasure_Diff) (auto simp del: A.emeasure_finite simp: emeasure_A)
  1064       also have "\<dots> < ?e n"
  1065         using U(1,2,3) A.emeasure_finite[of B]
  1066         by (subst minus_less_iff_ennreal)
  1067           (auto simp del: A.emeasure_finite simp: emeasure_A less_top ac_simps intro!: emeasure_mono)
  1068       finally have "?\<mu> ((?B n \<inter> U) - B) < ?e n" . }
  1069     ultimately show "\<exists>U. open U \<and> ?B n \<inter> B \<subseteq> U \<and> ?\<mu> (U - B) < ?e n"
  1070       by (intro exI[of _ "?B n \<inter> U"]) auto
  1071   qed
  1072   then obtain U
  1073     where U: "\<And>n. open (U n)" "\<And>n. ?B n \<inter> B \<subseteq> U n" "\<And>n. ?\<mu> (U n - B) < ?e n"
  1074     by metis
  1075   then show ?thesis
  1076   proof (intro exI conjI)
  1077     { fix x assume "x \<in> B"
  1078       moreover
  1079       have "\<exists>n. norm x < real n"
  1080         by (simp add: reals_Archimedean2)
  1081       then guess n ..
  1082       ultimately have "x \<in> (\<Union>n. U n)"
  1083         using U(2)[of n] by auto }
  1084     note * = this
  1085     then show "open (\<Union>n. U n)" "B \<subseteq> (\<Union>n. U n)"
  1086       using U(1,2) by auto
  1087     have "?\<mu> (\<Union>n. U n) = ?\<mu> (B \<union> (\<Union>n. U n - B))"
  1088       using * U(2) by (intro arg_cong[where ?f="?\<mu>"]) auto
  1089     also have "\<dots> = ?\<mu> B + ?\<mu> (\<Union>n. U n - B)"
  1090       using U(1) by (intro plus_emeasure[symmetric]) auto
  1091     also have "\<dots> \<le> ?\<mu> B + (\<Sum>n. ?\<mu> (U n - B))"
  1092       using U(1) by (intro add_mono emeasure_subadditive_countably) auto
  1093     also have "\<dots> \<le> ?\<mu> B + (\<Sum>n. ennreal (?e n))"
  1094       using U(3) by (intro add_mono suminf_le) (auto intro: less_imp_le)
  1095     also have "(\<Sum>n. ennreal (?e n)) = ennreal (e * 1)"
  1096       using \<open>0<e\<close> by (intro suminf_ennreal_eq sums_mult power_half_series) auto
  1097     finally show "emeasure lborel (\<Union>n. U n) \<le> emeasure lborel B + ennreal e"
  1098       by simp
  1099   qed
  1100 qed
  1101 
  1102 lemma lmeasurable_outer_open:
  1103   assumes S: "S \<in> lmeasurable" and "0 < e"
  1104   obtains T where "open T" "S \<subseteq> T" "T \<in> lmeasurable" "measure lebesgue T \<le> measure lebesgue S + e"
  1105 proof -
  1106   obtain S' where S': "S \<subseteq> S'" "S' \<in> sets borel" "emeasure lborel S' = emeasure lebesgue S"
  1107     using completion_upper[of S lborel] S by auto
  1108   then have f_S': "S' \<in> fmeasurable lborel"
  1109     using S by (auto simp: fmeasurable_def)
  1110   from outer_regular_lborel[OF this \<open>0<e\<close>] guess U .. note U = this
  1111   show thesis
  1112   proof (rule that)
  1113     show "open U" "S \<subseteq> U" "U \<in> lmeasurable"
  1114       using f_S' U S' by (auto simp: fmeasurable_def less_top[symmetric] top_unique)
  1115     then have "U \<in> fmeasurable lborel"
  1116       by (auto simp: fmeasurable_def)
  1117     with S U \<open>0<e\<close> show "measure lebesgue U \<le> measure lebesgue S + e"
  1118       unfolding S'(3) by (simp add: emeasure_eq_measure2 ennreal_plus[symmetric] del: ennreal_plus)
  1119   qed
  1120 qed
  1121 
  1122 end