src/HOL/Topological_Spaces.thy
author immler
Fri Mar 10 23:16:40 2017 +0100 (2017-03-10)
changeset 65204 d23eded35a33
parent 65036 ab7e11730ad8
child 65583 8d53b3bebab4
permissions -rw-r--r--
modernized construction of type bcontfun; base explicit theorems on Uniform_Limit.thy; added some lemmas
     1 (*  Title:      HOL/Topological_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 section \<open>Topological Spaces\<close>
     7 
     8 theory Topological_Spaces
     9   imports Main
    10 begin
    11 
    12 named_theorems continuous_intros "structural introduction rules for continuity"
    13 
    14 subsection \<open>Topological space\<close>
    15 
    16 class "open" =
    17   fixes "open" :: "'a set \<Rightarrow> bool"
    18 
    19 class topological_space = "open" +
    20   assumes open_UNIV [simp, intro]: "open UNIV"
    21   assumes open_Int [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<inter> T)"
    22   assumes open_Union [intro]: "\<forall>S\<in>K. open S \<Longrightarrow> open (\<Union>K)"
    23 begin
    24 
    25 definition closed :: "'a set \<Rightarrow> bool"
    26   where "closed S \<longleftrightarrow> open (- S)"
    27 
    28 lemma open_empty [continuous_intros, intro, simp]: "open {}"
    29   using open_Union [of "{}"] by simp
    30 
    31 lemma open_Un [continuous_intros, intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<union> T)"
    32   using open_Union [of "{S, T}"] by simp
    33 
    34 lemma open_UN [continuous_intros, intro]: "\<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Union>x\<in>A. B x)"
    35   using open_Union [of "B ` A"] by simp
    36 
    37 lemma open_Inter [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. open T \<Longrightarrow> open (\<Inter>S)"
    38   by (induct set: finite) auto
    39 
    40 lemma open_INT [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Inter>x\<in>A. B x)"
    41   using open_Inter [of "B ` A"] by simp
    42 
    43 lemma openI:
    44   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
    45   shows "open S"
    46 proof -
    47   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
    48   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
    49   ultimately show "open S" by simp
    50 qed
    51 
    52 lemma closed_empty [continuous_intros, intro, simp]: "closed {}"
    53   unfolding closed_def by simp
    54 
    55 lemma closed_Un [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<union> T)"
    56   unfolding closed_def by auto
    57 
    58 lemma closed_UNIV [continuous_intros, intro, simp]: "closed UNIV"
    59   unfolding closed_def by simp
    60 
    61 lemma closed_Int [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<inter> T)"
    62   unfolding closed_def by auto
    63 
    64 lemma closed_INT [continuous_intros, intro]: "\<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Inter>x\<in>A. B x)"
    65   unfolding closed_def by auto
    66 
    67 lemma closed_Inter [continuous_intros, intro]: "\<forall>S\<in>K. closed S \<Longrightarrow> closed (\<Inter>K)"
    68   unfolding closed_def uminus_Inf by auto
    69 
    70 lemma closed_Union [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. closed T \<Longrightarrow> closed (\<Union>S)"
    71   by (induct set: finite) auto
    72 
    73 lemma closed_UN [continuous_intros, intro]:
    74   "finite A \<Longrightarrow> \<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Union>x\<in>A. B x)"
    75   using closed_Union [of "B ` A"] by simp
    76 
    77 lemma open_closed: "open S \<longleftrightarrow> closed (- S)"
    78   by (simp add: closed_def)
    79 
    80 lemma closed_open: "closed S \<longleftrightarrow> open (- S)"
    81   by (rule closed_def)
    82 
    83 lemma open_Diff [continuous_intros, intro]: "open S \<Longrightarrow> closed T \<Longrightarrow> open (S - T)"
    84   by (simp add: closed_open Diff_eq open_Int)
    85 
    86 lemma closed_Diff [continuous_intros, intro]: "closed S \<Longrightarrow> open T \<Longrightarrow> closed (S - T)"
    87   by (simp add: open_closed Diff_eq closed_Int)
    88 
    89 lemma open_Compl [continuous_intros, intro]: "closed S \<Longrightarrow> open (- S)"
    90   by (simp add: closed_open)
    91 
    92 lemma closed_Compl [continuous_intros, intro]: "open S \<Longrightarrow> closed (- S)"
    93   by (simp add: open_closed)
    94 
    95 lemma open_Collect_neg: "closed {x. P x} \<Longrightarrow> open {x. \<not> P x}"
    96   unfolding Collect_neg_eq by (rule open_Compl)
    97 
    98 lemma open_Collect_conj:
    99   assumes "open {x. P x}" "open {x. Q x}"
   100   shows "open {x. P x \<and> Q x}"
   101   using open_Int[OF assms] by (simp add: Int_def)
   102 
   103 lemma open_Collect_disj:
   104   assumes "open {x. P x}" "open {x. Q x}"
   105   shows "open {x. P x \<or> Q x}"
   106   using open_Un[OF assms] by (simp add: Un_def)
   107 
   108 lemma open_Collect_ex: "(\<And>i. open {x. P i x}) \<Longrightarrow> open {x. \<exists>i. P i x}"
   109   using open_UN[of UNIV "\<lambda>i. {x. P i x}"] unfolding Collect_ex_eq by simp
   110 
   111 lemma open_Collect_imp: "closed {x. P x} \<Longrightarrow> open {x. Q x} \<Longrightarrow> open {x. P x \<longrightarrow> Q x}"
   112   unfolding imp_conv_disj by (intro open_Collect_disj open_Collect_neg)
   113 
   114 lemma open_Collect_const: "open {x. P}"
   115   by (cases P) auto
   116 
   117 lemma closed_Collect_neg: "open {x. P x} \<Longrightarrow> closed {x. \<not> P x}"
   118   unfolding Collect_neg_eq by (rule closed_Compl)
   119 
   120 lemma closed_Collect_conj:
   121   assumes "closed {x. P x}" "closed {x. Q x}"
   122   shows "closed {x. P x \<and> Q x}"
   123   using closed_Int[OF assms] by (simp add: Int_def)
   124 
   125 lemma closed_Collect_disj:
   126   assumes "closed {x. P x}" "closed {x. Q x}"
   127   shows "closed {x. P x \<or> Q x}"
   128   using closed_Un[OF assms] by (simp add: Un_def)
   129 
   130 lemma closed_Collect_all: "(\<And>i. closed {x. P i x}) \<Longrightarrow> closed {x. \<forall>i. P i x}"
   131   using closed_INT[of UNIV "\<lambda>i. {x. P i x}"] by (simp add: Collect_all_eq)
   132 
   133 lemma closed_Collect_imp: "open {x. P x} \<Longrightarrow> closed {x. Q x} \<Longrightarrow> closed {x. P x \<longrightarrow> Q x}"
   134   unfolding imp_conv_disj by (intro closed_Collect_disj closed_Collect_neg)
   135 
   136 lemma closed_Collect_const: "closed {x. P}"
   137   by (cases P) auto
   138 
   139 end
   140 
   141 
   142 subsection \<open>Hausdorff and other separation properties\<close>
   143 
   144 class t0_space = topological_space +
   145   assumes t0_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U)"
   146 
   147 class t1_space = topological_space +
   148   assumes t1_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   149 
   150 instance t1_space \<subseteq> t0_space
   151   by standard (fast dest: t1_space)
   152 
   153 context t1_space begin
   154 
   155 lemma separation_t1: "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U)"
   156   using t1_space[of x y] by blast
   157 
   158 lemma closed_singleton [iff]: "closed {a}"
   159 proof -
   160   let ?T = "\<Union>{S. open S \<and> a \<notin> S}"
   161   have "open ?T"
   162     by (simp add: open_Union)
   163   also have "?T = - {a}"
   164     by (auto simp add: set_eq_iff separation_t1)
   165   finally show "closed {a}"
   166     by (simp only: closed_def)
   167 qed
   168 
   169 lemma closed_insert [continuous_intros, simp]:
   170   assumes "closed S"
   171   shows "closed (insert a S)"
   172 proof -
   173   from closed_singleton assms have "closed ({a} \<union> S)"
   174     by (rule closed_Un)
   175   then show "closed (insert a S)"
   176     by simp
   177 qed
   178 
   179 lemma finite_imp_closed: "finite S \<Longrightarrow> closed S"
   180   by (induct pred: finite) simp_all
   181 
   182 end
   183 
   184 text \<open>T2 spaces are also known as Hausdorff spaces.\<close>
   185 
   186 class t2_space = topological_space +
   187   assumes hausdorff: "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   188 
   189 instance t2_space \<subseteq> t1_space
   190   by standard (fast dest: hausdorff)
   191 
   192 lemma (in t2_space) separation_t2: "x \<noteq> y \<longleftrightarrow> (\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {})"
   193   using hausdorff [of x y] by blast
   194 
   195 lemma (in t0_space) separation_t0: "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U))"
   196   using t0_space [of x y] by blast
   197 
   198 
   199 text \<open>A perfect space is a topological space with no isolated points.\<close>
   200 
   201 class perfect_space = topological_space +
   202   assumes not_open_singleton: "\<not> open {x}"
   203 
   204 lemma (in perfect_space) UNIV_not_singleton: "UNIV \<noteq> {x}"
   205   for x::'a
   206   by (metis (no_types) open_UNIV not_open_singleton)
   207 
   208 
   209 subsection \<open>Generators for toplogies\<close>
   210 
   211 inductive generate_topology :: "'a set set \<Rightarrow> 'a set \<Rightarrow> bool" for S :: "'a set set"
   212   where
   213     UNIV: "generate_topology S UNIV"
   214   | Int: "generate_topology S (a \<inter> b)" if "generate_topology S a" and "generate_topology S b"
   215   | UN: "generate_topology S (\<Union>K)" if "(\<And>k. k \<in> K \<Longrightarrow> generate_topology S k)"
   216   | Basis: "generate_topology S s" if "s \<in> S"
   217 
   218 hide_fact (open) UNIV Int UN Basis
   219 
   220 lemma generate_topology_Union:
   221   "(\<And>k. k \<in> I \<Longrightarrow> generate_topology S (K k)) \<Longrightarrow> generate_topology S (\<Union>k\<in>I. K k)"
   222   using generate_topology.UN [of "K ` I"] by auto
   223 
   224 lemma topological_space_generate_topology: "class.topological_space (generate_topology S)"
   225   by standard (auto intro: generate_topology.intros)
   226 
   227 
   228 subsection \<open>Order topologies\<close>
   229 
   230 class order_topology = order + "open" +
   231   assumes open_generated_order: "open = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   232 begin
   233 
   234 subclass topological_space
   235   unfolding open_generated_order
   236   by (rule topological_space_generate_topology)
   237 
   238 lemma open_greaterThan [continuous_intros, simp]: "open {a <..}"
   239   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   240 
   241 lemma open_lessThan [continuous_intros, simp]: "open {..< a}"
   242   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   243 
   244 lemma open_greaterThanLessThan [continuous_intros, simp]: "open {a <..< b}"
   245    unfolding greaterThanLessThan_eq by (simp add: open_Int)
   246 
   247 end
   248 
   249 class linorder_topology = linorder + order_topology
   250 
   251 lemma closed_atMost [continuous_intros, simp]: "closed {..a}"
   252   for a :: "'a::linorder_topology"
   253   by (simp add: closed_open)
   254 
   255 lemma closed_atLeast [continuous_intros, simp]: "closed {a..}"
   256   for a :: "'a::linorder_topology"
   257   by (simp add: closed_open)
   258 
   259 lemma closed_atLeastAtMost [continuous_intros, simp]: "closed {a..b}"
   260   for a b :: "'a::linorder_topology"
   261 proof -
   262   have "{a .. b} = {a ..} \<inter> {.. b}"
   263     by auto
   264   then show ?thesis
   265     by (simp add: closed_Int)
   266 qed
   267 
   268 lemma (in linorder) less_separate:
   269   assumes "x < y"
   270   shows "\<exists>a b. x \<in> {..< a} \<and> y \<in> {b <..} \<and> {..< a} \<inter> {b <..} = {}"
   271 proof (cases "\<exists>z. x < z \<and> z < y")
   272   case True
   273   then obtain z where "x < z \<and> z < y" ..
   274   then have "x \<in> {..< z} \<and> y \<in> {z <..} \<and> {z <..} \<inter> {..< z} = {}"
   275     by auto
   276   then show ?thesis by blast
   277 next
   278   case False
   279   with \<open>x < y\<close> have "x \<in> {..< y}" "y \<in> {x <..}" "{x <..} \<inter> {..< y} = {}"
   280     by auto
   281   then show ?thesis by blast
   282 qed
   283 
   284 instance linorder_topology \<subseteq> t2_space
   285 proof
   286   fix x y :: 'a
   287   show "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   288     using less_separate [of x y] less_separate [of y x]
   289     by (elim neqE; metis open_lessThan open_greaterThan Int_commute)
   290 qed
   291 
   292 lemma (in linorder_topology) open_right:
   293   assumes "open S" "x \<in> S"
   294     and gt_ex: "x < y"
   295   shows "\<exists>b>x. {x ..< b} \<subseteq> S"
   296   using assms unfolding open_generated_order
   297 proof induct
   298   case UNIV
   299   then show ?case by blast
   300 next
   301   case (Int A B)
   302   then obtain a b where "a > x" "{x ..< a} \<subseteq> A"  "b > x" "{x ..< b} \<subseteq> B"
   303     by auto
   304   then show ?case
   305     by (auto intro!: exI[of _ "min a b"])
   306 next
   307   case UN
   308   then show ?case by blast
   309 next
   310   case Basis
   311   then show ?case
   312     by (fastforce intro: exI[of _ y] gt_ex)
   313 qed
   314 
   315 lemma (in linorder_topology) open_left:
   316   assumes "open S" "x \<in> S"
   317     and lt_ex: "y < x"
   318   shows "\<exists>b<x. {b <.. x} \<subseteq> S"
   319   using assms unfolding open_generated_order
   320 proof induction
   321   case UNIV
   322   then show ?case by blast
   323 next
   324   case (Int A B)
   325   then obtain a b where "a < x" "{a <.. x} \<subseteq> A"  "b < x" "{b <.. x} \<subseteq> B"
   326     by auto
   327   then show ?case
   328     by (auto intro!: exI[of _ "max a b"])
   329 next
   330   case UN
   331   then show ?case by blast
   332 next
   333   case Basis
   334   then show ?case
   335     by (fastforce intro: exI[of _ y] lt_ex)
   336 qed
   337 
   338 
   339 subsection \<open>Setup some topologies\<close>
   340 
   341 subsubsection \<open>Boolean is an order topology\<close>
   342 
   343 class discrete_topology = topological_space +
   344   assumes open_discrete: "\<And>A. open A"
   345 
   346 instance discrete_topology < t2_space
   347 proof
   348   fix x y :: 'a
   349   assume "x \<noteq> y"
   350   then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   351     by (intro exI[of _ "{_}"]) (auto intro!: open_discrete)
   352 qed
   353 
   354 instantiation bool :: linorder_topology
   355 begin
   356 
   357 definition open_bool :: "bool set \<Rightarrow> bool"
   358   where "open_bool = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   359 
   360 instance
   361   by standard (rule open_bool_def)
   362 
   363 end
   364 
   365 instance bool :: discrete_topology
   366 proof
   367   fix A :: "bool set"
   368   have *: "{False <..} = {True}" "{..< True} = {False}"
   369     by auto
   370   have "A = UNIV \<or> A = {} \<or> A = {False <..} \<or> A = {..< True}"
   371     using subset_UNIV[of A] unfolding UNIV_bool * by blast
   372   then show "open A"
   373     by auto
   374 qed
   375 
   376 instantiation nat :: linorder_topology
   377 begin
   378 
   379 definition open_nat :: "nat set \<Rightarrow> bool"
   380   where "open_nat = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   381 
   382 instance
   383   by standard (rule open_nat_def)
   384 
   385 end
   386 
   387 instance nat :: discrete_topology
   388 proof
   389   fix A :: "nat set"
   390   have "open {n}" for n :: nat
   391   proof (cases n)
   392     case 0
   393     moreover have "{0} = {..<1::nat}"
   394       by auto
   395     ultimately show ?thesis
   396        by auto
   397   next
   398     case (Suc n')
   399     then have "{n} = {..<Suc n} \<inter> {n' <..}"
   400       by auto
   401     with Suc show ?thesis
   402       by (auto intro: open_lessThan open_greaterThan)
   403   qed
   404   then have "open (\<Union>a\<in>A. {a})"
   405     by (intro open_UN) auto
   406   then show "open A"
   407     by simp
   408 qed
   409 
   410 instantiation int :: linorder_topology
   411 begin
   412 
   413 definition open_int :: "int set \<Rightarrow> bool"
   414   where "open_int = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   415 
   416 instance
   417   by standard (rule open_int_def)
   418 
   419 end
   420 
   421 instance int :: discrete_topology
   422 proof
   423   fix A :: "int set"
   424   have "{..<i + 1} \<inter> {i-1 <..} = {i}" for i :: int
   425     by auto
   426   then have "open {i}" for i :: int
   427     using open_Int[OF open_lessThan[of "i + 1"] open_greaterThan[of "i - 1"]] by auto
   428   then have "open (\<Union>a\<in>A. {a})"
   429     by (intro open_UN) auto
   430   then show "open A"
   431     by simp
   432 qed
   433 
   434 
   435 subsubsection \<open>Topological filters\<close>
   436 
   437 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   438   where "nhds a = (INF S:{S. open S \<and> a \<in> S}. principal S)"
   439 
   440 definition (in topological_space) at_within :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a filter"
   441     ("at (_)/ within (_)" [1000, 60] 60)
   442   where "at a within s = inf (nhds a) (principal (s - {a}))"
   443 
   444 abbreviation (in topological_space) at :: "'a \<Rightarrow> 'a filter"  ("at")
   445   where "at x \<equiv> at x within (CONST UNIV)"
   446 
   447 abbreviation (in order_topology) at_right :: "'a \<Rightarrow> 'a filter"
   448   where "at_right x \<equiv> at x within {x <..}"
   449 
   450 abbreviation (in order_topology) at_left :: "'a \<Rightarrow> 'a filter"
   451   where "at_left x \<equiv> at x within {..< x}"
   452 
   453 lemma (in topological_space) nhds_generated_topology:
   454   "open = generate_topology T \<Longrightarrow> nhds x = (INF S:{S\<in>T. x \<in> S}. principal S)"
   455   unfolding nhds_def
   456 proof (safe intro!: antisym INF_greatest)
   457   fix S
   458   assume "generate_topology T S" "x \<in> S"
   459   then show "(INF S:{S \<in> T. x \<in> S}. principal S) \<le> principal S"
   460     by induct
   461       (auto intro: INF_lower order_trans simp: inf_principal[symmetric] simp del: inf_principal)
   462 qed (auto intro!: INF_lower intro: generate_topology.intros)
   463 
   464 lemma (in topological_space) eventually_nhds:
   465   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   466   unfolding nhds_def by (subst eventually_INF_base) (auto simp: eventually_principal)
   467 
   468 lemma eventually_eventually:
   469   "eventually (\<lambda>y. eventually P (nhds y)) (nhds x) = eventually P (nhds x)"
   470   by (auto simp: eventually_nhds)
   471 
   472 lemma (in topological_space) eventually_nhds_in_open:
   473   "open s \<Longrightarrow> x \<in> s \<Longrightarrow> eventually (\<lambda>y. y \<in> s) (nhds x)"
   474   by (subst eventually_nhds) blast
   475 
   476 lemma (in topological_space) eventually_nhds_x_imp_x: "eventually P (nhds x) \<Longrightarrow> P x"
   477   by (subst (asm) eventually_nhds) blast
   478 
   479 lemma (in topological_space) nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   480   by (simp add: trivial_limit_def eventually_nhds)
   481 
   482 lemma (in t1_space) t1_space_nhds: "x \<noteq> y \<Longrightarrow> (\<forall>\<^sub>F x in nhds x. x \<noteq> y)"
   483   by (drule t1_space) (auto simp: eventually_nhds)
   484 
   485 lemma (in topological_space) nhds_discrete_open: "open {x} \<Longrightarrow> nhds x = principal {x}"
   486   by (auto simp: nhds_def intro!: antisym INF_greatest INF_lower2[of "{x}"])
   487 
   488 lemma (in discrete_topology) nhds_discrete: "nhds x = principal {x}"
   489   by (simp add: nhds_discrete_open open_discrete)
   490 
   491 lemma (in discrete_topology) at_discrete: "at x within S = bot"
   492   unfolding at_within_def nhds_discrete by simp
   493 
   494 lemma (in topological_space) at_within_eq:
   495   "at x within s = (INF S:{S. open S \<and> x \<in> S}. principal (S \<inter> s - {x}))"
   496   unfolding nhds_def at_within_def
   497   by (subst INF_inf_const2[symmetric]) (auto simp: Diff_Int_distrib)
   498 
   499 lemma (in topological_space) eventually_at_filter:
   500   "eventually P (at a within s) \<longleftrightarrow> eventually (\<lambda>x. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x) (nhds a)"
   501   by (simp add: at_within_def eventually_inf_principal imp_conjL[symmetric] conj_commute)
   502 
   503 lemma (in topological_space) at_le: "s \<subseteq> t \<Longrightarrow> at x within s \<le> at x within t"
   504   unfolding at_within_def by (intro inf_mono) auto
   505 
   506 lemma (in topological_space) eventually_at_topological:
   507   "eventually P (at a within s) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x))"
   508   by (simp add: eventually_nhds eventually_at_filter)
   509 
   510 lemma (in topological_space) at_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> at a within S = at a"
   511   unfolding filter_eq_iff eventually_at_topological by (metis open_Int Int_iff UNIV_I)
   512 
   513 lemma (in topological_space) at_within_open_NO_MATCH:
   514   "a \<in> s \<Longrightarrow> open s \<Longrightarrow> NO_MATCH UNIV s \<Longrightarrow> at a within s = at a"
   515   by (simp only: at_within_open)
   516 
   517 lemma (in topological_space) at_within_open_subset:
   518   "a \<in> S \<Longrightarrow> open S \<Longrightarrow> S \<subseteq> T \<Longrightarrow> at a within T = at a"
   519   by (metis at_le at_within_open dual_order.antisym subset_UNIV)
   520 
   521 lemma (in topological_space) at_within_nhd:
   522   assumes "x \<in> S" "open S" "T \<inter> S - {x} = U \<inter> S - {x}"
   523   shows "at x within T = at x within U"
   524   unfolding filter_eq_iff eventually_at_filter
   525 proof (intro allI eventually_subst)
   526   have "eventually (\<lambda>x. x \<in> S) (nhds x)"
   527     using \<open>x \<in> S\<close> \<open>open S\<close> by (auto simp: eventually_nhds)
   528   then show "\<forall>\<^sub>F n in nhds x. (n \<noteq> x \<longrightarrow> n \<in> T \<longrightarrow> P n) = (n \<noteq> x \<longrightarrow> n \<in> U \<longrightarrow> P n)" for P
   529     by eventually_elim (insert \<open>T \<inter> S - {x} = U \<inter> S - {x}\<close>, blast)
   530 qed
   531 
   532 lemma (in topological_space) at_within_empty [simp]: "at a within {} = bot"
   533   unfolding at_within_def by simp
   534 
   535 lemma (in topological_space) at_within_union:
   536   "at x within (S \<union> T) = sup (at x within S) (at x within T)"
   537   unfolding filter_eq_iff eventually_sup eventually_at_filter
   538   by (auto elim!: eventually_rev_mp)
   539 
   540 lemma (in topological_space) at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   541   unfolding trivial_limit_def eventually_at_topological
   542   apply safe
   543    apply (case_tac "S = {a}")
   544     apply simp
   545    apply fast
   546   apply fast
   547   done
   548 
   549 lemma (in perfect_space) at_neq_bot [simp]: "at a \<noteq> bot"
   550   by (simp add: at_eq_bot_iff not_open_singleton)
   551 
   552 lemma (in order_topology) nhds_order:
   553   "nhds x = inf (INF a:{x <..}. principal {..< a}) (INF a:{..< x}. principal {a <..})"
   554 proof -
   555   have 1: "{S \<in> range lessThan \<union> range greaterThan. x \<in> S} =
   556       (\<lambda>a. {..< a}) ` {x <..} \<union> (\<lambda>a. {a <..}) ` {..< x}"
   557     by auto
   558   show ?thesis
   559     by (simp only: nhds_generated_topology[OF open_generated_order] INF_union 1 INF_image comp_def)
   560 qed
   561 
   562 lemma (in topological_space) filterlim_at_within_If:
   563   assumes "filterlim f G (at x within (A \<inter> {x. P x}))"
   564     and "filterlim g G (at x within (A \<inter> {x. \<not>P x}))"
   565   shows "filterlim (\<lambda>x. if P x then f x else g x) G (at x within A)"
   566 proof (rule filterlim_If)
   567   note assms(1)
   568   also have "at x within (A \<inter> {x. P x}) = inf (nhds x) (principal (A \<inter> Collect P - {x}))"
   569     by (simp add: at_within_def)
   570   also have "A \<inter> Collect P - {x} = (A - {x}) \<inter> Collect P"
   571     by blast
   572   also have "inf (nhds x) (principal \<dots>) = inf (at x within A) (principal (Collect P))"
   573     by (simp add: at_within_def inf_assoc)
   574   finally show "filterlim f G (inf (at x within A) (principal (Collect P)))" .
   575 next
   576   note assms(2)
   577   also have "at x within (A \<inter> {x. \<not> P x}) = inf (nhds x) (principal (A \<inter> {x. \<not> P x} - {x}))"
   578     by (simp add: at_within_def)
   579   also have "A \<inter> {x. \<not> P x} - {x} = (A - {x}) \<inter> {x. \<not> P x}"
   580     by blast
   581   also have "inf (nhds x) (principal \<dots>) = inf (at x within A) (principal {x. \<not> P x})"
   582     by (simp add: at_within_def inf_assoc)
   583   finally show "filterlim g G (inf (at x within A) (principal {x. \<not> P x}))" .
   584 qed
   585 
   586 lemma (in topological_space) filterlim_at_If:
   587   assumes "filterlim f G (at x within {x. P x})"
   588     and "filterlim g G (at x within {x. \<not>P x})"
   589   shows "filterlim (\<lambda>x. if P x then f x else g x) G (at x)"
   590   using assms by (intro filterlim_at_within_If) simp_all
   591 
   592 lemma (in linorder_topology) at_within_order:
   593   assumes "UNIV \<noteq> {x}"
   594   shows "at x within s =
   595     inf (INF a:{x <..}. principal ({..< a} \<inter> s - {x}))
   596         (INF a:{..< x}. principal ({a <..} \<inter> s - {x}))"
   597 proof (cases "{x <..} = {}" "{..< x} = {}" rule: case_split [case_product case_split])
   598   case True_True
   599   have "UNIV = {..< x} \<union> {x} \<union> {x <..}"
   600     by auto
   601   with assms True_True show ?thesis
   602     by auto
   603 qed (auto simp del: inf_principal simp: at_within_def nhds_order Int_Diff
   604       inf_principal[symmetric] INF_inf_const2 inf_sup_aci[where 'a="'a filter"])
   605 
   606 lemma (in linorder_topology) at_left_eq:
   607   "y < x \<Longrightarrow> at_left x = (INF a:{..< x}. principal {a <..< x})"
   608   by (subst at_within_order)
   609      (auto simp: greaterThan_Int_greaterThan greaterThanLessThan_eq[symmetric] min.absorb2 INF_constant
   610            intro!: INF_lower2 inf_absorb2)
   611 
   612 lemma (in linorder_topology) eventually_at_left:
   613   "y < x \<Longrightarrow> eventually P (at_left x) \<longleftrightarrow> (\<exists>b<x. \<forall>y>b. y < x \<longrightarrow> P y)"
   614   unfolding at_left_eq
   615   by (subst eventually_INF_base) (auto simp: eventually_principal Ball_def)
   616 
   617 lemma (in linorder_topology) at_right_eq:
   618   "x < y \<Longrightarrow> at_right x = (INF a:{x <..}. principal {x <..< a})"
   619   by (subst at_within_order)
   620      (auto simp: lessThan_Int_lessThan greaterThanLessThan_eq[symmetric] max.absorb2 INF_constant Int_commute
   621            intro!: INF_lower2 inf_absorb1)
   622 
   623 lemma (in linorder_topology) eventually_at_right:
   624   "x < y \<Longrightarrow> eventually P (at_right x) \<longleftrightarrow> (\<exists>b>x. \<forall>y>x. y < b \<longrightarrow> P y)"
   625   unfolding at_right_eq
   626   by (subst eventually_INF_base) (auto simp: eventually_principal Ball_def)
   627 
   628 lemma eventually_at_right_less: "\<forall>\<^sub>F y in at_right (x::'a::{linorder_topology, no_top}). x < y"
   629   using gt_ex[of x] eventually_at_right[of x] by auto
   630 
   631 lemma trivial_limit_at_right_top: "at_right (top::_::{order_top,linorder_topology}) = bot"
   632   by (auto simp: filter_eq_iff eventually_at_topological)
   633 
   634 lemma trivial_limit_at_left_bot: "at_left (bot::_::{order_bot,linorder_topology}) = bot"
   635   by (auto simp: filter_eq_iff eventually_at_topological)
   636 
   637 lemma trivial_limit_at_left_real [simp]: "\<not> trivial_limit (at_left x)"
   638   for x :: "'a::{no_bot,dense_order,linorder_topology}"
   639   using lt_ex [of x]
   640   by safe (auto simp add: trivial_limit_def eventually_at_left dest: dense)
   641 
   642 lemma trivial_limit_at_right_real [simp]: "\<not> trivial_limit (at_right x)"
   643   for x :: "'a::{no_top,dense_order,linorder_topology}"
   644   using gt_ex[of x]
   645   by safe (auto simp add: trivial_limit_def eventually_at_right dest: dense)
   646 
   647 lemma (in linorder_topology) at_eq_sup_left_right: "at x = sup (at_left x) (at_right x)"
   648   by (auto simp: eventually_at_filter filter_eq_iff eventually_sup
   649       elim: eventually_elim2 eventually_mono)
   650 
   651 lemma (in linorder_topology) eventually_at_split:
   652   "eventually P (at x) \<longleftrightarrow> eventually P (at_left x) \<and> eventually P (at_right x)"
   653   by (subst at_eq_sup_left_right) (simp add: eventually_sup)
   654 
   655 lemma (in order_topology) eventually_at_leftI:
   656   assumes "\<And>x. x \<in> {a<..<b} \<Longrightarrow> P x" "a < b"
   657   shows   "eventually P (at_left b)"
   658   using assms unfolding eventually_at_topological by (intro exI[of _ "{a<..}"]) auto
   659 
   660 lemma (in order_topology) eventually_at_rightI:
   661   assumes "\<And>x. x \<in> {a<..<b} \<Longrightarrow> P x" "a < b"
   662   shows   "eventually P (at_right a)"
   663   using assms unfolding eventually_at_topological by (intro exI[of _ "{..<b}"]) auto
   664 
   665 
   666 subsubsection \<open>Tendsto\<close>
   667 
   668 abbreviation (in topological_space)
   669   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool"  (infixr "\<longlongrightarrow>" 55)
   670   where "(f \<longlongrightarrow> l) F \<equiv> filterlim f (nhds l) F"
   671 
   672 definition (in t2_space) Lim :: "'f filter \<Rightarrow> ('f \<Rightarrow> 'a) \<Rightarrow> 'a"
   673   where "Lim A f = (THE l. (f \<longlongrightarrow> l) A)"
   674 
   675 lemma (in topological_space) tendsto_eq_rhs: "(f \<longlongrightarrow> x) F \<Longrightarrow> x = y \<Longrightarrow> (f \<longlongrightarrow> y) F"
   676   by simp
   677 
   678 named_theorems tendsto_intros "introduction rules for tendsto"
   679 setup \<open>
   680   Global_Theory.add_thms_dynamic (@{binding tendsto_eq_intros},
   681     fn context =>
   682       Named_Theorems.get (Context.proof_of context) @{named_theorems tendsto_intros}
   683       |> map_filter (try (fn thm => @{thm tendsto_eq_rhs} OF [thm])))
   684 \<close>
   685 
   686 context topological_space begin
   687 
   688 lemma tendsto_def:
   689    "(f \<longlongrightarrow> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
   690    unfolding nhds_def filterlim_INF filterlim_principal by auto
   691 
   692 lemma tendsto_cong: "(f \<longlongrightarrow> c) F \<longleftrightarrow> (g \<longlongrightarrow> c) F" if "eventually (\<lambda>x. f x = g x) F"
   693   by (rule filterlim_cong [OF refl refl that])
   694 
   695 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f \<longlongrightarrow> l) F' \<Longrightarrow> (f \<longlongrightarrow> l) F"
   696   unfolding tendsto_def le_filter_def by fast
   697 
   698 lemma tendsto_ident_at [tendsto_intros, simp, intro]: "((\<lambda>x. x) \<longlongrightarrow> a) (at a within s)"
   699   by (auto simp: tendsto_def eventually_at_topological)
   700 
   701 lemma tendsto_const [tendsto_intros, simp, intro]: "((\<lambda>x. k) \<longlongrightarrow> k) F"
   702   by (simp add: tendsto_def)
   703 
   704 lemma  filterlim_at:
   705   "(LIM x F. f x :> at b within s) \<longleftrightarrow> eventually (\<lambda>x. f x \<in> s \<and> f x \<noteq> b) F \<and> (f \<longlongrightarrow> b) F"
   706   by (simp add: at_within_def filterlim_inf filterlim_principal conj_commute)
   707 
   708 lemma  filterlim_at_withinI:
   709   assumes "filterlim f (nhds c) F"
   710   assumes "eventually (\<lambda>x. f x \<in> A - {c}) F"
   711   shows   "filterlim f (at c within A) F"
   712   using assms by (simp add: filterlim_at)
   713 
   714 lemma filterlim_atI:
   715   assumes "filterlim f (nhds c) F"
   716   assumes "eventually (\<lambda>x. f x \<noteq> c) F"
   717   shows   "filterlim f (at c) F"
   718   using assms by (intro filterlim_at_withinI) simp_all
   719 
   720 lemma topological_tendstoI:
   721   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F) \<Longrightarrow> (f \<longlongrightarrow> l) F"
   722   by (auto simp: tendsto_def)
   723 
   724 lemma topological_tendstoD:
   725   "(f \<longlongrightarrow> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
   726   by (auto simp: tendsto_def)
   727 
   728 lemma tendsto_bot [simp]: "(f \<longlongrightarrow> a) bot"
   729   by (simp add: tendsto_def)
   730 
   731 end
   732 
   733 lemma tendsto_within_subset:
   734   "(f \<longlongrightarrow> l) (at x within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f \<longlongrightarrow> l) (at x within T)"
   735   by (blast intro: tendsto_mono at_le)
   736 
   737 lemma (in order_topology) order_tendsto_iff:
   738   "(f \<longlongrightarrow> x) F \<longleftrightarrow> (\<forall>l<x. eventually (\<lambda>x. l < f x) F) \<and> (\<forall>u>x. eventually (\<lambda>x. f x < u) F)"
   739   by (auto simp: nhds_order filterlim_inf filterlim_INF filterlim_principal)
   740 
   741 lemma (in order_topology) order_tendstoI:
   742   "(\<And>a. a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F) \<Longrightarrow> (\<And>a. y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F) \<Longrightarrow>
   743     (f \<longlongrightarrow> y) F"
   744   by (auto simp: order_tendsto_iff)
   745 
   746 lemma (in order_topology) order_tendstoD:
   747   assumes "(f \<longlongrightarrow> y) F"
   748   shows "a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
   749     and "y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
   750   using assms by (auto simp: order_tendsto_iff)
   751 
   752 lemma (in linorder_topology) tendsto_max:
   753   assumes X: "(X \<longlongrightarrow> x) net"
   754     and Y: "(Y \<longlongrightarrow> y) net"
   755   shows "((\<lambda>x. max (X x) (Y x)) \<longlongrightarrow> max x y) net"
   756 proof (rule order_tendstoI)
   757   fix a
   758   assume "a < max x y"
   759   then show "eventually (\<lambda>x. a < max (X x) (Y x)) net"
   760     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
   761     by (auto simp: less_max_iff_disj elim: eventually_mono)
   762 next
   763   fix a
   764   assume "max x y < a"
   765   then show "eventually (\<lambda>x. max (X x) (Y x) < a) net"
   766     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
   767     by (auto simp: eventually_conj_iff)
   768 qed
   769 
   770 lemma (in linorder_topology) tendsto_min:
   771   assumes X: "(X \<longlongrightarrow> x) net"
   772     and Y: "(Y \<longlongrightarrow> y) net"
   773   shows "((\<lambda>x. min (X x) (Y x)) \<longlongrightarrow> min x y) net"
   774 proof (rule order_tendstoI)
   775   fix a
   776   assume "a < min x y"
   777   then show "eventually (\<lambda>x. a < min (X x) (Y x)) net"
   778     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
   779     by (auto simp: eventually_conj_iff)
   780 next
   781   fix a
   782   assume "min x y < a"
   783   then show "eventually (\<lambda>x. min (X x) (Y x) < a) net"
   784     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
   785     by (auto simp: min_less_iff_disj elim: eventually_mono)
   786 qed
   787 
   788 lemma (in order_topology)
   789   assumes "a < b"
   790   shows at_within_Icc_at_right: "at a within {a..b} = at_right a"
   791     and at_within_Icc_at_left:  "at b within {a..b} = at_left b"
   792   using order_tendstoD(2)[OF tendsto_ident_at assms, of "{a<..}"]
   793   using order_tendstoD(1)[OF tendsto_ident_at assms, of "{..<b}"]
   794   by (auto intro!: order_class.antisym filter_leI
   795       simp: eventually_at_filter less_le
   796       elim: eventually_elim2)
   797 
   798 lemma (in order_topology) at_within_Icc_at: "a < x \<Longrightarrow> x < b \<Longrightarrow> at x within {a..b} = at x"
   799   by (rule at_within_open_subset[where S="{a<..<b}"]) auto
   800 
   801 lemma (in t2_space) tendsto_unique:
   802   assumes "F \<noteq> bot"
   803     and "(f \<longlongrightarrow> a) F"
   804     and "(f \<longlongrightarrow> b) F"
   805   shows "a = b"
   806 proof (rule ccontr)
   807   assume "a \<noteq> b"
   808   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
   809     using hausdorff [OF \<open>a \<noteq> b\<close>] by fast
   810   have "eventually (\<lambda>x. f x \<in> U) F"
   811     using \<open>(f \<longlongrightarrow> a) F\<close> \<open>open U\<close> \<open>a \<in> U\<close> by (rule topological_tendstoD)
   812   moreover
   813   have "eventually (\<lambda>x. f x \<in> V) F"
   814     using \<open>(f \<longlongrightarrow> b) F\<close> \<open>open V\<close> \<open>b \<in> V\<close> by (rule topological_tendstoD)
   815   ultimately
   816   have "eventually (\<lambda>x. False) F"
   817   proof eventually_elim
   818     case (elim x)
   819     then have "f x \<in> U \<inter> V" by simp
   820     with \<open>U \<inter> V = {}\<close> show ?case by simp
   821   qed
   822   with \<open>\<not> trivial_limit F\<close> show "False"
   823     by (simp add: trivial_limit_def)
   824 qed
   825 
   826 lemma (in t2_space) tendsto_const_iff:
   827   fixes a b :: 'a
   828   assumes "\<not> trivial_limit F"
   829   shows "((\<lambda>x. a) \<longlongrightarrow> b) F \<longleftrightarrow> a = b"
   830   by (auto intro!: tendsto_unique [OF assms tendsto_const])
   831 
   832 lemma (in order_topology) increasing_tendsto:
   833   assumes bdd: "eventually (\<lambda>n. f n \<le> l) F"
   834     and en: "\<And>x. x < l \<Longrightarrow> eventually (\<lambda>n. x < f n) F"
   835   shows "(f \<longlongrightarrow> l) F"
   836   using assms by (intro order_tendstoI) (auto elim!: eventually_mono)
   837 
   838 lemma (in order_topology) decreasing_tendsto:
   839   assumes bdd: "eventually (\<lambda>n. l \<le> f n) F"
   840     and en: "\<And>x. l < x \<Longrightarrow> eventually (\<lambda>n. f n < x) F"
   841   shows "(f \<longlongrightarrow> l) F"
   842   using assms by (intro order_tendstoI) (auto elim!: eventually_mono)
   843 
   844 lemma (in order_topology) tendsto_sandwich:
   845   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
   846   assumes lim: "(f \<longlongrightarrow> c) net" "(h \<longlongrightarrow> c) net"
   847   shows "(g \<longlongrightarrow> c) net"
   848 proof (rule order_tendstoI)
   849   fix a
   850   show "a < c \<Longrightarrow> eventually (\<lambda>x. a < g x) net"
   851     using order_tendstoD[OF lim(1), of a] ev by (auto elim: eventually_elim2)
   852 next
   853   fix a
   854   show "c < a \<Longrightarrow> eventually (\<lambda>x. g x < a) net"
   855     using order_tendstoD[OF lim(2), of a] ev by (auto elim: eventually_elim2)
   856 qed
   857 
   858 lemma (in t1_space) limit_frequently_eq:
   859   assumes "F \<noteq> bot"
   860     and "frequently (\<lambda>x. f x = c) F"
   861     and "(f \<longlongrightarrow> d) F"
   862   shows "d = c"
   863 proof (rule ccontr)
   864   assume "d \<noteq> c"
   865   from t1_space[OF this] obtain U where "open U" "d \<in> U" "c \<notin> U"
   866     by blast
   867   with assms have "eventually (\<lambda>x. f x \<in> U) F"
   868     unfolding tendsto_def by blast
   869   then have "eventually (\<lambda>x. f x \<noteq> c) F"
   870     by eventually_elim (insert \<open>c \<notin> U\<close>, blast)
   871   with assms(2) show False
   872     unfolding frequently_def by contradiction
   873 qed
   874 
   875 lemma (in t1_space) tendsto_imp_eventually_ne:
   876   assumes  "(f \<longlongrightarrow> c) F" "c \<noteq> c'"
   877   shows "eventually (\<lambda>z. f z \<noteq> c') F"
   878 proof (cases "F=bot")
   879   case True
   880   thus ?thesis by auto
   881 next
   882   case False
   883   show ?thesis
   884   proof (rule ccontr)
   885     assume "\<not> eventually (\<lambda>z. f z \<noteq> c') F"
   886     then have "frequently (\<lambda>z. f z = c') F"
   887       by (simp add: frequently_def)
   888     from limit_frequently_eq[OF False this \<open>(f \<longlongrightarrow> c) F\<close>] and \<open>c \<noteq> c'\<close> show False
   889       by contradiction
   890   qed
   891 qed
   892 
   893 lemma (in linorder_topology) tendsto_le:
   894   assumes F: "\<not> trivial_limit F"
   895     and x: "(f \<longlongrightarrow> x) F"
   896     and y: "(g \<longlongrightarrow> y) F"
   897     and ev: "eventually (\<lambda>x. g x \<le> f x) F"
   898   shows "y \<le> x"
   899 proof (rule ccontr)
   900   assume "\<not> y \<le> x"
   901   with less_separate[of x y] obtain a b where xy: "x < a" "b < y" "{..<a} \<inter> {b<..} = {}"
   902     by (auto simp: not_le)
   903   then have "eventually (\<lambda>x. f x < a) F" "eventually (\<lambda>x. b < g x) F"
   904     using x y by (auto intro: order_tendstoD)
   905   with ev have "eventually (\<lambda>x. False) F"
   906     by eventually_elim (insert xy, fastforce)
   907   with F show False
   908     by (simp add: eventually_False)
   909 qed
   910 
   911 lemma (in linorder_topology) tendsto_lowerbound:
   912   assumes x: "(f \<longlongrightarrow> x) F"
   913       and ev: "eventually (\<lambda>i. a \<le> f i) F"
   914       and F: "\<not> trivial_limit F"
   915   shows "a \<le> x"
   916   using F x tendsto_const ev by (rule tendsto_le)
   917 
   918 lemma (in linorder_topology) tendsto_upperbound:
   919   assumes x: "(f \<longlongrightarrow> x) F"
   920       and ev: "eventually (\<lambda>i. a \<ge> f i) F"
   921       and F: "\<not> trivial_limit F"
   922   shows "a \<ge> x"
   923   by (rule tendsto_le [OF F tendsto_const x ev])
   924 
   925 
   926 subsubsection \<open>Rules about @{const Lim}\<close>
   927 
   928 lemma tendsto_Lim: "\<not> trivial_limit net \<Longrightarrow> (f \<longlongrightarrow> l) net \<Longrightarrow> Lim net f = l"
   929   unfolding Lim_def using tendsto_unique [of net f] by auto
   930 
   931 lemma Lim_ident_at: "\<not> trivial_limit (at x within s) \<Longrightarrow> Lim (at x within s) (\<lambda>x. x) = x"
   932   by (rule tendsto_Lim[OF _ tendsto_ident_at]) auto
   933 
   934 lemma filterlim_at_bot_at_right:
   935   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
   936   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   937     and bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
   938     and Q: "eventually Q (at_right a)"
   939     and bound: "\<And>b. Q b \<Longrightarrow> a < b"
   940     and P: "eventually P at_bot"
   941   shows "filterlim f at_bot (at_right a)"
   942 proof -
   943   from P obtain x where x: "\<And>y. y \<le> x \<Longrightarrow> P y"
   944     unfolding eventually_at_bot_linorder by auto
   945   show ?thesis
   946   proof (intro filterlim_at_bot_le[THEN iffD2] allI impI)
   947     fix z
   948     assume "z \<le> x"
   949     with x have "P z" by auto
   950     have "eventually (\<lambda>x. x \<le> g z) (at_right a)"
   951       using bound[OF bij(2)[OF \<open>P z\<close>]]
   952       unfolding eventually_at_right[OF bound[OF bij(2)[OF \<open>P z\<close>]]]
   953       by (auto intro!: exI[of _ "g z"])
   954     with Q show "eventually (\<lambda>x. f x \<le> z) (at_right a)"
   955       by eventually_elim (metis bij \<open>P z\<close> mono)
   956   qed
   957 qed
   958 
   959 lemma filterlim_at_top_at_left:
   960   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
   961   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   962     and bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
   963     and Q: "eventually Q (at_left a)"
   964     and bound: "\<And>b. Q b \<Longrightarrow> b < a"
   965     and P: "eventually P at_top"
   966   shows "filterlim f at_top (at_left a)"
   967 proof -
   968   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
   969     unfolding eventually_at_top_linorder by auto
   970   show ?thesis
   971   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
   972     fix z
   973     assume "x \<le> z"
   974     with x have "P z" by auto
   975     have "eventually (\<lambda>x. g z \<le> x) (at_left a)"
   976       using bound[OF bij(2)[OF \<open>P z\<close>]]
   977       unfolding eventually_at_left[OF bound[OF bij(2)[OF \<open>P z\<close>]]]
   978       by (auto intro!: exI[of _ "g z"])
   979     with Q show "eventually (\<lambda>x. z \<le> f x) (at_left a)"
   980       by eventually_elim (metis bij \<open>P z\<close> mono)
   981   qed
   982 qed
   983 
   984 lemma filterlim_split_at:
   985   "filterlim f F (at_left x) \<Longrightarrow> filterlim f F (at_right x) \<Longrightarrow>
   986     filterlim f F (at x)"
   987   for x :: "'a::linorder_topology"
   988   by (subst at_eq_sup_left_right) (rule filterlim_sup)
   989 
   990 lemma filterlim_at_split:
   991   "filterlim f F (at x) \<longleftrightarrow> filterlim f F (at_left x) \<and> filterlim f F (at_right x)"
   992   for x :: "'a::linorder_topology"
   993   by (subst at_eq_sup_left_right) (simp add: filterlim_def filtermap_sup)
   994 
   995 lemma eventually_nhds_top:
   996   fixes P :: "'a :: {order_top,linorder_topology} \<Rightarrow> bool"
   997     and b :: 'a
   998   assumes "b < top"
   999   shows "eventually P (nhds top) \<longleftrightarrow> (\<exists>b<top. (\<forall>z. b < z \<longrightarrow> P z))"
  1000   unfolding eventually_nhds
  1001 proof safe
  1002   fix S :: "'a set"
  1003   assume "open S" "top \<in> S"
  1004   note open_left[OF this \<open>b < top\<close>]
  1005   moreover assume "\<forall>s\<in>S. P s"
  1006   ultimately show "\<exists>b<top. \<forall>z>b. P z"
  1007     by (auto simp: subset_eq Ball_def)
  1008 next
  1009   fix b
  1010   assume "b < top" "\<forall>z>b. P z"
  1011   then show "\<exists>S. open S \<and> top \<in> S \<and> (\<forall>xa\<in>S. P xa)"
  1012     by (intro exI[of _ "{b <..}"]) auto
  1013 qed
  1014 
  1015 lemma tendsto_at_within_iff_tendsto_nhds:
  1016   "(g \<longlongrightarrow> g l) (at l within S) \<longleftrightarrow> (g \<longlongrightarrow> g l) (inf (nhds l) (principal S))"
  1017   unfolding tendsto_def eventually_at_filter eventually_inf_principal
  1018   by (intro ext all_cong imp_cong) (auto elim!: eventually_mono)
  1019 
  1020 
  1021 subsection \<open>Limits on sequences\<close>
  1022 
  1023 abbreviation (in topological_space)
  1024   LIMSEQ :: "[nat \<Rightarrow> 'a, 'a] \<Rightarrow> bool"  ("((_)/ \<longlonglongrightarrow> (_))" [60, 60] 60)
  1025   where "X \<longlonglongrightarrow> L \<equiv> (X \<longlongrightarrow> L) sequentially"
  1026 
  1027 abbreviation (in t2_space) lim :: "(nat \<Rightarrow> 'a) \<Rightarrow> 'a"
  1028   where "lim X \<equiv> Lim sequentially X"
  1029 
  1030 definition (in topological_space) convergent :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool"
  1031   where "convergent X = (\<exists>L. X \<longlonglongrightarrow> L)"
  1032 
  1033 lemma lim_def: "lim X = (THE L. X \<longlonglongrightarrow> L)"
  1034   unfolding Lim_def ..
  1035 
  1036 
  1037 subsubsection \<open>Monotone sequences and subsequences\<close>
  1038 
  1039 text \<open>
  1040   Definition of monotonicity.
  1041   The use of disjunction here complicates proofs considerably.
  1042   One alternative is to add a Boolean argument to indicate the direction.
  1043   Another is to develop the notions of increasing and decreasing first.
  1044 \<close>
  1045 definition monoseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool"
  1046   where "monoseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X m \<le> X n) \<or> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
  1047 
  1048 abbreviation incseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool"
  1049   where "incseq X \<equiv> mono X"
  1050 
  1051 lemma incseq_def: "incseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<ge> X m)"
  1052   unfolding mono_def ..
  1053 
  1054 abbreviation decseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool"
  1055   where "decseq X \<equiv> antimono X"
  1056 
  1057 lemma decseq_def: "decseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
  1058   unfolding antimono_def ..
  1059 
  1060 text \<open>Definition of subsequence.\<close>
  1061 definition subseq :: "(nat \<Rightarrow> nat) \<Rightarrow> bool"
  1062   where "subseq f \<longleftrightarrow> (\<forall>m. \<forall>n>m. f m < f n)"
  1063 
  1064 lemma subseq_le_mono: "subseq r \<Longrightarrow> m \<le> n \<Longrightarrow> r m \<le> r n"
  1065   by (simp add: less_mono_imp_le_mono subseq_def)
  1066 
  1067 lemma subseq_id: "subseq id"
  1068   by (simp add: subseq_def)
  1069 
  1070 lemma incseq_SucI: "(\<And>n. X n \<le> X (Suc n)) \<Longrightarrow> incseq X"
  1071   using lift_Suc_mono_le[of X] by (auto simp: incseq_def)
  1072 
  1073 lemma incseqD: "incseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f i \<le> f j"
  1074   by (auto simp: incseq_def)
  1075 
  1076 lemma incseq_SucD: "incseq A \<Longrightarrow> A i \<le> A (Suc i)"
  1077   using incseqD[of A i "Suc i"] by auto
  1078 
  1079 lemma incseq_Suc_iff: "incseq f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1080   by (auto intro: incseq_SucI dest: incseq_SucD)
  1081 
  1082 lemma incseq_const[simp, intro]: "incseq (\<lambda>x. k)"
  1083   unfolding incseq_def by auto
  1084 
  1085 lemma decseq_SucI: "(\<And>n. X (Suc n) \<le> X n) \<Longrightarrow> decseq X"
  1086   using order.lift_Suc_mono_le[OF dual_order, of X] by (auto simp: decseq_def)
  1087 
  1088 lemma decseqD: "decseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f j \<le> f i"
  1089   by (auto simp: decseq_def)
  1090 
  1091 lemma decseq_SucD: "decseq A \<Longrightarrow> A (Suc i) \<le> A i"
  1092   using decseqD[of A i "Suc i"] by auto
  1093 
  1094 lemma decseq_Suc_iff: "decseq f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1095   by (auto intro: decseq_SucI dest: decseq_SucD)
  1096 
  1097 lemma decseq_const[simp, intro]: "decseq (\<lambda>x. k)"
  1098   unfolding decseq_def by auto
  1099 
  1100 lemma monoseq_iff: "monoseq X \<longleftrightarrow> incseq X \<or> decseq X"
  1101   unfolding monoseq_def incseq_def decseq_def ..
  1102 
  1103 lemma monoseq_Suc: "monoseq X \<longleftrightarrow> (\<forall>n. X n \<le> X (Suc n)) \<or> (\<forall>n. X (Suc n) \<le> X n)"
  1104   unfolding monoseq_iff incseq_Suc_iff decseq_Suc_iff ..
  1105 
  1106 lemma monoI1: "\<forall>m. \<forall>n \<ge> m. X m \<le> X n \<Longrightarrow> monoseq X"
  1107   by (simp add: monoseq_def)
  1108 
  1109 lemma monoI2: "\<forall>m. \<forall>n \<ge> m. X n \<le> X m \<Longrightarrow> monoseq X"
  1110   by (simp add: monoseq_def)
  1111 
  1112 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) \<Longrightarrow> monoseq X"
  1113   by (simp add: monoseq_Suc)
  1114 
  1115 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n \<Longrightarrow> monoseq X"
  1116   by (simp add: monoseq_Suc)
  1117 
  1118 lemma monoseq_minus:
  1119   fixes a :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
  1120   assumes "monoseq a"
  1121   shows "monoseq (\<lambda> n. - a n)"
  1122 proof (cases "\<forall>m. \<forall>n \<ge> m. a m \<le> a n")
  1123   case True
  1124   then have "\<forall>m. \<forall>n \<ge> m. - a n \<le> - a m" by auto
  1125   then show ?thesis by (rule monoI2)
  1126 next
  1127   case False
  1128   then have "\<forall>m. \<forall>n \<ge> m. - a m \<le> - a n"
  1129     using \<open>monoseq a\<close>[unfolded monoseq_def] by auto
  1130   then show ?thesis by (rule monoI1)
  1131 qed
  1132 
  1133 
  1134 text \<open>Subsequence (alternative definition, (e.g. Hoskins)\<close>
  1135 
  1136 lemma subseq_Suc_iff: "subseq f \<longleftrightarrow> (\<forall>n. f n < f (Suc n))"
  1137   apply (simp add: subseq_def)
  1138   apply (auto dest!: less_imp_Suc_add)
  1139   apply (induct_tac k)
  1140    apply (auto intro: less_trans)
  1141   done
  1142 
  1143 lemma subseq_add: "subseq (\<lambda>n. n + k)"
  1144   by (auto simp: subseq_Suc_iff)
  1145 
  1146 text \<open>For any sequence, there is a monotonic subsequence.\<close>
  1147 lemma seq_monosub:
  1148   fixes s :: "nat \<Rightarrow> 'a::linorder"
  1149   shows "\<exists>f. subseq f \<and> monoseq (\<lambda>n. (s (f n)))"
  1150 proof (cases "\<forall>n. \<exists>p>n. \<forall>m\<ge>p. s m \<le> s p")
  1151   case True
  1152   then have "\<exists>f. \<forall>n. (\<forall>m\<ge>f n. s m \<le> s (f n)) \<and> f n < f (Suc n)"
  1153     by (intro dependent_nat_choice) (auto simp: conj_commute)
  1154   then obtain f where f: "subseq f" and mono: "\<And>n m. f n \<le> m \<Longrightarrow> s m \<le> s (f n)"
  1155     by (auto simp: subseq_Suc_iff)
  1156   then have "incseq f"
  1157     unfolding subseq_Suc_iff incseq_Suc_iff by (auto intro: less_imp_le)
  1158   then have "monoseq (\<lambda>n. s (f n))"
  1159     by (auto simp add: incseq_def intro!: mono monoI2)
  1160   with f show ?thesis
  1161     by auto
  1162 next
  1163   case False
  1164   then obtain N where N: "p > N \<Longrightarrow> \<exists>m>p. s p < s m" for p
  1165     by (force simp: not_le le_less)
  1166   have "\<exists>f. \<forall>n. N < f n \<and> f n < f (Suc n) \<and> s (f n) \<le> s (f (Suc n))"
  1167   proof (intro dependent_nat_choice)
  1168     fix x
  1169     assume "N < x" with N[of x]
  1170     show "\<exists>y>N. x < y \<and> s x \<le> s y"
  1171       by (auto intro: less_trans)
  1172   qed auto
  1173   then show ?thesis
  1174     by (auto simp: monoseq_iff incseq_Suc_iff subseq_Suc_iff)
  1175 qed
  1176 
  1177 lemma seq_suble:
  1178   assumes sf: "subseq f"
  1179   shows "n \<le> f n"
  1180 proof (induct n)
  1181   case 0
  1182   show ?case by simp
  1183 next
  1184   case (Suc n)
  1185   with sf [unfolded subseq_Suc_iff, rule_format, of n] have "n < f (Suc n)"
  1186      by arith
  1187   then show ?case by arith
  1188 qed
  1189 
  1190 lemma eventually_subseq:
  1191   "subseq r \<Longrightarrow> eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  1192   unfolding eventually_sequentially by (metis seq_suble le_trans)
  1193 
  1194 lemma not_eventually_sequentiallyD:
  1195   assumes "\<not> eventually P sequentially"
  1196   shows "\<exists>r. subseq r \<and> (\<forall>n. \<not> P (r n))"
  1197 proof -
  1198   from assms have "\<forall>n. \<exists>m\<ge>n. \<not> P m"
  1199     unfolding eventually_sequentially by (simp add: not_less)
  1200   then obtain r where "\<And>n. r n \<ge> n" "\<And>n. \<not> P (r n)"
  1201     by (auto simp: choice_iff)
  1202   then show ?thesis
  1203     by (auto intro!: exI[of _ "\<lambda>n. r (((Suc \<circ> r) ^^ Suc n) 0)"]
  1204              simp: less_eq_Suc_le subseq_Suc_iff)
  1205 qed
  1206 
  1207 lemma filterlim_subseq: "subseq f \<Longrightarrow> filterlim f sequentially sequentially"
  1208   unfolding filterlim_iff by (metis eventually_subseq)
  1209 
  1210 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  1211   unfolding subseq_def by simp
  1212 
  1213 lemma subseq_mono: "subseq r \<Longrightarrow> m < n \<Longrightarrow> r m < r n"
  1214   by (auto simp: subseq_def)
  1215 
  1216 lemma subseq_imp_inj_on: "subseq g \<Longrightarrow> inj_on g A"
  1217 proof (rule inj_onI)
  1218   assume g: "subseq g"
  1219   fix x y
  1220   assume "g x = g y"
  1221   with subseq_mono[OF g, of x y] subseq_mono[OF g, of y x] show "x = y"
  1222     by (cases x y rule: linorder_cases) simp_all
  1223 qed
  1224 
  1225 lemma subseq_strict_mono: "subseq g \<Longrightarrow> strict_mono g"
  1226   by (intro strict_monoI subseq_mono[of g])
  1227 
  1228 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
  1229   by (simp add: incseq_def monoseq_def)
  1230 
  1231 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
  1232   by (simp add: decseq_def monoseq_def)
  1233 
  1234 lemma decseq_eq_incseq: "decseq X = incseq (\<lambda>n. - X n)"
  1235   for X :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
  1236   by (simp add: decseq_def incseq_def)
  1237 
  1238 lemma INT_decseq_offset:
  1239   assumes "decseq F"
  1240   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
  1241 proof safe
  1242   fix x i
  1243   assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
  1244   show "x \<in> F i"
  1245   proof cases
  1246     from x have "x \<in> F n" by auto
  1247     also assume "i \<le> n" with \<open>decseq F\<close> have "F n \<subseteq> F i"
  1248       unfolding decseq_def by simp
  1249     finally show ?thesis .
  1250   qed (insert x, simp)
  1251 qed auto
  1252 
  1253 lemma LIMSEQ_const_iff: "(\<lambda>n. k) \<longlonglongrightarrow> l \<longleftrightarrow> k = l"
  1254   for k l :: "'a::t2_space"
  1255   using trivial_limit_sequentially by (rule tendsto_const_iff)
  1256 
  1257 lemma LIMSEQ_SUP: "incseq X \<Longrightarrow> X \<longlonglongrightarrow> (SUP i. X i :: 'a::{complete_linorder,linorder_topology})"
  1258   by (intro increasing_tendsto)
  1259     (auto simp: SUP_upper less_SUP_iff incseq_def eventually_sequentially intro: less_le_trans)
  1260 
  1261 lemma LIMSEQ_INF: "decseq X \<Longrightarrow> X \<longlonglongrightarrow> (INF i. X i :: 'a::{complete_linorder,linorder_topology})"
  1262   by (intro decreasing_tendsto)
  1263     (auto simp: INF_lower INF_less_iff decseq_def eventually_sequentially intro: le_less_trans)
  1264 
  1265 lemma LIMSEQ_ignore_initial_segment: "f \<longlonglongrightarrow> a \<Longrightarrow> (\<lambda>n. f (n + k)) \<longlonglongrightarrow> a"
  1266   unfolding tendsto_def by (subst eventually_sequentially_seg[where k=k])
  1267 
  1268 lemma LIMSEQ_offset: "(\<lambda>n. f (n + k)) \<longlonglongrightarrow> a \<Longrightarrow> f \<longlonglongrightarrow> a"
  1269   unfolding tendsto_def
  1270   by (subst (asm) eventually_sequentially_seg[where k=k])
  1271 
  1272 lemma LIMSEQ_Suc: "f \<longlonglongrightarrow> l \<Longrightarrow> (\<lambda>n. f (Suc n)) \<longlonglongrightarrow> l"
  1273   by (drule LIMSEQ_ignore_initial_segment [where k="Suc 0"]) simp
  1274 
  1275 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) \<longlonglongrightarrow> l \<Longrightarrow> f \<longlonglongrightarrow> l"
  1276   by (rule LIMSEQ_offset [where k="Suc 0"]) simp
  1277 
  1278 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) \<longlonglongrightarrow> l = f \<longlonglongrightarrow> l"
  1279   by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
  1280 
  1281 lemma LIMSEQ_unique: "X \<longlonglongrightarrow> a \<Longrightarrow> X \<longlonglongrightarrow> b \<Longrightarrow> a = b"
  1282   for a b :: "'a::t2_space"
  1283   using trivial_limit_sequentially by (rule tendsto_unique)
  1284 
  1285 lemma LIMSEQ_le_const: "X \<longlonglongrightarrow> x \<Longrightarrow> \<exists>N. \<forall>n\<ge>N. a \<le> X n \<Longrightarrow> a \<le> x"
  1286   for a x :: "'a::linorder_topology"
  1287   by (simp add: eventually_at_top_linorder tendsto_lowerbound)
  1288 
  1289 lemma LIMSEQ_le: "X \<longlonglongrightarrow> x \<Longrightarrow> Y \<longlonglongrightarrow> y \<Longrightarrow> \<exists>N. \<forall>n\<ge>N. X n \<le> Y n \<Longrightarrow> x \<le> y"
  1290   for x y :: "'a::linorder_topology"
  1291   using tendsto_le[of sequentially Y y X x] by (simp add: eventually_sequentially)
  1292 
  1293 lemma LIMSEQ_le_const2: "X \<longlonglongrightarrow> x \<Longrightarrow> \<exists>N. \<forall>n\<ge>N. X n \<le> a \<Longrightarrow> x \<le> a"
  1294   for a x :: "'a::linorder_topology"
  1295   by (rule LIMSEQ_le[of X x "\<lambda>n. a"]) auto
  1296 
  1297 lemma convergentD: "convergent X \<Longrightarrow> \<exists>L. X \<longlonglongrightarrow> L"
  1298   by (simp add: convergent_def)
  1299 
  1300 lemma convergentI: "X \<longlonglongrightarrow> L \<Longrightarrow> convergent X"
  1301   by (auto simp add: convergent_def)
  1302 
  1303 lemma convergent_LIMSEQ_iff: "convergent X \<longleftrightarrow> X \<longlonglongrightarrow> lim X"
  1304   by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
  1305 
  1306 lemma convergent_const: "convergent (\<lambda>n. c)"
  1307   by (rule convergentI) (rule tendsto_const)
  1308 
  1309 lemma monoseq_le:
  1310   "monoseq a \<Longrightarrow> a \<longlonglongrightarrow> x \<Longrightarrow>
  1311     (\<forall>n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n) \<or>
  1312     (\<forall>n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m)"
  1313   for x :: "'a::linorder_topology"
  1314   by (metis LIMSEQ_le_const LIMSEQ_le_const2 decseq_def incseq_def monoseq_iff)
  1315 
  1316 lemma LIMSEQ_subseq_LIMSEQ: "X \<longlonglongrightarrow> L \<Longrightarrow> subseq f \<Longrightarrow> (X \<circ> f) \<longlonglongrightarrow> L"
  1317   unfolding comp_def by (rule filterlim_compose [of X, OF _ filterlim_subseq])
  1318 
  1319 lemma convergent_subseq_convergent: "convergent X \<Longrightarrow> subseq f \<Longrightarrow> convergent (X \<circ> f)"
  1320   by (auto simp: convergent_def intro: LIMSEQ_subseq_LIMSEQ)
  1321 
  1322 lemma limI: "X \<longlonglongrightarrow> L \<Longrightarrow> lim X = L"
  1323   by (rule tendsto_Lim) (rule trivial_limit_sequentially)
  1324 
  1325 lemma lim_le: "convergent f \<Longrightarrow> (\<And>n. f n \<le> x) \<Longrightarrow> lim f \<le> x"
  1326   for x :: "'a::linorder_topology"
  1327   using LIMSEQ_le_const2[of f "lim f" x] by (simp add: convergent_LIMSEQ_iff)
  1328 
  1329 lemma lim_const [simp]: "lim (\<lambda>m. a) = a"
  1330   by (simp add: limI)
  1331 
  1332 
  1333 subsubsection \<open>Increasing and Decreasing Series\<close>
  1334 
  1335 lemma incseq_le: "incseq X \<Longrightarrow> X \<longlonglongrightarrow> L \<Longrightarrow> X n \<le> L"
  1336   for L :: "'a::linorder_topology"
  1337   by (metis incseq_def LIMSEQ_le_const)
  1338 
  1339 lemma decseq_le: "decseq X \<Longrightarrow> X \<longlonglongrightarrow> L \<Longrightarrow> L \<le> X n"
  1340   for L :: "'a::linorder_topology"
  1341   by (metis decseq_def LIMSEQ_le_const2)
  1342 
  1343 
  1344 subsection \<open>First countable topologies\<close>
  1345 
  1346 class first_countable_topology = topological_space +
  1347   assumes first_countable_basis:
  1348     "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1349 
  1350 lemma (in first_countable_topology) countable_basis_at_decseq:
  1351   obtains A :: "nat \<Rightarrow> 'a set" where
  1352     "\<And>i. open (A i)" "\<And>i. x \<in> (A i)"
  1353     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1354 proof atomize_elim
  1355   from first_countable_basis[of x] obtain A :: "nat \<Rightarrow> 'a set"
  1356     where nhds: "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1357       and incl: "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"
  1358     by auto
  1359   define F where "F n = (\<Inter>i\<le>n. A i)" for n
  1360   show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and>
  1361     (\<forall>S. open S \<longrightarrow> x \<in> S \<longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially)"
  1362   proof (safe intro!: exI[of _ F])
  1363     fix i
  1364     show "open (F i)"
  1365       using nhds(1) by (auto simp: F_def)
  1366     show "x \<in> F i"
  1367       using nhds(2) by (auto simp: F_def)
  1368   next
  1369     fix S
  1370     assume "open S" "x \<in> S"
  1371     from incl[OF this] obtain i where "F i \<subseteq> S"
  1372       unfolding F_def by auto
  1373     moreover have "\<And>j. i \<le> j \<Longrightarrow> F j \<subseteq> F i"
  1374       by (simp add: Inf_superset_mono F_def image_mono)
  1375     ultimately show "eventually (\<lambda>i. F i \<subseteq> S) sequentially"
  1376       by (auto simp: eventually_sequentially)
  1377   qed
  1378 qed
  1379 
  1380 lemma (in first_countable_topology) nhds_countable:
  1381   obtains X :: "nat \<Rightarrow> 'a set"
  1382   where "decseq X" "\<And>n. open (X n)" "\<And>n. x \<in> X n" "nhds x = (INF n. principal (X n))"
  1383 proof -
  1384   from first_countable_basis obtain A :: "nat \<Rightarrow> 'a set"
  1385     where *: "\<And>n. x \<in> A n" "\<And>n. open (A n)" "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"
  1386     by metis
  1387   show thesis
  1388   proof
  1389     show "decseq (\<lambda>n. \<Inter>i\<le>n. A i)"
  1390       by (simp add: antimono_iff_le_Suc atMost_Suc)
  1391     show "x \<in> (\<Inter>i\<le>n. A i)" "\<And>n. open (\<Inter>i\<le>n. A i)" for n
  1392       using * by auto
  1393     show "nhds x = (INF n. principal (\<Inter>i\<le>n. A i))"
  1394       using *
  1395       unfolding nhds_def
  1396       apply -
  1397       apply (rule INF_eq)
  1398        apply simp_all
  1399        apply fastforce
  1400       apply (intro exI [of _ "\<Inter>i\<le>n. A i" for n] conjI open_INT)
  1401          apply auto
  1402       done
  1403   qed
  1404 qed
  1405 
  1406 lemma (in first_countable_topology) countable_basis:
  1407   obtains A :: "nat \<Rightarrow> 'a set" where
  1408     "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1409     "\<And>F. (\<forall>n. F n \<in> A n) \<Longrightarrow> F \<longlonglongrightarrow> x"
  1410 proof atomize_elim
  1411   obtain A :: "nat \<Rightarrow> 'a set" where *:
  1412     "\<And>i. open (A i)"
  1413     "\<And>i. x \<in> A i"
  1414     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1415     by (rule countable_basis_at_decseq) blast
  1416   have "eventually (\<lambda>n. F n \<in> S) sequentially"
  1417     if "\<forall>n. F n \<in> A n" "open S" "x \<in> S" for F S
  1418     using *(3)[of S] that by (auto elim: eventually_mono simp: subset_eq)
  1419   with * show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and> (\<forall>F. (\<forall>n. F n \<in> A n) \<longrightarrow> F \<longlonglongrightarrow> x)"
  1420     by (intro exI[of _ A]) (auto simp: tendsto_def)
  1421 qed
  1422 
  1423 lemma (in first_countable_topology) sequentially_imp_eventually_nhds_within:
  1424   assumes "\<forall>f. (\<forall>n. f n \<in> s) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1425   shows "eventually P (inf (nhds a) (principal s))"
  1426 proof (rule ccontr)
  1427   obtain A :: "nat \<Rightarrow> 'a set" where *:
  1428     "\<And>i. open (A i)"
  1429     "\<And>i. a \<in> A i"
  1430     "\<And>F. \<forall>n. F n \<in> A n \<Longrightarrow> F \<longlonglongrightarrow> a"
  1431     by (rule countable_basis) blast
  1432   assume "\<not> ?thesis"
  1433   with * have "\<exists>F. \<forall>n. F n \<in> s \<and> F n \<in> A n \<and> \<not> P (F n)"
  1434     unfolding eventually_inf_principal eventually_nhds
  1435     by (intro choice) fastforce
  1436   then obtain F where F: "\<forall>n. F n \<in> s" and "\<forall>n. F n \<in> A n" and F': "\<forall>n. \<not> P (F n)"
  1437     by blast
  1438   with * have "F \<longlonglongrightarrow> a"
  1439     by auto
  1440   then have "eventually (\<lambda>n. P (F n)) sequentially"
  1441     using assms F by simp
  1442   then show False
  1443     by (simp add: F')
  1444 qed
  1445 
  1446 lemma (in first_countable_topology) eventually_nhds_within_iff_sequentially:
  1447   "eventually P (inf (nhds a) (principal s)) \<longleftrightarrow>
  1448     (\<forall>f. (\<forall>n. f n \<in> s) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1449 proof (safe intro!: sequentially_imp_eventually_nhds_within)
  1450   assume "eventually P (inf (nhds a) (principal s))"
  1451   then obtain S where "open S" "a \<in> S" "\<forall>x\<in>S. x \<in> s \<longrightarrow> P x"
  1452     by (auto simp: eventually_inf_principal eventually_nhds)
  1453   moreover
  1454   fix f
  1455   assume "\<forall>n. f n \<in> s" "f \<longlonglongrightarrow> a"
  1456   ultimately show "eventually (\<lambda>n. P (f n)) sequentially"
  1457     by (auto dest!: topological_tendstoD elim: eventually_mono)
  1458 qed
  1459 
  1460 lemma (in first_countable_topology) eventually_nhds_iff_sequentially:
  1461   "eventually P (nhds a) \<longleftrightarrow> (\<forall>f. f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1462   using eventually_nhds_within_iff_sequentially[of P a UNIV] by simp
  1463 
  1464 lemma tendsto_at_iff_sequentially:
  1465   "(f \<longlongrightarrow> a) (at x within s) \<longleftrightarrow> (\<forall>X. (\<forall>i. X i \<in> s - {x}) \<longrightarrow> X \<longlonglongrightarrow> x \<longrightarrow> ((f \<circ> X) \<longlonglongrightarrow> a))"
  1466   for f :: "'a::first_countable_topology \<Rightarrow> _"
  1467   unfolding filterlim_def[of _ "nhds a"] le_filter_def eventually_filtermap
  1468     at_within_def eventually_nhds_within_iff_sequentially comp_def
  1469   by metis
  1470 
  1471 lemma approx_from_above_dense_linorder:
  1472   fixes x::"'a::{dense_linorder, linorder_topology, first_countable_topology}"
  1473   assumes "x < y"
  1474   shows "\<exists>u. (\<forall>n. u n > x) \<and> (u \<longlonglongrightarrow> x)"
  1475 proof -
  1476   obtain A :: "nat \<Rightarrow> 'a set" where A: "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1477                                       "\<And>F. (\<forall>n. F n \<in> A n) \<Longrightarrow> F \<longlonglongrightarrow> x"
  1478     by (metis first_countable_topology_class.countable_basis)
  1479   define u where "u = (\<lambda>n. SOME z. z \<in> A n \<and> z > x)"
  1480   have "\<exists>z. z \<in> U \<and> x < z" if "x \<in> U" "open U" for U
  1481     using open_right[OF `open U` `x \<in> U` `x < y`]
  1482     by (meson atLeastLessThan_iff dense less_imp_le subset_eq)
  1483   then have *: "u n \<in> A n \<and> x < u n" for n
  1484     using `x \<in> A n` `open (A n)` unfolding u_def by (metis (no_types, lifting) someI_ex)
  1485   then have "u \<longlonglongrightarrow> x" using A(3) by simp
  1486   then show ?thesis using * by auto
  1487 qed
  1488 
  1489 lemma approx_from_below_dense_linorder:
  1490   fixes x::"'a::{dense_linorder, linorder_topology, first_countable_topology}"
  1491   assumes "x > y"
  1492   shows "\<exists>u. (\<forall>n. u n < x) \<and> (u \<longlonglongrightarrow> x)"
  1493 proof -
  1494   obtain A :: "nat \<Rightarrow> 'a set" where A: "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1495                                       "\<And>F. (\<forall>n. F n \<in> A n) \<Longrightarrow> F \<longlonglongrightarrow> x"
  1496     by (metis first_countable_topology_class.countable_basis)
  1497   define u where "u = (\<lambda>n. SOME z. z \<in> A n \<and> z < x)"
  1498   have "\<exists>z. z \<in> U \<and> z < x" if "x \<in> U" "open U" for U
  1499     using open_left[OF `open U` `x \<in> U` `x > y`]
  1500     by (meson dense greaterThanAtMost_iff less_imp_le subset_eq)
  1501   then have *: "u n \<in> A n \<and> u n < x" for n
  1502     using `x \<in> A n` `open (A n)` unfolding u_def by (metis (no_types, lifting) someI_ex)
  1503   then have "u \<longlonglongrightarrow> x" using A(3) by simp
  1504   then show ?thesis using * by auto
  1505 qed
  1506 
  1507 
  1508 subsection \<open>Function limit at a point\<close>
  1509 
  1510 abbreviation LIM :: "('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
  1511     ("((_)/ \<midarrow>(_)/\<rightarrow> (_))" [60, 0, 60] 60)
  1512   where "f \<midarrow>a\<rightarrow> L \<equiv> (f \<longlongrightarrow> L) (at a)"
  1513 
  1514 lemma tendsto_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> (f \<longlongrightarrow> l) (at a within S) \<longleftrightarrow> (f \<midarrow>a\<rightarrow> l)"
  1515   by (simp add: tendsto_def at_within_open[where S = S])
  1516 
  1517 lemma tendsto_within_open_NO_MATCH:
  1518   "a \<in> S \<Longrightarrow> NO_MATCH UNIV S \<Longrightarrow> open S \<Longrightarrow> (f \<longlongrightarrow> l)(at a within S) \<longleftrightarrow> (f \<longlongrightarrow> l)(at a)"
  1519   for f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1520   using tendsto_within_open by blast
  1521 
  1522 lemma LIM_const_not_eq[tendsto_intros]: "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) \<midarrow>a\<rightarrow> L"
  1523   for a :: "'a::perfect_space" and k L :: "'b::t2_space"
  1524   by (simp add: tendsto_const_iff)
  1525 
  1526 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
  1527 
  1528 lemma LIM_const_eq: "(\<lambda>x. k) \<midarrow>a\<rightarrow> L \<Longrightarrow> k = L"
  1529   for a :: "'a::perfect_space" and k L :: "'b::t2_space"
  1530   by (simp add: tendsto_const_iff)
  1531 
  1532 lemma LIM_unique: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> f \<midarrow>a\<rightarrow> M \<Longrightarrow> L = M"
  1533   for a :: "'a::perfect_space" and L M :: "'b::t2_space"
  1534   using at_neq_bot by (rule tendsto_unique)
  1535 
  1536 
  1537 text \<open>Limits are equal for functions equal except at limit point.\<close>
  1538 lemma LIM_equal: "\<forall>x. x \<noteq> a \<longrightarrow> f x = g x \<Longrightarrow> (f \<midarrow>a\<rightarrow> l) \<longleftrightarrow> (g \<midarrow>a\<rightarrow> l)"
  1539   by (simp add: tendsto_def eventually_at_topological)
  1540 
  1541 lemma LIM_cong: "a = b \<Longrightarrow> (\<And>x. x \<noteq> b \<Longrightarrow> f x = g x) \<Longrightarrow> l = m \<Longrightarrow> (f \<midarrow>a\<rightarrow> l) \<longleftrightarrow> (g \<midarrow>b\<rightarrow> m)"
  1542   by (simp add: LIM_equal)
  1543 
  1544 lemma LIM_cong_limit: "f \<midarrow>x\<rightarrow> L \<Longrightarrow> K = L \<Longrightarrow> f \<midarrow>x\<rightarrow> K"
  1545   by simp
  1546 
  1547 lemma tendsto_at_iff_tendsto_nhds: "g \<midarrow>l\<rightarrow> g l \<longleftrightarrow> (g \<longlongrightarrow> g l) (nhds l)"
  1548   unfolding tendsto_def eventually_at_filter
  1549   by (intro ext all_cong imp_cong) (auto elim!: eventually_mono)
  1550 
  1551 lemma tendsto_compose: "g \<midarrow>l\<rightarrow> g l \<Longrightarrow> (f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) \<longlongrightarrow> g l) F"
  1552   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
  1553 
  1554 lemma tendsto_compose_eventually:
  1555   "g \<midarrow>l\<rightarrow> m \<Longrightarrow> (f \<longlongrightarrow> l) F \<Longrightarrow> eventually (\<lambda>x. f x \<noteq> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) \<longlongrightarrow> m) F"
  1556   by (rule filterlim_compose[of g _ "at l"]) (auto simp add: filterlim_at)
  1557 
  1558 lemma LIM_compose_eventually:
  1559   assumes "f \<midarrow>a\<rightarrow> b"
  1560     and "g \<midarrow>b\<rightarrow> c"
  1561     and "eventually (\<lambda>x. f x \<noteq> b) (at a)"
  1562   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> c"
  1563   using assms(2,1,3) by (rule tendsto_compose_eventually)
  1564 
  1565 lemma tendsto_compose_filtermap: "((g \<circ> f) \<longlongrightarrow> T) F \<longleftrightarrow> (g \<longlongrightarrow> T) (filtermap f F)"
  1566   by (simp add: filterlim_def filtermap_filtermap comp_def)
  1567 
  1568 lemma tendsto_compose_at:
  1569   assumes f: "(f \<longlongrightarrow> y) F" and g: "(g \<longlongrightarrow> z) (at y)" and fg: "eventually (\<lambda>w. f w = y \<longrightarrow> g y = z) F"
  1570   shows "((g \<circ> f) \<longlongrightarrow> z) F"
  1571 proof -
  1572   have "(\<forall>\<^sub>F a in F. f a \<noteq> y) \<or> g y = z"
  1573     using fg by force
  1574   moreover have "(g \<longlongrightarrow> z) (filtermap f F) \<or> \<not> (\<forall>\<^sub>F a in F. f a \<noteq> y)"
  1575     by (metis (no_types) filterlim_atI filterlim_def tendsto_mono f g)
  1576   ultimately show ?thesis
  1577     by (metis (no_types) f filterlim_compose filterlim_filtermap g tendsto_at_iff_tendsto_nhds tendsto_compose_filtermap)
  1578 qed
  1579 
  1580 
  1581 subsubsection \<open>Relation of \<open>LIM\<close> and \<open>LIMSEQ\<close>\<close>
  1582 
  1583 lemma (in first_countable_topology) sequentially_imp_eventually_within:
  1584   "(\<forall>f. (\<forall>n. f n \<in> s \<and> f n \<noteq> a) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow>
  1585     eventually P (at a within s)"
  1586   unfolding at_within_def
  1587   by (intro sequentially_imp_eventually_nhds_within) auto
  1588 
  1589 lemma (in first_countable_topology) sequentially_imp_eventually_at:
  1590   "(\<forall>f. (\<forall>n. f n \<noteq> a) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow> eventually P (at a)"
  1591   using sequentially_imp_eventually_within [where s=UNIV] by simp
  1592 
  1593 lemma LIMSEQ_SEQ_conv1:
  1594   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1595   assumes f: "f \<midarrow>a\<rightarrow> l"
  1596   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S \<longlonglongrightarrow> a \<longrightarrow> (\<lambda>n. f (S n)) \<longlonglongrightarrow> l"
  1597   using tendsto_compose_eventually [OF f, where F=sequentially] by simp
  1598 
  1599 lemma LIMSEQ_SEQ_conv2:
  1600   fixes f :: "'a::first_countable_topology \<Rightarrow> 'b::topological_space"
  1601   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S \<longlonglongrightarrow> a \<longrightarrow> (\<lambda>n. f (S n)) \<longlonglongrightarrow> l"
  1602   shows "f \<midarrow>a\<rightarrow> l"
  1603   using assms unfolding tendsto_def [where l=l] by (simp add: sequentially_imp_eventually_at)
  1604 
  1605 lemma LIMSEQ_SEQ_conv: "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S \<longlonglongrightarrow> a \<longrightarrow> (\<lambda>n. X (S n)) \<longlonglongrightarrow> L) \<longleftrightarrow> X \<midarrow>a\<rightarrow> L"
  1606   for a :: "'a::first_countable_topology" and L :: "'b::topological_space"
  1607   using LIMSEQ_SEQ_conv2 LIMSEQ_SEQ_conv1 ..
  1608 
  1609 lemma sequentially_imp_eventually_at_left:
  1610   fixes a :: "'a::{linorder_topology,first_countable_topology}"
  1611   assumes b[simp]: "b < a"
  1612     and *: "\<And>f. (\<And>n. b < f n) \<Longrightarrow> (\<And>n. f n < a) \<Longrightarrow> incseq f \<Longrightarrow> f \<longlonglongrightarrow> a \<Longrightarrow>
  1613       eventually (\<lambda>n. P (f n)) sequentially"
  1614   shows "eventually P (at_left a)"
  1615 proof (safe intro!: sequentially_imp_eventually_within)
  1616   fix X
  1617   assume X: "\<forall>n. X n \<in> {..< a} \<and> X n \<noteq> a" "X \<longlonglongrightarrow> a"
  1618   show "eventually (\<lambda>n. P (X n)) sequentially"
  1619   proof (rule ccontr)
  1620     assume neg: "\<not> ?thesis"
  1621     have "\<exists>s. \<forall>n. (\<not> P (X (s n)) \<and> b < X (s n)) \<and> (X (s n) \<le> X (s (Suc n)) \<and> Suc (s n) \<le> s (Suc n))"
  1622       (is "\<exists>s. ?P s")
  1623     proof (rule dependent_nat_choice)
  1624       have "\<not> eventually (\<lambda>n. b < X n \<longrightarrow> P (X n)) sequentially"
  1625         by (intro not_eventually_impI neg order_tendstoD(1) [OF X(2) b])
  1626       then show "\<exists>x. \<not> P (X x) \<and> b < X x"
  1627         by (auto dest!: not_eventuallyD)
  1628     next
  1629       fix x n
  1630       have "\<not> eventually (\<lambda>n. Suc x \<le> n \<longrightarrow> b < X n \<longrightarrow> X x < X n \<longrightarrow> P (X n)) sequentially"
  1631         using X
  1632         by (intro not_eventually_impI order_tendstoD(1)[OF X(2)] eventually_ge_at_top neg) auto
  1633       then show "\<exists>n. (\<not> P (X n) \<and> b < X n) \<and> (X x \<le> X n \<and> Suc x \<le> n)"
  1634         by (auto dest!: not_eventuallyD)
  1635     qed
  1636     then obtain s where "?P s" ..
  1637     with X have "b < X (s n)"
  1638       and "X (s n) < a"
  1639       and "incseq (\<lambda>n. X (s n))"
  1640       and "(\<lambda>n. X (s n)) \<longlonglongrightarrow> a"
  1641       and "\<not> P (X (s n))"
  1642       for n
  1643       by (auto simp: subseq_Suc_iff Suc_le_eq incseq_Suc_iff
  1644           intro!: LIMSEQ_subseq_LIMSEQ[OF \<open>X \<longlonglongrightarrow> a\<close>, unfolded comp_def])
  1645     from *[OF this(1,2,3,4)] this(5) show False
  1646       by auto
  1647   qed
  1648 qed
  1649 
  1650 lemma tendsto_at_left_sequentially:
  1651   fixes a b :: "'b::{linorder_topology,first_countable_topology}"
  1652   assumes "b < a"
  1653   assumes *: "\<And>S. (\<And>n. S n < a) \<Longrightarrow> (\<And>n. b < S n) \<Longrightarrow> incseq S \<Longrightarrow> S \<longlonglongrightarrow> a \<Longrightarrow>
  1654     (\<lambda>n. X (S n)) \<longlonglongrightarrow> L"
  1655   shows "(X \<longlongrightarrow> L) (at_left a)"
  1656   using assms by (simp add: tendsto_def [where l=L] sequentially_imp_eventually_at_left)
  1657 
  1658 lemma sequentially_imp_eventually_at_right:
  1659   fixes a b :: "'a::{linorder_topology,first_countable_topology}"
  1660   assumes b[simp]: "a < b"
  1661   assumes *: "\<And>f. (\<And>n. a < f n) \<Longrightarrow> (\<And>n. f n < b) \<Longrightarrow> decseq f \<Longrightarrow> f \<longlonglongrightarrow> a \<Longrightarrow>
  1662     eventually (\<lambda>n. P (f n)) sequentially"
  1663   shows "eventually P (at_right a)"
  1664 proof (safe intro!: sequentially_imp_eventually_within)
  1665   fix X
  1666   assume X: "\<forall>n. X n \<in> {a <..} \<and> X n \<noteq> a" "X \<longlonglongrightarrow> a"
  1667   show "eventually (\<lambda>n. P (X n)) sequentially"
  1668   proof (rule ccontr)
  1669     assume neg: "\<not> ?thesis"
  1670     have "\<exists>s. \<forall>n. (\<not> P (X (s n)) \<and> X (s n) < b) \<and> (X (s (Suc n)) \<le> X (s n) \<and> Suc (s n) \<le> s (Suc n))"
  1671       (is "\<exists>s. ?P s")
  1672     proof (rule dependent_nat_choice)
  1673       have "\<not> eventually (\<lambda>n. X n < b \<longrightarrow> P (X n)) sequentially"
  1674         by (intro not_eventually_impI neg order_tendstoD(2) [OF X(2) b])
  1675       then show "\<exists>x. \<not> P (X x) \<and> X x < b"
  1676         by (auto dest!: not_eventuallyD)
  1677     next
  1678       fix x n
  1679       have "\<not> eventually (\<lambda>n. Suc x \<le> n \<longrightarrow> X n < b \<longrightarrow> X n < X x \<longrightarrow> P (X n)) sequentially"
  1680         using X
  1681         by (intro not_eventually_impI order_tendstoD(2)[OF X(2)] eventually_ge_at_top neg) auto
  1682       then show "\<exists>n. (\<not> P (X n) \<and> X n < b) \<and> (X n \<le> X x \<and> Suc x \<le> n)"
  1683         by (auto dest!: not_eventuallyD)
  1684     qed
  1685     then obtain s where "?P s" ..
  1686     with X have "a < X (s n)"
  1687       and "X (s n) < b"
  1688       and "decseq (\<lambda>n. X (s n))"
  1689       and "(\<lambda>n. X (s n)) \<longlonglongrightarrow> a"
  1690       and "\<not> P (X (s n))"
  1691       for n
  1692       by (auto simp: subseq_Suc_iff Suc_le_eq decseq_Suc_iff
  1693           intro!: LIMSEQ_subseq_LIMSEQ[OF \<open>X \<longlonglongrightarrow> a\<close>, unfolded comp_def])
  1694     from *[OF this(1,2,3,4)] this(5) show False
  1695       by auto
  1696   qed
  1697 qed
  1698 
  1699 lemma tendsto_at_right_sequentially:
  1700   fixes a :: "_ :: {linorder_topology, first_countable_topology}"
  1701   assumes "a < b"
  1702     and *: "\<And>S. (\<And>n. a < S n) \<Longrightarrow> (\<And>n. S n < b) \<Longrightarrow> decseq S \<Longrightarrow> S \<longlonglongrightarrow> a \<Longrightarrow>
  1703       (\<lambda>n. X (S n)) \<longlonglongrightarrow> L"
  1704   shows "(X \<longlongrightarrow> L) (at_right a)"
  1705   using assms by (simp add: tendsto_def [where l=L] sequentially_imp_eventually_at_right)
  1706 
  1707 
  1708 subsection \<open>Continuity\<close>
  1709 
  1710 subsubsection \<open>Continuity on a set\<close>
  1711 
  1712 definition continuous_on :: "'a set \<Rightarrow> ('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> bool"
  1713   where "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f \<longlongrightarrow> f x) (at x within s))"
  1714 
  1715 lemma continuous_on_cong [cong]:
  1716   "s = t \<Longrightarrow> (\<And>x. x \<in> t \<Longrightarrow> f x = g x) \<Longrightarrow> continuous_on s f \<longleftrightarrow> continuous_on t g"
  1717   unfolding continuous_on_def
  1718   by (intro ball_cong filterlim_cong) (auto simp: eventually_at_filter)
  1719 
  1720 lemma continuous_on_strong_cong:
  1721   "s = t \<Longrightarrow> (\<And>x. x \<in> t =simp=> f x = g x) \<Longrightarrow> continuous_on s f \<longleftrightarrow> continuous_on t g"
  1722   unfolding simp_implies_def by (rule continuous_on_cong)
  1723 
  1724 lemma continuous_on_topological:
  1725   "continuous_on s f \<longleftrightarrow>
  1726     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1727   unfolding continuous_on_def tendsto_def eventually_at_topological by metis
  1728 
  1729 lemma continuous_on_open_invariant:
  1730   "continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s))"
  1731 proof safe
  1732   fix B :: "'b set"
  1733   assume "continuous_on s f" "open B"
  1734   then have "\<forall>x\<in>f -` B \<inter> s. (\<exists>A. open A \<and> x \<in> A \<and> s \<inter> A \<subseteq> f -` B)"
  1735     by (auto simp: continuous_on_topological subset_eq Ball_def imp_conjL)
  1736   then obtain A where "\<forall>x\<in>f -` B \<inter> s. open (A x) \<and> x \<in> A x \<and> s \<inter> A x \<subseteq> f -` B"
  1737     unfolding bchoice_iff ..
  1738   then show "\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s"
  1739     by (intro exI[of _ "\<Union>x\<in>f -` B \<inter> s. A x"]) auto
  1740 next
  1741   assume B: "\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s)"
  1742   show "continuous_on s f"
  1743     unfolding continuous_on_topological
  1744   proof safe
  1745     fix x B
  1746     assume "x \<in> s" "open B" "f x \<in> B"
  1747     with B obtain A where A: "open A" "A \<inter> s = f -` B \<inter> s"
  1748       by auto
  1749     with \<open>x \<in> s\<close> \<open>f x \<in> B\<close> show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  1750       by (intro exI[of _ A]) auto
  1751   qed
  1752 qed
  1753 
  1754 lemma continuous_on_open_vimage:
  1755   "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> open (f -` B \<inter> s))"
  1756   unfolding continuous_on_open_invariant
  1757   by (metis open_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1758 
  1759 corollary continuous_imp_open_vimage:
  1760   assumes "continuous_on s f" "open s" "open B" "f -` B \<subseteq> s"
  1761   shows "open (f -` B)"
  1762   by (metis assms continuous_on_open_vimage le_iff_inf)
  1763 
  1764 corollary open_vimage[continuous_intros]:
  1765   assumes "open s"
  1766     and "continuous_on UNIV f"
  1767   shows "open (f -` s)"
  1768   using assms by (simp add: continuous_on_open_vimage [OF open_UNIV])
  1769 
  1770 lemma continuous_on_closed_invariant:
  1771   "continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> (\<exists>A. closed A \<and> A \<inter> s = f -` B \<inter> s))"
  1772 proof -
  1773   have *: "(\<And>A. P A \<longleftrightarrow> Q (- A)) \<Longrightarrow> (\<forall>A. P A) \<longleftrightarrow> (\<forall>A. Q A)"
  1774     for P Q :: "'b set \<Rightarrow> bool"
  1775     by (metis double_compl)
  1776   show ?thesis
  1777     unfolding continuous_on_open_invariant
  1778     by (intro *) (auto simp: open_closed[symmetric])
  1779 qed
  1780 
  1781 lemma continuous_on_closed_vimage:
  1782   "closed s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> closed (f -` B \<inter> s))"
  1783   unfolding continuous_on_closed_invariant
  1784   by (metis closed_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1785 
  1786 corollary closed_vimage_Int[continuous_intros]:
  1787   assumes "closed s"
  1788     and "continuous_on t f"
  1789     and t: "closed t"
  1790   shows "closed (f -` s \<inter> t)"
  1791   using assms by (simp add: continuous_on_closed_vimage [OF t])
  1792 
  1793 corollary closed_vimage[continuous_intros]:
  1794   assumes "closed s"
  1795     and "continuous_on UNIV f"
  1796   shows "closed (f -` s)"
  1797   using closed_vimage_Int [OF assms] by simp
  1798 
  1799 lemma continuous_on_empty [simp]: "continuous_on {} f"
  1800   by (simp add: continuous_on_def)
  1801 
  1802 lemma continuous_on_sing [simp]: "continuous_on {x} f"
  1803   by (simp add: continuous_on_def at_within_def)
  1804 
  1805 lemma continuous_on_open_Union:
  1806   "(\<And>s. s \<in> S \<Longrightarrow> open s) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on s f) \<Longrightarrow> continuous_on (\<Union>S) f"
  1807   unfolding continuous_on_def
  1808   by safe (metis open_Union at_within_open UnionI)
  1809 
  1810 lemma continuous_on_open_UN:
  1811   "(\<And>s. s \<in> S \<Longrightarrow> open (A s)) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on (A s) f) \<Longrightarrow>
  1812     continuous_on (\<Union>s\<in>S. A s) f"
  1813   by (rule continuous_on_open_Union) auto
  1814 
  1815 lemma continuous_on_open_Un:
  1816   "open s \<Longrightarrow> open t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  1817   using continuous_on_open_Union [of "{s,t}"] by auto
  1818 
  1819 lemma continuous_on_closed_Un:
  1820   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  1821   by (auto simp add: continuous_on_closed_vimage closed_Un Int_Un_distrib)
  1822 
  1823 lemma continuous_on_If:
  1824   assumes closed: "closed s" "closed t"
  1825     and cont: "continuous_on s f" "continuous_on t g"
  1826     and P: "\<And>x. x \<in> s \<Longrightarrow> \<not> P x \<Longrightarrow> f x = g x" "\<And>x. x \<in> t \<Longrightarrow> P x \<Longrightarrow> f x = g x"
  1827   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)"
  1828     (is "continuous_on _ ?h")
  1829 proof-
  1830   from P have "\<forall>x\<in>s. f x = ?h x" "\<forall>x\<in>t. g x = ?h x"
  1831     by auto
  1832   with cont have "continuous_on s ?h" "continuous_on t ?h"
  1833     by simp_all
  1834   with closed show ?thesis
  1835     by (rule continuous_on_closed_Un)
  1836 qed
  1837 
  1838 lemma continuous_on_cases:
  1839   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t g \<Longrightarrow>
  1840     \<forall>x. (x\<in>s \<and> \<not> P x) \<or> (x \<in> t \<and> P x) \<longrightarrow> f x = g x \<Longrightarrow>
  1841     continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)"
  1842   by (rule continuous_on_If) auto
  1843 
  1844 lemma continuous_on_id[continuous_intros]: "continuous_on s (\<lambda>x. x)"
  1845   unfolding continuous_on_def by fast
  1846 
  1847 lemma continuous_on_id'[continuous_intros]: "continuous_on s id"
  1848   unfolding continuous_on_def id_def by fast
  1849 
  1850 lemma continuous_on_const[continuous_intros]: "continuous_on s (\<lambda>x. c)"
  1851   unfolding continuous_on_def by auto
  1852 
  1853 lemma continuous_on_subset: "continuous_on s f \<Longrightarrow> t \<subseteq> s \<Longrightarrow> continuous_on t f"
  1854   unfolding continuous_on_def
  1855   by (metis subset_eq tendsto_within_subset)
  1856 
  1857 lemma continuous_on_compose[continuous_intros]:
  1858   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g \<circ> f)"
  1859   unfolding continuous_on_topological by simp metis
  1860 
  1861 lemma continuous_on_compose2:
  1862   "continuous_on t g \<Longrightarrow> continuous_on s f \<Longrightarrow> f ` s \<subseteq> t \<Longrightarrow> continuous_on s (\<lambda>x. g (f x))"
  1863   using continuous_on_compose[of s f g] continuous_on_subset by (force simp add: comp_def)
  1864 
  1865 lemma continuous_on_generate_topology:
  1866   assumes *: "open = generate_topology X"
  1867     and **: "\<And>B. B \<in> X \<Longrightarrow> \<exists>C. open C \<and> C \<inter> A = f -` B \<inter> A"
  1868   shows "continuous_on A f"
  1869   unfolding continuous_on_open_invariant
  1870 proof safe
  1871   fix B :: "'a set"
  1872   assume "open B"
  1873   then show "\<exists>C. open C \<and> C \<inter> A = f -` B \<inter> A"
  1874     unfolding *
  1875   proof induct
  1876     case (UN K)
  1877     then obtain C where "\<And>k. k \<in> K \<Longrightarrow> open (C k)" "\<And>k. k \<in> K \<Longrightarrow> C k \<inter> A = f -` k \<inter> A"
  1878       by metis
  1879     then show ?case
  1880       by (intro exI[of _ "\<Union>k\<in>K. C k"]) blast
  1881   qed (auto intro: **)
  1882 qed
  1883 
  1884 lemma continuous_onI_mono:
  1885   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::{dense_order,linorder_topology}"
  1886   assumes "open (f`A)"
  1887     and mono: "\<And>x y. x \<in> A \<Longrightarrow> y \<in> A \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1888   shows "continuous_on A f"
  1889 proof (rule continuous_on_generate_topology[OF open_generated_order], safe)
  1890   have monoD: "\<And>x y. x \<in> A \<Longrightarrow> y \<in> A \<Longrightarrow> f x < f y \<Longrightarrow> x < y"
  1891     by (auto simp: not_le[symmetric] mono)
  1892   have "\<exists>x. x \<in> A \<and> f x < b \<and> a < x" if a: "a \<in> A" and fa: "f a < b" for a b
  1893   proof -
  1894     obtain y where "f a < y" "{f a ..< y} \<subseteq> f`A"
  1895       using open_right[OF \<open>open (f`A)\<close>, of "f a" b] a fa
  1896       by auto
  1897     obtain z where z: "f a < z" "z < min b y"
  1898       using dense[of "f a" "min b y"] \<open>f a < y\<close> \<open>f a < b\<close> by auto
  1899     then obtain c where "z = f c" "c \<in> A"
  1900       using \<open>{f a ..< y} \<subseteq> f`A\<close>[THEN subsetD, of z] by (auto simp: less_imp_le)
  1901     with a z show ?thesis
  1902       by (auto intro!: exI[of _ c] simp: monoD)
  1903   qed
  1904   then show "\<exists>C. open C \<and> C \<inter> A = f -` {..<b} \<inter> A" for b
  1905     by (intro exI[of _ "(\<Union>x\<in>{x\<in>A. f x < b}. {..< x})"])
  1906        (auto intro: le_less_trans[OF mono] less_imp_le)
  1907 
  1908   have "\<exists>x. x \<in> A \<and> b < f x \<and> x < a" if a: "a \<in> A" and fa: "b < f a" for a b
  1909   proof -
  1910     note a fa
  1911     moreover
  1912     obtain y where "y < f a" "{y <.. f a} \<subseteq> f`A"
  1913       using open_left[OF \<open>open (f`A)\<close>, of "f a" b]  a fa
  1914       by auto
  1915     then obtain z where z: "max b y < z" "z < f a"
  1916       using dense[of "max b y" "f a"] \<open>y < f a\<close> \<open>b < f a\<close> by auto
  1917     then obtain c where "z = f c" "c \<in> A"
  1918       using \<open>{y <.. f a} \<subseteq> f`A\<close>[THEN subsetD, of z] by (auto simp: less_imp_le)
  1919     with a z show ?thesis
  1920       by (auto intro!: exI[of _ c] simp: monoD)
  1921   qed
  1922   then show "\<exists>C. open C \<and> C \<inter> A = f -` {b <..} \<inter> A" for b
  1923     by (intro exI[of _ "(\<Union>x\<in>{x\<in>A. b < f x}. {x <..})"])
  1924        (auto intro: less_le_trans[OF _ mono] less_imp_le)
  1925 qed
  1926 
  1927 lemma continuous_on_IccI:
  1928   "\<lbrakk>(f \<longlongrightarrow> f a) (at_right a);
  1929     (f \<longlongrightarrow> f b) (at_left b);
  1930     (\<And>x. a < x \<Longrightarrow> x < b \<Longrightarrow> f \<midarrow>x\<rightarrow> f x); a < b\<rbrakk> \<Longrightarrow>
  1931     continuous_on {a .. b} f"
  1932   for a::"'a::linorder_topology"
  1933   using at_within_open[of _ "{a<..<b}"]
  1934   by (auto simp: continuous_on_def at_within_Icc_at_right at_within_Icc_at_left le_less
  1935       at_within_Icc_at)
  1936 
  1937 lemma
  1938   fixes a b::"'a::linorder_topology"
  1939   assumes "continuous_on {a .. b} f" "a < b"
  1940   shows continuous_on_Icc_at_rightD: "(f \<longlongrightarrow> f a) (at_right a)"
  1941     and continuous_on_Icc_at_leftD: "(f \<longlongrightarrow> f b) (at_left b)"
  1942   using assms
  1943   by (auto simp: at_within_Icc_at_right at_within_Icc_at_left continuous_on_def
  1944       dest: bspec[where x=a] bspec[where x=b])
  1945 
  1946 
  1947 subsubsection \<open>Continuity at a point\<close>
  1948 
  1949 definition continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool"
  1950   where "continuous F f \<longleftrightarrow> (f \<longlongrightarrow> f (Lim F (\<lambda>x. x))) F"
  1951 
  1952 lemma continuous_bot[continuous_intros, simp]: "continuous bot f"
  1953   unfolding continuous_def by auto
  1954 
  1955 lemma continuous_trivial_limit: "trivial_limit net \<Longrightarrow> continuous net f"
  1956   by simp
  1957 
  1958 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f \<longlongrightarrow> f x) (at x within s)"
  1959   by (cases "trivial_limit (at x within s)") (auto simp add: Lim_ident_at continuous_def)
  1960 
  1961 lemma continuous_within_topological:
  1962   "continuous (at x within s) f \<longleftrightarrow>
  1963     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1964   unfolding continuous_within tendsto_def eventually_at_topological by metis
  1965 
  1966 lemma continuous_within_compose[continuous_intros]:
  1967   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1968     continuous (at x within s) (g \<circ> f)"
  1969   by (simp add: continuous_within_topological) metis
  1970 
  1971 lemma continuous_within_compose2:
  1972   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1973     continuous (at x within s) (\<lambda>x. g (f x))"
  1974   using continuous_within_compose[of x s f g] by (simp add: comp_def)
  1975 
  1976 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> f \<midarrow>x\<rightarrow> f x"
  1977   using continuous_within[of x UNIV f] by simp
  1978 
  1979 lemma continuous_ident[continuous_intros, simp]: "continuous (at x within S) (\<lambda>x. x)"
  1980   unfolding continuous_within by (rule tendsto_ident_at)
  1981 
  1982 lemma continuous_const[continuous_intros, simp]: "continuous F (\<lambda>x. c)"
  1983   unfolding continuous_def by (rule tendsto_const)
  1984 
  1985 lemma continuous_on_eq_continuous_within:
  1986   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. continuous (at x within s) f)"
  1987   unfolding continuous_on_def continuous_within ..
  1988 
  1989 abbreviation isCont :: "('a::t2_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> bool"
  1990   where "isCont f a \<equiv> continuous (at a) f"
  1991 
  1992 lemma isCont_def: "isCont f a \<longleftrightarrow> f \<midarrow>a\<rightarrow> f a"
  1993   by (rule continuous_at)
  1994 
  1995 lemma isCont_cong:
  1996   assumes "eventually (\<lambda>x. f x = g x) (nhds x)"
  1997   shows "isCont f x \<longleftrightarrow> isCont g x"
  1998 proof -
  1999   from assms have [simp]: "f x = g x"
  2000     by (rule eventually_nhds_x_imp_x)
  2001   from assms have "eventually (\<lambda>x. f x = g x) (at x)"
  2002     by (auto simp: eventually_at_filter elim!: eventually_mono)
  2003   with assms have "isCont f x \<longleftrightarrow> isCont g x" unfolding isCont_def
  2004     by (intro filterlim_cong) (auto elim!: eventually_mono)
  2005   with assms show ?thesis by simp
  2006 qed
  2007 
  2008 lemma continuous_at_imp_continuous_at_within: "isCont f x \<Longrightarrow> continuous (at x within s) f"
  2009   by (auto intro: tendsto_mono at_le simp: continuous_at continuous_within)
  2010 
  2011 lemma continuous_on_eq_continuous_at: "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. isCont f x)"
  2012   by (simp add: continuous_on_def continuous_at at_within_open[of _ s])
  2013 
  2014 lemma continuous_within_open: "a \<in> A \<Longrightarrow> open A \<Longrightarrow> continuous (at a within A) f \<longleftrightarrow> isCont f a"
  2015   by (simp add: at_within_open_NO_MATCH)
  2016 
  2017 lemma continuous_at_imp_continuous_on: "\<forall>x\<in>s. isCont f x \<Longrightarrow> continuous_on s f"
  2018   by (auto intro: continuous_at_imp_continuous_at_within simp: continuous_on_eq_continuous_within)
  2019 
  2020 lemma isCont_o2: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
  2021   unfolding isCont_def by (rule tendsto_compose)
  2022 
  2023 lemma isCont_o[continuous_intros]: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (g \<circ> f) a"
  2024   unfolding o_def by (rule isCont_o2)
  2025 
  2026 lemma isCont_tendsto_compose: "isCont g l \<Longrightarrow> (f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) \<longlongrightarrow> g l) F"
  2027   unfolding isCont_def by (rule tendsto_compose)
  2028 
  2029 lemma continuous_on_tendsto_compose:
  2030   assumes f_cont: "continuous_on s f"
  2031     and g: "(g \<longlongrightarrow> l) F"
  2032     and l: "l \<in> s"
  2033     and ev: "\<forall>\<^sub>Fx in F. g x \<in> s"
  2034   shows "((\<lambda>x. f (g x)) \<longlongrightarrow> f l) F"
  2035 proof -
  2036   from f_cont l have f: "(f \<longlongrightarrow> f l) (at l within s)"
  2037     by (simp add: continuous_on_def)
  2038   have i: "((\<lambda>x. if g x = l then f l else f (g x)) \<longlongrightarrow> f l) F"
  2039     by (rule filterlim_If)
  2040        (auto intro!: filterlim_compose[OF f] eventually_conj tendsto_mono[OF _ g]
  2041              simp: filterlim_at eventually_inf_principal eventually_mono[OF ev])
  2042   show ?thesis
  2043     by (rule filterlim_cong[THEN iffD1[OF _ i]]) auto
  2044 qed
  2045 
  2046 lemma continuous_within_compose3:
  2047   "isCont g (f x) \<Longrightarrow> continuous (at x within s) f \<Longrightarrow> continuous (at x within s) (\<lambda>x. g (f x))"
  2048   using continuous_at_imp_continuous_at_within continuous_within_compose2 by blast
  2049 
  2050 lemma filtermap_nhds_open_map:
  2051   assumes cont: "isCont f a"
  2052     and open_map: "\<And>S. open S \<Longrightarrow> open (f`S)"
  2053   shows "filtermap f (nhds a) = nhds (f a)"
  2054   unfolding filter_eq_iff
  2055 proof safe
  2056   fix P
  2057   assume "eventually P (filtermap f (nhds a))"
  2058   then obtain S where "open S" "a \<in> S" "\<forall>x\<in>S. P (f x)"
  2059     by (auto simp: eventually_filtermap eventually_nhds)
  2060   then show "eventually P (nhds (f a))"
  2061     unfolding eventually_nhds by (intro exI[of _ "f`S"]) (auto intro!: open_map)
  2062 qed (metis filterlim_iff tendsto_at_iff_tendsto_nhds isCont_def eventually_filtermap cont)
  2063 
  2064 lemma continuous_at_split:
  2065   "continuous (at x) f \<longleftrightarrow> continuous (at_left x) f \<and> continuous (at_right x) f"
  2066   for x :: "'a::linorder_topology"
  2067   by (simp add: continuous_within filterlim_at_split)
  2068 
  2069 text \<open>
  2070   The following open/closed Collect lemmas are ported from
  2071   Sébastien Gouëzel's \<open>Ergodic_Theory\<close>.
  2072 \<close>
  2073 lemma open_Collect_neq:
  2074   fixes f g :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2075   assumes f: "continuous_on UNIV f" and g: "continuous_on UNIV g"
  2076   shows "open {x. f x \<noteq> g x}"
  2077 proof (rule openI)
  2078   fix t
  2079   assume "t \<in> {x. f x \<noteq> g x}"
  2080   then obtain U V where *: "open U" "open V" "f t \<in> U" "g t \<in> V" "U \<inter> V = {}"
  2081     by (auto simp add: separation_t2)
  2082   with open_vimage[OF \<open>open U\<close> f] open_vimage[OF \<open>open V\<close> g]
  2083   show "\<exists>T. open T \<and> t \<in> T \<and> T \<subseteq> {x. f x \<noteq> g x}"
  2084     by (intro exI[of _ "f -` U \<inter> g -` V"]) auto
  2085 qed
  2086 
  2087 lemma closed_Collect_eq:
  2088   fixes f g :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2089   assumes f: "continuous_on UNIV f" and g: "continuous_on UNIV g"
  2090   shows "closed {x. f x = g x}"
  2091   using open_Collect_neq[OF f g] by (simp add: closed_def Collect_neg_eq)
  2092 
  2093 lemma open_Collect_less:
  2094   fixes f g :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2095   assumes f: "continuous_on UNIV f" and g: "continuous_on UNIV g"
  2096   shows "open {x. f x < g x}"
  2097 proof (rule openI)
  2098   fix t
  2099   assume t: "t \<in> {x. f x < g x}"
  2100   show "\<exists>T. open T \<and> t \<in> T \<and> T \<subseteq> {x. f x < g x}"
  2101   proof (cases "\<exists>z. f t < z \<and> z < g t")
  2102     case True
  2103     then obtain z where "f t < z \<and> z < g t" by blast
  2104     then show ?thesis
  2105       using open_vimage[OF _ f, of "{..< z}"] open_vimage[OF _ g, of "{z <..}"]
  2106       by (intro exI[of _ "f -` {..<z} \<inter> g -` {z<..}"]) auto
  2107   next
  2108     case False
  2109     then have *: "{g t ..} = {f t <..}" "{..< g t} = {.. f t}"
  2110       using t by (auto intro: leI)
  2111     show ?thesis
  2112       using open_vimage[OF _ f, of "{..< g t}"] open_vimage[OF _ g, of "{f t <..}"] t
  2113       apply (intro exI[of _ "f -` {..< g t} \<inter> g -` {f t<..}"])
  2114       apply (simp add: open_Int)
  2115       apply (auto simp add: *)
  2116       done
  2117   qed
  2118 qed
  2119 
  2120 lemma closed_Collect_le:
  2121   fixes f g :: "'a :: topological_space \<Rightarrow> 'b::linorder_topology"
  2122   assumes f: "continuous_on UNIV f"
  2123     and g: "continuous_on UNIV g"
  2124   shows "closed {x. f x \<le> g x}"
  2125   using open_Collect_less [OF g f]
  2126   by (simp add: closed_def Collect_neg_eq[symmetric] not_le)
  2127 
  2128 
  2129 subsubsection \<open>Open-cover compactness\<close>
  2130 
  2131 context topological_space
  2132 begin
  2133 
  2134 definition compact :: "'a set \<Rightarrow> bool"
  2135   where compact_eq_heine_borel:  (* This name is used for backwards compatibility *)
  2136     "compact S \<longleftrightarrow> (\<forall>C. (\<forall>c\<in>C. open c) \<and> S \<subseteq> \<Union>C \<longrightarrow> (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D))"
  2137 
  2138 lemma compactI:
  2139   assumes "\<And>C. \<forall>t\<in>C. open t \<Longrightarrow> s \<subseteq> \<Union>C \<Longrightarrow> \<exists>C'. C' \<subseteq> C \<and> finite C' \<and> s \<subseteq> \<Union>C'"
  2140   shows "compact s"
  2141   unfolding compact_eq_heine_borel using assms by metis
  2142 
  2143 lemma compact_empty[simp]: "compact {}"
  2144   by (auto intro!: compactI)
  2145 
  2146 lemma compactE: (*related to COMPACT_IMP_HEINE_BOREL in HOL Light*)
  2147   assumes "compact S" "S \<subseteq> \<Union>\<T>" "\<And>B. B \<in> \<T> \<Longrightarrow> open B"
  2148   obtains \<T>' where "\<T>' \<subseteq> \<T>" "finite \<T>'" "S \<subseteq> \<Union>\<T>'"
  2149   by (meson assms compact_eq_heine_borel)
  2150 
  2151 lemma compactE_image:
  2152   assumes "compact S"
  2153     and "\<forall>T\<in>C. open (f T)"
  2154     and "S \<subseteq> (\<Union>c\<in>C. f c)"
  2155   obtains C' where "C' \<subseteq> C" and "finite C'" and "S \<subseteq> (\<Union>c\<in>C'. f c)"
  2156   using assms unfolding ball_simps [symmetric]
  2157   by (metis (lifting) finite_subset_image compact_eq_heine_borel[of S])
  2158 
  2159 lemma compact_Int_closed [intro]:
  2160   assumes "compact S"
  2161     and "closed T"
  2162   shows "compact (S \<inter> T)"
  2163 proof (rule compactI)
  2164   fix C
  2165   assume C: "\<forall>c\<in>C. open c"
  2166   assume cover: "S \<inter> T \<subseteq> \<Union>C"
  2167   from C \<open>closed T\<close> have "\<forall>c\<in>C \<union> {- T}. open c"
  2168     by auto
  2169   moreover from cover have "S \<subseteq> \<Union>(C \<union> {- T})"
  2170     by auto
  2171   ultimately have "\<exists>D\<subseteq>C \<union> {- T}. finite D \<and> S \<subseteq> \<Union>D"
  2172     using \<open>compact S\<close> unfolding compact_eq_heine_borel by auto
  2173   then obtain D where "D \<subseteq> C \<union> {- T} \<and> finite D \<and> S \<subseteq> \<Union>D" ..
  2174   then show "\<exists>D\<subseteq>C. finite D \<and> S \<inter> T \<subseteq> \<Union>D"
  2175     by (intro exI[of _ "D - {-T}"]) auto
  2176 qed
  2177 
  2178 lemma compact_diff: "\<lbrakk>compact S; open T\<rbrakk> \<Longrightarrow> compact(S - T)"
  2179   by (simp add: Diff_eq compact_Int_closed open_closed)
  2180 
  2181 lemma inj_setminus: "inj_on uminus (A::'a set set)"
  2182   by (auto simp: inj_on_def)
  2183 
  2184 
  2185 subsection \<open>Finite intersection property\<close>
  2186 
  2187 lemma compact_fip:
  2188   "compact U \<longleftrightarrow>
  2189     (\<forall>A. (\<forall>a\<in>A. closed a) \<longrightarrow> (\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}) \<longrightarrow> U \<inter> \<Inter>A \<noteq> {})"
  2190   (is "_ \<longleftrightarrow> ?R")
  2191 proof (safe intro!: compact_eq_heine_borel[THEN iffD2])
  2192   fix A
  2193   assume "compact U"
  2194   assume A: "\<forall>a\<in>A. closed a" "U \<inter> \<Inter>A = {}"
  2195   assume fin: "\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}"
  2196   from A have "(\<forall>a\<in>uminus`A. open a) \<and> U \<subseteq> \<Union>(uminus`A)"
  2197     by auto
  2198   with \<open>compact U\<close> obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<subseteq> \<Union>(uminus`B)"
  2199     unfolding compact_eq_heine_borel by (metis subset_image_iff)
  2200   with fin[THEN spec, of B] show False
  2201     by (auto dest: finite_imageD intro: inj_setminus)
  2202 next
  2203   fix A
  2204   assume ?R
  2205   assume "\<forall>a\<in>A. open a" "U \<subseteq> \<Union>A"
  2206   then have "U \<inter> \<Inter>(uminus`A) = {}" "\<forall>a\<in>uminus`A. closed a"
  2207     by auto
  2208   with \<open>?R\<close> obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<inter> \<Inter>(uminus`B) = {}"
  2209     by (metis subset_image_iff)
  2210   then show "\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T"
  2211     by (auto intro!: exI[of _ B] inj_setminus dest: finite_imageD)
  2212 qed
  2213 
  2214 lemma compact_imp_fip:
  2215   assumes "compact S"
  2216     and "\<And>T. T \<in> F \<Longrightarrow> closed T"
  2217     and "\<And>F'. finite F' \<Longrightarrow> F' \<subseteq> F \<Longrightarrow> S \<inter> (\<Inter>F') \<noteq> {}"
  2218   shows "S \<inter> (\<Inter>F) \<noteq> {}"
  2219   using assms unfolding compact_fip by auto
  2220 
  2221 lemma compact_imp_fip_image:
  2222   assumes "compact s"
  2223     and P: "\<And>i. i \<in> I \<Longrightarrow> closed (f i)"
  2224     and Q: "\<And>I'. finite I' \<Longrightarrow> I' \<subseteq> I \<Longrightarrow> (s \<inter> (\<Inter>i\<in>I'. f i) \<noteq> {})"
  2225   shows "s \<inter> (\<Inter>i\<in>I. f i) \<noteq> {}"
  2226 proof -
  2227   note \<open>compact s\<close>
  2228   moreover from P have "\<forall>i \<in> f ` I. closed i"
  2229     by blast
  2230   moreover have "\<forall>A. finite A \<and> A \<subseteq> f ` I \<longrightarrow> (s \<inter> (\<Inter>A) \<noteq> {})"
  2231     apply rule
  2232     apply rule
  2233     apply (erule conjE)
  2234   proof -
  2235     fix A :: "'a set set"
  2236     assume "finite A" and "A \<subseteq> f ` I"
  2237     then obtain B where "B \<subseteq> I" and "finite B" and "A = f ` B"
  2238       using finite_subset_image [of A f I] by blast
  2239     with Q [of B] show "s \<inter> \<Inter>A \<noteq> {}"
  2240       by simp
  2241   qed
  2242   ultimately have "s \<inter> (\<Inter>(f ` I)) \<noteq> {}"
  2243     by (metis compact_imp_fip)
  2244   then show ?thesis by simp
  2245 qed
  2246 
  2247 end
  2248 
  2249 lemma (in t2_space) compact_imp_closed:
  2250   assumes "compact s"
  2251   shows "closed s"
  2252   unfolding closed_def
  2253 proof (rule openI)
  2254   fix y
  2255   assume "y \<in> - s"
  2256   let ?C = "\<Union>x\<in>s. {u. open u \<and> x \<in> u \<and> eventually (\<lambda>y. y \<notin> u) (nhds y)}"
  2257   have "s \<subseteq> \<Union>?C"
  2258   proof
  2259     fix x
  2260     assume "x \<in> s"
  2261     with \<open>y \<in> - s\<close> have "x \<noteq> y" by clarsimp
  2262     then have "\<exists>u v. open u \<and> open v \<and> x \<in> u \<and> y \<in> v \<and> u \<inter> v = {}"
  2263       by (rule hausdorff)
  2264     with \<open>x \<in> s\<close> show "x \<in> \<Union>?C"
  2265       unfolding eventually_nhds by auto
  2266   qed
  2267   then obtain D where "D \<subseteq> ?C" and "finite D" and "s \<subseteq> \<Union>D"
  2268     by (rule compactE [OF \<open>compact s\<close>]) auto
  2269   from \<open>D \<subseteq> ?C\<close> have "\<forall>x\<in>D. eventually (\<lambda>y. y \<notin> x) (nhds y)"
  2270     by auto
  2271   with \<open>finite D\<close> have "eventually (\<lambda>y. y \<notin> \<Union>D) (nhds y)"
  2272     by (simp add: eventually_ball_finite)
  2273   with \<open>s \<subseteq> \<Union>D\<close> have "eventually (\<lambda>y. y \<notin> s) (nhds y)"
  2274     by (auto elim!: eventually_mono)
  2275   then show "\<exists>t. open t \<and> y \<in> t \<and> t \<subseteq> - s"
  2276     by (simp add: eventually_nhds subset_eq)
  2277 qed
  2278 
  2279 lemma compact_continuous_image:
  2280   assumes f: "continuous_on s f"
  2281     and s: "compact s"
  2282   shows "compact (f ` s)"
  2283 proof (rule compactI)
  2284   fix C
  2285   assume "\<forall>c\<in>C. open c" and cover: "f`s \<subseteq> \<Union>C"
  2286   with f have "\<forall>c\<in>C. \<exists>A. open A \<and> A \<inter> s = f -` c \<inter> s"
  2287     unfolding continuous_on_open_invariant by blast
  2288   then obtain A where A: "\<forall>c\<in>C. open (A c) \<and> A c \<inter> s = f -` c \<inter> s"
  2289     unfolding bchoice_iff ..
  2290   with cover have "\<forall>c\<in>C. open (A c)" "s \<subseteq> (\<Union>c\<in>C. A c)"
  2291     by (fastforce simp add: subset_eq set_eq_iff)+
  2292   from compactE_image[OF s this] obtain D where "D \<subseteq> C" "finite D" "s \<subseteq> (\<Union>c\<in>D. A c)" .
  2293   with A show "\<exists>D \<subseteq> C. finite D \<and> f`s \<subseteq> \<Union>D"
  2294     by (intro exI[of _ D]) (fastforce simp add: subset_eq set_eq_iff)+
  2295 qed
  2296 
  2297 lemma continuous_on_inv:
  2298   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2299   assumes "continuous_on s f"
  2300     and "compact s"
  2301     and "\<forall>x\<in>s. g (f x) = x"
  2302   shows "continuous_on (f ` s) g"
  2303   unfolding continuous_on_topological
  2304 proof (clarsimp simp add: assms(3))
  2305   fix x :: 'a and B :: "'a set"
  2306   assume "x \<in> s" and "open B" and "x \<in> B"
  2307   have 1: "\<forall>x\<in>s. f x \<in> f ` (s - B) \<longleftrightarrow> x \<in> s - B"
  2308     using assms(3) by (auto, metis)
  2309   have "continuous_on (s - B) f"
  2310     using \<open>continuous_on s f\<close> Diff_subset
  2311     by (rule continuous_on_subset)
  2312   moreover have "compact (s - B)"
  2313     using \<open>open B\<close> and \<open>compact s\<close>
  2314     unfolding Diff_eq by (intro compact_Int_closed closed_Compl)
  2315   ultimately have "compact (f ` (s - B))"
  2316     by (rule compact_continuous_image)
  2317   then have "closed (f ` (s - B))"
  2318     by (rule compact_imp_closed)
  2319   then have "open (- f ` (s - B))"
  2320     by (rule open_Compl)
  2321   moreover have "f x \<in> - f ` (s - B)"
  2322     using \<open>x \<in> s\<close> and \<open>x \<in> B\<close> by (simp add: 1)
  2323   moreover have "\<forall>y\<in>s. f y \<in> - f ` (s - B) \<longrightarrow> y \<in> B"
  2324     by (simp add: 1)
  2325   ultimately show "\<exists>A. open A \<and> f x \<in> A \<and> (\<forall>y\<in>s. f y \<in> A \<longrightarrow> y \<in> B)"
  2326     by fast
  2327 qed
  2328 
  2329 lemma continuous_on_inv_into:
  2330   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2331   assumes s: "continuous_on s f" "compact s"
  2332     and f: "inj_on f s"
  2333   shows "continuous_on (f ` s) (the_inv_into s f)"
  2334   by (rule continuous_on_inv[OF s]) (auto simp: the_inv_into_f_f[OF f])
  2335 
  2336 lemma (in linorder_topology) compact_attains_sup:
  2337   assumes "compact S" "S \<noteq> {}"
  2338   shows "\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s"
  2339 proof (rule classical)
  2340   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s)"
  2341   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. s < t s"
  2342     by (metis not_le)
  2343   then have "\<forall>s\<in>S. open {..< t s}" "S \<subseteq> (\<Union>s\<in>S. {..< t s})"
  2344     by auto
  2345   with \<open>compact S\<close> obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {..< t s})"
  2346     by (erule compactE_image)
  2347   with \<open>S \<noteq> {}\<close> have Max: "Max (t`C) \<in> t`C" and "\<forall>s\<in>t`C. s \<le> Max (t`C)"
  2348     by (auto intro!: Max_in)
  2349   with C have "S \<subseteq> {..< Max (t`C)}"
  2350     by (auto intro: less_le_trans simp: subset_eq)
  2351   with t Max \<open>C \<subseteq> S\<close> show ?thesis
  2352     by fastforce
  2353 qed
  2354 
  2355 lemma (in linorder_topology) compact_attains_inf:
  2356   assumes "compact S" "S \<noteq> {}"
  2357   shows "\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t"
  2358 proof (rule classical)
  2359   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t)"
  2360   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. t s < s"
  2361     by (metis not_le)
  2362   then have "\<forall>s\<in>S. open {t s <..}" "S \<subseteq> (\<Union>s\<in>S. {t s <..})"
  2363     by auto
  2364   with \<open>compact S\<close> obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {t s <..})"
  2365     by (erule compactE_image)
  2366   with \<open>S \<noteq> {}\<close> have Min: "Min (t`C) \<in> t`C" and "\<forall>s\<in>t`C. Min (t`C) \<le> s"
  2367     by (auto intro!: Min_in)
  2368   with C have "S \<subseteq> {Min (t`C) <..}"
  2369     by (auto intro: le_less_trans simp: subset_eq)
  2370   with t Min \<open>C \<subseteq> S\<close> show ?thesis
  2371     by fastforce
  2372 qed
  2373 
  2374 lemma continuous_attains_sup:
  2375   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2376   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s.  f y \<le> f x)"
  2377   using compact_attains_sup[of "f ` s"] compact_continuous_image[of s f] by auto
  2378 
  2379 lemma continuous_attains_inf:
  2380   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2381   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s. f x \<le> f y)"
  2382   using compact_attains_inf[of "f ` s"] compact_continuous_image[of s f] by auto
  2383 
  2384 
  2385 subsection \<open>Connectedness\<close>
  2386 
  2387 context topological_space
  2388 begin
  2389 
  2390 definition "connected S \<longleftrightarrow>
  2391   \<not> (\<exists>A B. open A \<and> open B \<and> S \<subseteq> A \<union> B \<and> A \<inter> B \<inter> S = {} \<and> A \<inter> S \<noteq> {} \<and> B \<inter> S \<noteq> {})"
  2392 
  2393 lemma connectedI:
  2394   "(\<And>A B. open A \<Longrightarrow> open B \<Longrightarrow> A \<inter> U \<noteq> {} \<Longrightarrow> B \<inter> U \<noteq> {} \<Longrightarrow> A \<inter> B \<inter> U = {} \<Longrightarrow> U \<subseteq> A \<union> B \<Longrightarrow> False)
  2395   \<Longrightarrow> connected U"
  2396   by (auto simp: connected_def)
  2397 
  2398 lemma connected_empty [simp]: "connected {}"
  2399   by (auto intro!: connectedI)
  2400 
  2401 lemma connected_sing [simp]: "connected {x}"
  2402   by (auto intro!: connectedI)
  2403 
  2404 lemma connectedD:
  2405   "connected A \<Longrightarrow> open U \<Longrightarrow> open V \<Longrightarrow> U \<inter> V \<inter> A = {} \<Longrightarrow> A \<subseteq> U \<union> V \<Longrightarrow> U \<inter> A = {} \<or> V \<inter> A = {}"
  2406   by (auto simp: connected_def)
  2407 
  2408 end
  2409 
  2410 lemma connected_closed:
  2411   "connected s \<longleftrightarrow>
  2412     \<not> (\<exists>A B. closed A \<and> closed B \<and> s \<subseteq> A \<union> B \<and> A \<inter> B \<inter> s = {} \<and> A \<inter> s \<noteq> {} \<and> B \<inter> s \<noteq> {})"
  2413   apply (simp add: connected_def del: ex_simps, safe)
  2414    apply (drule_tac x="-A" in spec)
  2415    apply (drule_tac x="-B" in spec)
  2416    apply (fastforce simp add: closed_def [symmetric])
  2417   apply (drule_tac x="-A" in spec)
  2418   apply (drule_tac x="-B" in spec)
  2419   apply (fastforce simp add: open_closed [symmetric])
  2420   done
  2421 
  2422 lemma connected_closedD:
  2423   "\<lbrakk>connected s; A \<inter> B \<inter> s = {}; s \<subseteq> A \<union> B; closed A; closed B\<rbrakk> \<Longrightarrow> A \<inter> s = {} \<or> B \<inter> s = {}"
  2424   by (simp add: connected_closed)
  2425 
  2426 lemma connected_Union:
  2427   assumes cs: "\<And>s. s \<in> S \<Longrightarrow> connected s"
  2428     and ne: "\<Inter>S \<noteq> {}"
  2429   shows "connected(\<Union>S)"
  2430 proof (rule connectedI)
  2431   fix A B
  2432   assume A: "open A" and B: "open B" and Alap: "A \<inter> \<Union>S \<noteq> {}" and Blap: "B \<inter> \<Union>S \<noteq> {}"
  2433     and disj: "A \<inter> B \<inter> \<Union>S = {}" and cover: "\<Union>S \<subseteq> A \<union> B"
  2434   have disjs:"\<And>s. s \<in> S \<Longrightarrow> A \<inter> B \<inter> s = {}"
  2435     using disj by auto
  2436   obtain sa where sa: "sa \<in> S" "A \<inter> sa \<noteq> {}"
  2437     using Alap by auto
  2438   obtain sb where sb: "sb \<in> S" "B \<inter> sb \<noteq> {}"
  2439     using Blap by auto
  2440   obtain x where x: "\<And>s. s \<in> S \<Longrightarrow> x \<in> s"
  2441     using ne by auto
  2442   then have "x \<in> \<Union>S"
  2443     using \<open>sa \<in> S\<close> by blast
  2444   then have "x \<in> A \<or> x \<in> B"
  2445     using cover by auto
  2446   then show False
  2447     using cs [unfolded connected_def]
  2448     by (metis A B IntI Sup_upper sa sb disjs x cover empty_iff subset_trans)
  2449 qed
  2450 
  2451 lemma connected_Un: "connected s \<Longrightarrow> connected t \<Longrightarrow> s \<inter> t \<noteq> {} \<Longrightarrow> connected (s \<union> t)"
  2452   using connected_Union [of "{s,t}"] by auto
  2453 
  2454 lemma connected_diff_open_from_closed:
  2455   assumes st: "s \<subseteq> t"
  2456     and tu: "t \<subseteq> u"
  2457     and s: "open s"
  2458     and t: "closed t"
  2459     and u: "connected u"
  2460     and ts: "connected (t - s)"
  2461   shows "connected(u - s)"
  2462 proof (rule connectedI)
  2463   fix A B
  2464   assume AB: "open A" "open B" "A \<inter> (u - s) \<noteq> {}" "B \<inter> (u - s) \<noteq> {}"
  2465     and disj: "A \<inter> B \<inter> (u - s) = {}"
  2466     and cover: "u - s \<subseteq> A \<union> B"
  2467   then consider "A \<inter> (t - s) = {}" | "B \<inter> (t - s) = {}"
  2468     using st ts tu connectedD [of "t-s" "A" "B"] by auto
  2469   then show False
  2470   proof cases
  2471     case 1
  2472     then have "(A - t) \<inter> (B \<union> s) \<inter> u = {}"
  2473       using disj st by auto
  2474     moreover have "u \<subseteq> (A - t) \<union> (B \<union> s)"
  2475       using 1 cover by auto
  2476     ultimately show False
  2477       using connectedD [of u "A - t" "B \<union> s"] AB s t 1 u by auto
  2478   next
  2479     case 2
  2480     then have "(A \<union> s) \<inter> (B - t) \<inter> u = {}"
  2481       using disj st by auto
  2482     moreover have "u \<subseteq> (A \<union> s) \<union> (B - t)"
  2483       using 2 cover by auto
  2484     ultimately show False
  2485       using connectedD [of u "A \<union> s" "B - t"] AB s t 2 u by auto
  2486   qed
  2487 qed
  2488 
  2489 lemma connected_iff_const:
  2490   fixes S :: "'a::topological_space set"
  2491   shows "connected S \<longleftrightarrow> (\<forall>P::'a \<Rightarrow> bool. continuous_on S P \<longrightarrow> (\<exists>c. \<forall>s\<in>S. P s = c))"
  2492 proof safe
  2493   fix P :: "'a \<Rightarrow> bool"
  2494   assume "connected S" "continuous_on S P"
  2495   then have "\<And>b. \<exists>A. open A \<and> A \<inter> S = P -` {b} \<inter> S"
  2496     unfolding continuous_on_open_invariant by (simp add: open_discrete)
  2497   from this[of True] this[of False]
  2498   obtain t f where "open t" "open f" and *: "f \<inter> S = P -` {False} \<inter> S" "t \<inter> S = P -` {True} \<inter> S"
  2499     by meson
  2500   then have "t \<inter> S = {} \<or> f \<inter> S = {}"
  2501     by (intro connectedD[OF \<open>connected S\<close>])  auto
  2502   then show "\<exists>c. \<forall>s\<in>S. P s = c"
  2503   proof (rule disjE)
  2504     assume "t \<inter> S = {}"
  2505     then show ?thesis
  2506       unfolding * by (intro exI[of _ False]) auto
  2507   next
  2508     assume "f \<inter> S = {}"
  2509     then show ?thesis
  2510       unfolding * by (intro exI[of _ True]) auto
  2511   qed
  2512 next
  2513   assume P: "\<forall>P::'a \<Rightarrow> bool. continuous_on S P \<longrightarrow> (\<exists>c. \<forall>s\<in>S. P s = c)"
  2514   show "connected S"
  2515   proof (rule connectedI)
  2516     fix A B
  2517     assume *: "open A" "open B" "A \<inter> S \<noteq> {}" "B \<inter> S \<noteq> {}" "A \<inter> B \<inter> S = {}" "S \<subseteq> A \<union> B"
  2518     have "continuous_on S (\<lambda>x. x \<in> A)"
  2519       unfolding continuous_on_open_invariant
  2520     proof safe
  2521       fix C :: "bool set"
  2522       have "C = UNIV \<or> C = {True} \<or> C = {False} \<or> C = {}"
  2523         using subset_UNIV[of C] unfolding UNIV_bool by auto
  2524       with * show "\<exists>T. open T \<and> T \<inter> S = (\<lambda>x. x \<in> A) -` C \<inter> S"
  2525         by (intro exI[of _ "(if True \<in> C then A else {}) \<union> (if False \<in> C then B else {})"]) auto
  2526     qed
  2527     from P[rule_format, OF this] obtain c where "\<And>s. s \<in> S \<Longrightarrow> (s \<in> A) = c"
  2528       by blast
  2529     with * show False
  2530       by (cases c) auto
  2531   qed
  2532 qed
  2533 
  2534 lemma connectedD_const: "connected S \<Longrightarrow> continuous_on S P \<Longrightarrow> \<exists>c. \<forall>s\<in>S. P s = c"
  2535   for P :: "'a::topological_space \<Rightarrow> bool"
  2536   by (auto simp: connected_iff_const)
  2537 
  2538 lemma connectedI_const:
  2539   "(\<And>P::'a::topological_space \<Rightarrow> bool. continuous_on S P \<Longrightarrow> \<exists>c. \<forall>s\<in>S. P s = c) \<Longrightarrow> connected S"
  2540   by (auto simp: connected_iff_const)
  2541 
  2542 lemma connected_local_const:
  2543   assumes "connected A" "a \<in> A" "b \<in> A"
  2544     and *: "\<forall>a\<in>A. eventually (\<lambda>b. f a = f b) (at a within A)"
  2545   shows "f a = f b"
  2546 proof -
  2547   obtain S where S: "\<And>a. a \<in> A \<Longrightarrow> a \<in> S a" "\<And>a. a \<in> A \<Longrightarrow> open (S a)"
  2548     "\<And>a x. a \<in> A \<Longrightarrow> x \<in> S a \<Longrightarrow> x \<in> A \<Longrightarrow> f a = f x"
  2549     using * unfolding eventually_at_topological by metis
  2550   let ?P = "\<Union>b\<in>{b\<in>A. f a = f b}. S b" and ?N = "\<Union>b\<in>{b\<in>A. f a \<noteq> f b}. S b"
  2551   have "?P \<inter> A = {} \<or> ?N \<inter> A = {}"
  2552     using \<open>connected A\<close> S \<open>a\<in>A\<close>
  2553     by (intro connectedD) (auto, metis)
  2554   then show "f a = f b"
  2555   proof
  2556     assume "?N \<inter> A = {}"
  2557     then have "\<forall>x\<in>A. f a = f x"
  2558       using S(1) by auto
  2559     with \<open>b\<in>A\<close> show ?thesis by auto
  2560   next
  2561     assume "?P \<inter> A = {}" then show ?thesis
  2562       using \<open>a \<in> A\<close> S(1)[of a] by auto
  2563   qed
  2564 qed
  2565 
  2566 lemma (in linorder_topology) connectedD_interval:
  2567   assumes "connected U"
  2568     and xy: "x \<in> U" "y \<in> U"
  2569     and "x \<le> z" "z \<le> y"
  2570   shows "z \<in> U"
  2571 proof -
  2572   have eq: "{..<z} \<union> {z<..} = - {z}"
  2573     by auto
  2574   have "\<not> connected U" if "z \<notin> U" "x < z" "z < y"
  2575     using xy that
  2576     apply (simp only: connected_def simp_thms)
  2577     apply (rule_tac exI[of _ "{..< z}"])
  2578     apply (rule_tac exI[of _ "{z <..}"])
  2579     apply (auto simp add: eq)
  2580     done
  2581   with assms show "z \<in> U"
  2582     by (metis less_le)
  2583 qed
  2584 
  2585 lemma connected_continuous_image:
  2586   assumes *: "continuous_on s f"
  2587     and "connected s"
  2588   shows "connected (f ` s)"
  2589 proof (rule connectedI_const)
  2590   fix P :: "'b \<Rightarrow> bool"
  2591   assume "continuous_on (f ` s) P"
  2592   then have "continuous_on s (P \<circ> f)"
  2593     by (rule continuous_on_compose[OF *])
  2594   from connectedD_const[OF \<open>connected s\<close> this] show "\<exists>c. \<forall>s\<in>f ` s. P s = c"
  2595     by auto
  2596 qed
  2597 
  2598 
  2599 section \<open>Linear Continuum Topologies\<close>
  2600 
  2601 class linear_continuum_topology = linorder_topology + linear_continuum
  2602 begin
  2603 
  2604 lemma Inf_notin_open:
  2605   assumes A: "open A"
  2606     and bnd: "\<forall>a\<in>A. x < a"
  2607   shows "Inf A \<notin> A"
  2608 proof
  2609   assume "Inf A \<in> A"
  2610   then obtain b where "b < Inf A" "{b <.. Inf A} \<subseteq> A"
  2611     using open_left[of A "Inf A" x] assms by auto
  2612   with dense[of b "Inf A"] obtain c where "c < Inf A" "c \<in> A"
  2613     by (auto simp: subset_eq)
  2614   then show False
  2615     using cInf_lower[OF \<open>c \<in> A\<close>] bnd
  2616     by (metis not_le less_imp_le bdd_belowI)
  2617 qed
  2618 
  2619 lemma Sup_notin_open:
  2620   assumes A: "open A"
  2621     and bnd: "\<forall>a\<in>A. a < x"
  2622   shows "Sup A \<notin> A"
  2623 proof
  2624   assume "Sup A \<in> A"
  2625   with assms obtain b where "Sup A < b" "{Sup A ..< b} \<subseteq> A"
  2626     using open_right[of A "Sup A" x] by auto
  2627   with dense[of "Sup A" b] obtain c where "Sup A < c" "c \<in> A"
  2628     by (auto simp: subset_eq)
  2629   then show False
  2630     using cSup_upper[OF \<open>c \<in> A\<close>] bnd
  2631     by (metis less_imp_le not_le bdd_aboveI)
  2632 qed
  2633 
  2634 end
  2635 
  2636 instance linear_continuum_topology \<subseteq> perfect_space
  2637 proof
  2638   fix x :: 'a
  2639   obtain y where "x < y \<or> y < x"
  2640     using ex_gt_or_lt [of x] ..
  2641   with Inf_notin_open[of "{x}" y] Sup_notin_open[of "{x}" y] show "\<not> open {x}"
  2642     by auto
  2643 qed
  2644 
  2645 lemma connectedI_interval:
  2646   fixes U :: "'a :: linear_continuum_topology set"
  2647   assumes *: "\<And>x y z. x \<in> U \<Longrightarrow> y \<in> U \<Longrightarrow> x \<le> z \<Longrightarrow> z \<le> y \<Longrightarrow> z \<in> U"
  2648   shows "connected U"
  2649 proof (rule connectedI)
  2650   {
  2651     fix A B
  2652     assume "open A" "open B" "A \<inter> B \<inter> U = {}" "U \<subseteq> A \<union> B"
  2653     fix x y
  2654     assume "x < y" "x \<in> A" "y \<in> B" "x \<in> U" "y \<in> U"
  2655 
  2656     let ?z = "Inf (B \<inter> {x <..})"
  2657 
  2658     have "x \<le> ?z" "?z \<le> y"
  2659       using \<open>y \<in> B\<close> \<open>x < y\<close> by (auto intro: cInf_lower cInf_greatest)
  2660     with \<open>x \<in> U\<close> \<open>y \<in> U\<close> have "?z \<in> U"
  2661       by (rule *)
  2662     moreover have "?z \<notin> B \<inter> {x <..}"
  2663       using \<open>open B\<close> by (intro Inf_notin_open) auto
  2664     ultimately have "?z \<in> A"
  2665       using \<open>x \<le> ?z\<close> \<open>A \<inter> B \<inter> U = {}\<close> \<open>x \<in> A\<close> \<open>U \<subseteq> A \<union> B\<close> by auto
  2666     have "\<exists>b\<in>B. b \<in> A \<and> b \<in> U" if "?z < y"
  2667     proof -
  2668       obtain a where "?z < a" "{?z ..< a} \<subseteq> A"
  2669         using open_right[OF \<open>open A\<close> \<open>?z \<in> A\<close> \<open>?z < y\<close>] by auto
  2670       moreover obtain b where "b \<in> B" "x < b" "b < min a y"
  2671         using cInf_less_iff[of "B \<inter> {x <..}" "min a y"] \<open>?z < a\<close> \<open>?z < y\<close> \<open>x < y\<close> \<open>y \<in> B\<close>
  2672         by auto
  2673       moreover have "?z \<le> b"
  2674         using \<open>b \<in> B\<close> \<open>x < b\<close>
  2675         by (intro cInf_lower) auto
  2676       moreover have "b \<in> U"
  2677         using \<open>x \<le> ?z\<close> \<open>?z \<le> b\<close> \<open>b < min a y\<close>
  2678         by (intro *[OF \<open>x \<in> U\<close> \<open>y \<in> U\<close>]) (auto simp: less_imp_le)
  2679       ultimately show ?thesis
  2680         by (intro bexI[of _ b]) auto
  2681     qed
  2682     then have False
  2683       using \<open>?z \<le> y\<close> \<open>?z \<in> A\<close> \<open>y \<in> B\<close> \<open>y \<in> U\<close> \<open>A \<inter> B \<inter> U = {}\<close>
  2684       unfolding le_less by blast
  2685   }
  2686   note not_disjoint = this
  2687 
  2688   fix A B assume AB: "open A" "open B" "U \<subseteq> A \<union> B" "A \<inter> B \<inter> U = {}"
  2689   moreover assume "A \<inter> U \<noteq> {}" then obtain x where x: "x \<in> U" "x \<in> A" by auto
  2690   moreover assume "B \<inter> U \<noteq> {}" then obtain y where y: "y \<in> U" "y \<in> B" by auto
  2691   moreover note not_disjoint[of B A y x] not_disjoint[of A B x y]
  2692   ultimately show False
  2693     by (cases x y rule: linorder_cases) auto
  2694 qed
  2695 
  2696 lemma connected_iff_interval: "connected U \<longleftrightarrow> (\<forall>x\<in>U. \<forall>y\<in>U. \<forall>z. x \<le> z \<longrightarrow> z \<le> y \<longrightarrow> z \<in> U)"
  2697   for U :: "'a::linear_continuum_topology set"
  2698   by (auto intro: connectedI_interval dest: connectedD_interval)
  2699 
  2700 lemma connected_UNIV[simp]: "connected (UNIV::'a::linear_continuum_topology set)"
  2701   by (simp add: connected_iff_interval)
  2702 
  2703 lemma connected_Ioi[simp]: "connected {a<..}"
  2704   for a :: "'a::linear_continuum_topology"
  2705   by (auto simp: connected_iff_interval)
  2706 
  2707 lemma connected_Ici[simp]: "connected {a..}"
  2708   for a :: "'a::linear_continuum_topology"
  2709   by (auto simp: connected_iff_interval)
  2710 
  2711 lemma connected_Iio[simp]: "connected {..<a}"
  2712   for a :: "'a::linear_continuum_topology"
  2713   by (auto simp: connected_iff_interval)
  2714 
  2715 lemma connected_Iic[simp]: "connected {..a}"
  2716   for a :: "'a::linear_continuum_topology"
  2717   by (auto simp: connected_iff_interval)
  2718 
  2719 lemma connected_Ioo[simp]: "connected {a<..<b}"
  2720   for a b :: "'a::linear_continuum_topology"
  2721   unfolding connected_iff_interval by auto
  2722 
  2723 lemma connected_Ioc[simp]: "connected {a<..b}"
  2724   for a b :: "'a::linear_continuum_topology"
  2725   by (auto simp: connected_iff_interval)
  2726 
  2727 lemma connected_Ico[simp]: "connected {a..<b}"
  2728   for a b :: "'a::linear_continuum_topology"
  2729   by (auto simp: connected_iff_interval)
  2730 
  2731 lemma connected_Icc[simp]: "connected {a..b}"
  2732   for a b :: "'a::linear_continuum_topology"
  2733   by (auto simp: connected_iff_interval)
  2734 
  2735 lemma connected_contains_Ioo:
  2736   fixes A :: "'a :: linorder_topology set"
  2737   assumes "connected A" "a \<in> A" "b \<in> A" shows "{a <..< b} \<subseteq> A"
  2738   using connectedD_interval[OF assms] by (simp add: subset_eq Ball_def less_imp_le)
  2739 
  2740 lemma connected_contains_Icc:
  2741   fixes A :: "'a::linorder_topology set"
  2742   assumes "connected A" "a \<in> A" "b \<in> A"
  2743   shows "{a..b} \<subseteq> A"
  2744 proof
  2745   fix x assume "x \<in> {a..b}"
  2746   then have "x = a \<or> x = b \<or> x \<in> {a<..<b}"
  2747     by auto
  2748   then show "x \<in> A"
  2749     using assms connected_contains_Ioo[of A a b] by auto
  2750 qed
  2751 
  2752 
  2753 subsection \<open>Intermediate Value Theorem\<close>
  2754 
  2755 lemma IVT':
  2756   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b::linorder_topology"
  2757   assumes y: "f a \<le> y" "y \<le> f b" "a \<le> b"
  2758     and *: "continuous_on {a .. b} f"
  2759   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2760 proof -
  2761   have "connected {a..b}"
  2762     unfolding connected_iff_interval by auto
  2763   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f a" "f b" y] y
  2764   show ?thesis
  2765     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2766 qed
  2767 
  2768 lemma IVT2':
  2769   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2770   assumes y: "f b \<le> y" "y \<le> f a" "a \<le> b"
  2771     and *: "continuous_on {a .. b} f"
  2772   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2773 proof -
  2774   have "connected {a..b}"
  2775     unfolding connected_iff_interval by auto
  2776   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f b" "f a" y] y
  2777   show ?thesis
  2778     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2779 qed
  2780 
  2781 lemma IVT:
  2782   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b::linorder_topology"
  2783   shows "f a \<le> y \<Longrightarrow> y \<le> f b \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow>
  2784     \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2785   by (rule IVT') (auto intro: continuous_at_imp_continuous_on)
  2786 
  2787 lemma IVT2:
  2788   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b::linorder_topology"
  2789   shows "f b \<le> y \<Longrightarrow> y \<le> f a \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow>
  2790     \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2791   by (rule IVT2') (auto intro: continuous_at_imp_continuous_on)
  2792 
  2793 lemma continuous_inj_imp_mono:
  2794   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b::linorder_topology"
  2795   assumes x: "a < x" "x < b"
  2796     and cont: "continuous_on {a..b} f"
  2797     and inj: "inj_on f {a..b}"
  2798   shows "(f a < f x \<and> f x < f b) \<or> (f b < f x \<and> f x < f a)"
  2799 proof -
  2800   note I = inj_on_eq_iff[OF inj]
  2801   {
  2802     assume "f x < f a" "f x < f b"
  2803     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f x < f s"
  2804       using IVT'[of f x "min (f a) (f b)" b] IVT2'[of f x "min (f a) (f b)" a] x
  2805       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2806     with x I have False by auto
  2807   }
  2808   moreover
  2809   {
  2810     assume "f a < f x" "f b < f x"
  2811     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f s < f x"
  2812       using IVT'[of f a "max (f a) (f b)" x] IVT2'[of f b "max (f a) (f b)" x] x
  2813       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2814     with x I have False by auto
  2815   }
  2816   ultimately show ?thesis
  2817     using I[of a x] I[of x b] x less_trans[OF x]
  2818     by (auto simp add: le_less less_imp_neq neq_iff)
  2819 qed
  2820 
  2821 lemma continuous_at_Sup_mono:
  2822   fixes f :: "'a::{linorder_topology,conditionally_complete_linorder} \<Rightarrow>
  2823     'b::{linorder_topology,conditionally_complete_linorder}"
  2824   assumes "mono f"
  2825     and cont: "continuous (at_left (Sup S)) f"
  2826     and S: "S \<noteq> {}" "bdd_above S"
  2827   shows "f (Sup S) = (SUP s:S. f s)"
  2828 proof (rule antisym)
  2829   have f: "(f \<longlongrightarrow> f (Sup S)) (at_left (Sup S))"
  2830     using cont unfolding continuous_within .
  2831   show "f (Sup S) \<le> (SUP s:S. f s)"
  2832   proof cases
  2833     assume "Sup S \<in> S"
  2834     then show ?thesis
  2835       by (rule cSUP_upper) (auto intro: bdd_above_image_mono S \<open>mono f\<close>)
  2836   next
  2837     assume "Sup S \<notin> S"
  2838     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2839       by auto
  2840     with \<open>Sup S \<notin> S\<close> S have "s < Sup S"
  2841       unfolding less_le by (blast intro: cSup_upper)
  2842     show ?thesis
  2843     proof (rule ccontr)
  2844       assume "\<not> ?thesis"
  2845       with order_tendstoD(1)[OF f, of "SUP s:S. f s"] obtain b where "b < Sup S"
  2846         and *: "\<And>y. b < y \<Longrightarrow> y < Sup S \<Longrightarrow> (SUP s:S. f s) < f y"
  2847         by (auto simp: not_le eventually_at_left[OF \<open>s < Sup S\<close>])
  2848       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "b < c"
  2849         using less_cSupD[of S b] by auto
  2850       with \<open>Sup S \<notin> S\<close> S have "c < Sup S"
  2851         unfolding less_le by (blast intro: cSup_upper)
  2852       from *[OF \<open>b < c\<close> \<open>c < Sup S\<close>] cSUP_upper[OF \<open>c \<in> S\<close> bdd_above_image_mono[of f]]
  2853       show False
  2854         by (auto simp: assms)
  2855     qed
  2856   qed
  2857 qed (intro cSUP_least \<open>mono f\<close>[THEN monoD] cSup_upper S)
  2858 
  2859 lemma continuous_at_Sup_antimono:
  2860   fixes f :: "'a::{linorder_topology,conditionally_complete_linorder} \<Rightarrow>
  2861     'b::{linorder_topology,conditionally_complete_linorder}"
  2862   assumes "antimono f"
  2863     and cont: "continuous (at_left (Sup S)) f"
  2864     and S: "S \<noteq> {}" "bdd_above S"
  2865   shows "f (Sup S) = (INF s:S. f s)"
  2866 proof (rule antisym)
  2867   have f: "(f \<longlongrightarrow> f (Sup S)) (at_left (Sup S))"
  2868     using cont unfolding continuous_within .
  2869   show "(INF s:S. f s) \<le> f (Sup S)"
  2870   proof cases
  2871     assume "Sup S \<in> S"
  2872     then show ?thesis
  2873       by (intro cINF_lower) (auto intro: bdd_below_image_antimono S \<open>antimono f\<close>)
  2874   next
  2875     assume "Sup S \<notin> S"
  2876     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2877       by auto
  2878     with \<open>Sup S \<notin> S\<close> S have "s < Sup S"
  2879       unfolding less_le by (blast intro: cSup_upper)
  2880     show ?thesis
  2881     proof (rule ccontr)
  2882       assume "\<not> ?thesis"
  2883       with order_tendstoD(2)[OF f, of "INF s:S. f s"] obtain b where "b < Sup S"
  2884         and *: "\<And>y. b < y \<Longrightarrow> y < Sup S \<Longrightarrow> f y < (INF s:S. f s)"
  2885         by (auto simp: not_le eventually_at_left[OF \<open>s < Sup S\<close>])
  2886       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "b < c"
  2887         using less_cSupD[of S b] by auto
  2888       with \<open>Sup S \<notin> S\<close> S have "c < Sup S"
  2889         unfolding less_le by (blast intro: cSup_upper)
  2890       from *[OF \<open>b < c\<close> \<open>c < Sup S\<close>] cINF_lower[OF bdd_below_image_antimono, of f S c] \<open>c \<in> S\<close>
  2891       show False
  2892         by (auto simp: assms)
  2893     qed
  2894   qed
  2895 qed (intro cINF_greatest \<open>antimono f\<close>[THEN antimonoD] cSup_upper S)
  2896 
  2897 lemma continuous_at_Inf_mono:
  2898   fixes f :: "'a::{linorder_topology,conditionally_complete_linorder} \<Rightarrow>
  2899     'b::{linorder_topology,conditionally_complete_linorder}"
  2900   assumes "mono f"
  2901     and cont: "continuous (at_right (Inf S)) f"
  2902     and S: "S \<noteq> {}" "bdd_below S"
  2903   shows "f (Inf S) = (INF s:S. f s)"
  2904 proof (rule antisym)
  2905   have f: "(f \<longlongrightarrow> f (Inf S)) (at_right (Inf S))"
  2906     using cont unfolding continuous_within .
  2907   show "(INF s:S. f s) \<le> f (Inf S)"
  2908   proof cases
  2909     assume "Inf S \<in> S"
  2910     then show ?thesis
  2911       by (rule cINF_lower[rotated]) (auto intro: bdd_below_image_mono S \<open>mono f\<close>)
  2912   next
  2913     assume "Inf S \<notin> S"
  2914     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2915       by auto
  2916     with \<open>Inf S \<notin> S\<close> S have "Inf S < s"
  2917       unfolding less_le by (blast intro: cInf_lower)
  2918     show ?thesis
  2919     proof (rule ccontr)
  2920       assume "\<not> ?thesis"
  2921       with order_tendstoD(2)[OF f, of "INF s:S. f s"] obtain b where "Inf S < b"
  2922         and *: "\<And>y. Inf S < y \<Longrightarrow> y < b \<Longrightarrow> f y < (INF s:S. f s)"
  2923         by (auto simp: not_le eventually_at_right[OF \<open>Inf S < s\<close>])
  2924       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "c < b"
  2925         using cInf_lessD[of S b] by auto
  2926       with \<open>Inf S \<notin> S\<close> S have "Inf S < c"
  2927         unfolding less_le by (blast intro: cInf_lower)
  2928       from *[OF \<open>Inf S < c\<close> \<open>c < b\<close>] cINF_lower[OF bdd_below_image_mono[of f] \<open>c \<in> S\<close>]
  2929       show False
  2930         by (auto simp: assms)
  2931     qed
  2932   qed
  2933 qed (intro cINF_greatest \<open>mono f\<close>[THEN monoD] cInf_lower \<open>bdd_below S\<close> \<open>S \<noteq> {}\<close>)
  2934 
  2935 lemma continuous_at_Inf_antimono:
  2936   fixes f :: "'a::{linorder_topology,conditionally_complete_linorder} \<Rightarrow>
  2937     'b::{linorder_topology,conditionally_complete_linorder}"
  2938   assumes "antimono f"
  2939     and cont: "continuous (at_right (Inf S)) f"
  2940     and S: "S \<noteq> {}" "bdd_below S"
  2941   shows "f (Inf S) = (SUP s:S. f s)"
  2942 proof (rule antisym)
  2943   have f: "(f \<longlongrightarrow> f (Inf S)) (at_right (Inf S))"
  2944     using cont unfolding continuous_within .
  2945   show "f (Inf S) \<le> (SUP s:S. f s)"
  2946   proof cases
  2947     assume "Inf S \<in> S"
  2948     then show ?thesis
  2949       by (rule cSUP_upper) (auto intro: bdd_above_image_antimono S \<open>antimono f\<close>)
  2950   next
  2951     assume "Inf S \<notin> S"
  2952     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2953       by auto
  2954     with \<open>Inf S \<notin> S\<close> S have "Inf S < s"
  2955       unfolding less_le by (blast intro: cInf_lower)
  2956     show ?thesis
  2957     proof (rule ccontr)
  2958       assume "\<not> ?thesis"
  2959       with order_tendstoD(1)[OF f, of "SUP s:S. f s"] obtain b where "Inf S < b"
  2960         and *: "\<And>y. Inf S < y \<Longrightarrow> y < b \<Longrightarrow> (SUP s:S. f s) < f y"
  2961         by (auto simp: not_le eventually_at_right[OF \<open>Inf S < s\<close>])
  2962       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "c < b"
  2963         using cInf_lessD[of S b] by auto
  2964       with \<open>Inf S \<notin> S\<close> S have "Inf S < c"
  2965         unfolding less_le by (blast intro: cInf_lower)
  2966       from *[OF \<open>Inf S < c\<close> \<open>c < b\<close>] cSUP_upper[OF \<open>c \<in> S\<close> bdd_above_image_antimono[of f]]
  2967       show False
  2968         by (auto simp: assms)
  2969     qed
  2970   qed
  2971 qed (intro cSUP_least \<open>antimono f\<close>[THEN antimonoD] cInf_lower S)
  2972 
  2973 
  2974 subsection \<open>Uniform spaces\<close>
  2975 
  2976 class uniformity =
  2977   fixes uniformity :: "('a \<times> 'a) filter"
  2978 begin
  2979 
  2980 abbreviation uniformity_on :: "'a set \<Rightarrow> ('a \<times> 'a) filter"
  2981   where "uniformity_on s \<equiv> inf uniformity (principal (s\<times>s))"
  2982 
  2983 end
  2984 
  2985 lemma uniformity_Abort:
  2986   "uniformity =
  2987     Filter.abstract_filter (\<lambda>u. Code.abort (STR ''uniformity is not executable'') (\<lambda>u. uniformity))"
  2988   by simp
  2989 
  2990 class open_uniformity = "open" + uniformity +
  2991   assumes open_uniformity:
  2992     "\<And>U. open U \<longleftrightarrow> (\<forall>x\<in>U. eventually (\<lambda>(x', y). x' = x \<longrightarrow> y \<in> U) uniformity)"
  2993 
  2994 class uniform_space = open_uniformity +
  2995   assumes uniformity_refl: "eventually E uniformity \<Longrightarrow> E (x, x)"
  2996     and uniformity_sym: "eventually E uniformity \<Longrightarrow> eventually (\<lambda>(x, y). E (y, x)) uniformity"
  2997     and uniformity_trans:
  2998       "eventually E uniformity \<Longrightarrow>
  2999         \<exists>D. eventually D uniformity \<and> (\<forall>x y z. D (x, y) \<longrightarrow> D (y, z) \<longrightarrow> E (x, z))"
  3000 begin
  3001 
  3002 subclass topological_space
  3003   by standard (force elim: eventually_mono eventually_elim2 simp: split_beta' open_uniformity)+
  3004 
  3005 lemma uniformity_bot: "uniformity \<noteq> bot"
  3006   using uniformity_refl by auto
  3007 
  3008 lemma uniformity_trans':
  3009   "eventually E uniformity \<Longrightarrow>
  3010     eventually (\<lambda>((x, y), (y', z)). y = y' \<longrightarrow> E (x, z)) (uniformity \<times>\<^sub>F uniformity)"
  3011   by (drule uniformity_trans) (auto simp add: eventually_prod_same)
  3012 
  3013 lemma uniformity_transE:
  3014   assumes "eventually E uniformity"
  3015   obtains D where "eventually D uniformity" "\<And>x y z. D (x, y) \<Longrightarrow> D (y, z) \<Longrightarrow> E (x, z)"
  3016   using uniformity_trans [OF assms] by auto
  3017 
  3018 lemma eventually_nhds_uniformity:
  3019   "eventually P (nhds x) \<longleftrightarrow> eventually (\<lambda>(x', y). x' = x \<longrightarrow> P y) uniformity"
  3020   (is "_ \<longleftrightarrow> ?N P x")
  3021   unfolding eventually_nhds
  3022 proof safe
  3023   assume *: "?N P x"
  3024   have "?N (?N P) x" if "?N P x" for x
  3025   proof -
  3026     from that obtain D where ev: "eventually D uniformity"
  3027       and D: "D (a, b) \<Longrightarrow> D (b, c) \<Longrightarrow> case (a, c) of (x', y) \<Rightarrow> x' = x \<longrightarrow> P y" for a b c
  3028       by (rule uniformity_transE) simp
  3029     from ev show ?thesis
  3030       by eventually_elim (insert ev D, force elim: eventually_mono split: prod.split)
  3031   qed
  3032   then have "open {x. ?N P x}"
  3033     by (simp add: open_uniformity)
  3034   then show "\<exists>S. open S \<and> x \<in> S \<and> (\<forall>x\<in>S. P x)"
  3035     by (intro exI[of _ "{x. ?N P x}"]) (auto dest: uniformity_refl simp: *)
  3036 qed (force simp add: open_uniformity elim: eventually_mono)
  3037 
  3038 
  3039 subsubsection \<open>Totally bounded sets\<close>
  3040 
  3041 definition totally_bounded :: "'a set \<Rightarrow> bool"
  3042   where "totally_bounded S \<longleftrightarrow>
  3043     (\<forall>E. eventually E uniformity \<longrightarrow> (\<exists>X. finite X \<and> (\<forall>s\<in>S. \<exists>x\<in>X. E (x, s))))"
  3044 
  3045 lemma totally_bounded_empty[iff]: "totally_bounded {}"
  3046   by (auto simp add: totally_bounded_def)
  3047 
  3048 lemma totally_bounded_subset: "totally_bounded S \<Longrightarrow> T \<subseteq> S \<Longrightarrow> totally_bounded T"
  3049   by (fastforce simp add: totally_bounded_def)
  3050 
  3051 lemma totally_bounded_Union[intro]:
  3052   assumes M: "finite M" "\<And>S. S \<in> M \<Longrightarrow> totally_bounded S"
  3053   shows "totally_bounded (\<Union>M)"
  3054   unfolding totally_bounded_def
  3055 proof safe
  3056   fix E
  3057   assume "eventually E uniformity"
  3058   with M obtain X where "\<forall>S\<in>M. finite (X S) \<and> (\<forall>s\<in>S. \<exists>x\<in>X S. E (x, s))"
  3059     by (metis totally_bounded_def)
  3060   with \<open>finite M\<close> show "\<exists>X. finite X \<and> (\<forall>s\<in>\<Union>M. \<exists>x\<in>X. E (x, s))"
  3061     by (intro exI[of _ "\<Union>S\<in>M. X S"]) force
  3062 qed
  3063 
  3064 
  3065 subsubsection \<open>Cauchy filter\<close>
  3066 
  3067 definition cauchy_filter :: "'a filter \<Rightarrow> bool"
  3068   where "cauchy_filter F \<longleftrightarrow> F \<times>\<^sub>F F \<le> uniformity"
  3069 
  3070 definition Cauchy :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool"
  3071   where Cauchy_uniform: "Cauchy X = cauchy_filter (filtermap X sequentially)"
  3072 
  3073 lemma Cauchy_uniform_iff:
  3074   "Cauchy X \<longleftrightarrow> (\<forall>P. eventually P uniformity \<longrightarrow> (\<exists>N. \<forall>n\<ge>N. \<forall>m\<ge>N. P (X n, X m)))"
  3075   unfolding Cauchy_uniform cauchy_filter_def le_filter_def eventually_prod_same
  3076     eventually_filtermap eventually_sequentially
  3077 proof safe
  3078   let ?U = "\<lambda>P. eventually P uniformity"
  3079   {
  3080     fix P
  3081     assume "?U P" "\<forall>P. ?U P \<longrightarrow> (\<exists>Q. (\<exists>N. \<forall>n\<ge>N. Q (X n)) \<and> (\<forall>x y. Q x \<longrightarrow> Q y \<longrightarrow> P (x, y)))"
  3082     then obtain Q N where "\<And>n. n \<ge> N \<Longrightarrow> Q (X n)" "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> P (x, y)"
  3083       by metis
  3084     then show "\<exists>N. \<forall>n\<ge>N. \<forall>m\<ge>N. P (X n, X m)"
  3085       by blast
  3086   next
  3087     fix P
  3088     assume "?U P" and P: "\<forall>P. ?U P \<longrightarrow> (\<exists>N. \<forall>n\<ge>N. \<forall>m\<ge>N. P (X n, X m))"
  3089     then obtain Q where "?U Q" and Q: "\<And>x y z. Q (x, y) \<Longrightarrow> Q (y, z) \<Longrightarrow> P (x, z)"
  3090       by (auto elim: uniformity_transE)
  3091     then have "?U (\<lambda>x. Q x \<and> (\<lambda>(x, y). Q (y, x)) x)"
  3092       unfolding eventually_conj_iff by (simp add: uniformity_sym)
  3093     from P[rule_format, OF this]
  3094     obtain N where N: "\<And>n m. n \<ge> N \<Longrightarrow> m \<ge> N \<Longrightarrow> Q (X n, X m) \<and> Q (X m, X n)"
  3095       by auto
  3096     show "\<exists>Q. (\<exists>N. \<forall>n\<ge>N. Q (X n)) \<and> (\<forall>x y. Q x \<longrightarrow> Q y \<longrightarrow> P (x, y))"
  3097     proof (safe intro!: exI[of _ "\<lambda>x. \<forall>n\<ge>N. Q (x, X n) \<and> Q (X n, x)"] exI[of _ N] N)
  3098       fix x y
  3099       assume "\<forall>n\<ge>N. Q (x, X n) \<and> Q (X n, x)" "\<forall>n\<ge>N. Q (y, X n) \<and> Q (X n, y)"
  3100       then have "Q (x, X N)" "Q (X N, y)" by auto
  3101       then show "P (x, y)"
  3102         by (rule Q)
  3103     qed
  3104   }
  3105 qed
  3106 
  3107 lemma nhds_imp_cauchy_filter:
  3108   assumes *: "F \<le> nhds x"
  3109   shows "cauchy_filter F"
  3110 proof -
  3111   have "F \<times>\<^sub>F F \<le> nhds x \<times>\<^sub>F nhds x"
  3112     by (intro prod_filter_mono *)
  3113   also have "\<dots> \<le> uniformity"
  3114     unfolding le_filter_def eventually_nhds_uniformity eventually_prod_same
  3115   proof safe
  3116     fix P
  3117     assume "eventually P uniformity"
  3118     then obtain Ql where ev: "eventually Ql uniformity"
  3119       and "Ql (x, y) \<Longrightarrow> Ql (y, z) \<Longrightarrow> P (x, z)" for x y z
  3120       by (rule uniformity_transE) simp
  3121     with ev[THEN uniformity_sym]
  3122     show "\<exists>Q. eventually (\<lambda>(x', y). x' = x \<longrightarrow> Q y) uniformity \<and>
  3123         (\<forall>x y. Q x \<longrightarrow> Q y \<longrightarrow> P (x, y))"
  3124       by (rule_tac exI[of _ "\<lambda>y. Ql (y, x) \<and> Ql (x, y)"]) (fastforce elim: eventually_elim2)
  3125   qed
  3126   finally show ?thesis
  3127     by (simp add: cauchy_filter_def)
  3128 qed
  3129 
  3130 lemma LIMSEQ_imp_Cauchy: "X \<longlonglongrightarrow> x \<Longrightarrow> Cauchy X"
  3131   unfolding Cauchy_uniform filterlim_def by (intro nhds_imp_cauchy_filter)
  3132 
  3133 lemma Cauchy_subseq_Cauchy:
  3134   assumes "Cauchy X" "subseq f"
  3135   shows "Cauchy (X \<circ> f)"
  3136   unfolding Cauchy_uniform comp_def filtermap_filtermap[symmetric] cauchy_filter_def
  3137   by (rule order_trans[OF _ \<open>Cauchy X\<close>[unfolded Cauchy_uniform cauchy_filter_def]])
  3138      (intro prod_filter_mono filtermap_mono filterlim_subseq[OF \<open>subseq f\<close>, unfolded filterlim_def])
  3139 
  3140 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  3141   unfolding convergent_def by (erule exE, erule LIMSEQ_imp_Cauchy)
  3142 
  3143 definition complete :: "'a set \<Rightarrow> bool"
  3144   where complete_uniform: "complete S \<longleftrightarrow>
  3145     (\<forall>F \<le> principal S. F \<noteq> bot \<longrightarrow> cauchy_filter F \<longrightarrow> (\<exists>x\<in>S. F \<le> nhds x))"
  3146 
  3147 end
  3148 
  3149 
  3150 subsubsection \<open>Uniformly continuous functions\<close>
  3151 
  3152 definition uniformly_continuous_on :: "'a set \<Rightarrow> ('a::uniform_space \<Rightarrow> 'b::uniform_space) \<Rightarrow> bool"
  3153   where uniformly_continuous_on_uniformity: "uniformly_continuous_on s f \<longleftrightarrow>
  3154     (LIM (x, y) (uniformity_on s). (f x, f y) :> uniformity)"
  3155 
  3156 lemma uniformly_continuous_onD:
  3157   "uniformly_continuous_on s f \<Longrightarrow> eventually E uniformity \<Longrightarrow>
  3158     eventually (\<lambda>(x, y). x \<in> s \<longrightarrow> y \<in> s \<longrightarrow> E (f x, f y)) uniformity"
  3159   by (simp add: uniformly_continuous_on_uniformity filterlim_iff
  3160       eventually_inf_principal split_beta' mem_Times_iff imp_conjL)
  3161 
  3162 lemma uniformly_continuous_on_const[continuous_intros]: "uniformly_continuous_on s (\<lambda>x. c)"
  3163   by (auto simp: uniformly_continuous_on_uniformity filterlim_iff uniformity_refl)
  3164 
  3165 lemma uniformly_continuous_on_id[continuous_intros]: "uniformly_continuous_on s (\<lambda>x. x)"
  3166   by (auto simp: uniformly_continuous_on_uniformity filterlim_def)
  3167 
  3168 lemma uniformly_continuous_on_compose[continuous_intros]:
  3169   "uniformly_continuous_on s g \<Longrightarrow> uniformly_continuous_on (g`s) f \<Longrightarrow>
  3170     uniformly_continuous_on s (\<lambda>x. f (g x))"
  3171   using filterlim_compose[of "\<lambda>(x, y). (f x, f y)" uniformity
  3172       "uniformity_on (g`s)"  "\<lambda>(x, y). (g x, g y)" "uniformity_on s"]
  3173   by (simp add: split_beta' uniformly_continuous_on_uniformity
  3174       filterlim_inf filterlim_principal eventually_inf_principal mem_Times_iff)
  3175 
  3176 lemma uniformly_continuous_imp_continuous:
  3177   assumes f: "uniformly_continuous_on s f"
  3178   shows "continuous_on s f"
  3179   by (auto simp: filterlim_iff eventually_at_filter eventually_nhds_uniformity continuous_on_def
  3180            elim: eventually_mono dest!: uniformly_continuous_onD[OF f])
  3181 
  3182 
  3183 section \<open>Product Topology\<close>
  3184 
  3185 subsection \<open>Product is a topological space\<close>
  3186 
  3187 instantiation prod :: (topological_space, topological_space) topological_space
  3188 begin
  3189 
  3190 definition open_prod_def[code del]:
  3191   "open (S :: ('a \<times> 'b) set) \<longleftrightarrow>
  3192     (\<forall>x\<in>S. \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S)"
  3193 
  3194 lemma open_prod_elim:
  3195   assumes "open S" and "x \<in> S"
  3196   obtains A B where "open A" and "open B" and "x \<in> A \<times> B" and "A \<times> B \<subseteq> S"
  3197   using assms unfolding open_prod_def by fast
  3198 
  3199 lemma open_prod_intro:
  3200   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S"
  3201   shows "open S"
  3202   using assms unfolding open_prod_def by fast
  3203 
  3204 instance
  3205 proof
  3206   show "open (UNIV :: ('a \<times> 'b) set)"
  3207     unfolding open_prod_def by auto
  3208 next
  3209   fix S T :: "('a \<times> 'b) set"
  3210   assume "open S" "open T"
  3211   show "open (S \<inter> T)"
  3212   proof (rule open_prod_intro)
  3213     fix x
  3214     assume x: "x \<in> S \<inter> T"
  3215     from x have "x \<in> S" by simp
  3216     obtain Sa Sb where A: "open Sa" "open Sb" "x \<in> Sa \<times> Sb" "Sa \<times> Sb \<subseteq> S"
  3217       using \<open>open S\<close> and \<open>x \<in> S\<close> by (rule open_prod_elim)
  3218     from x have "x \<in> T" by simp
  3219     obtain Ta Tb where B: "open Ta" "open Tb" "x \<in> Ta \<times> Tb" "Ta \<times> Tb \<subseteq> T"
  3220       using \<open>open T\<close> and \<open>x \<in> T\<close> by (rule open_prod_elim)
  3221     let ?A = "Sa \<inter> Ta" and ?B = "Sb \<inter> Tb"
  3222     have "open ?A \<and> open ?B \<and> x \<in> ?A \<times> ?B \<and> ?A \<times> ?B \<subseteq> S \<inter> T"
  3223       using A B by (auto simp add: open_Int)
  3224     then show "\<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S \<inter> T"
  3225       by fast
  3226   qed
  3227 next
  3228   fix K :: "('a \<times> 'b) set set"
  3229   assume "\<forall>S\<in>K. open S"
  3230   then show "open (\<Union>K)"
  3231     unfolding open_prod_def by fast
  3232 qed
  3233 
  3234 end
  3235 
  3236 declare [[code abort: "open :: ('a::topological_space \<times> 'b::topological_space) set \<Rightarrow> bool"]]
  3237 
  3238 lemma open_Times: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<times> T)"
  3239   unfolding open_prod_def by auto
  3240 
  3241 lemma fst_vimage_eq_Times: "fst -` S = S \<times> UNIV"
  3242   by auto
  3243 
  3244 lemma snd_vimage_eq_Times: "snd -` S = UNIV \<times> S"
  3245   by auto
  3246 
  3247 lemma open_vimage_fst: "open S \<Longrightarrow> open (fst -` S)"
  3248   by (simp add: fst_vimage_eq_Times open_Times)
  3249 
  3250 lemma open_vimage_snd: "open S \<Longrightarrow> open (snd -` S)"
  3251   by (simp add: snd_vimage_eq_Times open_Times)
  3252 
  3253 lemma closed_vimage_fst: "closed S \<Longrightarrow> closed (fst -` S)"
  3254   unfolding closed_open vimage_Compl [symmetric]
  3255   by (rule open_vimage_fst)
  3256 
  3257 lemma closed_vimage_snd: "closed S \<Longrightarrow> closed (snd -` S)"
  3258   unfolding closed_open vimage_Compl [symmetric]
  3259   by (rule open_vimage_snd)
  3260 
  3261 lemma closed_Times: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
  3262 proof -
  3263   have "S \<times> T = (fst -` S) \<inter> (snd -` T)"
  3264     by auto
  3265   then show "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
  3266     by (simp add: closed_vimage_fst closed_vimage_snd closed_Int)
  3267 qed
  3268 
  3269 lemma subset_fst_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> y \<in> B \<Longrightarrow> A \<subseteq> fst ` S"
  3270   unfolding image_def subset_eq by force
  3271 
  3272 lemma subset_snd_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> x \<in> A \<Longrightarrow> B \<subseteq> snd ` S"
  3273   unfolding image_def subset_eq by force
  3274 
  3275 lemma open_image_fst:
  3276   assumes "open S"
  3277   shows "open (fst ` S)"
  3278 proof (rule openI)
  3279   fix x
  3280   assume "x \<in> fst ` S"
  3281   then obtain y where "(x, y) \<in> S"
  3282     by auto
  3283   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
  3284     using \<open>open S\<close> unfolding open_prod_def by auto
  3285   from \<open>A \<times> B \<subseteq> S\<close> \<open>y \<in> B\<close> have "A \<subseteq> fst ` S"
  3286     by (rule subset_fst_imageI)
  3287   with \<open>open A\<close> \<open>x \<in> A\<close> have "open A \<and> x \<in> A \<and> A \<subseteq> fst ` S"
  3288     by simp
  3289   then show "\<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> fst ` S" ..
  3290 qed
  3291 
  3292 lemma open_image_snd:
  3293   assumes "open S"
  3294   shows "open (snd ` S)"
  3295 proof (rule openI)
  3296   fix y
  3297   assume "y \<in> snd ` S"
  3298   then obtain x where "(x, y) \<in> S"
  3299     by auto
  3300   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
  3301     using \<open>open S\<close> unfolding open_prod_def by auto
  3302   from \<open>A \<times> B \<subseteq> S\<close> \<open>x \<in> A\<close> have "B \<subseteq> snd ` S"
  3303     by (rule subset_snd_imageI)
  3304   with \<open>open B\<close> \<open>y \<in> B\<close> have "open B \<and> y \<in> B \<and> B \<subseteq> snd ` S"
  3305     by simp
  3306   then show "\<exists>T. open T \<and> y \<in> T \<and> T \<subseteq> snd ` S" ..
  3307 qed
  3308 
  3309 lemma nhds_prod: "nhds (a, b) = nhds a \<times>\<^sub>F nhds b"
  3310   unfolding nhds_def
  3311 proof (subst prod_filter_INF, auto intro!: antisym INF_greatest simp: principal_prod_principal)
  3312   fix S T
  3313   assume "open S" "a \<in> S" "open T" "b \<in> T"
  3314   then show "(INF x : {S. open S \<and> (a, b) \<in> S}. principal x) \<le> principal (S \<times> T)"
  3315     by (intro INF_lower) (auto intro!: open_Times)
  3316 next
  3317   fix S'
  3318   assume "open S'" "(a, b) \<in> S'"
  3319   then obtain S T where "open S" "a \<in> S" "open T" "b \<in> T" "S \<times> T \<subseteq> S'"
  3320     by (auto elim: open_prod_elim)
  3321   then show "(INF x : {S. open S \<and> a \<in> S}. INF y : {S. open S \<and> b \<in> S}.
  3322       principal (x \<times> y)) \<le> principal S'"
  3323     by (auto intro!: INF_lower2)
  3324 qed
  3325 
  3326 
  3327 subsubsection \<open>Continuity of operations\<close>
  3328 
  3329 lemma tendsto_fst [tendsto_intros]:
  3330   assumes "(f \<longlongrightarrow> a) F"
  3331   shows "((\<lambda>x. fst (f x)) \<longlongrightarrow> fst a) F"
  3332 proof (rule topological_tendstoI)
  3333   fix S
  3334   assume "open S" and "fst a \<in> S"
  3335   then have "open (fst -` S)" and "a \<in> fst -` S"
  3336     by (simp_all add: open_vimage_fst)
  3337   with assms have "eventually (\<lambda>x. f x \<in> fst -` S) F"
  3338     by (rule topological_tendstoD)
  3339   then show "eventually (\<lambda>x. fst (f x) \<in> S) F"
  3340     by simp
  3341 qed
  3342 
  3343 lemma tendsto_snd [tendsto_intros]:
  3344   assumes "(f \<longlongrightarrow> a) F"
  3345   shows "((\<lambda>x. snd (f x)) \<longlongrightarrow> snd a) F"
  3346 proof (rule topological_tendstoI)
  3347   fix S
  3348   assume "open S" and "snd a \<in> S"
  3349   then have "open (snd -` S)" and "a \<in> snd -` S"
  3350     by (simp_all add: open_vimage_snd)
  3351   with assms have "eventually (\<lambda>x. f x \<in> snd -` S) F"
  3352     by (rule topological_tendstoD)
  3353   then show "eventually (\<lambda>x. snd (f x) \<in> S) F"
  3354     by simp
  3355 qed
  3356 
  3357 lemma tendsto_Pair [tendsto_intros]:
  3358   assumes "(f \<longlongrightarrow> a) F" and "(g \<longlongrightarrow> b) F"
  3359   shows "((\<lambda>x. (f x, g x)) \<longlongrightarrow> (a, b)) F"
  3360 proof (rule topological_tendstoI)
  3361   fix S
  3362   assume "open S" and "(a, b) \<in> S"
  3363   then obtain A B where "open A" "open B" "a \<in> A" "b \<in> B" "A \<times> B \<subseteq> S"
  3364     unfolding open_prod_def by fast
  3365   have "eventually (\<lambda>x. f x \<in> A) F"
  3366     using \<open>(f \<longlongrightarrow> a) F\<close> \<open>open A\<close> \<open>a \<in> A\<close>
  3367     by (rule topological_tendstoD)
  3368   moreover
  3369   have "eventually (\<lambda>x. g x \<in> B) F"
  3370     using \<open>(g \<longlongrightarrow> b) F\<close> \<open>open B\<close> \<open>b \<in> B\<close>
  3371     by (rule topological_tendstoD)
  3372   ultimately
  3373   show "eventually (\<lambda>x. (f x, g x) \<in> S) F"
  3374     by (rule eventually_elim2)
  3375        (simp add: subsetD [OF \<open>A \<times> B \<subseteq> S\<close>])
  3376 qed
  3377 
  3378 lemma continuous_fst[continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. fst (f x))"
  3379   unfolding continuous_def by (rule tendsto_fst)
  3380 
  3381 lemma continuous_snd[continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. snd (f x))"
  3382   unfolding continuous_def by (rule tendsto_snd)
  3383 
  3384 lemma continuous_Pair[continuous_intros]:
  3385   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. (f x, g x))"
  3386   unfolding continuous_def by (rule tendsto_Pair)
  3387 
  3388 lemma continuous_on_fst[continuous_intros]:
  3389   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. fst (f x))"
  3390   unfolding continuous_on_def by (auto intro: tendsto_fst)
  3391 
  3392 lemma continuous_on_snd[continuous_intros]:
  3393   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. snd (f x))"
  3394   unfolding continuous_on_def by (auto intro: tendsto_snd)
  3395 
  3396 lemma continuous_on_Pair[continuous_intros]:
  3397   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. (f x, g x))"
  3398   unfolding continuous_on_def by (auto intro: tendsto_Pair)
  3399 
  3400 lemma continuous_on_swap[continuous_intros]: "continuous_on A prod.swap"
  3401   by (simp add: prod.swap_def continuous_on_fst continuous_on_snd
  3402       continuous_on_Pair continuous_on_id)
  3403 
  3404 lemma continuous_on_swap_args:
  3405   assumes "continuous_on (A\<times>B) (\<lambda>(x,y). d x y)"
  3406     shows "continuous_on (B\<times>A) (\<lambda>(x,y). d y x)"
  3407 proof -
  3408   have "(\<lambda>(x,y). d y x) = (\<lambda>(x,y). d x y) \<circ> prod.swap"
  3409     by force
  3410   then show ?thesis
  3411     apply (rule ssubst)
  3412     apply (rule continuous_on_compose)
  3413      apply (force intro: continuous_on_subset [OF continuous_on_swap])
  3414     apply (force intro: continuous_on_subset [OF assms])
  3415     done
  3416 qed
  3417 
  3418 lemma isCont_fst [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. fst (f x)) a"
  3419   by (fact continuous_fst)
  3420 
  3421 lemma isCont_snd [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. snd (f x)) a"
  3422   by (fact continuous_snd)
  3423 
  3424 lemma isCont_Pair [simp]: "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. (f x, g x)) a"
  3425   by (fact continuous_Pair)
  3426 
  3427 
  3428 subsubsection \<open>Separation axioms\<close>
  3429 
  3430 instance prod :: (t0_space, t0_space) t0_space
  3431 proof
  3432   fix x y :: "'a \<times> 'b"
  3433   assume "x \<noteq> y"
  3434   then have "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
  3435     by (simp add: prod_eq_iff)
  3436   then show "\<exists>U. open U \<and> (x \<in> U) \<noteq> (y \<in> U)"
  3437     by (fast dest: t0_space elim: open_vimage_fst open_vimage_snd)
  3438 qed
  3439 
  3440 instance prod :: (t1_space, t1_space) t1_space
  3441 proof
  3442   fix x y :: "'a \<times> 'b"
  3443   assume "x \<noteq> y"
  3444   then have "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
  3445     by (simp add: prod_eq_iff)
  3446   then show "\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
  3447     by (fast dest: t1_space elim: open_vimage_fst open_vimage_snd)
  3448 qed
  3449 
  3450 instance prod :: (t2_space, t2_space) t2_space
  3451 proof
  3452   fix x y :: "'a \<times> 'b"
  3453   assume "x \<noteq> y"
  3454   then have "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
  3455     by (simp add: prod_eq_iff)
  3456   then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
  3457     by (fast dest: hausdorff elim: open_vimage_fst open_vimage_snd)
  3458 qed
  3459 
  3460 lemma isCont_swap[continuous_intros]: "isCont prod.swap a"
  3461   using continuous_on_eq_continuous_within continuous_on_swap by blast
  3462 
  3463 lemma open_diagonal_complement:
  3464   "open {(x,y) | x y. x \<noteq> (y::('a::t2_space))}"
  3465 proof (rule topological_space_class.openI)
  3466   fix t assume "t \<in> {(x, y) | x y. x \<noteq> (y::'a)}"
  3467   then obtain x y where "t = (x,y)" "x \<noteq> y" by blast
  3468   then obtain U V where *: "open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
  3469     by (auto simp add: separation_t2)
  3470   define T where "T = U \<times> V"
  3471   have "open T" using * open_Times T_def by auto
  3472   moreover have "t \<in> T" unfolding T_def using `t = (x,y)` * by auto
  3473   moreover have "T \<subseteq> {(x, y) | x y. x \<noteq> y}" unfolding T_def using * by auto
  3474   ultimately show "\<exists>T. open T \<and> t \<in> T \<and> T \<subseteq> {(x, y) | x y. x \<noteq> y}" by auto
  3475 qed
  3476 
  3477 lemma closed_diagonal:
  3478   "closed {y. \<exists> x::('a::t2_space). y = (x,x)}"
  3479 proof -
  3480   have "{y. \<exists> x::'a. y = (x,x)} = UNIV - {(x,y) | x y. x \<noteq> y}" by auto
  3481   then show ?thesis using open_diagonal_complement closed_Diff by auto
  3482 qed
  3483 
  3484 lemma open_superdiagonal:
  3485   "open {(x,y) | x y. x > (y::'a::{linorder_topology})}"
  3486 proof (rule topological_space_class.openI)
  3487   fix t assume "t \<in> {(x, y) | x y. y < (x::'a)}"
  3488   then obtain x y where "t = (x, y)" "x > y" by blast
  3489   show "\<exists>T. open T \<and> t \<in> T \<and> T \<subseteq> {(x, y) | x y. y < x}"
  3490   proof (cases)
  3491     assume "\<exists>z. y < z \<and> z < x"
  3492     then obtain z where z: "y < z \<and> z < x" by blast
  3493     define T where "T = {z<..} \<times> {..<z}"
  3494     have "open T" unfolding T_def by (simp add: open_Times)
  3495     moreover have "t \<in> T" using T_def z `t = (x,y)` by auto
  3496     moreover have "T \<subseteq> {(x, y) | x y. y < x}" unfolding T_def by auto
  3497     ultimately show ?thesis by auto
  3498   next
  3499     assume "\<not>(\<exists>z. y < z \<and> z < x)"
  3500     then have *: "{x ..} = {y<..}" "{..< x} = {..y}"
  3501       using `x > y` apply auto using leI by blast
  3502     define T where "T = {x ..} \<times> {.. y}"
  3503     then have "T = {y<..} \<times> {..< x}" using * by simp
  3504     then have "open T" unfolding T_def by (simp add: open_Times)
  3505     moreover have "t \<in> T" using T_def `t = (x,y)` by auto
  3506     moreover have "T \<subseteq> {(x, y) | x y. y < x}" unfolding T_def using `x > y` by auto
  3507     ultimately show ?thesis by auto
  3508   qed
  3509 qed
  3510 
  3511 lemma closed_subdiagonal:
  3512   "closed {(x,y) | x y. x \<le> (y::'a::{linorder_topology})}"
  3513 proof -
  3514   have "{(x,y) | x y. x \<le> (y::'a)} = UNIV - {(x,y) | x y. x > (y::'a)}" by auto
  3515   then show ?thesis using open_superdiagonal closed_Diff by auto
  3516 qed
  3517 
  3518 lemma open_subdiagonal:
  3519   "open {(x,y) | x y. x < (y::'a::{linorder_topology})}"
  3520 proof (rule topological_space_class.openI)
  3521   fix t assume "t \<in> {(x, y) | x y. y > (x::'a)}"
  3522   then obtain x y where "t = (x, y)" "x < y" by blast
  3523   show "\<exists>T. open T \<and> t \<in> T \<and> T \<subseteq> {(x, y) | x y. y > x}"
  3524   proof (cases)
  3525     assume "\<exists>z. y > z \<and> z > x"
  3526     then obtain z where z: "y > z \<and> z > x" by blast
  3527     define T where "T = {..<z} \<times> {z<..}"
  3528     have "open T" unfolding T_def by (simp add: open_Times)
  3529     moreover have "t \<in> T" using T_def z `t = (x,y)` by auto
  3530     moreover have "T \<subseteq> {(x, y) |x y. y > x}" unfolding T_def by auto
  3531     ultimately show ?thesis by auto
  3532   next
  3533     assume "\<not>(\<exists>z. y > z \<and> z > x)"
  3534     then have *: "{..x} = {..<y}" "{x<..} = {y..}"
  3535       using `x < y` apply auto using leI by blast
  3536     define T where "T = {..x} \<times> {y..}"
  3537     then have "T = {..<y} \<times> {x<..}" using * by simp
  3538     then have "open T" unfolding T_def by (simp add: open_Times)
  3539     moreover have "t \<in> T" using T_def `t = (x,y)` by auto
  3540     moreover have "T \<subseteq> {(x, y) |x y. y > x}" unfolding T_def using `x < y` by auto
  3541     ultimately show ?thesis by auto
  3542   qed
  3543 qed
  3544 
  3545 lemma closed_superdiagonal:
  3546   "closed {(x,y) | x y. x \<ge> (y::('a::{linorder_topology}))}"
  3547 proof -
  3548   have "{(x,y) | x y. x \<ge> (y::'a)} = UNIV - {(x,y) | x y. x < y}" by auto
  3549   then show ?thesis using open_subdiagonal closed_Diff by auto
  3550 qed
  3551 
  3552 end