src/HOL/Complex.thy
author wenzelm
Mon Mar 16 18:24:30 2009 +0100 (2009-03-16)
changeset 30549 d2d7874648bd
parent 30273 ecd6f0ca62ea
child 30729 461ee3e49ad3
permissions -rw-r--r--
simplified method setup;
     1 (*  Title:       Complex.thy
     2     Author:      Jacques D. Fleuriot
     3     Copyright:   2001 University of Edinburgh
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5 *)
     6 
     7 header {* Complex Numbers: Rectangular and Polar Representations *}
     8 
     9 theory Complex
    10 imports Transcendental
    11 begin
    12 
    13 datatype complex = Complex real real
    14 
    15 primrec
    16   Re :: "complex \<Rightarrow> real"
    17 where
    18   Re: "Re (Complex x y) = x"
    19 
    20 primrec
    21   Im :: "complex \<Rightarrow> real"
    22 where
    23   Im: "Im (Complex x y) = y"
    24 
    25 lemma complex_surj [simp]: "Complex (Re z) (Im z) = z"
    26   by (induct z) simp
    27 
    28 lemma complex_equality [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
    29   by (induct x, induct y) simp
    30 
    31 lemma expand_complex_eq: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
    32   by (induct x, induct y) simp
    33 
    34 lemmas complex_Re_Im_cancel_iff = expand_complex_eq
    35 
    36 
    37 subsection {* Addition and Subtraction *}
    38 
    39 instantiation complex :: ab_group_add
    40 begin
    41 
    42 definition
    43   complex_zero_def: "0 = Complex 0 0"
    44 
    45 definition
    46   complex_add_def: "x + y = Complex (Re x + Re y) (Im x + Im y)"
    47 
    48 definition
    49   complex_minus_def: "- x = Complex (- Re x) (- Im x)"
    50 
    51 definition
    52   complex_diff_def: "x - (y\<Colon>complex) = x + - y"
    53 
    54 lemma Complex_eq_0 [simp]: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
    55   by (simp add: complex_zero_def)
    56 
    57 lemma complex_Re_zero [simp]: "Re 0 = 0"
    58   by (simp add: complex_zero_def)
    59 
    60 lemma complex_Im_zero [simp]: "Im 0 = 0"
    61   by (simp add: complex_zero_def)
    62 
    63 lemma complex_add [simp]:
    64   "Complex a b + Complex c d = Complex (a + c) (b + d)"
    65   by (simp add: complex_add_def)
    66 
    67 lemma complex_Re_add [simp]: "Re (x + y) = Re x + Re y"
    68   by (simp add: complex_add_def)
    69 
    70 lemma complex_Im_add [simp]: "Im (x + y) = Im x + Im y"
    71   by (simp add: complex_add_def)
    72 
    73 lemma complex_minus [simp]:
    74   "- (Complex a b) = Complex (- a) (- b)"
    75   by (simp add: complex_minus_def)
    76 
    77 lemma complex_Re_minus [simp]: "Re (- x) = - Re x"
    78   by (simp add: complex_minus_def)
    79 
    80 lemma complex_Im_minus [simp]: "Im (- x) = - Im x"
    81   by (simp add: complex_minus_def)
    82 
    83 lemma complex_diff [simp]:
    84   "Complex a b - Complex c d = Complex (a - c) (b - d)"
    85   by (simp add: complex_diff_def)
    86 
    87 lemma complex_Re_diff [simp]: "Re (x - y) = Re x - Re y"
    88   by (simp add: complex_diff_def)
    89 
    90 lemma complex_Im_diff [simp]: "Im (x - y) = Im x - Im y"
    91   by (simp add: complex_diff_def)
    92 
    93 instance
    94   by intro_classes (simp_all add: complex_add_def complex_diff_def)
    95 
    96 end
    97 
    98 
    99 
   100 subsection {* Multiplication and Division *}
   101 
   102 instantiation complex :: "{field, division_by_zero}"
   103 begin
   104 
   105 definition
   106   complex_one_def: "1 = Complex 1 0"
   107 
   108 definition
   109   complex_mult_def: "x * y =
   110     Complex (Re x * Re y - Im x * Im y) (Re x * Im y + Im x * Re y)"
   111 
   112 definition
   113   complex_inverse_def: "inverse x =
   114     Complex (Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)) (- Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>))"
   115 
   116 definition
   117   complex_divide_def: "x / (y\<Colon>complex) = x * inverse y"
   118 
   119 lemma Complex_eq_1 [simp]: "(Complex a b = 1) = (a = 1 \<and> b = 0)"
   120   by (simp add: complex_one_def)
   121 
   122 lemma complex_Re_one [simp]: "Re 1 = 1"
   123   by (simp add: complex_one_def)
   124 
   125 lemma complex_Im_one [simp]: "Im 1 = 0"
   126   by (simp add: complex_one_def)
   127 
   128 lemma complex_mult [simp]:
   129   "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
   130   by (simp add: complex_mult_def)
   131 
   132 lemma complex_Re_mult [simp]: "Re (x * y) = Re x * Re y - Im x * Im y"
   133   by (simp add: complex_mult_def)
   134 
   135 lemma complex_Im_mult [simp]: "Im (x * y) = Re x * Im y + Im x * Re y"
   136   by (simp add: complex_mult_def)
   137 
   138 lemma complex_inverse [simp]:
   139   "inverse (Complex a b) = Complex (a / (a\<twosuperior> + b\<twosuperior>)) (- b / (a\<twosuperior> + b\<twosuperior>))"
   140   by (simp add: complex_inverse_def)
   141 
   142 lemma complex_Re_inverse:
   143   "Re (inverse x) = Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   144   by (simp add: complex_inverse_def)
   145 
   146 lemma complex_Im_inverse:
   147   "Im (inverse x) = - Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   148   by (simp add: complex_inverse_def)
   149 
   150 instance
   151   by intro_classes (simp_all add: complex_mult_def
   152   right_distrib left_distrib right_diff_distrib left_diff_distrib
   153   complex_inverse_def complex_divide_def
   154   power2_eq_square add_divide_distrib [symmetric]
   155   expand_complex_eq)
   156 
   157 end
   158 
   159 
   160 subsection {* Exponentiation *}
   161 
   162 instantiation complex :: recpower
   163 begin
   164 
   165 primrec power_complex where
   166   "z ^ 0     = (1\<Colon>complex)"
   167 | "z ^ Suc n = (z\<Colon>complex) * z ^ n"
   168 
   169 instance proof
   170 qed simp_all
   171 
   172 declare power_complex.simps [simp del]
   173 
   174 end
   175 
   176 
   177 subsection {* Numerals and Arithmetic *}
   178 
   179 instantiation complex :: number_ring
   180 begin
   181 
   182 definition number_of_complex where
   183   complex_number_of_def: "number_of w = (of_int w \<Colon> complex)"
   184 
   185 instance
   186   by intro_classes (simp only: complex_number_of_def)
   187 
   188 end
   189 
   190 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
   191 by (induct n) simp_all
   192 
   193 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
   194 by (induct n) simp_all
   195 
   196 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
   197 by (cases z rule: int_diff_cases) simp
   198 
   199 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
   200 by (cases z rule: int_diff_cases) simp
   201 
   202 lemma complex_Re_number_of [simp]: "Re (number_of v) = number_of v"
   203 unfolding number_of_eq by (rule complex_Re_of_int)
   204 
   205 lemma complex_Im_number_of [simp]: "Im (number_of v) = 0"
   206 unfolding number_of_eq by (rule complex_Im_of_int)
   207 
   208 lemma Complex_eq_number_of [simp]:
   209   "(Complex a b = number_of w) = (a = number_of w \<and> b = 0)"
   210 by (simp add: expand_complex_eq)
   211 
   212 
   213 subsection {* Scalar Multiplication *}
   214 
   215 instantiation complex :: real_field
   216 begin
   217 
   218 definition
   219   complex_scaleR_def: "scaleR r x = Complex (r * Re x) (r * Im x)"
   220 
   221 lemma complex_scaleR [simp]:
   222   "scaleR r (Complex a b) = Complex (r * a) (r * b)"
   223   unfolding complex_scaleR_def by simp
   224 
   225 lemma complex_Re_scaleR [simp]: "Re (scaleR r x) = r * Re x"
   226   unfolding complex_scaleR_def by simp
   227 
   228 lemma complex_Im_scaleR [simp]: "Im (scaleR r x) = r * Im x"
   229   unfolding complex_scaleR_def by simp
   230 
   231 instance
   232 proof
   233   fix a b :: real and x y :: complex
   234   show "scaleR a (x + y) = scaleR a x + scaleR a y"
   235     by (simp add: expand_complex_eq right_distrib)
   236   show "scaleR (a + b) x = scaleR a x + scaleR b x"
   237     by (simp add: expand_complex_eq left_distrib)
   238   show "scaleR a (scaleR b x) = scaleR (a * b) x"
   239     by (simp add: expand_complex_eq mult_assoc)
   240   show "scaleR 1 x = x"
   241     by (simp add: expand_complex_eq)
   242   show "scaleR a x * y = scaleR a (x * y)"
   243     by (simp add: expand_complex_eq algebra_simps)
   244   show "x * scaleR a y = scaleR a (x * y)"
   245     by (simp add: expand_complex_eq algebra_simps)
   246 qed
   247 
   248 end
   249 
   250 
   251 subsection{* Properties of Embedding from Reals *}
   252 
   253 abbreviation
   254   complex_of_real :: "real \<Rightarrow> complex" where
   255     "complex_of_real \<equiv> of_real"
   256 
   257 lemma complex_of_real_def: "complex_of_real r = Complex r 0"
   258 by (simp add: of_real_def complex_scaleR_def)
   259 
   260 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
   261 by (simp add: complex_of_real_def)
   262 
   263 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
   264 by (simp add: complex_of_real_def)
   265 
   266 lemma Complex_add_complex_of_real [simp]:
   267      "Complex x y + complex_of_real r = Complex (x+r) y"
   268 by (simp add: complex_of_real_def)
   269 
   270 lemma complex_of_real_add_Complex [simp]:
   271      "complex_of_real r + Complex x y = Complex (r+x) y"
   272 by (simp add: complex_of_real_def)
   273 
   274 lemma Complex_mult_complex_of_real:
   275      "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
   276 by (simp add: complex_of_real_def)
   277 
   278 lemma complex_of_real_mult_Complex:
   279      "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
   280 by (simp add: complex_of_real_def)
   281 
   282 
   283 subsection {* Vector Norm *}
   284 
   285 instantiation complex :: real_normed_field
   286 begin
   287 
   288 definition
   289   complex_norm_def: "norm z = sqrt ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   290 
   291 abbreviation
   292   cmod :: "complex \<Rightarrow> real" where
   293   "cmod \<equiv> norm"
   294 
   295 definition
   296   complex_sgn_def: "sgn x = x /\<^sub>R cmod x"
   297 
   298 lemmas cmod_def = complex_norm_def
   299 
   300 lemma complex_norm [simp]: "cmod (Complex x y) = sqrt (x\<twosuperior> + y\<twosuperior>)"
   301   by (simp add: complex_norm_def)
   302 
   303 instance
   304 proof
   305   fix r :: real and x y :: complex
   306   show "0 \<le> norm x"
   307     by (induct x) simp
   308   show "(norm x = 0) = (x = 0)"
   309     by (induct x) simp
   310   show "norm (x + y) \<le> norm x + norm y"
   311     by (induct x, induct y)
   312        (simp add: real_sqrt_sum_squares_triangle_ineq)
   313   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   314     by (induct x)
   315        (simp add: power_mult_distrib right_distrib [symmetric] real_sqrt_mult)
   316   show "norm (x * y) = norm x * norm y"
   317     by (induct x, induct y)
   318        (simp add: real_sqrt_mult [symmetric] power2_eq_square algebra_simps)
   319   show "sgn x = x /\<^sub>R cmod x" by(simp add: complex_sgn_def)
   320 qed
   321 
   322 end
   323 
   324 lemma cmod_unit_one [simp]: "cmod (Complex (cos a) (sin a)) = 1"
   325 by simp
   326 
   327 lemma cmod_complex_polar [simp]:
   328      "cmod (complex_of_real r * Complex (cos a) (sin a)) = abs r"
   329 by (simp add: norm_mult)
   330 
   331 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
   332 unfolding complex_norm_def
   333 by (rule real_sqrt_sum_squares_ge1)
   334 
   335 lemma complex_mod_minus_le_complex_mod [simp]: "- cmod x \<le> cmod x"
   336 by (rule order_trans [OF _ norm_ge_zero], simp)
   337 
   338 lemma complex_mod_triangle_ineq2 [simp]: "cmod(b + a) - cmod b \<le> cmod a"
   339 by (rule ord_le_eq_trans [OF norm_triangle_ineq2], simp)
   340 
   341 lemmas real_sum_squared_expand = power2_sum [where 'a=real]
   342 
   343 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
   344 by (cases x) simp
   345 
   346 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
   347 by (cases x) simp
   348 
   349 subsection {* Completeness of the Complexes *}
   350 
   351 interpretation Re!: bounded_linear "Re"
   352 apply (unfold_locales, simp, simp)
   353 apply (rule_tac x=1 in exI)
   354 apply (simp add: complex_norm_def)
   355 done
   356 
   357 interpretation Im!: bounded_linear "Im"
   358 apply (unfold_locales, simp, simp)
   359 apply (rule_tac x=1 in exI)
   360 apply (simp add: complex_norm_def)
   361 done
   362 
   363 lemma LIMSEQ_Complex:
   364   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. Complex (X n) (Y n)) ----> Complex a b"
   365 apply (rule LIMSEQ_I)
   366 apply (subgoal_tac "0 < r / sqrt 2")
   367 apply (drule_tac r="r / sqrt 2" in LIMSEQ_D, safe)
   368 apply (drule_tac r="r / sqrt 2" in LIMSEQ_D, safe)
   369 apply (rename_tac M N, rule_tac x="max M N" in exI, safe)
   370 apply (simp add: real_sqrt_sum_squares_less)
   371 apply (simp add: divide_pos_pos)
   372 done
   373 
   374 instance complex :: banach
   375 proof
   376   fix X :: "nat \<Rightarrow> complex"
   377   assume X: "Cauchy X"
   378   from Re.Cauchy [OF X] have 1: "(\<lambda>n. Re (X n)) ----> lim (\<lambda>n. Re (X n))"
   379     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   380   from Im.Cauchy [OF X] have 2: "(\<lambda>n. Im (X n)) ----> lim (\<lambda>n. Im (X n))"
   381     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   382   have "X ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
   383     using LIMSEQ_Complex [OF 1 2] by simp
   384   thus "convergent X"
   385     by (rule convergentI)
   386 qed
   387 
   388 
   389 subsection {* The Complex Number @{term "\<i>"} *}
   390 
   391 definition
   392   "ii" :: complex  ("\<i>") where
   393   i_def: "ii \<equiv> Complex 0 1"
   394 
   395 lemma complex_Re_i [simp]: "Re ii = 0"
   396 by (simp add: i_def)
   397 
   398 lemma complex_Im_i [simp]: "Im ii = 1"
   399 by (simp add: i_def)
   400 
   401 lemma Complex_eq_i [simp]: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
   402 by (simp add: i_def)
   403 
   404 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
   405 by (simp add: expand_complex_eq)
   406 
   407 lemma complex_i_not_one [simp]: "ii \<noteq> 1"
   408 by (simp add: expand_complex_eq)
   409 
   410 lemma complex_i_not_number_of [simp]: "ii \<noteq> number_of w"
   411 by (simp add: expand_complex_eq)
   412 
   413 lemma i_mult_Complex [simp]: "ii * Complex a b = Complex (- b) a"
   414 by (simp add: expand_complex_eq)
   415 
   416 lemma Complex_mult_i [simp]: "Complex a b * ii = Complex (- b) a"
   417 by (simp add: expand_complex_eq)
   418 
   419 lemma i_complex_of_real [simp]: "ii * complex_of_real r = Complex 0 r"
   420 by (simp add: i_def complex_of_real_def)
   421 
   422 lemma complex_of_real_i [simp]: "complex_of_real r * ii = Complex 0 r"
   423 by (simp add: i_def complex_of_real_def)
   424 
   425 lemma i_squared [simp]: "ii * ii = -1"
   426 by (simp add: i_def)
   427 
   428 lemma power2_i [simp]: "ii\<twosuperior> = -1"
   429 by (simp add: power2_eq_square)
   430 
   431 lemma inverse_i [simp]: "inverse ii = - ii"
   432 by (rule inverse_unique, simp)
   433 
   434 
   435 subsection {* Complex Conjugation *}
   436 
   437 definition
   438   cnj :: "complex \<Rightarrow> complex" where
   439   "cnj z = Complex (Re z) (- Im z)"
   440 
   441 lemma complex_cnj [simp]: "cnj (Complex a b) = Complex a (- b)"
   442 by (simp add: cnj_def)
   443 
   444 lemma complex_Re_cnj [simp]: "Re (cnj x) = Re x"
   445 by (simp add: cnj_def)
   446 
   447 lemma complex_Im_cnj [simp]: "Im (cnj x) = - Im x"
   448 by (simp add: cnj_def)
   449 
   450 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
   451 by (simp add: expand_complex_eq)
   452 
   453 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
   454 by (simp add: cnj_def)
   455 
   456 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
   457 by (simp add: expand_complex_eq)
   458 
   459 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
   460 by (simp add: expand_complex_eq)
   461 
   462 lemma complex_cnj_add: "cnj (x + y) = cnj x + cnj y"
   463 by (simp add: expand_complex_eq)
   464 
   465 lemma complex_cnj_diff: "cnj (x - y) = cnj x - cnj y"
   466 by (simp add: expand_complex_eq)
   467 
   468 lemma complex_cnj_minus: "cnj (- x) = - cnj x"
   469 by (simp add: expand_complex_eq)
   470 
   471 lemma complex_cnj_one [simp]: "cnj 1 = 1"
   472 by (simp add: expand_complex_eq)
   473 
   474 lemma complex_cnj_mult: "cnj (x * y) = cnj x * cnj y"
   475 by (simp add: expand_complex_eq)
   476 
   477 lemma complex_cnj_inverse: "cnj (inverse x) = inverse (cnj x)"
   478 by (simp add: complex_inverse_def)
   479 
   480 lemma complex_cnj_divide: "cnj (x / y) = cnj x / cnj y"
   481 by (simp add: complex_divide_def complex_cnj_mult complex_cnj_inverse)
   482 
   483 lemma complex_cnj_power: "cnj (x ^ n) = cnj x ^ n"
   484 by (induct n, simp_all add: complex_cnj_mult)
   485 
   486 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
   487 by (simp add: expand_complex_eq)
   488 
   489 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
   490 by (simp add: expand_complex_eq)
   491 
   492 lemma complex_cnj_number_of [simp]: "cnj (number_of w) = number_of w"
   493 by (simp add: expand_complex_eq)
   494 
   495 lemma complex_cnj_scaleR: "cnj (scaleR r x) = scaleR r (cnj x)"
   496 by (simp add: expand_complex_eq)
   497 
   498 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
   499 by (simp add: complex_norm_def)
   500 
   501 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
   502 by (simp add: expand_complex_eq)
   503 
   504 lemma complex_cnj_i [simp]: "cnj ii = - ii"
   505 by (simp add: expand_complex_eq)
   506 
   507 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
   508 by (simp add: expand_complex_eq)
   509 
   510 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
   511 by (simp add: expand_complex_eq)
   512 
   513 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   514 by (simp add: expand_complex_eq power2_eq_square)
   515 
   516 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<twosuperior>"
   517 by (simp add: norm_mult power2_eq_square)
   518 
   519 interpretation cnj!: bounded_linear "cnj"
   520 apply (unfold_locales)
   521 apply (rule complex_cnj_add)
   522 apply (rule complex_cnj_scaleR)
   523 apply (rule_tac x=1 in exI, simp)
   524 done
   525 
   526 
   527 subsection{*The Functions @{term sgn} and @{term arg}*}
   528 
   529 text {*------------ Argand -------------*}
   530 
   531 definition
   532   arg :: "complex => real" where
   533   "arg z = (SOME a. Re(sgn z) = cos a & Im(sgn z) = sin a & -pi < a & a \<le> pi)"
   534 
   535 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
   536 by (simp add: complex_sgn_def divide_inverse scaleR_conv_of_real mult_commute)
   537 
   538 lemma i_mult_eq: "ii * ii = complex_of_real (-1)"
   539 by (simp add: i_def complex_of_real_def)
   540 
   541 lemma i_mult_eq2 [simp]: "ii * ii = -(1::complex)"
   542 by (simp add: i_def complex_one_def)
   543 
   544 lemma complex_eq_cancel_iff2 [simp]:
   545      "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
   546 by (simp add: complex_of_real_def)
   547 
   548 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
   549 by (simp add: complex_sgn_def divide_inverse)
   550 
   551 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
   552 by (simp add: complex_sgn_def divide_inverse)
   553 
   554 lemma complex_inverse_complex_split:
   555      "inverse(complex_of_real x + ii * complex_of_real y) =
   556       complex_of_real(x/(x ^ 2 + y ^ 2)) -
   557       ii * complex_of_real(y/(x ^ 2 + y ^ 2))"
   558 by (simp add: complex_of_real_def i_def diff_minus divide_inverse)
   559 
   560 (*----------------------------------------------------------------------------*)
   561 (* Many of the theorems below need to be moved elsewhere e.g. Transc. Also *)
   562 (* many of the theorems are not used - so should they be kept?                *)
   563 (*----------------------------------------------------------------------------*)
   564 
   565 lemma cos_arg_i_mult_zero_pos:
   566    "0 < y ==> cos (arg(Complex 0 y)) = 0"
   567 apply (simp add: arg_def abs_if)
   568 apply (rule_tac a = "pi/2" in someI2, auto)
   569 apply (rule order_less_trans [of _ 0], auto)
   570 done
   571 
   572 lemma cos_arg_i_mult_zero_neg:
   573    "y < 0 ==> cos (arg(Complex 0 y)) = 0"
   574 apply (simp add: arg_def abs_if)
   575 apply (rule_tac a = "- pi/2" in someI2, auto)
   576 apply (rule order_trans [of _ 0], auto)
   577 done
   578 
   579 lemma cos_arg_i_mult_zero [simp]:
   580      "y \<noteq> 0 ==> cos (arg(Complex 0 y)) = 0"
   581 by (auto simp add: linorder_neq_iff cos_arg_i_mult_zero_pos cos_arg_i_mult_zero_neg)
   582 
   583 
   584 subsection{*Finally! Polar Form for Complex Numbers*}
   585 
   586 definition
   587 
   588   (* abbreviation for (cos a + i sin a) *)
   589   cis :: "real => complex" where
   590   "cis a = Complex (cos a) (sin a)"
   591 
   592 definition
   593   (* abbreviation for r*(cos a + i sin a) *)
   594   rcis :: "[real, real] => complex" where
   595   "rcis r a = complex_of_real r * cis a"
   596 
   597 definition
   598   (* e ^ (x + iy) *)
   599   expi :: "complex => complex" where
   600   "expi z = complex_of_real(exp (Re z)) * cis (Im z)"
   601 
   602 lemma complex_split_polar:
   603      "\<exists>r a. z = complex_of_real r * (Complex (cos a) (sin a))"
   604 apply (induct z)
   605 apply (auto simp add: polar_Ex complex_of_real_mult_Complex)
   606 done
   607 
   608 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
   609 apply (induct z)
   610 apply (simp add: rcis_def cis_def polar_Ex complex_of_real_mult_Complex)
   611 done
   612 
   613 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
   614 by (simp add: rcis_def cis_def)
   615 
   616 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
   617 by (simp add: rcis_def cis_def)
   618 
   619 lemma sin_cos_squared_add2_mult: "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior>"
   620 proof -
   621   have "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior> * ((cos a)\<twosuperior> + (sin a)\<twosuperior>)"
   622     by (simp only: power_mult_distrib right_distrib)
   623   thus ?thesis by simp
   624 qed
   625 
   626 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"
   627 by (simp add: rcis_def cis_def sin_cos_squared_add2_mult)
   628 
   629 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
   630 by (simp add: cmod_def power2_eq_square)
   631 
   632 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
   633 by simp
   634 
   635 
   636 (*---------------------------------------------------------------------------*)
   637 (*  (r1 * cis a) * (r2 * cis b) = r1 * r2 * cis (a + b)                      *)
   638 (*---------------------------------------------------------------------------*)
   639 
   640 lemma cis_rcis_eq: "cis a = rcis 1 a"
   641 by (simp add: rcis_def)
   642 
   643 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
   644 by (simp add: rcis_def cis_def cos_add sin_add right_distrib right_diff_distrib
   645               complex_of_real_def)
   646 
   647 lemma cis_mult: "cis a * cis b = cis (a + b)"
   648 by (simp add: cis_rcis_eq rcis_mult)
   649 
   650 lemma cis_zero [simp]: "cis 0 = 1"
   651 by (simp add: cis_def complex_one_def)
   652 
   653 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
   654 by (simp add: rcis_def)
   655 
   656 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
   657 by (simp add: rcis_def)
   658 
   659 lemma complex_of_real_minus_one:
   660    "complex_of_real (-(1::real)) = -(1::complex)"
   661 by (simp add: complex_of_real_def complex_one_def)
   662 
   663 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
   664 by (simp add: mult_assoc [symmetric])
   665 
   666 
   667 lemma cis_real_of_nat_Suc_mult:
   668    "cis (real (Suc n) * a) = cis a * cis (real n * a)"
   669 by (simp add: cis_def real_of_nat_Suc left_distrib cos_add sin_add right_distrib)
   670 
   671 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
   672 apply (induct_tac "n")
   673 apply (auto simp add: cis_real_of_nat_Suc_mult)
   674 done
   675 
   676 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
   677 by (simp add: rcis_def power_mult_distrib DeMoivre)
   678 
   679 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
   680 by (simp add: cis_def complex_inverse_complex_split diff_minus)
   681 
   682 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
   683 by (simp add: divide_inverse rcis_def)
   684 
   685 lemma cis_divide: "cis a / cis b = cis (a - b)"
   686 by (simp add: complex_divide_def cis_mult real_diff_def)
   687 
   688 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
   689 apply (simp add: complex_divide_def)
   690 apply (case_tac "r2=0", simp)
   691 apply (simp add: rcis_inverse rcis_mult real_diff_def)
   692 done
   693 
   694 lemma Re_cis [simp]: "Re(cis a) = cos a"
   695 by (simp add: cis_def)
   696 
   697 lemma Im_cis [simp]: "Im(cis a) = sin a"
   698 by (simp add: cis_def)
   699 
   700 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
   701 by (auto simp add: DeMoivre)
   702 
   703 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
   704 by (auto simp add: DeMoivre)
   705 
   706 lemma expi_add: "expi(a + b) = expi(a) * expi(b)"
   707 by (simp add: expi_def exp_add cis_mult [symmetric] mult_ac)
   708 
   709 lemma expi_zero [simp]: "expi (0::complex) = 1"
   710 by (simp add: expi_def)
   711 
   712 lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"
   713 apply (insert rcis_Ex [of z])
   714 apply (auto simp add: expi_def rcis_def mult_assoc [symmetric])
   715 apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
   716 done
   717 
   718 lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"
   719 by (simp add: expi_def cis_def)
   720 
   721 end