src/HOL/Series.thy
author huffman
Thu Aug 11 09:11:15 2011 -0700 (2011-08-11)
changeset 44165 d26a45f3c835
parent 41970 47d6e13d1710
child 44282 f0de18b62d63
permissions -rw-r--r--
remove lemma stupid_ext
     1 (*  Title       : Series.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4 
     5 Converted to Isar and polished by lcp
     6 Converted to setsum and polished yet more by TNN
     7 Additional contributions by Jeremy Avigad
     8 *)
     9 
    10 header{*Finite Summation and Infinite Series*}
    11 
    12 theory Series
    13 imports SEQ Deriv
    14 begin
    15 
    16 definition
    17    sums  :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> 'a \<Rightarrow> bool"
    18      (infixr "sums" 80) where
    19    "f sums s = (%n. setsum f {0..<n}) ----> s"
    20 
    21 definition
    22    summable :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> bool" where
    23    "summable f = (\<exists>s. f sums s)"
    24 
    25 definition
    26    suminf   :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> 'a" where
    27    "suminf f = (THE s. f sums s)"
    28 
    29 syntax
    30   "_suminf" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a" ("\<Sum>_. _" [0, 10] 10)
    31 translations
    32   "\<Sum>i. b" == "CONST suminf (%i. b)"
    33 
    34 
    35 lemma [trans]: "f=g ==> g sums z ==> f sums z"
    36   by simp
    37 
    38 lemma sumr_diff_mult_const:
    39  "setsum f {0..<n} - (real n*r) = setsum (%i. f i - r) {0..<n::nat}"
    40 by (simp add: diff_minus setsum_addf real_of_nat_def)
    41 
    42 lemma real_setsum_nat_ivl_bounded:
    43      "(!!p. p < n \<Longrightarrow> f(p) \<le> K)
    44       \<Longrightarrow> setsum f {0..<n::nat} \<le> real n * K"
    45 using setsum_bounded[where A = "{0..<n}"]
    46 by (auto simp:real_of_nat_def)
    47 
    48 (* Generalize from real to some algebraic structure? *)
    49 lemma sumr_minus_one_realpow_zero [simp]:
    50   "(\<Sum>i=0..<2*n. (-1) ^ Suc i) = (0::real)"
    51 by (induct "n", auto)
    52 
    53 (* FIXME this is an awful lemma! *)
    54 lemma sumr_one_lb_realpow_zero [simp]:
    55   "(\<Sum>n=Suc 0..<n. f(n) * (0::real) ^ n) = 0"
    56 by (rule setsum_0', simp)
    57 
    58 lemma sumr_group:
    59      "(\<Sum>m=0..<n::nat. setsum f {m * k ..< m*k + k}) = setsum f {0 ..< n * k}"
    60 apply (subgoal_tac "k = 0 | 0 < k", auto)
    61 apply (induct "n")
    62 apply (simp_all add: setsum_add_nat_ivl add_commute)
    63 done
    64 
    65 lemma sumr_offset3:
    66   "setsum f {0::nat..<n+k} = (\<Sum>m=0..<n. f (m+k)) + setsum f {0..<k}"
    67 apply (subst setsum_shift_bounds_nat_ivl [symmetric])
    68 apply (simp add: setsum_add_nat_ivl add_commute)
    69 done
    70 
    71 lemma sumr_offset:
    72   fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
    73   shows "(\<Sum>m=0..<n. f(m+k)) = setsum f {0..<n+k} - setsum f {0..<k}"
    74 by (simp add: sumr_offset3)
    75 
    76 lemma sumr_offset2:
    77  "\<forall>f. (\<Sum>m=0..<n::nat. f(m+k)::real) = setsum f {0..<n+k} - setsum f {0..<k}"
    78 by (simp add: sumr_offset)
    79 
    80 lemma sumr_offset4:
    81   "\<forall>n f. setsum f {0::nat..<n+k} = (\<Sum>m=0..<n. f (m+k)::real) + setsum f {0..<k}"
    82 by (clarify, rule sumr_offset3)
    83 
    84 subsection{* Infinite Sums, by the Properties of Limits*}
    85 
    86 (*----------------------
    87    suminf is the sum
    88  ---------------------*)
    89 lemma sums_summable: "f sums l ==> summable f"
    90   by (simp add: sums_def summable_def, blast)
    91 
    92 lemma summable_sums:
    93   fixes f :: "nat \<Rightarrow> 'a::{t2_space, comm_monoid_add}" assumes "summable f" shows "f sums (suminf f)"
    94 proof -
    95   from assms guess s unfolding summable_def sums_def_raw .. note s = this
    96   then show ?thesis unfolding sums_def_raw suminf_def
    97     by (rule theI, auto intro!: tendsto_unique[OF trivial_limit_sequentially])
    98 qed
    99 
   100 lemma summable_sumr_LIMSEQ_suminf:
   101   fixes f :: "nat \<Rightarrow> 'a::{t2_space, comm_monoid_add}"
   102   shows "summable f \<Longrightarrow> (\<lambda>n. setsum f {0..<n}) ----> suminf f"
   103 by (rule summable_sums [unfolded sums_def])
   104 
   105 lemma suminf_eq_lim: "suminf f = lim (%n. setsum f {0..<n})"
   106   by (simp add: suminf_def sums_def lim_def)
   107 
   108 (*-------------------
   109     sum is unique
   110  ------------------*)
   111 lemma sums_unique:
   112   fixes f :: "nat \<Rightarrow> 'a::{t2_space, comm_monoid_add}"
   113   shows "f sums s \<Longrightarrow> (s = suminf f)"
   114 apply (frule sums_summable[THEN summable_sums])
   115 apply (auto intro!: tendsto_unique[OF trivial_limit_sequentially] simp add: sums_def)
   116 done
   117 
   118 lemma sums_iff:
   119   fixes f :: "nat \<Rightarrow> 'a::{t2_space, comm_monoid_add}"
   120   shows "f sums x \<longleftrightarrow> summable f \<and> (suminf f = x)"
   121   by (metis summable_sums sums_summable sums_unique)
   122 
   123 lemma sums_split_initial_segment:
   124   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   125   shows "f sums s ==> (\<lambda>n. f(n + k)) sums (s - (SUM i = 0..< k. f i))"
   126   apply (unfold sums_def)
   127   apply (simp add: sumr_offset)
   128   apply (rule LIMSEQ_diff_const)
   129   apply (rule LIMSEQ_ignore_initial_segment)
   130   apply assumption
   131 done
   132 
   133 lemma summable_ignore_initial_segment:
   134   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   135   shows "summable f ==> summable (%n. f(n + k))"
   136   apply (unfold summable_def)
   137   apply (auto intro: sums_split_initial_segment)
   138 done
   139 
   140 lemma suminf_minus_initial_segment:
   141   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   142   shows "summable f ==>
   143     suminf f = s ==> suminf (%n. f(n + k)) = s - (SUM i = 0..< k. f i)"
   144   apply (frule summable_ignore_initial_segment)
   145   apply (rule sums_unique [THEN sym])
   146   apply (frule summable_sums)
   147   apply (rule sums_split_initial_segment)
   148   apply auto
   149 done
   150 
   151 lemma suminf_split_initial_segment:
   152   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   153   shows "summable f ==>
   154     suminf f = (SUM i = 0..< k. f i) + (\<Sum>n. f(n + k))"
   155 by (auto simp add: suminf_minus_initial_segment)
   156 
   157 lemma suminf_exist_split: fixes r :: real assumes "0 < r" and "summable a"
   158   shows "\<exists> N. \<forall> n \<ge> N. \<bar> \<Sum> i. a (i + n) \<bar> < r"
   159 proof -
   160   from LIMSEQ_D[OF summable_sumr_LIMSEQ_suminf[OF `summable a`] `0 < r`]
   161   obtain N :: nat where "\<forall> n \<ge> N. norm (setsum a {0..<n} - suminf a) < r" by auto
   162   thus ?thesis unfolding suminf_minus_initial_segment[OF `summable a` refl] abs_minus_commute real_norm_def
   163     by auto
   164 qed
   165 
   166 lemma sums_Suc:
   167   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   168   assumes sumSuc: "(\<lambda> n. f (Suc n)) sums l" shows "f sums (l + f 0)"
   169 proof -
   170   from sumSuc[unfolded sums_def]
   171   have "(\<lambda>i. \<Sum>n = Suc 0..<Suc i. f n) ----> l" unfolding setsum_reindex[OF inj_Suc] image_Suc_atLeastLessThan[symmetric] comp_def .
   172   from LIMSEQ_add_const[OF this, where b="f 0"]
   173   have "(\<lambda>i. \<Sum>n = 0..<Suc i. f n) ----> l + f 0" unfolding add_commute setsum_head_upt_Suc[OF zero_less_Suc] .
   174   thus ?thesis unfolding sums_def by (rule LIMSEQ_imp_Suc)
   175 qed
   176 
   177 lemma series_zero:
   178   fixes f :: "nat \<Rightarrow> 'a::{t2_space, comm_monoid_add}"
   179   assumes "\<forall>m. n \<le> m \<longrightarrow> f m = 0"
   180   shows "f sums (setsum f {0..<n})"
   181 proof -
   182   { fix k :: nat have "setsum f {0..<k + n} = setsum f {0..<n}"
   183       using assms by (induct k) auto }
   184   note setsum_const = this
   185   show ?thesis
   186     unfolding sums_def
   187     apply (rule LIMSEQ_offset[of _ n])
   188     unfolding setsum_const
   189     apply (rule LIMSEQ_const)
   190     done
   191 qed
   192 
   193 lemma sums_zero[simp, intro]: "(\<lambda>n. 0) sums 0"
   194 unfolding sums_def by (simp add: LIMSEQ_const)
   195 
   196 lemma summable_zero[simp, intro]: "summable (\<lambda>n. 0)"
   197 by (rule sums_zero [THEN sums_summable])
   198 
   199 lemma suminf_zero[simp]: "suminf (\<lambda>n. 0::'a::{t2_space, comm_monoid_add}) = 0"
   200 by (rule sums_zero [THEN sums_unique, symmetric])
   201 
   202 lemma (in bounded_linear) sums:
   203   "(\<lambda>n. X n) sums a \<Longrightarrow> (\<lambda>n. f (X n)) sums (f a)"
   204 unfolding sums_def by (drule LIMSEQ, simp only: setsum)
   205 
   206 lemma (in bounded_linear) summable:
   207   "summable (\<lambda>n. X n) \<Longrightarrow> summable (\<lambda>n. f (X n))"
   208 unfolding summable_def by (auto intro: sums)
   209 
   210 lemma (in bounded_linear) suminf:
   211   "summable (\<lambda>n. X n) \<Longrightarrow> f (\<Sum>n. X n) = (\<Sum>n. f (X n))"
   212 by (intro sums_unique sums summable_sums)
   213 
   214 lemma sums_mult:
   215   fixes c :: "'a::real_normed_algebra"
   216   shows "f sums a \<Longrightarrow> (\<lambda>n. c * f n) sums (c * a)"
   217 by (rule mult_right.sums)
   218 
   219 lemma summable_mult:
   220   fixes c :: "'a::real_normed_algebra"
   221   shows "summable f \<Longrightarrow> summable (%n. c * f n)"
   222 by (rule mult_right.summable)
   223 
   224 lemma suminf_mult:
   225   fixes c :: "'a::real_normed_algebra"
   226   shows "summable f \<Longrightarrow> suminf (\<lambda>n. c * f n) = c * suminf f"
   227 by (rule mult_right.suminf [symmetric])
   228 
   229 lemma sums_mult2:
   230   fixes c :: "'a::real_normed_algebra"
   231   shows "f sums a \<Longrightarrow> (\<lambda>n. f n * c) sums (a * c)"
   232 by (rule mult_left.sums)
   233 
   234 lemma summable_mult2:
   235   fixes c :: "'a::real_normed_algebra"
   236   shows "summable f \<Longrightarrow> summable (\<lambda>n. f n * c)"
   237 by (rule mult_left.summable)
   238 
   239 lemma suminf_mult2:
   240   fixes c :: "'a::real_normed_algebra"
   241   shows "summable f \<Longrightarrow> suminf f * c = (\<Sum>n. f n * c)"
   242 by (rule mult_left.suminf)
   243 
   244 lemma sums_divide:
   245   fixes c :: "'a::real_normed_field"
   246   shows "f sums a \<Longrightarrow> (\<lambda>n. f n / c) sums (a / c)"
   247 by (rule divide.sums)
   248 
   249 lemma summable_divide:
   250   fixes c :: "'a::real_normed_field"
   251   shows "summable f \<Longrightarrow> summable (\<lambda>n. f n / c)"
   252 by (rule divide.summable)
   253 
   254 lemma suminf_divide:
   255   fixes c :: "'a::real_normed_field"
   256   shows "summable f \<Longrightarrow> suminf (\<lambda>n. f n / c) = suminf f / c"
   257 by (rule divide.suminf [symmetric])
   258 
   259 lemma sums_add:
   260   fixes a b :: "'a::real_normed_field"
   261   shows "\<lbrakk>X sums a; Y sums b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n + Y n) sums (a + b)"
   262 unfolding sums_def by (simp add: setsum_addf LIMSEQ_add)
   263 
   264 lemma summable_add:
   265   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
   266   shows "\<lbrakk>summable X; summable Y\<rbrakk> \<Longrightarrow> summable (\<lambda>n. X n + Y n)"
   267 unfolding summable_def by (auto intro: sums_add)
   268 
   269 lemma suminf_add:
   270   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
   271   shows "\<lbrakk>summable X; summable Y\<rbrakk> \<Longrightarrow> suminf X + suminf Y = (\<Sum>n. X n + Y n)"
   272 by (intro sums_unique sums_add summable_sums)
   273 
   274 lemma sums_diff:
   275   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
   276   shows "\<lbrakk>X sums a; Y sums b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n - Y n) sums (a - b)"
   277 unfolding sums_def by (simp add: setsum_subtractf LIMSEQ_diff)
   278 
   279 lemma summable_diff:
   280   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
   281   shows "\<lbrakk>summable X; summable Y\<rbrakk> \<Longrightarrow> summable (\<lambda>n. X n - Y n)"
   282 unfolding summable_def by (auto intro: sums_diff)
   283 
   284 lemma suminf_diff:
   285   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
   286   shows "\<lbrakk>summable X; summable Y\<rbrakk> \<Longrightarrow> suminf X - suminf Y = (\<Sum>n. X n - Y n)"
   287 by (intro sums_unique sums_diff summable_sums)
   288 
   289 lemma sums_minus:
   290   fixes X :: "nat \<Rightarrow> 'a::real_normed_field"
   291   shows "X sums a ==> (\<lambda>n. - X n) sums (- a)"
   292 unfolding sums_def by (simp add: setsum_negf LIMSEQ_minus)
   293 
   294 lemma summable_minus:
   295   fixes X :: "nat \<Rightarrow> 'a::real_normed_field"
   296   shows "summable X \<Longrightarrow> summable (\<lambda>n. - X n)"
   297 unfolding summable_def by (auto intro: sums_minus)
   298 
   299 lemma suminf_minus:
   300   fixes X :: "nat \<Rightarrow> 'a::real_normed_field"
   301   shows "summable X \<Longrightarrow> (\<Sum>n. - X n) = - (\<Sum>n. X n)"
   302 by (intro sums_unique [symmetric] sums_minus summable_sums)
   303 
   304 lemma sums_group:
   305   fixes f :: "nat \<Rightarrow> 'a::real_normed_field"
   306   shows "[|summable f; 0 < k |] ==> (%n. setsum f {n*k..<n*k+k}) sums (suminf f)"
   307 apply (drule summable_sums)
   308 apply (simp only: sums_def sumr_group)
   309 apply (unfold LIMSEQ_iff, safe)
   310 apply (drule_tac x="r" in spec, safe)
   311 apply (rule_tac x="no" in exI, safe)
   312 apply (drule_tac x="n*k" in spec)
   313 apply (erule mp)
   314 apply (erule order_trans)
   315 apply simp
   316 done
   317 
   318 text{*A summable series of positive terms has limit that is at least as
   319 great as any partial sum.*}
   320 
   321 lemma pos_summable:
   322   fixes f:: "nat \<Rightarrow> real"
   323   assumes pos: "!!n. 0 \<le> f n" and le: "!!n. setsum f {0..<n} \<le> x"
   324   shows "summable f"
   325 proof -
   326   have "convergent (\<lambda>n. setsum f {0..<n})"
   327     proof (rule Bseq_mono_convergent)
   328       show "Bseq (\<lambda>n. setsum f {0..<n})"
   329         by (rule f_inc_g_dec_Beq_f [of "(\<lambda>n. setsum f {0..<n})" "\<lambda>n. x"])
   330            (auto simp add: le pos)
   331     next
   332       show "\<forall>m n. m \<le> n \<longrightarrow> setsum f {0..<m} \<le> setsum f {0..<n}"
   333         by (auto intro: setsum_mono2 pos)
   334     qed
   335   then obtain L where "(%n. setsum f {0..<n}) ----> L"
   336     by (blast dest: convergentD)
   337   thus ?thesis
   338     by (force simp add: summable_def sums_def)
   339 qed
   340 
   341 lemma series_pos_le:
   342   fixes f :: "nat \<Rightarrow> real"
   343   shows "\<lbrakk>summable f; \<forall>m\<ge>n. 0 \<le> f m\<rbrakk> \<Longrightarrow> setsum f {0..<n} \<le> suminf f"
   344 apply (drule summable_sums)
   345 apply (simp add: sums_def)
   346 apply (cut_tac k = "setsum f {0..<n}" in LIMSEQ_const)
   347 apply (erule LIMSEQ_le, blast)
   348 apply (rule_tac x="n" in exI, clarify)
   349 apply (rule setsum_mono2)
   350 apply auto
   351 done
   352 
   353 lemma series_pos_less:
   354   fixes f :: "nat \<Rightarrow> real"
   355   shows "\<lbrakk>summable f; \<forall>m\<ge>n. 0 < f m\<rbrakk> \<Longrightarrow> setsum f {0..<n} < suminf f"
   356 apply (rule_tac y="setsum f {0..<Suc n}" in order_less_le_trans)
   357 apply simp
   358 apply (erule series_pos_le)
   359 apply (simp add: order_less_imp_le)
   360 done
   361 
   362 lemma suminf_gt_zero:
   363   fixes f :: "nat \<Rightarrow> real"
   364   shows "\<lbrakk>summable f; \<forall>n. 0 < f n\<rbrakk> \<Longrightarrow> 0 < suminf f"
   365 by (drule_tac n="0" in series_pos_less, simp_all)
   366 
   367 lemma suminf_ge_zero:
   368   fixes f :: "nat \<Rightarrow> real"
   369   shows "\<lbrakk>summable f; \<forall>n. 0 \<le> f n\<rbrakk> \<Longrightarrow> 0 \<le> suminf f"
   370 by (drule_tac n="0" in series_pos_le, simp_all)
   371 
   372 lemma sumr_pos_lt_pair:
   373   fixes f :: "nat \<Rightarrow> real"
   374   shows "\<lbrakk>summable f;
   375         \<forall>d. 0 < f (k + (Suc(Suc 0) * d)) + f (k + ((Suc(Suc 0) * d) + 1))\<rbrakk>
   376       \<Longrightarrow> setsum f {0..<k} < suminf f"
   377 unfolding One_nat_def
   378 apply (subst suminf_split_initial_segment [where k="k"])
   379 apply assumption
   380 apply simp
   381 apply (drule_tac k="k" in summable_ignore_initial_segment)
   382 apply (drule_tac k="Suc (Suc 0)" in sums_group, simp)
   383 apply simp
   384 apply (frule sums_unique)
   385 apply (drule sums_summable)
   386 apply simp
   387 apply (erule suminf_gt_zero)
   388 apply (simp add: add_ac)
   389 done
   390 
   391 text{*Sum of a geometric progression.*}
   392 
   393 lemmas sumr_geometric = geometric_sum [where 'a = real]
   394 
   395 lemma geometric_sums:
   396   fixes x :: "'a::{real_normed_field}"
   397   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) sums (1 / (1 - x))"
   398 proof -
   399   assume less_1: "norm x < 1"
   400   hence neq_1: "x \<noteq> 1" by auto
   401   hence neq_0: "x - 1 \<noteq> 0" by simp
   402   from less_1 have lim_0: "(\<lambda>n. x ^ n) ----> 0"
   403     by (rule LIMSEQ_power_zero)
   404   hence "(\<lambda>n. x ^ n / (x - 1) - 1 / (x - 1)) ----> 0 / (x - 1) - 1 / (x - 1)"
   405     using neq_0 by (intro LIMSEQ_divide LIMSEQ_diff LIMSEQ_const)
   406   hence "(\<lambda>n. (x ^ n - 1) / (x - 1)) ----> 1 / (1 - x)"
   407     by (simp add: nonzero_minus_divide_right [OF neq_0] diff_divide_distrib)
   408   thus "(\<lambda>n. x ^ n) sums (1 / (1 - x))"
   409     by (simp add: sums_def geometric_sum neq_1)
   410 qed
   411 
   412 lemma summable_geometric:
   413   fixes x :: "'a::{real_normed_field}"
   414   shows "norm x < 1 \<Longrightarrow> summable (\<lambda>n. x ^ n)"
   415 by (rule geometric_sums [THEN sums_summable])
   416 
   417 lemma half: "0 < 1 / (2::'a::{number_ring,linordered_field_inverse_zero})"
   418   by arith
   419 
   420 lemma power_half_series: "(\<lambda>n. (1/2::real)^Suc n) sums 1"
   421 proof -
   422   have 2: "(\<lambda>n. (1/2::real)^n) sums 2" using geometric_sums [of "1/2::real"]
   423     by auto
   424   have "(\<lambda>n. (1/2::real)^Suc n) = (\<lambda>n. (1 / 2) ^ n / 2)"
   425     by simp
   426   thus ?thesis using divide.sums [OF 2, of 2]
   427     by simp
   428 qed
   429 
   430 text{*Cauchy-type criterion for convergence of series (c.f. Harrison)*}
   431 
   432 lemma summable_convergent_sumr_iff:
   433  "summable f = convergent (%n. setsum f {0..<n})"
   434 by (simp add: summable_def sums_def convergent_def)
   435 
   436 lemma summable_LIMSEQ_zero:
   437   fixes f :: "nat \<Rightarrow> 'a::real_normed_field"
   438   shows "summable f \<Longrightarrow> f ----> 0"
   439 apply (drule summable_convergent_sumr_iff [THEN iffD1])
   440 apply (drule convergent_Cauchy)
   441 apply (simp only: Cauchy_iff LIMSEQ_iff, safe)
   442 apply (drule_tac x="r" in spec, safe)
   443 apply (rule_tac x="M" in exI, safe)
   444 apply (drule_tac x="Suc n" in spec, simp)
   445 apply (drule_tac x="n" in spec, simp)
   446 done
   447 
   448 lemma suminf_le:
   449   fixes x :: real
   450   shows "summable f \<Longrightarrow> (!!n. setsum f {0..<n} \<le> x) \<Longrightarrow> suminf f \<le> x"
   451   by (simp add: summable_convergent_sumr_iff suminf_eq_lim lim_le)
   452 
   453 lemma summable_Cauchy:
   454      "summable (f::nat \<Rightarrow> 'a::banach) =
   455       (\<forall>e > 0. \<exists>N. \<forall>m \<ge> N. \<forall>n. norm (setsum f {m..<n}) < e)"
   456 apply (simp only: summable_convergent_sumr_iff Cauchy_convergent_iff [symmetric] Cauchy_iff, safe)
   457 apply (drule spec, drule (1) mp)
   458 apply (erule exE, rule_tac x="M" in exI, clarify)
   459 apply (rule_tac x="m" and y="n" in linorder_le_cases)
   460 apply (frule (1) order_trans)
   461 apply (drule_tac x="n" in spec, drule (1) mp)
   462 apply (drule_tac x="m" in spec, drule (1) mp)
   463 apply (simp add: setsum_diff [symmetric])
   464 apply simp
   465 apply (drule spec, drule (1) mp)
   466 apply (erule exE, rule_tac x="N" in exI, clarify)
   467 apply (rule_tac x="m" and y="n" in linorder_le_cases)
   468 apply (subst norm_minus_commute)
   469 apply (simp add: setsum_diff [symmetric])
   470 apply (simp add: setsum_diff [symmetric])
   471 done
   472 
   473 text{*Comparison test*}
   474 
   475 lemma norm_setsum:
   476   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   477   shows "norm (setsum f A) \<le> (\<Sum>i\<in>A. norm (f i))"
   478 apply (case_tac "finite A")
   479 apply (erule finite_induct)
   480 apply simp
   481 apply simp
   482 apply (erule order_trans [OF norm_triangle_ineq add_left_mono])
   483 apply simp
   484 done
   485 
   486 lemma summable_comparison_test:
   487   fixes f :: "nat \<Rightarrow> 'a::banach"
   488   shows "\<lbrakk>\<exists>N. \<forall>n\<ge>N. norm (f n) \<le> g n; summable g\<rbrakk> \<Longrightarrow> summable f"
   489 apply (simp add: summable_Cauchy, safe)
   490 apply (drule_tac x="e" in spec, safe)
   491 apply (rule_tac x = "N + Na" in exI, safe)
   492 apply (rotate_tac 2)
   493 apply (drule_tac x = m in spec)
   494 apply (auto, rotate_tac 2, drule_tac x = n in spec)
   495 apply (rule_tac y = "\<Sum>k=m..<n. norm (f k)" in order_le_less_trans)
   496 apply (rule norm_setsum)
   497 apply (rule_tac y = "setsum g {m..<n}" in order_le_less_trans)
   498 apply (auto intro: setsum_mono simp add: abs_less_iff)
   499 done
   500 
   501 lemma summable_norm_comparison_test:
   502   fixes f :: "nat \<Rightarrow> 'a::banach"
   503   shows "\<lbrakk>\<exists>N. \<forall>n\<ge>N. norm (f n) \<le> g n; summable g\<rbrakk>
   504          \<Longrightarrow> summable (\<lambda>n. norm (f n))"
   505 apply (rule summable_comparison_test)
   506 apply (auto)
   507 done
   508 
   509 lemma summable_rabs_comparison_test:
   510   fixes f :: "nat \<Rightarrow> real"
   511   shows "\<lbrakk>\<exists>N. \<forall>n\<ge>N. \<bar>f n\<bar> \<le> g n; summable g\<rbrakk> \<Longrightarrow> summable (\<lambda>n. \<bar>f n\<bar>)"
   512 apply (rule summable_comparison_test)
   513 apply (auto)
   514 done
   515 
   516 text{*Summability of geometric series for real algebras*}
   517 
   518 lemma complete_algebra_summable_geometric:
   519   fixes x :: "'a::{real_normed_algebra_1,banach}"
   520   shows "norm x < 1 \<Longrightarrow> summable (\<lambda>n. x ^ n)"
   521 proof (rule summable_comparison_test)
   522   show "\<exists>N. \<forall>n\<ge>N. norm (x ^ n) \<le> norm x ^ n"
   523     by (simp add: norm_power_ineq)
   524   show "norm x < 1 \<Longrightarrow> summable (\<lambda>n. norm x ^ n)"
   525     by (simp add: summable_geometric)
   526 qed
   527 
   528 text{*Limit comparison property for series (c.f. jrh)*}
   529 
   530 lemma summable_le:
   531   fixes f g :: "nat \<Rightarrow> real"
   532   shows "\<lbrakk>\<forall>n. f n \<le> g n; summable f; summable g\<rbrakk> \<Longrightarrow> suminf f \<le> suminf g"
   533 apply (drule summable_sums)+
   534 apply (simp only: sums_def, erule (1) LIMSEQ_le)
   535 apply (rule exI)
   536 apply (auto intro!: setsum_mono)
   537 done
   538 
   539 lemma summable_le2:
   540   fixes f g :: "nat \<Rightarrow> real"
   541   shows "\<lbrakk>\<forall>n. \<bar>f n\<bar> \<le> g n; summable g\<rbrakk> \<Longrightarrow> summable f \<and> suminf f \<le> suminf g"
   542 apply (subgoal_tac "summable f")
   543 apply (auto intro!: summable_le)
   544 apply (simp add: abs_le_iff)
   545 apply (rule_tac g="g" in summable_comparison_test, simp_all)
   546 done
   547 
   548 (* specialisation for the common 0 case *)
   549 lemma suminf_0_le:
   550   fixes f::"nat\<Rightarrow>real"
   551   assumes gt0: "\<forall>n. 0 \<le> f n" and sm: "summable f"
   552   shows "0 \<le> suminf f"
   553 proof -
   554   let ?g = "(\<lambda>n. (0::real))"
   555   from gt0 have "\<forall>n. ?g n \<le> f n" by simp
   556   moreover have "summable ?g" by (rule summable_zero)
   557   moreover from sm have "summable f" .
   558   ultimately have "suminf ?g \<le> suminf f" by (rule summable_le)
   559   then show "0 \<le> suminf f" by (simp add: suminf_zero)
   560 qed
   561 
   562 
   563 text{*Absolute convergence imples normal convergence*}
   564 lemma summable_norm_cancel:
   565   fixes f :: "nat \<Rightarrow> 'a::banach"
   566   shows "summable (\<lambda>n. norm (f n)) \<Longrightarrow> summable f"
   567 apply (simp only: summable_Cauchy, safe)
   568 apply (drule_tac x="e" in spec, safe)
   569 apply (rule_tac x="N" in exI, safe)
   570 apply (drule_tac x="m" in spec, safe)
   571 apply (rule order_le_less_trans [OF norm_setsum])
   572 apply (rule order_le_less_trans [OF abs_ge_self])
   573 apply simp
   574 done
   575 
   576 lemma summable_rabs_cancel:
   577   fixes f :: "nat \<Rightarrow> real"
   578   shows "summable (\<lambda>n. \<bar>f n\<bar>) \<Longrightarrow> summable f"
   579 by (rule summable_norm_cancel, simp)
   580 
   581 text{*Absolute convergence of series*}
   582 lemma summable_norm:
   583   fixes f :: "nat \<Rightarrow> 'a::banach"
   584   shows "summable (\<lambda>n. norm (f n)) \<Longrightarrow> norm (suminf f) \<le> (\<Sum>n. norm (f n))"
   585 by (auto intro: LIMSEQ_le LIMSEQ_norm summable_norm_cancel
   586                 summable_sumr_LIMSEQ_suminf norm_setsum)
   587 
   588 lemma summable_rabs:
   589   fixes f :: "nat \<Rightarrow> real"
   590   shows "summable (\<lambda>n. \<bar>f n\<bar>) \<Longrightarrow> \<bar>suminf f\<bar> \<le> (\<Sum>n. \<bar>f n\<bar>)"
   591 by (fold real_norm_def, rule summable_norm)
   592 
   593 subsection{* The Ratio Test*}
   594 
   595 lemma norm_ratiotest_lemma:
   596   fixes x y :: "'a::real_normed_vector"
   597   shows "\<lbrakk>c \<le> 0; norm x \<le> c * norm y\<rbrakk> \<Longrightarrow> x = 0"
   598 apply (subgoal_tac "norm x \<le> 0", simp)
   599 apply (erule order_trans)
   600 apply (simp add: mult_le_0_iff)
   601 done
   602 
   603 lemma rabs_ratiotest_lemma: "[| c \<le> 0; abs x \<le> c * abs y |] ==> x = (0::real)"
   604 by (erule norm_ratiotest_lemma, simp)
   605 
   606 lemma le_Suc_ex: "(k::nat) \<le> l ==> (\<exists>n. l = k + n)"
   607 apply (drule le_imp_less_or_eq)
   608 apply (auto dest: less_imp_Suc_add)
   609 done
   610 
   611 lemma le_Suc_ex_iff: "((k::nat) \<le> l) = (\<exists>n. l = k + n)"
   612 by (auto simp add: le_Suc_ex)
   613 
   614 (*All this trouble just to get 0<c *)
   615 lemma ratio_test_lemma2:
   616   fixes f :: "nat \<Rightarrow> 'a::banach"
   617   shows "\<lbrakk>\<forall>n\<ge>N. norm (f (Suc n)) \<le> c * norm (f n)\<rbrakk> \<Longrightarrow> 0 < c \<or> summable f"
   618 apply (simp (no_asm) add: linorder_not_le [symmetric])
   619 apply (simp add: summable_Cauchy)
   620 apply (safe, subgoal_tac "\<forall>n. N < n --> f (n) = 0")
   621  prefer 2
   622  apply clarify
   623  apply(erule_tac x = "n - Suc 0" in allE)
   624  apply (simp add:diff_Suc split:nat.splits)
   625  apply (blast intro: norm_ratiotest_lemma)
   626 apply (rule_tac x = "Suc N" in exI, clarify)
   627 apply(simp cong:setsum_ivl_cong)
   628 done
   629 
   630 lemma ratio_test:
   631   fixes f :: "nat \<Rightarrow> 'a::banach"
   632   shows "\<lbrakk>c < 1; \<forall>n\<ge>N. norm (f (Suc n)) \<le> c * norm (f n)\<rbrakk> \<Longrightarrow> summable f"
   633 apply (frule ratio_test_lemma2, auto)
   634 apply (rule_tac g = "%n. (norm (f N) / (c ^ N))*c ^ n"
   635        in summable_comparison_test)
   636 apply (rule_tac x = N in exI, safe)
   637 apply (drule le_Suc_ex_iff [THEN iffD1])
   638 apply (auto simp add: power_add field_power_not_zero)
   639 apply (induct_tac "na", auto)
   640 apply (rule_tac y = "c * norm (f (N + n))" in order_trans)
   641 apply (auto intro: mult_right_mono simp add: summable_def)
   642 apply (rule_tac x = "norm (f N) * (1/ (1 - c)) / (c ^ N)" in exI)
   643 apply (rule sums_divide)
   644 apply (rule sums_mult)
   645 apply (auto intro!: geometric_sums)
   646 done
   647 
   648 subsection {* Cauchy Product Formula *}
   649 
   650 (* Proof based on Analysis WebNotes: Chapter 07, Class 41
   651 http://www.math.unl.edu/~webnotes/classes/class41/prp77.htm *)
   652 
   653 lemma setsum_triangle_reindex:
   654   fixes n :: nat
   655   shows "(\<Sum>(i,j)\<in>{(i,j). i+j < n}. f i j) = (\<Sum>k=0..<n. \<Sum>i=0..k. f i (k - i))"
   656 proof -
   657   have "(\<Sum>(i, j)\<in>{(i, j). i + j < n}. f i j) =
   658     (\<Sum>(k, i)\<in>(SIGMA k:{0..<n}. {0..k}). f i (k - i))"
   659   proof (rule setsum_reindex_cong)
   660     show "inj_on (\<lambda>(k,i). (i, k - i)) (SIGMA k:{0..<n}. {0..k})"
   661       by (rule inj_on_inverseI [where g="\<lambda>(i,j). (i+j, i)"], auto)
   662     show "{(i,j). i + j < n} = (\<lambda>(k,i). (i, k - i)) ` (SIGMA k:{0..<n}. {0..k})"
   663       by (safe, rule_tac x="(a+b,a)" in image_eqI, auto)
   664     show "\<And>a. (\<lambda>(k, i). f i (k - i)) a = split f ((\<lambda>(k, i). (i, k - i)) a)"
   665       by clarify
   666   qed
   667   thus ?thesis by (simp add: setsum_Sigma)
   668 qed
   669 
   670 lemma Cauchy_product_sums:
   671   fixes a b :: "nat \<Rightarrow> 'a::{real_normed_algebra,banach}"
   672   assumes a: "summable (\<lambda>k. norm (a k))"
   673   assumes b: "summable (\<lambda>k. norm (b k))"
   674   shows "(\<lambda>k. \<Sum>i=0..k. a i * b (k - i)) sums ((\<Sum>k. a k) * (\<Sum>k. b k))"
   675 proof -
   676   let ?S1 = "\<lambda>n::nat. {0..<n} \<times> {0..<n}"
   677   let ?S2 = "\<lambda>n::nat. {(i,j). i + j < n}"
   678   have S1_mono: "\<And>m n. m \<le> n \<Longrightarrow> ?S1 m \<subseteq> ?S1 n" by auto
   679   have S2_le_S1: "\<And>n. ?S2 n \<subseteq> ?S1 n" by auto
   680   have S1_le_S2: "\<And>n. ?S1 (n div 2) \<subseteq> ?S2 n" by auto
   681   have finite_S1: "\<And>n. finite (?S1 n)" by simp
   682   with S2_le_S1 have finite_S2: "\<And>n. finite (?S2 n)" by (rule finite_subset)
   683 
   684   let ?g = "\<lambda>(i,j). a i * b j"
   685   let ?f = "\<lambda>(i,j). norm (a i) * norm (b j)"
   686   have f_nonneg: "\<And>x. 0 \<le> ?f x"
   687     by (auto simp add: mult_nonneg_nonneg)
   688   hence norm_setsum_f: "\<And>A. norm (setsum ?f A) = setsum ?f A"
   689     unfolding real_norm_def
   690     by (simp only: abs_of_nonneg setsum_nonneg [rule_format])
   691 
   692   have "(\<lambda>n. (\<Sum>k=0..<n. a k) * (\<Sum>k=0..<n. b k))
   693            ----> (\<Sum>k. a k) * (\<Sum>k. b k)"
   694     by (intro LIMSEQ_mult summable_sumr_LIMSEQ_suminf
   695         summable_norm_cancel [OF a] summable_norm_cancel [OF b])
   696   hence 1: "(\<lambda>n. setsum ?g (?S1 n)) ----> (\<Sum>k. a k) * (\<Sum>k. b k)"
   697     by (simp only: setsum_product setsum_Sigma [rule_format]
   698                    finite_atLeastLessThan)
   699 
   700   have "(\<lambda>n. (\<Sum>k=0..<n. norm (a k)) * (\<Sum>k=0..<n. norm (b k)))
   701        ----> (\<Sum>k. norm (a k)) * (\<Sum>k. norm (b k))"
   702     using a b by (intro LIMSEQ_mult summable_sumr_LIMSEQ_suminf)
   703   hence "(\<lambda>n. setsum ?f (?S1 n)) ----> (\<Sum>k. norm (a k)) * (\<Sum>k. norm (b k))"
   704     by (simp only: setsum_product setsum_Sigma [rule_format]
   705                    finite_atLeastLessThan)
   706   hence "convergent (\<lambda>n. setsum ?f (?S1 n))"
   707     by (rule convergentI)
   708   hence Cauchy: "Cauchy (\<lambda>n. setsum ?f (?S1 n))"
   709     by (rule convergent_Cauchy)
   710   have "Zfun (\<lambda>n. setsum ?f (?S1 n - ?S2 n)) sequentially"
   711   proof (rule ZfunI, simp only: eventually_sequentially norm_setsum_f)
   712     fix r :: real
   713     assume r: "0 < r"
   714     from CauchyD [OF Cauchy r] obtain N
   715     where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (setsum ?f (?S1 m) - setsum ?f (?S1 n)) < r" ..
   716     hence "\<And>m n. \<lbrakk>N \<le> n; n \<le> m\<rbrakk> \<Longrightarrow> norm (setsum ?f (?S1 m - ?S1 n)) < r"
   717       by (simp only: setsum_diff finite_S1 S1_mono)
   718     hence N: "\<And>m n. \<lbrakk>N \<le> n; n \<le> m\<rbrakk> \<Longrightarrow> setsum ?f (?S1 m - ?S1 n) < r"
   719       by (simp only: norm_setsum_f)
   720     show "\<exists>N. \<forall>n\<ge>N. setsum ?f (?S1 n - ?S2 n) < r"
   721     proof (intro exI allI impI)
   722       fix n assume "2 * N \<le> n"
   723       hence n: "N \<le> n div 2" by simp
   724       have "setsum ?f (?S1 n - ?S2 n) \<le> setsum ?f (?S1 n - ?S1 (n div 2))"
   725         by (intro setsum_mono2 finite_Diff finite_S1 f_nonneg
   726                   Diff_mono subset_refl S1_le_S2)
   727       also have "\<dots> < r"
   728         using n div_le_dividend by (rule N)
   729       finally show "setsum ?f (?S1 n - ?S2 n) < r" .
   730     qed
   731   qed
   732   hence "Zfun (\<lambda>n. setsum ?g (?S1 n - ?S2 n)) sequentially"
   733     apply (rule Zfun_le [rule_format])
   734     apply (simp only: norm_setsum_f)
   735     apply (rule order_trans [OF norm_setsum setsum_mono])
   736     apply (auto simp add: norm_mult_ineq)
   737     done
   738   hence 2: "(\<lambda>n. setsum ?g (?S1 n) - setsum ?g (?S2 n)) ----> 0"
   739     unfolding tendsto_Zfun_iff diff_0_right
   740     by (simp only: setsum_diff finite_S1 S2_le_S1)
   741 
   742   with 1 have "(\<lambda>n. setsum ?g (?S2 n)) ----> (\<Sum>k. a k) * (\<Sum>k. b k)"
   743     by (rule LIMSEQ_diff_approach_zero2)
   744   thus ?thesis by (simp only: sums_def setsum_triangle_reindex)
   745 qed
   746 
   747 lemma Cauchy_product:
   748   fixes a b :: "nat \<Rightarrow> 'a::{real_normed_algebra,banach}"
   749   assumes a: "summable (\<lambda>k. norm (a k))"
   750   assumes b: "summable (\<lambda>k. norm (b k))"
   751   shows "(\<Sum>k. a k) * (\<Sum>k. b k) = (\<Sum>k. \<Sum>i=0..k. a i * b (k - i))"
   752 using a b
   753 by (rule Cauchy_product_sums [THEN sums_unique])
   754 
   755 end